compiler/main/HscTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 \section[HscTypes]{Types for the per-module compiler}
   5
   6 \begin{code}
   7 module HscTypes (
   8         -- * Sessions and compilation state
   9         Session(..), withSession, modifySession,
  10         HscEnv(..), hscEPS,
  11         FinderCache, FindResult(..), ModLocationCache,
  12         Target(..), TargetId(..), pprTarget, pprTargetId,
  13         ModuleGraph, emptyMG,
  14
  15         ModDetails(..), emptyModDetails,
  16         ModGuts(..), CoreModule(..), CgGuts(..), ModImports(..), ForeignStubs(..),
  17         ImportedMods,
  18
  19         ModSummary(..), ms_mod_name, showModMsg, isBootSummary,
  20         msHsFilePath, msHiFilePath, msObjFilePath,
  21
  22         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
  23
  24         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
  25         hptInstances, hptRules, hptVectInfo,
  26
  27         ExternalPackageState(..), EpsStats(..), addEpsInStats,
  28         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
  29         lookupIfaceByModule, emptyModIface,
  30
  31         InteractiveContext(..), emptyInteractiveContext,
  32         icPrintUnqual, mkPrintUnqualified, extendInteractiveContext,
  33         substInteractiveContext,
  34
  35         ModIface(..), mkIfaceDepCache, mkIfaceVerCache, mkIfaceFixCache,
  36         emptyIfaceDepCache,
  37
  38         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
  39
  40         implicitTyThings, isImplicitTyThing,
  41
  42         TyThing(..), tyThingClass, tyThingTyCon, tyThingDataCon, tyThingId,
  43         TypeEnv, lookupType, mkTypeEnv, emptyTypeEnv,
  44         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
  45         typeEnvElts, typeEnvClasses, typeEnvTyCons, typeEnvIds,
  46         typeEnvDataCons,
  47
  48         WhetherHasOrphans, IsBootInterface, Usage(..),
  49         Dependencies(..), noDependencies,
  50         NameCache(..), OrigNameCache, OrigIParamCache,
  51         Avails, availsToNameSet, availsToNameEnv, availName, availNames,
  52         GenAvailInfo(..), AvailInfo, RdrAvailInfo,
  53         IfaceExport,
  54
  55         Deprecations(..), DeprecTxt, plusDeprecs,
  56
  57         PackageInstEnv, PackageRuleBase,
  58
  59         -- Linker stuff
  60         Linkable(..), isObjectLinkable,
  61         Unlinked(..), CompiledByteCode,
  62         isObject, nameOfObject, isInterpretable, byteCodeOfObject,
  63         HpcInfo(..), emptyHpcInfo, isHpcUsed, AnyHpcUsage,
  64
  65         -- Breakpoints
  66         ModBreaks (..), BreakIndex, emptyModBreaks,
  67
  68         -- Vectorisation information
  69         VectInfo(..), IfaceVectInfo(..), noVectInfo, plusVectInfo,
  70         noIfaceVectInfo
  71     ) where
  72
  73 #include "HsVersions.h"
  74
  75 #ifdef GHCI
  76 import ByteCodeAsm      ( CompiledByteCode )
  77 import {-# SOURCE #-}  InteractiveEval ( Resume )
  78 #endif
  79
  80 import RdrName
  81 import Name             ( Name, NamedThing, getName, nameOccName, nameModule )
  82 import NameEnv
  83 import NameSet
  84 import OccName          ( OccName, OccEnv, lookupOccEnv, mkOccEnv, emptyOccEnv,
  85                           extendOccEnv )
  86 import Module
  87 import InstEnv          ( InstEnv, Instance )
  88 import FamInstEnv       ( FamInstEnv, FamInst )
  89 import Rules            ( RuleBase )
  90 import CoreSyn          ( CoreBind )
  91 import VarEnv
  92 import VarSet
  93 import Var       hiding ( setIdType )
  94 import Id
  95 import Type
  96
  97 import Class            ( Class, classSelIds, classATs, classTyCon )
  98 import TyCon
  99 import DataCon          ( DataCon, dataConImplicitIds, dataConWrapId )
 100 import PrelNames        ( gHC_PRIM )
 101 import Packages hiding ( Version(..) )
 102 import DynFlags         ( DynFlags(..), isOneShot, HscTarget (..) )
 103 import DriverPhases     ( HscSource(..), isHsBoot, hscSourceString, Phase )
 104 import BasicTypes       ( Version, initialVersion, IPName,
 105                           Fixity, defaultFixity, DeprecTxt )
 106 import IfaceSyn
 107 import FiniteMap        ( FiniteMap )
 108 import CoreSyn          ( CoreRule )
 109 import Maybes           ( orElse, expectJust, catMaybes )
 110 import Outputable
 111 import BreakArray
 112 import SrcLoc           ( SrcSpan, Located )
 113 import LazyUniqFM               ( lookupUFM, eltsUFM, emptyUFM )
 114 import UniqSupply       ( UniqSupply )
 115 import FastString
 116 import StringBuffer     ( StringBuffer )
 117
 118 import System.FilePath
 119 import System.Time      ( ClockTime )
 120 import Data.IORef
 121 import Data.Array       ( Array, array )
 122 import Data.List
 123 import Control.Monad    ( mplus )
 124 \end{code}
 125
 126
 127 %************************************************************************
 128 %*                                                                      *
 129 \subsection{Compilation environment}
 130 %*                                                                      *
 131 %************************************************************************
 132
 133
 134 \begin{code}
 135 -- | The Session is a handle to the complete state of a compilation
 136 -- session.  A compilation session consists of a set of modules
 137 -- constituting the current program or library, the context for
 138 -- interactive evaluation, and various caches.
 139 newtype Session = Session (IORef HscEnv)
 140
 141 withSession :: Session -> (HscEnv -> IO a) -> IO a
 142 withSession (Session ref) f = do h <- readIORef ref; f h
 143
 144 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 145 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 146 \end{code}
 147
 148 HscEnv is like Session, except that some of the fields are immutable.
 149 An HscEnv is used to compile a single module from plain Haskell source
 150 code (after preprocessing) to either C, assembly or C--.  Things like
 151 the module graph don't change during a single compilation.
 152
 153 Historical note: "hsc" used to be the name of the compiler binary,
 154 when there was a separate driver and compiler.  To compile a single
 155 module, the driver would invoke hsc on the source code... so nowadays
 156 we think of hsc as the layer of the compiler that deals with compiling
 157 a single module.
 158
 159 \begin{code}
 160 data HscEnv
 161   = HscEnv {
 162         hsc_dflags :: DynFlags,
 163                 -- The dynamic flag settings
 164
 165         hsc_targets :: [Target],
 166                 -- The targets (or roots) of the current session
 167
 168         hsc_mod_graph :: ModuleGraph,
 169                 -- The module graph of the current session
 170
 171         hsc_IC :: InteractiveContext,
 172                 -- The context for evaluating interactive statements
 173
 174         hsc_HPT    :: HomePackageTable,
 175                 -- The home package table describes already-compiled
 176                 -- home-packge modules, *excluding* the module we
 177                 -- are compiling right now.
 178                 -- (In one-shot mode the current module is the only
 179                 --  home-package module, so hsc_HPT is empty.  All other
 180                 --  modules count as "external-package" modules.
 181                 --  However, even in GHCi mode, hi-boot interfaces are
 182                 --  demand-loadeded into the external-package table.)
 183                 --
 184                 -- hsc_HPT is not mutable because we only demand-load
 185                 -- external packages; the home package is eagerly
 186                 -- loaded, module by module, by the compilation manager.
 187                 --
 188                 -- The HPT may contain modules compiled earlier by --make
 189                 -- but not actually below the current module in the dependency
 190                 -- graph.  (This changes a previous invariant: changed Jan 05.)
 191
 192         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
 193         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
 194                 -- These are side-effected by compiling to reflect
 195                 -- sucking in interface files.  They cache the state of
 196                 -- external interface files, in effect.
 197
 198         hsc_FC   :: {-# UNPACK #-} !(IORef FinderCache),
 199         hsc_MLC  :: {-# UNPACK #-} !(IORef ModLocationCache),
 200                 -- The finder's cache.  This caches the location of modules,
 201                 -- so we don't have to search the filesystem multiple times.
 202
 203         hsc_global_rdr_env :: GlobalRdrEnv,
 204         hsc_global_type_env :: TypeEnv
 205  }
 206
 207 hscEPS :: HscEnv -> IO ExternalPackageState
 208 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
 209
 210 -- | A compilation target.
 211 --
 212 -- A target may be supplied with the actual text of the
 213 -- module.  If so, use this instead of the file contents (this
 214 -- is for use in an IDE where the file hasn't been saved by
 215 -- the user yet).
 216 data Target = Target TargetId (Maybe (StringBuffer,ClockTime))
 217
 218 data TargetId
 219   = TargetModule ModuleName
 220         -- ^ A module name: search for the file
 221   | TargetFile FilePath (Maybe Phase)
 222         -- ^ A filename: preprocess & parse it to find the module name.
 223         -- If specified, the Phase indicates how to compile this file
 224         -- (which phase to start from).  Nothing indicates the starting phase
 225         -- should be determined from the suffix of the filename.
 226   deriving Eq
 227
 228 pprTarget :: Target -> SDoc
 229 pprTarget (Target id _) = pprTargetId id
 230
 231 instance Outputable Target where
 232     ppr = pprTarget
 233
 234 pprTargetId :: TargetId -> SDoc
 235 pprTargetId (TargetModule m) = ppr m
 236 pprTargetId (TargetFile f _) = text f
 237
 238 instance Outputable TargetId where
 239     ppr = pprTargetId
 240
 241 type HomePackageTable  = ModuleNameEnv HomeModInfo
 242         -- Domain = modules in the home package
 243         -- "home" package name cached here for convenience
 244 type PackageIfaceTable = ModuleEnv ModIface
 245         -- Domain = modules in the imported packages
 246
 247 emptyHomePackageTable :: HomePackageTable
 248 emptyHomePackageTable  = emptyUFM
 249
 250 emptyPackageIfaceTable :: PackageIfaceTable
 251 emptyPackageIfaceTable = emptyModuleEnv
 252
 253 data HomeModInfo
 254   = HomeModInfo { hm_iface    :: !ModIface,
 255                   hm_details  :: !ModDetails,
 256                   hm_linkable :: !(Maybe Linkable) }
 257                 -- hm_linkable might be Nothing if:
 258                 --   a) this is an .hs-boot module
 259                 --   b) temporarily during compilation if we pruned away
 260                 --      the old linkable because it was out of date.
 261                 -- after a complete compilation (GHC.load), all hm_linkable
 262                 -- fields in the HPT will be Just.
 263                 --
 264                 -- When re-linking a module (hscNoRecomp), we construct
 265                 -- the HomModInfo by building a new ModDetails from the
 266                 -- old ModIface (only).
 267
 268 -- | Find the 'ModIface' for a 'Module'
 269 lookupIfaceByModule
 270         :: DynFlags
 271         -> HomePackageTable
 272         -> PackageIfaceTable
 273         -> Module
 274         -> Maybe ModIface
 275 lookupIfaceByModule dflags hpt pit mod
 276   | modulePackageId mod == thisPackage dflags
 277   =     -- The module comes from the home package, so look first
 278         -- in the HPT.  If it's not from the home package it's wrong to look
 279         -- in the HPT, because the HPT is indexed by *ModuleName* not Module
 280     fmap hm_iface (lookupUFM hpt (moduleName mod))
 281     `mplus` lookupModuleEnv pit mod
 282
 283   | otherwise = lookupModuleEnv pit mod         -- Look in PIT only
 284
 285 -- If the module does come from the home package, why do we look in the PIT as well?
 286 -- (a) In OneShot mode, even home-package modules accumulate in the PIT
 287 -- (b) Even in Batch (--make) mode, there is *one* case where a home-package
 288 --     module is in the PIT, namely GHC.Prim when compiling the base package.
 289 -- We could eliminate (b) if we wanted, by making GHC.Prim belong to a package
 290 -- of its own, but it doesn't seem worth the bother.
 291 \end{code}
 292
 293
 294 \begin{code}
 295 hptInstances :: HscEnv -> (ModuleName -> Bool) -> ([Instance], [FamInst])
 296 -- Find all the instance declarations (of classes and families) that are in
 297 -- modules imported by this one, directly or indirectly, and are in the Home
 298 -- Package Table.  This ensures that we don't see instances from modules --make
 299 -- compiled before this one, but which are not below this one.
 300 hptInstances hsc_env want_this_module
 301   = let (insts, famInsts) = unzip
 302           [ (md_insts details, md_fam_insts details)
 303           | mod_info <- eltsUFM (hsc_HPT hsc_env)
 304           , want_this_module (moduleName (mi_module (hm_iface mod_info)))
 305           , let details = hm_details mod_info ]
 306     in
 307     (concat insts, concat famInsts)
 308
 309 hptRules :: HscEnv -> [(ModuleName, IsBootInterface)] -> [CoreRule]
 310 -- Get rules from modules "below" this one (in the dependency sense)
 311 -- C.f Inst.hptInstances
 312 hptRules hsc_env deps
 313   | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
 314   | otherwise
 315   = let
 316         hpt = hsc_HPT hsc_env
 317     in
 318     [ rule
 319     |   -- Find each non-hi-boot module below me
 320       (mod, False) <- deps
 321
 322         -- unsavoury: when compiling the base package with --make, we
 323         -- sometimes try to look up RULES for GHC.Prim.  GHC.Prim won't
 324         -- be in the HPT, because we never compile it; it's in the EPT
 325         -- instead.  ToDo: clean up, and remove this slightly bogus
 326         -- filter:
 327     , mod /= moduleName gHC_PRIM
 328
 329         -- Look it up in the HPT
 330     , let rules = case lookupUFM hpt mod of
 331                     Just info -> md_rules (hm_details info)
 332                     Nothing -> pprTrace "WARNING in hptRules" msg []
 333           msg = vcat [ptext SLIT("missing module") <+> ppr mod,
 334                       ptext SLIT("Probable cause: out-of-date interface files")]
 335                         -- This really shouldn't happen, but see Trac #962
 336
 337         -- And get its dfuns
 338     , rule <- rules ]
 339
 340 hptVectInfo :: HscEnv -> VectInfo
 341 -- Get the combined VectInfo of all modules in the home package table.  In
 342 -- contrast to instances and rules, we don't care whether the modules are
 343 -- "below" or us.  The VectInfo of those modules not "below" us does not
 344 -- affect the compilation of the current module.
 345 hptVectInfo hsc_env
 346   = foldr plusVectInfo noVectInfo [ md_vect_info (hm_details mod_info)
 347                                   | mod_info <- eltsUFM (hsc_HPT hsc_env)]
 348 \end{code}
 349
 350 %************************************************************************
 351 %*                                                                      *
 352 \subsection{The Finder cache}
 353 %*                                                                      *
 354 %************************************************************************
 355
 356 \begin{code}
 357 -- | The 'FinderCache' maps home module names to the result of
 358 -- searching for that module.  It records the results of searching for
 359 -- modules along the search path.  On @:load@, we flush the entire
 360 -- contents of this cache.
 361 --
 362 -- Although the @FinderCache@ range is 'FindResult' for convenience ,
 363 -- in fact it will only ever contain 'Found' or 'NotFound' entries.
 364 --
 365 type FinderCache = ModuleNameEnv FindResult
 366
 367 -- | The result of searching for an imported module.
 368 data FindResult
 369   = Found ModLocation Module
 370         -- the module was found
 371   | NoPackage PackageId
 372         -- the requested package was not found
 373   | FoundMultiple [PackageId]
 374         -- *error*: both in multiple packages
 375   | PackageHidden PackageId
 376         -- for an explicit source import: the package containing the module is
 377         -- not exposed.
 378   | ModuleHidden  PackageId
 379         -- for an explicit source import: the package containing the module is
 380         -- exposed, but the module itself is hidden.
 381   | NotFound [FilePath] (Maybe PackageId)
 382         -- the module was not found, the specified places were searched
 383   | NotFoundInPackage PackageId
 384         -- the module was not found in this package
 385
 386 -- | Cache that remembers where we found a particular module.  Contains both
 387 -- home modules and package modules.  On @:load@, only home modules are
 388 -- purged from this cache.
 389 type ModLocationCache = ModuleEnv ModLocation
 390 \end{code}
 391
 392 %************************************************************************
 393 %*                                                                      *
 394 \subsection{Symbol tables and Module details}
 395 %*                                                                      *
 396 %************************************************************************
 397
 398 A @ModIface@ plus a @ModDetails@ summarises everything we know
 399 about a compiled module.  The @ModIface@ is the stuff *before* linking,
 400 and can be written out to an interface file.  (The @ModDetails@ is after
 401 linking; it is the "linked" form of the mi_decls field.)
 402
 403 When we *read* an interface file, we also construct a @ModIface@ from it,
 404 except that the mi_decls part is empty; when reading we consolidate
 405 the declarations into a single indexed map in the @PersistentRenamerState@.
 406
 407 \begin{code}
 408 data ModIface
 409    = ModIface {
 410         mi_module   :: !Module,
 411         mi_mod_vers :: !Version,            -- Module version: changes when anything changes
 412
 413         mi_orphan   :: !WhetherHasOrphans,  -- Whether this module has orphans
 414         mi_finsts   :: !WhetherHasFamInst,  -- Whether module has family insts
 415         mi_boot     :: !IsBootInterface,    -- Read from an hi-boot file?
 416
 417         mi_deps     :: Dependencies,
 418                 -- This is consulted for directly-imported modules,
 419                 -- but not for anything else (hence lazy)
 420
 421                 -- Usages; kept sorted so that it's easy to decide
 422                 -- whether to write a new iface file (changing usages
 423                 -- doesn't affect the version of this module)
 424         mi_usages   :: [Usage],
 425                 -- NOT STRICT!  we read this field lazily from the interface file
 426                 -- It is *only* consulted by the recompilation checker
 427
 428                 -- Exports
 429                 -- Kept sorted by (mod,occ), to make version comparisons easier
 430         mi_exports  :: ![IfaceExport],
 431         mi_exp_vers :: !Version,        -- Version number of export list
 432
 433                 -- Fixities
 434         mi_fixities :: [(OccName,Fixity)],
 435                 -- NOT STRICT!  we read this field lazily from the interface file
 436
 437                 -- Deprecations
 438         mi_deprecs  :: Deprecations,
 439                 -- NOT STRICT!  we read this field lazily from the interface file
 440
 441                 -- Type, class and variable declarations
 442                 -- The version of an Id changes if its fixity or deprecations change
 443                 --      (as well as its type of course)
 444                 -- Ditto data constructors, class operations, except that
 445                 -- the version of the parent class/tycon changes
 446         mi_decls :: [(Version,IfaceDecl)],      -- Sorted
 447
 448         mi_globals  :: !(Maybe GlobalRdrEnv),
 449                 -- Binds all the things defined at the top level in
 450                 -- the *original source* code for this module. which
 451                 -- is NOT the same as mi_exports, nor mi_decls (which
 452                 -- may contains declarations for things not actually
 453                 -- defined by the user).  Used for GHCi and for inspecting
 454                 -- the contents of modules via the GHC API only.
 455                 --
 456                 -- (We need the source file to figure out the
 457                 -- top-level environment, if we didn't compile this module
 458                 -- from source then this field contains Nothing).
 459                 --
 460                 -- Strictly speaking this field should live in the
 461                 -- HomeModInfo, but that leads to more plumbing.
 462
 463                 -- Instance declarations and rules
 464         mi_insts     :: [IfaceInst],                    -- Sorted
 465         mi_fam_insts :: [IfaceFamInst],                 -- Sorted
 466         mi_rules     :: [IfaceRule],                    -- Sorted
 467         mi_rule_vers :: !Version,       -- Version number for rules and
 468                                         -- instances (for classes and families)
 469                                         -- combined
 470
 471                 -- Vectorisation information
 472         mi_vect_info :: !IfaceVectInfo,
 473
 474                 -- Cached environments for easy lookup
 475                 -- These are computed (lazily) from other fields
 476                 -- and are not put into the interface file
 477         mi_dep_fn  :: Name -> Maybe DeprecTxt,  -- Cached lookup for mi_deprecs
 478         mi_fix_fn  :: OccName -> Fixity,        -- Cached lookup for mi_fixities
 479         mi_ver_fn  :: OccName -> Maybe (OccName, Version),
 480                         -- Cached lookup for mi_decls
 481                         -- The Nothing in mi_ver_fn means that the thing
 482                         -- isn't in decls. It's useful to know that when
 483                         -- seeing if we are up to date wrt the old interface
 484                         -- The 'OccName' is the parent of the name, if it has one.
 485         mi_hpc    :: !AnyHpcUsage
 486           -- True if this program uses Hpc at any point in the program.
 487      }
 488
 489 -- Should be able to construct ModDetails from mi_decls in ModIface
 490 data ModDetails
 491    = ModDetails {
 492         -- The next two fields are created by the typechecker
 493         md_exports   :: [AvailInfo],
 494         md_types     :: !TypeEnv,
 495         md_insts     :: ![Instance],  -- Dfun-ids for the instances in this module
 496         md_fam_insts :: ![FamInst],
 497         md_rules     :: ![CoreRule],  -- Domain may include Ids from other modules
 498         md_vect_info :: !VectInfo     -- Vectorisation information
 499      }
 500
 501 emptyModDetails :: ModDetails
 502 emptyModDetails = ModDetails { md_types = emptyTypeEnv,
 503                                md_exports = [],
 504                                md_insts     = [],
 505                                md_rules     = [],
 506                                md_fam_insts = [],
 507                                md_vect_info = noVectInfo
 508                              }
 509
 510 -- A ModGuts is carried through the compiler, accumulating stuff as it goes
 511 -- There is only one ModGuts at any time, the one for the module
 512 -- being compiled right now.  Once it is compiled, a ModIface and
 513 -- ModDetails are extracted and the ModGuts is dicarded.
 514
 515 type ImportedMods = ModuleEnv (Module, [(ModuleName, Bool, SrcSpan)])
 516
 517 data ModGuts
 518   = ModGuts {
 519         mg_module    :: !Module,
 520         mg_boot      :: IsBootInterface, -- Whether it's an hs-boot module
 521         mg_exports   :: ![AvailInfo],    -- What it exports
 522         mg_deps      :: !Dependencies,   -- What is below it, directly or
 523                                          --   otherwise
 524         mg_dir_imps  :: !ImportedMods,   -- Directly-imported modules; used to
 525                                          --     generate initialisation code
 526         mg_used_names:: !NameSet,        -- What it needed (used in mkIface)
 527
 528         mg_rdr_env   :: !GlobalRdrEnv,   -- Top-level lexical environment
 529
 530         -- These fields all describe the things **declared in this module**
 531         mg_fix_env   :: !FixityEnv,      -- Fixities
 532         mg_types     :: !TypeEnv,
 533         mg_insts     :: ![Instance],     -- Instances
 534         mg_fam_insts :: ![FamInst],      -- Instances
 535         mg_rules     :: ![CoreRule],     -- Rules from this module
 536         mg_binds     :: ![CoreBind],     -- Bindings for this module
 537         mg_foreign   :: !ForeignStubs,
 538         mg_deprecs   :: !Deprecations,   -- Deprecations declared in the module
 539         mg_hpc_info  :: !HpcInfo,        -- info about coverage tick boxes
 540         mg_modBreaks :: !ModBreaks,
 541         mg_vect_info :: !VectInfo,        -- Pool of vectorised declarations
 542
 543         -- The next two fields are unusual, because they give instance
 544         -- environments for *all* modules in the home package, including
 545         -- this module, rather than for *just* this module.
 546         -- Reason: when looking up an instance we don't want to have to
 547         --        look at each module in the home package in turn
 548         mg_inst_env     :: InstEnv,      -- Class instance enviroment fro
 549                                          -- *home-package* modules (including
 550                                          -- this one); c.f. tcg_inst_env
 551         mg_fam_inst_env :: FamInstEnv    -- Type-family instance enviroment
 552                                          -- for *home-package* modules (including
 553                                          -- this one); c.f. tcg_fam_inst_env
 554     }
 555
 556 -- A CoreModule consists of just the fields of a ModGuts that are needed for
 557 -- the compileToCoreModule interface.
 558 data CoreModule
 559   = CoreModule {
 560       -- Module name
 561       cm_module   :: !Module,
 562       -- Type environment for types declared in this module
 563       cm_types    :: !TypeEnv,
 564       -- Declarations
 565       cm_binds    :: [CoreBind],
 566       -- Imports
 567       cm_imports  :: ![Module]
 568     }
 569
 570 instance Outputable CoreModule where
 571    ppr (CoreModule {cm_module = mn, cm_types = te, cm_binds = cb}) =
 572       text "%module" <+> ppr mn <+> ppr te $$ vcat (map ppr cb)
 573
 574 -- The ModGuts takes on several slightly different forms:
 575 --
 576 -- After simplification, the following fields change slightly:
 577 --      mg_rules        Orphan rules only (local ones now attached to binds)
 578 --      mg_binds        With rules attached
 579
 580
 581 ---------------------------------------------------------
 582 -- The Tidy pass forks the information about this module:
 583 --      * one lot goes to interface file generation (ModIface)
 584 --        and later compilations (ModDetails)
 585 --      * the other lot goes to code generation (CgGuts)
 586 data CgGuts
 587   = CgGuts {
 588         cg_module   :: !Module,
 589
 590         cg_tycons   :: [TyCon],
 591                 -- Algebraic data types (including ones that started
 592                 -- life as classes); generate constructors and info
 593                 -- tables Includes newtypes, just for the benefit of
 594                 -- External Core
 595
 596         cg_binds    :: [CoreBind],
 597                 -- The tidied main bindings, including
 598                 -- previously-implicit bindings for record and class
 599                 -- selectors, and data construtor wrappers.  But *not*
 600                 -- data constructor workers; reason: we we regard them
 601                 -- as part of the code-gen of tycons
 602
 603         cg_dir_imps :: ![Module],
 604                 -- Directly-imported modules; used to generate
 605                 -- initialisation code
 606
 607         cg_foreign  :: !ForeignStubs,
 608         cg_dep_pkgs :: ![PackageId],    -- Used to generate #includes for C code gen
 609         cg_hpc_info :: !HpcInfo,         -- info about coverage tick boxes
 610         cg_modBreaks :: !ModBreaks
 611     }
 612
 613 -----------------------------------
 614 data ModImports
 615   = ModImports {
 616         imp_direct     :: ![(Module,Bool)],     -- Explicitly-imported modules
 617                                                 -- Boolean is true if we imported the whole
 618                                                 --      module (apart, perhaps, from hiding some)
 619         imp_pkg_mods   :: !ModuleSet,           -- Non-home-package modules on which we depend,
 620                                                 --      directly or indirectly
 621         imp_home_names :: !NameSet              -- Home package things on which we depend,
 622                                                 --      directly or indirectly
 623     }
 624
 625 -----------------------------------
 626 data ForeignStubs = NoStubs
 627                   | ForeignStubs
 628                         SDoc            -- Header file prototypes for
 629                                         --      "foreign exported" functions
 630                         SDoc            -- C stubs to use when calling
 631                                         --      "foreign exported" functions
 632 \end{code}
 633
 634 \begin{code}
 635 emptyModIface :: Module -> ModIface
 636 emptyModIface mod
 637   = ModIface { mi_module   = mod,
 638                mi_mod_vers = initialVersion,
 639                mi_orphan   = False,
 640                mi_finsts   = False,
 641                mi_boot     = False,
 642                mi_deps     = noDependencies,
 643                mi_usages   = [],
 644                mi_exports  = [],
 645                mi_exp_vers = initialVersion,
 646                mi_fixities = [],
 647                mi_deprecs  = NoDeprecs,
 648                mi_insts     = [],
 649                mi_fam_insts = [],
 650                mi_rules     = [],
 651                mi_decls     = [],
 652                mi_globals   = Nothing,
 653                mi_rule_vers = initialVersion,
 654                mi_vect_info = noIfaceVectInfo,
 655                mi_dep_fn = emptyIfaceDepCache,
 656                mi_fix_fn = emptyIfaceFixCache,
 657                mi_ver_fn = emptyIfaceVerCache,
 658                mi_hpc    = False
 659     }
 660 \end{code}
 661
 662
 663 %************************************************************************
 664 %*                                                                      *
 665 \subsection{The interactive context}
 666 %*                                                                      *
 667 %************************************************************************
 668
 669 \begin{code}
 670 data InteractiveContext
 671   = InteractiveContext {
 672         ic_toplev_scope :: [Module],    -- Include the "top-level" scope of
 673                                         -- these modules
 674
 675         ic_exports :: [Module],         -- Include just the exports of these
 676                                         -- modules
 677
 678         ic_rn_gbl_env :: GlobalRdrEnv,  -- The cached GlobalRdrEnv, built from
 679                                         -- ic_toplev_scope and ic_exports
 680
 681         ic_tmp_ids :: [Id],             -- Names bound during interaction.
 682                                         -- Later Ids shadow
 683                                         -- earlier ones with the same OccName.
 684
 685         ic_tyvars :: TyVarSet           -- skolem type variables free in
 686                                         -- ic_tmp_ids.  These arise at
 687                                         -- breakpoints in a polymorphic
 688                                         -- context, where we have only partial
 689                                         -- type information.
 690
 691 #ifdef GHCI
 692         , ic_resume :: [Resume]         -- the stack of breakpoint contexts
 693 #endif
 694     }
 695
 696
 697 emptyInteractiveContext :: InteractiveContext
 698 emptyInteractiveContext
 699   = InteractiveContext { ic_toplev_scope = [],
 700                          ic_exports = [],
 701                          ic_rn_gbl_env = emptyGlobalRdrEnv,
 702                          ic_tmp_ids = [],
 703                          ic_tyvars = emptyVarSet
 704 #ifdef GHCI
 705                          , ic_resume = []
 706 #endif
 707                        }
 708
 709 icPrintUnqual :: DynFlags -> InteractiveContext -> PrintUnqualified
 710 icPrintUnqual dflags ictxt = mkPrintUnqualified dflags (ic_rn_gbl_env ictxt)
 711
 712
 713 extendInteractiveContext
 714         :: InteractiveContext
 715         -> [Id]
 716         -> TyVarSet
 717         -> InteractiveContext
 718 extendInteractiveContext ictxt ids tyvars
 719   = ictxt { ic_tmp_ids =  ic_tmp_ids ictxt ++ ids,
 720                           -- NB. must be this way around, because we want
 721                           -- new ids to shadow existing bindings.
 722             ic_tyvars   = ic_tyvars ictxt `unionVarSet` tyvars }
 723
 724
 725 substInteractiveContext :: InteractiveContext -> TvSubst -> InteractiveContext
 726 substInteractiveContext ictxt subst | isEmptyTvSubst subst = ictxt
 727 substInteractiveContext ictxt@InteractiveContext{ic_tmp_ids=ids} subst =
 728    let ids'     = map (\id -> id `setIdType` substTy subst (idType id)) ids
 729        subst_dom= varEnvKeys$ getTvSubstEnv subst
 730        subst_ran= varEnvElts$ getTvSubstEnv subst
 731        new_tvs  = [ tv | Just tv <- map getTyVar_maybe subst_ran]
 732        ic_tyvars'= (`delVarSetListByKey` subst_dom)
 733                  . (`extendVarSetList`   new_tvs)
 734                    $ ic_tyvars ictxt
 735     in ictxt { ic_tmp_ids = ids'
 736              , ic_tyvars   = ic_tyvars' }
 737
 738           where delVarSetListByKey = foldl' delVarSetByKey
 739 \end{code}
 740
 741 %************************************************************************
 742 %*                                                                      *
 743         Building a PrintUnqualified
 744 %*                                                                      *
 745 %************************************************************************
 746
 747 Deciding how to print names is pretty tricky.  We are given a name
 748 P:M.T, where P is the package name, M is the defining module, and T is
 749 the occurrence name, and we have to decide in which form to display
 750 the name given a GlobalRdrEnv describing the current scope.
 751
 752 Ideally we want to display the name in the form in which it is in
 753 scope.  However, the name might not be in scope at all, and that's
 754 where it gets tricky.  Here are the cases:
 755
 756  1. T   uniquely maps to  P:M.T                         --->  "T"
 757  2. there is an X for which X.T uniquely maps to  P:M.T --->  "X.T"
 758  3. there is no binding for "M.T"                       --->  "M.T"
 759  4. otherwise                                           --->  "P:M.T"
 760
 761 3 and 4 apply when P:M.T is not in scope.  In these cases we want to
 762 refer to the name as "M.T", but "M.T" might mean something else in the
 763 current scope (e.g. if there's an "import X as M"), so to avoid
 764 confusion we avoid using "M.T" if there's already a binding for it.
 765
 766 There's one further subtlety: if the module M cannot be imported
 767 because it is not exposed by any package, then we must refer to it as
 768 "P:M".  This is handled by the qual_mod component of PrintUnqualified.
 769
 770 \begin{code}
 771 mkPrintUnqualified :: DynFlags -> GlobalRdrEnv -> PrintUnqualified
 772 mkPrintUnqualified dflags env = (qual_name, qual_mod)
 773   where
 774   qual_name mod occ     -- The (mod,occ) pair is the original name of the thing
 775         | [gre] <- unqual_gres, right_name gre = NameUnqual
 776                 -- If there's a unique entity that's in scope unqualified with 'occ'
 777                 -- AND that entity is the right one, then we can use the unqualified name
 778
 779         | [gre] <- qual_gres = NameQual (get_qual_mod (gre_prov gre))
 780
 781         | null qual_gres =
 782               if null (lookupGRE_RdrName (mkRdrQual (moduleName mod) occ) env)
 783                    then NameNotInScope1
 784                    else NameNotInScope2
 785
 786         | otherwise = panic "mkPrintUnqualified"
 787       where
 788         right_name gre = nameModule (gre_name gre) == mod
 789
 790         unqual_gres = lookupGRE_RdrName (mkRdrUnqual occ) env
 791         qual_gres   = filter right_name (lookupGlobalRdrEnv env occ)
 792
 793         get_qual_mod LocalDef      = moduleName mod
 794         get_qual_mod (Imported is) = ASSERT( not (null is) ) is_as (is_decl (head is))
 795
 796     -- we can mention a module P:M without the P: qualifier iff
 797     -- "import M" would resolve unambiguously to P:M.  (if P is the
 798     -- current package we can just assume it is unqualified).
 799
 800   qual_mod mod
 801      | modulePackageId mod == thisPackage dflags = False
 802
 803      | [pkgconfig] <- [pkg | (pkg,exposed_module) <- lookup,
 804                              exposed pkg && exposed_module],
 805        packageConfigId pkgconfig == modulePackageId mod
 806         -- this says: we are given a module P:M, is there just one exposed package
 807         -- that exposes a module M, and is it package P?
 808      = False
 809
 810      | otherwise = True
 811      where lookup = lookupModuleInAllPackages dflags (moduleName mod)
 812 \end{code}
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817                 TyThing
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 \begin{code}
 822 -- N.B. the set of TyThings returned here *must* match the set of
 823 -- names returned by LoadIface.ifaceDeclSubBndrs, in the sense that
 824 -- TyThing.getOccName should define a bijection between the two lists.
 825 -- This invariant is used in LoadIface.loadDecl (see note [Tricky iface loop])
 826 -- The order of the list does not matter.
 827 implicitTyThings :: TyThing -> [TyThing]
 828
 829 -- For data and newtype declarations:
 830 implicitTyThings (ATyCon tc) =
 831     -- fields (names of selectors)
 832     map AnId (tyConSelIds tc) ++
 833     -- (possibly) implicit coercion and family coercion
 834     --   depending on whether it's a newtype or a family instance or both
 835     implicitCoTyCon tc ++
 836     -- for each data constructor in order,
 837     --   the contructor, worker, and (possibly) wrapper
 838     concatMap (extras_plus . ADataCon) (tyConDataCons tc)
 839
 840 implicitTyThings (AClass cl)
 841   = -- dictionary datatype:
 842     --    [extras_plus:]
 843     --      type constructor
 844     --    [recursive call:]
 845     --      (possibly) newtype coercion; definitely no family coercion here
 846     --      data constructor
 847     --      worker
 848     --      (no wrapper by invariant)
 849     extras_plus (ATyCon (classTyCon cl)) ++
 850     -- associated types
 851     --    No extras_plus (recursive call) for the classATs, because they
 852     --    are only the family decls; they have no implicit things
 853     map ATyCon (classATs cl) ++
 854     -- superclass and operation selectors
 855     map AnId (classSelIds cl)
 856
 857 implicitTyThings (ADataCon dc) =
 858     -- For data cons add the worker and (possibly) wrapper
 859     map AnId (dataConImplicitIds dc)
 860
 861 implicitTyThings (AnId _)   = []
 862
 863 -- add a thing and recursive call
 864 extras_plus :: TyThing -> [TyThing]
 865 extras_plus thing = thing : implicitTyThings thing
 866
 867 -- For newtypes and indexed data types (and both),
 868 -- add the implicit coercion tycon
 869 implicitCoTyCon :: TyCon -> [TyThing]
 870 implicitCoTyCon tc
 871   = map ATyCon . catMaybes $ [-- Just if newtype, Nothing if not
 872                               newTyConCo_maybe tc,
 873                               -- Just if family instance, Nothing if not
 874                                 tyConFamilyCoercion_maybe tc]
 875
 876 -- sortByOcc = sortBy (\ x -> \ y -> getOccName x < getOccName y)
 877
 878
 879 -- | returns 'True' if there should be no interface-file declaration
 880 -- for this thing on its own: either it is built-in, or it is part
 881 -- of some other declaration, or it is generated implicitly by some
 882 -- other declaration.
 883 isImplicitTyThing :: TyThing -> Bool
 884 isImplicitTyThing (ADataCon _)  = True
 885 isImplicitTyThing (AnId     id) = isImplicitId id
 886 isImplicitTyThing (AClass   _)  = False
 887 isImplicitTyThing (ATyCon   tc) = isImplicitTyCon tc
 888
 889 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
 890 extendTypeEnvWithIds env ids
 891   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
 892 \end{code}
 893
 894 %************************************************************************
 895 %*                                                                      *
 896                 TypeEnv
 897 %*                                                                      *
 898 %************************************************************************
 899
 900 \begin{code}
 901 type TypeEnv = NameEnv TyThing
 902
 903 emptyTypeEnv    :: TypeEnv
 904 typeEnvElts     :: TypeEnv -> [TyThing]
 905 typeEnvClasses  :: TypeEnv -> [Class]
 906 typeEnvTyCons   :: TypeEnv -> [TyCon]
 907 typeEnvIds      :: TypeEnv -> [Id]
 908 typeEnvDataCons :: TypeEnv -> [DataCon]
 909 lookupTypeEnv   :: TypeEnv -> Name -> Maybe TyThing
 910
 911 emptyTypeEnv        = emptyNameEnv
 912 typeEnvElts     env = nameEnvElts env
 913 typeEnvClasses  env = [cl | AClass cl   <- typeEnvElts env]
 914 typeEnvTyCons   env = [tc | ATyCon tc   <- typeEnvElts env]
 915 typeEnvIds      env = [id | AnId id     <- typeEnvElts env]
 916 typeEnvDataCons env = [dc | ADataCon dc <- typeEnvElts env]
 917
 918 mkTypeEnv :: [TyThing] -> TypeEnv
 919 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
 920
 921 lookupTypeEnv = lookupNameEnv
 922
 923 -- Extend the type environment
 924 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
 925 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
 926
 927 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
 928 extendTypeEnvList env things = foldl extendTypeEnv env things
 929 \end{code}
 930
 931 \begin{code}
 932 lookupType :: DynFlags
 933            -> HomePackageTable
 934            -> PackageTypeEnv
 935            -> Name
 936            -> Maybe TyThing
 937
 938 lookupType dflags hpt pte name
 939   -- in one-shot, we don't use the HPT
 940   | not (isOneShot (ghcMode dflags)) && modulePackageId mod == this_pkg
 941   = do hm <- lookupUFM hpt (moduleName mod) -- Maybe monad
 942        lookupNameEnv (md_types (hm_details hm)) name
 943   | otherwise
 944   = lookupNameEnv pte name
 945   where mod = nameModule name
 946         this_pkg = thisPackage dflags
 947 \end{code}
 948
 949 \begin{code}
 950 tyThingTyCon :: TyThing -> TyCon
 951 tyThingTyCon (ATyCon tc) = tc
 952 tyThingTyCon other       = pprPanic "tyThingTyCon" (pprTyThing other)
 953
 954 tyThingClass :: TyThing -> Class
 955 tyThingClass (AClass cls) = cls
 956 tyThingClass other        = pprPanic "tyThingClass" (pprTyThing other)
 957
 958 tyThingDataCon :: TyThing -> DataCon
 959 tyThingDataCon (ADataCon dc) = dc
 960 tyThingDataCon other         = pprPanic "tyThingDataCon" (pprTyThing other)
 961
 962 tyThingId :: TyThing -> Id
 963 tyThingId (AnId id)     = id
 964 tyThingId (ADataCon dc) = dataConWrapId dc
 965 tyThingId other         = pprPanic "tyThingId" (pprTyThing other)
 966 \end{code}
 967
 968 %************************************************************************
 969 %*                                                                      *
 970 \subsection{Auxiliary types}
 971 %*                                                                      *
 972 %************************************************************************
 973
 974 These types are defined here because they are mentioned in ModDetails,
 975 but they are mostly elaborated elsewhere
 976
 977 \begin{code}
 978 mkIfaceVerCache :: [(Version,IfaceDecl)]
 979                 -> (OccName -> Maybe (OccName, Version))
 980 mkIfaceVerCache pairs
 981   = \occ -> lookupOccEnv env occ
 982   where
 983     env = foldr add_decl emptyOccEnv pairs
 984     add_decl (v,d) env0 = foldr add_imp env1 (ifaceDeclSubBndrs d)
 985       where
 986           decl_name = ifName d
 987           env1 = extendOccEnv env0 decl_name (decl_name, v)
 988           add_imp bndr env = extendOccEnv env bndr (decl_name, v)
 989
 990 emptyIfaceVerCache :: OccName -> Maybe (OccName, Version)
 991 emptyIfaceVerCache _occ = Nothing
 992
 993 ------------------ Deprecations -------------------------
 994 data Deprecations
 995   = NoDeprecs
 996   | DeprecAll DeprecTxt         -- Whole module deprecated
 997   | DeprecSome [(OccName,DeprecTxt)] -- Some specific things deprecated
 998      -- Only an OccName is needed because
 999      --    (1) a deprecation always applies to a binding
1000      --        defined in the module in which the deprecation appears.
1001      --    (2) deprecations are only reported outside the defining module.
1002      --        this is important because, otherwise, if we saw something like
1003      --
1004      --        {-# DEPRECATED f "" #-}
1005      --        f = ...
1006      --        h = f
1007      --        g = let f = undefined in f
1008      --
1009      --        we'd need more information than an OccName to know to say something
1010      --        about the use of f in h but not the use of the locally bound f in g
1011      --
1012      --        however, because we only report about deprecations from the outside,
1013      --        and a module can only export one value called f,
1014      --        an OccName suffices.
1015      --
1016      --        this is in contrast with fixity declarations, where we need to map
1017      --        a Name to its fixity declaration.
1018   deriving( Eq )
1019
1020 mkIfaceDepCache :: Deprecations -> Name -> Maybe DeprecTxt
1021 mkIfaceDepCache NoDeprecs         = \_ -> Nothing
1022 mkIfaceDepCache (DeprecAll t)     = \_ -> Just t
1023 mkIfaceDepCache (DeprecSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
1024
1025 emptyIfaceDepCache :: Name -> Maybe DeprecTxt
1026 emptyIfaceDepCache _ = Nothing
1027
1028 plusDeprecs :: Deprecations -> Deprecations -> Deprecations
1029 plusDeprecs d NoDeprecs = d
1030 plusDeprecs NoDeprecs d = d
1031 plusDeprecs _ (DeprecAll t) = DeprecAll t
1032 plusDeprecs (DeprecAll t) _ = DeprecAll t
1033 plusDeprecs (DeprecSome v1) (DeprecSome v2) = DeprecSome (v1 ++ v2)
1034 \end{code}
1035
1036
1037 \begin{code}
1038 type Avails       = [AvailInfo]
1039 type AvailInfo    = GenAvailInfo Name
1040 type RdrAvailInfo = GenAvailInfo OccName
1041
1042 data GenAvailInfo name  = Avail name     -- An ordinary identifier
1043                         | AvailTC name   -- The name of the type or class
1044                                   [name] -- The available pieces of type/class.
1045                                          -- NB: If the type or class is itself
1046                                          -- to be in scope, it must be in this list.
1047                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
1048                         deriving( Eq )
1049                         -- Equality used when deciding if the interface has changed
1050
1051 type IfaceExport = (Module, [GenAvailInfo OccName])
1052
1053 availsToNameSet :: [AvailInfo] -> NameSet
1054 availsToNameSet avails = foldr add emptyNameSet avails
1055       where add avail set = addListToNameSet set (availNames avail)
1056
1057 availsToNameEnv :: [AvailInfo] -> NameEnv AvailInfo
1058 availsToNameEnv avails = foldr add emptyNameEnv avails
1059      where add avail env = extendNameEnvList env
1060                                 (zip (availNames avail) (repeat avail))
1061
1062 availName :: GenAvailInfo name -> name
1063 availName (Avail n)     = n
1064 availName (AvailTC n _) = n
1065
1066 availNames :: GenAvailInfo name -> [name]
1067 availNames (Avail n)      = [n]
1068 availNames (AvailTC _ ns) = ns
1069
1070 instance Outputable n => Outputable (GenAvailInfo n) where
1071    ppr = pprAvail
1072
1073 pprAvail :: Outputable n => GenAvailInfo n -> SDoc
1074 pprAvail (Avail n)      = ppr n
1075 pprAvail (AvailTC n ns) = ppr n <> braces (hsep (punctuate comma (map ppr ns)))
1076 \end{code}
1077
1078 \begin{code}
1079 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
1080 mkIfaceFixCache pairs
1081   = \n -> lookupOccEnv env n `orElse` defaultFixity
1082   where
1083    env = mkOccEnv pairs
1084
1085 emptyIfaceFixCache :: OccName -> Fixity
1086 emptyIfaceFixCache _ = defaultFixity
1087
1088 -- This fixity environment is for source code only
1089 type FixityEnv = NameEnv FixItem
1090
1091 -- We keep the OccName in the range so that we can generate an interface from it
1092 data FixItem = FixItem OccName Fixity
1093
1094 instance Outputable FixItem where
1095   ppr (FixItem occ fix) = ppr fix <+> ppr occ
1096
1097 emptyFixityEnv :: FixityEnv
1098 emptyFixityEnv = emptyNameEnv
1099
1100 lookupFixity :: FixityEnv -> Name -> Fixity
1101 lookupFixity env n = case lookupNameEnv env n of
1102                         Just (FixItem _ fix) -> fix
1103                         Nothing         -> defaultFixity
1104 \end{code}
1105
1106
1107 %************************************************************************
1108 %*                                                                      *
1109 \subsection{WhatsImported}
1110 %*                                                                      *
1111 %************************************************************************
1112
1113 \begin{code}
1114 type WhetherHasOrphans   = Bool
1115         -- An "orphan" is
1116         --      * an instance decl in a module other than the defn module for
1117         --              one of the tycons or classes in the instance head
1118         --      * a transformation rule in a module other than the one defining
1119         --              the function in the head of the rule.
1120
1121 type WhetherHasFamInst = Bool        -- This module defines family instances?
1122
1123 type IsBootInterface = Bool
1124
1125 -- Dependency info about modules and packages below this one
1126 -- in the import hierarchy.  See TcRnTypes.ImportAvails for details.
1127 -- The orphan modules in `dep_orphs' do *not* include family instance orphans,
1128 -- as they are anyway included in `dep_finsts'.
1129 --
1130 -- Invariant: the dependencies of a module M never includes M
1131 -- Invariant: the lists are unordered, with no duplicates
1132 data Dependencies
1133   = Deps { dep_mods   :: [(ModuleName,      -- Home-package module dependencies
1134                            IsBootInterface)]
1135          , dep_pkgs   :: [PackageId]        -- External package dependencies
1136          , dep_orphs  :: [Module]           -- Orphan modules (whether home or
1137                                             -- external pkg)
1138          , dep_finsts :: [Module]           -- Modules that contain family
1139                                             -- instances (whether home or
1140                                             -- external pkg)
1141          }
1142   deriving( Eq )
1143         -- Equality used only for old/new comparison in MkIface.addVersionInfo
1144
1145 noDependencies :: Dependencies
1146 noDependencies = Deps [] [] [] []
1147
1148 data Usage
1149   = Usage { usg_name     :: ModuleName,                 -- Name of the module
1150             usg_mod      :: Version,                    -- Module version
1151             usg_entities :: [(OccName,Version)],        -- Sorted by occurrence name
1152                 -- NB. usages are for parent names only, eg. tycon but not constructors.
1153             usg_exports  :: Maybe Version,              -- Export-list version, if we depend on it
1154             usg_rules    :: Version                     -- Orphan-rules version (for non-orphan
1155                                                         -- modules this will always be initialVersion)
1156     }       deriving( Eq )
1157         -- This type doesn't let you say "I imported f but none of the rules in
1158         -- the module". If you use anything in the module you get its rule version
1159         -- So if the rules change, you'll recompile, even if you don't use them.
1160         -- This is easy to implement, and it's safer: you might not have used the rules last
1161         -- time round, but if someone has added a new rule you might need it this time
1162
1163         -- The export list field is (Just v) if we depend on the export list:
1164         --      i.e. we imported the module directly, whether or not we
1165         --           enumerated the things we imported, or just imported everything
1166         -- We need to recompile if M's exports change, because
1167         -- if the import was    import M,       we might now have a name clash in the
1168         --                                      importing module.
1169         -- if the import was    import M(x)     M might no longer export x
1170         -- The only way we don't depend on the export list is if we have
1171         --                      import M()
1172         -- And of course, for modules that aren't imported directly we don't
1173         -- depend on their export lists
1174 \end{code}
1175
1176
1177 %************************************************************************
1178 %*                                                                      *
1179                 The External Package State
1180 %*                                                                      *
1181 %************************************************************************
1182
1183 \begin{code}
1184 type PackageTypeEnv    = TypeEnv
1185 type PackageRuleBase   = RuleBase
1186 type PackageInstEnv    = InstEnv
1187 type PackageFamInstEnv = FamInstEnv
1188 type PackageVectInfo   = VectInfo
1189
1190 data ExternalPackageState
1191   = EPS {
1192         eps_is_boot :: !(ModuleNameEnv (ModuleName, IsBootInterface)),
1193                 -- In OneShot mode (only), home-package modules
1194                 -- accumulate in the external package state, and are
1195                 -- sucked in lazily.  For these home-pkg modules
1196                 -- (only) we need to record which are boot modules.
1197                 -- We set this field after loading all the
1198                 -- explicitly-imported interfaces, but before doing
1199                 -- anything else
1200                 --
1201                 -- The ModuleName part is not necessary, but it's useful for
1202                 -- debug prints, and it's convenient because this field comes
1203                 -- direct from TcRnTypes.ImportAvails.imp_dep_mods
1204
1205         eps_PIT :: !PackageIfaceTable,
1206                 -- The ModuleIFaces for modules in external packages
1207                 -- whose interfaces we have opened
1208                 -- The declarations in these interface files are held in
1209                 -- eps_decls, eps_inst_env, eps_fam_inst_env, eps_rules
1210                 -- (below), not in the mi_decls fields of the iPIT.
1211                 -- What _is_ in the iPIT is:
1212                 --      * The Module
1213                 --      * Version info
1214                 --      * Its exports
1215                 --      * Fixities
1216                 --      * Deprecations
1217
1218         eps_PTE :: !PackageTypeEnv,        -- Domain = external-package modules
1219
1220         eps_inst_env     :: !PackageInstEnv,   -- The total InstEnv accumulated
1221                                                -- from all the external-package
1222                                                -- modules
1223         eps_fam_inst_env :: !PackageFamInstEnv,-- Ditto FamInstEnv
1224         eps_rule_base    :: !PackageRuleBase,  -- Ditto RuleEnv
1225         eps_vect_info    :: !PackageVectInfo,  -- Ditto VectInfo
1226
1227         eps_mod_fam_inst_env :: !(ModuleEnv FamInstEnv), -- identifies family
1228                                                        -- instances of each mod
1229         eps_stats :: !EpsStats
1230   }
1231
1232 -- "In" means read from iface files
1233 -- "Out" means actually sucked in and type-checked
1234 data EpsStats = EpsStats { n_ifaces_in
1235                          , n_decls_in, n_decls_out
1236                          , n_rules_in, n_rules_out
1237                          , n_insts_in, n_insts_out :: !Int }
1238
1239 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
1240 -- Add stats for one newly-read interface
1241 addEpsInStats stats n_decls n_insts n_rules
1242   = stats { n_ifaces_in = n_ifaces_in stats + 1
1243           , n_decls_in  = n_decls_in stats + n_decls
1244           , n_insts_in  = n_insts_in stats + n_insts
1245           , n_rules_in  = n_rules_in stats + n_rules }
1246 \end{code}
1247
1248 The NameCache makes sure that there is just one Unique assigned for
1249 each original name; i.e. (module-name, occ-name) pair.  The Name is
1250 always stored as a Global, and has the SrcLoc of its binding location.
1251 Actually that's not quite right.  When we first encounter the original
1252 name, we might not be at its binding site (e.g. we are reading an
1253 interface file); so we give it 'noSrcLoc' then.  Later, when we find
1254 its binding site, we fix it up.
1255
1256 \begin{code}
1257 data NameCache
1258  = NameCache {  nsUniqs :: UniqSupply,
1259                 -- Supply of uniques
1260                 nsNames :: OrigNameCache,
1261                 -- Ensures that one original name gets one unique
1262                 nsIPs   :: OrigIParamCache
1263                 -- Ensures that one implicit parameter name gets one unique
1264    }
1265
1266 type OrigNameCache   = ModuleEnv (OccEnv Name)
1267 type OrigIParamCache = FiniteMap (IPName OccName) (IPName Name)
1268 \end{code}
1269
1270
1271
1272 %************************************************************************
1273 %*                                                                      *
1274                 The module graph and ModSummary type
1275         A ModSummary is a node in the compilation manager's
1276         dependency graph, and it's also passed to hscMain
1277 %*                                                                      *
1278 %************************************************************************
1279
1280 A ModuleGraph contains all the nodes from the home package (only).
1281 There will be a node for each source module, plus a node for each hi-boot
1282 module.
1283
1284 \begin{code}
1285 type ModuleGraph = [ModSummary]  -- The module graph,
1286                                  -- NOT NECESSARILY IN TOPOLOGICAL ORDER
1287
1288 emptyMG :: ModuleGraph
1289 emptyMG = []
1290
1291 -- The nodes of the module graph are
1292 --      EITHER a regular Haskell source module
1293 --      OR     a hi-boot source module
1294
1295 data ModSummary
1296    = ModSummary {
1297         ms_mod       :: Module,                 -- Identity of the module
1298         ms_hsc_src   :: HscSource,              -- Source is Haskell, hs-boot, external core
1299         ms_location  :: ModLocation,            -- Location
1300         ms_hs_date   :: ClockTime,              -- Timestamp of source file
1301         ms_obj_date  :: Maybe ClockTime,        -- Timestamp of object, maybe
1302         ms_srcimps   :: [Located ModuleName],   -- Source imports
1303         ms_imps      :: [Located ModuleName],   -- Non-source imports
1304         ms_hspp_file :: FilePath,               -- Filename of preprocessed source.
1305         ms_hspp_opts :: DynFlags,               -- Cached flags from OPTIONS, INCLUDE
1306                                                 -- and LANGUAGE pragmas.
1307         ms_hspp_buf  :: Maybe StringBuffer      -- The actual preprocessed source, maybe.
1308      }
1309
1310 ms_mod_name :: ModSummary -> ModuleName
1311 ms_mod_name = moduleName . ms_mod
1312
1313 -- The ModLocation contains both the original source filename and the
1314 -- filename of the cleaned-up source file after all preprocessing has been
1315 -- done.  The point is that the summariser will have to cpp/unlit/whatever
1316 -- all files anyway, and there's no point in doing this twice -- just
1317 -- park the result in a temp file, put the name of it in the location,
1318 -- and let @compile@ read from that file on the way back up.
1319
1320 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
1321 -- the ms_hs_date and imports can, of course, change
1322
1323 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
1324 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
1325 msHiFilePath  ms = ml_hi_file  (ms_location ms)
1326 msObjFilePath ms = ml_obj_file (ms_location ms)
1327
1328 isBootSummary :: ModSummary -> Bool
1329 isBootSummary ms = isHsBoot (ms_hsc_src ms)
1330
1331 instance Outputable ModSummary where
1332    ppr ms
1333       = sep [text "ModSummary {",
1334              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
1335                           text "ms_mod =" <+> ppr (ms_mod ms)
1336                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
1337                           text "ms_imps =" <+> ppr (ms_imps ms),
1338                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
1339              char '}'
1340             ]
1341
1342 showModMsg :: HscTarget -> Bool -> ModSummary -> String
1343 showModMsg target recomp mod_summary
1344   = showSDoc $
1345         hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
1346               char '(', text (normalise $ msHsFilePath mod_summary) <> comma,
1347               case target of
1348                   HscInterpreted | recomp
1349                              -> text "interpreted"
1350                   HscNothing -> text "nothing"
1351                   _          -> text (normalise $ msObjFilePath mod_summary),
1352               char ')']
1353  where
1354     mod     = moduleName (ms_mod mod_summary)
1355     mod_str = showSDoc (ppr mod) ++ hscSourceString (ms_hsc_src mod_summary)
1356 \end{code}
1357
1358
1359 %************************************************************************
1360 %*                                                                      *
1361 \subsection{Hpc Support}
1362 %*                                                                      *
1363 %************************************************************************
1364
1365 \begin{code}
1366 data HpcInfo
1367   = HpcInfo
1368      { hpcInfoTickCount :: Int
1369      , hpcInfoHash      :: Int
1370      }
1371   | NoHpcInfo
1372      { hpcUsed          :: AnyHpcUsage  -- is hpc used anywhere on the module tree?
1373      }
1374
1375 -- This is used to mean there is no module-local hpc usage,
1376 -- but one of my imports used hpc instrumentation.
1377
1378 type AnyHpcUsage = Bool
1379
1380 emptyHpcInfo :: AnyHpcUsage -> HpcInfo
1381 emptyHpcInfo = NoHpcInfo
1382
1383 isHpcUsed :: HpcInfo -> AnyHpcUsage
1384 isHpcUsed (HpcInfo {})                   = True
1385 isHpcUsed (NoHpcInfo { hpcUsed = used }) = used
1386 \end{code}
1387
1388 %************************************************************************
1389 %*                                                                      *
1390 \subsection{Vectorisation Support}
1391 %*                                                                      *
1392 %************************************************************************
1393
1394 The following information is generated and consumed by the vectorisation
1395 subsystem.  It communicates the vectorisation status of declarations from one
1396 module to another.
1397
1398 Why do we need both f and f_v in the ModGuts/ModDetails/EPS version VectInfo
1399 below?  We need to know `f' when converting to IfaceVectInfo.  However, during
1400 vectorisation, we need to know `f_v', whose `Var' we cannot lookup based
1401 on just the OccName easily in a Core pass.
1402
1403 \begin{code}
1404 -- ModGuts/ModDetails/EPS version
1405 data VectInfo
1406   = VectInfo {
1407       vectInfoVar     :: VarEnv  (Var    , Var  ),   -- (f, f_v) keyed on f
1408       vectInfoTyCon   :: NameEnv (TyCon  , TyCon),   -- (T, T_v) keyed on T
1409       vectInfoDataCon :: NameEnv (DataCon, DataCon), -- (C, C_v) keyed on C
1410       vectInfoPADFun  :: NameEnv (TyCon  , Var),     -- (T_v, paT) keyed on T_v
1411       vectInfoIso     :: NameEnv (TyCon  , Var)      -- (T, isoT) keyed on T
1412     }
1413     -- all of this is always tidy, even in ModGuts
1414
1415 -- ModIface version
1416 data IfaceVectInfo
1417   = IfaceVectInfo {
1418       ifaceVectInfoVar        :: [Name],
1419         -- all variables in here have a vectorised variant;
1420         -- the name of the vectorised variant is determined by `mkCloVect'
1421       ifaceVectInfoTyCon      :: [Name],
1422         -- all tycons in here have a vectorised variant;
1423         -- the name of the vectorised variant and those of its
1424         -- data constructors are determined by `mkVectTyConOcc'
1425         -- and `mkVectDataConOcc'; the names of
1426         -- the isomorphisms is determined by `mkVectIsoOcc'
1427       ifaceVectInfoTyConReuse :: [Name]
1428         -- the vectorised form of all the tycons in here coincids with
1429         -- the unconverted from; the names of the isomorphisms is determined
1430         -- by `mkVectIsoOcc'
1431     }
1432
1433 noVectInfo :: VectInfo
1434 noVectInfo = VectInfo emptyVarEnv emptyNameEnv emptyNameEnv emptyNameEnv emptyNameEnv
1435
1436 plusVectInfo :: VectInfo -> VectInfo -> VectInfo
1437 plusVectInfo vi1 vi2 =
1438   VectInfo (vectInfoVar     vi1 `plusVarEnv`  vectInfoVar     vi2)
1439            (vectInfoTyCon   vi1 `plusNameEnv` vectInfoTyCon   vi2)
1440            (vectInfoDataCon vi1 `plusNameEnv` vectInfoDataCon vi2)
1441            (vectInfoPADFun  vi1 `plusNameEnv` vectInfoPADFun  vi2)
1442            (vectInfoIso     vi1 `plusNameEnv` vectInfoIso     vi2)
1443
1444 noIfaceVectInfo :: IfaceVectInfo
1445 noIfaceVectInfo = IfaceVectInfo [] [] []
1446 \end{code}
1447
1448 %************************************************************************
1449 %*                                                                      *
1450 \subsection{Linkable stuff}
1451 %*                                                                      *
1452 %************************************************************************
1453
1454 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
1455 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
1456
1457 \begin{code}
1458 data Linkable = LM {
1459   linkableTime     :: ClockTime,        -- Time at which this linkable was built
1460                                         -- (i.e. when the bytecodes were produced,
1461                                         --       or the mod date on the files)
1462   linkableModule   :: Module,           -- Should be Module, but see below
1463   linkableUnlinked :: [Unlinked]
1464  }
1465
1466 isObjectLinkable :: Linkable -> Bool
1467 isObjectLinkable l = not (null unlinked) && all isObject unlinked
1468   where unlinked = linkableUnlinked l
1469         -- A linkable with no Unlinked's is treated as a BCO.  We can
1470         -- generate a linkable with no Unlinked's as a result of
1471         -- compiling a module in HscNothing mode, and this choice
1472         -- happens to work well with checkStability in module GHC.
1473
1474 instance Outputable Linkable where
1475    ppr (LM when_made mod unlinkeds)
1476       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
1477         $$ nest 3 (ppr unlinkeds)
1478
1479 -------------------------------------------
1480 data Unlinked
1481    = DotO FilePath
1482    | DotA FilePath
1483    | DotDLL FilePath
1484    | BCOs CompiledByteCode ModBreaks
1485
1486 #ifndef GHCI
1487 data CompiledByteCode = CompiledByteCodeUndefined
1488 _unused :: CompiledByteCode
1489 _unused = CompiledByteCodeUndefined
1490 #endif
1491
1492 instance Outputable Unlinked where
1493    ppr (DotO path)   = text "DotO" <+> text path
1494    ppr (DotA path)   = text "DotA" <+> text path
1495    ppr (DotDLL path) = text "DotDLL" <+> text path
1496 #ifdef GHCI
1497    ppr (BCOs bcos _) = text "BCOs" <+> ppr bcos
1498 #else
1499    ppr (BCOs _ _)    = text "No byte code"
1500 #endif
1501
1502 isObject :: Unlinked -> Bool
1503 isObject (DotO _)   = True
1504 isObject (DotA _)   = True
1505 isObject (DotDLL _) = True
1506 isObject _          = False
1507
1508 isInterpretable :: Unlinked -> Bool
1509 isInterpretable = not . isObject
1510
1511 nameOfObject :: Unlinked -> FilePath
1512 nameOfObject (DotO fn)   = fn
1513 nameOfObject (DotA fn)   = fn
1514 nameOfObject (DotDLL fn) = fn
1515 nameOfObject other       = pprPanic "nameOfObject" (ppr other)
1516
1517 byteCodeOfObject :: Unlinked -> CompiledByteCode
1518 byteCodeOfObject (BCOs bc _) = bc
1519 byteCodeOfObject other       = pprPanic "byteCodeOfObject" (ppr other)
1520 \end{code}
1521
1522 %************************************************************************
1523 %*                                                                      *
1524 \subsection{Breakpoint Support}
1525 %*                                                                      *
1526 %************************************************************************
1527
1528 \begin{code}
1529 type BreakIndex = Int
1530
1531 -- | all the information about the breakpoints for a given module
1532 data ModBreaks
1533    = ModBreaks
1534    { modBreaks_flags :: BreakArray
1535         -- The array of flags, one per breakpoint,
1536         -- indicating which breakpoints are enabled.
1537    , modBreaks_locs :: !(Array BreakIndex SrcSpan)
1538         -- An array giving the source span of each breakpoint.
1539    , modBreaks_vars :: !(Array BreakIndex [OccName])
1540         -- An array giving the names of the free variables at each breakpoint.
1541    }
1542
1543 emptyModBreaks :: ModBreaks
1544 emptyModBreaks = ModBreaks
1545    { modBreaks_flags = error "ModBreaks.modBreaks_array not initialised"
1546          -- Todo: can we avoid this?
1547    , modBreaks_locs = array (0,-1) []
1548    , modBreaks_vars = array (0,-1) []
1549    }
1550 \end{code}