compiler/main/TidyPgm.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module TidyPgm( mkBootModDetailsDs, mkBootModDetailsTc,
   8                 tidyProgram, globaliseAndTidyId ) where
   9
  10 #include "HsVersions.h"
  11
  12 import TcRnTypes
  13 import FamInstEnv
  14 import DynFlags
  15 import CoreSyn
  16 import CoreUnfold
  17 import CoreFVs
  18 import CoreTidy
  19 import CoreMonad
  20 import CoreUtils
  21 import Rules
  22 import CoreArity        ( exprArity, exprBotStrictness_maybe )
  23 import Class            ( classAllSelIds )
  24 import VarEnv
  25 import VarSet
  26 import Var
  27 import Id
  28 import IdInfo
  29 import InstEnv
  30 import Demand
  31 import BasicTypes
  32 import Name hiding (varName)
  33 import NameSet
  34 import IfaceEnv
  35 import NameEnv
  36 import TcType
  37 import DataCon
  38 import TyCon
  39 import Module
  40 import Packages( isDllName )
  41 import HscTypes
  42 import Maybes
  43 import UniqSupply
  44 import Outputable
  45 import FastBool hiding ( fastOr )
  46 import Util
  47 import FastString
  48
  49 import Control.Monad    ( when )
  50 import Data.List        ( sortBy )
  51 import Data.IORef       ( IORef, readIORef, writeIORef )
  52 \end{code}
  53
  54
  55 Constructing the TypeEnv, Instances, Rules, VectInfo from which the
  56 ModIface is constructed, and which goes on to subsequent modules in
  57 --make mode.
  58
  59 Most of the interface file is obtained simply by serialising the
  60 TypeEnv.  One important consequence is that if the *interface file*
  61 has pragma info if and only if the final TypeEnv does. This is not so
  62 important for *this* module, but it's essential for ghc --make:
  63 subsequent compilations must not see (e.g.) the arity if the interface
  64 file does not contain arity If they do, they'll exploit the arity;
  65 then the arity might change, but the iface file doesn't change =>
  66 recompilation does not happen => disaster.
  67
  68 For data types, the final TypeEnv will have a TyThing for the TyCon,
  69 plus one for each DataCon; the interface file will contain just one
  70 data type declaration, but it is de-serialised back into a collection
  71 of TyThings.
  72
  73 %************************************************************************
  74 %*                                                                      *
  75                 Plan A: simpleTidyPgm
  76 %*                                                                      *
  77 %************************************************************************
  78
  79
  80 Plan A: mkBootModDetails: omit pragmas, make interfaces small
  81 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  82 * Ignore the bindings
  83
  84 * Drop all WiredIn things from the TypeEnv
  85         (we never want them in interface files)
  86
  87 * Retain all TyCons and Classes in the TypeEnv, to avoid
  88         having to find which ones are mentioned in the
  89         types of exported Ids
  90
  91 * Trim off the constructors of non-exported TyCons, both
  92         from the TyCon and from the TypeEnv
  93
  94 * Drop non-exported Ids from the TypeEnv
  95
  96 * Tidy the types of the DFunIds of Instances,
  97   make them into GlobalIds, (they already have External Names)
  98   and add them to the TypeEnv
  99
 100 * Tidy the types of the (exported) Ids in the TypeEnv,
 101   make them into GlobalIds (they already have External Names)
 102
 103 * Drop rules altogether
 104
 105 * Tidy the bindings, to ensure that the Caf and Arity
 106   information is correct for each top-level binder; the
 107   code generator needs it. And to ensure that local names have
 108   distinct OccNames in case of object-file splitting
 109
 110 \begin{code}
 111 -- This is Plan A: make a small type env when typechecking only,
 112 -- or when compiling a hs-boot file, or simply when not using -O
 113 --
 114 -- We don't look at the bindings at all -- there aren't any
 115 -- for hs-boot files
 116
 117 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
 118 mkBootModDetailsTc hsc_env
 119         TcGblEnv{ tcg_exports   = exports,
 120                   tcg_type_env  = type_env,
 121                   tcg_insts     = insts,
 122                   tcg_fam_insts = fam_insts
 123                 }
 124   = mkBootModDetails hsc_env exports type_env insts fam_insts
 125
 126 mkBootModDetailsDs :: HscEnv -> ModGuts -> IO ModDetails
 127 mkBootModDetailsDs hsc_env
 128         ModGuts{ mg_exports   = exports,
 129                  mg_types     = type_env,
 130                  mg_insts     = insts,
 131                  mg_fam_insts = fam_insts
 132                 }
 133   = mkBootModDetails hsc_env exports type_env insts fam_insts
 134
 135 mkBootModDetails :: HscEnv -> [AvailInfo] -> NameEnv TyThing
 136                  -> [Instance] -> [FamInstEnv.FamInst] -> IO ModDetails
 137 mkBootModDetails hsc_env exports type_env insts fam_insts
 138   = do  { let dflags = hsc_dflags hsc_env
 139         ; showPass dflags CoreTidy
 140
 141         ; let { insts'     = tidyInstances globaliseAndTidyId insts
 142               ; dfun_ids   = map instanceDFunId insts'
 143               ; type_env1  = tidyBootTypeEnv (availsToNameSet exports) type_env
 144               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
 145               }
 146         ; return (ModDetails { md_types     = type_env'
 147                              , md_insts     = insts'
 148                              , md_fam_insts = fam_insts
 149                              , md_rules     = []
 150                              , md_anns      = []
 151                              , md_exports   = exports
 152                              , md_vect_info = noVectInfo
 153                              })
 154         }
 155   where
 156
 157 tidyBootTypeEnv :: NameSet -> TypeEnv -> TypeEnv
 158 tidyBootTypeEnv exports type_env
 159   = tidyTypeEnv True False exports type_env final_ids
 160   where
 161         -- Find the LocalIds in the type env that are exported
 162         -- Make them into GlobalIds, and tidy their types
 163         --
 164         -- It's very important to remove the non-exported ones
 165         -- because we don't tidy the OccNames, and if we don't remove
 166         -- the non-exported ones we'll get many things with the
 167         -- same name in the interface file, giving chaos.
 168     final_ids = [ globaliseAndTidyId id
 169                 | id <- typeEnvIds type_env
 170                 , isLocalId id
 171                 , keep_it id ]
 172
 173         -- default methods have their export flag set, but everything
 174         -- else doesn't (yet), because this is pre-desugaring, so we
 175         -- must test both.
 176     keep_it id = isExportedId id || idName id `elemNameSet` exports
 177
 178
 179
 180 globaliseAndTidyId :: Id -> Id
 181 -- Takes an LocalId with an External Name,
 182 -- makes it into a GlobalId
 183 --     * unchanged Name (might be Internal or External)
 184 --     * unchanged details
 185 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
 186 globaliseAndTidyId id
 187   = Id.setIdType (globaliseId id) tidy_type
 188   where
 189     tidy_type = tidyTopType (idType id)
 190 \end{code}
 191
 192
 193 %************************************************************************
 194 %*                                                                      *
 195         Plan B: tidy bindings, make TypeEnv full of IdInfo
 196 %*                                                                      *
 197 %************************************************************************
 198
 199 Plan B: include pragmas, make interfaces
 200 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 201 * Figure out which Ids are externally visible
 202
 203 * Tidy the bindings, externalising appropriate Ids
 204
 205 * Drop all Ids from the TypeEnv, and add all the External Ids from
 206   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
 207   floated-out Ids that weren't even in the TypeEnv before.)
 208
 209 Step 1: Figure out external Ids
 210 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 211 Note [choosing external names]
 212
 213 See also the section "Interface stability" in the
 214 RecompilationAvoidance commentary:
 215   http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
 216
 217 First we figure out which Ids are "external" Ids.  An
 218 "external" Id is one that is visible from outside the compilation
 219 unit.  These are
 220         a) the user exported ones
 221         b) ones mentioned in the unfoldings, workers,
 222            or rules of externally-visible ones
 223
 224 While figuring out which Ids are external, we pick a "tidy" OccName
 225 for each one.  That is, we make its OccName distinct from the other
 226 external OccNames in this module, so that in interface files and
 227 object code we can refer to it unambiguously by its OccName.  The
 228 OccName for each binder is prefixed by the name of the exported Id
 229 that references it; e.g. if "f" references "x" in its unfolding, then
 230 "x" is renamed to "f_x".  This helps distinguish the different "x"s
 231 from each other, and means that if "f" is later removed, things that
 232 depend on the other "x"s will not need to be recompiled.  Of course,
 233 if there are multiple "f_x"s, then we have to disambiguate somehow; we
 234 use "f_x0", "f_x1" etc.
 235
 236 As far as possible we should assign names in a deterministic fashion.
 237 Each time this module is compiled with the same options, we should end
 238 up with the same set of external names with the same types.  That is,
 239 the ABI hash in the interface should not change.  This turns out to be
 240 quite tricky, since the order of the bindings going into the tidy
 241 phase is already non-deterministic, as it is based on the ordering of
 242 Uniques, which are assigned unpredictably.
 243
 244 To name things in a stable way, we do a depth-first-search of the
 245 bindings, starting from the exports sorted by name.  This way, as long
 246 as the bindings themselves are deterministic (they sometimes aren't!),
 247 the order in which they are presented to the tidying phase does not
 248 affect the names we assign.
 249
 250 Step 2: Tidy the program
 251 ~~~~~~~~~~~~~~~~~~~~~~~~
 252 Next we traverse the bindings top to bottom.  For each *top-level*
 253 binder
 254
 255  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal,
 256     reflecting the fact that from now on we regard it as a global,
 257     not local, Id
 258
 259  2. Give it a system-wide Unique.
 260     [Even non-exported things need system-wide Uniques because the
 261     byte-code generator builds a single Name->BCO symbol table.]
 262
 263     We use the NameCache kept in the HscEnv as the
 264     source of such system-wide uniques.
 265
 266     For external Ids, use the original-name cache in the NameCache
 267     to ensure that the unique assigned is the same as the Id had
 268     in any previous compilation run.
 269
 270  3. Rename top-level Ids according to the names we chose in step 1.
 271     If it's an external Id, make it have a External Name, otherwise
 272     make it have an Internal Name.  This is used by the code generator
 273     to decide whether to make the label externally visible
 274
 275  4. Give it its UTTERLY FINAL IdInfo; in ptic,
 276         * its unfolding, if it should have one
 277
 278         * its arity, computed from the number of visible lambdas
 279
 280         * its CAF info, computed from what is free in its RHS
 281
 282
 283 Finally, substitute these new top-level binders consistently
 284 throughout, including in unfoldings.  We also tidy binders in
 285 RHSs, so that they print nicely in interfaces.
 286
 287 \begin{code}
 288 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
 289 tidyProgram hsc_env  (ModGuts { mg_module = mod, mg_exports = exports,
 290                                 mg_types = type_env,
 291                                 mg_insts = insts, mg_fam_insts = fam_insts,
 292                                 mg_binds = binds,
 293                                 mg_rules = imp_rules,
 294                                 mg_vect_info = vect_info,
 295                                 mg_anns = anns,
 296                                 mg_deps = deps,
 297                                 mg_foreign = foreign_stubs,
 298                                 mg_hpc_info = hpc_info,
 299                                 mg_modBreaks = modBreaks })
 300
 301   = do  { let { dflags     = hsc_dflags hsc_env
 302               ; omit_prags = dopt Opt_OmitInterfacePragmas dflags
 303               ; expose_all = dopt Opt_ExposeAllUnfoldings  dflags
 304               ; th         = xopt Opt_TemplateHaskell      dflags
 305               }
 306         ; showPass dflags CoreTidy
 307
 308         ; let { implicit_binds = getImplicitBinds type_env }
 309
 310         ; (unfold_env, tidy_occ_env)
 311               <- chooseExternalIds hsc_env mod omit_prags expose_all
 312                                    binds implicit_binds imp_rules
 313
 314         ; let { ext_rules = findExternalRules omit_prags binds imp_rules unfold_env }
 315                 -- Glom together imp_rules and rules currently attached to binders
 316                 -- Then pick just the ones we need to expose
 317                 -- See Note [Which rules to expose]
 318
 319         ; let { (tidy_env, tidy_binds)
 320                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
 321
 322         ; let { export_set = availsToNameSet exports
 323               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds,
 324                                     isExternalName (idName id)]
 325               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
 326                                             type_env final_ids
 327               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
 328                 -- A DFunId will have a binding in tidy_binds, and so
 329                 -- will now be in final_env, replete with IdInfo
 330                 -- Its name will be unchanged since it was born, but
 331                 -- we want Global, IdInfo-rich (or not) DFunId in the
 332                 -- tidy_insts
 333
 334               ; tidy_rules = tidyRules tidy_env ext_rules
 335                 -- You might worry that the tidy_env contains IdInfo-rich stuff
 336                 -- and indeed it does, but if omit_prags is on, ext_rules is
 337                 -- empty
 338
 339               ; tidy_vect_info = tidyVectInfo tidy_env vect_info
 340
 341               -- See Note [Injecting implicit bindings]
 342               ; all_tidy_binds = implicit_binds ++ tidy_binds
 343
 344               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
 345               }
 346
 347         ; endPass dflags CoreTidy all_tidy_binds tidy_rules
 348
 349           -- If the endPass didn't print the rules, but ddump-rules is on, print now
 350         ; dumpIfSet (dopt Opt_D_dump_rules dflags
 351                      && (not (dopt Opt_D_dump_simpl dflags)))
 352                     CoreTidy
 353                     (ptext (sLit "rules"))
 354                     (pprRulesForUser tidy_rules)
 355
 356           -- Print one-line size info
 357         ; let cs = coreBindsStats tidy_binds
 358         ; when (dopt Opt_D_dump_core_stats dflags)
 359                (printDump (ptext (sLit "Tidy size (terms,types,coercions)")
 360                            <+> ppr (moduleName mod) <> colon
 361                            <+> int (cs_tm cs)
 362                            <+> int (cs_ty cs)
 363                            <+> int (cs_co cs) ))
 364
 365         ; return (CgGuts { cg_module   = mod,
 366                            cg_tycons   = alg_tycons,
 367                            cg_binds    = all_tidy_binds,
 368                            cg_foreign  = foreign_stubs,
 369                            cg_dep_pkgs = dep_pkgs deps,
 370                            cg_hpc_info = hpc_info,
 371                            cg_modBreaks = modBreaks },
 372
 373                    ModDetails { md_types     = tidy_type_env,
 374                                 md_rules     = tidy_rules,
 375                                 md_insts     = tidy_insts,
 376                                 md_vect_info = tidy_vect_info,
 377                                 md_fam_insts = fam_insts,
 378                                 md_exports   = exports,
 379                                 md_anns      = anns      -- are already tidy
 380                               })
 381         }
 382
 383 lookup_dfun :: TypeEnv -> Var -> Id
 384 lookup_dfun type_env dfun_id
 385   = case lookupTypeEnv type_env (idName dfun_id) of
 386         Just (AnId dfun_id') -> dfun_id'
 387         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
 388
 389 --------------------------
 390 tidyTypeEnv :: Bool     -- Compiling without -O, so omit prags
 391             -> Bool     -- Template Haskell is on
 392             -> NameSet -> TypeEnv -> [Id] -> TypeEnv
 393
 394 -- The competed type environment is gotten from
 395 --      Dropping any wired-in things, and then
 396 --      a) keeping the types and classes
 397 --      b) removing all Ids,
 398 --      c) adding Ids with correct IdInfo, including unfoldings,
 399 --              gotten from the bindings
 400 -- From (c) we keep only those Ids with External names;
 401 --          the CoreTidy pass makes sure these are all and only
 402 --          the externally-accessible ones
 403 -- This truncates the type environment to include only the
 404 -- exported Ids and things needed from them, which saves space
 405
 406 tidyTypeEnv omit_prags th exports type_env final_ids
 407  = let  type_env1 = filterNameEnv keep_it type_env
 408         type_env2 = extendTypeEnvWithIds type_env1 final_ids
 409         type_env3 | omit_prags = mapNameEnv (trimThing th exports) type_env2
 410                   | otherwise  = type_env2
 411     in
 412     type_env3
 413   where
 414         -- We keep GlobalIds, because they won't appear
 415         -- in the bindings from which final_ids are derived!
 416         -- (The bindings bind LocalIds.)
 417     keep_it thing | isWiredInThing thing = False
 418     keep_it (AnId id) = isGlobalId id   -- Keep GlobalIds (e.g. class ops)
 419     keep_it _other    = True            -- Keep all TyCons, DataCons, and Classes
 420
 421 --------------------------
 422 isWiredInThing :: TyThing -> Bool
 423 isWiredInThing thing = isWiredInName (getName thing)
 424
 425 --------------------------
 426 trimThing :: Bool -> NameSet -> TyThing -> TyThing
 427 -- Trim off inessentials, for boot files and no -O
 428 trimThing th exports (ATyCon tc)
 429    | not th && not (mustExposeTyCon exports tc)
 430    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
 431
 432 trimThing _th _exports (AnId id)
 433    | not (isImplicitId id)
 434    = AnId (id `setIdInfo` vanillaIdInfo)
 435
 436 trimThing _th _exports other_thing
 437   = other_thing
 438
 439
 440 {- Note [Trimming and Template Haskell]
 441    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 442 Consider (Trac #2386) this
 443         module M(T, makeOne) where
 444           data T = Yay String
 445           makeOne = [| Yay "Yep" |]
 446 Notice that T is exported abstractly, but makeOne effectively exports it too!
 447 A module that splices in $(makeOne) will then look for a declartion of Yay,
 448 so it'd better be there.  Hence, brutally but simply, we switch off type
 449 constructor trimming if TH is enabled in this module. -}
 450
 451
 452 mustExposeTyCon :: NameSet      -- Exports
 453                 -> TyCon        -- The tycon
 454                 -> Bool         -- Can its rep be hidden?
 455 -- We are compiling without -O, and thus trying to write as little as
 456 -- possible into the interface file.  But we must expose the details of
 457 -- any data types whose constructors or fields are exported
 458 mustExposeTyCon exports tc
 459   | not (isAlgTyCon tc)         -- Synonyms
 460   = True
 461   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
 462   = True                        -- won't lead to the need for further exposure
 463                                 -- (This includes data types with no constructors.)
 464   | isFamilyTyCon tc            -- Open type family
 465   = True
 466
 467   | otherwise                   -- Newtype, datatype
 468   = any exported_con (tyConDataCons tc)
 469         -- Expose rep if any datacon or field is exported
 470
 471   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
 472         -- Expose the rep for newtypes if the rep is an FFI type.
 473         -- For a very annoying reason.  'Foreign import' is meant to
 474         -- be able to look through newtypes transparently, but it
 475         -- can only do that if it can "see" the newtype representation
 476   where
 477     exported_con con = any (`elemNameSet` exports)
 478                            (dataConName con : dataConFieldLabels con)
 479
 480 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
 481 tidyInstances tidy_dfun ispecs
 482   = map tidy ispecs
 483   where
 484     tidy ispec = setInstanceDFunId ispec $
 485                  tidy_dfun (instanceDFunId ispec)
 486 \end{code}
 487
 488 \begin{code}
 489 tidyVectInfo :: TidyEnv -> VectInfo -> VectInfo
 490 tidyVectInfo (_, var_env) info@(VectInfo { vectInfoVar     = vars
 491                                          , vectInfoPADFun  = pas
 492                                          , vectInfoIso     = isos })
 493   = info { vectInfoVar    = tidy_vars
 494          , vectInfoPADFun = tidy_pas
 495          , vectInfoIso    = tidy_isos }
 496   where
 497     tidy_vars = mkVarEnv
 498               $ map tidy_var_mapping
 499               $ varEnvElts vars
 500
 501     tidy_pas = mapNameEnv tidy_snd_var pas
 502     tidy_isos = mapNameEnv tidy_snd_var isos
 503
 504     tidy_var_mapping (from, to) = (from', (from', lookup_var to))
 505       where from' = lookup_var from
 506     tidy_snd_var (x, var) = (x, lookup_var var)
 507
 508     lookup_var var = lookupWithDefaultVarEnv var_env var var
 509 \end{code}
 510
 511
 512 %************************************************************************
 513 %*                                                                      *
 514         Implicit bindings
 515 %*                                                                      *
 516 %************************************************************************
 517
 518 Note [Injecting implicit bindings]
 519 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 520 We inject the implict bindings right at the end, in CoreTidy.
 521 Some of these bindings, notably record selectors, are not
 522 constructed in an optimised form.  E.g. record selector for
 523         data T = MkT { x :: {-# UNPACK #-} !Int }
 524 Then the unfolding looks like
 525         x = \t. case t of MkT x1 -> let x = I# x1 in x
 526 This generates bad code unless it's first simplified a bit.  That is
 527 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
 528 optimisation first.  (Only matters when the selector is used curried;
 529 eg map x ys.)  See Trac #2070.
 530
 531 [Oct 09: in fact, record selectors are no longer implicit Ids at all,
 532 because we really do want to optimise them properly. They are treated
 533 much like any other Id.  But doing "light" optimisation on an implicit
 534 Id still makes sense.]
 535
 536 At one time I tried injecting the implicit bindings *early*, at the
 537 beginning of SimplCore.  But that gave rise to real difficulty,
 538 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
 539 simplifier and other core-to-core passes mess with IdInfo all the
 540 time.  The straw that broke the camels back was when a class selector
 541 got the wrong arity -- ie the simplifier gave it arity 2, whereas
 542 importing modules were expecting it to have arity 1 (Trac #2844).
 543 It's much safer just to inject them right at the end, after tidying.
 544
 545 Oh: two other reasons for injecting them late:
 546
 547   - If implicit Ids are already in the bindings when we start TidyPgm,
 548     we'd have to be careful not to treat them as external Ids (in
 549     the sense of findExternalIds); else the Ids mentioned in *their*
 550     RHSs will be treated as external and you get an interface file
 551     saying      a18 = <blah>
 552     but nothing refererring to a18 (because the implicit Id is the
 553     one that does, and implicit Ids don't appear in interface files).
 554
 555   - More seriously, the tidied type-envt will include the implicit
 556     Id replete with a18 in its unfolding; but we won't take account
 557     of a18 when computing a fingerprint for the class; result chaos.
 558
 559 There is one sort of implicit binding that is injected still later,
 560 namely those for data constructor workers. Reason (I think): it's
 561 really just a code generation trick.... binding itself makes no sense.
 562 See CorePrep Note [Data constructor workers].
 563
 564 \begin{code}
 565 getImplicitBinds :: TypeEnv -> [CoreBind]
 566 getImplicitBinds type_env
 567   = map get_defn (concatMap implicit_ids (typeEnvElts type_env))
 568   where
 569     implicit_ids (ATyCon tc)  = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
 570     implicit_ids (AClass cls) = classAllSelIds cls
 571     implicit_ids _            = []
 572
 573     get_defn :: Id -> CoreBind
 574     get_defn id = NonRec id (unfoldingTemplate (realIdUnfolding id))
 575 \end{code}
 576
 577
 578 %************************************************************************
 579 %*                                                                      *
 580 \subsection{Step 1: finding externals}
 581 %*                                                                      *
 582 %************************************************************************
 583
 584 Sete Note [choosing external names].
 585
 586 \begin{code}
 587 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
 588   -- Maps each top-level Id to its new Name (the Id is tidied in step 2)
 589   -- The Unique is unchanged.  If the new Name is external, it will be
 590   -- visible in the interface file.
 591   --
 592   -- Bool => expose unfolding or not.
 593
 594 chooseExternalIds :: HscEnv
 595                   -> Module
 596                   -> Bool -> Bool
 597                   -> [CoreBind]
 598                   -> [CoreBind]
 599                   -> [CoreRule]
 600                   -> IO (UnfoldEnv, TidyOccEnv)
 601         -- Step 1 from the notes above
 602
 603 chooseExternalIds hsc_env mod omit_prags expose_all binds implicit_binds imp_id_rules
 604   = do { (unfold_env1,occ_env1) <- search init_work_list emptyVarEnv init_occ_env
 605        ; let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
 606        ; tidy_internal internal_ids unfold_env1 occ_env1 }
 607  where
 608   nc_var = hsc_NC hsc_env
 609
 610   -- init_ext_ids is the intial list of Ids that should be
 611   -- externalised.  It serves as the starting point for finding a
 612   -- deterministic, tidy, renaming for all external Ids in this
 613   -- module.
 614   --
 615   -- It is sorted, so that it has adeterministic order (i.e. it's the
 616   -- same list every time this module is compiled), in contrast to the
 617   -- bindings, which are ordered non-deterministically.
 618   init_work_list = zip init_ext_ids init_ext_ids
 619   init_ext_ids   = sortBy (compare `on` getOccName) $
 620                    filter is_external binders
 621
 622   -- An Id should be external if either (a) it is exported or
 623   -- (b) it appears in the RHS of a local rule for an imported Id.
 624   -- See Note [Which rules to expose]
 625   is_external id = isExportedId id || id `elemVarSet` rule_rhs_vars
 626   rule_rhs_vars = foldr (unionVarSet . ruleRhsFreeVars) emptyVarSet imp_id_rules
 627
 628   binders          = bindersOfBinds binds
 629   implicit_binders = bindersOfBinds implicit_binds
 630   binder_set       = mkVarSet binders
 631
 632   avoids   = [getOccName name | bndr <- binders ++ implicit_binders,
 633                                 let name = idName bndr,
 634                                 isExternalName name ]
 635                 -- In computing our "avoids" list, we must include
 636                 --      all implicit Ids
 637                 --      all things with global names (assigned once and for
 638                 --                                      all by the renamer)
 639                 -- since their names are "taken".
 640                 -- The type environment is a convenient source of such things.
 641                 -- In particular, the set of binders doesn't include
 642                 -- implicit Ids at this stage.
 643
 644         -- We also make sure to avoid any exported binders.  Consider
 645         --      f{-u1-} = 1     -- Local decl
 646         --      ...
 647         --      f{-u2-} = 2     -- Exported decl
 648         --
 649         -- The second exported decl must 'get' the name 'f', so we
 650         -- have to put 'f' in the avoids list before we get to the first
 651         -- decl.  tidyTopId then does a no-op on exported binders.
 652   init_occ_env = initTidyOccEnv avoids
 653
 654
 655   search :: [(Id,Id)]    -- The work-list: (external id, referrring id)
 656                          -- Make a tidy, external Name for the external id,
 657                          --   add it to the UnfoldEnv, and do the same for the
 658                          --   transitive closure of Ids it refers to
 659                          -- The referring id is used to generate a tidy
 660                          ---  name for the external id
 661          -> UnfoldEnv    -- id -> (new Name, show_unfold)
 662          -> TidyOccEnv   -- occ env for choosing new Names
 663          -> IO (UnfoldEnv, TidyOccEnv)
 664
 665   search [] unfold_env occ_env = return (unfold_env, occ_env)
 666
 667   search ((idocc,referrer) : rest) unfold_env occ_env
 668     | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
 669     | otherwise = do
 670       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
 671       let
 672           (new_ids, show_unfold)
 673                 | omit_prags = ([], False)
 674                 | otherwise  = addExternal expose_all refined_id
 675
 676                 -- 'idocc' is an *occurrence*, but we need to see the
 677                 -- unfolding in the *definition*; so look up in binder_set
 678           refined_id = case lookupVarSet binder_set idocc of
 679                          Just id -> id
 680                          Nothing -> WARN( True, ppr idocc ) idocc
 681
 682           unfold_env' = extendVarEnv unfold_env idocc (name',show_unfold)
 683           referrer' | isExportedId refined_id = refined_id
 684                     | otherwise               = referrer
 685       --
 686       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
 687
 688   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
 689                 -> IO (UnfoldEnv, TidyOccEnv)
 690   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
 691   tidy_internal (id:ids) unfold_env occ_env = do
 692       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
 693       let unfold_env' = extendVarEnv unfold_env id (name',False)
 694       tidy_internal ids unfold_env' occ_env'
 695
 696 addExternal :: Bool -> Id -> ([Id],Bool)
 697 addExternal expose_all id = (new_needed_ids, show_unfold)
 698   where
 699     new_needed_ids = unfold_ids ++
 700                      filter (\id -> isLocalId id &&
 701                                     not (id `elemVarSet` unfold_set))
 702                        (varSetElems spec_ids) -- XXX non-det ordering
 703
 704     idinfo         = idInfo id
 705     never_active   = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
 706     loop_breaker   = isNonRuleLoopBreaker (occInfo idinfo)
 707     bottoming_fn   = isBottomingSig (strictnessInfo idinfo `orElse` topSig)
 708     spec_ids       = specInfoFreeVars (specInfo idinfo)
 709
 710         -- Stuff to do with the Id's unfolding
 711         -- We leave the unfolding there even if there is a worker
 712         -- In GHCI the unfolding is used by importers
 713     show_unfold = isJust mb_unfold_ids
 714     (unfold_set, unfold_ids) = mb_unfold_ids `orElse` (emptyVarSet, [])
 715
 716     mb_unfold_ids :: Maybe (IdSet, [Id])        -- Nothing => don't unfold
 717     mb_unfold_ids = case unfoldingInfo idinfo of
 718                       CoreUnfolding { uf_tmpl = unf_rhs, uf_src = src, uf_guidance = guide }
 719                                             | show_unfolding src guide
 720                                             -> Just (unf_ext_ids src unf_rhs)
 721                       DFunUnfolding _ _ ops -> Just (exprsFvsInOrder (dfunArgExprs ops))
 722                       _                     -> Nothing
 723                   where
 724                     unf_ext_ids (InlineWrapper v) _ = (unitVarSet v, [v])
 725                     unf_ext_ids _           unf_rhs = exprFvsInOrder unf_rhs
 726                     -- For a wrapper, externalise the wrapper id rather than the
 727                     -- fvs of the rhs.  The two usually come down to the same thing
 728                     -- but I've seen cases where we had a wrapper id $w but a
 729                     -- rhs where $w had been inlined; see Trac #3922
 730
 731     show_unfolding unf_source unf_guidance
 732        =  expose_all         -- 'expose_all' says to expose all
 733                              -- unfoldings willy-nilly
 734
 735        || isStableSource unf_source          -- Always expose things whose
 736                                              -- source is an inline rule
 737
 738        || not (bottoming_fn      -- No need to inline bottom functions
 739            || never_active       -- Or ones that say not to
 740            || loop_breaker       -- Or that are loop breakers
 741            || neverUnfoldGuidance unf_guidance)
 742
 743 -- We want a deterministic free-variable list.  exprFreeVars gives us
 744 -- a VarSet, which is in a non-deterministic order when converted to a
 745 -- list.  Hence, here we define a free-variable finder that returns
 746 -- the free variables in the order that they are encountered.
 747 --
 748 -- Note [choosing external names]
 749
 750 exprFvsInOrder :: CoreExpr -> (VarSet, [Id])
 751 exprFvsInOrder e = run (dffvExpr e)
 752
 753 exprsFvsInOrder :: [CoreExpr] -> (VarSet, [Id])
 754 exprsFvsInOrder es = run (mapM_ dffvExpr es)
 755
 756 run :: DFFV () -> (VarSet, [Id])
 757 run (DFFV m) = case m emptyVarSet [] of
 758                  (set,ids,_) -> (set,ids)
 759
 760 newtype DFFV a = DFFV (VarSet -> [Var] -> (VarSet,[Var],a))
 761
 762 instance Monad DFFV where
 763   return a = DFFV $ \set ids -> (set, ids, a)
 764   (DFFV m) >>= k = DFFV $ \set ids ->
 765     case m set ids of
 766        (set',ids',a) -> case k a of
 767                           DFFV f -> f set' ids'
 768
 769 insert :: Var -> DFFV ()
 770 insert v = DFFV $ \ set ids  -> case () of
 771  _ | v `elemVarSet` set -> (set,ids,())
 772    | otherwise          -> (extendVarSet set v, v:ids, ())
 773
 774 dffvExpr :: CoreExpr -> DFFV ()
 775 dffvExpr e = go emptyVarSet e
 776   where
 777     go scope e = case e of
 778       Var v | isLocalId v && not (v `elemVarSet` scope) -> insert v
 779       App e1 e2          -> do go scope e1; go scope e2
 780       Lam v e            -> go (extendVarSet scope v) e
 781       Note _ e           -> go scope e
 782       Cast e _           -> go scope e
 783       Let (NonRec x r) e -> do go scope r; go (extendVarSet scope x) e
 784       Let (Rec prs) e    -> do let scope' = extendVarSetList scope (map fst prs)
 785                                mapM_ (go scope') (map snd prs)
 786                                go scope' e
 787       Case e b _ as      -> do go scope e
 788                                mapM_ (go_alt (extendVarSet scope b)) as
 789       _other             -> return ()
 790
 791     go_alt scope (_,xs,r) = go (extendVarSetList scope xs) r
 792 \end{code}
 793
 794
 795 --------------------------------------------------------------------
 796 --              tidyTopName
 797 -- This is where we set names to local/global based on whether they really are
 798 -- externally visible (see comment at the top of this module).  If the name
 799 -- was previously local, we have to give it a unique occurrence name if
 800 -- we intend to externalise it.
 801
 802 \begin{code}
 803 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
 804             -> Id -> IO (TidyOccEnv, Name)
 805 tidyTopName mod nc_var maybe_ref occ_env id
 806   | global && internal = return (occ_env, localiseName name)
 807
 808   | global && external = return (occ_env, name)
 809         -- Global names are assumed to have been allocated by the renamer,
 810         -- so they already have the "right" unique
 811         -- And it's a system-wide unique too
 812
 813   -- Now we get to the real reason that all this is in the IO Monad:
 814   -- we have to update the name cache in a nice atomic fashion
 815
 816   | local  && internal = do { nc <- readIORef nc_var
 817                             ; let (nc', new_local_name) = mk_new_local nc
 818                             ; writeIORef nc_var nc'
 819                             ; return (occ_env', new_local_name) }
 820         -- Even local, internal names must get a unique occurrence, because
 821         -- if we do -split-objs we externalise the name later, in the code generator
 822         --
 823         -- Similarly, we must make sure it has a system-wide Unique, because
 824         -- the byte-code generator builds a system-wide Name->BCO symbol table
 825
 826   | local  && external = do { nc <- readIORef nc_var
 827                             ; let (nc', new_external_name) = mk_new_external nc
 828                             ; writeIORef nc_var nc'
 829                             ; return (occ_env', new_external_name) }
 830
 831   | otherwise = panic "tidyTopName"
 832   where
 833     name        = idName id
 834     external    = isJust maybe_ref
 835     global      = isExternalName name
 836     local       = not global
 837     internal    = not external
 838     loc         = nameSrcSpan name
 839
 840     old_occ     = nameOccName name
 841     new_occ
 842       | Just ref <- maybe_ref, ref /= id =
 843           mkOccName (occNameSpace old_occ) $
 844              let
 845                  ref_str = occNameString (getOccName ref)
 846                  occ_str = occNameString old_occ
 847              in
 848              case occ_str of
 849                '$':'w':_ -> occ_str
 850                   -- workers: the worker for a function already
 851                   -- includes the occname for its parent, so there's
 852                   -- no need to prepend the referrer.
 853                _other | isSystemName name -> ref_str
 854                       | otherwise         -> ref_str ++ '_' : occ_str
 855                   -- If this name was system-generated, then don't bother
 856                   -- to retain its OccName, just use the referrer.  These
 857                   -- system-generated names will become "f1", "f2", etc. for
 858                   -- a referrer "f".
 859       | otherwise = old_occ
 860
 861     (occ_env', occ') = tidyOccName occ_env new_occ
 862
 863     mk_new_local nc = (nc { nsUniqs = us }, mkInternalName uniq occ' loc)
 864                     where
 865                       (uniq, us) = takeUniqFromSupply (nsUniqs nc)
 866
 867     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
 868         -- If we want to externalise a currently-local name, check
 869         -- whether we have already assigned a unique for it.
 870         -- If so, use it; if not, extend the table.
 871         -- All this is done by allcoateGlobalBinder.
 872         -- This is needed when *re*-compiling a module in GHCi; we must
 873         -- use the same name for externally-visible things as we did before.
 874 \end{code}
 875
 876 \begin{code}
 877 findExternalRules :: Bool       -- Omit pragmas
 878                   -> [CoreBind]
 879                   -> [CoreRule] -- Local rules for imported fns
 880                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
 881                   -> [CoreRule]
 882   -- The complete rules are gotten by combining
 883   --    a) local rules for imported Ids
 884   --    b) rules embedded in the top-level Ids
 885 findExternalRules omit_prags binds imp_id_rules unfold_env
 886   | omit_prags = []
 887   | otherwise  = filterOut internal_rule (imp_id_rules ++ local_rules)
 888   where
 889     local_rules  = [ rule
 890                    | id <- bindersOfBinds binds,
 891                      external_id id,
 892                      rule <- idCoreRules id
 893                    ]
 894
 895     internal_rule rule
 896         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
 897                 -- Don't export a rule whose LHS mentions a locally-defined
 898                 --  Id that is completely internal (i.e. not visible to an
 899                 -- importing module)
 900
 901     external_id id
 902       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
 903       | otherwise = False
 904 \end{code}
 905
 906 Note [Which rules to expose]
 907 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 908 findExternalRules filters imp_rules to avoid binders that
 909 aren't externally visible; but the externally-visible binders
 910 are computed (by findExternalIds) assuming that all orphan
 911 rules are externalised (see init_ext_ids in function
 912 'search'). So in fact we may export more than we need.
 913 (It's a sort of mutual recursion.)
 914
 915 %************************************************************************
 916 %*                                                                      *
 917 \subsection{Step 2: top-level tidying}
 918 %*                                                                      *
 919 %************************************************************************
 920
 921
 922 \begin{code}
 923 -- TopTidyEnv: when tidying we need to know
 924 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.
 925 --        These may have arisen because the
 926 --        renamer read in an interface file mentioning M.$wf, say,
 927 --        and assigned it unique r77.  If, on this compilation, we've
 928 --        invented an Id whose name is $wf (but with a different unique)
 929 --        we want to rename it to have unique r77, so that we can do easy
 930 --        comparisons with stuff from the interface file
 931 --
 932 --   * occ_env: The TidyOccEnv, which tells us which local occurrences
 933 --     are 'used'
 934 --
 935 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
 936
 937 tidyTopBinds :: HscEnv
 938              -> UnfoldEnv
 939              -> TidyOccEnv
 940              -> [CoreBind]
 941              -> (TidyEnv, [CoreBind])
 942
 943 tidyTopBinds hsc_env unfold_env init_occ_env binds
 944   = tidy init_env binds
 945   where
 946     init_env = (init_occ_env, emptyVarEnv)
 947
 948     this_pkg = thisPackage (hsc_dflags hsc_env)
 949
 950     tidy env []     = (env, [])
 951     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
 952                           (env2, bs') = tidy env1 bs
 953                       in
 954                           (env2, b':bs')
 955
 956 ------------------------
 957 tidyTopBind  :: PackageId
 958              -> UnfoldEnv
 959              -> TidyEnv
 960              -> CoreBind
 961              -> (TidyEnv, CoreBind)
 962
 963 tidyTopBind this_pkg unfold_env (occ_env,subst1) (NonRec bndr rhs)
 964   = (tidy_env2,  NonRec bndr' rhs')
 965   where
 966     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
 967     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
 968     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
 969     subst2        = extendVarEnv subst1 bndr bndr'
 970     tidy_env2     = (occ_env, subst2)
 971
 972 tidyTopBind this_pkg unfold_env (occ_env,subst1) (Rec prs)
 973   = (tidy_env2, Rec prs')
 974   where
 975     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
 976            | (id,rhs) <- prs,
 977              let (name',show_unfold) =
 978                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
 979            ]
 980
 981     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
 982     tidy_env2 = (occ_env, subst2)
 983
 984     bndrs = map fst prs
 985
 986         -- the CafInfo for a recursive group says whether *any* rhs in
 987         -- the group may refer indirectly to a CAF (because then, they all do).
 988     caf_info
 989         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
 990              | (bndr,rhs) <- prs ] = MayHaveCafRefs
 991         | otherwise                = NoCafRefs
 992
 993 -----------------------------------------------------------
 994 tidyTopPair :: Bool  -- show unfolding
 995             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
 996                         -- It is knot-tied: don't look at it!
 997             -> CafInfo
 998             -> Name             -- New name
 999             -> (Id, CoreExpr)   -- Binder and RHS before tidying
1000             -> (Id, CoreExpr)
1001         -- This function is the heart of Step 2
1002         -- The rec_tidy_env is the one to use for the IdInfo
1003         -- It's necessary because when we are dealing with a recursive
1004         -- group, a variable late in the group might be mentioned
1005         -- in the IdInfo of one early in the group
1006
1007 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
1008   = (bndr1, rhs1)
1009   where
1010     bndr1    = mkGlobalId details name' ty' idinfo'
1011     details  = idDetails bndr   -- Preserve the IdDetails
1012     ty'      = tidyTopType (idType bndr)
1013     rhs1     = tidyExpr rhs_tidy_env rhs
1014     idinfo'  = tidyTopIdInfo rhs_tidy_env name' rhs rhs1 (idInfo bndr)
1015                              show_unfold caf_info
1016
1017 -- tidyTopIdInfo creates the final IdInfo for top-level
1018 -- binders.  There are two delicate pieces:
1019 --
1020 --  * Arity.  After CoreTidy, this arity must not change any more.
1021 --      Indeed, CorePrep must eta expand where necessary to make
1022 --      the manifest arity equal to the claimed arity.
1023 --
1024 --  * CAF info.  This must also remain valid through to code generation.
1025 --      We add the info here so that it propagates to all
1026 --      occurrences of the binders in RHSs, and hence to occurrences in
1027 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
1028 --      CoreToStg makes use of this when constructing SRTs.
1029 tidyTopIdInfo :: TidyEnv -> Name -> CoreExpr -> CoreExpr
1030               -> IdInfo -> Bool -> CafInfo -> IdInfo
1031 tidyTopIdInfo rhs_tidy_env name orig_rhs tidy_rhs idinfo show_unfold caf_info
1032   | not is_external     -- For internal Ids (not externally visible)
1033   = vanillaIdInfo       -- we only need enough info for code generation
1034                         -- Arity and strictness info are enough;
1035                         --      c.f. CoreTidy.tidyLetBndr
1036         `setCafInfo`        caf_info
1037         `setArityInfo`      arity
1038         `setStrictnessInfo` final_sig
1039
1040   | otherwise           -- Externally-visible Ids get the whole lot
1041   = vanillaIdInfo
1042         `setCafInfo`           caf_info
1043         `setArityInfo`         arity
1044         `setStrictnessInfo`    final_sig
1045         `setOccInfo`           robust_occ_info
1046         `setInlinePragInfo`    (inlinePragInfo idinfo)
1047         `setUnfoldingInfo`     unfold_info
1048                 -- NB: we throw away the Rules
1049                 -- They have already been extracted by findExternalRules
1050   where
1051     is_external = isExternalName name
1052
1053     --------- OccInfo ------------
1054     robust_occ_info = zapFragileOcc (occInfo idinfo)
1055     -- It's important to keep loop-breaker information
1056     -- when we are doing -fexpose-all-unfoldings
1057
1058     --------- Strictness ------------
1059     final_sig | Just sig <- strictnessInfo idinfo
1060               = WARN( _bottom_hidden sig, ppr name ) Just sig
1061               | Just (_, sig) <- mb_bot_str = Just sig
1062               | otherwise                   = Nothing
1063
1064     -- If the cheap-and-cheerful bottom analyser can see that
1065     -- the RHS is bottom, it should jolly well be exposed
1066     _bottom_hidden id_sig = case mb_bot_str of
1067                                Nothing         -> False
1068                                Just (arity, _) -> not (appIsBottom id_sig arity)
1069
1070     mb_bot_str = exprBotStrictness_maybe orig_rhs
1071
1072     --------- Unfolding ------------
1073     unf_info = unfoldingInfo idinfo
1074     unfold_info | show_unfold = tidyUnfolding rhs_tidy_env unf_info unf_from_rhs
1075                 | otherwise   = noUnfolding
1076     unf_from_rhs = mkTopUnfolding is_bot tidy_rhs
1077     is_bot = case final_sig of
1078                 Just sig -> isBottomingSig sig
1079                 Nothing  -> False
1080     -- NB: do *not* expose the worker if show_unfold is off,
1081     --     because that means this thing is a loop breaker or
1082     --     marked NOINLINE or something like that
1083     -- This is important: if you expose the worker for a loop-breaker
1084     -- then you can make the simplifier go into an infinite loop, because
1085     -- in effect the unfolding is exposed.  See Trac #1709
1086     --
1087     -- You might think that if show_unfold is False, then the thing should
1088     -- not be w/w'd in the first place.  But a legitimate reason is this:
1089     --    the function returns bottom
1090     -- In this case, show_unfold will be false (we don't expose unfoldings
1091     -- for bottoming functions), but we might still have a worker/wrapper
1092     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
1093
1094     --------- Arity ------------
1095     -- Usually the Id will have an accurate arity on it, because
1096     -- the simplifier has just run, but not always.
1097     -- One case I found was when the last thing the simplifier
1098     -- did was to let-bind a non-atomic argument and then float
1099     -- it to the top level. So it seems more robust just to
1100     -- fix it here.
1101     arity = exprArity orig_rhs
1102 \end{code}
1103
1104 %************************************************************************
1105 %*                                                                      *
1106 \subsection{Figuring out CafInfo for an expression}
1107 %*                                                                      *
1108 %************************************************************************
1109
1110 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1111 We mark such things as `MayHaveCafRefs' because this information is
1112 used to decide whether a particular closure needs to be referenced
1113 in an SRT or not.
1114
1115 There are two reasons for setting MayHaveCafRefs:
1116         a) The RHS is a CAF: a top-level updatable thunk.
1117         b) The RHS refers to something that MayHaveCafRefs
1118
1119 Possible improvement: In an effort to keep the number of CAFs (and
1120 hence the size of the SRTs) down, we could also look at the expression and
1121 decide whether it requires a small bounded amount of heap, so we can ignore
1122 it as a CAF.  In these cases however, we would need to use an additional
1123 CAF list to keep track of non-collectable CAFs.
1124
1125 \begin{code}
1126 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1127 hasCafRefs this_pkg p arity expr
1128   | is_caf || mentions_cafs = MayHaveCafRefs
1129   | otherwise               = NoCafRefs
1130  where
1131   mentions_cafs = isFastTrue (cafRefs p expr)
1132   is_dynamic_name = isDllName this_pkg
1133   is_caf = not (arity > 0 || rhsIsStatic is_dynamic_name expr)
1134
1135   -- NB. we pass in the arity of the expression, which is expected
1136   -- to be calculated by exprArity.  This is because exprArity
1137   -- knows how much eta expansion is going to be done by
1138   -- CorePrep later on, and we don't want to duplicate that
1139   -- knowledge in rhsIsStatic below.
1140
1141 cafRefs :: VarEnv Id -> Expr a -> FastBool
1142 cafRefs p (Var id)
1143         -- imported Ids first:
1144   | not (isLocalId id) = fastBool (mayHaveCafRefs (idCafInfo id))
1145         -- now Ids local to this module:
1146   | otherwise =
1147      case lookupVarEnv p id of
1148         Just id' -> fastBool (mayHaveCafRefs (idCafInfo id'))
1149         Nothing  -> fastBool False
1150
1151 cafRefs _ (Lit _)              = fastBool False
1152 cafRefs p (App f a)            = fastOr (cafRefs p f) (cafRefs p) a
1153 cafRefs p (Lam _ e)            = cafRefs p e
1154 cafRefs p (Let b e)            = fastOr (cafRefss p (rhssOfBind b)) (cafRefs p) e
1155 cafRefs p (Case e _bndr _ alts) = fastOr (cafRefs p e) (cafRefss p) (rhssOfAlts alts)
1156 cafRefs p (Note _n e)          = cafRefs p e
1157 cafRefs p (Cast e _co)         = cafRefs p e
1158 cafRefs _ (Type _)             = fastBool False
1159 cafRefs _ (Coercion _)         = fastBool False
1160
1161 cafRefss :: VarEnv Id -> [Expr a] -> FastBool
1162 cafRefss _ []     = fastBool False
1163 cafRefss p (e:es) = fastOr (cafRefs p e) (cafRefss p) es
1164
1165 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1166 -- hack for lazy-or over FastBool.
1167 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1168 \end{code}