compiler/main/TidyPgm.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module TidyPgm( mkBootModDetailsDs, mkBootModDetailsTc,
   8                 tidyProgram, globaliseAndTidyId ) where
   9
  10 #include "HsVersions.h"
  11
  12 import TcRnTypes
  13 import FamInstEnv
  14 import DynFlags
  15 import CoreSyn
  16 import CoreUnfold
  17 import CoreFVs
  18 import CoreTidy
  19 import CoreMonad
  20 import CoreUtils
  21 import Rules
  22 import CoreArity        ( exprArity, exprBotStrictness_maybe )
  23 import Class            ( classAllSelIds )
  24 import VarEnv
  25 import VarSet
  26 import Var
  27 import Id
  28 import IdInfo
  29 import InstEnv
  30 import Demand
  31 import BasicTypes
  32 import Name hiding (varName)
  33 import NameSet
  34 import IfaceEnv
  35 import NameEnv
  36 import TcType
  37 import DataCon
  38 import TyCon
  39 import Module
  40 import Packages( isDllName )
  41 import HscTypes
  42 import Maybes
  43 import UniqSupply
  44 import Outputable
  45 import FastBool hiding ( fastOr )
  46 import Util
  47 import FastString
  48
  49 import Control.Monad    ( when )
  50 import Data.List        ( sortBy )
  51 import Data.IORef       ( IORef, readIORef, writeIORef )
  52 \end{code}
  53
  54
  55 Constructing the TypeEnv, Instances, Rules, VectInfo from which the
  56 ModIface is constructed, and which goes on to subsequent modules in
  57 --make mode.
  58
  59 Most of the interface file is obtained simply by serialising the
  60 TypeEnv.  One important consequence is that if the *interface file*
  61 has pragma info if and only if the final TypeEnv does. This is not so
  62 important for *this* module, but it's essential for ghc --make:
  63 subsequent compilations must not see (e.g.) the arity if the interface
  64 file does not contain arity If they do, they'll exploit the arity;
  65 then the arity might change, but the iface file doesn't change =>
  66 recompilation does not happen => disaster.
  67
  68 For data types, the final TypeEnv will have a TyThing for the TyCon,
  69 plus one for each DataCon; the interface file will contain just one
  70 data type declaration, but it is de-serialised back into a collection
  71 of TyThings.
  72
  73 %************************************************************************
  74 %*                                                                      *
  75                 Plan A: simpleTidyPgm
  76 %*                                                                      *
  77 %************************************************************************
  78
  79
  80 Plan A: mkBootModDetails: omit pragmas, make interfaces small
  81 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  82 * Ignore the bindings
  83
  84 * Drop all WiredIn things from the TypeEnv
  85         (we never want them in interface files)
  86
  87 * Retain all TyCons and Classes in the TypeEnv, to avoid
  88         having to find which ones are mentioned in the
  89         types of exported Ids
  90
  91 * Trim off the constructors of non-exported TyCons, both
  92         from the TyCon and from the TypeEnv
  93
  94 * Drop non-exported Ids from the TypeEnv
  95
  96 * Tidy the types of the DFunIds of Instances,
  97   make them into GlobalIds, (they already have External Names)
  98   and add them to the TypeEnv
  99
 100 * Tidy the types of the (exported) Ids in the TypeEnv,
 101   make them into GlobalIds (they already have External Names)
 102
 103 * Drop rules altogether
 104
 105 * Tidy the bindings, to ensure that the Caf and Arity
 106   information is correct for each top-level binder; the
 107   code generator needs it. And to ensure that local names have
 108   distinct OccNames in case of object-file splitting
 109
 110 \begin{code}
 111 -- This is Plan A: make a small type env when typechecking only,
 112 -- or when compiling a hs-boot file, or simply when not using -O
 113 --
 114 -- We don't look at the bindings at all -- there aren't any
 115 -- for hs-boot files
 116
 117 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
 118 mkBootModDetailsTc hsc_env
 119         TcGblEnv{ tcg_exports   = exports,
 120                   tcg_type_env  = type_env,
 121                   tcg_insts     = insts,
 122                   tcg_fam_insts = fam_insts
 123                 }
 124   = mkBootModDetails hsc_env exports type_env insts fam_insts
 125
 126 mkBootModDetailsDs :: HscEnv -> ModGuts -> IO ModDetails
 127 mkBootModDetailsDs hsc_env
 128         ModGuts{ mg_exports   = exports,
 129                  mg_types     = type_env,
 130                  mg_insts     = insts,
 131                  mg_fam_insts = fam_insts
 132                 }
 133   = mkBootModDetails hsc_env exports type_env insts fam_insts
 134
 135 mkBootModDetails :: HscEnv -> [AvailInfo] -> NameEnv TyThing
 136                  -> [Instance] -> [FamInstEnv.FamInst] -> IO ModDetails
 137 mkBootModDetails hsc_env exports type_env insts fam_insts
 138   = do  { let dflags = hsc_dflags hsc_env
 139         ; showPass dflags CoreTidy
 140
 141         ; let { insts'     = tidyInstances globaliseAndTidyId insts
 142               ; dfun_ids   = map instanceDFunId insts'
 143               ; type_env1  = tidyBootTypeEnv (availsToNameSet exports) type_env
 144               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
 145               }
 146         ; return (ModDetails { md_types     = type_env'
 147                              , md_insts     = insts'
 148                              , md_fam_insts = fam_insts
 149                              , md_rules     = []
 150                              , md_anns      = []
 151                              , md_exports   = exports
 152                              , md_vect_info = noVectInfo
 153                              })
 154         }
 155   where
 156
 157 tidyBootTypeEnv :: NameSet -> TypeEnv -> TypeEnv
 158 tidyBootTypeEnv exports type_env
 159   = tidyTypeEnv True False exports type_env final_ids
 160   where
 161         -- Find the LocalIds in the type env that are exported
 162         -- Make them into GlobalIds, and tidy their types
 163         --
 164         -- It's very important to remove the non-exported ones
 165         -- because we don't tidy the OccNames, and if we don't remove
 166         -- the non-exported ones we'll get many things with the
 167         -- same name in the interface file, giving chaos.
 168     final_ids = [ globaliseAndTidyId id
 169                 | id <- typeEnvIds type_env
 170                 , isLocalId id
 171                 , keep_it id ]
 172
 173         -- default methods have their export flag set, but everything
 174         -- else doesn't (yet), because this is pre-desugaring, so we
 175         -- must test both.
 176     keep_it id = isExportedId id || idName id `elemNameSet` exports
 177
 178
 179
 180 globaliseAndTidyId :: Id -> Id
 181 -- Takes an LocalId with an External Name,
 182 -- makes it into a GlobalId
 183 --     * unchanged Name (might be Internal or External)
 184 --     * unchanged details
 185 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
 186 globaliseAndTidyId id
 187   = Id.setIdType (globaliseId id) tidy_type
 188   where
 189     tidy_type = tidyTopType (idType id)
 190 \end{code}
 191
 192
 193 %************************************************************************
 194 %*                                                                      *
 195         Plan B: tidy bindings, make TypeEnv full of IdInfo
 196 %*                                                                      *
 197 %************************************************************************
 198
 199 Plan B: include pragmas, make interfaces
 200 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 201 * Figure out which Ids are externally visible
 202
 203 * Tidy the bindings, externalising appropriate Ids
 204
 205 * Drop all Ids from the TypeEnv, and add all the External Ids from
 206   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
 207   floated-out Ids that weren't even in the TypeEnv before.)
 208
 209 Step 1: Figure out external Ids
 210 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 211 Note [choosing external names]
 212
 213 See also the section "Interface stability" in the
 214 RecompilationAvoidance commentary:
 215   http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
 216
 217 First we figure out which Ids are "external" Ids.  An
 218 "external" Id is one that is visible from outside the compilation
 219 unit.  These are
 220         a) the user exported ones
 221         b) ones mentioned in the unfoldings, workers,
 222            or rules of externally-visible ones
 223
 224 While figuring out which Ids are external, we pick a "tidy" OccName
 225 for each one.  That is, we make its OccName distinct from the other
 226 external OccNames in this module, so that in interface files and
 227 object code we can refer to it unambiguously by its OccName.  The
 228 OccName for each binder is prefixed by the name of the exported Id
 229 that references it; e.g. if "f" references "x" in its unfolding, then
 230 "x" is renamed to "f_x".  This helps distinguish the different "x"s
 231 from each other, and means that if "f" is later removed, things that
 232 depend on the other "x"s will not need to be recompiled.  Of course,
 233 if there are multiple "f_x"s, then we have to disambiguate somehow; we
 234 use "f_x0", "f_x1" etc.
 235
 236 As far as possible we should assign names in a deterministic fashion.
 237 Each time this module is compiled with the same options, we should end
 238 up with the same set of external names with the same types.  That is,
 239 the ABI hash in the interface should not change.  This turns out to be
 240 quite tricky, since the order of the bindings going into the tidy
 241 phase is already non-deterministic, as it is based on the ordering of
 242 Uniques, which are assigned unpredictably.
 243
 244 To name things in a stable way, we do a depth-first-search of the
 245 bindings, starting from the exports sorted by name.  This way, as long
 246 as the bindings themselves are deterministic (they sometimes aren't!),
 247 the order in which they are presented to the tidying phase does not
 248 affect the names we assign.
 249
 250 Step 2: Tidy the program
 251 ~~~~~~~~~~~~~~~~~~~~~~~~
 252 Next we traverse the bindings top to bottom.  For each *top-level*
 253 binder
 254
 255  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal,
 256     reflecting the fact that from now on we regard it as a global,
 257     not local, Id
 258
 259  2. Give it a system-wide Unique.
 260     [Even non-exported things need system-wide Uniques because the
 261     byte-code generator builds a single Name->BCO symbol table.]
 262
 263     We use the NameCache kept in the HscEnv as the
 264     source of such system-wide uniques.
 265
 266     For external Ids, use the original-name cache in the NameCache
 267     to ensure that the unique assigned is the same as the Id had
 268     in any previous compilation run.
 269
 270  3. Rename top-level Ids according to the names we chose in step 1.
 271     If it's an external Id, make it have a External Name, otherwise
 272     make it have an Internal Name.  This is used by the code generator
 273     to decide whether to make the label externally visible
 274
 275  4. Give it its UTTERLY FINAL IdInfo; in ptic,
 276         * its unfolding, if it should have one
 277
 278         * its arity, computed from the number of visible lambdas
 279
 280         * its CAF info, computed from what is free in its RHS
 281
 282
 283 Finally, substitute these new top-level binders consistently
 284 throughout, including in unfoldings.  We also tidy binders in
 285 RHSs, so that they print nicely in interfaces.
 286
 287 \begin{code}
 288 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
 289 tidyProgram hsc_env  (ModGuts { mg_module = mod, mg_exports = exports,
 290                                 mg_types = type_env,
 291                                 mg_insts = insts, mg_fam_insts = fam_insts,
 292                                 mg_binds = binds,
 293                                 mg_rules = imp_rules,
 294                                 mg_vect_info = vect_info,
 295                                 mg_anns = anns,
 296                                 mg_deps = deps,
 297                                 mg_foreign = foreign_stubs,
 298                                 mg_hpc_info = hpc_info,
 299                                 mg_modBreaks = modBreaks })
 300
 301   = do  { let { dflags     = hsc_dflags hsc_env
 302               ; omit_prags = dopt Opt_OmitInterfacePragmas dflags
 303               ; expose_all = dopt Opt_ExposeAllUnfoldings  dflags
 304               ; th         = xopt Opt_TemplateHaskell      dflags
 305               }
 306         ; showPass dflags CoreTidy
 307
 308         ; let { implicit_binds = getImplicitBinds type_env }
 309
 310         ; (unfold_env, tidy_occ_env)
 311               <- chooseExternalIds hsc_env mod omit_prags expose_all
 312                                    binds implicit_binds imp_rules
 313
 314         ; let { ext_rules = findExternalRules omit_prags binds imp_rules unfold_env }
 315                 -- Glom together imp_rules and rules currently attached to binders
 316                 -- Then pick just the ones we need to expose
 317                 -- See Note [Which rules to expose]
 318
 319         ; let { (tidy_env, tidy_binds)
 320                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
 321
 322         ; let { export_set = availsToNameSet exports
 323               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds,
 324                                     isExternalName (idName id)]
 325               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
 326                                             type_env final_ids
 327               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
 328                 -- A DFunId will have a binding in tidy_binds, and so
 329                 -- will now be in final_env, replete with IdInfo
 330                 -- Its name will be unchanged since it was born, but
 331                 -- we want Global, IdInfo-rich (or not) DFunId in the
 332                 -- tidy_insts
 333
 334               ; tidy_rules = tidyRules tidy_env ext_rules
 335                 -- You might worry that the tidy_env contains IdInfo-rich stuff
 336                 -- and indeed it does, but if omit_prags is on, ext_rules is
 337                 -- empty
 338
 339               ; tidy_vect_info = tidyVectInfo tidy_env vect_info
 340
 341               -- See Note [Injecting implicit bindings]
 342               ; all_tidy_binds = implicit_binds ++ tidy_binds
 343
 344               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
 345               }
 346
 347         ; endPass dflags CoreTidy all_tidy_binds tidy_rules
 348
 349           -- If the endPass didn't print the rules, but ddump-rules is on, print now
 350         ; dumpIfSet (dopt Opt_D_dump_rules dflags
 351                      && (not (dopt Opt_D_dump_simpl dflags)))
 352                     CoreTidy
 353                     (ptext (sLit "rules"))
 354                     (pprRulesForUser tidy_rules)
 355
 356           -- Print one-line size info
 357         ; let cs = coreBindsStats tidy_binds
 358         ; when (dopt Opt_D_dump_core_stats dflags)
 359                (printDump (ptext (sLit "Tidy size (terms,types,coercions)")
 360                            <+> ppr (moduleName mod) <> colon
 361                            <+> int (cs_tm cs)
 362                            <+> int (cs_ty cs)
 363                            <+> int (cs_co cs) ))
 364
 365         ; return (CgGuts { cg_module   = mod,
 366                            cg_tycons   = alg_tycons,
 367                            cg_binds    = all_tidy_binds,
 368                            cg_foreign  = foreign_stubs,
 369                            cg_dep_pkgs = dep_pkgs deps,
 370                            cg_hpc_info = hpc_info,
 371                            cg_modBreaks = modBreaks },
 372
 373                    ModDetails { md_types     = tidy_type_env,
 374                                 md_rules     = tidy_rules,
 375                                 md_insts     = tidy_insts,
 376                                 md_vect_info = tidy_vect_info,
 377                                 md_fam_insts = fam_insts,
 378                                 md_exports   = exports,
 379                                 md_anns      = anns      -- are already tidy
 380                               })
 381         }
 382
 383 lookup_dfun :: TypeEnv -> Var -> Id
 384 lookup_dfun type_env dfun_id
 385   = case lookupTypeEnv type_env (idName dfun_id) of
 386         Just (AnId dfun_id') -> dfun_id'
 387         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
 388
 389 --------------------------
 390 tidyTypeEnv :: Bool     -- Compiling without -O, so omit prags
 391             -> Bool     -- Template Haskell is on
 392             -> NameSet -> TypeEnv -> [Id] -> TypeEnv
 393
 394 -- The competed type environment is gotten from
 395 --      Dropping any wired-in things, and then
 396 --      a) keeping the types and classes
 397 --      b) removing all Ids,
 398 --      c) adding Ids with correct IdInfo, including unfoldings,
 399 --              gotten from the bindings
 400 -- From (c) we keep only those Ids with External names;
 401 --          the CoreTidy pass makes sure these are all and only
 402 --          the externally-accessible ones
 403 -- This truncates the type environment to include only the
 404 -- exported Ids and things needed from them, which saves space
 405
 406 tidyTypeEnv omit_prags th exports type_env final_ids
 407  = let  type_env1 = filterNameEnv keep_it type_env
 408         type_env2 = extendTypeEnvWithIds type_env1 final_ids
 409         type_env3 | omit_prags = mapNameEnv (trimThing th exports) type_env2
 410                   | otherwise  = type_env2
 411     in
 412     type_env3
 413   where
 414         -- We keep GlobalIds, because they won't appear
 415         -- in the bindings from which final_ids are derived!
 416         -- (The bindings bind LocalIds.)
 417     keep_it thing | isWiredInThing thing = False
 418     keep_it (AnId id) = isGlobalId id   -- Keep GlobalIds (e.g. class ops)
 419     keep_it _other    = True            -- Keep all TyCons, DataCons, and Classes
 420
 421 --------------------------
 422 isWiredInThing :: TyThing -> Bool
 423 isWiredInThing thing = isWiredInName (getName thing)
 424
 425 --------------------------
 426 trimThing :: Bool -> NameSet -> TyThing -> TyThing
 427 -- Trim off inessentials, for boot files and no -O
 428 trimThing th exports (ATyCon tc)
 429    | not th && not (mustExposeTyCon exports tc)
 430    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
 431
 432 trimThing _th _exports (AnId id)
 433    | not (isImplicitId id)
 434    = AnId (id `setIdInfo` vanillaIdInfo)
 435
 436 trimThing _th _exports other_thing
 437   = other_thing
 438
 439
 440 {- Note [Trimming and Template Haskell]
 441    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 442 Consider (Trac #2386) this
 443         module M(T, makeOne) where
 444           data T = Yay String
 445           makeOne = [| Yay "Yep" |]
 446 Notice that T is exported abstractly, but makeOne effectively exports it too!
 447 A module that splices in $(makeOne) will then look for a declartion of Yay,
 448 so it'd better be there.  Hence, brutally but simply, we switch off type
 449 constructor trimming if TH is enabled in this module. -}
 450
 451
 452 mustExposeTyCon :: NameSet      -- Exports
 453                 -> TyCon        -- The tycon
 454                 -> Bool         -- Can its rep be hidden?
 455 -- We are compiling without -O, and thus trying to write as little as
 456 -- possible into the interface file.  But we must expose the details of
 457 -- any data types whose constructors or fields are exported
 458 mustExposeTyCon exports tc
 459   | not (isAlgTyCon tc)         -- Synonyms
 460   = True
 461   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
 462   = True                        -- won't lead to the need for further exposure
 463                                 -- (This includes data types with no constructors.)
 464   | isFamilyTyCon tc            -- Open type family
 465   = True
 466
 467   | otherwise                   -- Newtype, datatype
 468   = any exported_con (tyConDataCons tc)
 469         -- Expose rep if any datacon or field is exported
 470
 471   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
 472         -- Expose the rep for newtypes if the rep is an FFI type.
 473         -- For a very annoying reason.  'Foreign import' is meant to
 474         -- be able to look through newtypes transparently, but it
 475         -- can only do that if it can "see" the newtype representation
 476   where
 477     exported_con con = any (`elemNameSet` exports)
 478                            (dataConName con : dataConFieldLabels con)
 479
 480 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
 481 tidyInstances tidy_dfun ispecs
 482   = map tidy ispecs
 483   where
 484     tidy ispec = setInstanceDFunId ispec $
 485                  tidy_dfun (instanceDFunId ispec)
 486 \end{code}
 487
 488 \begin{code}
 489 tidyVectInfo :: TidyEnv -> VectInfo -> VectInfo
 490 tidyVectInfo (_, var_env) info@(VectInfo { vectInfoVar          = vars
 491                                          , vectInfoPADFun       = pas
 492                                          , vectInfoIso          = isos
 493                                          , vectInfoScalarVars   = scalarVars
 494                                          })
 495   = info { vectInfoVar          = tidy_vars
 496          , vectInfoPADFun       = tidy_pas
 497          , vectInfoIso          = tidy_isos
 498          , vectInfoScalarVars   = tidy_scalarVars
 499          }
 500   where
 501     tidy_vars = mkVarEnv
 502               $ map tidy_var_mapping
 503               $ varEnvElts vars
 504
 505     tidy_pas = mapNameEnv tidy_snd_var pas
 506     tidy_isos = mapNameEnv tidy_snd_var isos
 507
 508     tidy_var_mapping (from, to) = (from', (from', lookup_var to))
 509       where from' = lookup_var from
 510     tidy_snd_var (x, var) = (x, lookup_var var)
 511
 512     tidy_scalarVars = mkVarSet
 513                     $ map lookup_var
 514                     $ varSetElems scalarVars
 515
 516     lookup_var var = lookupWithDefaultVarEnv var_env var var
 517 \end{code}
 518
 519
 520 %************************************************************************
 521 %*                                                                      *
 522         Implicit bindings
 523 %*                                                                      *
 524 %************************************************************************
 525
 526 Note [Injecting implicit bindings]
 527 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 528 We inject the implict bindings right at the end, in CoreTidy.
 529 Some of these bindings, notably record selectors, are not
 530 constructed in an optimised form.  E.g. record selector for
 531         data T = MkT { x :: {-# UNPACK #-} !Int }
 532 Then the unfolding looks like
 533         x = \t. case t of MkT x1 -> let x = I# x1 in x
 534 This generates bad code unless it's first simplified a bit.  That is
 535 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
 536 optimisation first.  (Only matters when the selector is used curried;
 537 eg map x ys.)  See Trac #2070.
 538
 539 [Oct 09: in fact, record selectors are no longer implicit Ids at all,
 540 because we really do want to optimise them properly. They are treated
 541 much like any other Id.  But doing "light" optimisation on an implicit
 542 Id still makes sense.]
 543
 544 At one time I tried injecting the implicit bindings *early*, at the
 545 beginning of SimplCore.  But that gave rise to real difficulty,
 546 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
 547 simplifier and other core-to-core passes mess with IdInfo all the
 548 time.  The straw that broke the camels back was when a class selector
 549 got the wrong arity -- ie the simplifier gave it arity 2, whereas
 550 importing modules were expecting it to have arity 1 (Trac #2844).
 551 It's much safer just to inject them right at the end, after tidying.
 552
 553 Oh: two other reasons for injecting them late:
 554
 555   - If implicit Ids are already in the bindings when we start TidyPgm,
 556     we'd have to be careful not to treat them as external Ids (in
 557     the sense of findExternalIds); else the Ids mentioned in *their*
 558     RHSs will be treated as external and you get an interface file
 559     saying      a18 = <blah>
 560     but nothing refererring to a18 (because the implicit Id is the
 561     one that does, and implicit Ids don't appear in interface files).
 562
 563   - More seriously, the tidied type-envt will include the implicit
 564     Id replete with a18 in its unfolding; but we won't take account
 565     of a18 when computing a fingerprint for the class; result chaos.
 566
 567 There is one sort of implicit binding that is injected still later,
 568 namely those for data constructor workers. Reason (I think): it's
 569 really just a code generation trick.... binding itself makes no sense.
 570 See CorePrep Note [Data constructor workers].
 571
 572 \begin{code}
 573 getImplicitBinds :: TypeEnv -> [CoreBind]
 574 getImplicitBinds type_env
 575   = map get_defn (concatMap implicit_ids (typeEnvElts type_env))
 576   where
 577     implicit_ids (ATyCon tc)  = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
 578     implicit_ids (AClass cls) = classAllSelIds cls
 579     implicit_ids _            = []
 580
 581     get_defn :: Id -> CoreBind
 582     get_defn id = NonRec id (unfoldingTemplate (realIdUnfolding id))
 583 \end{code}
 584
 585
 586 %************************************************************************
 587 %*                                                                      *
 588 \subsection{Step 1: finding externals}
 589 %*                                                                      *
 590 %************************************************************************
 591
 592 Sete Note [choosing external names].
 593
 594 \begin{code}
 595 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
 596   -- Maps each top-level Id to its new Name (the Id is tidied in step 2)
 597   -- The Unique is unchanged.  If the new Name is external, it will be
 598   -- visible in the interface file.
 599   --
 600   -- Bool => expose unfolding or not.
 601
 602 chooseExternalIds :: HscEnv
 603                   -> Module
 604                   -> Bool -> Bool
 605                   -> [CoreBind]
 606                   -> [CoreBind]
 607                   -> [CoreRule]
 608                   -> IO (UnfoldEnv, TidyOccEnv)
 609         -- Step 1 from the notes above
 610
 611 chooseExternalIds hsc_env mod omit_prags expose_all binds implicit_binds imp_id_rules
 612   = do { (unfold_env1,occ_env1) <- search init_work_list emptyVarEnv init_occ_env
 613        ; let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
 614        ; tidy_internal internal_ids unfold_env1 occ_env1 }
 615  where
 616   nc_var = hsc_NC hsc_env
 617
 618   -- init_ext_ids is the intial list of Ids that should be
 619   -- externalised.  It serves as the starting point for finding a
 620   -- deterministic, tidy, renaming for all external Ids in this
 621   -- module.
 622   --
 623   -- It is sorted, so that it has adeterministic order (i.e. it's the
 624   -- same list every time this module is compiled), in contrast to the
 625   -- bindings, which are ordered non-deterministically.
 626   init_work_list = zip init_ext_ids init_ext_ids
 627   init_ext_ids   = sortBy (compare `on` getOccName) $
 628                    filter is_external binders
 629
 630   -- An Id should be external if either (a) it is exported or
 631   -- (b) it appears in the RHS of a local rule for an imported Id.
 632   -- See Note [Which rules to expose]
 633   is_external id = isExportedId id || id `elemVarSet` rule_rhs_vars
 634   rule_rhs_vars = foldr (unionVarSet . ruleRhsFreeVars) emptyVarSet imp_id_rules
 635
 636   binders          = bindersOfBinds binds
 637   implicit_binders = bindersOfBinds implicit_binds
 638   binder_set       = mkVarSet binders
 639
 640   avoids   = [getOccName name | bndr <- binders ++ implicit_binders,
 641                                 let name = idName bndr,
 642                                 isExternalName name ]
 643                 -- In computing our "avoids" list, we must include
 644                 --      all implicit Ids
 645                 --      all things with global names (assigned once and for
 646                 --                                      all by the renamer)
 647                 -- since their names are "taken".
 648                 -- The type environment is a convenient source of such things.
 649                 -- In particular, the set of binders doesn't include
 650                 -- implicit Ids at this stage.
 651
 652         -- We also make sure to avoid any exported binders.  Consider
 653         --      f{-u1-} = 1     -- Local decl
 654         --      ...
 655         --      f{-u2-} = 2     -- Exported decl
 656         --
 657         -- The second exported decl must 'get' the name 'f', so we
 658         -- have to put 'f' in the avoids list before we get to the first
 659         -- decl.  tidyTopId then does a no-op on exported binders.
 660   init_occ_env = initTidyOccEnv avoids
 661
 662
 663   search :: [(Id,Id)]    -- The work-list: (external id, referrring id)
 664                          -- Make a tidy, external Name for the external id,
 665                          --   add it to the UnfoldEnv, and do the same for the
 666                          --   transitive closure of Ids it refers to
 667                          -- The referring id is used to generate a tidy
 668                          ---  name for the external id
 669          -> UnfoldEnv    -- id -> (new Name, show_unfold)
 670          -> TidyOccEnv   -- occ env for choosing new Names
 671          -> IO (UnfoldEnv, TidyOccEnv)
 672
 673   search [] unfold_env occ_env = return (unfold_env, occ_env)
 674
 675   search ((idocc,referrer) : rest) unfold_env occ_env
 676     | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
 677     | otherwise = do
 678       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
 679       let
 680           (new_ids, show_unfold)
 681                 | omit_prags = ([], False)
 682                 | otherwise  = addExternal expose_all refined_id
 683
 684                 -- 'idocc' is an *occurrence*, but we need to see the
 685                 -- unfolding in the *definition*; so look up in binder_set
 686           refined_id = case lookupVarSet binder_set idocc of
 687                          Just id -> id
 688                          Nothing -> WARN( True, ppr idocc ) idocc
 689
 690           unfold_env' = extendVarEnv unfold_env idocc (name',show_unfold)
 691           referrer' | isExportedId refined_id = refined_id
 692                     | otherwise               = referrer
 693       --
 694       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
 695
 696   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
 697                 -> IO (UnfoldEnv, TidyOccEnv)
 698   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
 699   tidy_internal (id:ids) unfold_env occ_env = do
 700       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
 701       let unfold_env' = extendVarEnv unfold_env id (name',False)
 702       tidy_internal ids unfold_env' occ_env'
 703
 704 addExternal :: Bool -> Id -> ([Id],Bool)
 705 addExternal expose_all id = (new_needed_ids, show_unfold)
 706   where
 707     new_needed_ids = unfold_ids ++
 708                      filter (\id -> isLocalId id &&
 709                                     not (id `elemVarSet` unfold_set))
 710                        (varSetElems spec_ids) -- XXX non-det ordering
 711
 712     idinfo         = idInfo id
 713     never_active   = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
 714     loop_breaker   = isNonRuleLoopBreaker (occInfo idinfo)
 715     bottoming_fn   = isBottomingSig (strictnessInfo idinfo `orElse` topSig)
 716     spec_ids       = specInfoFreeVars (specInfo idinfo)
 717
 718         -- Stuff to do with the Id's unfolding
 719         -- We leave the unfolding there even if there is a worker
 720         -- In GHCI the unfolding is used by importers
 721     show_unfold = isJust mb_unfold_ids
 722     (unfold_set, unfold_ids) = mb_unfold_ids `orElse` (emptyVarSet, [])
 723
 724     mb_unfold_ids :: Maybe (IdSet, [Id])        -- Nothing => don't unfold
 725     mb_unfold_ids = case unfoldingInfo idinfo of
 726                       CoreUnfolding { uf_tmpl = unf_rhs, uf_src = src, uf_guidance = guide }
 727                                             | show_unfolding src guide
 728                                             -> Just (unf_ext_ids src unf_rhs)
 729                       DFunUnfolding _ _ ops -> Just (exprsFvsInOrder (dfunArgExprs ops))
 730                       _                     -> Nothing
 731                   where
 732                     unf_ext_ids (InlineWrapper v) _ = (unitVarSet v, [v])
 733                     unf_ext_ids _           unf_rhs = exprFvsInOrder unf_rhs
 734                     -- For a wrapper, externalise the wrapper id rather than the
 735                     -- fvs of the rhs.  The two usually come down to the same thing
 736                     -- but I've seen cases where we had a wrapper id $w but a
 737                     -- rhs where $w had been inlined; see Trac #3922
 738
 739     show_unfolding unf_source unf_guidance
 740        =  expose_all         -- 'expose_all' says to expose all
 741                              -- unfoldings willy-nilly
 742
 743        || isStableSource unf_source          -- Always expose things whose
 744                                              -- source is an inline rule
 745
 746        || not (bottoming_fn      -- No need to inline bottom functions
 747            || never_active       -- Or ones that say not to
 748            || loop_breaker       -- Or that are loop breakers
 749            || neverUnfoldGuidance unf_guidance)
 750
 751 -- We want a deterministic free-variable list.  exprFreeVars gives us
 752 -- a VarSet, which is in a non-deterministic order when converted to a
 753 -- list.  Hence, here we define a free-variable finder that returns
 754 -- the free variables in the order that they are encountered.
 755 --
 756 -- Note [choosing external names]
 757
 758 exprFvsInOrder :: CoreExpr -> (VarSet, [Id])
 759 exprFvsInOrder e = run (dffvExpr e)
 760
 761 exprsFvsInOrder :: [CoreExpr] -> (VarSet, [Id])
 762 exprsFvsInOrder es = run (mapM_ dffvExpr es)
 763
 764 run :: DFFV () -> (VarSet, [Id])
 765 run (DFFV m) = case m emptyVarSet [] of
 766                  (set,ids,_) -> (set,ids)
 767
 768 newtype DFFV a = DFFV (VarSet -> [Var] -> (VarSet,[Var],a))
 769
 770 instance Monad DFFV where
 771   return a = DFFV $ \set ids -> (set, ids, a)
 772   (DFFV m) >>= k = DFFV $ \set ids ->
 773     case m set ids of
 774        (set',ids',a) -> case k a of
 775                           DFFV f -> f set' ids'
 776
 777 insert :: Var -> DFFV ()
 778 insert v = DFFV $ \ set ids  -> case () of
 779  _ | v `elemVarSet` set -> (set,ids,())
 780    | otherwise          -> (extendVarSet set v, v:ids, ())
 781
 782 dffvExpr :: CoreExpr -> DFFV ()
 783 dffvExpr e = go emptyVarSet e
 784   where
 785     go scope e = case e of
 786       Var v | isLocalId v && not (v `elemVarSet` scope) -> insert v
 787       App e1 e2          -> do go scope e1; go scope e2
 788       Lam v e            -> go (extendVarSet scope v) e
 789       Note _ e           -> go scope e
 790       Cast e _           -> go scope e
 791       Let (NonRec x r) e -> do go scope r; go (extendVarSet scope x) e
 792       Let (Rec prs) e    -> do let scope' = extendVarSetList scope (map fst prs)
 793                                mapM_ (go scope') (map snd prs)
 794                                go scope' e
 795       Case e b _ as      -> do go scope e
 796                                mapM_ (go_alt (extendVarSet scope b)) as
 797       _other             -> return ()
 798
 799     go_alt scope (_,xs,r) = go (extendVarSetList scope xs) r
 800 \end{code}
 801
 802
 803 --------------------------------------------------------------------
 804 --              tidyTopName
 805 -- This is where we set names to local/global based on whether they really are
 806 -- externally visible (see comment at the top of this module).  If the name
 807 -- was previously local, we have to give it a unique occurrence name if
 808 -- we intend to externalise it.
 809
 810 \begin{code}
 811 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
 812             -> Id -> IO (TidyOccEnv, Name)
 813 tidyTopName mod nc_var maybe_ref occ_env id
 814   | global && internal = return (occ_env, localiseName name)
 815
 816   | global && external = return (occ_env, name)
 817         -- Global names are assumed to have been allocated by the renamer,
 818         -- so they already have the "right" unique
 819         -- And it's a system-wide unique too
 820
 821   -- Now we get to the real reason that all this is in the IO Monad:
 822   -- we have to update the name cache in a nice atomic fashion
 823
 824   | local  && internal = do { nc <- readIORef nc_var
 825                             ; let (nc', new_local_name) = mk_new_local nc
 826                             ; writeIORef nc_var nc'
 827                             ; return (occ_env', new_local_name) }
 828         -- Even local, internal names must get a unique occurrence, because
 829         -- if we do -split-objs we externalise the name later, in the code generator
 830         --
 831         -- Similarly, we must make sure it has a system-wide Unique, because
 832         -- the byte-code generator builds a system-wide Name->BCO symbol table
 833
 834   | local  && external = do { nc <- readIORef nc_var
 835                             ; let (nc', new_external_name) = mk_new_external nc
 836                             ; writeIORef nc_var nc'
 837                             ; return (occ_env', new_external_name) }
 838
 839   | otherwise = panic "tidyTopName"
 840   where
 841     name        = idName id
 842     external    = isJust maybe_ref
 843     global      = isExternalName name
 844     local       = not global
 845     internal    = not external
 846     loc         = nameSrcSpan name
 847
 848     old_occ     = nameOccName name
 849     new_occ
 850       | Just ref <- maybe_ref, ref /= id =
 851           mkOccName (occNameSpace old_occ) $
 852              let
 853                  ref_str = occNameString (getOccName ref)
 854                  occ_str = occNameString old_occ
 855              in
 856              case occ_str of
 857                '$':'w':_ -> occ_str
 858                   -- workers: the worker for a function already
 859                   -- includes the occname for its parent, so there's
 860                   -- no need to prepend the referrer.
 861                _other | isSystemName name -> ref_str
 862                       | otherwise         -> ref_str ++ '_' : occ_str
 863                   -- If this name was system-generated, then don't bother
 864                   -- to retain its OccName, just use the referrer.  These
 865                   -- system-generated names will become "f1", "f2", etc. for
 866                   -- a referrer "f".
 867       | otherwise = old_occ
 868
 869     (occ_env', occ') = tidyOccName occ_env new_occ
 870
 871     mk_new_local nc = (nc { nsUniqs = us }, mkInternalName uniq occ' loc)
 872                     where
 873                       (uniq, us) = takeUniqFromSupply (nsUniqs nc)
 874
 875     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
 876         -- If we want to externalise a currently-local name, check
 877         -- whether we have already assigned a unique for it.
 878         -- If so, use it; if not, extend the table.
 879         -- All this is done by allcoateGlobalBinder.
 880         -- This is needed when *re*-compiling a module in GHCi; we must
 881         -- use the same name for externally-visible things as we did before.
 882 \end{code}
 883
 884 \begin{code}
 885 findExternalRules :: Bool       -- Omit pragmas
 886                   -> [CoreBind]
 887                   -> [CoreRule] -- Local rules for imported fns
 888                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
 889                   -> [CoreRule]
 890   -- The complete rules are gotten by combining
 891   --    a) local rules for imported Ids
 892   --    b) rules embedded in the top-level Ids
 893 findExternalRules omit_prags binds imp_id_rules unfold_env
 894   | omit_prags = []
 895   | otherwise  = filterOut internal_rule (imp_id_rules ++ local_rules)
 896   where
 897     local_rules  = [ rule
 898                    | id <- bindersOfBinds binds,
 899                      external_id id,
 900                      rule <- idCoreRules id
 901                    ]
 902
 903     internal_rule rule
 904         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
 905                 -- Don't export a rule whose LHS mentions a locally-defined
 906                 --  Id that is completely internal (i.e. not visible to an
 907                 -- importing module)
 908
 909     external_id id
 910       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
 911       | otherwise = False
 912 \end{code}
 913
 914 Note [Which rules to expose]
 915 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 916 findExternalRules filters imp_rules to avoid binders that
 917 aren't externally visible; but the externally-visible binders
 918 are computed (by findExternalIds) assuming that all orphan
 919 rules are externalised (see init_ext_ids in function
 920 'search'). So in fact we may export more than we need.
 921 (It's a sort of mutual recursion.)
 922
 923 %************************************************************************
 924 %*                                                                      *
 925 \subsection{Step 2: top-level tidying}
 926 %*                                                                      *
 927 %************************************************************************
 928
 929
 930 \begin{code}
 931 -- TopTidyEnv: when tidying we need to know
 932 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.
 933 --        These may have arisen because the
 934 --        renamer read in an interface file mentioning M.$wf, say,
 935 --        and assigned it unique r77.  If, on this compilation, we've
 936 --        invented an Id whose name is $wf (but with a different unique)
 937 --        we want to rename it to have unique r77, so that we can do easy
 938 --        comparisons with stuff from the interface file
 939 --
 940 --   * occ_env: The TidyOccEnv, which tells us which local occurrences
 941 --     are 'used'
 942 --
 943 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
 944
 945 tidyTopBinds :: HscEnv
 946              -> UnfoldEnv
 947              -> TidyOccEnv
 948              -> [CoreBind]
 949              -> (TidyEnv, [CoreBind])
 950
 951 tidyTopBinds hsc_env unfold_env init_occ_env binds
 952   = tidy init_env binds
 953   where
 954     init_env = (init_occ_env, emptyVarEnv)
 955
 956     this_pkg = thisPackage (hsc_dflags hsc_env)
 957
 958     tidy env []     = (env, [])
 959     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
 960                           (env2, bs') = tidy env1 bs
 961                       in
 962                           (env2, b':bs')
 963
 964 ------------------------
 965 tidyTopBind  :: PackageId
 966              -> UnfoldEnv
 967              -> TidyEnv
 968              -> CoreBind
 969              -> (TidyEnv, CoreBind)
 970
 971 tidyTopBind this_pkg unfold_env (occ_env,subst1) (NonRec bndr rhs)
 972   = (tidy_env2,  NonRec bndr' rhs')
 973   where
 974     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
 975     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
 976     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
 977     subst2        = extendVarEnv subst1 bndr bndr'
 978     tidy_env2     = (occ_env, subst2)
 979
 980 tidyTopBind this_pkg unfold_env (occ_env,subst1) (Rec prs)
 981   = (tidy_env2, Rec prs')
 982   where
 983     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
 984            | (id,rhs) <- prs,
 985              let (name',show_unfold) =
 986                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
 987            ]
 988
 989     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
 990     tidy_env2 = (occ_env, subst2)
 991
 992     bndrs = map fst prs
 993
 994         -- the CafInfo for a recursive group says whether *any* rhs in
 995         -- the group may refer indirectly to a CAF (because then, they all do).
 996     caf_info
 997         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
 998              | (bndr,rhs) <- prs ] = MayHaveCafRefs
 999         | otherwise                = NoCafRefs
1000
1001 -----------------------------------------------------------
1002 tidyTopPair :: Bool  -- show unfolding
1003             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
1004                         -- It is knot-tied: don't look at it!
1005             -> CafInfo
1006             -> Name             -- New name
1007             -> (Id, CoreExpr)   -- Binder and RHS before tidying
1008             -> (Id, CoreExpr)
1009         -- This function is the heart of Step 2
1010         -- The rec_tidy_env is the one to use for the IdInfo
1011         -- It's necessary because when we are dealing with a recursive
1012         -- group, a variable late in the group might be mentioned
1013         -- in the IdInfo of one early in the group
1014
1015 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
1016   = (bndr1, rhs1)
1017   where
1018     bndr1    = mkGlobalId details name' ty' idinfo'
1019     details  = idDetails bndr   -- Preserve the IdDetails
1020     ty'      = tidyTopType (idType bndr)
1021     rhs1     = tidyExpr rhs_tidy_env rhs
1022     idinfo'  = tidyTopIdInfo rhs_tidy_env name' rhs rhs1 (idInfo bndr)
1023                              show_unfold caf_info
1024
1025 -- tidyTopIdInfo creates the final IdInfo for top-level
1026 -- binders.  There are two delicate pieces:
1027 --
1028 --  * Arity.  After CoreTidy, this arity must not change any more.
1029 --      Indeed, CorePrep must eta expand where necessary to make
1030 --      the manifest arity equal to the claimed arity.
1031 --
1032 --  * CAF info.  This must also remain valid through to code generation.
1033 --      We add the info here so that it propagates to all
1034 --      occurrences of the binders in RHSs, and hence to occurrences in
1035 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
1036 --      CoreToStg makes use of this when constructing SRTs.
1037 tidyTopIdInfo :: TidyEnv -> Name -> CoreExpr -> CoreExpr
1038               -> IdInfo -> Bool -> CafInfo -> IdInfo
1039 tidyTopIdInfo rhs_tidy_env name orig_rhs tidy_rhs idinfo show_unfold caf_info
1040   | not is_external     -- For internal Ids (not externally visible)
1041   = vanillaIdInfo       -- we only need enough info for code generation
1042                         -- Arity and strictness info are enough;
1043                         --      c.f. CoreTidy.tidyLetBndr
1044         `setCafInfo`        caf_info
1045         `setArityInfo`      arity
1046         `setStrictnessInfo` final_sig
1047
1048   | otherwise           -- Externally-visible Ids get the whole lot
1049   = vanillaIdInfo
1050         `setCafInfo`           caf_info
1051         `setArityInfo`         arity
1052         `setStrictnessInfo`    final_sig
1053         `setOccInfo`           robust_occ_info
1054         `setInlinePragInfo`    (inlinePragInfo idinfo)
1055         `setUnfoldingInfo`     unfold_info
1056                 -- NB: we throw away the Rules
1057                 -- They have already been extracted by findExternalRules
1058   where
1059     is_external = isExternalName name
1060
1061     --------- OccInfo ------------
1062     robust_occ_info = zapFragileOcc (occInfo idinfo)
1063     -- It's important to keep loop-breaker information
1064     -- when we are doing -fexpose-all-unfoldings
1065
1066     --------- Strictness ------------
1067     final_sig | Just sig <- strictnessInfo idinfo
1068               = WARN( _bottom_hidden sig, ppr name ) Just sig
1069               | Just (_, sig) <- mb_bot_str = Just sig
1070               | otherwise                   = Nothing
1071
1072     -- If the cheap-and-cheerful bottom analyser can see that
1073     -- the RHS is bottom, it should jolly well be exposed
1074     _bottom_hidden id_sig = case mb_bot_str of
1075                                Nothing         -> False
1076                                Just (arity, _) -> not (appIsBottom id_sig arity)
1077
1078     mb_bot_str = exprBotStrictness_maybe orig_rhs
1079
1080     --------- Unfolding ------------
1081     unf_info = unfoldingInfo idinfo
1082     unfold_info | show_unfold = tidyUnfolding rhs_tidy_env unf_info unf_from_rhs
1083                 | otherwise   = noUnfolding
1084     unf_from_rhs = mkTopUnfolding is_bot tidy_rhs
1085     is_bot = case final_sig of
1086                 Just sig -> isBottomingSig sig
1087                 Nothing  -> False
1088     -- NB: do *not* expose the worker if show_unfold is off,
1089     --     because that means this thing is a loop breaker or
1090     --     marked NOINLINE or something like that
1091     -- This is important: if you expose the worker for a loop-breaker
1092     -- then you can make the simplifier go into an infinite loop, because
1093     -- in effect the unfolding is exposed.  See Trac #1709
1094     --
1095     -- You might think that if show_unfold is False, then the thing should
1096     -- not be w/w'd in the first place.  But a legitimate reason is this:
1097     --    the function returns bottom
1098     -- In this case, show_unfold will be false (we don't expose unfoldings
1099     -- for bottoming functions), but we might still have a worker/wrapper
1100     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
1101
1102     --------- Arity ------------
1103     -- Usually the Id will have an accurate arity on it, because
1104     -- the simplifier has just run, but not always.
1105     -- One case I found was when the last thing the simplifier
1106     -- did was to let-bind a non-atomic argument and then float
1107     -- it to the top level. So it seems more robust just to
1108     -- fix it here.
1109     arity = exprArity orig_rhs
1110 \end{code}
1111
1112 %************************************************************************
1113 %*                                                                      *
1114 \subsection{Figuring out CafInfo for an expression}
1115 %*                                                                      *
1116 %************************************************************************
1117
1118 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1119 We mark such things as `MayHaveCafRefs' because this information is
1120 used to decide whether a particular closure needs to be referenced
1121 in an SRT or not.
1122
1123 There are two reasons for setting MayHaveCafRefs:
1124         a) The RHS is a CAF: a top-level updatable thunk.
1125         b) The RHS refers to something that MayHaveCafRefs
1126
1127 Possible improvement: In an effort to keep the number of CAFs (and
1128 hence the size of the SRTs) down, we could also look at the expression and
1129 decide whether it requires a small bounded amount of heap, so we can ignore
1130 it as a CAF.  In these cases however, we would need to use an additional
1131 CAF list to keep track of non-collectable CAFs.
1132
1133 \begin{code}
1134 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1135 hasCafRefs this_pkg p arity expr
1136   | is_caf || mentions_cafs = MayHaveCafRefs
1137   | otherwise               = NoCafRefs
1138  where
1139   mentions_cafs = isFastTrue (cafRefs p expr)
1140   is_dynamic_name = isDllName this_pkg
1141   is_caf = not (arity > 0 || rhsIsStatic is_dynamic_name expr)
1142
1143   -- NB. we pass in the arity of the expression, which is expected
1144   -- to be calculated by exprArity.  This is because exprArity
1145   -- knows how much eta expansion is going to be done by
1146   -- CorePrep later on, and we don't want to duplicate that
1147   -- knowledge in rhsIsStatic below.
1148
1149 cafRefs :: VarEnv Id -> Expr a -> FastBool
1150 cafRefs p (Var id)
1151         -- imported Ids first:
1152   | not (isLocalId id) = fastBool (mayHaveCafRefs (idCafInfo id))
1153         -- now Ids local to this module:
1154   | otherwise =
1155      case lookupVarEnv p id of
1156         Just id' -> fastBool (mayHaveCafRefs (idCafInfo id'))
1157         Nothing  -> fastBool False
1158
1159 cafRefs _ (Lit _)              = fastBool False
1160 cafRefs p (App f a)            = fastOr (cafRefs p f) (cafRefs p) a
1161 cafRefs p (Lam _ e)            = cafRefs p e
1162 cafRefs p (Let b e)            = fastOr (cafRefss p (rhssOfBind b)) (cafRefs p) e
1163 cafRefs p (Case e _bndr _ alts) = fastOr (cafRefs p e) (cafRefss p) (rhssOfAlts alts)
1164 cafRefs p (Note _n e)          = cafRefs p e
1165 cafRefs p (Cast e _co)         = cafRefs p e
1166 cafRefs _ (Type _)             = fastBool False
1167 cafRefs _ (Coercion _)         = fastBool False
1168
1169 cafRefss :: VarEnv Id -> [Expr a] -> FastBool
1170 cafRefss _ []     = fastBool False
1171 cafRefss p (e:es) = fastOr (cafRefs p e) (cafRefss p) es
1172
1173 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1174 -- hack for lazy-or over FastBool.
1175 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1176 \end{code}