compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         newSession,
  15
  16         -- * Flags and settings
  17         DynFlags(..), DynFlag(..), Severity(..), HscTarget(..), dopt,
  18         GhcMode(..), GhcLink(..), defaultObjectTarget,
  19         parseDynamicFlags,
  20         getSessionDynFlags,
  21         setSessionDynFlags,
  22         parseStaticFlags,
  23
  24         -- * Targets
  25         Target(..), TargetId(..), Phase,
  26         setTargets,
  27         getTargets,
  28         addTarget,
  29         removeTarget,
  30         guessTarget,
  31
  32         -- * Extending the program scope
  33         extendGlobalRdrScope,  -- :: Session -> [GlobalRdrElt] -> IO ()
  34         setGlobalRdrScope,     -- :: Session -> [GlobalRdrElt] -> IO ()
  35         extendGlobalTypeScope, -- :: Session -> [Id] -> IO ()
  36         setGlobalTypeScope,    -- :: Session -> [Id] -> IO ()
  37
  38         -- * Loading\/compiling the program
  39         depanal,
  40         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  41         workingDirectoryChanged,
  42         checkModule, CheckedModule(..),
  43         TypecheckedSource, ParsedSource, RenamedSource,
  44
  45         -- * Parsing Haddock comments
  46         parseHaddockComment,
  47
  48         -- * Inspecting the module structure of the program
  49         ModuleGraph, ModSummary(..), ms_mod_name, ModLocation(..),
  50         getModuleGraph,
  51         isLoaded,
  52         topSortModuleGraph,
  53
  54         -- * Inspecting modules
  55         ModuleInfo,
  56         getModuleInfo,
  57         modInfoTyThings,
  58         modInfoTopLevelScope,
  59         modInfoPrintUnqualified,
  60         modInfoExports,
  61         modInfoInstances,
  62         modInfoIsExportedName,
  63         modInfoLookupName,
  64         lookupGlobalName,
  65
  66         -- * Printing
  67         PrintUnqualified, alwaysQualify,
  68
  69         -- * Interactive evaluation
  70         getBindings, getPrintUnqual,
  71         findModule,
  72 #ifdef GHCI
  73         setContext, getContext,
  74         getNamesInScope,
  75         getRdrNamesInScope,
  76         moduleIsInterpreted,
  77         getInfo,
  78         exprType,
  79         typeKind,
  80         parseName,
  81         RunResult(..),
  82         runStmt, SingleStep(..),
  83         resume,
  84         Resume(resumeStmt, resumeThreadId, resumeBreakInfo, resumeSpan,
  85                resumeHistory, resumeHistoryIx),
  86         History(historyBreakInfo), getHistorySpan,
  87         getResumeContext,
  88         abandon, abandonAll,
  89         InteractiveEval.back,
  90         InteractiveEval.forward,
  91         showModule,
  92         isModuleInterpreted,
  93         compileExpr, HValue, dynCompileExpr,
  94         lookupName,
  95         obtainTerm, obtainTerm1,
  96         modInfoModBreaks,
  97         ModBreaks(..), BreakIndex,
  98         BreakInfo(breakInfo_number, breakInfo_module),
  99         BreakArray, setBreakOn, setBreakOff, getBreak,
 100 #endif
 101
 102         -- * Abstract syntax elements
 103
 104         -- ** Packages
 105         PackageId,
 106
 107         -- ** Modules
 108         Module, mkModule, pprModule, moduleName, modulePackageId,
 109         ModuleName, mkModuleName, moduleNameString,
 110
 111         -- ** Names
 112         Name,
 113         isExternalName, nameModule, pprParenSymName, nameSrcSpan,
 114         NamedThing(..),
 115         RdrName(Qual,Unqual),
 116
 117         -- ** Identifiers
 118         Id, idType,
 119         isImplicitId, isDeadBinder,
 120         isExportedId, isLocalId, isGlobalId,
 121         isRecordSelector,
 122         isPrimOpId, isFCallId, isClassOpId_maybe,
 123         isDataConWorkId, idDataCon,
 124         isBottomingId, isDictonaryId,
 125         recordSelectorFieldLabel,
 126
 127         -- ** Type constructors
 128         TyCon,
 129         tyConTyVars, tyConDataCons, tyConArity,
 130         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 131         isOpenTyCon,
 132         synTyConDefn, synTyConType, synTyConResKind,
 133
 134         -- ** Type variables
 135         TyVar,
 136         alphaTyVars,
 137
 138         -- ** Data constructors
 139         DataCon,
 140         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 141         dataConIsInfix, isVanillaDataCon,
 142         dataConStrictMarks,
 143         StrictnessMark(..), isMarkedStrict,
 144
 145         -- ** Classes
 146         Class,
 147         classMethods, classSCTheta, classTvsFds,
 148         pprFundeps,
 149
 150         -- ** Instances
 151         Instance,
 152         instanceDFunId, pprInstance, pprInstanceHdr,
 153
 154         -- ** Types and Kinds
 155         Type, dropForAlls, splitForAllTys, funResultTy,
 156         pprParendType, pprTypeApp,
 157         Kind,
 158         PredType,
 159         ThetaType, pprThetaArrow,
 160
 161         -- ** Entities
 162         TyThing(..),
 163
 164         -- ** Syntax
 165         module HsSyn, -- ToDo: remove extraneous bits
 166
 167         -- ** Fixities
 168         FixityDirection(..),
 169         defaultFixity, maxPrecedence,
 170         negateFixity,
 171         compareFixity,
 172
 173         -- ** Source locations
 174         SrcLoc, pprDefnLoc,
 175         mkSrcLoc, isGoodSrcLoc, noSrcLoc,
 176         srcLocFile, srcLocLine, srcLocCol,
 177         SrcSpan,
 178         mkSrcSpan, srcLocSpan, isGoodSrcSpan, noSrcSpan,
 179         srcSpanStart, srcSpanEnd,
 180         srcSpanFile,
 181         srcSpanStartLine, srcSpanEndLine,
 182         srcSpanStartCol, srcSpanEndCol,
 183
 184         -- * Exceptions
 185         GhcException(..), showGhcException,
 186
 187         -- * Miscellaneous
 188         sessionHscEnv,
 189         cyclicModuleErr,
 190   ) where
 191
 192 {-
 193  ToDo:
 194
 195   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 196   * what StaticFlags should we expose, if any?
 197 -}
 198
 199 #include "HsVersions.h"
 200
 201 #ifdef GHCI
 202 import qualified Linker
 203 import Linker           ( HValue )
 204 import ByteCodeInstr
 205 import BreakArray
 206 import NameSet
 207 import TcRnDriver
 208 import InteractiveEval
 209 #endif
 210
 211 import Packages
 212 import NameSet
 213 import RdrName
 214 import HsSyn
 215 import Type             hiding (typeKind)
 216 import TcType           hiding (typeKind)
 217 import Id
 218 import Var              hiding (setIdType)
 219 import TysPrim          ( alphaTyVars )
 220 import TyCon
 221 import Class
 222 import FunDeps
 223 import DataCon
 224 import Name             hiding ( varName )
 225 import OccName          ( parenSymOcc )
 226 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr )
 227 import SrcLoc
 228 import DriverPipeline
 229 import DriverPhases     ( Phase(..), isHaskellSrcFilename, startPhase )
 230 import HeaderInfo       ( getImports, getOptions )
 231 import Finder
 232 import HscMain          ( newHscEnv, hscFileCheck, HscChecked(..) )
 233 import HscTypes
 234 import DynFlags
 235 import StaticFlags
 236 import SysTools     ( initSysTools, cleanTempFiles, cleanTempFilesExcept,
 237                       cleanTempDirs )
 238 import Module
 239 import UniqFM
 240 import UniqSet
 241 import Unique
 242 import PackageConfig
 243 import FiniteMap
 244 import Panic
 245 import Digraph
 246 import Bag              ( unitBag, listToBag )
 247 import ErrUtils         ( Severity(..), showPass, fatalErrorMsg, debugTraceMsg,
 248                           mkPlainErrMsg, printBagOfErrors, printBagOfWarnings,
 249                           WarnMsg )
 250 import qualified ErrUtils
 251 import Util
 252 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 253 import Outputable
 254 import BasicTypes
 255 import Maybes           ( expectJust, mapCatMaybes )
 256 import HaddockParse
 257 import HaddockLex       ( tokenise )
 258
 259 import Control.Concurrent
 260 import System.Directory ( getModificationTime, doesFileExist )
 261 import Data.Maybe
 262 import Data.List
 263 import qualified Data.List as List
 264 import Control.Monad
 265 import System.Exit      ( exitWith, ExitCode(..) )
 266 import System.Time      ( ClockTime )
 267 import Control.Exception as Exception hiding (handle)
 268 import Data.IORef
 269 import System.IO
 270 import System.IO.Error  ( try, isDoesNotExistError )
 271 import Prelude hiding (init)
 272
 273
 274 -- -----------------------------------------------------------------------------
 275 -- Exception handlers
 276
 277 -- | Install some default exception handlers and run the inner computation.
 278 -- Unless you want to handle exceptions yourself, you should wrap this around
 279 -- the top level of your program.  The default handlers output the error
 280 -- message(s) to stderr and exit cleanly.
 281 defaultErrorHandler :: DynFlags -> IO a -> IO a
 282 defaultErrorHandler dflags inner =
 283   -- top-level exception handler: any unrecognised exception is a compiler bug.
 284   handle (\exception -> do
 285            hFlush stdout
 286            case exception of
 287                 -- an IO exception probably isn't our fault, so don't panic
 288                 IOException _ ->
 289                   fatalErrorMsg dflags (text (show exception))
 290                 AsyncException StackOverflow ->
 291                   fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 292                 _other ->
 293                   fatalErrorMsg dflags (text (show (Panic (show exception))))
 294            exitWith (ExitFailure 1)
 295          ) $
 296
 297   -- program errors: messages with locations attached.  Sometimes it is
 298   -- convenient to just throw these as exceptions.
 299   handleDyn (\dyn -> do printBagOfErrors dflags (unitBag dyn)
 300                         exitWith (ExitFailure 1)) $
 301
 302   -- error messages propagated as exceptions
 303   handleDyn (\dyn -> do
 304                 hFlush stdout
 305                 case dyn of
 306                      PhaseFailed _ code -> exitWith code
 307                      Interrupted -> exitWith (ExitFailure 1)
 308                      _ -> do fatalErrorMsg dflags (text (show (dyn :: GhcException)))
 309                              exitWith (ExitFailure 1)
 310             ) $
 311   inner
 312
 313 -- | Install a default cleanup handler to remove temporary files
 314 -- deposited by a GHC run.  This is seperate from
 315 -- 'defaultErrorHandler', because you might want to override the error
 316 -- handling, but still get the ordinary cleanup behaviour.
 317 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 318 defaultCleanupHandler dflags inner =
 319     -- make sure we clean up after ourselves
 320     later (do cleanTempFiles dflags
 321               cleanTempDirs dflags
 322           )
 323           -- exceptions will be blocked while we clean the temporary files,
 324           -- so there shouldn't be any difficulty if we receive further
 325           -- signals.
 326     inner
 327
 328
 329 -- | Starts a new session.  A session consists of a set of loaded
 330 -- modules, a set of options (DynFlags), and an interactive context.
 331 newSession :: Maybe FilePath -> IO Session
 332 newSession mb_top_dir = do
 333   -- catch ^C
 334   main_thread <- myThreadId
 335   modifyMVar_ interruptTargetThread (return . (main_thread :))
 336   installSignalHandlers
 337
 338   initStaticOpts
 339   dflags0 <- initSysTools mb_top_dir defaultDynFlags
 340   dflags  <- initDynFlags dflags0
 341   env <- newHscEnv dflags
 342   ref <- newIORef env
 343   return (Session ref)
 344
 345 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 346 -- needs to call the Finder.  ToDo: untangle this.
 347 sessionHscEnv :: Session -> IO HscEnv
 348 sessionHscEnv (Session ref) = readIORef ref
 349
 350 -- -----------------------------------------------------------------------------
 351 -- Flags & settings
 352
 353 -- | Grabs the DynFlags from the Session
 354 getSessionDynFlags :: Session -> IO DynFlags
 355 getSessionDynFlags s = withSession s (return . hsc_dflags)
 356
 357 -- | Updates the DynFlags in a Session.  This also reads
 358 -- the package database (unless it has already been read),
 359 -- and prepares the compilers knowledge about packages.  It
 360 -- can be called again to load new packages: just add new
 361 -- package flags to (packageFlags dflags).
 362 --
 363 -- Returns a list of new packages that may need to be linked in using
 364 -- the dynamic linker (see 'linkPackages') as a result of new package
 365 -- flags.  If you are not doing linking or doing static linking, you
 366 -- can ignore the list of packages returned.
 367 --
 368 setSessionDynFlags :: Session -> DynFlags -> IO [PackageId]
 369 setSessionDynFlags (Session ref) dflags = do
 370   hsc_env <- readIORef ref
 371   (dflags', preload) <- initPackages dflags
 372   writeIORef ref $! hsc_env{ hsc_dflags = dflags' }
 373   return preload
 374
 375 -- | If there is no -o option, guess the name of target executable
 376 -- by using top-level source file name as a base.
 377 guessOutputFile :: Session -> IO ()
 378 guessOutputFile s = modifySession s $ \env ->
 379     let dflags = hsc_dflags env
 380         mod_graph = hsc_mod_graph env
 381         mainModuleSrcPath, guessedName :: Maybe String
 382         mainModuleSrcPath = do
 383             let isMain = (== mainModIs dflags) . ms_mod
 384             [ms] <- return (filter isMain mod_graph)
 385             ml_hs_file (ms_location ms)
 386         guessedName = fmap basenameOf mainModuleSrcPath
 387     in
 388     case outputFile dflags of
 389         Just _ -> env
 390         Nothing -> env { hsc_dflags = dflags { outputFile = guessedName } }
 391
 392 -- -----------------------------------------------------------------------------
 393 -- Targets
 394
 395 -- ToDo: think about relative vs. absolute file paths. And what
 396 -- happens when the current directory changes.
 397
 398 -- | Sets the targets for this session.  Each target may be a module name
 399 -- or a filename.  The targets correspond to the set of root modules for
 400 -- the program\/library.  Unloading the current program is achieved by
 401 -- setting the current set of targets to be empty, followed by load.
 402 setTargets :: Session -> [Target] -> IO ()
 403 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 404
 405 -- | returns the current set of targets
 406 getTargets :: Session -> IO [Target]
 407 getTargets s = withSession s (return . hsc_targets)
 408
 409 -- | Add another target
 410 addTarget :: Session -> Target -> IO ()
 411 addTarget s target
 412   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 413
 414 -- | Remove a target
 415 removeTarget :: Session -> TargetId -> IO ()
 416 removeTarget s target_id
 417   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 418   where
 419    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 420
 421 -- Attempts to guess what Target a string refers to.  This function implements
 422 -- the --make/GHCi command-line syntax for filenames:
 423 --
 424 --      - if the string looks like a Haskell source filename, then interpret
 425 --        it as such
 426 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 427 --        then use that
 428 --      - otherwise interpret the string as a module name
 429 --
 430 guessTarget :: String -> Maybe Phase -> IO Target
 431 guessTarget file (Just phase)
 432    = return (Target (TargetFile file (Just phase)) Nothing)
 433 guessTarget file Nothing
 434    | isHaskellSrcFilename file
 435    = return (Target (TargetFile file Nothing) Nothing)
 436    | otherwise
 437    = do exists <- doesFileExist hs_file
 438         if exists
 439            then return (Target (TargetFile hs_file Nothing) Nothing)
 440            else do
 441         exists <- doesFileExist lhs_file
 442         if exists
 443            then return (Target (TargetFile lhs_file Nothing) Nothing)
 444            else do
 445         return (Target (TargetModule (mkModuleName file)) Nothing)
 446      where
 447          hs_file  = file `joinFileExt` "hs"
 448          lhs_file = file `joinFileExt` "lhs"
 449
 450 -- -----------------------------------------------------------------------------
 451 -- Extending the program scope
 452
 453 extendGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 454 extendGlobalRdrScope session rdrElts
 455     = modifySession session $ \hscEnv ->
 456       let global_rdr = hsc_global_rdr_env hscEnv
 457       in hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv global_rdr rdrElts }
 458
 459 setGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 460 setGlobalRdrScope session rdrElts
 461     = modifySession session $ \hscEnv ->
 462       hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv emptyGlobalRdrEnv rdrElts }
 463
 464 extendGlobalTypeScope :: Session -> [Id] -> IO ()
 465 extendGlobalTypeScope session ids
 466     = modifySession session $ \hscEnv ->
 467       let global_type = hsc_global_type_env hscEnv
 468       in hscEnv{ hsc_global_type_env = extendTypeEnvWithIds global_type ids }
 469
 470 setGlobalTypeScope :: Session -> [Id] -> IO ()
 471 setGlobalTypeScope session ids
 472     = modifySession session $ \hscEnv ->
 473       hscEnv{ hsc_global_type_env = extendTypeEnvWithIds emptyTypeEnv ids }
 474
 475 -- -----------------------------------------------------------------------------
 476 -- Parsing Haddock comments
 477
 478 parseHaddockComment :: String -> Either String (HsDoc RdrName)
 479 parseHaddockComment string = parseHaddockParagraphs (tokenise string)
 480
 481 -- -----------------------------------------------------------------------------
 482 -- Loading the program
 483
 484 -- Perform a dependency analysis starting from the current targets
 485 -- and update the session with the new module graph.
 486 depanal :: Session -> [ModuleName] -> Bool -> IO (Maybe ModuleGraph)
 487 depanal (Session ref) excluded_mods allow_dup_roots = do
 488   hsc_env <- readIORef ref
 489   let
 490          dflags  = hsc_dflags hsc_env
 491          targets = hsc_targets hsc_env
 492          old_graph = hsc_mod_graph hsc_env
 493
 494   showPass dflags "Chasing dependencies"
 495   debugTraceMsg dflags 2 (hcat [
 496              text "Chasing modules from: ",
 497              hcat (punctuate comma (map pprTarget targets))])
 498
 499   r <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 500   case r of
 501     Just mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 502     _ -> return ()
 503   return r
 504
 505 {-
 506 -- | The result of load.
 507 data LoadResult
 508   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 509   | LoadFailed  Errors  -- ^ not all modules were loaded.
 510
 511 type Errors = [String]
 512
 513 data ErrMsg = ErrMsg {
 514         errMsgSeverity  :: Severity,  -- warning, error, etc.
 515         errMsgSpans     :: [SrcSpan],
 516         errMsgShortDoc  :: Doc,
 517         errMsgExtraInfo :: Doc
 518         }
 519 -}
 520
 521 data LoadHowMuch
 522    = LoadAllTargets
 523    | LoadUpTo ModuleName
 524    | LoadDependenciesOf ModuleName
 525
 526 -- | Try to load the program.  If a Module is supplied, then just
 527 -- attempt to load up to this target.  If no Module is supplied,
 528 -- then try to load all targets.
 529 load :: Session -> LoadHowMuch -> IO SuccessFlag
 530 load s@(Session ref) how_much
 531    = do
 532         -- Dependency analysis first.  Note that this fixes the module graph:
 533         -- even if we don't get a fully successful upsweep, the full module
 534         -- graph is still retained in the Session.  We can tell which modules
 535         -- were successfully loaded by inspecting the Session's HPT.
 536         mb_graph <- depanal s [] False
 537         case mb_graph of
 538            Just mod_graph -> load2 s how_much mod_graph
 539            Nothing        -> return Failed
 540
 541 load2 s@(Session ref) how_much mod_graph = do
 542         guessOutputFile s
 543         hsc_env <- readIORef ref
 544
 545         let hpt1      = hsc_HPT hsc_env
 546         let dflags    = hsc_dflags hsc_env
 547
 548         -- The "bad" boot modules are the ones for which we have
 549         -- B.hs-boot in the module graph, but no B.hs
 550         -- The downsweep should have ensured this does not happen
 551         -- (see msDeps)
 552         let all_home_mods = [ms_mod_name s
 553                             | s <- mod_graph, not (isBootSummary s)]
 554 #ifdef DEBUG
 555             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 556                                         not (ms_mod_name s `elem` all_home_mods)]
 557 #endif
 558         ASSERT( null bad_boot_mods ) return ()
 559
 560         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 561         -- graph with cycles.  Among other things, it is used for
 562         -- backing out partially complete cycles following a failed
 563         -- upsweep, and for removing from hpt all the modules
 564         -- not in strict downwards closure, during calls to compile.
 565         let mg2_with_srcimps :: [SCC ModSummary]
 566             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 567
 568         -- If we can determine that any of the {-# SOURCE #-} imports
 569         -- are definitely unnecessary, then emit a warning.
 570         warnUnnecessarySourceImports dflags mg2_with_srcimps
 571
 572         let
 573             -- check the stability property for each module.
 574             stable_mods@(stable_obj,stable_bco)
 575                 = checkStability hpt1 mg2_with_srcimps all_home_mods
 576
 577             -- prune bits of the HPT which are definitely redundant now,
 578             -- to save space.
 579             pruned_hpt = pruneHomePackageTable hpt1
 580                                 (flattenSCCs mg2_with_srcimps)
 581                                 stable_mods
 582
 583         evaluate pruned_hpt
 584
 585         debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 586                                 text "Stable BCO:" <+> ppr stable_bco)
 587
 588         -- Unload any modules which are going to be re-linked this time around.
 589         let stable_linkables = [ linkable
 590                                | m <- stable_obj++stable_bco,
 591                                  Just hmi <- [lookupUFM pruned_hpt m],
 592                                  Just linkable <- [hm_linkable hmi] ]
 593         unload hsc_env stable_linkables
 594
 595         -- We could at this point detect cycles which aren't broken by
 596         -- a source-import, and complain immediately, but it seems better
 597         -- to let upsweep_mods do this, so at least some useful work gets
 598         -- done before the upsweep is abandoned.
 599         --hPutStrLn stderr "after tsort:\n"
 600         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 601
 602         -- Now do the upsweep, calling compile for each module in
 603         -- turn.  Final result is version 3 of everything.
 604
 605         -- Topologically sort the module graph, this time including hi-boot
 606         -- nodes, and possibly just including the portion of the graph
 607         -- reachable from the module specified in the 2nd argument to load.
 608         -- This graph should be cycle-free.
 609         -- If we're restricting the upsweep to a portion of the graph, we
 610         -- also want to retain everything that is still stable.
 611         let full_mg :: [SCC ModSummary]
 612             full_mg    = topSortModuleGraph False mod_graph Nothing
 613
 614             maybe_top_mod = case how_much of
 615                                 LoadUpTo m           -> Just m
 616                                 LoadDependenciesOf m -> Just m
 617                                 _                    -> Nothing
 618
 619             partial_mg0 :: [SCC ModSummary]
 620             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 621
 622             -- LoadDependenciesOf m: we want the upsweep to stop just
 623             -- short of the specified module (unless the specified module
 624             -- is stable).
 625             partial_mg
 626                 | LoadDependenciesOf mod <- how_much
 627                 = ASSERT( case last partial_mg0 of
 628                             AcyclicSCC ms -> ms_mod_name ms == mod; _ -> False )
 629                   List.init partial_mg0
 630                 | otherwise
 631                 = partial_mg0
 632
 633             stable_mg =
 634                 [ AcyclicSCC ms
 635                 | AcyclicSCC ms <- full_mg,
 636                   ms_mod_name ms `elem` stable_obj++stable_bco,
 637                   ms_mod_name ms `notElem` [ ms_mod_name ms' |
 638                                                 AcyclicSCC ms' <- partial_mg ] ]
 639
 640             mg = stable_mg ++ partial_mg
 641
 642         -- clean up between compilations
 643         let cleanup = cleanTempFilesExcept dflags
 644                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 645
 646         debugTraceMsg dflags 2 (hang (text "Ready for upsweep")
 647                                    2 (ppr mg))
 648         (upsweep_ok, hsc_env1, modsUpswept)
 649            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 650                            pruned_hpt stable_mods cleanup mg
 651
 652         -- Make modsDone be the summaries for each home module now
 653         -- available; this should equal the domain of hpt3.
 654         -- Get in in a roughly top .. bottom order (hence reverse).
 655
 656         let modsDone = reverse modsUpswept
 657
 658         -- Try and do linking in some form, depending on whether the
 659         -- upsweep was completely or only partially successful.
 660
 661         if succeeded upsweep_ok
 662
 663          then
 664            -- Easy; just relink it all.
 665            do debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 666
 667               -- Clean up after ourselves
 668               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 669
 670               -- Issue a warning for the confusing case where the user
 671               -- said '-o foo' but we're not going to do any linking.
 672               -- We attempt linking if either (a) one of the modules is
 673               -- called Main, or (b) the user said -no-hs-main, indicating
 674               -- that main() is going to come from somewhere else.
 675               --
 676               let ofile = outputFile dflags
 677               let no_hs_main = dopt Opt_NoHsMain dflags
 678               let
 679                 main_mod = mainModIs dflags
 680                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 681                 do_linking = a_root_is_Main || no_hs_main
 682
 683               when (ghcLink dflags == LinkBinary
 684                     && isJust ofile && not do_linking) $
 685                 debugTraceMsg dflags 1 $
 686                     text ("Warning: output was redirected with -o, " ++
 687                           "but no output will be generated\n" ++
 688                           "because there is no " ++
 689                           moduleNameString (moduleName main_mod) ++ " module.")
 690
 691               -- link everything together
 692               linkresult <- link (ghcLink dflags) dflags do_linking (hsc_HPT hsc_env1)
 693
 694               loadFinish Succeeded linkresult ref hsc_env1
 695
 696          else
 697            -- Tricky.  We need to back out the effects of compiling any
 698            -- half-done cycles, both so as to clean up the top level envs
 699            -- and to avoid telling the interactive linker to link them.
 700            do debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 701
 702               let modsDone_names
 703                      = map ms_mod modsDone
 704               let mods_to_zap_names
 705                      = findPartiallyCompletedCycles modsDone_names
 706                           mg2_with_srcimps
 707               let mods_to_keep
 708                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 709                           modsDone
 710
 711               let hpt4 = retainInTopLevelEnvs (map ms_mod_name mods_to_keep)
 712                                               (hsc_HPT hsc_env1)
 713
 714               -- Clean up after ourselves
 715               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 716
 717               -- there should be no Nothings where linkables should be, now
 718               ASSERT(all (isJust.hm_linkable)
 719                         (eltsUFM (hsc_HPT hsc_env))) do
 720
 721               -- Link everything together
 722               linkresult <- link (ghcLink dflags) dflags False hpt4
 723
 724               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 725               loadFinish Failed linkresult ref hsc_env4
 726
 727 -- Finish up after a load.
 728
 729 -- If the link failed, unload everything and return.
 730 loadFinish all_ok Failed ref hsc_env
 731   = do unload hsc_env []
 732        writeIORef ref $! discardProg hsc_env
 733        return Failed
 734
 735 -- Empty the interactive context and set the module context to the topmost
 736 -- newly loaded module, or the Prelude if none were loaded.
 737 loadFinish all_ok Succeeded ref hsc_env
 738   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 739        return all_ok
 740
 741
 742 -- Forget the current program, but retain the persistent info in HscEnv
 743 discardProg :: HscEnv -> HscEnv
 744 discardProg hsc_env
 745   = hsc_env { hsc_mod_graph = emptyMG,
 746               hsc_IC = emptyInteractiveContext,
 747               hsc_HPT = emptyHomePackageTable }
 748
 749 -- used to fish out the preprocess output files for the purposes of
 750 -- cleaning up.  The preprocessed file *might* be the same as the
 751 -- source file, but that doesn't do any harm.
 752 ppFilesFromSummaries summaries = map ms_hspp_file summaries
 753
 754 -- -----------------------------------------------------------------------------
 755 -- Check module
 756
 757 data CheckedModule =
 758   CheckedModule { parsedSource      :: ParsedSource,
 759                   renamedSource     :: Maybe RenamedSource,
 760                   typecheckedSource :: Maybe TypecheckedSource,
 761                   checkedModuleInfo :: Maybe ModuleInfo
 762                 }
 763         -- ToDo: improvements that could be made here:
 764         --  if the module succeeded renaming but not typechecking,
 765         --  we can still get back the GlobalRdrEnv and exports, so
 766         --  perhaps the ModuleInfo should be split up into separate
 767         --  fields within CheckedModule.
 768
 769 type ParsedSource      = Located (HsModule RdrName)
 770 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name],
 771                           Maybe (HsDoc Name), HaddockModInfo Name)
 772 type TypecheckedSource = LHsBinds Id
 773
 774 -- NOTE:
 775 --   - things that aren't in the output of the typechecker right now:
 776 --     - the export list
 777 --     - the imports
 778 --     - type signatures
 779 --     - type/data/newtype declarations
 780 --     - class declarations
 781 --     - instances
 782 --   - extra things in the typechecker's output:
 783 --     - default methods are turned into top-level decls.
 784 --     - dictionary bindings
 785
 786
 787 -- | This is the way to get access to parsed and typechecked source code
 788 -- for a module.  'checkModule' loads all the dependencies of the specified
 789 -- module in the Session, and then attempts to typecheck the module.  If
 790 -- successful, it returns the abstract syntax for the module.
 791 checkModule :: Session -> ModuleName -> IO (Maybe CheckedModule)
 792 checkModule session@(Session ref) mod = do
 793         -- load up the dependencies first
 794    r <- load session (LoadDependenciesOf mod)
 795    if (failed r) then return Nothing else do
 796
 797         -- now parse & typecheck the module
 798    hsc_env <- readIORef ref
 799    let mg  = hsc_mod_graph hsc_env
 800    case [ ms | ms <- mg, ms_mod_name ms == mod ] of
 801         [] -> return Nothing
 802         (ms:_) -> do
 803            mbChecked <- hscFileCheck hsc_env{hsc_dflags=ms_hspp_opts ms} ms
 804            case mbChecked of
 805              Nothing -> return Nothing
 806              Just (HscChecked parsed renamed Nothing) ->
 807                    return (Just (CheckedModule {
 808                                         parsedSource = parsed,
 809                                         renamedSource = renamed,
 810                                         typecheckedSource = Nothing,
 811                                         checkedModuleInfo = Nothing }))
 812              Just (HscChecked parsed renamed
 813                            (Just (tc_binds, rdr_env, details))) -> do
 814                    let minf = ModuleInfo {
 815                                 minf_type_env  = md_types details,
 816                                 minf_exports   = availsToNameSet $
 817                                                      md_exports details,
 818                                 minf_rdr_env   = Just rdr_env,
 819                                 minf_instances = md_insts details
 820 #ifdef GHCI
 821                                ,minf_modBreaks = emptyModBreaks
 822 #endif
 823                               }
 824                    return (Just (CheckedModule {
 825                                         parsedSource = parsed,
 826                                         renamedSource = renamed,
 827                                         typecheckedSource = Just tc_binds,
 828                                         checkedModuleInfo = Just minf }))
 829
 830 -- ---------------------------------------------------------------------------
 831 -- Unloading
 832
 833 unload :: HscEnv -> [Linkable] -> IO ()
 834 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 835   = case ghcLink (hsc_dflags hsc_env) of
 836 #ifdef GHCI
 837         LinkInMemory -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 838 #else
 839         LinkInMemory -> panic "unload: no interpreter"
 840 #endif
 841         other -> return ()
 842
 843 -- -----------------------------------------------------------------------------
 844 -- checkStability
 845
 846 {-
 847   Stability tells us which modules definitely do not need to be recompiled.
 848   There are two main reasons for having stability:
 849
 850    - avoid doing a complete upsweep of the module graph in GHCi when
 851      modules near the bottom of the tree have not changed.
 852
 853    - to tell GHCi when it can load object code: we can only load object code
 854      for a module when we also load object code fo  all of the imports of the
 855      module.  So we need to know that we will definitely not be recompiling
 856      any of these modules, and we can use the object code.
 857
 858   The stability check is as follows.  Both stableObject and
 859   stableBCO are used during the upsweep phase later.
 860
 861   -------------------
 862   stable m = stableObject m || stableBCO m
 863
 864   stableObject m =
 865         all stableObject (imports m)
 866         && old linkable does not exist, or is == on-disk .o
 867         && date(on-disk .o) > date(.hs)
 868
 869   stableBCO m =
 870         all stable (imports m)
 871         && date(BCO) > date(.hs)
 872   -------------------
 873
 874   These properties embody the following ideas:
 875
 876     - if a module is stable, then:
 877         - if it has been compiled in a previous pass (present in HPT)
 878           then it does not need to be compiled or re-linked.
 879         - if it has not been compiled in a previous pass,
 880           then we only need to read its .hi file from disk and
 881           link it to produce a ModDetails.
 882
 883     - if a modules is not stable, we will definitely be at least
 884       re-linking, and possibly re-compiling it during the upsweep.
 885       All non-stable modules can (and should) therefore be unlinked
 886       before the upsweep.
 887
 888     - Note that objects are only considered stable if they only depend
 889       on other objects.  We can't link object code against byte code.
 890 -}
 891
 892 checkStability
 893         :: HomePackageTable             -- HPT from last compilation
 894         -> [SCC ModSummary]             -- current module graph (cyclic)
 895         -> [ModuleName]                 -- all home modules
 896         -> ([ModuleName],               -- stableObject
 897             [ModuleName])               -- stableBCO
 898
 899 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 900   where
 901    checkSCC (stable_obj, stable_bco) scc0
 902      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 903      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 904      | otherwise     = (stable_obj, stable_bco)
 905      where
 906         scc = flattenSCC scc0
 907         scc_mods = map ms_mod_name scc
 908         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 909
 910         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 911             -- all imports outside the current SCC, but in the home pkg
 912
 913         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 914         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 915
 916         stableObjects =
 917            and stable_obj_imps
 918            && all object_ok scc
 919
 920         stableBCOs =
 921            and (zipWith (||) stable_obj_imps stable_bco_imps)
 922            && all bco_ok scc
 923
 924         object_ok ms
 925           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 926                                          && same_as_prev t
 927           | otherwise = False
 928           where
 929              same_as_prev t = case lookupUFM hpt (ms_mod_name ms) of
 930                                 Just hmi  | Just l <- hm_linkable hmi
 931                                  -> isObjectLinkable l && t == linkableTime l
 932                                 _other  -> True
 933                 -- why '>=' rather than '>' above?  If the filesystem stores
 934                 -- times to the nearset second, we may occasionally find that
 935                 -- the object & source have the same modification time,
 936                 -- especially if the source was automatically generated
 937                 -- and compiled.  Using >= is slightly unsafe, but it matches
 938                 -- make's behaviour.
 939
 940         bco_ok ms
 941           = case lookupUFM hpt (ms_mod_name ms) of
 942                 Just hmi  | Just l <- hm_linkable hmi ->
 943                         not (isObjectLinkable l) &&
 944                         linkableTime l >= ms_hs_date ms
 945                 _other  -> False
 946
 947 ms_allimps :: ModSummary -> [ModuleName]
 948 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 949
 950 -- -----------------------------------------------------------------------------
 951 -- Prune the HomePackageTable
 952
 953 -- Before doing an upsweep, we can throw away:
 954 --
 955 --   - For non-stable modules:
 956 --      - all ModDetails, all linked code
 957 --   - all unlinked code that is out of date with respect to
 958 --     the source file
 959 --
 960 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 961 -- space at the end of the upsweep, because the topmost ModDetails of the
 962 -- old HPT holds on to the entire type environment from the previous
 963 -- compilation.
 964
 965 pruneHomePackageTable
 966    :: HomePackageTable
 967    -> [ModSummary]
 968    -> ([ModuleName],[ModuleName])
 969    -> HomePackageTable
 970
 971 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
 972   = mapUFM prune hpt
 973   where prune hmi
 974           | is_stable modl = hmi'
 975           | otherwise      = hmi'{ hm_details = emptyModDetails }
 976           where
 977            modl = moduleName (mi_module (hm_iface hmi))
 978            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
 979                 = hmi{ hm_linkable = Nothing }
 980                 | otherwise
 981                 = hmi
 982                 where ms = expectJust "prune" (lookupUFM ms_map modl)
 983
 984         ms_map = listToUFM [(ms_mod_name ms, ms) | ms <- summ]
 985
 986         is_stable m = m `elem` stable_obj || m `elem` stable_bco
 987
 988 -- -----------------------------------------------------------------------------
 989
 990 -- Return (names of) all those in modsDone who are part of a cycle
 991 -- as defined by theGraph.
 992 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 993 findPartiallyCompletedCycles modsDone theGraph
 994    = chew theGraph
 995      where
 996         chew [] = []
 997         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 998         chew ((CyclicSCC vs):rest)
 999            = let names_in_this_cycle = nub (map ms_mod vs)
