compiler/profiling/SCCfinal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SCCfinal]{Modify and collect code generation for final STG program}
   5
   6 This is now a sort-of-normal STG-to-STG pass (WDP 94/06), run by stg2stg.
   7
   8 * Traverses the STG program collecting the cost centres. These are
   9   required to declare the cost centres at the start of code
  10   generation.
  11
  12   Note: because of cross-module unfolding, some of these cost centres
  13   may be from other modules.  But will still have to give them
  14   "extern" declarations.
  15
  16 * Puts on CAF cost-centres if the user has asked for individual CAF
  17   cost-centres.
  18
  19 * Ditto for individual DICT cost-centres.
  20
  21 * Boxes top-level inherited functions passed as arguments.
  22
  23 * "Distributes" given cost-centres to all as-yet-unmarked RHSs.
  24
  25 \begin{code}
  26 module SCCfinal ( stgMassageForProfiling ) where
  27
  28 #include "HsVersions.h"
  29
  30 import StgSyn
  31
  32 import PackageConfig    ( PackageId )
  33 import StaticFlags      ( opt_AutoSccsOnIndividualCafs )
  34 import CostCentre       -- lots of things
  35 import Id               ( Id )
  36 import Module           ( Module )
  37 import UniqSupply       ( splitUniqSupply, UniqSupply )
  38 #ifdef PROF_DO_BOXING
  39 import UniqSupply       ( uniqFromSupply )
  40 #endif
  41 import Unique           ( Unique )
  42 import VarSet
  43 import ListSetOps       ( removeDups )
  44 import Outputable
  45
  46 infixr 9 `thenMM`, `thenMM_`
  47 \end{code}
  48
  49 \begin{code}
  50 stgMassageForProfiling
  51         :: PackageId
  52         -> Module                       -- module name
  53         -> UniqSupply                   -- unique supply
  54         -> [StgBinding]                 -- input
  55         -> (CollectedCCs, [StgBinding])
  56
  57 stgMassageForProfiling this_pkg mod_name us stg_binds
  58   = let
  59         ((local_ccs, extern_ccs, cc_stacks),
  60          stg_binds2)
  61           = initMM mod_name us (do_top_bindings stg_binds)
  62
  63         (fixed_ccs, fixed_cc_stacks)
  64           = if opt_AutoSccsOnIndividualCafs
  65             then ([],[])  -- don't need "all CAFs" CC
  66                           -- (for Prelude, we use PreludeCC)
  67             else ([all_cafs_cc], [all_cafs_ccs])
  68
  69         local_ccs_no_dups  = fst (removeDups cmpCostCentre local_ccs)
  70         extern_ccs_no_dups = fst (removeDups cmpCostCentre extern_ccs)
  71     in
  72     ((fixed_ccs ++ local_ccs_no_dups,
  73       extern_ccs_no_dups,
  74       fixed_cc_stacks ++ cc_stacks), stg_binds2)
  75   where
  76
  77     all_cafs_cc  = mkAllCafsCC mod_name
  78     all_cafs_ccs = mkSingletonCCS all_cafs_cc
  79
  80     ----------
  81     do_top_bindings :: [StgBinding] -> MassageM [StgBinding]
  82
  83     do_top_bindings [] = returnMM []
  84
  85     do_top_bindings (StgNonRec b rhs : bs)
  86       = do_top_rhs b rhs                `thenMM` \ rhs' ->
  87         addTopLevelIshId b (
  88            do_top_bindings bs `thenMM` \bs' ->
  89            returnMM (StgNonRec b rhs' : bs')
  90         )
  91
  92     do_top_bindings (StgRec pairs : bs)
  93       = addTopLevelIshIds binders (
  94            mapMM do_pair pairs          `thenMM` \ pairs2 ->
  95            do_top_bindings bs `thenMM` \ bs' ->
  96            returnMM (StgRec pairs2 : bs')
  97         )
  98       where
  99         binders = map fst pairs
 100         do_pair (b, rhs)
 101            = do_top_rhs b rhs   `thenMM` \ rhs2 ->
 102              returnMM (b, rhs2)
 103
 104     ----------
 105     do_top_rhs :: Id -> StgRhs -> MassageM StgRhs
 106
 107     do_top_rhs binder (StgRhsClosure _ bi fv u srt [] (StgSCC cc (StgConApp con args)))
 108       | not (isSccCountCostCentre cc) && not (isDllConApp this_pkg con args)
 109         -- Trivial _scc_ around nothing but static data
 110         -- Eliminate _scc_ ... and turn into StgRhsCon
 111
 112         -- isDllConApp checks for LitLit args too
 113       = returnMM (StgRhsCon dontCareCCS con args)
 114
 115 {- Can't do this one with cost-centre stacks:  --SDM
 116     do_top_rhs binder (StgRhsClosure no_cc bi fv u [] (StgSCC ty cc expr))
 117       | (noCCSAttached no_cc || currentOrSubsumedCCS no_cc)
 118         && not (isSccCountCostCentre cc)
 119         -- Top level CAF without a cost centre attached
 120         -- Attach and collect cc of trivial _scc_ in body
 121       = collectCC cc                                    `thenMM_`
 122         set_prevailing_cc cc (do_expr expr)             `thenMM`  \ expr' ->
 123         returnMM (StgRhsClosure cc bi fv u [] expr')
 124 -}
 125
 126     do_top_rhs binder (StgRhsClosure no_cc bi fv u srt [] body)
 127       | noCCSAttached no_cc || currentOrSubsumedCCS no_cc
 128         -- Top level CAF without a cost centre attached
 129         -- Attach CAF cc (collect if individual CAF ccs)
 130       = (if opt_AutoSccsOnIndividualCafs
 131                 then let cc = mkAutoCC binder mod_name CafCC
 132                          ccs = mkSingletonCCS cc
 133                      in
 134                      collectCC  cc  `thenMM_`
 135                      collectCCS ccs `thenMM_`
 136                      returnMM ccs
 137                 else
 138                      returnMM all_cafs_ccs)             `thenMM`  \ caf_ccs ->
 139            set_prevailing_cc caf_ccs (do_expr body)     `thenMM`  \ body' ->
 140            returnMM (StgRhsClosure caf_ccs bi fv u srt [] body')
 141
 142     do_top_rhs binder (StgRhsClosure cc bi fv u srt [] body)
 143         -- Top level CAF with cost centre attached
 144         -- Should this be a CAF cc ??? Does this ever occur ???
 145       = pprPanic "SCCfinal: CAF with cc:" (ppr cc)
 146
 147     do_top_rhs binder (StgRhsClosure no_ccs bi fv u srt args body)
 148         -- Top level function, probably subsumed
 149       | noCCSAttached no_ccs
 150       = set_lambda_cc (do_expr body)    `thenMM` \ body' ->
 151         returnMM (StgRhsClosure subsumedCCS bi fv u srt args body')
 152
 153       | otherwise
 154       = pprPanic "SCCfinal: CAF with cc:" (ppr no_ccs)
 155
 156     do_top_rhs binder (StgRhsCon ccs con args)
 157         -- Top-level (static) data is not counted in heap
 158         -- profiles; nor do we set CCCS from it; so we
 159         -- just slam in dontCareCostCentre
 160       = returnMM (StgRhsCon dontCareCCS con args)
 161
 162     ------
 163     do_expr :: StgExpr -> MassageM StgExpr
 164
 165     do_expr (StgLit l) = returnMM (StgLit l)
 166
 167     do_expr (StgApp fn args)
 168       = boxHigherOrderArgs (StgApp fn) args
 169
 170     do_expr (StgConApp con args)
 171       = boxHigherOrderArgs (\args -> StgConApp con args) args
 172
 173     do_expr (StgOpApp con args res_ty)
 174       = boxHigherOrderArgs (\args -> StgOpApp con args res_ty) args
 175
 176     do_expr (StgSCC cc expr)    -- Ha, we found a cost centre!
 177       = collectCC cc            `thenMM_`
 178         do_expr expr            `thenMM` \ expr' ->
 179         returnMM (StgSCC cc expr')
 180
 181     do_expr (StgCase expr fv1 fv2 bndr srt alt_type alts)
 182       = do_expr expr            `thenMM` \ expr' ->
 183         mapMM do_alt alts       `thenMM` \ alts' ->
 184         returnMM (StgCase expr' fv1 fv2 bndr srt alt_type alts')
 185       where
 186         do_alt (id, bs, use_mask, e)
 187           = do_expr e `thenMM` \ e' ->
 188             returnMM (id, bs, use_mask, e')
 189
 190     do_expr (StgLet b e)
 191         = do_let b e `thenMM` \ (b,e) ->
 192           returnMM (StgLet b e)
 193
 194     do_expr (StgLetNoEscape lvs1 lvs2 b e)
 195         = do_let b e `thenMM` \ (b,e) ->
 196           returnMM (StgLetNoEscape lvs1 lvs2 b e)
 197
 198     do_expr (StgTick m n expr)
 199         = do_expr expr `thenMM` \ expr' ->
 200           returnMM (StgTick m n expr')
 201
 202 #ifdef DEBUG
 203     do_expr other = pprPanic "SCCfinal.do_expr" (ppr other)
 204 #endif
 205
 206     ----------------------------------
 207
 208     do_let (StgNonRec b rhs) e
 209       = do_rhs rhs                      `thenMM` \ rhs' ->
 210         addTopLevelIshId b (
 211           do_expr e                     `thenMM` \ e' ->
 212           returnMM (StgNonRec b rhs',e')
 213         )
 214
 215     do_let (StgRec pairs) e
 216       = addTopLevelIshIds binders (
 217            mapMM do_pair pairs          `thenMM` \ pairs' ->
 218            do_expr e                    `thenMM` \ e' ->
 219            returnMM (StgRec pairs', e')
 220         )
 221       where
 222         binders = map fst pairs
 223         do_pair (b, rhs)
 224            = do_rhs rhs                 `thenMM` \ rhs2 ->
 225              returnMM (b, rhs2)
 226
 227     ----------------------------------
 228     do_rhs :: StgRhs -> MassageM StgRhs
 229         -- We play much the same game as we did in do_top_rhs above;
 230         -- but we don't have to worry about cafs etc.
 231
 232 {-
 233     do_rhs (StgRhsClosure closure_cc bi fv u [] (StgSCC ty cc (StgCon (DataCon con) args _)))
 234       | not (isSccCountCostCentre cc)
 235       = collectCC cc `thenMM_`
 236         returnMM (StgRhsCon cc con args)
 237 -}
 238
 239     do_rhs (StgRhsClosure _ bi fv u srt args expr)
 240       = slurpSCCs currentCCS expr       `thenMM` \ (expr', ccs) ->
 241         do_expr expr'                   `thenMM` \ expr'' ->
 242         returnMM (StgRhsClosure ccs bi fv u srt args expr'')
 243       where
 244         slurpSCCs ccs (StgSCC cc e)
 245              = collectCC cc                     `thenMM_`
 246                slurpSCCs (cc `pushCCOnCCS` ccs) e
 247         slurpSCCs ccs e
 248              = returnMM (e, ccs)
 249
 250     do_rhs (StgRhsCon cc con args)
 251       = returnMM (StgRhsCon currentCCS con args)
 252 \end{code}
 253
 254 %************************************************************************
 255 %*                                                                      *
 256 \subsection{Boxing higher-order args}
 257 %*                                                                      *
 258 %************************************************************************
 259
 260 Boxing is *turned off* at the moment, until we can figure out how to
 261 do it properly in general.
 262
 263 \begin{code}
 264 boxHigherOrderArgs
 265     :: ([StgArg] -> StgExpr)
 266                         -- An application lacking its arguments
 267     -> [StgArg]         -- arguments which we might box
 268     -> MassageM StgExpr
 269
 270 #ifndef PROF_DO_BOXING
 271 boxHigherOrderArgs almost_expr args
 272    = returnMM (almost_expr args)
 273 #else
 274 boxHigherOrderArgs almost_expr args
 275   = getTopLevelIshIds           `thenMM` \ ids ->
 276     mapAccumMM (do_arg ids) [] args     `thenMM` \ (let_bindings, new_args) ->
 277     returnMM (foldr (mk_stg_let currentCCS) (almost_expr new_args) let_bindings)
 278   where
 279     ---------------
 280
 281     do_arg ids bindings arg@(StgVarArg old_var)
 282         |  (not (isLocalVar old_var) || elemVarSet old_var ids)
 283         && isFunTy (dropForAlls var_type)
 284       =     -- make a trivial let-binding for the top-level function
 285         getUniqueMM             `thenMM` \ uniq ->
 286         let
 287             new_var = mkSysLocal FSLIT("sf") uniq var_type
 288         in
 289         returnMM ( (new_var, old_var) : bindings, StgVarArg new_var )
 290       where
 291         var_type = idType old_var
 292
 293     do_arg ids bindings arg = returnMM (bindings, arg)
 294
 295     ---------------
 296     mk_stg_let :: CostCentreStack -> (Id, Id) -> StgExpr -> StgExpr
 297
 298     mk_stg_let cc (new_var, old_var) body
 299       = let
 300             rhs_body    = StgApp old_var [{-args-}]
 301             rhs_closure = StgRhsClosure cc stgArgOcc [{-fvs-}] ReEntrant NoSRT{-eeek!!!-} [{-args-}] rhs_body
 302         in
 303         StgLet (StgNonRec new_var rhs_closure) body
 304       where
 305         bOGUS_LVs = emptyUniqSet -- easier to print than: panic "mk_stg_let: LVs"
 306 #endif
 307 \end{code}
 308
 309 %************************************************************************
 310 %*                                                                      *
 311 \subsection{Boring monad stuff for this}
 312 %*                                                                      *
 313 %************************************************************************
 314
 315 \begin{code}
 316 type MassageM result
 317   =  Module             -- module name
 318   -> CostCentreStack    -- prevailing CostCentre
 319                         -- if none, subsumedCosts at top-level
 320                         -- currentCostCentre at nested levels
 321   -> UniqSupply
 322   -> VarSet             -- toplevel-ish Ids for boxing
 323   -> CollectedCCs
 324   -> (CollectedCCs, result)
 325
 326 -- the initMM function also returns the final CollectedCCs
 327
 328 initMM :: Module        -- module name, which we may consult
 329        -> UniqSupply
 330        -> MassageM a
 331        -> (CollectedCCs, a)
 332
 333 initMM mod_name init_us m = m mod_name noCCS init_us emptyVarSet ([],[],[])
 334
 335 thenMM  :: MassageM a -> (a -> MassageM b) -> MassageM b
 336 thenMM_ :: MassageM a -> (MassageM b) -> MassageM b
 337
 338 thenMM expr cont mod scope_cc us ids ccs
 339   = case splitUniqSupply us     of { (s1, s2) ->
 340     case (expr mod scope_cc s1 ids ccs) of { (ccs2, result) ->
 341     cont result mod scope_cc s2 ids ccs2 }}
 342
 343 thenMM_ expr cont mod scope_cc us ids ccs
 344   = case splitUniqSupply us     of { (s1, s2) ->
 345     case (expr mod scope_cc s1 ids ccs) of { (ccs2, _) ->
 346     cont mod scope_cc s2 ids ccs2 }}
 347
 348 returnMM :: a -> MassageM a
 349 returnMM result mod scope_cc us ids ccs = (ccs, result)
 350
 351 nopMM :: MassageM ()
 352 nopMM mod scope_cc us ids ccs = (ccs, ())
 353
 354 mapMM :: (a -> MassageM b) -> [a] -> MassageM [b]
 355 mapMM f [] = returnMM []
 356 mapMM f (m:ms)
 357   = f m         `thenMM` \ r  ->
 358     mapMM f ms  `thenMM` \ rs ->
 359     returnMM (r:rs)
 360
 361 mapAccumMM :: (acc -> x -> MassageM (acc, y)) -> acc -> [x] -> MassageM (acc, [y])
 362 mapAccumMM f b [] = returnMM (b, [])
 363 mapAccumMM f b (m:ms)
 364   = f b m               `thenMM` \ (b2, r)  ->
 365     mapAccumMM f b2 ms  `thenMM` \ (b3, rs) ->
 366     returnMM (b3, r:rs)
 367
 368 #ifdef PROF_DO_BOXING
 369 getUniqueMM :: MassageM Unique
 370 getUniqueMM mod scope_cc us ids ccs = (ccs, uniqFromSupply us)
 371 #endif
 372
 373 addTopLevelIshId :: Id -> MassageM a -> MassageM a
 374 addTopLevelIshId id scope mod scope_cc us ids ccs
 375   | isCurrentCCS scope_cc = scope mod scope_cc us ids ccs
 376   | otherwise             = scope mod scope_cc us (extendVarSet ids id) ccs
 377
 378 addTopLevelIshIds :: [Id] -> MassageM a -> MassageM a
 379 addTopLevelIshIds [] cont = cont
 380 addTopLevelIshIds (id:ids) cont
 381   = addTopLevelIshId id (addTopLevelIshIds ids cont)
 382
 383 getTopLevelIshIds :: MassageM VarSet
 384 getTopLevelIshIds mod scope_cc us ids ccs = (ccs, ids)
 385 \end{code}
 386
 387 The prevailing CCS is used to tell whether we're in a top-levelish
 388 position, where top-levelish is defined as "not inside a lambda".
 389 Prevailing CCs used to be used for something much more complicated,
 390 I'm sure --SDM
 391
 392 \begin{code}
 393 set_lambda_cc :: MassageM a -> MassageM a
 394 set_lambda_cc action mod scope_cc us ids ccs
 395   = action mod currentCCS us ids ccs
 396
 397 set_prevailing_cc :: CostCentreStack -> MassageM a -> MassageM a
 398 set_prevailing_cc cc_to_set_to action mod scope_cc us ids ccs
 399   = action mod cc_to_set_to us ids ccs
 400
 401 get_prevailing_cc :: MassageM CostCentreStack
 402 get_prevailing_cc mod scope_cc us ids ccs = (ccs, scope_cc)
 403 \end{code}
 404
 405 \begin{code}
 406 collectCC :: CostCentre -> MassageM ()
 407
 408 collectCC cc mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 409   = ASSERT(not (noCCAttached cc))
 410     if (cc `ccFromThisModule` mod_name) then
 411         ((cc : local_ccs, extern_ccs, ccss), ())
 412     else -- must declare it "extern"
 413         ((local_ccs, cc : extern_ccs, ccss), ())
 414
 415 collectCCS :: CostCentreStack -> MassageM ()
 416
 417 collectCCS ccs mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 418   = ASSERT(not (noCCSAttached ccs))
 419     ((local_ccs, extern_ccs, ccs : ccss), ())
 420 \end{code}