compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         newSession,
  15
  16         -- * Flags and settings
  17         DynFlags(..), DynFlag(..), Severity(..), HscTarget(..), dopt,
  18         GhcMode(..), GhcLink(..), defaultObjectTarget,
  19         parseDynamicFlags,
  20         getSessionDynFlags,
  21         setSessionDynFlags,
  22         parseStaticFlags,
  23
  24         -- * Targets
  25         Target(..), TargetId(..), Phase,
  26         setTargets,
  27         getTargets,
  28         addTarget,
  29         removeTarget,
  30         guessTarget,
  31
  32         -- * Extending the program scope
  33         extendGlobalRdrScope,  -- :: Session -> [GlobalRdrElt] -> IO ()
  34         setGlobalRdrScope,     -- :: Session -> [GlobalRdrElt] -> IO ()
  35         extendGlobalTypeScope, -- :: Session -> [Id] -> IO ()
  36         setGlobalTypeScope,    -- :: Session -> [Id] -> IO ()
  37
  38         -- * Loading\/compiling the program
  39         depanal,
  40         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  41         workingDirectoryChanged,
  42         checkModule, CheckedModule(..),
  43         TypecheckedSource, ParsedSource, RenamedSource,
  44         compileToCore,
  45
  46         -- * Parsing Haddock comments
  47         parseHaddockComment,
  48
  49         -- * Inspecting the module structure of the program
  50         ModuleGraph, ModSummary(..), ms_mod_name, ModLocation(..),
  51         getModuleGraph,
  52         isLoaded,
  53         topSortModuleGraph,
  54
  55         -- * Inspecting modules
  56         ModuleInfo,
  57         getModuleInfo,
  58         modInfoTyThings,
  59         modInfoTopLevelScope,
  60         modInfoExports,
  61         modInfoInstances,
  62         modInfoIsExportedName,
  63         modInfoLookupName,
  64         lookupGlobalName,
  65         mkPrintUnqualifiedForModule,
  66
  67         -- * Printing
  68         PrintUnqualified, alwaysQualify,
  69
  70         -- * Interactive evaluation
  71         getBindings, getPrintUnqual,
  72         findModule,
  73 #ifdef GHCI
  74         setContext, getContext,
  75         getNamesInScope,
  76         getRdrNamesInScope,
  77         moduleIsInterpreted,
  78         getInfo,
  79         exprType,
  80         typeKind,
  81         parseName,
  82         RunResult(..),
  83         runStmt, SingleStep(..),
  84         resume,
  85         Resume(resumeStmt, resumeThreadId, resumeBreakInfo, resumeSpan,
  86                resumeHistory, resumeHistoryIx),
  87         History(historyBreakInfo, historyEnclosingDecl),
  88         GHC.getHistorySpan, getHistoryModule,
  89         getResumeContext,
  90         abandon, abandonAll,
  91         InteractiveEval.back,
  92         InteractiveEval.forward,
  93         showModule,
  94         isModuleInterpreted,
  95         compileExpr, HValue, dynCompileExpr,
  96         lookupName,
  97         GHC.obtainTerm, GHC.obtainTerm1, GHC.obtainTermB, reconstructType,
  98         modInfoModBreaks,
  99         ModBreaks(..), BreakIndex,
 100         BreakInfo(breakInfo_number, breakInfo_module),
 101         BreakArray, setBreakOn, setBreakOff, getBreak,
 102 #endif
 103
 104         -- * Abstract syntax elements
 105
 106         -- ** Packages
 107         PackageId,
 108
 109         -- ** Modules
 110         Module, mkModule, pprModule, moduleName, modulePackageId,
 111         ModuleName, mkModuleName, moduleNameString,
 112
 113         -- ** Names
 114         Name,
 115         isExternalName, nameModule, pprParenSymName, nameSrcSpan,
 116         NamedThing(..),
 117         RdrName(Qual,Unqual),
 118
 119         -- ** Identifiers
 120         Id, idType,
 121         isImplicitId, isDeadBinder,
 122         isExportedId, isLocalId, isGlobalId,
 123         isRecordSelector,
 124         isPrimOpId, isFCallId, isClassOpId_maybe,
 125         isDataConWorkId, idDataCon,
 126         isBottomingId, isDictonaryId,
 127         recordSelectorFieldLabel,
 128
 129         -- ** Type constructors
 130         TyCon,
 131         tyConTyVars, tyConDataCons, tyConArity,
 132         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 133         isOpenTyCon,
 134         synTyConDefn, synTyConType, synTyConResKind,
 135
 136         -- ** Type variables
 137         TyVar,
 138         alphaTyVars,
 139
 140         -- ** Data constructors
 141         DataCon,
 142         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 143         dataConIsInfix, isVanillaDataCon,
 144         dataConStrictMarks,
 145         StrictnessMark(..), isMarkedStrict,
 146
 147         -- ** Classes
 148         Class,
 149         classMethods, classSCTheta, classTvsFds,
 150         pprFundeps,
 151
 152         -- ** Instances
 153         Instance,
 154         instanceDFunId, pprInstance, pprInstanceHdr,
 155
 156         -- ** Types and Kinds
 157         Type, dropForAlls, splitForAllTys, funResultTy,
 158         pprParendType, pprTypeApp,
 159         Kind,
 160         PredType,
 161         ThetaType, pprThetaArrow,
 162
 163         -- ** Entities
 164         TyThing(..),
 165
 166         -- ** Syntax
 167         module HsSyn, -- ToDo: remove extraneous bits
 168
 169         -- ** Fixities
 170         FixityDirection(..),
 171         defaultFixity, maxPrecedence,
 172         negateFixity,
 173         compareFixity,
 174
 175         -- ** Source locations
 176         SrcLoc, pprDefnLoc,
 177         mkSrcLoc, isGoodSrcLoc, noSrcLoc,
 178         srcLocFile, srcLocLine, srcLocCol,
 179         SrcSpan,
 180         mkSrcSpan, srcLocSpan, isGoodSrcSpan, noSrcSpan,
 181         srcSpanStart, srcSpanEnd,
 182         srcSpanFile,
 183         srcSpanStartLine, srcSpanEndLine,
 184         srcSpanStartCol, srcSpanEndCol,
 185
 186         -- * Exceptions
 187         GhcException(..), showGhcException,
 188
 189         -- * Miscellaneous
 190         sessionHscEnv,
 191         cyclicModuleErr,
 192   ) where
 193
 194 {-
 195  ToDo:
 196
 197   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 198   * what StaticFlags should we expose, if any?
 199 -}
 200
 201 #include "HsVersions.h"
 202
 203 #ifdef GHCI
 204 import qualified Linker
 205 import Linker           ( HValue )
 206 import ByteCodeInstr
 207 import BreakArray
 208 import NameSet
 209 import InteractiveEval
 210 import TcRnDriver
 211 #endif
 212
 213 import TcIface
 214 import TcRnMonad        ( initIfaceCheck )
 215 import Packages
 216 import NameSet
 217 import RdrName
 218 import HsSyn
 219 import Type             hiding (typeKind)
 220 import TcType           hiding (typeKind)
 221 import Id
 222 import Var              hiding (setIdType)
 223 import TysPrim          ( alphaTyVars )
 224 import TyCon
 225 import Class
 226 import FunDeps
 227 import DataCon
 228 import Name             hiding ( varName )
 229 import OccName          ( parenSymOcc )
 230 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr )
 231 import SrcLoc
 232 import CoreSyn
 233 import DriverPipeline
 234 import DriverPhases     ( HscSource(..), Phase(..), isHaskellSrcFilename, startPhase )
 235 import HeaderInfo       ( getImports, getOptions )
 236 import Finder
 237 import HscMain          ( newHscEnv, hscFileCheck, HscChecked(..) )
 238 import HscTypes
 239 import DynFlags
 240 import StaticFlags
 241 import SysTools     ( initSysTools, cleanTempFiles, cleanTempFilesExcept,
 242                       cleanTempDirs )
 243 import Module
 244 import UniqFM
 245 import UniqSet
 246 import Unique
 247 import PackageConfig
 248 import FiniteMap
 249 import Panic
 250 import Digraph
 251 import Bag              ( unitBag, listToBag )
 252 import ErrUtils         ( Severity(..), showPass, fatalErrorMsg, debugTraceMsg,
 253                           mkPlainErrMsg, printBagOfErrors, printBagOfWarnings,
 254                           WarnMsg )
 255 import qualified ErrUtils
 256 import Util
 257 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 258 import Outputable
 259 import BasicTypes
 260 import Maybes           ( expectJust, mapCatMaybes )
 261 import HaddockParse
 262 import HaddockLex       ( tokenise )
 263
 264 import Control.Concurrent
 265 import System.Directory ( getModificationTime, doesFileExist )
 266 import Data.Maybe
 267 import Data.List
 268 import qualified Data.List as List
 269 import Control.Monad
 270 import System.Exit      ( exitWith, ExitCode(..) )
 271 import System.Time      ( ClockTime )
 272 import Control.Exception as Exception hiding (handle)
 273 import Data.IORef
 274 import System.IO
 275 import System.IO.Error  ( try, isDoesNotExistError )
 276 import Prelude hiding (init)
 277
 278
 279 -- -----------------------------------------------------------------------------
 280 -- Exception handlers
 281
 282 -- | Install some default exception handlers and run the inner computation.
 283 -- Unless you want to handle exceptions yourself, you should wrap this around
 284 -- the top level of your program.  The default handlers output the error
 285 -- message(s) to stderr and exit cleanly.
 286 defaultErrorHandler :: DynFlags -> IO a -> IO a
 287 defaultErrorHandler dflags inner =
 288   -- top-level exception handler: any unrecognised exception is a compiler bug.
 289   handle (\exception -> do
 290            hFlush stdout
 291            case exception of
 292                 -- an IO exception probably isn't our fault, so don't panic
 293                 IOException _ ->
 294                   fatalErrorMsg dflags (text (show exception))
 295                 AsyncException StackOverflow ->
 296                   fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 297                 _other ->
 298                   fatalErrorMsg dflags (text (show (Panic (show exception))))
 299            exitWith (ExitFailure 1)
 300          ) $
 301
 302   -- program errors: messages with locations attached.  Sometimes it is
 303   -- convenient to just throw these as exceptions.
 304   handleDyn (\dyn -> do printBagOfErrors dflags (unitBag dyn)
 305                         exitWith (ExitFailure 1)) $
 306
 307   -- error messages propagated as exceptions
 308   handleDyn (\dyn -> do
 309                 hFlush stdout
 310                 case dyn of
 311                      PhaseFailed _ code -> exitWith code
 312                      Interrupted -> exitWith (ExitFailure 1)
 313                      _ -> do fatalErrorMsg dflags (text (show (dyn :: GhcException)))
 314                              exitWith (ExitFailure 1)
 315             ) $
 316   inner
 317
 318 -- | Install a default cleanup handler to remove temporary files
 319 -- deposited by a GHC run.  This is seperate from
 320 -- 'defaultErrorHandler', because you might want to override the error
 321 -- handling, but still get the ordinary cleanup behaviour.
 322 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 323 defaultCleanupHandler dflags inner =
 324     -- make sure we clean up after ourselves
 325     later (do cleanTempFiles dflags
 326               cleanTempDirs dflags
 327           )
 328           -- exceptions will be blocked while we clean the temporary files,
 329           -- so there shouldn't be any difficulty if we receive further
 330           -- signals.
 331     inner
 332
 333
 334 -- | Starts a new session.  A session consists of a set of loaded
 335 -- modules, a set of options (DynFlags), and an interactive context.
 336 newSession :: Maybe FilePath -> IO Session
 337 newSession mb_top_dir = do
 338   -- catch ^C
 339   main_thread <- myThreadId
 340   modifyMVar_ interruptTargetThread (return . (main_thread :))
 341   installSignalHandlers
 342
 343   initStaticOpts
 344   dflags0 <- initSysTools mb_top_dir defaultDynFlags
 345   dflags  <- initDynFlags dflags0
 346   env <- newHscEnv dflags
 347   ref <- newIORef env
 348   return (Session ref)
 349
 350 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 351 -- needs to call the Finder.  ToDo: untangle this.
 352 sessionHscEnv :: Session -> IO HscEnv
 353 sessionHscEnv (Session ref) = readIORef ref
 354
 355 -- -----------------------------------------------------------------------------
 356 -- Flags & settings
 357
 358 -- | Grabs the DynFlags from the Session
 359 getSessionDynFlags :: Session -> IO DynFlags
 360 getSessionDynFlags s = withSession s (return . hsc_dflags)
 361
 362 -- | Updates the DynFlags in a Session.  This also reads
 363 -- the package database (unless it has already been read),
 364 -- and prepares the compilers knowledge about packages.  It
 365 -- can be called again to load new packages: just add new
 366 -- package flags to (packageFlags dflags).
 367 --
 368 -- Returns a list of new packages that may need to be linked in using
 369 -- the dynamic linker (see 'linkPackages') as a result of new package
 370 -- flags.  If you are not doing linking or doing static linking, you
 371 -- can ignore the list of packages returned.
 372 --
 373 setSessionDynFlags :: Session -> DynFlags -> IO [PackageId]
 374 setSessionDynFlags (Session ref) dflags = do
 375   hsc_env <- readIORef ref
 376   (dflags', preload) <- initPackages dflags
 377   writeIORef ref $! hsc_env{ hsc_dflags = dflags' }
 378   return preload
 379
 380 -- | If there is no -o option, guess the name of target executable
 381 -- by using top-level source file name as a base.
 382 guessOutputFile :: Session -> IO ()
 383 guessOutputFile s = modifySession s $ \env ->
 384     let dflags = hsc_dflags env
 385         mod_graph = hsc_mod_graph env
 386         mainModuleSrcPath, guessedName :: Maybe String
 387         mainModuleSrcPath = do
 388             let isMain = (== mainModIs dflags) . ms_mod
 389             [ms] <- return (filter isMain mod_graph)
 390             ml_hs_file (ms_location ms)
 391         guessedName = fmap basenameOf mainModuleSrcPath
 392     in
 393     case outputFile dflags of
 394         Just _ -> env
 395         Nothing -> env { hsc_dflags = dflags { outputFile = guessedName } }
 396
 397 -- -----------------------------------------------------------------------------
 398 -- Targets
 399
 400 -- ToDo: think about relative vs. absolute file paths. And what
 401 -- happens when the current directory changes.
 402
 403 -- | Sets the targets for this session.  Each target may be a module name
 404 -- or a filename.  The targets correspond to the set of root modules for
 405 -- the program\/library.  Unloading the current program is achieved by
 406 -- setting the current set of targets to be empty, followed by load.
 407 setTargets :: Session -> [Target] -> IO ()
 408 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 409
 410 -- | returns the current set of targets
 411 getTargets :: Session -> IO [Target]
 412 getTargets s = withSession s (return . hsc_targets)
 413
 414 -- | Add another target
 415 addTarget :: Session -> Target -> IO ()
 416 addTarget s target
 417   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 418
 419 -- | Remove a target
 420 removeTarget :: Session -> TargetId -> IO ()
 421 removeTarget s target_id
 422   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 423   where
 424    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 425
 426 -- Attempts to guess what Target a string refers to.  This function implements
 427 -- the --make/GHCi command-line syntax for filenames:
 428 --
 429 --      - if the string looks like a Haskell source filename, then interpret
 430 --        it as such
 431 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 432 --        then use that
 433 --      - otherwise interpret the string as a module name
 434 --
 435 guessTarget :: String -> Maybe Phase -> IO Target
 436 guessTarget file (Just phase)
 437    = return (Target (TargetFile file (Just phase)) Nothing)
 438 guessTarget file Nothing
 439    | isHaskellSrcFilename file
 440    = return (Target (TargetFile file Nothing) Nothing)
 441    | otherwise
 442    = do exists <- doesFileExist hs_file
 443         if exists
 444            then return (Target (TargetFile hs_file Nothing) Nothing)
 445            else do
 446         exists <- doesFileExist lhs_file
 447         if exists
 448            then return (Target (TargetFile lhs_file Nothing) Nothing)
 449            else do
 450         return (Target (TargetModule (mkModuleName file)) Nothing)
 451      where
 452          hs_file  = file `joinFileExt` "hs"
 453          lhs_file = file `joinFileExt` "lhs"
 454
 455 -- -----------------------------------------------------------------------------
 456 -- Extending the program scope
 457
 458 extendGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 459 extendGlobalRdrScope session rdrElts
 460     = modifySession session $ \hscEnv ->
 461       let global_rdr = hsc_global_rdr_env hscEnv
 462       in hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv global_rdr rdrElts }
 463
 464 setGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 465 setGlobalRdrScope session rdrElts
 466     = modifySession session $ \hscEnv ->
 467       hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv emptyGlobalRdrEnv rdrElts }
 468
 469 extendGlobalTypeScope :: Session -> [Id] -> IO ()
 470 extendGlobalTypeScope session ids
 471     = modifySession session $ \hscEnv ->
 472       let global_type = hsc_global_type_env hscEnv
 473       in hscEnv{ hsc_global_type_env = extendTypeEnvWithIds global_type ids }
 474
 475 setGlobalTypeScope :: Session -> [Id] -> IO ()
 476 setGlobalTypeScope session ids
 477     = modifySession session $ \hscEnv ->
 478       hscEnv{ hsc_global_type_env = extendTypeEnvWithIds emptyTypeEnv ids }
 479
 480 -- -----------------------------------------------------------------------------
 481 -- Parsing Haddock comments
 482
 483 parseHaddockComment :: String -> Either String (HsDoc RdrName)
 484 parseHaddockComment string = parseHaddockParagraphs (tokenise string)
 485
 486 -- -----------------------------------------------------------------------------
 487 -- Loading the program
 488
 489 -- Perform a dependency analysis starting from the current targets
 490 -- and update the session with the new module graph.
 491 depanal :: Session -> [ModuleName] -> Bool -> IO (Maybe ModuleGraph)
 492 depanal (Session ref) excluded_mods allow_dup_roots = do
 493   hsc_env <- readIORef ref
 494   let
 495          dflags  = hsc_dflags hsc_env
 496          targets = hsc_targets hsc_env
 497          old_graph = hsc_mod_graph hsc_env
 498
 499   showPass dflags "Chasing dependencies"
 500   debugTraceMsg dflags 2 (hcat [
 501              text "Chasing modules from: ",
 502              hcat (punctuate comma (map pprTarget targets))])
 503
 504   r <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 505   case r of
 506     Just mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 507     _ -> return ()
 508   return r
 509
 510 {-
 511 -- | The result of load.
 512 data LoadResult
 513   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 514   | LoadFailed  Errors  -- ^ not all modules were loaded.
 515
 516 type Errors = [String]
 517
 518 data ErrMsg = ErrMsg {
 519         errMsgSeverity  :: Severity,  -- warning, error, etc.
 520         errMsgSpans     :: [SrcSpan],
 521         errMsgShortDoc  :: Doc,
 522         errMsgExtraInfo :: Doc
 523         }
 524 -}
 525
 526 data LoadHowMuch
 527    = LoadAllTargets
 528    | LoadUpTo ModuleName
 529    | LoadDependenciesOf ModuleName
 530
 531 -- | Try to load the program.  If a Module is supplied, then just
 532 -- attempt to load up to this target.  If no Module is supplied,
 533 -- then try to load all targets.
 534 load :: Session -> LoadHowMuch -> IO SuccessFlag
 535 load s@(Session ref) how_much
 536    = do
 537         -- Dependency analysis first.  Note that this fixes the module graph:
 538         -- even if we don't get a fully successful upsweep, the full module
 539         -- graph is still retained in the Session.  We can tell which modules
 540         -- were successfully loaded by inspecting the Session's HPT.
 541         mb_graph <- depanal s [] False
 542         case mb_graph of
 543            Just mod_graph -> catchingFailure $ load2 s how_much mod_graph
 544            Nothing        -> return Failed
 545     where catchingFailure f = f `Exception.catch` \e -> do
 546               hsc_env <- readIORef ref
 547               -- trac #1565 / test ghci021:
 548               -- let bindings may explode if we try to use them after
 549               -- failing to reload
 550               writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 551               throw e
 552
 553 load2 :: Session -> LoadHowMuch -> [ModSummary] -> IO SuccessFlag
 554 load2 s@(Session ref) how_much mod_graph = do
 555         guessOutputFile s
 556         hsc_env <- readIORef ref
 557
 558         let hpt1      = hsc_HPT hsc_env
 559         let dflags    = hsc_dflags hsc_env
 560
 561         -- The "bad" boot modules are the ones for which we have
 562         -- B.hs-boot in the module graph, but no B.hs
 563         -- The downsweep should have ensured this does not happen
 564         -- (see msDeps)
 565         let all_home_mods = [ms_mod_name s
 566                             | s <- mod_graph, not (isBootSummary s)]
 567             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 568                                         not (ms_mod_name s `elem` all_home_mods)]
 569         ASSERT( null bad_boot_mods ) return ()
 570
 571         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 572         -- graph with cycles.  Among other things, it is used for
 573         -- backing out partially complete cycles following a failed
 574         -- upsweep, and for removing from hpt all the modules
 575         -- not in strict downwards closure, during calls to compile.
 576         let mg2_with_srcimps :: [SCC ModSummary]
 577             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 578
 579         -- If we can determine that any of the {-# SOURCE #-} imports
 580         -- are definitely unnecessary, then emit a warning.
 581         warnUnnecessarySourceImports dflags mg2_with_srcimps
 582
 583         let
 584             -- check the stability property for each module.
 585             stable_mods@(stable_obj,stable_bco)
 586                 = checkStability hpt1 mg2_with_srcimps all_home_mods
 587
 588             -- prune bits of the HPT which are definitely redundant now,
 589             -- to save space.
 590             pruned_hpt = pruneHomePackageTable hpt1
 591                                 (flattenSCCs mg2_with_srcimps)
 592                                 stable_mods
 593
 594         evaluate pruned_hpt
 595
 596         debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 597                                 text "Stable BCO:" <+> ppr stable_bco)
 598
 599         -- Unload any modules which are going to be re-linked this time around.
 600         let stable_linkables = [ linkable
 601                                | m <- stable_obj++stable_bco,
 602                                  Just hmi <- [lookupUFM pruned_hpt m],
 603                                  Just linkable <- [hm_linkable hmi] ]
 604         unload hsc_env stable_linkables
 605
 606         -- We could at this point detect cycles which aren't broken by
 607         -- a source-import, and complain immediately, but it seems better
 608         -- to let upsweep_mods do this, so at least some useful work gets
 609         -- done before the upsweep is abandoned.
 610         --hPutStrLn stderr "after tsort:\n"
 611         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 612
 613         -- Now do the upsweep, calling compile for each module in
 614         -- turn.  Final result is version 3 of everything.
 615
 616         -- Topologically sort the module graph, this time including hi-boot
 617         -- nodes, and possibly just including the portion of the graph
 618         -- reachable from the module specified in the 2nd argument to load.
 619         -- This graph should be cycle-free.
 620         -- If we're restricting the upsweep to a portion of the graph, we
 621         -- also want to retain everything that is still stable.
 622         let full_mg :: [SCC ModSummary]
 623             full_mg    = topSortModuleGraph False mod_graph Nothing
 624
 625             maybe_top_mod = case how_much of
 626                                 LoadUpTo m           -> Just m
 627                                 LoadDependenciesOf m -> Just m
 628                                 _                    -> Nothing
 629
 630             partial_mg0 :: [SCC ModSummary]
 631             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 632
 633             -- LoadDependenciesOf m: we want the upsweep to stop just
 634             -- short of the specified module (unless the specified module
 635             -- is stable).
 636             partial_mg
 637                 | LoadDependenciesOf _mod <- how_much
 638                 = ASSERT( case last partial_mg0 of
 639                             AcyclicSCC ms -> ms_mod_name ms == _mod; _ -> False )
 640                   List.init partial_mg0
 641                 | otherwise
 642                 = partial_mg0
 643
 644             stable_mg =
 645                 [ AcyclicSCC ms
 646                 | AcyclicSCC ms <- full_mg,
 647                   ms_mod_name ms `elem` stable_obj++stable_bco,
 648                   ms_mod_name ms `notElem` [ ms_mod_name ms' |
 649                                                 AcyclicSCC ms' <- partial_mg ] ]
 650
 651             mg = stable_mg ++ partial_mg
 652
 653         -- clean up between compilations
 654         let cleanup = cleanTempFilesExcept dflags
 655                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 656
 657         debugTraceMsg dflags 2 (hang (text "Ready for upsweep")
 658                                    2 (ppr mg))
 659         (upsweep_ok, hsc_env1, modsUpswept)
 660            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 661                            pruned_hpt stable_mods cleanup mg
 662
 663         -- Make modsDone be the summaries for each home module now
 664         -- available; this should equal the domain of hpt3.
 665         -- Get in in a roughly top .. bottom order (hence reverse).
 666
 667         let modsDone = reverse modsUpswept
 668
 669         -- Try and do linking in some form, depending on whether the
 670         -- upsweep was completely or only partially successful.
 671
 672         if succeeded upsweep_ok
 673
 674          then
 675            -- Easy; just relink it all.
 676            do debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 677
 678               -- Clean up after ourselves
 679               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 680
 681               -- Issue a warning for the confusing case where the user
 682               -- said '-o foo' but we're not going to do any linking.
 683               -- We attempt linking if either (a) one of the modules is
 684               -- called Main, or (b) the user said -no-hs-main, indicating
 685               -- that main() is going to come from somewhere else.
 686               --
 687               let ofile = outputFile dflags
 688               let no_hs_main = dopt Opt_NoHsMain dflags
 689               let
 690                 main_mod = mainModIs dflags
 691                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 692                 do_linking = a_root_is_Main || no_hs_main
 693
 694               when (ghcLink dflags == LinkBinary
 695                     && isJust ofile && not do_linking) $
 696                 debugTraceMsg dflags 1 $
 697                     text ("Warning: output was redirected with -o, " ++
 698                           "but no output will be generated\n" ++
 699                           "because there is no " ++
 700                           moduleNameString (moduleName main_mod) ++ " module.")
 701
 702               -- link everything together
 703               linkresult <- link (ghcLink dflags) dflags do_linking (hsc_HPT hsc_env1)
 704
 705               loadFinish Succeeded linkresult ref hsc_env1
 706
 707          else
 708            -- Tricky.  We need to back out the effects of compiling any
 709            -- half-done cycles, both so as to clean up the top level envs
 710            -- and to avoid telling the interactive linker to link them.
 711            do debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 712
 713               let modsDone_names
 714                      = map ms_mod modsDone
 715               let mods_to_zap_names
 716                      = findPartiallyCompletedCycles modsDone_names
 717                           mg2_with_srcimps
 718               let mods_to_keep
 719                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 720                           modsDone
 721
 722               let hpt4 = retainInTopLevelEnvs (map ms_mod_name mods_to_keep)
 723                                               (hsc_HPT hsc_env1)
 724
 725               -- Clean up after ourselves
 726               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 727
 728               -- there should be no Nothings where linkables should be, now
 729               ASSERT(all (isJust.hm_linkable)
 730                         (eltsUFM (hsc_HPT hsc_env))) do
 731
 732               -- Link everything together
 733               linkresult <- link (ghcLink dflags) dflags False hpt4
 734
 735               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 736               loadFinish Failed linkresult ref hsc_env4
 737
 738 -- Finish up after a load.
 739
 740 -- If the link failed, unload everything and return.
 741 loadFinish :: SuccessFlag -> SuccessFlag -> IORef HscEnv -> HscEnv -> IO SuccessFlag
 742 loadFinish _all_ok Failed ref hsc_env
 743   = do unload hsc_env []
 744        writeIORef ref $! discardProg hsc_env
 745        return Failed
 746
 747 -- Empty the interactive context and set the module context to the topmost
 748 -- newly loaded module, or the Prelude if none were loaded.
 749 loadFinish all_ok Succeeded ref hsc_env
 750   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 751        return all_ok
 752
 753
 754 -- Forget the current program, but retain the persistent info in HscEnv
 755 discardProg :: HscEnv -> HscEnv
 756 discardProg hsc_env
 757   = hsc_env { hsc_mod_graph = emptyMG,
 758               hsc_IC = emptyInteractiveContext,
 759               hsc_HPT = emptyHomePackageTable }
 760
 761 -- used to fish out the preprocess output files for the purposes of
 762 -- cleaning up.  The preprocessed file *might* be the same as the
 763 -- source file, but that doesn't do any harm.
 764 ppFilesFromSummaries :: [ModSummary] -> [FilePath]
 765 ppFilesFromSummaries summaries = map ms_hspp_file summaries
 766
 767 -- -----------------------------------------------------------------------------
 768 -- Check module
 769
 770 data CheckedModule =
 771   CheckedModule { parsedSource      :: ParsedSource,
 772                   renamedSource     :: Maybe RenamedSource,
 773                   typecheckedSource :: Maybe TypecheckedSource,
 774                   checkedModuleInfo :: Maybe ModuleInfo,
 775                   coreBinds         :: Maybe [CoreBind]
 776                 }
 777         -- ToDo: improvements that could be made here:
 778         --  if the module succeeded renaming but not typechecking,
 779         --  we can still get back the GlobalRdrEnv and exports, so
 780         --  perhaps the ModuleInfo should be split up into separate
 781         --  fields within CheckedModule.
 782
 783 type ParsedSource      = Located (HsModule RdrName)
 784 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name],
 785                           Maybe (HsDoc Name), HaddockModInfo Name)
 786 type TypecheckedSource = LHsBinds Id
 787
 788 -- NOTE:
 789 --   - things that aren't in the output of the typechecker right now:
 790 --     - the export list
 791 --     - the imports
 792 --     - type signatures
 793 --     - type/data/newtype declarations
 794 --     - class declarations
 795 --     - instances
 796 --   - extra things in the typechecker's output:
 797 --     - default methods are turned into top-level decls.
 798 --     - dictionary bindings
 799
 800
 801 -- | This is the way to get access to parsed and typechecked source code
 802 -- for a module.  'checkModule' attempts to typecheck the module.  If
 803 -- successful, it returns the abstract syntax for the module.
 804 -- If compileToCore is true, it also desugars the module and returns the
 805 -- resulting Core bindings as a component of the CheckedModule.
 806 checkModule :: Session -> ModuleName -> Bool -> IO (Maybe CheckedModule)
 807 checkModule (Session ref) mod compileToCore = do
 808         -- parse & typecheck the module
 809    hsc_env <- readIORef ref
 810    let mg  = hsc_mod_graph hsc_env
 811    case [ ms | ms <- mg, ms_mod_name ms == mod ] of
 812         [] -> return Nothing
 813         (ms:_) -> do
 814            mbChecked <- hscFileCheck
 815                           hsc_env{hsc_dflags=ms_hspp_opts ms}
 816                           ms compileToCore
 817            case mbChecked of
 818              Nothing -> return Nothing
 819              Just (HscChecked parsed renamed Nothing _) ->
 820                    return (Just (CheckedModule {
 821                                         parsedSource = parsed,
 822                                         renamedSource = renamed,
 823                                         typecheckedSource = Nothing,
 824                                         checkedModuleInfo = Nothing,
 825                                         coreBinds = Nothing }))
 826              Just (HscChecked parsed renamed
 827                            (Just (tc_binds, rdr_env, details))
 828                            maybeCoreBinds) -> do
 829                    let minf = ModuleInfo {
 830                                 minf_type_env  = md_types details,
 831                                 minf_exports   = availsToNameSet $
 832                                                      md_exports details,
 833                                 minf_rdr_env   = Just rdr_env,
 834                                 minf_instances = md_insts details
 835 #ifdef GHCI
 836                                ,minf_modBreaks = emptyModBreaks
 837 #endif
 838                               }
 839                    return (Just (CheckedModule {
 840                                         parsedSource = parsed,
 841                                         renamedSource = renamed,
 842                                         typecheckedSource = Just tc_binds,
 843                                         checkedModuleInfo = Just minf,
 844                                         coreBinds = maybeCoreBinds}))
 845
 846 -- | This is the way to get access to the Core bindings corresponding
 847 -- to a module. 'compileToCore' invokes 'checkModule' to parse, typecheck, and
 848 -- desugar the module, then returns the resulting list of Core bindings if
 849 -- successful.
 850 compileToCore :: Session -> FilePath -> IO (Maybe [CoreBind])
 851 compileToCore session fn = do
 852    -- First, set the target to the desired filename
 853    target <- guessTarget fn Nothing
 854    addTarget session target
 855    load session LoadAllTargets
 856    -- Then find dependencies
 857    maybeModGraph <- depanal session [] True
 858    case maybeModGraph of
 859      Nothing -> return Nothing
 860      Just modGraph -> do
 861         let modSummary = expectJust "compileToCore" $
 862                           find ((== fn) . msHsFilePath) modGraph
 863         -- Now we have the module name;
 864         -- parse, typecheck and desugar the module
 865         let mod = ms_mod_name modSummary
 866         maybeCheckedModule <- checkModule session mod True
 867         case maybeCheckedModule of
 868              Nothing -> return Nothing
 869              Just checkedMod -> return $ coreBinds checkedMod
 870  -- ---------------------------------------------------------------------------
 871 -- Unloading
 872
 873 unload :: HscEnv -> [Linkable] -> IO ()
 874 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 875   = case ghcLink (hsc_dflags hsc_env) of
 876 #ifdef GHCI
 877         LinkInMemory -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 878 #else
 879         LinkInMemory -> panic "unload: no interpreter"
 880                                 -- urgh.  avoid warnings:
 881                                 hsc_env stable_linkables
 882 #endif
 883         _other -> return ()
 884
 885 -- -----------------------------------------------------------------------------
 886 -- checkStability
 887
 888 {-
 889   Stability tells us which modules definitely do not need to be recompiled.
 890   There are two main reasons for having stability:
 891
 892    - avoid doing a complete upsweep of the module graph in GHCi when
 893      modules near the bottom of the tree have not changed.
 894
 895    - to tell GHCi when it can load object code: we can only load object code
 896      for a module when we also load object code fo  all of the imports of the
 897      module.  So we need to know that we will definitely not be recompiling
 898      any of these modules, and we can use the object code.
 899
 900   The stability check is as follows.  Both stableObject and
 901   stableBCO are used during the upsweep phase later.
 902
 903   -------------------
 904   stable m = stableObject m || stableBCO m
 905
 906   stableObject m =
 907         all stableObject (imports m)
 908         && old linkable does not exist, or is == on-disk .o
 909         && date(on-disk .o) > date(.hs)
 910
 911   stableBCO m =
 912         all stable (imports m)
 913         && date(BCO) > date(.hs)
 914   -------------------
 915
 916   These properties embody the following ideas:
 917
 918     - if a module is stable, then:
 919         - if it has been compiled in a previous pass (present in HPT)
 920           then it does not need to be compiled or re-linked.
 921         - if it has not been compiled in a previous pass,
 922           then we only need to read its .hi file from disk and
 923           link it to produce a ModDetails.
 924
 925     - if a modules is not stable, we will definitely be at least
 926       re-linking, and possibly re-compiling it during the upsweep.
 927       All non-stable modules can (and should) therefore be unlinked
 928       before the upsweep.
 929
 930     - Note that objects are only considered stable if they only depend
 931       on other objects.  We can't link object code against byte code.
 932 -}
 933
 934 checkStability
 935         :: HomePackageTable             -- HPT from last compilation
 936         -> [SCC ModSummary]             -- current module graph (cyclic)
 937         -> [ModuleName]                 -- all home modules
 938         -> ([ModuleName],               -- stableObject
 939             [ModuleName])               -- stableBCO
 940
 941 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 942   where
 943    checkSCC (stable_obj, stable_bco) scc0
 944      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 945      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 946      | otherwise     = (stable_obj, stable_bco)
 947      where
 948         scc = flattenSCC scc0
 949         scc_mods = map ms_mod_name scc
 950         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 951
 952         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 953             -- all imports outside the current SCC, but in the home pkg
 954
 955         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 956         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 957
 958         stableObjects =
 959            and stable_obj_imps
 960            && all object_ok scc
 961
 962         stableBCOs =
 963            and (zipWith (||) stable_obj_imps stable_bco_imps)
 964            && all bco_ok scc
 965
 966         object_ok ms
 967           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 968                                          && same_as_prev t
 969           | otherwise = False
 970           where
 971              same_as_prev t = case lookupUFM hpt (ms_mod_name ms) of
 972                                 Just hmi  | Just l <- hm_linkable hmi
 973                                  -> isObjectLinkable l && t == linkableTime l
 974                                 _other  -> True
 975                 -- why '>=' rather than '>' above?  If the filesystem stores
 976                 -- times to the nearset second, we may occasionally find that
 977                 -- the object & source have the same modification time,
 978                 -- especially if the source was automatically generated
 979                 -- and compiled.  Using >= is slightly unsafe, but it matches
 980                 -- make's behaviour.
 981
 982         bco_ok ms
 983           = case lookupUFM hpt (ms_mod_name ms) of
 984                 Just hmi  | Just l <- hm_linkable hmi ->
 985                         not (isObjectLinkable l) &&
 986                         linkableTime l >= ms_hs_date ms
 987                 _other  -> False
 988
 989 ms_allimps :: ModSummary -> [ModuleName]
 990 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 991
 992 -- -----------------------------------------------------------------------------
 993 -- Prune the HomePackageTable
 994
 995 -- Before doing an upsweep, we can throw away:
 996 --
 997 --   - For non-stable modules:
 998 --      - all ModDetails, all linked code
 999 --   - all unlinked code that is out of date with respect to
