compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         newSession,
  15
  16         -- * Flags and settings
  17         DynFlags(..), DynFlag(..), Severity(..), HscTarget(..), dopt,
  18         GhcMode(..), GhcLink(..), defaultObjectTarget,
  19         parseDynamicFlags,
  20         getSessionDynFlags,
  21         setSessionDynFlags,
  22         parseStaticFlags,
  23
  24         -- * Targets
  25         Target(..), TargetId(..), Phase,
  26         setTargets,
  27         getTargets,
  28         addTarget,
  29         removeTarget,
  30         guessTarget,
  31
  32         -- * Extending the program scope
  33         extendGlobalRdrScope,  -- :: Session -> [GlobalRdrElt] -> IO ()
  34         setGlobalRdrScope,     -- :: Session -> [GlobalRdrElt] -> IO ()
  35         extendGlobalTypeScope, -- :: Session -> [Id] -> IO ()
  36         setGlobalTypeScope,    -- :: Session -> [Id] -> IO ()
  37
  38         -- * Loading\/compiling the program
  39         depanal,
  40         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  41         workingDirectoryChanged,
  42         checkModule, CheckedModule(..),
  43         TypecheckedSource, ParsedSource, RenamedSource,
  44         compileToCore,
  45
  46         -- * Parsing Haddock comments
  47         parseHaddockComment,
  48
  49         -- * Inspecting the module structure of the program
  50         ModuleGraph, ModSummary(..), ms_mod_name, ModLocation(..),
  51         getModuleGraph,
  52         isLoaded,
  53         topSortModuleGraph,
  54
  55         -- * Inspecting modules
  56         ModuleInfo,
  57         getModuleInfo,
  58         modInfoTyThings,
  59         modInfoTopLevelScope,
  60         modInfoPrintUnqualified,
  61         modInfoExports,
  62         modInfoInstances,
  63         modInfoIsExportedName,
  64         modInfoLookupName,
  65         lookupGlobalName,
  66
  67         -- * Printing
  68         PrintUnqualified, alwaysQualify,
  69
  70         -- * Interactive evaluation
  71         getBindings, getPrintUnqual,
  72         findModule,
  73 #ifdef GHCI
  74         setContext, getContext,
  75         getNamesInScope,
  76         getRdrNamesInScope,
  77         moduleIsInterpreted,
  78         getInfo,
  79         exprType,
  80         typeKind,
  81         parseName,
  82         RunResult(..),
  83         runStmt, SingleStep(..),
  84         resume,
  85         Resume(resumeStmt, resumeThreadId, resumeBreakInfo, resumeSpan,
  86                resumeHistory, resumeHistoryIx),
  87         History(historyBreakInfo), getHistorySpan, getHistoryModule,
  88         getResumeContext,
  89         abandon, abandonAll,
  90         InteractiveEval.back,
  91         InteractiveEval.forward,
  92         showModule,
  93         isModuleInterpreted,
  94         compileExpr, HValue, dynCompileExpr,
  95         lookupName,
  96         obtainTerm, obtainTerm1,
  97         modInfoModBreaks,
  98         ModBreaks(..), BreakIndex,
  99         BreakInfo(breakInfo_number, breakInfo_module),
 100         BreakArray, setBreakOn, setBreakOff, getBreak,
 101 #endif
 102
 103         -- * Abstract syntax elements
 104
 105         -- ** Packages
 106         PackageId,
 107
 108         -- ** Modules
 109         Module, mkModule, pprModule, moduleName, modulePackageId,
 110         ModuleName, mkModuleName, moduleNameString,
 111
 112         -- ** Names
 113         Name,
 114         isExternalName, nameModule, pprParenSymName, nameSrcSpan,
 115         NamedThing(..),
 116         RdrName(Qual,Unqual),
 117
 118         -- ** Identifiers
 119         Id, idType,
 120         isImplicitId, isDeadBinder,
 121         isExportedId, isLocalId, isGlobalId,
 122         isRecordSelector,
 123         isPrimOpId, isFCallId, isClassOpId_maybe,
 124         isDataConWorkId, idDataCon,
 125         isBottomingId, isDictonaryId,
 126         recordSelectorFieldLabel,
 127
 128         -- ** Type constructors
 129         TyCon,
 130         tyConTyVars, tyConDataCons, tyConArity,
 131         isClassTyCon, isSynTyCon, isNewTyCon, isPrimTyCon, isFunTyCon,
 132         isOpenTyCon,
 133         synTyConDefn, synTyConType, synTyConResKind,
 134
 135         -- ** Type variables
 136         TyVar,
 137         alphaTyVars,
 138
 139         -- ** Data constructors
 140         DataCon,
 141         dataConSig, dataConType, dataConTyCon, dataConFieldLabels,
 142         dataConIsInfix, isVanillaDataCon,
 143         dataConStrictMarks,
 144         StrictnessMark(..), isMarkedStrict,
 145
 146         -- ** Classes
 147         Class,
 148         classMethods, classSCTheta, classTvsFds,
 149         pprFundeps,
 150
 151         -- ** Instances
 152         Instance,
 153         instanceDFunId, pprInstance, pprInstanceHdr,
 154
 155         -- ** Types and Kinds
 156         Type, dropForAlls, splitForAllTys, funResultTy,
 157         pprParendType, pprTypeApp,
 158         Kind,
 159         PredType,
 160         ThetaType, pprThetaArrow,
 161
 162         -- ** Entities
 163         TyThing(..),
 164
 165         -- ** Syntax
 166         module HsSyn, -- ToDo: remove extraneous bits
 167
 168         -- ** Fixities
 169         FixityDirection(..),
 170         defaultFixity, maxPrecedence,
 171         negateFixity,
 172         compareFixity,
 173
 174         -- ** Source locations
 175         SrcLoc, pprDefnLoc,
 176         mkSrcLoc, isGoodSrcLoc, noSrcLoc,
 177         srcLocFile, srcLocLine, srcLocCol,
 178         SrcSpan,
 179         mkSrcSpan, srcLocSpan, isGoodSrcSpan, noSrcSpan,
 180         srcSpanStart, srcSpanEnd,
 181         srcSpanFile,
 182         srcSpanStartLine, srcSpanEndLine,
 183         srcSpanStartCol, srcSpanEndCol,
 184
 185         -- * Exceptions
 186         GhcException(..), showGhcException,
 187
 188         -- * Miscellaneous
 189         sessionHscEnv,
 190         cyclicModuleErr,
 191   ) where
 192
 193 {-
 194  ToDo:
 195
 196   * inline bits of HscMain here to simplify layering: hscTcExpr, hscStmt.
 197   * what StaticFlags should we expose, if any?
 198 -}
 199
 200 #include "HsVersions.h"
 201
 202 #ifdef GHCI
 203 import qualified Linker
 204 import Linker           ( HValue )
 205 import ByteCodeInstr
 206 import BreakArray
 207 import NameSet
 208 import TcRnDriver
 209 import InteractiveEval
 210 #endif
 211
 212 import Packages
 213 import NameSet
 214 import RdrName
 215 import HsSyn
 216 import Type             hiding (typeKind)
 217 import TcType           hiding (typeKind)
 218 import Id
 219 import Var              hiding (setIdType)
 220 import TysPrim          ( alphaTyVars )
 221 import TyCon
 222 import Class
 223 import FunDeps
 224 import DataCon
 225 import Name             hiding ( varName )
 226 import OccName          ( parenSymOcc )
 227 import InstEnv          ( Instance, instanceDFunId, pprInstance, pprInstanceHdr )
 228 import SrcLoc
 229 import Desugar
 230 import CoreSyn
 231 import TcRnDriver       ( tcRnModule )
 232 import DriverPipeline
 233 import DriverPhases     ( HscSource(..), Phase(..), isHaskellSrcFilename, startPhase )
 234 import HeaderInfo       ( getImports, getOptions )
 235 import Finder
 236 import HscMain          ( newHscEnv, hscFileCheck, HscChecked(..) )
 237 import HscTypes
 238 import DynFlags
 239 import StaticFlags
 240 import SysTools     ( initSysTools, cleanTempFiles, cleanTempFilesExcept,
 241                       cleanTempDirs )
 242 import Module
 243 import UniqFM
 244 import UniqSet
 245 import Unique
 246 import PackageConfig
 247 import FiniteMap
 248 import Panic
 249 import Digraph
 250 import Bag              ( unitBag, listToBag )
 251 import ErrUtils         ( Severity(..), showPass, fatalErrorMsg, debugTraceMsg,
 252                           mkPlainErrMsg, printBagOfErrors, printBagOfWarnings,
 253                           WarnMsg )
 254 import qualified ErrUtils
 255 import Util
 256 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 257 import Outputable
 258 import BasicTypes
 259 import Maybes           ( expectJust, mapCatMaybes )
 260 import HaddockParse
 261 import HaddockLex       ( tokenise )
 262
 263 import Control.Concurrent
 264 import System.Directory ( getModificationTime, doesFileExist )
 265 import Data.Maybe
 266 import Data.List
 267 import qualified Data.List as List
 268 import Control.Monad
 269 import System.Exit      ( exitWith, ExitCode(..) )
 270 import System.Time      ( ClockTime )
 271 import Control.Exception as Exception hiding (handle)
 272 import Data.IORef
 273 import System.IO
 274 import System.IO.Error  ( try, isDoesNotExistError )
 275 import Prelude hiding (init)
 276
 277
 278 -- -----------------------------------------------------------------------------
 279 -- Exception handlers
 280
 281 -- | Install some default exception handlers and run the inner computation.
 282 -- Unless you want to handle exceptions yourself, you should wrap this around
 283 -- the top level of your program.  The default handlers output the error
 284 -- message(s) to stderr and exit cleanly.
 285 defaultErrorHandler :: DynFlags -> IO a -> IO a
 286 defaultErrorHandler dflags inner =
 287   -- top-level exception handler: any unrecognised exception is a compiler bug.
 288   handle (\exception -> do
 289            hFlush stdout
 290            case exception of
 291                 -- an IO exception probably isn't our fault, so don't panic
 292                 IOException _ ->
 293                   fatalErrorMsg dflags (text (show exception))
 294                 AsyncException StackOverflow ->
 295                   fatalErrorMsg dflags (text "stack overflow: use +RTS -K<size> to increase it")
 296                 _other ->
 297                   fatalErrorMsg dflags (text (show (Panic (show exception))))
 298            exitWith (ExitFailure 1)
 299          ) $
 300
 301   -- program errors: messages with locations attached.  Sometimes it is
 302   -- convenient to just throw these as exceptions.
 303   handleDyn (\dyn -> do printBagOfErrors dflags (unitBag dyn)
 304                         exitWith (ExitFailure 1)) $
 305
 306   -- error messages propagated as exceptions
 307   handleDyn (\dyn -> do
 308                 hFlush stdout
 309                 case dyn of
 310                      PhaseFailed _ code -> exitWith code
 311                      Interrupted -> exitWith (ExitFailure 1)
 312                      _ -> do fatalErrorMsg dflags (text (show (dyn :: GhcException)))
 313                              exitWith (ExitFailure 1)
 314             ) $
 315   inner
 316
 317 -- | Install a default cleanup handler to remove temporary files
 318 -- deposited by a GHC run.  This is seperate from
 319 -- 'defaultErrorHandler', because you might want to override the error
 320 -- handling, but still get the ordinary cleanup behaviour.
 321 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 322 defaultCleanupHandler dflags inner =
 323     -- make sure we clean up after ourselves
 324     later (do cleanTempFiles dflags
 325               cleanTempDirs dflags
 326           )
 327           -- exceptions will be blocked while we clean the temporary files,
 328           -- so there shouldn't be any difficulty if we receive further
 329           -- signals.
 330     inner
 331
 332
 333 -- | Starts a new session.  A session consists of a set of loaded
 334 -- modules, a set of options (DynFlags), and an interactive context.
 335 newSession :: Maybe FilePath -> IO Session
 336 newSession mb_top_dir = do
 337   -- catch ^C
 338   main_thread <- myThreadId
 339   modifyMVar_ interruptTargetThread (return . (main_thread :))
 340   installSignalHandlers
 341
 342   initStaticOpts
 343   dflags0 <- initSysTools mb_top_dir defaultDynFlags
 344   dflags  <- initDynFlags dflags0
 345   env <- newHscEnv dflags
 346   ref <- newIORef env
 347   return (Session ref)
 348
 349 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 350 -- needs to call the Finder.  ToDo: untangle this.
 351 sessionHscEnv :: Session -> IO HscEnv
 352 sessionHscEnv (Session ref) = readIORef ref
 353
 354 -- -----------------------------------------------------------------------------
 355 -- Flags & settings
 356
 357 -- | Grabs the DynFlags from the Session
 358 getSessionDynFlags :: Session -> IO DynFlags
 359 getSessionDynFlags s = withSession s (return . hsc_dflags)
 360
 361 -- | Updates the DynFlags in a Session.  This also reads
 362 -- the package database (unless it has already been read),
 363 -- and prepares the compilers knowledge about packages.  It
 364 -- can be called again to load new packages: just add new
 365 -- package flags to (packageFlags dflags).
 366 --
 367 -- Returns a list of new packages that may need to be linked in using
 368 -- the dynamic linker (see 'linkPackages') as a result of new package
 369 -- flags.  If you are not doing linking or doing static linking, you
 370 -- can ignore the list of packages returned.
 371 --
 372 setSessionDynFlags :: Session -> DynFlags -> IO [PackageId]
 373 setSessionDynFlags (Session ref) dflags = do
 374   hsc_env <- readIORef ref
 375   (dflags', preload) <- initPackages dflags
 376   writeIORef ref $! hsc_env{ hsc_dflags = dflags' }
 377   return preload
 378
 379 -- | If there is no -o option, guess the name of target executable
 380 -- by using top-level source file name as a base.
 381 guessOutputFile :: Session -> IO ()
 382 guessOutputFile s = modifySession s $ \env ->
 383     let dflags = hsc_dflags env
 384         mod_graph = hsc_mod_graph env
 385         mainModuleSrcPath, guessedName :: Maybe String
 386         mainModuleSrcPath = do
 387             let isMain = (== mainModIs dflags) . ms_mod
 388             [ms] <- return (filter isMain mod_graph)
 389             ml_hs_file (ms_location ms)
 390         guessedName = fmap basenameOf mainModuleSrcPath
 391     in
 392     case outputFile dflags of
 393         Just _ -> env
 394         Nothing -> env { hsc_dflags = dflags { outputFile = guessedName } }
 395
 396 -- -----------------------------------------------------------------------------
 397 -- Targets
 398
 399 -- ToDo: think about relative vs. absolute file paths. And what
 400 -- happens when the current directory changes.
 401
 402 -- | Sets the targets for this session.  Each target may be a module name
 403 -- or a filename.  The targets correspond to the set of root modules for
 404 -- the program\/library.  Unloading the current program is achieved by
 405 -- setting the current set of targets to be empty, followed by load.
 406 setTargets :: Session -> [Target] -> IO ()
 407 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 408
 409 -- | returns the current set of targets
 410 getTargets :: Session -> IO [Target]
 411 getTargets s = withSession s (return . hsc_targets)
 412
 413 -- | Add another target
 414 addTarget :: Session -> Target -> IO ()
 415 addTarget s target
 416   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 417
 418 -- | Remove a target
 419 removeTarget :: Session -> TargetId -> IO ()
 420 removeTarget s target_id
 421   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 422   where
 423    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 424
 425 -- Attempts to guess what Target a string refers to.  This function implements
 426 -- the --make/GHCi command-line syntax for filenames:
 427 --
 428 --      - if the string looks like a Haskell source filename, then interpret
 429 --        it as such
 430 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 431 --        then use that
 432 --      - otherwise interpret the string as a module name
 433 --
 434 guessTarget :: String -> Maybe Phase -> IO Target
 435 guessTarget file (Just phase)
 436    = return (Target (TargetFile file (Just phase)) Nothing)
 437 guessTarget file Nothing
 438    | isHaskellSrcFilename file
 439    = return (Target (TargetFile file Nothing) Nothing)
 440    | otherwise
 441    = do exists <- doesFileExist hs_file
 442         if exists
 443            then return (Target (TargetFile hs_file Nothing) Nothing)
 444            else do
 445         exists <- doesFileExist lhs_file
 446         if exists
 447            then return (Target (TargetFile lhs_file Nothing) Nothing)
 448            else do
 449         return (Target (TargetModule (mkModuleName file)) Nothing)
 450      where
 451          hs_file  = file `joinFileExt` "hs"
 452          lhs_file = file `joinFileExt` "lhs"
 453
 454 -- -----------------------------------------------------------------------------
 455 -- Extending the program scope
 456
 457 extendGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 458 extendGlobalRdrScope session rdrElts
 459     = modifySession session $ \hscEnv ->
 460       let global_rdr = hsc_global_rdr_env hscEnv
 461       in hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv global_rdr rdrElts }
 462
 463 setGlobalRdrScope :: Session -> [GlobalRdrElt] -> IO ()
 464 setGlobalRdrScope session rdrElts
 465     = modifySession session $ \hscEnv ->
 466       hscEnv{ hsc_global_rdr_env = foldl extendGlobalRdrEnv emptyGlobalRdrEnv rdrElts }
 467
 468 extendGlobalTypeScope :: Session -> [Id] -> IO ()
 469 extendGlobalTypeScope session ids
 470     = modifySession session $ \hscEnv ->
 471       let global_type = hsc_global_type_env hscEnv
 472       in hscEnv{ hsc_global_type_env = extendTypeEnvWithIds global_type ids }
 473
 474 setGlobalTypeScope :: Session -> [Id] -> IO ()
 475 setGlobalTypeScope session ids
 476     = modifySession session $ \hscEnv ->
 477       hscEnv{ hsc_global_type_env = extendTypeEnvWithIds emptyTypeEnv ids }
 478
 479 -- -----------------------------------------------------------------------------
 480 -- Parsing Haddock comments
 481
 482 parseHaddockComment :: String -> Either String (HsDoc RdrName)
 483 parseHaddockComment string = parseHaddockParagraphs (tokenise string)
 484
 485 -- -----------------------------------------------------------------------------
 486 -- Loading the program
 487
 488 -- Perform a dependency analysis starting from the current targets
 489 -- and update the session with the new module graph.
 490 depanal :: Session -> [ModuleName] -> Bool -> IO (Maybe ModuleGraph)
 491 depanal (Session ref) excluded_mods allow_dup_roots = do
 492   hsc_env <- readIORef ref
 493   let
 494          dflags  = hsc_dflags hsc_env
 495          targets = hsc_targets hsc_env
 496          old_graph = hsc_mod_graph hsc_env
 497
 498   showPass dflags "Chasing dependencies"
 499   debugTraceMsg dflags 2 (hcat [
 500              text "Chasing modules from: ",
 501              hcat (punctuate comma (map pprTarget targets))])
 502
 503   r <- downsweep hsc_env old_graph excluded_mods allow_dup_roots
 504   case r of
 505     Just mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 506     _ -> return ()
 507   return r
 508
 509 {-
 510 -- | The result of load.
 511 data LoadResult
 512   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 513   | LoadFailed  Errors  -- ^ not all modules were loaded.
 514
 515 type Errors = [String]
 516
 517 data ErrMsg = ErrMsg {
 518         errMsgSeverity  :: Severity,  -- warning, error, etc.
 519         errMsgSpans     :: [SrcSpan],
 520         errMsgShortDoc  :: Doc,
 521         errMsgExtraInfo :: Doc
 522         }
 523 -}
 524
 525 data LoadHowMuch
 526    = LoadAllTargets
 527    | LoadUpTo ModuleName
 528    | LoadDependenciesOf ModuleName
 529
 530 -- | Try to load the program.  If a Module is supplied, then just
 531 -- attempt to load up to this target.  If no Module is supplied,
 532 -- then try to load all targets.
 533 load :: Session -> LoadHowMuch -> IO SuccessFlag
 534 load s@(Session ref) how_much
 535    = do
 536         -- Dependency analysis first.  Note that this fixes the module graph:
 537         -- even if we don't get a fully successful upsweep, the full module
 538         -- graph is still retained in the Session.  We can tell which modules
 539         -- were successfully loaded by inspecting the Session's HPT.
 540         mb_graph <- depanal s [] False
 541         case mb_graph of
 542            Just mod_graph -> load2 s how_much mod_graph
 543            Nothing        -> return Failed
 544
 545 load2 s@(Session ref) how_much mod_graph = do
 546         guessOutputFile s
 547         hsc_env <- readIORef ref
 548
 549         let hpt1      = hsc_HPT hsc_env
 550         let dflags    = hsc_dflags hsc_env
 551
 552         -- The "bad" boot modules are the ones for which we have
 553         -- B.hs-boot in the module graph, but no B.hs
 554         -- The downsweep should have ensured this does not happen
 555         -- (see msDeps)
 556         let all_home_mods = [ms_mod_name s
 557                             | s <- mod_graph, not (isBootSummary s)]
 558 #ifdef DEBUG
 559             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 560                                         not (ms_mod_name s `elem` all_home_mods)]
 561 #endif
 562         ASSERT( null bad_boot_mods ) return ()
 563
 564         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 565         -- graph with cycles.  Among other things, it is used for
 566         -- backing out partially complete cycles following a failed
 567         -- upsweep, and for removing from hpt all the modules
 568         -- not in strict downwards closure, during calls to compile.
 569         let mg2_with_srcimps :: [SCC ModSummary]
 570             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 571
 572         -- If we can determine that any of the {-# SOURCE #-} imports
 573         -- are definitely unnecessary, then emit a warning.
 574         warnUnnecessarySourceImports dflags mg2_with_srcimps
 575
 576         let
 577             -- check the stability property for each module.
 578             stable_mods@(stable_obj,stable_bco)
 579                 = checkStability hpt1 mg2_with_srcimps all_home_mods
 580
 581             -- prune bits of the HPT which are definitely redundant now,
 582             -- to save space.
 583             pruned_hpt = pruneHomePackageTable hpt1
 584                                 (flattenSCCs mg2_with_srcimps)
 585                                 stable_mods
 586
 587         evaluate pruned_hpt
 588
 589         debugTraceMsg dflags 2 (text "Stable obj:" <+> ppr stable_obj $$
 590                                 text "Stable BCO:" <+> ppr stable_bco)
 591
 592         -- Unload any modules which are going to be re-linked this time around.
 593         let stable_linkables = [ linkable
 594                                | m <- stable_obj++stable_bco,
 595                                  Just hmi <- [lookupUFM pruned_hpt m],
 596                                  Just linkable <- [hm_linkable hmi] ]
 597         unload hsc_env stable_linkables
 598
 599         -- We could at this point detect cycles which aren't broken by
 600         -- a source-import, and complain immediately, but it seems better
 601         -- to let upsweep_mods do this, so at least some useful work gets
 602         -- done before the upsweep is abandoned.
 603         --hPutStrLn stderr "after tsort:\n"
 604         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 605
 606         -- Now do the upsweep, calling compile for each module in
 607         -- turn.  Final result is version 3 of everything.
 608
 609         -- Topologically sort the module graph, this time including hi-boot
 610         -- nodes, and possibly just including the portion of the graph
 611         -- reachable from the module specified in the 2nd argument to load.
 612         -- This graph should be cycle-free.
 613         -- If we're restricting the upsweep to a portion of the graph, we
 614         -- also want to retain everything that is still stable.
 615         let full_mg :: [SCC ModSummary]
 616             full_mg    = topSortModuleGraph False mod_graph Nothing
 617
 618             maybe_top_mod = case how_much of
 619                                 LoadUpTo m           -> Just m
 620                                 LoadDependenciesOf m -> Just m
 621                                 _                    -> Nothing
 622
 623             partial_mg0 :: [SCC ModSummary]
 624             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 625
 626             -- LoadDependenciesOf m: we want the upsweep to stop just
 627             -- short of the specified module (unless the specified module
 628             -- is stable).
 629             partial_mg
 630                 | LoadDependenciesOf mod <- how_much
 631                 = ASSERT( case last partial_mg0 of
 632                             AcyclicSCC ms -> ms_mod_name ms == mod; _ -> False )
 633                   List.init partial_mg0
 634                 | otherwise
 635                 = partial_mg0
 636
 637             stable_mg =
 638                 [ AcyclicSCC ms
 639                 | AcyclicSCC ms <- full_mg,
 640                   ms_mod_name ms `elem` stable_obj++stable_bco,
 641                   ms_mod_name ms `notElem` [ ms_mod_name ms' |
 642                                                 AcyclicSCC ms' <- partial_mg ] ]
 643
 644             mg = stable_mg ++ partial_mg
 645
 646         -- clean up between compilations
 647         let cleanup = cleanTempFilesExcept dflags
 648                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 649
 650         debugTraceMsg dflags 2 (hang (text "Ready for upsweep")
 651                                    2 (ppr mg))
 652         (upsweep_ok, hsc_env1, modsUpswept)
 653            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 654                            pruned_hpt stable_mods cleanup mg
 655
 656         -- Make modsDone be the summaries for each home module now
 657         -- available; this should equal the domain of hpt3.
 658         -- Get in in a roughly top .. bottom order (hence reverse).
 659
 660         let modsDone = reverse modsUpswept
 661
 662         -- Try and do linking in some form, depending on whether the
 663         -- upsweep was completely or only partially successful.
 664
 665         if succeeded upsweep_ok
 666
 667          then
 668            -- Easy; just relink it all.
 669            do debugTraceMsg dflags 2 (text "Upsweep completely successful.")
 670
 671               -- Clean up after ourselves
 672               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 673
 674               -- Issue a warning for the confusing case where the user
 675               -- said '-o foo' but we're not going to do any linking.
 676               -- We attempt linking if either (a) one of the modules is
 677               -- called Main, or (b) the user said -no-hs-main, indicating
 678               -- that main() is going to come from somewhere else.
 679               --
 680               let ofile = outputFile dflags
 681               let no_hs_main = dopt Opt_NoHsMain dflags
 682               let
 683                 main_mod = mainModIs dflags
 684                 a_root_is_Main = any ((==main_mod).ms_mod) mod_graph
 685                 do_linking = a_root_is_Main || no_hs_main
 686
 687               when (ghcLink dflags == LinkBinary
 688                     && isJust ofile && not do_linking) $
 689                 debugTraceMsg dflags 1 $
 690                     text ("Warning: output was redirected with -o, " ++
 691                           "but no output will be generated\n" ++
 692                           "because there is no " ++
 693                           moduleNameString (moduleName main_mod) ++ " module.")
 694
 695               -- link everything together
 696               linkresult <- link (ghcLink dflags) dflags do_linking (hsc_HPT hsc_env1)
 697
 698               loadFinish Succeeded linkresult ref hsc_env1
 699
 700          else
 701            -- Tricky.  We need to back out the effects of compiling any
 702            -- half-done cycles, both so as to clean up the top level envs
 703            -- and to avoid telling the interactive linker to link them.
 704            do debugTraceMsg dflags 2 (text "Upsweep partially successful.")
 705
 706               let modsDone_names
 707                      = map ms_mod modsDone
 708               let mods_to_zap_names
 709                      = findPartiallyCompletedCycles modsDone_names
 710                           mg2_with_srcimps
 711               let mods_to_keep
 712                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 713                           modsDone
 714
 715               let hpt4 = retainInTopLevelEnvs (map ms_mod_name mods_to_keep)
 716                                               (hsc_HPT hsc_env1)
 717
 718               -- Clean up after ourselves
 719               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 720
 721               -- there should be no Nothings where linkables should be, now
 722               ASSERT(all (isJust.hm_linkable)
 723                         (eltsUFM (hsc_HPT hsc_env))) do
 724
 725               -- Link everything together
 726               linkresult <- link (ghcLink dflags) dflags False hpt4
 727
 728               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 729               loadFinish Failed linkresult ref hsc_env4
 730
 731 -- Finish up after a load.
 732
 733 -- If the link failed, unload everything and return.
 734 loadFinish all_ok Failed ref hsc_env
 735   = do unload hsc_env []
 736        writeIORef ref $! discardProg hsc_env
 737        return Failed
 738
 739 -- Empty the interactive context and set the module context to the topmost
 740 -- newly loaded module, or the Prelude if none were loaded.
 741 loadFinish all_ok Succeeded ref hsc_env
 742   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 743        return all_ok
 744
 745
 746 -- Forget the current program, but retain the persistent info in HscEnv
 747 discardProg :: HscEnv -> HscEnv
 748 discardProg hsc_env
 749   = hsc_env { hsc_mod_graph = emptyMG,
 750               hsc_IC = emptyInteractiveContext,
 751               hsc_HPT = emptyHomePackageTable }
 752
 753 -- used to fish out the preprocess output files for the purposes of
 754 -- cleaning up.  The preprocessed file *might* be the same as the
 755 -- source file, but that doesn't do any harm.
 756 ppFilesFromSummaries summaries = map ms_hspp_file summaries
 757
 758 -- -----------------------------------------------------------------------------
 759 -- Check module
 760
 761 data CheckedModule =
 762   CheckedModule { parsedSource      :: ParsedSource,
 763                   renamedSource     :: Maybe RenamedSource,
 764                   typecheckedSource :: Maybe TypecheckedSource,
 765                   checkedModuleInfo :: Maybe ModuleInfo,
 766                   coreBinds         :: Maybe [CoreBind]
 767                 }
 768         -- ToDo: improvements that could be made here:
 769         --  if the module succeeded renaming but not typechecking,
 770         --  we can still get back the GlobalRdrEnv and exports, so
 771         --  perhaps the ModuleInfo should be split up into separate
 772         --  fields within CheckedModule.
 773
 774 type ParsedSource      = Located (HsModule RdrName)
 775 type RenamedSource     = (HsGroup Name, [LImportDecl Name], Maybe [LIE Name],
 776                           Maybe (HsDoc Name), HaddockModInfo Name)
 777 type TypecheckedSource = LHsBinds Id
 778
 779 -- NOTE:
 780 --   - things that aren't in the output of the typechecker right now:
 781 --     - the export list
 782 --     - the imports
 783 --     - type signatures
 784 --     - type/data/newtype declarations
 785 --     - class declarations
 786 --     - instances
 787 --   - extra things in the typechecker's output:
 788 --     - default methods are turned into top-level decls.
 789 --     - dictionary bindings
 790
 791
 792 -- | This is the way to get access to parsed and typechecked source code
 793 -- for a module.  'checkModule' attempts to typecheck the module.  If
 794 -- successful, it returns the abstract syntax for the module.
 795 -- If compileToCore is true, it also desugars the module and returns the
 796 -- resulting Core bindings as a component of the CheckedModule.
 797 checkModule :: Session -> ModuleName -> Bool -> IO (Maybe CheckedModule)
 798 checkModule session@(Session ref) mod compileToCore = do
 799         -- parse & typecheck the module
 800    hsc_env <- readIORef ref
 801    let mg  = hsc_mod_graph hsc_env
 802    case [ ms | ms <- mg, ms_mod_name ms == mod ] of
 803         [] -> return Nothing
 804         (ms:_) -> do
 805            mbChecked <- hscFileCheck
 806                           hsc_env{hsc_dflags=ms_hspp_opts ms}
 807                           ms compileToCore
 808            case mbChecked of
 809              Nothing -> return Nothing
 810              Just (HscChecked parsed renamed Nothing _) ->
 811                    return (Just (CheckedModule {
 812                                         parsedSource = parsed,
 813                                         renamedSource = renamed,
 814                                         typecheckedSource = Nothing,
 815                                         checkedModuleInfo = Nothing,
 816                                         coreBinds = Nothing }))
 817              Just (HscChecked parsed renamed
 818                            (Just (tc_binds, rdr_env, details))
 819                            maybeCoreBinds) -> do
 820                    let minf = ModuleInfo {
 821                                 minf_type_env  = md_types details,
 822                                 minf_exports   = availsToNameSet $
 823                                                      md_exports details,
 824                                 minf_rdr_env   = Just rdr_env,
 825                                 minf_instances = md_insts details
 826 #ifdef GHCI
 827                                ,minf_modBreaks = emptyModBreaks
 828 #endif
 829                               }
 830                    return (Just (CheckedModule {
 831                                         parsedSource = parsed,
 832                                         renamedSource = renamed,
 833                                         typecheckedSource = Just tc_binds,
 834                                         checkedModuleInfo = Just minf,
 835                                         coreBinds = maybeCoreBinds}))
 836
 837 -- | This is the way to get access to the Core bindings corresponding
 838 -- to a module. 'compileToCore' invokes 'checkModule' to parse, typecheck, and
 839 -- desugar the module, then returns the resulting list of Core bindings if
 840 -- successful.
 841 compileToCore :: Session -> FilePath -> IO (Maybe [CoreBind])
 842 compileToCore session@(Session ref) fn = do
 843    hsc_env <- readIORef ref
 844    -- First, set the target to the desired filename
 845    target <- guessTarget fn Nothing
 846    addTarget session target
 847    load session LoadAllTargets
 848    -- Then find dependencies
 849    maybeModGraph <- depanal session [] True
 850    case maybeModGraph of
 851      Nothing -> return Nothing
 852      Just modGraph -> do
 853        case find ((== fn) . msHsFilePath) modGraph of
 854          Just modSummary -> do
 855            -- Now we have the module name;
 856            -- parse, typecheck and desugar the module
 857            let mod = ms_mod_name modSummary
 858            maybeCheckedModule <- checkModule session mod True
 859            case maybeCheckedModule of
 860              Nothing -> return Nothing
 861              Just checkedMod -> return $ coreBinds checkedMod
 862  -- ---------------------------------------------------------------------------
 863 -- Unloading
 864
 865 unload :: HscEnv -> [Linkable] -> IO ()
 866 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 867   = case ghcLink (hsc_dflags hsc_env) of
 868 #ifdef GHCI
 869         LinkInMemory -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 870 #else
 871         LinkInMemory -> panic "unload: no interpreter"
 872 #endif
 873         other -> return ()
 874
 875 -- -----------------------------------------------------------------------------
 876 -- checkStability
 877
 878 {-
 879   Stability tells us which modules definitely do not need to be recompiled.
 880   There are two main reasons for having stability:
 881
 882    - avoid doing a complete upsweep of the module graph in GHCi when
 883      modules near the bottom of the tree have not changed.
 884
 885    - to tell GHCi when it can load object code: we can only load object code
 886      for a module when we also load object code fo  all of the imports of the
 887      module.  So we need to know that we will definitely not be recompiling
 888      any of these modules, and we can use the object code.
 889
 890   The stability check is as follows.  Both stableObject and
 891   stableBCO are used during the upsweep phase later.
 892
 893   -------------------
 894   stable m = stableObject m || stableBCO m
 895
 896   stableObject m =
 897         all stableObject (imports m)
 898         && old linkable does not exist, or is == on-disk .o
 899         && date(on-disk .o) > date(.hs)
 900
 901   stableBCO m =
 902         all stable (imports m)
 903         && date(BCO) > date(.hs)
 904   -------------------
 905
 906   These properties embody the following ideas:
 907
 908     - if a module is stable, then:
 909         - if it has been compiled in a previous pass (present in HPT)
 910           then it does not need to be compiled or re-linked.
 911         - if it has not been compiled in a previous pass,
 912           then we only need to read its .hi file from disk and
 913           link it to produce a ModDetails.
 914
 915     - if a modules is not stable, we will definitely be at least
 916       re-linking, and possibly re-compiling it during the upsweep.
 917       All non-stable modules can (and should) therefore be unlinked
 918       before the upsweep.
 919
 920     - Note that objects are only considered stable if they only depend
 921       on other objects.  We can't link object code against byte code.
 922 -}
 923
 924 checkStability
 925         :: HomePackageTable             -- HPT from last compilation
 926         -> [SCC ModSummary]             -- current module graph (cyclic)
 927         -> [ModuleName]                 -- all home modules
 928         -> ([ModuleName],               -- stableObject
 929             [ModuleName])               -- stableBCO
 930
 931 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 932   where
 933    checkSCC (stable_obj, stable_bco) scc0
 934      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 935      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 936      | otherwise     = (stable_obj, stable_bco)
 937      where
 938         scc = flattenSCC scc0
 939         scc_mods = map ms_mod_name scc
 940         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 941
 942         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 943             -- all imports outside the current SCC, but in the home pkg
 944
 945         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 946         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 947
 948         stableObjects =
 949            and stable_obj_imps
 950            && all object_ok scc
 951
 952         stableBCOs =
 953            and (zipWith (||) stable_obj_imps stable_bco_imps)
 954            && all bco_ok scc
 955
 956         object_ok ms
 957           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 958                                          && same_as_prev t
 959           | otherwise = False
 960           where
 961              same_as_prev t = case lookupUFM hpt (ms_mod_name ms) of
 962                                 Just hmi  | Just l <- hm_linkable hmi
 963                                  -> isObjectLinkable l && t == linkableTime l
 964                                 _other  -> True
 965                 -- why '>=' rather than '>' above?  If the filesystem stores
 966                 -- times to the nearset second, we may occasionally find that
 967                 -- the object & source have the same modification time,
 968                 -- especially if the source was automatically generated
 969                 -- and compiled.  Using >= is slightly unsafe, but it matches
 970                 -- make's behaviour.
 971
 972         bco_ok ms
 973           = case lookupUFM hpt (ms_mod_name ms) of
 974                 Just hmi  | Just l <- hm_linkable hmi ->
 975                         not (isObjectLinkable l) &&
 976                         linkableTime l >= ms_hs_date ms
 977                 _other  -> False
 978
 979 ms_allimps :: ModSummary -> [ModuleName]
 980 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 981
 982 -- -----------------------------------------------------------------------------
 983 -- Prune the HomePackageTable
 984
 985 -- Before doing an upsweep, we can throw away:
 986 --
 987 --   - For non-stable modules:
 988 --      - all ModDetails, all linked code
 989 --   - all unlinked code that is out of date with respect to
 990 --     the source file
 991 --
 992 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 993 -- space at the end of the upsweep, because the topmost ModDetails of the
 994 -- old HPT holds on to the entire type environment from the previous
 995 -- compilation.
 996
 997 pruneHomePackageTable
 998    :: HomePackageTable
 999    -> [ModSummary]
1000    -> ([ModuleName],[ModuleName])
1001    -> HomePackageTable
1002
1003 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
1004   = mapUFM prune hpt
1005   where prune hmi
1006           | is_stable modl = hmi'
1007           | otherwise      = hmi'{ hm_details = emptyModDetails }
1008           where
1009            modl = moduleName (mi_module (hm_iface hmi))
1010            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
1011                 = hmi{ hm_linkable = Nothing }
1012                 | otherwise
1013                 = hmi
1014                 where ms = expectJust "prune" (lookupUFM ms_map modl)
1015
1016         ms_map = listToUFM [(ms_mod_name ms, ms) | ms <- summ]
1017
1018         is_stable m = m `elem` stable_obj || m `elem` stable_bco
1019
1020 -- -----------------------------------------------------------------------------
1021
1022 -- Return (names of) all those in modsDone who are part of a cycle
1023 -- as defined by theGraph.
1024 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
1025 findPartiallyCompletedCycles modsDone theGraph
1026    = chew theGraph
1027      where
1028         chew [] = []
1029         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
1030         chew ((CyclicSCC vs):rest)
1031            = let names_in_this_cycle = nub (map ms_mod vs)
1032                  mods_in_this_cycle
1033                     = nub ([done | done <- modsDone,
1034                                    done `elem` names_in_this_cycle])
1035                  chewed_rest = chew rest
1036              in
1037              if   notNull mods_in_this_cycle
1038                   && length mods_in_this_cycle < length names_in_this_cycle
1039              then mods_in_this_cycle ++ chewed_rest
1040              else chewed_rest
1041
1042 -- -----------------------------------------------------------------------------
1043 -- The upsweep
1044
1045 -- This is where we compile each module in the module graph, in a pass
1046 -- from the bottom to the top of the graph.
1047
1048 -- There better had not be any cyclic groups here -- we check for them.
1049
1050 upsweep
1051     :: HscEnv                   -- Includes initially-empty HPT
1052     -> HomePackageTable         -- HPT from last time round (pruned)
1053     -> ([ModuleName],[ModuleName]) -- stable modules (see checkStability)
1054     -> IO ()                    -- How to clean up unwanted tmp files
1055     -> [SCC ModSummary]         -- Mods to do (the worklist)
1056     -> IO (SuccessFlag,
1057            HscEnv,              -- With an updated HPT
1058            [ModSummary])        -- Mods which succeeded
1059
1060 upsweep hsc_env old_hpt stable_mods cleanup mods
1061    = upsweep' hsc_env old_hpt stable_mods cleanup mods 1 (length mods)
1062
1063 upsweep' hsc_env old_hpt stable_mods cleanup
1064      [] _ _
1065    = return (Succeeded, hsc_env, [])
1066
1067 upsweep' hsc_env old_hpt stable_mods cleanup
1068      (CyclicSCC ms:_) _ _
1069    = do fatalErrorMsg (hsc_dflags hsc_env) (cyclicModuleErr ms)
1070         return (Failed, hsc_env, [])
1071
1072 upsweep' hsc_env old_hpt stable_mods cleanup
1073      (AcyclicSCC mod:mods) mod_index nmods
1074    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
1075         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
1076         --                     (moduleEnvElts (hsc_HPT hsc_env)))
1077
1078         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
1079                        mod_index nmods
1080
1081         cleanup         -- Remove unwanted tmp files between compilations
1082
1083         case mb_mod_info of
1084             Nothing -> return (Failed, hsc_env, [])
1085             Just mod_info -> do
1086                 { let this_mod = ms_mod_name mod
1087
1088                         -- Add new info to hsc_env
1089                       hpt1     = addToUFM (hsc_HPT hsc_env) this_mod mod_info
1090                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1091
1092                         -- Space-saving: delete the old HPT entry
1093                         -- for mod BUT if mod is a hs-boot
1094                         -- node, don't delete it.  For the
1095                         -- interface, the HPT entry is probaby for the
1096                         -- main Haskell source file.  Deleting it
1097                         -- would force .. (what?? --SDM)
1098                       old_hpt1 | isBootSummary mod = old_hpt
1099                                | otherwise = delFromUFM old_hpt this_mod
1100
1101                 ; (restOK, hsc_env2, modOKs)
1102                         <- upsweep' hsc_env1 old_hpt1 stable_mods cleanup
1103                                 mods (mod_index+1) nmods
1104                 ; return (restOK, hsc_env2, mod:modOKs)
1105                 }
1106
1107
1108 -- Compile a single module.  Always produce a Linkable for it if
1109 -- successful.  If no compilation happened, return the old Linkable.
1110 upsweep_mod :: HscEnv
1111             -> HomePackageTable
1112             -> ([ModuleName],[ModuleName])
1113             -> ModSummary
1114             -> Int  -- index of module
1115             -> Int  -- total number of modules
1116             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1117
1118 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary mod_index nmods
1119    =    let
1120             this_mod_name = ms_mod_name summary
1121             this_mod    = ms_mod summary
1122             mb_obj_date = ms_obj_date summary
1123             obj_fn      = ml_obj_file (ms_location summary)
1124             hs_date     = ms_hs_date summary
1125
1126             is_stable_obj = this_mod_name `elem` stable_obj
1127             is_stable_bco = this_mod_name `elem` stable_bco
1128
1129             old_hmi = lookupUFM old_hpt this_mod_name
1130
1131             -- We're using the dflags for this module now, obtained by
1132             -- applying any options in its LANGUAGE & OPTIONS_GHC pragmas.
1133             dflags = ms_hspp_opts summary
1134             prevailing_target = hscTarget (hsc_dflags hsc_env)
1135             local_target      = hscTarget dflags
1136
1137             -- If OPTIONS_GHC contains -fasm or -fvia-C, be careful that
1138             -- we don't do anything dodgy: these should only work to change
1139             -- from -fvia-C to -fasm and vice-versa, otherwise we could
1140             -- end up trying to link object code to byte code.
1141             target = if prevailing_target /= local_target
1142                         && (not (isObjectTarget prevailing_target)
1143                             || not (isObjectTarget local_target))
1144                         then prevailing_target
1145                         else local_target
1146
1147             -- store the corrected hscTarget into the summary
1148             summary' = summary{ ms_hspp_opts = dflags { hscTarget = target } }
1149
1150             -- The old interface is ok if
1151             --  a) we're compiling a source file, and the old HPT
1152             --     entry is for a source file
1153             --  b) we're compiling a hs-boot file
1154             -- Case (b) allows an hs-boot file to get the interface of its
1155             -- real source file on the second iteration of the compilation
1156             -- manager, but that does no harm.  Otherwise the hs-boot file
1157             -- will always be recompiled
1158
1159             mb_old_iface
1160                 = case old_hmi of
1161                      Nothing                              -> Nothing
1162                      Just hm_info | isBootSummary summary -> Just iface
1163                                   | not (mi_boot iface)   -> Just iface
1164                                   | otherwise             -> Nothing
1165                                    where
1166                                      iface = hm_iface hm_info
1167
1168             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1169             compile_it  = upsweep_compile hsc_env old_hpt this_mod_name
1170                                 summary' mod_index nmods mb_old_iface
1171
1172             compile_it_discard_iface
1173                         = upsweep_compile hsc_env old_hpt this_mod_name
1174                                 summary' mod_index nmods Nothing
1175
1176         in
1177         case target of
1178
1179             _any
1180                 -- Regardless of whether we're generating object code or
1181                 -- byte code, we can always use an existing object file
1182                 -- if it is *stable* (see checkStability).
1183                 | is_stable_obj, isJust old_hmi ->
1184                         return old_hmi
1185                         -- object is stable, and we have an entry in the
1186                         -- old HPT: nothing to do
1187
1188                 | is_stable_obj, isNothing old_hmi -> do
1189                         linkable <- findObjectLinkable this_mod obj_fn
1190                                         (expectJust "upseep1" mb_obj_date)
1191                         compile_it (Just linkable)
1192                         -- object is stable, but we need to load the interface
1193                         -- off disk to make a HMI.
1194
1195             HscInterpreted
1196                 | is_stable_bco ->
1197                         ASSERT(isJust old_hmi) -- must be in the old_hpt
1198                         return old_hmi
1199                         -- BCO is stable: nothing to do
1200
1201                 | Just hmi <- old_hmi,
1202                   Just l <- hm_linkable hmi, not (isObjectLinkable l),
1203                   linkableTime l >= ms_hs_date summary ->
1204                         compile_it (Just l)
1205                         -- we have an old BCO that is up to date with respect
1206                         -- to the source: do a recompilation check as normal.
1207
1208                 | otherwise ->
1209                         compile_it Nothing
1210                         -- no existing code at all: we must recompile.
1211
1212               -- When generating object code, if there's an up-to-date
1213               -- object file on the disk, then we can use it.
1214               -- However, if the object file is new (compared to any
1215               -- linkable we had from a previous compilation), then we
1216               -- must discard any in-memory interface, because this
1217               -- means the user has compiled the source file
1218               -- separately and generated a new interface, that we must
1219               -- read from the disk.
1220               --
1221             obj | isObjectTarget obj,
1222                   Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1223                      case old_hmi of
1224                         Just hmi
1225                           | Just l <- hm_linkable hmi,
1226                             isObjectLinkable l && linkableTime l == obj_date
1227                             -> compile_it (Just l)
1228                         _otherwise -> do
1229                           linkable <- findObjectLinkable this_mod obj_fn obj_date
1230                           compile_it_discard_iface (Just linkable)
1231
1232             _otherwise ->
1233                   compile_it Nothing
1234
1235
1236 -- Run hsc to compile a module
1237 upsweep_compile hsc_env old_hpt this_mod summary
1238                 mod_index nmods
1239                 mb_old_iface
1240                 mb_old_linkable
1241  = do
1242    compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1243                         mod_index nmods
1244
1245    case compresult of
1246         -- Compilation failed.  Compile may still have updated the PCS, tho.
1247         CompErrs -> return Nothing
1248
1249         -- Compilation "succeeded", and may or may not have returned a new
1250         -- linkable (depending on whether compilation was actually performed
1251         -- or not).
1252         CompOK new_details new_iface new_linkable
1253               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1254                                                  hm_details = new_details,
1255                                                  hm_linkable = new_linkable }
1256                     return (Just new_info)
1257
1258
1259 -- Filter modules in the HPT
1260 retainInTopLevelEnvs :: [ModuleName] -> HomePackageTable -> HomePackageTable
1261 retainInTopLevelEnvs keep_these hpt
1262    = listToUFM   [ (mod, expectJust "retain" mb_mod_info)
1263                  | mod <- keep_these
1264                  , let mb_mod_info = lookupUFM hpt mod
1265                  , isJust mb_mod_info ]
1266
1267 -- ---------------------------------------------------------------------------
1268 -- Topological sort of the module graph
1269
1270 topSortModuleGraph
1271           :: Bool               -- Drop hi-boot nodes? (see below)
1272           -> [ModSummary]
1273           -> Maybe ModuleName
1274           -> [SCC ModSummary]
1275 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1276 -- The resulting list of strongly-connected-components is in topologically
1277 -- sorted order, starting with the module(s) at the bottom of the
1278 -- dependency graph (ie compile them first) and ending with the ones at
1279 -- the top.
1280 --
1281 -- Drop hi-boot nodes (first boolean arg)?
1282 --
1283 --   False:     treat the hi-boot summaries as nodes of the graph,
1284 --              so the graph must be acyclic
1285 --
1286 --   True:      eliminate the hi-boot nodes, and instead pretend
1287 --              the a source-import of Foo is an import of Foo
1288 --              The resulting graph has no hi-boot nodes, but can by cyclic
1289
1290 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1291   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1292 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1293   = stronglyConnComp (map vertex_fn (reachable graph root))
1294   where
1295         -- restrict the graph to just those modules reachable from
1296         -- the specified module.  We do this by building a graph with
1297         -- the full set of nodes, and determining the reachable set from
1298         -- the specified node.
1299         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1300         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1301         root
1302           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1303           | otherwise  = throwDyn (ProgramError "module does not exist")
1304
1305 moduleGraphNodes :: Bool -> [ModSummary]
1306   -> ([(ModSummary, Int, [Int])], HscSource -> ModuleName -> Maybe Int)
1307 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1308    where
1309         -- Drop hs-boot nodes by using HsSrcFile as the key
1310         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1311                     | otherwise          = HsBootFile
1312
1313         -- We use integers as the keys for the SCC algorithm
1314         nodes :: [(ModSummary, Int, [Int])]
1315         nodes = [(s, expectJust "topSort" $
1316                         lookup_key (ms_hsc_src s) (ms_mod_name s),
1317                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1318                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s)) ++
1319                      (-- see [boot-edges] below
1320                       if drop_hs_boot_nodes || ms_hsc_src s == HsBootFile
1321                         then []
1322                         else case lookup_key HsBootFile (ms_mod_name s) of
1323                                 Nothing -> []
1324                                 Just k  -> [k])
1325                  )
1326                 | s <- summaries
1327                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1328                 -- Drop the hi-boot ones if told to do so
1329
1330         -- [boot-edges] if this is a .hs and there is an equivalent
1331         -- .hs-boot, add a link from the former to the latter.  This
1332         -- has the effect of detecting bogus cases where the .hs-boot
1333         -- depends on the .hs, by introducing a cycle.  Additionally,
1334         -- it ensures that we will always process the .hs-boot before
1335         -- the .hs, and so the HomePackageTable will always have the
1336         -- most up to date information.
1337
1338         key_map :: NodeMap Int
1339         key_map = listToFM ([(moduleName (ms_mod s), ms_hsc_src s)
1340                             | s <- summaries]
1341                            `zip` [1..])
1342
1343         lookup_key :: HscSource -> ModuleName -> Maybe Int
1344         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1345
1346         out_edge_keys :: HscSource -> [ModuleName] -> [Int]
1347         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1348                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1349                 -- the IsBootInterface parameter True; else False
1350
1351
1352 type NodeKey   = (ModuleName, HscSource)  -- The nodes of the graph are
1353 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1354
1355 msKey :: ModSummary -> NodeKey
1356 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (moduleName mod,boot)
1357
1358 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1359 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1360
1361 nodeMapElts :: NodeMap a -> [a]
1362 nodeMapElts = eltsFM
1363
1364 -- If there are {-# SOURCE #-} imports between strongly connected
1365 -- components in the topological sort, then those imports can
1366 -- definitely be replaced by ordinary non-SOURCE imports: if SOURCE
1367 -- were necessary, then the edge would be part of a cycle.
1368 warnUnnecessarySourceImports :: DynFlags -> [SCC ModSummary] -> IO ()
1369 warnUnnecessarySourceImports dflags sccs =
1370   printBagOfWarnings dflags (listToBag (concat (map (check.flattenSCC) sccs)))
1371   where check ms =
1372            let mods_in_this_cycle = map ms_mod_name ms in
1373            [ warn m i | m <- ms, i <- ms_srcimps m,
1374                         unLoc i `notElem`  mods_in_this_cycle ]
1375
1376         warn :: ModSummary -> Located ModuleName -> WarnMsg
1377         warn ms (L loc mod) =
1378            mkPlainErrMsg loc
1379                 (ptext SLIT("Warning: {-# SOURCE #-} unnecessary in import of ")
1380                  <+> quotes (ppr mod))
1381
1382 -----------------------------------------------------------------------------
1383 -- Downsweep (dependency analysis)
1384
1385 -- Chase downwards from the specified root set, returning summaries
1386 -- for all home modules encountered.  Only follow source-import
1387 -- links.
1388
1389 -- We pass in the previous collection of summaries, which is used as a
1390 -- cache to avoid recalculating a module summary if the source is
1391 -- unchanged.
1392 --
1393 -- The returned list of [ModSummary] nodes has one node for each home-package
1394 -- module, plus one for any hs-boot files.  The imports of these nodes
1395 -- are all there, including the imports of non-home-package modules.
1396
1397 downsweep :: HscEnv
1398           -> [ModSummary]       -- Old summaries
1399           -> [ModuleName]       -- Ignore dependencies on these; treat
1400                                 -- them as if they were package modules
1401           -> Bool               -- True <=> allow multiple targets to have
1402                                 --          the same module name; this is
1403                                 --          very useful for ghc -M
1404           -> IO (Maybe [ModSummary])
1405                 -- The elts of [ModSummary] all have distinct
1406                 -- (Modules, IsBoot) identifiers, unless the Bool is true
1407                 -- in which case there can be repeats
1408 downsweep hsc_env old_summaries excl_mods allow_dup_roots
1409    = -- catch error messages and return them
1410      handleDyn (\err_msg -> printBagOfErrors (hsc_dflags hsc_env) (unitBag err_msg) >> return Nothing) $ do
1411        rootSummaries <- mapM getRootSummary roots
1412        let root_map = mkRootMap rootSummaries
1413        checkDuplicates root_map
1414        summs <- loop (concatMap msDeps rootSummaries) root_map
1415        return (Just summs)
1416      where
1417         roots = hsc_targets hsc_env
1418
1419         old_summary_map :: NodeMap ModSummary
1420         old_summary_map = mkNodeMap old_summaries
1421
1422         getRootSummary :: Target -> IO ModSummary
1423         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1424            = do exists <- doesFileExist file
1425                 if exists
1426                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1427                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1428                            text "can't find file:" <+> text file
1429         getRootSummary (Target (TargetModule modl) maybe_buf)
1430            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1431                                            (L rootLoc modl) maybe_buf excl_mods
1432                 case maybe_summary of
1433                    Nothing -> packageModErr modl
1434                    Just s  -> return s
1435
1436         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1437
1438         -- In a root module, the filename is allowed to diverge from the module
1439         -- name, so we have to check that there aren't multiple root files
1440         -- defining the same module (otherwise the duplicates will be silently
1441         -- ignored, leading to confusing behaviour).
1442         checkDuplicates :: NodeMap [ModSummary] -> IO ()
1443         checkDuplicates root_map
1444            | allow_dup_roots = return ()
1445            | null dup_roots  = return ()
1446            | otherwise       = multiRootsErr (head dup_roots)
1447            where
1448              dup_roots :: [[ModSummary]]        -- Each at least of length 2
1449              dup_roots = filterOut isSingleton (nodeMapElts root_map)
1450
1451         loop :: [(Located ModuleName,IsBootInterface)]
1452                         -- Work list: process these modules
1453              -> NodeMap [ModSummary]
1454                         -- Visited set; the range is a list because
1455                         -- the roots can have the same module names
1456                         -- if allow_dup_roots is True
1457              -> IO [ModSummary]
1458                         -- The result includes the worklist, except
1459                         -- for those mentioned in the visited set
1460         loop [] done      = return (concat (nodeMapElts done))
1461         loop ((wanted_mod, is_boot) : ss) done
1462           | Just summs <- lookupFM done key
1463           = if isSingleton summs then
1464                 loop ss done
1465             else
1466                 do { multiRootsErr summs; return [] }
1467           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1468                                                  is_boot wanted_mod Nothing excl_mods
1469                                    ; case mb_s of
1470                                         Nothing -> loop ss done
1471                                         Just s  -> loop (msDeps s ++ ss)
1472                                                         (addToFM done key [s]) }
1473           where
1474             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1475
1476 mkRootMap :: [ModSummary] -> NodeMap [ModSummary]
1477 mkRootMap summaries = addListToFM_C (++) emptyFM
1478                         [ (msKey s, [s]) | s <- summaries ]
1479
1480 msDeps :: ModSummary -> [(Located ModuleName, IsBootInterface)]
1481 -- (msDeps s) returns the dependencies of the ModSummary s.
1482 -- A wrinkle is that for a {-# SOURCE #-} import we return
1483 --      *both* the hs-boot file
1484 --      *and* the source file
1485 -- as "dependencies".  That ensures that the list of all relevant
1486 -- modules always contains B.hs if it contains B.hs-boot.
1487 -- Remember, this pass isn't doing the topological sort.  It's
1488 -- just gathering the list of all relevant ModSummaries
1489 msDeps s =
1490     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1491          ++ [ (m,False) | m <- ms_imps s ]
1492
1493 -----------------------------------------------------------------------------
1494 -- Summarising modules
1495
1496 -- We have two types of summarisation:
1497 --
1498 --    * Summarise a file.  This is used for the root module(s) passed to
1499 --      cmLoadModules.  The file is read, and used to determine the root
1500 --      module name.  The module name may differ from the filename.
1501 --
1502 --    * Summarise a module.  We are given a module name, and must provide
1503 --      a summary.  The finder is used to locate the file in which the module
1504 --      resides.
1505
1506 summariseFile
1507         :: HscEnv
1508         -> [ModSummary]                 -- old summaries
1509         -> FilePath                     -- source file name
1510         -> Maybe Phase                  -- start phase
1511         -> Maybe (StringBuffer,ClockTime)
1512         -> IO ModSummary
1513
1514 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1515         -- we can use a cached summary if one is available and the
1516         -- source file hasn't changed,  But we have to look up the summary
1517         -- by source file, rather than module name as we do in summarise.
1518    | Just old_summary <- findSummaryBySourceFile old_summaries file
1519    = do
1520         let location = ms_location old_summary
1521
1522                 -- return the cached summary if the source didn't change
1523         src_timestamp <- case maybe_buf of
1524                            Just (_,t) -> return t
1525                            Nothing    -> getModificationTime file
1526                 -- The file exists; we checked in getRootSummary above.
1527                 -- If it gets removed subsequently, then this
1528                 -- getModificationTime may fail, but that's the right
1529                 -- behaviour.
1530
1531         if ms_hs_date old_summary == src_timestamp
1532            then do -- update the object-file timestamp
1533                   obj_timestamp <- getObjTimestamp location False
1534                   return old_summary{ ms_obj_date = obj_timestamp }
1535            else
1536                 new_summary
1537
1538    | otherwise
1539    = new_summary
1540   where
1541     new_summary = do
1542         let dflags = hsc_dflags hsc_env
1543
1544         (dflags', hspp_fn, buf)
1545             <- preprocessFile dflags file mb_phase maybe_buf
1546
1547         (srcimps,the_imps, L _ mod_name) <- getImports dflags' buf hspp_fn
1548
1549         -- Make a ModLocation for this file
1550         location <- mkHomeModLocation dflags mod_name file
1551
1552         -- Tell the Finder cache where it is, so that subsequent calls
1553         -- to findModule will find it, even if it's not on any search path
1554         mod <- addHomeModuleToFinder hsc_env mod_name location
1555
1556         src_timestamp <- case maybe_buf of
1557                            Just (_,t) -> return t
1558                            Nothing    -> getModificationTime file
1559                         -- getMofificationTime may fail
1560
1561         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1562
1563         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1564                              ms_location = location,
1565                              ms_hspp_file = hspp_fn,
1566                              ms_hspp_opts = dflags',
1567                              ms_hspp_buf  = Just buf,
1568                              ms_srcimps = srcimps, ms_imps = the_imps,
1569                              ms_hs_date = src_timestamp,
1570                              ms_obj_date = obj_timestamp })
1571
1572 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1573 findSummaryBySourceFile summaries file
1574   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1575                                  expectJust "findSummaryBySourceFile" (ml_hs_file (ms_location ms)) == file ] of
1576         [] -> Nothing
1577         (x:xs) -> Just x
1578
1579 -- Summarise a module, and pick up source and timestamp.
1580 summariseModule
1581           :: HscEnv
1582           -> NodeMap ModSummary -- Map of old summaries
1583           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1584           -> Located ModuleName -- Imported module to be summarised
1585           -> Maybe (StringBuffer, ClockTime)
1586           -> [ModuleName]               -- Modules to exclude
1587           -> IO (Maybe ModSummary)      -- Its new summary
1588
1589 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1590   | wanted_mod `elem` excl_mods
1591   = return Nothing
1592
1593   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1594   = do          -- Find its new timestamp; all the
1595                 -- ModSummaries in the old map have valid ml_hs_files
1596         let location = ms_location old_summary
1597             src_fn = expectJust "summariseModule" (ml_hs_file location)
1598
1599                 -- check the modification time on the source file, and
1600                 -- return the cached summary if it hasn't changed.  If the
1601                 -- file has disappeared, we need to call the Finder again.
1602         case maybe_buf of
1603            Just (_,t) -> check_timestamp old_summary location src_fn t
1604            Nothing    -> do
1605                 m <- System.IO.Error.try (getModificationTime src_fn)
1606                 case m of
1607                    Right t -> check_timestamp old_summary location src_fn t
1608                    Left e | isDoesNotExistError e -> find_it
1609                           | otherwise             -> ioError e
1610
1611   | otherwise  = find_it
1612   where
1613     dflags = hsc_dflags hsc_env
1614
1615     hsc_src = if is_boot then HsBootFile else HsSrcFile
1616
1617     check_timestamp old_summary location src_fn src_timestamp
1618         | ms_hs_date old_summary == src_timestamp = do
1619                 -- update the object-file timestamp
1620                 obj_timestamp <- getObjTimestamp location is_boot
1621                 return (Just old_summary{ ms_obj_date = obj_timestamp })
1622         | otherwise =
1623                 -- source changed: re-summarise.
1624                 new_summary location (ms_mod old_summary) src_fn src_timestamp
1625
1626     find_it = do
1627         -- Don't use the Finder's cache this time.  If the module was
1628         -- previously a package module, it may have now appeared on the
1629         -- search path, so we want to consider it to be a home module.  If
1630         -- the module was previously a home module, it may have moved.
1631         uncacheModule hsc_env wanted_mod
1632         found <- findImportedModule hsc_env wanted_mod Nothing
1633         case found of
1634              Found location mod
1635                 | isJust (ml_hs_file location) ->
1636                         -- Home package
1637                          just_found location mod
1638                 | otherwise ->
1639                         -- Drop external-pkg
1640                         ASSERT(modulePackageId mod /= thisPackage dflags)
1641                         return Nothing
1642                 where
1643
1644              err -> noModError dflags loc wanted_mod err
1645                         -- Not found
1646
1647     just_found location mod = do
1648                 -- Adjust location to point to the hs-boot source file,
1649                 -- hi file, object file, when is_boot says so
1650         let location' | is_boot   = addBootSuffixLocn location
1651                       | otherwise = location
1652             src_fn = expectJust "summarise2" (ml_hs_file location')
1653
1654                 -- Check that it exists
1655                 -- It might have been deleted since the Finder last found it
1656         maybe_t <- modificationTimeIfExists src_fn
1657         case maybe_t of
1658           Nothing -> noHsFileErr loc src_fn
1659           Just t  -> new_summary location' mod src_fn t
1660
1661
1662     new_summary location mod src_fn src_timestamp
1663       = do
1664         -- Preprocess the source file and get its imports
1665         -- The dflags' contains the OPTIONS pragmas
1666         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1667         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1668
1669         when (mod_name /= wanted_mod) $
1670                 throwDyn $ mkPlainErrMsg mod_loc $
1671                               text "file name does not match module name"
1672                               <+> quotes (ppr mod_name)
1673
1674                 -- Find the object timestamp, and return the summary
1675         obj_timestamp <- getObjTimestamp location is_boot
1676
1677         return (Just ( ModSummary { ms_mod       = mod,
1678                                     ms_hsc_src   = hsc_src,
1679                                     ms_location  = location,
1680                                     ms_hspp_file = hspp_fn,
1681                                     ms_hspp_opts = dflags',
1682                                     ms_hspp_buf  = Just buf,
1683                                     ms_srcimps   = srcimps,
1684                                     ms_imps      = the_imps,
1685                                     ms_hs_date   = src_timestamp,
1686                                     ms_obj_date  = obj_timestamp }))
1687
1688
1689 getObjTimestamp location is_boot
1690   = if is_boot then return Nothing
1691                else modificationTimeIfExists (ml_obj_file location)
1692
1693
1694 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1695   -> IO (DynFlags, FilePath, StringBuffer)
1696 preprocessFile dflags src_fn mb_phase Nothing
1697   = do
1698         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1699         buf <- hGetStringBuffer hspp_fn
1700         return (dflags', hspp_fn, buf)
1701
1702 preprocessFile dflags src_fn mb_phase (Just (buf, time))
1703   = do
1704         -- case we bypass the preprocessing stage?
1705         let
1706             local_opts = getOptions buf src_fn
1707         --
1708         (dflags', errs) <- parseDynamicFlags dflags (map unLoc local_opts)
1709
1710         let
1711             needs_preprocessing
1712                 | Just (Unlit _) <- mb_phase    = True
1713                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1714                   -- note: local_opts is only required if there's no Unlit phase
1715                 | dopt Opt_Cpp dflags'          = True
1716                 | dopt Opt_Pp  dflags'          = True
1717                 | otherwise                     = False
1718
1719         when needs_preprocessing $
1720            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1721
1722         return (dflags', src_fn, buf)
1723
1724
1725 -----------------------------------------------------------------------------
1726 --                      Error messages
1727 -----------------------------------------------------------------------------
1728
1729 noModError :: DynFlags -> SrcSpan -> ModuleName -> FindResult -> IO ab
1730 -- ToDo: we don't have a proper line number for this error
1731 noModError dflags loc wanted_mod err
1732   = throwDyn $ mkPlainErrMsg loc $ cannotFindModule dflags wanted_mod err
1733
1734 noHsFileErr loc path
1735   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1736
1737 packageModErr mod
1738   = throwDyn $ mkPlainErrMsg noSrcSpan $
1739         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1740
1741 multiRootsErr :: [ModSummary] -> IO ()
1742 multiRootsErr summs@(summ1:_)
1743   = throwDyn $ mkPlainErrMsg noSrcSpan $
1744         text "module" <+> quotes (ppr mod) <+>
1745         text "is defined in multiple files:" <+>
1746         sep (map text files)
1747   where
1748     mod = ms_mod summ1
1749     files = map (expectJust "checkDup" . ml_hs_file . ms_location) summs
1750
1751 cyclicModuleErr :: [ModSummary] -> SDoc
1752 cyclicModuleErr ms
1753   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1754        2 (vcat (map show_one ms))
1755   where
1756     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1757                         nest 2 $ ptext SLIT("imports:") <+>
1758                                    (pp_imps HsBootFile (ms_srcimps ms)
1759                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1760     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1761     pp_imps src mods = fsep (map (show_mod src) mods)
1762
1763
1764 -- | Inform GHC that the working directory has changed.  GHC will flush
1765 -- its cache of module locations, since it may no longer be valid.
1766 -- Note: if you change the working directory, you should also unload
1767 -- the current program (set targets to empty, followed by load).
1768 workingDirectoryChanged :: Session -> IO ()
1769 workingDirectoryChanged s = withSession s $ flushFinderCaches
1770
1771 -- -----------------------------------------------------------------------------
1772 -- inspecting the session
1773
1774 -- | Get the module dependency graph.
1775 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1776 getModuleGraph s = withSession s (return . hsc_mod_graph)
1777
1778 isLoaded :: Session -> ModuleName -> IO Bool
1779 isLoaded s m = withSession s $ \hsc_env ->
1780   return $! isJust (lookupUFM (hsc_HPT hsc_env) m)
1781
1782 getBindings :: Session -> IO [TyThing]
1783 getBindings s = withSession s $ \hsc_env ->
1784    -- we have to implement the shadowing behaviour of ic_tmp_ids here
1785    -- (see InteractiveContext) and the quickest way is to use an OccEnv.
1786    let
1787        tmp_ids = ic_tmp_ids (hsc_IC hsc_env)
1788        filtered = foldr f (const []) tmp_ids emptyUniqSet
1789        f id rest set
1790            | uniq `elementOfUniqSet` set = rest set
1791            | otherwise  = AnId id : rest (addOneToUniqSet set uniq)
1792            where uniq = getUnique (nameOccName (idName id))
1793    in
1794    return filtered
1795
1796 getPrintUnqual :: Session -> IO PrintUnqualified
1797 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1798
1799 -- | Container for information about a 'Module'.
1800 data ModuleInfo = ModuleInfo {
1801         minf_type_env  :: TypeEnv,
1802         minf_exports   :: NameSet, -- ToDo, [AvailInfo] like ModDetails?
1803         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1804         minf_instances :: [Instance]
1805 #ifdef GHCI
1806         ,minf_modBreaks :: ModBreaks
1807 #endif
1808         -- ToDo: this should really contain the ModIface too
1809   }
1810         -- We don't want HomeModInfo here, because a ModuleInfo applies
1811         -- to package modules too.
1812
1813 -- | Request information about a loaded 'Module'
1814 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1815 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1816   let mg = hsc_mod_graph hsc_env
1817   if mdl `elem` map ms_mod mg
1818         then getHomeModuleInfo hsc_env (moduleName mdl)
1819         else do
1820   {- if isHomeModule (hsc_dflags hsc_env) mdl
1821         then return Nothing
1822         else -} getPackageModuleInfo hsc_env mdl
1823    -- getPackageModuleInfo will attempt to find the interface, so
1824    -- we don't want to call it for a home module, just in case there
1825    -- was a problem loading the module and the interface doesn't
1826    -- exist... hence the isHomeModule test here.  (ToDo: reinstate)
1827
1828 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1829 getPackageModuleInfo hsc_env mdl = do
1830 #ifdef GHCI
1831   (_msgs, mb_avails) <- getModuleExports hsc_env mdl
1832   case mb_avails of
1833     Nothing -> return Nothing
1834     Just avails -> do
1835         eps <- readIORef (hsc_EPS hsc_env)
1836         let
1837             names  = availsToNameSet avails
1838             pte    = eps_PTE eps
1839             tys    = [ ty | name <- concatMap availNames avails,
1840                             Just ty <- [lookupTypeEnv pte name] ]
1841         --
1842         return (Just (ModuleInfo {
1843                         minf_type_env  = mkTypeEnv tys,
1844                         minf_exports   = names,
1845                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names (moduleName mdl),
1846                         minf_instances = error "getModuleInfo: instances for package module unimplemented",
1847                         minf_modBreaks = emptyModBreaks
1848                 }))
1849 #else
1850   -- bogusly different for non-GHCI (ToDo)
1851   return Nothing
1852 #endif
1853
1854 getHomeModuleInfo hsc_env mdl =
1855   case lookupUFM (hsc_HPT hsc_env) mdl of
1856     Nothing  -> return Nothing
1857     Just hmi -> do
1858       let details = hm_details hmi
1859       return (Just (ModuleInfo {
1860                         minf_type_env  = md_types details,
1861                         minf_exports   = availsToNameSet (md_exports details),
1862                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1863                         minf_instances = md_insts details
1864 #ifdef GHCI
1865                        ,minf_modBreaks = md_modBreaks details
1866 #endif
1867                         }))
1868
1869 -- | The list of top-level entities defined in a module
1870 modInfoTyThings :: ModuleInfo -> [TyThing]
1871 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1872
1873 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1874 modInfoTopLevelScope minf
1875   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1876
1877 modInfoExports :: ModuleInfo -> [Name]
1878 modInfoExports minf = nameSetToList $! minf_exports minf
1879
1880 -- | Returns the instances defined by the specified module.
1881 -- Warning: currently unimplemented for package modules.
1882 modInfoInstances :: ModuleInfo -> [Instance]
1883 modInfoInstances = minf_instances
1884
1885 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1886 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1887
1888 modInfoPrintUnqualified :: ModuleInfo -> Maybe PrintUnqualified
1889 modInfoPrintUnqualified minf = fmap mkPrintUnqualified (minf_rdr_env minf)
1890
1891 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1892 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1893    case lookupTypeEnv (minf_type_env minf) name of
1894      Just tyThing -> return (Just tyThing)
1895      Nothing      -> do
1896        eps <- readIORef (hsc_EPS hsc_env)
1897        return $! lookupType (hsc_dflags hsc_env)
1898                             (hsc_HPT hsc_env) (eps_PTE eps) name
1899
1900 #ifdef GHCI
1901 modInfoModBreaks = minf_modBreaks
1902 #endif
1903
1904 isDictonaryId :: Id -> Bool
1905 isDictonaryId id
1906   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1907
1908 -- | Looks up a global name: that is, any top-level name in any
1909 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
1910 -- the interactive context, and therefore does not require a preceding
1911 -- 'setContext'.
1912 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
1913 lookupGlobalName s name = withSession s $ \hsc_env -> do
1914    eps <- readIORef (hsc_EPS hsc_env)
1915    return $! lookupType (hsc_dflags hsc_env)
1916                         (hsc_HPT hsc_env) (eps_PTE eps) name
1917
1918 -- -----------------------------------------------------------------------------
1919 -- Misc exported utils
1920
1921 dataConType :: DataCon -> Type
1922 dataConType dc = idType (dataConWrapId dc)
1923
1924 -- | print a 'NamedThing', adding parentheses if the name is an operator.
1925 pprParenSymName :: NamedThing a => a -> SDoc
1926 pprParenSymName a = parenSymOcc (getOccName a) (ppr (getName a))
1927
1928 -- ----------------------------------------------------------------------------
1929
1930 #if 0
1931
1932 -- ToDo:
1933 --   - Data and Typeable instances for HsSyn.
1934
1935 -- ToDo: check for small transformations that happen to the syntax in
1936 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1937
1938 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1939 -- to get from TyCons, Ids etc. to TH syntax (reify).
1940
1941 -- :browse will use either lm_toplev or inspect lm_interface, depending
1942 -- on whether the module is interpreted or not.
1943
1944 -- This is for reconstructing refactored source code
1945 -- Calls the lexer repeatedly.
1946 -- ToDo: add comment tokens to token stream
1947 getTokenStream :: Session -> Module -> IO [Located Token]
1948 #endif
1949
1950 -- -----------------------------------------------------------------------------
1951 -- Interactive evaluation
1952
1953 -- | Takes a 'ModuleName' and possibly a 'PackageId', and consults the
1954 -- filesystem and package database to find the corresponding 'Module',
1955 -- using the algorithm that is used for an @import@ declaration.
1956 findModule :: Session -> ModuleName -> Maybe PackageId -> IO Module
1957 findModule s mod_name maybe_pkg = withSession s $ \hsc_env ->
1958   findModule' hsc_env mod_name maybe_pkg
1959
1960 findModule' hsc_env mod_name maybe_pkg =
1961   let
1962         dflags = hsc_dflags hsc_env
1963         hpt    = hsc_HPT hsc_env
1964         this_pkg = thisPackage dflags
1965   in
1966   case lookupUFM hpt mod_name of
1967     Just mod_info -> return (mi_module (hm_iface mod_info))
1968     _not_a_home_module -> do
1969           res <- findImportedModule hsc_env mod_name maybe_pkg
1970           case res of
1971             Found _ m | modulePackageId m /= this_pkg -> return m
1972                       | otherwise -> throwDyn (CmdLineError (showSDoc $
1973                                         text "module" <+> pprModule m <+>
1974                                         text "is not loaded"))
1975             err -> let msg = cannotFindModule dflags mod_name err in
1976                    throwDyn (CmdLineError (showSDoc msg))