compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         -- * Sessions and compilation state
   9         Session(..), withSession, modifySession,
  10         HscEnv(..), hscEPS,
  11         FinderCache, FindResult(..), ModLocationCache,
  12         Target(..), TargetId(..), pprTarget, pprTargetId,
  13         ModuleGraph, emptyMG,
  14
  15         ModDetails(..), emptyModDetails,
  16         ModGuts(..), CgGuts(..), ModImports(..), ForeignStubs(..),
  17
  18         ModSummary(..), ms_mod_name, showModMsg, isBootSummary,
  19         msHsFilePath, msHiFilePath, msObjFilePath,
  20
  21         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
  22
  23         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
  24         hptInstances, hptRules, hptVectInfo,
  25
  26         ExternalPackageState(..), EpsStats(..), addEpsInStats,
  27         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
  28         lookupIfaceByModule, emptyModIface,
  29
  30         InteractiveContext(..), emptyInteractiveContext,
  31         icPrintUnqual, mkPrintUnqualified, extendInteractiveContext,
  32         substInteractiveContext,
  33
  34         ModIface(..), mkIfaceDepCache, mkIfaceVerCache, mkIfaceFixCache,
  35         emptyIfaceDepCache,
  36
  37         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
  38
  39         implicitTyThings, isImplicitTyThing,
  40
  41         TyThing(..), tyThingClass, tyThingTyCon, tyThingDataCon, tyThingId,
  42         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  43         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
  44         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  45         typeEnvDataCons,
  46
  47         WhetherHasOrphans, IsBootInterface, Usage(..),
  48         Dependencies(..), noDependencies,
  49         NameCache(..), OrigNameCache, OrigIParamCache,
  50         Avails, availsToNameSet, availsToNameEnv, availName, availNames,
  51         GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  52         IfaceExport,
  53
  54         Deprecations(..), DeprecTxt, plusDeprecs,
  55
  56         PackageInstEnv, PackageRuleBase,
  57
  58         -- Linker stuff
  59         Linkable(..), isObjectLinkable,
  60         Unlinked(..), CompiledByteCode,
  61         isObject, nameOfObject, isInterpretable, byteCodeOfObject,
  62         HpcInfo(..), emptyHpcInfo, isHpcUsed, AnyHpcUsage,
  63
  64         -- Breakpoints
  65         ModBreaks (..), BreakIndex, emptyModBreaks,
  66
  67         -- Vectorisation information
  68         VectInfo(..), IfaceVectInfo(..), noVectInfo, plusVectInfo,
  69         noIfaceVectInfo
  70     ) where
  71
  72 #include "HsVersions.h"
  73
  74 #ifdef GHCI
  75 import ByteCodeAsm      ( CompiledByteCode )
  76 import {-# SOURCE #-}  InteractiveEval ( Resume )
  77 #endif
  78
  79 import RdrName
  80 import Name             ( Name, NamedThing, getName, nameOccName, nameModule )
  81 import NameEnv
  82 import NameSet
  83 import OccName          ( OccName, OccEnv, lookupOccEnv, mkOccEnv, emptyOccEnv,
  84                           extendOccEnv )
  85 import Module
  86 import InstEnv          ( InstEnv, Instance )
  87 import FamInstEnv       ( FamInstEnv, FamInst )
  88 import Rules            ( RuleBase )
  89 import CoreSyn          ( CoreBind )
  90 import VarEnv
  91 import VarSet
  92 import Var       hiding ( setIdType )
  93 import Id
  94 import Type
  95
  96 import Class            ( Class, classSelIds, classATs, classTyCon )
  97 import TyCon
  98 import DataCon          ( DataCon, dataConImplicitIds )
  99 import PrelNames        ( gHC_PRIM )
 100 import Packages hiding ( Version(..) )
 101 import DynFlags         ( DynFlags(..), isOneShot, HscTarget (..) )
 102 import DriverPhases     ( HscSource(..), isHsBoot, hscSourceString, Phase )
 103 import BasicTypes       ( Version, initialVersion, IPName,
 104                           Fixity, defaultFixity, DeprecTxt )
 105 import IfaceSyn
 106 import FiniteMap        ( FiniteMap )
 107 import CoreSyn          ( CoreRule )
 108 import Maybes           ( orElse, expectJust, catMaybes, seqMaybe )
 109 import Outputable
 110 import BreakArray
 111 import SrcLoc           ( SrcSpan, Located )
 112 import UniqFM           ( lookupUFM, eltsUFM, emptyUFM )
 113 import UniqSupply       ( UniqSupply )
 114 import FastString       ( FastString )
 115 import StringBuffer     ( StringBuffer )
 116
 117 import System.Time      ( ClockTime )
 118 import Data.IORef
 119 import Data.Array       ( Array, array )
 120 import Data.List
 121 \end{code}
 122
 123
 124 %************************************************************************
 125 %*                                                                      *
 126 \subsection{Compilation environment}
 127 %*                                                                      *
 128 %************************************************************************
 129
 130
 131 \begin{code}
 132 -- | The Session is a handle to the complete state of a compilation
 133 -- session.  A compilation session consists of a set of modules
 134 -- constituting the current program or library, the context for
 135 -- interactive evaluation, and various caches.
 136 newtype Session = Session (IORef HscEnv)
 137
 138 withSession :: Session -> (HscEnv -> IO a) -> IO a
 139 withSession (Session ref) f = do h <- readIORef ref; f h
 140
 141 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 142 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 143 \end{code}
 144
 145 HscEnv is like Session, except that some of the fields are immutable.
 146 An HscEnv is used to compile a single module from plain Haskell source
 147 code (after preprocessing) to either C, assembly or C--.  Things like
 148 the module graph don't change during a single compilation.
 149
 150 Historical note: "hsc" used to be the name of the compiler binary,
 151 when there was a separate driver and compiler.  To compile a single
 152 module, the driver would invoke hsc on the source code... so nowadays
 153 we think of hsc as the layer of the compiler that deals with compiling
 154 a single module.
 155
 156 \begin{code}
 157 data HscEnv
 158   = HscEnv {
 159         hsc_dflags :: DynFlags,
 160                 -- The dynamic flag settings
 161
 162         hsc_targets :: [Target],
 163                 -- The targets (or roots) of the current session
 164
 165         hsc_mod_graph :: ModuleGraph,
 166                 -- The module graph of the current session
 167
 168         hsc_IC :: InteractiveContext,
 169                 -- The context for evaluating interactive statements
 170
 171         hsc_HPT    :: HomePackageTable,
 172                 -- The home package table describes already-compiled
 173                 -- home-packge modules, *excluding* the module we
 174                 -- are compiling right now.
 175                 -- (In one-shot mode the current module is the only
 176                 --  home-package module, so hsc_HPT is empty.  All other
 177                 --  modules count as "external-package" modules.
 178                 --  However, even in GHCi mode, hi-boot interfaces are
 179                 --  demand-loadeded into the external-package table.)
 180                 --
 181                 -- hsc_HPT is not mutable because we only demand-load
 182                 -- external packages; the home package is eagerly
 183                 -- loaded, module by module, by the compilation manager.
 184                 --
 185                 -- The HPT may contain modules compiled earlier by --make
 186                 -- but not actually below the current module in the dependency
 187                 -- graph.  (This changes a previous invariant: changed Jan 05.)
 188
 189         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
 190         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
 191                 -- These are side-effected by compiling to reflect
 192                 -- sucking in interface files.  They cache the state of
 193                 -- external interface files, in effect.
 194
 195         hsc_FC   :: {-# UNPACK #-} !(IORef FinderCache),
 196         hsc_MLC  :: {-# UNPACK #-} !(IORef ModLocationCache),
 197                 -- The finder's cache.  This caches the location of modules,
 198                 -- so we don't have to search the filesystem multiple times.
 199
 200         hsc_global_rdr_env :: GlobalRdrEnv,
 201         hsc_global_type_env :: TypeEnv
 202  }
 203
 204 hscEPS :: HscEnv -> IO ExternalPackageState
 205 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
 206
 207 -- | A compilation target.
 208 --
 209 -- A target may be supplied with the actual text of the
 210 -- module.  If so, use this instead of the file contents (this
 211 -- is for use in an IDE where the file hasn't been saved by
 212 -- the user yet).
 213 data Target = Target TargetId (Maybe (StringBuffer,ClockTime))
 214
 215 data TargetId
 216   = TargetModule ModuleName
 217         -- ^ A module name: search for the file
 218   | TargetFile FilePath (Maybe Phase)
 219         -- ^ A filename: preprocess & parse it to find the module name.
 220         -- If specified, the Phase indicates how to compile this file
 221         -- (which phase to start from).  Nothing indicates the starting phase
 222         -- should be determined from the suffix of the filename.
 223   deriving Eq
 224
 225 pprTarget :: Target -> SDoc
 226 pprTarget (Target id _) = pprTargetId id
 227
 228 instance Outputable Target where
 229     ppr = pprTarget
 230
 231 pprTargetId :: TargetId -> SDoc
 232 pprTargetId (TargetModule m) = ppr m
 233 pprTargetId (TargetFile f _) = text f
 234
 235 instance Outputable TargetId where
 236     ppr = pprTargetId
 237
 238 type HomePackageTable  = ModuleNameEnv HomeModInfo
 239         -- Domain = modules in the home package
 240         -- "home" package name cached here for convenience
 241 type PackageIfaceTable = ModuleEnv ModIface
 242         -- Domain = modules in the imported packages
 243
 244 emptyHomePackageTable :: HomePackageTable
 245 emptyHomePackageTable  = emptyUFM
 246
 247 emptyPackageIfaceTable :: PackageIfaceTable
 248 emptyPackageIfaceTable = emptyModuleEnv
 249
 250 data HomeModInfo
 251   = HomeModInfo { hm_iface    :: !ModIface,
 252                   hm_details  :: !ModDetails,
 253                   hm_linkable :: !(Maybe Linkable) }
 254                 -- hm_linkable might be Nothing if:
 255                 --   a) this is an .hs-boot module
 256                 --   b) temporarily during compilation if we pruned away
 257                 --      the old linkable because it was out of date.
 258                 -- after a complete compilation (GHC.load), all hm_linkable
 259                 -- fields in the HPT will be Just.
 260                 --
 261                 -- When re-linking a module (hscNoRecomp), we construct
 262                 -- the HomModInfo by building a new ModDetails from the
 263                 -- old ModIface (only).
 264
 265 -- | Find the 'ModIface' for a 'Module'
 266 lookupIfaceByModule
 267         :: DynFlags
 268         -> HomePackageTable
 269         -> PackageIfaceTable
 270         -> Module
 271         -> Maybe ModIface
 272 lookupIfaceByModule dflags hpt pit mod
 273   | modulePackageId mod == thisPackage dflags
 274   =     -- The module comes from the home package, so look first
 275         -- in the HPT.  If it's not from the home package it's wrong to look
 276         -- in the HPT, because the HPT is indexed by *ModuleName* not Module
 277     fmap hm_iface (lookupUFM hpt (moduleName mod))
 278     `seqMaybe` lookupModuleEnv pit mod
 279
 280   | otherwise = lookupModuleEnv pit mod         -- Look in PIT only
 281
 282 -- If the module does come from the home package, why do we look in the PIT as well?
 283 -- (a) In OneShot mode, even home-package modules accumulate in the PIT
 284 -- (b) Even in Batch (--make) mode, there is *one* case where a home-package
 285 --     module is in the PIT, namely GHC.Prim when compiling the base package.
 286 -- We could eliminate (b) if we wanted, by making GHC.Prim belong to a packake
 287 -- of its own, but it doesn't seem worth the bother.
 288 \end{code}
 289
 290
 291 \begin{code}
 292 hptInstances :: HscEnv -> (ModuleName -> Bool) -> ([Instance], [FamInst])
 293 -- Find all the instance declarations (of classes and families) that are in
 294 -- modules imported by this one, directly or indirectly, and are in the Home
 295 -- Package Table.  This ensures that we don't see instances from modules --make
 296 -- compiled before this one, but which are not below this one.
 297 hptInstances hsc_env want_this_module
 298   = let (insts, famInsts) = unzip
 299           [ (md_insts details, md_fam_insts details)
 300           | mod_info <- eltsUFM (hsc_HPT hsc_env)
 301           , want_this_module (moduleName (mi_module (hm_iface mod_info)))
 302           , let details = hm_details mod_info ]
 303     in
 304     (concat insts, concat famInsts)
 305
 306 hptRules :: HscEnv -> [(ModuleName, IsBootInterface)] -> [CoreRule]
 307 -- Get rules from modules "below" this one (in the dependency sense)
 308 -- C.f Inst.hptInstances
 309 hptRules hsc_env deps
 310   | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
 311   | otherwise
 312   = let
 313         hpt = hsc_HPT hsc_env
 314     in
 315     [ rule
 316     |   -- Find each non-hi-boot module below me
 317       (mod, False) <- deps
 318
 319         -- unsavoury: when compiling the base package with --make, we
 320         -- sometimes try to look up RULES for GHC.Prim.  GHC.Prim won't
 321         -- be in the HPT, because we never compile it; it's in the EPT
 322         -- instead.  ToDo: clean up, and remove this slightly bogus
 323         -- filter:
 324     , mod /= moduleName gHC_PRIM
 325
 326         -- Look it up in the HPT
 327     , let rules = case lookupUFM hpt mod of
 328                     Just info -> md_rules (hm_details info)
 329                     Nothing -> pprTrace "WARNING in hptRules" msg []
 330           msg = vcat [ptext SLIT("missing module") <+> ppr mod,
 331                       ptext SLIT("Probable cause: out-of-date interface files")]
 332                         -- This really shouldn't happen, but see Trac #962
 333
 334         -- And get its dfuns
 335     , rule <- rules ]
 336
 337 hptVectInfo :: HscEnv -> VectInfo
 338 -- Get the combined VectInfo of all modules in the home package table.  In
 339 -- contrast to instances and rules, we don't care whether the modules are
 340 -- "below" or us.  The VectInfo of those modules not "below" us does not
 341 -- affect the compilation of the current module.
 342 hptVectInfo hsc_env
 343   = foldr plusVectInfo noVectInfo [ md_vect_info (hm_details mod_info)
 344                                   | mod_info <- eltsUFM (hsc_HPT hsc_env)]
 345 \end{code}
 346
 347 %************************************************************************
 348 %*                                                                      *
 349 \subsection{The Finder cache}
 350 %*                                                                      *
 351 %************************************************************************
 352
 353 \begin{code}
 354 -- | The 'FinderCache' maps home module names to the result of
 355 -- searching for that module.  It records the results of searching for
 356 -- modules along the search path.  On @:load@, we flush the entire
 357 -- contents of this cache.
 358 --
 359 -- Although the @FinderCache@ range is 'FindResult' for convenience ,
 360 -- in fact it will only ever contain 'Found' or 'NotFound' entries.
 361 --
 362 type FinderCache = ModuleNameEnv FindResult
 363
 364 -- | The result of searching for an imported module.
 365 data FindResult
 366   = Found ModLocation Module
 367         -- the module was found
 368   | NoPackage PackageId
 369         -- the requested package was not found
 370   | FoundMultiple [PackageId]
 371         -- *error*: both in multiple packages
 372   | PackageHidden PackageId
 373         -- for an explicit source import: the package containing the module is
 374         -- not exposed.
 375   | ModuleHidden  PackageId
 376         -- for an explicit source import: the package containing the module is
 377         -- exposed, but the module itself is hidden.
 378   | NotFound [FilePath] (Maybe PackageId)
 379         -- the module was not found, the specified places were searched
 380   | NotFoundInPackage PackageId
 381         -- the module was not found in this package
 382
 383 -- | Cache that remembers where we found a particular module.  Contains both
 384 -- home modules and package modules.  On @:load@, only home modules are
 385 -- purged from this cache.
 386 type ModLocationCache = ModuleEnv ModLocation
 387 \end{code}
 388
 389 %************************************************************************
 390 %*                                                                      *
 391 \subsection{Symbol tables and Module details}
 392 %*                                                                      *
 393 %************************************************************************
 394
 395 A @ModIface@ plus a @ModDetails@ summarises everything we know
 396 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 397 and can be written out to an interface file.  (The @ModDetails@ is after
 398 linking; it is the "linked" form of the mi_decls field.)
 399
 400 When we *read* an interface file, we also construct a @ModIface@ from it,
 401 except that the mi_decls part is empty; when reading we consolidate
 402 the declarations into a single indexed map in the @PersistentRenamerState@.
 403
 404 \begin{code}
 405 data ModIface
 406    = ModIface {
 407         mi_module   :: !Module,
 408         mi_mod_vers :: !Version,            -- Module version: changes when anything changes
 409
 410         mi_orphan   :: !WhetherHasOrphans,  -- Whether this module has orphans
 411         mi_finsts   :: !WhetherHasFamInst,  -- Whether module has family insts
 412         mi_boot     :: !IsBootInterface,    -- Read from an hi-boot file?
 413
 414         mi_deps     :: Dependencies,
 415                 -- This is consulted for directly-imported modules,
 416                 -- but not for anything else (hence lazy)
 417
 418                 -- Usages; kept sorted so that it's easy to decide
 419                 -- whether to write a new iface file (changing usages
 420                 -- doesn't affect the version of this module)
 421         mi_usages   :: [Usage],
 422                 -- NOT STRICT!  we read this field lazily from the interface file
 423                 -- It is *only* consulted by the recompilation checker
 424
 425                 -- Exports
 426                 -- Kept sorted by (mod,occ), to make version comparisons easier
 427         mi_exports  :: ![IfaceExport],
 428         mi_exp_vers :: !Version,        -- Version number of export list
 429
 430                 -- Fixities
 431         mi_fixities :: [(OccName,Fixity)],
 432                 -- NOT STRICT!  we read this field lazily from the interface file
 433
 434                 -- Deprecations
 435         mi_deprecs  :: Deprecations,
 436                 -- NOT STRICT!  we read this field lazily from the interface file
 437
 438                 -- Type, class and variable declarations
 439                 -- The version of an Id changes if its fixity or deprecations change
 440                 --      (as well as its type of course)
 441                 -- Ditto data constructors, class operations, except that
 442                 -- the version of the parent class/tycon changes
 443         mi_decls :: [(Version,IfaceDecl)],      -- Sorted
 444
 445         mi_globals  :: !(Maybe GlobalRdrEnv),
 446                 -- Binds all the things defined at the top level in
 447                 -- the *original source* code for this module. which
 448                 -- is NOT the same as mi_exports, nor mi_decls (which
 449                 -- may contains declarations for things not actually
 450                 -- defined by the user).  Used for GHCi and for inspecting
 451                 -- the contents of modules via the GHC API only.
 452                 --
 453                 -- (We need the source file to figure out the
 454                 -- top-level environment, if we didn't compile this module
 455                 -- from source then this field contains Nothing).
 456                 --
 457                 -- Strictly speaking this field should live in the
 458                 -- HomeModInfo, but that leads to more plumbing.
 459
 460                 -- Instance declarations and rules
 461         mi_insts     :: [IfaceInst],                    -- Sorted
 462         mi_fam_insts :: [IfaceFamInst],                 -- Sorted
 463         mi_rules     :: [IfaceRule],                    -- Sorted
 464         mi_rule_vers :: !Version,       -- Version number for rules and
 465                                         -- instances (for classes and families)
 466                                         -- combined
 467
 468                 -- Vectorisation information
 469         mi_vect_info :: !IfaceVectInfo,
 470
 471                 -- Cached environments for easy lookup
 472                 -- These are computed (lazily) from other fields
 473                 -- and are not put into the interface file
 474         mi_dep_fn  :: Name -> Maybe DeprecTxt,  -- Cached lookup for mi_deprecs
 475         mi_fix_fn  :: OccName -> Fixity,        -- Cached lookup for mi_fixities
 476         mi_ver_fn  :: OccName -> Maybe (OccName, Version),
 477                         -- Cached lookup for mi_decls
 478                         -- The Nothing in mi_ver_fn means that the thing
 479                         -- isn't in decls. It's useful to know that when
 480                         -- seeing if we are up to date wrt the old interface
 481                         -- The 'OccName' is the parent of the name, if it has one.
 482         mi_hpc    :: !AnyHpcUsage
 483           -- True if this program uses Hpc at any point in the program.
 484      }
 485
 486 -- Should be able to construct ModDetails from mi_decls in ModIface
 487 data ModDetails
 488    = ModDetails {
 489         -- The next two fields are created by the typechecker
 490         md_exports   :: [AvailInfo],
 491         md_types     :: !TypeEnv,
 492         md_insts     :: ![Instance],  -- Dfun-ids for the instances in this module
 493         md_fam_insts :: ![FamInst],
 494         md_rules     :: ![CoreRule],  -- Domain may include Ids from other modules
 495         md_vect_info :: !VectInfo     -- Vectorisation information
 496      }
 497
 498 emptyModDetails :: ModDetails
 499 emptyModDetails = ModDetails { md_types = emptyTypeEnv,
 500                                md_exports = [],
 501                                md_insts     = [],
 502                                md_rules     = [],
 503                                md_fam_insts = [],
 504                                md_vect_info = noVectInfo
 505                              }
 506
 507 -- A ModGuts is carried through the compiler, accumulating stuff as it goes
 508 -- There is only one ModGuts at any time, the one for the module
 509 -- being compiled right now.  Once it is compiled, a ModIface and
 510 -- ModDetails are extracted and the ModGuts is dicarded.
 511
 512 data ModGuts
 513   = ModGuts {
 514         mg_module    :: !Module,
 515         mg_boot      :: IsBootInterface, -- Whether it's an hs-boot module
 516         mg_exports   :: ![AvailInfo],    -- What it exports
 517         mg_deps      :: !Dependencies,   -- What is below it, directly or
 518                                          --   otherwise
 519         mg_dir_imps  :: ![Module],       -- Directly-imported modules; used to
 520                                          --     generate initialisation code
 521         mg_usages    :: ![Usage],        -- Version info for what it needed
 522
 523         mg_rdr_env   :: !GlobalRdrEnv,   -- Top-level lexical environment
 524
 525         -- These fields all describe the things **declared in this module**
 526         mg_fix_env   :: !FixityEnv,      -- Fixities
 527         mg_types     :: !TypeEnv,
 528         mg_insts     :: ![Instance],     -- Instances
 529         mg_fam_insts :: ![FamInst],      -- Instances
 530         mg_rules     :: ![CoreRule],     -- Rules from this module
 531         mg_binds     :: ![CoreBind],     -- Bindings for this module
 532         mg_foreign   :: !ForeignStubs,
 533         mg_deprecs   :: !Deprecations,   -- Deprecations declared in the module
 534         mg_hpc_info  :: !HpcInfo,        -- info about coverage tick boxes
 535         mg_modBreaks :: !ModBreaks,
 536         mg_vect_info :: !VectInfo,        -- Pool of vectorised declarations
 537
 538         -- The next two fields are unusual, because they give instance
 539         -- environments for *all* modules in the home package, including
 540         -- this module, rather than for *just* this module.
 541         -- Reason: when looking up an instance we don't want to have to
 542         --        look at each module in the home package in turn
 543         mg_inst_env     :: InstEnv,      -- Class instance enviroment fro
 544                                          -- *home-package* modules (including
 545                                          -- this one); c.f. tcg_inst_env
 546         mg_fam_inst_env :: FamInstEnv    -- Type-family instance enviroment
 547                                          -- for *home-package* modules (including
 548                                          -- this one); c.f. tcg_fam_inst_env
 549     }
 550
 551 -- The ModGuts takes on several slightly different forms:
 552 --
 553 -- After simplification, the following fields change slightly:
 554 --      mg_rules        Orphan rules only (local ones now attached to binds)
 555 --      mg_binds        With rules attached
 556
 557
 558 ---------------------------------------------------------
 559 -- The Tidy pass forks the information about this module:
 560 --      * one lot goes to interface file generation (ModIface)
 561 --        and later compilations (ModDetails)
 562 --      * the other lot goes to code generation (CgGuts)
 563 data CgGuts
 564   = CgGuts {
 565         cg_module   :: !Module,
 566
 567         cg_tycons   :: [TyCon],
 568                 -- Algebraic data types (including ones that started
 569                 -- life as classes); generate constructors and info
 570                 -- tables Includes newtypes, just for the benefit of
 571                 -- External Core
 572
 573         cg_binds    :: [CoreBind],
 574                 -- The tidied main bindings, including
 575                 -- previously-implicit bindings for record and class
 576                 -- selectors, and data construtor wrappers.  But *not*
 577                 -- data constructor workers; reason: we we regard them
 578                 -- as part of the code-gen of tycons
 579
 580         cg_dir_imps :: ![Module],
 581                 -- Directly-imported modules; used to generate
 582                 -- initialisation code
 583
 584         cg_foreign  :: !ForeignStubs,
 585         cg_dep_pkgs :: ![PackageId],    -- Used to generate #includes for C code gen
 586         cg_hpc_info :: !HpcInfo,         -- info about coverage tick boxes
 587         cg_modBreaks :: !ModBreaks
 588     }
 589
 590 -----------------------------------
 591 data ModImports
 592   = ModImports {
 593         imp_direct     :: ![(Module,Bool)],     -- Explicitly-imported modules
 594                                                 -- Boolean is true if we imported the whole
 595                                                 --      module (apart, perhaps, from hiding some)
 596         imp_pkg_mods   :: !ModuleSet,           -- Non-home-package modules on which we depend,
 597                                                 --      directly or indirectly
 598         imp_home_names :: !NameSet              -- Home package things on which we depend,
 599                                                 --      directly or indirectly
 600     }
 601
 602 -----------------------------------
 603 data ForeignStubs = NoStubs
 604                   | ForeignStubs
 605                         SDoc            -- Header file prototypes for
 606                                         --      "foreign exported" functions
 607                         SDoc            -- C stubs to use when calling
 608                                         --      "foreign exported" functions
 609                         [FastString]    -- Headers that need to be included
 610                                         --      into C code generated for this module
 611
 612 \end{code}
 613
 614 \begin{code}
 615 emptyModIface :: Module -> ModIface
 616 emptyModIface mod
 617   = ModIface { mi_module   = mod,
 618                mi_mod_vers = initialVersion,
 619                mi_orphan   = False,
 620                mi_finsts   = False,
 621                mi_boot     = False,
 622                mi_deps     = noDependencies,
 623                mi_usages   = [],
 624                mi_exports  = [],
 625                mi_exp_vers = initialVersion,
 626                mi_fixities = [],
 627                mi_deprecs  = NoDeprecs,
 628                mi_insts     = [],
 629                mi_fam_insts = [],
 630                mi_rules     = [],
 631                mi_decls     = [],
 632                mi_globals   = Nothing,
 633                mi_rule_vers = initialVersion,
 634                mi_vect_info = noIfaceVectInfo,
 635                mi_dep_fn = emptyIfaceDepCache,
 636                mi_fix_fn = emptyIfaceFixCache,
 637                mi_ver_fn = emptyIfaceVerCache,
 638                mi_hpc    = False
 639     }
 640 \end{code}
 641
 642
 643 %************************************************************************
 644 %*                                                                      *
 645 \subsection{The interactive context}
 646 %*                                                                      *
 647 %************************************************************************
 648
 649 \begin{code}
 650 data InteractiveContext
 651   = InteractiveContext {
 652         ic_toplev_scope :: [Module],    -- Include the "top-level" scope of
 653                                         -- these modules
 654
 655         ic_exports :: [Module],         -- Include just the exports of these
 656                                         -- modules
 657
 658         ic_rn_gbl_env :: GlobalRdrEnv,  -- The cached GlobalRdrEnv, built from
 659                                         -- ic_toplev_scope and ic_exports
 660
 661         ic_tmp_ids :: [Id],             -- Names bound during interaction.
 662                                         -- Later Ids shadow
 663                                         -- earlier ones with the same OccName.
 664
 665         ic_tyvars :: TyVarSet           -- skolem type variables free in
 666                                         -- ic_tmp_ids.  These arise at
 667                                         -- breakpoints in a polymorphic
 668                                         -- context, where we have only partial
 669                                         -- type information.
 670
 671 #ifdef GHCI
 672         , ic_resume :: [Resume]         -- the stack of breakpoint contexts
 673 #endif
 674     }
 675
 676
 677 emptyInteractiveContext :: InteractiveContext
 678 emptyInteractiveContext
 679   = InteractiveContext { ic_toplev_scope = [],
 680                          ic_exports = [],
 681                          ic_rn_gbl_env = emptyGlobalRdrEnv,
 682                          ic_tmp_ids = [],
 683                          ic_tyvars = emptyVarSet
 684 #ifdef GHCI
 685                          , ic_resume = []
 686 #endif
 687                        }
 688
 689 icPrintUnqual :: DynFlags -> InteractiveContext -> PrintUnqualified
 690 icPrintUnqual dflags ictxt = mkPrintUnqualified dflags (ic_rn_gbl_env ictxt)
 691
 692
 693 extendInteractiveContext
 694         :: InteractiveContext
 695         -> [Id]
 696         -> TyVarSet
 697         -> InteractiveContext
 698 extendInteractiveContext ictxt ids tyvars
 699   = ictxt { ic_tmp_ids =  ic_tmp_ids ictxt ++ ids,
 700                           -- NB. must be this way around, because we want
 701                           -- new ids to shadow existing bindings.
 702             ic_tyvars   = ic_tyvars ictxt `unionVarSet` tyvars }
 703
 704
 705 substInteractiveContext :: InteractiveContext -> TvSubst -> InteractiveContext
 706 substInteractiveContext ictxt subst | isEmptyTvSubst subst = ictxt
 707 substInteractiveContext ictxt@InteractiveContext{ic_tmp_ids=ids} subst =
 708    let ids'     = map (\id -> id `setIdType` substTy subst (idType id)) ids
 709        subst_dom= varEnvKeys$ getTvSubstEnv subst
 710        subst_ran= varEnvElts$ getTvSubstEnv subst
 711        new_tvs  = [ tv | Just tv <- map getTyVar_maybe subst_ran]
 712        ic_tyvars'= (`delVarSetListByKey` subst_dom)
 713                  . (`extendVarSetList`   new_tvs)
 714                    $ ic_tyvars ictxt
 715     in ictxt { ic_tmp_ids = ids'
 716              , ic_tyvars   = ic_tyvars' }
 717
 718           where delVarSetListByKey = foldl' delVarSetByKey
 719 \end{code}
 720
 721 %************************************************************************
 722 %*                                                                      *
 723         Building a PrintUnqualified
 724 %*                                                                      *
 725 %************************************************************************
 726
 727 Deciding how to print names is pretty tricky.  We are given a name
 728 P:M.T, where P is the package name, M is the defining module, and T is
 729 the occurrence name, and we have to decide in which form to display
 730 the name given a GlobalRdrEnv describing the current scope.
 731
 732 Ideally we want to display the name in the form in which it is in
 733 scope.  However, the name might not be in scope at all, and that's
 734 where it gets tricky.  Here are the cases:
 735
 736  1. T   uniquely maps to  P:M.T                         --->  "T"
 737  2. there is an X for which X.T uniquely maps to  P:M.T --->  "X.T"
 738  3. there is no binding for "M.T"                       --->  "M.T"
 739  4. otherwise                                           --->  "P:M.T"
 740
 741 3 and 4 apply when P:M.T is not in scope.  In these cases we want to
 742 refer to the name as "M.T", but "M.T" might mean something else in the
 743 current scope (e.g. if there's an "import X as M"), so to avoid
 744 confusion we avoid using "M.T" if there's already a binding for it.
 745
 746 There's one further subtlety: if the module M cannot be imported
 747 because it is not exposed by any package, then we must refer to it as
 748 "P:M".  This is handled by the qual_mod component of PrintUnqualified.
 749
 750 \begin{code}
 751 mkPrintUnqualified :: DynFlags -> GlobalRdrEnv -> PrintUnqualified
 752 mkPrintUnqualified dflags env = (qual_name, qual_mod)
 753   where
 754   qual_name mod occ     -- The (mod,occ) pair is the original name of the thing
 755         | [gre] <- unqual_gres, right_name gre = NameUnqual
 756                 -- If there's a unique entity that's in scope unqualified with 'occ'
 757                 -- AND that entity is the right one, then we can use the unqualified name
 758
 759         | [gre] <- qual_gres = NameQual (get_qual_mod (gre_prov gre))
 760
 761         | null qual_gres =
 762               if null (lookupGRE_RdrName (mkRdrQual (moduleName mod) occ) env)
 763                    then NameNotInScope1
 764                    else NameNotInScope2
 765
 766         | otherwise = panic "mkPrintUnqualified"
 767       where
 768         right_name gre = nameModule (gre_name gre) == mod
 769
 770         unqual_gres = lookupGRE_RdrName (mkRdrUnqual occ) env
 771         qual_gres   = filter right_name (lookupGlobalRdrEnv env occ)
 772
 773         get_qual_mod LocalDef      = moduleName mod
 774         get_qual_mod (Imported is) = ASSERT( not (null is) ) is_as (is_decl (head is))
 775
 776     -- we can mention a module P:M without the P: qualifier iff
 777     -- "import M" would resolve unambiguously to P:M.  (if P is the
 778     -- current package we can just assume it is unqualified).
 779
 780   qual_mod mod
 781      | modulePackageId mod == thisPackage dflags = False
 782
 783      | [pkgconfig] <- [pkg | (pkg,exposed_module) <- lookup,
 784                              exposed pkg && exposed_module],
 785        packageConfigId pkgconfig == modulePackageId mod
 786         -- this says: we are given a module P:M, is there just one exposed package
 787         -- that exposes a module M, and is it package P?
 788      = False
 789
 790      | otherwise = True
 791      where lookup = lookupModuleInAllPackages dflags (moduleName mod)
 792 \end{code}
 793
 794
 795 %************************************************************************
 796 %*                                                                      *
 797                 TyThing
 798 %*                                                                      *
 799 %************************************************************************
 800
 801 \begin{code}
 802 -- N.B. the set of TyThings returned here *must* match the set of
 803 -- names returned by LoadIface.ifaceDeclSubBndrs, in the sense that
 804 -- TyThing.getOccName should define a bijection between the two lists.
 805 -- This invariant is used in LoadIface.loadDecl (see note [Tricky iface loop])
 806 -- The order of the list does not matter.
 807 implicitTyThings :: TyThing -> [TyThing]
 808
 809 -- For data and newtype declarations:
 810 implicitTyThings (ATyCon tc) =
 811     -- fields (names of selectors)
 812     map AnId (tyConSelIds tc) ++
 813     -- (possibly) implicit coercion and family coercion
 814     --   depending on whether it's a newtype or a family instance or both
 815     implicitCoTyCon tc ++
 816     -- for each data constructor in order,
 817     --   the contructor, worker, and (possibly) wrapper
 818     concatMap (extras_plus . ADataCon) (tyConDataCons tc)
 819
 820 implicitTyThings (AClass cl)
 821   = -- dictionary datatype:
 822     --    [extras_plus:]
 823     --      type constructor
 824     --    [recursive call:]
 825     --      (possibly) newtype coercion; definitely no family coercion here
 826     --      data constructor
 827     --      worker
 828     --      (no wrapper by invariant)
 829     extras_plus (ATyCon (classTyCon cl)) ++
 830     -- associated types
 831     --    No extras_plus (recursive call) for the classATs, because they
 832     --    are only the family decls; they have no implicit things
 833     map ATyCon (classATs cl) ++
 834     -- superclass and operation selectors
 835     map AnId (classSelIds cl)
 836
 837 implicitTyThings (ADataCon dc) =
 838     -- For data cons add the worker and (possibly) wrapper
 839     map AnId (dataConImplicitIds dc)
 840
 841 implicitTyThings (AnId _)   = []
 842
 843 -- add a thing and recursive call
 844 extras_plus :: TyThing -> [TyThing]
 845 extras_plus thing = thing : implicitTyThings thing
 846
 847 -- For newtypes and indexed data types (and both),
 848 -- add the implicit coercion tycon
 849 implicitCoTyCon :: TyCon -> [TyThing]
 850 implicitCoTyCon tc
 851   = map ATyCon . catMaybes $ [-- Just if newtype, Nothing if not
 852                               newTyConCo_maybe tc,
 853                               -- Just if family instance, Nothing if not
 854                                 tyConFamilyCoercion_maybe tc]
 855
 856 -- sortByOcc = sortBy (\ x -> \ y -> getOccName x < getOccName y)
 857
 858
 859 -- | returns 'True' if there should be no interface-file declaration
 860 -- for this thing on its own: either it is built-in, or it is part
 861 -- of some other declaration, or it is generated implicitly by some
 862 -- other declaration.
 863 isImplicitTyThing :: TyThing -> Bool
 864 isImplicitTyThing (ADataCon _)  = True
 865 isImplicitTyThing (AnId     id) = isImplicitId id
 866 isImplicitTyThing (AClass   _)  = False
 867 isImplicitTyThing (ATyCon   tc) = isImplicitTyCon tc
 868
 869 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 870 extendTypeEnvWithIds env ids
 871   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 872 \end{code}
 873
 874 %************************************************************************
 875 %*                                                                      *
 876                 TypeEnv
 877 %*                                                                      *
 878 %************************************************************************
 879
 880 \begin{code}
 881 type TypeEnv = NameEnv TyThing
 882
 883 emptyTypeEnv    :: TypeEnv
 884 typeEnvElts     :: TypeEnv -> [TyThing]
 885 typeEnvClasses  :: TypeEnv -> [Class]
 886 typeEnvTyCons   :: TypeEnv -> [TyCon]
 887 typeEnvIds      :: TypeEnv -> [Id]
 888 typeEnvDataCons :: TypeEnv -> [DataCon]
 889 lookupTypeEnv   :: TypeEnv -> Name -> Maybe TyThing
 890
 891 emptyTypeEnv        = emptyNameEnv
 892 typeEnvElts     env = nameEnvElts env
 893 typeEnvClasses  env = [cl | AClass cl   <- typeEnvElts env]
 894 typeEnvTyCons   env = [tc | ATyCon tc   <- typeEnvElts env]
 895 typeEnvIds      env = [id | AnId id     <- typeEnvElts env]
 896 typeEnvDataCons env = [dc | ADataCon dc <- typeEnvElts env]
 897
 898 mkTypeEnv :: [TyThing] -> TypeEnv
 899 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 900
 901 lookupTypeEnv = lookupNameEnv
 902
 903 -- Extend the type environment
 904 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
 905 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
 906
 907 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 908 extendTypeEnvList env things = foldl extendTypeEnv env things
 909 \end{code}
 910
 911 \begin{code}
 912 lookupType :: DynFlags
 913            -> HomePackageTable
 914            -> PackageTypeEnv
 915            -> Name
 916            -> Maybe TyThing
 917
 918 lookupType dflags hpt pte name
 919   -- in one-shot, we don't use the HPT
 920   | not (isOneShot (ghcMode dflags)) && modulePackageId mod == this_pkg
 921   = do hm <- lookupUFM hpt (moduleName mod) -- Maybe monad
 922        lookupNameEnv (md_types (hm_details hm)) name
 923   | otherwise
 924   = lookupNameEnv pte name
 925   where mod = nameModule name
 926         this_pkg = thisPackage dflags
 927 \end{code}
 928
 929 \begin{code}
 930 tyThingTyCon :: TyThing -> TyCon
 931 tyThingTyCon (ATyCon tc) = tc
 932 tyThingTyCon other       = pprPanic "tyThingTyCon" (pprTyThing other)
 933
 934 tyThingClass :: TyThing -> Class
 935 tyThingClass (AClass cls) = cls
 936 tyThingClass other        = pprPanic "tyThingClass" (pprTyThing other)
 937
 938 tyThingDataCon :: TyThing -> DataCon
 939 tyThingDataCon (ADataCon dc) = dc
 940 tyThingDataCon other         = pprPanic "tyThingDataCon" (pprTyThing other)
 941
 942 tyThingId :: TyThing -> Id
 943 tyThingId (AnId id) = id
 944 tyThingId other     = pprPanic "tyThingId" (pprTyThing other)
 945 \end{code}
 946
 947 %************************************************************************
 948 %*                                                                      *
 949 \subsection{Auxiliary types}
 950 %*                                                                      *
 951 %************************************************************************
 952
 953 These types are defined here because they are mentioned in ModDetails,
 954 but they are mostly elaborated elsewhere
 955
 956 \begin{code}
 957 mkIfaceVerCache :: [(Version,IfaceDecl)]
 958                 -> (OccName -> Maybe (OccName, Version))
 959 mkIfaceVerCache pairs
 960   = \occ -> lookupOccEnv env occ
 961   where
 962     env = foldr add_decl emptyOccEnv pairs
 963     add_decl (v,d) env0 = foldr add_imp env1 (ifaceDeclSubBndrs d)
 964       where
 965           decl_name = ifName d
 966           env1 = extendOccEnv env0 decl_name (decl_name, v)
 967           add_imp bndr env = extendOccEnv env bndr (decl_name, v)
 968
 969 emptyIfaceVerCache :: OccName -> Maybe (OccName, Version)
 970 emptyIfaceVerCache _occ = Nothing
 971
 972 ------------------ Deprecations -------------------------
 973 data Deprecations
 974   = NoDeprecs
 975   | DeprecAll DeprecTxt         -- Whole module deprecated
 976   | DeprecSome [(OccName,DeprecTxt)] -- Some specific things deprecated
 977      -- Only an OccName is needed because
 978      --    (1) a deprecation always applies to a binding
 979      --        defined in the module in which the deprecation appears.
 980      --    (2) deprecations are only reported outside the defining module.
 981      --        this is important because, otherwise, if we saw something like
 982      --
 983      --        {-# DEPRECATED f "" #-}
 984      --        f = ...
 985      --        h = f
 986      --        g = let f = undefined in f
 987      --
 988      --        we'd need more information than an OccName to know to say something
 989      --        about the use of f in h but not the use of the locally bound f in g
 990      --
 991      --        however, because we only report about deprecations from the outside,
 992      --        and a module can only export one value called f,
 993      --        an OccName suffices.
 994      --
 995      --        this is in contrast with fixity declarations, where we need to map
 996      --        a Name to its fixity declaration.
 997   deriving( Eq )
 998
 999 mkIfaceDepCache :: Deprecations -> Name -> Maybe DeprecTxt
1000 mkIfaceDepCache NoDeprecs         = \_ -> Nothing
1001 mkIfaceDepCache (DeprecAll t)     = \_ -> Just t
1002 mkIfaceDepCache (DeprecSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
1003
1004 emptyIfaceDepCache :: Name -> Maybe DeprecTxt
1005 emptyIfaceDepCache _ = Nothing
1006
1007 plusDeprecs :: Deprecations -> Deprecations -> Deprecations
1008 plusDeprecs d NoDeprecs = d
1009 plusDeprecs NoDeprecs d = d
1010 plusDeprecs _ (DeprecAll t) = DeprecAll t
1011 plusDeprecs (DeprecAll t) _ = DeprecAll t
1012 plusDeprecs (DeprecSome v1) (DeprecSome v2) = DeprecSome (v1 ++ v2)
1013 \end{code}
1014
1015
1016 \begin{code}
1017 type Avails       = [AvailInfo]
1018 type AvailInfo    = GenAvailInfo Name
1019 type RdrAvailInfo = GenAvailInfo OccName
1020
1021 data GenAvailInfo name  = Avail name     -- An ordinary identifier
1022                         | AvailTC name   -- The name of the type or class
1023                                   [name] -- The available pieces of type/class.
1024                                          -- NB: If the type or class is itself
1025                                          -- to be in scope, it must be in this list.
1026                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
1027                         deriving( Eq )
1028                         -- Equality used when deciding if the interface has changed
1029
1030 type IfaceExport = (Module, [GenAvailInfo OccName])
1031
1032 availsToNameSet :: [AvailInfo] -> NameSet
1033 availsToNameSet avails = foldr add emptyNameSet avails
1034       where add avail set = addListToNameSet set (availNames avail)
1035
1036 availsToNameEnv :: [AvailInfo] -> NameEnv AvailInfo
1037 availsToNameEnv avails = foldr add emptyNameEnv avails
1038      where add avail env = extendNameEnvList env
1039                                 (zip (availNames avail) (repeat avail))
1040
1041 availName :: GenAvailInfo name -> name
1042 availName (Avail n)     = n
1043 availName (AvailTC n _) = n
1044
1045 availNames :: GenAvailInfo name -> [name]
1046 availNames (Avail n)      = [n]
1047 availNames (AvailTC _ ns) = ns
1048
1049 instance Outputable n => Outputable (GenAvailInfo n) where
1050    ppr = pprAvail
1051
1052 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
1053 pprAvail (Avail n)      = ppr n
1054 pprAvail (AvailTC n ns) = ppr n <> braces (hsep (punctuate comma (map ppr ns)))
1055 \end{code}
1056
1057 \begin{code}
1058 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
1059 mkIfaceFixCache pairs
1060   = \n -> lookupOccEnv env n `orElse` defaultFixity
1061   where
1062    env = mkOccEnv pairs
1063
1064 emptyIfaceFixCache :: OccName -> Fixity
1065 emptyIfaceFixCache _ = defaultFixity
1066
1067 -- This fixity environment is for source code only
1068 type FixityEnv = NameEnv FixItem
1069
1070 -- We keep the OccName in the range so that we can generate an interface from it
1071 data FixItem = FixItem OccName Fixity
1072
1073 instance Outputable FixItem where
1074   ppr (FixItem occ fix) = ppr fix <+> ppr occ
1075
1076 emptyFixityEnv :: FixityEnv
1077 emptyFixityEnv = emptyNameEnv
1078
1079 lookupFixity :: FixityEnv -> Name -> Fixity
1080 lookupFixity env n = case lookupNameEnv env n of
1081                         Just (FixItem _ fix) -> fix
1082                         Nothing         -> defaultFixity
1083 \end{code}
1084
1085
1086 %************************************************************************
1087 %*                                                                      *
1088 \subsection{WhatsImported}
1089 %*                                                                      *
1090 %************************************************************************
1091
1092 \begin{code}
1093 type WhetherHasOrphans   = Bool
1094         -- An "orphan" is
1095         --      * an instance decl in a module other than the defn module for
1096         --              one of the tycons or classes in the instance head
1097         --      * a transformation rule in a module other than the one defining
1098         --              the function in the head of the rule.
1099
1100 type WhetherHasFamInst = Bool        -- This module defines family instances?
1101
1102 type IsBootInterface = Bool
1103
1104 -- Dependency info about modules and packages below this one
1105 -- in the import hierarchy.  See TcRnTypes.ImportAvails for details.
1106 -- The orphan modules in `dep_orphs' do *not* include family instance orphans,
1107 -- as they are anyway included in `dep_finsts'.
1108 --
1109 -- Invariant: the dependencies of a module M never includes M
1110 -- Invariant: the lists are unordered, with no duplicates
1111 data Dependencies
1112   = Deps { dep_mods   :: [(ModuleName,      -- Home-package module dependencies
1113                            IsBootInterface)]
1114          , dep_pkgs   :: [PackageId]        -- External package dependencies
1115          , dep_orphs  :: [Module]           -- Orphan modules (whether home or
1116                                             -- external pkg)
1117          , dep_finsts :: [Module]           -- Modules that contain family
1118                                             -- instances (whether home or
1119                                             -- external pkg)
1120          }
1121   deriving( Eq )
1122         -- Equality used only for old/new comparison in MkIface.addVersionInfo
1123
1124 noDependencies :: Dependencies
1125 noDependencies = Deps [] [] [] []
1126
1127 data Usage
1128   = Usage { usg_name     :: ModuleName,                 -- Name of the module
1129             usg_mod      :: Version,                    -- Module version
1130             usg_entities :: [(OccName,Version)],        -- Sorted by occurrence name
1131                 -- NB. usages are for parent names only, eg. tycon but not constructors.
1132             usg_exports  :: Maybe Version,              -- Export-list version, if we depend on it
1133             usg_rules    :: Version                     -- Orphan-rules version (for non-orphan
1134                                                         -- modules this will always be initialVersion)
1135     }       deriving( Eq )
1136         -- This type doesn't let you say "I imported f but none of the rules in
1137         -- the module". If you use anything in the module you get its rule version
1138         -- So if the rules change, you'll recompile, even if you don't use them.
1139         -- This is easy to implement, and it's safer: you might not have used the rules last
1140         -- time round, but if someone has added a new rule you might need it this time
1141
1142         -- The export list field is (Just v) if we depend on the export list:
1143         --      i.e. we imported the module directly, whether or not we
1144         --           enumerated the things we imported, or just imported everything
1145         -- We need to recompile if M's exports change, because
1146         -- if the import was    import M,       we might now have a name clash in the
1147         --                                      importing module.
1148         -- if the import was    import M(x)     M might no longer export x
1149         -- The only way we don't depend on the export list is if we have
1150         --                      import M()
1151         -- And of course, for modules that aren't imported directly we don't
1152         -- depend on their export lists
1153 \end{code}
1154
1155
1156 %************************************************************************
1157 %*                                                                      *
1158                 The External Package State
1159 %*                                                                      *
1160 %************************************************************************
1161
1162 \begin{code}
1163 type PackageTypeEnv    = TypeEnv
1164 type PackageRuleBase   = RuleBase
1165 type PackageInstEnv    = InstEnv
1166 type PackageFamInstEnv = FamInstEnv
1167 type PackageVectInfo   = VectInfo
1168
1169 data ExternalPackageState
1170   = EPS {
1171         eps_is_boot :: !(ModuleNameEnv (ModuleName, IsBootInterface)),
1172                 -- In OneShot mode (only), home-package modules
1173                 -- accumulate in the external package state, and are
1174                 -- sucked in lazily.  For these home-pkg modules
1175                 -- (only) we need to record which are boot modules.
1176                 -- We set this field after loading all the
1177                 -- explicitly-imported interfaces, but before doing
1178                 -- anything else
1179                 --
1180                 -- The ModuleName part is not necessary, but it's useful for
1181                 -- debug prints, and it's convenient because this field comes
1182                 -- direct from TcRnTypes.ImportAvails.imp_dep_mods
1183
1184         eps_PIT :: !PackageIfaceTable,
1185                 -- The ModuleIFaces for modules in external packages
1186                 -- whose interfaces we have opened
1187                 -- The declarations in these interface files are held in
1188                 -- eps_decls, eps_inst_env, eps_fam_inst_env, eps_rules
1189                 -- (below), not in the mi_decls fields of the iPIT.
1190                 -- What _is_ in the iPIT is:
1191                 --      * The Module
1192                 --      * Version info
1193                 --      * Its exports
1194                 --      * Fixities
1195                 --      * Deprecations
1196
1197         eps_PTE :: !PackageTypeEnv,        -- Domain = external-package modules
1198
1199         eps_inst_env     :: !PackageInstEnv,   -- The total InstEnv accumulated
1200                                                -- from all the external-package
1201                                                -- modules
1202         eps_fam_inst_env :: !PackageFamInstEnv,-- Ditto FamInstEnv
1203         eps_rule_base    :: !PackageRuleBase,  -- Ditto RuleEnv
1204         eps_vect_info    :: !PackageVectInfo,  -- Ditto VectInfo
1205
1206         eps_mod_fam_inst_env :: !(ModuleEnv FamInstEnv), -- identifies family
1207                                                        -- instances of each mod
1208         eps_stats :: !EpsStats
1209   }
1210
1211 -- "In" means read from iface files
1212 -- "Out" means actually sucked in and type-checked
1213 data EpsStats = EpsStats { n_ifaces_in
1214                          , n_decls_in, n_decls_out
1215                          , n_rules_in, n_rules_out
1216                          , n_insts_in, n_insts_out :: !Int }
1217
1218 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
1219 -- Add stats for one newly-read interface
1220 addEpsInStats stats n_decls n_insts n_rules
1221   = stats { n_ifaces_in = n_ifaces_in stats + 1
1222           , n_decls_in  = n_decls_in stats + n_decls
1223           , n_insts_in  = n_insts_in stats + n_insts
1224           , n_rules_in  = n_rules_in stats + n_rules }
1225 \end{code}
1226
1227 The NameCache makes sure that there is just one Unique assigned for
1228 each original name; i.e. (module-name, occ-name) pair.  The Name is
1229 always stored as a Global, and has the SrcLoc of its binding location.
1230 Actually that's not quite right.  When we first encounter the original
1231 name, we might not be at its binding site (e.g. we are reading an
1232 interface file); so we give it 'noSrcLoc' then.  Later, when we find
1233 its binding site, we fix it up.
1234
1235 \begin{code}
1236 data NameCache
1237  = NameCache {  nsUniqs :: UniqSupply,
1238                 -- Supply of uniques
1239                 nsNames :: OrigNameCache,
1240                 -- Ensures that one original name gets one unique
1241                 nsIPs   :: OrigIParamCache
1242                 -- Ensures that one implicit parameter name gets one unique
1243    }
1244
1245 type OrigNameCache   = ModuleEnv (OccEnv Name)
1246 type OrigIParamCache = FiniteMap (IPName OccName) (IPName Name)
1247 \end{code}
1248
1249
1250
1251 %************************************************************************
1252 %*                                                                      *
1253                 The module graph and ModSummary type
1254         A ModSummary is a node in the compilation manager's
1255         dependency graph, and it's also passed to hscMain
1256 %*                                                                      *
1257 %************************************************************************
1258
1259 A ModuleGraph contains all the nodes from the home package (only).
1260 There will be a node for each source module, plus a node for each hi-boot
1261 module.
1262
1263 \begin{code}
1264 type ModuleGraph = [ModSummary]  -- The module graph,
1265                                  -- NOT NECESSARILY IN TOPOLOGICAL ORDER
1266
1267 emptyMG :: ModuleGraph
1268 emptyMG = []
1269
1270 -- The nodes of the module graph are
1271 --      EITHER a regular Haskell source module
1272 --      OR     a hi-boot source module
1273
1274 data ModSummary
1275    = ModSummary {
1276         ms_mod       :: Module,                 -- Identity of the module
1277         ms_hsc_src   :: HscSource,              -- Source is Haskell, hs-boot, external core
1278         ms_location  :: ModLocation,            -- Location
1279         ms_hs_date   :: ClockTime,              -- Timestamp of source file
1280         ms_obj_date  :: Maybe ClockTime,        -- Timestamp of object, maybe
1281         ms_srcimps   :: [Located ModuleName],   -- Source imports
1282         ms_imps      :: [Located ModuleName],   -- Non-source imports
1283         ms_hspp_file :: FilePath,               -- Filename of preprocessed source.
1284         ms_hspp_opts :: DynFlags,               -- Cached flags from OPTIONS, INCLUDE
1285                                                 -- and LANGUAGE pragmas.
1286         ms_hspp_buf  :: Maybe StringBuffer      -- The actual preprocessed source, maybe.
1287      }
1288
1289 ms_mod_name :: ModSummary -> ModuleName
1290 ms_mod_name = moduleName . ms_mod
1291
1292 -- The ModLocation contains both the original source filename and the
1293 -- filename of the cleaned-up source file after all preprocessing has been
1294 -- done.  The point is that the summariser will have to cpp/unlit/whatever
1295 -- all files anyway, and there's no point in doing this twice -- just
1296 -- park the result in a temp file, put the name of it in the location,
1297 -- and let @compile@ read from that file on the way back up.
1298
1299 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
1300 -- the ms_hs_date and imports can, of course, change
1301
1302 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
1303 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
1304 msHiFilePath  ms = ml_hi_file  (ms_location ms)
1305 msObjFilePath ms = ml_obj_file (ms_location ms)
1306
1307 isBootSummary :: ModSummary -> Bool
1308 isBootSummary ms = isHsBoot (ms_hsc_src ms)
1309
1310 instance Outputable ModSummary where
1311    ppr ms
1312       = sep [text "ModSummary {",
1313              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
1314                           text "ms_mod =" <+> ppr (ms_mod ms)
1315                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
1316                           text "ms_imps =" <+> ppr (ms_imps ms),
1317                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
1318              char '}'
1319             ]
1320
1321 showModMsg :: HscTarget -> Bool -> ModSummary -> String
1322 showModMsg target recomp mod_summary
1323   = showSDoc (hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
1324                     char '(', text (msHsFilePath mod_summary) <> comma,
1325                     case target of
1326                       HscInterpreted | recomp
1327                                  -> text "interpreted"
1328                       HscNothing -> text "nothing"
1329                       _other     -> text (msObjFilePath mod_summary),
1330                     char ')'])
1331  where
1332     mod     = moduleName (ms_mod mod_summary)
1333     mod_str = showSDoc (ppr mod) ++ hscSourceString (ms_hsc_src mod_summary)
1334 \end{code}
1335
1336
1337 %************************************************************************
1338 %*                                                                      *
1339 \subsection{Hpc Support}
1340 %*                                                                      *
1341 %************************************************************************
1342
1343 \begin{code}
1344 data HpcInfo
1345   = HpcInfo
1346      { hpcInfoTickCount :: Int
1347      , hpcInfoHash      :: Int
1348      }
1349   | NoHpcInfo
1350      { hpcUsed          :: AnyHpcUsage  -- is hpc used anywhere on the module tree?
1351      }
1352
1353 -- This is used to mean there is no module-local hpc usage,
1354 -- but one of my imports used hpc instrumentation.
1355
1356 type AnyHpcUsage = Bool
1357
1358 emptyHpcInfo :: AnyHpcUsage -> HpcInfo
1359 emptyHpcInfo = NoHpcInfo
1360
1361 isHpcUsed :: HpcInfo -> AnyHpcUsage
1362 isHpcUsed (HpcInfo {})                   = True
1363 isHpcUsed (NoHpcInfo { hpcUsed = used }) = used
1364 \end{code}
1365
1366 %************************************************************************
1367 %*                                                                      *
1368 \subsection{Vectorisation Support}
1369 %*                                                                      *
1370 %************************************************************************
1371
1372 The following information is generated and consumed by the vectorisation
1373 subsystem.  It communicates the vectorisation status of declarations from one
1374 module to another.
1375
1376 Why do we need both f and f_v in the ModGuts/ModDetails/EPS version VectInfo
1377 below?  We need to know `f' when converting to IfaceVectInfo.  However, during
1378 vectorisation, we need to know `f_v', whose `Var' we cannot lookup based
1379 on just the OccName easily in a Core pass.
1380
1381 \begin{code}
1382 -- ModGuts/ModDetails/EPS version
1383 data VectInfo
1384   = VectInfo {
1385       vectInfoVar     :: VarEnv  (Var    , Var  ),   -- (f, f_v) keyed on f
1386       vectInfoTyCon   :: NameEnv (TyCon  , TyCon),   -- (T, T_v) keyed on T
1387       vectInfoDataCon :: NameEnv (DataCon, DataCon), -- (C, C_v) keyed on C
1388       vectInfoPADFun  :: NameEnv (TyCon  , Var),     -- (T_v, paT) keyed on T_v
1389       vectInfoIso     :: NameEnv (TyCon  , Var)      -- (T, isoT) keyed on T
1390     }
1391     -- all of this is always tidy, even in ModGuts
1392
1393 -- ModIface version
1394 data IfaceVectInfo
1395   = IfaceVectInfo {
1396       ifaceVectInfoVar        :: [Name],
1397         -- all variables in here have a vectorised variant;
1398         -- the name of the vectorised variant is determined by `mkCloVect'
1399       ifaceVectInfoTyCon      :: [Name],
1400         -- all tycons in here have a vectorised variant;
1401         -- the name of the vectorised variant and those of its
1402         -- data constructors are determined by `mkVectTyConOcc'
1403         -- and `mkVectDataConOcc'; the names of
1404         -- the isomorphisms is determined by `mkVectIsoOcc'
1405       ifaceVectInfoTyConReuse :: [Name]
1406         -- the vectorised form of all the tycons in here coincids with
1407         -- the unconverted from; the names of the isomorphisms is determined
1408         -- by `mkVectIsoOcc'
1409     }
1410
1411 noVectInfo :: VectInfo
1412 noVectInfo = VectInfo emptyVarEnv emptyNameEnv emptyNameEnv emptyNameEnv emptyNameEnv
1413
1414 plusVectInfo :: VectInfo -> VectInfo -> VectInfo
1415 plusVectInfo vi1 vi2 =
1416   VectInfo (vectInfoVar     vi1 `plusVarEnv`  vectInfoVar     vi2)
1417            (vectInfoTyCon   vi1 `plusNameEnv` vectInfoTyCon   vi2)
1418            (vectInfoDataCon vi1 `plusNameEnv` vectInfoDataCon vi2)
1419            (vectInfoPADFun  vi1 `plusNameEnv` vectInfoPADFun  vi2)
1420            (vectInfoIso     vi1 `plusNameEnv` vectInfoIso     vi2)
1421
1422 noIfaceVectInfo :: IfaceVectInfo
1423 noIfaceVectInfo = IfaceVectInfo [] [] []
1424 \end{code}
1425
1426 %************************************************************************
1427 %*                                                                      *
1428 \subsection{Linkable stuff}
1429 %*                                                                      *
1430 %************************************************************************
1431
1432 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
1433 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
1434
1435 \begin{code}
1436 data Linkable = LM {
1437   linkableTime     :: ClockTime,        -- Time at which this linkable was built
1438                                         -- (i.e. when the bytecodes were produced,
1439                                         --       or the mod date on the files)
1440   linkableModule   :: Module,           -- Should be Module, but see below
1441   linkableUnlinked :: [Unlinked]
1442  }
1443
1444 isObjectLinkable :: Linkable -> Bool
1445 isObjectLinkable l = not (null unlinked) && all isObject unlinked
1446   where unlinked = linkableUnlinked l
1447         -- A linkable with no Unlinked's is treated as a BCO.  We can
1448         -- generate a linkable with no Unlinked's as a result of
1449         -- compiling a module in HscNothing mode, and this choice
1450         -- happens to work well with checkStability in module GHC.
1451
1452 instance Outputable Linkable where
1453    ppr (LM when_made mod unlinkeds)
1454       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
1455         $$ nest 3 (ppr unlinkeds)
1456
1457 -------------------------------------------
1458 data Unlinked
1459    = DotO FilePath
1460    | DotA FilePath
1461    | DotDLL FilePath
1462    | BCOs CompiledByteCode ModBreaks
1463
1464 #ifndef GHCI
1465 data CompiledByteCode
1466 #endif
1467
1468 instance Outputable Unlinked where
1469    ppr (DotO path)   = text "DotO" <+> text path
1470    ppr (DotA path)   = text "DotA" <+> text path
1471    ppr (DotDLL path) = text "DotDLL" <+> text path
1472 #ifdef GHCI
1473    ppr (BCOs bcos _) = text "BCOs" <+> ppr bcos
1474 #else
1475    ppr (BCOs _ _)    = text "No byte code"
1476 #endif
1477
1478 isObject :: Unlinked -> Bool
1479 isObject (DotO _)   = True
1480 isObject (DotA _)   = True
1481 isObject (DotDLL _) = True
1482 isObject _          = False
1483
1484 isInterpretable :: Unlinked -> Bool
1485 isInterpretable = not . isObject
1486
1487 nameOfObject :: Unlinked -> FilePath
1488 nameOfObject (DotO fn)   = fn
1489 nameOfObject (DotA fn)   = fn
1490 nameOfObject (DotDLL fn) = fn
1491 nameOfObject other       = pprPanic "nameOfObject" (ppr other)
1492
1493 byteCodeOfObject :: Unlinked -> CompiledByteCode
1494 byteCodeOfObject (BCOs bc _) = bc
1495 byteCodeOfObject other       = pprPanic "byteCodeOfObject" (ppr other)
1496 \end{code}
1497
1498 %************************************************************************
1499 %*                                                                      *
1500 \subsection{Breakpoint Support}
1501 %*                                                                      *
1502 %************************************************************************
1503
1504 \begin{code}
1505 type BreakIndex = Int
1506
1507 -- | all the information about the breakpoints for a given module
1508 data ModBreaks
1509    = ModBreaks
1510    { modBreaks_flags :: BreakArray
1511         -- The array of flags, one per breakpoint,
1512         -- indicating which breakpoints are enabled.
1513    , modBreaks_locs :: !(Array BreakIndex SrcSpan)
1514         -- An array giving the source span of each breakpoint.
1515    , modBreaks_vars :: !(Array BreakIndex [OccName])
1516         -- An array giving the names of the free variables at each breakpoint.
1517    }
1518
1519 emptyModBreaks :: ModBreaks
1520 emptyModBreaks = ModBreaks
1521    { modBreaks_flags = error "ModBreaks.modBreaks_array not initialised"
1522          -- Todo: can we avoid this?
1523    , modBreaks_locs = array (0,-1) []
1524    , modBreaks_vars = array (0,-1) []
1525    }
1526 \end{code}