1000 --     the source file
1001 --
1002 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
1003 -- space at the end of the upsweep, because the topmost ModDetails of the
1004 -- old HPT holds on to the entire type environment from the previous
1005 -- compilation.
1006
1007 pruneHomePackageTable
1008    :: HomePackageTable
1009    -> [ModSummary]
1010    -> ([ModuleName],[ModuleName])
1011    -> HomePackageTable
1012
1013 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
1014   = mapUFM prune hpt
1015   where prune hmi
1016           | is_stable modl = hmi'
1017           | otherwise      = hmi'{ hm_details = emptyModDetails }
1018           where
1019            modl = moduleName (mi_module (hm_iface hmi))
1020            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
1021                 = hmi{ hm_linkable = Nothing }
1022                 | otherwise
1023                 = hmi
1024                 where ms = expectJust "prune" (lookupUFM ms_map modl)
1025
1026         ms_map = listToUFM [(ms_mod_name ms, ms) | ms <- summ]
1027
1028         is_stable m = m `elem` stable_obj || m `elem` stable_bco
1029
1030 -- -----------------------------------------------------------------------------
1031
1032 -- Return (names of) all those in modsDone who are part of a cycle
1033 -- as defined by theGraph.
1034 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
1035 findPartiallyCompletedCycles modsDone theGraph
1036    = chew theGraph
1037      where
1038         chew [] = []
1039         chew ((AcyclicSCC _):rest) = chew rest    -- acyclic?  not interesting.
1040         chew ((CyclicSCC vs):rest)
1041            = let names_in_this_cycle = nub (map ms_mod vs)
1042                  mods_in_this_cycle
1043                     = nub ([done | done <- modsDone,
1044                                    done `elem` names_in_this_cycle])
1045                  chewed_rest = chew rest
1046              in
1047              if   notNull mods_in_this_cycle
1048                   && length mods_in_this_cycle < length names_in_this_cycle
1049              then mods_in_this_cycle ++ chewed_rest
1050              else chewed_rest
1051
1052 -- -----------------------------------------------------------------------------
1053 -- The upsweep
1054
1055 -- This is where we compile each module in the module graph, in a pass
1056 -- from the bottom to the top of the graph.
1057
1058 -- There better had not be any cyclic groups here -- we check for them.
1059
1060 upsweep
1061     :: HscEnv                   -- Includes initially-empty HPT
1062     -> HomePackageTable         -- HPT from last time round (pruned)
1063     -> ([ModuleName],[ModuleName]) -- stable modules (see checkStability)
1064     -> IO ()                    -- How to clean up unwanted tmp files
1065     -> [SCC ModSummary]         -- Mods to do (the worklist)
1066     -> IO (SuccessFlag,
1067            HscEnv,              -- With an updated HPT
1068            [ModSummary])        -- Mods which succeeded
1069
1070 upsweep hsc_env old_hpt stable_mods cleanup sccs = do
1071    (res, hsc_env, done) <- upsweep' hsc_env old_hpt [] sccs 1 (length sccs)
1072    return (res, hsc_env, reverse done)
1073  where
1074
1075   upsweep' hsc_env _old_hpt done
1076      [] _ _
1077    = return (Succeeded, hsc_env, done)
1078
1079   upsweep' hsc_env _old_hpt done
1080      (CyclicSCC ms:_) _ _
1081    = do fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1082         return (Failed, hsc_env, done)
1083
1084   upsweep' hsc_env old_hpt done
1085      (AcyclicSCC mod:mods) mod_index nmods
1086    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1087         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1088         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1089
1090         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
1091                        mod_index nmods
1092
1093         cleanup         -- Remove unwanted tmp files between compilations
1094
1095         case mb_mod_info of
1096             Nothing -> return (Failed, hsc_env, [])
1097             Just mod_info -> do
1098                 let this_mod = ms_mod_name mod
1099
1100                         -- Add new info to hsc_env
1101                     hpt1     = addToUFM (hsc_HPT hsc_env) this_mod mod_info
1102                     hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1103
1104                         -- Space-saving: delete the old HPT entry
1105                         -- for mod BUT if mod is a hs-boot
1106                         -- node, don't delete it.  For the
1107                         -- interface, the HPT entry is probaby for the
1108                         -- main Haskell source file.  Deleting it
1109                         -- would force the real module to be recompiled
1110                         -- every time.
1111                     old_hpt1 | isBootSummary mod = old_hpt
1112                              | otherwise = delFromUFM old_hpt this_mod
1113
1114                     done' = mod:done
1115
1116                         -- fixup our HomePackageTable after we've finished compiling
1117                         -- a mutually-recursive loop.  See reTypecheckLoop, below.
1118                 hsc_env2 <- reTypecheckLoop hsc_env1 mod done'
1119
1120                 upsweep' hsc_env2 old_hpt1 done' mods (mod_index+1) nmods
1121
1122
1123 -- Compile a single module.  Always produce a Linkable for it if
1124 -- successful.  If no compilation happened, return the old Linkable.
1125 upsweep_mod :: HscEnv
1126             -> HomePackageTable
1127             -> ([ModuleName],[ModuleName])
1128             -> ModSummary
1129             -> Int  -- index of module
1130             -> Int  -- total number of modules
1131             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1132
1133 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1134    =    let
1135             this_mod_name = ms_mod_name summary
1136             this_mod    = ms_mod summary
1137             mb_obj_date = ms_obj_date summary
1138             obj_fn      = ml_obj_file (ms_location summary)
1139             hs_date     = ms_hs_date summary
1140
1141             is_stable_obj = this_mod_name `elem` stable_obj
1142             is_stable_bco = this_mod_name `elem` stable_bco
1143
1144             old_hmi = lookupUFM old_hpt this_mod_name
1145
1146             -- We're using the dflags for this module now, obtained by
1147             -- applying any options in its LANGUAGE & OPTIONS_GHC pragmas.
1148             dflags = ms_hspp_opts summary
1149             prevailing_target = hscTarget (hsc_dflags hsc_env)
1150             local_target      = hscTarget dflags
1151
1152             -- If OPTIONS_GHC contains -fasm or -fvia-C, be careful that
1153             -- we don't do anything dodgy: these should only work to change
1154             -- from -fvia-C to -fasm and vice-versa, otherwise we could
1155             -- end up trying to link object code to byte code.
1156             target = if prevailing_target /= local_target
1157                         && (not (isObjectTarget prevailing_target)
1158                             || not (isObjectTarget local_target))
1159                         then prevailing_target
1160                         else local_target
1161
1162             -- store the corrected hscTarget into the summary
1163             summary' = summary{ ms_hspp_opts = dflags { hscTarget = target } }
1164
1165             -- The old interface is ok if
1166             --  a) we're compiling a source file, and the old HPT
1167             --     entry is for a source file
1168             --  b) we're compiling a hs-boot file
1169             -- Case (b) allows an hs-boot file to get the interface of its
1170             -- real source file on the second iteration of the compilation
1171             -- manager, but that does no harm.  Otherwise the hs-boot file
1172             -- will always be recompiled
1173
1174             mb_old_iface
1175                 = case old_hmi of
1176                      Nothing                              -> Nothing
1177                      Just hm_info | isBootSummary summary -> Just iface
1178                                   | not (mi_boot iface)   -> Just iface
1179                                   | otherwise             -> Nothing
1180                                    where
1181                                      iface = hm_iface hm_info
1182
1183             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1184             compile_it  = upsweep_compile hsc_env
1185                                 summary' mod_index nmods mb_old_iface
1186
1187             compile_it_discard_iface
1188                         = upsweep_compile hsc_env
1189                                 summary' mod_index nmods Nothing
1190
1191         in
1192         case target of
1193
1194             _any
1195                 -- Regardless of whether we're generating object code or
1196                 -- byte code, we can always use an existing object file
1197                 -- if it is *stable* (see checkStability).
1198                 | is_stable_obj, isJust old_hmi ->
1199                         return old_hmi
1200                         -- object is stable, and we have an entry in the
1201                         -- old HPT: nothing to do
1202
1203                 | is_stable_obj, isNothing old_hmi -> do
1204                         linkable <- findObjectLinkable this_mod obj_fn
1205                                         (expectJust "upseep1" mb_obj_date)
1206                         compile_it (Just linkable)
1207                         -- object is stable, but we need to load the interface
1208                         -- off disk to make a HMI.
1209
1210             HscInterpreted
1211                 | is_stable_bco ->
1212                         ASSERT(isJust old_hmi) -- must be in the old_hpt
1213                         return old_hmi
1214                         -- BCO is stable: nothing to do
1215
1216                 | Just hmi <- old_hmi,
1217                   Just l <- hm_linkable hmi, not (isObjectLinkable l),
1218                   linkableTime l >= ms_hs_date summary ->
1219                         compile_it (Just l)
1220                         -- we have an old BCO that is up to date with respect
1221                         -- to the source: do a recompilation check as normal.
1222
1223                 | otherwise ->
1224                         compile_it Nothing
1225                         -- no existing code at all: we must recompile.
1226
1227               -- When generating object code, if there's an up-to-date
1228               -- object file on the disk, then we can use it.
1229               -- However, if the object file is new (compared to any
1230               -- linkable we had from a previous compilation), then we
1231               -- must discard any in-memory interface, because this
1232               -- means the user has compiled the source file
1233               -- separately and generated a new interface, that we must
1234               -- read from the disk.
1235               --
1236             obj | isObjectTarget obj,
1237                   Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1238                      case old_hmi of
1239                         Just hmi
1240                           | Just l <- hm_linkable hmi,
1241                             isObjectLinkable l && linkableTime l == obj_date
1242                             -> compile_it (Just l)
1243                         _otherwise -> do
1244                           linkable <- findObjectLinkable this_mod obj_fn obj_date
1245                           compile_it_discard_iface (Just linkable)
1246
1247             _otherwise ->
1248                   compile_it Nothing
1249
1250
1251 -- Run hsc to compile a module
1252 upsweep_compile :: HscEnv -> ModSummary -> Int -> Int
1253                 -> Maybe ModIface -> Maybe Linkable -> IO (Maybe HomeModInfo)
1254 upsweep_compile hsc_env summary mod_index nmods mb_old_iface mb_old_linkable
1255  = do
1256    compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1257                         mod_index nmods
1258
1259    case compresult of
1260         -- Compilation failed.  Compile may still have updated the PCS, tho.
1261         CompErrs -> return Nothing
1262
1263         -- Compilation "succeeded", and may or may not have returned a new
1264         -- linkable (depending on whether compilation was actually performed
1265         -- or not).
1266         CompOK new_details new_iface new_linkable
1267               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1268                                                  hm_details = new_details,
1269                                                  hm_linkable = new_linkable }
1270                     return (Just new_info)
1271
1272
1273 -- Filter modules in the HPT
1274 retainInTopLevelEnvs :: [ModuleName] -> HomePackageTable -> HomePackageTable
1275 retainInTopLevelEnvs keep_these hpt
1276    = listToUFM   [ (mod, expectJust "retain" mb_mod_info)
1277                  | mod <- keep_these
1278                  , let mb_mod_info = lookupUFM hpt mod
1279                  , isJust mb_mod_info ]
1280
1281 -- ---------------------------------------------------------------------------
1282 -- Typecheck module loops
1283
1284 {-
1285 See bug #930.  This code fixes a long-standing bug in --make.  The
1286 problem is that when compiling the modules *inside* a loop, a data
1287 type that is only defined at the top of the loop looks opaque; but
1288 after the loop is done, the structure of the data type becomes
1289 apparent.
1290
1291 The difficulty is then that two different bits of code have
1292 different notions of what the data type looks like.
1293
1294 The idea is that after we compile a module which also has an .hs-boot
1295 file, we re-generate the ModDetails for each of the modules that
1296 depends on the .hs-boot file, so that everyone points to the proper
1297 TyCons, Ids etc. defined by the real module, not the boot module.
1298 Fortunately re-generating a ModDetails from a ModIface is easy: the
1299 function TcIface.typecheckIface does exactly that.
1300
1301 Picking the modules to re-typecheck is slightly tricky.  Starting from
1302 the module graph consisting of the modules that have already been
1303 compiled, we reverse the edges (so they point from the imported module
1304 to the importing module), and depth-first-search from the .hs-boot
1305 node.  This gives us all the modules that depend transitively on the
1306 .hs-boot module, and those are exactly the modules that we need to
1307 re-typecheck.
1308
1309 Following this fix, GHC can compile itself with --make -O2.
1310 -}
1311
1312 reTypecheckLoop :: HscEnv -> ModSummary -> ModuleGraph -> IO HscEnv
1313 reTypecheckLoop hsc_env ms graph
1314   | not (isBootSummary ms) &&
1315     any (\m -> ms_mod m == this_mod && isBootSummary m) graph
1316   = do
1317         let mss = reachableBackwards (ms_mod_name ms) graph
1318             non_boot = filter (not.isBootSummary) mss
1319         debugTraceMsg (hsc_dflags hsc_env) 2 $
1320            text "Re-typechecking loop: " <> ppr (map ms_mod_name non_boot)
1321         typecheckLoop hsc_env (map ms_mod_name non_boot)
1322   | otherwise
1323   = return hsc_env
1324  where
1325   this_mod = ms_mod ms
1326
1327 typecheckLoop :: HscEnv -> [ModuleName] -> IO HscEnv
1328 typecheckLoop hsc_env mods = do
1329   new_hpt <-
1330     fixIO $ \new_hpt -> do
1331       let new_hsc_env = hsc_env{ hsc_HPT = new_hpt }
1332       mds <- initIfaceCheck new_hsc_env $
1333                 mapM (typecheckIface . hm_iface) hmis
1334       let new_hpt = addListToUFM old_hpt
1335                         (zip mods [ hmi{ hm_details = details }
1336                                   | (hmi,details) <- zip hmis mds ])
1337       return new_hpt
1338   return hsc_env{ hsc_HPT = new_hpt }
1339   where
1340     old_hpt = hsc_HPT hsc_env
1341     hmis    = map (expectJust "typecheckLoop" . lookupUFM old_hpt) mods
1342
1343 reachableBackwards :: ModuleName -> [ModSummary] -> [ModSummary]
1344 reachableBackwards mod summaries
1345   = [ ms | (ms,_,_) <- map vertex_fn nodes_we_want ]
1346   where
1347         -- all the nodes reachable by traversing the edges backwards
1348         -- from the root node:
1349         nodes_we_want = reachable (transposeG graph) root
1350
1351         -- the rest just sets up the graph:
1352         (nodes, lookup_key) = moduleGraphNodes False summaries
1353         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1354         root
1355           | Just key <- lookup_key HsBootFile mod, Just v <- key_fn key = v
1356           | otherwise = panic "reachableBackwards"
1357
1358 -- ---------------------------------------------------------------------------
1359 -- Topological sort of the module graph
1360
1361 topSortModuleGraph
1362           :: Bool               -- Drop hi-boot nodes? (see below)
1363           -> [ModSummary]
1364           -> Maybe ModuleName
1365           -> [SCC ModSummary]
1366 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1367 -- The resulting list of strongly-connected-components is in topologically
1368 -- sorted order, starting with the module(s) at the bottom of the
1369 -- dependency graph (ie compile them first) and ending with the ones at
1370 -- the top.
1371 --
1372 -- Drop hi-boot nodes (first boolean arg)?
1373 --
1374 --   False:     treat the hi-boot summaries as nodes of the graph,
1375 --              so the graph must be acyclic
1376 --
1377 --   True:      eliminate the hi-boot nodes, and instead pretend
1378 --              the a source-import of Foo is an import of Foo
1379 --              The resulting graph has no hi-boot nodes, but can by cyclic
1380
1381 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1382   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1383 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1384   = stronglyConnComp (map vertex_fn (reachable graph root))
1385   where
1386         -- restrict the graph to just those modules reachable from
1387         -- the specified module.  We do this by building a graph with
1388         -- the full set of nodes, and determining the reachable set from
1389         -- the specified node.
1390         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1391         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1392         root
1393           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1394           | otherwise  = throwDyn (ProgramError "module does not exist")
1395
1396 moduleGraphNodes :: Bool -> [ModSummary]
1397   -> ([(ModSummary, Int, [Int])], HscSource -> ModuleName -> Maybe Int)
1398 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1399    where
1400         -- Drop hs-boot nodes by using HsSrcFile as the key
1401         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1402                     | otherwise          = HsBootFile
1403
1404         -- We use integers as the keys for the SCC algorithm
1405         nodes :: [(ModSummary, Int, [Int])]
1406         nodes = [(s, expectJust "topSort" $
1407                         lookup_key (ms_hsc_src s) (ms_mod_name s),
1408                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1409                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s)) ++
1410                      (-- see [boot-edges] below
1411                       if drop_hs_boot_nodes || ms_hsc_src s == HsBootFile
1412                         then []
1413                         else case lookup_key HsBootFile (ms_mod_name s) of
1414                                 Nothing -> []
1415                                 Just k  -> [k])
1416                  )
1417                 | s <- summaries
1418                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1419                 -- Drop the hi-boot ones if told to do so
1420
1421         -- [boot-edges] if this is a .hs and there is an equivalent
1422         -- .hs-boot, add a link from the former to the latter.  This
1423         -- has the effect of detecting bogus cases where the .hs-boot
1424         -- depends on the .hs, by introducing a cycle.  Additionally,
1425         -- it ensures that we will always process the .hs-boot before
1426         -- the .hs, and so the HomePackageTable will always have the
1427         -- most up to date information.
1428
1429         key_map :: NodeMap Int
1430         key_map = listToFM ([(moduleName (ms_mod s), ms_hsc_src s)
1431                             | s <- summaries]
1432                            `zip` [1..])
1433
1434         lookup_key :: HscSource -> ModuleName -> Maybe Int
1435         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1436
1437         out_edge_keys :: HscSource -> [ModuleName] -> [Int]
1438         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1439                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1440                 -- the IsBootInterface parameter True; else False
1441
1442
1443 type NodeKey   = (ModuleName, HscSource)  -- The nodes of the graph are
1444 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1445
1446 msKey :: ModSummary -> NodeKey
1447 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (moduleName mod,boot)
1448
1449 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1450 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1451
1452 nodeMapElts :: NodeMap a -> [a]
1453 nodeMapElts = eltsFM
1454
1455 -- If there are {-# SOURCE #-} imports between strongly connected
1456 -- components in the topological sort, then those imports can
1457 -- definitely be replaced by ordinary non-SOURCE imports: if SOURCE
1458 -- were necessary, then the edge would be part of a cycle.
1459 warnUnnecessarySourceImports :: DynFlags -> [SCC ModSummary] -> IO ()
1460 warnUnnecessarySourceImports dflags sccs =
1461   printBagOfWarnings dflags (listToBag (concat (map (check.flattenSCC) sccs)))
1462   where check ms =
1463            let mods_in_this_cycle = map ms_mod_name ms in
1464            [ warn i | m <- ms, i <- ms_srcimps m,
1465                         unLoc i `notElem`  mods_in_this_cycle ]
1466
1467         warn :: Located ModuleName -> WarnMsg
1468         warn (L loc mod) =
1469            mkPlainErrMsg loc
1470                 (ptext SLIT("Warning: {-# SOURCE #-} unnecessary in import of ")
1471                  <+> quotes (ppr mod))
1472
1473 -----------------------------------------------------------------------------
1474 -- Downsweep (dependency analysis)
1475
1476 -- Chase downwards from the specified root set, returning summaries
1477 -- for all home modules encountered.  Only follow source-import
1478 -- links.
1479
1480 -- We pass in the previous collection of summaries, which is used as a
1481 -- cache to avoid recalculating a module summary if the source is
1482 -- unchanged.
1483 --
1484 -- The returned list of [ModSummary] nodes has one node for each home-package
1485 -- module, plus one for any hs-boot files.  The imports of these nodes
1486 -- are all there, including the imports of non-home-package modules.
1487
1488 downsweep :: HscEnv
1489           -> [ModSummary]       -- Old summaries
1490           -> [ModuleName]       -- Ignore dependencies on these; treat
1491                                 -- them as if they were package modules
1492           -> Bool               -- True <=> allow multiple targets to have
1493                                 --          the same module name; this is
1494                                 --          very useful for ghc -M
1495           -> IO (Maybe [ModSummary])
1496                 -- The elts of [ModSummary] all have distinct
1497                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1498                 -- in which case there can be repeats
1499 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1500    = -- catch error messages and return them
1501      handleDyn (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1502        rootSummaries <- mapM getRootSummary roots
1503        let root_map = mkRootMap rootSummaries
1504        checkDuplicates root_map
1505        summs <- loop (concatMap msDeps rootSummaries) root_map
1506        return (Just summs)
1507      where
1508         roots = hsc_targets hsc_env
1509
1510         old_summary_map :: NodeMap ModSummary
1511         old_summary_map = mkNodeMap old_summaries
1512
1513         getRootSummary :: Target -> IO ModSummary
1514         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1515            = do exists <- doesFileExist file
1516                 if exists
1517                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1518                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1519                            text "can't find file:" <+> text file
1520         getRootSummary (Target (TargetModule modl) maybe_buf)
1521            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1522                                            (L rootLoc modl) maybe_buf excl_mods
1523                 case maybe_summary of
1524                    Nothing -> packageModErr modl
1525                    Just s  -> return s
1526
1527         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1528
1529         -- In a root module, the filename is allowed to diverge from the module
1530         -- name, so we have to check that there aren't multiple root files
1531         -- defining the same module (otherwise the duplicates will be silently
1532         -- ignored, leading to confusing behaviour).
1533         checkDuplicates :: NodeMap [ModSummary] -> IO ()
1534         checkDuplicates root_map
1535            | allow_dup_roots = return ()
1536            | null dup_roots  = return ()
1537            | otherwise       = multiRootsErr (head dup_roots)
1538            where
1539              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1540              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1541
1542         loop :: [(Located ModuleName,IsBootInterface)]
1543                         -- Work list: process these modules
1544              -> NodeMap [ModSummary]
1545                         -- Visited set; the range is a list because
1546                         -- the roots can have the same module names
1547                         -- if allow_dup_roots is True
1548              -> IO [ModSummary]
1549                         -- The result includes the worklist, except
1550                         -- for those mentioned in the visited set
1551         loop [] done      = return (concat (nodeMapElts done))
1552         loop ((wanted_mod, is_boot) : ss) done
1553           | Just summs <- lookupFM done key
1554           = if isSingleton summs then
1555                 loop ss done
1556             else
1557                 do { multiRootsErr summs; return [] }
1558           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1559                                                  is_boot wanted_mod Nothing excl_mods
1560                                    ; case mb_s of
1561                                         Nothing -> loop ss done
1562                                         Just s  -> loop (msDeps s ++ ss)
1563                                                         (addToFM done key [s]) }
1564           where
1565             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1566
1567 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1568 mkRootMap summaries = addListToFM_C (++) emptyFM
1569                         [ (msKey s, [s]) | s <- summaries ]
1570
1571 msDeps :: ModSummary -> [(Located ModuleName, IsBootInterface)]
1572 -- (msDeps s) returns the dependencies of the ModSummary s.
1573 -- A wrinkle is that for a {-# SOURCE #-} import we return
1574 --      *both* the hs-boot file
1575 --      *and* the source file
1576 -- as "dependencies".  That ensures that the list of all relevant
1577 -- modules always contains B.hs if it contains B.hs-boot.
1578 -- Remember, this pass isn't doing the topological sort.  It's
1579 -- just gathering the list of all relevant ModSummaries
1580 msDeps s =
1581     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1582          ++ [ (m,False) | m <- ms_imps s ]
1583
1584 -----------------------------------------------------------------------------
1585 -- Summarising modules
1586
1587 -- We have two types of summarisation:
1588 --
1589 --    * Summarise a file.  This is used for the root module(s) passed to
1590 --      cmLoadModules.  The file is read, and used to determine the root
1591 --      module name.  The module name may differ from the filename.
1592 --
1593 --    * Summarise a module.  We are given a module name, and must provide
1594 --      a summary.  The finder is used to locate the file in which the module
1595 --      resides.
1596
1597 summariseFile
1598         :: HscEnv
1599         -> [ModSummary]                 -- old summaries
1600         -> FilePath                     -- source file name
1601         -> Maybe Phase                  -- start phase
1602         -> Maybe (StringBuffer,ClockTime)
1603         -> IO ModSummary
1604
1605 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1606         -- we can use a cached summary if one is available and the
1607         -- source file hasn't changed,  But we have to look up the summary
1608         -- by source file, rather than module name as we do in summarise.
1609    | Just old_summary <- findSummaryBySourceFile old_summaries file
1610    = do
1611         let location = ms_location old_summary
1612
1613                 -- return the cached summary if the source didn't change
1614         src_timestamp <- case maybe_buf of
1615                            Just (_,t) -> return t
1616                            Nothing    -> getModificationTime file
1617                 -- The file exists; we checked in getRootSummary above.
1618                 -- If it gets removed subsequently, then this
1619                 -- getModificationTime may fail, but that's the right
1620                 -- behaviour.
1621
1622         if ms_hs_date old_summary == src_timestamp
1623            then do -- update the object-file timestamp
1624                   obj_timestamp <- getObjTimestamp location False
1625                   return old_summary{ ms_obj_date = obj_timestamp }
1626            else
1627                 new_summary
1628
1629    | otherwise
1630    = new_summary
1631   where
1632     new_summary = do
1633         let dflags = hsc_dflags hsc_env
1634
1635         (dflags', hspp_fn, buf)
1636             <- preprocessFile dflags file mb_phase maybe_buf
1637
1638         (srcimps,the_imps, L _ mod_name) <- getImports dflags' buf hspp_fn
1639
1640         -- Make a ModLocation for this file
1641         location <- mkHomeModLocation dflags mod_name file
1642
1643         -- Tell the Finder cache where it is, so that subsequent calls
1644         -- to findModule will find it, even if it's not on any search path
1645         mod <- addHomeModuleToFinder hsc_env mod_name location
1646
1647         src_timestamp <- case maybe_buf of
1648                            Just (_,t) -> return t
1649                            Nothing    -> getModificationTime file
1650                         -- getMofificationTime may fail
1651
1652         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1653
1654         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1655                              ms_location = location,
1656                              ms_hspp_file = hspp_fn,
1657                              ms_hspp_opts = dflags',
1658                              ms_hspp_buf  = Just buf,
1659                              ms_srcimps = srcimps, ms_imps = the_imps,
1660                              ms_hs_date = src_timestamp,
1661                              ms_obj_date = obj_timestamp })
1662
1663 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1664 findSummaryBySourceFile summaries file
1665   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1666                                  expectJust "findSummaryBySourceFile" (ml_hs_file (ms_location ms)) == file ] of
1667         [] -> Nothing
1668         (x:_) -> Just x
1669
1670 -- Summarise a module, and pick up source and timestamp.
1671 summariseModule
1672           :: HscEnv
1673           -> NodeMap ModSummary -- Map of old summaries
1674           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1675           -> Located ModuleName -- Imported module to be summarised
1676           -> Maybe (StringBuffer, ClockTime)
1677           -> [ModuleName]               -- Modules to exclude
1678           -> IO (Maybe ModSummary)      -- Its new summary
1679
1680 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1681   | wanted_mod `elem` excl_mods
1682   = return Nothing
1683
1684   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1685   = do          -- Find its new timestamp; all the
1686                 -- ModSummaries in the old map have valid ml_hs_files
1687         let location = ms_location old_summary
1688             src_fn = expectJust "summariseModule" (ml_hs_file location)
1689
1690                 -- check the modification time on the source file, and
1691                 -- return the cached summary if it hasn't changed.  If the
1692                 -- file has disappeared, we need to call the Finder again.
1693         case maybe_buf of
1694            Just (_,t) -> check_timestamp old_summary location src_fn t
1695            Nothing    -> do
1696                 m <- System.IO.Error.try (getModificationTime src_fn)
1697                 case m of
1698                    Right t -> check_timestamp old_summary location src_fn t
1699                    Left e | isDoesNotExistError e -> find_it
1700                           | otherwise             -> ioError e
1701
1702   | otherwise  = find_it
1703   where
1704     dflags = hsc_dflags hsc_env
1705
1706     hsc_src = if is_boot then HsBootFile else HsSrcFile
1707
1708     check_timestamp old_summary location src_fn src_timestamp
1709         | ms_hs_date old_summary == src_timestamp = do
1710                 -- update the object-file timestamp
1711                 obj_timestamp <- getObjTimestamp location is_boot
1712                 return (Just old_summary{ ms_obj_date = obj_timestamp })
1713         | otherwise =
1714                 -- source changed: re-summarise.
1715                 new_summary location (ms_mod old_summary) src_fn src_timestamp
1716
1717     find_it = do
1718         -- Don't use the Finder's cache this time.  If the module was
1719         -- previously a package module, it may have now appeared on the
1720         -- search path, so we want to consider it to be a home module.  If
1721         -- the module was previously a home module, it may have moved.
1722         uncacheModule hsc_env wanted_mod
1723         found <- findImportedModule hsc_env wanted_mod Nothing
1724         case found of
1725              Found location mod
1726                 | isJust (ml_hs_file location) ->
1727                         -- Home package
1728                          just_found location mod
1729                 | otherwise ->
1730                         -- Drop external-pkg
1731                         ASSERT(modulePackageId mod /= thisPackage dflags)
1732                         return Nothing
1733                 where
1734
1735              err -> noModError dflags loc wanted_mod err
1736                         -- Not found
1737
1738     just_found location mod = do
1739                 -- Adjust location to point to the hs-boot source file,
1740                 -- hi file, object file, when is_boot says so
1741         let location' | is_boot   = addBootSuffixLocn location
1742                       | otherwise = location
1743             src_fn = expectJust "summarise2" (ml_hs_file location')
1744
1745                 -- Check that it exists
1746                 -- It might have been deleted since the Finder last found it
1747         maybe_t <- modificationTimeIfExists src_fn
1748         case maybe_t of
1749           Nothing -> noHsFileErr loc src_fn
1750           Just t  -> new_summary location' mod src_fn t
1751
1752
1753     new_summary location mod src_fn src_timestamp
1754       = do
1755         -- Preprocess the source file and get its imports
1756         -- The dflags' contains the OPTIONS pragmas
1757         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1758         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1759
1760         when (mod_name /= wanted_mod) $
1761                 throwDyn $ mkPlainErrMsg mod_loc $
1762                               text "file name does not match module name"
1763                               <+> quotes (ppr mod_name)
1764
1765                 -- Find the object timestamp, and return the summary
1766         obj_timestamp <- getObjTimestamp location is_boot
1767
1768         return (Just ( ModSummary { ms_mod       = mod,
1769                                     ms_hsc_src   = hsc_src,
1770                                     ms_location  = location,
1771                                     ms_hspp_file = hspp_fn,
1772                                     ms_hspp_opts = dflags',
1773                                     ms_hspp_buf  = Just buf,
1774                                     ms_srcimps   = srcimps,
1775                                     ms_imps      = the_imps,
1776                                     ms_hs_date   = src_timestamp,
1777                                     ms_obj_date  = obj_timestamp }))
1778
1779
1780 getObjTimestamp :: ModLocation -> Bool -> IO (Maybe ClockTime)
1781 getObjTimestamp location is_boot
1782   = if is_boot then return Nothing
1783                else modificationTimeIfExists (ml_obj_file location)
1784
1785
1786 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1787   -> IO (DynFlags, FilePath, StringBuffer)
1788 preprocessFile dflags src_fn mb_phase Nothing
1789   = do
1790         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1791         buf <- hGetStringBuffer hspp_fn
1792         return (dflags', hspp_fn, buf)
1793
1794 preprocessFile dflags src_fn mb_phase (Just (buf, _time))
1795   = do
1796         -- case we bypass the preprocessing stage?
1797         let
1798             local_opts = getOptions buf src_fn
1799         --
1800         (dflags', _errs) <- parseDynamicFlags dflags (map unLoc local_opts)
1801         -- XXX: shouldn't we be reporting the errors?
1802
1803         let
1804             needs_preprocessing
1805                 | Just (Unlit _) <- mb_phase    = True
1806                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1807                   -- note: local_opts is only required if there's no Unlit phase
1808                 | dopt Opt_Cpp dflags'          = True
1809                 | dopt Opt_Pp  dflags'          = True
1810                 | otherwise                     = False
1811
1812         when needs_preprocessing $
1813            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1814
1815         return (dflags', src_fn, buf)
1816
1817
1818 -----------------------------------------------------------------------------
1819 --                      Error messages
1820 -----------------------------------------------------------------------------
1821
1822 noModError :: DynFlags -> SrcSpan -> ModuleName -> FindResult -> IO ab
1823 -- ToDo: we don't have a proper line number for this error
1824 noModError dflags loc wanted_mod err
1825   = throwDyn $ mkPlainErrMsg loc $ cannotFindModule dflags wanted_mod err
1826
1827 noHsFileErr :: SrcSpan -> String -> a
1828 noHsFileErr loc path
1829   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1830
1831 packageModErr :: ModuleName -> a
1832 packageModErr mod
1833   = throwDyn $ mkPlainErrMsg noSrcSpan $
1834         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1835
1836 multiRootsErr :: [ModSummary] -> IO ()
1837 multiRootsErr [] = panic "multiRootsErr"
1838 multiRootsErr summs@(summ1:_)
1839   = throwDyn $ mkPlainErrMsg noSrcSpan $
1840         text "module" <+> quotes (ppr mod) <+>
1841         text "is defined in multiple files:" <+>
1842         sep (map text files)
1843   where
1844     mod = ms_mod summ1
1845     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
1846
1847 cyclicModuleErr :: [ModSummary] -> SDoc
1848 cyclicModuleErr ms
1849   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1850        2 (vcat (map show_one ms))
1851   where
1852     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1853                         nest 2 $ ptext SLIT("imports:") <+>
1854                                    (pp_imps HsBootFile (ms_srcimps ms)
1855                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1856     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1857     pp_imps src mods = fsep (map (show_mod src) mods)
1858
1859
1860 -- | Inform GHC that the working directory has changed.  GHC will flush
1861 -- its cache of module locations, since it may no longer be valid.
1862 -- Note: if you change the working directory, you should also unload
1863 -- the current program (set targets to empty, followed by load).
1864 workingDirectoryChanged :: Session -> IO ()
1865 workingDirectoryChanged s = withSession s $ flushFinderCaches
1866
1867 -- -----------------------------------------------------------------------------
1868 -- inspecting the session
1869
1870 -- | Get the module dependency graph.
1871 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1872 getModuleGraph s = withSession s (return . hsc_mod_graph)
1873
1874 isLoaded :: Session -> ModuleName -> IO Bool
1875 isLoaded s m = withSession s $ \hsc_env ->
1876   return $! isJust (lookupUFM (hsc_HPT hsc_env) m)
1877
1878 getBindings :: Session -> IO [TyThing]
1879 getBindings s = withSession s $ \hsc_env ->
1880    -- we have to implement the shadowing behaviour of ic_tmp_ids here
1881    -- (see InteractiveContext) and the quickest way is to use an OccEnv.
1882    let
1883        tmp_ids = ic_tmp_ids (hsc_IC hsc_env)
1884        filtered = foldr f (const []) tmp_ids emptyUniqSet
1885        f id rest set
1886            | uniq `elementOfUniqSet` set = rest set
1887            | otherwise  = AnId id : rest (addOneToUniqSet set uniq)
1888            where uniq = getUnique (nameOccName (idName id))
1889    in
1890    return filtered
1891
1892 getPrintUnqual :: Session -> IO PrintUnqualified
1893 getPrintUnqual s = withSession s $ \hsc_env ->
1894   return (icPrintUnqual (hsc_dflags hsc_env) (hsc_IC hsc_env))
1895
1896 -- | Container for information about a 'Module'.
1897 data ModuleInfo = ModuleInfo {
1898         minf_type_env  :: TypeEnv,
1899         minf_exports   :: NameSet, -- ToDo, [AvailInfo] like ModDetails?
1900         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1901         minf_instances :: [Instance]
1902 #ifdef GHCI
1903         ,minf_modBreaks :: ModBreaks
1904 #endif
1905         -- ToDo: this should really contain the ModIface too
1906   }
1907         -- We don't want HomeModInfo here, because a ModuleInfo applies
1908         -- to package modules too.
1909
1910 -- | Request information about a loaded 'Module'
1911 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1912 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1913   let mg = hsc_mod_graph hsc_env
1914   if mdl `elem` map ms_mod mg
1915         then getHomeModuleInfo hsc_env (moduleName mdl)
1916         else do
1917   {- if isHomeModule (hsc_dflags hsc_env) mdl
1918         then return Nothing
1919         else -} getPackageModuleInfo hsc_env mdl
1920    -- getPackageModuleInfo will attempt to find the interface, so
1921    -- we don't want to call it for a home module, just in case there
1922    -- was a problem loading the module and the interface doesn't
1923    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
1924
1925 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1926 #ifdef GHCI
1927 getPackageModuleInfo hsc_env mdl = do
1928   (_msgs, mb_avails) <- getModuleExports hsc_env mdl
1929   case mb_avails of
1930     Nothing -> return Nothing
1931     Just avails -> do
1932         eps <- readIORef (hsc_EPS hsc_env)
1933         let
1934             names  = availsToNameSet avails
1935             pte    = eps_PTE eps
1936             tys    = [ ty | name <- concatMap availNames avails,
1937                             Just ty <- [lookupTypeEnv pte name] ]
1938         --
1939         return (Just (ModuleInfo {
1940                         minf_type_env  = mkTypeEnv tys,
1941                         minf_exports   = names,
1942                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names (moduleName mdl),
1943                         minf_instances = error "getModuleInfo: instances for package module unimplemented",
1944                         minf_modBreaks = emptyModBreaks
1945                 }))
1946 #else
1947 getPackageModuleInfo _hsc_env _mdl = do
1948   -- bogusly different for non-GHCI (ToDo)
1949   return Nothing
1950 #endif
1951
1952 getHomeModuleInfo :: HscEnv -> ModuleName -> IO (Maybe ModuleInfo)
1953 getHomeModuleInfo hsc_env mdl =
1954   case lookupUFM (hsc_HPT hsc_env) mdl of
1955     Nothing  -> return Nothing
1956     Just hmi -> do
1957       let details = hm_details hmi
1958       return (Just (ModuleInfo {
1959                         minf_type_env  = md_types details,
1960                         minf_exports   = availsToNameSet (md_exports details),
1961                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1962                         minf_instances = md_insts details
1963 #ifdef GHCI
1964                        ,minf_modBreaks = getModBreaks hmi
1965 #endif
1966                         }))
1967
1968 -- | The list of top-level entities defined in a module
1969 modInfoTyThings :: ModuleInfo -> [TyThing]
1970 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1971
1972 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1973 modInfoTopLevelScope minf
1974   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1975
1976 modInfoExports :: ModuleInfo -> [Name]
1977 modInfoExports minf = nameSetToList $! minf_exports minf
1978
1979 -- | Returns the instances defined by the specified module.
1980 -- Warning: currently unimplemented for package modules.
1981 modInfoInstances :: ModuleInfo -> [Instance]
1982 modInfoInstances = minf_instances
1983
1984 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1985 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1986
1987 mkPrintUnqualifiedForModule :: Session -> ModuleInfo -> IO (Maybe PrintUnqualified)
1988 mkPrintUnqualifiedForModule s minf = withSession s $ \hsc_env -> do
1989   return (fmap (mkPrintUnqualified (hsc_dflags hsc_env)) (minf_rdr_env minf))
1990
1991 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1992 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1993    case lookupTypeEnv (minf_type_env minf) name of
1994      Just tyThing -> return (Just tyThing)
1995      Nothing      -> do
1996        eps <- readIORef (hsc_EPS hsc_env)
1997        return $! lookupType (hsc_dflags hsc_env)
1998                             (hsc_HPT hsc_env) (eps_PTE eps) name
1999
2000 #ifdef GHCI
2001 modInfoModBreaks :: ModuleInfo -> ModBreaks
2002 modInfoModBreaks = minf_modBreaks
2003 #endif
2004
2005 isDictonaryId :: Id -> Bool
2006 isDictonaryId id
2007   = case tcSplitSigmaTy (idType id) of { (_tvs, _theta, tau) -> isDictTy tau }
2008
2009 -- | Looks up a global name: that is, any top-level name in any
2010 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
2011 -- the interactive context, and therefore does not require a preceding
2012 -- 'setContext'.
2013 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
2014 lookupGlobalName s name = withSession s $ \hsc_env -> do
2015    eps <- readIORef (hsc_EPS hsc_env)
2016    return $! lookupType (hsc_dflags hsc_env)
2017                         (hsc_HPT hsc_env) (eps_PTE eps) name
2018
2019 -- -----------------------------------------------------------------------------
2020 -- Misc exported utils
2021
2022 dataConType :: DataCon -> Type
2023 dataConType dc = idType (dataConWrapId dc)
2024
2025 -- | print a 'NamedThing', adding parentheses if the name is an operator.
2026 pprParenSymName :: NamedThing a => a -> SDoc
2027 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
2028
2029 -- ----------------------------------------------------------------------------
2030
2031 #if 0
2032
2033 -- ToDo:
2034 --   - Data and Typeable instances for HsSyn.
2035
2036 -- ToDo: check for small transformations that happen to the syntax in
2037 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
2038
2039 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
2040 -- to get from TyCons, Ids etc. to TH syntax (reify).
2041
2042 -- :browse will use either lm_toplev or inspect lm_interface, depending
2043 -- on whether the module is interpreted or not.
2044
2045 -- This is for reconstructing refactored source code
2046 -- Calls the lexer repeatedly.
2047 -- ToDo: add comment tokens to token stream
2048 getTokenStream :: Session -> Module -> IO [Located Token]
2049 #endif
2050
2051 -- -----------------------------------------------------------------------------
2052 -- Interactive evaluation
2053
2054 -- | Takes a 'ModuleName' and possibly a 'PackageId', and consults the
2055 -- filesystem and package database to find the corresponding 'Module',
2056 -- using the algorithm that is used for an @import@ declaration.
2057 findModule :: Session -> ModuleName -> Maybe PackageId -> IO Module
2058 findModule s mod_name maybe_pkg = withSession s $ \hsc_env ->
2059   let
2060         dflags = hsc_dflags hsc_env
2061         hpt    = hsc_HPT hsc_env
2062         this_pkg = thisPackage dflags
2063   in
2064   case lookupUFM hpt mod_name of
2065     Just mod_info -> return (mi_module (hm_iface mod_info))
2066     _not_a_home_module -> do
2067           res <- findImportedModule hsc_env mod_name maybe_pkg
2068           case res of
2069             Found _ m | modulePackageId m /= this_pkg -> return m
2070                       | otherwise -> throwDyn (CmdLineError (showSDoc $
2071                                         text "module" <+> pprModule m <+>
2072                                         text "is not loaded"))
2073             err -> let msg = cannotFindModule dflags mod_name err in
2074                    throwDyn (CmdLineError (showSDoc msg))
2075
2076 #ifdef GHCI
2077 getHistorySpan :: Session -> History -> IO SrcSpan
2078 getHistorySpan sess h = withSession sess $ \hsc_env ->
2079                           return$ InteractiveEval.getHistorySpan hsc_env h
2080
2081 obtainTerm :: Session -> Bool -> Id -> IO Term
2082 obtainTerm sess force id = withSession sess $ \hsc_env ->
2083                             InteractiveEval.obtainTerm hsc_env force id
2084
2085 obtainTerm1 :: Session -> Bool -> Maybe Type -> a -> IO Term
2086 obtainTerm1 sess force mb_ty a = withSession sess $ \hsc_env ->
2087                                InteractiveEval.obtainTerm1 hsc_env force mb_ty a
2088
2089 obtainTermB :: Session -> Int -> Bool -> Id -> IO Term
2090 obtainTermB sess bound force id = withSession sess $ \hsc_env ->
2091                             InteractiveEval.obtainTermB hsc_env bound force id
2092
2093 #endif