compiler/parser/Parser.y.pp

   1 --                                                              -*-haskell-*-
   2 -- ---------------------------------------------------------------------------
   3 -- (c) The University of Glasgow 1997-2003
   4 ---
   5 -- The GHC grammar.
   6 --
   7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -- ---------------------------------------------------------------------------
   9
  10 {
  11 {-# OPTIONS -w #-}
  12 -- The above warning supression flag is a temporary kludge.
  13 -- While working on this module you are encouraged to remove it and fix
  14 -- any warnings in the module. See
  15 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  16 -- for details
  17
  18 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
  19 {-
  20 Careful optimisation of the parser: we don't want to throw everything
  21 at it, because that takes too long and doesn't buy much, but we do want
  22 to inline certain key external functions, so we instruct GHC not to
  23 throw away inlinings as it would normally do in -O0 mode.
  24 -}
  25
  26 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
  27                 parseHeader ) where
  28
  29 import HsSyn
  30 import RdrHsSyn
  31 import HscTypes         ( IsBootInterface, WarningTxt(..) )
  32 import Lexer
  33 import RdrName
  34 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  35                           unboxedSingletonTyCon, unboxedSingletonDataCon,
  36                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  37 import Type             ( funTyCon )
  38 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
  39                           CCallConv(..), CCallTarget(..), defaultCCallConv
  40                         )
  41 import OccName          ( varName, dataName, tcClsName, tvName )
  42 import DataCon          ( DataCon, dataConName )
  43 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
  44                           SrcSpan, combineLocs, srcLocFile,
  45                           mkSrcLoc, mkSrcSpan )
  46 import Module
  47 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
  48 import Type             ( Kind, mkArrowKind, liftedTypeKind, unliftedTypeKind )
  49 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  50                           Activation(..), RuleMatchInfo(..), defaultInlineSpec )
  51 import DynFlags
  52 import OrdList
  53 import HaddockParse
  54 import {-# SOURCE #-} HaddockLex hiding ( Token )
  55 import HaddockUtils
  56
  57 import FastString
  58 import Maybes           ( orElse )
  59 import Outputable
  60
  61 import Control.Monad    ( unless )
  62 import GHC.Exts
  63 import Data.Char
  64 import Control.Monad    ( mplus )
  65 }
  66
  67 {-
  68 -----------------------------------------------------------------------------
  69 24 Februar 2006
  70
  71 Conflicts: 33 shift/reduce
  72            1 reduce/reduce
  73
  74 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  75 would think the two should never occur in the same context.
  76
  77   -=chak
  78
  79 -----------------------------------------------------------------------------
  80 31 December 2006
  81
  82 Conflicts: 34 shift/reduce
  83            1 reduce/reduce
  84
  85 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  86 would think the two should never occur in the same context.
  87
  88   -=chak
  89
  90 -----------------------------------------------------------------------------
  91 6 December 2006
  92
  93 Conflicts: 32 shift/reduce
  94            1 reduce/reduce
  95
  96 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
  97 would think the two should never occur in the same context.
  98
  99   -=chak
 100
 101 -----------------------------------------------------------------------------
 102 26 July 2006
 103
 104 Conflicts: 37 shift/reduce
 105            1 reduce/reduce
 106
 107 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
 108 would think the two should never occur in the same context.
 109
 110   -=chak
 111
 112 -----------------------------------------------------------------------------
 113 Conflicts: 38 shift/reduce (1.25)
 114
 115 10 for abiguity in 'if x then y else z + 1'             [State 178]
 116         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
 117         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
 118
 119 1 for ambiguity in 'if x then y else z :: T'            [State 178]
 120         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
 121
 122 4 for ambiguity in 'if x then y else z -< e'            [State 178]
 123         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
 124         There are four such operators: -<, >-, -<<, >>-
 125
 126
 127 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
 128         Which of these two is intended?
 129           case v of
 130             (x::T) -> T         -- Rhs is T
 131     or
 132           case v of
 133             (x::T -> T) -> ..   -- Rhs is ...
 134
 135 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
 136         (e::a) `b` c, or
 137         (e :: (a `b` c))
 138     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
 139     Same duplication between states 11 and 253 as the previous case
 140
 141 1 for ambiguity in 'let ?x ...'                         [State 329]
 142         the parser can't tell whether the ?x is the lhs of a normal binding or
 143         an implicit binding.  Fortunately resolving as shift gives it the only
 144         sensible meaning, namely the lhs of an implicit binding.
 145
 146 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
 147         we don't know whether the '[' starts the activation or not: it
 148         might be the start of the declaration with the activation being
 149         empty.  --SDM 1/4/2002
 150
 151 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
 152         since 'forall' is a valid variable name, we don't know whether
 153         to treat a forall on the input as the beginning of a quantifier
 154         or the beginning of the rule itself.  Resolving to shift means
 155         it's always treated as a quantifier, hence the above is disallowed.
 156         This saves explicitly defining a grammar for the rule lhs that
 157         doesn't include 'forall'.
 158
 159 1 for ambiguity when the source file starts with "-- | doc". We need another
 160   token of lookahead to determine if a top declaration or the 'module' keyword
 161   follows. Shift parses as if the 'module' keyword follows.
 162
 163 -- ---------------------------------------------------------------------------
 164 -- Adding location info
 165
 166 This is done in a stylised way using the three macros below, L0, L1
 167 and LL.  Each of these macros can be thought of as having type
 168
 169    L0, L1, LL :: a -> Located a
 170
 171 They each add a SrcSpan to their argument.
 172
 173    L0   adds 'noSrcSpan', used for empty productions
 174      -- This doesn't seem to work anymore -=chak
 175
 176    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
 177         from that token.
 178
 179    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
 180         the first and last tokens.
 181
 182 These suffice for the majority of cases.  However, we must be
 183 especially careful with empty productions: LL won't work if the first
 184 or last token on the lhs can represent an empty span.  In these cases,
 185 we have to calculate the span using more of the tokens from the lhs, eg.
 186
 187         | 'newtype' tycl_hdr '=' newconstr deriving
 188                 { L (comb3 $1 $4 $5)
 189                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
 190
 191 We provide comb3 and comb4 functions which are useful in such cases.
 192
 193 Be careful: there's no checking that you actually got this right, the
 194 only symptom will be that the SrcSpans of your syntax will be
 195 incorrect.
 196
 197 /*
 198  * We must expand these macros *before* running Happy, which is why this file is
 199  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 200  */
 201 #define L0   L noSrcSpan
 202 #define L1   sL (getLoc $1)
 203 #define LL   sL (comb2 $1 $>)
 204
 205 -- -----------------------------------------------------------------------------
 206
 207 -}
 208
 209 %token
 210  '_'            { L _ ITunderscore }            -- Haskell keywords
 211  'as'           { L _ ITas }
 212  'case'         { L _ ITcase }
 213  'class'        { L _ ITclass }
 214  'data'         { L _ ITdata }
 215  'default'      { L _ ITdefault }
 216  'deriving'     { L _ ITderiving }
 217  'do'           { L _ ITdo }
 218  'else'         { L _ ITelse }
 219  'hiding'       { L _ IThiding }
 220  'if'           { L _ ITif }
 221  'import'       { L _ ITimport }
 222  'in'           { L _ ITin }
 223  'infix'        { L _ ITinfix }
 224  'infixl'       { L _ ITinfixl }
 225  'infixr'       { L _ ITinfixr }
 226  'instance'     { L _ ITinstance }
 227  'let'          { L _ ITlet }
 228  'module'       { L _ ITmodule }
 229  'newtype'      { L _ ITnewtype }
 230  'of'           { L _ ITof }
 231  'qualified'    { L _ ITqualified }
 232  'then'         { L _ ITthen }
 233  'type'         { L _ ITtype }
 234  'where'        { L _ ITwhere }
 235  '_scc_'        { L _ ITscc }         -- ToDo: remove
 236
 237  'forall'       { L _ ITforall }                -- GHC extension keywords
 238  'foreign'      { L _ ITforeign }
 239  'export'       { L _ ITexport }
 240  'label'        { L _ ITlabel }
 241  'dynamic'      { L _ ITdynamic }
 242  'safe'         { L _ ITsafe }
 243  'threadsafe'   { L _ ITthreadsafe }
 244  'unsafe'       { L _ ITunsafe }
 245  'mdo'          { L _ ITmdo }
 246  'family'       { L _ ITfamily }
 247  'stdcall'      { L _ ITstdcallconv }
 248  'ccall'        { L _ ITccallconv }
 249  'dotnet'       { L _ ITdotnet }
 250  'proc'         { L _ ITproc }          -- for arrow notation extension
 251  'rec'          { L _ ITrec }           -- for arrow notation extension
 252  'group'    { L _ ITgroup }     -- for list transform extension
 253  'by'       { L _ ITby }        -- for list transform extension
 254  'using'    { L _ ITusing }     -- for list transform extension
 255
 256  '{-# INLINE'             { L _ (ITinline_prag _) }
 257  '{-# INLINE_CONLIKE'     { L _ (ITinline_conlike_prag _) }
 258  '{-# SPECIALISE'         { L _ ITspec_prag }
 259  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
 260  '{-# SOURCE'      { L _ ITsource_prag }
 261  '{-# RULES'       { L _ ITrules_prag }
 262  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 263  '{-# SCC'         { L _ ITscc_prag }
 264  '{-# GENERATED'   { L _ ITgenerated_prag }
 265  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 266  '{-# WARNING'  { L _ ITwarning_prag }
 267  '{-# UNPACK'      { L _ ITunpack_prag }
 268  '{-# ANN'      { L _ ITann_prag }
 269  '#-}'             { L _ ITclose_prag }
 270
 271  '..'           { L _ ITdotdot }                        -- reserved symbols
 272  ':'            { L _ ITcolon }
 273  '::'           { L _ ITdcolon }
 274  '='            { L _ ITequal }
 275  '\\'           { L _ ITlam }
 276  '|'            { L _ ITvbar }
 277  '<-'           { L _ ITlarrow }
 278  '->'           { L _ ITrarrow }
 279  '@'            { L _ ITat }
 280  '~'            { L _ ITtilde }
 281  '=>'           { L _ ITdarrow }
 282  '-'            { L _ ITminus }
 283  '!'            { L _ ITbang }
 284  '*'            { L _ ITstar }
 285  '-<'           { L _ ITlarrowtail }            -- for arrow notation
 286  '>-'           { L _ ITrarrowtail }            -- for arrow notation
 287  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
 288  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
 289  '.'            { L _ ITdot }
 290
 291  '{'            { L _ ITocurly }                        -- special symbols
 292  '}'            { L _ ITccurly }
 293  '{|'           { L _ ITocurlybar }
 294  '|}'           { L _ ITccurlybar }
 295  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
 296  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
 297  '['            { L _ ITobrack }
 298  ']'            { L _ ITcbrack }
 299  '[:'           { L _ ITopabrack }
 300  ':]'           { L _ ITcpabrack }
 301  '('            { L _ IToparen }
 302  ')'            { L _ ITcparen }
 303  '(#'           { L _ IToubxparen }
 304  '#)'           { L _ ITcubxparen }
 305  '(|'           { L _ IToparenbar }
 306  '|)'           { L _ ITcparenbar }
 307  ';'            { L _ ITsemi }
 308  ','            { L _ ITcomma }
 309  '`'            { L _ ITbackquote }
 310
 311  VARID          { L _ (ITvarid    _) }          -- identifiers
 312  CONID          { L _ (ITconid    _) }
 313  VARSYM         { L _ (ITvarsym   _) }
 314  CONSYM         { L _ (ITconsym   _) }
 315  QVARID         { L _ (ITqvarid   _) }
 316  QCONID         { L _ (ITqconid   _) }
 317  QVARSYM        { L _ (ITqvarsym  _) }
 318  QCONSYM        { L _ (ITqconsym  _) }
 319  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
 320  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
 321
 322  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
 323
 324  CHAR           { L _ (ITchar     _) }
 325  STRING         { L _ (ITstring   _) }
 326  INTEGER        { L _ (ITinteger  _) }
 327  RATIONAL       { L _ (ITrational _) }
 328
 329  PRIMCHAR       { L _ (ITprimchar   _) }
 330  PRIMSTRING     { L _ (ITprimstring _) }
 331  PRIMINTEGER    { L _ (ITprimint    _) }
 332  PRIMWORD       { L _ (ITprimword  _) }
 333  PRIMFLOAT      { L _ (ITprimfloat  _) }
 334  PRIMDOUBLE     { L _ (ITprimdouble _) }
 335
 336  DOCNEXT        { L _ (ITdocCommentNext _) }
 337  DOCPREV        { L _ (ITdocCommentPrev _) }
 338  DOCNAMED       { L _ (ITdocCommentNamed _) }
 339  DOCSECTION     { L _ (ITdocSection _ _) }
 340
 341 -- Template Haskell
 342 '[|'            { L _ ITopenExpQuote  }
 343 '[p|'           { L _ ITopenPatQuote  }
 344 '[t|'           { L _ ITopenTypQuote  }
 345 '[d|'           { L _ ITopenDecQuote  }
 346 '|]'            { L _ ITcloseQuote    }
 347 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
 348 '$('            { L _ ITparenEscape   }     -- $( exp )
 349 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
 350 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
 351 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
 352
 353 %monad { P } { >>= } { return }
 354 %lexer { lexer } { L _ ITeof }
 355 %name parseModule module
 356 %name parseStmt   maybe_stmt
 357 %name parseIdentifier  identifier
 358 %name parseType ctype
 359 %partial parseHeader header
 360 %tokentype { (Located Token) }
 361 %%
 362
 363 -----------------------------------------------------------------------------
 364 -- Identifiers; one of the entry points
 365 identifier :: { Located RdrName }
 366         : qvar                          { $1 }
 367         | qcon                          { $1 }
 368         | qvarop                        { $1 }
 369         | qconop                        { $1 }
 370     | '(' '->' ')'      { LL $ getRdrName funTyCon }
 371
 372 -----------------------------------------------------------------------------
 373 -- Module Header
 374
 375 -- The place for module deprecation is really too restrictive, but if it
 376 -- was allowed at its natural place just before 'module', we get an ugly
 377 -- s/r conflict with the second alternative. Another solution would be the
 378 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 379 -- either, and DEPRECATED is only expected to be used by people who really
 380 -- know what they are doing. :-)
 381
 382 module  :: { Located (HsModule RdrName) }
 383         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
 384                 {% fileSrcSpan >>= \ loc -> case $1 of { (info, doc) ->
 385                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4
 386                           info doc) )}}
 387         | body2
 388                 {% fileSrcSpan >>= \ loc ->
 389                    return (L loc (HsModule Nothing Nothing
 390                           (fst $1) (snd $1) Nothing emptyHaddockModInfo
 391                           Nothing)) }
 392
 393 maybedocheader :: { (HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
 394         : moduleheader            { $1 }
 395         | {- empty -}             { (emptyHaddockModInfo, Nothing) }
 396
 397 missing_module_keyword :: { () }
 398         : {- empty -}                           {% pushCurrentContext }
 399
 400 maybemodwarning :: { Maybe WarningTxt }
 401     : '{-# DEPRECATED' STRING '#-}' { Just (DeprecatedTxt (getSTRING $2)) }
 402     | '{-# WARNING' STRING '#-}'    { Just (WarningTxt (getSTRING $2)) }
 403     |  {- empty -}                  { Nothing }
 404
 405 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 406         :  '{'            top '}'               { $2 }
 407         |      vocurly    top close             { $2 }
 408
 409 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 410         :  '{' top '}'                          { $2 }
 411         |  missing_module_keyword top close     { $2 }
 412
 413 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 414         : importdecls                           { (reverse $1,[]) }
 415         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 416         | cvtopdecls                            { ([],$1) }
 417
 418 cvtopdecls :: { [LHsDecl RdrName] }
 419         : topdecls                              { cvTopDecls $1 }
 420
 421 -----------------------------------------------------------------------------
 422 -- Module declaration & imports only
 423
 424 header  :: { Located (HsModule RdrName) }
 425         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
 426                 {% fileSrcSpan >>= \ loc -> case $1 of { (info, doc) ->
 427                    return (L loc (HsModule (Just $3) $5 $7 [] $4
 428                    info doc))}}
 429         | missing_module_keyword importdecls
 430                 {% fileSrcSpan >>= \ loc ->
 431                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
 432                    emptyHaddockModInfo Nothing)) }
 433
 434 header_body :: { [LImportDecl RdrName] }
 435         :  '{'            importdecls           { $2 }
 436         |      vocurly    importdecls           { $2 }
 437
 438 -----------------------------------------------------------------------------
 439 -- The Export List
 440
 441 maybeexports :: { Maybe [LIE RdrName] }
 442         :  '(' exportlist ')'                   { Just $2 }
 443         |  {- empty -}                          { Nothing }
 444
 445 exportlist :: { [LIE RdrName] }
 446         : expdoclist ',' expdoclist             { $1 ++ $3 }
 447         | exportlist1                           { $1 }
 448
 449 exportlist1 :: { [LIE RdrName] }
 450         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
 451         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
 452         | expdoclist                                   { $1 }
 453
 454 expdoclist :: { [LIE RdrName] }
 455         : exp_doc expdoclist                           { $1 : $2 }
 456         | {- empty -}                                  { [] }
 457
 458 exp_doc :: { LIE RdrName }
 459         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
 460         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) }
 461         | docnext       { L1 (IEDoc (unLoc $1)) }
 462
 463    -- No longer allow things like [] and (,,,) to be exported
 464    -- They are built in syntax, always available
 465 export  :: { LIE RdrName }
 466         :  qvar                         { L1 (IEVar (unLoc $1)) }
 467         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
 468         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
 469         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
 470         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
 471         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
 472
 473 qcnames :: { [RdrName] }
 474         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
 475         |  qcname_ext                   { [unLoc $1]  }
 476
 477 qcname_ext :: { Located RdrName }       -- Variable or data constructor
 478                                         -- or tagged type constructor
 479         :  qcname                       { $1 }
 480         |  'type' qcon                  { sL (comb2 $1 $2)
 481                                              (setRdrNameSpace (unLoc $2)
 482                                                               tcClsName)  }
 483
 484 -- Cannot pull into qcname_ext, as qcname is also used in expression.
 485 qcname  :: { Located RdrName }  -- Variable or data constructor
 486         :  qvar                         { $1 }
 487         |  qcon                         { $1 }
 488
 489 -----------------------------------------------------------------------------
 490 -- Import Declarations
 491
 492 -- import decls can be *empty*, or even just a string of semicolons
 493 -- whereas topdecls must contain at least one topdecl.
 494
 495 importdecls :: { [LImportDecl RdrName] }
 496         : importdecls ';' importdecl            { $3 : $1 }
 497         | importdecls ';'                       { $1 }
 498         | importdecl                            { [ $1 ] }
 499         | {- empty -}                           { [] }
 500
 501 importdecl :: { LImportDecl RdrName }
 502         : 'import' maybe_src optqualified maybe_pkg modid maybeas maybeimpspec
 503                 { L (comb4 $1 $5 $6 $7) (ImportDecl $5 $4 $2 $3 (unLoc $6) (unLoc $7)) }
 504
 505 maybe_src :: { IsBootInterface }
 506         : '{-# SOURCE' '#-}'                    { True }
 507         | {- empty -}                           { False }
 508
 509 maybe_pkg :: { Maybe FastString }
 510         : STRING                                { Just (getSTRING $1) }
 511         | {- empty -}                           { Nothing }
 512
 513 optqualified :: { Bool }
 514         : 'qualified'                           { True  }
 515         | {- empty -}                           { False }
 516
 517 maybeas :: { Located (Maybe ModuleName) }
 518         : 'as' modid                            { LL (Just (unLoc $2)) }
 519         | {- empty -}                           { noLoc Nothing }
 520
 521 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
 522         : impspec                               { L1 (Just (unLoc $1)) }
 523         | {- empty -}                           { noLoc Nothing }
 524
 525 impspec :: { Located (Bool, [LIE RdrName]) }
 526         :  '(' exportlist ')'                   { LL (False, $2) }
 527         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
 528
 529 -----------------------------------------------------------------------------
 530 -- Fixity Declarations
 531
 532 prec    :: { Int }
 533         : {- empty -}           { 9 }
 534         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
 535
 536 infix   :: { Located FixityDirection }
 537         : 'infix'                               { L1 InfixN  }
 538         | 'infixl'                              { L1 InfixL  }
 539         | 'infixr'                              { L1 InfixR }
 540
 541 ops     :: { Located [Located RdrName] }
 542         : ops ',' op                            { LL ($3 : unLoc $1) }
 543         | op                                    { L1 [$1] }
 544
 545 -----------------------------------------------------------------------------
 546 -- Top-Level Declarations
 547
 548 topdecls :: { OrdList (LHsDecl RdrName) }
 549         : topdecls ';' topdecl                  { $1 `appOL` $3 }
 550         | topdecls ';'                          { $1 }
 551         | topdecl                               { $1 }
 552
 553 topdecl :: { OrdList (LHsDecl RdrName) }
 554         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 555         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
 556         | 'instance' inst_type where_inst
 557             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
 558               in
 559               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
 560         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
 561         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
 562         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
 563     | '{-# DEPRECATED' deprecations '#-}' { $2 }
 564     | '{-# WARNING' warnings '#-}'        { $2 }
 565         | '{-# RULES' rules '#-}'               { $2 }
 566         | annotation { unitOL $1 }
 567         | decl                                  { unLoc $1 }
 568
 569         -- Template Haskell Extension
 570         | '$(' exp ')'                          { unitOL (LL $ SpliceD (SpliceDecl $2)) }
 571         | TH_ID_SPLICE                          { unitOL (LL $ SpliceD (SpliceDecl $
 572                                                         L1 $ HsVar (mkUnqual varName (getTH_ID_SPLICE $1))
 573                                                   )) }
 574
 575 -- Type classes
 576 --
 577 cl_decl :: { LTyClDecl RdrName }
 578         : 'class' tycl_hdr fds where_cls
 579                 {% do { let { (binds, sigs, ats, docs)           =
 580                                 cvBindsAndSigs (unLoc $4)
 581                             ; (ctxt, tc, tvs, tparms) = unLoc $2}
 582                       ; checkTyVars tparms      -- only type vars allowed
 583                       ; checkKindSigs ats
 584                       ; return $ L (comb4 $1 $2 $3 $4)
 585                                    (mkClassDecl (ctxt, tc, tvs)
 586                                                 (unLoc $3) sigs binds ats docs) } }
 587
 588 -- Type declarations (toplevel)
 589 --
 590 ty_decl :: { LTyClDecl RdrName }
 591            -- ordinary type synonyms
 592         : 'type' type '=' ctype
 593                 -- Note ctype, not sigtype, on the right of '='
 594                 -- We allow an explicit for-all but we don't insert one
 595                 -- in   type Foo a = (b,b)
 596                 -- Instead we just say b is out of scope
 597                 --
 598                 -- Note the use of type for the head; this allows
 599                 -- infix type constructors to be declared
 600                 {% do { (tc, tvs, _) <- checkSynHdr $2 False
 601                       ; return (L (comb2 $1 $4)
 602                                   (TySynonym tc tvs Nothing $4))
 603                       } }
 604
 605            -- type family declarations
 606         | 'type' 'family' type opt_kind_sig
 607                 -- Note the use of type for the head; this allows
 608                 -- infix type constructors to be declared
 609                 --
 610                 {% do { (tc, tvs, _) <- checkSynHdr $3 False
 611                       ; return (L (comb3 $1 $3 $4)
 612                                   (TyFamily TypeFamily tc tvs (unLoc $4)))
 613                       } }
 614
 615            -- type instance declarations
 616         | 'type' 'instance' type '=' ctype
 617                 -- Note the use of type for the head; this allows
 618                 -- infix type constructors and type patterns
 619                 --
 620                 {% do { (tc, tvs, typats) <- checkSynHdr $3 True
 621                       ; return (L (comb2 $1 $5)
 622                                   (TySynonym tc tvs (Just typats) $5))
 623                       } }
 624
 625           -- ordinary data type or newtype declaration
 626         | data_or_newtype tycl_hdr constrs deriving
 627                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 628                       ; checkTyVars tparms    -- no type pattern
 629                       ; return $!
 630                           sL (comb4 $1 $2 $3 $4)
 631                                    -- We need the location on tycl_hdr in case
 632                                    -- constrs and deriving are both empty
 633                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 634                                Nothing (reverse (unLoc $3)) (unLoc $4)) } }
 635
 636           -- ordinary GADT declaration
 637         | data_or_newtype tycl_hdr opt_kind_sig
 638                  'where' gadt_constrlist
 639                  deriving
 640                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 641                       ; checkTyVars tparms    -- can have type pats
 642                       ; return $!
 643                           sL (comb4 $1 $2 $4 $5)
 644                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing)
 645                               (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
 646
 647           -- data/newtype family
 648         | 'data' 'family' tycl_hdr opt_kind_sig
 649                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 650                       ; checkTyVars tparms            -- no type pattern
 651                       ; unless (null (unLoc ctxt)) $  -- and no context
 652                           parseError (getLoc ctxt)
 653                             "A family declaration cannot have a context"
 654                       ; return $
 655                           L (comb3 $1 $2 $4)
 656                             (TyFamily DataFamily tc tvs (unLoc $4)) } }
 657
 658           -- data/newtype instance declaration
 659         | data_or_newtype 'instance' tycl_hdr constrs deriving
 660                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 661                                              -- can have type pats
 662                       ; return $
 663                           L (comb4 $1 $3 $4 $5)
 664                                    -- We need the location on tycl_hdr in case
 665                                    -- constrs and deriving are both empty
 666                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 667                               Nothing (reverse (unLoc $4)) (unLoc $5)) } }
 668
 669           -- GADT instance declaration
 670         | data_or_newtype 'instance' tycl_hdr opt_kind_sig
 671                  'where' gadt_constrlist
 672                  deriving
 673                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
 674                                              -- can have type pats
 675                       ; return $
 676                           L (comb4 $1 $3 $6 $7)
 677                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 678                                (unLoc $4) (reverse (unLoc $6)) (unLoc $7)) } }
 679
 680 -- Associate type family declarations
 681 --
 682 -- * They have a different syntax than on the toplevel (no family special
 683 --   identifier).
 684 --
 685 -- * They also need to be separate from instances; otherwise, data family
 686 --   declarations without a kind signature cause parsing conflicts with empty
 687 --   data declarations.
 688 --
 689 at_decl_cls :: { LTyClDecl RdrName }
 690            -- type family declarations
 691         : 'type' type opt_kind_sig
 692                 -- Note the use of type for the head; this allows
 693                 -- infix type constructors to be declared
 694                 --
 695                 {% do { (tc, tvs, _) <- checkSynHdr $2 False
 696                       ; return (L (comb3 $1 $2 $3)
 697                                   (TyFamily TypeFamily tc tvs (unLoc $3)))
 698                       } }
 699
 700            -- default type instance
 701         | 'type' type '=' ctype
 702                 -- Note the use of type for the head; this allows
 703                 -- infix type constructors and type patterns
 704                 --
 705                 {% do { (tc, tvs, typats) <- checkSynHdr $2 True
 706                       ; return (L (comb2 $1 $4)
 707                                   (TySynonym tc tvs (Just typats) $4))
 708                       } }
 709
 710           -- data/newtype family declaration
 711         | 'data' tycl_hdr opt_kind_sig
 712                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 713                       ; checkTyVars tparms            -- no type pattern
 714                       ; unless (null (unLoc ctxt)) $  -- and no context
 715                           parseError (getLoc ctxt)
 716                             "A family declaration cannot have a context"
 717                       ; return $
 718                           L (comb3 $1 $2 $3)
 719                             (TyFamily DataFamily tc tvs (unLoc $3))
 720                       } }
 721
 722 -- Associate type instances
 723 --
 724 at_decl_inst :: { LTyClDecl RdrName }
 725            -- type instance declarations
 726         : 'type' type '=' ctype
 727                 -- Note the use of type for the head; this allows
 728                 -- infix type constructors and type patterns
 729                 --
 730                 {% do { (tc, tvs, typats) <- checkSynHdr $2 True
 731                       ; return (L (comb2 $1 $4)
 732                                   (TySynonym tc tvs (Just typats) $4))
 733                       } }
 734
 735         -- data/newtype instance declaration
 736         | data_or_newtype tycl_hdr constrs deriving
 737                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 738                                              -- can have type pats
 739                       ; return $
 740                           L (comb4 $1 $2 $3 $4)
 741                                    -- We need the location on tycl_hdr in case
 742                                    -- constrs and deriving are both empty
 743                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 744                               Nothing (reverse (unLoc $3)) (unLoc $4)) } }
 745
 746         -- GADT instance declaration
 747         | data_or_newtype tycl_hdr opt_kind_sig
 748                  'where' gadt_constrlist
 749                  deriving
 750                 {% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
 751                                              -- can have type pats
 752                       ; return $
 753                           L (comb4 $1 $2 $5 $6)
 754                             (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms)
 755                              (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
 756
 757 data_or_newtype :: { Located NewOrData }
 758         : 'data'        { L1 DataType }
 759         | 'newtype'     { L1 NewType }
 760
 761 opt_kind_sig :: { Located (Maybe Kind) }
 762         :                               { noLoc Nothing }
 763         | '::' kind                     { LL (Just (unLoc $2)) }
 764
 765 -- tycl_hdr parses the header of a class or data type decl,
 766 -- which takes the form
 767 --      T a b
 768 --      Eq a => T a
 769 --      (Eq a, Ord b) => T a b
 770 --      T Int [a]                       -- for associated types
 771 -- Rather a lot of inlining here, else we get reduce/reduce errors
 772 tycl_hdr :: { Located (LHsContext RdrName,
 773                        Located RdrName,
 774                        [LHsTyVarBndr RdrName],
 775                        [LHsType RdrName]) }
 776         : context '=>' type             {% checkTyClHdr $1         $3 >>= return.LL }
 777         | type                          {% checkTyClHdr (noLoc []) $1 >>= return.L1 }
 778
 779 -----------------------------------------------------------------------------
 780 -- Stand-alone deriving
 781
 782 -- Glasgow extension: stand-alone deriving declarations
 783 stand_alone_deriving :: { LDerivDecl RdrName }
 784         : 'deriving' 'instance' inst_type {% checkDerivDecl (LL (DerivDecl $3)) }
 785
 786 -----------------------------------------------------------------------------
 787 -- Nested declarations
 788
 789 -- Declaration in class bodies
 790 --
 791 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
 792 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 793           | decl                        { $1 }
 794
 795 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 796           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
 797           | decls_cls ';'               { LL (unLoc $1) }
 798           | decl_cls                    { $1 }
 799           | {- empty -}                 { noLoc nilOL }
 800
 801
 802 decllist_cls
 803         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 804         : '{'         decls_cls '}'     { LL (unLoc $2) }
 805         |     vocurly decls_cls close   { $2 }
 806
 807 -- Class body
 808 --
 809 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
 810                                 -- No implicit parameters
 811                                 -- May have type declarations
 812         : 'where' decllist_cls          { LL (unLoc $2) }
 813         | {- empty -}                   { noLoc nilOL }
 814
 815 -- Declarations in instance bodies
 816 --
 817 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
 818 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
 819            | decl                       { $1 }
 820
 821 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 822            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
 823            | decls_inst ';'             { LL (unLoc $1) }
 824            | decl_inst                  { $1 }
 825            | {- empty -}                { noLoc nilOL }
 826
 827 decllist_inst
 828         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 829         : '{'         decls_inst '}'    { LL (unLoc $2) }
 830         |     vocurly decls_inst close  { $2 }
 831
 832 -- Instance body
 833 --
 834 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
 835                                 -- No implicit parameters
 836                                 -- May have type declarations
 837         : 'where' decllist_inst         { LL (unLoc $2) }
 838         | {- empty -}                   { noLoc nilOL }
 839
 840 -- Declarations in binding groups other than classes and instances
 841 --
 842 decls   :: { Located (OrdList (LHsDecl RdrName)) }
 843         : decls ';' decl                { let { this = unLoc $3;
 844                                     rest = unLoc $1;
 845                                     these = rest `appOL` this }
 846                               in rest `seq` this `seq` these `seq`
 847                                     LL these }
 848         | decls ';'                     { LL (unLoc $1) }
 849         | decl                          { $1 }
 850         | {- empty -}                   { noLoc nilOL }
 851
 852 decllist :: { Located (OrdList (LHsDecl RdrName)) }
 853         : '{'            decls '}'      { LL (unLoc $2) }
 854         |     vocurly    decls close    { $2 }
 855
 856 -- Binding groups other than those of class and instance declarations
 857 --
 858 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
 859                                                 -- No type declarations
 860         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
 861         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 862         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 863
 864 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
 865                                                 -- No type declarations
 866         : 'where' binds                 { LL (unLoc $2) }
 867         | {- empty -}                   { noLoc emptyLocalBinds }
 868
 869
 870 -----------------------------------------------------------------------------
 871 -- Transformation Rules
 872
 873 rules   :: { OrdList (LHsDecl RdrName) }
 874         :  rules ';' rule                       { $1 `snocOL` $3 }
 875         |  rules ';'                            { $1 }
 876         |  rule                                 { unitOL $1 }
 877         |  {- empty -}                          { nilOL }
 878
 879 rule    :: { LHsDecl RdrName }
 880         : STRING activation rule_forall infixexp '=' exp
 881              { LL $ RuleD (HsRule (getSTRING $1)
 882                                   ($2 `orElse` AlwaysActive)
 883                                   $3 $4 placeHolderNames $6 placeHolderNames) }
 884
 885 activation :: { Maybe Activation }
 886         : {- empty -}                           { Nothing }
 887         | explicit_activation                   { Just $1 }
 888
 889 explicit_activation :: { Activation }  -- In brackets
 890         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
 891         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
 892
 893 rule_forall :: { [RuleBndr RdrName] }
 894         : 'forall' rule_var_list '.'            { $2 }
 895         | {- empty -}                           { [] }
 896
 897 rule_var_list :: { [RuleBndr RdrName] }
 898         : rule_var                              { [$1] }
 899         | rule_var rule_var_list                { $1 : $2 }
 900
 901 rule_var :: { RuleBndr RdrName }
 902         : varid                                 { RuleBndr $1 }
 903         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 904
 905 -----------------------------------------------------------------------------
 906 -- Warnings and deprecations (c.f. rules)
 907
 908 warnings :: { OrdList (LHsDecl RdrName) }
 909         : warnings ';' warning          { $1 `appOL` $3 }
 910         | warnings ';'                  { $1 }
 911         | warning                               { $1 }
 912         | {- empty -}                           { nilOL }
 913
 914 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 915 warning :: { OrdList (LHsDecl RdrName) }
 916         : namelist STRING
 917                 { toOL [ LL $ WarningD (Warning n (WarningTxt (getSTRING $2)))
 918                        | n <- unLoc $1 ] }
 919
 920 deprecations :: { OrdList (LHsDecl RdrName) }
 921         : deprecations ';' deprecation          { $1 `appOL` $3 }
 922         | deprecations ';'                      { $1 }
 923         | deprecation                           { $1 }
 924         | {- empty -}                           { nilOL }
 925
 926 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 927 deprecation :: { OrdList (LHsDecl RdrName) }
 928         : namelist STRING
 929                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt (getSTRING $2)))
 930                        | n <- unLoc $1 ] }
 931
 932 -----------------------------------------------------------------------------
 933 -- Annotations
 934 annotation :: { LHsDecl RdrName }
 935     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
 936     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
 937     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
 938
 939
 940 -----------------------------------------------------------------------------
 941 -- Foreign import and export declarations
 942
 943 fdecl :: { LHsDecl RdrName }
 944 fdecl : 'import' callconv safety fspec
 945                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
 946       | 'import' callconv        fspec
 947                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
 948                         return (LL d) } }
 949       | 'export' callconv fspec
 950                 {% mkExport $2 (unLoc $3) >>= return.LL }
 951
 952 callconv :: { CallConv }
 953           : 'stdcall'                   { CCall  StdCallConv }
 954           | 'ccall'                     { CCall  CCallConv   }
 955           | 'dotnet'                    { DNCall             }
 956
 957 safety :: { Safety }
 958         : 'unsafe'                      { PlayRisky }
 959         | 'safe'                        { PlaySafe  False }
 960         | 'threadsafe'                  { PlaySafe  True }
 961
 962 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
 963        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
 964        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
 965          -- if the entity string is missing, it defaults to the empty string;
 966          -- the meaning of an empty entity string depends on the calling
 967          -- convention
 968
 969 -----------------------------------------------------------------------------
 970 -- Type signatures
 971
 972 opt_sig :: { Maybe (LHsType RdrName) }
 973         : {- empty -}                   { Nothing }
 974         | '::' sigtype                  { Just $2 }
 975
 976 opt_asig :: { Maybe (LHsType RdrName) }
 977         : {- empty -}                   { Nothing }
 978         | '::' atype                    { Just $2 }
 979
 980 sigtypes1 :: { [LHsType RdrName] }
 981         : sigtype                       { [ $1 ] }
 982         | sigtype ',' sigtypes1         { $1 : $3 }
 983
 984 sigtype :: { LHsType RdrName }
 985         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 986         -- Wrap an Implicit forall if there isn't one there already
 987
 988 sigtypedoc :: { LHsType RdrName }
 989         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 990         -- Wrap an Implicit forall if there isn't one there already
 991
 992 sig_vars :: { Located [Located RdrName] }
 993          : sig_vars ',' var             { LL ($3 : unLoc $1) }
 994          | var                          { L1 [$1] }
 995
 996 -----------------------------------------------------------------------------
 997 -- Types
 998
 999 infixtype :: { LHsType RdrName }
