compiler/iface/TcIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type checking of type signatures in interface files
   7
   8 \begin{code}
   9 module TcIface (
  10         tcImportDecl, checkWiredInTyCon, tcHiBootIface, typecheckIface,
  11         tcIfaceDecl, tcIfaceInst, tcIfaceFamInst, tcIfaceRules, tcIfaceGlobal,
  12         tcExtCoreBindings
  13  ) where
  14
  15 #include "HsVersions.h"
  16
  17 import IfaceSyn
  18 import LoadIface
  19 import IfaceEnv
  20 import BuildTyCl
  21 import TcRnMonad
  22 import Type
  23 import TypeRep
  24 import HscTypes
  25 import InstEnv
  26 import FamInstEnv
  27 import CoreSyn
  28 import CoreUtils
  29 import CoreUnfold
  30 import CoreLint
  31 import WorkWrap
  32 import Id
  33 import MkId
  34 import IdInfo
  35 import Class
  36 import TyCon
  37 import DataCon
  38 import TysWiredIn
  39 import Var              ( TyVar )
  40 import qualified Var
  41 import Name
  42 import NameEnv
  43 import NameSet
  44 import OccName
  45 import Module
  46 import UniqFM
  47 import UniqSupply
  48 import Outputable
  49 import ErrUtils
  50 import Maybes
  51 import SrcLoc
  52 import DynFlags
  53 import Control.Monad
  54
  55 import Data.List
  56 import Data.Maybe
  57 \end{code}
  58
  59 This module takes
  60
  61         IfaceDecl -> TyThing
  62         IfaceType -> Type
  63         etc
  64
  65 An IfaceDecl is populated with RdrNames, and these are not renamed to
  66 Names before typechecking, because there should be no scope errors etc.
  67
  68         -- For (b) consider: f = $(...h....)
  69         -- where h is imported, and calls f via an hi-boot file.
  70         -- This is bad!  But it is not seen as a staging error, because h
  71         -- is indeed imported.  We don't want the type-checker to black-hole
  72         -- when simplifying and compiling the splice!
  73         --
  74         -- Simple solution: discard any unfolding that mentions a variable
  75         -- bound in this module (and hence not yet processed).
  76         -- The discarding happens when forkM finds a type error.
  77
  78 %************************************************************************
  79 %*                                                                      *
  80 %*      tcImportDecl is the key function for "faulting in"              *
  81 %*      imported things
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 The main idea is this.  We are chugging along type-checking source code, and
  86 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  87 it in the EPS type envt.  So it
  88         1 loads GHC.Base.hi
  89         2 gets the decl for GHC.Base.map
  90         3 typechecks it via tcIfaceDecl
  91         4 and adds it to the type env in the EPS
  92
  93 Note that DURING STEP 4, we may find that map's type mentions a type
  94 constructor that also
  95
  96 Notice that for imported things we read the current version from the EPS
  97 mutable variable.  This is important in situations like
  98         ...$(e1)...$(e2)...
  99 where the code that e1 expands to might import some defns that
 100 also turn out to be needed by the code that e2 expands to.
 101
 102 \begin{code}
 103 tcImportDecl :: Name -> TcM TyThing
 104 -- Entry point for *source-code* uses of importDecl
 105 tcImportDecl name
 106   | Just thing <- wiredInNameTyThing_maybe name
 107   = do  { initIfaceTcRn (loadWiredInHomeIface name)
 108         ; return thing }
 109   | otherwise
 110   = do  { traceIf (text "tcImportDecl" <+> ppr name)
 111         ; mb_thing <- initIfaceTcRn (importDecl name)
 112         ; case mb_thing of
 113             Succeeded thing -> return thing
 114             Failed err      -> failWithTc err }
 115
 116 checkWiredInTyCon :: TyCon -> TcM ()
 117 -- Ensure that the home module of the TyCon (and hence its instances)
 118 -- are loaded. It might not be a wired-in tycon (see the calls in TcUnify),
 119 -- in which case this is a no-op.
 120 checkWiredInTyCon tc
 121   | not (isWiredInName tc_name)
 122   = return ()
 123   | otherwise
 124   = do  { mod <- getModule
 125         ; unless (mod == nameModule tc_name)
 126                  (initIfaceTcRn (loadWiredInHomeIface tc_name))
 127                 -- Don't look for (non-existent) Float.hi when
 128                 -- compiling Float.lhs, which mentions Float of course
 129                 -- A bit yukky to call initIfaceTcRn here
 130         }
 131   where
 132     tc_name = tyConName tc
 133
 134 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 135 -- Get the TyThing for this Name from an interface file
 136 -- It's not a wired-in thing -- the caller caught that
 137 importDecl name
 138   = ASSERT( not (isWiredInName name) )
 139     do  { traceIf nd_doc
 140
 141         -- Load the interface, which should populate the PTE
 142         ; mb_iface <- loadInterface nd_doc (nameModule name) ImportBySystem
 143         ; case mb_iface of {
 144                 Failed err_msg  -> return (Failed err_msg) ;
 145                 Succeeded iface -> do
 146
 147         -- Now look it up again; this time we should find it
 148         { eps <- getEps
 149         ; case lookupTypeEnv (eps_PTE eps) name of
 150             Just thing -> return (Succeeded thing)
 151             Nothing    -> return (Failed not_found_msg)
 152     }}}
 153   where
 154     nd_doc = ptext SLIT("Need decl for") <+> ppr name
 155     not_found_msg = hang (ptext SLIT("Can't find interface-file declaration for") <+>
 156                                 pprNameSpace (occNameSpace (nameOccName name)) <+> ppr name)
 157                        2 (vcat [ptext SLIT("Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 158                                 ptext SLIT("Use -ddump-if-trace to get an idea of which file caused the error")])
 159 \end{code}
 160
 161 %************************************************************************
 162 %*                                                                      *
 163                 Type-checking a complete interface
 164 %*                                                                      *
 165 %************************************************************************
 166
 167 Suppose we discover we don't need to recompile.  Then we must type
 168 check the old interface file.  This is a bit different to the
 169 incremental type checking we do as we suck in interface files.  Instead
 170 we do things similarly as when we are typechecking source decls: we
 171 bring into scope the type envt for the interface all at once, using a
 172 knot.  Remember, the decls aren't necessarily in dependency order --
 173 and even if they were, the type decls might be mutually recursive.
 174
 175 \begin{code}
 176 typecheckIface :: ModIface      -- Get the decls from here
 177                -> TcRnIf gbl lcl ModDetails
 178 typecheckIface iface
 179   = initIfaceTc iface $ \ tc_env_var -> do
 180         -- The tc_env_var is freshly allocated, private to
 181         -- type-checking this particular interface
 182         {       -- Get the right set of decls and rules.  If we are compiling without -O
 183                 -- we discard pragmas before typechecking, so that we don't "see"
 184                 -- information that we shouldn't.  From a versioning point of view
 185                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 186                 -- to handle unboxed tuples, so it must not see unfoldings.
 187           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 188
 189                 -- Typecheck the decls.  This is done lazily, so that the knot-tying
 190                 -- within this single module work out right.  In the If monad there is
 191                 -- no global envt for the current interface; instead, the knot is tied
 192                 -- through the if_rec_types field of IfGblEnv
 193         ; names_w_things <- loadDecls ignore_prags (mi_decls iface)
 194         ; let type_env = mkNameEnv names_w_things
 195         ; writeMutVar tc_env_var type_env
 196
 197                 -- Now do those rules and instances
 198         ; insts     <- mapM tcIfaceInst    (mi_insts     iface)
 199         ; fam_insts <- mapM tcIfaceFamInst (mi_fam_insts iface)
 200         ; rules     <- tcIfaceRules ignore_prags (mi_rules iface)
 201
 202                 -- Vectorisation information
 203         ; let vect_info = VectInfo
 204                            (mkNameSet (ifaceVectInfoCCVar (mi_vect_info iface)))
 205
 206                 -- Exports
 207         ; exports <- ifaceExportNames (mi_exports iface)
 208
 209                 -- Finished
 210         ; traceIf (vcat [text "Finished typechecking interface for" <+> ppr (mi_module iface),
 211                          text "Type envt:" <+> ppr type_env])
 212         ; return $ ModDetails { md_types     = type_env
 213                               , md_insts     = insts
 214                               , md_fam_insts = fam_insts
 215                               , md_rules     = rules
 216                               , md_vect_info = vect_info
 217                               , md_exports   = exports
 218                               , md_modBreaks = emptyModBreaks
 219                               }
 220     }
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226                 Type and class declarations
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 \begin{code}
 231 tcHiBootIface :: HscSource -> Module -> TcRn ModDetails
 232 -- Load the hi-boot iface for the module being compiled,
 233 -- if it indeed exists in the transitive closure of imports
 234 -- Return the ModDetails, empty if no hi-boot iface
 235 tcHiBootIface hsc_src mod
 236   | isHsBoot hsc_src            -- Already compiling a hs-boot file
 237   = return emptyModDetails
 238   | otherwise
 239   = do  { traceIf (text "loadHiBootInterface" <+> ppr mod)
 240
 241         ; mode <- getGhcMode
 242         ; if not (isOneShot mode)
 243                 -- In --make and interactive mode, if this module has an hs-boot file
 244                 -- we'll have compiled it already, and it'll be in the HPT
 245                 --
 246                 -- We check wheher the interface is a *boot* interface.
 247                 -- It can happen (when using GHC from Visual Studio) that we
 248                 -- compile a module in TypecheckOnly mode, with a stable,
 249                 -- fully-populated HPT.  In that case the boot interface isn't there
 250                 -- (it's been replaced by the mother module) so we can't check it.
 251                 -- And that's fine, because if M's ModInfo is in the HPT, then
 252                 -- it's been compiled once, and we don't need to check the boot iface
 253           then do { hpt <- getHpt
 254                   ; case lookupUFM hpt (moduleName mod) of
 255                       Just info | mi_boot (hm_iface info)
 256                                 -> return (hm_details info)
 257                       other -> return emptyModDetails }
 258           else do
 259
 260         -- OK, so we're in one-shot mode.
 261         -- In that case, we're read all the direct imports by now,
 262         -- so eps_is_boot will record if any of our imports mention us by
 263         -- way of hi-boot file
 264         { eps <- getEps
 265         ; case lookupUFM (eps_is_boot eps) (moduleName mod) of {
 266             Nothing -> return emptyModDetails ; -- The typical case
 267
 268             Just (_, False) -> failWithTc moduleLoop ;
 269                 -- Someone below us imported us!
 270                 -- This is a loop with no hi-boot in the way
 271
 272             Just (_mod, True) ->        -- There's a hi-boot interface below us
 273
 274     do  { read_result <- findAndReadIface
 275                                 need mod
 276                                 True    -- Hi-boot file
 277
 278         ; case read_result of
 279                 Failed err               -> failWithTc (elaborate err)
 280                 Succeeded (iface, _path) -> typecheckIface iface
 281     }}}}
 282   where
 283     need = ptext SLIT("Need the hi-boot interface for") <+> ppr mod
 284                  <+> ptext SLIT("to compare against the Real Thing")
 285
 286     moduleLoop = ptext SLIT("Circular imports: module") <+> quotes (ppr mod)
 287                      <+> ptext SLIT("depends on itself")
 288
 289     elaborate err = hang (ptext SLIT("Could not find hi-boot interface for") <+>
 290                           quotes (ppr mod) <> colon) 4 err
 291 \end{code}
 292
 293
 294 %************************************************************************
 295 %*                                                                      *
 296                 Type and class declarations
 297 %*                                                                      *
 298 %************************************************************************
 299
 300 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 301 the constructor argument types.  This is in the hope that we may never
 302 poke on those argument types, and hence may never need to load the
 303 interface files for types mentioned in the arg types.
 304
 305 E.g.
 306         data Foo.S = MkS Baz.T
 307 Mabye we can get away without even loading the interface for Baz!
 308
 309 This is not just a performance thing.  Suppose we have
 310         data Foo.S = MkS Baz.T
 311         data Baz.T = MkT Foo.S
 312 (in different interface files, of course).
 313 Now, first we load and typecheck Foo.S, and add it to the type envt.
 314 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 315 If we explore MkT's argument we'll find Foo.S already in the envt.
 316
 317 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 318 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 319 which isn't done yet.
 320
 321 All very cunning. However, there is a rather subtle gotcha which bit
 322 me when developing this stuff.  When we typecheck the decl for S, we
 323 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 324 (a bug, but it happened) that the list of implicit Ids depended in
 325 turn on the constructor arg types.  Then the following sequence of
 326 events takes place:
 327         * we build a thunk <t> for the constructor arg tys
 328         * we build a thunk for the extended type environment (depends on <t>)
 329         * we write the extended type envt into the global EPS mutvar
 330
 331 Now we look something up in the type envt
 332         * that pulls on <t>
 333         * which reads the global type envt out of the global EPS mutvar
 334         * but that depends in turn on <t>
 335
 336 It's subtle, because, it'd work fine if we typechecked the constructor args
 337 eagerly -- they don't need the extended type envt.  They just get the extended
 338 type envt by accident, because they look at it later.
 339
 340 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 341 the forkM stuff.
 342
 343
 344 \begin{code}
 345 tcIfaceDecl :: Bool     -- True <=> discard IdInfo on IfaceId bindings
 346             -> IfaceDecl
 347             -> IfL TyThing
 348
 349 tcIfaceDecl ignore_prags (IfaceId {ifName = occ_name, ifType = iface_type, ifIdInfo = info})
 350   = do  { name <- lookupIfaceTop occ_name
 351         ; ty <- tcIfaceType iface_type
 352         ; info <- tcIdInfo ignore_prags name ty info
 353         ; return (AnId (mkVanillaGlobal name ty info)) }
 354
 355 tcIfaceDecl ignore_prags
 356             (IfaceData {ifName = occ_name,
 357                         ifTyVars = tv_bndrs,
 358                         ifCtxt = ctxt, ifGadtSyntax = gadt_syn,
 359                         ifCons = rdr_cons,
 360                         ifRec = is_rec,
 361                         ifGeneric = want_generic,
 362                         ifFamInst = mb_family })
 363   = do  { tc_name <- lookupIfaceTop occ_name
 364         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 365
 366         { tycon <- fixM ( \ tycon -> do
 367             { stupid_theta <- tcIfaceCtxt ctxt
 368             ; famInst <-
 369                 case mb_family of
 370                   Nothing         -> return Nothing
 371                   Just (fam, tys) ->
 372                     do { famTyCon <- tcIfaceTyCon fam
 373                        ; insttys <- mapM tcIfaceType tys
 374                        ; return $ Just (famTyCon, insttys)
 375                        }
 376             ; cons <- tcIfaceDataCons tc_name tycon tyvars rdr_cons
 377             ; buildAlgTyCon tc_name tyvars stupid_theta
 378                             cons is_rec want_generic gadt_syn famInst
 379             })
 380         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 381         ; return (ATyCon tycon)
 382     }}
 383
 384 tcIfaceDecl ignore_prags
 385             (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 386                        ifOpenSyn = isOpen, ifSynRhs = rdr_rhs_ty})
 387    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 388      { tc_name <- lookupIfaceTop occ_name
 389      ; rhs_tyki <- tcIfaceType rdr_rhs_ty
 390      ; let rhs = if isOpen then OpenSynTyCon rhs_tyki Nothing
 391                            else SynonymTyCon rhs_tyki
 392      -- !!!TODO: read mb_family info from iface and pass as last argument
 393      ; tycon <- buildSynTyCon tc_name tyvars rhs Nothing
 394      ; return $ ATyCon tycon
 395      }
 396
 397 tcIfaceDecl ignore_prags
 398             (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name,
 399                          ifTyVars = tv_bndrs, ifFDs = rdr_fds,
 400                          ifATs = rdr_ats, ifSigs = rdr_sigs,
 401                          ifRec = tc_isrec })
 402 -- ToDo: in hs-boot files we should really treat abstract classes specially,
 403 --       as we do abstract tycons
 404   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 405     { cls_name <- lookupIfaceTop occ_name
 406     ; ctxt <- tcIfaceCtxt rdr_ctxt
 407     ; sigs <- mappM tc_sig rdr_sigs
 408     ; fds  <- mappM tc_fd rdr_fds
 409     ; ats'  <- mappM (tcIfaceDecl ignore_prags) rdr_ats
 410     ; let ats = zipWith setTyThingPoss ats' (map ifTyVars rdr_ats)
 411     ; cls  <- buildClass cls_name tyvars ctxt fds ats sigs tc_isrec
 412     ; return (AClass cls) }
 413   where
 414    tc_sig (IfaceClassOp occ dm rdr_ty)
 415      = do { op_name <- lookupIfaceTop occ
 416           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 417                 -- Must be done lazily for just the same reason as the
 418                 -- type of a data con; to avoid sucking in types that
 419                 -- it mentions unless it's necessray to do so
 420           ; return (op_name, dm, op_ty) }
 421
 422    mk_doc op_name op_ty = ptext SLIT("Class op") <+> sep [ppr op_name, ppr op_ty]
 423
 424    tc_fd (tvs1, tvs2) = do { tvs1' <- mappM tcIfaceTyVar tvs1
 425                            ; tvs2' <- mappM tcIfaceTyVar tvs2
 426                            ; return (tvs1', tvs2') }
 427
 428    -- For each AT argument compute the position of the corresponding class
 429    -- parameter in the class head.  This will later serve as a permutation
 430    -- vector when checking the validity of instance declarations.
 431    setTyThingPoss (ATyCon tycon) atTyVars =
 432      let classTyVars = map fst tv_bndrs
 433          poss        =   catMaybes
 434                        . map ((`elemIndex` classTyVars) . fst)
 435                        $ atTyVars
 436                     -- There will be no Nothing, as we already passed renaming
 437      in
 438      ATyCon (setTyConArgPoss tycon poss)
 439    setTyThingPoss _               _ = panic "TcIface.setTyThingPoss"
 440
 441 tcIfaceDecl ignore_prags (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 442   = do  { name <- lookupIfaceTop rdr_name
 443         ; return (ATyCon (mkForeignTyCon name ext_name
 444                                          liftedTypeKind 0)) }
 445
 446 tcIfaceDataCons tycon_name tycon tc_tyvars if_cons
 447   = case if_cons of
 448         IfAbstractTyCon  -> return mkAbstractTyConRhs
 449         IfOpenDataTyCon  -> return mkOpenDataTyConRhs
 450         IfOpenNewTyCon   -> return mkOpenNewTyConRhs
 451         IfDataTyCon cons -> do  { data_cons <- mappM tc_con_decl cons
 452                                 ; return (mkDataTyConRhs data_cons) }
 453         IfNewTyCon con   -> do  { data_con <- tc_con_decl con
 454                                 ; mkNewTyConRhs tycon_name tycon data_con }
 455   where
 456     tc_con_decl (IfCon { ifConInfix = is_infix,
 457                          ifConUnivTvs = univ_tvs, ifConExTvs = ex_tvs,
 458                          ifConOcc = occ, ifConCtxt = ctxt, ifConEqSpec = spec,
 459                          ifConArgTys = args, ifConFields = field_lbls,
 460                          ifConStricts = stricts})
 461      = bindIfaceTyVars univ_tvs $ \ univ_tyvars -> do
 462        bindIfaceTyVars ex_tvs    $ \ ex_tyvars -> do
 463         { name  <- lookupIfaceTop occ
 464         ; eq_spec <- tcIfaceEqSpec spec
 465         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 466                 -- At one stage I thought that this context checking *had*
 467                 -- to be lazy, because of possible mutual recursion between the
 468                 -- type and the classe:
 469                 -- E.g.
 470                 --      class Real a where { toRat :: a -> Ratio Integer }
 471                 --      data (Real a) => Ratio a = ...
 472                 -- But now I think that the laziness in checking class ops breaks
 473                 -- the loop, so no laziness needed
 474
 475         -- Read the argument types, but lazily to avoid faulting in
 476         -- the component types unless they are really needed
 477         ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 478         ; lbl_names <- mappM lookupIfaceTop field_lbls
 479
 480         ; buildDataCon name is_infix {- Not infix -}
 481                        stricts lbl_names
 482                        univ_tyvars ex_tyvars
 483                        eq_spec theta
 484                        arg_tys tycon
 485         }
 486     mk_doc con_name = ptext SLIT("Constructor") <+> ppr con_name
 487
 488 tcIfaceEqSpec spec
 489   = mapM do_item spec
 490   where
 491     do_item (occ, if_ty) = do { tv <- tcIfaceTyVar (occNameFS occ)
 492                               ; ty <- tcIfaceType if_ty
 493                               ; return (tv,ty) }
 494 \end{code}
 495
 496
 497 %************************************************************************
 498 %*                                                                      *
 499                 Instances
 500 %*                                                                      *
 501 %************************************************************************
 502
 503 \begin{code}
 504 tcIfaceInst :: IfaceInst -> IfL Instance
 505 tcIfaceInst (IfaceInst { ifDFun = dfun_occ, ifOFlag = oflag,
 506                          ifInstCls = cls, ifInstTys = mb_tcs,
 507                          ifInstOrph = orph })
 508   = do  { dfun    <- forkM (ptext SLIT("Dict fun") <+> ppr dfun_occ) $
 509                      tcIfaceExtId dfun_occ
 510         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 511         ; return (mkImportedInstance cls mb_tcs' dfun oflag) }
 512
 513 tcIfaceFamInst :: IfaceFamInst -> IfL FamInst
 514 tcIfaceFamInst (IfaceFamInst { ifFamInstTyCon = tycon,
 515                                ifFamInstFam = fam, ifFamInstTys = mb_tcs })
 516 --  = do        { tycon'  <- forkM (ptext SLIT("Inst tycon") <+> ppr tycon) $
 517 -- ^^^this line doesn't work, but vvv this does => CPP in Haskell = evil!
 518   = do  { tycon'  <- forkM (text ("Inst tycon") <+> ppr tycon) $
 519                      tcIfaceTyCon tycon
 520         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 521         ; return (mkImportedFamInst fam mb_tcs' tycon') }
 522 \end{code}
 523
 524
 525 %************************************************************************
 526 %*                                                                      *
 527                 Rules
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 532 are in the type environment.  However, remember that typechecking a Rule may
 533 (as a side effect) augment the type envt, and so we may need to iterate the process.
 534
 535 \begin{code}
 536 tcIfaceRules :: Bool            -- True <=> ignore rules
 537              -> [IfaceRule]
 538              -> IfL [CoreRule]
 539 tcIfaceRules ignore_prags if_rules
 540   | ignore_prags = return []
 541   | otherwise    = mapM tcIfaceRule if_rules
 542
 543 tcIfaceRule :: IfaceRule -> IfL CoreRule
 544 tcIfaceRule (IfaceRule {ifRuleName = name, ifActivation = act, ifRuleBndrs = bndrs,
 545                         ifRuleHead = fn, ifRuleArgs = args, ifRuleRhs = rhs,
 546                         ifRuleOrph = orph })
 547   = do  { ~(bndrs', args', rhs') <-
 548                 -- Typecheck the payload lazily, in the hope it'll never be looked at
 549                 forkM (ptext SLIT("Rule") <+> ftext name) $
 550                 bindIfaceBndrs bndrs                      $ \ bndrs' ->
 551                 do { args' <- mappM tcIfaceExpr args
 552                    ; rhs'  <- tcIfaceExpr rhs
 553                    ; return (bndrs', args', rhs') }
 554         ; let mb_tcs = map ifTopFreeName args
 555         ; lcl <- getLclEnv
 556         ; returnM (Rule { ru_name = name, ru_fn = fn, ru_act = act,
 557                           ru_bndrs = bndrs', ru_args = args',
 558                           ru_rhs = rhs',
 559                           ru_rough = mb_tcs,
 560                           ru_local = False }) } -- An imported RULE is never for a local Id
 561                                                 -- or, even if it is (module loop, perhaps)
 562                                                 -- we'll just leave it in the non-local set
 563   where
 564         -- This function *must* mirror exactly what Rules.topFreeName does
 565         -- We could have stored the ru_rough field in the iface file
 566         -- but that would be redundant, I think.
 567         -- The only wrinkle is that we must not be deceived by
 568         -- type syononyms at the top of a type arg.  Since
 569         -- we can't tell at this point, we are careful not
 570         -- to write them out in coreRuleToIfaceRule
 571     ifTopFreeName :: IfaceExpr -> Maybe Name
 572     ifTopFreeName (IfaceType (IfaceTyConApp tc _ )) = Just (ifaceTyConName tc)
 573     ifTopFreeName (IfaceApp f a)                    = ifTopFreeName f
 574     ifTopFreeName (IfaceExt n)                      = Just n
 575     ifTopFreeName other                             = Nothing
 576 \end{code}
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581                         Types
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 \begin{code}
 586 tcIfaceType :: IfaceType -> IfL Type
 587 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 588 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 589 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 590 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkTyConApp tc' ts') }
 591 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 592 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 593
 594 tcIfaceTypes tys = mapM tcIfaceType tys
 595
 596 -----------------------------------------
 597 tcIfacePredType :: IfacePredType -> IfL PredType
 598 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 599 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 600 tcIfacePredType (IfaceEqPred t1 t2)  = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (EqPred t1' t2') }
 601
 602 -----------------------------------------
 603 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 604 tcIfaceCtxt sts = mappM tcIfacePredType sts
 605 \end{code}
 606
 607
 608 %************************************************************************
 609 %*                                                                      *
 610                         Core
 611 %*                                                                      *
 612 %************************************************************************
 613
 614 \begin{code}
 615 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 616 tcIfaceExpr (IfaceType ty)
 617   = tcIfaceType ty              `thenM` \ ty' ->
 618     returnM (Type ty')
 619
 620 tcIfaceExpr (IfaceLcl name)
 621   = tcIfaceLclId name   `thenM` \ id ->
 622     returnM (Var id)
 623
 624 tcIfaceExpr (IfaceExt gbl)
 625   = tcIfaceExtId gbl    `thenM` \ id ->
 626     returnM (Var id)
 627
 628 tcIfaceExpr (IfaceLit lit)
 629   = returnM (Lit lit)
 630
 631 tcIfaceExpr (IfaceFCall cc ty)
 632   = tcIfaceType ty      `thenM` \ ty' ->
 633     newUnique           `thenM` \ u ->
 634     returnM (Var (mkFCallId u cc ty'))
 635
 636 tcIfaceExpr (IfaceTuple boxity args)
 637   = mappM tcIfaceExpr args      `thenM` \ args' ->
 638     let
 639         -- Put the missing type arguments back in
 640         con_args = map (Type . exprType) args' ++ args'
 641     in
 642     returnM (mkApps (Var con_id) con_args)
 643   where
 644     arity = length args
 645     con_id = dataConWorkId (tupleCon boxity arity)
 646
 647
 648 tcIfaceExpr (IfaceLam bndr body)
 649   = bindIfaceBndr bndr          $ \ bndr' ->
 650     tcIfaceExpr body            `thenM` \ body' ->
 651     returnM (Lam bndr' body')
 652
 653 tcIfaceExpr (IfaceApp fun arg)
 654   = tcIfaceExpr fun             `thenM` \ fun' ->
 655     tcIfaceExpr arg             `thenM` \ arg' ->
 656     returnM (App fun' arg')
 657
 658 tcIfaceExpr (IfaceCase scrut case_bndr ty alts)
 659   = tcIfaceExpr scrut           `thenM` \ scrut' ->
 660     newIfaceName (mkVarOccFS case_bndr) `thenM` \ case_bndr_name ->
 661     let
 662         scrut_ty   = exprType scrut'
 663         case_bndr' = mkLocalId case_bndr_name scrut_ty
 664         tc_app     = splitTyConApp scrut_ty
 665                 -- NB: Won't always succeed (polymoprhic case)
 666                 --     but won't be demanded in those cases
 667                 -- NB: not tcSplitTyConApp; we are looking at Core here
 668                 --     look through non-rec newtypes to find the tycon that
 669                 --     corresponds to the datacon in this case alternative
 670     in
 671     extendIfaceIdEnv [case_bndr']       $
 672     mappM (tcIfaceAlt tc_app) alts      `thenM` \ alts' ->
 673     tcIfaceType ty              `thenM` \ ty' ->
 674     returnM (Case scrut' case_bndr' ty' alts')
 675
 676 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body)
 677   = do  { rhs' <- tcIfaceExpr rhs
 678         ; id   <- tcIfaceLetBndr bndr
 679         ; body' <- extendIfaceIdEnv [id] (tcIfaceExpr body)
 680         ; return (Let (NonRec id rhs') body') }
 681
 682 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 683   = do  { ids <- mapM tcIfaceLetBndr bndrs
 684         ; extendIfaceIdEnv ids $ do
 685         { rhss' <- mapM tcIfaceExpr rhss
 686         ; body' <- tcIfaceExpr body
 687         ; return (Let (Rec (ids `zip` rhss')) body') } }
 688   where
 689     (bndrs, rhss) = unzip pairs
 690
 691 tcIfaceExpr (IfaceCast expr co) = do
 692   expr' <- tcIfaceExpr expr
 693   co' <- tcIfaceType co
 694   returnM (Cast expr' co')
 695
 696 tcIfaceExpr (IfaceNote note expr)
 697   = tcIfaceExpr expr            `thenM` \ expr' ->
 698     case note of
 699         IfaceInlineMe     -> returnM (Note InlineMe   expr')
 700         IfaceSCC cc       -> returnM (Note (SCC cc)   expr')
 701         IfaceCoreNote n   -> returnM (Note (CoreNote n) expr')
 702
 703 -------------------------
 704 tcIfaceAlt _ (IfaceDefault, names, rhs)
 705   = ASSERT( null names )
 706     tcIfaceExpr rhs             `thenM` \ rhs' ->
 707     returnM (DEFAULT, [], rhs')
 708
 709 tcIfaceAlt _ (IfaceLitAlt lit, names, rhs)
 710   = ASSERT( null names )
 711     tcIfaceExpr rhs             `thenM` \ rhs' ->
 712     returnM (LitAlt lit, [], rhs')
 713
 714 -- A case alternative is made quite a bit more complicated
 715 -- by the fact that we omit type annotations because we can
 716 -- work them out.  True enough, but its not that easy!
 717 tcIfaceAlt (tycon, inst_tys) (IfaceDataAlt data_occ, arg_strs, rhs)
 718   = do  { con <- tcIfaceDataCon data_occ
 719         ; ASSERT2( con `elem` tyConDataCons tycon,
 720                    ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon) )
 721           tcIfaceDataAlt con inst_tys arg_strs rhs }
 722
 723 tcIfaceAlt (tycon, inst_tys) (IfaceTupleAlt boxity, arg_occs, rhs)
 724   = ASSERT( isTupleTyCon tycon )
 725     do  { let [data_con] = tyConDataCons tycon
 726         ; tcIfaceDataAlt data_con inst_tys arg_occs rhs }
 727
 728 tcIfaceDataAlt con inst_tys arg_strs rhs
 729   = do  { us <- newUniqueSupply
 730         ; let uniqs = uniqsFromSupply us
 731         ; let (ex_tvs, co_tvs, arg_ids)
 732                       = dataConRepFSInstPat arg_strs uniqs con inst_tys
 733               all_tvs = ex_tvs ++ co_tvs
 734
 735         ; rhs' <- extendIfaceTyVarEnv all_tvs   $
 736                   extendIfaceIdEnv arg_ids      $
 737                   tcIfaceExpr rhs
 738         ; return (DataAlt con, all_tvs ++ arg_ids, rhs') }
 739 \end{code}
 740
 741
 742 \begin{code}
 743 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 744 tcExtCoreBindings []     = return []
 745 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 746
 747 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 748 do_one (IfaceNonRec bndr rhs) thing_inside
 749   = do  { rhs' <- tcIfaceExpr rhs
 750         ; bndr' <- newExtCoreBndr bndr
 751         ; extendIfaceIdEnv [bndr'] $ do
 752         { core_binds <- thing_inside
 753         ; return (NonRec bndr' rhs' : core_binds) }}
 754
 755 do_one (IfaceRec pairs) thing_inside
 756   = do  { bndrs' <- mappM newExtCoreBndr bndrs
 757         ; extendIfaceIdEnv bndrs' $ do
 758         { rhss' <- mappM tcIfaceExpr rhss
 759         ; core_binds <- thing_inside
 760         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 761   where
 762     (bndrs,rhss) = unzip pairs
 763 \end{code}
 764
 765
 766 %************************************************************************
 767 %*                                                                      *
 768                 IdInfo
 769 %*                                                                      *
 770 %************************************************************************
 771
 772 \begin{code}
 773 tcIdInfo :: Bool -> Name -> Type -> IfaceIdInfo -> IfL IdInfo
 774 tcIdInfo ignore_prags name ty info
 775   | ignore_prags = return vanillaIdInfo
 776   | otherwise    = case info of
 777                         NoInfo       -> return vanillaIdInfo
 778                         HasInfo info -> foldlM tcPrag init_info info
 779   where
 780     -- Set the CgInfo to something sensible but uninformative before
 781     -- we start; default assumption is that it has CAFs
 782     init_info = vanillaIdInfo
 783
 784     tcPrag info HsNoCafRefs         = returnM (info `setCafInfo`   NoCafRefs)
 785     tcPrag info (HsArity arity)     = returnM (info `setArityInfo` arity)
 786     tcPrag info (HsStrictness str)  = returnM (info `setAllStrictnessInfo` Just str)
 787
 788         -- The next two are lazy, so they don't transitively suck stuff in
 789     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
 790     tcPrag info (HsInline inline_prag) = returnM (info `setInlinePragInfo` inline_prag)
 791     tcPrag info (HsUnfold expr)
 792         = tcPragExpr name expr  `thenM` \ maybe_expr' ->
 793           let
 794                 -- maybe_expr' doesn't get looked at if the unfolding
 795                 -- is never inspected; so the typecheck doesn't even happen
 796                 unfold_info = case maybe_expr' of
 797                                 Nothing    -> noUnfolding
 798                                 Just expr' -> mkTopUnfolding expr'
 799           in
 800           returnM (info `setUnfoldingInfoLazily` unfold_info)
 801 \end{code}
 802
 803 \begin{code}
 804 tcWorkerInfo ty info wkr arity
 805   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId wkr)
 806
 807         -- We return without testing maybe_wkr_id, but as soon as info is
 808         -- looked at we will test it.  That's ok, because its outside the
 809         -- knot; and there seems no big reason to further defer the
 810         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
 811         -- over the unfolding until it's actually used does seem worth while.)
 812         ; us <- newUniqueSupply
 813
 814         ; returnM (case mb_wkr_id of
 815                      Nothing     -> info
 816                      Just wkr_id -> add_wkr_info us wkr_id info) }
 817   where
 818     doc = text "Worker for" <+> ppr wkr
 819     add_wkr_info us wkr_id info
 820         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
 821                `setWorkerInfo`           HasWorker wkr_id arity
 822
 823     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
 824
 825         -- We are relying here on strictness info always appearing
 826         -- before worker info,  fingers crossed ....
 827     strict_sig = case newStrictnessInfo info of
 828                    Just sig -> sig
 829                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr)
 830 \end{code}
 831
 832 For unfoldings we try to do the job lazily, so that we never type check
 833 an unfolding that isn't going to be looked at.
 834
 835 \begin{code}
 836 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
 837 tcPragExpr name expr
 838   = forkM_maybe doc $
 839     tcIfaceExpr expr            `thenM` \ core_expr' ->
 840
 841                 -- Check for type consistency in the unfolding
 842     ifOptM Opt_DoCoreLinting (
 843         get_in_scope_ids                        `thenM` \ in_scope ->
 844         case lintUnfolding noSrcLoc in_scope core_expr' of
 845           Nothing       -> returnM ()
 846           Just fail_msg -> pprPanic "Iface Lint failure" (hang doc 2 fail_msg)
 847     )                           `thenM_`
 848
 849    returnM core_expr'
 850   where
 851     doc = text "Unfolding of" <+> ppr name
 852     get_in_scope_ids    -- Urgh; but just for linting
 853         = setLclEnv () $
 854           do    { env <- getGblEnv
 855                 ; case if_rec_types env of {
 856                           Nothing -> return [] ;
 857                           Just (_, get_env) -> do
 858                 { type_env <- get_env
 859                 ; return (typeEnvIds type_env) }}}
 860 \end{code}
 861
 862
 863
 864 %************************************************************************
 865 %*                                                                      *
 866                 Getting from Names to TyThings
 867 %*                                                                      *
 868 %************************************************************************
 869
 870 \begin{code}
 871 tcIfaceGlobal :: Name -> IfL TyThing
 872 tcIfaceGlobal name
 873   | Just thing <- wiredInNameTyThing_maybe name
 874         -- Wired-in things include TyCons, DataCons, and Ids
 875   = do { ifCheckWiredInThing name; return thing }
 876   | otherwise
 877   = do  { (eps,hpt) <- getEpsAndHpt
 878         ; dflags <- getDOpts
 879         ; case lookupType dflags hpt (eps_PTE eps) name of {
 880             Just thing -> return thing ;
 881             Nothing    -> do
 882
 883         { env <- getGblEnv
 884         ; case if_rec_types env of {
 885             Just (mod, get_type_env)
 886                 | nameIsLocalOrFrom mod name
 887                 -> do           -- It's defined in the module being compiled
 888                 { type_env <- setLclEnv () get_type_env         -- yuk
 889                 ; case lookupNameEnv type_env name of
 890                         Just thing -> return thing
 891                         Nothing    -> pprPanic "tcIfaceGlobal (local): not found:"
 892                                                 (ppr name $$ ppr type_env) }
 893
 894           ; other -> do
 895
 896         { mb_thing <- importDecl name   -- It's imported; go get it
 897         ; case mb_thing of
 898             Failed err      -> failIfM err
 899             Succeeded thing -> return thing
 900     }}}}}
 901
 902 ifCheckWiredInThing :: Name -> IfL ()
 903 -- Even though we are in an interface file, we want to make
 904 -- sure the instances of a wired-in thing are loaded (imagine f :: Double -> Double)
 905 -- Ditto want to ensure that RULES are loaded too
 906 ifCheckWiredInThing name
 907   = do  { mod <- getIfModule
 908                 -- Check whether we are typechecking the interface for this
 909                 -- very module.  E.g when compiling the base library in --make mode
 910                 -- we may typecheck GHC.Base.hi. At that point, GHC.Base is not in
 911                 -- the HPT, so without the test we'll demand-load it into the PIT!
 912                 -- C.f. the same test in checkWiredInTyCon above
 913         ; unless (mod == nameModule name)
 914                  (loadWiredInHomeIface name) }
 915
 916 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
 917 tcIfaceTyCon IfaceIntTc         = tcWiredInTyCon intTyCon
 918 tcIfaceTyCon IfaceBoolTc        = tcWiredInTyCon boolTyCon
 919 tcIfaceTyCon IfaceCharTc        = tcWiredInTyCon charTyCon
 920 tcIfaceTyCon IfaceListTc        = tcWiredInTyCon listTyCon
 921 tcIfaceTyCon IfacePArrTc        = tcWiredInTyCon parrTyCon
 922 tcIfaceTyCon (IfaceTupTc bx ar) = tcWiredInTyCon (tupleTyCon bx ar)
 923 tcIfaceTyCon (IfaceTc name)     = do { thing <- tcIfaceGlobal name
 924                                      ; return (check_tc (tyThingTyCon thing)) }
 925   where
 926 #ifdef DEBUG
 927     check_tc tc = case toIfaceTyCon tc of
 928                    IfaceTc _ -> tc
 929                    other     -> pprTrace "check_tc" (ppr tc) tc
 930 #else
 931     check_tc tc = tc
 932 #endif
 933 -- we should be okay just returning Kind constructors without extra loading
 934 tcIfaceTyCon IfaceLiftedTypeKindTc   = return liftedTypeKindTyCon
 935 tcIfaceTyCon IfaceOpenTypeKindTc     = return openTypeKindTyCon
 936 tcIfaceTyCon IfaceUnliftedTypeKindTc = return unliftedTypeKindTyCon
 937 tcIfaceTyCon IfaceArgTypeKindTc      = return argTypeKindTyCon
 938 tcIfaceTyCon IfaceUbxTupleKindTc     = return ubxTupleKindTyCon
 939
 940 -- Even though we are in an interface file, we want to make
 941 -- sure the instances and RULES of this tycon are loaded
 942 -- Imagine: f :: Double -> Double
 943 tcWiredInTyCon :: TyCon -> IfL TyCon
 944 tcWiredInTyCon tc = do { ifCheckWiredInThing (tyConName tc)
 945                        ; return tc }
 946
 947 tcIfaceClass :: Name -> IfL Class
 948 tcIfaceClass name = do { thing <- tcIfaceGlobal name
 949                        ; return (tyThingClass thing) }
 950
 951 tcIfaceDataCon :: Name -> IfL DataCon
 952 tcIfaceDataCon name = do { thing <- tcIfaceGlobal name
 953                          ; case thing of
 954                                 ADataCon dc -> return dc
 955                                 other   -> pprPanic "tcIfaceExtDC" (ppr name$$ ppr thing) }
 956
 957 tcIfaceExtId :: Name -> IfL Id
 958 tcIfaceExtId name = do { thing <- tcIfaceGlobal name
 959                        ; case thing of
 960                           AnId id -> return id
 961                           other   -> pprPanic "tcIfaceExtId" (ppr name$$ ppr thing) }
 962 \end{code}
 963
 964 %************************************************************************
 965 %*                                                                      *
 966                 Bindings
 967 %*                                                                      *
 968 %************************************************************************
 969
 970 \begin{code}
 971 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
 972 bindIfaceBndr (IfaceIdBndr (fs, ty)) thing_inside
 973   = do  { name <- newIfaceName (mkVarOccFS fs)
 974         ; ty' <- tcIfaceType ty
 975         ; let id = mkLocalId name ty'
 976         ; extendIfaceIdEnv [id] (thing_inside id) }
 977 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
 978   = bindIfaceTyVar bndr thing_inside
 979
 980 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
 981 bindIfaceBndrs []     thing_inside = thing_inside []
 982 bindIfaceBndrs (b:bs) thing_inside
 983   = bindIfaceBndr b     $ \ b' ->
 984     bindIfaceBndrs bs   $ \ bs' ->
 985     thing_inside (b':bs')
 986
 987 -----------------------
 988 tcIfaceLetBndr (IfLetBndr fs ty info)
 989   = do  { name <- newIfaceName (mkVarOccFS fs)
 990         ; ty' <- tcIfaceType ty
 991         ; case info of
 992                 NoInfo    -> return (mkLocalId name ty')
 993                 HasInfo i -> return (mkLocalIdWithInfo name ty' (tc_info i)) }
 994   where
 995         -- Similar to tcIdInfo, but much simpler
 996     tc_info [] = vanillaIdInfo
 997     tc_info (HsInline p     : i) = tc_info i `setInlinePragInfo` p
 998     tc_info (HsArity a      : i) = tc_info i `setArityInfo` a
 999     tc_info (HsStrictness s : i) = tc_info i `setAllStrictnessInfo` Just s
1000     tc_info (other          : i) = pprTrace "tcIfaceLetBndr: discarding unexpected IdInfo"
1001                                             (ppr other) (tc_info i)
1002
1003 -----------------------
1004 newExtCoreBndr :: IfaceLetBndr -> IfL Id
1005 newExtCoreBndr (IfLetBndr var ty _)     -- Ignoring IdInfo for now
1006   = do  { mod <- getIfModule
1007         ; name <- newGlobalBinder mod (mkVarOccFS var) noSrcLoc
1008         ; ty' <- tcIfaceType ty
1009         ; return (mkLocalId name ty') }
1010
1011 -----------------------
1012 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
1013 bindIfaceTyVar (occ,kind) thing_inside
1014   = do  { name <- newIfaceName (mkTyVarOcc occ)
1015         ; tyvar <- mk_iface_tyvar name kind
1016         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
1017
1018 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
1019 bindIfaceTyVars bndrs thing_inside
1020   = do  { names <- newIfaceNames (map mkTyVarOcc occs)
1021         ; tyvars <- TcRnMonad.zipWithM mk_iface_tyvar names kinds
1022         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
1023   where
1024     (occs,kinds) = unzip bndrs
1025
1026 mk_iface_tyvar :: Name -> IfaceKind -> IfL TyVar
1027 mk_iface_tyvar name ifKind
1028    = do { kind <- tcIfaceType ifKind
1029         ; if isCoercionKind kind then
1030                 return (Var.mkCoVar name kind)
1031           else
1032                 return (Var.mkTyVar name kind) }
1033 \end{code}
1034