Teach the alternative layout rule about mdo and rec
[ghc-hetmet.git] / compiler / parser / Parser.y.pp
1 --                                                              -*-haskell-*-
2 -- ---------------------------------------------------------------------------
3 -- (c) The University of Glasgow 1997-2003
4 ---
5 -- The GHC grammar.
6 --
7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
8 -- ---------------------------------------------------------------------------
9
10 {
11 {-# OPTIONS -Wwarn -w #-}
12 -- The above warning supression flag is a temporary kludge.
13 -- While working on this module you are encouraged to remove it and fix
14 -- any warnings in the module. See
15 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
16 -- for details
17
18 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
19 {-
20 Careful optimisation of the parser: we don't want to throw everything
21 at it, because that takes too long and doesn't buy much, but we do want
22 to inline certain key external functions, so we instruct GHC not to
23 throw away inlinings as it would normally do in -O0 mode.
24 -}
25
26 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
27                 parseHeader ) where
28
29 import HsSyn
30 import RdrHsSyn
31 import HscTypes         ( IsBootInterface, WarningTxt(..) )
32 import Lexer
33 import RdrName
34 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
35                           unboxedSingletonTyCon, unboxedSingletonDataCon,
36                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
37 import Type             ( funTyCon )
38 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
39                           CCallConv(..), CCallTarget(..), defaultCCallConv
40                         )
41 import OccName          ( varName, dataName, tcClsName, tvName )
42 import DataCon          ( DataCon, dataConName )
43 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
44                           SrcSpan, combineLocs, srcLocFile, 
45                           mkSrcLoc, mkSrcSpan )
46 import Module
47 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
48 import Type             ( Kind, liftedTypeKind, unliftedTypeKind )
49 import Coercion         ( mkArrowKind )
50 import Class            ( FunDep )
51 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
52                           Activation(..), RuleMatchInfo(..), defaultInlinePragma )
53 import DynFlags
54 import OrdList
55 import HaddockUtils
56
57 import FastString
58 import Maybes           ( orElse )
59 import Outputable
60
61 import Control.Monad    ( unless )
62 import GHC.Exts
63 import Data.Char
64 import Control.Monad    ( mplus )
65 }
66
67 {-
68 -----------------------------------------------------------------------------
69 24 Februar 2006
70
71 Conflicts: 33 shift/reduce
72            1 reduce/reduce
73
74 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
75 would think the two should never occur in the same context.
76
77   -=chak
78
79 -----------------------------------------------------------------------------
80 31 December 2006
81
82 Conflicts: 34 shift/reduce
83            1 reduce/reduce
84
85 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
86 would think the two should never occur in the same context.
87
88   -=chak
89
90 -----------------------------------------------------------------------------
91 6 December 2006
92
93 Conflicts: 32 shift/reduce
94            1 reduce/reduce
95
96 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
97 would think the two should never occur in the same context.
98
99   -=chak
100
101 -----------------------------------------------------------------------------
102 26 July 2006
103
104 Conflicts: 37 shift/reduce
105            1 reduce/reduce
106
107 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
108 would think the two should never occur in the same context.
109
110   -=chak
111
112 -----------------------------------------------------------------------------
113 Conflicts: 38 shift/reduce (1.25)
114
115 10 for abiguity in 'if x then y else z + 1'             [State 178]
116         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
117         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
118
119 1 for ambiguity in 'if x then y else z :: T'            [State 178]
120         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
121
122 4 for ambiguity in 'if x then y else z -< e'            [State 178]
123         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
124         There are four such operators: -<, >-, -<<, >>-
125
126
127 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
128         Which of these two is intended?
129           case v of
130             (x::T) -> T         -- Rhs is T
131     or
132           case v of
133             (x::T -> T) -> ..   -- Rhs is ...
134
135 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
136         (e::a) `b` c, or 
137         (e :: (a `b` c))
138     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
139     Same duplication between states 11 and 253 as the previous case
140
141 1 for ambiguity in 'let ?x ...'                         [State 329]
142         the parser can't tell whether the ?x is the lhs of a normal binding or
143         an implicit binding.  Fortunately resolving as shift gives it the only
144         sensible meaning, namely the lhs of an implicit binding.
145
146 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
147         we don't know whether the '[' starts the activation or not: it
148         might be the start of the declaration with the activation being
149         empty.  --SDM 1/4/2002
150
151 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
152         since 'forall' is a valid variable name, we don't know whether
153         to treat a forall on the input as the beginning of a quantifier
154         or the beginning of the rule itself.  Resolving to shift means
155         it's always treated as a quantifier, hence the above is disallowed.
156         This saves explicitly defining a grammar for the rule lhs that
157         doesn't include 'forall'.
158
159 1 for ambiguity when the source file starts with "-- | doc". We need another
160   token of lookahead to determine if a top declaration or the 'module' keyword
161   follows. Shift parses as if the 'module' keyword follows.   
162
163 -- ---------------------------------------------------------------------------
164 -- Adding location info
165
166 This is done in a stylised way using the three macros below, L0, L1
167 and LL.  Each of these macros can be thought of as having type
168
169    L0, L1, LL :: a -> Located a
170
171 They each add a SrcSpan to their argument.
172
173    L0   adds 'noSrcSpan', used for empty productions
174      -- This doesn't seem to work anymore -=chak
175
176    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
177         from that token.
178
179    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
180         the first and last tokens.
181
182 These suffice for the majority of cases.  However, we must be
183 especially careful with empty productions: LL won't work if the first
184 or last token on the lhs can represent an empty span.  In these cases,
185 we have to calculate the span using more of the tokens from the lhs, eg.
186
187         | 'newtype' tycl_hdr '=' newconstr deriving
188                 { L (comb3 $1 $4 $5)
189                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
190
191 We provide comb3 and comb4 functions which are useful in such cases.
192
193 Be careful: there's no checking that you actually got this right, the
194 only symptom will be that the SrcSpans of your syntax will be
195 incorrect.
196
197 /*
198  * We must expand these macros *before* running Happy, which is why this file is
199  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
200  */
201 #define L0   L noSrcSpan
202 #define L1   sL (getLoc $1)
203 #define LL   sL (comb2 $1 $>)
204
205 -- -----------------------------------------------------------------------------
206
207 -}
208
209 %token
210  '_'            { L _ ITunderscore }            -- Haskell keywords
211  'as'           { L _ ITas }
212  'case'         { L _ ITcase }          
213  'class'        { L _ ITclass } 
214  'data'         { L _ ITdata } 
215  'default'      { L _ ITdefault }
216  'deriving'     { L _ ITderiving }
217  'do'           { L _ ITdo }
218  'else'         { L _ ITelse }
219  'hiding'       { L _ IThiding }
220  'if'           { L _ ITif }
221  'import'       { L _ ITimport }
222  'in'           { L _ ITin }
223  'infix'        { L _ ITinfix }
224  'infixl'       { L _ ITinfixl }
225  'infixr'       { L _ ITinfixr }
226  'instance'     { L _ ITinstance }
227  'let'          { L _ ITlet }
228  'module'       { L _ ITmodule }
229  'newtype'      { L _ ITnewtype }
230  'of'           { L _ ITof }
231  'qualified'    { L _ ITqualified }
232  'then'         { L _ ITthen }
233  'type'         { L _ ITtype }
234  'where'        { L _ ITwhere }
235  '_scc_'        { L _ ITscc }         -- ToDo: remove
236
237  'forall'       { L _ ITforall }                -- GHC extension keywords
238  'foreign'      { L _ ITforeign }
239  'export'       { L _ ITexport }
240  'label'        { L _ ITlabel } 
241  'dynamic'      { L _ ITdynamic }
242  'safe'         { L _ ITsafe }
243  'threadsafe'   { L _ ITthreadsafe }  -- ToDo: remove deprecated alias
244  'unsafe'       { L _ ITunsafe }
245  'mdo'          { L _ ITmdo }
246  'family'       { L _ ITfamily }
247  'stdcall'      { L _ ITstdcallconv }
248  'ccall'        { L _ ITccallconv }
249  'prim'         { L _ ITprimcallconv }
250  'proc'         { L _ ITproc }          -- for arrow notation extension
251  'rec'          { L _ ITrec }           -- for arrow notation extension
252  'group'    { L _ ITgroup }     -- for list transform extension
253  'by'       { L _ ITby }        -- for list transform extension
254  'using'    { L _ ITusing }     -- for list transform extension
255
256  '{-# INLINE'             { L _ (ITinline_prag _) }
257  '{-# INLINE_CONLIKE'     { L _ (ITinline_conlike_prag _) }
258  '{-# SPECIALISE'         { L _ ITspec_prag }
259  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
260  '{-# SOURCE'      { L _ ITsource_prag }
261  '{-# RULES'       { L _ ITrules_prag }
262  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
263  '{-# SCC'         { L _ ITscc_prag }
264  '{-# GENERATED'   { L _ ITgenerated_prag }
265  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
266  '{-# WARNING'     { L _ ITwarning_prag }
267  '{-# UNPACK'      { L _ ITunpack_prag }
268  '{-# ANN'         { L _ ITann_prag }
269  '#-}'             { L _ ITclose_prag }
270
271  '..'           { L _ ITdotdot }                        -- reserved symbols
272  ':'            { L _ ITcolon }
273  '::'           { L _ ITdcolon }
274  '='            { L _ ITequal }
275  '\\'           { L _ ITlam }
276  '|'            { L _ ITvbar }
277  '<-'           { L _ ITlarrow }
278  '->'           { L _ ITrarrow }
279  '@'            { L _ ITat }
280  '~'            { L _ ITtilde }
281  '=>'           { L _ ITdarrow }
282  '-'            { L _ ITminus }
283  '!'            { L _ ITbang }
284  '*'            { L _ ITstar }
285  '-<'           { L _ ITlarrowtail }            -- for arrow notation
286  '>-'           { L _ ITrarrowtail }            -- for arrow notation
287  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
288  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
289  '.'            { L _ ITdot }
290
291  '{'            { L _ ITocurly }                        -- special symbols
292  '}'            { L _ ITccurly }
293  '{|'           { L _ ITocurlybar }
294  '|}'           { L _ ITccurlybar }
295  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
296  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
297  '['            { L _ ITobrack }
298  ']'            { L _ ITcbrack }
299  '[:'           { L _ ITopabrack }
300  ':]'           { L _ ITcpabrack }
301  '('            { L _ IToparen }
302  ')'            { L _ ITcparen }
303  '(#'           { L _ IToubxparen }
304  '#)'           { L _ ITcubxparen }
305  '(|'           { L _ IToparenbar }
306  '|)'           { L _ ITcparenbar }
307  ';'            { L _ ITsemi }
308  ','            { L _ ITcomma }
309  '`'            { L _ ITbackquote }
310
311  VARID          { L _ (ITvarid    _) }          -- identifiers
312  CONID          { L _ (ITconid    _) }
313  VARSYM         { L _ (ITvarsym   _) }
314  CONSYM         { L _ (ITconsym   _) }
315  QVARID         { L _ (ITqvarid   _) }
316  QCONID         { L _ (ITqconid   _) }
317  QVARSYM        { L _ (ITqvarsym  _) }
318  QCONSYM        { L _ (ITqconsym  _) }
319  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
320  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
321
322  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
323
324  CHAR           { L _ (ITchar     _) }
325  STRING         { L _ (ITstring   _) }
326  INTEGER        { L _ (ITinteger  _) }
327  RATIONAL       { L _ (ITrational _) }
328                     
329  PRIMCHAR       { L _ (ITprimchar   _) }
330  PRIMSTRING     { L _ (ITprimstring _) }
331  PRIMINTEGER    { L _ (ITprimint    _) }
332  PRIMWORD       { L _ (ITprimword  _) }
333  PRIMFLOAT      { L _ (ITprimfloat  _) }
334  PRIMDOUBLE     { L _ (ITprimdouble _) }
335
336  DOCNEXT        { L _ (ITdocCommentNext _) }
337  DOCPREV        { L _ (ITdocCommentPrev _) }
338  DOCNAMED       { L _ (ITdocCommentNamed _) }
339  DOCSECTION     { L _ (ITdocSection _ _) }
340
341 -- Template Haskell 
342 '[|'            { L _ ITopenExpQuote  }       
343 '[p|'           { L _ ITopenPatQuote  }      
344 '[t|'           { L _ ITopenTypQuote  }      
345 '[d|'           { L _ ITopenDecQuote  }      
346 '|]'            { L _ ITcloseQuote    }
347 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
348 '$('            { L _ ITparenEscape   }     -- $( exp )
349 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
350 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
351 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
352
353 %monad { P } { >>= } { return }
354 %lexer { lexer } { L _ ITeof }
355 %name parseModule module
356 %name parseStmt   maybe_stmt
357 %name parseIdentifier  identifier
358 %name parseType ctype
359 %partial parseHeader header
360 %tokentype { (Located Token) }
361 %%
362
363 -----------------------------------------------------------------------------
364 -- Identifiers; one of the entry points
365 identifier :: { Located RdrName }
366         : qvar                          { $1 }
367         | qcon                          { $1 }
368         | qvarop                        { $1 }
369         | qconop                        { $1 }
370     | '(' '->' ')'      { LL $ getRdrName funTyCon }
371
372 -----------------------------------------------------------------------------
373 -- Module Header
374
375 -- The place for module deprecation is really too restrictive, but if it
376 -- was allowed at its natural place just before 'module', we get an ugly
377 -- s/r conflict with the second alternative. Another solution would be the
378 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
379 -- either, and DEPRECATED is only expected to be used by people who really
380 -- know what they are doing. :-)
381
382 module  :: { Located (HsModule RdrName) }
383         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
384                 {% fileSrcSpan >>= \ loc ->
385                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
386                           ) )}
387         | body2
388                 {% fileSrcSpan >>= \ loc ->
389                    return (L loc (HsModule Nothing Nothing
390                           (fst $1) (snd $1) Nothing Nothing
391                           )) }
392
393 maybedocheader :: { Maybe LHsDocString }
394         : moduleheader            { $1 }
395         | {- empty -}             { Nothing }
396
397 missing_module_keyword :: { () }
398         : {- empty -}                           {% pushCurrentContext }
399
400 maybemodwarning :: { Maybe WarningTxt }
401     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
402     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
403     |  {- empty -}                  { Nothing }
404
405 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
406         :  '{'            top '}'               { $2 }
407         |      vocurly    top close             { $2 }
408
409 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
410         :  '{' top '}'                          { $2 }
411         |  missing_module_keyword top close     { $2 }
412
413 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
414         : importdecls                           { (reverse $1,[]) }
415         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
416         | cvtopdecls                            { ([],$1) }
417
418 cvtopdecls :: { [LHsDecl RdrName] }
419         : topdecls                              { cvTopDecls $1 }
420
421 -----------------------------------------------------------------------------
422 -- Module declaration & imports only
423
424 header  :: { Located (HsModule RdrName) }
425         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
426                 {% fileSrcSpan >>= \ loc ->
427                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
428                           ))}
429         | missing_module_keyword importdecls
430                 {% fileSrcSpan >>= \ loc ->
431                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
432                           Nothing)) }
433
434 header_body :: { [LImportDecl RdrName] }
435         :  '{'            importdecls           { $2 }
436         |      vocurly    importdecls           { $2 }
437
438 -----------------------------------------------------------------------------
439 -- The Export List
440
441 maybeexports :: { Maybe [LIE RdrName] }
442         :  '(' exportlist ')'                   { Just $2 }
443         |  {- empty -}                          { Nothing }
444
445 exportlist :: { [LIE RdrName] }
446         : expdoclist ',' expdoclist             { $1 ++ $3 }
447         | exportlist1                           { $1 }
448
449 exportlist1 :: { [LIE RdrName] }
450         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
451         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
452         | expdoclist                                   { $1 }
453
454 expdoclist :: { [LIE RdrName] }
455         : exp_doc expdoclist                           { $1 : $2 }
456         | {- empty -}                                  { [] }
457
458 exp_doc :: { LIE RdrName }                                                   
459         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
460         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
461         | docnext       { L1 (IEDoc (unLoc $1)) }       
462                        
463    -- No longer allow things like [] and (,,,) to be exported
464    -- They are built in syntax, always available
465 export  :: { LIE RdrName }
466         :  qvar                         { L1 (IEVar (unLoc $1)) }
467         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
468         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
469         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
470         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
471         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
472
473 qcnames :: { [RdrName] }
474         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
475         |  qcname_ext                   { [unLoc $1]  }
476
477 qcname_ext :: { Located RdrName }       -- Variable or data constructor
478                                         -- or tagged type constructor
479         :  qcname                       { $1 }
480         |  'type' qcon                  { sL (comb2 $1 $2) 
481                                              (setRdrNameSpace (unLoc $2) 
482                                                               tcClsName)  }
483
484 -- Cannot pull into qcname_ext, as qcname is also used in expression.
485 qcname  :: { Located RdrName }  -- Variable or data constructor
486         :  qvar                         { $1 }
487         |  qcon                         { $1 }
488
489 -----------------------------------------------------------------------------
490 -- Import Declarations
491
492 -- import decls can be *empty*, or even just a string of semicolons
493 -- whereas topdecls must contain at least one topdecl.
494
495 importdecls :: { [LImportDecl RdrName] }
496         : importdecls ';' importdecl            { $3 : $1 }
497         | importdecls ';'                       { $1 }
498         | importdecl                            { [ $1 ] }
499         | {- empty -}                           { [] }
500
501 importdecl :: { LImportDecl RdrName }
502         : 'import' maybe_src optqualified maybe_pkg modid maybeas maybeimpspec 
503                 { L (comb4 $1 $5 $6 $7) (ImportDecl $5 $4 $2 $3 (unLoc $6) (unLoc $7)) }
504
505 maybe_src :: { IsBootInterface }
506         : '{-# SOURCE' '#-}'                    { True }
507         | {- empty -}                           { False }
508
509 maybe_pkg :: { Maybe FastString }
510         : STRING                                { Just (getSTRING $1) }
511         | {- empty -}                           { Nothing }
512
513 optqualified :: { Bool }
514         : 'qualified'                           { True  }
515         | {- empty -}                           { False }
516
517 maybeas :: { Located (Maybe ModuleName) }
518         : 'as' modid                            { LL (Just (unLoc $2)) }
519         | {- empty -}                           { noLoc Nothing }
520
521 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
522         : impspec                               { L1 (Just (unLoc $1)) }
523         | {- empty -}                           { noLoc Nothing }
524
525 impspec :: { Located (Bool, [LIE RdrName]) }
526         :  '(' exportlist ')'                   { LL (False, $2) }
527         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
528
529 -----------------------------------------------------------------------------
530 -- Fixity Declarations
531
532 prec    :: { Int }
533         : {- empty -}           { 9 }
534         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
535
536 infix   :: { Located FixityDirection }
537         : 'infix'                               { L1 InfixN  }
538         | 'infixl'                              { L1 InfixL  }
539         | 'infixr'                              { L1 InfixR }
540
541 ops     :: { Located [Located RdrName] }
542         : ops ',' op                            { LL ($3 : unLoc $1) }
543         | op                                    { L1 [$1] }
544
545 -----------------------------------------------------------------------------
546 -- Top-Level Declarations
547
548 topdecls :: { OrdList (LHsDecl RdrName) }
549         : topdecls ';' topdecl                  { $1 `appOL` $3 }
550         | topdecls ';'                          { $1 }
551         | topdecl                               { $1 }
552
553 topdecl :: { OrdList (LHsDecl RdrName) }
554         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
555         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
556         | 'instance' inst_type where_inst
557             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
558               in 
559               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
560         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
561         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
562         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
563         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
564         | '{-# WARNING' warnings '#-}'          { $2 }
565         | '{-# RULES' rules '#-}'               { $2 }
566         | annotation { unitOL $1 }
567         | decl                                  { unLoc $1 }
568
569         -- Template Haskell Extension
570         -- The $(..) form is one possible form of infixexp
571         -- but we treat an arbitrary expression just as if 
572         -- it had a $(..) wrapped around it
573         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) } 
574
575 -- Type classes
576 --
577 cl_decl :: { LTyClDecl RdrName }
578         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
579
580 -- Type declarations (toplevel)
581 --
582 ty_decl :: { LTyClDecl RdrName }
583            -- ordinary type synonyms
584         : 'type' type '=' ctypedoc
585                 -- Note ctype, not sigtype, on the right of '='
586                 -- We allow an explicit for-all but we don't insert one
587                 -- in   type Foo a = (b,b)
588                 -- Instead we just say b is out of scope
589                 --
590                 -- Note the use of type for the head; this allows
591                 -- infix type constructors to be declared 
592                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
593
594            -- type family declarations
595         | 'type' 'family' type opt_kind_sig 
596                 -- Note the use of type for the head; this allows
597                 -- infix type constructors to be declared
598                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
599
600            -- type instance declarations
601         | 'type' 'instance' type '=' ctype
602                 -- Note the use of type for the head; this allows
603                 -- infix type constructors and type patterns
604                 {% mkTySynonym (comb2 $1 $5) True $3 $5 }
605
606           -- ordinary data type or newtype declaration
607         | data_or_newtype tycl_hdr constrs deriving
608                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) False $2 
609                             Nothing (reverse (unLoc $3)) (unLoc $4) }
610                                    -- We need the location on tycl_hdr in case 
611                                    -- constrs and deriving are both empty
612
613           -- ordinary GADT declaration
614         | data_or_newtype tycl_hdr opt_kind_sig 
615                  gadt_constrlist
616                  deriving
617                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) False $2 
618                             (unLoc $3) (unLoc $4) (unLoc $5) }
619                                    -- We need the location on tycl_hdr in case 
620                                    -- constrs and deriving are both empty
621
622           -- data/newtype family
623         | 'data' 'family' type opt_kind_sig
624                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
625
626           -- data/newtype instance declaration
627         | data_or_newtype 'instance' tycl_hdr constrs deriving
628                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $3
629                             Nothing (reverse (unLoc $4)) (unLoc $5) }
630
631           -- GADT instance declaration
632         | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
633                  gadt_constrlist
634                  deriving
635                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $3
636                             (unLoc $4) (unLoc $5) (unLoc $6) }
637
638 -- Associated type family declarations
639 --
640 -- * They have a different syntax than on the toplevel (no family special
641 --   identifier).
642 --
643 -- * They also need to be separate from instances; otherwise, data family
644 --   declarations without a kind signature cause parsing conflicts with empty
645 --   data declarations. 
646 --
647 at_decl_cls :: { LTyClDecl RdrName }
648            -- type family declarations
649         : 'type' type opt_kind_sig
650                 -- Note the use of type for the head; this allows
651                 -- infix type constructors to be declared
652                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
653
654            -- default type instance
655         | 'type' type '=' ctype
656                 -- Note the use of type for the head; this allows
657                 -- infix type constructors and type patterns
658                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
659
660           -- data/newtype family declaration
661         | 'data' type opt_kind_sig
662                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
663
664 -- Associated type instances
665 --
666 at_decl_inst :: { LTyClDecl RdrName }
667            -- type instance declarations
668         : 'type' type '=' ctype
669                 -- Note the use of type for the head; this allows
670                 -- infix type constructors and type patterns
671                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
672
673         -- data/newtype instance declaration
674         | data_or_newtype tycl_hdr constrs deriving
675                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) True $2 
676                             Nothing (reverse (unLoc $3)) (unLoc $4) }
677
678         -- GADT instance declaration
679         | data_or_newtype tycl_hdr opt_kind_sig 
680                  gadt_constrlist
681                  deriving
682                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) True $2 
683                             (unLoc $3) (unLoc $4) (unLoc $5) }
684
685 data_or_newtype :: { Located NewOrData }
686         : 'data'        { L1 DataType }
687         | 'newtype'     { L1 NewType }
688
689 opt_kind_sig :: { Located (Maybe Kind) }
690         :                               { noLoc Nothing }
691         | '::' kind                     { LL (Just (unLoc $2)) }
692
693 -- tycl_hdr parses the header of a class or data type decl,
694 -- which takes the form
695 --      T a b
696 --      Eq a => T a
697 --      (Eq a, Ord b) => T a b
698 --      T Int [a]                       -- for associated types
699 -- Rather a lot of inlining here, else we get reduce/reduce errors
700 tycl_hdr :: { Located (LHsContext RdrName, LHsType RdrName) }
701         : context '=>' type             { LL ($1, $3) }
702         | type                          { L1 (noLoc [], $1) }
703
704 -----------------------------------------------------------------------------
705 -- Stand-alone deriving
706
707 -- Glasgow extension: stand-alone deriving declarations
708 stand_alone_deriving :: { LDerivDecl RdrName }
709         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
710
711 -----------------------------------------------------------------------------
712 -- Nested declarations
713
714 -- Declaration in class bodies
715 --
716 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
717 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
718           | decl                        { $1 }
719
720 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
721           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
722           | decls_cls ';'               { LL (unLoc $1) }
723           | decl_cls                    { $1 }
724           | {- empty -}                 { noLoc nilOL }
725
726
727 decllist_cls
728         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
729         : '{'         decls_cls '}'     { LL (unLoc $2) }
730         |     vocurly decls_cls close   { $2 }
731
732 -- Class body
733 --
734 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
735                                 -- No implicit parameters
736                                 -- May have type declarations
737         : 'where' decllist_cls          { LL (unLoc $2) }
738         | {- empty -}                   { noLoc nilOL }
739
740 -- Declarations in instance bodies
741 --
742 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
743 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
744            | decl                       { $1 }
745
746 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
747            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
748            | decls_inst ';'             { LL (unLoc $1) }
749            | decl_inst                  { $1 }
750            | {- empty -}                { noLoc nilOL }
751
752 decllist_inst 
753         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
754         : '{'         decls_inst '}'    { LL (unLoc $2) }
755         |     vocurly decls_inst close  { $2 }
756
757 -- Instance body
758 --
759 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
760                                 -- No implicit parameters
761                                 -- May have type declarations
762         : 'where' decllist_inst         { LL (unLoc $2) }
763         | {- empty -}                   { noLoc nilOL }
764
765 -- Declarations in binding groups other than classes and instances
766 --
767 decls   :: { Located (OrdList (LHsDecl RdrName)) }      
768         : decls ';' decl                { let { this = unLoc $3;
769                                     rest = unLoc $1;
770                                     these = rest `appOL` this }
771                               in rest `seq` this `seq` these `seq`
772                                     LL these }
773         | decls ';'                     { LL (unLoc $1) }
774         | decl                          { $1 }
775         | {- empty -}                   { noLoc nilOL }
776
777 decllist :: { Located (OrdList (LHsDecl RdrName)) }
778         : '{'            decls '}'      { LL (unLoc $2) }
779         |     vocurly    decls close    { $2 }
780
781 -- Binding groups other than those of class and instance declarations
782 --
783 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
784                                                 -- No type declarations
785         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
786         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
787         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
788
789 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
790                                                 -- No type declarations
791         : 'where' binds                 { LL (unLoc $2) }
792         | {- empty -}                   { noLoc emptyLocalBinds }
793
794
795 -----------------------------------------------------------------------------
796 -- Transformation Rules
797
798 rules   :: { OrdList (LHsDecl RdrName) }
799         :  rules ';' rule                       { $1 `snocOL` $3 }
800         |  rules ';'                            { $1 }
801         |  rule                                 { unitOL $1 }
802         |  {- empty -}                          { nilOL }
803
804 rule    :: { LHsDecl RdrName }
805         : STRING activation rule_forall infixexp '=' exp
806              { LL $ RuleD (HsRule (getSTRING $1) 
807                                   ($2 `orElse` AlwaysActive) 
808                                   $3 $4 placeHolderNames $6 placeHolderNames) }
809
810 activation :: { Maybe Activation } 
811         : {- empty -}                           { Nothing }
812         | explicit_activation                   { Just $1 }
813
814 explicit_activation :: { Activation }  -- In brackets
815         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
816         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
817
818 rule_forall :: { [RuleBndr RdrName] }
819         : 'forall' rule_var_list '.'            { $2 }
820         | {- empty -}                           { [] }
821
822 rule_var_list :: { [RuleBndr RdrName] }
823         : rule_var                              { [$1] }
824         | rule_var rule_var_list                { $1 : $2 }
825
826 rule_var :: { RuleBndr RdrName }
827         : varid                                 { RuleBndr $1 }
828         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
829
830 -----------------------------------------------------------------------------
831 -- Warnings and deprecations (c.f. rules)
832
833 warnings :: { OrdList (LHsDecl RdrName) }
834         : warnings ';' warning          { $1 `appOL` $3 }
835         | warnings ';'                  { $1 }
836         | warning                               { $1 }
837         | {- empty -}                           { nilOL }
838
839 -- SUP: TEMPORARY HACK, not checking for `module Foo'
840 warning :: { OrdList (LHsDecl RdrName) }
841         : namelist strings
842                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
843                        | n <- unLoc $1 ] }
844
845 deprecations :: { OrdList (LHsDecl RdrName) }
846         : deprecations ';' deprecation          { $1 `appOL` $3 }
847         | deprecations ';'                      { $1 }
848         | deprecation                           { $1 }
849         | {- empty -}                           { nilOL }
850
851 -- SUP: TEMPORARY HACK, not checking for `module Foo'
852 deprecation :: { OrdList (LHsDecl RdrName) }
853         : namelist strings
854                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
855                        | n <- unLoc $1 ] }
856
857 strings :: { Located [FastString] }
858     : STRING { L1 [getSTRING $1] }
859     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
860
861 stringlist :: { Located (OrdList FastString) }
862     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
863     | STRING                { LL (unitOL (getSTRING $1)) }
864
865 -----------------------------------------------------------------------------
866 -- Annotations
867 annotation :: { LHsDecl RdrName }
868     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
869     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
870     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
871
872
873 -----------------------------------------------------------------------------
874 -- Foreign import and export declarations
875
876 fdecl :: { LHsDecl RdrName }
877 fdecl : 'import' callconv safety fspec
878                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
879       | 'import' callconv        fspec          
880                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
881                         return (LL d) } }
882       | 'export' callconv fspec
883                 {% mkExport $2 (unLoc $3) >>= return.LL }
884
885 callconv :: { CCallConv }
886           : 'stdcall'                   { StdCallConv }
887           | 'ccall'                     { CCallConv   }
888           | 'prim'                      { PrimCallConv}
889
890 safety :: { Safety }
891         : 'unsafe'                      { PlayRisky }
892         | 'safe'                        { PlaySafe  False }
893         | 'threadsafe'                  { PlaySafe  True } -- deprecated alias
894
895 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
896        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
897        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
898          -- if the entity string is missing, it defaults to the empty string;
899          -- the meaning of an empty entity string depends on the calling
900          -- convention
901
902 -----------------------------------------------------------------------------
903 -- Type signatures
904
905 opt_sig :: { Maybe (LHsType RdrName) }
906         : {- empty -}                   { Nothing }
907         | '::' sigtype                  { Just $2 }
908
909 opt_asig :: { Maybe (LHsType RdrName) }
910         : {- empty -}                   { Nothing }
911         | '::' atype                    { Just $2 }
912
913 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
914                                         -- to tell the renamer where to generalise
915         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
916         -- Wrap an Implicit forall if there isn't one there already
917
918 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
919         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
920         -- Wrap an Implicit forall if there isn't one there already
921
922 sig_vars :: { Located [Located RdrName] }
923          : sig_vars ',' var             { LL ($3 : unLoc $1) }
924          | var                          { L1 [$1] }
925
926 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
927         : sigtype                       { [ $1 ] }
928         | sigtype ',' sigtypes1         { $1 : $3 }
929
930 -----------------------------------------------------------------------------
931 -- Types
932
933 infixtype :: { LHsType RdrName }
934         : btype qtyconop type         { LL $ HsOpTy $1 $2 $3 }
935         | btype tyvarop  type    { LL $ HsOpTy $1 $2 $3 }
936
937 strict_mark :: { Located HsBang }
938         : '!'                           { L1 HsStrict }
939         | '{-# UNPACK' '#-}' '!'        { LL HsUnbox }
940
941 -- A ctype is a for-all type
942 ctype   :: { LHsType RdrName }
943         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
944         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
945         -- A type of form (context => type) is an *implicit* HsForAllTy
946         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
947         | type                          { $1 }
948
949 ----------------------
950 -- Notes for 'ctypedoc'
951 -- It would have been nice to simplify the grammar by unifying `ctype` and 
952 -- ctypedoc` into one production, allowing comments on types everywhere (and
953 -- rejecting them after parsing, where necessary).  This is however not possible
954 -- since it leads to ambiguity. The reason is the support for comments on record
955 -- fields: 
956 --         data R = R { field :: Int -- ^ comment on the field }
957 -- If we allow comments on types here, it's not clear if the comment applies
958 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
959
960 ctypedoc :: { LHsType RdrName }
961         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
962         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
963         -- A type of form (context => type) is an *implicit* HsForAllTy
964         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
965         | typedoc                       { $1 }
966
967 ----------------------
968 -- Notes for 'context'
969 -- We parse a context as a btype so that we don't get reduce/reduce
970 -- errors in ctype.  The basic problem is that
971 --      (Eq a, Ord a)
972 -- looks so much like a tuple type.  We can't tell until we find the =>
973
974 -- We have the t1 ~ t2 form both in 'context' and in type, 
975 -- to permit an individual equational constraint without parenthesis.
976 -- Thus for some reason we allow    f :: a~b => blah
977 -- but not                          f :: ?x::Int => blah
978 context :: { LHsContext RdrName }
979         : btype '~'      btype          {% checkContext
980                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
981         | btype                         {% checkContext $1 }
982
983 type :: { LHsType RdrName }
984         : btype                         { $1 }
985         | btype qtyconop type           { LL $ HsOpTy $1 $2 $3 }
986         | btype tyvarop  type           { LL $ HsOpTy $1 $2 $3 }
987         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
988         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
989
990 typedoc :: { LHsType RdrName }
991         : btype                          { $1 }
992         | btype docprev                  { LL $ HsDocTy $1 $2 }
993         | btype qtyconop type            { LL $ HsOpTy $1 $2 $3 }
994         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
995         | btype tyvarop  type            { LL $ HsOpTy $1 $2 $3 }
996         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
997         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
998         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
999         | btype '~'      btype           { LL $ HsPredTy (HsEqualP $1 $3) }
1000
1001 btype :: { LHsType RdrName }
1002         : btype atype                   { LL $ HsAppTy $1 $2 }
1003         | atype                         { $1 }
1004
1005 atype :: { LHsType RdrName }
1006         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1007         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1008         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1009         | '{' fielddecls '}'            { LL $ HsRecTy $2 }              -- Constructor sigs only
1010         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1011         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1012         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1013         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1014         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1015         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1016         | '$(' exp ')'                  { LL $ HsSpliceTy (mkHsSplice $2 ) }
1017         | TH_ID_SPLICE                  { LL $ HsSpliceTy (mkHsSplice 
1018                                                  (L1 $ HsVar (mkUnqual varName 
1019                                                                 (getTH_ID_SPLICE $1)))) } -- $x
1020 -- Generics
1021         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
1022
1023 -- An inst_type is what occurs in the head of an instance decl
1024 --      e.g.  (Foo a, Gaz b) => Wibble a b
1025 -- It's kept as a single type, with a MonoDictTy at the right
1026 -- hand corner, for convenience.
1027 inst_type :: { LHsType RdrName }
1028         : sigtype                       {% checkInstType $1 }
1029
1030 inst_types1 :: { [LHsType RdrName] }
1031         : inst_type                     { [$1] }
1032         | inst_type ',' inst_types1     { $1 : $3 }
1033
1034 comma_types0  :: { [LHsType RdrName] }
1035         : comma_types1                  { $1 }
1036         | {- empty -}                   { [] }
1037
1038 comma_types1    :: { [LHsType RdrName] }
1039         : ctype                         { [$1] }
1040         | ctype  ',' comma_types1       { $1 : $3 }
1041
1042 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1043          : tv_bndr tv_bndrs             { $1 : $2 }
1044          | {- empty -}                  { [] }
1045
1046 tv_bndr :: { LHsTyVarBndr RdrName }
1047         : tyvar                         { L1 (UserTyVar (unLoc $1)) }
1048         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) 
1049                                                           (unLoc $4)) }
1050
1051 fds :: { Located [Located (FunDep RdrName)] }
1052         : {- empty -}                   { noLoc [] }
1053         | '|' fds1                      { LL (reverse (unLoc $2)) }
1054
1055 fds1 :: { Located [Located (FunDep RdrName)] }
1056         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1057         | fd                            { L1 [$1] }
1058
1059 fd :: { Located (FunDep RdrName) }
1060         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1061                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1062
1063 varids0 :: { Located [RdrName] }
1064         : {- empty -}                   { noLoc [] }
1065         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1066
1067 -----------------------------------------------------------------------------
1068 -- Kinds
1069
1070 kind    :: { Located Kind }
1071         : akind                 { $1 }
1072         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1073
1074 akind   :: { Located Kind }
1075         : '*'                   { L1 liftedTypeKind }
1076         | '!'                   { L1 unliftedTypeKind }
1077         | '(' kind ')'          { LL (unLoc $2) }
1078
1079
1080 -----------------------------------------------------------------------------
1081 -- Datatype declarations
1082
1083 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1084         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1085         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1086         | {- empty -}                              { noLoc [] }
1087
1088 gadt_constrs :: { Located [LConDecl RdrName] }
1089         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1090         | gadt_constr                   { L (getLoc (head $1)) $1 }
1091         | {- empty -}                   { noLoc [] }
1092
1093 -- We allow the following forms:
1094 --      C :: Eq a => a -> T a
1095 --      C :: forall a. Eq a => !a -> T a
1096 --      D { x,y :: a } :: T a
1097 --      forall a. Eq a => D { x,y :: a } :: T a
1098
1099 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1100         : con_list '::' sigtype
1101                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) } 
1102
1103                 -- Deprecated syntax for GADT record declarations
1104         | oqtycon '{' fielddecls '}' '::' sigtype
1105                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1106                       ; return [cd] } }
1107
1108 constrs :: { Located [LConDecl RdrName] }
1109         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1110
1111 constrs1 :: { Located [LConDecl RdrName] }
1112         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1113         | constr                                          { L1 [$1] }
1114
1115 constr :: { LConDecl RdrName }
1116         : maybe_docnext forall context '=>' constr_stuff maybe_docprev  
1117                 { let (con,details) = unLoc $5 in 
1118                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1119                             ($1 `mplus` $6) }
1120         | maybe_docnext forall constr_stuff maybe_docprev
1121                 { let (con,details) = unLoc $3 in 
1122                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1123                             ($1 `mplus` $4) }
1124
1125 forall :: { Located [LHsTyVarBndr RdrName] }
1126         : 'forall' tv_bndrs '.'         { LL $2 }
1127         | {- empty -}                   { noLoc [] }
1128
1129 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1130 -- We parse the constructor declaration 
1131 --      C t1 t2
1132 -- as a btype (treating C as a type constructor) and then convert C to be
1133 -- a data constructor.  Reason: it might continue like this:
1134 --      C t1 t2 %: D Int
1135 -- in which case C really would be a type constructor.  We can't resolve this
1136 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1137         : btype                         {% splitCon $1 >>= return.LL }
1138         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1139
1140 fielddecls :: { [ConDeclField RdrName] }
1141         : {- empty -}     { [] }
1142         | fielddecls1     { $1 }
1143
1144 fielddecls1 :: { [ConDeclField RdrName] }
1145         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1146                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1147                              -- This adds the doc $4 to each field separately
1148         | fielddecl   { $1 }
1149
1150 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1151         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5) 
1152                                                                  | fld <- reverse (unLoc $2) ] }
1153
1154 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1155 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1156 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1157 -- We don't allow a context, but that's sorted out by the type checker.
1158 deriving :: { Located (Maybe [LHsType RdrName]) }
1159         : {- empty -}                           { noLoc Nothing }
1160         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1161                                       ; p <- checkInstType (L loc (HsTyVar tv))
1162                                       ; return (LL (Just [p])) } }
1163         | 'deriving' '(' ')'                    { LL (Just []) }
1164         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1165              -- Glasgow extension: allow partial 
1166              -- applications in derivings
1167
1168 -----------------------------------------------------------------------------
1169 -- Value definitions
1170
1171 {- Note [Declaration/signature overlap]
1172 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1173 There's an awkward overlap with a type signature.  Consider
1174         f :: Int -> Int = ...rhs...
1175    Then we can't tell whether it's a type signature or a value
1176    definition with a result signature until we see the '='.
1177    So we have to inline enough to postpone reductions until we know.
1178 -}
1179
1180 {-
1181   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1182   instead of qvar, we get another shift/reduce-conflict. Consider the
1183   following programs:
1184   
1185      { (^^) :: Int->Int ; }          Type signature; only var allowed
1186
1187      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1188                                      qvar allowed (because of instance decls)
1189   
1190   We can't tell whether to reduce var to qvar until after we've read the signatures.
1191 -}
1192
1193 docdecl :: { LHsDecl RdrName }
1194         : docdecld { L1 (DocD (unLoc $1)) }
1195
1196 docdecld :: { LDocDecl }
1197         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1198         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1199         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1200         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1201
1202 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1203         : sigdecl                       { $1 }
1204         | '!' aexp rhs                  {% do { pat <- checkPattern $2;
1205                                                 return (LL $ unitOL $ LL $ ValD ( 
1206                                                         PatBind (LL $ BangPat pat) (unLoc $3)
1207                                                                 placeHolderType placeHolderNames)) } }
1208         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
1209                                                 let { l = comb2 $1 $> };
1210                                                 return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1211         | docdecl                       { LL $ unitOL $1 }
1212
1213 rhs     :: { Located (GRHSs RdrName) }
1214         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1215         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1216
1217 gdrhs :: { Located [LGRHS RdrName] }
1218         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1219         | gdrh                  { L1 [$1] }
1220
1221 gdrh :: { LGRHS RdrName }
1222         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1223
1224 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1225         : infixexp '::' sigtypedoc      {% do s <- checkValSig $1 $3 
1226                                          ; return (LL $ unitOL (LL $ SigD s)) }
1227                 -- See Note [Declaration/signature overlap] for why we need infixexp here
1228         | var ',' sig_vars '::' sigtypedoc
1229                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1230         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1231                                              | n <- unLoc $3 ] }
1232         | '{-# INLINE'   activation qvar '#-}'        
1233                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma $2 FunLike (getINLINE $1)))) }
1234         | '{-# INLINE_CONLIKE' activation qvar '#-}'
1235                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma $2 ConLike (getINLINE_CONLIKE $1)))) }
1236         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1237                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlinePragma) 
1238                                             | t <- $4] }
1239         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1240                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma $2 FunLike (getSPEC_INLINE $1)))
1241                                             | t <- $5] }
1242         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1243                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1244
1245 -----------------------------------------------------------------------------
1246 -- Expressions
1247
1248 exp   :: { LHsExpr RdrName }
1249         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1250         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1251         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1252         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1253         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1254         | infixexp                      { $1 }
1255
1256 infixexp :: { LHsExpr RdrName }
1257         : exp10                         { $1 }
1258         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1259
1260 exp10 :: { LHsExpr RdrName }
1261         : '\\' apat apats opt_asig '->' exp     
1262                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1263                                                                 (unguardedGRHSs $6)
1264                                                             ]) }
1265         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1266         | 'if' exp 'then' exp 'else' exp        { LL $ HsIf $2 $4 $6 }
1267         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1268         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1269
1270         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1271                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1272                                            return (L loc (mkHsDo DoExpr stmts body)) }
1273         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1274                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1275                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1276         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1277                                                         then HsSCC (unLoc $1) $2
1278                                                         else HsPar $2 }
1279         | hpc_annot exp                         { LL $ if opt_Hpc
1280                                                         then HsTickPragma (unLoc $1) $2
1281                                                         else HsPar $2 }
1282
1283         | 'proc' aexp '->' exp  
1284                         {% checkPattern $2 >>= \ p -> 
1285                            return (LL $ HsProc p (LL $ HsCmdTop $4 [] 
1286                                                    placeHolderType undefined)) }
1287                                                 -- TODO: is LL right here?
1288
1289         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1290                                                     -- hdaume: core annotation
1291         | fexp                                  { $1 }
1292
1293 scc_annot :: { Located FastString }
1294         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1295                                    ( do scc <- getSCC $2; return $ LL scc ) }
1296         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1297
1298 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1299         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1300                                                 { LL $ (getSTRING $2
1301                                                        ,( fromInteger $ getINTEGER $3
1302                                                         , fromInteger $ getINTEGER $5
1303                                                         )
1304                                                        ,( fromInteger $ getINTEGER $7
1305                                                         , fromInteger $ getINTEGER $9
1306                                                         )
1307                                                        )
1308                                                  }
1309
1310 fexp    :: { LHsExpr RdrName }
1311         : fexp aexp                             { LL $ HsApp $1 $2 }
1312         | aexp                                  { $1 }
1313
1314 aexp    :: { LHsExpr RdrName }
1315         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1316         | '~' aexp                      { LL $ ELazyPat $2 }
1317         | aexp1                 { $1 }
1318
1319 aexp1   :: { LHsExpr RdrName }
1320         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1321                                       ; return (LL r) }}
1322         | aexp2                 { $1 }
1323
1324 -- Here was the syntax for type applications that I was planning
1325 -- but there are difficulties (e.g. what order for type args)
1326 -- so it's not enabled yet.
1327 -- But this case *is* used for the left hand side of a generic definition,
1328 -- which is parsed as an expression before being munged into a pattern
1329         | qcname '{|' type '|}'         { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1330                                                      (sL (getLoc $3) (HsType $3)) }
1331
1332 aexp2   :: { LHsExpr RdrName }
1333         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1334         | qcname                        { L1 (HsVar   $! unLoc $1) }
1335         | literal                       { L1 (HsLit   $! unLoc $1) }
1336 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1337 -- into HsOverLit when -foverloaded-strings is on.
1338 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1339         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1340         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1341
1342         -- N.B.: sections get parsed by these next two productions.
1343         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't correct Haskell98
1344         -- (you'd have to write '((+ 3), (4 -))')
1345         -- but the less cluttered version fell out of having texps.
1346         | '(' texp ')'                  { LL (HsPar $2) }
1347         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1348
1349         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1350         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1351
1352         | '[' list ']'                  { LL (unLoc $2) }
1353         | '[:' parr ':]'                { LL (unLoc $2) }
1354         | '_'                           { L1 EWildPat }
1355         
1356         -- Template Haskell Extension
1357         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice 
1358                                         (L1 $ HsVar (mkUnqual varName 
1359                                                         (getTH_ID_SPLICE $1)))) } -- $x
1360         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               -- $( exp )
1361
1362         | TH_QUASIQUOTE         { let { loc = getLoc $1
1363                                       ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1364                                       ; quoterId = mkUnqual varName quoter
1365                                       }
1366                                   in sL loc $ HsQuasiQuoteE (mkHsQuasiQuote quoterId quoteSpan quote) }
1367         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1368         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1369         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1370         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1371         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }                       
1372         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }                       
1373         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1374                                         return (LL $ HsBracket (PatBr p)) }
1375         | '[d|' cvtopbody '|]'  {% checkDecBrGroup $2 >>= \g -> 
1376                                         return (LL $ HsBracket (DecBr g)) }
1377
1378         -- arrow notation extension
1379         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1380
1381 cmdargs :: { [LHsCmdTop RdrName] }
1382         : cmdargs acmd                  { $2 : $1 }
1383         | {- empty -}                   { [] }
1384
1385 acmd    :: { LHsCmdTop RdrName }
1386         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1387
1388 cvtopbody :: { [LHsDecl RdrName] }
1389         :  '{'            cvtopdecls0 '}'               { $2 }
1390         |      vocurly    cvtopdecls0 close             { $2 }
1391
1392 cvtopdecls0 :: { [LHsDecl RdrName] }
1393         : {- empty -}           { [] }
1394         | cvtopdecls            { $1 }
1395
1396 -----------------------------------------------------------------------------
1397 -- Tuple expressions
1398
1399 -- "texp" is short for tuple expressions: 
1400 -- things that can appear unparenthesized as long as they're
1401 -- inside parens or delimitted by commas
1402 texp :: { LHsExpr RdrName }
1403         : exp                           { $1 }
1404
1405         -- Note [Parsing sections]
1406         -- ~~~~~~~~~~~~~~~~~~~~~~~
1407         -- We include left and right sections here, which isn't
1408         -- technically right according to Haskell 98.  For example
1409         --      (3 +, True) isn't legal
1410         -- However, we want to parse bang patterns like
1411         --      (!x, !y)
1412         -- and it's convenient to do so here as a section
1413         -- Then when converting expr to pattern we unravel it again
1414         -- Meanwhile, the renamer checks that real sections appear
1415         -- inside parens.
1416         | infixexp qop  { LL $ SectionL $1 $2 }
1417         | qopm infixexp       { LL $ SectionR $1 $2 }
1418
1419        -- View patterns get parenthesized above
1420         | exp '->' texp   { LL $ EViewPat $1 $3 }
1421
1422 -- Always at least one comma
1423 tup_exprs :: { [HsTupArg RdrName] }
1424            : texp commas_tup_tail  { Present $1 : $2 }
1425            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1426
1427 -- Always starts with commas; always follows an expr
1428 commas_tup_tail :: { [HsTupArg RdrName] }
1429 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1430
1431 -- Always follows a comma
1432 tup_tail :: { [HsTupArg RdrName] }
1433           : texp commas_tup_tail        { Present $1 : $2 }
1434           | texp                        { [Present $1] }
1435           | {- empty -}                 { [missingTupArg] }
1436
1437 -----------------------------------------------------------------------------
1438 -- List expressions
1439
1440 -- The rules below are little bit contorted to keep lexps left-recursive while
1441 -- avoiding another shift/reduce-conflict.
1442
1443 list :: { LHsExpr RdrName }
1444         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1445         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1446         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1447         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1448         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1449         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1450         | texp '|' flattenedpquals      { sL (comb2 $1 $>) $ mkHsDo ListComp (unLoc $3) $1 }
1451
1452 lexps :: { Located [LHsExpr RdrName] }
1453         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1454         | texp ',' texp                 { LL [$3,$1] }
1455
1456 -----------------------------------------------------------------------------
1457 -- List Comprehensions
1458
1459 flattenedpquals :: { Located [LStmt RdrName] }
1460     : pquals   { case (unLoc $1) of
1461                     [qs] -> L1 qs
1462                     -- We just had one thing in our "parallel" list so 
1463                     -- we simply return that thing directly
1464                     
1465                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss]]
1466                     -- We actually found some actual parallel lists so
1467                     -- we wrap them into as a ParStmt
1468                 }
1469
1470 pquals :: { Located [[LStmt RdrName]] }
1471     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1472     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1473
1474 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last 
1475                                         -- one can "grab" the earlier ones
1476     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1477     | squals ',' qual                        { LL ($3 : unLoc $1) }
1478     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1479     | qual                                   { L1 [$1] }
1480 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1481 --  | '{|' pquals '|}'                       { L1 [$2] }
1482
1483
1484 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1485 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1486 -- demand. Note that the {| |} symbols are reused from -XGenerics and hence if you want to compile
1487 -- a program that makes use of this temporary syntax you must supply that flag to GHC
1488
1489 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1490                         -- Function is applied to a list of stmts *in order*
1491     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt leftStmts $2) }
1492     -- >>>
1493     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt leftStmts $2 $4) }
1494     | 'then' 'group' 'by' exp   { LL $ \leftStmts -> (mkGroupByStmt leftStmts $4) }
1495     -- <<<
1496     -- These two productions deliberately have a shift-reduce conflict. I have made 'group' into a special_id,
1497     -- which means you can enable TransformListComp while still using Data.List.group. However, this makes the two
1498     -- productions ambiguous. I've set things up so that Happy chooses to resolve the conflict in that case by
1499     -- choosing the "group by" variant, which is what we want.
1500     --
1501     -- This is rather dubious: the user might be confused as to how to parse this statement. However, it is a good
1502     -- practical choice. NB: Data.List.group :: [a] -> [[a]], so using the first production would not even type check
1503     -- if /that/ is the group function we conflict with.
1504     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt leftStmts $4) }
1505     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt leftStmts $4 $6) }
1506
1507 -----------------------------------------------------------------------------
1508 -- Parallel array expressions
1509
1510 -- The rules below are little bit contorted; see the list case for details.
1511 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1512 -- Moreover, we allow explicit arrays with no element (represented by the nil
1513 -- constructor in the list case).
1514
1515 parr :: { LHsExpr RdrName }
1516         :                               { noLoc (ExplicitPArr placeHolderType []) }
1517         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1518         | lexps                         { L1 $ ExplicitPArr placeHolderType 
1519                                                        (reverse (unLoc $1)) }
1520         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1521         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1522         | texp '|' flattenedpquals      { LL $ mkHsDo PArrComp (unLoc $3) $1 }
1523
1524 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1525
1526 -----------------------------------------------------------------------------
1527 -- Guards
1528
1529 guardquals :: { Located [LStmt RdrName] }
1530     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1531
1532 guardquals1 :: { Located [LStmt RdrName] }
1533     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1534     | qual                  { L1 [$1] }
1535
1536 -----------------------------------------------------------------------------
1537 -- Case alternatives
1538
1539 altslist :: { Located [LMatch RdrName] }
1540         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1541         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1542
1543 alts    :: { Located [LMatch RdrName] }
1544         : alts1                         { L1 (unLoc $1) }
1545         | ';' alts                      { LL (unLoc $2) }
1546
1547 alts1   :: { Located [LMatch RdrName] }
1548         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1549         | alts1 ';'                     { LL (unLoc $1) }
1550         | alt                           { L1 [$1] }
1551
1552 alt     :: { LMatch RdrName }
1553         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1554
1555 alt_rhs :: { Located (GRHSs RdrName) }
1556         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1557
1558 ralt :: { Located [LGRHS RdrName] }
1559         : '->' exp                      { LL (unguardedRHS $2) }
1560         | gdpats                        { L1 (reverse (unLoc $1)) }
1561
1562 gdpats :: { Located [LGRHS RdrName] }
1563         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1564         | gdpat                         { L1 [$1] }
1565
1566 gdpat   :: { LGRHS RdrName }
1567         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1568
1569 -- 'pat' recognises a pattern, including one with a bang at the top
1570 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1571 -- Bangs inside are parsed as infix operator applications, so that
1572 -- we parse them right when bang-patterns are off
1573 pat     :: { LPat RdrName }
1574 pat     :  exp                  {% checkPattern $1 }
1575         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1576
1577 apat   :: { LPat RdrName }      
1578 apat    : aexp                  {% checkPattern $1 }
1579         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1580
1581 apats  :: { [LPat RdrName] }
1582         : apat apats            { $1 : $2 }
1583         | {- empty -}           { [] }
1584
1585 -----------------------------------------------------------------------------
1586 -- Statement sequences
1587
1588 stmtlist :: { Located [LStmt RdrName] }
1589         : '{'           stmts '}'       { LL (unLoc $2) }
1590         |     vocurly   stmts close     { $2 }
1591
1592 --      do { ;; s ; s ; ; s ;; }
1593 -- The last Stmt should be an expression, but that's hard to enforce
1594 -- here, because we need too much lookahead if we see do { e ; }
1595 -- So we use ExprStmts throughout, and switch the last one over
1596 -- in ParseUtils.checkDo instead
1597 stmts :: { Located [LStmt RdrName] }
1598         : stmt stmts_help               { LL ($1 : unLoc $2) }
1599         | ';' stmts                     { LL (unLoc $2) }
1600         | {- empty -}                   { noLoc [] }
1601
1602 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1603         : ';' stmts                     { LL (unLoc $2) }
1604         | {- empty -}                   { noLoc [] }
1605
1606 -- For typing stmts at the GHCi prompt, where 
1607 -- the input may consist of just comments.
1608 maybe_stmt :: { Maybe (LStmt RdrName) }
1609         : stmt                          { Just $1 }
1610         | {- nothing -}                 { Nothing }
1611
1612 stmt  :: { LStmt RdrName }
1613         : qual                              { $1 }
1614         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1615
1616 qual  :: { LStmt RdrName }
1617     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1618     | exp                                   { L1 $ mkExprStmt $1 }
1619     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1620
1621 -----------------------------------------------------------------------------
1622 -- Record Field Update/Construction
1623
1624 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1625         : fbinds1                       { $1 }
1626         | {- empty -}                   { ([], False) }
1627
1628 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1629         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) } 
1630         | fbind                         { ([$1], False) }
1631         | '..'                          { ([],   True) }
1632   
1633 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1634         : qvar '=' exp  { HsRecField $1 $3 False }
1635         | qvar          { HsRecField $1 (L (getLoc $1) placeHolderPunRhs) True }
1636                         -- Here's where we say that plain 'x'
1637                         -- means exactly 'x = x'.  The pun-flag boolean is
1638                         -- there so we can still print it right
1639
1640 -----------------------------------------------------------------------------
1641 -- Implicit Parameter Bindings
1642
1643 dbinds  :: { Located [LIPBind RdrName] }
1644         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1645                               in rest `seq` this `seq` LL (this : rest) }
1646         | dbinds ';'                    { LL (unLoc $1) }
1647         | dbind                         { let this = $1 in this `seq` L1 [this] }
1648 --      | {- empty -}                   { [] }
1649
1650 dbind   :: { LIPBind RdrName }
1651 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1652
1653 ipvar   :: { Located (IPName RdrName) }
1654         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1655
1656 -----------------------------------------------------------------------------
1657 -- Warnings and deprecations
1658
1659 namelist :: { Located [RdrName] }
1660 namelist : name_var              { L1 [unLoc $1] }
1661          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1662
1663 name_var :: { Located RdrName }
1664 name_var : var { $1 }
1665          | con { $1 }
1666
1667 -----------------------------------------
1668 -- Data constructors
1669 qcon    :: { Located RdrName }
1670         : qconid                { $1 }
1671         | '(' qconsym ')'       { LL (unLoc $2) }
1672         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1673 -- The case of '[:' ':]' is part of the production `parr'
1674
1675 con     :: { Located RdrName }
1676         : conid                 { $1 }
1677         | '(' consym ')'        { LL (unLoc $2) }
1678         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1679
1680 con_list :: { Located [Located RdrName] }
1681 con_list : con                  { L1 [$1] }
1682          | con ',' con_list     { LL ($1 : unLoc $3) }
1683
1684 sysdcon :: { Located DataCon }  -- Wired in data constructors
1685         : '(' ')'               { LL unitDataCon }
1686         | '(' commas ')'        { LL $ tupleCon Boxed ($2 + 1) }
1687         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1688         | '(#' commas '#)'      { LL $ tupleCon Unboxed ($2 + 1) }
1689         | '[' ']'               { LL nilDataCon }
1690
1691 conop :: { Located RdrName }
1692         : consym                { $1 }  
1693         | '`' conid '`'         { LL (unLoc $2) }
1694
1695 qconop :: { Located RdrName }
1696         : qconsym               { $1 }
1697         | '`' qconid '`'        { LL (unLoc $2) }
1698
1699 -----------------------------------------------------------------------------
1700 -- Type constructors
1701
1702 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1703         : oqtycon                       { $1 }
1704         | '(' ')'                       { LL $ getRdrName unitTyCon }
1705         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed ($2 + 1)) }
1706         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1707         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed ($2 + 1)) }
1708         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1709         | '[' ']'                       { LL $ listTyCon_RDR }
1710         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1711
1712 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1713         : qtycon                        { $1 }
1714         | '(' qtyconsym ')'             { LL (unLoc $2) }
1715
1716 qtyconop :: { Located RdrName } -- Qualified or unqualified
1717         : qtyconsym                     { $1 }
1718         | '`' qtycon '`'                { LL (unLoc $2) }
1719
1720 qtycon :: { Located RdrName }   -- Qualified or unqualified
1721         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1722         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1723         | tycon                         { $1 }
1724
1725 tycon   :: { Located RdrName }  -- Unqualified
1726         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1727
1728 qtyconsym :: { Located RdrName }
1729         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1730         | tyconsym                      { $1 }
1731
1732 tyconsym :: { Located RdrName }
1733         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1734
1735 -----------------------------------------------------------------------------
1736 -- Operators
1737
1738 op      :: { Located RdrName }   -- used in infix decls
1739         : varop                 { $1 }
1740         | conop                 { $1 }
1741
1742 varop   :: { Located RdrName }
1743         : varsym                { $1 }
1744         | '`' varid '`'         { LL (unLoc $2) }
1745
1746 qop     :: { LHsExpr RdrName }   -- used in sections
1747         : qvarop                { L1 $ HsVar (unLoc $1) }
1748         | qconop                { L1 $ HsVar (unLoc $1) }
1749
1750 qopm    :: { LHsExpr RdrName }   -- used in sections
1751         : qvaropm               { L1 $ HsVar (unLoc $1) }
1752         | qconop                { L1 $ HsVar (unLoc $1) }
1753
1754 qvarop :: { Located RdrName }
1755         : qvarsym               { $1 }
1756         | '`' qvarid '`'        { LL (unLoc $2) }
1757
1758 qvaropm :: { Located RdrName }
1759         : qvarsym_no_minus      { $1 }
1760         | '`' qvarid '`'        { LL (unLoc $2) }
1761
1762 -----------------------------------------------------------------------------
1763 -- Type variables
1764
1765 tyvar   :: { Located RdrName }
1766 tyvar   : tyvarid               { $1 }
1767         | '(' tyvarsym ')'      { LL (unLoc $2) }
1768
1769 tyvarop :: { Located RdrName }
1770 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1771         | tyvarsym              { $1 }
1772         | '.'                   {% parseErrorSDoc (getLoc $1) 
1773                                       (vcat [ptext (sLit "Illegal symbol '.' in type"), 
1774                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1775                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1776                                 }
1777
1778 tyvarid :: { Located RdrName }
1779         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1780         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1781         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1782         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1783         | 'threadsafe'          { L1 $! mkUnqual tvName (fsLit "threadsafe") }
1784
1785 tyvarsym :: { Located RdrName }
1786 -- Does not include "!", because that is used for strictness marks
1787 --               or ".", because that separates the quantified type vars from the rest
1788 --               or "*", because that's used for kinds
1789 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1790
1791 -----------------------------------------------------------------------------
1792 -- Variables 
1793
1794 var     :: { Located RdrName }
1795         : varid                 { $1 }
1796         | '(' varsym ')'        { LL (unLoc $2) }
1797
1798 qvar    :: { Located RdrName }
1799         : qvarid                { $1 }
1800         | '(' varsym ')'        { LL (unLoc $2) }
1801         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1802 -- We've inlined qvarsym here so that the decision about
1803 -- whether it's a qvar or a var can be postponed until
1804 -- *after* we see the close paren.
1805
1806 qvarid :: { Located RdrName }
1807         : varid                 { $1 }
1808         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1809         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1810
1811 varid :: { Located RdrName }
1812         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1813         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1814         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1815         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1816         | 'threadsafe'          { L1 $! mkUnqual varName (fsLit "threadsafe") }
1817         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1818         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1819
1820 qvarsym :: { Located RdrName }
1821         : varsym                { $1 }
1822         | qvarsym1              { $1 }
1823
1824 qvarsym_no_minus :: { Located RdrName }
1825         : varsym_no_minus       { $1 }
1826         | qvarsym1              { $1 }
1827
1828 qvarsym1 :: { Located RdrName }
1829 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1830
1831 varsym :: { Located RdrName }
1832         : varsym_no_minus       { $1 }
1833         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1834
1835 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1836         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1837         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1838
1839
1840 -- These special_ids are treated as keywords in various places, 
1841 -- but as ordinary ids elsewhere.   'special_id' collects all these
1842 -- except 'unsafe', 'forall', and 'family' whose treatment differs
1843 -- depending on context 
1844 special_id :: { Located FastString }
1845 special_id
1846         : 'as'                  { L1 (fsLit "as") }
1847         | 'qualified'           { L1 (fsLit "qualified") }
1848         | 'hiding'              { L1 (fsLit "hiding") }
1849         | 'export'              { L1 (fsLit "export") }
1850         | 'label'               { L1 (fsLit "label")  }
1851         | 'dynamic'             { L1 (fsLit "dynamic") }
1852         | 'stdcall'             { L1 (fsLit "stdcall") }
1853         | 'ccall'               { L1 (fsLit "ccall") }
1854         | 'prim'                { L1 (fsLit "prim") }
1855         | 'group'               { L1 (fsLit "group") }
1856
1857 special_sym :: { Located FastString }
1858 special_sym : '!'       { L1 (fsLit "!") }
1859             | '.'       { L1 (fsLit ".") }
1860             | '*'       { L1 (fsLit "*") }
1861
1862 -----------------------------------------------------------------------------
1863 -- Data constructors
1864
1865 qconid :: { Located RdrName }   -- Qualified or unqualified
1866         : conid                 { $1 }
1867         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1868         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1869
1870 conid   :: { Located RdrName }
1871         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1872
1873 qconsym :: { Located RdrName }  -- Qualified or unqualified
1874         : consym                { $1 }
1875         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1876
1877 consym :: { Located RdrName }
1878         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1879
1880         -- ':' means only list cons
1881         | ':'                   { L1 $ consDataCon_RDR }
1882
1883
1884 -----------------------------------------------------------------------------
1885 -- Literals
1886
1887 literal :: { Located HsLit }
1888         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1889         | STRING                { L1 $ HsString     $ getSTRING $1 }
1890         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1891         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1892         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1893         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1894         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1895         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1896
1897 -----------------------------------------------------------------------------
1898 -- Layout
1899
1900 close :: { () }
1901         : vccurly               { () } -- context popped in lexer.
1902         | error                 {% popContext }
1903
1904 -----------------------------------------------------------------------------
1905 -- Miscellaneous (mostly renamings)
1906
1907 modid   :: { Located ModuleName }
1908         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1909         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1910                                   mkModuleNameFS
1911                                    (mkFastString
1912                                      (unpackFS mod ++ '.':unpackFS c))
1913                                 }
1914
1915 commas :: { Int }
1916         : commas ','                    { $1 + 1 }
1917         | ','                           { 1 }
1918
1919 -----------------------------------------------------------------------------
1920 -- Documentation comments
1921
1922 docnext :: { LHsDocString }
1923   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
1924
1925 docprev :: { LHsDocString }
1926   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
1927
1928 docnamed :: { Located (String, HsDocString) }
1929   : DOCNAMED {%
1930       let string = getDOCNAMED $1 
1931           (name, rest) = break isSpace string
1932       in return (L1 (name, HsDocString (mkFastString rest))) }
1933
1934 docsection :: { Located (Int, HsDocString) }
1935   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1936         return (L1 (n, HsDocString (mkFastString doc))) }
1937
1938 moduleheader :: { Maybe LHsDocString }
1939         : DOCNEXT {% let string = getDOCNEXT $1 in
1940                      return (Just (L1 (HsDocString (mkFastString string)))) }
1941
1942 maybe_docprev :: { Maybe LHsDocString }
1943         : docprev                       { Just $1 }
1944         | {- empty -}                   { Nothing }
1945
1946 maybe_docnext :: { Maybe LHsDocString }
1947         : docnext                       { Just $1 }
1948         | {- empty -}                   { Nothing }
1949
1950 {
1951 happyError :: P a
1952 happyError = srcParseFail
1953
1954 getVARID        (L _ (ITvarid    x)) = x
1955 getCONID        (L _ (ITconid    x)) = x
1956 getVARSYM       (L _ (ITvarsym   x)) = x
1957 getCONSYM       (L _ (ITconsym   x)) = x
1958 getQVARID       (L _ (ITqvarid   x)) = x
1959 getQCONID       (L _ (ITqconid   x)) = x
1960 getQVARSYM      (L _ (ITqvarsym  x)) = x
1961 getQCONSYM      (L _ (ITqconsym  x)) = x
1962 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
1963 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
1964 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1965 getCHAR         (L _ (ITchar     x)) = x
1966 getSTRING       (L _ (ITstring   x)) = x
1967 getINTEGER      (L _ (ITinteger  x)) = x
1968 getRATIONAL     (L _ (ITrational x)) = x
1969 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1970 getPRIMSTRING   (L _ (ITprimstring x)) = x
1971 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1972 getPRIMWORD     (L _ (ITprimword x)) = x
1973 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
1974 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
1975 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
1976 getINLINE       (L _ (ITinline_prag b)) = b
1977 getINLINE_CONLIKE (L _ (ITinline_conlike_prag b)) = b
1978 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
1979
1980 getDOCNEXT (L _ (ITdocCommentNext x)) = x
1981 getDOCPREV (L _ (ITdocCommentPrev x)) = x
1982 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
1983 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
1984
1985 getSCC :: Located Token -> P FastString
1986 getSCC lt = do let s = getSTRING lt
1987                    err = "Spaces are not allowed in SCCs"
1988                -- We probably actually want to be more restrictive than this
1989                if ' ' `elem` unpackFS s
1990                    then failSpanMsgP (getLoc lt) (text err)
1991                    else return s
1992
1993 -- Utilities for combining source spans
1994 comb2 :: Located a -> Located b -> SrcSpan
1995 comb2 a b = a `seq` b `seq` combineLocs a b
1996
1997 comb3 :: Located a -> Located b -> Located c -> SrcSpan
1998 comb3 a b c = a `seq` b `seq` c `seq`
1999     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2000
2001 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2002 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2003     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2004                 combineSrcSpans (getLoc c) (getLoc d))
2005
2006 -- strict constructor version:
2007 {-# INLINE sL #-}
2008 sL :: SrcSpan -> a -> Located a
2009 sL span a = span `seq` a `seq` L span a
2010
2011 -- Make a source location for the file.  We're a bit lazy here and just
2012 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2013 -- try to find the span of the whole file (ToDo).
2014 fileSrcSpan :: P SrcSpan
2015 fileSrcSpan = do 
2016   l <- getSrcLoc; 
2017   let loc = mkSrcLoc (srcLocFile l) 1 1;
2018   return (mkSrcSpan loc loc)
2019 }