compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         -- * Sessions and compilation state
   9         Session(..), HscEnv(..), hscEPS,
  10         FinderCache, FindResult(..), ModLocationCache,
  11         Target(..), TargetId(..), pprTarget, pprTargetId,
  12         ModuleGraph, emptyMG,
  13
  14         ModDetails(..), emptyModDetails,
  15         ModGuts(..), CgGuts(..), ModImports(..), ForeignStubs(..),
  16
  17         ModSummary(..), showModMsg, isBootSummary,
  18         msHsFilePath, msHiFilePath, msObjFilePath,
  19
  20         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
  21
  22         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
  23         hptInstances, hptRules,
  24
  25         ExternalPackageState(..), EpsStats(..), addEpsInStats,
  26         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
  27         lookupIfaceByModule, emptyModIface,
  28
  29         InteractiveContext(..), emptyInteractiveContext,
  30         icPrintUnqual, mkPrintUnqualified,
  31
  32         ModIface(..), mkIfaceDepCache, mkIfaceVerCache, mkIfaceFixCache,
  33         emptyIfaceDepCache,
  34
  35         Deprecs(..), IfaceDeprecs,
  36
  37         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
  38
  39         implicitTyThings, isImplicitTyThing,
  40
  41         TyThing(..), tyThingClass, tyThingTyCon, tyThingDataCon, tyThingId,
  42         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  43         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
  44         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  45         typeEnvDataCons,
  46
  47         WhetherHasOrphans, IsBootInterface, Usage(..),
  48         Dependencies(..), noDependencies,
  49         NameCache(..), OrigNameCache, OrigIParamCache,
  50         Avails, availsToNameSet, availsToNameEnv, availName, availNames,
  51         GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  52         IfaceExport,
  53
  54         Deprecations, DeprecTxt, lookupDeprec, plusDeprecs,
  55
  56         PackageInstEnv, PackageRuleBase,
  57
  58         -- Linker stuff
  59         Linkable(..), isObjectLinkable,
  60         Unlinked(..), CompiledByteCode,
  61         isObject, nameOfObject, isInterpretable, byteCodeOfObject
  62     ) where
  63
  64 #include "HsVersions.h"
  65
  66 #ifdef GHCI
  67 import ByteCodeAsm      ( CompiledByteCode )
  68 #endif
  69
  70 import RdrName          ( GlobalRdrEnv, emptyGlobalRdrEnv,
  71                           LocalRdrEnv, emptyLocalRdrEnv, GlobalRdrElt(..),
  72                           unQualOK, ImpDeclSpec(..), Provenance(..),
  73                           ImportSpec(..), lookupGlobalRdrEnv )
  74 import Name             ( Name, NamedThing, getName, nameOccName, nameModule )
  75 import NameEnv
  76 import NameSet
  77 import OccName          ( OccName, OccEnv, lookupOccEnv, mkOccEnv, emptyOccEnv,
  78                           extendOccEnv )
  79 import Module
  80 import InstEnv          ( InstEnv, Instance )
  81 import FamInstEnv       ( FamInstEnv, FamInst )
  82 import Rules            ( RuleBase )
  83 import CoreSyn          ( CoreBind )
  84 import Id               ( Id, isImplicitId )
  85 import Type             ( TyThing(..) )
  86
  87 import Class            ( Class, classSelIds, classATs, classTyCon )
  88 import TyCon
  89 import DataCon          ( DataCon, dataConImplicitIds )
  90 import PrelNames        ( gHC_PRIM )
  91 import Packages         ( PackageId )
  92 import DynFlags         ( DynFlags(..), isOneShot, HscTarget (..) )
  93 import DriverPhases     ( HscSource(..), isHsBoot, hscSourceString, Phase )
  94 import BasicTypes       ( Version, initialVersion, IPName,
  95                           Fixity, defaultFixity, DeprecTxt )
  96 import IfaceSyn
  97 import FiniteMap        ( FiniteMap )
  98 import CoreSyn          ( CoreRule )
  99 import Maybes           ( orElse, expectJust )
 100 import Outputable
 101 import SrcLoc           ( SrcSpan, Located )
 102 import UniqFM           ( lookupUFM, eltsUFM, emptyUFM )
 103 import UniqSupply       ( UniqSupply )
 104 import FastString       ( FastString )
 105
 106 import StringBuffer     ( StringBuffer )
 107 import Maybes           ( catMaybes, seqMaybe )
 108
 109 import System.Time      ( ClockTime )
 110 import Data.IORef       ( IORef, readIORef )
 111 \end{code}
 112
 113
 114 %************************************************************************
 115 %*                                                                      *
 116 \subsection{Compilation environment}
 117 %*                                                                      *
 118 %************************************************************************
 119
 120
 121 \begin{code}
 122 -- | The Session is a handle to the complete state of a compilation
 123 -- session.  A compilation session consists of a set of modules
 124 -- constituting the current program or library, the context for
 125 -- interactive evaluation, and various caches.
 126 newtype Session = Session (IORef HscEnv)
 127 \end{code}
 128
 129 HscEnv is like Session, except that some of the fields are immutable.
 130 An HscEnv is used to compile a single module from plain Haskell source
 131 code (after preprocessing) to either C, assembly or C--.  Things like
 132 the module graph don't change during a single compilation.
 133
 134 Historical note: "hsc" used to be the name of the compiler binary,
 135 when there was a separate driver and compiler.  To compile a single
 136 module, the driver would invoke hsc on the source code... so nowadays
 137 we think of hsc as the layer of the compiler that deals with compiling
 138 a single module.
 139
 140 \begin{code}
 141 data HscEnv
 142   = HscEnv {
 143         hsc_dflags :: DynFlags,
 144                 -- The dynamic flag settings
 145
 146         hsc_targets :: [Target],
 147                 -- The targets (or roots) of the current session
 148
 149         hsc_mod_graph :: ModuleGraph,
 150                 -- The module graph of the current session
 151
 152         hsc_IC :: InteractiveContext,
 153                 -- The context for evaluating interactive statements
 154
 155         hsc_HPT    :: HomePackageTable,
 156                 -- The home package table describes already-compiled
 157                 -- home-packge modules, *excluding* the module we
 158                 -- are compiling right now.
 159                 -- (In one-shot mode the current module is the only
 160                 --  home-package module, so hsc_HPT is empty.  All other
 161                 --  modules count as "external-package" modules.
 162                 --  However, even in GHCi mode, hi-boot interfaces are
 163                 --  demand-loadeded into the external-package table.)
 164                 --
 165                 -- hsc_HPT is not mutable because we only demand-load
 166                 -- external packages; the home package is eagerly
 167                 -- loaded, module by module, by the compilation manager.
 168                 --
 169                 -- The HPT may contain modules compiled earlier by --make
 170                 -- but not actually below the current module in the dependency
 171                 -- graph.  (This changes a previous invariant: changed Jan 05.)
 172
 173         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
 174         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
 175                 -- These are side-effected by compiling to reflect
 176                 -- sucking in interface files.  They cache the state of
 177                 -- external interface files, in effect.
 178
 179         hsc_FC   :: {-# UNPACK #-} !(IORef FinderCache),
 180         hsc_MLC  :: {-# UNPACK #-} !(IORef ModLocationCache),
 181                 -- The finder's cache.  This caches the location of modules,
 182                 -- so we don't have to search the filesystem multiple times.
 183
 184         hsc_global_rdr_env :: GlobalRdrEnv,
 185         hsc_global_type_env :: TypeEnv
 186  }
 187
 188 hscEPS :: HscEnv -> IO ExternalPackageState
 189 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
 190
 191 -- | A compilation target.
 192 --
 193 -- A target may be supplied with the actual text of the
 194 -- module.  If so, use this instead of the file contents (this
 195 -- is for use in an IDE where the file hasn't been saved by
 196 -- the user yet).
 197 data Target = Target TargetId (Maybe (StringBuffer,ClockTime))
 198
 199 data TargetId
 200   = TargetModule ModuleName
 201         -- ^ A module name: search for the file
 202   | TargetFile FilePath (Maybe Phase)
 203         -- ^ A filename: preprocess & parse it to find the module name.
 204         -- If specified, the Phase indicates how to compile this file
 205         -- (which phase to start from).  Nothing indicates the starting phase
 206         -- should be determined from the suffix of the filename.
 207   deriving Eq
 208
 209 pprTarget :: Target -> SDoc
 210 pprTarget (Target id _) = pprTargetId id
 211
 212 pprTargetId (TargetModule m) = ppr m
 213 pprTargetId (TargetFile f _) = text f
 214
 215 type HomePackageTable  = ModuleNameEnv HomeModInfo
 216         -- Domain = modules in the home package
 217         -- "home" package name cached here for convenience
 218 type PackageIfaceTable = ModuleEnv ModIface
 219         -- Domain = modules in the imported packages
 220
 221 emptyHomePackageTable  = emptyUFM
 222 emptyPackageIfaceTable = emptyModuleEnv
 223
 224 data HomeModInfo
 225   = HomeModInfo { hm_iface    :: !ModIface,
 226                   hm_details  :: !ModDetails,
 227                   hm_linkable :: !(Maybe Linkable) }
 228                 -- hm_linkable might be Nothing if:
 229                 --   a) this is an .hs-boot module
 230                 --   b) temporarily during compilation if we pruned away
 231                 --      the old linkable because it was out of date.
 232                 -- after a complete compilation (GHC.load), all hm_linkable
 233                 -- fields in the HPT will be Just.
 234                 --
 235                 -- When re-linking a module (hscNoRecomp), we construct
 236                 -- the HomModInfo by building a new ModDetails from the
 237                 -- old ModIface (only).
 238
 239 -- | Find the 'ModIface' for a 'Module'
 240 lookupIfaceByModule
 241         :: DynFlags
 242         -> HomePackageTable
 243         -> PackageIfaceTable
 244         -> Module
 245         -> Maybe ModIface
 246 lookupIfaceByModule dflags hpt pit mod
 247   | modulePackageId mod == thisPackage dflags
 248   =     -- The module comes from the home package, so look first
 249         -- in the HPT.  If it's not from the home package it's wrong to look
 250         -- in the HPT, because the HPT is indexed by *ModuleName* not Module
 251     fmap hm_iface (lookupUFM hpt (moduleName mod))
 252     `seqMaybe` lookupModuleEnv pit mod
 253
 254   | otherwise = lookupModuleEnv pit mod         -- Look in PIT only
 255
 256 -- If the module does come from the home package, why do we look in the PIT as well?
 257 -- (a) In OneShot mode, even home-package modules accumulate in the PIT
 258 -- (b) Even in Batch (--make) mode, there is *one* case where a home-package
 259 --     module is in the PIT, namely GHC.Prim when compiling the base package.
 260 -- We could eliminate (b) if we wanted, by making GHC.Prim belong to a packake
 261 -- of its own, but it doesn't seem worth the bother.
 262 \end{code}
 263
 264
 265 \begin{code}
 266 hptInstances :: HscEnv -> (ModuleName -> Bool) -> [Instance]
 267 -- Find all the instance declarations that are in modules imported
 268 -- by this one, directly or indirectly, and are in the Home Package Table
 269 -- This ensures that we don't see instances from modules --make compiled
 270 -- before this one, but which are not below this one
 271 hptInstances hsc_env want_this_module
 272   = [ ispec
 273     | mod_info <- eltsUFM (hsc_HPT hsc_env)
 274     , want_this_module (moduleName (mi_module (hm_iface mod_info)))
 275     , ispec <- md_insts (hm_details mod_info) ]
 276
 277 hptRules :: HscEnv -> [(ModuleName, IsBootInterface)] -> [CoreRule]
 278 -- Get rules from modules "below" this one (in the dependency sense)
 279 -- C.f Inst.hptInstances
 280 hptRules hsc_env deps
 281   | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
 282   | otherwise
 283   = let
 284         hpt = hsc_HPT hsc_env
 285     in
 286     [ rule
 287     |   -- Find each non-hi-boot module below me
 288       (mod, False) <- deps
 289
 290         -- unsavoury: when compiling the base package with --make, we
 291         -- sometimes try to look up RULES for GHC.Prim.  GHC.Prim won't
 292         -- be in the HPT, because we never compile it; it's in the EPT
 293         -- instead.  ToDo: clean up, and remove this slightly bogus
 294         -- filter:
 295     , mod /= moduleName gHC_PRIM
 296
 297         -- Look it up in the HPT
 298     , let mod_info = case lookupUFM hpt mod of
 299                         Nothing -> pprPanic "hptRules" (ppr mod <+> ppr deps)
 300                         Just x  -> x
 301
 302         -- And get its dfuns
 303     , rule <- md_rules (hm_details mod_info) ]
 304 \end{code}
 305
 306 %************************************************************************
 307 %*                                                                      *
 308 \subsection{The Finder cache}
 309 %*                                                                      *
 310 %************************************************************************
 311
 312 \begin{code}
 313 -- | The 'FinderCache' maps home module names to the result of
 314 -- searching for that module.  It records the results of searching for
 315 -- modules along the search path.  On @:load@, we flush the entire
 316 -- contents of this cache.
 317 --
 318 -- Although the @FinderCache@ range is 'FindResult' for convenience ,
 319 -- in fact it will only ever contain 'Found' or 'NotFound' entries.
 320 --
 321 type FinderCache = ModuleNameEnv FindResult
 322
 323 -- | The result of searching for an imported module.
 324 data FindResult
 325   = Found ModLocation Module
 326         -- the module was found
 327   | NoPackage PackageId
 328         -- the requested package was not found
 329   | FoundMultiple [PackageId]
 330         -- *error*: both in multiple packages
 331   | PackageHidden PackageId
 332         -- for an explicit source import: the package containing the module is
 333         -- not exposed.
 334   | ModuleHidden  PackageId
 335         -- for an explicit source import: the package containing the module is
 336         -- exposed, but the module itself is hidden.
 337   | NotFound [FilePath] (Maybe PackageId)
 338         -- the module was not found, the specified places were searched
 339   | NotFoundInPackage PackageId
 340         -- the module was not found in this package
 341
 342 -- | Cache that remembers where we found a particular module.  Contains both
 343 -- home modules and package modules.  On @:load@, only home modules are
 344 -- purged from this cache.
 345 type ModLocationCache = ModuleEnv ModLocation
 346 \end{code}
 347
 348 %************************************************************************
 349 %*                                                                      *
 350 \subsection{Symbol tables and Module details}
 351 %*                                                                      *
 352 %************************************************************************
 353
 354 A @ModIface@ plus a @ModDetails@ summarises everything we know
 355 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 356 and can be written out to an interface file.  (The @ModDetails@ is after
 357 linking; it is the "linked" form of the mi_decls field.)
 358
 359 When we *read* an interface file, we also construct a @ModIface@ from it,
 360 except that the mi_decls part is empty; when reading we consolidate
 361 the declarations into a single indexed map in the @PersistentRenamerState@.
 362
 363 \begin{code}
 364 data ModIface
 365    = ModIface {
 366         mi_module   :: !Module,
 367         mi_mod_vers :: !Version,            -- Module version: changes when anything changes
 368
 369         mi_orphan   :: !WhetherHasOrphans,  -- Whether this module has orphans
 370         mi_boot     :: !IsBootInterface,    -- Read from an hi-boot file?
 371
 372         mi_deps     :: Dependencies,
 373                 -- This is consulted for directly-imported modules,
 374                 -- but not for anything else (hence lazy)
 375
 376                 -- Usages; kept sorted so that it's easy to decide
 377                 -- whether to write a new iface file (changing usages
 378                 -- doesn't affect the version of this module)
 379         mi_usages   :: [Usage],
 380                 -- NOT STRICT!  we read this field lazily from the interface file
 381                 -- It is *only* consulted by the recompilation checker
 382
 383                 -- Exports
 384                 -- Kept sorted by (mod,occ), to make version comparisons easier
 385         mi_exports  :: ![IfaceExport],
 386         mi_exp_vers :: !Version,        -- Version number of export list
 387
 388                 -- Fixities
 389         mi_fixities :: [(OccName,Fixity)],
 390                 -- NOT STRICT!  we read this field lazily from the interface file
 391
 392                 -- Deprecations
 393         mi_deprecs  :: IfaceDeprecs,
 394                 -- NOT STRICT!  we read this field lazily from the interface file
 395
 396                 -- Type, class and variable declarations
 397                 -- The version of an Id changes if its fixity or deprecations change
 398                 --      (as well as its type of course)
 399                 -- Ditto data constructors, class operations, except that
 400                 -- the version of the parent class/tycon changes
 401         mi_decls :: [(Version,IfaceDecl)],      -- Sorted
 402
 403         mi_globals  :: !(Maybe GlobalRdrEnv),
 404                 -- Binds all the things defined at the top level in
 405                 -- the *original source* code for this module. which
 406                 -- is NOT the same as mi_exports, nor mi_decls (which
 407                 -- may contains declarations for things not actually
 408                 -- defined by the user).  Used for GHCi and for inspecting
 409                 -- the contents of modules via the GHC API only.
 410                 --
 411                 -- (We need the source file to figure out the
 412                 -- top-level environment, if we didn't compile this module
 413                 -- from source then this field contains Nothing).
 414                 --
 415                 -- Strictly speaking this field should live in the
 416                 -- HomeModInfo, but that leads to more plumbing.
 417
 418                 -- Instance declarations and rules
 419         mi_insts     :: [IfaceInst],                    -- Sorted
 420         mi_fam_insts :: [IfaceFamInst],                 -- Sorted
 421         mi_rules     :: [IfaceRule],                    -- Sorted
 422         mi_rule_vers :: !Version,       -- Version number for rules and
 423                                         -- instances combined
 424
 425                 -- Cached environments for easy lookup
 426                 -- These are computed (lazily) from other fields
 427                 -- and are not put into the interface file
 428         mi_dep_fn  :: Name -> Maybe DeprecTxt,  -- Cached lookup for mi_deprecs
 429         mi_fix_fn  :: OccName -> Fixity,        -- Cached lookup for mi_fixities
 430         mi_ver_fn  :: OccName -> Maybe (OccName, Version)
 431                         -- Cached lookup for mi_decls
 432                         -- The Nothing in mi_ver_fn means that the thing
 433                         -- isn't in decls. It's useful to know that when
 434                         -- seeing if we are up to date wrt the old interface
 435                         -- The 'OccName' is the parent of the name, if it has one.
 436      }
 437
 438 -- Should be able to construct ModDetails from mi_decls in ModIface
 439 data ModDetails
 440    = ModDetails {
 441         -- The next three fields are created by the typechecker
 442         md_exports  :: [AvailInfo],
 443         md_types    :: !TypeEnv,
 444         md_fam_insts :: ![FamInst],     -- Cached value extracted from md_types
 445         md_insts    :: ![Instance],     -- Dfun-ids for the instances in this module
 446         md_rules    :: ![CoreRule]      -- Domain may include Ids from other modules
 447      }
 448
 449 emptyModDetails = ModDetails { md_types = emptyTypeEnv,
 450                                md_exports = [],
 451                                md_insts     = [],
 452                                md_rules     = [],
 453                                md_fam_insts = [] }
 454
 455 -- A ModGuts is carried through the compiler, accumulating stuff as it goes
 456 -- There is only one ModGuts at any time, the one for the module
 457 -- being compiled right now.  Once it is compiled, a ModIface and
 458 -- ModDetails are extracted and the ModGuts is dicarded.
 459
 460 data ModGuts
 461   = ModGuts {
 462         mg_module    :: !Module,
 463         mg_boot      :: IsBootInterface, -- Whether it's an hs-boot module
 464         mg_exports   :: ![AvailInfo],    -- What it exports
 465         mg_deps      :: !Dependencies,   -- What is below it, directly or
 466                                          --   otherwise
 467         mg_dir_imps  :: ![Module],       -- Directly-imported modules; used to
 468                                          --     generate initialisation code
 469         mg_usages    :: ![Usage],        -- Version info for what it needed
 470
 471         mg_rdr_env   :: !GlobalRdrEnv,   -- Top-level lexical environment
 472         mg_fix_env   :: !FixityEnv,      -- Fixity env, for things declared in
 473                                          --   this module
 474         mg_deprecs   :: !Deprecations,   -- Deprecations declared in the module
 475
 476         mg_types     :: !TypeEnv,
 477         mg_insts     :: ![Instance],     -- Instances
 478         mg_fam_insts :: ![FamInst],      -- Instances
 479         mg_rules     :: ![CoreRule],     -- Rules from this module
 480         mg_binds     :: ![CoreBind],     -- Bindings for this module
 481         mg_foreign   :: !ForeignStubs
 482     }
 483
 484 -- The ModGuts takes on several slightly different forms:
 485 --
 486 -- After simplification, the following fields change slightly:
 487 --      mg_rules        Orphan rules only (local ones now attached to binds)
 488 --      mg_binds        With rules attached
 489
 490
 491 ---------------------------------------------------------
 492 -- The Tidy pass forks the information about this module:
 493 --      * one lot goes to interface file generation (ModIface)
 494 --        and later compilations (ModDetails)
 495 --      * the other lot goes to code generation (CgGuts)
 496 data CgGuts
 497   = CgGuts {
 498         cg_module   :: !Module,
 499
 500         cg_tycons   :: [TyCon],
 501                 -- Algebraic data types (including ones that started
 502                 -- life as classes); generate constructors and info
 503                 -- tables Includes newtypes, just for the benefit of
 504                 -- External Core
 505
 506         cg_binds    :: [CoreBind],
 507                 -- The tidied main bindings, including
 508                 -- previously-implicit bindings for record and class
 509                 -- selectors, and data construtor wrappers.  But *not*
 510                 -- data constructor workers; reason: we we regard them
 511                 -- as part of the code-gen of tycons
 512
 513         cg_dir_imps :: ![Module],
 514                 -- Directly-imported modules; used to generate
 515                 -- initialisation code
 516
 517         cg_foreign  :: !ForeignStubs,
 518         cg_dep_pkgs :: ![PackageId]     -- Used to generate #includes for C code gen
 519     }
 520
 521 -----------------------------------
 522 data ModImports
 523   = ModImports {
 524         imp_direct     :: ![(Module,Bool)],     -- Explicitly-imported modules
 525                                                 -- Boolean is true if we imported the whole
 526                                                 --      module (apart, perhaps, from hiding some)
 527         imp_pkg_mods   :: !ModuleSet,           -- Non-home-package modules on which we depend,
 528                                                 --      directly or indirectly
 529         imp_home_names :: !NameSet              -- Home package things on which we depend,
 530                                                 --      directly or indirectly
 531     }
 532
 533 -----------------------------------
 534 data ForeignStubs = NoStubs
 535                   | ForeignStubs
 536                         SDoc            -- Header file prototypes for
 537                                         --      "foreign exported" functions
 538                         SDoc            -- C stubs to use when calling
 539                                         --      "foreign exported" functions
 540                         [FastString]    -- Headers that need to be included
 541                                         --      into C code generated for this module
 542                         [Id]            -- Foreign-exported binders
 543                                         --      we have to generate code to register these
 544
 545 \end{code}
 546
 547 \begin{code}
 548 emptyModIface :: Module -> ModIface
 549 emptyModIface mod
 550   = ModIface { mi_module   = mod,
 551                mi_mod_vers = initialVersion,
 552                mi_orphan   = False,
 553                mi_boot     = False,
 554                mi_deps     = noDependencies,
 555                mi_usages   = [],
 556                mi_exports  = [],
 557                mi_exp_vers = initialVersion,
 558                mi_fixities = [],
 559                mi_deprecs  = NoDeprecs,
 560                mi_insts     = [],
 561                mi_fam_insts = [],
 562                mi_rules     = [],
 563                mi_decls     = [],
 564                mi_globals   = Nothing,
 565                mi_rule_vers = initialVersion,
 566                mi_dep_fn = emptyIfaceDepCache,
 567                mi_fix_fn = emptyIfaceFixCache,
 568                mi_ver_fn = emptyIfaceVerCache
 569     }
 570 \end{code}
 571
 572
 573 %************************************************************************
 574 %*                                                                      *
 575 \subsection{The interactive context}
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 \begin{code}
 580 data InteractiveContext
 581   = InteractiveContext {
 582         ic_toplev_scope :: [Module],    -- Include the "top-level" scope of
 583                                         -- these modules
 584
 585         ic_exports :: [Module],         -- Include just the exports of these
 586                                         -- modules
 587
 588         ic_rn_gbl_env :: GlobalRdrEnv,  -- The cached GlobalRdrEnv, built from
 589                                         -- ic_toplev_scope and ic_exports
 590
 591         ic_rn_local_env :: LocalRdrEnv, -- Lexical context for variables bound
 592                                         -- during interaction
 593
 594         ic_type_env :: TypeEnv          -- Ditto for types
 595     }
 596
 597 emptyInteractiveContext
 598   = InteractiveContext { ic_toplev_scope = [],
 599                          ic_exports = [],
 600                          ic_rn_gbl_env = emptyGlobalRdrEnv,
 601                          ic_rn_local_env = emptyLocalRdrEnv,
 602                          ic_type_env = emptyTypeEnv }
 603
 604 icPrintUnqual :: InteractiveContext -> PrintUnqualified
 605 icPrintUnqual ictxt = mkPrintUnqualified (ic_rn_gbl_env ictxt)
 606 \end{code}
 607
 608 %************************************************************************
 609 %*                                                                      *
 610         Building a PrintUnqualified
 611 %*                                                                      *
 612 %************************************************************************
 613
 614 \begin{code}
 615 mkPrintUnqualified :: GlobalRdrEnv -> PrintUnqualified
 616 mkPrintUnqualified env = (qual_name, qual_mod)
 617   where
 618   qual_name mod occ
 619         | null gres = Just (moduleName mod)
 620                 -- it isn't in scope at all, this probably shouldn't happen,
 621                 -- but we'll qualify it by the original module anyway.
 622         | any unQualOK gres = Nothing
 623         | (Imported is : _) <- map gre_prov gres, (idecl : _) <- is
 624           = Just (is_as (is_decl idecl))
 625         | otherwise = panic "mkPrintUnqualified"
 626       where
 627         gres  = [ gre | gre <- lookupGlobalRdrEnv env occ,
 628                         nameModule (gre_name gre) == mod ]
 629
 630   qual_mod mod = Nothing       -- For now...
 631 \end{code}
 632
 633
 634 %************************************************************************
 635 %*                                                                      *
 636                 TyThing
 637 %*                                                                      *
 638 %************************************************************************
 639
 640 \begin{code}
 641 implicitTyThings :: TyThing -> [TyThing]
 642 -- If you change this, make sure you change LoadIface.ifaceDeclSubBndrs in sync
 643
 644 implicitTyThings (AnId id)   = []
 645
 646         -- For type constructors, add the data cons (and their extras),
 647         -- and the selectors and generic-programming Ids too
 648         --
 649         -- Newtypes don't have a worker Id, so don't generate that?
 650 implicitTyThings (ATyCon tc) = implicitCoTyCon tc ++
 651                                map AnId (tyConSelIds tc) ++
 652                                concatMap (extras_plus . ADataCon)
 653                                          (tyConDataCons tc)
 654
 655         -- For classes, add the class TyCon too (and its extras)
 656         -- and the class selector Ids and the associated types (they don't
 657         -- have extras as these are only the family decls)
 658 implicitTyThings (AClass cl) = map AnId (classSelIds cl) ++
 659                                map ATyCon (classATs cl) ++
 660                                extras_plus (ATyCon (classTyCon cl))
 661
 662         -- For data cons add the worker and wrapper (if any)
 663 implicitTyThings (ADataCon dc) = map AnId (dataConImplicitIds dc)
 664
 665 -- | returns 'True' if there should be no interface-file declaration
 666 -- for this thing on its own: either it is built-in, or it is part
 667 -- of some other declaration, or it is generated implicitly by some
 668 -- other declaration.
 669 isImplicitTyThing :: TyThing -> Bool
 670 isImplicitTyThing (ADataCon _)  = True
 671 isImplicitTyThing (AnId     id) = isImplicitId id
 672 isImplicitTyThing (AClass   _)  = False
 673 isImplicitTyThing (ATyCon   tc) = isImplicitTyCon tc
 674
 675         -- For newtypes and indexed data types, add the implicit coercion tycon
 676 implicitCoTyCon tc
 677   = map ATyCon . catMaybes $ [newTyConCo_maybe tc,
 678                               tyConFamilyCoercion_maybe tc]
 679
 680 extras_plus thing = thing : implicitTyThings thing
 681
 682 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 683 extendTypeEnvWithIds env ids
 684   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 685 \end{code}
 686
 687 %************************************************************************
 688 %*                                                                      *
 689                 TypeEnv
 690 %*                                                                      *
 691 %************************************************************************
 692
 693 \begin{code}
 694 type TypeEnv = NameEnv TyThing
 695
 696 emptyTypeEnv    :: TypeEnv
 697 typeEnvElts     :: TypeEnv -> [TyThing]
 698 typeEnvClasses  :: TypeEnv -> [Class]
 699 typeEnvTyCons   :: TypeEnv -> [TyCon]
 700 typeEnvIds      :: TypeEnv -> [Id]
 701 typeEnvDataCons :: TypeEnv -> [DataCon]
 702 lookupTypeEnv   :: TypeEnv -> Name -> Maybe TyThing
 703
 704 emptyTypeEnv        = emptyNameEnv
 705 typeEnvElts     env = nameEnvElts env
 706 typeEnvClasses  env = [cl | AClass cl   <- typeEnvElts env]
 707 typeEnvTyCons   env = [tc | ATyCon tc   <- typeEnvElts env]
 708 typeEnvIds      env = [id | AnId id     <- typeEnvElts env]
 709 typeEnvDataCons env = [dc | ADataCon dc <- typeEnvElts env]
 710
 711 mkTypeEnv :: [TyThing] -> TypeEnv
 712 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 713
 714 lookupTypeEnv = lookupNameEnv
 715
 716 -- Extend the type environment
 717 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
 718 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
 719
 720 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 721 extendTypeEnvList env things = foldl extendTypeEnv env things
 722 \end{code}
 723
 724 \begin{code}
 725 lookupType :: DynFlags
 726            -> HomePackageTable
 727            -> PackageTypeEnv
 728            -> Name
 729            -> Maybe TyThing
 730
 731 lookupType dflags hpt pte name
 732   -- in one-shot, we don't use the HPT
 733   | not (isOneShot (ghcMode dflags)) && modulePackageId mod == this_pkg
 734   = do hm <- lookupUFM hpt (moduleName mod) -- Maybe monad
 735        lookupNameEnv (md_types (hm_details hm)) name
 736   | otherwise
 737   = lookupNameEnv pte name
 738   where mod = nameModule name
 739         this_pkg = thisPackage dflags
 740 \end{code}
 741
 742 \begin{code}
 743 tyThingTyCon (ATyCon tc) = tc
 744 tyThingTyCon other       = pprPanic "tyThingTyCon" (ppr other)
 745
 746 tyThingClass (AClass cls) = cls
 747 tyThingClass other        = pprPanic "tyThingClass" (ppr other)
 748
 749 tyThingDataCon (ADataCon dc) = dc
 750 tyThingDataCon other         = pprPanic "tyThingDataCon" (ppr other)
 751
 752 tyThingId (AnId id) = id
 753 tyThingId other     = pprPanic "tyThingId" (ppr other)
 754 \end{code}
 755
 756 %************************************************************************
 757 %*                                                                      *
 758 \subsection{Auxiliary types}
 759 %*                                                                      *
 760 %************************************************************************
 761
 762 These types are defined here because they are mentioned in ModDetails,
 763 but they are mostly elaborated elsewhere
 764
 765 \begin{code}
 766 mkIfaceVerCache :: [(Version,IfaceDecl)]
 767                 -> (OccName -> Maybe (OccName, Version))
 768 mkIfaceVerCache pairs
 769   = \occ -> lookupOccEnv env occ
 770   where
 771     env = foldr add_decl emptyOccEnv pairs
 772     add_decl (v,d) env0 = foldr add_imp env1 (ifaceDeclSubBndrs d)
 773       where
 774           decl_name = ifName d
 775           env1 = extendOccEnv env0 decl_name (decl_name, v)
 776           add_imp bndr env = extendOccEnv env bndr (decl_name, v)
 777
 778 emptyIfaceVerCache :: OccName -> Maybe (OccName, Version)
 779 emptyIfaceVerCache occ = Nothing
 780
 781 ------------------ Deprecations -------------------------
 782 data Deprecs a
 783   = NoDeprecs
 784   | DeprecAll DeprecTxt -- Whole module deprecated
 785   | DeprecSome a        -- Some specific things deprecated
 786   deriving( Eq )
 787
 788 type IfaceDeprecs = Deprecs [(OccName,DeprecTxt)]
 789 type Deprecations = Deprecs (NameEnv (OccName,DeprecTxt))
 790         -- Keep the OccName so we can flatten the NameEnv to
 791         -- get an IfaceDeprecs from a Deprecations
 792         -- Only an OccName is needed, because a deprecation always
 793         -- applies to things defined in the module in which the
 794         -- deprecation appears.
 795
 796 mkIfaceDepCache:: IfaceDeprecs -> Name -> Maybe DeprecTxt
 797 mkIfaceDepCache NoDeprecs         = \n -> Nothing
 798 mkIfaceDepCache (DeprecAll t)     = \n -> Just t
 799 mkIfaceDepCache (DeprecSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
 800
 801 emptyIfaceDepCache :: Name -> Maybe DeprecTxt
 802 emptyIfaceDepCache n = Nothing
 803
 804 lookupDeprec :: Deprecations -> Name -> Maybe DeprecTxt
 805 lookupDeprec NoDeprecs        name = Nothing
 806 lookupDeprec (DeprecAll  txt) name = Just txt
 807 lookupDeprec (DeprecSome env) name = case lookupNameEnv env name of
 808                                             Just (_, txt) -> Just txt
 809                                             Nothing       -> Nothing
 810
 811 plusDeprecs :: Deprecations -> Deprecations -> Deprecations
 812 plusDeprecs d NoDeprecs = d
 813 plusDeprecs NoDeprecs d = d
 814 plusDeprecs d (DeprecAll t) = DeprecAll t
 815 plusDeprecs (DeprecAll t) d = DeprecAll t
 816 plusDeprecs (DeprecSome v1) (DeprecSome v2) = DeprecSome (v1 `plusNameEnv` v2)
 817 \end{code}
 818
 819
 820 \begin{code}
 821 type Avails       = [AvailInfo]
 822 type AvailInfo    = GenAvailInfo Name
 823 type RdrAvailInfo = GenAvailInfo OccName
 824
 825 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 826                         | AvailTC name   -- The name of the type or class
 827                                   [name] -- The available pieces of type/class.
 828                                          -- NB: If the type or class is itself
 829                                          -- to be in scope, it must be in this list.
 830                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 831                         deriving( Eq )
 832                         -- Equality used when deciding if the interface has changed
 833
 834 type IfaceExport = (Module, [GenAvailInfo OccName])
 835
 836 availsToNameSet :: [AvailInfo] -> NameSet
 837 availsToNameSet avails = foldr add emptyNameSet avails
 838       where add avail set = addListToNameSet set (availNames avail)
 839
 840 availsToNameEnv :: [AvailInfo] -> NameEnv AvailInfo
 841 availsToNameEnv avails = foldr add emptyNameEnv avails
 842      where add avail env = extendNameEnvList env
 843                                 (zip (availNames avail) (repeat avail))
 844
 845 availName :: GenAvailInfo name -> name
 846 availName (Avail n)     = n
 847 availName (AvailTC n _) = n
 848
 849 availNames :: GenAvailInfo name -> [name]
 850 availNames (Avail n)      = [n]
 851 availNames (AvailTC n ns) = ns
 852
 853 instance Outputable n => Outputable (GenAvailInfo n) where
 854    ppr = pprAvail
 855
 856 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
 857 pprAvail (AvailTC n ns) = ppr n <> case {- filter (/= n) -} ns of
 858                                         []  -> empty
 859                                         ns' -> braces (hsep (punctuate comma (map ppr ns')))
 860
 861 pprAvail (Avail n) = ppr n
 862 \end{code}
 863
 864 \begin{code}
 865 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
 866 mkIfaceFixCache pairs
 867   = \n -> lookupOccEnv env n `orElse` defaultFixity
 868   where
 869    env = mkOccEnv pairs
 870
 871 emptyIfaceFixCache :: OccName -> Fixity
 872 emptyIfaceFixCache n = defaultFixity
 873
 874 -- This fixity environment is for source code only
 875 type FixityEnv = NameEnv FixItem
 876
 877 -- We keep the OccName in the range so that we can generate an interface from it
 878 data FixItem = FixItem OccName Fixity SrcSpan
 879
 880 instance Outputable FixItem where
 881   ppr (FixItem occ fix loc) = ppr fix <+> ppr occ <+> parens (ppr loc)
 882
 883 emptyFixityEnv :: FixityEnv
 884 emptyFixityEnv = emptyNameEnv
 885
 886 lookupFixity :: FixityEnv -> Name -> Fixity
 887 lookupFixity env n = case lookupNameEnv env n of
 888                         Just (FixItem _ fix _) -> fix
 889                         Nothing                -> defaultFixity
 890 \end{code}
 891
 892
 893 %************************************************************************
 894 %*                                                                      *
 895 \subsection{WhatsImported}
 896 %*                                                                      *
 897 %************************************************************************
 898
 899 \begin{code}
 900 type WhetherHasOrphans   = Bool
 901         -- An "orphan" is
 902         --      * an instance decl in a module other than the defn module for
 903         --              one of the tycons or classes in the instance head
 904         --      * a transformation rule in a module other than the one defining
 905         --              the function in the head of the rule.
 906
 907 type IsBootInterface = Bool
 908
 909 -- Dependency info about modules and packages below this one
 910 -- in the import hierarchy.  See TcRnTypes.ImportAvails for details.
 911 --
 912 -- Invariant: the dependencies of a module M never includes M
 913 -- Invariant: the lists are unordered, with no duplicates
 914 data Dependencies
 915   = Deps { dep_mods  :: [(ModuleName,IsBootInterface)], -- Home-package module dependencies
 916            dep_pkgs  :: [PackageId],                    -- External package dependencies
 917            dep_orphs :: [Module] }                      -- Orphan modules (whether home or external pkg)
 918   deriving( Eq )
 919         -- Equality used only for old/new comparison in MkIface.addVersionInfo
 920
 921 noDependencies :: Dependencies
 922 noDependencies = Deps [] [] []
 923
 924 data Usage
 925   = Usage { usg_name     :: ModuleName,                 -- Name of the module
 926             usg_mod      :: Version,                    -- Module version
 927             usg_entities :: [(OccName,Version)],        -- Sorted by occurrence name
 928                 -- NB. usages are for parent names only, eg. tycon but not constructors.
 929             usg_exports  :: Maybe Version,              -- Export-list version, if we depend on it
 930             usg_rules    :: Version                     -- Orphan-rules version (for non-orphan
 931                                                         -- modules this will always be initialVersion)
 932     }       deriving( Eq )
 933         -- This type doesn't let you say "I imported f but none of the rules in
 934         -- the module". If you use anything in the module you get its rule version
 935         -- So if the rules change, you'll recompile, even if you don't use them.
 936         -- This is easy to implement, and it's safer: you might not have used the rules last
 937         -- time round, but if someone has added a new rule you might need it this time
 938
 939         -- The export list field is (Just v) if we depend on the export list:
 940         --      i.e. we imported the module directly, whether or not we
 941         --           enumerated the things we imported, or just imported everything
 942         -- We need to recompile if M's exports change, because
 943         -- if the import was    import M,       we might now have a name clash in the
 944         --                                      importing module.
 945         -- if the import was    import M(x)     M might no longer export x
 946         -- The only way we don't depend on the export list is if we have
 947         --                      import M()
 948         -- And of course, for modules that aren't imported directly we don't
 949         -- depend on their export lists
 950 \end{code}
 951
 952
 953 %************************************************************************
 954 %*                                                                      *
 955                 The External Package State
 956 %*                                                                      *
 957 %************************************************************************
 958
 959 \begin{code}
 960 type PackageTypeEnv    = TypeEnv
 961 type PackageRuleBase   = RuleBase
 962 type PackageInstEnv    = InstEnv
 963 type PackageFamInstEnv = FamInstEnv
 964
 965 data ExternalPackageState
 966   = EPS {
 967         eps_is_boot :: !(ModuleNameEnv (ModuleName, IsBootInterface)),
 968                 -- In OneShot mode (only), home-package modules
 969                 -- accumulate in the external package state, and are
 970                 -- sucked in lazily.  For these home-pkg modules
 971                 -- (only) we need to record which are boot modules.
 972                 -- We set this field after loading all the
 973                 -- explicitly-imported interfaces, but before doing
 974                 -- anything else
 975                 --
 976                 -- The ModuleName part is not necessary, but it's useful for
 977                 -- debug prints, and it's convenient because this field comes
 978                 -- direct from TcRnTypes.ImportAvails.imp_dep_mods
 979
 980         eps_PIT :: !PackageIfaceTable,
 981                 -- The ModuleIFaces for modules in external packages
 982                 -- whose interfaces we have opened
 983                 -- The declarations in these interface files are held in
 984                 -- eps_decls, eps_inst_env, eps_fam_inst_env, eps_rules
 985                 -- (below), not in the mi_decls fields of the iPIT.
 986                 -- What _is_ in the iPIT is:
 987                 --      * The Module
 988                 --      * Version info
 989                 --      * Its exports
 990                 --      * Fixities
 991                 --      * Deprecations
 992
 993         eps_PTE :: !PackageTypeEnv,        -- Domain = external-package modules
 994
 995         eps_inst_env     :: !PackageInstEnv,   -- The total InstEnv accumulated
 996                                                -- from all the external-package
 997                                                -- modules
 998         eps_fam_inst_env :: !PackageFamInstEnv,-- Ditto FamInstEnv
 999         eps_rule_base    :: !PackageRuleBase,  -- Ditto RuleEnv
1000
1001         eps_stats :: !EpsStats
1002   }
1003
1004 -- "In" means read from iface files
1005 -- "Out" means actually sucked in and type-checked
1006 data EpsStats = EpsStats { n_ifaces_in
1007                          , n_decls_in, n_decls_out
1008                          , n_rules_in, n_rules_out
1009                          , n_insts_in, n_insts_out :: !Int }
1010
1011 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
1012 -- Add stats for one newly-read interface
1013 addEpsInStats stats n_decls n_insts n_rules
1014   = stats { n_ifaces_in = n_ifaces_in stats + 1
1015           , n_decls_in  = n_decls_in stats + n_decls
1016           , n_insts_in  = n_insts_in stats + n_insts
1017           , n_rules_in  = n_rules_in stats + n_rules }
1018 \end{code}
1019
1020 The NameCache makes sure that there is just one Unique assigned for
1021 each original name; i.e. (module-name, occ-name) pair.  The Name is
1022 always stored as a Global, and has the SrcLoc of its binding location.
1023 Actually that's not quite right.  When we first encounter the original
1024 name, we might not be at its binding site (e.g. we are reading an
1025 interface file); so we give it 'noSrcLoc' then.  Later, when we find
1026 its binding site, we fix it up.
1027
1028 \begin{code}
1029 data NameCache
1030  = NameCache {  nsUniqs :: UniqSupply,
1031                 -- Supply of uniques
1032                 nsNames :: OrigNameCache,
1033                 -- Ensures that one original name gets one unique
1034                 nsIPs   :: OrigIParamCache
1035                 -- Ensures that one implicit parameter name gets one unique
1036    }
1037
1038 type OrigNameCache   = ModuleEnv (OccEnv Name)
1039 type OrigIParamCache = FiniteMap (IPName OccName) (IPName Name)
1040 \end{code}
1041
1042
1043
1044 %************************************************************************
1045 %*                                                                      *
1046                 The module graph and ModSummary type
1047         A ModSummary is a node in the compilation manager's
1048         dependency graph, and it's also passed to hscMain
1049 %*                                                                      *
1050 %************************************************************************
1051
1052 A ModuleGraph contains all the nodes from the home package (only).
1053 There will be a node for each source module, plus a node for each hi-boot
1054 module.
1055
1056 \begin{code}
1057 type ModuleGraph = [ModSummary]  -- The module graph,
1058                                  -- NOT NECESSARILY IN TOPOLOGICAL ORDER
1059
1060 emptyMG :: ModuleGraph
1061 emptyMG = []
1062
1063 -- The nodes of the module graph are
1064 --      EITHER a regular Haskell source module
1065 --      OR     a hi-boot source module
1066
1067 data ModSummary
1068    = ModSummary {
1069         ms_mod       :: Module,                 -- Identity of the module
1070         ms_hsc_src   :: HscSource,              -- Source is Haskell, hs-boot, external core
1071         ms_location  :: ModLocation,            -- Location
1072         ms_hs_date   :: ClockTime,              -- Timestamp of source file
1073         ms_obj_date  :: Maybe ClockTime,        -- Timestamp of object, maybe
1074         ms_srcimps   :: [Located ModuleName],   -- Source imports
1075         ms_imps      :: [Located ModuleName],   -- Non-source imports
1076         ms_hspp_file :: FilePath,               -- Filename of preprocessed source.
1077         ms_hspp_opts :: DynFlags,               -- Cached flags from OPTIONS, INCLUDE
1078                                                 -- and LANGUAGE pragmas.
1079         ms_hspp_buf  :: Maybe StringBuffer      -- The actual preprocessed source, maybe.
1080      }
1081
1082 -- The ModLocation contains both the original source filename and the
1083 -- filename of the cleaned-up source file after all preprocessing has been
1084 -- done.  The point is that the summariser will have to cpp/unlit/whatever
1085 -- all files anyway, and there's no point in doing this twice -- just
1086 -- park the result in a temp file, put the name of it in the location,
1087 -- and let @compile@ read from that file on the way back up.
1088
1089 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
1090 -- the ms_hs_date and imports can, of course, change
1091
1092 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
1093 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
1094 msHiFilePath  ms = ml_hi_file  (ms_location ms)
1095 msObjFilePath ms = ml_obj_file (ms_location ms)
1096
1097 isBootSummary :: ModSummary -> Bool
1098 isBootSummary ms = isHsBoot (ms_hsc_src ms)
1099
1100 instance Outputable ModSummary where
1101    ppr ms
1102       = sep [text "ModSummary {",
1103              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
1104                           text "ms_mod =" <+> ppr (ms_mod ms)
1105                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
1106                           text "ms_imps =" <+> ppr (ms_imps ms),
1107                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
1108              char '}'
1109             ]
1110
1111 showModMsg :: HscTarget -> Bool -> ModSummary -> String
1112 showModMsg target recomp mod_summary
1113   = showSDoc (hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
1114                     char '(', text (msHsFilePath mod_summary) <> comma,
1115                     case target of
1116                       HscInterpreted | recomp
1117                                  -> text "interpreted"
1118                       HscNothing -> text "nothing"
1119                       _other     -> text (msObjFilePath mod_summary),
1120                     char ')'])
1121  where
1122     mod     = moduleName (ms_mod mod_summary)
1123     mod_str = showSDoc (ppr mod) ++ hscSourceString (ms_hsc_src mod_summary)
1124 \end{code}
1125
1126
1127 %************************************************************************
1128 %*                                                                      *
1129 \subsection{Linkable stuff}
1130 %*                                                                      *
1131 %************************************************************************
1132
1133 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
1134 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
1135
1136 \begin{code}
1137 data Linkable = LM {
1138   linkableTime     :: ClockTime,        -- Time at which this linkable was built
1139                                         -- (i.e. when the bytecodes were produced,
1140                                         --       or the mod date on the files)
1141   linkableModule   :: Module,           -- Should be Module, but see below
1142   linkableUnlinked :: [Unlinked]
1143  }
1144
1145 isObjectLinkable :: Linkable -> Bool
1146 isObjectLinkable l = not (null unlinked) && all isObject unlinked
1147   where unlinked = linkableUnlinked l
1148         -- A linkable with no Unlinked's is treated as a BCO.  We can
1149         -- generate a linkable with no Unlinked's as a result of
1150         -- compiling a module in HscNothing mode, and this choice
1151         -- happens to work well with checkStability in module GHC.
1152
1153 instance Outputable Linkable where
1154    ppr (LM when_made mod unlinkeds)
1155       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
1156         $$ nest 3 (ppr unlinkeds)
1157
1158 -------------------------------------------
1159 data Unlinked
1160    = DotO FilePath
1161    | DotA FilePath
1162    | DotDLL FilePath
1163    | BCOs CompiledByteCode
1164
1165 #ifndef GHCI
1166 data CompiledByteCode = NoByteCode
1167 #endif
1168
1169 instance Outputable Unlinked where
1170    ppr (DotO path)   = text "DotO" <+> text path
1171    ppr (DotA path)   = text "DotA" <+> text path
1172    ppr (DotDLL path) = text "DotDLL" <+> text path
1173 #ifdef GHCI
1174    ppr (BCOs bcos)   = text "BCOs" <+> ppr bcos
1175 #else
1176    ppr (BCOs bcos)   = text "No byte code"
1177 #endif
1178
1179 isObject (DotO _)   = True
1180 isObject (DotA _)   = True
1181 isObject (DotDLL _) = True
1182 isObject _          = False
1183
1184 isInterpretable = not . isObject
1185
1186 nameOfObject (DotO fn)   = fn
1187 nameOfObject (DotA fn)   = fn
1188 nameOfObject (DotDLL fn) = fn
1189 nameOfObject other       = pprPanic "nameOfObject" (ppr other)
1190
1191 byteCodeOfObject (BCOs bc) = bc
1192 byteCodeOfObject other     = pprPanic "byteCodeOfObject" (ppr other)
1193 \end{code}
1194
1195
1196