compiler/main/Packages.lhs

   1  %
   2 % (c) The University of Glasgow, 2006
   3 %
   4 % Package manipulation
   5 %
   6 \begin{code}
   7 module Packages (
   8         module PackageConfig,
   9
  10         -- * The PackageConfigMap
  11         PackageConfigMap, emptyPackageConfigMap, lookupPackage,
  12         extendPackageConfigMap, dumpPackages,
  13
  14         -- * Reading the package config, and processing cmdline args
  15         PackageState(..),
  16         initPackages,
  17         getPackageDetails,
  18         lookupModuleInAllPackages,
  19
  20         -- * Inspecting the set of packages in scope
  21         getPackageIncludePath,
  22         getPackageCIncludes,
  23         getPackageLibraryPath,
  24         getPackageLinkOpts,
  25         getPackageExtraCcOpts,
  26         getPackageFrameworkPath,
  27         getPackageFrameworks,
  28         getPreloadPackagesAnd,
  29
  30         -- * Utils
  31         isDllName
  32     )
  33 where
  34
  35 #include "HsVersions.h"
  36
  37 import PackageConfig
  38 import ParsePkgConf     ( loadPackageConfig )
  39 import DynFlags         ( dopt, DynFlag(..), DynFlags(..), PackageFlag(..) )
  40 import StaticFlags      ( opt_Static )
  41 import Config           ( cProjectVersion )
  42 import Name             ( Name, nameModule_maybe )
  43 import UniqFM
  44 import Module
  45 import Util
  46 import Maybes           ( expectJust, MaybeErr(..) )
  47 import Panic
  48 import Outputable
  49
  50 #if __GLASGOW_HASKELL__ < 603
  51 import Compat.Directory ( getAppUserDataDirectory )
  52 #endif
  53
  54 import System.Environment ( getEnv )
  55 import Distribution.InstalledPackageInfo
  56 import Distribution.Package
  57 import Distribution.Version
  58 import FastString
  59 import ErrUtils         ( debugTraceMsg, putMsg, Message )
  60
  61 import System.Directory
  62 import Data.Maybe
  63 import Control.Monad
  64 import Data.List
  65 import Control.Exception        ( throwDyn )
  66
  67 -- ---------------------------------------------------------------------------
  68 -- The Package state
  69
  70 -- Package state is all stored in DynFlags, including the details of
  71 -- all packages, which packages are exposed, and which modules they
  72 -- provide.
  73
  74 -- The package state is computed by initPackages, and kept in DynFlags.
  75 --
  76 --   * -package <pkg> causes <pkg> to become exposed, and all other packages
  77 --      with the same name to become hidden.
  78 --
  79 --   * -hide-package <pkg> causes <pkg> to become hidden.
  80 --
  81 --   * Let exposedPackages be the set of packages thus exposed.
  82 --     Let depExposedPackages be the transitive closure from exposedPackages of
  83 --     their dependencies.
  84 --
  85 --   * When searching for a module from an preload import declaration,
  86 --     only the exposed modules in exposedPackages are valid.
  87 --
  88 --   * When searching for a module from an implicit import, all modules
  89 --     from depExposedPackages are valid.
  90 --
  91 --   * When linking in a comp manager mode, we link in packages the
  92 --     program depends on (the compiler knows this list by the
  93 --     time it gets to the link step).  Also, we link in all packages
  94 --     which were mentioned with preload -package flags on the command-line,
  95 --     or are a transitive dependency of same, or are "base"/"rts".
  96 --     The reason for (b) is that we might need packages which don't
  97 --     contain any Haskell modules, and therefore won't be discovered
  98 --     by the normal mechanism of dependency tracking.
  99
 100 -- Notes on DLLs
 101 -- ~~~~~~~~~~~~~
 102 -- When compiling module A, which imports module B, we need to
 103 -- know whether B will be in the same DLL as A.
 104 --      If it's in the same DLL, we refer to B_f_closure
 105 --      If it isn't, we refer to _imp__B_f_closure
 106 -- When compiling A, we record in B's Module value whether it's
 107 -- in a different DLL, by setting the DLL flag.
 108
 109 data PackageState = PackageState {
 110   pkgIdMap              :: PackageConfigMap, -- PackageId   -> PackageConfig
 111         -- The exposed flags are adjusted according to -package and
 112         -- -hide-package flags, and -ignore-package removes packages.
 113
 114   preloadPackages      :: [PackageId],
 115         -- The packages we're going to link in eagerly.  This list
 116         -- should be in reverse dependency order; that is, a package
 117         -- is always mentioned before the packages it depends on.
 118
 119   moduleToPkgConfAll    :: UniqFM [(PackageConfig,Bool)] -- ModuleEnv mapping
 120         -- Derived from pkgIdMap.
 121         -- Maps Module to (pkgconf,exposed), where pkgconf is the
 122         -- PackageConfig for the package containing the module, and
 123         -- exposed is True if the package exposes that module.
 124   }
 125
 126 -- A PackageConfigMap maps a PackageId to a PackageConfig
 127 type PackageConfigMap = UniqFM PackageConfig
 128
 129 emptyPackageConfigMap :: PackageConfigMap
 130 emptyPackageConfigMap = emptyUFM
 131
 132 lookupPackage :: PackageConfigMap -> PackageId -> Maybe PackageConfig
 133 lookupPackage = lookupUFM
 134
 135 extendPackageConfigMap
 136    :: PackageConfigMap -> [PackageConfig] -> PackageConfigMap
 137 extendPackageConfigMap pkg_map new_pkgs
 138   = foldl add pkg_map new_pkgs
 139   where add pkg_map p = addToUFM pkg_map (packageConfigId p) p
 140
 141 getPackageDetails :: PackageState -> PackageId -> PackageConfig
 142 getPackageDetails dflags ps = expectJust "getPackageDetails" (lookupPackage (pkgIdMap dflags) ps)
 143
 144 -- ----------------------------------------------------------------------------
 145 -- Loading the package config files and building up the package state
 146
 147 -- | Call this after 'DynFlags.parseDynFlags'.  It reads the package
 148 -- configuration files, and sets up various internal tables of package
 149 -- information, according to the package-related flags on the
 150 -- command-line (@-package@, @-hide-package@ etc.)
 151 --
 152 -- Returns a list of packages to link in if we're doing dynamic linking.
 153 -- This list contains the packages that the user explicitly mentioned with
 154 -- -package flags.
 155 --
 156 -- 'initPackages' can be called again subsequently after updating the
 157 -- 'packageFlags' field of the 'DynFlags', and it will update the
 158 -- 'packageState' in 'DynFlags' and return a list of packages to
 159 -- link in.
 160 initPackages :: DynFlags -> IO (DynFlags, [PackageId])
 161 initPackages dflags = do
 162   pkg_db <- case pkgDatabase dflags of
 163                 Nothing -> readPackageConfigs dflags
 164                 Just db -> return db
 165   (pkg_state, preload, this_pkg)
 166         <- mkPackageState dflags pkg_db [] (thisPackage dflags)
 167   return (dflags{ pkgDatabase = Just pkg_db,
 168                   pkgState = pkg_state,
 169                   thisPackage = this_pkg },
 170           preload)
 171
 172 -- -----------------------------------------------------------------------------
 173 -- Reading the package database(s)
 174
 175 readPackageConfigs :: DynFlags -> IO PackageConfigMap
 176 readPackageConfigs dflags = do
 177    e_pkg_path <- try (getEnv "GHC_PACKAGE_PATH")
 178    system_pkgconfs <- getSystemPackageConfigs dflags
 179
 180    let pkgconfs = case e_pkg_path of
 181                     Left _   -> system_pkgconfs
 182                     Right path
 183                      | last cs == "" -> init cs ++ system_pkgconfs
 184                      | otherwise     -> cs
 185                      where cs = parseSearchPath path
 186                      -- if the path ends in a separator (eg. "/foo/bar:")
 187                      -- the we tack on the system paths.
 188
 189         -- Read all the ones mentioned in -package-conf flags
 190    pkg_map <- foldM (readPackageConfig dflags) emptyPackageConfigMap
 191                  (reverse pkgconfs ++ extraPkgConfs dflags)
 192
 193    return pkg_map
 194
 195
 196 getSystemPackageConfigs :: DynFlags -> IO [FilePath]
 197 getSystemPackageConfigs dflags = do
 198         -- System one always comes first
 199    let system_pkgconf = systemPackageConfig dflags
 200
 201         -- allow package.conf.d to contain a bunch of .conf files
 202         -- containing package specifications.  This is an easier way
 203         -- to maintain the package database on systems with a package
 204         -- management system, or systems that don't want to run ghc-pkg
 205         -- to register or unregister packages.  Undocumented feature for now.
 206    let system_pkgconf_dir = system_pkgconf ++ ".d"
 207    system_pkgconf_dir_exists <- doesDirectoryExist system_pkgconf_dir
 208    system_pkgconfs <-
 209      if system_pkgconf_dir_exists
 210        then do files <- getDirectoryContents system_pkgconf_dir
 211                return [ system_pkgconf_dir ++ '/' : file
 212                       | file <- files
 213                       , isSuffixOf ".conf" file]
 214        else return []
 215
 216         -- Read user's package conf (eg. ~/.ghc/i386-linux-6.3/package.conf)
 217         -- unless the -no-user-package-conf flag was given.
 218         -- We only do this when getAppUserDataDirectory is available
 219         -- (GHC >= 6.3).
 220    user_pkgconf <- handle (\_ -> return []) $ do
 221       appdir <- getAppUserDataDirectory "ghc"
 222       let
 223          pkgconf = appdir
 224                    `joinFileName` (TARGET_ARCH ++ '-':TARGET_OS ++ '-':cProjectVersion)
 225                    `joinFileName` "package.conf"
 226       flg <- doesFileExist pkgconf
 227       if (flg && dopt Opt_ReadUserPackageConf dflags)
 228         then return [pkgconf]
 229         else return []
 230
 231    return (user_pkgconf ++ system_pkgconfs ++ [system_pkgconf])
 232
 233
 234 readPackageConfig
 235    :: DynFlags -> PackageConfigMap -> FilePath -> IO PackageConfigMap
 236 readPackageConfig dflags pkg_map conf_file = do
 237   debugTraceMsg dflags 2 (text "Using package config file:" <+> text conf_file)
 238   proto_pkg_configs <- loadPackageConfig conf_file
 239   let top_dir = topDir dflags
 240       pkg_configs1 = mungePackagePaths top_dir proto_pkg_configs
 241       pkg_configs2 = maybeHidePackages dflags pkg_configs1
 242   return (extendPackageConfigMap pkg_map pkg_configs2)
 243
 244 maybeHidePackages :: DynFlags -> [PackageConfig] -> [PackageConfig]
 245 maybeHidePackages dflags pkgs
 246   | dopt Opt_HideAllPackages dflags = map hide pkgs
 247   | otherwise                       = pkgs
 248   where
 249     hide pkg = pkg{ exposed = False }
 250
 251 mungePackagePaths :: String -> [PackageConfig] -> [PackageConfig]
 252 -- Replace the string "$topdir" at the beginning of a path
 253 -- with the current topdir (obtained from the -B option).
 254 mungePackagePaths top_dir ps = map munge_pkg ps
 255  where
 256   munge_pkg p = p{ importDirs  = munge_paths (importDirs p),
 257                    includeDirs = munge_paths (includeDirs p),
 258                    libraryDirs = munge_paths (libraryDirs p),
 259                    frameworkDirs = munge_paths (frameworkDirs p) }
 260
 261   munge_paths = map munge_path
 262
 263   munge_path p
 264           | Just p' <- maybePrefixMatch "$topdir" p = top_dir ++ p'
 265           | otherwise                               = p
 266
 267
 268 -- -----------------------------------------------------------------------------
 269 -- Modify our copy of the package database based on a package flag
 270 -- (-package, -hide-package, -ignore-package).
 271
 272 applyPackageFlag
 273    :: [PackageConfig]           -- Initial database
 274    -> PackageFlag               -- flag to apply
 275    -> IO [PackageConfig]        -- new database
 276
 277 applyPackageFlag pkgs flag =
 278   case flag of
 279         ExposePackage str ->
 280            case matchingPackages str pkgs of
 281                 Nothing -> missingPackageErr str
 282                 Just (p:ps,qs) -> return (p':ps')
 283                   where p' = p {exposed=True}
 284                         ps' = hideAll (pkgName (package p)) (ps++qs)
 285
 286         HidePackage str ->
 287            case matchingPackages str pkgs of
 288                 Nothing -> missingPackageErr str
 289                 Just (ps,qs) -> return (map hide ps ++ qs)
 290                   where hide p = p {exposed=False}
 291
 292         IgnorePackage str ->
 293            case matchingPackages str pkgs of
 294                 Nothing -> return pkgs
 295                 Just (ps,qs) -> return qs
 296                 -- missing package is not an error for -ignore-package,
 297                 -- because a common usage is to -ignore-package P as
 298                 -- a preventative measure just in case P exists.
 299    where
 300         -- When a package is requested to be exposed, we hide all other
 301         -- packages with the same name.
 302         hideAll name ps = map maybe_hide ps
 303           where maybe_hide p | pkgName (package p) == name = p {exposed=False}
 304                              | otherwise                   = p
 305
 306
 307 matchingPackages :: String -> [PackageConfig]
 308          -> Maybe ([PackageConfig], [PackageConfig])
 309 matchingPackages str pkgs
 310   = case partition (matches str) pkgs of
 311         ([],_)    -> Nothing
 312         (ps,rest) -> Just (sortByVersion ps, rest)
 313   where
 314         -- A package named on the command line can either include the
 315         -- version, or just the name if it is unambiguous.
 316         matches str p
 317                 =  str == showPackageId (package p)
 318                 || str == pkgName (package p)
 319
 320
 321 pickPackages pkgs strs =
 322   [ p | p <- strs, Just (p:ps,_) <- [matchingPackages p pkgs] ]
 323
 324 sortByVersion = sortBy (flip (comparing (pkgVersion.package)))
 325 comparing f a b = f a `compare` f b
 326
 327 -- -----------------------------------------------------------------------------
 328 -- Hide old versions of packages
 329
 330 --
 331 -- hide all packages for which there is also a later version
 332 -- that is already exposed.  This just makes it non-fatal to have two
 333 -- versions of a package exposed, which can happen if you install a
 334 -- later version of a package in the user database, for example.
 335 --
 336 hideOldPackages :: DynFlags -> [PackageConfig] -> IO [PackageConfig]
 337 hideOldPackages dflags pkgs = mapM maybe_hide pkgs
 338   where maybe_hide p
 339            | not (exposed p) = return p
 340            | (p' : _) <- later_versions = do
 341                 debugTraceMsg dflags 2 $
 342                    (ptext SLIT("hiding package") <+>
 343                     text (showPackageId (package p)) <+>
 344                     ptext SLIT("to avoid conflict with later version") <+>
 345                     text (showPackageId (package p')))
 346                 return (p {exposed=False})
 347            | otherwise = return p
 348           where myname = pkgName (package p)
 349                 myversion = pkgVersion (package p)
 350                 later_versions = [ p | p <- pkgs, exposed p,
 351                                     let pkg = package p,
 352                                     pkgName pkg == myname,
 353                                     pkgVersion pkg > myversion ]
 354
 355 -- -----------------------------------------------------------------------------
 356 -- Wired-in packages
 357
 358 findWiredInPackages
 359    :: DynFlags
 360    -> [PackageConfig]           -- database
 361    -> [PackageIdentifier]       -- preload packages
 362    -> PackageId                 -- this package
 363    -> IO ([PackageConfig],
 364           [PackageIdentifier],
 365           PackageId)
 366
 367 findWiredInPackages dflags pkgs preload this_package = do
 368   --
 369   -- Now we must find our wired-in packages, and rename them to
 370   -- their canonical names (eg. base-1.0 ==> base).
 371   --
 372   let
 373         wired_in_pkgids = [ basePackageId,
 374                             rtsPackageId,
 375                             haskell98PackageId,
 376                             thPackageId,
 377                             ndpPackageId ]
 378
 379         wired_in_names = map packageIdString wired_in_pkgids
 380
 381         -- find which package corresponds to each wired-in package
 382         -- delete any other packages with the same name
 383         -- update the package and any dependencies to point to the new
 384         -- one.
 385         --
 386         -- When choosing which package to map to a wired-in package
 387         -- name, we prefer exposed packages, and pick the latest
 388         -- version.  To override the default choice, -hide-package
 389         -- could be used to hide newer versions.
 390         --
 391         findWiredInPackage :: [PackageConfig] -> String
 392                            -> IO (Maybe PackageIdentifier)
 393         findWiredInPackage pkgs wired_pkg =
 394            let all_ps = [ p | p <- pkgs, pkgName (package p) == wired_pkg ] in
 395            case filter exposed all_ps of
 396                 [] -> case all_ps of
 397                         []   -> notfound
 398                         many -> pick (head (sortByVersion many))
 399                 many  -> pick (head (sortByVersion many))
 400           where
 401                 notfound = do
 402                           debugTraceMsg dflags 2 $
 403                             ptext SLIT("wired-in package ")
 404                                  <> text wired_pkg
 405                                  <> ptext SLIT(" not found.")
 406                           return Nothing
 407                 pick pkg = do
 408                         debugTraceMsg dflags 2 $
 409                             ptext SLIT("wired-in package ")
 410                                  <> text wired_pkg
 411                                  <> ptext SLIT(" mapped to ")
 412                                  <> text (showPackageId (package pkg))
 413                         return (Just (package pkg))
 414
 415
 416   mb_wired_in_ids <- mapM (findWiredInPackage pkgs) wired_in_names
 417   let
 418         wired_in_ids = catMaybes mb_wired_in_ids
 419
 420         deleteOtherWiredInPackages pkgs = filter ok pkgs
 421           where ok p = pkgName (package p) `notElem` wired_in_names
 422                      || package p `elem` wired_in_ids
 423
 424         updateWiredInDependencies pkgs = map upd_pkg pkgs
 425           where upd_pkg p = p{ package = upd_pid (package p),
 426                                depends = map upd_pid (depends p) }
 427
 428         upd_pid pid = case filter (== pid) wired_in_ids of
 429                                 [] -> pid
 430                                 (x:_) -> x{ pkgVersion = Version [] [] }
 431
 432         pkgs1 = deleteOtherWiredInPackages pkgs
 433
 434         pkgs2 = updateWiredInDependencies pkgs1
 435
 436         preload1 = map upd_pid preload
 437
 438         -- we must return an updated thisPackage, just in case we
 439         -- are actually compiling one of the wired-in packages
 440         Just old_this_pkg = unpackPackageId this_package
 441         new_this_pkg = mkPackageId (upd_pid old_this_pkg)
 442
 443   return (pkgs2, preload1, new_this_pkg)
 444
 445 -- -----------------------------------------------------------------------------
 446 --
 447 -- Eliminate any packages which have dangling dependencies (
 448 -- because the dependency was removed by -ignore-package).
 449 --
 450 elimDanglingDeps
 451    :: DynFlags
 452    -> [PackageConfig]
 453    -> [PackageId]       -- ignored packages
 454    -> IO [PackageConfig]
 455
 456 elimDanglingDeps dflags pkgs ignored =
 457    case partition (not.null.snd) (map (getDanglingDeps pkgs ignored) pkgs) of
 458         ([],ps) -> return (map fst ps)
 459         (ps,qs) -> do
 460             mapM_ reportElim ps
 461             elimDanglingDeps dflags (map fst qs)
 462                 (ignored ++ map packageConfigId (map fst ps))
 463  where
 464    reportElim (p, deps) =
 465         debugTraceMsg dflags 2 $
 466              (ptext SLIT("package") <+> pprPkg p <+>
 467                   ptext SLIT("will be ignored due to missing dependencies:") $$
 468               nest 2 (hsep (map (text.showPackageId) deps)))
 469
 470    getDanglingDeps pkgs ignored p = (p, filter dangling (depends p))
 471         where dangling pid = mkPackageId pid `elem` ignored
 472
 473 -- -----------------------------------------------------------------------------
 474 -- When all the command-line options are in, we can process our package
 475 -- settings and populate the package state.
 476
 477 mkPackageState
 478     :: DynFlags
 479     -> PackageConfigMap         -- initial database
 480     -> [PackageId]              -- preloaded packages
 481     -> PackageId                -- this package
 482     -> IO (PackageState,
 483            [PackageId],         -- new packages to preload
 484            PackageId) -- this package, might be modified if the current
 485
 486                       -- package is a wired-in package.
 487
 488 mkPackageState dflags orig_pkg_db preload0 this_package = do
 489   --
 490   -- Modify the package database according to the command-line flags
 491   -- (-package, -hide-package, -ignore-package, -hide-all-packages).
 492   --
 493   let flags = reverse (packageFlags dflags)
 494   let pkgs0 = eltsUFM orig_pkg_db
 495   pkgs1 <- foldM applyPackageFlag pkgs0 flags
 496
 497   -- Here we build up a set of the packages mentioned in -package
 498   -- flags on the command line; these are called the "preload"
 499   -- packages.  we link these packages in eagerly.  The preload set
 500   -- should contain at least rts & base, which is why we pretend that
 501   -- the command line contains -package rts & -package base.
 502   --
 503   let new_preload_packages =
 504         map package (pickPackages pkgs0 [ p | ExposePackage p <- flags ])
 505
 506   -- hide packages that are subsumed by later versions
 507   pkgs2 <- hideOldPackages dflags pkgs1
 508
 509   -- sort out which packages are wired in
 510   (pkgs3, preload1, new_this_pkg)
 511         <- findWiredInPackages dflags pkgs2 new_preload_packages this_package
 512
 513   let ignored = map packageConfigId $
 514                    pickPackages pkgs0 [ p | IgnorePackage p <- flags ]
 515   pkgs <- elimDanglingDeps dflags pkgs3 ignored
 516
 517   let pkg_db = extendPackageConfigMap emptyPackageConfigMap pkgs
 518       pkgids = map packageConfigId pkgs
 519
 520       -- add base & rts to the preload packages
 521       basicLinkedPackages = filter (flip elemUFM pkg_db)
 522                                  [basePackageId,rtsPackageId]
 523       preload2 = nub (basicLinkedPackages ++ map mkPackageId preload1)
 524
 525   -- Close the preload packages with their dependencies
 526   dep_preload <- closeDeps pkg_db (zip preload2 (repeat Nothing))
 527   let new_dep_preload = filter (`notElem` preload0) dep_preload
 528
 529   let pstate = PackageState{ preloadPackages     = dep_preload,
 530                              pkgIdMap            = pkg_db,
 531                              moduleToPkgConfAll  = mkModuleMap pkg_db
 532                            }
 533
 534   return (pstate, new_dep_preload, new_this_pkg)
 535
 536
 537 -- -----------------------------------------------------------------------------
 538 -- Make the mapping from module to package info
 539
 540 mkModuleMap
 541   :: PackageConfigMap
 542   -> UniqFM [(PackageConfig, Bool)]
 543 mkModuleMap pkg_db = foldr extend_modmap emptyUFM pkgids
 544   where
 545         pkgids = map packageConfigId (eltsUFM pkg_db)
 546
 547         extend_modmap pkgid modmap =
 548                 addListToUFM_C (++) modmap
 549                     [(m, [(pkg, m `elem` exposed_mods)]) | m <- all_mods]
 550           where
 551                 pkg = expectJust "mkModuleMap" (lookupPackage pkg_db pkgid)
 552                 exposed_mods = map mkModuleName (exposedModules pkg)
 553                 hidden_mods  = map mkModuleName (hiddenModules pkg)
 554                 all_mods = exposed_mods ++ hidden_mods
 555
 556 pprPkg :: PackageConfig -> SDoc
 557 pprPkg p = text (showPackageId (package p))
 558
 559 -- -----------------------------------------------------------------------------
 560 -- Extracting information from the packages in scope
 561
 562 -- Many of these functions take a list of packages: in those cases,
 563 -- the list is expected to contain the "dependent packages",
 564 -- i.e. those packages that were found to be depended on by the
 565 -- current module/program.  These can be auto or non-auto packages, it
 566 -- doesn't really matter.  The list is always combined with the list
 567 -- of preload (command-line) packages to determine which packages to
 568 -- use.
 569
 570 getPackageIncludePath :: DynFlags -> [PackageId] -> IO [String]
 571 getPackageIncludePath dflags pkgs = do
 572   ps <- getPreloadPackagesAnd dflags pkgs
 573   return (nub (filter notNull (concatMap includeDirs ps)))
 574
 575         -- includes are in reverse dependency order (i.e. rts first)
 576 getPackageCIncludes :: [PackageConfig] -> IO [String]
 577 getPackageCIncludes pkg_configs = do
 578   return (reverse (nub (filter notNull (concatMap includes pkg_configs))))
 579
 580 getPackageLibraryPath :: DynFlags -> [PackageId] -> IO [String]
 581 getPackageLibraryPath dflags pkgs = do
 582   ps <- getPreloadPackagesAnd dflags pkgs
 583   return (nub (filter notNull (concatMap libraryDirs ps)))
 584
 585 getPackageLinkOpts :: DynFlags -> [PackageId] -> IO [String]
 586 getPackageLinkOpts dflags pkgs = do
 587   ps <- getPreloadPackagesAnd dflags pkgs
 588   let tag = buildTag dflags
 589       rts_tag = rtsBuildTag dflags
 590   let
 591         mkDynName | opt_Static = id
 592                   | otherwise = (++ ("-ghc" ++ cProjectVersion))
 593         libs p     = map (mkDynName . addSuffix) (hsLibraries p)
 594                          ++ extraLibraries p
 595         all_opts p = map ("-l" ++) (libs p) ++ ldOptions p
 596
 597         addSuffix rts@"HSrts"    = rts       ++ (expandTag rts_tag)
 598         addSuffix other_lib      = other_lib ++ (expandTag tag)
 599
 600         expandTag t | null t = ""
 601                     | otherwise = '_':t
 602
 603   return (concat (map all_opts ps))
 604
 605 getPackageExtraCcOpts :: DynFlags -> [PackageId] -> IO [String]
 606 getPackageExtraCcOpts dflags pkgs = do
 607   ps <- getPreloadPackagesAnd dflags pkgs
 608   return (concatMap ccOptions ps)
 609
 610 getPackageFrameworkPath  :: DynFlags -> [PackageId] -> IO [String]
 611 getPackageFrameworkPath dflags pkgs = do
 612   ps <- getPreloadPackagesAnd dflags pkgs
 613   return (nub (filter notNull (concatMap frameworkDirs ps)))
 614
 615 getPackageFrameworks  :: DynFlags -> [PackageId] -> IO [String]
 616 getPackageFrameworks dflags pkgs = do
 617   ps <- getPreloadPackagesAnd dflags pkgs
 618   return (concatMap frameworks ps)
 619
 620 -- -----------------------------------------------------------------------------
 621 -- Package Utils
 622
 623 -- | Takes a Module, and if the module is in a package returns
 624 -- @(pkgconf,exposed)@ where pkgconf is the PackageConfig for that package,
 625 -- and exposed is True if the package exposes the module.
 626 lookupModuleInAllPackages :: DynFlags -> ModuleName -> [(PackageConfig,Bool)]
 627 lookupModuleInAllPackages dflags m =
 628   case lookupUFM (moduleToPkgConfAll (pkgState dflags)) m of
 629         Nothing -> []
 630         Just ps -> ps
 631
 632 getPreloadPackagesAnd :: DynFlags -> [PackageId] -> IO [PackageConfig]
 633 getPreloadPackagesAnd dflags pkgids =
 634   let
 635       state   = pkgState dflags
 636       pkg_map = pkgIdMap state
 637       preload = preloadPackages state
 638       pairs = zip pkgids (repeat Nothing)
 639   in do
 640   all_pkgs <- throwErr (foldM (add_package pkg_map) preload pairs)
 641   return (map (getPackageDetails state) all_pkgs)
 642
 643 -- Takes a list of packages, and returns the list with dependencies included,
 644 -- in reverse dependency order (a package appears before those it depends on).
 645 closeDeps :: PackageConfigMap -> [(PackageId, Maybe PackageId)]
 646         -> IO [PackageId]
 647 closeDeps pkg_map ps = throwErr (closeDepsErr pkg_map ps)
 648
 649 throwErr :: MaybeErr Message a -> IO a
 650 throwErr m = case m of
 651                 Failed e    -> throwDyn (CmdLineError (showSDoc e))
 652                 Succeeded r -> return r
 653
 654 closeDepsErr :: PackageConfigMap -> [(PackageId,Maybe PackageId)]
 655         -> MaybeErr Message [PackageId]
 656 closeDepsErr pkg_map ps = foldM (add_package pkg_map) [] ps
 657
 658 -- internal helper
 659 add_package :: PackageConfigMap -> [PackageId] -> (PackageId,Maybe PackageId)
 660         -> MaybeErr Message [PackageId]
 661 add_package pkg_db ps (p, mb_parent)
 662   | p `elem` ps = return ps     -- Check if we've already added this package
 663   | otherwise =
 664       case lookupPackage pkg_db p of
 665         Nothing -> Failed (missingPackageMsg (packageIdString p) <>
 666                            missingDependencyMsg mb_parent)
 667         Just pkg -> do
 668            -- Add the package's dependents also
 669            let deps = map mkPackageId (depends pkg)
 670            ps' <- foldM (add_package pkg_db) ps (zip deps (repeat (Just p)))
 671            return (p : ps')
 672
 673 missingPackageErr p = throwDyn (CmdLineError (showSDoc (missingPackageMsg p)))
 674 missingPackageMsg p = ptext SLIT("unknown package:") <+> text p
 675
 676 missingDependencyMsg Nothing = empty
 677 missingDependencyMsg (Just parent)
 678   = space <> parens (ptext SLIT("dependency of") <+> ftext (packageIdFS parent))
 679
 680 -- -----------------------------------------------------------------------------
 681
 682 isDllName :: PackageId -> Name -> Bool
 683 isDllName this_pkg name
 684   | opt_Static = False
 685   | Just mod <- nameModule_maybe name = modulePackageId mod /= this_pkg
 686   | otherwise = False  -- no, it is not even an external name
 687
 688 -- -----------------------------------------------------------------------------
 689 -- Displaying packages
 690
 691 dumpPackages :: DynFlags -> IO ()
 692 -- Show package info on console, if verbosity is >= 3
 693 dumpPackages dflags
 694   = do  let pkg_map = pkgIdMap (pkgState dflags)
 695         putMsg dflags $
 696               vcat (map (text.showInstalledPackageInfo) (eltsUFM pkg_map))
 697 \end{code}