compiler/parser/Parser.y.pp

   1 --                                                              -*-haskell-*-
   2 -- ---------------------------------------------------------------------------
   3 -- (c) The University of Glasgow 1997-2003
   4 ---
   5 -- The GHC grammar.
   6 --
   7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -- ---------------------------------------------------------------------------
   9
  10 {
  11 {-# OPTIONS -Wwarn -w #-}
  12 -- The above warning supression flag is a temporary kludge.
  13 -- While working on this module you are encouraged to remove it and fix
  14 -- any warnings in the module. See
  15 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  16 -- for details
  17
  18 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
  19 {-
  20 Careful optimisation of the parser: we don't want to throw everything
  21 at it, because that takes too long and doesn't buy much, but we do want
  22 to inline certain key external functions, so we instruct GHC not to
  23 throw away inlinings as it would normally do in -O0 mode.
  24 -}
  25
  26 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
  27                 parseHeader ) where
  28
  29 import HsSyn
  30 import RdrHsSyn
  31 import HscTypes         ( IsBootInterface, WarningTxt(..) )
  32 import Lexer
  33 import RdrName
  34 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  35                           unboxedSingletonTyCon, unboxedSingletonDataCon,
  36                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  37 import Type             ( funTyCon )
  38 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
  39                           CCallConv(..), CCallTarget(..), defaultCCallConv
  40                         )
  41 import OccName          ( varName, dataName, tcClsName, tvName )
  42 import DataCon          ( DataCon, dataConName )
  43 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
  44                           SrcSpan, combineLocs, srcLocFile,
  45                           mkSrcLoc, mkSrcSpan )
  46 import Module
  47 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
  48 import Type             ( Kind, liftedTypeKind, unliftedTypeKind )
  49 import Coercion         ( mkArrowKind )
  50 import Class            ( FunDep )
  51 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  52                           Activation(..), RuleMatchInfo(..), defaultInlinePragma )
  53 import DynFlags
  54 import OrdList
  55 import HaddockUtils
  56
  57 import FastString
  58 import Maybes           ( orElse )
  59 import Outputable
  60
  61 import Control.Monad    ( unless )
  62 import GHC.Exts
  63 import Data.Char
  64 import Control.Monad    ( mplus )
  65 }
  66
  67 {-
  68 -----------------------------------------------------------------------------
  69 24 Februar 2006
  70
  71 Conflicts: 33 shift/reduce
  72            1 reduce/reduce
  73
  74 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  75 would think the two should never occur in the same context.
  76
  77   -=chak
  78
  79 -----------------------------------------------------------------------------
  80 31 December 2006
  81
  82 Conflicts: 34 shift/reduce
  83            1 reduce/reduce
  84
  85 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  86 would think the two should never occur in the same context.
  87
  88   -=chak
  89
  90 -----------------------------------------------------------------------------
  91 6 December 2006
  92
  93 Conflicts: 32 shift/reduce
  94            1 reduce/reduce
  95
  96 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  97 would think the two should never occur in the same context.
  98
  99   -=chak
 100
 101 -----------------------------------------------------------------------------
 102 26 July 2006
 103
 104 Conflicts: 37 shift/reduce
 105            1 reduce/reduce
 106
 107 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
 108 would think the two should never occur in the same context.
 109
 110   -=chak
 111
 112 -----------------------------------------------------------------------------
 113 Conflicts: 38 shift/reduce (1.25)
 114
 115 10 for abiguity in 'if x then y else z + 1'             [State 178]
 116         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
 117         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
 118
 119 1 for ambiguity in 'if x then y else z :: T'            [State 178]
 120         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
 121
 122 4 for ambiguity in 'if x then y else z -< e'            [State 178]
 123         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
 124         There are four such operators: -<, >-, -<<, >>-
 125
 126
 127 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
 128         Which of these two is intended?
 129           case v of
 130             (x::T) -> T         -- Rhs is T
 131     or
 132           case v of
 133             (x::T -> T) -> ..   -- Rhs is ...
 134
 135 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
 136         (e::a) `b` c, or
 137         (e :: (a `b` c))
 138     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
 139     Same duplication between states 11 and 253 as the previous case
 140
 141 1 for ambiguity in 'let ?x ...'                         [State 329]
 142         the parser can't tell whether the ?x is the lhs of a normal binding or
 143         an implicit binding.  Fortunately resolving as shift gives it the only
 144         sensible meaning, namely the lhs of an implicit binding.
 145
 146 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
 147         we don't know whether the '[' starts the activation or not: it
 148         might be the start of the declaration with the activation being
 149         empty.  --SDM 1/4/2002
 150
 151 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
 152         since 'forall' is a valid variable name, we don't know whether
 153         to treat a forall on the input as the beginning of a quantifier
 154         or the beginning of the rule itself.  Resolving to shift means
 155         it's always treated as a quantifier, hence the above is disallowed.
 156         This saves explicitly defining a grammar for the rule lhs that
 157         doesn't include 'forall'.
 158
 159 1 for ambiguity when the source file starts with "-- | doc". We need another
 160   token of lookahead to determine if a top declaration or the 'module' keyword
 161   follows. Shift parses as if the 'module' keyword follows.
 162
 163 -- ---------------------------------------------------------------------------
 164 -- Adding location info
 165
 166 This is done in a stylised way using the three macros below, L0, L1
 167 and LL.  Each of these macros can be thought of as having type
 168
 169    L0, L1, LL :: a -> Located a
 170
 171 They each add a SrcSpan to their argument.
 172
 173    L0   adds 'noSrcSpan', used for empty productions
 174      -- This doesn't seem to work anymore -=chak
 175
 176    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
 177         from that token.
 178
 179    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
 180         the first and last tokens.
 181
 182 These suffice for the majority of cases.  However, we must be
 183 especially careful with empty productions: LL won't work if the first
 184 or last token on the lhs can represent an empty span.  In these cases,
 185 we have to calculate the span using more of the tokens from the lhs, eg.
 186
 187         | 'newtype' tycl_hdr '=' newconstr deriving
 188                 { L (comb3 $1 $4 $5)
 189                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
 190
 191 We provide comb3 and comb4 functions which are useful in such cases.
 192
 193 Be careful: there's no checking that you actually got this right, the
 194 only symptom will be that the SrcSpans of your syntax will be
 195 incorrect.
 196
 197 /*
 198  * We must expand these macros *before* running Happy, which is why this file is
 199  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 200  */
 201 #define L0   L noSrcSpan
 202 #define L1   sL (getLoc $1)
 203 #define LL   sL (comb2 $1 $>)
 204
 205 -- -----------------------------------------------------------------------------
 206
 207 -}
 208
 209 %token
 210  '_'            { L _ ITunderscore }            -- Haskell keywords
 211  'as'           { L _ ITas }
 212  'case'         { L _ ITcase }
 213  'class'        { L _ ITclass }
 214  'data'         { L _ ITdata }
 215  'default'      { L _ ITdefault }
 216  'deriving'     { L _ ITderiving }
 217  'do'           { L _ ITdo }
 218  'else'         { L _ ITelse }
 219  'hiding'       { L _ IThiding }
 220  'if'           { L _ ITif }
 221  'import'       { L _ ITimport }
 222  'in'           { L _ ITin }
 223  'infix'        { L _ ITinfix }
 224  'infixl'       { L _ ITinfixl }
 225  'infixr'       { L _ ITinfixr }
 226  'instance'     { L _ ITinstance }
 227  'let'          { L _ ITlet }
 228  'module'       { L _ ITmodule }
 229  'newtype'      { L _ ITnewtype }
 230  'of'           { L _ ITof }
 231  'qualified'    { L _ ITqualified }
 232  'then'         { L _ ITthen }
 233  'type'         { L _ ITtype }
 234  'where'        { L _ ITwhere }
 235  '_scc_'        { L _ ITscc }         -- ToDo: remove
 236
 237  'forall'       { L _ ITforall }                -- GHC extension keywords
 238  'foreign'      { L _ ITforeign }
 239  'export'       { L _ ITexport }
 240  'label'        { L _ ITlabel }
 241  'dynamic'      { L _ ITdynamic }
 242  'safe'         { L _ ITsafe }
 243  'threadsafe'   { L _ ITthreadsafe }  -- ToDo: remove deprecated alias
 244  'unsafe'       { L _ ITunsafe }
 245  'mdo'          { L _ ITmdo }
 246  'family'       { L _ ITfamily }
 247  'stdcall'      { L _ ITstdcallconv }
 248  'ccall'        { L _ ITccallconv }
 249  'prim'         { L _ ITprimcallconv }
 250  'proc'         { L _ ITproc }          -- for arrow notation extension
 251  'rec'          { L _ ITrec }           -- for arrow notation extension
 252  'group'    { L _ ITgroup }     -- for list transform extension
 253  'by'       { L _ ITby }        -- for list transform extension
 254  'using'    { L _ ITusing }     -- for list transform extension
 255
 256  '{-# INLINE'             { L _ (ITinline_prag _) }
 257  '{-# INLINE_CONLIKE'     { L _ (ITinline_conlike_prag _) }
 258  '{-# SPECIALISE'         { L _ ITspec_prag }
 259  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
 260  '{-# SOURCE'      { L _ ITsource_prag }
 261  '{-# RULES'       { L _ ITrules_prag }
 262  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 263  '{-# SCC'         { L _ ITscc_prag }
 264  '{-# GENERATED'   { L _ ITgenerated_prag }
 265  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 266  '{-# WARNING'     { L _ ITwarning_prag }
 267  '{-# UNPACK'      { L _ ITunpack_prag }
 268  '{-# ANN'         { L _ ITann_prag }
 269  '#-}'             { L _ ITclose_prag }
 270
 271  '..'           { L _ ITdotdot }                        -- reserved symbols
 272  ':'            { L _ ITcolon }
 273  '::'           { L _ ITdcolon }
 274  '='            { L _ ITequal }
 275  '\\'           { L _ ITlam }
 276  '|'            { L _ ITvbar }
 277  '<-'           { L _ ITlarrow }
 278  '->'           { L _ ITrarrow }
 279  '@'            { L _ ITat }
 280  '~'            { L _ ITtilde }
 281  '=>'           { L _ ITdarrow }
 282  '-'            { L _ ITminus }
 283  '!'            { L _ ITbang }
 284  '*'            { L _ ITstar }
 285  '-<'           { L _ ITlarrowtail }            -- for arrow notation
 286  '>-'           { L _ ITrarrowtail }            -- for arrow notation
 287  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
 288  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
 289  '.'            { L _ ITdot }
 290
 291  '{'            { L _ ITocurly }                        -- special symbols
 292  '}'            { L _ ITccurly }
 293  '{|'           { L _ ITocurlybar }
 294  '|}'           { L _ ITccurlybar }
 295  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
 296  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
 297  '['            { L _ ITobrack }
 298  ']'            { L _ ITcbrack }
 299  '[:'           { L _ ITopabrack }
 300  ':]'           { L _ ITcpabrack }
 301  '('            { L _ IToparen }
 302  ')'            { L _ ITcparen }
 303  '(#'           { L _ IToubxparen }
 304  '#)'           { L _ ITcubxparen }
 305  '(|'           { L _ IToparenbar }
 306  '|)'           { L _ ITcparenbar }
 307  ';'            { L _ ITsemi }
 308  ','            { L _ ITcomma }
 309  '`'            { L _ ITbackquote }
 310
 311  VARID          { L _ (ITvarid    _) }          -- identifiers
 312  CONID          { L _ (ITconid    _) }
 313  VARSYM         { L _ (ITvarsym   _) }
 314  CONSYM         { L _ (ITconsym   _) }
 315  QVARID         { L _ (ITqvarid   _) }
 316  QCONID         { L _ (ITqconid   _) }
 317  QVARSYM        { L _ (ITqvarsym  _) }
 318  QCONSYM        { L _ (ITqconsym  _) }
 319  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
 320  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
 321
 322  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
 323
 324  CHAR           { L _ (ITchar     _) }
 325  STRING         { L _ (ITstring   _) }
 326  INTEGER        { L _ (ITinteger  _) }
 327  RATIONAL       { L _ (ITrational _) }
 328
 329  PRIMCHAR       { L _ (ITprimchar   _) }
 330  PRIMSTRING     { L _ (ITprimstring _) }
 331  PRIMINTEGER    { L _ (ITprimint    _) }
 332  PRIMWORD       { L _ (ITprimword  _) }
 333  PRIMFLOAT      { L _ (ITprimfloat  _) }
 334  PRIMDOUBLE     { L _ (ITprimdouble _) }
 335
 336  DOCNEXT        { L _ (ITdocCommentNext _) }
 337  DOCPREV        { L _ (ITdocCommentPrev _) }
 338  DOCNAMED       { L _ (ITdocCommentNamed _) }
 339  DOCSECTION     { L _ (ITdocSection _ _) }
 340
 341 -- Template Haskell
 342 '[|'            { L _ ITopenExpQuote  }
 343 '[p|'           { L _ ITopenPatQuote  }
 344 '[t|'           { L _ ITopenTypQuote  }
 345 '[d|'           { L _ ITopenDecQuote  }
 346 '|]'            { L _ ITcloseQuote    }
 347 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
 348 '$('            { L _ ITparenEscape   }     -- $( exp )
 349 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
 350 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
 351 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
 352
 353 %monad { P } { >>= } { return }
 354 %lexer { lexer } { L _ ITeof }
 355 %name parseModule module
 356 %name parseStmt   maybe_stmt
 357 %name parseIdentifier  identifier
 358 %name parseType ctype
 359 %partial parseHeader header
 360 %tokentype { (Located Token) }
 361 %%
 362
 363 -----------------------------------------------------------------------------
 364 -- Identifiers; one of the entry points
 365 identifier :: { Located RdrName }
 366         : qvar                          { $1 }
 367         | qcon                          { $1 }
 368         | qvarop                        { $1 }
 369         | qconop                        { $1 }
 370     | '(' '->' ')'      { LL $ getRdrName funTyCon }
 371
 372 -----------------------------------------------------------------------------
 373 -- Module Header
 374
 375 -- The place for module deprecation is really too restrictive, but if it
 376 -- was allowed at its natural place just before 'module', we get an ugly
 377 -- s/r conflict with the second alternative. Another solution would be the
 378 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 379 -- either, and DEPRECATED is only expected to be used by people who really
 380 -- know what they are doing. :-)
 381
 382 module  :: { Located (HsModule RdrName) }
 383         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
 384                 {% fileSrcSpan >>= \ loc ->
 385                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
 386                           ) )}
 387         | body2
 388                 {% fileSrcSpan >>= \ loc ->
 389                    return (L loc (HsModule Nothing Nothing
 390                           (fst $1) (snd $1) Nothing Nothing
 391                           )) }
 392
 393 maybedocheader :: { Maybe LHsDocString }
 394         : moduleheader            { $1 }
 395         | {- empty -}             { Nothing }
 396
 397 missing_module_keyword :: { () }
 398         : {- empty -}                           {% pushCurrentContext }
 399
 400 maybemodwarning :: { Maybe WarningTxt }
 401     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
 402     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
 403     |  {- empty -}                  { Nothing }
 404
 405 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 406         :  '{'            top '}'               { $2 }
 407         |      vocurly    top close             { $2 }
 408
 409 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 410         :  '{' top '}'                          { $2 }
 411         |  missing_module_keyword top close     { $2 }
 412
 413 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 414         : importdecls                           { (reverse $1,[]) }
 415         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 416         | cvtopdecls                            { ([],$1) }
 417
 418 cvtopdecls :: { [LHsDecl RdrName] }
 419         : topdecls                              { cvTopDecls $1 }
 420
 421 -----------------------------------------------------------------------------
 422 -- Module declaration & imports only
 423
 424 header  :: { Located (HsModule RdrName) }
 425         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
 426                 {% fileSrcSpan >>= \ loc ->
 427                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
 428                           ))}
 429         | missing_module_keyword importdecls
 430                 {% fileSrcSpan >>= \ loc ->
 431                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
 432                           Nothing)) }
 433
 434 header_body :: { [LImportDecl RdrName] }
 435         :  '{'            importdecls           { $2 }
 436         |      vocurly    importdecls           { $2 }
 437
 438 -----------------------------------------------------------------------------
 439 -- The Export List
 440
 441 maybeexports :: { Maybe [LIE RdrName] }
 442         :  '(' exportlist ')'                   { Just $2 }
 443         |  {- empty -}                          { Nothing }
 444
 445 exportlist :: { [LIE RdrName] }
 446         : expdoclist ',' expdoclist             { $1 ++ $3 }
 447         | exportlist1                           { $1 }
 448
 449 exportlist1 :: { [LIE RdrName] }
 450         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
 451         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
 452         | expdoclist                                   { $1 }
 453
 454 expdoclist :: { [LIE RdrName] }
 455         : exp_doc expdoclist                           { $1 : $2 }
 456         | {- empty -}                                  { [] }
 457
 458 exp_doc :: { LIE RdrName }
 459         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
 460         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) }
 461         | docnext       { L1 (IEDoc (unLoc $1)) }
 462
 463    -- No longer allow things like [] and (,,,) to be exported
 464    -- They are built in syntax, always available
 465 export  :: { LIE RdrName }
 466         :  qvar                         { L1 (IEVar (unLoc $1)) }
 467         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
 468         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
 469         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
 470         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
 471         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
 472
 473 qcnames :: { [RdrName] }
 474         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
 475         |  qcname_ext                   { [unLoc $1]  }
 476
 477 qcname_ext :: { Located RdrName }       -- Variable or data constructor
 478                                         -- or tagged type constructor
 479         :  qcname                       { $1 }
 480         |  'type' qcon                  { sL (comb2 $1 $2)
 481                                              (setRdrNameSpace (unLoc $2)
 482                                                               tcClsName)  }
 483
 484 -- Cannot pull into qcname_ext, as qcname is also used in expression.
 485 qcname  :: { Located RdrName }  -- Variable or data constructor
 486         :  qvar                         { $1 }
 487         |  qcon                         { $1 }
 488
 489 -----------------------------------------------------------------------------
 490 -- Import Declarations
 491
 492 -- import decls can be *empty*, or even just a string of semicolons
 493 -- whereas topdecls must contain at least one topdecl.
 494
 495 importdecls :: { [LImportDecl RdrName] }
 496         : importdecls ';' importdecl            { $3 : $1 }
 497         | importdecls ';'                       { $1 }
 498         | importdecl                            { [ $1 ] }
 499         | {- empty -}                           { [] }
 500
 501 importdecl :: { LImportDecl RdrName }
 502         : 'import' maybe_src optqualified maybe_pkg modid maybeas maybeimpspec
 503                 { L (comb4 $1 $5 $6 $7) (ImportDecl $5 $4 $2 $3 (unLoc $6) (unLoc $7)) }
 504
 505 maybe_src :: { IsBootInterface }
 506         : '{-# SOURCE' '#-}'                    { True }
 507         | {- empty -}                           { False }
 508
 509 maybe_pkg :: { Maybe FastString }
 510         : STRING                                { Just (getSTRING $1) }
 511         | {- empty -}                           { Nothing }
 512
 513 optqualified :: { Bool }
 514         : 'qualified'                           { True  }
 515         | {- empty -}                           { False }
 516
 517 maybeas :: { Located (Maybe ModuleName) }
 518         : 'as' modid                            { LL (Just (unLoc $2)) }
 519         | {- empty -}                           { noLoc Nothing }
 520
 521 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
 522         : impspec                               { L1 (Just (unLoc $1)) }
 523         | {- empty -}                           { noLoc Nothing }
 524
 525 impspec :: { Located (Bool, [LIE RdrName]) }
 526         :  '(' exportlist ')'                   { LL (False, $2) }
 527         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
 528
 529 -----------------------------------------------------------------------------
 530 -- Fixity Declarations
 531
 532 prec    :: { Int }
 533         : {- empty -}           { 9 }
 534         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
 535
 536 infix   :: { Located FixityDirection }
 537         : 'infix'                               { L1 InfixN  }
 538         | 'infixl'                              { L1 InfixL  }
 539         | 'infixr'                              { L1 InfixR }
 540
 541 ops     :: { Located [Located RdrName] }
 542         : ops ',' op                            { LL ($3 : unLoc $1) }
 543         | op                                    { L1 [$1] }
 544
 545 -----------------------------------------------------------------------------
 546 -- Top-Level Declarations
 547
 548 topdecls :: { OrdList (LHsDecl RdrName) }
 549         : topdecls ';' topdecl                  { $1 `appOL` $3 }
 550         | topdecls ';'                          { $1 }
 551         | topdecl                               { $1 }
 552
 553 topdecl :: { OrdList (LHsDecl RdrName) }
 554         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 555         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 556         | 'instance' inst_type where_inst
 557             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
 558               in
 559               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
 560         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
 561         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
 562         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
 563         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
 564         | '{-# WARNING' warnings '#-}'          { $2 }
 565         | '{-# RULES' rules '#-}'               { $2 }
 566         | annotation { unitOL $1 }
 567         | decl                                  { unLoc $1 }
 568
 569         -- Template Haskell Extension
 570         -- The $(..) form is one possible form of infixexp
 571         -- but we treat an arbitrary expression just as if
 572         -- it had a $(..) wrapped around it
 573         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) }
 574
 575 -- Type classes
 576 --
 577 cl_decl :: { LTyClDecl RdrName }
 578         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
 579
 580 -- Type declarations (toplevel)
 581 --
 582 ty_decl :: { LTyClDecl RdrName }
 583            -- ordinary type synonyms
 584         : 'type' type '=' ctypedoc
 585                 -- Note ctype, not sigtype, on the right of '='
 586                 -- We allow an explicit for-all but we don't insert one
 587                 -- in   type Foo a = (b,b)
 588                 -- Instead we just say b is out of scope
 589                 --
 590                 -- Note the use of type for the head; this allows
 591                 -- infix type constructors to be declared
 592                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
 593
 594            -- type family declarations
 595         | 'type' 'family' type opt_kind_sig
 596                 -- Note the use of type for the head; this allows
 597                 -- infix type constructors to be declared
 598                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
 599
 600            -- type instance declarations
 601         | 'type' 'instance' type '=' ctype
 602                 -- Note the use of type for the head; this allows
 603                 -- infix type constructors and type patterns
 604                 {% mkTySynonym (comb2 $1 $5) True $3 $5 }
 605
 606           -- ordinary data type or newtype declaration
 607         | data_or_newtype tycl_hdr constrs deriving
 608                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) False $2
 609                             Nothing (reverse (unLoc $3)) (unLoc $4) }
 610                                    -- We need the location on tycl_hdr in case
 611                                    -- constrs and deriving are both empty
 612
 613           -- ordinary GADT declaration
 614         | data_or_newtype tycl_hdr opt_kind_sig
 615                  gadt_constrlist
 616                  deriving
 617                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) False $2
 618                             (unLoc $3) (unLoc $4) (unLoc $5) }
 619                                    -- We need the location on tycl_hdr in case
 620                                    -- constrs and deriving are both empty
 621
 622           -- data/newtype family
 623         | 'data' 'family' type opt_kind_sig
 624                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
 625
 626           -- data/newtype instance declaration
 627         | data_or_newtype 'instance' tycl_hdr constrs deriving
 628                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $3
 629                             Nothing (reverse (unLoc $4)) (unLoc $5) }
 630
 631           -- GADT instance declaration
 632         | data_or_newtype 'instance' tycl_hdr opt_kind_sig
 633                  gadt_constrlist
 634                  deriving
 635                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $3
 636                             (unLoc $4) (unLoc $5) (unLoc $6) }
 637
 638 -- Associated type family declarations
 639 --
 640 -- * They have a different syntax than on the toplevel (no family special
 641 --   identifier).
 642 --
 643 -- * They also need to be separate from instances; otherwise, data family
 644 --   declarations without a kind signature cause parsing conflicts with empty
 645 --   data declarations.
 646 --
 647 at_decl_cls :: { LTyClDecl RdrName }
 648            -- type family declarations
 649         : 'type' type opt_kind_sig
 650                 -- Note the use of type for the head; this allows
 651                 -- infix type constructors to be declared
 652                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
 653
 654            -- default type instance
 655         | 'type' type '=' ctype
 656                 -- Note the use of type for the head; this allows
 657                 -- infix type constructors and type patterns
 658                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
 659
 660           -- data/newtype family declaration
 661         | 'data' type opt_kind_sig
 662                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
 663
 664 -- Associated type instances
 665 --
 666 at_decl_inst :: { LTyClDecl RdrName }
 667            -- type instance declarations
 668         : 'type' type '=' ctype
 669                 -- Note the use of type for the head; this allows
 670                 -- infix type constructors and type patterns
 671                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
 672
 673         -- data/newtype instance declaration
 674         | data_or_newtype tycl_hdr constrs deriving
 675                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) True $2
 676                             Nothing (reverse (unLoc $3)) (unLoc $4) }
 677
 678         -- GADT instance declaration
 679         | data_or_newtype tycl_hdr opt_kind_sig
 680                  gadt_constrlist
 681                  deriving
 682                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) True $2
 683                             (unLoc $3) (unLoc $4) (unLoc $5) }
 684
 685 data_or_newtype :: { Located NewOrData }
 686         : 'data'        { L1 DataType }
 687         | 'newtype'     { L1 NewType }
 688
 689 opt_kind_sig :: { Located (Maybe Kind) }
 690         :                               { noLoc Nothing }
 691         | '::' kind                     { LL (Just (unLoc $2)) }
 692
 693 -- tycl_hdr parses the header of a class or data type decl,
 694 -- which takes the form
 695 --      T a b
 696 --      Eq a => T a
 697 --      (Eq a, Ord b) => T a b
 698 --      T Int [a]                       -- for associated types
 699 -- Rather a lot of inlining here, else we get reduce/reduce errors
 700 tycl_hdr :: { Located (Maybe (LHsContext RdrName), LHsType RdrName) }
 701         : context '=>' type             { LL (Just $1, $3) }
 702         | type                          { L1 (Nothing, $1) }
 703
 704 -----------------------------------------------------------------------------
 705 -- Stand-alone deriving
 706
 707 -- Glasgow extension: stand-alone deriving declarations
 708 stand_alone_deriving :: { LDerivDecl RdrName }
 709         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
 710
 711 -----------------------------------------------------------------------------
 712 -- Nested declarations
 713
 714 -- Declaration in class bodies
 715 --
 716 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
 717 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 718           | decl                        { $1 }
 719
 720 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 721           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
 722           | decls_cls ';'               { LL (unLoc $1) }
 723           | decl_cls                    { $1 }
 724           | {- empty -}                 { noLoc nilOL }
 725
 726
 727 decllist_cls
 728         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 729         : '{'         decls_cls '}'     { LL (unLoc $2) }
 730         |     vocurly decls_cls close   { $2 }
 731
 732 -- Class body
 733 --
 734 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 735                                 -- No implicit parameters
 736                                 -- May have type declarations
 737         : 'where' decllist_cls          { LL (unLoc $2) }
 738         | {- empty -}                   { noLoc nilOL }
 739
 740 -- Declarations in instance bodies
 741 --
 742 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
 743 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 744            | decl                       { $1 }
 745
 746 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 747            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
 748            | decls_inst ';'             { LL (unLoc $1) }
 749            | decl_inst                  { $1 }
 750            | {- empty -}                { noLoc nilOL }
 751
 752 decllist_inst
 753         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 754         : '{'         decls_inst '}'    { LL (unLoc $2) }
 755         |     vocurly decls_inst close  { $2 }
 756
 757 -- Instance body
 758 --
 759 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 760                                 -- No implicit parameters
 761                                 -- May have type declarations
 762         : 'where' decllist_inst         { LL (unLoc $2) }
 763         | {- empty -}                   { noLoc nilOL }
 764
 765 -- Declarations in binding groups other than classes and instances
 766 --
 767 decls   :: { Located (OrdList (LHsDecl RdrName)) }
 768         : decls ';' decl                { let { this = unLoc $3;
 769                                     rest = unLoc $1;
 770                                     these = rest `appOL` this }
 771                               in rest `seq` this `seq` these `seq`
 772                                     LL these }
 773         | decls ';'                     { LL (unLoc $1) }
 774         | decl                          { $1 }
 775         | {- empty -}                   { noLoc nilOL }
 776
 777 decllist :: { Located (OrdList (LHsDecl RdrName)) }
 778         : '{'            decls '}'      { LL (unLoc $2) }
 779         |     vocurly    decls close    { $2 }
 780
 781 -- Binding groups other than those of class and instance declarations
 782 --
 783 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
 784                                                 -- No type declarations
 785         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
 786         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 787         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 788
 789 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
 790                                                 -- No type declarations
 791         : 'where' binds                 { LL (unLoc $2) }
 792         | {- empty -}                   { noLoc emptyLocalBinds }
 793
 794
 795 -----------------------------------------------------------------------------
 796 -- Transformation Rules
 797
 798 rules   :: { OrdList (LHsDecl RdrName) }
 799         :  rules ';' rule                       { $1 `snocOL` $3 }
 800         |  rules ';'                            { $1 }
 801         |  rule                                 { unitOL $1 }
 802         |  {- empty -}                          { nilOL }
 803
 804 rule    :: { LHsDecl RdrName }
 805         : STRING activation rule_forall infixexp '=' exp
 806              { LL $ RuleD (HsRule (getSTRING $1)
 807                                   ($2 `orElse` AlwaysActive)
 808                                   $3 $4 placeHolderNames $6 placeHolderNames) }
 809
 810 activation :: { Maybe Activation }
 811         : {- empty -}                           { Nothing }
 812         | explicit_activation                   { Just $1 }
 813
 814 explicit_activation :: { Activation }  -- In brackets
 815         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
 816         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
 817
 818 rule_forall :: { [RuleBndr RdrName] }
 819         : 'forall' rule_var_list '.'            { $2 }
 820         | {- empty -}                           { [] }
 821
 822 rule_var_list :: { [RuleBndr RdrName] }
 823         : rule_var                              { [$1] }
 824         | rule_var rule_var_list                { $1 : $2 }
 825
 826 rule_var :: { RuleBndr RdrName }
 827         : varid                                 { RuleBndr $1 }
 828         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 829
 830 -----------------------------------------------------------------------------
 831 -- Warnings and deprecations (c.f. rules)
 832
 833 warnings :: { OrdList (LHsDecl RdrName) }
 834         : warnings ';' warning          { $1 `appOL` $3 }
 835         | warnings ';'                  { $1 }
 836         | warning                               { $1 }
 837         | {- empty -}                           { nilOL }
 838
 839 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 840 warning :: { OrdList (LHsDecl RdrName) }
 841         : namelist strings
 842                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
 843                        | n <- unLoc $1 ] }
 844
 845 deprecations :: { OrdList (LHsDecl RdrName) }
 846         : deprecations ';' deprecation          { $1 `appOL` $3 }
 847         | deprecations ';'                      { $1 }
 848         | deprecation                           { $1 }
 849         | {- empty -}                           { nilOL }
 850
 851 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 852 deprecation :: { OrdList (LHsDecl RdrName) }
 853         : namelist strings
 854                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
 855                        | n <- unLoc $1 ] }
 856
 857 strings :: { Located [FastString] }
 858     : STRING { L1 [getSTRING $1] }
 859     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
 860
 861 stringlist :: { Located (OrdList FastString) }
 862     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
 863     | STRING                { LL (unitOL (getSTRING $1)) }
 864
 865 -----------------------------------------------------------------------------
 866 -- Annotations
 867 annotation :: { LHsDecl RdrName }
 868     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
 869     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
 870     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
 871
 872
 873 -----------------------------------------------------------------------------
 874 -- Foreign import and export declarations
 875
 876 fdecl :: { LHsDecl RdrName }
 877 fdecl : 'import' callconv safety fspec
 878                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
 879       | 'import' callconv        fspec
 880                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
 881                         return (LL d) } }
 882       | 'export' callconv fspec
 883                 {% mkExport $2 (unLoc $3) >>= return.LL }
 884
 885 callconv :: { CCallConv }
 886           : 'stdcall'                   { StdCallConv }
 887           | 'ccall'                     { CCallConv   }
 888           | 'prim'                      { PrimCallConv}
 889
 890 safety :: { Safety }
 891         : 'unsafe'                      { PlayRisky }
 892         | 'safe'                        { PlaySafe  False }
 893         | 'threadsafe'                  { PlaySafe  True } -- deprecated alias
 894
 895 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
 896        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
 897        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
 898          -- if the entity string is missing, it defaults to the empty string;
 899          -- the meaning of an empty entity string depends on the calling
 900          -- convention
 901
 902 -----------------------------------------------------------------------------
 903 -- Type signatures
 904
 905 opt_sig :: { Maybe (LHsType RdrName) }
 906         : {- empty -}                   { Nothing }
 907         | '::' sigtype                  { Just $2 }
 908
 909 opt_asig :: { Maybe (LHsType RdrName) }
 910         : {- empty -}                   { Nothing }
 911         | '::' atype                    { Just $2 }
 912
 913 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
 914                                         -- to tell the renamer where to generalise
 915         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 916         -- Wrap an Implicit forall if there isn't one there already
 917
 918 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
 919         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 920         -- Wrap an Implicit forall if there isn't one there already
 921
 922 sig_vars :: { Located [Located RdrName] }
 923          : sig_vars ',' var             { LL ($3 : unLoc $1) }
 924          | var                          { L1 [$1] }
 925
 926 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
 927         : sigtype                       { [ $1 ] }
 928         | sigtype ',' sigtypes1         { $1 : $3 }
 929
 930 -----------------------------------------------------------------------------
 931 -- Types
 932
 933 infixtype :: { LHsType RdrName }
 934         : btype qtyconop type         { LL $ HsOpTy $1 $2 $3 }
 935         | btype tyvarop  type    { LL $ HsOpTy $1 $2 $3 }
 936
 937 strict_mark :: { Located HsBang }
 938         : '!'                           { L1 HsStrict }
 939         | '{-# UNPACK' '#-}' '!'        { LL HsUnpack }
 940
 941 -- A ctype is a for-all type
 942 ctype   :: { LHsType RdrName }
 943         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 944         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
 945         -- A type of form (context => type) is an *implicit* HsForAllTy
 946         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 947         | type                          { $1 }
 948
 949 ----------------------
 950 -- Notes for 'ctypedoc'
 951 -- It would have been nice to simplify the grammar by unifying `ctype` and
 952 -- ctypedoc` into one production, allowing comments on types everywhere (and
 953 -- rejecting them after parsing, where necessary).  This is however not possible
 954 -- since it leads to ambiguity. The reason is the support for comments on record
 955 -- fields:
 956 --         data R = R { field :: Int -- ^ comment on the field }
 957 -- If we allow comments on types here, it's not clear if the comment applies
 958 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
 959
 960 ctypedoc :: { LHsType RdrName }
 961         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 962         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
 963         -- A type of form (context => type) is an *implicit* HsForAllTy
 964         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 965         | typedoc                       { $1 }
 966
 967 ----------------------
 968 -- Notes for 'context'
 969 -- We parse a context as a btype so that we don't get reduce/reduce
 970 -- errors in ctype.  The basic problem is that
 971 --      (Eq a, Ord a)
 972 -- looks so much like a tuple type.  We can't tell until we find the =>
 973
 974 -- We have the t1 ~ t2 form both in 'context' and in type,
 975 -- to permit an individual equational constraint without parenthesis.
 976 -- Thus for some reason we allow    f :: a~b => blah
 977 -- but not                          f :: ?x::Int => blah
 978 context :: { LHsContext RdrName }
 979         : btype '~'      btype          {% checkContext
 980                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
 981         | btype                         {% checkContext $1 }
 982
 983 type :: { LHsType RdrName }
 984         : btype                         { $1 }
 985         | btype qtyconop type           { LL $ HsOpTy $1 $2 $3 }
 986         | btype tyvarop  type           { LL $ HsOpTy $1 $2 $3 }
 987         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
 988         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
 989
 990 typedoc :: { LHsType RdrName }
 991         : btype                          { $1 }
 992         | btype docprev                  { LL $ HsDocTy $1 $2 }
 993         | btype qtyconop type            { LL $ HsOpTy $1 $2 $3 }
 994         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
 995         | btype tyvarop  type            { LL $ HsOpTy $1 $2 $3 }
 996         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
 997         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
 998         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
 999         | btype '~'      btype           { LL $ HsPredTy (HsEqualP $1 $3) }
1000
1001 btype :: { LHsType RdrName }
1002         : btype atype                   { LL $ HsAppTy $1 $2 }
1003         | atype                         { $1 }
1004
1005 atype :: { LHsType RdrName }
1006         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1007         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1008         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1009         | '{' fielddecls '}'            { LL $ HsRecTy $2 }              -- Constructor sigs only
1010         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1011         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1012         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1013         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1014         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1015         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1016         | quasiquote                    { L1 (HsQuasiQuoteTy (unLoc $1)) }
1017         | '$(' exp ')'                  { LL $ mkHsSpliceTy $2 }
1018         | TH_ID_SPLICE                  { LL $ mkHsSpliceTy $ L1 $ HsVar $
1019                                           mkUnqual varName (getTH_ID_SPLICE $1) }
1020 -- Generics
1021         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
1022
1023 -- An inst_type is what occurs in the head of an instance decl
1024 --      e.g.  (Foo a, Gaz b) => Wibble a b
1025 -- It's kept as a single type, with a MonoDictTy at the right
1026 -- hand corner, for convenience.
1027 inst_type :: { LHsType RdrName }
1028         : sigtype                       {% checkInstType $1 }
1029
1030 inst_types1 :: { [LHsType RdrName] }
1031         : inst_type                     { [$1] }
1032         | inst_type ',' inst_types1     { $1 : $3 }
1033
1034 comma_types0  :: { [LHsType RdrName] }
1035         : comma_types1                  { $1 }
1036         | {- empty -}                   { [] }
1037
1038 comma_types1    :: { [LHsType RdrName] }
1039         : ctype                         { [$1] }
1040         | ctype  ',' comma_types1       { $1 : $3 }
1041
1042 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1043          : tv_bndr tv_bndrs             { $1 : $2 }
1044          | {- empty -}                  { [] }
1045
1046 tv_bndr :: { LHsTyVarBndr RdrName }
1047         : tyvar                         { L1 (UserTyVar (unLoc $1) placeHolderKind) }
1048         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2)
1049                                                           (unLoc $4)) }
1050
1051 fds :: { Located [Located (FunDep RdrName)] }
1052         : {- empty -}                   { noLoc [] }
1053         | '|' fds1                      { LL (reverse (unLoc $2)) }
1054
1055 fds1 :: { Located [Located (FunDep RdrName)] }
1056         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1057         | fd                            { L1 [$1] }
1058
1059 fd :: { Located (FunDep RdrName) }
1060         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1061                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1062
1063 varids0 :: { Located [RdrName] }
1064         : {- empty -}                   { noLoc [] }
1065         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1066
1067 -----------------------------------------------------------------------------
1068 -- Kinds
1069
1070 kind    :: { Located Kind }
1071         : akind                 { $1 }
1072         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1073
1074 akind   :: { Located Kind }
1075         : '*'                   { L1 liftedTypeKind }
1076         | '!'                   { L1 unliftedTypeKind }
1077         | '(' kind ')'          { LL (unLoc $2) }
1078
1079
1080 -----------------------------------------------------------------------------
1081 -- Datatype declarations
1082
1083 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1084         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1085         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1086         | {- empty -}                              { noLoc [] }
1087
1088 gadt_constrs :: { Located [LConDecl RdrName] }
1089         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1090         | gadt_constr                   { L (getLoc (head $1)) $1 }
1091         | {- empty -}                   { noLoc [] }
1092
1093 -- We allow the following forms:
1094 --      C :: Eq a => a -> T a
1095 --      C :: forall a. Eq a => !a -> T a
1096 --      D { x,y :: a } :: T a
1097 --      forall a. Eq a => D { x,y :: a } :: T a
1098
1099 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1100         : con_list '::' sigtype
1101                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) }
1102
1103                 -- Deprecated syntax for GADT record declarations
1104         | oqtycon '{' fielddecls '}' '::' sigtype
1105                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1106                       ; return [cd] } }
1107
1108 constrs :: { Located [LConDecl RdrName] }
1109         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1110
1111 constrs1 :: { Located [LConDecl RdrName] }
1112         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1113         | constr                                          { L1 [$1] }
1114
1115 constr :: { LConDecl RdrName }
1116         : maybe_docnext forall context '=>' constr_stuff maybe_docprev
1117                 { let (con,details) = unLoc $5 in
1118                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1119                             ($1 `mplus` $6) }
1120         | maybe_docnext forall constr_stuff maybe_docprev
1121                 { let (con,details) = unLoc $3 in
1122                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1123                             ($1 `mplus` $4) }
1124
1125 forall :: { Located [LHsTyVarBndr RdrName] }
1126         : 'forall' tv_bndrs '.'         { LL $2 }
1127         | {- empty -}                   { noLoc [] }
1128
1129 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1130 -- We parse the constructor declaration
1131 --      C t1 t2
1132 -- as a btype (treating C as a type constructor) and then convert C to be
1133 -- a data constructor.  Reason: it might continue like this:
1134 --      C t1 t2 %: D Int
1135 -- in which case C really would be a type constructor.  We can't resolve this
1136 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1137         : btype                         {% splitCon $1 >>= return.LL }
1138         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1139
1140 fielddecls :: { [ConDeclField RdrName] }
1141         : {- empty -}     { [] }
1142         | fielddecls1     { $1 }
1143
1144 fielddecls1 :: { [ConDeclField RdrName] }
1145         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1146                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1147                              -- This adds the doc $4 to each field separately
1148         | fielddecl   { $1 }
1149
1150 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1151         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5)
1152                                                                  | fld <- reverse (unLoc $2) ] }
1153
1154 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1155 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1156 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1157 -- We don't allow a context, but that's sorted out by the type checker.
1158 deriving :: { Located (Maybe [LHsType RdrName]) }
1159         : {- empty -}                           { noLoc Nothing }
1160         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1161                                       ; p <- checkInstType (L loc (HsTyVar tv))
1162                                       ; return (LL (Just [p])) } }
1163         | 'deriving' '(' ')'                    { LL (Just []) }
1164         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1165              -- Glasgow extension: allow partial
1166              -- applications in derivings
1167
1168 -----------------------------------------------------------------------------
1169 -- Value definitions
1170
1171 {- Note [Declaration/signature overlap]
1172 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1173 There's an awkward overlap with a type signature.  Consider
1174         f :: Int -> Int = ...rhs...
1175    Then we can't tell whether it's a type signature or a value
1176    definition with a result signature until we see the '='.
1177    So we have to inline enough to postpone reductions until we know.
1178 -}
1179
1180 {-
1181   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1182   instead of qvar, we get another shift/reduce-conflict. Consider the
1183   following programs:
1184
1185      { (^^) :: Int->Int ; }          Type signature; only var allowed
1186
1187      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1188                                      qvar allowed (because of instance decls)
1189
1190   We can't tell whether to reduce var to qvar until after we've read the signatures.
1191 -}
1192
1193 docdecl :: { LHsDecl RdrName }
1194         : docdecld { L1 (DocD (unLoc $1)) }
1195
1196 docdecld :: { LDocDecl }
1197         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1198         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1199         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1200         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1201
1202 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1203         : sigdecl                       { $1 }
1204         | '!' aexp rhs                  {% do { pat <- checkPattern $2;
1205                                                 return (LL $ unitOL $ LL $ ValD (
1206                                                         PatBind (LL $ BangPat pat) (unLoc $3)
1207                                                                 placeHolderType placeHolderNames)) } }
1208         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
1209                                                 let { l = comb2 $1 $> };
1210                                                 return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1211         | docdecl                       { LL $ unitOL $1 }
1212
1213 rhs     :: { Located (GRHSs RdrName) }
1214         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1215         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1216
1217 gdrhs :: { Located [LGRHS RdrName] }
1218         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1219         | gdrh                  { L1 [$1] }
1220
1221 gdrh :: { LGRHS RdrName }
1222         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1223
1224 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1225         : infixexp '::' sigtypedoc      {% do s <- checkValSig $1 $3
1226                                          ; return (LL $ unitOL (LL $ SigD s)) }
1227                 -- See Note [Declaration/signature overlap] for why we need infixexp here
1228         | var ',' sig_vars '::' sigtypedoc
1229                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1230         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1231                                              | n <- unLoc $3 ] }
1232         | '{-# INLINE'   activation qvar '#-}'
1233                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma $2 FunLike (getINLINE $1)))) }
1234         | '{-# INLINE_CONLIKE' activation qvar '#-}'
1235                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma $2 ConLike (getINLINE_CONLIKE $1)))) }
1236         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1237                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlinePragma)
1238                                             | t <- $4] }
1239         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1240                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma $2 FunLike (getSPEC_INLINE $1)))
1241                                             | t <- $5] }
1242         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1243                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1244
1245 -----------------------------------------------------------------------------
1246 -- Expressions
1247
1248 quasiquote :: { Located (HsQuasiQuote RdrName) }
1249         : TH_QUASIQUOTE   { let { loc = getLoc $1
1250                                 ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1251                                 ; quoterId = mkUnqual varName quoter }
1252                             in L1 (mkHsQuasiQuote quoterId quoteSpan quote) }
1253
1254 exp   :: { LHsExpr RdrName }
1255         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1256         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1257         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1258         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1259         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1260         | infixexp                      { $1 }
1261
1262 infixexp :: { LHsExpr RdrName }
1263         : exp10                         { $1 }
1264         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1265
1266 exp10 :: { LHsExpr RdrName }
1267         : '\\' apat apats opt_asig '->' exp
1268                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1269                                                                 (unguardedGRHSs $6)
1270                                                             ]) }
1271         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1272         | 'if' exp optSemi 'then' exp optSemi 'else' exp
1273                                         {% checkDoAndIfThenElse $2 $3 $5 $6 $8 >>
1274                                            return (LL $ HsIf $2 $5 $8) }
1275         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1276         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1277
1278         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1279                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1280                                            return (L loc (mkHsDo DoExpr stmts body)) }
1281         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1282                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1283                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1284         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1285                                                         then HsSCC (unLoc $1) $2
1286                                                         else HsPar $2 }
1287         | hpc_annot exp                         { LL $ if opt_Hpc
1288                                                         then HsTickPragma (unLoc $1) $2
1289                                                         else HsPar $2 }
1290
1291         | 'proc' aexp '->' exp
1292                         {% checkPattern $2 >>= \ p ->
1293                            return (LL $ HsProc p (LL $ HsCmdTop $4 []
1294                                                    placeHolderType undefined)) }
1295                                                 -- TODO: is LL right here?
1296
1297         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1298                                                     -- hdaume: core annotation
1299         | fexp                                  { $1 }
1300
1301 optSemi :: { Bool }
1302         : ';'         { True }
1303         | {- empty -} { False }
1304
1305 scc_annot :: { Located FastString }
1306         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1307                                    ( do scc <- getSCC $2; return $ LL scc ) }
1308         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1309
1310 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1311         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1312                                                 { LL $ (getSTRING $2
1313                                                        ,( fromInteger $ getINTEGER $3
1314                                                         , fromInteger $ getINTEGER $5
1315                                                         )
1316                                                        ,( fromInteger $ getINTEGER $7
1317                                                         , fromInteger $ getINTEGER $9
1318                                                         )
1319                                                        )
1320                                                  }
1321
1322 fexp    :: { LHsExpr RdrName }
1323         : fexp aexp                             { LL $ HsApp $1 $2 }
1324         | aexp                                  { $1 }
1325
1326 aexp    :: { LHsExpr RdrName }
1327         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1328         | '~' aexp                      { LL $ ELazyPat $2 }
1329         | aexp1                 { $1 }
1330
1331 aexp1   :: { LHsExpr RdrName }
1332         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1333                                       ; return (LL r) }}
1334         | aexp2                 { $1 }
1335
1336 -- Here was the syntax for type applications that I was planning
1337 -- but there are difficulties (e.g. what order for type args)
1338 -- so it's not enabled yet.
1339 -- But this case *is* used for the left hand side of a generic definition,
1340 -- which is parsed as an expression before being munged into a pattern
1341         | qcname '{|' type '|}'         { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1342                                                      (sL (getLoc $3) (HsType $3)) }
1343
1344 aexp2   :: { LHsExpr RdrName }
1345         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1346         | qcname                        { L1 (HsVar   $! unLoc $1) }
1347         | literal                       { L1 (HsLit   $! unLoc $1) }
1348 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1349 -- into HsOverLit when -foverloaded-strings is on.
1350 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1351         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1352         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1353
1354         -- N.B.: sections get parsed by these next two productions.
1355         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't correct Haskell98
1356         -- (you'd have to write '((+ 3), (4 -))')
1357         -- but the less cluttered version fell out of having texps.
1358         | '(' texp ')'                  { LL (HsPar $2) }
1359         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1360
1361         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1362         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1363
1364         | '[' list ']'                  { LL (unLoc $2) }
1365         | '[:' parr ':]'                { LL (unLoc $2) }
1366         | '_'                           { L1 EWildPat }
1367
1368         -- Template Haskell Extension
1369         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice
1370                                         (L1 $ HsVar (mkUnqual varName
1371                                                         (getTH_ID_SPLICE $1)))) }
1372         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }
1373
1374
1375         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1376         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1377         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1378         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1379         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }
1380         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }
1381         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1382                                         return (LL $ HsBracket (PatBr p)) }
1383         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBrL $2) }
1384         | quasiquote            { L1 (HsQuasiQuoteE (unLoc $1)) }
1385
1386         -- arrow notation extension
1387         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1388
1389 cmdargs :: { [LHsCmdTop RdrName] }
1390         : cmdargs acmd                  { $2 : $1 }
1391         | {- empty -}                   { [] }
1392
1393 acmd    :: { LHsCmdTop RdrName }
1394         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1395
1396 cvtopbody :: { [LHsDecl RdrName] }
1397         :  '{'            cvtopdecls0 '}'               { $2 }
1398         |      vocurly    cvtopdecls0 close             { $2 }
1399
1400 cvtopdecls0 :: { [LHsDecl RdrName] }
1401         : {- empty -}           { [] }
1402         | cvtopdecls            { $1 }
1403
1404 -----------------------------------------------------------------------------
1405 -- Tuple expressions
1406
1407 -- "texp" is short for tuple expressions:
1408 -- things that can appear unparenthesized as long as they're
1409 -- inside parens or delimitted by commas
1410 texp :: { LHsExpr RdrName }
1411         : exp                           { $1 }
1412
1413         -- Note [Parsing sections]
1414         -- ~~~~~~~~~~~~~~~~~~~~~~~
1415         -- We include left and right sections here, which isn't
1416         -- technically right according to Haskell 98.  For example
1417         --      (3 +, True) isn't legal
1418         -- However, we want to parse bang patterns like
1419         --      (!x, !y)
1420         -- and it's convenient to do so here as a section
1421         -- Then when converting expr to pattern we unravel it again
1422         -- Meanwhile, the renamer checks that real sections appear
1423         -- inside parens.
1424         | infixexp qop  { LL $ SectionL $1 $2 }
1425         | qopm infixexp       { LL $ SectionR $1 $2 }
1426
1427        -- View patterns get parenthesized above
1428         | exp '->' texp   { LL $ EViewPat $1 $3 }
1429
1430 -- Always at least one comma
1431 tup_exprs :: { [HsTupArg RdrName] }
1432            : texp commas_tup_tail  { Present $1 : $2 }
1433            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1434
1435 -- Always starts with commas; always follows an expr
1436 commas_tup_tail :: { [HsTupArg RdrName] }
1437 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1438
1439 -- Always follows a comma
1440 tup_tail :: { [HsTupArg RdrName] }
1441           : texp commas_tup_tail        { Present $1 : $2 }
1442           | texp                        { [Present $1] }
1443           | {- empty -}                 { [missingTupArg] }
1444
1445 -----------------------------------------------------------------------------
1446 -- List expressions
1447
1448 -- The rules below are little bit contorted to keep lexps left-recursive while
1449 -- avoiding another shift/reduce-conflict.
1450
1451 list :: { LHsExpr RdrName }
1452         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1453         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1454         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1455         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1456         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1457         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1458         | texp '|' flattenedpquals      { sL (comb2 $1 $>) $ mkHsDo ListComp (unLoc $3) $1 }
1459
1460 lexps :: { Located [LHsExpr RdrName] }
1461         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1462         | texp ',' texp                 { LL [$3,$1] }
1463
1464 -----------------------------------------------------------------------------
1465 -- List Comprehensions
1466
1467 flattenedpquals :: { Located [LStmt RdrName] }
1468     : pquals   { case (unLoc $1) of
1469                     [qs] -> L1 qs
1470                     -- We just had one thing in our "parallel" list so
1471                     -- we simply return that thing directly
1472
1473                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss]]
1474                     -- We actually found some actual parallel lists so
1475                     -- we wrap them into as a ParStmt
1476                 }
1477
1478 pquals :: { Located [[LStmt RdrName]] }
1479     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1480     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1481
1482 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last
1483                                         -- one can "grab" the earlier ones
1484     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1485     | squals ',' qual                        { LL ($3 : unLoc $1) }
1486     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1487     | qual                                   { L1 [$1] }
1488 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1489 --  | '{|' pquals '|}'                       { L1 [$2] }
1490
1491
1492 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1493 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1494 -- demand. Note that the {| |} symbols are reused from -XGenerics and hence if you want to compile
1495 -- a program that makes use of this temporary syntax you must supply that flag to GHC
1496
1497 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1498                         -- Function is applied to a list of stmts *in order*
1499     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt leftStmts $2) }
1500     -- >>>
1501     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt leftStmts $2 $4) }
1502     | 'then' 'group' 'by' exp   { LL $ \leftStmts -> (mkGroupByStmt leftStmts $4) }
1503     -- <<<
1504     -- These two productions deliberately have a shift-reduce conflict. I have made 'group' into a special_id,
1505     -- which means you can enable TransformListComp while still using Data.List.group. However, this makes the two
1506     -- productions ambiguous. I've set things up so that Happy chooses to resolve the conflict in that case by
1507     -- choosing the "group by" variant, which is what we want.
1508     --
1509     -- This is rather dubious: the user might be confused as to how to parse this statement. However, it is a good
1510     -- practical choice. NB: Data.List.group :: [a] -> [[a]], so using the first production would not even type check
1511     -- if /that/ is the group function we conflict with.
1512     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt leftStmts $4) }
1513     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt leftStmts $4 $6) }
1514
1515 -----------------------------------------------------------------------------
1516 -- Parallel array expressions
1517
1518 -- The rules below are little bit contorted; see the list case for details.
1519 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1520 -- Moreover, we allow explicit arrays with no element (represented by the nil
1521 -- constructor in the list case).
1522
1523 parr :: { LHsExpr RdrName }
1524         :                               { noLoc (ExplicitPArr placeHolderType []) }
1525         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1526         | lexps                         { L1 $ ExplicitPArr placeHolderType
1527                                                        (reverse (unLoc $1)) }
1528         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1529         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1530         | texp '|' flattenedpquals      { LL $ mkHsDo PArrComp (unLoc $3) $1 }
1531
1532 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1533
1534 -----------------------------------------------------------------------------
1535 -- Guards
1536
1537 guardquals :: { Located [LStmt RdrName] }
1538     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1539
1540 guardquals1 :: { Located [LStmt RdrName] }
1541     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1542     | qual                  { L1 [$1] }
1543
1544 -----------------------------------------------------------------------------
1545 -- Case alternatives
1546
1547 altslist :: { Located [LMatch RdrName] }
1548         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1549         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1550
1551 alts    :: { Located [LMatch RdrName] }
1552         : alts1                         { L1 (unLoc $1) }
1553         | ';' alts                      { LL (unLoc $2) }
1554
1555 alts1   :: { Located [LMatch RdrName] }
1556         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1557         | alts1 ';'                     { LL (unLoc $1) }
1558         | alt                           { L1 [$1] }
1559
1560 alt     :: { LMatch RdrName }
1561         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1562
1563 alt_rhs :: { Located (GRHSs RdrName) }
1564         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1565
1566 ralt :: { Located [LGRHS RdrName] }
1567         : '->' exp                      { LL (unguardedRHS $2) }
1568         | gdpats                        { L1 (reverse (unLoc $1)) }
1569
1570 gdpats :: { Located [LGRHS RdrName] }
1571         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1572         | gdpat                         { L1 [$1] }
1573
1574 gdpat   :: { LGRHS RdrName }
1575         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1576
1577 -- 'pat' recognises a pattern, including one with a bang at the top
1578 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1579 -- Bangs inside are parsed as infix operator applications, so that
1580 -- we parse them right when bang-patterns are off
1581 pat     :: { LPat RdrName }
1582 pat     :  exp                  {% checkPattern $1 }
1583         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1584
1585 apat   :: { LPat RdrName }
1586 apat    : aexp                  {% checkPattern $1 }
1587         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1588
1589 apats  :: { [LPat RdrName] }
1590         : apat apats            { $1 : $2 }
1591         | {- empty -}           { [] }
1592
1593 -----------------------------------------------------------------------------
1594 -- Statement sequences
1595
1596 stmtlist :: { Located [LStmt RdrName] }
1597         : '{'           stmts '}'       { LL (unLoc $2) }
1598         |     vocurly   stmts close     { $2 }
1599
1600 --      do { ;; s ; s ; ; s ;; }
1601 -- The last Stmt should be an expression, but that's hard to enforce
1602 -- here, because we need too much lookahead if we see do { e ; }
1603 -- So we use ExprStmts throughout, and switch the last one over
1604 -- in ParseUtils.checkDo instead
1605 stmts :: { Located [LStmt RdrName] }
1606         : stmt stmts_help               { LL ($1 : unLoc $2) }
1607         | ';' stmts                     { LL (unLoc $2) }
1608         | {- empty -}                   { noLoc [] }
1609
1610 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1611         : ';' stmts                     { LL (unLoc $2) }
1612         | {- empty -}                   { noLoc [] }
1613
1614 -- For typing stmts at the GHCi prompt, where
1615 -- the input may consist of just comments.
1616 maybe_stmt :: { Maybe (LStmt RdrName) }
1617         : stmt                          { Just $1 }
1618         | {- nothing -}                 { Nothing }
1619
1620 stmt  :: { LStmt RdrName }
1621         : qual                              { $1 }
1622         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1623
1624 qual  :: { LStmt RdrName }
1625     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1626     | exp                                   { L1 $ mkExprStmt $1 }
1627     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1628
1629 -----------------------------------------------------------------------------
1630 -- Record Field Update/Construction
1631
1632 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1633         : fbinds1                       { $1 }
1634         | {- empty -}                   { ([], False) }
1635
1636 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1637         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) }
1638         | fbind                         { ([$1], False) }
1639         | '..'                          { ([],   True) }
1640
1641 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1642         : qvar '=' exp  { HsRecField $1 $3                False }
1643         | qvar          { HsRecField $1 placeHolderPunRhs True }
1644                         -- In the punning case, use a place-holder
1645                         -- The renamer fills in the final value
1646
1647 -----------------------------------------------------------------------------
1648 -- Implicit Parameter Bindings
1649
1650 dbinds  :: { Located [LIPBind RdrName] }
1651         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1652                               in rest `seq` this `seq` LL (this : rest) }
1653         | dbinds ';'                    { LL (unLoc $1) }
1654         | dbind                         { let this = $1 in this `seq` L1 [this] }
1655 --      | {- empty -}                   { [] }
1656
1657 dbind   :: { LIPBind RdrName }
1658 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1659
1660 ipvar   :: { Located (IPName RdrName) }
1661         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1662
1663 -----------------------------------------------------------------------------
1664 -- Warnings and deprecations
1665
1666 namelist :: { Located [RdrName] }
1667 namelist : name_var              { L1 [unLoc $1] }
1668          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1669
1670 name_var :: { Located RdrName }
1671 name_var : var { $1 }
1672          | con { $1 }
1673
1674 -----------------------------------------
1675 -- Data constructors
1676 qcon    :: { Located RdrName }
1677         : qconid                { $1 }
1678         | '(' qconsym ')'       { LL (unLoc $2) }
1679         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1680 -- The case of '[:' ':]' is part of the production `parr'
1681
1682 con     :: { Located RdrName }
1683         : conid                 { $1 }
1684         | '(' consym ')'        { LL (unLoc $2) }
1685         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1686
1687 con_list :: { Located [Located RdrName] }
1688 con_list : con                  { L1 [$1] }
1689          | con ',' con_list     { LL ($1 : unLoc $3) }
1690
1691 sysdcon :: { Located DataCon }  -- Wired in data constructors
1692         : '(' ')'               { LL unitDataCon }
1693         | '(' commas ')'        { LL $ tupleCon Boxed ($2 + 1) }
1694         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1695         | '(#' commas '#)'      { LL $ tupleCon Unboxed ($2 + 1) }
1696         | '[' ']'               { LL nilDataCon }
1697
1698 conop :: { Located RdrName }
1699         : consym                { $1 }
1700         | '`' conid '`'         { LL (unLoc $2) }
1701
1702 qconop :: { Located RdrName }
1703         : qconsym               { $1 }
1704         | '`' qconid '`'        { LL (unLoc $2) }
1705
1706 -----------------------------------------------------------------------------
1707 -- Type constructors
1708
1709 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1710         : oqtycon                       { $1 }
1711         | '(' ')'                       { LL $ getRdrName unitTyCon }
1712         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed ($2 + 1)) }
1713         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1714         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed ($2 + 1)) }
1715         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1716         | '[' ']'                       { LL $ listTyCon_RDR }
1717         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1718
1719 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1720         : qtycon                        { $1 }
1721         | '(' qtyconsym ')'             { LL (unLoc $2) }
1722
1723 qtyconop :: { Located RdrName } -- Qualified or unqualified
1724         : qtyconsym                     { $1 }
1725         | '`' qtycon '`'                { LL (unLoc $2) }
1726
1727 qtycon :: { Located RdrName }   -- Qualified or unqualified
1728         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1729         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1730         | tycon                         { $1 }
1731
1732 tycon   :: { Located RdrName }  -- Unqualified
1733         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1734
1735 qtyconsym :: { Located RdrName }
1736         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1737         | tyconsym                      { $1 }
1738
1739 tyconsym :: { Located RdrName }
1740         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1741
1742 -----------------------------------------------------------------------------
1743 -- Operators
1744
1745 op      :: { Located RdrName }   -- used in infix decls
1746         : varop                 { $1 }
1747         | conop                 { $1 }
1748
1749 varop   :: { Located RdrName }
1750         : varsym                { $1 }
1751         | '`' varid '`'         { LL (unLoc $2) }
1752
1753 qop     :: { LHsExpr RdrName }   -- used in sections
1754         : qvarop                { L1 $ HsVar (unLoc $1) }
1755         | qconop                { L1 $ HsVar (unLoc $1) }
1756
1757 qopm    :: { LHsExpr RdrName }   -- used in sections
1758         : qvaropm               { L1 $ HsVar (unLoc $1) }
1759         | qconop                { L1 $ HsVar (unLoc $1) }
1760
1761 qvarop :: { Located RdrName }
1762         : qvarsym               { $1 }
1763         | '`' qvarid '`'        { LL (unLoc $2) }
1764
1765 qvaropm :: { Located RdrName }
1766         : qvarsym_no_minus      { $1 }
1767         | '`' qvarid '`'        { LL (unLoc $2) }
1768
1769 -----------------------------------------------------------------------------
1770 -- Type variables
1771
1772 tyvar   :: { Located RdrName }
1773 tyvar   : tyvarid               { $1 }
1774         | '(' tyvarsym ')'      { LL (unLoc $2) }
1775
1776 tyvarop :: { Located RdrName }
1777 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1778         | tyvarsym              { $1 }
1779         | '.'                   {% parseErrorSDoc (getLoc $1)
1780                                       (vcat [ptext (sLit "Illegal symbol '.' in type"),
1781                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1782                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1783                                 }
1784
1785 tyvarid :: { Located RdrName }
1786         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1787         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1788         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1789         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1790         | 'threadsafe'          { L1 $! mkUnqual tvName (fsLit "threadsafe") }
1791
1792 tyvarsym :: { Located RdrName }
1793 -- Does not include "!", because that is used for strictness marks
1794 --               or ".", because that separates the quantified type vars from the rest
1795 --               or "*", because that's used for kinds
1796 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1797
1798 -----------------------------------------------------------------------------
1799 -- Variables
1800
1801 var     :: { Located RdrName }
1802         : varid                 { $1 }
1803         | '(' varsym ')'        { LL (unLoc $2) }
1804
1805 qvar    :: { Located RdrName }
1806         : qvarid                { $1 }
1807         | '(' varsym ')'        { LL (unLoc $2) }
1808         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1809 -- We've inlined qvarsym here so that the decision about
1810 -- whether it's a qvar or a var can be postponed until
1811 -- *after* we see the close paren.
1812
1813 qvarid :: { Located RdrName }
1814         : varid                 { $1 }
1815         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1816         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1817
1818 varid :: { Located RdrName }
1819         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1820         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1821         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1822         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1823         | 'threadsafe'          { L1 $! mkUnqual varName (fsLit "threadsafe") }
1824         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1825         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1826
1827 qvarsym :: { Located RdrName }
1828         : varsym                { $1 }
1829         | qvarsym1              { $1 }
1830
1831 qvarsym_no_minus :: { Located RdrName }
1832         : varsym_no_minus       { $1 }
1833         | qvarsym1              { $1 }
1834
1835 qvarsym1 :: { Located RdrName }
1836 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1837
1838 varsym :: { Located RdrName }
1839         : varsym_no_minus       { $1 }
1840         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1841
1842 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1843         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1844         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1845
1846
1847 -- These special_ids are treated as keywords in various places,
1848 -- but as ordinary ids elsewhere.   'special_id' collects all these
1849 -- except 'unsafe', 'forall', and 'family' whose treatment differs
1850 -- depending on context
1851 special_id :: { Located FastString }
1852 special_id
1853         : 'as'                  { L1 (fsLit "as") }
1854         | 'qualified'           { L1 (fsLit "qualified") }
1855         | 'hiding'              { L1 (fsLit "hiding") }
1856         | 'export'              { L1 (fsLit "export") }
1857         | 'label'               { L1 (fsLit "label")  }
1858         | 'dynamic'             { L1 (fsLit "dynamic") }
1859         | 'stdcall'             { L1 (fsLit "stdcall") }
1860         | 'ccall'               { L1 (fsLit "ccall") }
1861         | 'prim'                { L1 (fsLit "prim") }
1862         | 'group'               { L1 (fsLit "group") }
1863
1864 special_sym :: { Located FastString }
1865 special_sym : '!'       { L1 (fsLit "!") }
1866             | '.'       { L1 (fsLit ".") }
1867             | '*'       { L1 (fsLit "*") }
1868
1869 -----------------------------------------------------------------------------
1870 -- Data constructors
1871
1872 qconid :: { Located RdrName }   -- Qualified or unqualified
1873         : conid                 { $1 }
1874         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1875         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1876
1877 conid   :: { Located RdrName }
1878         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1879
1880 qconsym :: { Located RdrName }  -- Qualified or unqualified
1881         : consym                { $1 }
1882         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1883
1884 consym :: { Located RdrName }
1885         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1886
1887         -- ':' means only list cons
1888         | ':'                   { L1 $ consDataCon_RDR }
1889
1890
1891 -----------------------------------------------------------------------------
1892 -- Literals
1893
1894 literal :: { Located HsLit }
1895         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1896         | STRING                { L1 $ HsString     $ getSTRING $1 }
1897         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1898         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1899         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1900         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1901         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1902         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1903
1904 -----------------------------------------------------------------------------
1905 -- Layout
1906
1907 close :: { () }
1908         : vccurly               { () } -- context popped in lexer.
1909         | error                 {% popContext }
1910
1911 -----------------------------------------------------------------------------
1912 -- Miscellaneous (mostly renamings)
1913
1914 modid   :: { Located ModuleName }
1915         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1916         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1917                                   mkModuleNameFS
1918                                    (mkFastString
1919                                      (unpackFS mod ++ '.':unpackFS c))
1920                                 }
1921
1922 commas :: { Int }
1923         : commas ','                    { $1 + 1 }
1924         | ','                           { 1 }
1925
1926 -----------------------------------------------------------------------------
1927 -- Documentation comments
1928
1929 docnext :: { LHsDocString }
1930   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
1931
1932 docprev :: { LHsDocString }
1933   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
1934
1935 docnamed :: { Located (String, HsDocString) }
1936   : DOCNAMED {%
1937       let string = getDOCNAMED $1
1938           (name, rest) = break isSpace string
1939       in return (L1 (name, HsDocString (mkFastString rest))) }
1940
1941 docsection :: { Located (Int, HsDocString) }
1942   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1943         return (L1 (n, HsDocString (mkFastString doc))) }
1944
1945 moduleheader :: { Maybe LHsDocString }
1946         : DOCNEXT {% let string = getDOCNEXT $1 in
1947                      return (Just (L1 (HsDocString (mkFastString string)))) }
1948
1949 maybe_docprev :: { Maybe LHsDocString }
1950         : docprev                       { Just $1 }
1951         | {- empty -}                   { Nothing }
1952
1953 maybe_docnext :: { Maybe LHsDocString }
1954         : docnext                       { Just $1 }
1955         | {- empty -}                   { Nothing }
1956
1957 {
1958 happyError :: P a
1959 happyError = srcParseFail
1960
1961 getVARID        (L _ (ITvarid    x)) = x
1962 getCONID        (L _ (ITconid    x)) = x
1963 getVARSYM       (L _ (ITvarsym   x)) = x
1964 getCONSYM       (L _ (ITconsym   x)) = x
1965 getQVARID       (L _ (ITqvarid   x)) = x
1966 getQCONID       (L _ (ITqconid   x)) = x
1967 getQVARSYM      (L _ (ITqvarsym  x)) = x
1968 getQCONSYM      (L _ (ITqconsym  x)) = x
1969 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
1970 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
1971 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1972 getCHAR         (L _ (ITchar     x)) = x
1973 getSTRING       (L _ (ITstring   x)) = x
1974 getINTEGER      (L _ (ITinteger  x)) = x
1975 getRATIONAL     (L _ (ITrational x)) = x
1976 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1977 getPRIMSTRING   (L _ (ITprimstring x)) = x
1978 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1979 getPRIMWORD     (L _ (ITprimword x)) = x
1980 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
1981 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
1982 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
1983 getINLINE       (L _ (ITinline_prag b)) = b
1984 getINLINE_CONLIKE (L _ (ITinline_conlike_prag b)) = b
1985 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
1986
1987 getDOCNEXT (L _ (ITdocCommentNext x)) = x
1988 getDOCPREV (L _ (ITdocCommentPrev x)) = x
1989 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
1990 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
1991
1992 getSCC :: Located Token -> P FastString
1993 getSCC lt = do let s = getSTRING lt
1994                    err = "Spaces are not allowed in SCCs"
1995                -- We probably actually want to be more restrictive than this
1996                if ' ' `elem` unpackFS s
1997                    then failSpanMsgP (getLoc lt) (text err)
1998                    else return s
1999
2000 -- Utilities for combining source spans
2001 comb2 :: Located a -> Located b -> SrcSpan
2002 comb2 a b = a `seq` b `seq` combineLocs a b
2003
2004 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2005 comb3 a b c = a `seq` b `seq` c `seq`
2006     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2007
2008 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2009 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2010     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2011                 combineSrcSpans (getLoc c) (getLoc d))
2012
2013 -- strict constructor version:
2014 {-# INLINE sL #-}
2015 sL :: SrcSpan -> a -> Located a
2016 sL span a = span `seq` a `seq` L span a
2017
2018 -- Make a source location for the file.  We're a bit lazy here and just
2019 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2020 -- try to find the span of the whole file (ToDo).
2021 fileSrcSpan :: P SrcSpan
2022 fileSrcSpan = do
2023   l <- getSrcLoc;
2024   let loc = mkSrcLoc (srcLocFile l) 1 1;
2025   return (mkSrcSpan loc loc)
2026 }