compiler/parser/Parser.y.pp

   1 --                                                              -*-haskell-*-
   2 -- ---------------------------------------------------------------------------
   3 -- (c) The University of Glasgow 1997-2003
   4 ---
   5 -- The GHC grammar.
   6 --
   7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -- ---------------------------------------------------------------------------
   9
  10 {
  11 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
  12                 parseHeader ) where
  13
  14 #define INCLUDE #include
  15 INCLUDE "HsVersions.h"
  16
  17 import HsSyn
  18 import RdrHsSyn
  19 import HscTypes         ( IsBootInterface, DeprecTxt )
  20 import Lexer
  21 import RdrName
  22 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  23                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  24 import Type             ( funTyCon )
  25 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
  26                           CCallConv(..), CCallTarget(..), defaultCCallConv
  27                         )
  28 import OccName          ( varName, dataName, tcClsName, tvName )
  29 import DataCon          ( DataCon, dataConName )
  30 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
  31                           SrcSpan, combineLocs, srcLocFile,
  32                           mkSrcLoc, mkSrcSpan )
  33 import Module
  34 import StaticFlags      ( opt_SccProfilingOn )
  35 import Type             ( Kind, mkArrowKind, liftedTypeKind, unliftedTypeKind )
  36 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  37                           Activation(..), defaultInlineSpec )
  38 import OrdList
  39 import HaddockParse
  40 import {-# SOURCE #-} HaddockLex hiding ( Token )
  41 import HaddockUtils
  42
  43 import FastString
  44 import Maybes           ( orElse )
  45 import Outputable
  46
  47 import Control.Monad    ( when )
  48 import GHC.Exts
  49 import Data.Char
  50 import Control.Monad    ( mplus )
  51 }
  52
  53 {-
  54 -----------------------------------------------------------------------------
  55 6 December 2006
  56
  57 Conflicts: 32 shift/reduce
  58            1 reduce/reduce
  59
  60 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  61 would think the two should never occur in the same context.
  62
  63   -=chak
  64
  65 -----------------------------------------------------------------------------
  66 26 July 2006
  67
  68 Conflicts: 37 shift/reduce
  69            1 reduce/reduce
  70
  71 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  72 would think the two should never occur in the same context.
  73
  74   -=chak
  75
  76 -----------------------------------------------------------------------------
  77 Conflicts: 38 shift/reduce (1.25)
  78
  79 10 for abiguity in 'if x then y else z + 1'             [State 178]
  80         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  81         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
  82
  83 1 for ambiguity in 'if x then y else z :: T'            [State 178]
  84         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  85
  86 4 for ambiguity in 'if x then y else z -< e'            [State 178]
  87         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
  88         There are four such operators: -<, >-, -<<, >>-
  89
  90
  91 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
  92         Which of these two is intended?
  93           case v of
  94             (x::T) -> T         -- Rhs is T
  95     or
  96           case v of
  97             (x::T -> T) -> ..   -- Rhs is ...
  98
  99 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
 100         (e::a) `b` c, or
 101         (e :: (a `b` c))
 102     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
 103     Same duplication between states 11 and 253 as the previous case
 104
 105 1 for ambiguity in 'let ?x ...'                         [State 329]
 106         the parser can't tell whether the ?x is the lhs of a normal binding or
 107         an implicit binding.  Fortunately resolving as shift gives it the only
 108         sensible meaning, namely the lhs of an implicit binding.
 109
 110 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
 111         we don't know whether the '[' starts the activation or not: it
 112         might be the start of the declaration with the activation being
 113         empty.  --SDM 1/4/2002
 114
 115 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
 116         since 'forall' is a valid variable name, we don't know whether
 117         to treat a forall on the input as the beginning of a quantifier
 118         or the beginning of the rule itself.  Resolving to shift means
 119         it's always treated as a quantifier, hence the above is disallowed.
 120         This saves explicitly defining a grammar for the rule lhs that
 121         doesn't include 'forall'.
 122
 123 1 for ambiguity when the source file starts with "-- | doc". We need another
 124   token of lookahead to determine if a top declaration or the 'module' keyword
 125   follows. Shift parses as if the 'module' keyword follows.
 126
 127 -- ---------------------------------------------------------------------------
 128 -- Adding location info
 129
 130 This is done in a stylised way using the three macros below, L0, L1
 131 and LL.  Each of these macros can be thought of as having type
 132
 133    L0, L1, LL :: a -> Located a
 134
 135 They each add a SrcSpan to their argument.
 136
 137    L0   adds 'noSrcSpan', used for empty productions
 138      -- This doesn't seem to work anymore -=chak
 139
 140    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
 141         from that token.
 142
 143    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
 144         the first and last tokens.
 145
 146 These suffice for the majority of cases.  However, we must be
 147 especially careful with empty productions: LL won't work if the first
 148 or last token on the lhs can represent an empty span.  In these cases,
 149 we have to calculate the span using more of the tokens from the lhs, eg.
 150
 151         | 'newtype' tycl_hdr '=' newconstr deriving
 152                 { L (comb3 $1 $4 $5)
 153                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
 154
 155 We provide comb3 and comb4 functions which are useful in such cases.
 156
 157 Be careful: there's no checking that you actually got this right, the
 158 only symptom will be that the SrcSpans of your syntax will be
 159 incorrect.
 160
 161 /*
 162  * We must expand these macros *before* running Happy, which is why this file is
 163  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 164  */
 165 #define L0   L noSrcSpan
 166 #define L1   sL (getLoc $1)
 167 #define LL   sL (comb2 $1 $>)
 168
 169 -- -----------------------------------------------------------------------------
 170
 171 -}
 172
 173 %token
 174  '_'            { L _ ITunderscore }            -- Haskell keywords
 175  'as'           { L _ ITas }
 176  'case'         { L _ ITcase }
 177  'class'        { L _ ITclass }
 178  'data'         { L _ ITdata }
 179  'default'      { L _ ITdefault }
 180  'deriving'     { L _ ITderiving }
 181  'do'           { L _ ITdo }
 182  'else'         { L _ ITelse }
 183  'for'          { L _ ITfor }
 184  'hiding'       { L _ IThiding }
 185  'if'           { L _ ITif }
 186  'import'       { L _ ITimport }
 187  'in'           { L _ ITin }
 188  'infix'        { L _ ITinfix }
 189  'infixl'       { L _ ITinfixl }
 190  'infixr'       { L _ ITinfixr }
 191  'instance'     { L _ ITinstance }
 192  'let'          { L _ ITlet }
 193  'module'       { L _ ITmodule }
 194  'newtype'      { L _ ITnewtype }
 195  'of'           { L _ ITof }
 196  'qualified'    { L _ ITqualified }
 197  'then'         { L _ ITthen }
 198  'type'         { L _ ITtype }
 199  'where'        { L _ ITwhere }
 200  '_scc_'        { L _ ITscc }         -- ToDo: remove
 201
 202  'forall'       { L _ ITforall }                -- GHC extension keywords
 203  'foreign'      { L _ ITforeign }
 204  'export'       { L _ ITexport }
 205  'label'        { L _ ITlabel }
 206  'dynamic'      { L _ ITdynamic }
 207  'safe'         { L _ ITsafe }
 208  'threadsafe'   { L _ ITthreadsafe }
 209  'unsafe'       { L _ ITunsafe }
 210  'mdo'          { L _ ITmdo }
 211  'iso'          { L _ ITiso }
 212  'family'       { L _ ITfamily }
 213  'stdcall'      { L _ ITstdcallconv }
 214  'ccall'        { L _ ITccallconv }
 215  'dotnet'       { L _ ITdotnet }
 216  'proc'         { L _ ITproc }          -- for arrow notation extension
 217  'rec'          { L _ ITrec }           -- for arrow notation extension
 218
 219  '{-# INLINE'             { L _ (ITinline_prag _) }
 220  '{-# SPECIALISE'         { L _ ITspec_prag }
 221  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
 222  '{-# SOURCE'      { L _ ITsource_prag }
 223  '{-# RULES'       { L _ ITrules_prag }
 224  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 225  '{-# SCC'         { L _ ITscc_prag }
 226  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 227  '{-# UNPACK'      { L _ ITunpack_prag }
 228  '#-}'             { L _ ITclose_prag }
 229
 230  '..'           { L _ ITdotdot }                        -- reserved symbols
 231  ':'            { L _ ITcolon }
 232  '::'           { L _ ITdcolon }
 233  '='            { L _ ITequal }
 234  '\\'           { L _ ITlam }
 235  '|'            { L _ ITvbar }
 236  '<-'           { L _ ITlarrow }
 237  '->'           { L _ ITrarrow }
 238  '@'            { L _ ITat }
 239  '~'            { L _ ITtilde }
 240  '=>'           { L _ ITdarrow }
 241  '-'            { L _ ITminus }
 242  '!'            { L _ ITbang }
 243  '*'            { L _ ITstar }
 244  '-<'           { L _ ITlarrowtail }            -- for arrow notation
 245  '>-'           { L _ ITrarrowtail }            -- for arrow notation
 246  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
 247  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
 248  '.'            { L _ ITdot }
 249
 250  '{'            { L _ ITocurly }                        -- special symbols
 251  '}'            { L _ ITccurly }
 252  '{|'           { L _ ITocurlybar }
 253  '|}'           { L _ ITccurlybar }
 254  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
 255  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
 256  '['            { L _ ITobrack }
 257  ']'            { L _ ITcbrack }
 258  '[:'           { L _ ITopabrack }
 259  ':]'           { L _ ITcpabrack }
 260  '('            { L _ IToparen }
 261  ')'            { L _ ITcparen }
 262  '(#'           { L _ IToubxparen }
 263  '#)'           { L _ ITcubxparen }
 264  '(|'           { L _ IToparenbar }
 265  '|)'           { L _ ITcparenbar }
 266  ';'            { L _ ITsemi }
 267  ','            { L _ ITcomma }
 268  '`'            { L _ ITbackquote }
 269
 270  VARID          { L _ (ITvarid    _) }          -- identifiers
 271  CONID          { L _ (ITconid    _) }
 272  VARSYM         { L _ (ITvarsym   _) }
 273  CONSYM         { L _ (ITconsym   _) }
 274  QVARID         { L _ (ITqvarid   _) }
 275  QCONID         { L _ (ITqconid   _) }
 276  QVARSYM        { L _ (ITqvarsym  _) }
 277  QCONSYM        { L _ (ITqconsym  _) }
 278
 279  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
 280
 281  CHAR           { L _ (ITchar     _) }
 282  STRING         { L _ (ITstring   _) }
 283  INTEGER        { L _ (ITinteger  _) }
 284  RATIONAL       { L _ (ITrational _) }
 285
 286  PRIMCHAR       { L _ (ITprimchar   _) }
 287  PRIMSTRING     { L _ (ITprimstring _) }
 288  PRIMINTEGER    { L _ (ITprimint    _) }
 289  PRIMFLOAT      { L _ (ITprimfloat  _) }
 290  PRIMDOUBLE     { L _ (ITprimdouble _) }
 291
 292  DOCNEXT        { L _ (ITdocCommentNext _) }
 293  DOCPREV        { L _ (ITdocCommentPrev _) }
 294  DOCNAMED       { L _ (ITdocCommentNamed _) }
 295  DOCSECTION     { L _ (ITdocSection _ _) }
 296  DOCOPTIONS     { L _ (ITdocOptions _) }
 297
 298 -- Template Haskell
 299 '[|'            { L _ ITopenExpQuote  }
 300 '[p|'           { L _ ITopenPatQuote  }
 301 '[t|'           { L _ ITopenTypQuote  }
 302 '[d|'           { L _ ITopenDecQuote  }
 303 '|]'            { L _ ITcloseQuote    }
 304 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
 305 '$('            { L _ ITparenEscape   }     -- $( exp )
 306 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
 307 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
 308
 309 %monad { P } { >>= } { return }
 310 %lexer { lexer } { L _ ITeof }
 311 %name parseModule module
 312 %name parseStmt   maybe_stmt
 313 %name parseIdentifier  identifier
 314 %name parseType ctype
 315 %partial parseHeader header
 316 %tokentype { (Located Token) }
 317 %%
 318
 319 -----------------------------------------------------------------------------
 320 -- Identifiers; one of the entry points
 321 identifier :: { Located RdrName }
 322         : qvar                          { $1 }
 323         | qcon                          { $1 }
 324         | qvarop                        { $1 }
 325         | qconop                        { $1 }
 326
 327 -----------------------------------------------------------------------------
 328 -- Module Header
 329
 330 -- The place for module deprecation is really too restrictive, but if it
 331 -- was allowed at its natural place just before 'module', we get an ugly
 332 -- s/r conflict with the second alternative. Another solution would be the
 333 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 334 -- either, and DEPRECATED is only expected to be used by people who really
 335 -- know what they are doing. :-)
 336
 337 module  :: { Located (HsModule RdrName) }
 338         : optdoc 'module' modid maybemoddeprec maybeexports 'where' body
 339                 {% fileSrcSpan >>= \ loc -> case $1 of { (opt, info, doc) ->
 340                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4
 341                           opt info doc) )}}
 342         | missing_module_keyword top close
 343                 {% fileSrcSpan >>= \ loc ->
 344                    return (L loc (HsModule Nothing Nothing
 345                           (fst $2) (snd $2) Nothing Nothing emptyHaddockModInfo
 346                           Nothing)) }
 347
 348 optdoc :: { (Maybe String, HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
 349         : moduleheader            { (Nothing, fst $1, snd $1) }
 350         | docoptions              { (Just $1, emptyHaddockModInfo, Nothing)}
 351         | docoptions moduleheader { (Just $1, fst $2, snd $2) }
 352         | moduleheader docoptions { (Just $2, fst $1, snd $1) }
 353         | {- empty -}             { (Nothing, emptyHaddockModInfo, Nothing) }
 354
 355 missing_module_keyword :: { () }
 356         : {- empty -}                           {% pushCurrentContext }
 357
 358 maybemoddeprec :: { Maybe DeprecTxt }
 359         : '{-# DEPRECATED' STRING '#-}'         { Just (getSTRING $2) }
 360         |  {- empty -}                          { Nothing }
 361
 362 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 363         :  '{'            top '}'               { $2 }
 364         |      vocurly    top close             { $2 }
 365
 366 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 367         : importdecls                           { (reverse $1,[]) }
 368         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 369         | cvtopdecls                            { ([],$1) }
 370
 371 cvtopdecls :: { [LHsDecl RdrName] }
 372         : topdecls                              { cvTopDecls $1 }
 373
 374 -----------------------------------------------------------------------------
 375 -- Module declaration & imports only
 376
 377 header  :: { Located (HsModule RdrName) }
 378         : optdoc 'module' modid maybemoddeprec maybeexports 'where' header_body
 379                 {% fileSrcSpan >>= \ loc -> case $1 of { (opt, info, doc) ->
 380                    return (L loc (HsModule (Just $3) $5 $7 [] $4
 381                    opt info doc))}}
 382         | missing_module_keyword importdecls
 383                 {% fileSrcSpan >>= \ loc ->
 384                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
 385                    Nothing emptyHaddockModInfo Nothing)) }
 386
 387 header_body :: { [LImportDecl RdrName] }
 388         :  '{'            importdecls           { $2 }
 389         |      vocurly    importdecls           { $2 }
 390
 391 -----------------------------------------------------------------------------
 392 -- The Export List
 393
 394 maybeexports :: { Maybe [LIE RdrName] }
 395         :  '(' exportlist ')'                   { Just $2 }
 396         |  {- empty -}                          { Nothing }
 397
 398 exportlist :: { [LIE RdrName] }
 399         : expdoclist ',' expdoclist             { $1 ++ $3 }
 400         | exportlist1                           { $1 }
 401
 402 exportlist1 :: { [LIE RdrName] }
 403         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
 404         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
 405         | expdoclist                                   { $1 }
 406
 407 expdoclist :: { [LIE RdrName] }
 408         : exp_doc expdoclist                           { $1 : $2 }
 409         | {- empty -}                                  { [] }
 410
 411 exp_doc :: { LIE RdrName }
 412         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
 413         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) }
 414         | docnext       { L1 (IEDoc (unLoc $1)) }
 415
 416    -- No longer allow things like [] and (,,,) to be exported
 417    -- They are built in syntax, always available
 418 export  :: { LIE RdrName }
 419         :  qvar                         { L1 (IEVar (unLoc $1)) }
 420         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
 421         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
 422         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
 423         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
 424         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
 425
 426 qcnames :: { [RdrName] }
 427         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
 428         |  qcname_ext                   { [unLoc $1]  }
 429
 430 qcname_ext :: { Located RdrName }       -- Variable or data constructor
 431                                         -- or tagged type constructor
 432         :  qcname                       { $1 }
 433         |  'type' qcon                  { sL (comb2 $1 $2)
 434                                              (setRdrNameSpace (unLoc $2)
 435                                                               tcClsName)  }
 436
 437 -- Cannot pull into qcname_ext, as qcname is also used in expression.
 438 qcname  :: { Located RdrName }  -- Variable or data constructor
 439         :  qvar                         { $1 }
 440         |  qcon                         { $1 }
 441
 442 -----------------------------------------------------------------------------
 443 -- Import Declarations
 444
 445 -- import decls can be *empty*, or even just a string of semicolons
 446 -- whereas topdecls must contain at least one topdecl.
 447
 448 importdecls :: { [LImportDecl RdrName] }
 449         : importdecls ';' importdecl            { $3 : $1 }
 450         | importdecls ';'                       { $1 }
 451         | importdecl                            { [ $1 ] }
 452         | {- empty -}                           { [] }
 453
 454 importdecl :: { LImportDecl RdrName }
 455         : 'import' maybe_src optqualified modid maybeas maybeimpspec
 456                 { L (comb4 $1 $4 $5 $6) (ImportDecl $4 $2 $3 (unLoc $5) (unLoc $6)) }
 457
 458 maybe_src :: { IsBootInterface }
 459         : '{-# SOURCE' '#-}'                    { True }
 460         | {- empty -}                           { False }
 461
 462 optqualified :: { Bool }
 463         : 'qualified'                           { True  }
 464         | {- empty -}                           { False }
 465
 466 maybeas :: { Located (Maybe ModuleName) }
 467         : 'as' modid                            { LL (Just (unLoc $2)) }
 468         | {- empty -}                           { noLoc Nothing }
 469
 470 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
 471         : impspec                               { L1 (Just (unLoc $1)) }
 472         | {- empty -}                           { noLoc Nothing }
 473
 474 impspec :: { Located (Bool, [LIE RdrName]) }
 475         :  '(' exportlist ')'                   { LL (False, $2) }
 476         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
 477
 478 -----------------------------------------------------------------------------
 479 -- Fixity Declarations
 480
 481 prec    :: { Int }
 482         : {- empty -}           { 9 }
 483         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
 484
 485 infix   :: { Located FixityDirection }
 486         : 'infix'                               { L1 InfixN  }
 487         | 'infixl'                              { L1 InfixL  }
 488         | 'infixr'                              { L1 InfixR }
 489
 490 ops     :: { Located [Located RdrName] }
 491         : ops ',' op                            { LL ($3 : unLoc $1) }
 492         | op                                    { L1 [$1] }
 493
 494 -----------------------------------------------------------------------------
 495 -- Top-Level Declarations
 496
 497 topdecls :: { OrdList (LHsDecl RdrName) }
 498         : topdecls ';' topdecl                  { $1 `appOL` $3 }
 499         | topdecls ';'                          { $1 }
 500         | topdecl                               { $1 }
 501
 502 topdecl :: { OrdList (LHsDecl RdrName) }
 503         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 504         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 505         | 'instance' inst_type where_inst
 506             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
 507               in
 508               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
 509         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
 510         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
 511         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
 512         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
 513         | '{-# RULES' rules '#-}'               { $2 }
 514         | decl                                  { unLoc $1 }
 515
 516         -- Template Haskell Extension
 517         | '$(' exp ')'                          { unitOL (LL $ SpliceD (SpliceDecl $2)) }
 518         | TH_ID_SPLICE                          { unitOL (LL $ SpliceD (SpliceDecl $
 519                                                         L1 $ HsVar (mkUnqual varName (getTH_ID_SPLICE $1))
 520                                                   )) }
 521
 522 -- Type classes
 523 --
 524 cl_decl :: { LTyClDecl RdrName }
 525         : 'class' tycl_hdr fds where_cls
 526                 {% do { let { (binds, sigs, ats, docs)           =
 527                                 cvBindsAndSigs (unLoc $4)
 528                             ; (ctxt, tc, tvs, tparms) = unLoc $2}
 529                       ; checkTyVars tparms      -- only type vars allowed
 530                       ; checkKindSigs ats
 531                       ; return $ L (comb4 $1 $2 $3 $4)
 532                                    (mkClassDecl (ctxt, tc, tvs)
 533                                                 (unLoc $3) sigs binds ats docs) } }
 534
 535 -- Type declarations (toplevel)
 536 --
 537 ty_decl :: { LTyClDecl RdrName }
 538            -- ordinary type synonyms
 539         : 'type' type '=' ctype
 540                 -- Note ctype, not sigtype, on the right of '='
 541                 -- We allow an explicit for-all but we don't insert one
 542                 -- in   type Foo a = (b,b)
 543                 -- Instead we just say b is out of scope
 544                 --
 545                 -- Note the use of type for the head; this allows
 546                 -- infix type constructors to be declared
 547                 {% do { (tc, tvs, _) <- checkSynHdr $2 False
 548                       ; return (L (comb2 $1 $4)
 549                                   (TySynonym tc tvs Nothing $4))
 550                       } }
 551
 552            -- type family declarations
 553         | 'type' 'family' type opt_kind_sig
 554                 -- Note the use of type for the head; this allows
 555                 -- infix type constructors to be declared
 556                 --
 557                 {% do { (tc, tvs, _) <- checkSynHdr $3 False
 558                       ; let kind = case unLoc $4 of
 559                                      Nothing -> liftedTypeKind
 560                                      Just ki -> ki
 561                       ; return (L (comb3 $1 $3 $4)
 562                                   (TyFunction tc tvs False kind))
 563                       } }
 564
 565            -- type instance declarations
 566         | 'type' 'instance' type '=' ctype
 567                 -- Note the use of type for the head; this allows
 568                 -- infix type constructors and type patterns
 569                 --
 570                 {% do { (tc, tvs, typats) <- checkSynHdr $3 True
 571                       ; return (L (comb2 $1 $5)
 572                                   (TySynonym tc tvs (Just typats) $5))
 573                       } }
 574
 575           -- ordinary data type or newtype declaration
 576         | data_or_newtype tycl_hdr constrs deriving
 577                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 578                       ; checkTyVars tparms    -- no type pattern
 579                       ; return $
 580                           L (comb4 $1 $2 $3 $4)
 581                                    -- We need the location on tycl_hdr in case
 582                                    -- constrs and deriving are both empty
 583                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 584                                Nothing (reverse (unLoc $3)) (unLoc $4)) } }
 585
 586           -- ordinary GADT declaration
 587         | data_or_newtype tycl_hdr opt_kind_sig
 588                  'where' gadt_constrlist
 589                  deriving
 590                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 591                       ; checkTyVars tparms    -- can have type pats
 592                       ; return $
 593                           L (comb4 $1 $2 $4 $5)
 594                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 595                               (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
 596
 597           -- data/newtype family
 598         | data_or_newtype 'family' tycl_hdr opt_kind_sig
 599                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 600                       ; checkTyVars tparms    -- no type pattern
 601                       ; let kind = case unLoc $4 of
 602                                      Nothing -> liftedTypeKind
 603                                      Just ki -> ki
 604                       ; return $
 605                           L (comb3 $1 $2 $4)
 606                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 607                               (Just kind) [] Nothing) } }
 608
 609           -- data/newtype instance declaration
 610         | data_or_newtype 'instance' tycl_hdr constrs deriving
 611                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 612                                              -- can have type pats
 613                       ; return $
 614                           L (comb4 $1 $3 $4 $5)
 615                                    -- We need the location on tycl_hdr in case
 616                                    -- constrs and deriving are both empty
 617                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 618                               Nothing (reverse (unLoc $4)) (unLoc $5)) } }
 619
 620           -- GADT instance declaration
 621         | data_or_newtype 'instance' tycl_hdr opt_kind_sig
 622                  'where' gadt_constrlist
 623                  deriving
 624                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 625                                              -- can have type pats
 626                       ; return $
 627                           L (comb4 $1 $3 $6 $7)
 628                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 629                                (unLoc $4) (reverse (unLoc $6)) (unLoc $7)) } }
 630
 631 -- Associate type family declarations
 632 --
 633 -- * They have a different syntax than on the toplevel (no family special
 634 --   identifier).
 635 --
 636 -- * They also need to be separate from instances; otherwise, data family
 637 --   declarations without a kind signature cause parsing conflicts with empty
 638 --   data declarations.
 639 --
 640 at_decl_cls :: { LTyClDecl RdrName }
 641            -- type family declarations
 642         : 'type' type opt_kind_sig
 643                 -- Note the use of type for the head; this allows
 644                 -- infix type constructors to be declared
 645                 --
 646                 {% do { (tc, tvs, _) <- checkSynHdr $2 False
 647                       ; let kind = case unLoc $3 of
 648                                      Nothing -> liftedTypeKind
 649                                      Just ki -> ki
 650                       ; return (L (comb3 $1 $2 $3)
 651                                   (TyFunction tc tvs False kind))
 652                       } }
 653
 654            -- default type instance
 655         | 'type' type '=' ctype
 656                 -- Note the use of type for the head; this allows
 657                 -- infix type constructors and type patterns
 658                 --
 659                 {% do { (tc, tvs, typats) <- checkSynHdr $2 True
 660                       ; return (L (comb2 $1 $4)
 661                                   (TySynonym tc tvs (Just typats) $4))
 662                       } }
 663
 664           -- data/newtype family declaration
 665         | data_or_newtype tycl_hdr opt_kind_sig
 666                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 667                       ; checkTyVars tparms    -- no type pattern
 668                       ; let kind = case unLoc $3 of
 669                                      Nothing -> liftedTypeKind
 670                                      Just ki -> ki
 671                       ; return $
 672                           L (comb3 $1 $2 $3)
 673                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 674                               (Just kind) [] Nothing) } }
 675
 676 -- Associate type instances
 677 --
 678 at_decl_inst :: { LTyClDecl RdrName }
 679            -- type instance declarations
 680         : 'type' type '=' ctype
 681                 -- Note the use of type for the head; this allows
 682                 -- infix type constructors and type patterns
 683                 --
 684                 {% do { (tc, tvs, typats) <- checkSynHdr $2 True
 685                       ; return (L (comb2 $1 $4)
 686                                   (TySynonym tc tvs (Just typats) $4))
 687                       } }
 688
 689         -- data/newtype instance declaration
 690         | data_or_newtype tycl_hdr constrs deriving
 691                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 692                                              -- can have type pats
 693                       ; return $
 694                           L (comb4 $1 $2 $3 $4)
 695                                    -- We need the location on tycl_hdr in case
 696                                    -- constrs and deriving are both empty
 697                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 698                               Nothing (reverse (unLoc $3)) (unLoc $4)) } }
 699
 700         -- GADT instance declaration
 701         | data_or_newtype tycl_hdr opt_kind_sig
 702                  'where' gadt_constrlist
 703                  deriving
 704                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 705                                              -- can have type pats
 706                       ; return $
 707                           L (comb4 $1 $2 $5 $6)
 708                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 709                              (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
 710
 711 opt_iso :: { Bool }
 712         :       { False }
 713         | 'iso' { True  }
 714
 715 data_or_newtype :: { Located NewOrData }
 716         : 'data'        { L1 DataType }
 717         | 'newtype'     { L1 NewType }
 718
 719 opt_kind_sig :: { Located (Maybe Kind) }
 720         :                               { noLoc Nothing }
 721         | '::' kind                     { LL (Just (unLoc $2)) }
 722
 723 -- tycl_hdr parses the header of a class or data type decl,
 724 -- which takes the form
 725 --      T a b
 726 --      Eq a => T a
 727 --      (Eq a, Ord b) => T a b
 728 --      T Int [a]                       -- for associated types
 729 -- Rather a lot of inlining here, else we get reduce/reduce errors
 730 tycl_hdr :: { Located (LHsContext RdrName,
 731                        Located RdrName,
 732                        [LHsTyVarBndr RdrName],
 733                        [LHsType RdrName]) }
 734         : context '=>' type             {% checkTyClHdr $1         $3 >>= return.LL }
 735         | type                          {% checkTyClHdr (noLoc []) $1 >>= return.L1 }
 736
 737 -----------------------------------------------------------------------------
 738 -- Stand-alone deriving
 739
 740 -- Glasgow extension: stand-alone deriving declarations
 741 stand_alone_deriving :: { LDerivDecl RdrName }
 742         : 'deriving' qtycon            'for' qtycon  {% do { p <- checkInstType (fmap HsTyVar $2)
 743                                                            ; checkDerivDecl (LL (DerivDecl p $4)) } }
 744
 745         | 'deriving' '(' inst_type ')' 'for' qtycon  {% checkDerivDecl (LL (DerivDecl $3 $6)) }
 746
 747 -----------------------------------------------------------------------------
 748 -- Nested declarations
 749
 750 -- Declaration in class bodies
 751 --
 752 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
 753 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 754           | decl                        { $1 }
 755
 756 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 757           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
 758           | decls_cls ';'               { LL (unLoc $1) }
 759           | decl_cls                    { $1 }
 760           | {- empty -}                 { noLoc nilOL }
 761
 762
 763 decllist_cls
 764         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 765         : '{'         decls_cls '}'     { LL (unLoc $2) }
 766         |     vocurly decls_cls close   { $2 }
 767
 768 -- Class body
 769 --
 770 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 771                                 -- No implicit parameters
 772                                 -- May have type declarations
 773         : 'where' decllist_cls          { LL (unLoc $2) }
 774         | {- empty -}                   { noLoc nilOL }
 775
 776 -- Declarations in instance bodies
 777 --
 778 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
 779 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 780            | decl                       { $1 }
 781
 782 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 783            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
 784            | decls_inst ';'             { LL (unLoc $1) }
 785            | decl_inst                  { $1 }
 786            | {- empty -}                { noLoc nilOL }
 787
 788 decllist_inst
 789         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 790         : '{'         decls_inst '}'    { LL (unLoc $2) }
 791         |     vocurly decls_inst close  { $2 }
 792
 793 -- Instance body
 794 --
 795 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 796                                 -- No implicit parameters
 797                                 -- May have type declarations
 798         : 'where' decllist_inst         { LL (unLoc $2) }
 799         | {- empty -}                   { noLoc nilOL }
 800
 801 -- Declarations in binding groups other than classes and instances
 802 --
 803 decls   :: { Located (OrdList (LHsDecl RdrName)) }
 804         : decls ';' decl                { LL (unLoc $1 `appOL` unLoc $3) }
 805         | decls ';'                     { LL (unLoc $1) }
 806         | decl                          { $1 }
 807         | {- empty -}                   { noLoc nilOL }
 808
 809 decllist :: { Located (OrdList (LHsDecl RdrName)) }
 810         : '{'            decls '}'      { LL (unLoc $2) }
 811         |     vocurly    decls close    { $2 }
 812
 813 -- Binding groups other than those of class and instance declarations
 814 --
 815 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
 816                                                 -- No type declarations
 817         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
 818         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 819         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 820
 821 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
 822                                                 -- No type declarations
 823         : 'where' binds                 { LL (unLoc $2) }
 824         | {- empty -}                   { noLoc emptyLocalBinds }
 825
 826
 827 -----------------------------------------------------------------------------
 828 -- Transformation Rules
 829
 830 rules   :: { OrdList (LHsDecl RdrName) }
 831         :  rules ';' rule                       { $1 `snocOL` $3 }
 832         |  rules ';'                            { $1 }
 833         |  rule                                 { unitOL $1 }
 834         |  {- empty -}                          { nilOL }
 835
 836 rule    :: { LHsDecl RdrName }
 837         : STRING activation rule_forall infixexp '=' exp
 838              { LL $ RuleD (HsRule (getSTRING $1)
 839                                   ($2 `orElse` AlwaysActive)
 840                                   $3 $4 placeHolderNames $6 placeHolderNames) }
 841
 842 activation :: { Maybe Activation }
 843         : {- empty -}                           { Nothing }
 844         | explicit_activation                   { Just $1 }
 845
 846 explicit_activation :: { Activation }  -- In brackets
 847         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
 848         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
 849
 850 rule_forall :: { [RuleBndr RdrName] }
 851         : 'forall' rule_var_list '.'            { $2 }
 852         | {- empty -}                           { [] }
 853
 854 rule_var_list :: { [RuleBndr RdrName] }
 855         : rule_var                              { [$1] }
 856         | rule_var rule_var_list                { $1 : $2 }
 857
 858 rule_var :: { RuleBndr RdrName }
 859         : varid                                 { RuleBndr $1 }
 860         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 861
 862 -----------------------------------------------------------------------------
 863 -- Deprecations (c.f. rules)
 864
 865 deprecations :: { OrdList (LHsDecl RdrName) }
 866         : deprecations ';' deprecation          { $1 `appOL` $3 }
 867         | deprecations ';'                      { $1 }
 868         | deprecation                           { $1 }
 869         | {- empty -}                           { nilOL }
 870
 871 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 872 deprecation :: { OrdList (LHsDecl RdrName) }
 873         : depreclist STRING
 874                 { toOL [ LL $ DeprecD (Deprecation n (getSTRING $2))
 875                        | n <- unLoc $1 ] }
 876
 877
 878 -----------------------------------------------------------------------------
 879 -- Foreign import and export declarations
 880
 881 fdecl :: { LHsDecl RdrName }
 882 fdecl : 'import' callconv safety fspec
 883                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
 884       | 'import' callconv        fspec
 885                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
 886                         return (LL d) } }
 887       | 'export' callconv fspec
 888                 {% mkExport $2 (unLoc $3) >>= return.LL }
 889
 890 callconv :: { CallConv }
 891           : 'stdcall'                   { CCall  StdCallConv }
 892           | 'ccall'                     { CCall  CCallConv   }
 893           | 'dotnet'                    { DNCall             }
 894
 895 safety :: { Safety }
 896         : 'unsafe'                      { PlayRisky }
 897         | 'safe'                        { PlaySafe  False }
 898         | 'threadsafe'                  { PlaySafe  True }
 899
 900 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
 901        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
 902        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
 903          -- if the entity string is missing, it defaults to the empty string;
 904          -- the meaning of an empty entity string depends on the calling
 905          -- convention
 906
 907 -----------------------------------------------------------------------------
 908 -- Type signatures
 909
 910 opt_sig :: { Maybe (LHsType RdrName) }
 911         : {- empty -}                   { Nothing }
 912         | '::' sigtype                  { Just $2 }
 913
 914 opt_asig :: { Maybe (LHsType RdrName) }
 915         : {- empty -}                   { Nothing }
 916         | '::' atype                    { Just $2 }
 917
 918 sigtypes1 :: { [LHsType RdrName] }
 919         : sigtype                       { [ $1 ] }
 920         | sigtype ',' sigtypes1         { $1 : $3 }
 921
 922 sigtype :: { LHsType RdrName }
 923         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 924         -- Wrap an Implicit forall if there isn't one there already
 925
 926 sigtypedoc :: { LHsType RdrName }
 927         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 928         -- Wrap an Implicit forall if there isn't one there already
 929
 930 sig_vars :: { Located [Located RdrName] }
 931          : sig_vars ',' var             { LL ($3 : unLoc $1) }
 932          | var                          { L1 [$1] }
 933
 934 -----------------------------------------------------------------------------
 935 -- Types
 936
 937 infixtype :: { LHsType RdrName }
 938         : btype qtyconop gentype         { LL $ HsOpTy $1 $2 $3 }
 939         | btype tyvarop  gentype         { LL $ HsOpTy $1 $2 $3 }
 940
 941 infixtypedoc :: { LHsType RdrName }
 942         : infixtype                      { $1 }
 943         | infixtype docprev              { LL $ HsDocTy $1 $2 }
 944
 945 gentypedoc :: { LHsType RdrName }
 946         : btype                          { $1 }
 947         | btypedoc                       { $1 }
 948         | infixtypedoc                   { $1 }
 949         | btype '->' ctypedoc            { LL $ HsFunTy $1 $3 }
 950         | btypedoc '->' ctypedoc         { LL $ HsFunTy $1 $3 }
 951
 952 ctypedoc  :: { LHsType RdrName }
 953         : 'forall' tv_bndrs '.' ctypedoc { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 954         | context '=>' gentypedoc        { LL $ mkImplicitHsForAllTy   $1 $3 }
 955         -- A type of form (context => type) is an *implicit* HsForAllTy
 956         | gentypedoc                     { $1 }
 957
 958 strict_mark :: { Located HsBang }
 959         : '!'                           { L1 HsStrict }
 960         | '{-# UNPACK' '#-}' '!'        { LL HsUnbox }
 961
 962 -- A ctype is a for-all type
 963 ctype   :: { LHsType RdrName }
 964         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 965         | context '=>' type             { LL $ mkImplicitHsForAllTy   $1 $3 }
 966         -- A type of form (context => type) is an *implicit* HsForAllTy
 967         | type                          { $1 }
 968
 969 -- We parse a context as a btype so that we don't get reduce/reduce
 970 -- errors in ctype.  The basic problem is that
 971 --      (Eq a, Ord a)
 972 -- looks so much like a tuple type.  We can't tell until we find the =>
 973 context :: { LHsContext RdrName }
 974         : btype                         {% checkContext $1 }
 975
 976 type :: { LHsType RdrName }
 977         : ipvar '::' gentype            { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 978         | gentype                       { $1 }
 979
 980 gentype :: { LHsType RdrName }
 981         : btype                         { $1 }
 982         | btype qtyconop gentype        { LL $ HsOpTy $1 $2 $3 }
 983         | btype tyvarop  gentype        { LL $ HsOpTy $1 $2 $3 }
 984         | btype '->' ctype              { LL $ HsFunTy $1 $3 }
 985
 986 btype :: { LHsType RdrName }
 987         : btype atype                   { LL $ HsAppTy $1 $2 }
 988         | atype                         { $1 }
 989
 990 btypedoc :: { LHsType RdrName }
 991         : btype atype docprev           { LL $ HsDocTy (L (comb2 $1 $2) (HsAppTy $1 $2)) $3 }
 992         | atype docprev                 { LL $ HsDocTy $1 $2 }
 993
 994 atype :: { LHsType RdrName }
 995         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
 996         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
 997         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }
 998         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
 999         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1000         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1001         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1002         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1003         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1004 -- Generics
1005         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
1006
1007 -- An inst_type is what occurs in the head of an instance decl
1008 --      e.g.  (Foo a, Gaz b) => Wibble a b
1009 -- It's kept as a single type, with a MonoDictTy at the right
1010 -- hand corner, for convenience.
1011 inst_type :: { LHsType RdrName }
1012         : sigtype                       {% checkInstType $1 }
1013
1014 inst_types1 :: { [LHsType RdrName] }
1015         : inst_type                     { [$1] }
1016         | inst_type ',' inst_types1     { $1 : $3 }
1017
1018 comma_types0  :: { [LHsType RdrName] }
1019         : comma_types1                  { $1 }
1020         | {- empty -}                   { [] }
1021
1022 comma_types1    :: { [LHsType RdrName] }
1023         : ctype                         { [$1] }
1024         | ctype  ',' comma_types1       { $1 : $3 }
1025
1026 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1027          : tv_bndr tv_bndrs             { $1 : $2 }
1028          | {- empty -}                  { [] }
1029
1030 tv_bndr :: { LHsTyVarBndr RdrName }
1031         : tyvar                         { L1 (UserTyVar (unLoc $1)) }
1032         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2)
1033                                                           (unLoc $4)) }
1034
1035 fds :: { Located [Located ([RdrName], [RdrName])] }
1036         : {- empty -}                   { noLoc [] }
1037         | '|' fds1                      { LL (reverse (unLoc $2)) }
1038
1039 fds1 :: { Located [Located ([RdrName], [RdrName])] }
1040         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1041         | fd                            { L1 [$1] }
1042
1043 fd :: { Located ([RdrName], [RdrName]) }
1044         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1045                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1046
1047 varids0 :: { Located [RdrName] }
1048         : {- empty -}                   { noLoc [] }
1049         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1050
1051 -----------------------------------------------------------------------------
1052 -- Kinds
1053
1054 kind    :: { Located Kind }
1055         : akind                 { $1 }
1056         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1057
1058 akind   :: { Located Kind }
1059         : '*'                   { L1 liftedTypeKind }
1060         | '!'                   { L1 unliftedTypeKind }
1061         | '(' kind ')'          { LL (unLoc $2) }
1062
1063
1064 -----------------------------------------------------------------------------
1065 -- Datatype declarations
1066
1067 gadt_constrlist :: { Located [LConDecl RdrName] }
1068         : '{'            gadt_constrs '}'       { LL (unLoc $2) }
1069         |     vocurly    gadt_constrs close     { $2 }
1070
1071 gadt_constrs :: { Located [LConDecl RdrName] }
1072         : gadt_constrs ';' gadt_constr  { LL ($3 : unLoc $1) }
1073         | gadt_constrs ';'              { $1 }
1074         | gadt_constr                   { L1 [$1] }
1075
1076 -- We allow the following forms:
1077 --      C :: Eq a => a -> T a
1078 --      C :: forall a. Eq a => !a -> T a
1079 --      D { x,y :: a } :: T a
1080 --      forall a. Eq a => D { x,y :: a } :: T a
1081
1082 gadt_constr :: { LConDecl RdrName }
1083         : con '::' sigtype
1084               { LL (mkGadtDecl $1 $3) }
1085         -- Syntax: Maybe merge the record stuff with the single-case above?
1086         --         (to kill the mostly harmless reduce/reduce error)
1087         -- XXX revisit audreyt
1088         | constr_stuff_record '::' sigtype
1089                 { let (con,details) = unLoc $1 in
1090                   LL (ConDecl con Implicit [] (noLoc []) details (ResTyGADT $3) Nothing) }
1091 {-
1092         | forall context '=>' constr_stuff_record '::' sigtype
1093                 { let (con,details) = unLoc $4 in
1094                   LL (ConDecl con Implicit (unLoc $1) $2 details (ResTyGADT $6) Nothing ) }
1095         | forall constr_stuff_record '::' sigtype
1096                 { let (con,details) = unLoc $2 in
1097                   LL (ConDecl con Implicit (unLoc $1) (noLoc []) details (ResTyGADT $4) Nothing) }
1098 -}
1099
1100
1101 constrs :: { Located [LConDecl RdrName] }
1102         : {- empty; a GHC extension -}  { noLoc [] }
1103         | maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1104
1105 constrs1 :: { Located [LConDecl RdrName] }
1106         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1107         | constr                                          { L1 [$1] }
1108
1109 constr :: { LConDecl RdrName }
1110         : maybe_docnext forall context '=>' constr_stuff maybe_docprev
1111                 { let (con,details) = unLoc $5 in
1112                   L (comb4 $2 $3 $4 $5) (ConDecl con Explicit (unLoc $2) $3 details ResTyH98 ($1 `mplus` $6)) }
1113         | maybe_docnext forall constr_stuff maybe_docprev
1114                 { let (con,details) = unLoc $3 in
1115                   L (comb2 $2 $3) (ConDecl con Explicit (unLoc $2) (noLoc []) details ResTyH98 ($1 `mplus` $4)) }
1116
1117 forall :: { Located [LHsTyVarBndr RdrName] }
1118         : 'forall' tv_bndrs '.'         { LL $2 }
1119         | {- empty -}                   { noLoc [] }
1120
1121 constr_stuff :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
1122 -- We parse the constructor declaration
1123 --      C t1 t2
1124 -- as a btype (treating C as a type constructor) and then convert C to be
1125 -- a data constructor.  Reason: it might continue like this:
1126 --      C t1 t2 %: D Int
1127 -- in which case C really would be a type constructor.  We can't resolve this
1128 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1129         : btype                         {% mkPrefixCon $1 [] >>= return.LL }
1130         | oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.LL }
1131         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.LL }
1132         | btype conop btype             { LL ($2, InfixCon $1 $3) }
1133
1134 constr_stuff_record :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
1135         : oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.sL (comb2 $1 $>) }
1136         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.sL (comb2 $1 $>) }
1137
1138 fielddecls :: { [([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName))] }
1139         : fielddecl maybe_docnext ',' maybe_docprev fielddecls { addFieldDoc (unLoc $1) $4 : addFieldDocs $5 $2 }
1140         | fielddecl                                            { [unLoc $1] }
1141
1142 fielddecl :: { Located ([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName)) }
1143         : maybe_docnext sig_vars '::' ctype maybe_docprev      { L (comb3 $2 $3 $4) (reverse (unLoc $2), $4, $1 `mplus` $5) }
1144
1145 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1146 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1147 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1148 -- We don't allow a context, but that's sorted out by the type checker.
1149 deriving :: { Located (Maybe [LHsType RdrName]) }
1150         : {- empty -}                           { noLoc Nothing }
1151         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1152                                       ; p <- checkInstType (L loc (HsTyVar tv))
1153                                       ; return (LL (Just [p])) } }
1154         | 'deriving' '(' ')'                    { LL (Just []) }
1155         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1156              -- Glasgow extension: allow partial
1157              -- applications in derivings
1158
1159 -----------------------------------------------------------------------------
1160 -- Value definitions
1161
1162 {- There's an awkward overlap with a type signature.  Consider
1163         f :: Int -> Int = ...rhs...
1164    Then we can't tell whether it's a type signature or a value
1165    definition with a result signature until we see the '='.
1166    So we have to inline enough to postpone reductions until we know.
1167 -}
1168
1169 {-
1170   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1171   instead of qvar, we get another shift/reduce-conflict. Consider the
1172   following programs:
1173
1174      { (^^) :: Int->Int ; }          Type signature; only var allowed
1175
1176      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1177                                      qvar allowed (because of instance decls)
1178
1179   We can't tell whether to reduce var to qvar until after we've read the signatures.
1180 -}
1181
1182 docdecl :: { LHsDecl RdrName }
1183         : docdecld { L1 (DocD (unLoc $1)) }
1184
1185 docdecld :: { LDocDecl RdrName }
1186         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1187         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1188         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1189         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1190
1191 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1192         : sigdecl                       { $1 }
1193         | '!' aexp rhs                  {% do { pat <- checkPattern $2;
1194                                                 return (LL $ unitOL $ LL $ ValD (
1195                                                         PatBind (LL $ BangPat pat) (unLoc $3)
1196                                                                 placeHolderType placeHolderNames)) } }
1197         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
1198                                                 return (LL $ unitOL (LL $ ValD r)) } }
1199         | docdecl                       { LL $ unitOL $1 }
1200
1201 rhs     :: { Located (GRHSs RdrName) }
1202         : '=' exp wherebinds    { L (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1203         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1204
1205 gdrhs :: { Located [LGRHS RdrName] }
1206         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1207         | gdrh                  { L1 [$1] }
1208
1209 gdrh :: { LGRHS RdrName }
1210         : '|' quals '=' exp     { sL (comb2 $1 $>) $ GRHS (reverse (unLoc $2)) $4 }
1211
1212 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1213         : infixexp '::' sigtypedoc
1214                                 {% do s <- checkValSig $1 $3;
1215                                       return (LL $ unitOL (LL $ SigD s)) }
1216                 -- See the above notes for why we need infixexp here
1217         | var ',' sig_vars '::' sigtypedoc
1218                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1219         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1220                                              | n <- unLoc $3 ] }
1221         | '{-# INLINE'   activation qvar '#-}'
1222                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 (getINLINE $1)))) }
1223         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1224                                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlineSpec)
1225                                             | t <- $4] }
1226         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1227                                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlineSpec $2 (getSPEC_INLINE $1)))
1228                                             | t <- $5] }
1229         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1230                                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1231
1232 -----------------------------------------------------------------------------
1233 -- Expressions
1234
1235 exp   :: { LHsExpr RdrName }
1236         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1237         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1238         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1239         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1240         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1241         | infixexp                      { $1 }
1242
1243 infixexp :: { LHsExpr RdrName }
1244         : exp10                         { $1 }
1245         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1246
1247 exp10 :: { LHsExpr RdrName }
1248         : '\\' apat apats opt_asig '->' exp
1249                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1250                                                                 (unguardedGRHSs $6)
1251                                                             ]) }
1252         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1253         | 'if' exp 'then' exp 'else' exp        { LL $ HsIf $2 $4 $6 }
1254         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1255         | '-' fexp                              { LL $ mkHsNegApp $2 }
1256
1257         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1258                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1259                                            return (L loc (mkHsDo DoExpr stmts body)) }
1260         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1261                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1262                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1263         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1264                                                         then HsSCC (unLoc $1) $2
1265                                                         else HsPar $2 }
1266
1267         | 'proc' aexp '->' exp
1268                         {% checkPattern $2 >>= \ p ->
1269                            return (LL $ HsProc p (LL $ HsCmdTop $4 []
1270                                                    placeHolderType undefined)) }
1271                                                 -- TODO: is LL right here?
1272
1273         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1274                                                     -- hdaume: core annotation
1275         | fexp                                  { $1 }
1276
1277 scc_annot :: { Located FastString }
1278         : '_scc_' STRING                        { LL $ getSTRING $2 }
1279         | '{-# SCC' STRING '#-}'                { LL $ getSTRING $2 }
1280
1281 fexp    :: { LHsExpr RdrName }
1282         : fexp aexp                             { LL $ HsApp $1 $2 }
1283         | aexp                                  { $1 }
1284
1285 aexp    :: { LHsExpr RdrName }
1286         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1287         | '~' aexp                      { LL $ ELazyPat $2 }
1288         | aexp1                         { $1 }
1289
1290 aexp1   :: { LHsExpr RdrName }
1291         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4)
1292                                                         (reverse $3);
1293                                         return (LL r) }}
1294         | aexp2                 { $1 }
1295
1296 -- Here was the syntax for type applications that I was planning
1297 -- but there are difficulties (e.g. what order for type args)
1298 -- so it's not enabled yet.
1299 -- But this case *is* used for the left hand side of a generic definition,
1300 -- which is parsed as an expression before being munged into a pattern
1301         | qcname '{|' gentype '|}'      { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1302                                                      (sL (getLoc $3) (HsType $3)) }
1303
1304 aexp2   :: { LHsExpr RdrName }
1305         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1306         | qcname                        { L1 (HsVar   $! unLoc $1) }
1307         | literal                       { L1 (HsLit   $! unLoc $1) }
1308         | INTEGER                       { L1 (HsOverLit $! mkHsIntegral (getINTEGER $1)) }
1309         | RATIONAL                      { L1 (HsOverLit $! mkHsFractional (getRATIONAL $1)) }
1310         | '(' exp ')'                   { LL (HsPar $2) }
1311         | '(' texp ',' texps ')'        { LL $ ExplicitTuple ($2 : reverse $4) Boxed }
1312         | '(#' texps '#)'               { LL $ ExplicitTuple (reverse $2)      Unboxed }
1313         | '[' list ']'                  { LL (unLoc $2) }
1314         | '[:' parr ':]'                { LL (unLoc $2) }
1315         | '(' infixexp qop ')'          { LL $ SectionL $2 $3 }
1316         | '(' qopm infixexp ')'         { LL $ SectionR $2 $3 }
1317         | '_'                           { L1 EWildPat }
1318
1319         -- Template Haskell Extension
1320         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice
1321                                         (L1 $ HsVar (mkUnqual varName
1322                                                         (getTH_ID_SPLICE $1)))) } -- $x
1323         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               -- $( exp )
1324
1325         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1326         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1327         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1328         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1329         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }
1330         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }
1331         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1332                                            return (LL $ HsBracket (PatBr p)) }
1333         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBr (mkGroup $2)) }
1334
1335         -- arrow notation extension
1336         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1337
1338 cmdargs :: { [LHsCmdTop RdrName] }
1339         : cmdargs acmd                  { $2 : $1 }
1340         | {- empty -}                   { [] }
1341
1342 acmd    :: { LHsCmdTop RdrName }
1343         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1344
1345 cvtopbody :: { [LHsDecl RdrName] }
1346         :  '{'            cvtopdecls0 '}'               { $2 }
1347         |      vocurly    cvtopdecls0 close             { $2 }
1348
1349 cvtopdecls0 :: { [LHsDecl RdrName] }
1350         : {- empty -}           { [] }
1351         | cvtopdecls            { $1 }
1352
1353 texp :: { LHsExpr RdrName }
1354         : exp                           { $1 }
1355         | qopm infixexp                 { LL $ SectionR $1 $2 }
1356         -- The second production is really here only for bang patterns
1357         -- but
1358
1359 texps :: { [LHsExpr RdrName] }
1360         : texps ',' texp                { $3 : $1 }
1361         | texp                          { [$1] }
1362
1363
1364 -----------------------------------------------------------------------------
1365 -- List expressions
1366
1367 -- The rules below are little bit contorted to keep lexps left-recursive while
1368 -- avoiding another shift/reduce-conflict.
1369
1370 list :: { LHsExpr RdrName }
1371         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1372         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1373         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1374         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1375         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1376         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1377         | texp pquals           { sL (comb2 $1 $>) $ mkHsDo ListComp (reverse (unLoc $2)) $1 }
1378
1379 lexps :: { Located [LHsExpr RdrName] }
1380         : lexps ',' texp                { LL ($3 : unLoc $1) }
1381         | texp ',' texp                 { LL [$3,$1] }
1382
1383 -----------------------------------------------------------------------------
1384 -- List Comprehensions
1385
1386 pquals :: { Located [LStmt RdrName] }   -- Either a singleton ParStmt,
1387                                         -- or a reversed list of Stmts
1388         : pquals1                       { case unLoc $1 of
1389                                             [qs] -> L1 qs
1390                                             qss  -> L1 [L1 (ParStmt stmtss)]
1391                                                  where
1392                                                     stmtss = [ (reverse qs, undefined)
1393                                                              | qs <- qss ]
1394                                         }
1395
1396 pquals1 :: { Located [[LStmt RdrName]] }
1397         : pquals1 '|' quals             { LL (unLoc $3 : unLoc $1) }
1398         | '|' quals                     { L (getLoc $2) [unLoc $2] }
1399
1400 quals :: { Located [LStmt RdrName] }
1401         : quals ',' qual                { LL ($3 : unLoc $1) }
1402         | qual                          { L1 [$1] }
1403
1404 -----------------------------------------------------------------------------
1405 -- Parallel array expressions
1406
1407 -- The rules below are little bit contorted; see the list case for details.
1408 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1409 -- Moreover, we allow explicit arrays with no element (represented by the nil
1410 -- constructor in the list case).
1411
1412 parr :: { LHsExpr RdrName }
1413         :                               { noLoc (ExplicitPArr placeHolderType []) }
1414         | exp                           { L1 $ ExplicitPArr placeHolderType [$1] }
1415         | lexps                         { L1 $ ExplicitPArr placeHolderType
1416                                                        (reverse (unLoc $1)) }
1417         | exp '..' exp                  { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1418         | exp ',' exp '..' exp          { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1419         | exp pquals                    { sL (comb2 $1 $>) $ mkHsDo PArrComp (reverse (unLoc $2)) $1 }
1420
1421 -- We are reusing `lexps' and `pquals' from the list case.
1422
1423 -----------------------------------------------------------------------------
1424 -- Case alternatives
1425
1426 altslist :: { Located [LMatch RdrName] }
1427         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1428         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1429
1430 alts    :: { Located [LMatch RdrName] }
1431         : alts1                         { L1 (unLoc $1) }
1432         | ';' alts                      { LL (unLoc $2) }
1433
1434 alts1   :: { Located [LMatch RdrName] }
1435         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1436         | alts1 ';'                     { LL (unLoc $1) }
1437         | alt                           { L1 [$1] }
1438
1439 alt     :: { LMatch RdrName }
1440         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1441
1442 alt_rhs :: { Located (GRHSs RdrName) }
1443         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1444
1445 ralt :: { Located [LGRHS RdrName] }
1446         : '->' exp                      { LL (unguardedRHS $2) }
1447         | gdpats                        { L1 (reverse (unLoc $1)) }
1448
1449 gdpats :: { Located [LGRHS RdrName] }
1450         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1451         | gdpat                         { L1 [$1] }
1452
1453 gdpat   :: { LGRHS RdrName }
1454         : '|' quals '->' exp            { sL (comb2 $1 $>) $ GRHS (reverse (unLoc $2)) $4 }
1455
1456 -- 'pat' recognises a pattern, including one with a bang at the top
1457 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1458 -- Bangs inside are parsed as infix operator applications, so that
1459 -- we parse them right when bang-patterns are off
1460 pat     :: { LPat RdrName }
1461 pat     : infixexp              {% checkPattern $1 }
1462         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1463
1464 apat   :: { LPat RdrName }
1465 apat    : aexp                  {% checkPattern $1 }
1466         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1467
1468 apats  :: { [LPat RdrName] }
1469         : apat apats            { $1 : $2 }
1470         | {- empty -}           { [] }
1471
1472 -----------------------------------------------------------------------------
1473 -- Statement sequences
1474
1475 stmtlist :: { Located [LStmt RdrName] }
1476         : '{'           stmts '}'       { LL (unLoc $2) }
1477         |     vocurly   stmts close     { $2 }
1478
1479 --      do { ;; s ; s ; ; s ;; }
1480 -- The last Stmt should be an expression, but that's hard to enforce
1481 -- here, because we need too much lookahead if we see do { e ; }
1482 -- So we use ExprStmts throughout, and switch the last one over
1483 -- in ParseUtils.checkDo instead
1484 stmts :: { Located [LStmt RdrName] }
1485         : stmt stmts_help               { LL ($1 : unLoc $2) }
1486         | ';' stmts                     { LL (unLoc $2) }
1487         | {- empty -}                   { noLoc [] }
1488
1489 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1490         : ';' stmts                     { LL (unLoc $2) }
1491         | {- empty -}                   { noLoc [] }
1492
1493 -- For typing stmts at the GHCi prompt, where
1494 -- the input may consist of just comments.
1495 maybe_stmt :: { Maybe (LStmt RdrName) }
1496         : stmt                          { Just $1 }
1497         | {- nothing -}                 { Nothing }
1498
1499 stmt  :: { LStmt RdrName }
1500         : qual                          { $1 }
1501 -- What is this next production doing?  I have no clue!  SLPJ Dec06
1502         | infixexp '->' exp             {% checkPattern $3 >>= \p ->
1503                                            return (LL $ mkBindStmt p $1) }
1504         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1505
1506 qual  :: { LStmt RdrName }
1507         : pat '<-' exp                  { LL $ mkBindStmt $1 $3 }
1508         | exp                           { L1 $ mkExprStmt $1 }
1509         | 'let' binds                   { LL $ LetStmt (unLoc $2) }
1510
1511 -----------------------------------------------------------------------------
1512 -- Record Field Update/Construction
1513
1514 fbinds  :: { HsRecordBinds RdrName }
1515         : fbinds1                       { $1 }
1516         | {- empty -}                   { [] }
1517
1518 fbinds1 :: { HsRecordBinds RdrName }
1519         : fbinds1 ',' fbind             { $3 : $1 }
1520         | fbind                         { [$1] }
1521
1522 fbind   :: { (Located RdrName, LHsExpr RdrName) }
1523         : qvar '=' exp                  { ($1,$3) }
1524
1525 -----------------------------------------------------------------------------
1526 -- Implicit Parameter Bindings
1527
1528 dbinds  :: { Located [LIPBind RdrName] }
1529         : dbinds ';' dbind              { LL ($3 : unLoc $1) }
1530         | dbinds ';'                    { LL (unLoc $1) }
1531         | dbind                         { L1 [$1] }
1532 --      | {- empty -}                   { [] }
1533
1534 dbind   :: { LIPBind RdrName }
1535 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1536
1537 ipvar   :: { Located (IPName RdrName) }
1538         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1539
1540 -----------------------------------------------------------------------------
1541 -- Deprecations
1542
1543 depreclist :: { Located [RdrName] }
1544 depreclist : deprec_var                 { L1 [unLoc $1] }
1545            | deprec_var ',' depreclist  { LL (unLoc $1 : unLoc $3) }
1546
1547 deprec_var :: { Located RdrName }
1548 deprec_var : var                        { $1 }
1549            | con                        { $1 }
1550
1551 -----------------------------------------
1552 -- Data constructors
1553 qcon    :: { Located RdrName }
1554         : qconid                { $1 }
1555         | '(' qconsym ')'       { LL (unLoc $2) }
1556         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1557 -- The case of '[:' ':]' is part of the production `parr'
1558
1559 con     :: { Located RdrName }
1560         : conid                 { $1 }
1561         | '(' consym ')'        { LL (unLoc $2) }
1562         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1563
1564 sysdcon :: { Located DataCon }  -- Wired in data constructors
1565         : '(' ')'               { LL unitDataCon }
1566         | '(' commas ')'        { LL $ tupleCon Boxed $2 }
1567         | '[' ']'               { LL nilDataCon }
1568
1569 conop :: { Located RdrName }
1570         : consym                { $1 }
1571         | '`' conid '`'         { LL (unLoc $2) }
1572
1573 qconop :: { Located RdrName }
1574         : qconsym               { $1 }
1575         | '`' qconid '`'        { LL (unLoc $2) }
1576
1577 -----------------------------------------------------------------------------
1578 -- Type constructors
1579
1580 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1581         : oqtycon                       { $1 }
1582         | '(' ')'                       { LL $ getRdrName unitTyCon }
1583         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed $2) }
1584         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1585         | '[' ']'                       { LL $ listTyCon_RDR }
1586         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1587
1588 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1589         : qtycon                        { $1 }
1590         | '(' qtyconsym ')'             { LL (unLoc $2) }
1591
1592 qtyconop :: { Located RdrName } -- Qualified or unqualified
1593         : qtyconsym                     { $1 }
1594         | '`' qtycon '`'                { LL (unLoc $2) }
1595
1596 qtycon :: { Located RdrName }   -- Qualified or unqualified
1597         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1598         | tycon                         { $1 }
1599
1600 tycon   :: { Located RdrName }  -- Unqualified
1601         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1602
1603 qtyconsym :: { Located RdrName }
1604         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1605         | tyconsym                      { $1 }
1606
1607 tyconsym :: { Located RdrName }
1608         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1609
1610 -----------------------------------------------------------------------------
1611 -- Operators
1612
1613 op      :: { Located RdrName }   -- used in infix decls
1614         : varop                 { $1 }
1615         | conop                 { $1 }
1616
1617 varop   :: { Located RdrName }
1618         : varsym                { $1 }
1619         | '`' varid '`'         { LL (unLoc $2) }
1620
1621 qop     :: { LHsExpr RdrName }   -- used in sections
1622         : qvarop                { L1 $ HsVar (unLoc $1) }
1623         | qconop                { L1 $ HsVar (unLoc $1) }
1624
1625 qopm    :: { LHsExpr RdrName }   -- used in sections
1626         : qvaropm               { L1 $ HsVar (unLoc $1) }
1627         | qconop                { L1 $ HsVar (unLoc $1) }
1628
1629 qvarop :: { Located RdrName }
1630         : qvarsym               { $1 }
1631         | '`' qvarid '`'        { LL (unLoc $2) }
1632
1633 qvaropm :: { Located RdrName }
1634         : qvarsym_no_minus      { $1 }
1635         | '`' qvarid '`'        { LL (unLoc $2) }
1636
1637 -----------------------------------------------------------------------------
1638 -- Type variables
1639
1640 tyvar   :: { Located RdrName }
1641 tyvar   : tyvarid               { $1 }
1642         | '(' tyvarsym ')'      { LL (unLoc $2) }
1643
1644 tyvarop :: { Located RdrName }
1645 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1646         | tyvarsym              { $1 }
1647
1648 tyvarid :: { Located RdrName }
1649         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1650         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1651         | 'unsafe'              { L1 $! mkUnqual tvName FSLIT("unsafe") }
1652         | 'safe'                { L1 $! mkUnqual tvName FSLIT("safe") }
1653         | 'threadsafe'          { L1 $! mkUnqual tvName FSLIT("threadsafe") }
1654
1655 tyvarsym :: { Located RdrName }
1656 -- Does not include "!", because that is used for strictness marks
1657 --               or ".", because that separates the quantified type vars from the rest
1658 --               or "*", because that's used for kinds
1659 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1660
1661 -----------------------------------------------------------------------------
1662 -- Variables
1663
1664 var     :: { Located RdrName }
1665         : varid                 { $1 }
1666         | '(' varsym ')'        { LL (unLoc $2) }
1667
1668 qvar    :: { Located RdrName }
1669         : qvarid                { $1 }
1670         | '(' varsym ')'        { LL (unLoc $2) }
1671         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1672 -- We've inlined qvarsym here so that the decision about
1673 -- whether it's a qvar or a var can be postponed until
1674 -- *after* we see the close paren.
1675
1676 qvarid :: { Located RdrName }
1677         : varid                 { $1 }
1678         | QVARID                { L1 $ mkQual varName (getQVARID $1) }
1679
1680 varid :: { Located RdrName }
1681         : varid_no_unsafe       { $1 }
1682         | 'unsafe'              { L1 $! mkUnqual varName FSLIT("unsafe") }
1683         | 'safe'                { L1 $! mkUnqual varName FSLIT("safe") }
1684         | 'threadsafe'          { L1 $! mkUnqual varName FSLIT("threadsafe") }
1685
1686 varid_no_unsafe :: { Located RdrName }
1687         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1688         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1689         | 'forall'              { L1 $! mkUnqual varName FSLIT("forall") }
1690         | 'iso'                 { L1 $! mkUnqual varName FSLIT("iso") }
1691         | 'family'              { L1 $! mkUnqual varName FSLIT("family") }
1692
1693 qvarsym :: { Located RdrName }
1694         : varsym                { $1 }
1695         | qvarsym1              { $1 }
1696
1697 qvarsym_no_minus :: { Located RdrName }
1698         : varsym_no_minus       { $1 }
1699         | qvarsym1              { $1 }
1700
1701 qvarsym1 :: { Located RdrName }
1702 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1703
1704 varsym :: { Located RdrName }
1705         : varsym_no_minus       { $1 }
1706         | '-'                   { L1 $ mkUnqual varName FSLIT("-") }
1707
1708 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1709         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1710         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1711
1712
1713 -- These special_ids are treated as keywords in various places,
1714 -- but as ordinary ids elsewhere.   'special_id' collects all these
1715 -- except 'unsafe', 'forall', 'family', and 'iso' whose treatment differs
1716 -- depending on context
1717 special_id :: { Located FastString }
1718 special_id
1719         : 'as'                  { L1 FSLIT("as") }
1720         | 'qualified'           { L1 FSLIT("qualified") }
1721         | 'hiding'              { L1 FSLIT("hiding") }
1722         | 'for'                 { L1 FSLIT("for") }
1723         | 'export'              { L1 FSLIT("export") }
1724         | 'label'               { L1 FSLIT("label")  }
1725         | 'dynamic'             { L1 FSLIT("dynamic") }
1726         | 'stdcall'             { L1 FSLIT("stdcall") }
1727         | 'ccall'               { L1 FSLIT("ccall") }
1728
1729 special_sym :: { Located FastString }
1730 special_sym : '!'       { L1 FSLIT("!") }
1731             | '.'       { L1 FSLIT(".") }
1732             | '*'       { L1 FSLIT("*") }
1733
1734 -----------------------------------------------------------------------------
1735 -- Data constructors
1736
1737 qconid :: { Located RdrName }   -- Qualified or unqualified
1738         : conid                 { $1 }
1739         | QCONID                { L1 $ mkQual dataName (getQCONID $1) }
1740
1741 conid   :: { Located RdrName }
1742         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1743
1744 qconsym :: { Located RdrName }  -- Qualified or unqualified
1745         : consym                { $1 }
1746         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1747
1748 consym :: { Located RdrName }
1749         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1750
1751         -- ':' means only list cons
1752         | ':'                   { L1 $ consDataCon_RDR }
1753
1754
1755 -----------------------------------------------------------------------------
1756 -- Literals
1757
1758 literal :: { Located HsLit }
1759         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1760         | STRING                { L1 $ HsString     $ getSTRING $1 }
1761         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1762         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1763         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1764         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1765         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1766
1767 -----------------------------------------------------------------------------
1768 -- Layout
1769
1770 close :: { () }
1771         : vccurly               { () } -- context popped in lexer.
1772         | error                 {% popContext }
1773
1774 -----------------------------------------------------------------------------
1775 -- Miscellaneous (mostly renamings)
1776
1777 modid   :: { Located ModuleName }
1778         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1779         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1780                                   mkModuleNameFS
1781                                    (mkFastString
1782                                      (unpackFS mod ++ '.':unpackFS c))
1783                                 }
1784
1785 commas :: { Int }
1786         : commas ','                    { $1 + 1 }
1787         | ','                           { 2 }
1788
1789 -----------------------------------------------------------------------------
1790 -- Documentation comments
1791
1792 docnext :: { LHsDoc RdrName }
1793   : DOCNEXT {% case parseHaddockParagraphs (tokenise (getDOCNEXT $1)) of {
1794       Left  err -> parseError (getLoc $1) err;
1795       Right doc -> return (L1 doc) } }
1796
1797 docprev :: { LHsDoc RdrName }
1798   : DOCPREV {% case parseHaddockParagraphs (tokenise (getDOCPREV $1)) of {
1799       Left  err -> parseError (getLoc $1) err;
1800       Right doc -> return (L1 doc) } }
1801
1802 docnamed :: { Located (String, (HsDoc RdrName)) }
1803   : DOCNAMED {%
1804       let string = getDOCNAMED $1
1805           (name, rest) = break isSpace string
1806       in case parseHaddockParagraphs (tokenise rest) of {
1807         Left  err -> parseError (getLoc $1) err;
1808         Right doc -> return (L1 (name, doc)) } }
1809
1810 docsection :: { Located (n, HsDoc RdrName) }
1811   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1812         case parseHaddockString (tokenise doc) of {
1813       Left  err -> parseError (getLoc $1) err;
1814       Right doc -> return (L1 (n, doc)) } }
1815
1816 docoptions :: { String }
1817   : DOCOPTIONS { getDOCOPTIONS $1 }
1818
1819 moduleheader :: { (HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
1820         : DOCNEXT {% let string = getDOCNEXT $1 in
1821                case parseModuleHeader string of {
1822                  Right (str, info) ->
1823                    case parseHaddockParagraphs (tokenise str) of {
1824                      Left err -> parseError (getLoc $1) err;
1825                      Right doc -> return (info, Just doc);
1826                    };
1827                  Left err -> parseError (getLoc $1) err
1828             }  }
1829
1830 maybe_docprev :: { Maybe (LHsDoc RdrName) }
1831         : docprev                       { Just $1 }
1832         | {- empty -}                   { Nothing }
1833
1834 maybe_docnext :: { Maybe (LHsDoc RdrName) }
1835         : docnext                       { Just $1 }
1836         | {- empty -}                   { Nothing }
1837
1838 {
1839 happyError :: P a
1840 happyError = srcParseFail
1841
1842 getVARID        (L _ (ITvarid    x)) = x
1843 getCONID        (L _ (ITconid    x)) = x
1844 getVARSYM       (L _ (ITvarsym   x)) = x
1845 getCONSYM       (L _ (ITconsym   x)) = x
1846 getQVARID       (L _ (ITqvarid   x)) = x
1847 getQCONID       (L _ (ITqconid   x)) = x
1848 getQVARSYM      (L _ (ITqvarsym  x)) = x
1849 getQCONSYM      (L _ (ITqconsym  x)) = x
1850 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1851 getCHAR         (L _ (ITchar     x)) = x
1852 getSTRING       (L _ (ITstring   x)) = x
1853 getINTEGER      (L _ (ITinteger  x)) = x
1854 getRATIONAL     (L _ (ITrational x)) = x
1855 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1856 getPRIMSTRING   (L _ (ITprimstring x)) = x
1857 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1858 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
1859 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
1860 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
1861 getINLINE       (L _ (ITinline_prag b)) = b
1862 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
1863
1864 getDOCNEXT (L _ (ITdocCommentNext x)) = x
1865 getDOCPREV (L _ (ITdocCommentPrev x)) = x
1866 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
1867 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
1868 getDOCOPTIONS (L _ (ITdocOptions x)) = x
1869
1870 -- Utilities for combining source spans
1871 comb2 :: Located a -> Located b -> SrcSpan
1872 comb2 = combineLocs
1873
1874 comb3 :: Located a -> Located b -> Located c -> SrcSpan
1875 comb3 a b c = combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
1876
1877 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
1878 comb4 a b c d = combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
1879                 combineSrcSpans (getLoc c) (getLoc d)
1880
1881 -- strict constructor version:
1882 {-# INLINE sL #-}
1883 sL :: SrcSpan -> a -> Located a
1884 sL span a = span `seq` L span a
1885
1886 -- Make a source location for the file.  We're a bit lazy here and just
1887 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
1888 -- try to find the span of the whole file (ToDo).
1889 fileSrcSpan :: P SrcSpan
1890 fileSrcSpan = do
1891   l <- getSrcLoc;
1892   let loc = mkSrcLoc (srcLocFile l) 1 0;
1893   return (mkSrcSpan loc loc)
1894 }