compiler/main/Packages.lhs

   1 %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 \begin{code}
   5 -- | Package manipulation
   6 module Packages (
   7         module PackageConfig,
   8
   9         -- * The PackageConfigMap
  10         PackageConfigMap, emptyPackageConfigMap, lookupPackage,
  11         extendPackageConfigMap, dumpPackages,
  12
  13         -- * Reading the package config, and processing cmdline args
  14         PackageState(..),
  15         initPackages,
  16         getPackageDetails,
  17         lookupModuleInAllPackages,
  18
  19         -- * Inspecting the set of packages in scope
  20         getPackageIncludePath,
  21         getPackageLibraryPath,
  22         getPackageLinkOpts,
  23         getPackageExtraCcOpts,
  24         getPackageFrameworkPath,
  25         getPackageFrameworks,
  26         getPreloadPackagesAnd,
  27
  28         collectIncludeDirs, collectLibraryPaths, collectLinkOpts,
  29         packageHsLibs,
  30
  31         -- * Utils
  32         isDllName
  33     )
  34 where
  35
  36 #include "HsVersions.h"
  37
  38 import PackageConfig
  39 import ParsePkgConf     ( loadPackageConfig )
  40 import DynFlags         ( dopt, DynFlag(..), DynFlags(..), PackageFlag(..) )
  41 import StaticFlags      ( opt_Static )
  42 import Config           ( cProjectVersion )
  43 import Name             ( Name, nameModule_maybe )
  44 import UniqFM
  45 import Module
  46 import Util
  47 import Maybes           ( expectJust, MaybeErr(..) )
  48 import Panic
  49 import Outputable
  50
  51 import System.Environment ( getEnv )
  52 import Distribution.InstalledPackageInfo hiding (depends)
  53 import Distribution.Package hiding (depends, PackageId)
  54 import Distribution.Text
  55 import Distribution.Version
  56 import FastString
  57 import ErrUtils         ( debugTraceMsg, putMsg, Message )
  58 import Exception
  59
  60 import System.Directory
  61 import System.FilePath
  62 import Data.Maybe
  63 import Control.Monad
  64 import Data.List
  65
  66 -- ---------------------------------------------------------------------------
  67 -- The Package state
  68
  69 -- | Package state is all stored in 'DynFlag's, including the details of
  70 -- all packages, which packages are exposed, and which modules they
  71 -- provide.
  72 --
  73 -- The package state is computed by 'initPackages', and kept in DynFlags.
  74 --
  75 --   * @-package <pkg>@ causes @<pkg>@ to become exposed, and all other packages
  76 --      with the same name to become hidden.
  77 --
  78 --   * @-hide-package <pkg>@ causes @<pkg>@ to become hidden.
  79 --
  80 --   * Let @exposedPackages@ be the set of packages thus exposed.
  81 --     Let @depExposedPackages@ be the transitive closure from @exposedPackages@ of
  82 --     their dependencies.
  83 --
  84 --   * When searching for a module from an preload import declaration,
  85 --     only the exposed modules in @exposedPackages@ are valid.
  86 --
  87 --   * When searching for a module from an implicit import, all modules
  88 --     from @depExposedPackages@ are valid.
  89 --
  90 --   * When linking in a compilation manager mode, we link in packages the
  91 --     program depends on (the compiler knows this list by the
  92 --     time it gets to the link step).  Also, we link in all packages
  93 --     which were mentioned with preload @-package@ flags on the command-line,
  94 --     or are a transitive dependency of same, or are \"base\"\/\"rts\".
  95 --     The reason for this is that we might need packages which don't
  96 --     contain any Haskell modules, and therefore won't be discovered
  97 --     by the normal mechanism of dependency tracking.
  98
  99 -- Notes on DLLs
 100 -- ~~~~~~~~~~~~~
 101 -- When compiling module A, which imports module B, we need to
 102 -- know whether B will be in the same DLL as A.
 103 --      If it's in the same DLL, we refer to B_f_closure
 104 --      If it isn't, we refer to _imp__B_f_closure
 105 -- When compiling A, we record in B's Module value whether it's
 106 -- in a different DLL, by setting the DLL flag.
 107
 108 data PackageState = PackageState {
 109   pkgIdMap              :: PackageConfigMap, -- PackageId   -> PackageConfig
 110         -- The exposed flags are adjusted according to -package and
 111         -- -hide-package flags, and -ignore-package removes packages.
 112
 113   preloadPackages      :: [PackageId],
 114         -- The packages we're going to link in eagerly.  This list
 115         -- should be in reverse dependency order; that is, a package
 116         -- is always mentioned before the packages it depends on.
 117
 118   moduleToPkgConfAll    :: UniqFM [(PackageConfig,Bool)] -- ModuleEnv mapping
 119         -- Derived from pkgIdMap.
 120         -- Maps Module to (pkgconf,exposed), where pkgconf is the
 121         -- PackageConfig for the package containing the module, and
 122         -- exposed is True if the package exposes that module.
 123   }
 124
 125 -- | A PackageConfigMap maps a 'PackageId' to a 'PackageConfig'
 126 type PackageConfigMap = UniqFM PackageConfig
 127
 128 emptyPackageConfigMap :: PackageConfigMap
 129 emptyPackageConfigMap = emptyUFM
 130
 131 -- | Find the package we know about with the given id (e.g. \"foo-1.0\"), if any
 132 lookupPackage :: PackageConfigMap -> PackageId -> Maybe PackageConfig
 133 lookupPackage = lookupUFM
 134
 135 extendPackageConfigMap
 136    :: PackageConfigMap -> [PackageConfig] -> PackageConfigMap
 137 extendPackageConfigMap pkg_map new_pkgs
 138   = foldl add pkg_map new_pkgs
 139   where add pkg_map p = addToUFM pkg_map (packageConfigId p) p
 140
 141 -- | Looks up the package with the given id in the package state, panicing if it is
 142 -- not found
 143 getPackageDetails :: PackageState -> PackageId -> PackageConfig
 144 getPackageDetails ps pid = expectJust "getPackageDetails" (lookupPackage (pkgIdMap ps) pid)
 145
 146 -- ----------------------------------------------------------------------------
 147 -- Loading the package config files and building up the package state
 148
 149 -- | Call this after 'DynFlags.parseDynFlags'.  It reads the package
 150 -- configuration files, and sets up various internal tables of package
 151 -- information, according to the package-related flags on the
 152 -- command-line (@-package@, @-hide-package@ etc.)
 153 --
 154 -- Returns a list of packages to link in if we're doing dynamic linking.
 155 -- This list contains the packages that the user explicitly mentioned with
 156 -- @-package@ flags.
 157 --
 158 -- 'initPackages' can be called again subsequently after updating the
 159 -- 'packageFlags' field of the 'DynFlags', and it will update the
 160 -- 'pkgState' in 'DynFlags' and return a list of packages to
 161 -- link in.
 162 initPackages :: DynFlags -> IO (DynFlags, [PackageId])
 163 initPackages dflags = do
 164   pkg_db <- case pkgDatabase dflags of
 165                 Nothing -> readPackageConfigs dflags
 166                 Just db -> return db
 167   (pkg_state, preload, this_pkg)
 168         <- mkPackageState dflags pkg_db [] (thisPackage dflags)
 169   return (dflags{ pkgDatabase = Just pkg_db,
 170                   pkgState = pkg_state,
 171                   thisPackage = this_pkg },
 172           preload)
 173
 174 -- -----------------------------------------------------------------------------
 175 -- Reading the package database(s)
 176
 177 readPackageConfigs :: DynFlags -> IO PackageConfigMap
 178 readPackageConfigs dflags = do
 179    e_pkg_path <- tryIO (getEnv "GHC_PACKAGE_PATH")
 180    system_pkgconfs <- getSystemPackageConfigs dflags
 181
 182    let pkgconfs = case e_pkg_path of
 183                     Left _   -> system_pkgconfs
 184                     Right path
 185                      | last cs == "" -> init cs ++ system_pkgconfs
 186                      | otherwise     -> cs
 187                      where cs = parseSearchPath path
 188                      -- if the path ends in a separator (eg. "/foo/bar:")
 189                      -- the we tack on the system paths.
 190
 191         -- Read all the ones mentioned in -package-conf flags
 192    pkg_map <- foldM (readPackageConfig dflags) emptyPackageConfigMap
 193                  (reverse pkgconfs ++ extraPkgConfs dflags)
 194
 195    return pkg_map
 196
 197
 198 getSystemPackageConfigs :: DynFlags -> IO [FilePath]
 199 getSystemPackageConfigs dflags = do
 200         -- System one always comes first
 201    let system_pkgconf = systemPackageConfig dflags
 202
 203         -- allow package.conf.d to contain a bunch of .conf files
 204         -- containing package specifications.  This is an easier way
 205         -- to maintain the package database on systems with a package
 206         -- management system, or systems that don't want to run ghc-pkg
 207         -- to register or unregister packages.  Undocumented feature for now.
 208    let system_pkgconf_dir = system_pkgconf <.> "d"
 209    system_pkgconf_dir_exists <- doesDirectoryExist system_pkgconf_dir
 210    system_pkgconfs <-
 211      if system_pkgconf_dir_exists
 212        then do files <- getDirectoryContents system_pkgconf_dir
 213                return [ system_pkgconf_dir </> file
 214                       | file <- files
 215                       , takeExtension file == ".conf" ]
 216        else return []
 217
 218         -- Read user's package conf (eg. ~/.ghc/i386-linux-6.3/package.conf)
 219         -- unless the -no-user-package-conf flag was given.
 220         -- We only do this when getAppUserDataDirectory is available
 221         -- (GHC >= 6.3).
 222    user_pkgconf <- do
 223       appdir <- getAppUserDataDirectory "ghc"
 224       let
 225          pkgconf = appdir
 226                    </> (TARGET_ARCH ++ '-':TARGET_OS ++ '-':cProjectVersion)
 227                    </> "package.conf"
 228       flg <- doesFileExist pkgconf
 229       if (flg && dopt Opt_ReadUserPackageConf dflags)
 230         then return [pkgconf]
 231         else return []
 232     `catchIO` (\_ -> return [])
 233
 234    return (user_pkgconf ++ system_pkgconfs ++ [system_pkgconf])
 235
 236
 237 readPackageConfig
 238    :: DynFlags -> PackageConfigMap -> FilePath -> IO PackageConfigMap
 239 readPackageConfig dflags pkg_map conf_file = do
 240   debugTraceMsg dflags 2 (text "Using package config file:" <+> text conf_file)
 241   proto_pkg_configs <- loadPackageConfig dflags conf_file
 242   let top_dir = topDir dflags
 243       pkg_configs1 = mungePackagePaths top_dir proto_pkg_configs
 244       pkg_configs2 = maybeHidePackages dflags pkg_configs1
 245   return (extendPackageConfigMap pkg_map pkg_configs2)
 246
 247 maybeHidePackages :: DynFlags -> [PackageConfig] -> [PackageConfig]
 248 maybeHidePackages dflags pkgs
 249   | dopt Opt_HideAllPackages dflags = map hide pkgs
 250   | otherwise                       = pkgs
 251   where
 252     hide pkg = pkg{ exposed = False }
 253
 254 mungePackagePaths :: String -> [PackageConfig] -> [PackageConfig]
 255 -- Replace the string "$topdir" at the beginning of a path
 256 -- with the current topdir (obtained from the -B option).
 257 mungePackagePaths top_dir ps = map munge_pkg ps
 258  where
 259   munge_pkg p = p{ importDirs  = munge_paths (importDirs p),
 260                    includeDirs = munge_paths (includeDirs p),
 261                    libraryDirs = munge_paths (libraryDirs p),
 262                    frameworkDirs = munge_paths (frameworkDirs p),
 263                    haddockInterfaces = munge_paths (haddockInterfaces p),
 264                    haddockHTMLs = munge_paths (haddockHTMLs p)
 265                     }
 266
 267   munge_paths = map munge_path
 268
 269   munge_path p
 270           | Just p' <- maybePrefixMatch "$topdir"     p =            top_dir ++ p'
 271           | Just p' <- maybePrefixMatch "$httptopdir" p = toHttpPath top_dir ++ p'
 272           | otherwise                               = p
 273
 274   toHttpPath p = "file:///" ++ p
 275
 276
 277 -- -----------------------------------------------------------------------------
 278 -- Modify our copy of the package database based on a package flag
 279 -- (-package, -hide-package, -ignore-package).
 280
 281 applyPackageFlag
 282    :: [PackageConfig]           -- Initial database
 283    -> PackageFlag               -- flag to apply
 284    -> IO [PackageConfig]        -- new database
 285
 286 applyPackageFlag pkgs flag =
 287   case flag of
 288         ExposePackage str ->
 289            case matchingPackages str pkgs of
 290                 Nothing -> missingPackageErr str
 291                 Just ([], _) -> panic "applyPackageFlag"
 292                 Just (p:ps,qs) -> return (p':ps')
 293                   where p' = p {exposed=True}
 294                         ps' = hideAll (pkgName (package p)) (ps++qs)
 295
 296         HidePackage str ->
 297            case matchingPackages str pkgs of
 298                 Nothing -> missingPackageErr str
 299                 Just (ps,qs) -> return (map hide ps ++ qs)
 300                   where hide p = p {exposed=False}
 301
 302         IgnorePackage str ->
 303            case matchingPackages str pkgs of
 304                 Nothing -> return pkgs
 305                 Just (_, qs) -> return qs
 306                 -- missing package is not an error for -ignore-package,
 307                 -- because a common usage is to -ignore-package P as
 308                 -- a preventative measure just in case P exists.
 309    where
 310         -- When a package is requested to be exposed, we hide all other
 311         -- packages with the same name.
 312         hideAll name ps = map maybe_hide ps
 313           where maybe_hide p | pkgName (package p) == name = p {exposed=False}
 314                              | otherwise                   = p
 315
 316
 317 matchingPackages :: String -> [PackageConfig]
 318          -> Maybe ([PackageConfig], [PackageConfig])
 319 matchingPackages str pkgs
 320   = case partition (packageMatches str) pkgs of
 321         ([],_)    -> Nothing
 322         (ps,rest) -> Just (sortByVersion ps, rest)
 323
 324 -- A package named on the command line can either include the
 325 -- version, or just the name if it is unambiguous.
 326 packageMatches :: String -> PackageConfig -> Bool
 327 packageMatches str p
 328         =  str == display (package p)
 329         || str == display (pkgName (package p))
 330
 331 pickPackages :: [PackageConfig] -> [String] -> [PackageConfig]
 332 pickPackages pkgs strs =
 333   [ p | p <- strs, Just (p:_, _) <- [matchingPackages p pkgs] ]
 334
 335 sortByVersion :: [InstalledPackageInfo_ m] -> [InstalledPackageInfo_ m]
 336 sortByVersion = sortBy (flip (comparing (pkgVersion.package)))
 337
 338 comparing :: Ord a => (t -> a) -> t -> t -> Ordering
 339 comparing f a b = f a `compare` f b
 340
 341 -- -----------------------------------------------------------------------------
 342 -- Hide old versions of packages
 343
 344 --
 345 -- hide all packages for which there is also a later version
 346 -- that is already exposed.  This just makes it non-fatal to have two
 347 -- versions of a package exposed, which can happen if you install a
 348 -- later version of a package in the user database, for example.
 349 --
 350 hideOldPackages :: DynFlags -> [PackageConfig] -> IO [PackageConfig]
 351 hideOldPackages dflags pkgs = mapM maybe_hide pkgs
 352   where maybe_hide p
 353            | not (exposed p) = return p
 354            | (p' : _) <- later_versions = do
 355                 debugTraceMsg dflags 2 $
 356                    (ptext (sLit "hiding package") <+>
 357                     text (display (package p)) <+>
 358                     ptext (sLit "to avoid conflict with later version") <+>
 359                     text (display (package p')))
 360                 return (p {exposed=False})
 361            | otherwise = return p
 362           where myname = pkgName (package p)
 363                 myversion = pkgVersion (package p)
 364                 later_versions = [ p | p <- pkgs, exposed p,
 365                                     let pkg = package p,
 366                                     pkgName pkg == myname,
 367                                     pkgVersion pkg > myversion ]
 368
 369 -- -----------------------------------------------------------------------------
 370 -- Wired-in packages
 371
 372 findWiredInPackages
 373    :: DynFlags
 374    -> [PackageConfig]           -- database
 375    -> [PackageIdentifier]       -- preload packages
 376    -> PackageId                 -- this package
 377    -> IO ([PackageConfig],
 378           [PackageIdentifier],
 379           PackageId)
 380
 381 findWiredInPackages dflags pkgs preload this_package = do
 382   --
 383   -- Now we must find our wired-in packages, and rename them to
 384   -- their canonical names (eg. base-1.0 ==> base).
 385   --
 386   let
 387         wired_in_pkgids :: [(PackageId, [String])]
 388         wired_in_pkgids = [ (primPackageId, [""]),
 389                             (integerPackageId, [""]),
 390                             (basePackageId, [""]),
 391                             (rtsPackageId, [""]),
 392                             (haskell98PackageId, [""]),
 393                             (thPackageId, [""]),
 394                             (dphSeqPackageId, [""]),
 395                             (dphParPackageId, [""])]
 396
 397         matches :: PackageConfig -> (PackageId, [String]) -> Bool
 398         pc `matches` (pid, suffixes)
 399             = display (pkgName (package pc)) `elem`
 400               (map (packageIdString pid ++) suffixes)
 401
 402         -- find which package corresponds to each wired-in package
 403         -- delete any other packages with the same name
 404         -- update the package and any dependencies to point to the new
 405         -- one.
 406         --
 407         -- When choosing which package to map to a wired-in package
 408         -- name, we prefer exposed packages, and pick the latest
 409         -- version.  To override the default choice, -hide-package
 410         -- could be used to hide newer versions.
 411         --
 412         findWiredInPackage :: [PackageConfig] -> (PackageId, [String])
 413                            -> IO (Maybe (PackageIdentifier, PackageId))
 414         findWiredInPackage pkgs wired_pkg =
 415            let all_ps = [ p | p <- pkgs, p `matches` wired_pkg ] in
 416            case all_ps of
 417                 []   -> notfound
 418                 many -> pick (head (sortByVersion many))
 419           where
 420                 suffixes = snd wired_pkg
 421                 notfound = do
 422                           debugTraceMsg dflags 2 $
 423                             ptext (sLit "wired-in package ")
 424                                  <> ppr (fst wired_pkg)
 425                                  <> (if null suffixes
 426                                      then empty
 427                                      else text (show suffixes))
 428                                  <> ptext (sLit " not found.")
 429                           return Nothing
 430                 pick :: InstalledPackageInfo_ ModuleName
 431                      -> IO (Maybe (PackageIdentifier, PackageId))
 432                 pick pkg = do
 433                         debugTraceMsg dflags 2 $
 434                             ptext (sLit "wired-in package ")
 435                                  <> ppr (fst wired_pkg)
 436                                  <> ptext (sLit " mapped to ")
 437                                  <> text (display (package pkg))
 438                         return (Just (package pkg, fst wired_pkg))
 439
 440
 441   mb_wired_in_ids <- mapM (findWiredInPackage pkgs) wired_in_pkgids
 442   let
 443         wired_in_ids = catMaybes mb_wired_in_ids
 444
 445         -- this is old: we used to assume that if there were
 446         -- multiple versions of wired-in packages installed that
 447         -- they were mutually exclusive.  Now we're assuming that
 448         -- you have one "main" version of each wired-in package
 449         -- (the latest version), and the others are backward-compat
 450         -- wrappers that depend on this one.  e.g. base-4.0 is the
 451         -- latest, base-3.0 is a compat wrapper depending on base-4.0.
 452         {-
 453         deleteOtherWiredInPackages pkgs = filterOut bad pkgs
 454           where bad p = any (p `matches`) wired_in_pkgids
 455                       && package p `notElem` map fst wired_in_ids
 456         -}
 457
 458         updateWiredInDependencies pkgs = map upd_pkg pkgs
 459           where upd_pkg p = p{ package = upd_pid (package p),
 460                                depends = map upd_pid (depends p) }
 461
 462         upd_pid pid = case filter ((== pid) . fst) wired_in_ids of
 463                                 [] -> pid
 464                                 ((x, y):_) -> x{ pkgName = PackageName (packageIdString y),
 465                                                  pkgVersion = Version [] [] }
 466
 467         -- pkgs1 = deleteOtherWiredInPackages pkgs
 468
 469         pkgs2 = updateWiredInDependencies pkgs
 470
 471         preload1 = map upd_pid preload
 472
 473         -- we must return an updated thisPackage, just in case we
 474         -- are actually compiling one of the wired-in packages
 475         Just old_this_pkg = unpackPackageId this_package
 476         new_this_pkg = mkPackageId (upd_pid old_this_pkg)
 477
 478   return (pkgs2, preload1, new_this_pkg)
 479
 480 -- ----------------------------------------------------------------------------
 481 --
 482 -- Detect any packages that have missing dependencies, and also any
 483 -- mutually-recursive groups of packages (loops in the package graph
 484 -- are not allowed).  We do this by taking the least fixpoint of the
 485 -- dependency graph, repeatedly adding packages whose dependencies are
 486 -- satisfied until no more can be added.
 487 --
 488 elimDanglingDeps
 489    :: DynFlags
 490    -> [PackageConfig]
 491    -> [PackageId]       -- ignored packages
 492    -> IO [PackageConfig]
 493
 494 elimDanglingDeps dflags pkgs ignored = go [] pkgs'
 495  where
 496    pkgs' = filter (\p -> packageConfigId p `notElem` ignored) pkgs
 497
 498    go avail not_avail =
 499      case partitionWith (depsAvailable avail) not_avail of
 500         ([],        not_avail) -> do mapM_ reportElim not_avail; return avail
 501         (new_avail, not_avail) -> go (new_avail ++ avail) (map fst not_avail)
 502
 503    depsAvailable :: [PackageConfig] -> PackageConfig
 504                  -> Either PackageConfig (PackageConfig, [PackageIdentifier])
 505    depsAvailable pkgs_ok pkg
 506         | null dangling = Left pkg
 507         | otherwise     = Right (pkg, dangling)
 508         where dangling = filter (`notElem` pids) (depends pkg)
 509               pids = map package pkgs_ok
 510
 511    reportElim (p, deps) =
 512         debugTraceMsg dflags 2 $
 513              (ptext (sLit "package") <+> pprPkg p <+>
 514                   ptext (sLit "will be ignored due to missing or recursive dependencies:") $$
 515               nest 2 (hsep (map (text.display) deps)))
 516
 517 -- -----------------------------------------------------------------------------
 518 -- When all the command-line options are in, we can process our package
 519 -- settings and populate the package state.
 520
 521 mkPackageState
 522     :: DynFlags
 523     -> PackageConfigMap         -- initial database
 524     -> [PackageId]              -- preloaded packages
 525     -> PackageId                -- this package
 526     -> IO (PackageState,
 527            [PackageId],         -- new packages to preload
 528            PackageId) -- this package, might be modified if the current
 529
 530                       -- package is a wired-in package.
 531
 532 mkPackageState dflags orig_pkg_db preload0 this_package = do
 533   --
 534   -- Modify the package database according to the command-line flags
 535   -- (-package, -hide-package, -ignore-package, -hide-all-packages).
 536   --
 537   let flags = reverse (packageFlags dflags)
 538   let pkgs0 = eltsUFM orig_pkg_db
 539   pkgs1 <- foldM applyPackageFlag pkgs0 flags
 540
 541   -- Here we build up a set of the packages mentioned in -package
 542   -- flags on the command line; these are called the "preload"
 543   -- packages.  we link these packages in eagerly.  The preload set
 544   -- should contain at least rts & base, which is why we pretend that
 545   -- the command line contains -package rts & -package base.
 546   --
 547   let new_preload_packages =
 548         map package (pickPackages pkgs0 [ p | ExposePackage p <- flags ])
 549
 550   -- hide packages that are subsumed by later versions
 551   pkgs2 <- hideOldPackages dflags pkgs1
 552
 553   -- sort out which packages are wired in
 554   (pkgs3, preload1, new_this_pkg)
 555         <- findWiredInPackages dflags pkgs2 new_preload_packages this_package
 556
 557   let ignored = map packageConfigId $
 558                    pickPackages pkgs0 [ p | IgnorePackage p <- flags ]
 559   pkgs <- elimDanglingDeps dflags pkgs3 ignored
 560
 561   let pkg_db = extendPackageConfigMap emptyPackageConfigMap pkgs
 562
 563       -- add base & rts to the preload packages
 564       basicLinkedPackages
 565        | dopt Opt_AutoLinkPackages dflags
 566           = filter (flip elemUFM pkg_db) [basePackageId, rtsPackageId]
 567        | otherwise = []
 568       -- but in any case remove the current package from the set of
 569       -- preloaded packages so that base/rts does not end up in the
 570       -- set up preloaded package when we are just building it
 571       preload2 = nub (filter (/= new_this_pkg)
 572                              (basicLinkedPackages ++ map mkPackageId preload1))
 573
 574   -- Close the preload packages with their dependencies
 575   dep_preload <- closeDeps pkg_db (zip preload2 (repeat Nothing))
 576   let new_dep_preload = filter (`notElem` preload0) dep_preload
 577
 578   let pstate = PackageState{ preloadPackages     = dep_preload,
 579                              pkgIdMap            = pkg_db,
 580                              moduleToPkgConfAll  = mkModuleMap pkg_db
 581                            }
 582
 583   return (pstate, new_dep_preload, new_this_pkg)
 584
 585
 586 -- -----------------------------------------------------------------------------
 587 -- Make the mapping from module to package info
 588
 589 mkModuleMap
 590   :: PackageConfigMap
 591   -> UniqFM [(PackageConfig, Bool)]
 592 mkModuleMap pkg_db = foldr extend_modmap emptyUFM pkgids
 593   where
 594         pkgids = map packageConfigId (eltsUFM pkg_db)
 595
 596         extend_modmap pkgid modmap =
 597                 addListToUFM_C (++) modmap
 598                    ([(m, [(pkg, True)])  | m <- exposed_mods] ++
 599                     [(m, [(pkg, False)]) | m <- hidden_mods])
 600           where
 601                 pkg = expectJust "mkModuleMap" (lookupPackage pkg_db pkgid)
 602                 exposed_mods = exposedModules pkg
 603                 hidden_mods  = hiddenModules pkg
 604
 605 pprPkg :: PackageConfig -> SDoc
 606 pprPkg p = text (display (package p))
 607
 608 -- -----------------------------------------------------------------------------
 609 -- Extracting information from the packages in scope
 610
 611 -- Many of these functions take a list of packages: in those cases,
 612 -- the list is expected to contain the "dependent packages",
 613 -- i.e. those packages that were found to be depended on by the
 614 -- current module/program.  These can be auto or non-auto packages, it
 615 -- doesn't really matter.  The list is always combined with the list
 616 -- of preload (command-line) packages to determine which packages to
 617 -- use.
 618
 619 -- | Find all the include directories in these and the preload packages
 620 getPackageIncludePath :: DynFlags -> [PackageId] -> IO [String]
 621 getPackageIncludePath dflags pkgs =
 622   collectIncludeDirs `fmap` getPreloadPackagesAnd dflags pkgs
 623
 624 collectIncludeDirs :: [PackageConfig] -> [FilePath]
 625 collectIncludeDirs ps = nub (filter notNull (concatMap includeDirs ps))
 626
 627 -- | Find all the library paths in these and the preload packages
 628 getPackageLibraryPath :: DynFlags -> [PackageId] -> IO [String]
 629 getPackageLibraryPath dflags pkgs =
 630   collectLibraryPaths `fmap` getPreloadPackagesAnd dflags pkgs
 631
 632 collectLibraryPaths :: [PackageConfig] -> [FilePath]
 633 collectLibraryPaths ps = nub (filter notNull (concatMap libraryDirs ps))
 634
 635 -- | Find all the link options in these and the preload packages
 636 getPackageLinkOpts :: DynFlags -> [PackageId] -> IO [String]
 637 getPackageLinkOpts dflags pkgs =
 638   collectLinkOpts dflags `fmap` getPreloadPackagesAnd dflags pkgs
 639
 640 collectLinkOpts :: DynFlags -> [PackageConfig] -> [String]
 641 collectLinkOpts dflags ps = concat (map all_opts ps)
 642   where
 643         libs p     = packageHsLibs dflags p ++ extraLibraries p
 644         all_opts p = map ("-l" ++) (libs p) ++ ldOptions p
 645
 646 packageHsLibs :: DynFlags -> PackageConfig -> [String]
 647 packageHsLibs dflags p = map (mkDynName . addSuffix) (hsLibraries p)
 648   where
 649         tag = buildTag dflags
 650         rts_tag = rtsBuildTag dflags
 651
 652         mkDynName | opt_Static = id
 653                   | otherwise = (++ ("-ghc" ++ cProjectVersion))
 654
 655         addSuffix rts@"HSrts"    = rts       ++ (expandTag rts_tag)
 656         addSuffix other_lib      = other_lib ++ (expandTag tag)
 657
 658         expandTag t | null t = ""
 659                     | otherwise = '_':t
 660
 661 -- | Find all the C-compiler options in these and the preload packages
 662 getPackageExtraCcOpts :: DynFlags -> [PackageId] -> IO [String]
 663 getPackageExtraCcOpts dflags pkgs = do
 664   ps <- getPreloadPackagesAnd dflags pkgs
 665   return (concatMap ccOptions ps)
 666
 667 -- | Find all the package framework paths in these and the preload packages
 668 getPackageFrameworkPath  :: DynFlags -> [PackageId] -> IO [String]
 669 getPackageFrameworkPath dflags pkgs = do
 670   ps <- getPreloadPackagesAnd dflags pkgs
 671   return (nub (filter notNull (concatMap frameworkDirs ps)))
 672
 673 -- | Find all the package frameworks in these and the preload packages
 674 getPackageFrameworks  :: DynFlags -> [PackageId] -> IO [String]
 675 getPackageFrameworks dflags pkgs = do
 676   ps <- getPreloadPackagesAnd dflags pkgs
 677   return (concatMap frameworks ps)
 678
 679 -- -----------------------------------------------------------------------------
 680 -- Package Utils
 681
 682 -- | Takes a 'Module', and if the module is in a package returns
 683 -- @(pkgconf, exposed)@ where pkgconf is the PackageConfig for that package,
 684 -- and exposed is @True@ if the package exposes the module.
 685 lookupModuleInAllPackages :: DynFlags -> ModuleName -> [(PackageConfig,Bool)]
 686 lookupModuleInAllPackages dflags m =
 687   case lookupUFM (moduleToPkgConfAll (pkgState dflags)) m of
 688         Nothing -> []
 689         Just ps -> ps
 690
 691 -- | Find all the 'PackageConfig' in both the preload packages from 'DynFlags' and corresponding to the list of
 692 -- 'PackageConfig's
 693 getPreloadPackagesAnd :: DynFlags -> [PackageId] -> IO [PackageConfig]
 694 getPreloadPackagesAnd dflags pkgids =
 695   let
 696       state   = pkgState dflags
 697       pkg_map = pkgIdMap state
 698       preload = preloadPackages state
 699       pairs = zip pkgids (repeat Nothing)
 700   in do
 701   all_pkgs <- throwErr (foldM (add_package pkg_map) preload pairs)
 702   return (map (getPackageDetails state) all_pkgs)
 703
 704 -- Takes a list of packages, and returns the list with dependencies included,
 705 -- in reverse dependency order (a package appears before those it depends on).
 706 closeDeps :: PackageConfigMap -> [(PackageId, Maybe PackageId)]
 707         -> IO [PackageId]
 708 closeDeps pkg_map ps = throwErr (closeDepsErr pkg_map ps)
 709
 710 throwErr :: MaybeErr Message a -> IO a
 711 throwErr m = case m of
 712                 Failed e    -> ghcError (CmdLineError (showSDoc e))
 713                 Succeeded r -> return r
 714
 715 closeDepsErr :: PackageConfigMap -> [(PackageId,Maybe PackageId)]
 716         -> MaybeErr Message [PackageId]
 717 closeDepsErr pkg_map ps = foldM (add_package pkg_map) [] ps
 718
 719 -- internal helper
 720 add_package :: PackageConfigMap -> [PackageId] -> (PackageId,Maybe PackageId)
 721         -> MaybeErr Message [PackageId]
 722 add_package pkg_db ps (p, mb_parent)
 723   | p `elem` ps = return ps     -- Check if we've already added this package
 724   | otherwise =
 725       case lookupPackage pkg_db p of
 726         Nothing -> Failed (missingPackageMsg (packageIdString p) <>
 727                            missingDependencyMsg mb_parent)
 728         Just pkg -> do
 729            -- Add the package's dependents also
 730            let deps = map mkPackageId (depends pkg)
 731            ps' <- foldM (add_package pkg_db) ps (zip deps (repeat (Just p)))
 732            return (p : ps')
 733
 734 missingPackageErr :: String -> IO [PackageConfig]
 735 missingPackageErr p = ghcError (CmdLineError (showSDoc (missingPackageMsg p)))
 736
 737 missingPackageMsg :: String -> SDoc
 738 missingPackageMsg p = ptext (sLit "unknown package:") <+> text p
 739
 740 missingDependencyMsg :: Maybe PackageId -> SDoc
 741 missingDependencyMsg Nothing = empty
 742 missingDependencyMsg (Just parent)
 743   = space <> parens (ptext (sLit "dependency of") <+> ftext (packageIdFS parent))
 744
 745 -- -----------------------------------------------------------------------------
 746
 747 -- | Will the 'Name' come from a dynamically linked library?
 748 isDllName :: PackageId -> Name -> Bool
 749 isDllName this_pkg name
 750   | opt_Static = False
 751   | Just mod <- nameModule_maybe name = modulePackageId mod /= this_pkg
 752   | otherwise = False  -- no, it is not even an external name
 753
 754 -- -----------------------------------------------------------------------------
 755 -- Displaying packages
 756
 757 -- | Show package info on console, if verbosity is >= 3
 758 dumpPackages :: DynFlags -> IO ()
 759 dumpPackages dflags
 760   = do  let pkg_map = pkgIdMap (pkgState dflags)
 761         putMsg dflags $
 762               vcat (map (text . showInstalledPackageInfo
 763                               . packageConfigToInstalledPackageInfo)
 764                         (eltsUFM pkg_map))
 765 \end{code}