compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         defaultErrorHandler,
  12         defaultCleanupHandler,
  13
  14         -- * GHC Monad
  15         Ghc, GhcT, GhcMonad(..),
  16         runGhc, runGhcT, initGhcMonad,
  17         gcatch, gbracket, gfinally,
  18         clearWarnings, getWarnings, hasWarnings,
  19         printExceptionAndWarnings, printWarnings,
  20         handleSourceError,
  21
  22         -- * Flags and settings
  23         DynFlags(..), DynFlag(..), Severity(..), HscTarget(..), dopt,
  24         GhcMode(..), GhcLink(..), defaultObjectTarget,
  25         parseDynamicFlags,
  26         getSessionDynFlags,
  27         setSessionDynFlags,
  28         parseStaticFlags,
  29
  30         -- * Targets
  31         Target(..), TargetId(..), Phase,
  32         setTargets,
  33         getTargets,
  34         addTarget,
  35         removeTarget,
  36         guessTarget,
  37
  38         -- * Extending the program scope
  39         extendGlobalRdrScope,
  40         setGlobalRdrScope,
  41         extendGlobalTypeScope,
  42         setGlobalTypeScope,
  43
  44         -- * Loading\/compiling the program
  45         depanal,
  46         load, loadWithLogger, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  47         defaultWarnErrLogger, WarnErrLogger,
  48         workingDirectoryChanged,
  49         parseModule, typecheckModule, desugarModule, loadModule,
  50         ParsedModule, TypecheckedModule, DesugaredModule, -- all abstract
  51         TypecheckedSource, ParsedSource, RenamedSource,   -- ditto
  52         TypecheckedMod, ParsedMod,
  53         moduleInfo, renamedSource, typecheckedSource,
  54         parsedSource, coreModule,
  55         compileToCoreModule, compileToCoreSimplified,
  56         compileCoreToObj,
  57         getModSummary,
  58
  59         -- * Parsing Haddock comments
  60         parseHaddockComment,
  61
  62         -- * Inspecting the module structure of the program
  63         ModuleGraph, ModSummary(..), ms_mod_name, ModLocation(..),
  64         getModuleGraph,
  65         isLoaded,
  66         topSortModuleGraph,
  67
  68         -- * Inspecting modules
  69         ModuleInfo,
  70         getModuleInfo,
  71         modInfoTyThings,
  72         modInfoTopLevelScope,
  73         modInfoExports,
  74         modInfoInstances,
  75         modInfoIsExportedName,
  76         modInfoLookupName,
  77         lookupGlobalName,
  78         findGlobalAnns,
  79         mkPrintUnqualifiedForModule,
  80
  81         -- * Querying the environment
  82         packageDbModules,
  83
  84         -- * Printing
  85         PrintUnqualified, alwaysQualify,
  86
  87         -- * Interactive evaluation
  88         getBindings, getPrintUnqual,
  89         findModule,
  90 #ifdef GHCI
  91         setContext, getContext,
  92         getNamesInScope,
  93         getRdrNamesInScope,
  94         getGRE,
  95         moduleIsInterpreted,
  96         getInfo,
  97         exprType,
  98         typeKind,
  99         parseName,
 100         RunResult(..),
 101         runStmt, SingleStep(..),
 102         resume,
 103         Resume(resumeStmt, resumeThreadId, resumeBreakInfo, resumeSpan,
 104                resumeHistory, resumeHistoryIx),
 105         History(historyBreakInfo, historyEnclosingDecl),
 106         GHC.getHistorySpan, getHistoryModule,
 107         getResumeContext,
 108         abandon, abandonAll,
 109         InteractiveEval.back,
 110         InteractiveEval.forward,
 111         showModule,
 112         isModuleInterpreted,
 113         InteractiveEval.compileExpr, HValue, dynCompileExpr,
 114         lookupName,
 115         GHC.obtainTermFromId, GHC.obtainTermFromVal, reconstructType,
 116         modInfoModBreaks,
 117         ModBreaks(..), BreakIndex,
 118         BreakInfo(breakInfo_number, breakInfo_module),
 119         BreakArray, setBreakOn, setBreakOff, getBreak,
 120 #endif
 121
 122         -- * Abstract syntax elements
 123
 124         -- ** Packages
 125         PackageId,
 126
 127         -- ** Modules
 128         Module, mkModule, pprModule, moduleName, modulePackageId,
 129         ModuleName, mkModuleName, moduleNameString,
 130
 131         -- ** Names
 132         Name,
 133         isExternalName, nameModule, pprParenSymName, nameSrcSpan,
 134         NamedThing(..),
 135         RdrName(Qual,Unqual),
 136
 137         -- ** Identifiers
 138         Id, idType,
 139         isImplicitId, isDeadBinder,
 140         isExportedId, isLocalId, isGlobalId,
 141         isRecordSelector,
 142         isPrimOpId, isFCallId, isClassOpId_maybe,
 143         isDataConWorkId, idDataCon,
 144         isBottomingId, isDictonaryId,
 145         recordSelectorFieldLabel,
 146
 147         -- ** Type constructors
 148         TyCon,
 149         tyConTyVars, tyConDataCons, tyConArity,
 150         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 151         isOpenTyCon,
 152         synTyConDefn, synTyConType, synTyConResKind,
 153
 154         -- ** Type variables
 155         TyVar,
 156         alphaTyVars,
 157
 158         -- ** Data constructors
 159         DataCon,
 160         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 161         dataConIsInfix, isVanillaDataCon,
 162         dataConStrictMarks,
 163         StrictnessMark(..), isMarkedStrict,
 164
 165         -- ** Classes
 166         Class,
 167         classMethods, classSCTheta, classTvsFds,
 168         pprFundeps,
 169
 170         -- ** Instances
 171         Instance,
 172         instanceDFunId, pprInstance, pprInstanceHdr,
 173
 174         -- ** Types and Kinds
 175         Type, splitForAllTys, funResultTy,
 176         pprParendType, pprTypeApp,
 177         Kind,
 178         PredType,
 179         ThetaType, pprThetaArrow,
 180
 181         -- ** Entities
 182         TyThing(..),
 183
 184         -- ** Syntax
 185         module HsSyn, -- ToDo: remove extraneous bits
 186
 187         -- ** Fixities
 188         FixityDirection(..),
 189         defaultFixity, maxPrecedence,
 190         negateFixity,
 191         compareFixity,
 192
 193         -- ** Source locations
 194         SrcLoc, pprDefnLoc,
 195         mkSrcLoc, isGoodSrcLoc, noSrcLoc,
 196         srcLocFile, srcLocLine, srcLocCol,
 197         SrcSpan,
 198         mkSrcSpan, srcLocSpan, isGoodSrcSpan, noSrcSpan,
 199         srcSpanStart, srcSpanEnd,
 200         srcSpanFile,
 201         srcSpanStartLine, srcSpanEndLine,
 202         srcSpanStartCol, srcSpanEndCol,
 203
 204         -- ** Located
 205         Located(..),
 206
 207         -- *** Constructing Located
 208         noLoc, mkGeneralLocated,
 209
 210         -- *** Deconstructing Located
 211         getLoc, unLoc,
 212
 213         -- *** Combining and comparing Located values
 214         eqLocated, cmpLocated, combineLocs, addCLoc,
 215         leftmost_smallest, leftmost_largest, rightmost,
 216         spans, isSubspanOf,
 217
 218         -- * Exceptions
 219         GhcException(..), showGhcException,
 220
 221         -- * Token stream manipulations
 222         Token,
 223         getTokenStream, getRichTokenStream,
 224         showRichTokenStream, addSourceToTokens,
 225
 226         -- * Miscellaneous
 227         --sessionHscEnv,
 228         cyclicModuleErr,
 229   ) where
 230
 231 {-
 232  ToDo:
 233
 234   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 235   * what StaticFlags should we expose, if any?
 236 -}
 237
 238 #include "HsVersions.h"
 239
 240 #ifdef GHCI
 241 import qualified Linker
 242 import Linker           ( HValue )
 243 import ByteCodeInstr
 244 import BreakArray
 245 import NameSet
 246 import InteractiveEval
 247 import TcRnDriver
 248 #endif
 249
 250 import TcIface
 251 import TcRnTypes        hiding (LIE)
 252 import TcRnMonad        ( initIfaceCheck )
 253 import Packages
 254 import NameSet
 255 import RdrName
 256 import qualified HsSyn -- hack as we want to reexport the whole module
 257 import HsSyn hiding ((<.>))
 258 import Type             hiding (typeKind)
 259 import TcType           hiding (typeKind)
 260 import Id
 261 import Var
 262 import TysPrim          ( alphaTyVars )
 263 import TyCon
 264 import Class
 265 import FunDeps
 266 import DataCon
 267 import Name             hiding ( varName )
 268 import OccName          ( parenSymOcc )
 269 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr,
 270                           emptyInstEnv )
 271 import FamInstEnv       ( emptyFamInstEnv )
 272 import SrcLoc
 273 --import CoreSyn
 274 import TidyPgm
 275 import DriverPipeline
 276 import DriverPhases     ( HscSource(..), Phase(..), isHaskellSrcFilename, startPhase )
 277 import HeaderInfo
 278 import Finder
 279 import HscMain
 280 import HscTypes
 281 import DynFlags
 282 import StaticFlagParser
 283 import qualified StaticFlags
 284 import SysTools     ( initSysTools, cleanTempFiles, cleanTempFilesExcept,
 285                       cleanTempDirs )
 286 import Annotations
 287 import Module
 288 import LazyUniqFM
 289 import qualified UniqFM as UFM
 290 import UniqSet
 291 import Unique
 292 import FiniteMap
 293 import Panic
 294 import Digraph
 295 import Bag              ( unitBag, listToBag, emptyBag, isEmptyBag )
 296 import ErrUtils
 297 import MonadUtils
 298 import Util
 299 import StringBuffer     ( StringBuffer, hGetStringBuffer, nextChar )
 300 import Outputable
 301 import BasicTypes
 302 import Maybes           ( expectJust, mapCatMaybes )
 303 import HaddockParse
 304 import HaddockLex       ( tokenise )
 305 import FastString
 306 import Lexer
 307
 308 import Control.Concurrent
 309 import System.Directory ( getModificationTime, doesFileExist,
 310                           getCurrentDirectory )
 311 import Data.Maybe
 312 import Data.List
 313 import qualified Data.List as List
 314 import Data.Typeable    ( Typeable )
 315 import Data.Word        ( Word8 )
 316 import Control.Monad
 317 import System.Exit      ( exitWith, ExitCode(..) )
 318 import System.Time      ( ClockTime, getClockTime )
 319 import Exception
 320 import Data.IORef
 321 import System.FilePath
 322 import System.IO
 323 import System.IO.Error  ( try, isDoesNotExistError )
 324 import Prelude hiding (init)
 325
 326
 327 -- -----------------------------------------------------------------------------
 328 -- Exception handlers
 329
 330 -- | Install some default exception handlers and run the inner computation.
 331 -- Unless you want to handle exceptions yourself, you should wrap this around
 332 -- the top level of your program.  The default handlers output the error
 333 -- message(s) to stderr and exit cleanly.
 334 defaultErrorHandler :: (ExceptionMonad m, MonadIO m) => DynFlags -> m a -> m a
 335 defaultErrorHandler dflags inner =
 336   -- top-level exception handler: any unrecognised exception is a compiler bug.
 337   ghandle (\exception -> liftIO $ do
 338            hFlush stdout
 339            case fromException exception of
 340                 -- an IO exception probably isn't our fault, so don't panic
 341                 Just (ioe :: IOException) ->
 342                   fatalErrorMsg dflags (text (show ioe))
 343                 _ -> case fromException exception of
 344                      Just StackOverflow ->
 345                          fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 346                      _ -> case fromException exception of
 347                           Just (ex :: ExitCode) -> throw ex
 348                           _ ->
 349                               fatalErrorMsg dflags
 350                                   (text (show (Panic (show exception))))
 351            exitWith (ExitFailure 1)
 352          ) $
 353
 354   -- error messages propagated as exceptions
 355   handleGhcException
 356             (\ge -> liftIO $ do
 357                 hFlush stdout
 358                 case ge of
 359                      PhaseFailed _ code -> exitWith code
 360                      Interrupted -> exitWith (ExitFailure 1)
 361                      _ -> do fatalErrorMsg dflags (text (show ge))
 362                              exitWith (ExitFailure 1)
 363             ) $
 364   inner
 365
 366 -- | Install a default cleanup handler to remove temporary files deposited by
 367 -- a GHC run.  This is seperate from 'defaultErrorHandler', because you might
 368 -- want to override the error handling, but still get the ordinary cleanup
 369 -- behaviour.
 370 defaultCleanupHandler :: (ExceptionMonad m, MonadIO m) =>
 371                          DynFlags -> m a -> m a
 372 defaultCleanupHandler dflags inner =
 373     -- make sure we clean up after ourselves
 374     inner `gonException`
 375           (liftIO $ do
 376               cleanTempFiles dflags
 377               cleanTempDirs dflags
 378           )
 379           --  exceptions will be blocked while we clean the temporary files,
 380           -- so there shouldn't be any difficulty if we receive further
 381           -- signals.
 382
 383 -- | Print the error message and all warnings.  Useful inside exception
 384 --   handlers.  Clears warnings after printing.
 385 printExceptionAndWarnings :: GhcMonad m => SourceError -> m ()
 386 printExceptionAndWarnings err = do
 387     let errs = srcErrorMessages err
 388     warns <- getWarnings
 389     dflags <- getSessionDynFlags
 390     if isEmptyBag errs
 391        -- Empty errors means we failed due to -Werror.  (Since this function
 392        -- takes a source error as argument, we know for sure _some_ error
 393        -- did indeed happen.)
 394        then liftIO $ do
 395               printBagOfWarnings dflags warns
 396               printBagOfErrors dflags (unitBag warnIsErrorMsg)
 397        else liftIO $ printBagOfErrors dflags errs
 398     clearWarnings
 399
 400 -- | Print all accumulated warnings using 'log_action'.
 401 printWarnings :: GhcMonad m => m ()
 402 printWarnings = do
 403     dflags <- getSessionDynFlags
 404     warns <- getWarnings
 405     liftIO $ printBagOfWarnings dflags warns
 406     clearWarnings
 407
 408 -- | Run function for the 'Ghc' monad.
 409 --
 410 -- It initialises the GHC session and warnings via 'initGhcMonad'.  Each call
 411 -- to this function will create a new session which should not be shared among
 412 -- several threads.
 413 --
 414 -- Any errors not handled inside the 'Ghc' action are propagated as IO
 415 -- exceptions.
 416
 417 runGhc :: Maybe FilePath  -- ^ See argument to 'initGhcMonad'.
 418        -> Ghc a           -- ^ The action to perform.
 419        -> IO a
 420 runGhc mb_top_dir ghc = do
 421   wref <- newIORef emptyBag
 422   ref <- newIORef undefined
 423   let session = Session ref wref
 424   flip unGhc session $ do
 425     initGhcMonad mb_top_dir
 426     ghc
 427   -- XXX: unregister interrupt handlers here?
 428
 429 -- | Run function for 'GhcT' monad transformer.
 430 --
 431 -- It initialises the GHC session and warnings via 'initGhcMonad'.  Each call
 432 -- to this function will create a new session which should not be shared among
 433 -- several threads.
 434
 435 runGhcT :: (ExceptionMonad m, Functor m, MonadIO m) =>
 436            Maybe FilePath  -- ^ See argument to 'initGhcMonad'.
 437         -> GhcT m a        -- ^ The action to perform.
 438         -> m a
 439 runGhcT mb_top_dir ghct = do
 440   wref <- liftIO $ newIORef emptyBag
 441   ref <- liftIO $ newIORef undefined
 442   let session = Session ref wref
 443   flip unGhcT session $ do
 444     initGhcMonad mb_top_dir
 445     ghct
 446
 447 -- | Initialise a GHC session.
 448 --
 449 -- If you implement a custom 'GhcMonad' you must call this function in the
 450 -- monad run function.  It will initialise the session variable and clear all
 451 -- warnings.
 452 --
 453 -- The first argument should point to the directory where GHC's library files
 454 -- reside.  More precisely, this should be the output of @ghc --print-libdir@
 455 -- of the version of GHC the module using this API is compiled with.  For
 456 -- portability, you should use the @ghc-paths@ package, available at
 457 -- <http://hackage.haskell.org/cgi-bin/hackage-scripts/package/ghc-paths>.
 458
 459 initGhcMonad :: GhcMonad m => Maybe FilePath -> m ()
 460 initGhcMonad mb_top_dir = do
 461   -- catch ^C
 462   main_thread <- liftIO $ myThreadId
 463   liftIO $ modifyMVar_ interruptTargetThread (return . (main_thread :))
 464   liftIO $ installSignalHandlers
 465
 466   liftIO $ StaticFlags.initStaticOpts
 467
 468   dflags0 <- liftIO $ initDynFlags defaultDynFlags
 469   dflags <- liftIO $ initSysTools mb_top_dir dflags0
 470   env <- liftIO $ newHscEnv dflags
 471   setSession env
 472   clearWarnings
 473
 474 -- -----------------------------------------------------------------------------
 475 -- Flags & settings
 476
 477 -- | Grabs the DynFlags from the Session
 478 getSessionDynFlags :: GhcMonad m => m DynFlags
 479 getSessionDynFlags = withSession (return . hsc_dflags)
 480
 481 -- | Updates the DynFlags in a Session.  This also reads
 482 -- the package database (unless it has already been read),
 483 -- and prepares the compilers knowledge about packages.  It
 484 -- can be called again to load new packages: just add new
 485 -- package flags to (packageFlags dflags).
 486 --
 487 -- Returns a list of new packages that may need to be linked in using
 488 -- the dynamic linker (see 'linkPackages') as a result of new package
 489 -- flags.  If you are not doing linking or doing static linking, you
 490 -- can ignore the list of packages returned.
 491 --
 492 setSessionDynFlags :: GhcMonad m => DynFlags -> m [PackageId]
 493 setSessionDynFlags dflags = do
 494   (dflags', preload) <- liftIO $ initPackages dflags
 495   modifySession (\h -> h{ hsc_dflags = dflags' })
 496   return preload
 497
 498 -- | If there is no -o option, guess the name of target executable
 499 -- by using top-level source file name as a base.
 500 guessOutputFile :: GhcMonad m => m ()
 501 guessOutputFile = modifySession $ \env ->
 502     let dflags = hsc_dflags env
 503         mod_graph = hsc_mod_graph env
 504         mainModuleSrcPath :: Maybe String
 505         mainModuleSrcPath = do
 506             let isMain = (== mainModIs dflags) . ms_mod
 507             [ms] <- return (filter isMain mod_graph)
 508             ml_hs_file (ms_location ms)
 509         name = fmap dropExtension mainModuleSrcPath
 510
 511 #if defined(mingw32_HOST_OS)
 512         -- we must add the .exe extention unconditionally here, otherwise
 513         -- when name has an extension of its own, the .exe extension will
 514         -- not be added by DriverPipeline.exeFileName.  See #2248
 515         name_exe = fmap (<.> "exe") name
 516 #else
 517         name_exe = name
 518 #endif
 519     in
 520     case outputFile dflags of
 521         Just _ -> env
 522         Nothing -> env { hsc_dflags = dflags { outputFile = name_exe } }
 523
 524 -- -----------------------------------------------------------------------------
 525 -- Targets
 526
 527 -- ToDo: think about relative vs. absolute file paths. And what
 528 -- happens when the current directory changes.
 529
 530 -- | Sets the targets for this session.  Each target may be a module name
 531 -- or a filename.  The targets correspond to the set of root modules for
 532 -- the program\/library.  Unloading the current program is achieved by
 533 -- setting the current set of targets to be empty, followed by 'load'.
 534 setTargets :: GhcMonad m => [Target] -> m ()
 535 setTargets targets = modifySession (\h -> h{ hsc_targets = targets })
 536
 537 -- | Returns the current set of targets
 538 getTargets :: GhcMonad m => m [Target]
 539 getTargets = withSession (return . hsc_targets)
 540
 541 -- | Add another target.
 542 addTarget :: GhcMonad m => Target -> m ()
 543 addTarget target
 544   = modifySession (\h -> h{ hsc_targets = target : hsc_targets h })
 545
 546 -- | Remove a target
 547 removeTarget :: GhcMonad m => TargetId -> m ()
 548 removeTarget target_id
 549   = modifySession (\h -> h{ hsc_targets = filter (hsc_targets h) })
 550   where
 551    filter targets = [ t | t@(Target id _ _) <- targets, id /= target_id ]
 552
 553 -- | Attempts to guess what Target a string refers to.  This function
 554 -- implements the @--make@/GHCi command-line syntax for filenames:
 555 --
 556 --   - if the string looks like a Haskell source filename, then interpret it
 557 --     as such
 558 --
 559 --   - if adding a .hs or .lhs suffix yields the name of an existing file,
 560 --     then use that
 561 --
 562 --   - otherwise interpret the string as a module name
 563 --
 564 guessTarget :: GhcMonad m => String -> Maybe Phase -> m Target
 565 guessTarget str (Just phase)
 566    = return (Target (TargetFile str (Just phase)) True Nothing)
 567 guessTarget str Nothing
 568    | isHaskellSrcFilename file
 569    = return (target (TargetFile file Nothing))
 570    | otherwise
 571    = do exists <- liftIO $ doesFileExist hs_file
 572         if exists
 573            then return (target (TargetFile hs_file Nothing))
 574            else do
 575         exists <- liftIO $ doesFileExist lhs_file
 576         if exists
 577            then return (target (TargetFile lhs_file Nothing))
 578            else do
 579         if looksLikeModuleName file
 580            then return (target (TargetModule (mkModuleName file)))
 581            else do
 582         throwGhcException
 583                  (ProgramError (showSDoc $
 584                  text "target" <+> quotes (text file) <+>
 585                  text "is not a module name or a source file"))
 586      where
 587          (file,obj_allowed)
 588                 | '*':rest <- str = (rest, False)
 589                 | otherwise       = (str,  True)
 590
 591          hs_file  = file <.> "hs"
 592          lhs_file = file <.> "lhs"
 593
 594          target tid = Target tid obj_allowed Nothing
 595
 596 -- -----------------------------------------------------------------------------
 597 -- Extending the program scope
 598
 599 extendGlobalRdrScope :: GhcMonad m => [GlobalRdrElt] -> m ()
 600 extendGlobalRdrScope rdrElts
 601     = modifySession $ \hscEnv ->
 602       let global_rdr = hsc_global_rdr_env hscEnv
 603       in hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv global_rdr rdrElts }
 604
 605 setGlobalRdrScope :: GhcMonad m => [GlobalRdrElt] -> m ()
 606 setGlobalRdrScope rdrElts
 607     = modifySession $ \hscEnv ->
 608       hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv emptyGlobalRdrEnv rdrElts }
 609
 610 extendGlobalTypeScope :: GhcMonad m => [Id] -> m ()
 611 extendGlobalTypeScope ids
 612     = modifySession $ \hscEnv ->
 613       let global_type = hsc_global_type_env hscEnv
 614       in hscEnv{ hsc_global_type_env = extendTypeEnvWithIds global_type ids }
 615
 616 setGlobalTypeScope :: GhcMonad m => [Id] -> m ()
 617 setGlobalTypeScope ids
 618     = modifySession $ \hscEnv ->
 619       hscEnv{ hsc_global_type_env = extendTypeEnvWithIds emptyTypeEnv ids }
 620
 621 -- -----------------------------------------------------------------------------
 622 -- Parsing Haddock comments
 623
 624 parseHaddockComment :: String -> Either String (HsDoc RdrName)
 625 parseHaddockComment string =
 626   case parseHaddockParagraphs (tokenise string) of
 627     MyLeft x  -> Left x
 628     MyRight x -> Right x
 629
 630 -- -----------------------------------------------------------------------------
 631 -- Loading the program
 632
 633 -- | Perform a dependency analysis starting from the current targets
 634 -- and update the session with the new module graph.
 635 depanal :: GhcMonad m =>
 636            [ModuleName]  -- ^ excluded modules
 637         -> Bool          -- ^ allow duplicate roots
 638         -> m ModuleGraph
 639 depanal excluded_mods allow_dup_roots = do
 640   hsc_env <- getSession
 641   let
 642          dflags  = hsc_dflags hsc_env
 643          targets = hsc_targets hsc_env
 644          old_graph = hsc_mod_graph hsc_env
 645
 646   liftIO $ showPass dflags "Chasing dependencies"
 647   liftIO $ debugTraceMsg dflags 2 (hcat [
 648              text "Chasing modules from: ",
 649              hcat (punctuate comma (map pprTarget targets))])
 650
 651   mod_graph <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 652   modifySession $ \_ -> hsc_env { hsc_mod_graph = mod_graph }
 653   return mod_graph
 654
 655 data LoadHowMuch
 656    = LoadAllTargets
 657    | LoadUpTo ModuleName
 658    | LoadDependenciesOf ModuleName
 659
 660 -- | Try to load the program.  Calls 'loadWithLogger' with the default
 661 -- compiler that just immediately logs all warnings and errors.
 662 --
 663 -- This function may throw a 'SourceError' if errors are encountered before
 664 -- the actual compilation starts (e.g., during dependency analysis).
 665 --
 666 load :: GhcMonad m => LoadHowMuch -> m SuccessFlag
 667 load how_much =
 668     loadWithLogger defaultWarnErrLogger how_much
 669
 670 -- | A function called to log warnings and errors.
 671 type WarnErrLogger = GhcMonad m => Maybe SourceError -> m ()
 672
 673 defaultWarnErrLogger :: WarnErrLogger
 674 defaultWarnErrLogger Nothing = printWarnings
 675 defaultWarnErrLogger (Just e) = printExceptionAndWarnings e
 676
 677 -- | Try to load the program.  If a Module is supplied, then just
 678 -- attempt to load up to this target.  If no Module is supplied,
 679 -- then try to load all targets.
 680 --
 681 -- The first argument is a function that is called after compiling each
 682 -- module to print wanrings and errors.
 683 --
 684 -- While compiling a module, all 'SourceError's are caught and passed to the
 685 -- logger, however, this function may still throw a 'SourceError' if
 686 -- dependency analysis failed (e.g., due to a parse error).
 687 --
 688 loadWithLogger :: GhcMonad m => WarnErrLogger -> LoadHowMuch -> m SuccessFlag
 689 loadWithLogger logger how_much = do
 690     -- Dependency analysis first.  Note that this fixes the module graph:
 691     -- even if we don't get a fully successful upsweep, the full module
 692     -- graph is still retained in the Session.  We can tell which modules
 693     -- were successfully loaded by inspecting the Session's HPT.
 694     mod_graph <- depanal [] False
 695     load2 how_much mod_graph logger
 696
 697 load2 :: GhcMonad m => LoadHowMuch -> [ModSummary] -> WarnErrLogger
 698       -> m SuccessFlag
 699 load2 how_much mod_graph logger = do
 700         guessOutputFile
 701         hsc_env <- getSession
 702
 703         let hpt1      = hsc_HPT hsc_env
 704         let dflags    = hsc_dflags hsc_env
 705
 706         -- The "bad" boot modules are the ones for which we have
 707         -- B.hs-boot in the module graph, but no B.hs
 708         -- The downsweep should have ensured this does not happen
 709         -- (see msDeps)
 710         let all_home_mods = [ms_mod_name s
 711                             | s <- mod_graph, not (isBootSummary s)]
 712             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 713                                         not (ms_mod_name s `elem` all_home_mods)]
 714         ASSERT( null bad_boot_mods ) return ()
 715
 716         -- check that the module given in HowMuch actually exists, otherwise
 717         -- topSortModuleGraph will bomb later.
 718         let checkHowMuch (LoadUpTo m)           = checkMod m
 719             checkHowMuch (LoadDependenciesOf m) = checkMod m
 720             checkHowMuch _ = id
 721
 722             checkMod m and_then
 723                 | m `elem` all_home_mods = and_then
 724                 | otherwise = do
 725                         liftIO $ errorMsg dflags (text "no such module:" <+>
 726                                          quotes (ppr m))
 727                         return Failed
 728
 729         checkHowMuch how_much $ do
 730
 731         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 732         -- graph with cycles.  Among other things, it is used for
 733         -- backing out partially complete cycles following a failed
 734         -- upsweep, and for removing from hpt all the modules
 735         -- not in strict downwards closure, during calls to compile.
 736         let mg2_with_srcimps :: [SCC ModSummary]
 737             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 738
 739         -- If we can determine that any of the {-# SOURCE #-} imports
 740         -- are definitely unnecessary, then emit a warning.
 741         warnUnnecessarySourceImports dflags mg2_with_srcimps
 742
 743         let
 744             -- check the stability property for each module.
 745             stable_mods@(stable_obj,stable_bco)
 746                 = checkStability hpt1 mg2_with_srcimps all_home_mods
 747
 748             -- prune bits of the HPT which are definitely redundant now,
 749             -- to save space.
 750             pruned_hpt = pruneHomePackageTable hpt1
 751                                 (flattenSCCs mg2_with_srcimps)
 752                                 stable_mods
 753
 754         liftIO $ evaluate pruned_hpt
 755
 756         -- before we unload anything, make sure we don't leave an old
 757         -- interactive context around pointing to dead bindings.  Also,
 758         -- write the pruned HPT to allow the old HPT to be GC'd.
 759         modifySession $ \_ -> hsc_env{ hsc_IC = emptyInteractiveContext,
 760                                        hsc_HPT = pruned_hpt }
 761
 762         liftIO $ debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 763                                 text "Stable BCO:" <+> ppr stable_bco)
 764
 765         -- Unload any modules which are going to be re-linked this time around.
 766         let stable_linkables = [ linkable
 767                                | m <- stable_obj++stable_bco,
 768                                  Just hmi <- [lookupUFM pruned_hpt m],
 769                                  Just linkable <- [hm_linkable hmi] ]
 770         liftIO $ unload hsc_env stable_linkables
 771
 772         -- We could at this point detect cycles which aren't broken by
 773         -- a source-import, and complain immediately, but it seems better
 774         -- to let upsweep_mods do this, so at least some useful work gets
 775         -- done before the upsweep is abandoned.
 776         --hPutStrLn stderr "after tsort:\n"
 777         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 778
 779         -- Now do the upsweep, calling compile for each module in
 780         -- turn.  Final result is version 3 of everything.
 781
 782         -- Topologically sort the module graph, this time including hi-boot
 783         -- nodes, and possibly just including the portion of the graph
 784         -- reachable from the module specified in the 2nd argument to load.
 785         -- This graph should be cycle-free.
 786         -- If we're restricting the upsweep to a portion of the graph, we
 787         -- also want to retain everything that is still stable.
 788         let full_mg :: [SCC ModSummary]
 789             full_mg    = topSortModuleGraph False mod_graph Nothing
 790
 791             maybe_top_mod = case how_much of
 792                                 LoadUpTo m           -> Just m
 793                                 LoadDependenciesOf m -> Just m
 794                                 _                    -> Nothing
 795
 796             partial_mg0 :: [SCC ModSummary]
 797             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 798
 799             -- LoadDependenciesOf m: we want the upsweep to stop just
 800             -- short of the specified module (unless the specified module
 801             -- is stable).
 802             partial_mg
 803                 | LoadDependenciesOf _mod <- how_much
 804                 = ASSERT( case last partial_mg0 of
 805                             AcyclicSCC ms -> ms_mod_name ms == _mod; _ -> False )
 806                   List.init partial_mg0
 807                 | otherwise
 808                 = partial_mg0
 809
 810             stable_mg =
 811                 [ AcyclicSCC ms
 812                 | AcyclicSCC ms <- full_mg,
 813                   ms_mod_name ms `elem` stable_obj++stable_bco,
 814                   ms_mod_name ms `notElem` [ ms_mod_name ms' |
 815                                                 AcyclicSCC ms' <- partial_mg ] ]
 816
 817             mg = stable_mg ++ partial_mg
 818
 819         -- clean up between compilations
 820         let cleanup = cleanTempFilesExcept dflags
 821                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 822
 823         liftIO $ debugTraceMsg dflags 2 (hang (text "Ready for upsweep")
 824                                    2 (ppr mg))
 825         (upsweep_ok, hsc_env1, modsUpswept)
 826            <- upsweep logger
 827                       (hsc_env { hsc_HPT = emptyHomePackageTable })
 828                       pruned_hpt stable_mods cleanup mg
 829
 830         -- Make modsDone be the summaries for each home module now
 831         -- available; this should equal the domain of hpt3.
 832         -- Get in in a roughly top .. bottom order (hence reverse).
 833
 834         let modsDone = reverse modsUpswept
 835
 836         -- Try and do linking in some form, depending on whether the
 837         -- upsweep was completely or only partially successful.
 838
 839         if succeeded upsweep_ok
 840
 841          then
 842            -- Easy; just relink it all.
 843            do liftIO $ debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 844
 845               -- Clean up after ourselves
 846               liftIO $ cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 847
 848               -- Issue a warning for the confusing case where the user
 849               -- said '-o foo' but we're not going to do any linking.
 850               -- We attempt linking if either (a) one of the modules is
 851               -- called Main, or (b) the user said -no-hs-main, indicating
 852               -- that main() is going to come from somewhere else.
 853               --
 854               let ofile = outputFile dflags
 855               let no_hs_main = dopt Opt_NoHsMain dflags
 856               let
 857                 main_mod = mainModIs dflags
 858                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 859                 do_linking = a_root_is_Main || no_hs_main
 860
 861               when (ghcLink dflags == LinkBinary
 862                     && isJust ofile && not do_linking) $
 863                 liftIO $ debugTraceMsg dflags 1 $
 864                     text ("Warning: output was redirected with -o, " ++
 865                           "but no output will be generated\n" ++
 866                           "because there is no " ++
 867                           moduleNameString (moduleName main_mod) ++ " module.")
 868
 869               -- link everything together
 870               linkresult <- liftIO $ link (ghcLink dflags) dflags do_linking (hsc_HPT hsc_env1)
 871
 872               loadFinish Succeeded linkresult hsc_env1
 873
 874          else
 875            -- Tricky.  We need to back out the effects of compiling any
 876            -- half-done cycles, both so as to clean up the top level envs
 877            -- and to avoid telling the interactive linker to link them.
 878            do liftIO $ debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 879
 880               let modsDone_names
 881                      = map ms_mod modsDone
 882               let mods_to_zap_names
 883                      = findPartiallyCompletedCycles modsDone_names
 884                           mg2_with_srcimps
 885               let mods_to_keep
 886                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 887                           modsDone
 888
 889               let hpt4 = retainInTopLevelEnvs (map ms_mod_name mods_to_keep)
 890                                               (hsc_HPT hsc_env1)
 891
 892               -- Clean up after ourselves
 893               liftIO $ cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 894
 895               -- there should be no Nothings where linkables should be, now
 896               ASSERT(all (isJust.hm_linkable)
 897                         (eltsUFM (hsc_HPT hsc_env))) do
 898
 899               -- Link everything together
 900               linkresult <- liftIO $ link (ghcLink dflags) dflags False hpt4
 901
 902               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 903               loadFinish Failed linkresult hsc_env4
 904
 905 -- Finish up after a load.
 906
 907 -- If the link failed, unload everything and return.
 908 loadFinish :: GhcMonad m =>
 909               SuccessFlag -> SuccessFlag -> HscEnv
 910            -> m SuccessFlag
 911 loadFinish _all_ok Failed hsc_env
 912   = do liftIO $ unload hsc_env []
 913        modifySession $ \_ -> discardProg hsc_env
 914        return Failed
 915
 916 -- Empty the interactive context and set the module context to the topmost
 917 -- newly loaded module, or the Prelude if none were loaded.
 918 loadFinish all_ok Succeeded hsc_env
 919   = do modifySession $ \_ -> hsc_env{ hsc_IC = emptyInteractiveContext }
 920        return all_ok
 921
 922
 923 -- Forget the current program, but retain the persistent info in HscEnv
 924 discardProg :: HscEnv -> HscEnv
 925 discardProg hsc_env
 926   = hsc_env { hsc_mod_graph = emptyMG,
 927               hsc_IC = emptyInteractiveContext,
 928               hsc_HPT = emptyHomePackageTable }
 929
 930 -- used to fish out the preprocess output files for the purposes of
 931 -- cleaning up.  The preprocessed file *might* be the same as the
 932 -- source file, but that doesn't do any harm.
 933 ppFilesFromSummaries :: [ModSummary] -> [FilePath]
 934 ppFilesFromSummaries summaries = map ms_hspp_file summaries
 935
 936 -- -----------------------------------------------------------------------------
 937
 938 class ParsedMod m where
 939   modSummary   :: m -> ModSummary
 940   parsedSource :: m -> ParsedSource
 941
 942 class ParsedMod m => TypecheckedMod m where
 943   renamedSource     :: m -> Maybe RenamedSource
 944   typecheckedSource :: m -> TypecheckedSource
 945   moduleInfo        :: m -> ModuleInfo
 946   tm_internals      :: m -> (TcGblEnv, ModDetails)
 947         -- ToDo: improvements that could be made here:
 948         --  if the module succeeded renaming but not typechecking,
 949         --  we can still get back the GlobalRdrEnv and exports, so
 950         --  perhaps the ModuleInfo should be split up into separate
 951         --  fields.
 952
 953 class TypecheckedMod m => DesugaredMod m where
 954   coreModule :: m -> ModGuts
 955
 956 -- | The result of successful parsing.
 957 data ParsedModule =
 958   ParsedModule { pm_mod_summary   :: ModSummary
 959                , pm_parsed_source :: ParsedSource }
 960
 961 instance ParsedMod ParsedModule where
 962   modSummary m    = pm_mod_summary m
 963   parsedSource m = pm_parsed_source m
 964
 965 -- | The result of successful typechecking.  It also contains the parser
 966 --   result.
 967 data TypecheckedModule =
 968   TypecheckedModule { tm_parsed_module       :: ParsedModule
 969                     , tm_renamed_source      :: Maybe RenamedSource
 970                     , tm_typechecked_source  :: TypecheckedSource
 971                     , tm_checked_module_info :: ModuleInfo
 972                     , tm_internals_          :: (TcGblEnv, ModDetails)
 973                     }
 974
 975 instance ParsedMod TypecheckedModule where
 976   modSummary m   = modSummary (tm_parsed_module m)
 977   parsedSource m = parsedSource (tm_parsed_module m)
 978
 979 instance TypecheckedMod TypecheckedModule where
 980   renamedSource m     = tm_renamed_source m
 981   typecheckedSource m = tm_typechecked_source m
 982   moduleInfo m = tm_checked_module_info m
 983   tm_internals m      = tm_internals_ m
 984
 985 -- | The result of successful desugaring (i.e., translation to core).  Also
 986 --  contains all the information of a typechecked module.
 987 data DesugaredModule =
 988   DesugaredModule { dm_typechecked_module :: TypecheckedModule
 989                   , dm_core_module        :: ModGuts
 990              }
 991
 992 instance ParsedMod DesugaredModule where
 993   modSummary m   = modSummary (dm_typechecked_module m)
 994   parsedSource m = parsedSource (dm_typechecked_module m)
 995
 996 instance TypecheckedMod DesugaredModule where
 997   renamedSource m     = renamedSource (dm_typechecked_module m)
 998   typecheckedSource m = typecheckedSource (dm_typechecked_module m)
 999   moduleInfo m        = moduleInfo (dm_typechecked_module m)
1000   tm_internals m      = tm_internals_ (dm_typechecked_module m)
1001
1002 instance DesugaredMod DesugaredModule where
1003   coreModule m = dm_core_module m
1004
1005 type ParsedSource      = Located (HsModule RdrName)
1006 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name],
1007                           Maybe (HsDoc Name), HaddockModInfo Name)
1008 type TypecheckedSource = LHsBinds Id
1009
1010 -- NOTE:
1011 --   - things that aren't in the output of the typechecker right now:
1012 --     - the export list
1013 --     - the imports
1014 --     - type signatures
1015 --     - type/data/newtype declarations
1016 --     - class declarations
1017 --     - instances
1018 --   - extra things in the typechecker's output:
1019 --     - default methods are turned into top-level decls.
1020 --     - dictionary bindings
1021
1022 -- | Return the 'ModSummary' of a module with the given name.
1023 --
1024 -- The module must be part of the module graph (see 'hsc_mod_graph' and
1025 -- 'ModuleGraph').  If this is not the case, this function will throw a
1026 -- 'GhcApiError'.
1027 --
1028 -- This function ignores boot modules and requires that there is only one
1029 -- non-boot module with the given name.
1030 getModSummary :: GhcMonad m => ModuleName -> m ModSummary
1031 getModSummary mod = do
1032    mg <- liftM hsc_mod_graph getSession
1033    case [ ms | ms <- mg, ms_mod_name ms == mod, not (isBootSummary ms) ] of
1034      [] -> throw $ mkApiErr (text "Module not part of module graph")
1035      [ms] -> return ms
1036      multiple -> throw $ mkApiErr (text "getModSummary is ambiguous: " <+> ppr multiple)
1037
1038 -- | Parse a module.
1039 --
1040 -- Throws a 'SourceError' on parse error.
1041 parseModule :: GhcMonad m => ModSummary -> m ParsedModule
1042 parseModule ms = do
1043    hsc_env0 <- getSession
1044    let hsc_env = hsc_env0 { hsc_dflags = ms_hspp_opts ms }
1045    rdr_module <- parseFile hsc_env ms
1046    return (ParsedModule ms rdr_module)
1047
1048 -- | Typecheck and rename a parsed module.
1049 --
1050 -- Throws a 'SourceError' if either fails.
1051 typecheckModule :: GhcMonad m => ParsedModule -> m TypecheckedModule
1052 typecheckModule pmod = do
1053    let ms = modSummary pmod
1054    hsc_env0 <- getSession
1055    let hsc_env = hsc_env0 { hsc_dflags = ms_hspp_opts ms }
1056    (tc_gbl_env, rn_info)
1057        <- typecheckRenameModule hsc_env ms (parsedSource pmod)
1058    details <- liftIO $ makeSimpleDetails hsc_env tc_gbl_env
1059    return $
1060      TypecheckedModule {
1061        tm_internals_          = (tc_gbl_env, details),
1062        tm_parsed_module       = pmod,
1063        tm_renamed_source      = rn_info,
1064        tm_typechecked_source  = tcg_binds tc_gbl_env,
1065        tm_checked_module_info =
1066          ModuleInfo {
1067            minf_type_env  = md_types details,
1068            minf_exports   = availsToNameSet $ md_exports details,
1069            minf_rdr_env   = Just (tcg_rdr_env tc_gbl_env),
1070            minf_instances = md_insts details
1071 #ifdef GHCI
1072            ,minf_modBreaks = emptyModBreaks
1073 #endif
1074          }}
1075
1076 -- | Desugar a typechecked module.
1077 desugarModule :: GhcMonad m => TypecheckedModule -> m DesugaredModule
1078 desugarModule tcm = do
1079    let ms = modSummary tcm
1080    hsc_env0 <- getSession
1081    let hsc_env = hsc_env0 { hsc_dflags = ms_hspp_opts ms }
1082    let (tcg, _) = tm_internals tcm
1083    guts <- deSugarModule hsc_env ms tcg
1084    return $
1085      DesugaredModule {
1086        dm_typechecked_module = tcm,
1087        dm_core_module        = guts
1088      }
1089
1090 -- | Load a module.  Input doesn't need to be desugared.
1091 --
1092 -- XXX: Describe usage.
1093 loadModule :: (TypecheckedMod mod, GhcMonad m) => mod -> m mod
1094 loadModule tcm = do
1095    let ms = modSummary tcm
1096    let mod = ms_mod_name ms
1097    hsc_env0 <- getSession
1098    let hsc_env = hsc_env0 { hsc_dflags = ms_hspp_opts ms }
1099    let (tcg, details) = tm_internals tcm
1100    (iface,_) <- liftIO $ makeSimpleIface hsc_env Nothing tcg details
1101    let mod_info = HomeModInfo {
1102                     hm_iface = iface,
1103                     hm_details = details,
1104                     hm_linkable = Nothing }
1105    let hpt_new = addToUFM (hsc_HPT hsc_env) mod mod_info
1106    modifySession $ \_ -> hsc_env0{ hsc_HPT = hpt_new }
1107    return tcm
1108
1109 -- | This is the way to get access to the Core bindings corresponding
1110 -- to a module. 'compileToCore' parses, typechecks, and
1111 -- desugars the module, then returns the resulting Core module (consisting of
1112 -- the module name, type declarations, and function declarations) if
1113 -- successful.
1114 compileToCoreModule :: GhcMonad m => FilePath -> m CoreModule
1115 compileToCoreModule = compileCore False
1116
1117 -- | Like compileToCoreModule, but invokes the simplifier, so
1118 -- as to return simplified and tidied Core.
1119 compileToCoreSimplified :: GhcMonad m => FilePath -> m CoreModule
1120 compileToCoreSimplified = compileCore True
1121 {-
1122 -- | Provided for backwards-compatibility: compileToCore returns just the Core
1123 -- bindings, but for most purposes, you probably want to call
1124 -- compileToCoreModule.
1125 compileToCore :: GhcMonad m => FilePath -> m [CoreBind]
1126 compileToCore fn = do
1127    mod <- compileToCoreModule session fn
1128    return $ cm_binds mod
1129 -}
1130 -- | Takes a CoreModule and compiles the bindings therein
1131 -- to object code. The first argument is a bool flag indicating
1132 -- whether to run the simplifier.
1133 -- The resulting .o, .hi, and executable files, if any, are stored in the
1134 -- current directory, and named according to the module name.
1135 -- Returns True iff compilation succeeded.
1136 -- This has only so far been tested with a single self-contained module.
1137 compileCoreToObj :: GhcMonad m => Bool -> CoreModule -> m ()
1138 compileCoreToObj simplify cm@(CoreModule{ cm_module = mName }) = do
1139   hscEnv      <- getSession
1140   dflags      <- getSessionDynFlags
1141   currentTime <- liftIO $ getClockTime
1142   cwd         <- liftIO $ getCurrentDirectory
1143   modLocation <- liftIO $ mkHiOnlyModLocation dflags (hiSuf dflags) cwd
1144                    ((moduleNameSlashes . moduleName) mName)
1145
1146   let modSummary = ModSummary { ms_mod = mName,
1147          ms_hsc_src = ExtCoreFile,
1148          ms_location = modLocation,
1149          -- By setting the object file timestamp to Nothing,
1150          -- we always force recompilation, which is what we
1151          -- want. (Thus it doesn't matter what the timestamp
1152          -- for the (nonexistent) source file is.)
1153          ms_hs_date = currentTime,
1154          ms_obj_date = Nothing,
1155          -- Only handling the single-module case for now, so no imports.
1156          ms_srcimps = [],
1157          ms_imps = [],
1158          -- No source file
1159          ms_hspp_file = "",
1160          ms_hspp_opts = dflags,
1161          ms_hspp_buf = Nothing
1162       }
1163
1164   ioMsgMaybe $ flip evalComp (CompState{ compHscEnv=hscEnv,
1165                                          compModSummary=modSummary,
1166                                          compOldIface=Nothing}) $
1167      let maybe_simplify mod_guts | simplify = hscSimplify mod_guts
1168                                  | otherwise = return mod_guts
1169      in maybe_simplify (mkModGuts cm)
1170           >>= hscNormalIface
1171           >>= hscWriteIface
1172           >>= hscOneShot
1173   return ()
1174
1175 -- Makes a "vanilla" ModGuts.
1176 mkModGuts :: CoreModule -> ModGuts
1177 mkModGuts coreModule = ModGuts {
1178   mg_module = cm_module coreModule,
1179   mg_boot = False,
1180   mg_exports = [],
1181   mg_deps = noDependencies,
1182   mg_dir_imps = emptyModuleEnv,
1183   mg_used_names = emptyNameSet,
1184   mg_rdr_env = emptyGlobalRdrEnv,
1185   mg_fix_env = emptyFixityEnv,
1186   mg_types = emptyTypeEnv,
1187   mg_insts = [],
1188   mg_fam_insts = [],
1189   mg_rules = [],
1190   mg_binds = cm_binds coreModule,
1191   mg_foreign = NoStubs,
1192   mg_warns = NoWarnings,
1193   mg_anns = [],
1194   mg_hpc_info = emptyHpcInfo False,
1195   mg_modBreaks = emptyModBreaks,
1196   mg_vect_info = noVectInfo,
1197   mg_inst_env = emptyInstEnv,
1198   mg_fam_inst_env = emptyFamInstEnv
1199 }
1200
1201 compileCore :: GhcMonad m => Bool -> FilePath -> m CoreModule
1202 compileCore simplify fn = do
1203    -- First, set the target to the desired filename
1204    target <- guessTarget fn Nothing
1205    addTarget target
1206    load LoadAllTargets
1207    -- Then find dependencies
1208    modGraph <- depanal [] True
1209    case find ((== fn) . msHsFilePath) modGraph of
1210      Just modSummary -> do
1211        -- Now we have the module name;
1212        -- parse, typecheck and desugar the module
1213        mod_guts <- coreModule `fmap`
1214                       (desugarModule =<< typecheckModule =<< parseModule modSummary)
1215        liftM gutsToCoreModule $
1216          if simplify
1217           then do
1218              -- If simplify is true: simplify (hscSimplify), then tidy
1219              -- (tidyProgram).
1220              hsc_env <- getSession
1221              simpl_guts <- ioMsg $ evalComp (hscSimplify mod_guts)
1222                                     (CompState{
1223                                        compHscEnv = hsc_env,
1224                                        compModSummary = modSummary,
1225                                        compOldIface = Nothing})
1226              tidy_guts <- liftIO $ tidyProgram hsc_env simpl_guts
1227              return $ Left tidy_guts
1228           else
1229              return $ Right mod_guts
1230
1231      Nothing -> panic "compileToCoreModule: target FilePath not found in\
1232                            module dependency graph"
1233   where -- two versions, based on whether we simplify (thus run tidyProgram,
1234         -- which returns a (CgGuts, ModDetails) pair, or not (in which case
1235         -- we just have a ModGuts.
1236         gutsToCoreModule :: Either (CgGuts, ModDetails) ModGuts -> CoreModule
1237         gutsToCoreModule (Left (cg, md))  = CoreModule {
1238           cm_module = cg_module cg,    cm_types = md_types md,
1239           cm_imports = cg_dir_imps cg, cm_binds = cg_binds cg
1240         }
1241         gutsToCoreModule (Right mg) = CoreModule {
1242           cm_module  = mg_module mg,                   cm_types   = mg_types mg,
1243           cm_imports = moduleEnvKeys (mg_dir_imps mg), cm_binds   = mg_binds mg
1244          }
1245
1246 -- ---------------------------------------------------------------------------
1247 -- Unloading
1248
1249 unload :: HscEnv -> [Linkable] -> IO ()
1250 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
1251   = case ghcLink (hsc_dflags hsc_env) of
1252 #ifdef GHCI
1253         LinkInMemory -> Linker.unload (hsc_dflags hsc_env) stable_linkables
1254 #else
1255         LinkInMemory -> panic "unload: no interpreter"
1256                                 -- urgh.  avoid warnings:
1257                                 hsc_env stable_linkables
1258 #endif
1259         _other -> return ()
1260
1261 -- -----------------------------------------------------------------------------
1262
1263 {- |
1264
1265   Stability tells us which modules definitely do not need to be recompiled.
1266   There are two main reasons for having stability:
1267
1268    - avoid doing a complete upsweep of the module graph in GHCi when
1269      modules near the bottom of the tree have not changed.
1270
1271    - to tell GHCi when it can load object code: we can only load object code
1272      for a module when we also load object code fo  all of the imports of the
1273      module.  So we need to know that we will definitely not be recompiling
1274      any of these modules, and we can use the object code.
1275
1276   The stability check is as follows.  Both stableObject and
1277   stableBCO are used during the upsweep phase later.
1278
1279 @
1280   stable m = stableObject m || stableBCO m
1281
1282   stableObject m =
1283         all stableObject (imports m)
1284         && old linkable does not exist, or is == on-disk .o
1285         && date(on-disk .o) > date(.hs)
1286
1287   stableBCO m =
1288         all stable (imports m)
1289         && date(BCO) > date(.hs)
1290 @
1291
1292   These properties embody the following ideas:
1293
1294     - if a module is stable, then:
1295
1296         - if it has been compiled in a previous pass (present in HPT)
1297           then it does not need to be compiled or re-linked.
1298
1299         - if it has not been compiled in a previous pass,
1300           then we only need to read its .hi file from disk and
1301           link it to produce a 'ModDetails'.
1302
1303     - if a modules is not stable, we will definitely be at least
1304       re-linking, and possibly re-compiling it during the 'upsweep'.
1305       All non-stable modules can (and should) therefore be unlinked
1306       before the 'upsweep'.
1307
1308     - Note that objects are only considered stable if they only depend
1309       on other objects.  We can't link object code against byte code.
1310 -}
1311
1312 checkStability
1313         :: HomePackageTable             -- HPT from last compilation
1314         -> [SCC ModSummary]             -- current module graph (cyclic)
1315         -> [ModuleName]                 -- all home modules
1316         -> ([ModuleName],               -- stableObject
1317             [ModuleName])               -- stableBCO
1318
1319 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
1320   where
1321    checkSCC (stable_obj, stable_bco) scc0
1322      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
1323      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
1324      | otherwise     = (stable_obj, stable_bco)
1325      where
1326         scc = flattenSCC scc0
1327         scc_mods = map ms_mod_name scc
1328         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
1329
1330         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
1331             -- all imports outside the current SCC, but in the home pkg
1332
1333         stable_obj_imps = map (`elem` stable_obj) scc_allimps
1334         stable_bco_imps = map (`elem` stable_bco) scc_allimps
1335
1336         stableObjects =
1337            and stable_obj_imps
1338            && all object_ok scc
1339
1340         stableBCOs =
1341            and (zipWith (||) stable_obj_imps stable_bco_imps)
1342            && all bco_ok scc
1343
1344         object_ok ms
1345           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
1346                                          && same_as_prev t
1347           | otherwise = False
1348           where
1349              same_as_prev t = case lookupUFM hpt (ms_mod_name ms) of
1350                                 Just hmi  | Just l <- hm_linkable hmi
1351                                  -> isObjectLinkable l && t == linkableTime l
1352                                 _other  -> True
1353                 -- why '>=' rather than '>' above?  If the filesystem stores
1354                 -- times to the nearset second, we may occasionally find that
1355                 -- the object & source have the same modification time,
1356                 -- especially if the source was automatically generated
1357                 -- and compiled.  Using >= is slightly unsafe, but it matches
1358                 -- make's behaviour.
1359
1360         bco_ok ms
1361           = case lookupUFM hpt (ms_mod_name ms) of
1362                 Just hmi  | Just l <- hm_linkable hmi ->
1363                         not (isObjectLinkable l) &&
1364                         linkableTime l >= ms_hs_date ms
1365                 _other  -> False
1366
1367 ms_allimps :: ModSummary -> [ModuleName]
1368 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
1369
1370 -- -----------------------------------------------------------------------------
1371
1372 -- | Prune the HomePackageTable
1373 --
1374 -- Before doing an upsweep, we can throw away:
1375 --
1376 --   - For non-stable modules:
1377 --      - all ModDetails, all linked code
1378 --   - all unlinked code that is out of date with respect to
1379 --     the source file
1380 --
1381 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
1382 -- space at the end of the upsweep, because the topmost ModDetails of the
1383 -- old HPT holds on to the entire type environment from the previous
1384 -- compilation.
1385
1386 pruneHomePackageTable
1387    :: HomePackageTable
1388    -> [ModSummary]
1389    -> ([ModuleName],[ModuleName])
1390    -> HomePackageTable
1391
1392 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
1393   = mapUFM prune hpt
1394   where prune hmi
1395           | is_stable modl = hmi'
1396           | otherwise      = hmi'{ hm_details = emptyModDetails }
1397           where
1398            modl = moduleName (mi_module (hm_iface hmi))
1399            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
1400                 = hmi{ hm_linkable = Nothing }
1401                 | otherwise
1402                 = hmi
1403                 where ms = expectJust "prune" (lookupUFM ms_map modl)
1404
1405         ms_map = listToUFM [(ms_mod_name ms, ms) | ms <- summ]
1406
1407         is_stable m = m `elem` stable_obj || m `elem` stable_bco
1408
1409 -- -----------------------------------------------------------------------------
1410
1411 -- Return (names of) all those in modsDone who are part of a cycle
1412 -- as defined by theGraph.
1413 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
1414 findPartiallyCompletedCycles modsDone theGraph
1415    = chew theGraph
1416      where
1417         chew [] = []
1418         chew ((AcyclicSCC _):rest) = chew rest    -- acyclic?  not interesting.
1419         chew ((CyclicSCC vs):rest)
1420            = let names_in_this_cycle = nub (map ms_mod vs)
1421                  mods_in_this_cycle
1422                     = nub ([done | done <- modsDone,
1423                                    done `elem` names_in_this_cycle])
1424                  chewed_rest = chew rest
1425              in
1426              if   notNull mods_in_this_cycle
1427                   && length mods_in_this_cycle < length names_in_this_cycle
1428              then mods_in_this_cycle ++ chewed_rest
1429              else chewed_rest
1430
1431 -- -----------------------------------------------------------------------------
1432
1433 -- | The upsweep
1434 --
1435 -- This is where we compile each module in the module graph, in a pass
1436 -- from the bottom to the top of the graph.
1437 --
1438 -- There better had not be any cyclic groups here -- we check for them.
1439
1440 upsweep
1441     :: GhcMonad m =>
1442        WarnErrLogger            -- ^ Called to print warnings and errors.
1443     -> HscEnv                   -- ^ Includes initially-empty HPT
1444     -> HomePackageTable         -- ^ HPT from last time round (pruned)
1445     -> ([ModuleName],[ModuleName]) -- ^ stable modules (see checkStability)
1446     -> IO ()                    -- ^ How to clean up unwanted tmp files
1447     -> [SCC ModSummary]         -- ^ Mods to do (the worklist)
1448     -> m (SuccessFlag,
1449          HscEnv,                -- With an updated HPT
1450          [ModSummary])  -- Mods which succeeded
1451
1452 upsweep logger hsc_env old_hpt stable_mods cleanup sccs = do
1453    (res, hsc_env, done) <- upsweep' hsc_env old_hpt [] sccs 1 (length sccs)
1454    return (res, hsc_env, reverse done)
1455  where
1456
1457   upsweep' hsc_env _old_hpt done
1458      [] _ _
1459    = return (Succeeded, hsc_env, done)
1460
1461   upsweep' hsc_env _old_hpt done
1462      (CyclicSCC ms:_) _ _
1463    = do liftIO $ fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1464         return (Failed, hsc_env, done)
1465
1466   upsweep' hsc_env old_hpt done
1467      (AcyclicSCC mod:mods) mod_index nmods
1468    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1469         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1470         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1471
1472         mb_mod_info
1473             <- handleSourceError
1474                    (\err -> do logger (Just err); return Nothing) $ do
1475                  mod_info <- upsweep_mod hsc_env old_hpt stable_mods
1476                                          mod mod_index nmods
1477                  logger Nothing -- log warnings
1478                  return (Just mod_info)
1479
1480         liftIO cleanup -- Remove unwanted tmp files between compilations
1481
1482         case mb_mod_info of
1483           Nothing -> return (Failed, hsc_env, done)
1484           Just mod_info -> do
1485                 let this_mod = ms_mod_name mod
1486
1487                         -- Add new info to hsc_env
1488                     hpt1     = addToUFM (hsc_HPT hsc_env) this_mod mod_info
1489                     hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1490
1491                         -- Space-saving: delete the old HPT entry
1492                         -- for mod BUT if mod is a hs-boot
1493                         -- node, don't delete it.  For the
1494                         -- interface, the HPT entry is probaby for the
1495                         -- main Haskell source file.  Deleting it
1496                         -- would force the real module to be recompiled
1497                         -- every time.
1498                     old_hpt1 | isBootSummary mod = old_hpt
1499                              | otherwise = delFromUFM old_hpt this_mod
1500
1501                     done' = mod:done
1502
1503                         -- fixup our HomePackageTable after we've finished compiling
1504                         -- a mutually-recursive loop.  See reTypecheckLoop, below.
1505                 hsc_env2 <- liftIO $ reTypecheckLoop hsc_env1 mod done'
1506
1507                 upsweep' hsc_env2 old_hpt1 done' mods (mod_index+1) nmods
1508
1509 -- | Compile a single module.  Always produce a Linkable for it if
1510 -- successful.  If no compilation happened, return the old Linkable.
1511 upsweep_mod :: GhcMonad m =>
1512                HscEnv
1513             -> HomePackageTable
1514             -> ([ModuleName],[ModuleName])
1515             -> ModSummary
1516             -> Int  -- index of module
1517             -> Int  -- total number of modules
1518             -> m HomeModInfo
1519
1520 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1521    =    let
1522             this_mod_name = ms_mod_name summary
1523             this_mod    = ms_mod summary
1524             mb_obj_date = ms_obj_date summary
1525             obj_fn      = ml_obj_file (ms_location summary)
1526             hs_date     = ms_hs_date summary
1527
1528             is_stable_obj = this_mod_name `elem` stable_obj
1529             is_stable_bco = this_mod_name `elem` stable_bco
1530
1531             old_hmi = lookupUFM old_hpt this_mod_name
1532
1533             -- We're using the dflags for this module now, obtained by
1534             -- applying any options in its LANGUAGE & OPTIONS_GHC pragmas.
1535             dflags = ms_hspp_opts summary
1536             prevailing_target = hscTarget (hsc_dflags hsc_env)
1537             local_target      = hscTarget dflags
1538
1539             -- If OPTIONS_GHC contains -fasm or -fvia-C, be careful that
1540             -- we don't do anything dodgy: these should only work to change
1541             -- from -fvia-C to -fasm and vice-versa, otherwise we could
1542             -- end up trying to link object code to byte code.
1543             target = if prevailing_target /= local_target
1544                         && (not (isObjectTarget prevailing_target)
1545                             || not (isObjectTarget local_target))
1546                         then prevailing_target
1547                         else local_target
1548
1549             -- store the corrected hscTarget into the summary
1550             summary' = summary{ ms_hspp_opts = dflags { hscTarget = target } }
1551
1552             -- The old interface is ok if
1553             --  a) we're compiling a source file, and the old HPT
1554             --     entry is for a source file
1555             --  b) we're compiling a hs-boot file
1556             -- Case (b) allows an hs-boot file to get the interface of its
1557             -- real source file on the second iteration of the compilation
1558             -- manager, but that does no harm.  Otherwise the hs-boot file
1559             -- will always be recompiled
1560
1561             mb_old_iface
1562                 = case old_hmi of
1563                      Nothing                              -> Nothing
1564                      Just hm_info | isBootSummary summary -> Just iface
1565                                   | not (mi_boot iface)   -> Just iface
1566                                   | otherwise             -> Nothing
1567                                    where
1568                                      iface = hm_iface hm_info
1569
1570             compile_it :: GhcMonad m => Maybe Linkable -> m HomeModInfo
1571             compile_it  = compile hsc_env summary' mod_index nmods mb_old_iface
1572
1573             compile_it_discard_iface :: GhcMonad m =>
1574                                         Maybe Linkable -> m HomeModInfo
1575             compile_it_discard_iface
1576                         = compile hsc_env summary' mod_index nmods Nothing
1577
1578         in
1579         case target of
1580
1581             _any
1582                 -- Regardless of whether we're generating object code or
1583                 -- byte code, we can always use an existing object file
1584                 -- if it is *stable* (see checkStability).
1585                 | is_stable_obj, isJust old_hmi ->
1586                         let Just hmi = old_hmi in
1587                         return hmi
1588                         -- object is stable, and we have an entry in the
1589                         -- old HPT: nothing to do
1590
1591                 | is_stable_obj, isNothing old_hmi -> do
1592                         linkable <- liftIO $ findObjectLinkable this_mod obj_fn
1593                                         (expectJust "upsweep1" mb_obj_date)
1594                         compile_it (Just linkable)
1595                         -- object is stable, but we need to load the interface
1596                         -- off disk to make a HMI.
1597
1598             HscInterpreted
1599                 | is_stable_bco ->
1600                         ASSERT(isJust old_hmi) -- must be in the old_hpt
1601                         let Just hmi = old_hmi in
1602                         return hmi
1603                         -- BCO is stable: nothing to do
1604
1605                 | Just hmi <- old_hmi,
1606                   Just l <- hm_linkable hmi, not (isObjectLinkable l),
1607                   linkableTime l >= ms_hs_date summary ->
1608                         compile_it (Just l)
1609                         -- we have an old BCO that is up to date with respect
1610                         -- to the source: do a recompilation check as normal.
1611
1612                 | otherwise ->
1613                         compile_it Nothing
1614                         -- no existing code at all: we must recompile.
1615
1616               -- When generating object code, if there's an up-to-date
1617               -- object file on the disk, then we can use it.
1618               -- However, if the object file is new (compared to any
1619               -- linkable we had from a previous compilation), then we
1620               -- must discard any in-memory interface, because this
1621               -- means the user has compiled the source file
1622               -- separately and generated a new interface, that we must
1623               -- read from the disk.
1624               --
1625             obj | isObjectTarget obj,
1626                   Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1627                      case old_hmi of
1628                         Just hmi
1629                           | Just l <- hm_linkable hmi,
1630                             isObjectLinkable l && linkableTime l == obj_date
1631                             -> compile_it (Just l)
1632                         _otherwise -> do
1633                           linkable <- liftIO $ findObjectLinkable this_mod obj_fn obj_date
1634                           compile_it_discard_iface (Just linkable)
1635
1636             _otherwise ->
1637                   compile_it Nothing
1638
1639
1640
1641 -- Filter modules in the HPT
1642 retainInTopLevelEnvs :: [ModuleName] -> HomePackageTable -> HomePackageTable
1643 retainInTopLevelEnvs keep_these hpt
1644    = listToUFM   [ (mod, expectJust "retain" mb_mod_info)
1645                  | mod <- keep_these
1646                  , let mb_mod_info = lookupUFM hpt mod
1647                  , isJust mb_mod_info ]
1648
1649 -- ---------------------------------------------------------------------------
1650 -- Typecheck module loops
1651
1652 {-
1653 See bug #930.  This code fixes a long-standing bug in --make.  The
1654 problem is that when compiling the modules *inside* a loop, a data
1655 type that is only defined at the top of the loop looks opaque; but
1656 after the loop is done, the structure of the data type becomes
1657 apparent.
1658
1659 The difficulty is then that two different bits of code have
1660 different notions of what the data type looks like.
1661
1662 The idea is that after we compile a module which also has an .hs-boot
1663 file, we re-generate the ModDetails for each of the modules that
1664 depends on the .hs-boot file, so that everyone points to the proper
1665 TyCons, Ids etc. defined by the real module, not the boot module.
1666 Fortunately re-generating a ModDetails from a ModIface is easy: the
1667 function TcIface.typecheckIface does exactly that.
1668
1669 Picking the modules to re-typecheck is slightly tricky.  Starting from
1670 the module graph consisting of the modules that have already been
1671 compiled, we reverse the edges (so they point from the imported module
1672 to the importing module), and depth-first-search from the .hs-boot
1673 node.  This gives us all the modules that depend transitively on the
1674 .hs-boot module, and those are exactly the modules that we need to
1675 re-typecheck.
1676
1677 Following this fix, GHC can compile itself with --make -O2.
1678 -}
1679
1680 reTypecheckLoop :: HscEnv -> ModSummary -> ModuleGraph -> IO HscEnv
1681 reTypecheckLoop hsc_env ms graph
1682   | not (isBootSummary ms) &&
1683     any (\m -> ms_mod m == this_mod && isBootSummary m) graph
1684   = do
1685         let mss = reachableBackwards (ms_mod_name ms) graph
1686             non_boot = filter (not.isBootSummary) mss
1687         debugTraceMsg (hsc_dflags hsc_env) 2 $
1688            text "Re-typechecking loop: " <> ppr (map ms_mod_name non_boot)
1689         typecheckLoop hsc_env (map ms_mod_name non_boot)
1690   | otherwise
1691   = return hsc_env
1692  where
1693   this_mod = ms_mod ms
1694
1695 typecheckLoop :: HscEnv -> [ModuleName] -> IO HscEnv
1696 typecheckLoop hsc_env mods = do
1697   new_hpt <-
1698     fixIO $ \new_hpt -> do
1699       let new_hsc_env = hsc_env{ hsc_HPT = new_hpt }
1700       mds <- initIfaceCheck new_hsc_env $
1701                 mapM (typecheckIface . hm_iface) hmis
1702       let new_hpt = addListToUFM old_hpt
1703                         (zip mods [ hmi{ hm_details = details }
1704                                   | (hmi,details) <- zip hmis mds ])
1705       return new_hpt
1706   return hsc_env{ hsc_HPT = new_hpt }
1707   where
1708     old_hpt = hsc_HPT hsc_env
1709     hmis    = map (expectJust "typecheckLoop" . lookupUFM old_hpt) mods
1710
1711 reachableBackwards :: ModuleName -> [ModSummary] -> [ModSummary]
1712 reachableBackwards mod summaries
1713   = [ ms | (ms,_,_) <- reachableG (transposeG graph) root ]
1714   where -- the rest just sets up the graph:
1715         (graph, lookup_node) = moduleGraphNodes False summaries
1716         root  = expectJust "reachableBackwards" (lookup_node HsBootFile mod)
1717
1718 -- ---------------------------------------------------------------------------
1719 -- Topological sort of the module graph
1720
1721 type SummaryNode = (ModSummary, Int, [Int])
1722
1723 topSortModuleGraph
1724           :: Bool
1725           -- ^ Drop hi-boot nodes? (see below)
1726           -> [ModSummary]
1727           -> Maybe ModuleName
1728           -> [SCC ModSummary]
1729 -- ^ Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1730 -- The resulting list of strongly-connected-components is in topologically
1731 -- sorted order, starting with the module(s) at the bottom of the
1732 -- dependency graph (ie compile them first) and ending with the ones at
1733 -- the top.
1734 --
1735 -- Drop hi-boot nodes (first boolean arg)?
1736 --
1737 -- - @False@:   treat the hi-boot summaries as nodes of the graph,
1738 --              so the graph must be acyclic
1739 --
1740 -- - @True@:    eliminate the hi-boot nodes, and instead pretend
1741 --              the a source-import of Foo is an import of Foo
1742 --              The resulting graph has no hi-boot nodes, but can be cyclic
1743
1744 topSortModuleGraph drop_hs_boot_nodes summaries mb_root_mod
1745   = map (fmap summaryNodeSummary) $ stronglyConnCompG initial_graph
1746   where
1747     (graph, lookup_node) = moduleGraphNodes drop_hs_boot_nodes summaries
1748
1749     initial_graph = case mb_root_mod of
1750         Nothing -> graph
1751         Just root_mod ->
1752             -- restrict the graph to just those modules reachable from
1753             -- the specified module.  We do this by building a graph with
1754             -- the full set of nodes, and determining the reachable set from
1755             -- the specified node.
1756             let root | Just node <- lookup_node HsSrcFile root_mod, graph `hasVertexG` node = node
1757                      | otherwise = ghcError (ProgramError "module does not exist")
1758             in graphFromEdgedVertices (seq root (reachableG graph root))
1759
1760 summaryNodeKey :: SummaryNode -> Int
1761 summaryNodeKey (_, k, _) = k
1762
1763 summaryNodeSummary :: SummaryNode -> ModSummary
1764 summaryNodeSummary (s, _, _) = s
1765
1766 moduleGraphNodes :: Bool -> [ModSummary]
1767   -> (Graph SummaryNode, HscSource -> ModuleName -> Maybe SummaryNode)
1768 moduleGraphNodes drop_hs_boot_nodes summaries = (graphFromEdgedVertices nodes, lookup_node)
1769   where
1770     numbered_summaries = zip summaries [1..]
1771
1772     lookup_node :: HscSource -> ModuleName -> Maybe SummaryNode
1773     lookup_node hs_src mod = lookupFM node_map (mod, hs_src)
1774
1775     lookup_key :: HscSource -> ModuleName -> Maybe Int
1776     lookup_key hs_src mod = fmap summaryNodeKey (lookup_node hs_src mod)
1777
1778     node_map :: NodeMap SummaryNode
1779     node_map = listToFM [ ((moduleName (ms_mod s), ms_hsc_src s), node)
1780                         | node@(s, _, _) <- nodes ]
1781
1782     -- We use integers as the keys for the SCC algorithm
1783     nodes :: [SummaryNode]
1784     nodes = [ (s, key, out_keys)
1785             | (s, key) <- numbered_summaries
1786              -- Drop the hi-boot ones if told to do so
1787             , not (isBootSummary s && drop_hs_boot_nodes)
1788             , let out_keys = out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1789                              out_edge_keys HsSrcFile   (map unLoc (ms_imps s)) ++
1790                              (-- see [boot-edges] below
1791                               if drop_hs_boot_nodes || ms_hsc_src s == HsBootFile
1792                               then []
1793                               else case lookup_key HsBootFile (ms_mod_name s) of
1794                                     Nothing -> []
1795                                     Just k  -> [k]) ]
1796
1797     -- [boot-edges] if this is a .hs and there is an equivalent
1798     -- .hs-boot, add a link from the former to the latter.  This
1799     -- has the effect of detecting bogus cases where the .hs-boot
1800     -- depends on the .hs, by introducing a cycle.  Additionally,
1801     -- it ensures that we will always process the .hs-boot before
1802     -- the .hs, and so the HomePackageTable will always have the
1803     -- most up to date information.
1804
1805     -- Drop hs-boot nodes by using HsSrcFile as the key
1806     hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1807                 | otherwise          = HsBootFile
1808
1809     out_edge_keys :: HscSource -> [ModuleName] -> [Int]
1810     out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1811         -- If we want keep_hi_boot_nodes, then we do lookup_key with
1812         -- the IsBootInterface parameter True; else False
1813
1814
1815 type NodeKey   = (ModuleName, HscSource)  -- The nodes of the graph are
1816 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1817
1818 msKey :: ModSummary -> NodeKey
1819 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (moduleName mod,boot)
1820
1821 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1822 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1823
1824 nodeMapElts :: NodeMap a -> [a]
1825 nodeMapElts = eltsFM
1826
1827 -- | If there are {-# SOURCE #-} imports between strongly connected
1828 -- components in the topological sort, then those imports can
1829 -- definitely be replaced by ordinary non-SOURCE imports: if SOURCE
1830 -- were necessary, then the edge would be part of a cycle.
1831 warnUnnecessarySourceImports :: GhcMonad m => DynFlags -> [SCC ModSummary] -> m ()
1832 warnUnnecessarySourceImports dflags sccs =
1833   liftIO $ printBagOfWarnings dflags (listToBag (concatMap (check.flattenSCC) sccs))
1834   where check ms =
1835            let mods_in_this_cycle = map ms_mod_name ms in
1836            [ warn i | m <- ms, i <- ms_srcimps m,
1837                         unLoc i `notElem`  mods_in_this_cycle ]
1838
1839         warn :: Located ModuleName -> WarnMsg
1840         warn (L loc mod) =
1841            mkPlainErrMsg loc
1842                 (ptext (sLit "Warning: {-# SOURCE #-} unnecessary in import of ")
1843                  <+> quotes (ppr mod))
1844
1845 -----------------------------------------------------------------------------
1846 -- Downsweep (dependency analysis)
1847
1848 -- Chase downwards from the specified root set, returning summaries
1849 -- for all home modules encountered.  Only follow source-import
1850 -- links.
1851
1852 -- We pass in the previous collection of summaries, which is used as a
1853 -- cache to avoid recalculating a module summary if the source is
1854 -- unchanged.
1855 --
1856 -- The returned list of [ModSummary] nodes has one node for each home-package
1857 -- module, plus one for any hs-boot files.  The imports of these nodes
1858 -- are all there, including the imports of non-home-package modules.
1859
1860 downsweep :: GhcMonad m =>
1861              HscEnv
1862           -> [ModSummary]       -- Old summaries
1863           -> [ModuleName]       -- Ignore dependencies on these; treat
1864                                 -- them as if they were package modules
1865           -> Bool               -- True <=> allow multiple targets to have
1866                                 --          the same module name; this is
1867                                 --          very useful for ghc -M
1868           -> m [ModSummary]
1869                 -- The elts of [ModSummary] all have distinct
1870                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1871                 -- in which case there can be repeats
1872 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1873    = do -- catch error messages and return them
1874      --handleErrMsg   -- should be covered by GhcMonad now
1875      --          (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1876        rootSummaries <- mapM getRootSummary roots
1877        let root_map = mkRootMap rootSummaries
1878        checkDuplicates root_map
1879        summs <- loop (concatMap msDeps rootSummaries) root_map
1880        return summs
1881      where
1882         roots = hsc_targets hsc_env
1883
1884         old_summary_map :: NodeMap ModSummary
1885         old_summary_map = mkNodeMap old_summaries
1886
1887         getRootSummary :: GhcMonad m => Target -> m ModSummary
1888         getRootSummary (Target (TargetFile file mb_phase) obj_allowed maybe_buf)
1889            = do exists <- liftIO $ doesFileExist file
1890                 if exists
1891                     then summariseFile hsc_env old_summaries file mb_phase
1892                                        obj_allowed maybe_buf
1893                     else throwOneError $ mkPlainErrMsg noSrcSpan $
1894                            text "can't find file:" <+> text file
1895         getRootSummary (Target (TargetModule modl) obj_allowed maybe_buf)
1896            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1897                                            (L rootLoc modl) obj_allowed
1898                                            maybe_buf excl_mods
1899                 case maybe_summary of
1900                    Nothing -> packageModErr modl
1901                    Just s  -> return s
1902
1903         rootLoc = mkGeneralSrcSpan (fsLit "<command line>")
1904
1905         -- In a root module, the filename is allowed to diverge from the module
1906         -- name, so we have to check that there aren't multiple root files
1907         -- defining the same module (otherwise the duplicates will be silently
1908         -- ignored, leading to confusing behaviour).
1909         checkDuplicates :: GhcMonad m => NodeMap [ModSummary] -> m ()
1910         checkDuplicates root_map
1911            | allow_dup_roots = return ()
1912            | null dup_roots  = return ()
1913            | otherwise       = liftIO $ multiRootsErr (head dup_roots)
1914            where
1915              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1916              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1917
1918         loop :: GhcMonad m =>
1919                 [(Located ModuleName,IsBootInterface)]
1920                         -- Work list: process these modules
1921              -> NodeMap [ModSummary]
1922                         -- Visited set; the range is a list because
1923                         -- the roots can have the same module names
1924                         -- if allow_dup_roots is True
1925              -> m [ModSummary]
1926                         -- The result includes the worklist, except
1927                         -- for those mentioned in the visited set
1928         loop [] done      = return (concat (nodeMapElts done))
1929         loop ((wanted_mod, is_boot) : ss) done
1930           | Just summs <- lookupFM done key
1931           = if isSingleton summs then
1932                 loop ss done
1933             else
1934                 do { liftIO $ multiRootsErr summs; return [] }
1935           | otherwise
1936           = do mb_s <- summariseModule hsc_env old_summary_map
1937                                        is_boot wanted_mod True
1938                                        Nothing excl_mods
1939                case mb_s of
1940                    Nothing -> loop ss done
1941                    Just s  -> loop (msDeps s ++ ss) (addToFM done key [s])
1942           where
1943             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1944
1945 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1946 mkRootMap summaries = addListToFM_C (++) emptyFM
1947                         [ (msKey s, [s]) | s <- summaries ]
1948
1949 msDeps :: ModSummary -> [(Located ModuleName, IsBootInterface)]
1950 -- (msDeps s) returns the dependencies of the ModSummary s.
1951 -- A wrinkle is that for a {-# SOURCE #-} import we return
1952 --      *both* the hs-boot file
1953 --      *and* the source file
1954 -- as "dependencies".  That ensures that the list of all relevant
1955 -- modules always contains B.hs if it contains B.hs-boot.
1956 -- Remember, this pass isn't doing the topological sort.  It's
1957 -- just gathering the list of all relevant ModSummaries
1958 msDeps s =
1959     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1960          ++ [ (m,False) | m <- ms_imps s ]
1961
1962 -----------------------------------------------------------------------------
1963 -- Summarising modules
1964
1965 -- We have two types of summarisation:
1966 --
1967 --    * Summarise a file.  This is used for the root module(s) passed to
1968 --      cmLoadModules.  The file is read, and used to determine the root
1969 --      module name.  The module name may differ from the filename.
1970 --
1971 --    * Summarise a module.  We are given a module name, and must provide
1972 --      a summary.  The finder is used to locate the file in which the module
1973 --      resides.
1974
1975 summariseFile
1976         :: GhcMonad m =>
1977            HscEnv
1978         -> [ModSummary]                 -- old summaries
1979         -> FilePath                     -- source file name
1980         -> Maybe Phase                  -- start phase
1981         -> Bool                         -- object code allowed?
1982         -> Maybe (StringBuffer,ClockTime)
1983         -> m ModSummary
1984
1985 summariseFile hsc_env old_summaries file mb_phase obj_allowed maybe_buf
1986         -- we can use a cached summary if one is available and the
1987         -- source file hasn't changed,  But we have to look up the summary
1988         -- by source file, rather than module name as we do in summarise.
1989    | Just old_summary <- findSummaryBySourceFile old_summaries file
1990    = do
1991         let location = ms_location old_summary
1992
1993                 -- return the cached summary if the source didn't change
1994         src_timestamp <- case maybe_buf of
1995                            Just (_,t) -> return t
1996                            Nothing    -> liftIO $ getModificationTime file
1997                 -- The file exists; we checked in getRootSummary above.
1998                 -- If it gets removed subsequently, then this
1999                 -- getModificationTime may fail, but that's the right
2000                 -- behaviour.
2001
2002         if ms_hs_date old_summary == src_timestamp
2003            then do -- update the object-file timestamp
2004                   obj_timestamp <-
2005                     if isObjectTarget (hscTarget (hsc_dflags hsc_env))
2006                         || obj_allowed -- bug #1205
2007                         then liftIO $ getObjTimestamp location False
2008                         else return Nothing
2009                   return old_summary{ ms_obj_date = obj_timestamp }
2010            else
2011                 new_summary
2012
2013    | otherwise
2014    = new_summary
2015   where
2016     new_summary = do
2017         let dflags = hsc_dflags hsc_env
2018
2019         (dflags', hspp_fn, buf)
2020             <- preprocessFile hsc_env file mb_phase maybe_buf
2021
2022         (srcimps,the_imps, L _ mod_name) <- liftIO $ getImports dflags' buf hspp_fn file
2023
2024         -- Make a ModLocation for this file
2025         location <- liftIO $ mkHomeModLocation dflags mod_name file
2026
2027         -- Tell the Finder cache where it is, so that subsequent calls
2028         -- to findModule will find it, even if it's not on any search path
2029         mod <- liftIO $ addHomeModuleToFinder hsc_env mod_name location
2030
2031         src_timestamp <- case maybe_buf of
2032                            Just (_,t) -> return t
2033                            Nothing    -> liftIO $ getModificationTime file
2034                         -- getMofificationTime may fail
2035
2036         -- when the user asks to load a source file by name, we only
2037         -- use an object file if -fobject-code is on.  See #1205.
2038         obj_timestamp <-
2039             if isObjectTarget (hscTarget (hsc_dflags hsc_env))
2040                || obj_allowed -- bug #1205
2041                 then liftIO $ modificationTimeIfExists (ml_obj_file location)
2042                 else return Nothing
2043
2044         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
2045                              ms_location = location,
2046                              ms_hspp_file = hspp_fn,
2047                              ms_hspp_opts = dflags',
2048                              ms_hspp_buf  = Just buf,
2049                              ms_srcimps = srcimps, ms_imps = the_imps,
2050                              ms_hs_date = src_timestamp,
2051                              ms_obj_date = obj_timestamp })
2052
2053 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
2054 findSummaryBySourceFile summaries file
2055   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
2056                                  expectJust "findSummaryBySourceFile" (ml_hs_file (ms_location ms)) == file ] of
2057         [] -> Nothing
2058         (x:_) -> Just x
2059
2060 -- Summarise a module, and pick up source and timestamp.
2061 summariseModule
2062           :: GhcMonad m =>
2063              HscEnv
2064           -> NodeMap ModSummary -- Map of old summaries
2065           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
2066           -> Located ModuleName -- Imported module to be summarised
2067           -> Bool               -- object code allowed?
2068           -> Maybe (StringBuffer, ClockTime)
2069           -> [ModuleName]               -- Modules to exclude
2070           -> m (Maybe ModSummary)       -- Its new summary
2071
2072 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod)
2073                 obj_allowed maybe_buf excl_mods
2074   | wanted_mod `elem` excl_mods
2075   = return Nothing
2076
2077   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
2078   = do          -- Find its new timestamp; all the
2079                 -- ModSummaries in the old map have valid ml_hs_files
2080         let location = ms_location old_summary
2081             src_fn = expectJust "summariseModule" (ml_hs_file location)
2082
2083                 -- check the modification time on the source file, and
2084                 -- return the cached summary if it hasn't changed.  If the
2085                 -- file has disappeared, we need to call the Finder again.
2086         case maybe_buf of
2087            Just (_,t) -> check_timestamp old_summary location src_fn t
2088            Nothing    -> do
2089                 m <- liftIO $ System.IO.Error.try (getModificationTime src_fn)
2090                 case m of
2091                    Right t -> check_timestamp old_summary location src_fn t
2092                    Left e | isDoesNotExistError e -> find_it
2093                           | otherwise             -> liftIO $ ioError e
2094
2095   | otherwise  = find_it
2096   where
2097     dflags = hsc_dflags hsc_env
2098
2099     hsc_src = if is_boot then HsBootFile else HsSrcFile
2100
2101     check_timestamp old_summary location src_fn src_timestamp
2102         | ms_hs_date old_summary == src_timestamp = do
2103                 -- update the object-file timestamp
2104                 obj_timestamp <- liftIO $
2105                     if isObjectTarget (hscTarget (hsc_dflags hsc_env))
2106                        || obj_allowed -- bug #1205
2107                        then getObjTimestamp location is_boot
2108                        else return Nothing
2109                 return (Just old_summary{ ms_obj_date = obj_timestamp })
2110         | otherwise =
2111                 -- source changed: re-summarise.
2112                 new_summary location (ms_mod old_summary) src_fn src_timestamp
2113
2114     find_it = do
2115         -- Don't use the Finder's cache this time.  If the module was
2116         -- previously a package module, it may have now appeared on the
2117         -- search path, so we want to consider it to be a home module.  If
2118         -- the module was previously a home module, it may have moved.
2119         liftIO $ uncacheModule hsc_env wanted_mod
2120         found <- liftIO $ findImportedModule hsc_env wanted_mod Nothing
2121         case found of
2122              Found location mod
2123                 | isJust (ml_hs_file location) ->
2124                         -- Home package
2125                          just_found location mod
2126                 | otherwise ->
2127                         -- Drop external-pkg
2128                         ASSERT(modulePackageId mod /= thisPackage dflags)
2129                         return Nothing
2130
2131              err -> liftIO $ noModError dflags loc wanted_mod err
2132                         -- Not found
2133
2134     just_found location mod = do
2135                 -- Adjust location to point to the hs-boot source file,
2136                 -- hi file, object file, when is_boot says so
2137         let location' | is_boot   = addBootSuffixLocn location
2138                       | otherwise = location
2139             src_fn = expectJust "summarise2" (ml_hs_file location')
2140
2141                 -- Check that it exists
2142                 -- It might have been deleted since the Finder last found it
2143         maybe_t <- liftIO $ modificationTimeIfExists src_fn
2144         case maybe_t of
2145           Nothing -> noHsFileErr loc src_fn
2146           Just t  -> new_summary location' mod src_fn t
2147
2148
2149     new_summary location mod src_fn src_timestamp
2150       = do
2151         -- Preprocess the source file and get its imports
2152         -- The dflags' contains the OPTIONS pragmas
2153         (dflags', hspp_fn, buf) <- preprocessFile hsc_env src_fn Nothing maybe_buf
2154         (srcimps, the_imps, L mod_loc mod_name) <- liftIO $ getImports dflags' buf hspp_fn src_fn
2155
2156         when (mod_name /= wanted_mod) $
2157                 throwOneError $ mkPlainErrMsg mod_loc $
2158                               text "File name does not match module name:"
2159                               $$ text "Saw:" <+> quotes (ppr mod_name)
2160                               $$ text "Expected:" <+> quotes (ppr wanted_mod)
2161
2162                 -- Find the object timestamp, and return the summary
2163         obj_timestamp <- liftIO $
2164            if isObjectTarget (hscTarget (hsc_dflags hsc_env))
2165               || obj_allowed -- bug #1205
2166               then getObjTimestamp location is_boot
2167               else return Nothing
2168
2169         return (Just (ModSummary { ms_mod       = mod,
2170                               ms_hsc_src   = hsc_src,
2171                               ms_location  = location,
2172                               ms_hspp_file = hspp_fn,
2173                               ms_hspp_opts = dflags',
2174                               ms_hspp_buf  = Just buf,
2175                               ms_srcimps   = srcimps,
2176                               ms_imps      = the_imps,
2177                               ms_hs_date   = src_timestamp,
2178                               ms_obj_date  = obj_timestamp }))
2179
2180
2181 getObjTimestamp :: ModLocation -> Bool -> IO (Maybe ClockTime)
2182 getObjTimestamp location is_boot
2183   = if is_boot then return Nothing
2184                else modificationTimeIfExists (ml_obj_file location)
2185
2186
2187 preprocessFile :: GhcMonad m =>
2188                   HscEnv
2189                -> FilePath
2190                -> Maybe Phase -- ^ Starting phase
2191                -> Maybe (StringBuffer,ClockTime)
2192                -> m (DynFlags, FilePath, StringBuffer)
2193 preprocessFile hsc_env src_fn mb_phase Nothing
2194   = do
2195         (dflags', hspp_fn) <- preprocess hsc_env (src_fn, mb_phase)
2196         buf <- liftIO $ hGetStringBuffer hspp_fn
2197         return (dflags', hspp_fn, buf)
2198
2199 preprocessFile hsc_env src_fn mb_phase (Just (buf, _time))
2200   = do
2201         let dflags = hsc_dflags hsc_env
2202         -- case we bypass the preprocessing stage?
2203         let
2204             local_opts = getOptions dflags buf src_fn
2205         --
2206         (dflags', leftovers, warns)
2207             <- parseDynamicNoPackageFlags dflags local_opts
2208         liftIO $ checkProcessArgsResult leftovers -- XXX: throws exceptions
2209         liftIO $ handleFlagWarnings dflags' warns -- XXX: throws exceptions
2210
2211         let
2212             needs_preprocessing
2213                 | Just (Unlit _) <- mb_phase    = True
2214                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
2215                   -- note: local_opts is only required if there's no Unlit phase
2216                 | dopt Opt_Cpp dflags'          = True
2217                 | dopt Opt_Pp  dflags'          = True
2218                 | otherwise                     = False
2219
2220         when needs_preprocessing $
2221            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
2222
2223         return (dflags', src_fn, buf)
2224
2225
2226 -----------------------------------------------------------------------------
2227 --                      Error messages
2228 -----------------------------------------------------------------------------
2229
2230 noModError :: DynFlags -> SrcSpan -> ModuleName -> FindResult -> IO ab
2231 -- ToDo: we don't have a proper line number for this error
2232 noModError dflags loc wanted_mod err
2233   = throwOneError $ mkPlainErrMsg loc $ cannotFindModule dflags wanted_mod err
2234
2235 noHsFileErr :: GhcMonad m => SrcSpan -> String -> m a
2236 noHsFileErr loc path
2237   = throwOneError $ mkPlainErrMsg loc $ text "Can't find" <+> text path
2238
2239 packageModErr :: GhcMonad m => ModuleName -> m a
2240 packageModErr mod
2241   = throwOneError $ mkPlainErrMsg noSrcSpan $
2242         text "module" <+> quotes (ppr mod) <+> text "is a package module"
2243
2244 multiRootsErr :: [ModSummary] -> IO ()
2245 multiRootsErr [] = panic "multiRootsErr"
2246 multiRootsErr summs@(summ1:_)
2247   = throwOneError $ mkPlainErrMsg noSrcSpan $
2248         text "module" <+> quotes (ppr mod) <+>
2249         text "is defined in multiple files:" <+>
2250         sep (map text files)
2251   where
2252     mod = ms_mod summ1
2253     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
2254
2255 cyclicModuleErr :: [ModSummary] -> SDoc
2256 cyclicModuleErr ms
2257   = hang (ptext (sLit "Module imports form a cycle for modules:"))
2258        2 (vcat (map show_one ms))
2259   where
2260     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
2261                         nest 2 $ ptext (sLit "imports:") <+>
2262                                    (pp_imps HsBootFile (ms_srcimps ms)
2263                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
2264     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
2265     pp_imps src mods = fsep (map (show_mod src) mods)
2266
2267
2268 -- | Inform GHC that the working directory has changed.  GHC will flush
2269 -- its cache of module locations, since it may no longer be valid.
2270 -- Note: if you change the working directory, you should also unload
2271 -- the current program (set targets to empty, followed by load).
2272 workingDirectoryChanged :: GhcMonad m => m ()
2273 workingDirectoryChanged = withSession $ (liftIO . flushFinderCaches)
2274
2275 -- -----------------------------------------------------------------------------
2276 -- inspecting the session
2277
2278 -- | Get the module dependency graph.
2279 getModuleGraph :: GhcMonad m => m ModuleGraph -- ToDo: DiGraph ModSummary
2280 getModuleGraph = liftM hsc_mod_graph getSession
2281
2282 -- | Return @True@ <==> module is loaded.
2283 isLoaded :: GhcMonad m => ModuleName -> m Bool
2284 isLoaded m = withSession $ \hsc_env ->
2285   return $! isJust (lookupUFM (hsc_HPT hsc_env) m)
2286
2287 -- | Return the bindings for the current interactive session.
2288 getBindings :: GhcMonad m => m [TyThing]
2289 getBindings = withSession $ \hsc_env ->
2290    -- we have to implement the shadowing behaviour of ic_tmp_ids here
2291    -- (see InteractiveContext) and the quickest way is to use an OccEnv.
2292    let
2293        tmp_ids = ic_tmp_ids (hsc_IC hsc_env)
2294        filtered = foldr f (const []) tmp_ids emptyUniqSet
2295        f id rest set
2296            | uniq `elementOfUniqSet` set = rest set
2297            | otherwise  = AnId id : rest (addOneToUniqSet set uniq)
2298            where uniq = getUnique (nameOccName (idName id))
2299    in
2300    return filtered
2301
2302 getPrintUnqual :: GhcMonad m => m PrintUnqualified
2303 getPrintUnqual = withSession $ \hsc_env ->
2304   return (icPrintUnqual (hsc_dflags hsc_env) (hsc_IC hsc_env))
2305
2306 -- | Container for information about a 'Module'.
2307 data ModuleInfo = ModuleInfo {
2308         minf_type_env  :: TypeEnv,
2309         minf_exports   :: NameSet, -- ToDo, [AvailInfo] like ModDetails?
2310         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
2311         minf_instances :: [Instance]
2312 #ifdef GHCI
2313         ,minf_modBreaks :: ModBreaks
2314 #endif
2315         -- ToDo: this should really contain the ModIface too
2316   }
2317         -- We don't want HomeModInfo here, because a ModuleInfo applies
2318         -- to package modules too.
2319
2320 -- | Request information about a loaded 'Module'
2321 getModuleInfo :: GhcMonad m => Module -> m (Maybe ModuleInfo)  -- XXX: Maybe X
2322 getModuleInfo mdl = withSession $ \hsc_env -> do
2323   let mg = hsc_mod_graph hsc_env
2324   if mdl `elem` map ms_mod mg
2325         then liftIO $ getHomeModuleInfo hsc_env (moduleName mdl)
2326         else do
2327   {- if isHomeModule (hsc_dflags hsc_env) mdl
2328         then return Nothing
2329         else -} liftIO $ getPackageModuleInfo hsc_env mdl
2330    -- getPackageModuleInfo will attempt to find the interface, so
2331    -- we don't want to call it for a home module, just in case there
2332    -- was a problem loading the module and the interface doesn't
2333    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
2334
2335 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
2336 #ifdef GHCI
2337 getPackageModuleInfo hsc_env mdl = do
2338   (_msgs, mb_avails) <- getModuleExports hsc_env mdl
2339   case mb_avails of
2340     Nothing -> return Nothing
2341     Just avails -> do
2342         eps <- readIORef (hsc_EPS hsc_env)
2343         let
2344             names  = availsToNameSet avails
2345             pte    = eps_PTE eps
2346             tys    = [ ty | name <- concatMap availNames avails,
2347                             Just ty <- [lookupTypeEnv pte name] ]
2348         --
2349         return (Just (ModuleInfo {
2350                         minf_type_env  = mkTypeEnv tys,
2351                         minf_exports   = names,
2352                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names (moduleName mdl),
2353                         minf_instances = error "getModuleInfo: instances for package module unimplemented",
2354                         minf_modBreaks = emptyModBreaks
2355                 }))
2356 #else
2357 getPackageModuleInfo _hsc_env _mdl = do
2358   -- bogusly different for non-GHCI (ToDo)
2359   return Nothing
2360 #endif
2361
2362 getHomeModuleInfo :: HscEnv -> ModuleName -> IO (Maybe ModuleInfo)
2363 getHomeModuleInfo hsc_env mdl =
2364   case lookupUFM (hsc_HPT hsc_env) mdl of
2365     Nothing  -> return Nothing
2366     Just hmi -> do
2367       let details = hm_details hmi
2368       return (Just (ModuleInfo {
2369                         minf_type_env  = md_types details,
2370                         minf_exports   = availsToNameSet (md_exports details),
2371                         minf_rdr_env   = mi_globals $! hm_iface hmi,
2372                         minf_instances = md_insts details
2373 #ifdef GHCI
2374                        ,minf_modBreaks = getModBreaks hmi
2375 #endif
2376                         }))
2377
2378 -- | The list of top-level entities defined in a module
2379 modInfoTyThings :: ModuleInfo -> [TyThing]
2380 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
2381
2382 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
2383 modInfoTopLevelScope minf
2384   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
2385
2386 modInfoExports :: ModuleInfo -> [Name]
2387 modInfoExports minf = nameSetToList $! minf_exports minf
2388
2389 -- | Returns the instances defined by the specified module.
2390 -- Warning: currently unimplemented for package modules.
2391 modInfoInstances :: ModuleInfo -> [Instance]
2392 modInfoInstances = minf_instances
2393
2394 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
2395 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
2396
2397 mkPrintUnqualifiedForModule :: GhcMonad m =>
2398                                ModuleInfo
2399                             -> m (Maybe PrintUnqualified) -- XXX: returns a Maybe X
2400 mkPrintUnqualifiedForModule minf = withSession $ \hsc_env -> do
2401   return (fmap (mkPrintUnqualified (hsc_dflags hsc_env)) (minf_rdr_env minf))
2402
2403 modInfoLookupName :: GhcMonad m =>
2404                      ModuleInfo -> Name
2405                   -> m (Maybe TyThing) -- XXX: returns a Maybe X
2406 modInfoLookupName minf name = withSession $ \hsc_env -> do
2407    case lookupTypeEnv (minf_type_env minf) name of
2408      Just tyThing -> return (Just tyThing)
2409      Nothing      -> do
2410        eps <- liftIO $ readIORef (hsc_EPS hsc_env)
2411        return $! lookupType (hsc_dflags hsc_env)
2412                             (hsc_HPT hsc_env) (eps_PTE eps) name
2413
2414 #ifdef GHCI
2415 modInfoModBreaks :: ModuleInfo -> ModBreaks
2416 modInfoModBreaks = minf_modBreaks
2417 #endif
2418
2419 isDictonaryId :: Id -> Bool
2420 isDictonaryId id
2421   = case tcSplitSigmaTy (idType id) of { (_tvs, _theta, tau) -> isDictTy tau }
2422
2423 -- | Looks up a global name: that is, any top-level name in any
2424 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
2425 -- the interactive context, and therefore does not require a preceding
2426 -- 'setContext'.
2427 lookupGlobalName :: GhcMonad m => Name -> m (Maybe TyThing)
2428 lookupGlobalName name = withSession $ \hsc_env -> do
2429    liftIO $ lookupTypeHscEnv hsc_env name
2430
2431 findGlobalAnns :: (GhcMonad m, Typeable a) => ([Word8] -> a) -> AnnTarget Name -> m [a]
2432 findGlobalAnns deserialize target = withSession $ \hsc_env -> do
2433     ann_env <- liftIO $ prepareAnnotations hsc_env Nothing
2434     return (findAnns deserialize ann_env target)
2435
2436 #ifdef GHCI
2437 -- | get the GlobalRdrEnv for a session
2438 getGRE :: GhcMonad m => m GlobalRdrEnv
2439 getGRE = withSession $ \hsc_env-> return $ ic_rn_gbl_env (hsc_IC hsc_env)
2440 #endif
2441
2442 -- -----------------------------------------------------------------------------
2443
2444 -- | Return all /external/ modules available in the package database.
2445 -- Modules from the current session (i.e., from the 'HomePackageTable') are
2446 -- not included.
2447 packageDbModules :: GhcMonad m =>
2448                     Bool  -- ^ Only consider exposed packages.
2449                  -> m [Module]
2450 packageDbModules only_exposed = do
2451    dflags <- getSessionDynFlags
2452    let pkgs = UFM.eltsUFM (pkgIdMap (pkgState dflags))
2453    return $
2454      [ mkModule pid modname | p <- pkgs
2455                             , not only_exposed || exposed p
2456                             , pid <- [mkPackageId (package p)]
2457                             , modname <- exposedModules p ]
2458
2459 -- -----------------------------------------------------------------------------
2460 -- Misc exported utils
2461
2462 dataConType :: DataCon -> Type
2463 dataConType dc = idType (dataConWrapId dc)
2464
2465 -- | print a 'NamedThing', adding parentheses if the name is an operator.
2466 pprParenSymName :: NamedThing a => a -> SDoc
2467 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
2468
2469 -- ----------------------------------------------------------------------------
2470
2471 #if 0
2472
2473 -- ToDo:
2474 --   - Data and Typeable instances for HsSyn.
2475
2476 -- ToDo: check for small transformations that happen to the syntax in
2477 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
2478
2479 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
2480 -- to get from TyCons, Ids etc. to TH syntax (reify).
2481
2482 -- :browse will use either lm_toplev or inspect lm_interface, depending
2483 -- on whether the module is interpreted or not.
2484
2485 #endif
2486
2487 -- Extract the filename, stringbuffer content and dynflags associed to a module
2488 --
2489 -- XXX: Explain pre-conditions
2490 getModuleSourceAndFlags :: GhcMonad m => Module -> m (String, StringBuffer, DynFlags)
2491 getModuleSourceAndFlags mod = do
2492   m <- getModSummary (moduleName mod)
2493   case ml_hs_file $ ms_location m of
2494     Nothing -> throw $ mkApiErr (text "No source available for module " <+> ppr mod)
2495     Just sourceFile -> do
2496         source <- liftIO $ hGetStringBuffer sourceFile
2497         return (sourceFile, source, ms_hspp_opts m)
2498
2499
2500 -- | Return module source as token stream, including comments.
2501 --
2502 -- The module must be in the module graph and its source must be available.
2503 -- Throws a 'HscTypes.SourceError' on parse error.
2504 getTokenStream :: GhcMonad m => Module -> m [Located Token]
2505 getTokenStream mod = do
2506   (sourceFile, source, flags) <- getModuleSourceAndFlags mod
2507   let startLoc = mkSrcLoc (mkFastString sourceFile) 0 0
2508   case lexTokenStream source startLoc flags of
2509     POk _ ts  -> return ts
2510     PFailed span err -> throw $ mkSrcErr (unitBag $ mkPlainErrMsg span err)
2511
2512 -- | Give even more information on the source than 'getTokenStream'
2513 -- This function allows reconstructing the source completely with
2514 -- 'showRichTokenStream'.
2515 getRichTokenStream :: GhcMonad m => Module -> m [(Located Token, String)]
2516 getRichTokenStream mod = do
2517   (sourceFile, source, flags) <- getModuleSourceAndFlags mod
2518   let startLoc = mkSrcLoc (mkFastString sourceFile) 0 0
2519   case lexTokenStream source startLoc flags of
2520     POk _ ts -> return $ addSourceToTokens startLoc source ts
2521     PFailed span err -> throw $ mkSrcErr (unitBag $ mkPlainErrMsg span err)
2522
2523 -- | Given a source location and a StringBuffer corresponding to this
2524 -- location, return a rich token stream with the source associated to the
2525 -- tokens.
2526 addSourceToTokens :: SrcLoc -> StringBuffer -> [Located Token]
2527                   -> [(Located Token, String)]
2528 addSourceToTokens _ _ [] = []
2529 addSourceToTokens loc buf (t@(L span _) : ts)
2530     | not (isGoodSrcSpan span) = (t,"") : addSourceToTokens loc buf ts
2531     | otherwise = (t,str) : addSourceToTokens newLoc newBuf ts
2532     where
2533       (newLoc, newBuf, str) = go "" loc buf
2534       start = srcSpanStart span
2535       end = srcSpanEnd span
2536       go acc loc buf | loc < start = go acc nLoc nBuf
2537                      | start <= loc && loc < end = go (ch:acc) nLoc nBuf
2538                      | otherwise = (loc, buf, reverse acc)
2539           where (ch, nBuf) = nextChar buf
2540                 nLoc = advanceSrcLoc loc ch
2541
2542
2543 -- | Take a rich token stream such as produced from 'getRichTokenStream' and
2544 -- return source code almost identical to the original code (except for
2545 -- insignificant whitespace.)
2546 showRichTokenStream :: [(Located Token, String)] -> String
2547 showRichTokenStream ts = go startLoc ts ""
2548     where sourceFile = srcSpanFile (getLoc . fst . head $ ts)
2549           startLoc = mkSrcLoc sourceFile 0 0
2550           go _ [] = id
2551           go loc ((L span _, str):ts)
2552               | not (isGoodSrcSpan span) = go loc ts
2553               | locLine == tokLine = ((replicate (tokCol - locCol) ' ') ++)
2554                                      . (str ++)
2555                                      . go tokEnd ts
2556               | otherwise = ((replicate (tokLine - locLine) '\n') ++)
2557                             . ((replicate tokCol ' ') ++)
2558                             . (str ++)
2559                             . go tokEnd ts
2560               where (locLine, locCol) = (srcLocLine loc, srcLocCol loc)
2561                     (tokLine, tokCol) = (srcSpanStartLine span, srcSpanStartCol span)
2562                     tokEnd = srcSpanEnd span
2563
2564 -- -----------------------------------------------------------------------------
2565 -- Interactive evaluation
2566
2567 -- | Takes a 'ModuleName' and possibly a 'PackageId', and consults the
2568 -- filesystem and package database to find the corresponding 'Module',
2569 -- using the algorithm that is used for an @import@ declaration.
2570 findModule :: GhcMonad m => ModuleName -> Maybe FastString -> m Module
2571 findModule mod_name maybe_pkg = withSession $ \hsc_env -> liftIO $ -- XXX
2572   let
2573         dflags = hsc_dflags hsc_env
2574         hpt    = hsc_HPT hsc_env
2575         this_pkg = thisPackage dflags
2576   in
2577   case lookupUFM hpt mod_name of
2578     Just mod_info -> return (mi_module (hm_iface mod_info))
2579     _not_a_home_module -> do
2580           res <- findImportedModule hsc_env mod_name maybe_pkg
2581           case res of
2582             Found _ m | modulePackageId m /= this_pkg -> return m
2583                       | otherwise -> ghcError (CmdLineError (showSDoc $
2584                                         text "module" <+> quotes (ppr (moduleName m)) <+>
2585                                         text "is not loaded"))
2586             err -> let msg = cannotFindModule dflags mod_name err in
2587                    ghcError (CmdLineError (showSDoc msg))
2588
2589 #ifdef GHCI
2590 getHistorySpan :: GhcMonad m => History -> m SrcSpan
2591 getHistorySpan h = withSession $ \hsc_env ->
2592                           return$ InteractiveEval.getHistorySpan hsc_env h
2593
2594 obtainTermFromVal :: GhcMonad m => Int ->  Bool -> Type -> a -> m Term
2595 obtainTermFromVal bound force ty a =
2596     withSession $ \hsc_env ->
2597       liftIO $ InteractiveEval.obtainTermFromVal hsc_env bound force ty a
2598
2599 obtainTermFromId :: GhcMonad m => Int -> Bool -> Id -> m Term
2600 obtainTermFromId bound force id =
2601     withSession $ \hsc_env ->
2602       liftIO $ InteractiveEval.obtainTermFromId hsc_env bound force id
2603
2604 #endif