compiler/main/TidyPgm.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module TidyPgm( mkBootModDetailsDs, mkBootModDetailsTc,
   8                 tidyProgram, globaliseAndTidyId ) where
   9
  10 #include "HsVersions.h"
  11
  12 import TcRnTypes
  13 import FamInstEnv
  14 import DynFlags
  15 import CoreSyn
  16 import CoreUnfold
  17 import CoreFVs
  18 import CoreTidy
  19 import PprCore
  20 import CoreLint
  21 import CoreUtils
  22 import CoreArity        ( exprArity )
  23 import Class            ( classSelIds )
  24 import VarEnv
  25 import VarSet
  26 import Var
  27 import Id
  28 import IdInfo
  29 import InstEnv
  30 import NewDemand
  31 import BasicTypes
  32 import Name
  33 import NameSet
  34 import IfaceEnv
  35 import NameEnv
  36 import TcType
  37 import DataCon
  38 import TyCon
  39 import Module
  40 import HscTypes
  41 import Maybes
  42 import ErrUtils
  43 import UniqSupply
  44 import Outputable
  45 import FastBool hiding ( fastOr )
  46 import Util
  47
  48 import Data.List        ( sortBy )
  49 import Data.IORef       ( IORef, readIORef, writeIORef )
  50 \end{code}
  51
  52
  53 Constructing the TypeEnv, Instances, Rules from which the ModIface is
  54 constructed, and which goes on to subsequent modules in --make mode.
  55
  56 Most of the interface file is obtained simply by serialising the
  57 TypeEnv.  One important consequence is that if the *interface file*
  58 has pragma info if and only if the final TypeEnv does. This is not so
  59 important for *this* module, but it's essential for ghc --make:
  60 subsequent compilations must not see (e.g.) the arity if the interface
  61 file does not contain arity If they do, they'll exploit the arity;
  62 then the arity might change, but the iface file doesn't change =>
  63 recompilation does not happen => disaster.
  64
  65 For data types, the final TypeEnv will have a TyThing for the TyCon,
  66 plus one for each DataCon; the interface file will contain just one
  67 data type declaration, but it is de-serialised back into a collection
  68 of TyThings.
  69
  70 %************************************************************************
  71 %*                                                                      *
  72                 Plan A: simpleTidyPgm
  73 %*                                                                      *
  74 %************************************************************************
  75
  76
  77 Plan A: mkBootModDetails: omit pragmas, make interfaces small
  78 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  79 * Ignore the bindings
  80
  81 * Drop all WiredIn things from the TypeEnv
  82         (we never want them in interface files)
  83
  84 * Retain all TyCons and Classes in the TypeEnv, to avoid
  85         having to find which ones are mentioned in the
  86         types of exported Ids
  87
  88 * Trim off the constructors of non-exported TyCons, both
  89         from the TyCon and from the TypeEnv
  90
  91 * Drop non-exported Ids from the TypeEnv
  92
  93 * Tidy the types of the DFunIds of Instances,
  94   make them into GlobalIds, (they already have External Names)
  95   and add them to the TypeEnv
  96
  97 * Tidy the types of the (exported) Ids in the TypeEnv,
  98   make them into GlobalIds (they already have External Names)
  99
 100 * Drop rules altogether
 101
 102 * Tidy the bindings, to ensure that the Caf and Arity
 103   information is correct for each top-level binder; the
 104   code generator needs it. And to ensure that local names have
 105   distinct OccNames in case of object-file splitting
 106
 107 \begin{code}
 108 -- This is Plan A: make a small type env when typechecking only,
 109 -- or when compiling a hs-boot file, or simply when not using -O
 110 --
 111 -- We don't look at the bindings at all -- there aren't any
 112 -- for hs-boot files
 113
 114 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
 115 mkBootModDetailsTc hsc_env
 116         TcGblEnv{ tcg_exports   = exports,
 117                   tcg_type_env  = type_env,
 118                   tcg_insts     = insts,
 119                   tcg_fam_insts = fam_insts
 120                 }
 121   = mkBootModDetails hsc_env exports type_env insts fam_insts
 122
 123 mkBootModDetailsDs :: HscEnv -> ModGuts -> IO ModDetails
 124 mkBootModDetailsDs hsc_env
 125         ModGuts{ mg_exports   = exports,
 126                  mg_types     = type_env,
 127                  mg_insts     = insts,
 128                  mg_fam_insts = fam_insts
 129                 }
 130   = mkBootModDetails hsc_env exports type_env insts fam_insts
 131
 132 mkBootModDetails :: HscEnv -> [AvailInfo] -> NameEnv TyThing
 133                  -> [Instance] -> [FamInstEnv.FamInst] -> IO ModDetails
 134 mkBootModDetails hsc_env exports type_env insts fam_insts
 135   = do  { let dflags = hsc_dflags hsc_env
 136         ; showPass dflags "Tidy [hoot] type env"
 137
 138         ; let { insts'     = tidyInstances globaliseAndTidyId insts
 139               ; dfun_ids   = map instanceDFunId insts'
 140               ; type_env1  = tidyBootTypeEnv (availsToNameSet exports) type_env
 141               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
 142               }
 143         ; return (ModDetails { md_types     = type_env'
 144                              , md_insts     = insts'
 145                              , md_fam_insts = fam_insts
 146                              , md_rules     = []
 147                              , md_anns      = []
 148                              , md_exports   = exports
 149                              , md_vect_info = noVectInfo
 150                              })
 151         }
 152   where
 153
 154 tidyBootTypeEnv :: NameSet -> TypeEnv -> TypeEnv
 155 tidyBootTypeEnv exports type_env
 156   = tidyTypeEnv True False exports type_env final_ids
 157   where
 158         -- Find the LocalIds in the type env that are exported
 159         -- Make them into GlobalIds, and tidy their types
 160         --
 161         -- It's very important to remove the non-exported ones
 162         -- because we don't tidy the OccNames, and if we don't remove
 163         -- the non-exported ones we'll get many things with the
 164         -- same name in the interface file, giving chaos.
 165     final_ids = [ globaliseAndTidyId id
 166                 | id <- typeEnvIds type_env
 167                 , isLocalId id
 168                 , keep_it id ]
 169
 170         -- default methods have their export flag set, but everything
 171         -- else doesn't (yet), because this is pre-desugaring, so we
 172         -- must test both.
 173     keep_it id = isExportedId id || idName id `elemNameSet` exports
 174
 175
 176
 177 globaliseAndTidyId :: Id -> Id
 178 -- Takes an LocalId with an External Name,
 179 -- makes it into a GlobalId
 180 --     * unchanged Name (might be Internal or External)
 181 --     * unchanged details
 182 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
 183 globaliseAndTidyId id
 184   = Id.setIdType (globaliseId id) tidy_type
 185   where
 186     tidy_type = tidyTopType (idType id)
 187 \end{code}
 188
 189
 190 %************************************************************************
 191 %*                                                                      *
 192         Plan B: tidy bindings, make TypeEnv full of IdInfo
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 Plan B: include pragmas, make interfaces
 197 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 198 * Figure out which Ids are externally visible
 199
 200 * Tidy the bindings, externalising appropriate Ids
 201
 202 * Drop all Ids from the TypeEnv, and add all the External Ids from
 203   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
 204   floated-out Ids that weren't even in the TypeEnv before.)
 205
 206 Step 1: Figure out external Ids
 207 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 208 Note [choosing external names]
 209
 210 First we figure out which Ids are "external" Ids.  An
 211 "external" Id is one that is visible from outside the compilation
 212 unit.  These are
 213         a) the user exported ones
 214         b) ones mentioned in the unfoldings, workers,
 215            or rules of externally-visible ones
 216
 217 While figuring out which Ids are external, we pick a "tidy" OccName
 218 for each one.  That is, we make its OccName distinct from the other
 219 external OccNames in this module, so that in interface files and
 220 object code we can refer to it unambiguously by its OccName.  The
 221 OccName for each binder is prefixed by the name of the exported Id
 222 that references it; e.g. if "f" references "x" in its unfolding, then
 223 "x" is renamed to "f_x".  This helps distinguish the different "x"s
 224 from each other, and means that if "f" is later removed, things that
 225 depend on the other "x"s will not need to be recompiled.  Of course,
 226 if there are multiple "f_x"s, then we have to disambiguate somehow; we
 227 use "f_x0", "f_x1" etc.
 228
 229 As far as possible we should assign names in a deterministic fashion.
 230 Each time this module is compiled with the same options, we should end
 231 up with the same set of external names with the same types.  That is,
 232 the ABI hash in the interface should not change.  This turns out to be
 233 quite tricky, since the order of the bindings going into the tidy
 234 phase is already non-deterministic, as it is based on the ordering of
 235 Uniques, which are assigned unpredictably.
 236
 237 To name things in a stable way, we do a depth-first-search of the
 238 bindings, starting from the exports sorted by name.  This way, as long
 239 as the bindings themselves are deterministic (they sometimes aren't!),
 240 the order in which they are presented to the tidying phase does not
 241 affect the names we assign.
 242
 243 Step 2: Tidy the program
 244 ~~~~~~~~~~~~~~~~~~~~~~~~
 245 Next we traverse the bindings top to bottom.  For each *top-level*
 246 binder
 247
 248  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal,
 249     reflecting the fact that from now on we regard it as a global,
 250     not local, Id
 251
 252  2. Give it a system-wide Unique.
 253     [Even non-exported things need system-wide Uniques because the
 254     byte-code generator builds a single Name->BCO symbol table.]
 255
 256     We use the NameCache kept in the HscEnv as the
 257     source of such system-wide uniques.
 258
 259     For external Ids, use the original-name cache in the NameCache
 260     to ensure that the unique assigned is the same as the Id had
 261     in any previous compilation run.
 262
 263  3. Rename top-level Ids according to the names we chose in step 1.
 264     If it's an external Id, make it have a External Name, otherwise
 265     make it have an Internal Name.  This is used by the code generator
 266     to decide whether to make the label externally visible
 267
 268  4. Give it its UTTERLY FINAL IdInfo; in ptic,
 269         * its unfolding, if it should have one
 270
 271         * its arity, computed from the number of visible lambdas
 272
 273         * its CAF info, computed from what is free in its RHS
 274
 275
 276 Finally, substitute these new top-level binders consistently
 277 throughout, including in unfoldings.  We also tidy binders in
 278 RHSs, so that they print nicely in interfaces.
 279
 280 \begin{code}
 281 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
 282 tidyProgram hsc_env  (ModGuts { mg_module = mod, mg_exports = exports,
 283                                 mg_types = type_env,
 284                                 mg_insts = insts, mg_fam_insts = fam_insts,
 285                                 mg_binds = binds,
 286                                 mg_rules = imp_rules,
 287                                 mg_vect_info = vect_info,
 288                                 mg_dir_imps = dir_imps,
 289                                 mg_anns = anns,
 290                                 mg_deps = deps,
 291                                 mg_foreign = foreign_stubs,
 292                                 mg_hpc_info = hpc_info,
 293                                 mg_modBreaks = modBreaks })
 294
 295   = do  { let dflags = hsc_dflags hsc_env
 296         ; showPass dflags "Tidy Core"
 297
 298         ; let { omit_prags = dopt Opt_OmitInterfacePragmas dflags
 299               ; th         = dopt Opt_TemplateHaskell      dflags
 300               }
 301
 302         ; (unfold_env, tidy_occ_env)
 303               <- chooseExternalIds hsc_env type_env mod omit_prags binds
 304
 305         ; let { ext_rules
 306                    | omit_prags = []
 307                    | otherwise  = findExternalRules binds imp_rules unfold_env
 308                 -- findExternalRules filters imp_rules to avoid binders that
 309                 -- aren't externally visible; but the externally-visible binders
 310                 -- are computed (by findExternalIds) assuming that all orphan
 311                 -- rules are exported (they get their Exported flag set in the desugarer)
 312                 -- So in fact we may export more than we need.
 313                 -- (It's a sort of mutual recursion.)
 314         }
 315
 316         ; let { (tidy_env, tidy_binds)
 317                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
 318
 319         ; let { export_set = availsToNameSet exports
 320               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds,
 321                                     isExternalName (idName id)]
 322               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
 323                                             type_env final_ids
 324               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
 325                 -- A DFunId will have a binding in tidy_binds, and so
 326                 -- will now be in final_env, replete with IdInfo
 327                 -- Its name will be unchanged since it was born, but
 328                 -- we want Global, IdInfo-rich (or not) DFunId in the
 329                 -- tidy_insts
 330
 331               ; tidy_rules = tidyRules tidy_env ext_rules
 332                 -- You might worry that the tidy_env contains IdInfo-rich stuff
 333                 -- and indeed it does, but if omit_prags is on, ext_rules is
 334                 -- empty
 335
 336               -- See Note [Injecting implicit bindings]
 337               ; implicit_binds = getImplicitBinds type_env
 338               ; all_tidy_binds = implicit_binds ++ tidy_binds
 339
 340               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
 341               }
 342
 343         ; endPass dflags "Tidy Core" Opt_D_dump_simpl all_tidy_binds
 344         ; dumpIfSet_core dflags Opt_D_dump_simpl
 345                 "Tidy Core Rules"
 346                 (pprRules tidy_rules)
 347
 348         ; let dir_imp_mods = moduleEnvKeys dir_imps
 349
 350         ; return (CgGuts { cg_module   = mod,
 351                            cg_tycons   = alg_tycons,
 352                            cg_binds    = all_tidy_binds,
 353                            cg_dir_imps = dir_imp_mods,
 354                            cg_foreign  = foreign_stubs,
 355                            cg_dep_pkgs = dep_pkgs deps,
 356                            cg_hpc_info = hpc_info,
 357                            cg_modBreaks = modBreaks },
 358
 359                    ModDetails { md_types     = tidy_type_env,
 360                                 md_rules     = tidy_rules,
 361                                 md_insts     = tidy_insts,
 362                                 md_fam_insts = fam_insts,
 363                                 md_exports   = exports,
 364                                 md_anns      = anns,     -- are already tidy
 365                                 md_vect_info = vect_info --
 366                               })
 367         }
 368
 369 lookup_dfun :: TypeEnv -> Var -> Id
 370 lookup_dfun type_env dfun_id
 371   = case lookupTypeEnv type_env (idName dfun_id) of
 372         Just (AnId dfun_id') -> dfun_id'
 373         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
 374
 375 --------------------------
 376 tidyTypeEnv :: Bool     -- Compiling without -O, so omit prags
 377             -> Bool     -- Template Haskell is on
 378             -> NameSet -> TypeEnv -> [Id] -> TypeEnv
 379
 380 -- The competed type environment is gotten from
 381 --      Dropping any wired-in things, and then
 382 --      a) keeping the types and classes
 383 --      b) removing all Ids,
 384 --      c) adding Ids with correct IdInfo, including unfoldings,
 385 --              gotten from the bindings
 386 -- From (c) we keep only those Ids with External names;
 387 --          the CoreTidy pass makes sure these are all and only
 388 --          the externally-accessible ones
 389 -- This truncates the type environment to include only the
 390 -- exported Ids and things needed from them, which saves space
 391
 392 tidyTypeEnv omit_prags th exports type_env final_ids
 393  = let  type_env1 = filterNameEnv keep_it type_env
 394         type_env2 = extendTypeEnvWithIds type_env1 final_ids
 395         type_env3 | omit_prags = mapNameEnv (trimThing th exports) type_env2
 396                   | otherwise  = type_env2
 397     in
 398     type_env3
 399   where
 400         -- We keep GlobalIds, because they won't appear
 401         -- in the bindings from which final_ids are derived!
 402         -- (The bindings bind LocalIds.)
 403     keep_it thing | isWiredInThing thing = False
 404     keep_it (AnId id) = isGlobalId id   -- Keep GlobalIds (e.g. class ops)
 405     keep_it _other    = True            -- Keep all TyCons, DataCons, and Classes
 406
 407 --------------------------
 408 isWiredInThing :: TyThing -> Bool
 409 isWiredInThing thing = isWiredInName (getName thing)
 410
 411 --------------------------
 412 trimThing :: Bool -> NameSet -> TyThing -> TyThing
 413 -- Trim off inessentials, for boot files and no -O
 414 trimThing th exports (ATyCon tc)
 415    | not th && not (mustExposeTyCon exports tc)
 416    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
 417
 418 trimThing _th _exports (AnId id)
 419    | not (isImplicitId id)
 420    = AnId (id `setIdInfo` vanillaIdInfo)
 421
 422 trimThing _th _exports other_thing
 423   = other_thing
 424
 425
 426 {- Note [Trimming and Template Haskell]
 427    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 428 Consider (Trac #2386) this
 429         module M(T, makeOne) where
 430           data T = Yay String
 431           makeOne = [| Yay "Yep" |]
 432 Notice that T is exported abstractly, but makeOne effectively exports it too!
 433 A module that splices in $(makeOne) will then look for a declartion of Yay,
 434 so it'd better be there.  Hence, brutally but simply, we switch off type
 435 constructor trimming if TH is enabled in this module. -}
 436
 437
 438 mustExposeTyCon :: NameSet      -- Exports
 439                 -> TyCon        -- The tycon
 440                 -> Bool         -- Can its rep be hidden?
 441 -- We are compiling without -O, and thus trying to write as little as
 442 -- possible into the interface file.  But we must expose the details of
 443 -- any data types whose constructors or fields are exported
 444 mustExposeTyCon exports tc
 445   | not (isAlgTyCon tc)         -- Synonyms
 446   = True
 447   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
 448   = True                        -- won't lead to the need for further exposure
 449                                 -- (This includes data types with no constructors.)
 450   | isOpenTyCon tc              -- Open type family
 451   = True
 452
 453   | otherwise                   -- Newtype, datatype
 454   = any exported_con (tyConDataCons tc)
 455         -- Expose rep if any datacon or field is exported
 456
 457   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
 458         -- Expose the rep for newtypes if the rep is an FFI type.
 459         -- For a very annoying reason.  'Foreign import' is meant to
 460         -- be able to look through newtypes transparently, but it
 461         -- can only do that if it can "see" the newtype representation
 462   where
 463     exported_con con = any (`elemNameSet` exports)
 464                            (dataConName con : dataConFieldLabels con)
 465
 466 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
 467 tidyInstances tidy_dfun ispecs
 468   = map tidy ispecs
 469   where
 470     tidy ispec = setInstanceDFunId ispec $
 471                  tidy_dfun (instanceDFunId ispec)
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477         Implicit bindings
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 Note [Injecting implicit bindings]
 482 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 483 We inject the implict bindings right at the end, in CoreTidy.
 484 Some of these bindings, notably record selectors, are not
 485 constructed in an optimised form.  E.g. record selector for
 486         data T = MkT { x :: {-# UNPACK #-} !Int }
 487 Then the unfolding looks like
 488         x = \t. case t of MkT x1 -> let x = I# x1 in x
 489 This generates bad code unless it's first simplified a bit.  That is
 490 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
 491 optimisation first.  (Only matters when the selector is used curried;
 492 eg map x ys.)  See Trac #2070.
 493
 494 At one time I tried injecting the implicit bindings *early*, at the
 495 beginning of SimplCore.  But that gave rise to real difficulty,
 496 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
 497 simplifier and other core-to-core passes mess with IdInfo all the
 498 time.  The straw that broke the camels back was when a class selector
 499 got the wrong arity -- ie the simplifier gave it arity 2, whereas
 500 importing modules were expecting it to have arity 1 (Trac #2844).
 501 It's much safer just to inject them right at the end, after tidying.
 502
 503 Oh: two other reasons for injecting them late:
 504   - If implicit Ids are already in the bindings when we start TidyPgm,
 505     we'd have to be careful not to treat them as external Ids (in
 506     the sense of findExternalIds); else the Ids mentioned in *their*
 507     RHSs will be treated as external and you get an interface file
 508     saying      a18 = <blah>
 509     but nothing refererring to a18 (because the implicit Id is the
 510     one that does).
 511
 512   - More seriously, the tidied type-envt will include the implicit
 513     Id replete with a18 in its unfolding; but we won't take account
 514     of a18 when computing a fingerprint for the class; result chaos.
 515
 516
 517 \begin{code}
 518 getImplicitBinds :: TypeEnv -> [CoreBind]
 519 getImplicitBinds type_env
 520   = map get_defn (concatMap implicit_ids (typeEnvElts type_env))
 521   where
 522     implicit_ids (ATyCon tc)  = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
 523     implicit_ids (AClass cls) = classSelIds cls
 524     implicit_ids _            = []
 525
 526     get_defn :: Id -> CoreBind
 527     get_defn id = NonRec id (unfoldingTemplate (idUnfolding id))
 528 \end{code}
 529
 530
 531 %************************************************************************
 532 %*                                                                      *
 533 \subsection{Step 1: finding externals}
 534 %*                                                                      *
 535 %************************************************************************
 536
 537 Sete Note [choosing external names].
 538
 539 \begin{code}
 540 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
 541
 542 chooseExternalIds :: HscEnv
 543                   -> TypeEnv
 544                   -> Module
 545                   -> Bool
 546                   -> [CoreBind]
 547                   -> IO (UnfoldEnv, TidyOccEnv)
 548                      -- maps top-level Ids to new, renamed, Ids.
 549                      -- If the new Id is external, it will be visible
 550                      -- in the interface file.
 551                      -- Bool => expose unfolding or not.
 552         -- Step 1 from the notes above
 553
 554 chooseExternalIds hsc_env type_env mod omit_prags binds
 555   = do
 556     (unfold_env1,occ_env1)
 557         <- search (zip sorted_exports sorted_exports) emptyVarEnv init_occ_env
 558     let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
 559     tidy_internal internal_ids unfold_env1 occ_env1
 560  where
 561   nc_var = hsc_NC hsc_env
 562
 563   -- the exports, sorted by OccName.  This is a deterministic list of
 564   -- Ids (i.e. it's the same list every time this module is compiled),
 565   -- in contrast to the bindings, which are ordered
 566   -- non-deterministically.
 567   --
 568   -- This list will serve as a starting point for finding a
 569   -- deterministic, tidy, renaming for all external Ids in this
 570   -- module.
 571   sorted_exports = sortBy (compare `on` getOccName) $
 572                      filter isExportedId binders
 573
 574   binders = bindersOfBinds binds
 575
 576   bind_env :: IdEnv CoreExpr
 577   bind_env = mkVarEnv (flattenBinds binds)
 578
 579   avoids   = [getOccName name | bndr <- typeEnvIds type_env,
 580                                 let name = idName bndr,
 581                                 isExternalName name]
 582                 -- In computing our "avoids" list, we must include
 583                 --      all implicit Ids
 584                 --      all things with global names (assigned once and for
 585                 --                                      all by the renamer)
 586                 -- since their names are "taken".
 587                 -- The type environment is a convenient source of such things.
 588
 589         -- We also make sure to avoid any exported binders.  Consider
 590         --      f{-u1-} = 1     -- Local decl
 591         --      ...
 592         --      f{-u2-} = 2     -- Exported decl
 593         --
 594         -- The second exported decl must 'get' the name 'f', so we
 595         -- have to put 'f' in the avoids list before we get to the first
 596         -- decl.  tidyTopId then does a no-op on exported binders.
 597   init_occ_env = initTidyOccEnv avoids
 598
 599
 600   search :: [(Id,Id)]    -- (external id, referrring id)
 601          -> UnfoldEnv    -- id -> (new Name, show_unfold)
 602          -> TidyOccEnv   -- occ env for choosing new Names
 603          -> IO (UnfoldEnv, TidyOccEnv)
 604
 605   search [] unfold_env occ_env = return (unfold_env, occ_env)
 606
 607   search ((id,referrer) : rest) unfold_env occ_env
 608     | id `elemVarEnv` unfold_env = search rest unfold_env occ_env
 609     | otherwise = do
 610       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env id
 611       let
 612           rhs = expectJust "chooseExternalIds" $ lookupVarEnv bind_env id
 613           (new_ids, show_unfold)
 614                 | omit_prags = ([], False)
 615                 | otherwise  = addExternal id rhs
 616           unfold_env' = extendVarEnv unfold_env id (name',show_unfold)
 617           referrer' | isExportedId id = id
 618                     | otherwise       = referrer
 619       --
 620       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
 621
 622   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
 623                 -> IO (UnfoldEnv, TidyOccEnv)
 624   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
 625   tidy_internal (id:ids) unfold_env occ_env = do
 626       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
 627       let unfold_env' = extendVarEnv unfold_env id (name',False)
 628       tidy_internal ids unfold_env' occ_env'
 629
 630 addExternal :: Id -> CoreExpr -> ([Id],Bool)
 631 addExternal id rhs = (new_needed_ids, show_unfold)
 632   where
 633     new_needed_ids = unfold_ids ++
 634                      filter (not . (`elemVarSet` unfold_set))
 635                        (varSetElems worker_ids ++
 636                         varSetElems spec_ids) -- XXX non-det ordering
 637
 638     idinfo         = idInfo id
 639     dont_inline    = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
 640     loop_breaker   = isNonRuleLoopBreaker (occInfo idinfo)
 641     bottoming_fn   = isBottomingSig (newStrictnessInfo idinfo `orElse` topSig)
 642     spec_ids       = specInfoFreeVars (specInfo idinfo)
 643     worker_info    = workerInfo idinfo
 644
 645         -- Stuff to do with the Id's unfolding
 646         -- The simplifier has put an up-to-date unfolding
 647         -- in the IdInfo, but the RHS will do just as well
 648     unfolding    = unfoldingInfo idinfo
 649     rhs_is_small = not (neverUnfold unfolding)
 650
 651         -- We leave the unfolding there even if there is a worker
 652         -- In GHCI the unfolding is used by importers
 653         -- When writing an interface file, we omit the unfolding
 654         -- if there is a worker
 655     show_unfold = not bottoming_fn       &&     -- Not necessary
 656                   not dont_inline        &&
 657                   not loop_breaker       &&
 658                   rhs_is_small                  -- Small enough
 659
 660     (unfold_set, unfold_ids)
 661                | show_unfold = freeVarsInDepthFirstOrder rhs
 662                | otherwise   = (emptyVarSet, [])
 663
 664     worker_ids = case worker_info of
 665                    HasWorker work_id _ -> unitVarSet work_id
 666                    _otherwise          -> emptyVarSet
 667
 668
 669 -- We want a deterministic free-variable list.  exprFreeVars gives us
 670 -- a VarSet, which is in a non-deterministic order when converted to a
 671 -- list.  Hence, here we define a free-variable finder that returns
 672 -- the free variables in the order that they are encountered.
 673 --
 674 -- Note [choosing external names]
 675
 676 freeVarsInDepthFirstOrder :: CoreExpr -> (VarSet, [Id])
 677 freeVarsInDepthFirstOrder e =
 678   case dffvExpr e of
 679     DFFV m -> case m emptyVarSet [] of
 680                 (set,ids,_) -> (set,ids)
 681
 682 newtype DFFV a = DFFV (VarSet -> [Var] -> (VarSet,[Var],a))
 683
 684 instance Monad DFFV where
 685   return a = DFFV $ \set ids -> (set, ids, a)
 686   (DFFV m) >>= k = DFFV $ \set ids ->
 687     case m set ids of
 688        (set',ids',a) -> case k a of
 689                           DFFV f -> f set' ids'
 690
 691 insert :: Var -> DFFV ()
 692 insert v = DFFV $ \ set ids  -> case () of
 693  _ | v `elemVarSet` set -> (set,ids,())
 694    | otherwise          -> (extendVarSet set v, v:ids, ())
 695
 696 dffvExpr :: CoreExpr -> DFFV ()
 697 dffvExpr e = go emptyVarSet e
 698   where
 699     go scope e = case e of
 700       Var v | isLocalId v && not (v `elemVarSet` scope) -> insert v
 701       App e1 e2          -> do go scope e1; go scope e2
 702       Lam v e            -> go (extendVarSet scope v) e
 703       Note _ e           -> go scope e
 704       Cast e _           -> go scope e
 705       Let (NonRec x r) e -> do go scope r; go (extendVarSet scope x) e
 706       Let (Rec prs) e    -> do let scope' = extendVarSetList scope (map fst prs)
 707                                mapM_ (go scope') (map snd prs)
 708                                go scope' e
 709       Case e b _ as      -> do go scope e
 710                                mapM_ (go_alt (extendVarSet scope b)) as
 711       _other             -> return ()
 712
 713     go_alt scope (_,xs,r) = go (extendVarSetList scope xs) r
 714 \end{code}
 715
 716
 717 --------------------------------------------------------------------
 718 --              tidyTopName
 719 -- This is where we set names to local/global based on whether they really are
 720 -- externally visible (see comment at the top of this module).  If the name
 721 -- was previously local, we have to give it a unique occurrence name if
 722 -- we intend to externalise it.
 723
 724 \begin{code}
 725 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
 726             -> Id -> IO (TidyOccEnv, Name)
 727 tidyTopName mod nc_var maybe_ref occ_env id
 728   | global && internal = return (occ_env, localiseName name)
 729
 730   | global && external = return (occ_env, name)
 731         -- Global names are assumed to have been allocated by the renamer,
 732         -- so they already have the "right" unique
 733         -- And it's a system-wide unique too
 734
 735   -- Now we get to the real reason that all this is in the IO Monad:
 736   -- we have to update the name cache in a nice atomic fashion
 737
 738   | local  && internal = do { nc <- readIORef nc_var
 739                             ; let (nc', new_local_name) = mk_new_local nc
 740                             ; writeIORef nc_var nc'
 741                             ; return (occ_env', new_local_name) }
 742         -- Even local, internal names must get a unique occurrence, because
 743         -- if we do -split-objs we externalise the name later, in the code generator
 744         --
 745         -- Similarly, we must make sure it has a system-wide Unique, because
 746         -- the byte-code generator builds a system-wide Name->BCO symbol table
 747
 748   | local  && external = do { nc <- readIORef nc_var
 749                             ; let (nc', new_external_name) = mk_new_external nc
 750                             ; writeIORef nc_var nc'
 751                             ; return (occ_env', new_external_name) }
 752
 753   | otherwise = panic "tidyTopName"
 754   where
 755     name        = idName id
 756     external    = isJust maybe_ref
 757     global      = isExternalName name
 758     local       = not global
 759     internal    = not external
 760     loc         = nameSrcSpan name
 761
 762     old_occ     = nameOccName name
 763     new_occ
 764       | Just ref <- maybe_ref, ref /= id =
 765           mkOccName (occNameSpace old_occ) $
 766              occNameString (getOccName ref) ++ '_' : occNameString old_occ
 767       | otherwise = old_occ
 768
 769     (occ_env', occ') = tidyOccName occ_env new_occ
 770
 771     mk_new_local nc = (nc { nsUniqs = us2 }, mkInternalName uniq occ' loc)
 772                     where
 773                       (us1, us2) = splitUniqSupply (nsUniqs nc)
 774                       uniq       = uniqFromSupply us1
 775
 776     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
 777         -- If we want to externalise a currently-local name, check
 778         -- whether we have already assigned a unique for it.
 779         -- If so, use it; if not, extend the table.
 780         -- All this is done by allcoateGlobalBinder.
 781         -- This is needed when *re*-compiling a module in GHCi; we must
 782         -- use the same name for externally-visible things as we did before.
 783 \end{code}
 784
 785 \begin{code}
 786 findExternalRules :: [CoreBind]
 787                   -> [CoreRule] -- Non-local rules (i.e. ones for imported fns)
 788                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
 789                   -> [CoreRule]
 790   -- The complete rules are gotten by combining
 791   --    a) the non-local rules
 792   --    b) rules embedded in the top-level Ids
 793 findExternalRules binds non_local_rules unfold_env
 794   = filter (not . internal_rule) (non_local_rules ++ local_rules)
 795   where
 796     local_rules  = [ rule
 797                    | id <- bindersOfBinds binds,
 798                      external_id id,
 799                      rule <- idCoreRules id
 800                    ]
 801
 802     internal_rule rule
 803         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
 804                 -- Don't export a rule whose LHS mentions a locally-defined
 805                 --  Id that is completely internal (i.e. not visible to an
 806                 -- importing module)
 807
 808     external_id id
 809       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
 810       | otherwise = False
 811 \end{code}
 812
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817 \subsection{Step 2: top-level tidying}
 818 %*                                                                      *
 819 %************************************************************************
 820
 821
 822 \begin{code}
 823 -- TopTidyEnv: when tidying we need to know
 824 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.
 825 --        These may have arisen because the
 826 --        renamer read in an interface file mentioning M.$wf, say,
 827 --        and assigned it unique r77.  If, on this compilation, we've
 828 --        invented an Id whose name is $wf (but with a different unique)
 829 --        we want to rename it to have unique r77, so that we can do easy
 830 --        comparisons with stuff from the interface file
 831 --
 832 --   * occ_env: The TidyOccEnv, which tells us which local occurrences
 833 --     are 'used'
 834 --
 835 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
 836
 837 tidyTopBinds :: HscEnv
 838              -> UnfoldEnv
 839              -> TidyOccEnv
 840              -> [CoreBind]
 841              -> (TidyEnv, [CoreBind])
 842
 843 tidyTopBinds hsc_env unfold_env init_occ_env binds
 844   = tidy init_env binds
 845   where
 846     init_env = (init_occ_env, emptyVarEnv)
 847
 848     this_pkg = thisPackage (hsc_dflags hsc_env)
 849
 850     tidy env []     = (env, [])
 851     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
 852                           (env2, bs') = tidy env1 bs
 853                       in
 854                           (env2, b':bs')
 855
 856 ------------------------
 857 tidyTopBind  :: PackageId
 858              -> UnfoldEnv
 859              -> TidyEnv
 860              -> CoreBind
 861              -> (TidyEnv, CoreBind)
 862
 863 tidyTopBind this_pkg unfold_env (occ_env1,subst1) (NonRec bndr rhs)
 864   = (tidy_env2,  NonRec bndr' rhs')
 865   where
 866     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
 867     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
 868     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
 869     subst2        = extendVarEnv subst1 bndr bndr'
 870     tidy_env2     = (occ_env1, subst2)
 871
 872 tidyTopBind this_pkg unfold_env (occ_env1,subst1) (Rec prs)
 873   = (tidy_env2, Rec prs')
 874   where
 875     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
 876            | (id,rhs) <- prs,
 877              let (name',show_unfold) =
 878                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
 879            ]
 880
 881     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
 882     tidy_env2 = (occ_env1, subst2)
 883
 884     bndrs = map fst prs
 885
 886         -- the CafInfo for a recursive group says whether *any* rhs in
 887         -- the group may refer indirectly to a CAF (because then, they all do).
 888     caf_info
 889         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
 890              | (bndr,rhs) <- prs ] = MayHaveCafRefs
 891         | otherwise                = NoCafRefs
 892
 893 -----------------------------------------------------------
 894 tidyTopPair :: Bool  -- show unfolding
 895             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
 896                         -- It is knot-tied: don't look at it!
 897             -> CafInfo
 898             -> Name             -- New name
 899             -> (Id, CoreExpr)   -- Binder and RHS before tidying
 900             -> (Id, CoreExpr)
 901         -- This function is the heart of Step 2
 902         -- The rec_tidy_env is the one to use for the IdInfo
 903         -- It's necessary because when we are dealing with a recursive
 904         -- group, a variable late in the group might be mentioned
 905         -- in the IdInfo of one early in the group
 906
 907 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
 908   = (bndr', rhs')
 909   where
 910     bndr' = mkGlobalId details name' ty' idinfo'
 911     details = idDetails bndr    -- Preserve the IdDetails
 912     ty'     = tidyTopType (idType bndr)
 913     rhs'    = tidyExpr rhs_tidy_env rhs
 914     idinfo  = idInfo bndr
 915     idinfo' = tidyTopIdInfo (isExternalName name')
 916                             idinfo unfold_info worker_info
 917                             arity caf_info
 918
 919     unfold_info | show_unfold = mkTopUnfolding rhs'
 920                 | otherwise   = noUnfolding
 921     worker_info = tidyWorker rhs_tidy_env show_unfold (workerInfo idinfo)
 922
 923     -- Usually the Id will have an accurate arity on it, because
 924     -- the simplifier has just run, but not always.
 925     -- One case I found was when the last thing the simplifier
 926     -- did was to let-bind a non-atomic argument and then float
 927     -- it to the top level. So it seems more robust just to
 928     -- fix it here.
 929     arity = exprArity rhs
 930
 931
 932 -- tidyTopIdInfo creates the final IdInfo for top-level
 933 -- binders.  There are two delicate pieces:
 934 --
 935 --  * Arity.  After CoreTidy, this arity must not change any more.
 936 --      Indeed, CorePrep must eta expand where necessary to make
 937 --      the manifest arity equal to the claimed arity.
 938 --
 939 --  * CAF info.  This must also remain valid through to code generation.
 940 --      We add the info here so that it propagates to all
 941 --      occurrences of the binders in RHSs, and hence to occurrences in
 942 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
 943 --      CoreToStg makes use of this when constructing SRTs.
 944 tidyTopIdInfo :: Bool -> IdInfo -> Unfolding
 945               -> WorkerInfo -> ArityInfo -> CafInfo
 946               -> IdInfo
 947 tidyTopIdInfo is_external idinfo unfold_info worker_info arity caf_info
 948   | not is_external     -- For internal Ids (not externally visible)
 949   = vanillaIdInfo       -- we only need enough info for code generation
 950                         -- Arity and strictness info are enough;
 951                         --      c.f. CoreTidy.tidyLetBndr
 952         `setCafInfo`           caf_info
 953         `setArityInfo`         arity
 954         `setAllStrictnessInfo` newStrictnessInfo idinfo
 955
 956   | otherwise           -- Externally-visible Ids get the whole lot
 957   = vanillaIdInfo
 958         `setCafInfo`           caf_info
 959         `setArityInfo`         arity
 960         `setAllStrictnessInfo` newStrictnessInfo idinfo
 961         `setInlinePragInfo`    inlinePragInfo idinfo
 962         `setUnfoldingInfo`     unfold_info
 963         `setWorkerInfo`        worker_info
 964                 -- NB: we throw away the Rules
 965                 -- They have already been extracted by findExternalRules
 966
 967
 968
 969 ------------  Worker  --------------
 970 tidyWorker :: TidyEnv -> Bool -> WorkerInfo -> WorkerInfo
 971 tidyWorker _tidy_env _show_unfold NoWorker
 972   = NoWorker
 973 tidyWorker tidy_env show_unfold (HasWorker work_id wrap_arity)
 974   | show_unfold = HasWorker (tidyVarOcc tidy_env work_id) wrap_arity
 975   | otherwise   = NoWorker
 976     -- NB: do *not* expose the worker if show_unfold is off,
 977     --     because that means this thing is a loop breaker or
 978     --     marked NOINLINE or something like that
 979     -- This is important: if you expose the worker for a loop-breaker
 980     -- then you can make the simplifier go into an infinite loop, because
 981     -- in effect the unfolding is exposed.  See Trac #1709
 982     --
 983     -- You might think that if show_unfold is False, then the thing should
 984     -- not be w/w'd in the first place.  But a legitimate reason is this:
 985     --    the function returns bottom
 986     -- In this case, show_unfold will be false (we don't expose unfoldings
 987     -- for bottoming functions), but we might still have a worker/wrapper
 988     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
 989 \end{code}
 990
 991 %************************************************************************
 992 %*                                                                      *
 993 \subsection{Figuring out CafInfo for an expression}
 994 %*                                                                      *
 995 %************************************************************************
 996
 997 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
 998 We mark such things as `MayHaveCafRefs' because this information is
 999 used to decide whether a particular closure needs to be referenced
1000 in an SRT or not.
1001
1002 There are two reasons for setting MayHaveCafRefs:
1003         a) The RHS is a CAF: a top-level updatable thunk.
1004         b) The RHS refers to something that MayHaveCafRefs
1005
1006 Possible improvement: In an effort to keep the number of CAFs (and
1007 hence the size of the SRTs) down, we could also look at the expression and
1008 decide whether it requires a small bounded amount of heap, so we can ignore
1009 it as a CAF.  In these cases however, we would need to use an additional
1010 CAF list to keep track of non-collectable CAFs.
1011
1012 \begin{code}
1013 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1014 hasCafRefs this_pkg p arity expr
1015   | is_caf || mentions_cafs
1016                             = MayHaveCafRefs
1017   | otherwise               = NoCafRefs
1018  where
1019   mentions_cafs = isFastTrue (cafRefs p expr)
1020   is_caf = not (arity > 0 || rhsIsStatic this_pkg expr)
1021
1022   -- NB. we pass in the arity of the expression, which is expected
1023   -- to be calculated by exprArity.  This is because exprArity
1024   -- knows how much eta expansion is going to be done by
1025   -- CorePrep later on, and we don't want to duplicate that
1026   -- knowledge in rhsIsStatic below.
1027
1028 cafRefs :: VarEnv Id -> Expr a -> FastBool
1029 cafRefs p (Var id)
1030         -- imported Ids first:
1031   | not (isLocalId id) = fastBool (mayHaveCafRefs (idCafInfo id))
1032         -- now Ids local to this module:
1033   | otherwise =
1034      case lookupVarEnv p id of
1035         Just id' -> fastBool (mayHaveCafRefs (idCafInfo id'))
1036         Nothing  -> fastBool False
1037
1038 cafRefs _ (Lit _)              = fastBool False
1039 cafRefs p (App f a)            = fastOr (cafRefs p f) (cafRefs p) a
1040 cafRefs p (Lam _ e)            = cafRefs p e
1041 cafRefs p (Let b e)            = fastOr (cafRefss p (rhssOfBind b)) (cafRefs p) e
1042 cafRefs p (Case e _bndr _ alts) = fastOr (cafRefs p e) (cafRefss p) (rhssOfAlts alts)
1043 cafRefs p (Note _n e)          = cafRefs p e
1044 cafRefs p (Cast e _co)         = cafRefs p e
1045 cafRefs _ (Type _)             = fastBool False
1046
1047 cafRefss :: VarEnv Id -> [Expr a] -> FastBool
1048 cafRefss _ []     = fastBool False
1049 cafRefss p (e:es) = fastOr (cafRefs p e) (cafRefss p) es
1050
1051 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1052 -- hack for lazy-or over FastBool.
1053 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1054 \end{code}