1000                  mods_in_this_cycle
1001                     = nub ([done | done <- modsDone,
1002                                    done `elem` names_in_this_cycle])
1003                  chewed_rest = chew rest
1004              in
1005              if   notNull mods_in_this_cycle
1006                   && length mods_in_this_cycle < length names_in_this_cycle
1007              then mods_in_this_cycle ++ chewed_rest
1008              else chewed_rest
1009
1010 -- -----------------------------------------------------------------------------
1011 -- The upsweep
1012
1013 -- This is where we compile each module in the module graph, in a pass
1014 -- from the bottom to the top of the graph.
1015
1016 -- There better had not be any cyclic groups here -- we check for them.
1017
1018 upsweep
1019     :: HscEnv                   -- Includes initially-empty HPT
1020     -> HomePackageTable         -- HPT from last time round (pruned)
1021     -> ([ModuleName],[ModuleName]) -- stable modules (see checkStability)
1022     -> IO ()                    -- How to clean up unwanted tmp files
1023     -> [SCC ModSummary]         -- Mods to do (the worklist)
1024     -> IO (SuccessFlag,
1025            HscEnv,              -- With an updated HPT
1026            [ModSummary])        -- Mods which succeeded
1027
1028 upsweep hsc_env old_hpt stable_mods cleanup mods
1029    = upsweep' hsc_env old_hpt stable_mods cleanup mods 1 (length mods)
1030
1031 upsweep' hsc_env old_hpt stable_mods cleanup
1032      [] _ _
1033    = return (Succeeded, hsc_env, [])
1034
1035 upsweep' hsc_env old_hpt stable_mods cleanup
1036      (CyclicSCC ms:_) _ _
1037    = do fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1038         return (Failed, hsc_env, [])
1039
1040 upsweep' hsc_env old_hpt stable_mods cleanup
1041      (AcyclicSCC mod:mods) mod_index nmods
1042    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1043         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1044         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1045
1046         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
1047                        mod_index nmods
1048
1049         cleanup         -- Remove unwanted tmp files between compilations
1050
1051         case mb_mod_info of
1052             Nothing -> return (Failed, hsc_env, [])
1053             Just mod_info -> do
1054                 { let this_mod = ms_mod_name mod
1055
1056                         -- Add new info to hsc_env
1057                       hpt1     = addToUFM (hsc_HPT hsc_env) this_mod mod_info
1058                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1059
1060                         -- Space-saving: delete the old HPT entry
1061                         -- for mod BUT if mod is a hs-boot
1062                         -- node, don't delete it.  For the
1063                         -- interface, the HPT entry is probaby for the
1064                         -- main Haskell source file.  Deleting it
1065                         -- would force .. (what?? --SDM)
1066                       old_hpt1 | isBootSummary mod = old_hpt
1067                                | otherwise = delFromUFM old_hpt this_mod
1068
1069                 ; (restOK, hsc_env2, modOKs)
1070                         <- upsweep' hsc_env1 old_hpt1 stable_mods cleanup
1071                                 mods (mod_index+1) nmods
1072                 ; return (restOK, hsc_env2, mod:modOKs)
1073                 }
1074
1075
1076 -- Compile a single module.  Always produce a Linkable for it if
1077 -- successful.  If no compilation happened, return the old Linkable.
1078 upsweep_mod :: HscEnv
1079             -> HomePackageTable
1080             -> ([ModuleName],[ModuleName])
1081             -> ModSummary
1082             -> Int  -- index of module
1083             -> Int  -- total number of modules
1084             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1085
1086 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1087    =    let
1088             this_mod_name = ms_mod_name summary
1089             this_mod    = ms_mod summary
1090             mb_obj_date = ms_obj_date summary
1091             obj_fn      = ml_obj_file (ms_location summary)
1092             hs_date     = ms_hs_date summary
1093
1094             is_stable_obj = this_mod_name `elem` stable_obj
1095             is_stable_bco = this_mod_name `elem` stable_bco
1096
1097             old_hmi = lookupUFM old_hpt this_mod_name
1098
1099             -- We're using the dflags for this module now, obtained by
1100             -- applying any options in its LANGUAGE & OPTIONS_GHC pragmas.
1101             dflags = ms_hspp_opts summary
1102             prevailing_target = hscTarget (hsc_dflags hsc_env)
1103             local_target      = hscTarget dflags
1104
1105             -- If OPTIONS_GHC contains -fasm or -fvia-C, be careful that
1106             -- we don't do anything dodgy: these should only work to change
1107             -- from -fvia-C to -fasm and vice-versa, otherwise we could
1108             -- end up trying to link object code to byte code.
1109             target = if prevailing_target /= local_target
1110                         && (not (isObjectTarget prevailing_target)
1111                             || not (isObjectTarget local_target))
1112                         then prevailing_target
1113                         else local_target
1114
1115             -- store the corrected hscTarget into the summary
1116             summary' = summary{ ms_hspp_opts = dflags { hscTarget = target } }
1117
1118             -- The old interface is ok if
1119             --  a) we're compiling a source file, and the old HPT
1120             --     entry is for a source file
1121             --  b) we're compiling a hs-boot file
1122             -- Case (b) allows an hs-boot file to get the interface of its
1123             -- real source file on the second iteration of the compilation
1124             -- manager, but that does no harm.  Otherwise the hs-boot file
1125             -- will always be recompiled
1126
1127             mb_old_iface
1128                 = case old_hmi of
1129                      Nothing                              -> Nothing
1130                      Just hm_info | isBootSummary summary -> Just iface
1131                                   | not (mi_boot iface)   -> Just iface
1132                                   | otherwise             -> Nothing
1133                                    where
1134                                      iface = hm_iface hm_info
1135
1136             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1137             compile_it  = upsweep_compile hsc_env old_hpt this_mod_name
1138                                 summary' mod_index nmods mb_old_iface
1139
1140             compile_it_discard_iface
1141                         = upsweep_compile hsc_env old_hpt this_mod_name
1142                                 summary' mod_index nmods Nothing
1143
1144         in
1145         case target of
1146
1147             _any
1148                 -- Regardless of whether we're generating object code or
1149                 -- byte code, we can always use an existing object file
1150                 -- if it is *stable* (see checkStability).
1151                 | is_stable_obj, isJust old_hmi ->
1152                         return old_hmi
1153                         -- object is stable, and we have an entry in the
1154                         -- old HPT: nothing to do
1155
1156                 | is_stable_obj, isNothing old_hmi -> do
1157                         linkable <- findObjectLinkable this_mod obj_fn
1158                                         (expectJust "upseep1" mb_obj_date)
1159                         compile_it (Just linkable)
1160                         -- object is stable, but we need to load the interface
1161                         -- off disk to make a HMI.
1162
1163             HscInterpreted
1164                 | is_stable_bco ->
1165                         ASSERT(isJust old_hmi) -- must be in the old_hpt
1166                         return old_hmi
1167                         -- BCO is stable: nothing to do
1168
1169                 | Just hmi <- old_hmi,
1170                   Just l <- hm_linkable hmi, not (isObjectLinkable l),
1171                   linkableTime l >= ms_hs_date summary ->
1172                         compile_it (Just l)
1173                         -- we have an old BCO that is up to date with respect
1174                         -- to the source: do a recompilation check as normal.
1175
1176                 | otherwise ->
1177                         compile_it Nothing
1178                         -- no existing code at all: we must recompile.
1179
1180               -- When generating object code, if there's an up-to-date
1181               -- object file on the disk, then we can use it.
1182               -- However, if the object file is new (compared to any
1183               -- linkable we had from a previous compilation), then we
1184               -- must discard any in-memory interface, because this
1185               -- means the user has compiled the source file
1186               -- separately and generated a new interface, that we must
1187               -- read from the disk.
1188               --
1189             obj | isObjectTarget obj,
1190                   Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1191                      case old_hmi of
1192                         Just hmi
1193                           | Just l <- hm_linkable hmi,
1194                             isObjectLinkable l && linkableTime l == obj_date
1195                             -> compile_it (Just l)
1196                         _otherwise -> do
1197                           linkable <- findObjectLinkable this_mod obj_fn obj_date
1198                           compile_it_discard_iface (Just linkable)
1199
1200             _otherwise ->
1201                   compile_it Nothing
1202
1203
1204 -- Run hsc to compile a module
1205 upsweep_compile hsc_env old_hpt this_mod summary
1206                 mod_index nmods
1207                 mb_old_iface
1208                 mb_old_linkable
1209  = do
1210    compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1211                         mod_index nmods
1212
1213    case compresult of
1214         -- Compilation failed.  Compile may still have updated the PCS, tho.
1215         CompErrs -> return Nothing
1216
1217         -- Compilation "succeeded", and may or may not have returned a new
1218         -- linkable (depending on whether compilation was actually performed
1219         -- or not).
1220         CompOK new_details new_iface new_linkable
1221               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1222                                                  hm_details = new_details,
1223                                                  hm_linkable = new_linkable }
1224                     return (Just new_info)
1225
1226
1227 -- Filter modules in the HPT
1228 retainInTopLevelEnvs :: [ModuleName] -> HomePackageTable -> HomePackageTable
1229 retainInTopLevelEnvs keep_these hpt
1230    = listToUFM   [ (mod, expectJust "retain" mb_mod_info)
1231                  | mod <- keep_these
1232                  , let mb_mod_info = lookupUFM hpt mod
1233                  , isJust mb_mod_info ]
1234
1235 -- ---------------------------------------------------------------------------
1236 -- Topological sort of the module graph
1237
1238 topSortModuleGraph
1239           :: Bool               -- Drop hi-boot nodes? (see below)
1240           -> [ModSummary]
1241           -> Maybe ModuleName
1242           -> [SCC ModSummary]
1243 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1244 -- The resulting list of strongly-connected-components is in topologically
1245 -- sorted order, starting with the module(s) at the bottom of the
1246 -- dependency graph (ie compile them first) and ending with the ones at
1247 -- the top.
1248 --
1249 -- Drop hi-boot nodes (first boolean arg)?
1250 --
1251 --   False:     treat the hi-boot summaries as nodes of the graph,
1252 --              so the graph must be acyclic
1253 --
1254 --   True:      eliminate the hi-boot nodes, and instead pretend
1255 --              the a source-import of Foo is an import of Foo
1256 --              The resulting graph has no hi-boot nodes, but can by cyclic
1257
1258 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1259   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1260 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1261   = stronglyConnComp (map vertex_fn (reachable graph root))
1262   where
1263         -- restrict the graph to just those modules reachable from
1264         -- the specified module.  We do this by building a graph with
1265         -- the full set of nodes, and determining the reachable set from
1266         -- the specified node.
1267         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1268         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1269         root
1270           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1271           | otherwise  = throwDyn (ProgramError "module does not exist")
1272
1273 moduleGraphNodes :: Bool -> [ModSummary]
1274   -> ([(ModSummary, Int, [Int])], HscSource -> ModuleName -> Maybe Int)
1275 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1276    where
1277         -- Drop hs-boot nodes by using HsSrcFile as the key
1278         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1279                     | otherwise          = HsBootFile
1280
1281         -- We use integers as the keys for the SCC algorithm
1282         nodes :: [(ModSummary, Int, [Int])]
1283         nodes = [(s, expectJust "topSort" $
1284                         lookup_key (ms_hsc_src s) (ms_mod_name s),
1285                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1286                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s)) ++
1287                      (-- see [boot-edges] below
1288                       if drop_hs_boot_nodes || ms_hsc_src s == HsBootFile
1289                         then []
1290                         else case lookup_key HsBootFile (ms_mod_name s) of
1291                                 Nothing -> []
1292                                 Just k  -> [k])
1293                  )
1294                 | s <- summaries
1295                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1296                 -- Drop the hi-boot ones if told to do so
1297
1298         -- [boot-edges] if this is a .hs and there is an equivalent
1299         -- .hs-boot, add a link from the former to the latter.  This
1300         -- has the effect of detecting bogus cases where the .hs-boot
1301         -- depends on the .hs, by introducing a cycle.  Additionally,
1302         -- it ensures that we will always process the .hs-boot before
1303         -- the .hs, and so the HomePackageTable will always have the
1304         -- most up to date information.
1305
1306         key_map :: NodeMap Int
1307         key_map = listToFM ([(moduleName (ms_mod s), ms_hsc_src s)
1308                             | s <- summaries]
1309                            `zip` [1..])
1310
1311         lookup_key :: HscSource -> ModuleName -> Maybe Int
1312         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1313
1314         out_edge_keys :: HscSource -> [ModuleName] -> [Int]
1315         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1316                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1317                 -- the IsBootInterface parameter True; else False
1318
1319
1320 type NodeKey   = (ModuleName, HscSource)  -- The nodes of the graph are
1321 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1322
1323 msKey :: ModSummary -> NodeKey
1324 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (moduleName mod,boot)
1325
1326 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1327 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1328
1329 nodeMapElts :: NodeMap a -> [a]
1330 nodeMapElts = eltsFM
1331
1332 -- If there are {-# SOURCE #-} imports between strongly connected
1333 -- components in the topological sort, then those imports can
1334 -- definitely be replaced by ordinary non-SOURCE imports: if SOURCE
1335 -- were necessary, then the edge would be part of a cycle.
1336 warnUnnecessarySourceImports :: DynFlags -> [SCC ModSummary] -> IO ()
1337 warnUnnecessarySourceImports dflags sccs =
1338   printBagOfWarnings dflags (listToBag (concat (map (check.flattenSCC) sccs)))
1339   where check ms =
1340            let mods_in_this_cycle = map ms_mod_name ms in
1341            [ warn m i | m <- ms, i <- ms_srcimps m,
1342                         unLoc i `notElem`  mods_in_this_cycle ]
1343
1344         warn :: ModSummary -> Located ModuleName -> WarnMsg
1345         warn ms (L loc mod) =
1346            mkPlainErrMsg loc
1347                 (ptext SLIT("Warning: {-# SOURCE #-} unnecessary in import of ")
1348                  <+> quotes (ppr mod))
1349
1350 -----------------------------------------------------------------------------
1351 -- Downsweep (dependency analysis)
1352
1353 -- Chase downwards from the specified root set, returning summaries
1354 -- for all home modules encountered.  Only follow source-import
1355 -- links.
1356
1357 -- We pass in the previous collection of summaries, which is used as a
1358 -- cache to avoid recalculating a module summary if the source is
1359 -- unchanged.
1360 --
1361 -- The returned list of [ModSummary] nodes has one node for each home-package
1362 -- module, plus one for any hs-boot files.  The imports of these nodes
1363 -- are all there, including the imports of non-home-package modules.
1364
1365 downsweep :: HscEnv
1366           -> [ModSummary]       -- Old summaries
1367           -> [ModuleName]       -- Ignore dependencies on these; treat
1368                                 -- them as if they were package modules
1369           -> Bool               -- True <=> allow multiple targets to have
1370                                 --          the same module name; this is
1371                                 --          very useful for ghc -M
1372           -> IO (Maybe [ModSummary])
1373                 -- The elts of [ModSummary] all have distinct
1374                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1375                 -- in which case there can be repeats
1376 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1377    = -- catch error messages and return them
1378      handleDyn (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1379        rootSummaries <- mapM getRootSummary roots
1380        let root_map = mkRootMap rootSummaries
1381        checkDuplicates root_map
1382        summs <- loop (concatMap msDeps rootSummaries) root_map
1383        return (Just summs)
1384      where
1385         roots = hsc_targets hsc_env
1386
1387         old_summary_map :: NodeMap ModSummary
1388         old_summary_map = mkNodeMap old_summaries
1389
1390         getRootSummary :: Target -> IO ModSummary
1391         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1392            = do exists <- doesFileExist file
1393                 if exists
1394                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1395                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1396                            text "can't find file:" <+> text file
1397         getRootSummary (Target (TargetModule modl) maybe_buf)
1398            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1399                                            (L rootLoc modl) maybe_buf excl_mods
1400                 case maybe_summary of
1401                    Nothing -> packageModErr modl
1402                    Just s  -> return s
1403
1404         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1405
1406         -- In a root module, the filename is allowed to diverge from the module
1407         -- name, so we have to check that there aren't multiple root files
1408         -- defining the same module (otherwise the duplicates will be silently
1409         -- ignored, leading to confusing behaviour).
1410         checkDuplicates :: NodeMap [ModSummary] -> IO ()
1411         checkDuplicates root_map
1412            | allow_dup_roots = return ()
1413            | null dup_roots  = return ()
1414            | otherwise       = multiRootsErr (head dup_roots)
1415            where
1416              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1417              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1418
1419         loop :: [(Located ModuleName,IsBootInterface)]
1420                         -- Work list: process these modules
1421              -> NodeMap [ModSummary]
1422                         -- Visited set; the range is a list because
1423                         -- the roots can have the same module names
1424                         -- if allow_dup_roots is True
1425              -> IO [ModSummary]
1426                         -- The result includes the worklist, except
1427                         -- for those mentioned in the visited set
1428         loop [] done      = return (concat (nodeMapElts done))
1429         loop ((wanted_mod, is_boot) : ss) done
1430           | Just summs <- lookupFM done key
1431           = if isSingleton summs then
1432                 loop ss done
1433             else
1434                 do { multiRootsErr summs; return [] }
1435           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1436                                                  is_boot wanted_mod Nothing excl_mods
1437                                    ; case mb_s of
1438                                         Nothing -> loop ss done
1439                                         Just s  -> loop (msDeps s ++ ss)
1440                                                         (addToFM done key [s]) }
1441           where
1442             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1443
1444 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1445 mkRootMap summaries = addListToFM_C (++) emptyFM
1446                         [ (msKey s, [s]) | s <- summaries ]
1447
1448 msDeps :: ModSummary -> [(Located ModuleName, IsBootInterface)]
1449 -- (msDeps s) returns the dependencies of the ModSummary s.
1450 -- A wrinkle is that for a {-# SOURCE #-} import we return
1451 --      *both* the hs-boot file
1452 --      *and* the source file
1453 -- as "dependencies".  That ensures that the list of all relevant
1454 -- modules always contains B.hs if it contains B.hs-boot.
1455 -- Remember, this pass isn't doing the topological sort.  It's
1456 -- just gathering the list of all relevant ModSummaries
1457 msDeps s =
1458     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1459          ++ [ (m,False) | m <- ms_imps s ]
1460
1461 -----------------------------------------------------------------------------
1462 -- Summarising modules
1463
1464 -- We have two types of summarisation:
1465 --
1466 --    * Summarise a file.  This is used for the root module(s) passed to
1467 --      cmLoadModules.  The file is read, and used to determine the root
1468 --      module name.  The module name may differ from the filename.
1469 --
1470 --    * Summarise a module.  We are given a module name, and must provide
1471 --      a summary.  The finder is used to locate the file in which the module
1472 --      resides.
1473
1474 summariseFile
1475         :: HscEnv
1476         -> [ModSummary]                 -- old summaries
1477         -> FilePath                     -- source file name
1478         -> Maybe Phase                  -- start phase
1479         -> Maybe (StringBuffer,ClockTime)
1480         -> IO ModSummary
1481
1482 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1483         -- we can use a cached summary if one is available and the
1484         -- source file hasn't changed,  But we have to look up the summary
1485         -- by source file, rather than module name as we do in summarise.
1486    | Just old_summary <- findSummaryBySourceFile old_summaries file
1487    = do
1488         let location = ms_location old_summary
1489
1490                 -- return the cached summary if the source didn't change
1491         src_timestamp <- case maybe_buf of
1492                            Just (_,t) -> return t
1493                            Nothing    -> getModificationTime file
1494                 -- The file exists; we checked in getRootSummary above.
1495                 -- If it gets removed subsequently, then this
1496                 -- getModificationTime may fail, but that's the right
1497                 -- behaviour.
1498
1499         if ms_hs_date old_summary == src_timestamp
1500            then do -- update the object-file timestamp
1501                   obj_timestamp <- getObjTimestamp location False
1502                   return old_summary{ ms_obj_date = obj_timestamp }
1503            else
1504                 new_summary
1505
1506    | otherwise
1507    = new_summary
1508   where
1509     new_summary = do
1510         let dflags = hsc_dflags hsc_env
1511
1512         (dflags', hspp_fn, buf)
1513             <- preprocessFile dflags file mb_phase maybe_buf
1514
1515         (srcimps,the_imps, L _ mod_name) <- getImports dflags' buf hspp_fn
1516
1517         -- Make a ModLocation for this file
1518         location <- mkHomeModLocation dflags mod_name file
1519
1520         -- Tell the Finder cache where it is, so that subsequent calls
1521         -- to findModule will find it, even if it's not on any search path
1522         mod <- addHomeModuleToFinder hsc_env mod_name location
1523
1524         src_timestamp <- case maybe_buf of
1525                            Just (_,t) -> return t
1526                            Nothing    -> getModificationTime file
1527                         -- getMofificationTime may fail
1528
1529         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1530
1531         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1532                              ms_location = location,
1533                              ms_hspp_file = hspp_fn,
1534                              ms_hspp_opts = dflags',
1535                              ms_hspp_buf  = Just buf,
1536                              ms_srcimps = srcimps, ms_imps = the_imps,
1537                              ms_hs_date = src_timestamp,
1538                              ms_obj_date = obj_timestamp })
1539
1540 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1541 findSummaryBySourceFile summaries file
1542   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1543                                  expectJust "findSummaryBySourceFile" (ml_hs_file (ms_location ms)) == file ] of
1544         [] -> Nothing
1545         (x:xs) -> Just x
1546
1547 -- Summarise a module, and pick up source and timestamp.
1548 summariseModule
1549           :: HscEnv
1550           -> NodeMap ModSummary -- Map of old summaries
1551           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1552           -> Located ModuleName -- Imported module to be summarised
1553           -> Maybe (StringBuffer, ClockTime)
1554           -> [ModuleName]               -- Modules to exclude
1555           -> IO (Maybe ModSummary)      -- Its new summary
1556
1557 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1558   | wanted_mod `elem` excl_mods
1559   = return Nothing
1560
1561   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1562   = do          -- Find its new timestamp; all the
1563                 -- ModSummaries in the old map have valid ml_hs_files
1564         let location = ms_location old_summary
1565             src_fn = expectJust "summariseModule" (ml_hs_file location)
1566
1567                 -- check the modification time on the source file, and
1568                 -- return the cached summary if it hasn't changed.  If the
1569                 -- file has disappeared, we need to call the Finder again.
1570         case maybe_buf of
1571            Just (_,t) -> check_timestamp old_summary location src_fn t
1572            Nothing    -> do
1573                 m <- System.IO.Error.try (getModificationTime src_fn)
1574                 case m of
1575                    Right t -> check_timestamp old_summary location src_fn t
1576                    Left e | isDoesNotExistError e -> find_it
1577                           | otherwise             -> ioError e
1578
1579   | otherwise  = find_it
1580   where
1581     dflags = hsc_dflags hsc_env
1582
1583     hsc_src = if is_boot then HsBootFile else HsSrcFile
1584
1585     check_timestamp old_summary location src_fn src_timestamp
1586         | ms_hs_date old_summary == src_timestamp = do
1587                 -- update the object-file timestamp
1588                 obj_timestamp <- getObjTimestamp location is_boot
1589                 return (Just old_summary{ ms_obj_date = obj_timestamp })
1590         | otherwise =
1591                 -- source changed: re-summarise.
1592                 new_summary location (ms_mod old_summary) src_fn src_timestamp
1593
1594     find_it = do
1595         -- Don't use the Finder's cache this time.  If the module was
1596         -- previously a package module, it may have now appeared on the
1597         -- search path, so we want to consider it to be a home module.  If
1598         -- the module was previously a home module, it may have moved.
1599         uncacheModule hsc_env wanted_mod
1600         found <- findImportedModule hsc_env wanted_mod Nothing
1601         case found of
1602              Found location mod
1603                 | isJust (ml_hs_file location) ->
1604                         -- Home package
1605                          just_found location mod
1606                 | otherwise ->
1607                         -- Drop external-pkg
1608                         ASSERT(modulePackageId mod /= thisPackage dflags)
1609                         return Nothing
1610                 where
1611
1612              err -> noModError dflags loc wanted_mod err
1613                         -- Not found
1614
1615     just_found location mod = do
1616                 -- Adjust location to point to the hs-boot source file,
1617                 -- hi file, object file, when is_boot says so
1618         let location' | is_boot   = addBootSuffixLocn location
1619                       | otherwise = location
1620             src_fn = expectJust "summarise2" (ml_hs_file location')
1621
1622                 -- Check that it exists
1623                 -- It might have been deleted since the Finder last found it
1624         maybe_t <- modificationTimeIfExists src_fn
1625         case maybe_t of
1626           Nothing -> noHsFileErr loc src_fn
1627           Just t  -> new_summary location' mod src_fn t
1628
1629
1630     new_summary location mod src_fn src_timestamp
1631       = do
1632         -- Preprocess the source file and get its imports
1633         -- The dflags' contains the OPTIONS pragmas
1634         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1635         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1636
1637         when (mod_name /= wanted_mod) $
1638                 throwDyn $ mkPlainErrMsg mod_loc $
1639                               text "file name does not match module name"
1640                               <+> quotes (ppr mod_name)
1641
1642                 -- Find the object timestamp, and return the summary
1643         obj_timestamp <- getObjTimestamp location is_boot
1644
1645         return (Just ( ModSummary { ms_mod       = mod,
1646                                     ms_hsc_src   = hsc_src,
1647                                     ms_location  = location,
1648                                     ms_hspp_file = hspp_fn,
1649                                     ms_hspp_opts = dflags',
1650                                     ms_hspp_buf  = Just buf,
1651                                     ms_srcimps   = srcimps,
1652                                     ms_imps      = the_imps,
1653                                     ms_hs_date   = src_timestamp,
1654                                     ms_obj_date  = obj_timestamp }))
1655
1656
1657 getObjTimestamp location is_boot
1658   = if is_boot then return Nothing
1659                else modificationTimeIfExists (ml_obj_file location)
1660
1661
1662 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1663   -> IO (DynFlags, FilePath, StringBuffer)
1664 preprocessFile dflags src_fn mb_phase Nothing
1665   = do
1666         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1667         buf <- hGetStringBuffer hspp_fn
1668         return (dflags', hspp_fn, buf)
1669
1670 preprocessFile dflags src_fn mb_phase (Just (buf, time))
1671   = do
1672         -- case we bypass the preprocessing stage?
1673         let
1674             local_opts = getOptions buf src_fn
1675         --
1676         (dflags', errs) <- parseDynamicFlags dflags (map unLoc local_opts)
1677
1678         let
1679             needs_preprocessing
1680                 | Just (Unlit _) <- mb_phase    = True
1681                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1682                   -- note: local_opts is only required if there's no Unlit phase
1683                 | dopt Opt_Cpp dflags'          = True
1684                 | dopt Opt_Pp  dflags'          = True
1685                 | otherwise                     = False
1686
1687         when needs_preprocessing $
1688            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1689
1690         return (dflags', src_fn, buf)
1691
1692
1693 -----------------------------------------------------------------------------
1694 --                      Error messages
1695 -----------------------------------------------------------------------------
1696
1697 noModError :: DynFlags -> SrcSpan -> ModuleName -> FindResult -> IO ab
1698 -- ToDo: we don't have a proper line number for this error
1699 noModError dflags loc wanted_mod err
1700   = throwDyn $ mkPlainErrMsg loc $ cannotFindModule dflags wanted_mod err
1701
1702 noHsFileErr loc path
1703   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1704
1705 packageModErr mod
1706   = throwDyn $ mkPlainErrMsg noSrcSpan $
1707         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1708
1709 multiRootsErr :: [ModSummary] -> IO ()
1710 multiRootsErr summs@(summ1:_)
1711   = throwDyn $ mkPlainErrMsg noSrcSpan $
1712         text "module" <+> quotes (ppr mod) <+>
1713         text "is defined in multiple files:" <+>
1714         sep (map text files)
1715   where
1716     mod = ms_mod summ1
1717     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
1718
1719 cyclicModuleErr :: [ModSummary] -> SDoc
1720 cyclicModuleErr ms
1721   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1722        2 (vcat (map show_one ms))
1723   where
1724     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1725                         nest 2 $ ptext SLIT("imports:") <+>
1726                                    (pp_imps HsBootFile (ms_srcimps ms)
1727                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1728     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1729     pp_imps src mods = fsep (map (show_mod src) mods)
1730
1731
1732 -- | Inform GHC that the working directory has changed.  GHC will flush
1733 -- its cache of module locations, since it may no longer be valid.
1734 -- Note: if you change the working directory, you should also unload
1735 -- the current program (set targets to empty, followed by load).
1736 workingDirectoryChanged :: Session -> IO ()
1737 workingDirectoryChanged s = withSession s $ flushFinderCaches
1738
1739 -- -----------------------------------------------------------------------------
1740 -- inspecting the session
1741
1742 -- | Get the module dependency graph.
1743 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1744 getModuleGraph s = withSession s (return . hsc_mod_graph)
1745
1746 isLoaded :: Session -> ModuleName -> IO Bool
1747 isLoaded s m = withSession s $ \hsc_env ->
1748   return $! isJust (lookupUFM (hsc_HPT hsc_env) m)
1749
1750 getBindings :: Session -> IO [TyThing]
1751 getBindings s = withSession s $ \hsc_env ->
1752    -- we have to implement the shadowing behaviour of ic_tmp_ids here
1753    -- (see InteractiveContext) and the quickest way is to use an OccEnv.
1754    let
1755        tmp_ids = ic_tmp_ids (hsc_IC hsc_env)
1756        filtered = foldr f (const []) tmp_ids emptyUniqSet
1757        f id rest set
1758            | uniq `elementOfUniqSet` set = rest set
1759            | otherwise  = AnId id : rest (addOneToUniqSet set uniq)
1760            where uniq = getUnique (nameOccName (idName id))
1761    in
1762    return filtered
1763
1764 getPrintUnqual :: Session -> IO PrintUnqualified
1765 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1766
1767 -- | Container for information about a 'Module'.
1768 data ModuleInfo = ModuleInfo {
1769         minf_type_env  :: TypeEnv,
1770         minf_exports   :: NameSet, -- ToDo, [AvailInfo] like ModDetails?
1771         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1772         minf_instances :: [Instance]
1773 #ifdef GHCI
1774         ,minf_modBreaks :: ModBreaks
1775 #endif
1776         -- ToDo: this should really contain the ModIface too
1777   }
1778         -- We don't want HomeModInfo here, because a ModuleInfo applies
1779         -- to package modules too.
1780
1781 -- | Request information about a loaded 'Module'
1782 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1783 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1784   let mg = hsc_mod_graph hsc_env
1785   if mdl `elem` map ms_mod mg
1786         then getHomeModuleInfo hsc_env (moduleName mdl)
1787         else do
1788   {- if isHomeModule (hsc_dflags hsc_env) mdl
1789         then return Nothing
1790         else -} getPackageModuleInfo hsc_env mdl
1791    -- getPackageModuleInfo will attempt to find the interface, so
1792    -- we don't want to call it for a home module, just in case there
1793    -- was a problem loading the module and the interface doesn't
1794    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
1795
1796 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1797 getPackageModuleInfo hsc_env mdl = do
1798 #ifdef GHCI
1799   (_msgs, mb_avails) <- getModuleExports hsc_env mdl
1800   case mb_avails of
1801     Nothing -> return Nothing
1802     Just avails -> do
1803         eps <- readIORef (hsc_EPS hsc_env)
1804         let
1805             names  = availsToNameSet avails
1806             pte    = eps_PTE eps
1807             tys    = [ ty | name <- concatMap availNames avails,
1808                             Just ty <- [lookupTypeEnv pte name] ]
1809         --
1810         return (Just (ModuleInfo {
1811                         minf_type_env  = mkTypeEnv tys,
1812                         minf_exports   = names,
1813                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names (moduleName mdl),
1814                         minf_instances = error "getModuleInfo: instances for package module unimplemented",
1815                         minf_modBreaks = emptyModBreaks
1816                 }))
1817 #else
1818   -- bogusly different for non-GHCI (ToDo)
1819   return Nothing
1820 #endif
1821
1822 getHomeModuleInfo hsc_env mdl =
1823   case lookupUFM (hsc_HPT hsc_env) mdl of
1824     Nothing  -> return Nothing
1825     Just hmi -> do
1826       let details = hm_details hmi
1827       return (Just (ModuleInfo {
1828                         minf_type_env  = md_types details,
1829                         minf_exports   = availsToNameSet (md_exports details),
1830                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1831                         minf_instances = md_insts details
1832 #ifdef GHCI
1833                        ,minf_modBreaks = md_modBreaks details
1834 #endif
1835                         }))
1836
1837 -- | The list of top-level entities defined in a module
1838 modInfoTyThings :: ModuleInfo -> [TyThing]
1839 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1840
1841 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1842 modInfoTopLevelScope minf
1843   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1844
1845 modInfoExports :: ModuleInfo -> [Name]
1846 modInfoExports minf = nameSetToList $! minf_exports minf
1847
1848 -- | Returns the instances defined by the specified module.
1849 -- Warning: currently unimplemented for package modules.
1850 modInfoInstances :: ModuleInfo -> [Instance]
1851 modInfoInstances = minf_instances
1852
1853 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1854 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1855
1856 modInfoPrintUnqualified :: ModuleInfo -> Maybe PrintUnqualified
1857 modInfoPrintUnqualified minf = fmap mkPrintUnqualified (minf_rdr_env minf)
1858
1859 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1860 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1861    case lookupTypeEnv (minf_type_env minf) name of
1862      Just tyThing -> return (Just tyThing)
1863      Nothing      -> do
1864        eps <- readIORef (hsc_EPS hsc_env)
1865        return $! lookupType (hsc_dflags hsc_env)
1866                             (hsc_HPT hsc_env) (eps_PTE eps) name
1867
1868 #ifdef GHCI
1869 modInfoModBreaks = minf_modBreaks
1870 #endif
1871
1872 isDictonaryId :: Id -> Bool
1873 isDictonaryId id
1874   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1875
1876 -- | Looks up a global name: that is, any top-level name in any
1877 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
1878 -- the interactive context, and therefore does not require a preceding
1879 -- 'setContext'.
1880 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
1881 lookupGlobalName s name = withSession s $ \hsc_env -> do
1882    eps <- readIORef (hsc_EPS hsc_env)
1883    return $! lookupType (hsc_dflags hsc_env)
1884                         (hsc_HPT hsc_env) (eps_PTE eps) name
1885
1886 -- -----------------------------------------------------------------------------
1887 -- Misc exported utils
1888
1889 dataConType :: DataCon -> Type
1890 dataConType dc = idType (dataConWrapId dc)
1891
1892 -- | print a 'NamedThing', adding parentheses if the name is an operator.
1893 pprParenSymName :: NamedThing a => a -> SDoc
1894 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
1895
1896 -- ----------------------------------------------------------------------------
1897
1898 #if 0
1899
1900 -- ToDo:
1901 --   - Data and Typeable instances for HsSyn.
1902
1903 -- ToDo: check for small transformations that happen to the syntax in
1904 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1905
1906 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1907 -- to get from TyCons, Ids etc. to TH syntax (reify).
1908
1909 -- :browse will use either lm_toplev or inspect lm_interface, depending
1910 -- on whether the module is interpreted or not.
1911
1912 -- This is for reconstructing refactored source code
1913 -- Calls the lexer repeatedly.
1914 -- ToDo: add comment tokens to token stream
1915 getTokenStream :: Session -> Module -> IO [Located Token]
1916 #endif
1917
1918 -- -----------------------------------------------------------------------------
1919 -- Interactive evaluation
1920
1921 -- | Takes a 'ModuleName' and possibly a 'PackageId', and consults the
1922 -- filesystem and package database to find the corresponding 'Module',
1923 -- using the algorithm that is used for an @import@ declaration.
1924 findModule :: Session -> ModuleName -> Maybe PackageId -> IO Module
1925 findModule s mod_name maybe_pkg = withSession s $ \hsc_env ->
1926   findModule' hsc_env mod_name maybe_pkg
1927
1928 findModule' hsc_env mod_name maybe_pkg =
1929   let
1930         dflags = hsc_dflags hsc_env
1931         hpt    = hsc_HPT hsc_env
1932         this_pkg = thisPackage dflags
1933   in
1934   case lookupUFM hpt mod_name of
1935     Just mod_info -> return (mi_module (hm_iface mod_info))
1936     _not_a_home_module -> do
1937           res <- findImportedModule hsc_env mod_name maybe_pkg
1938           case res of
1939             Found _ m | modulePackageId m /= this_pkg -> return m
1940                       | otherwise -> throwDyn (CmdLineError (showSDoc $
1941                                         text "module" <+> pprModule m <+>
1942                                         text "is not loaded"))
1943             err -> let msg = cannotFindModule dflags mod_name err in
1944                    throwDyn (CmdLineError (showSDoc msg))