compiler/parser/Parser.y.pp

   1 --                                                              -*-haskell-*-
   2 -- ---------------------------------------------------------------------------
   3 -- (c) The University of Glasgow 1997-2003
   4 ---
   5 -- The GHC grammar.
   6 --
   7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -- ---------------------------------------------------------------------------
   9
  10 {
  11 {-# OPTIONS -Wwarn -w #-}
  12 -- The above warning supression flag is a temporary kludge.
  13 -- While working on this module you are encouraged to remove it and fix
  14 -- any warnings in the module. See
  15 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  16 -- for details
  17
  18 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
  19 {-
  20 Careful optimisation of the parser: we don't want to throw everything
  21 at it, because that takes too long and doesn't buy much, but we do want
  22 to inline certain key external functions, so we instruct GHC not to
  23 throw away inlinings as it would normally do in -O0 mode.
  24 -}
  25
  26 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
  27                 parseHeader ) where
  28
  29 import HsSyn
  30 import RdrHsSyn
  31 import HscTypes         ( IsBootInterface, WarningTxt(..) )
  32 import Lexer
  33 import RdrName
  34 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  35                           unboxedSingletonTyCon, unboxedSingletonDataCon,
  36                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  37 import Type             ( funTyCon )
  38 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
  39                           CCallConv(..), CCallTarget(..), defaultCCallConv
  40                         )
  41 import OccName          ( varName, dataName, tcClsName, tvName )
  42 import DataCon          ( DataCon, dataConName )
  43 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
  44                           SrcSpan, combineLocs, srcLocFile,
  45                           mkSrcLoc, mkSrcSpan )
  46 import Module
  47 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
  48 import Type             ( Kind, mkArrowKind, liftedTypeKind, unliftedTypeKind )
  49 import Class            ( FunDep )
  50 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  51                           Activation(..), RuleMatchInfo(..), defaultInlineSpec )
  52 import DynFlags
  53 import OrdList
  54 import HaddockParse
  55 import {-# SOURCE #-} HaddockLex hiding ( Token )
  56 import HaddockUtils
  57
  58 import FastString
  59 import Maybes           ( orElse )
  60 import Outputable
  61
  62 import Control.Monad    ( unless )
  63 import GHC.Exts
  64 import Data.Char
  65 import Control.Monad    ( mplus )
  66 }
  67
  68 {-
  69 -----------------------------------------------------------------------------
  70 24 Februar 2006
  71
  72 Conflicts: 33 shift/reduce
  73            1 reduce/reduce
  74
  75 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  76 would think the two should never occur in the same context.
  77
  78   -=chak
  79
  80 -----------------------------------------------------------------------------
  81 31 December 2006
  82
  83 Conflicts: 34 shift/reduce
  84            1 reduce/reduce
  85
  86 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  87 would think the two should never occur in the same context.
  88
  89   -=chak
  90
  91 -----------------------------------------------------------------------------
  92 6 December 2006
  93
  94 Conflicts: 32 shift/reduce
  95            1 reduce/reduce
  96
  97 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  98 would think the two should never occur in the same context.
  99
 100   -=chak
 101
 102 -----------------------------------------------------------------------------
 103 26 July 2006
 104
 105 Conflicts: 37 shift/reduce
 106            1 reduce/reduce
 107
 108 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
 109 would think the two should never occur in the same context.
 110
 111   -=chak
 112
 113 -----------------------------------------------------------------------------
 114 Conflicts: 38 shift/reduce (1.25)
 115
 116 10 for abiguity in 'if x then y else z + 1'             [State 178]
 117         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
 118         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
 119
 120 1 for ambiguity in 'if x then y else z :: T'            [State 178]
 121         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
 122
 123 4 for ambiguity in 'if x then y else z -< e'            [State 178]
 124         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
 125         There are four such operators: -<, >-, -<<, >>-
 126
 127
 128 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
 129         Which of these two is intended?
 130           case v of
 131             (x::T) -> T         -- Rhs is T
 132     or
 133           case v of
 134             (x::T -> T) -> ..   -- Rhs is ...
 135
 136 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
 137         (e::a) `b` c, or
 138         (e :: (a `b` c))
 139     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
 140     Same duplication between states 11 and 253 as the previous case
 141
 142 1 for ambiguity in 'let ?x ...'                         [State 329]
 143         the parser can't tell whether the ?x is the lhs of a normal binding or
 144         an implicit binding.  Fortunately resolving as shift gives it the only
 145         sensible meaning, namely the lhs of an implicit binding.
 146
 147 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
 148         we don't know whether the '[' starts the activation or not: it
 149         might be the start of the declaration with the activation being
 150         empty.  --SDM 1/4/2002
 151
 152 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
 153         since 'forall' is a valid variable name, we don't know whether
 154         to treat a forall on the input as the beginning of a quantifier
 155         or the beginning of the rule itself.  Resolving to shift means
 156         it's always treated as a quantifier, hence the above is disallowed.
 157         This saves explicitly defining a grammar for the rule lhs that
 158         doesn't include 'forall'.
 159
 160 1 for ambiguity when the source file starts with "-- | doc". We need another
 161   token of lookahead to determine if a top declaration or the 'module' keyword
 162   follows. Shift parses as if the 'module' keyword follows.
 163
 164 -- ---------------------------------------------------------------------------
 165 -- Adding location info
 166
 167 This is done in a stylised way using the three macros below, L0, L1
 168 and LL.  Each of these macros can be thought of as having type
 169
 170    L0, L1, LL :: a -> Located a
 171
 172 They each add a SrcSpan to their argument.
 173
 174    L0   adds 'noSrcSpan', used for empty productions
 175      -- This doesn't seem to work anymore -=chak
 176
 177    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
 178         from that token.
 179
 180    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
 181         the first and last tokens.
 182
 183 These suffice for the majority of cases.  However, we must be
 184 especially careful with empty productions: LL won't work if the first
 185 or last token on the lhs can represent an empty span.  In these cases,
 186 we have to calculate the span using more of the tokens from the lhs, eg.
 187
 188         | 'newtype' tycl_hdr '=' newconstr deriving
 189                 { L (comb3 $1 $4 $5)
 190                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
 191
 192 We provide comb3 and comb4 functions which are useful in such cases.
 193
 194 Be careful: there's no checking that you actually got this right, the
 195 only symptom will be that the SrcSpans of your syntax will be
 196 incorrect.
 197
 198 /*
 199  * We must expand these macros *before* running Happy, which is why this file is
 200  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 201  */
 202 #define L0   L noSrcSpan
 203 #define L1   sL (getLoc $1)
 204 #define LL   sL (comb2 $1 $>)
 205
 206 -- -----------------------------------------------------------------------------
 207
 208 -}
 209
 210 %token
 211  '_'            { L _ ITunderscore }            -- Haskell keywords
 212  'as'           { L _ ITas }
 213  'case'         { L _ ITcase }
 214  'class'        { L _ ITclass }
 215  'data'         { L _ ITdata }
 216  'default'      { L _ ITdefault }
 217  'deriving'     { L _ ITderiving }
 218  'do'           { L _ ITdo }
 219  'else'         { L _ ITelse }
 220  'hiding'       { L _ IThiding }
 221  'if'           { L _ ITif }
 222  'import'       { L _ ITimport }
 223  'in'           { L _ ITin }
 224  'infix'        { L _ ITinfix }
 225  'infixl'       { L _ ITinfixl }
 226  'infixr'       { L _ ITinfixr }
 227  'instance'     { L _ ITinstance }
 228  'let'          { L _ ITlet }
 229  'module'       { L _ ITmodule }
 230  'newtype'      { L _ ITnewtype }
 231  'of'           { L _ ITof }
 232  'qualified'    { L _ ITqualified }
 233  'then'         { L _ ITthen }
 234  'type'         { L _ ITtype }
 235  'where'        { L _ ITwhere }
 236  '_scc_'        { L _ ITscc }         -- ToDo: remove
 237
 238  'forall'       { L _ ITforall }                -- GHC extension keywords
 239  'foreign'      { L _ ITforeign }
 240  'export'       { L _ ITexport }
 241  'label'        { L _ ITlabel }
 242  'dynamic'      { L _ ITdynamic }
 243  'safe'         { L _ ITsafe }
 244  'threadsafe'   { L _ ITthreadsafe }  -- ToDo: remove deprecated alias
 245  'unsafe'       { L _ ITunsafe }
 246  'mdo'          { L _ ITmdo }
 247  'family'       { L _ ITfamily }
 248  'stdcall'      { L _ ITstdcallconv }
 249  'ccall'        { L _ ITccallconv }
 250  'prim'         { L _ ITprimcallconv }
 251  'proc'         { L _ ITproc }          -- for arrow notation extension
 252  'rec'          { L _ ITrec }           -- for arrow notation extension
 253  'group'    { L _ ITgroup }     -- for list transform extension
 254  'by'       { L _ ITby }        -- for list transform extension
 255  'using'    { L _ ITusing }     -- for list transform extension
 256
 257  '{-# INLINE'             { L _ (ITinline_prag _) }
 258  '{-# INLINE_CONLIKE'     { L _ (ITinline_conlike_prag _) }
 259  '{-# SPECIALISE'         { L _ ITspec_prag }
 260  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
 261  '{-# SOURCE'      { L _ ITsource_prag }
 262  '{-# RULES'       { L _ ITrules_prag }
 263  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 264  '{-# SCC'         { L _ ITscc_prag }
 265  '{-# GENERATED'   { L _ ITgenerated_prag }
 266  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 267  '{-# WARNING'  { L _ ITwarning_prag }
 268  '{-# UNPACK'      { L _ ITunpack_prag }
 269  '{-# ANN'      { L _ ITann_prag }
 270  '#-}'             { L _ ITclose_prag }
 271
 272  '..'           { L _ ITdotdot }                        -- reserved symbols
 273  ':'            { L _ ITcolon }
 274  '::'           { L _ ITdcolon }
 275  '='            { L _ ITequal }
 276  '\\'           { L _ ITlam }
 277  '|'            { L _ ITvbar }
 278  '<-'           { L _ ITlarrow }
 279  '->'           { L _ ITrarrow }
 280  '@'            { L _ ITat }
 281  '~'            { L _ ITtilde }
 282  '=>'           { L _ ITdarrow }
 283  '-'            { L _ ITminus }
 284  '!'            { L _ ITbang }
 285  '*'            { L _ ITstar }
 286  '-<'           { L _ ITlarrowtail }            -- for arrow notation
 287  '>-'           { L _ ITrarrowtail }            -- for arrow notation
 288  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
 289  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
 290  '.'            { L _ ITdot }
 291
 292  '{'            { L _ ITocurly }                        -- special symbols
 293  '}'            { L _ ITccurly }
 294  '{|'           { L _ ITocurlybar }
 295  '|}'           { L _ ITccurlybar }
 296  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
 297  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
 298  '['            { L _ ITobrack }
 299  ']'            { L _ ITcbrack }
 300  '[:'           { L _ ITopabrack }
 301  ':]'           { L _ ITcpabrack }
 302  '('            { L _ IToparen }
 303  ')'            { L _ ITcparen }
 304  '(#'           { L _ IToubxparen }
 305  '#)'           { L _ ITcubxparen }
 306  '(|'           { L _ IToparenbar }
 307  '|)'           { L _ ITcparenbar }
 308  ';'            { L _ ITsemi }
 309  ','            { L _ ITcomma }
 310  '`'            { L _ ITbackquote }
 311
 312  VARID          { L _ (ITvarid    _) }          -- identifiers
 313  CONID          { L _ (ITconid    _) }
 314  VARSYM         { L _ (ITvarsym   _) }
 315  CONSYM         { L _ (ITconsym   _) }
 316  QVARID         { L _ (ITqvarid   _) }
 317  QCONID         { L _ (ITqconid   _) }
 318  QVARSYM        { L _ (ITqvarsym  _) }
 319  QCONSYM        { L _ (ITqconsym  _) }
 320  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
 321  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
 322
 323  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
 324
 325  CHAR           { L _ (ITchar     _) }
 326  STRING         { L _ (ITstring   _) }
 327  INTEGER        { L _ (ITinteger  _) }
 328  RATIONAL       { L _ (ITrational _) }
 329
 330  PRIMCHAR       { L _ (ITprimchar   _) }
 331  PRIMSTRING     { L _ (ITprimstring _) }
 332  PRIMINTEGER    { L _ (ITprimint    _) }
 333  PRIMWORD       { L _ (ITprimword  _) }
 334  PRIMFLOAT      { L _ (ITprimfloat  _) }
 335  PRIMDOUBLE     { L _ (ITprimdouble _) }
 336
 337  DOCNEXT        { L _ (ITdocCommentNext _) }
 338  DOCPREV        { L _ (ITdocCommentPrev _) }
 339  DOCNAMED       { L _ (ITdocCommentNamed _) }
 340  DOCSECTION     { L _ (ITdocSection _ _) }
 341
 342 -- Template Haskell
 343 '[|'            { L _ ITopenExpQuote  }
 344 '[p|'           { L _ ITopenPatQuote  }
 345 '[t|'           { L _ ITopenTypQuote  }
 346 '[d|'           { L _ ITopenDecQuote  }
 347 '|]'            { L _ ITcloseQuote    }
 348 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
 349 '$('            { L _ ITparenEscape   }     -- $( exp )
 350 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
 351 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
 352 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
 353
 354 %monad { P } { >>= } { return }
 355 %lexer { lexer } { L _ ITeof }
 356 %name parseModule module
 357 %name parseStmt   maybe_stmt
 358 %name parseIdentifier  identifier
 359 %name parseType ctype
 360 %partial parseHeader header
 361 %tokentype { (Located Token) }
 362 %%
 363
 364 -----------------------------------------------------------------------------
 365 -- Identifiers; one of the entry points
 366 identifier :: { Located RdrName }
 367         : qvar                          { $1 }
 368         | qcon                          { $1 }
 369         | qvarop                        { $1 }
 370         | qconop                        { $1 }
 371     | '(' '->' ')'      { LL $ getRdrName funTyCon }
 372
 373 -----------------------------------------------------------------------------
 374 -- Module Header
 375
 376 -- The place for module deprecation is really too restrictive, but if it
 377 -- was allowed at its natural place just before 'module', we get an ugly
 378 -- s/r conflict with the second alternative. Another solution would be the
 379 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 380 -- either, and DEPRECATED is only expected to be used by people who really
 381 -- know what they are doing. :-)
 382
 383 module  :: { Located (HsModule RdrName) }
 384         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
 385                 {% fileSrcSpan >>= \ loc -> case $1 of { (info, doc) ->
 386                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4
 387                           info doc) )}}
 388         | body2
 389                 {% fileSrcSpan >>= \ loc ->
 390                    return (L loc (HsModule Nothing Nothing
 391                           (fst $1) (snd $1) Nothing emptyHaddockModInfo
 392                           Nothing)) }
 393
 394 maybedocheader :: { (HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
 395         : moduleheader            { $1 }
 396         | {- empty -}             { (emptyHaddockModInfo, Nothing) }
 397
 398 missing_module_keyword :: { () }
 399         : {- empty -}                           {% pushCurrentContext }
 400
 401 maybemodwarning :: { Maybe WarningTxt }
 402     : '{-# DEPRECATED' STRING '#-}' { Just (DeprecatedTxt (getSTRING $2)) }
 403     | '{-# WARNING' STRING '#-}'    { Just (WarningTxt (getSTRING $2)) }
 404     |  {- empty -}                  { Nothing }
 405
 406 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 407         :  '{'            top '}'               { $2 }
 408         |      vocurly    top close             { $2 }
 409
 410 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 411         :  '{' top '}'                          { $2 }
 412         |  missing_module_keyword top close     { $2 }
 413
 414 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 415         : importdecls                           { (reverse $1,[]) }
 416         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 417         | cvtopdecls                            { ([],$1) }
 418
 419 cvtopdecls :: { [LHsDecl RdrName] }
 420         : topdecls                              { cvTopDecls $1 }
 421
 422 -----------------------------------------------------------------------------
 423 -- Module declaration & imports only
 424
 425 header  :: { Located (HsModule RdrName) }
 426         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
 427                 {% fileSrcSpan >>= \ loc -> case $1 of { (info, doc) ->
 428                    return (L loc (HsModule (Just $3) $5 $7 [] $4
 429                    info doc))}}
 430         | missing_module_keyword importdecls
 431                 {% fileSrcSpan >>= \ loc ->
 432                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
 433                    emptyHaddockModInfo Nothing)) }
 434
 435 header_body :: { [LImportDecl RdrName] }
 436         :  '{'            importdecls           { $2 }
 437         |      vocurly    importdecls           { $2 }
 438
 439 -----------------------------------------------------------------------------
 440 -- The Export List
 441
 442 maybeexports :: { Maybe [LIE RdrName] }
 443         :  '(' exportlist ')'                   { Just $2 }
 444         |  {- empty -}                          { Nothing }
 445
 446 exportlist :: { [LIE RdrName] }
 447         : expdoclist ',' expdoclist             { $1 ++ $3 }
 448         | exportlist1                           { $1 }
 449
 450 exportlist1 :: { [LIE RdrName] }
 451         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
 452         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
 453         | expdoclist                                   { $1 }
 454
 455 expdoclist :: { [LIE RdrName] }
 456         : exp_doc expdoclist                           { $1 : $2 }
 457         | {- empty -}                                  { [] }
 458
 459 exp_doc :: { LIE RdrName }
 460         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
 461         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) }
 462         | docnext       { L1 (IEDoc (unLoc $1)) }
 463
 464    -- No longer allow things like [] and (,,,) to be exported
 465    -- They are built in syntax, always available
 466 export  :: { LIE RdrName }
 467         :  qvar                         { L1 (IEVar (unLoc $1)) }
 468         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
 469         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
 470         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
 471         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
 472         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
 473
 474 qcnames :: { [RdrName] }
 475         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
 476         |  qcname_ext                   { [unLoc $1]  }
 477
 478 qcname_ext :: { Located RdrName }       -- Variable or data constructor
 479                                         -- or tagged type constructor
 480         :  qcname                       { $1 }
 481         |  'type' qcon                  { sL (comb2 $1 $2)
 482                                              (setRdrNameSpace (unLoc $2)
 483                                                               tcClsName)  }
 484
 485 -- Cannot pull into qcname_ext, as qcname is also used in expression.
 486 qcname  :: { Located RdrName }  -- Variable or data constructor
 487         :  qvar                         { $1 }
 488         |  qcon                         { $1 }
 489
 490 -----------------------------------------------------------------------------
 491 -- Import Declarations
 492
 493 -- import decls can be *empty*, or even just a string of semicolons
 494 -- whereas topdecls must contain at least one topdecl.
 495
 496 importdecls :: { [LImportDecl RdrName] }
 497         : importdecls ';' importdecl            { $3 : $1 }
 498         | importdecls ';'                       { $1 }
 499         | importdecl                            { [ $1 ] }
 500         | {- empty -}                           { [] }
 501
 502 importdecl :: { LImportDecl RdrName }
 503         : 'import' maybe_src optqualified maybe_pkg modid maybeas maybeimpspec
 504                 { L (comb4 $1 $5 $6 $7) (ImportDecl $5 $4 $2 $3 (unLoc $6) (unLoc $7)) }
 505
 506 maybe_src :: { IsBootInterface }
 507         : '{-# SOURCE' '#-}'                    { True }
 508         | {- empty -}                           { False }
 509
 510 maybe_pkg :: { Maybe FastString }
 511         : STRING                                { Just (getSTRING $1) }
 512         | {- empty -}                           { Nothing }
 513
 514 optqualified :: { Bool }
 515         : 'qualified'                           { True  }
 516         | {- empty -}                           { False }
 517
 518 maybeas :: { Located (Maybe ModuleName) }
 519         : 'as' modid                            { LL (Just (unLoc $2)) }
 520         | {- empty -}                           { noLoc Nothing }
 521
 522 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
 523         : impspec                               { L1 (Just (unLoc $1)) }
 524         | {- empty -}                           { noLoc Nothing }
 525
 526 impspec :: { Located (Bool, [LIE RdrName]) }
 527         :  '(' exportlist ')'                   { LL (False, $2) }
 528         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
 529
 530 -----------------------------------------------------------------------------
 531 -- Fixity Declarations
 532
 533 prec    :: { Int }
 534         : {- empty -}           { 9 }
 535         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
 536
 537 infix   :: { Located FixityDirection }
 538         : 'infix'                               { L1 InfixN  }
 539         | 'infixl'                              { L1 InfixL  }
 540         | 'infixr'                              { L1 InfixR }
 541
 542 ops     :: { Located [Located RdrName] }
 543         : ops ',' op                            { LL ($3 : unLoc $1) }
 544         | op                                    { L1 [$1] }
 545
 546 -----------------------------------------------------------------------------
 547 -- Top-Level Declarations
 548
 549 topdecls :: { OrdList (LHsDecl RdrName) }
 550         : topdecls ';' topdecl                  { $1 `appOL` $3 }
 551         | topdecls ';'                          { $1 }
 552         | topdecl                               { $1 }
 553
 554 topdecl :: { OrdList (LHsDecl RdrName) }
 555         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 556         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 557         | 'instance' inst_type where_inst
 558             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
 559               in
 560               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
 561         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
 562         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
 563         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
 564     | '{-# DEPRECATED' deprecations '#-}' { $2 }
 565     | '{-# WARNING' warnings '#-}'        { $2 }
 566         | '{-# RULES' rules '#-}'               { $2 }
 567         | annotation { unitOL $1 }
 568         | decl                                  { unLoc $1 }
 569
 570         -- Template Haskell Extension
 571         | '$(' exp ')'                          { unitOL (LL $ SpliceD (SpliceDecl $2)) }
 572         | TH_ID_SPLICE                          { unitOL (LL $ SpliceD (SpliceDecl $
 573                                                         L1 $ HsVar (mkUnqual varName (getTH_ID_SPLICE $1))
 574                                                   )) }
 575
 576 -- Type classes
 577 --
 578 cl_decl :: { LTyClDecl RdrName }
 579         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
 580
 581 -- Type declarations (toplevel)
 582 --
 583 ty_decl :: { LTyClDecl RdrName }
 584            -- ordinary type synonyms
 585         : 'type' type '=' ctypedoc
 586                 -- Note ctype, not sigtype, on the right of '='
 587                 -- We allow an explicit for-all but we don't insert one
 588                 -- in   type Foo a = (b,b)
 589                 -- Instead we just say b is out of scope
 590                 --
 591                 -- Note the use of type for the head; this allows
 592                 -- infix type constructors to be declared
 593                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
 594
 595            -- type family declarations
 596         | 'type' 'family' type opt_kind_sig
 597                 -- Note the use of type for the head; this allows
 598                 -- infix type constructors to be declared
 599                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
 600
 601            -- type instance declarations
 602         | 'type' 'instance' type '=' ctype
 603                 -- Note the use of type for the head; this allows
 604                 -- infix type constructors and type patterns
 605                 {% mkTySynonym (comb2 $1 $5) True $3 $5 }
 606
 607           -- ordinary data type or newtype declaration
 608         | data_or_newtype tycl_hdr constrs deriving
 609                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) False $2
 610                             Nothing (reverse (unLoc $3)) (unLoc $4) }
 611                                    -- We need the location on tycl_hdr in case
 612                                    -- constrs and deriving are both empty
 613
 614           -- ordinary GADT declaration
 615         | data_or_newtype tycl_hdr opt_kind_sig
 616                  'where' gadt_constrlist
 617                  deriving
 618                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) False $2
 619                             (unLoc $3) (reverse (unLoc $5)) (unLoc $6) }
 620                                    -- We need the location on tycl_hdr in case
 621                                    -- constrs and deriving are both empty
 622
 623           -- data/newtype family
 624         | 'data' 'family' type opt_kind_sig
 625                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
 626
 627           -- data/newtype instance declaration
 628         | data_or_newtype 'instance' tycl_hdr constrs deriving
 629                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $3
 630                             Nothing (reverse (unLoc $4)) (unLoc $5) }
 631
 632           -- GADT instance declaration
 633         | data_or_newtype 'instance' tycl_hdr opt_kind_sig
 634                  'where' gadt_constrlist
 635                  deriving
 636                 {% mkTyData (comb4 $1 $3 $6 $7) (unLoc $1) True $3
 637                             (unLoc $4) (reverse (unLoc $6)) (unLoc $7) }
 638
 639 -- Associated type family declarations
 640 --
 641 -- * They have a different syntax than on the toplevel (no family special
 642 --   identifier).
 643 --
 644 -- * They also need to be separate from instances; otherwise, data family
 645 --   declarations without a kind signature cause parsing conflicts with empty
 646 --   data declarations.
 647 --
 648 at_decl_cls :: { LTyClDecl RdrName }
 649            -- type family declarations
 650         : 'type' type opt_kind_sig
 651                 -- Note the use of type for the head; this allows
 652                 -- infix type constructors to be declared
 653                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
 654
 655            -- default type instance
 656         | 'type' type '=' ctype
 657                 -- Note the use of type for the head; this allows
 658                 -- infix type constructors and type patterns
 659                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
 660
 661           -- data/newtype family declaration
 662         | 'data' type opt_kind_sig
 663                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
 664
 665 -- Associated type instances
 666 --
 667 at_decl_inst :: { LTyClDecl RdrName }
 668            -- type instance declarations
 669         : 'type' type '=' ctype
 670                 -- Note the use of type for the head; this allows
 671                 -- infix type constructors and type patterns
 672                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
 673
 674         -- data/newtype instance declaration
 675         | data_or_newtype tycl_hdr constrs deriving
 676                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) True $2
 677                             Nothing (reverse (unLoc $3)) (unLoc $4) }
 678
 679         -- GADT instance declaration
 680         | data_or_newtype tycl_hdr opt_kind_sig
 681                  'where' gadt_constrlist
 682                  deriving
 683                 {% mkTyData (comb4 $1 $2 $5 $6) (unLoc $1) True $2
 684                             (unLoc $3) (reverse (unLoc $5)) (unLoc $6) }
 685
 686 data_or_newtype :: { Located NewOrData }
 687         : 'data'        { L1 DataType }
 688         | 'newtype'     { L1 NewType }
 689
 690 opt_kind_sig :: { Located (Maybe Kind) }
 691         :                               { noLoc Nothing }
 692         | '::' kind                     { LL (Just (unLoc $2)) }
 693
 694 -- tycl_hdr parses the header of a class or data type decl,
 695 -- which takes the form
 696 --      T a b
 697 --      Eq a => T a
 698 --      (Eq a, Ord b) => T a b
 699 --      T Int [a]                       -- for associated types
 700 -- Rather a lot of inlining here, else we get reduce/reduce errors
 701 tycl_hdr :: { Located (LHsContext RdrName, LHsType RdrName) }
 702         : context '=>' type             { LL ($1, $3) }
 703         | type                          { L1 (noLoc [], $1) }
 704
 705 -----------------------------------------------------------------------------
 706 -- Stand-alone deriving
 707
 708 -- Glasgow extension: stand-alone deriving declarations
 709 stand_alone_deriving :: { LDerivDecl RdrName }
 710         : 'deriving' 'instance' inst_type {% checkDerivDecl (LL (DerivDecl $3)) }
 711
 712 -----------------------------------------------------------------------------
 713 -- Nested declarations
 714
 715 -- Declaration in class bodies
 716 --
 717 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
 718 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 719           | decl                        { $1 }
 720
 721 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 722           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
 723           | decls_cls ';'               { LL (unLoc $1) }
 724           | decl_cls                    { $1 }
 725           | {- empty -}                 { noLoc nilOL }
 726
 727
 728 decllist_cls
 729         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 730         : '{'         decls_cls '}'     { LL (unLoc $2) }
 731         |     vocurly decls_cls close   { $2 }
 732
 733 -- Class body
 734 --
 735 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 736                                 -- No implicit parameters
 737                                 -- May have type declarations
 738         : 'where' decllist_cls          { LL (unLoc $2) }
 739         | {- empty -}                   { noLoc nilOL }
 740
 741 -- Declarations in instance bodies
 742 --
 743 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
 744 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 745            | decl                       { $1 }
 746
 747 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 748            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
 749            | decls_inst ';'             { LL (unLoc $1) }
 750            | decl_inst                  { $1 }
 751            | {- empty -}                { noLoc nilOL }
 752
 753 decllist_inst
 754         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 755         : '{'         decls_inst '}'    { LL (unLoc $2) }
 756         |     vocurly decls_inst close  { $2 }
 757
 758 -- Instance body
 759 --
 760 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 761                                 -- No implicit parameters
 762                                 -- May have type declarations
 763         : 'where' decllist_inst         { LL (unLoc $2) }
 764         | {- empty -}                   { noLoc nilOL }
 765
 766 -- Declarations in binding groups other than classes and instances
 767 --
 768 decls   :: { Located (OrdList (LHsDecl RdrName)) }
 769         : decls ';' decl                { let { this = unLoc $3;
 770                                     rest = unLoc $1;
 771                                     these = rest `appOL` this }
 772                               in rest `seq` this `seq` these `seq`
 773                                     LL these }
 774         | decls ';'                     { LL (unLoc $1) }
 775         | decl                          { $1 }
 776         | {- empty -}                   { noLoc nilOL }
 777
 778 decllist :: { Located (OrdList (LHsDecl RdrName)) }
 779         : '{'            decls '}'      { LL (unLoc $2) }
 780         |     vocurly    decls close    { $2 }
 781
 782 -- Binding groups other than those of class and instance declarations
 783 --
 784 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
 785                                                 -- No type declarations
 786         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
 787         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 788         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 789
 790 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
 791                                                 -- No type declarations
 792         : 'where' binds                 { LL (unLoc $2) }
 793         | {- empty -}                   { noLoc emptyLocalBinds }
 794
 795
 796 -----------------------------------------------------------------------------
 797 -- Transformation Rules
 798
 799 rules   :: { OrdList (LHsDecl RdrName) }
 800         :  rules ';' rule                       { $1 `snocOL` $3 }
 801         |  rules ';'                            { $1 }
 802         |  rule                                 { unitOL $1 }
 803         |  {- empty -}                          { nilOL }
 804
 805 rule    :: { LHsDecl RdrName }
 806         : STRING activation rule_forall infixexp '=' exp
 807              { LL $ RuleD (HsRule (getSTRING $1)
 808                                   ($2 `orElse` AlwaysActive)
 809                                   $3 $4 placeHolderNames $6 placeHolderNames) }
 810
 811 activation :: { Maybe Activation }
 812         : {- empty -}                           { Nothing }
 813         | explicit_activation                   { Just $1 }
 814
 815 explicit_activation :: { Activation }  -- In brackets
 816         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
 817         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
 818
 819 rule_forall :: { [RuleBndr RdrName] }
 820         : 'forall' rule_var_list '.'            { $2 }
 821         | {- empty -}                           { [] }
 822
 823 rule_var_list :: { [RuleBndr RdrName] }
 824         : rule_var                              { [$1] }
 825         | rule_var rule_var_list                { $1 : $2 }
 826
 827 rule_var :: { RuleBndr RdrName }
 828         : varid                                 { RuleBndr $1 }
 829         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 830
 831 -----------------------------------------------------------------------------
 832 -- Warnings and deprecations (c.f. rules)
 833
 834 warnings :: { OrdList (LHsDecl RdrName) }
 835         : warnings ';' warning          { $1 `appOL` $3 }
 836         | warnings ';'                  { $1 }
 837         | warning                               { $1 }
 838         | {- empty -}                           { nilOL }
 839
 840 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 841 warning :: { OrdList (LHsDecl RdrName) }
 842         : namelist STRING
 843                 { toOL [ LL $ WarningD (Warning n (WarningTxt (getSTRING $2)))
 844                        | n <- unLoc $1 ] }
 845
 846 deprecations :: { OrdList (LHsDecl RdrName) }
 847         : deprecations ';' deprecation          { $1 `appOL` $3 }
 848         | deprecations ';'                      { $1 }
 849         | deprecation                           { $1 }
 850         | {- empty -}                           { nilOL }
 851
 852 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 853 deprecation :: { OrdList (LHsDecl RdrName) }
 854         : namelist STRING
 855                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt (getSTRING $2)))
 856                        | n <- unLoc $1 ] }
 857
 858 -----------------------------------------------------------------------------
 859 -- Annotations
 860 annotation :: { LHsDecl RdrName }
 861     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
 862     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
 863     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
 864
 865
 866 -----------------------------------------------------------------------------
 867 -- Foreign import and export declarations
 868
 869 fdecl :: { LHsDecl RdrName }
 870 fdecl : 'import' callconv safety fspec
 871                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
 872       | 'import' callconv        fspec
 873                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
 874                         return (LL d) } }
 875       | 'export' callconv fspec
 876                 {% mkExport $2 (unLoc $3) >>= return.LL }
 877
 878 callconv :: { CCallConv }
 879           : 'stdcall'                   { StdCallConv }
 880           | 'ccall'                     { CCallConv   }
 881           | 'prim'                      { PrimCallConv}
 882
 883 safety :: { Safety }
 884         : 'unsafe'                      { PlayRisky }
 885         | 'safe'                        { PlaySafe  False }
 886         | 'threadsafe'                  { PlaySafe  True } -- deprecated alias
 887
 888 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
 889        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
 890        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
 891          -- if the entity string is missing, it defaults to the empty string;
 892          -- the meaning of an empty entity string depends on the calling
 893          -- convention
 894
 895 -----------------------------------------------------------------------------
 896 -- Type signatures
 897
 898 opt_sig :: { Maybe (LHsType RdrName) }
 899         : {- empty -}                   { Nothing }
 900         | '::' sigtype                  { Just $2 }
 901
 902 opt_asig :: { Maybe (LHsType RdrName) }
 903         : {- empty -}                   { Nothing }
 904         | '::' atype                    { Just $2 }
 905
 906 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
 907                                         -- to tell the renamer where to generalise
 908         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 909         -- Wrap an Implicit forall if there isn't one there already
 910
 911 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
 912         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 913         -- Wrap an Implicit forall if there isn't one there already
 914
 915 sig_vars :: { Located [Located RdrName] }
 916          : sig_vars ',' var             { LL ($3 : unLoc $1) }
 917          | var                          { L1 [$1] }
 918
 919 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
 920         : sigtype                       { [ $1 ] }
 921         | sigtype ',' sigtypes1         { $1 : $3 }
 922
 923 -----------------------------------------------------------------------------
 924 -- Types
 925
 926 infixtype :: { LHsType RdrName }
 927         : btype qtyconop type         { LL $ HsOpTy $1 $2 $3 }
 928         | btype tyvarop  type    { LL $ HsOpTy $1 $2 $3 }
 929
 930 strict_mark :: { Located HsBang }
 931         : '!'                           { L1 HsStrict }
 932         | '{-# UNPACK' '#-}' '!'        { LL HsUnbox }
 933
 934 -- A ctype is a for-all type
 935 ctype   :: { LHsType RdrName }
 936         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 937         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
 938         -- A type of form (context => type) is an *implicit* HsForAllTy
 939         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 940         | type                          { $1 }
 941
 942 ----------------------
 943 -- Notes for 'ctypedoc'
 944 -- It would have been nice to simplify the grammar by unifying `ctype` and
 945 -- ctypedoc` into one production, allowing comments on types everywhere (and
 946 -- rejecting them after parsing, where necessary).  This is however not possible
 947 -- since it leads to ambiguity. The reason is the support for comments on record
 948 -- fields:
 949 --         data R = R { field :: Int -- ^ comment on the field }
 950 -- If we allow comments on types here, it's not clear if the comment applies
 951 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
 952
 953 ctypedoc :: { LHsType RdrName }
 954         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 955         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
 956         -- A type of form (context => type) is an *implicit* HsForAllTy
 957         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 958         | typedoc                       { $1 }
 959
 960 ----------------------
 961 -- Notes for 'context'
 962 -- We parse a context as a btype so that we don't get reduce/reduce
 963 -- errors in ctype.  The basic problem is that
 964 --      (Eq a, Ord a)
 965 -- looks so much like a tuple type.  We can't tell until we find the =>
 966
 967 -- We have the t1 ~ t2 form both in 'context' and in type,
 968 -- to permit an individual equational constraint without parenthesis.
 969 -- Thus for some reason we allow    f :: a~b => blah
 970 -- but not                          f :: ?x::Int => blah
 971 context :: { LHsContext RdrName }
 972         : btype '~'      btype          {% checkContext
 973                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
 974         | btype                         {% checkContext $1 }
 975
 976 type :: { LHsType RdrName }
 977         : btype                         { $1 }
 978         | btype qtyconop type        { LL $ HsOpTy $1 $2 $3 }
 979         | btype tyvarop  type           { LL $ HsOpTy $1 $2 $3 }
 980         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
 981         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
 982
 983 typedoc :: { LHsType RdrName }
 984         : btype                          { $1 }
 985         | btype docprev                  { LL $ HsDocTy $1 $2 }
 986         | btype qtyconop type            { LL $ HsOpTy $1 $2 $3 }
 987         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
 988         | btype tyvarop  type            { LL $ HsOpTy $1 $2 $3 }
 989         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
 990         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
 991         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
 992         | btype '~'      btype           { LL $ HsPredTy (HsEqualP $1 $3) }
 993
 994 btype :: { LHsType RdrName }
 995         : btype atype                   { LL $ HsAppTy $1 $2 }
 996         | atype                         { $1 }
 997
 998 atype :: { LHsType RdrName }
 999         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1000         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1001         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1002         | '{' fielddecls '}'            { LL $ HsRecTy $2 }              -- Constructor sigs only
1003         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1004         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1005         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1006         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1007         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1008         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1009         | '$(' exp ')'                  { LL $ HsSpliceTy (mkHsSplice $2 ) }
1010         | TH_ID_SPLICE                  { LL $ HsSpliceTy (mkHsSplice
1011                                                  (L1 $ HsVar (mkUnqual varName
1012                                                                 (getTH_ID_SPLICE $1)))) } -- $x
1013 -- Generics
1014         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
1015
1016 -- An inst_type is what occurs in the head of an instance decl
1017 --      e.g.  (Foo a, Gaz b) => Wibble a b
1018 -- It's kept as a single type, with a MonoDictTy at the right
1019 -- hand corner, for convenience.
1020 inst_type :: { LHsType RdrName }
1021         : sigtype                       {% checkInstType $1 }
1022
1023 inst_types1 :: { [LHsType RdrName] }
1024         : inst_type                     { [$1] }
1025         | inst_type ',' inst_types1     { $1 : $3 }
1026
1027 comma_types0  :: { [LHsType RdrName] }
1028         : comma_types1                  { $1 }
1029         | {- empty -}                   { [] }
1030
1031 comma_types1    :: { [LHsType RdrName] }
1032         : ctype                         { [$1] }
1033         | ctype  ',' comma_types1       { $1 : $3 }
1034
1035 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1036          : tv_bndr tv_bndrs             { $1 : $2 }
1037          | {- empty -}                  { [] }
1038
1039 tv_bndr :: { LHsTyVarBndr RdrName }
1040         : tyvar                         { L1 (UserTyVar (unLoc $1)) }
1041         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2)
1042                                                           (unLoc $4)) }
1043
1044 fds :: { Located [Located (FunDep RdrName)] }
1045         : {- empty -}                   { noLoc [] }
1046         | '|' fds1                      { LL (reverse (unLoc $2)) }
1047
1048 fds1 :: { Located [Located (FunDep RdrName)] }
1049         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1050         | fd                            { L1 [$1] }
1051
1052 fd :: { Located (FunDep RdrName) }
1053         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1054                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1055
1056 varids0 :: { Located [RdrName] }
1057         : {- empty -}                   { noLoc [] }
1058         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1059
1060 -----------------------------------------------------------------------------
1061 -- Kinds
1062
1063 kind    :: { Located Kind }
1064         : akind                 { $1 }
1065         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1066
1067 akind   :: { Located Kind }
1068         : '*'                   { L1 liftedTypeKind }
1069         | '!'                   { L1 unliftedTypeKind }
1070         | '(' kind ')'          { LL (unLoc $2) }
1071
1072
1073 -----------------------------------------------------------------------------
1074 -- Datatype declarations
1075
1076 gadt_constrlist :: { Located [LConDecl RdrName] }
1077         : '{'            gadt_constrs '}'       { LL (unLoc $2) }
1078         |     vocurly    gadt_constrs close     { $2 }
1079
1080 gadt_constrs :: { Located [LConDecl RdrName] }
1081         : gadt_constrs ';' gadt_constr  { sL (comb2 $1 (head $3)) ($3 ++ unLoc $1) }
1082         | gadt_constrs ';'              { $1 }
1083         | gadt_constr                   { sL (getLoc (head $1)) $1 }
1084
1085 -- We allow the following forms:
1086 --      C :: Eq a => a -> T a
1087 --      C :: forall a. Eq a => !a -> T a
1088 --      D { x,y :: a } :: T a
1089 --      forall a. Eq a => D { x,y :: a } :: T a
1090
1091 gadt_constr :: { [LConDecl RdrName] }
1092         : con_list '::' sigtype
1093                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) }
1094
1095                 -- Deprecated syntax for GADT record declarations
1096         | oqtycon '{' fielddecls '}' '::' sigtype
1097                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1098                       ; return [cd] } }
1099
1100 constrs :: { Located [LConDecl RdrName] }
1101         : {- empty; a GHC extension -}  { noLoc [] }
1102         | maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1103
1104 constrs1 :: { Located [LConDecl RdrName] }
1105         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1106         | constr                                          { L1 [$1] }
1107
1108 constr :: { LConDecl RdrName }
1109         : maybe_docnext forall context '=>' constr_stuff maybe_docprev
1110                 { let (con,details) = unLoc $5 in
1111                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1112                             ($1 `mplus` $6) }
1113         | maybe_docnext forall constr_stuff maybe_docprev
1114                 { let (con,details) = unLoc $3 in
1115                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1116                             ($1 `mplus` $4) }
1117
1118 forall :: { Located [LHsTyVarBndr RdrName] }
1119         : 'forall' tv_bndrs '.'         { LL $2 }
1120         | {- empty -}                   { noLoc [] }
1121
1122 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1123 -- We parse the constructor declaration
1124 --      C t1 t2
1125 -- as a btype (treating C as a type constructor) and then convert C to be
1126 -- a data constructor.  Reason: it might continue like this:
1127 --      C t1 t2 %: D Int
1128 -- in which case C really would be a type constructor.  We can't resolve this
1129 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1130         : btype                         {% splitCon $1 >>= return.LL }
1131         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1132
1133 fielddecls :: { [ConDeclField RdrName] }
1134         : {- empty -}     { [] }
1135         | fielddecls1     { $1 }
1136
1137 fielddecls1 :: { [ConDeclField RdrName] }
1138         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1139                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1140                              -- This adds the doc $4 to each field separately
1141         | fielddecl   { $1 }
1142
1143 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1144         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5)
1145                                                                  | fld <- reverse (unLoc $2) ] }
1146
1147 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1148 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1149 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1150 -- We don't allow a context, but that's sorted out by the type checker.
1151 deriving :: { Located (Maybe [LHsType RdrName]) }
1152         : {- empty -}                           { noLoc Nothing }
1153         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1154                                       ; p <- checkInstType (L loc (HsTyVar tv))
1155                                       ; return (LL (Just [p])) } }
1156         | 'deriving' '(' ')'                    { LL (Just []) }
1157         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1158              -- Glasgow extension: allow partial
1159              -- applications in derivings
1160
1161 -----------------------------------------------------------------------------
1162 -- Value definitions
1163
1164 {- There's an awkward overlap with a type signature.  Consider
1165         f :: Int -> Int = ...rhs...
1166    Then we can't tell whether it's a type signature or a value
1167    definition with a result signature until we see the '='.
1168    So we have to inline enough to postpone reductions until we know.
1169 -}
1170
1171 {-
1172   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1173   instead of qvar, we get another shift/reduce-conflict. Consider the
1174   following programs:
1175
1176      { (^^) :: Int->Int ; }          Type signature; only var allowed
1177
1178      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1179                                      qvar allowed (because of instance decls)
1180
1181   We can't tell whether to reduce var to qvar until after we've read the signatures.
1182 -}
1183
1184 docdecl :: { LHsDecl RdrName }
1185         : docdecld { L1 (DocD (unLoc $1)) }
1186
1187 docdecld :: { LDocDecl RdrName }
1188         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1189         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1190         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1191         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1192
1193 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1194         : sigdecl                       { $1 }
1195         | '!' aexp rhs                  {% do { pat <- checkPattern $2;
1196                                                 return (LL $ unitOL $ LL $ ValD (
1197                                                         PatBind (LL $ BangPat pat) (unLoc $3)
1198                                                                 placeHolderType placeHolderNames)) } }
1199         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
1200                                                 let { l = comb2 $1 $> };
1201                                                 return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1202         | docdecl                       { LL $ unitOL $1 }
1203
1204 rhs     :: { Located (GRHSs RdrName) }
1205         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1206         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1207
1208 gdrhs :: { Located [LGRHS RdrName] }
1209         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1210         | gdrh                  { L1 [$1] }
1211
1212 gdrh :: { LGRHS RdrName }
1213         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1214
1215 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1216         : infixexp '::' sigtypedoc
1217                                 {% do s <- checkValSig $1 $3;
1218                                       return (LL $ unitOL (LL $ SigD s)) }
1219                 -- See the above notes for why we need infixexp here
1220         | var ',' sig_vars '::' sigtypedoc
1221                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1222         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1223                                              | n <- unLoc $3 ] }
1224         | '{-# INLINE'   activation qvar '#-}'
1225                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 FunLike (getINLINE $1)))) }
1226         | '{-# INLINE_CONLIKE' activation qvar '#-}'
1227                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 ConLike (getINLINE_CONLIKE $1)))) }
1228         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1229                                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlineSpec)
1230                                             | t <- $4] }
1231         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1232                                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlineSpec $2 FunLike (getSPEC_INLINE $1)))
1233                                             | t <- $5] }
1234         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1235                                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1236
1237 -----------------------------------------------------------------------------
1238 -- Expressions
1239
1240 exp   :: { LHsExpr RdrName }
1241         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1242         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1243         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1244         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1245         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1246         | infixexp                      { $1 }
1247
1248 infixexp :: { LHsExpr RdrName }
1249         : exp10                         { $1 }
1250         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1251
1252 exp10 :: { LHsExpr RdrName }
1253         : '\\' apat apats opt_asig '->' exp
1254                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1255                                                                 (unguardedGRHSs $6)
1256                                                             ]) }
1257         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1258         | 'if' exp 'then' exp 'else' exp        { LL $ HsIf $2 $4 $6 }
1259         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1260         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1261
1262         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1263                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1264                                            return (L loc (mkHsDo DoExpr stmts body)) }
1265         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1266                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1267                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1268         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1269                                                         then HsSCC (unLoc $1) $2
1270                                                         else HsPar $2 }
1271         | hpc_annot exp                         { LL $ if opt_Hpc
1272                                                         then HsTickPragma (unLoc $1) $2
1273                                                         else HsPar $2 }
1274
1275         | 'proc' aexp '->' exp
1276                         {% checkPattern $2 >>= \ p ->
1277                            return (LL $ HsProc p (LL $ HsCmdTop $4 []
1278                                                    placeHolderType undefined)) }
1279                                                 -- TODO: is LL right here?
1280
1281         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1282                                                     -- hdaume: core annotation
1283         | fexp                                  { $1 }
1284
1285 scc_annot :: { Located FastString }
1286         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1287                                    ( do scc <- getSCC $2; return $ LL scc ) }
1288         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1289
1290 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1291         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1292                                                 { LL $ (getSTRING $2
1293                                                        ,( fromInteger $ getINTEGER $3
1294                                                         , fromInteger $ getINTEGER $5
1295                                                         )
1296                                                        ,( fromInteger $ getINTEGER $7
1297                                                         , fromInteger $ getINTEGER $9
1298                                                         )
1299                                                        )
1300                                                  }
1301
1302 fexp    :: { LHsExpr RdrName }
1303         : fexp aexp                             { LL $ HsApp $1 $2 }
1304         | aexp                                  { $1 }
1305
1306 aexp    :: { LHsExpr RdrName }
1307         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1308         | '~' aexp                      { LL $ ELazyPat $2 }
1309         | aexp1                 { $1 }
1310
1311 aexp1   :: { LHsExpr RdrName }
1312         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1313                                       ; return (LL r) }}
1314         | aexp2                 { $1 }
1315
1316 -- Here was the syntax for type applications that I was planning
1317 -- but there are difficulties (e.g. what order for type args)
1318 -- so it's not enabled yet.
1319 -- But this case *is* used for the left hand side of a generic definition,
1320 -- which is parsed as an expression before being munged into a pattern
1321         | qcname '{|' type '|}'         { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1322                                                      (sL (getLoc $3) (HsType $3)) }
1323
1324 aexp2   :: { LHsExpr RdrName }
1325         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1326         | qcname                        { L1 (HsVar   $! unLoc $1) }
1327         | literal                       { L1 (HsLit   $! unLoc $1) }
1328 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1329 -- into HsOverLit when -foverloaded-strings is on.
1330 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1331         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1332         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1333
1334         -- N.B.: sections get parsed by these next two productions.
1335         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't correct Haskell98
1336         -- (you'd have to write '((+ 3), (4 -))')
1337         -- but the less cluttered version fell out of having texps.
1338         | '(' texp ')'                  { LL (HsPar $2) }
1339         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1340
1341         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1342         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1343
1344         | '[' list ']'                  { LL (unLoc $2) }
1345         | '[:' parr ':]'                { LL (unLoc $2) }
1346         | '_'                           { L1 EWildPat }
1347
1348         -- Template Haskell Extension
1349         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice
1350                                         (L1 $ HsVar (mkUnqual varName
1351                                                         (getTH_ID_SPLICE $1)))) } -- $x
1352         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               -- $( exp )
1353
1354         | TH_QUASIQUOTE         { let { loc = getLoc $1
1355                                       ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1356                                       ; quoterId = mkUnqual varName quoter
1357                                       }
1358                                   in sL loc $ HsQuasiQuoteE (mkHsQuasiQuote quoterId quoteSpan quote) }
1359         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1360         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1361         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1362         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1363         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }
1364         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }
1365         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1366                                         return (LL $ HsBracket (PatBr p)) }
1367         | '[d|' cvtopbody '|]'  {% checkDecBrGroup $2 >>= \g ->
1368                                         return (LL $ HsBracket (DecBr g)) }
1369
1370         -- arrow notation extension
1371         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1372
1373 cmdargs :: { [LHsCmdTop RdrName] }
1374         : cmdargs acmd                  { $2 : $1 }
1375         | {- empty -}                   { [] }
1376
1377 acmd    :: { LHsCmdTop RdrName }
1378         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1379
1380 cvtopbody :: { [LHsDecl RdrName] }
1381         :  '{'            cvtopdecls0 '}'               { $2 }
1382         |      vocurly    cvtopdecls0 close             { $2 }
1383
1384 cvtopdecls0 :: { [LHsDecl RdrName] }
1385         : {- empty -}           { [] }
1386         | cvtopdecls            { $1 }
1387
1388 -----------------------------------------------------------------------------
1389 -- Tuple expressions
1390
1391 -- "texp" is short for tuple expressions:
1392 -- things that can appear unparenthesized as long as they're
1393 -- inside parens or delimitted by commas
1394 texp :: { LHsExpr RdrName }
1395         : exp                           { $1 }
1396
1397         -- Note [Parsing sections]
1398         -- ~~~~~~~~~~~~~~~~~~~~~~~
1399         -- We include left and right sections here, which isn't
1400         -- technically right according to Haskell 98.  For example
1401         --      (3 +, True) isn't legal
1402         -- However, we want to parse bang patterns like
1403         --      (!x, !y)
1404         -- and it's convenient to do so here as a section
1405         -- Then when converting expr to pattern we unravel it again
1406         -- Meanwhile, the renamer checks that real sections appear
1407         -- inside parens.
1408         | infixexp qop  { LL $ SectionL $1 $2 }
1409         | qopm infixexp       { LL $ SectionR $1 $2 }
1410
1411        -- View patterns get parenthesized above
1412         | exp '->' exp   { LL $ EViewPat $1 $3 }
1413
1414 -- Always at least one comma
1415 tup_exprs :: { [HsTupArg RdrName] }
1416            : texp commas_tup_tail  { Present $1 : $2 }
1417            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1418
1419 -- Always starts with commas; always follows an expr
1420 commas_tup_tail :: { [HsTupArg RdrName] }
1421 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1422
1423 -- Always follows a comma
1424 tup_tail :: { [HsTupArg RdrName] }
1425           : texp commas_tup_tail        { Present $1 : $2 }
1426           | texp                        { [Present $1] }
1427           | {- empty -}                 { [missingTupArg] }
1428
1429 -----------------------------------------------------------------------------
1430 -- List expressions
1431
1432 -- The rules below are little bit contorted to keep lexps left-recursive while
1433 -- avoiding another shift/reduce-conflict.
1434
1435 list :: { LHsExpr RdrName }
1436         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1437         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1438         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1439         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1440         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1441         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1442         | texp '|' flattenedpquals      { sL (comb2 $1 $>) $ mkHsDo ListComp (unLoc $3) $1 }
1443
1444 lexps :: { Located [LHsExpr RdrName] }
1445         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1446         | texp ',' texp                 { LL [$3,$1] }
1447
1448 -----------------------------------------------------------------------------
1449 -- List Comprehensions
1450
1451 flattenedpquals :: { Located [LStmt RdrName] }
1452     : pquals   { case (unLoc $1) of
1453                     ParStmt [(qs, _)] -> L1 qs
1454                     -- We just had one thing in our "parallel" list so
1455                     -- we simply return that thing directly
1456
1457                     _ -> L1 [$1]
1458                     -- We actually found some actual parallel lists so
1459                     -- we leave them into as a ParStmt
1460                 }
1461
1462 pquals :: { LStmt RdrName }
1463     : pquals1   { L1 (ParStmt [(qs, undefined) | qs <- (reverse (unLoc $1))]) }
1464
1465 pquals1 :: { Located [[LStmt RdrName]] }
1466     : pquals1 '|' squals    { LL (unLoc $3 : unLoc $1) }
1467     | squals                { L (getLoc $1) [unLoc $1] }
1468
1469 squals :: { Located [LStmt RdrName] }
1470     : squals1               { L (getLoc $1) (reverse (unLoc $1)) }
1471
1472 squals1 :: { Located [LStmt RdrName] }
1473     : transformquals1       { LL (unLoc $1) }
1474
1475 transformquals1 :: { Located [LStmt RdrName] }
1476     : transformquals1 ',' transformqual         { LL $ [LL ((unLoc $3) (unLoc $1))] }
1477     | transformquals1 ',' qual                  { LL ($3 : unLoc $1) }
1478 --  | transformquals1 ',' '{|' pquals '|}'      { LL ($4 : unLoc $1) }
1479     | transformqual                             { LL $ [LL ((unLoc $1) [])] }
1480     | qual                                      { L1 [$1] }
1481 --  | '{|' pquals '|}'                          { L1 [$2] }
1482
1483
1484 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1485 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1486 -- demand. Note that the {| |} symbols are reused from -XGenerics and hence if you want to compile
1487 -- a program that makes use of this temporary syntax you must supply that flag to GHC
1488
1489 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1490     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt (reverse leftStmts) $2) }
1491     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt (reverse leftStmts) $2 $4) }
1492     | 'then' 'group' 'by' exp              { LL $ \leftStmts -> (mkGroupByStmt (reverse leftStmts) $4) }
1493     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt (reverse leftStmts) $4) }
1494     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt (reverse leftStmts) $4 $6) }
1495
1496 -----------------------------------------------------------------------------
1497 -- Parallel array expressions
1498
1499 -- The rules below are little bit contorted; see the list case for details.
1500 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1501 -- Moreover, we allow explicit arrays with no element (represented by the nil
1502 -- constructor in the list case).
1503
1504 parr :: { LHsExpr RdrName }
1505         :                               { noLoc (ExplicitPArr placeHolderType []) }
1506         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1507         | lexps                         { L1 $ ExplicitPArr placeHolderType
1508                                                        (reverse (unLoc $1)) }
1509         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1510         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1511         | texp '|' flattenedpquals      { LL $ mkHsDo PArrComp (unLoc $3) $1 }
1512
1513 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1514
1515 -----------------------------------------------------------------------------
1516 -- Guards
1517
1518 guardquals :: { Located [LStmt RdrName] }
1519     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1520
1521 guardquals1 :: { Located [LStmt RdrName] }
1522     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1523     | qual                  { L1 [$1] }
1524
1525 -----------------------------------------------------------------------------
1526 -- Case alternatives
1527
1528 altslist :: { Located [LMatch RdrName] }
1529         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1530         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1531
1532 alts    :: { Located [LMatch RdrName] }
1533         : alts1                         { L1 (unLoc $1) }
1534         | ';' alts                      { LL (unLoc $2) }
1535
1536 alts1   :: { Located [LMatch RdrName] }
1537         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1538         | alts1 ';'                     { LL (unLoc $1) }
1539         | alt                           { L1 [$1] }
1540
1541 alt     :: { LMatch RdrName }
1542         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1543
1544 alt_rhs :: { Located (GRHSs RdrName) }
1545         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1546
1547 ralt :: { Located [LGRHS RdrName] }
1548         : '->' exp                      { LL (unguardedRHS $2) }
1549         | gdpats                        { L1 (reverse (unLoc $1)) }
1550
1551 gdpats :: { Located [LGRHS RdrName] }
1552         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1553         | gdpat                         { L1 [$1] }
1554
1555 gdpat   :: { LGRHS RdrName }
1556         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1557
1558 -- 'pat' recognises a pattern, including one with a bang at the top
1559 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1560 -- Bangs inside are parsed as infix operator applications, so that
1561 -- we parse them right when bang-patterns are off
1562 pat     :: { LPat RdrName }
1563 pat     :  exp                  {% checkPattern $1 }
1564         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1565
1566 apat   :: { LPat RdrName }
1567 apat    : aexp                  {% checkPattern $1 }
1568         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1569
1570 apats  :: { [LPat RdrName] }
1571         : apat apats            { $1 : $2 }
1572         | {- empty -}           { [] }
1573
1574 -----------------------------------------------------------------------------
1575 -- Statement sequences
1576
1577 stmtlist :: { Located [LStmt RdrName] }
1578         : '{'           stmts '}'       { LL (unLoc $2) }
1579         |     vocurly   stmts close     { $2 }
1580
1581 --      do { ;; s ; s ; ; s ;; }
1582 -- The last Stmt should be an expression, but that's hard to enforce
1583 -- here, because we need too much lookahead if we see do { e ; }
1584 -- So we use ExprStmts throughout, and switch the last one over
1585 -- in ParseUtils.checkDo instead
1586 stmts :: { Located [LStmt RdrName] }
1587         : stmt stmts_help               { LL ($1 : unLoc $2) }
1588         | ';' stmts                     { LL (unLoc $2) }
1589         | {- empty -}                   { noLoc [] }
1590
1591 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1592         : ';' stmts                     { LL (unLoc $2) }
1593         | {- empty -}                   { noLoc [] }
1594
1595 -- For typing stmts at the GHCi prompt, where
1596 -- the input may consist of just comments.
1597 maybe_stmt :: { Maybe (LStmt RdrName) }
1598         : stmt                          { Just $1 }
1599         | {- nothing -}                 { Nothing }
1600
1601 stmt  :: { LStmt RdrName }
1602         : qual                              { $1 }
1603         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1604
1605 qual  :: { LStmt RdrName }
1606     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1607     | exp                                   { L1 $ mkExprStmt $1 }
1608     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1609
1610 -----------------------------------------------------------------------------
1611 -- Record Field Update/Construction
1612
1613 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1614         : fbinds1                       { $1 }
1615         | {- empty -}                   { ([], False) }
1616
1617 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1618         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) }
1619         | fbind                         { ([$1], False) }
1620         | '..'                          { ([],   True) }
1621
1622 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1623         : qvar '=' exp  { HsRecField $1 $3 False }
1624         | qvar          { HsRecField $1 (L (getLoc $1) (HsVar (unLoc $1))) True }
1625                         -- Here's where we say that plain 'x'
1626                         -- means exactly 'x = x'.  The pun-flag boolean is
1627                         -- there so we can still print it right
1628
1629 -----------------------------------------------------------------------------
1630 -- Implicit Parameter Bindings
1631
1632 dbinds  :: { Located [LIPBind RdrName] }
1633         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1634                               in rest `seq` this `seq` LL (this : rest) }
1635         | dbinds ';'                    { LL (unLoc $1) }
1636         | dbind                         { let this = $1 in this `seq` L1 [this] }
1637 --      | {- empty -}                   { [] }
1638
1639 dbind   :: { LIPBind RdrName }
1640 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1641
1642 ipvar   :: { Located (IPName RdrName) }
1643         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1644
1645 -----------------------------------------------------------------------------
1646 -- Warnings and deprecations
1647
1648 namelist :: { Located [RdrName] }
1649 namelist : name_var              { L1 [unLoc $1] }
1650          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1651
1652 name_var :: { Located RdrName }
1653 name_var : var { $1 }
1654          | con { $1 }
1655
1656 -----------------------------------------
1657 -- Data constructors
1658 qcon    :: { Located RdrName }
1659         : qconid                { $1 }
1660         | '(' qconsym ')'       { LL (unLoc $2) }
1661         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1662 -- The case of '[:' ':]' is part of the production `parr'
1663
1664 con     :: { Located RdrName }
1665         : conid                 { $1 }
1666         | '(' consym ')'        { LL (unLoc $2) }
1667         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1668
1669 con_list :: { Located [Located RdrName] }
1670 con_list : con                  { L1 [$1] }
1671          | con ',' con_list     { LL ($1 : unLoc $3) }
1672
1673 sysdcon :: { Located DataCon }  -- Wired in data constructors
1674         : '(' ')'               { LL unitDataCon }
1675         | '(' commas ')'        { LL $ tupleCon Boxed ($2 + 1) }
1676         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1677         | '(#' commas '#)'      { LL $ tupleCon Unboxed ($2 + 1) }
1678         | '[' ']'               { LL nilDataCon }
1679
1680 conop :: { Located RdrName }
1681         : consym                { $1 }
1682         | '`' conid '`'         { LL (unLoc $2) }
1683
1684 qconop :: { Located RdrName }
1685         : qconsym               { $1 }
1686         | '`' qconid '`'        { LL (unLoc $2) }
1687
1688 -----------------------------------------------------------------------------
1689 -- Type constructors
1690
1691 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1692         : oqtycon                       { $1 }
1693         | '(' ')'                       { LL $ getRdrName unitTyCon }
1694         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed ($2 + 1)) }
1695         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1696         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed ($2 + 1)) }
1697         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1698         | '[' ']'                       { LL $ listTyCon_RDR }
1699         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1700
1701 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1702         : qtycon                        { $1 }
1703         | '(' qtyconsym ')'             { LL (unLoc $2) }
1704
1705 qtyconop :: { Located RdrName } -- Qualified or unqualified
1706         : qtyconsym                     { $1 }
1707         | '`' qtycon '`'                { LL (unLoc $2) }
1708
1709 qtycon :: { Located RdrName }   -- Qualified or unqualified
1710         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1711         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1712         | tycon                         { $1 }
1713
1714 tycon   :: { Located RdrName }  -- Unqualified
1715         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1716
1717 qtyconsym :: { Located RdrName }
1718         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1719         | tyconsym                      { $1 }
1720
1721 tyconsym :: { Located RdrName }
1722         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1723
1724 -----------------------------------------------------------------------------
1725 -- Operators
1726
1727 op      :: { Located RdrName }   -- used in infix decls
1728         : varop                 { $1 }
1729         | conop                 { $1 }
1730
1731 varop   :: { Located RdrName }
1732         : varsym                { $1 }
1733         | '`' varid '`'         { LL (unLoc $2) }
1734
1735 qop     :: { LHsExpr RdrName }   -- used in sections
1736         : qvarop                { L1 $ HsVar (unLoc $1) }
1737         | qconop                { L1 $ HsVar (unLoc $1) }
1738
1739 qopm    :: { LHsExpr RdrName }   -- used in sections
1740         : qvaropm               { L1 $ HsVar (unLoc $1) }
1741         | qconop                { L1 $ HsVar (unLoc $1) }
1742
1743 qvarop :: { Located RdrName }
1744         : qvarsym               { $1 }
1745         | '`' qvarid '`'        { LL (unLoc $2) }
1746
1747 qvaropm :: { Located RdrName }
1748         : qvarsym_no_minus      { $1 }
1749         | '`' qvarid '`'        { LL (unLoc $2) }
1750
1751 -----------------------------------------------------------------------------
1752 -- Type variables
1753
1754 tyvar   :: { Located RdrName }
1755 tyvar   : tyvarid               { $1 }
1756         | '(' tyvarsym ')'      { LL (unLoc $2) }
1757
1758 tyvarop :: { Located RdrName }
1759 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1760         | tyvarsym              { $1 }
1761         | '.'                   {% parseErrorSDoc (getLoc $1)
1762                                       (vcat [ptext (sLit "Illegal symbol '.' in type"),
1763                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1764                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1765                                 }
1766
1767 tyvarid :: { Located RdrName }
1768         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1769         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1770         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1771         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1772         | 'threadsafe'          { L1 $! mkUnqual tvName (fsLit "threadsafe") }
1773
1774 tyvarsym :: { Located RdrName }
1775 -- Does not include "!", because that is used for strictness marks
1776 --               or ".", because that separates the quantified type vars from the rest
1777 --               or "*", because that's used for kinds
1778 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1779
1780 -----------------------------------------------------------------------------
1781 -- Variables
1782
1783 var     :: { Located RdrName }
1784         : varid                 { $1 }
1785         | '(' varsym ')'        { LL (unLoc $2) }
1786
1787 qvar    :: { Located RdrName }
1788         : qvarid                { $1 }
1789         | '(' varsym ')'        { LL (unLoc $2) }
1790         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1791 -- We've inlined qvarsym here so that the decision about
1792 -- whether it's a qvar or a var can be postponed until
1793 -- *after* we see the close paren.
1794
1795 qvarid :: { Located RdrName }
1796         : varid                 { $1 }
1797         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1798         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1799
1800 varid :: { Located RdrName }
1801         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1802         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1803         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1804         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1805         | 'threadsafe'          { L1 $! mkUnqual varName (fsLit "threadsafe") }
1806         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1807         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1808
1809 qvarsym :: { Located RdrName }
1810         : varsym                { $1 }
1811         | qvarsym1              { $1 }
1812
1813 qvarsym_no_minus :: { Located RdrName }
1814         : varsym_no_minus       { $1 }
1815         | qvarsym1              { $1 }
1816
1817 qvarsym1 :: { Located RdrName }
1818 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1819
1820 varsym :: { Located RdrName }
1821         : varsym_no_minus       { $1 }
1822         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1823
1824 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1825         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1826         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1827
1828
1829 -- These special_ids are treated as keywords in various places,
1830 -- but as ordinary ids elsewhere.   'special_id' collects all these
1831 -- except 'unsafe', 'forall', and 'family' whose treatment differs
1832 -- depending on context
1833 special_id :: { Located FastString }
1834 special_id
1835         : 'as'                  { L1 (fsLit "as") }
1836         | 'qualified'           { L1 (fsLit "qualified") }
1837         | 'hiding'              { L1 (fsLit "hiding") }
1838         | 'export'              { L1 (fsLit "export") }
1839         | 'label'               { L1 (fsLit "label")  }
1840         | 'dynamic'             { L1 (fsLit "dynamic") }
1841         | 'stdcall'             { L1 (fsLit "stdcall") }
1842         | 'ccall'               { L1 (fsLit "ccall") }
1843         | 'prim'                { L1 (fsLit "prim") }
1844
1845 special_sym :: { Located FastString }
1846 special_sym : '!'       { L1 (fsLit "!") }
1847             | '.'       { L1 (fsLit ".") }
1848             | '*'       { L1 (fsLit "*") }
1849
1850 -----------------------------------------------------------------------------
1851 -- Data constructors
1852
1853 qconid :: { Located RdrName }   -- Qualified or unqualified
1854         : conid                 { $1 }
1855         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1856         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1857
1858 conid   :: { Located RdrName }
1859         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1860
1861 qconsym :: { Located RdrName }  -- Qualified or unqualified
1862         : consym                { $1 }
1863         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1864
1865 consym :: { Located RdrName }
1866         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1867
1868         -- ':' means only list cons
1869         | ':'                   { L1 $ consDataCon_RDR }
1870
1871
1872 -----------------------------------------------------------------------------
1873 -- Literals
1874
1875 literal :: { Located HsLit }
1876         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1877         | STRING                { L1 $ HsString     $ getSTRING $1 }
1878         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1879         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1880         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1881         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1882         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1883         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1884
1885 -----------------------------------------------------------------------------
1886 -- Layout
1887
1888 close :: { () }
1889         : vccurly               { () } -- context popped in lexer.
1890         | error                 {% popContext }
1891
1892 -----------------------------------------------------------------------------
1893 -- Miscellaneous (mostly renamings)
1894
1895 modid   :: { Located ModuleName }
1896         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1897         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1898                                   mkModuleNameFS
1899                                    (mkFastString
1900                                      (unpackFS mod ++ '.':unpackFS c))
1901                                 }
1902
1903 commas :: { Int }
1904         : commas ','                    { $1 + 1 }
1905         | ','                           { 1 }
1906
1907 -----------------------------------------------------------------------------
1908 -- Documentation comments
1909
1910 docnext :: { LHsDoc RdrName }
1911   : DOCNEXT {% case parseHaddockParagraphs (tokenise (getDOCNEXT $1)) of {
1912       MyLeft  err -> parseError (getLoc $1) err;
1913       MyRight doc -> return (L1 doc) } }
1914
1915 docprev :: { LHsDoc RdrName }
1916   : DOCPREV {% case parseHaddockParagraphs (tokenise (getDOCPREV $1)) of {
1917       MyLeft  err -> parseError (getLoc $1) err;
1918       MyRight doc -> return (L1 doc) } }
1919
1920 docnamed :: { Located (String, (HsDoc RdrName)) }
1921   : DOCNAMED {%
1922       let string = getDOCNAMED $1
1923           (name, rest) = break isSpace string
1924       in case parseHaddockParagraphs (tokenise rest) of {
1925         MyLeft  err -> parseError (getLoc $1) err;
1926         MyRight doc -> return (L1 (name, doc)) } }
1927
1928 docsection :: { Located (Int, HsDoc RdrName) }
1929   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1930         case parseHaddockString (tokenise doc) of {
1931       MyLeft  err -> parseError (getLoc $1) err;
1932       MyRight doc -> return (L1 (n, doc)) } }
1933
1934 moduleheader :: { (HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
1935         : DOCNEXT {% let string = getDOCNEXT $1 in
1936                case parseModuleHeader string of {
1937                  Right (str, info) ->
1938                    case parseHaddockParagraphs (tokenise str) of {
1939                      MyLeft err -> parseError (getLoc $1) err;
1940                      MyRight doc -> return (info, Just doc);
1941                    };
1942                  Left err -> parseError (getLoc $1) err
1943             }  }
1944
1945 maybe_docprev :: { Maybe (LHsDoc RdrName) }
1946         : docprev                       { Just $1 }
1947         | {- empty -}                   { Nothing }
1948
1949 maybe_docnext :: { Maybe (LHsDoc RdrName) }
1950         : docnext                       { Just $1 }
1951         | {- empty -}                   { Nothing }
1952
1953 {
1954 happyError :: P a
1955 happyError = srcParseFail
1956
1957 getVARID        (L _ (ITvarid    x)) = x
1958 getCONID        (L _ (ITconid    x)) = x
1959 getVARSYM       (L _ (ITvarsym   x)) = x
1960 getCONSYM       (L _ (ITconsym   x)) = x
1961 getQVARID       (L _ (ITqvarid   x)) = x
1962 getQCONID       (L _ (ITqconid   x)) = x
1963 getQVARSYM      (L _ (ITqvarsym  x)) = x
1964 getQCONSYM      (L _ (ITqconsym  x)) = x
1965 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
1966 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
1967 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1968 getCHAR         (L _ (ITchar     x)) = x
1969 getSTRING       (L _ (ITstring   x)) = x
1970 getINTEGER      (L _ (ITinteger  x)) = x
1971 getRATIONAL     (L _ (ITrational x)) = x
1972 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1973 getPRIMSTRING   (L _ (ITprimstring x)) = x
1974 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1975 getPRIMWORD     (L _ (ITprimword x)) = x
1976 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
1977 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
1978 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
1979 getINLINE       (L _ (ITinline_prag b)) = b
1980 getINLINE_CONLIKE (L _ (ITinline_conlike_prag b)) = b
1981 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
1982
1983 getDOCNEXT (L _ (ITdocCommentNext x)) = x
1984 getDOCPREV (L _ (ITdocCommentPrev x)) = x
1985 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
1986 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
1987
1988 getSCC :: Located Token -> P FastString
1989 getSCC lt = do let s = getSTRING lt
1990                    err = "Spaces are not allowed in SCCs"
1991                -- We probably actually want to be more restrictive than this
1992                if ' ' `elem` unpackFS s
1993                    then failSpanMsgP (getLoc lt) (text err)
1994                    else return s
1995
1996 -- Utilities for combining source spans
1997 comb2 :: Located a -> Located b -> SrcSpan
1998 comb2 a b = a `seq` b `seq` combineLocs a b
1999
2000 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2001 comb3 a b c = a `seq` b `seq` c `seq`
2002     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2003
2004 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2005 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2006     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2007                 combineSrcSpans (getLoc c) (getLoc d))
2008
2009 -- strict constructor version:
2010 {-# INLINE sL #-}
2011 sL :: SrcSpan -> a -> Located a
2012 sL span a = span `seq` a `seq` L span a
2013
2014 -- Make a source location for the file.  We're a bit lazy here and just
2015 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2016 -- try to find the span of the whole file (ToDo).
2017 fileSrcSpan :: P SrcSpan
2018 fileSrcSpan = do
2019   l <- getSrcLoc;
2020   let loc = mkSrcLoc (srcLocFile l) 1 0;
2021   return (mkSrcSpan loc loc)
2022 }