1000         : btype qtyconop gentype         { LL $ HsOpTy $1 $2 $3 }
1001         | btype tyvarop  gentype         { LL $ HsOpTy $1 $2 $3 }
1002
1003 infixtypedoc :: { LHsType RdrName }
1004         : infixtype                      { $1 }
1005         | infixtype docprev              { LL $ HsDocTy $1 $2 }
1006
1007 gentypedoc :: { LHsType RdrName }
1008         : btype                          { $1 }
1009         | btypedoc                       { $1 }
1010         | infixtypedoc                   { $1 }
1011         | btype '->' ctypedoc            { LL $ HsFunTy $1 $3 }
1012         | btypedoc '->' ctypedoc         { LL $ HsFunTy $1 $3 }
1013
1014 ctypedoc  :: { LHsType RdrName }
1015         : 'forall' tv_bndrs '.' ctypedoc { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
1016         | context '=>' ctypedoc          { LL $ mkImplicitHsForAllTy   $1 $3 }
1017         -- A type of form (context => type) is an *implicit* HsForAllTy
1018         | gentypedoc                     { $1 }
1019
1020 strict_mark :: { Located HsBang }
1021         : '!'                           { L1 HsStrict }
1022         | '{-# UNPACK' '#-}' '!'        { LL HsUnbox }
1023
1024 -- A ctype is a for-all type
1025 ctype   :: { LHsType RdrName }
1026         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
1027         | context '=>' type             { LL $ mkImplicitHsForAllTy   $1 $3 }
1028         -- A type of form (context => type) is an *implicit* HsForAllTy
1029         | type                          { $1 }
1030
1031 -- We parse a context as a btype so that we don't get reduce/reduce
1032 -- errors in ctype.  The basic problem is that
1033 --      (Eq a, Ord a)
1034 -- looks so much like a tuple type.  We can't tell until we find the =>
1035 --
1036 -- We have the t1 ~ t2 form here and in gentype, to permit an individual
1037 -- equational constraint without parenthesis.
1038 context :: { LHsContext RdrName }
1039         : btype '~'      btype          {% checkContext
1040                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
1041         | btype                         {% checkContext $1 }
1042
1043 type :: { LHsType RdrName }
1044         : ipvar '::' gentype            { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
1045         | gentype                       { $1 }
1046
1047 gentype :: { LHsType RdrName }
1048         : btype                         { $1 }
1049         | btype qtyconop gentype        { LL $ HsOpTy $1 $2 $3 }
1050         | btype tyvarop  gentype        { LL $ HsOpTy $1 $2 $3 }
1051         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
1052         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
1053
1054 btype :: { LHsType RdrName }
1055         : btype atype                   { LL $ HsAppTy $1 $2 }
1056         | atype                         { $1 }
1057
1058 btypedoc :: { LHsType RdrName }
1059         : btype atype docprev           { LL $ HsDocTy (L (comb2 $1 $2) (HsAppTy $1 $2)) $3 }
1060         | atype docprev                 { LL $ HsDocTy $1 $2 }
1061
1062 atype :: { LHsType RdrName }
1063         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1064         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1065         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }
1066         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1067         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1068         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1069         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1070         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1071         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1072 -- Generics
1073         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
1074
1075 -- An inst_type is what occurs in the head of an instance decl
1076 --      e.g.  (Foo a, Gaz b) => Wibble a b
1077 -- It's kept as a single type, with a MonoDictTy at the right
1078 -- hand corner, for convenience.
1079 inst_type :: { LHsType RdrName }
1080         : sigtype                       {% checkInstType $1 }
1081
1082 inst_types1 :: { [LHsType RdrName] }
1083         : inst_type                     { [$1] }
1084         | inst_type ',' inst_types1     { $1 : $3 }
1085
1086 comma_types0  :: { [LHsType RdrName] }
1087         : comma_types1                  { $1 }
1088         | {- empty -}                   { [] }
1089
1090 comma_types1    :: { [LHsType RdrName] }
1091         : ctype                         { [$1] }
1092         | ctype  ',' comma_types1       { $1 : $3 }
1093
1094 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1095          : tv_bndr tv_bndrs             { $1 : $2 }
1096          | {- empty -}                  { [] }
1097
1098 tv_bndr :: { LHsTyVarBndr RdrName }
1099         : tyvar                         { L1 (UserTyVar (unLoc $1)) }
1100         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2)
1101                                                           (unLoc $4)) }
1102
1103 fds :: { Located [Located ([RdrName], [RdrName])] }
1104         : {- empty -}                   { noLoc [] }
1105         | '|' fds1                      { LL (reverse (unLoc $2)) }
1106
1107 fds1 :: { Located [Located ([RdrName], [RdrName])] }
1108         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1109         | fd                            { L1 [$1] }
1110
1111 fd :: { Located ([RdrName], [RdrName]) }
1112         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1113                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1114
1115 varids0 :: { Located [RdrName] }
1116         : {- empty -}                   { noLoc [] }
1117         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1118
1119 -----------------------------------------------------------------------------
1120 -- Kinds
1121
1122 kind    :: { Located Kind }
1123         : akind                 { $1 }
1124         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1125
1126 akind   :: { Located Kind }
1127         : '*'                   { L1 liftedTypeKind }
1128         | '!'                   { L1 unliftedTypeKind }
1129         | '(' kind ')'          { LL (unLoc $2) }
1130
1131
1132 -----------------------------------------------------------------------------
1133 -- Datatype declarations
1134
1135 gadt_constrlist :: { Located [LConDecl RdrName] }
1136         : '{'            gadt_constrs '}'       { LL (unLoc $2) }
1137         |     vocurly    gadt_constrs close     { $2 }
1138
1139 gadt_constrs :: { Located [LConDecl RdrName] }
1140         : gadt_constrs ';' gadt_constr  { LL ($3 : unLoc $1) }
1141         | gadt_constrs ';'              { $1 }
1142         | gadt_constr                   { L1 [$1] }
1143
1144 -- We allow the following forms:
1145 --      C :: Eq a => a -> T a
1146 --      C :: forall a. Eq a => !a -> T a
1147 --      D { x,y :: a } :: T a
1148 --      forall a. Eq a => D { x,y :: a } :: T a
1149
1150 gadt_constr :: { LConDecl RdrName }
1151         : con '::' sigtype
1152               { LL (mkGadtDecl $1 $3) }
1153         -- Syntax: Maybe merge the record stuff with the single-case above?
1154         --         (to kill the mostly harmless reduce/reduce error)
1155         -- XXX revisit audreyt
1156         | constr_stuff_record '::' sigtype
1157                 { let (con,details) = unLoc $1 in
1158                   LL (ConDecl con Implicit [] (noLoc []) details (ResTyGADT $3) Nothing) }
1159 {-
1160         | forall context '=>' constr_stuff_record '::' sigtype
1161                 { let (con,details) = unLoc $4 in
1162                   LL (ConDecl con Implicit (unLoc $1) $2 details (ResTyGADT $6) Nothing ) }
1163         | forall constr_stuff_record '::' sigtype
1164                 { let (con,details) = unLoc $2 in
1165                   LL (ConDecl con Implicit (unLoc $1) (noLoc []) details (ResTyGADT $4) Nothing) }
1166 -}
1167
1168
1169 constrs :: { Located [LConDecl RdrName] }
1170         : {- empty; a GHC extension -}  { noLoc [] }
1171         | maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1172
1173 constrs1 :: { Located [LConDecl RdrName] }
1174         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1175         | constr                                          { L1 [$1] }
1176
1177 constr :: { LConDecl RdrName }
1178         : maybe_docnext forall context '=>' constr_stuff maybe_docprev
1179                 { let (con,details) = unLoc $5 in
1180                   L (comb4 $2 $3 $4 $5) (ConDecl con Explicit (unLoc $2) $3 details ResTyH98 ($1 `mplus` $6)) }
1181         | maybe_docnext forall constr_stuff maybe_docprev
1182                 { let (con,details) = unLoc $3 in
1183                   L (comb2 $2 $3) (ConDecl con Explicit (unLoc $2) (noLoc []) details ResTyH98 ($1 `mplus` $4)) }
1184
1185 forall :: { Located [LHsTyVarBndr RdrName] }
1186         : 'forall' tv_bndrs '.'         { LL $2 }
1187         | {- empty -}                   { noLoc [] }
1188
1189 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1190 -- We parse the constructor declaration
1191 --      C t1 t2
1192 -- as a btype (treating C as a type constructor) and then convert C to be
1193 -- a data constructor.  Reason: it might continue like this:
1194 --      C t1 t2 %: D Int
1195 -- in which case C really would be a type constructor.  We can't resolve this
1196 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1197         : btype                         {% mkPrefixCon $1 [] >>= return.LL }
1198         | oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.LL }
1199         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.LL }
1200         | btype conop btype             { LL ($2, InfixCon $1 $3) }
1201
1202 constr_stuff_record :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1203         : oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.sL (comb2 $1 $>) }
1204         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.sL (comb2 $1 $>) }
1205
1206 fielddecls :: { [([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName))] }
1207         : fielddecl maybe_docnext ',' maybe_docprev fielddecls { addFieldDoc (unLoc $1) $4 : addFieldDocs $5 $2 }
1208         | fielddecl                                            { [unLoc $1] }
1209
1210 fielddecl :: { Located ([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName)) }
1211         : maybe_docnext sig_vars '::' ctype maybe_docprev      { L (comb3 $2 $3 $4) (reverse (unLoc $2), $4, $1 `mplus` $5) }
1212
1213 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1214 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1215 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1216 -- We don't allow a context, but that's sorted out by the type checker.
1217 deriving :: { Located (Maybe [LHsType RdrName]) }
1218         : {- empty -}                           { noLoc Nothing }
1219         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1220                                       ; p <- checkInstType (L loc (HsTyVar tv))
1221                                       ; return (LL (Just [p])) } }
1222         | 'deriving' '(' ')'                    { LL (Just []) }
1223         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1224              -- Glasgow extension: allow partial
1225              -- applications in derivings
1226
1227 -----------------------------------------------------------------------------
1228 -- Value definitions
1229
1230 {- There's an awkward overlap with a type signature.  Consider
1231         f :: Int -> Int = ...rhs...
1232    Then we can't tell whether it's a type signature or a value
1233    definition with a result signature until we see the '='.
1234    So we have to inline enough to postpone reductions until we know.
1235 -}
1236
1237 {-
1238   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1239   instead of qvar, we get another shift/reduce-conflict. Consider the
1240   following programs:
1241
1242      { (^^) :: Int->Int ; }          Type signature; only var allowed
1243
1244      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1245                                      qvar allowed (because of instance decls)
1246
1247   We can't tell whether to reduce var to qvar until after we've read the signatures.
1248 -}
1249
1250 docdecl :: { LHsDecl RdrName }
1251         : docdecld { L1 (DocD (unLoc $1)) }
1252
1253 docdecld :: { LDocDecl RdrName }
1254         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1255         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1256         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1257         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1258
1259 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1260         : sigdecl                       { $1 }
1261         | '!' aexp rhs                  {% do { pat <- checkPattern $2;
1262                                                 return (LL $ unitOL $ LL $ ValD (
1263                                                         PatBind (LL $ BangPat pat) (unLoc $3)
1264                                                                 placeHolderType placeHolderNames)) } }
1265         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
1266                                                 let { l = comb2 $1 $> };
1267                                                 return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1268         | docdecl                       { LL $ unitOL $1 }
1269
1270 rhs     :: { Located (GRHSs RdrName) }
1271         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1272         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1273
1274 gdrhs :: { Located [LGRHS RdrName] }
1275         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1276         | gdrh                  { L1 [$1] }
1277
1278 gdrh :: { LGRHS RdrName }
1279         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1280
1281 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1282         : infixexp '::' sigtypedoc
1283                                 {% do s <- checkValSig $1 $3;
1284                                       return (LL $ unitOL (LL $ SigD s)) }
1285                 -- See the above notes for why we need infixexp here
1286         | var ',' sig_vars '::' sigtypedoc
1287                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1288         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1289                                              | n <- unLoc $3 ] }
1290         | '{-# INLINE'   activation qvar '#-}'
1291                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 FunLike (getINLINE $1)))) }
1292         | '{-# INLINE_CONLIKE' activation qvar '#-}'
1293                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 ConLike (getINLINE_CONLIKE $1)))) }
1294         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1295                                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlineSpec)
1296                                             | t <- $4] }
1297         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1298                                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlineSpec $2 FunLike (getSPEC_INLINE $1)))
1299                                             | t <- $5] }
1300         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1301                                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1302
1303 -----------------------------------------------------------------------------
1304 -- Expressions
1305
1306 exp   :: { LHsExpr RdrName }
1307         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1308         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1309         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1310         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1311         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1312         | infixexp                      { $1 }
1313
1314 infixexp :: { LHsExpr RdrName }
1315         : exp10                         { $1 }
1316         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1317
1318 exp10 :: { LHsExpr RdrName }
1319         : '\\' apat apats opt_asig '->' exp
1320                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1321                                                                 (unguardedGRHSs $6)
1322                                                             ]) }
1323         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1324         | 'if' exp 'then' exp 'else' exp        { LL $ HsIf $2 $4 $6 }
1325         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1326         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1327
1328         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1329                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1330                                            return (L loc (mkHsDo DoExpr stmts body)) }
1331         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1332                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1333                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1334         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1335                                                         then HsSCC (unLoc $1) $2
1336                                                         else HsPar $2 }
1337         | hpc_annot exp                         { LL $ if opt_Hpc
1338                                                         then HsTickPragma (unLoc $1) $2
1339                                                         else HsPar $2 }
1340
1341         | 'proc' aexp '->' exp
1342                         {% checkPattern $2 >>= \ p ->
1343                            return (LL $ HsProc p (LL $ HsCmdTop $4 []
1344                                                    placeHolderType undefined)) }
1345                                                 -- TODO: is LL right here?
1346
1347         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1348                                                     -- hdaume: core annotation
1349         | fexp                                  { $1 }
1350
1351 scc_annot :: { Located FastString }
1352         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1353                                    ( do scc <- getSCC $2; return $ LL scc ) }
1354         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1355
1356 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1357         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1358                                                 { LL $ (getSTRING $2
1359                                                        ,( fromInteger $ getINTEGER $3
1360                                                         , fromInteger $ getINTEGER $5
1361                                                         )
1362                                                        ,( fromInteger $ getINTEGER $7
1363                                                         , fromInteger $ getINTEGER $9
1364                                                         )
1365                                                        )
1366                                                  }
1367
1368 fexp    :: { LHsExpr RdrName }
1369         : fexp aexp                             { LL $ HsApp $1 $2 }
1370         | aexp                                  { $1 }
1371
1372 aexp    :: { LHsExpr RdrName }
1373         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1374         | '~' aexp                      { LL $ ELazyPat $2 }
1375         | aexp1                 { $1 }
1376
1377 aexp1   :: { LHsExpr RdrName }
1378         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1379                                       ; return (LL r) }}
1380         | aexp2                 { $1 }
1381
1382 -- Here was the syntax for type applications that I was planning
1383 -- but there are difficulties (e.g. what order for type args)
1384 -- so it's not enabled yet.
1385 -- But this case *is* used for the left hand side of a generic definition,
1386 -- which is parsed as an expression before being munged into a pattern
1387         | qcname '{|' gentype '|}'      { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1388                                                      (sL (getLoc $3) (HsType $3)) }
1389
1390 aexp2   :: { LHsExpr RdrName }
1391         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1392         | qcname                        { L1 (HsVar   $! unLoc $1) }
1393         | literal                       { L1 (HsLit   $! unLoc $1) }
1394 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1395 -- into HsOverLit when -foverloaded-strings is on.
1396 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1397         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1398         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1399         -- N.B.: sections get parsed by these next two productions.
1400         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't correct Haskell98
1401         -- (you'd have to write '((+ 3), (4 -))')
1402         -- but the less cluttered version fell out of having texps.
1403         | '(' texp ')'                  { LL (HsPar $2) }
1404         | '(' texp ',' texps ')'        { LL $ ExplicitTuple ($2 : reverse $4) Boxed }
1405         | '(#' texps '#)'               { LL $ ExplicitTuple (reverse $2)      Unboxed }
1406         | '[' list ']'                  { LL (unLoc $2) }
1407         | '[:' parr ':]'                { LL (unLoc $2) }
1408         | '_'                           { L1 EWildPat }
1409
1410         -- Template Haskell Extension
1411         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice
1412                                         (L1 $ HsVar (mkUnqual varName
1413                                                         (getTH_ID_SPLICE $1)))) } -- $x
1414         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               -- $( exp )
1415
1416         | TH_QUASIQUOTE         { let { loc = getLoc $1
1417                                       ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1418                                       ; quoterId = mkUnqual varName quoter
1419                                       }
1420                                   in sL loc $ HsQuasiQuoteE (mkHsQuasiQuote quoterId quoteSpan quote) }
1421         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1422         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1423         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1424         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1425         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }
1426         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }
1427         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1428                                         return (LL $ HsBracket (PatBr p)) }
1429         | '[d|' cvtopbody '|]'  {% checkDecBrGroup $2 >>= \g ->
1430                                         return (LL $ HsBracket (DecBr g)) }
1431
1432         -- arrow notation extension
1433         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1434
1435 cmdargs :: { [LHsCmdTop RdrName] }
1436         : cmdargs acmd                  { $2 : $1 }
1437         | {- empty -}                   { [] }
1438
1439 acmd    :: { LHsCmdTop RdrName }
1440         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1441
1442 cvtopbody :: { [LHsDecl RdrName] }
1443         :  '{'            cvtopdecls0 '}'               { $2 }
1444         |      vocurly    cvtopdecls0 close             { $2 }
1445
1446 cvtopdecls0 :: { [LHsDecl RdrName] }
1447         : {- empty -}           { [] }
1448         | cvtopdecls            { $1 }
1449
1450 -- "texp" is short for tuple expressions:
1451 -- things that can appear unparenthesized as long as they're
1452 -- inside parens or delimitted by commas
1453 texp :: { LHsExpr RdrName }
1454         : exp                           { $1 }
1455
1456         -- Note [Parsing sections]
1457         -- ~~~~~~~~~~~~~~~~~~~~~~~
1458         -- We include left and right sections here, which isn't
1459         -- technically right according to Haskell 98.  For example
1460         --      (3 +, True) isn't legal
1461         -- However, we want to parse bang patterns like
1462         --      (!x, !y)
1463         -- and it's convenient to do so here as a section
1464         -- Then when converting expr to pattern we unravel it again
1465         -- Meanwhile, the renamer checks that real sections appear
1466         -- inside parens.
1467         | infixexp qop  { LL $ SectionL $1 $2 }
1468         | qopm infixexp       { LL $ SectionR $1 $2 }
1469
1470        -- View patterns get parenthesized above
1471         | exp '->' exp   { LL $ EViewPat $1 $3 }
1472
1473 texps :: { [LHsExpr RdrName] }
1474         : texps ',' texp                { $3 : $1 }
1475         | texp                          { [$1] }
1476
1477
1478 -----------------------------------------------------------------------------
1479 -- List expressions
1480
1481 -- The rules below are little bit contorted to keep lexps left-recursive while
1482 -- avoiding another shift/reduce-conflict.
1483
1484 list :: { LHsExpr RdrName }
1485         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1486         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1487         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1488         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1489         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1490         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1491         | texp '|' flattenedpquals      { sL (comb2 $1 $>) $ mkHsDo ListComp (unLoc $3) $1 }
1492
1493 lexps :: { Located [LHsExpr RdrName] }
1494         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1495         | texp ',' texp                 { LL [$3,$1] }
1496
1497 -----------------------------------------------------------------------------
1498 -- List Comprehensions
1499
1500 flattenedpquals :: { Located [LStmt RdrName] }
1501     : pquals   { case (unLoc $1) of
1502                     ParStmt [(qs, _)] -> L1 qs
1503                     -- We just had one thing in our "parallel" list so
1504                     -- we simply return that thing directly
1505
1506                     _ -> L1 [$1]
1507                     -- We actually found some actual parallel lists so
1508                     -- we leave them into as a ParStmt
1509                 }
1510
1511 pquals :: { LStmt RdrName }
1512     : pquals1   { L1 (ParStmt [(qs, undefined) | qs <- (reverse (unLoc $1))]) }
1513
1514 pquals1 :: { Located [[LStmt RdrName]] }
1515     : pquals1 '|' squals    { LL (unLoc $3 : unLoc $1) }
1516     | squals                { L (getLoc $1) [unLoc $1] }
1517
1518 squals :: { Located [LStmt RdrName] }
1519     : squals1               { L (getLoc $1) (reverse (unLoc $1)) }
1520
1521 squals1 :: { Located [LStmt RdrName] }
1522     : transformquals1       { LL (unLoc $1) }
1523
1524 transformquals1 :: { Located [LStmt RdrName] }
1525     : transformquals1 ',' transformqual         { LL $ [LL ((unLoc $3) (unLoc $1))] }
1526     | transformquals1 ',' qual                  { LL ($3 : unLoc $1) }
1527 --  | transformquals1 ',' '{|' pquals '|}'      { LL ($4 : unLoc $1) }
1528     | transformqual                             { LL $ [LL ((unLoc $1) [])] }
1529     | qual                                      { L1 [$1] }
1530 --  | '{|' pquals '|}'                          { L1 [$2] }
1531
1532
1533 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1534 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1535 -- demand. Note that the {| |} symbols are reused from -XGenerics and hence if you want to compile
1536 -- a program that makes use of this temporary syntax you must supply that flag to GHC
1537
1538 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1539     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt (reverse leftStmts) $2) }
1540     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt (reverse leftStmts) $2 $4) }
1541     | 'then' 'group' 'by' exp              { LL $ \leftStmts -> (mkGroupByStmt (reverse leftStmts) $4) }
1542     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt (reverse leftStmts) $4) }
1543     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt (reverse leftStmts) $4 $6) }
1544
1545 -----------------------------------------------------------------------------
1546 -- Parallel array expressions
1547
1548 -- The rules below are little bit contorted; see the list case for details.
1549 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1550 -- Moreover, we allow explicit arrays with no element (represented by the nil
1551 -- constructor in the list case).
1552
1553 parr :: { LHsExpr RdrName }
1554         :                               { noLoc (ExplicitPArr placeHolderType []) }
1555         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1556         | lexps                         { L1 $ ExplicitPArr placeHolderType
1557                                                        (reverse (unLoc $1)) }
1558         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1559         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1560         | texp '|' flattenedpquals      { LL $ mkHsDo PArrComp (unLoc $3) $1 }
1561
1562 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1563
1564 -----------------------------------------------------------------------------
1565 -- Guards
1566
1567 guardquals :: { Located [LStmt RdrName] }
1568     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1569
1570 guardquals1 :: { Located [LStmt RdrName] }
1571     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1572     | qual                  { L1 [$1] }
1573
1574 -----------------------------------------------------------------------------
1575 -- Case alternatives
1576
1577 altslist :: { Located [LMatch RdrName] }
1578         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1579         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1580
1581 alts    :: { Located [LMatch RdrName] }
1582         : alts1                         { L1 (unLoc $1) }
1583         | ';' alts                      { LL (unLoc $2) }
1584
1585 alts1   :: { Located [LMatch RdrName] }
1586         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1587         | alts1 ';'                     { LL (unLoc $1) }
1588         | alt                           { L1 [$1] }
1589
1590 alt     :: { LMatch RdrName }
1591         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1592
1593 alt_rhs :: { Located (GRHSs RdrName) }
1594         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1595
1596 ralt :: { Located [LGRHS RdrName] }
1597         : '->' exp                      { LL (unguardedRHS $2) }
1598         | gdpats                        { L1 (reverse (unLoc $1)) }
1599
1600 gdpats :: { Located [LGRHS RdrName] }
1601         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1602         | gdpat                         { L1 [$1] }
1603
1604 gdpat   :: { LGRHS RdrName }
1605         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1606
1607 -- 'pat' recognises a pattern, including one with a bang at the top
1608 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1609 -- Bangs inside are parsed as infix operator applications, so that
1610 -- we parse them right when bang-patterns are off
1611 pat     :: { LPat RdrName }
1612 pat     :  exp                  {% checkPattern $1 }
1613         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1614
1615 apat   :: { LPat RdrName }
1616 apat    : aexp                  {% checkPattern $1 }
1617         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1618
1619 apats  :: { [LPat RdrName] }
1620         : apat apats            { $1 : $2 }
1621         | {- empty -}           { [] }
1622
1623 -----------------------------------------------------------------------------
1624 -- Statement sequences
1625
1626 stmtlist :: { Located [LStmt RdrName] }
1627         : '{'           stmts '}'       { LL (unLoc $2) }
1628         |     vocurly   stmts close     { $2 }
1629
1630 --      do { ;; s ; s ; ; s ;; }
1631 -- The last Stmt should be an expression, but that's hard to enforce
1632 -- here, because we need too much lookahead if we see do { e ; }
1633 -- So we use ExprStmts throughout, and switch the last one over
1634 -- in ParseUtils.checkDo instead
1635 stmts :: { Located [LStmt RdrName] }
1636         : stmt stmts_help               { LL ($1 : unLoc $2) }
1637         | ';' stmts                     { LL (unLoc $2) }
1638         | {- empty -}                   { noLoc [] }
1639
1640 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1641         : ';' stmts                     { LL (unLoc $2) }
1642         | {- empty -}                   { noLoc [] }
1643
1644 -- For typing stmts at the GHCi prompt, where
1645 -- the input may consist of just comments.
1646 maybe_stmt :: { Maybe (LStmt RdrName) }
1647         : stmt                          { Just $1 }
1648         | {- nothing -}                 { Nothing }
1649
1650 stmt  :: { LStmt RdrName }
1651         : qual                              { $1 }
1652         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1653
1654 qual  :: { LStmt RdrName }
1655     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1656     | exp                                   { L1 $ mkExprStmt $1 }
1657     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1658
1659 -----------------------------------------------------------------------------
1660 -- Record Field Update/Construction
1661
1662 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1663         : fbinds1                       { $1 }
1664         | {- empty -}                   { ([], False) }
1665
1666 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1667         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) }
1668         | fbind                         { ([$1], False) }
1669         | '..'                          { ([],   True) }
1670
1671 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1672         : qvar '=' exp  { HsRecField $1 $3 False }
1673         | qvar          { HsRecField $1 (L (getLoc $1) (HsVar (unLoc $1))) True }
1674                         -- Here's where we say that plain 'x'
1675                         -- means exactly 'x = x'.  The pun-flag boolean is
1676                         -- there so we can still print it right
1677
1678 -----------------------------------------------------------------------------
1679 -- Implicit Parameter Bindings
1680
1681 dbinds  :: { Located [LIPBind RdrName] }
1682         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1683                               in rest `seq` this `seq` LL (this : rest) }
1684         | dbinds ';'                    { LL (unLoc $1) }
1685         | dbind                         { let this = $1 in this `seq` L1 [this] }
1686 --      | {- empty -}                   { [] }
1687
1688 dbind   :: { LIPBind RdrName }
1689 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1690
1691 ipvar   :: { Located (IPName RdrName) }
1692         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1693
1694 -----------------------------------------------------------------------------
1695 -- Warnings and deprecations
1696
1697 namelist :: { Located [RdrName] }
1698 namelist : name_var              { L1 [unLoc $1] }
1699          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1700
1701 name_var :: { Located RdrName }
1702 name_var : var { $1 }
1703          | con { $1 }
1704
1705 -----------------------------------------
1706 -- Data constructors
1707 qcon    :: { Located RdrName }
1708         : qconid                { $1 }
1709         | '(' qconsym ')'       { LL (unLoc $2) }
1710         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1711 -- The case of '[:' ':]' is part of the production `parr'
1712
1713 con     :: { Located RdrName }
1714         : conid                 { $1 }
1715         | '(' consym ')'        { LL (unLoc $2) }
1716         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1717
1718 sysdcon :: { Located DataCon }  -- Wired in data constructors
1719         : '(' ')'               { LL unitDataCon }
1720         | '(' commas ')'        { LL $ tupleCon Boxed $2 }
1721         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1722         | '(#' commas '#)'      { LL $ tupleCon Unboxed $2 }
1723         | '[' ']'               { LL nilDataCon }
1724
1725 conop :: { Located RdrName }
1726         : consym                { $1 }
1727         | '`' conid '`'         { LL (unLoc $2) }
1728
1729 qconop :: { Located RdrName }
1730         : qconsym               { $1 }
1731         | '`' qconid '`'        { LL (unLoc $2) }
1732
1733 -----------------------------------------------------------------------------
1734 -- Type constructors
1735
1736 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1737         : oqtycon                       { $1 }
1738         | '(' ')'                       { LL $ getRdrName unitTyCon }
1739         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed $2) }
1740         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1741         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed $2) }
1742         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1743         | '[' ']'                       { LL $ listTyCon_RDR }
1744         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1745
1746 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1747         : qtycon                        { $1 }
1748         | '(' qtyconsym ')'             { LL (unLoc $2) }
1749
1750 qtyconop :: { Located RdrName } -- Qualified or unqualified
1751         : qtyconsym                     { $1 }
1752         | '`' qtycon '`'                { LL (unLoc $2) }
1753
1754 qtycon :: { Located RdrName }   -- Qualified or unqualified
1755         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1756         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1757         | tycon                         { $1 }
1758
1759 tycon   :: { Located RdrName }  -- Unqualified
1760         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1761
1762 qtyconsym :: { Located RdrName }
1763         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1764         | tyconsym                      { $1 }
1765
1766 tyconsym :: { Located RdrName }
1767         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1768
1769 -----------------------------------------------------------------------------
1770 -- Operators
1771
1772 op      :: { Located RdrName }   -- used in infix decls
1773         : varop                 { $1 }
1774         | conop                 { $1 }
1775
1776 varop   :: { Located RdrName }
1777         : varsym                { $1 }
1778         | '`' varid '`'         { LL (unLoc $2) }
1779
1780 qop     :: { LHsExpr RdrName }   -- used in sections
1781         : qvarop                { L1 $ HsVar (unLoc $1) }
1782         | qconop                { L1 $ HsVar (unLoc $1) }
1783
1784 qopm    :: { LHsExpr RdrName }   -- used in sections
1785         : qvaropm               { L1 $ HsVar (unLoc $1) }
1786         | qconop                { L1 $ HsVar (unLoc $1) }
1787
1788 qvarop :: { Located RdrName }
1789         : qvarsym               { $1 }
1790         | '`' qvarid '`'        { LL (unLoc $2) }
1791
1792 qvaropm :: { Located RdrName }
1793         : qvarsym_no_minus      { $1 }
1794         | '`' qvarid '`'        { LL (unLoc $2) }
1795
1796 -----------------------------------------------------------------------------
1797 -- Type variables
1798
1799 tyvar   :: { Located RdrName }
1800 tyvar   : tyvarid               { $1 }
1801         | '(' tyvarsym ')'      { LL (unLoc $2) }
1802
1803 tyvarop :: { Located RdrName }
1804 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1805         | tyvarsym              { $1 }
1806
1807 tyvarid :: { Located RdrName }
1808         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1809         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1810         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1811         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1812         | 'threadsafe'          { L1 $! mkUnqual tvName (fsLit "threadsafe") }
1813
1814 tyvarsym :: { Located RdrName }
1815 -- Does not include "!", because that is used for strictness marks
1816 --               or ".", because that separates the quantified type vars from the rest
1817 --               or "*", because that's used for kinds
1818 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1819
1820 -----------------------------------------------------------------------------
1821 -- Variables
1822
1823 var     :: { Located RdrName }
1824         : varid                 { $1 }
1825         | '(' varsym ')'        { LL (unLoc $2) }
1826
1827 qvar    :: { Located RdrName }
1828         : qvarid                { $1 }
1829         | '(' varsym ')'        { LL (unLoc $2) }
1830         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1831 -- We've inlined qvarsym here so that the decision about
1832 -- whether it's a qvar or a var can be postponed until
1833 -- *after* we see the close paren.
1834
1835 qvarid :: { Located RdrName }
1836         : varid                 { $1 }
1837         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1838         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1839
1840 varid :: { Located RdrName }
1841         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1842         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1843         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1844         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1845         | 'threadsafe'          { L1 $! mkUnqual varName (fsLit "threadsafe") }
1846         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1847         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1848
1849 qvarsym :: { Located RdrName }
1850         : varsym                { $1 }
1851         | qvarsym1              { $1 }
1852
1853 qvarsym_no_minus :: { Located RdrName }
1854         : varsym_no_minus       { $1 }
1855         | qvarsym1              { $1 }
1856
1857 qvarsym1 :: { Located RdrName }
1858 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1859
1860 varsym :: { Located RdrName }
1861         : varsym_no_minus       { $1 }
1862         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1863
1864 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1865         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1866         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1867
1868
1869 -- These special_ids are treated as keywords in various places,
1870 -- but as ordinary ids elsewhere.   'special_id' collects all these
1871 -- except 'unsafe', 'forall', and 'family' whose treatment differs
1872 -- depending on context
1873 special_id :: { Located FastString }
1874 special_id
1875         : 'as'                  { L1 (fsLit "as") }
1876         | 'qualified'           { L1 (fsLit "qualified") }
1877         | 'hiding'              { L1 (fsLit "hiding") }
1878         | 'export'              { L1 (fsLit "export") }
1879         | 'label'               { L1 (fsLit "label")  }
1880         | 'dynamic'             { L1 (fsLit "dynamic") }
1881         | 'stdcall'             { L1 (fsLit "stdcall") }
1882         | 'ccall'               { L1 (fsLit "ccall") }
1883
1884 special_sym :: { Located FastString }
1885 special_sym : '!'       { L1 (fsLit "!") }
1886             | '.'       { L1 (fsLit ".") }
1887             | '*'       { L1 (fsLit "*") }
1888
1889 -----------------------------------------------------------------------------
1890 -- Data constructors
1891
1892 qconid :: { Located RdrName }   -- Qualified or unqualified
1893         : conid                 { $1 }
1894         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1895         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1896
1897 conid   :: { Located RdrName }
1898         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1899
1900 qconsym :: { Located RdrName }  -- Qualified or unqualified
1901         : consym                { $1 }
1902         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1903
1904 consym :: { Located RdrName }
1905         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1906
1907         -- ':' means only list cons
1908         | ':'                   { L1 $ consDataCon_RDR }
1909
1910
1911 -----------------------------------------------------------------------------
1912 -- Literals
1913
1914 literal :: { Located HsLit }
1915         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1916         | STRING                { L1 $ HsString     $ getSTRING $1 }
1917         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1918         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1919         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1920         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1921         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1922         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1923
1924 -----------------------------------------------------------------------------
1925 -- Layout
1926
1927 close :: { () }
1928         : vccurly               { () } -- context popped in lexer.
1929         | error                 {% popContext }
1930
1931 -----------------------------------------------------------------------------
1932 -- Miscellaneous (mostly renamings)
1933
1934 modid   :: { Located ModuleName }
1935         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1936         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1937                                   mkModuleNameFS
1938                                    (mkFastString
1939                                      (unpackFS mod ++ '.':unpackFS c))
1940                                 }
1941
1942 commas :: { Int }
1943         : commas ','                    { $1 + 1 }
1944         | ','                           { 2 }
1945
1946 -----------------------------------------------------------------------------
1947 -- Documentation comments
1948
1949 docnext :: { LHsDoc RdrName }
1950   : DOCNEXT {% case parseHaddockParagraphs (tokenise (getDOCNEXT $1)) of {
1951       MyLeft  err -> parseError (getLoc $1) err;
1952       MyRight doc -> return (L1 doc) } }
1953
1954 docprev :: { LHsDoc RdrName }
1955   : DOCPREV {% case parseHaddockParagraphs (tokenise (getDOCPREV $1)) of {
1956       MyLeft  err -> parseError (getLoc $1) err;
1957       MyRight doc -> return (L1 doc) } }
1958
1959 docnamed :: { Located (String, (HsDoc RdrName)) }
1960   : DOCNAMED {%
1961       let string = getDOCNAMED $1
1962           (name, rest) = break isSpace string
1963       in case parseHaddockParagraphs (tokenise rest) of {
1964         MyLeft  err -> parseError (getLoc $1) err;
1965         MyRight doc -> return (L1 (name, doc)) } }
1966
1967 docsection :: { Located (Int, HsDoc RdrName) }
1968   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1969         case parseHaddockString (tokenise doc) of {
1970       MyLeft  err -> parseError (getLoc $1) err;
1971       MyRight doc -> return (L1 (n, doc)) } }
1972
1973 moduleheader :: { (HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }
1974         : DOCNEXT {% let string = getDOCNEXT $1 in
1975                case parseModuleHeader string of {
1976                  Right (str, info) ->
1977                    case parseHaddockParagraphs (tokenise str) of {
1978                      MyLeft err -> parseError (getLoc $1) err;
1979                      MyRight doc -> return (info, Just doc);
1980                    };
1981                  Left err -> parseError (getLoc $1) err
1982             }  }
1983
1984 maybe_docprev :: { Maybe (LHsDoc RdrName) }
1985         : docprev                       { Just $1 }
1986         | {- empty -}                   { Nothing }
1987
1988 maybe_docnext :: { Maybe (LHsDoc RdrName) }
1989         : docnext                       { Just $1 }
1990         | {- empty -}                   { Nothing }
1991
1992 {
1993 happyError :: P a
1994 happyError = srcParseFail
1995
1996 getVARID        (L _ (ITvarid    x)) = x
1997 getCONID        (L _ (ITconid    x)) = x
1998 getVARSYM       (L _ (ITvarsym   x)) = x
1999 getCONSYM       (L _ (ITconsym   x)) = x
2000 getQVARID       (L _ (ITqvarid   x)) = x
2001 getQCONID       (L _ (ITqconid   x)) = x
2002 getQVARSYM      (L _ (ITqvarsym  x)) = x
2003 getQCONSYM      (L _ (ITqconsym  x)) = x
2004 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
2005 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
2006 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
2007 getCHAR         (L _ (ITchar     x)) = x
2008 getSTRING       (L _ (ITstring   x)) = x
2009 getINTEGER      (L _ (ITinteger  x)) = x
2010 getRATIONAL     (L _ (ITrational x)) = x
2011 getPRIMCHAR     (L _ (ITprimchar   x)) = x
2012 getPRIMSTRING   (L _ (ITprimstring x)) = x
2013 getPRIMINTEGER  (L _ (ITprimint    x)) = x
2014 getPRIMWORD     (L _ (ITprimword x)) = x
2015 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
2016 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
2017 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
2018 getINLINE       (L _ (ITinline_prag b)) = b
2019 getINLINE_CONLIKE (L _ (ITinline_conlike_prag b)) = b
2020 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
2021
2022 getDOCNEXT (L _ (ITdocCommentNext x)) = x
2023 getDOCPREV (L _ (ITdocCommentPrev x)) = x
2024 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
2025 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
2026
2027 getSCC :: Located Token -> P FastString
2028 getSCC lt = do let s = getSTRING lt
2029                    err = "Spaces are not allowed in SCCs"
2030                -- We probably actually want to be more restrictive than this
2031                if ' ' `elem` unpackFS s
2032                    then failSpanMsgP (getLoc lt) (text err)
2033                    else return s
2034
2035 -- Utilities for combining source spans
2036 comb2 :: Located a -> Located b -> SrcSpan
2037 comb2 a b = a `seq` b `seq` combineLocs a b
2038
2039 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2040 comb3 a b c = a `seq` b `seq` c `seq`
2041     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2042
2043 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2044 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2045     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2046                 combineSrcSpans (getLoc c) (getLoc d))
2047
2048 -- strict constructor version:
2049 {-# INLINE sL #-}
2050 sL :: SrcSpan -> a -> Located a
2051 sL span a = span `seq` a `seq` L span a
2052
2053 -- Make a source location for the file.  We're a bit lazy here and just
2054 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2055 -- try to find the span of the whole file (ToDo).
2056 fileSrcSpan :: P SrcSpan
2057 fileSrcSpan = do
2058   l <- getSrcLoc;
2059   let loc = mkSrcLoc (srcLocFile l) 1 0;
2060   return (mkSrcSpan loc loc)
2061 }