compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPats, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import DynFlags ( DynFlag(..) )
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import RdrName          ( RdrName, rdrNameOcc )
  36 import SrcLoc
  37 import ListSetOps       ( findDupsEq )
  38 import BasicTypes       ( RecFlag(..) )
  39 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  40 import Bag
  41 import Outputable
  42 import FastString
  43 import Data.List        ( partition )
  44 import Maybes           ( orElse )
  45 import Control.Monad
  46 \end{code}
  47
  48 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  49 -- place and can be used when complaining.
  50
  51 The code tree received by the function @rnBinds@ contains definitions
  52 in where-clauses which are all apparently mutually recursive, but which may
  53 not really depend upon each other. For example, in the top level program
  54 \begin{verbatim}
  55 f x = y where a = x
  56               y = x
  57 \end{verbatim}
  58 the definitions of @a@ and @y@ do not depend on each other at all.
  59 Unfortunately, the typechecker cannot always check such definitions.
  60 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  61 definitions. In Proceedings of the International Symposium on Programming,
  62 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  63 However, the typechecker usually can check definitions in which only the
  64 strongly connected components have been collected into recursive bindings.
  65 This is precisely what the function @rnBinds@ does.
  66
  67 ToDo: deal with case where a single monobinds binds the same variable
  68 twice.
  69
  70 The vertag tag is a unique @Int@; the tags only need to be unique
  71 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  72 (heavy monad machinery not needed).
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 %* naming conventions                                                   *
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 \subsection[name-conventions]{Name conventions}
  82
  83 The basic algorithm involves walking over the tree and returning a tuple
  84 containing the new tree plus its free variables. Some functions, such
  85 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  86 list comprehensions (@Quals@), return the variables bound in local
  87 environments. These are then used to calculate the free variables of the
  88 expression evaluated in these environments.
  89
  90 Conventions for variable names are as follows:
  91 \begin{itemize}
  92 \item
  93 new code is given a prime to distinguish it from the old.
  94
  95 \item
  96 a set of variables defined in @Exp@ is written @dvExp@
  97
  98 \item
  99 a set of variables free in @Exp@ is written @fvExp@
 100 \end{itemize}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 109
 110 Non-recursive expressions are reconstructed without any changes at top
 111 level, although their component expressions may have to be altered.
 112 However, non-recursive expressions are currently not expected as
 113 \Haskell{} programs, and this code should not be executed.
 114
 115 Monomorphic bindings contain information that is returned in a tuple
 116 (a @FlatMonoBinds@) containing:
 117
 118 \begin{enumerate}
 119 \item
 120 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 121
 122 \item
 123 the name of a function or the names in a pattern. These are a set
 124 referred to as @dvLhs@, the defined variables of the left hand side.
 125
 126 \item
 127 the free variables of the body. These are referred to as @fvBody@.
 128
 129 \item
 130 the definition's actual code. This is referred to as just @code@.
 131 \end{enumerate}
 132
 133 The function @nonRecDvFv@ returns two sets of variables. The first is
 134 the set of variables defined in the set of monomorphic bindings, while the
 135 second is the set of free variables in those bindings.
 136
 137 The set of variables defined in a non-recursive binding is just the
 138 union of all of them, as @union@ removes duplicates. However, the
 139 free variables in each successive set of cumulative bindings is the
 140 union of those in the previous set plus those of the newest binding after
 141 the defined variables of the previous set have been removed.
 142
 143 @rnMethodBinds@ deals only with the declarations in class and
 144 instance declarations.  It expects only to see @FunMonoBind@s, and
 145 it expects the global environment to contain bindings for the binders
 146 (which are all class operations).
 147
 148 %************************************************************************
 149 %*                                                                      *
 150 \subsubsection{ Top-level bindings}
 151 %*                                                                      *
 152 %************************************************************************
 153
 154 \begin{code}
 155 -- for top-level bindings, we need to make top-level names,
 156 -- so we have a different entry point than for local bindings
 157 rnTopBindsLHS :: MiniFixityEnv
 158               -> HsValBinds RdrName
 159               -> RnM (HsValBindsLR Name RdrName)
 160 rnTopBindsLHS fix_env binds
 161   = do { mod <- getModule
 162        ; rnValBindsLHSFromDoc (topRecNameMaker mod fix_env) binds }
 163
 164 rnTopBindsRHS :: NameSet        -- Names bound by these binds
 165               -> HsValBindsLR Name RdrName
 166               -> RnM (HsValBinds Name, DefUses)
 167 rnTopBindsRHS bound_names binds =
 168     do { is_boot <- tcIsHsBoot
 169        ; if is_boot
 170          then rnTopBindsBoot binds
 171          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 172                                bound_names binds }
 173
 174 -- Wrapper if we don't need to do anything in between the left and right,
 175 -- or anything else in the scope of the left
 176 --
 177 -- Never used when there are fixity declarations
 178 rnTopBinds :: HsValBinds RdrName
 179            -> RnM (HsValBinds Name, DefUses)
 180 rnTopBinds b =
 181   do nl <- rnTopBindsLHS emptyFsEnv b
 182      let bound_names = map unLoc (collectHsValBinders nl)
 183      bindLocalNames bound_names $ rnTopBindsRHS (mkNameSet bound_names) nl
 184
 185
 186 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 187 -- A hs-boot file has no bindings.
 188 -- Return a single HsBindGroup with empty binds and renamed signatures
 189 rnTopBindsBoot (ValBindsIn mbinds sigs)
 190   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 191         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 192         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 193 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 194 \end{code}
 195
 196
 197
 198 %*********************************************************
 199 %*                                                      *
 200                 HsLocalBinds
 201 %*                                                      *
 202 %*********************************************************
 203
 204 \begin{code}
 205 rnLocalBindsAndThen :: HsLocalBinds RdrName
 206                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 207                     -> RnM (result, FreeVars)
 208 -- This version (a) assumes that the binding vars are *not* already in scope
 209 --               (b) removes the binders from the free vars of the thing inside
 210 -- The parser doesn't produce ThenBinds
 211 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 212   = thing_inside EmptyLocalBinds
 213
 214 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 215   = rnValBindsAndThen val_binds $ \ val_binds' ->
 216       thing_inside (HsValBinds val_binds')
 217
 218 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 219     (binds',fv_binds) <- rnIPBinds binds
 220     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 221     return (thing, fvs_thing `plusFV` fv_binds)
 222
 223 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 224 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 225     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 226     return (IPBinds ip_binds' emptyLHsBinds, plusFVs fvs_s)
 227
 228 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 229 rnIPBind (IPBind n expr) = do
 230     name <- newIPNameRn  n
 231     (expr',fvExpr) <- rnLExpr expr
 232     return (IPBind name expr', fvExpr)
 233 \end{code}
 234
 235
 236 %************************************************************************
 237 %*                                                                      *
 238                 ValBinds
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 \begin{code}
 243 -- Renaming local binding gropus
 244 -- Does duplicate/shadow check
 245 rnValBindsLHS :: MiniFixityEnv
 246               -> HsValBinds RdrName
 247               -> RnM ([Name], HsValBindsLR Name RdrName)
 248 rnValBindsLHS fix_env binds
 249   = do { -- Do error checking: we need to check for dups here because we
 250          -- don't don't bind all of the variables from the ValBinds at once
 251          -- with bindLocatedLocals any more.
 252          --
 253          -- Note that we don't want to do this at the top level, since
 254          -- sorting out duplicates and shadowing there happens elsewhere.
 255          -- The behavior is even different. For example,
 256          --   import A(f)
 257          --   f = ...
 258          -- should not produce a shadowing warning (but it will produce
 259          -- an ambiguity warning if you use f), but
 260          --   import A(f)
 261          --   g = let f = ... in f
 262          -- should.
 263        ; binds' <- rnValBindsLHSFromDoc (localRecNameMaker fix_env) binds
 264        ; let bound_names = map unLoc $ collectHsValBinders binds'
 265        ; envs <- getRdrEnvs
 266        ; checkDupAndShadowedNames envs bound_names
 267        ; return (bound_names, binds') }
 268
 269 -- renames the left-hand sides
 270 -- generic version used both at the top level and for local binds
 271 -- does some error checking, but not what gets done elsewhere at the top level
 272 rnValBindsLHSFromDoc :: NameMaker
 273                      -> HsValBinds RdrName
 274                      -> RnM (HsValBindsLR Name RdrName)
 275 rnValBindsLHSFromDoc topP (ValBindsIn mbinds sigs)
 276   = do { mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 277        ; return $ ValBindsIn mbinds' sigs }
 278   where
 279     bndrs = collectHsBindBinders mbinds
 280     doc   = text "In the binding group for:" <+> pprWithCommas ppr bndrs
 281
 282 rnValBindsLHSFromDoc _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 283
 284 -- General version used both from the top-level and for local things
 285 -- Assumes the LHS vars are in scope
 286 --
 287 -- Does not bind the local fixity declarations
 288 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 289                      -- The trimming function trims the free vars we attach to a
 290                      -- binding so that it stays reasonably small
 291                  -> NameSet     -- Names bound by the LHSes
 292                  -> HsValBindsLR Name RdrName
 293                  -> RnM (HsValBinds Name, DefUses)
 294
 295 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs)
 296   = do {  -- rename the sigs
 297          sigs' <- renameSigs (Just bound_names) okBindSig sigs
 298           -- rename the RHSes
 299        ; binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 300        ; case depAnalBinds binds_w_dus of
 301             (anal_binds, anal_dus) -> do
 302        { let valbind' = ValBindsOut anal_binds sigs'
 303              valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 304        ; return (valbind', valbind'_dus) }}
 305
 306 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 307
 308 -- Wrapper for local binds
 309 --
 310 -- The *client* of this function is responsible for checking for unused binders;
 311 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 312 --
 313 -- The client is also responsible for bringing the fixities into scope
 314 rnValBindsRHS :: NameSet  -- names bound by the LHSes
 315               -> HsValBindsLR Name RdrName
 316               -> RnM (HsValBinds Name, DefUses)
 317 rnValBindsRHS bound_names binds =
 318   rnValBindsRHSGen (\ fvs -> -- only keep the names the names from this group
 319                     intersectNameSet bound_names fvs) bound_names binds
 320
 321
 322 -- for local binds
 323 -- wrapper that does both the left- and right-hand sides
 324 --
 325 -- here there are no local fixity decls passed in;
 326 -- the local fixity decls come from the ValBinds sigs
 327 rnValBindsAndThen :: HsValBinds RdrName
 328                   -> (HsValBinds Name -> RnM (result, FreeVars))
 329                   -> RnM (result, FreeVars)
 330 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 331  = do   {     -- (A) Create the local fixity environment
 332           new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 333
 334               -- (B) Rename the LHSes
 335         ; (bound_names, new_lhs) <- rnValBindsLHS new_fixities binds
 336
 337               --     ...and bring them (and their fixities) into scope
 338         ; bindLocalNamesFV_WithFixities bound_names new_fixities $ do
 339
 340         {      -- (C) Do the RHS and thing inside
 341           (binds', dus) <- rnValBindsRHS (mkNameSet bound_names) new_lhs
 342         ; (result, result_fvs) <- thing_inside binds'
 343
 344                 -- Report unused bindings based on the (accurate)
 345                 -- findUses.  E.g.
 346                 --      let x = x in 3
 347                 -- should report 'x' unused
 348         ; let real_uses = findUses dus result_fvs
 349         ; warnUnusedLocalBinds bound_names real_uses
 350
 351         ; let
 352             -- The variables "used" in the val binds are:
 353             --   (1) the uses of the binds (duUses)
 354             --   (2) the FVs of the thing-inside
 355             all_uses = duUses dus `plusFV` result_fvs
 356                 -- Note [Unused binding hack]
 357                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 358                 -- Note that *in contrast* to the above reporting of
 359                 -- unused bindings, (1) above uses duUses to return *all*
 360                 -- the uses, even if the binding is unused.  Otherwise consider:
 361                 --      x = 3
 362                 --      y = let p = x in 'x'    -- NB: p not used
 363                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 364                 -- bindings in the wrong order, and the type checker will complain
 365                 -- that x isn't in scope
 366                 --
 367                 -- But note that this means we won't report 'x' as unused,
 368                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 369
 370         ; return (result, all_uses) }}
 371                 -- The bound names are pruned out of all_uses
 372                 -- by the bindLocalNamesFV call above
 373
 374 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 375
 376
 377 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 378 -- (We keep the location around for reporting duplicate fixity declarations.)
 379 --
 380 -- Checks for duplicates, but not that only locally defined things are fixed.
 381 -- Note: for local fixity declarations, duplicates would also be checked in
 382 --       check_sigs below.  But we also use this function at the top level.
 383
 384 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 385
 386 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 387  where
 388    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 389      { -- this fixity decl is a duplicate iff
 390        -- the ReaderName's OccName's FastString is already in the env
 391        -- (we only need to check the local fix_env because
 392        --  definitions of non-local will be caught elsewhere)
 393        let { fs = occNameFS (rdrNameOcc name)
 394            ; fix_item = L loc fixity };
 395
 396        case lookupFsEnv env fs of
 397          Nothing -> return $ extendFsEnv env fs fix_item
 398          Just (L loc' _) -> do
 399            { setSrcSpan loc $
 400              addErrAt name_loc (dupFixityDecl loc' name)
 401            ; return env}
 402      }
 403
 404 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 405 dupFixityDecl loc rdr_name
 406   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 407           ptext (sLit "also at ") <+> ppr loc]
 408
 409 ---------------------
 410
 411 -- renaming a single bind
 412
 413 rnBindLHS :: NameMaker
 414           -> SDoc
 415           -> LHsBind RdrName
 416           -- returns the renamed left-hand side,
 417           -- and the FreeVars *of the LHS*
 418           -- (i.e., any free variables of the pattern)
 419           -> RnM (LHsBindLR Name RdrName)
 420
 421 rnBindLHS name_maker _ (L loc (PatBind { pat_lhs = pat,
 422                                          pat_rhs = grhss,
 423                                          pat_rhs_ty=pat_rhs_ty
 424                                        }))
 425   = setSrcSpan loc $ do
 426       -- we don't actually use the FV processing of rnPatsAndThen here
 427       (pat',pat'_fvs) <- rnBindPat name_maker pat
 428       return (L loc (PatBind { pat_lhs = pat',
 429                                pat_rhs = grhss,
 430                                -- we temporarily store the pat's FVs here;
 431                                -- gets updated to the FVs of the whole bind
 432                                -- when doing the RHS below
 433                                bind_fvs = pat'_fvs,
 434                                -- these will get ignored in the next pass,
 435                                -- when we rename the RHS
 436                                pat_rhs_ty = pat_rhs_ty }))
 437
 438 rnBindLHS name_maker _ (L loc (FunBind { fun_id = name@(L nameLoc _),
 439                                          fun_infix = inf,
 440                                          fun_matches = matches,
 441                                          fun_co_fn = fun_co_fn,
 442                                          fun_tick = fun_tick
 443                                        }))
 444   = setSrcSpan loc $
 445     do { newname <- applyNameMaker name_maker name
 446        ; return (L loc (FunBind { fun_id = L nameLoc newname,
 447                                   fun_infix = inf,
 448                                   fun_matches = matches,
 449                                   -- we temporatily store the LHS's FVs (empty in this case) here
 450                                   -- gets updated when doing the RHS below
 451                                   bind_fvs = emptyFVs,
 452                                   -- everything else will get ignored in the next pass
 453                                   fun_co_fn = fun_co_fn,
 454                                   fun_tick = fun_tick
 455                                   })) }
 456
 457 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 458
 459 -- assumes the left-hands-side vars are in scope
 460 rnBind :: (Name -> [Name])              -- Signature tyvar function
 461        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 462        -> LHsBindLR Name RdrName
 463        -> RnM (LHsBind Name, [Name], Uses)
 464 rnBind _ trim (L loc (PatBind { pat_lhs = pat,
 465                                 pat_rhs = grhss,
 466                                 -- pat fvs were stored here while
 467                                 -- processing the LHS
 468                                 bind_fvs=pat_fvs }))
 469   = setSrcSpan loc $
 470     do  {let bndrs = collectPatBinders pat
 471
 472         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 473                 -- No scoped type variables for pattern bindings
 474         ; let fvs' = trim fvs
 475
 476         ; fvs' `seq` -- See Note [Free-variable space leak]
 477       return (L loc (PatBind { pat_lhs = pat,
 478                                   pat_rhs = grhss',
 479                                      pat_rhs_ty = placeHolderType,
 480                                   bind_fvs = fvs' }),
 481                   bndrs, pat_fvs `plusFV` fvs) }
 482
 483 rnBind sig_fn
 484        trim
 485        (L loc (FunBind { fun_id = name,
 486                          fun_infix = is_infix,
 487                          fun_matches = matches,
 488                          -- no pattern FVs
 489                          bind_fvs = _
 490                        }))
 491        -- invariant: no free vars here when it's a FunBind
 492   = setSrcSpan loc $
 493     do  { let plain_name = unLoc name
 494
 495         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 496                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 497                              rnMatchGroup (FunRhs plain_name is_infix) matches
 498         ; let fvs' = trim fvs
 499
 500         ; when is_infix $ checkPrecMatch plain_name matches'
 501
 502         ; fvs' `seq` -- See Note [Free-variable space leak]
 503
 504           return (L loc (FunBind { fun_id = name,
 505                                    fun_infix = is_infix,
 506                                    fun_matches = matches',
 507                                    bind_fvs = fvs',
 508                                    fun_co_fn = idHsWrapper,
 509                                    fun_tick = Nothing }),
 510                   [plain_name], fvs)
 511       }
 512
 513 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 514
 515 {-
 516 Note [Free-variable space leak]
 517 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 518 We have
 519     fvs' = trim fvs
 520 and we seq fvs' before turning it as part of a record.
 521
 522 The reason is that trim is sometimes something like
 523     \xs -> intersectNameSet (mkNameSet bound_names) xs
 524 and we don't want to retain the list bound_names. This showed up in
 525 trac ticket #1136.
 526 -}
 527
 528 ---------------------
 529 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 530              -> ([(RecFlag, LHsBinds Name)], DefUses)
 531 -- Dependency analysis; this is important so that
 532 -- unused-binding reporting is accurate
 533 depAnalBinds binds_w_dus
 534   = (map get_binds sccs, map get_du sccs)
 535   where
 536     sccs = stronglyConnCompFromEdgedVertices edges
 537
 538     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 539
 540     edges = [ (node, key, [key | n <- nameSetToList uses,
 541                                  Just key <- [lookupNameEnv key_map n] ])
 542             | (node@(_,_,uses), key) <- keyd_nodes ]
 543
 544     key_map :: NameEnv Int      -- Which binding it comes from
 545     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 546                                      , bndr <- bndrs ]
 547
 548     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 549     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 550
 551     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 552     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 553         where
 554           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 555           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 556
 557
 558 ---------------------
 559 -- Bind the top-level forall'd type variables in the sigs.
 560 -- E.g  f :: a -> a
 561 --      f = rhs
 562 --      The 'a' scopes over the rhs
 563 --
 564 -- NB: there'll usually be just one (for a function binding)
 565 --     but if there are many, one may shadow the rest; too bad!
 566 --      e.g  x :: [a] -> [a]
 567 --           y :: [(a,a)] -> a
 568 --           (x,y) = e
 569 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 570
 571 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 572 -- Return a lookup function that maps an Id Name to the names
 573 -- of the type variables that should scope over its body..
 574 mkSigTvFn sigs
 575   = \n -> lookupNameEnv env n `orElse` []
 576   where
 577     env :: NameEnv [Name]
 578     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 579                     | L _ (TypeSig (L _ name)
 580                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 581         -- Note the pattern-match on "Explicit"; we only bind
 582         -- type variables from signatures with an explicit top-level for-all
 583 \end{code}
 584
 585
 586 @rnMethodBinds@ is used for the method bindings of a class and an instance
 587 declaration.   Like @rnBinds@ but without dependency analysis.
 588
 589 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 590 That's crucial when dealing with an instance decl:
 591 \begin{verbatim}
 592         instance Foo (T a) where
 593            op x = ...
 594 \end{verbatim}
 595 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 596 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 597 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 598 in many ways the @op@ in an instance decl is just like an occurrence, not
 599 a binder.
 600
 601 \begin{code}
 602 rnMethodBinds :: Name                   -- Class name
 603               -> (Name -> [Name])       -- Signature tyvar function
 604               -> [Name]                 -- Names for generic type variables
 605               -> LHsBinds RdrName
 606               -> RnM (LHsBinds Name, FreeVars)
 607
 608 rnMethodBinds cls sig_fn gen_tyvars binds
 609   = foldM do_one (emptyBag,emptyFVs) (bagToList binds)
 610   where do_one (binds,fvs) bind = do
 611            (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 612            return (bind' `unionBags` binds, fvs_bind `plusFV` fvs)
 613
 614 rnMethodBind :: Name
 615               -> (Name -> [Name])
 616               -> [Name]
 617               -> LHsBindLR RdrName RdrName
 618               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 619 rnMethodBind cls sig_fn gen_tyvars (L loc (FunBind { fun_id = name, fun_infix = is_infix,
 620                                                      fun_matches = MatchGroup matches _ }))
 621   = setSrcSpan loc $ do
 622     sel_name <- wrapLocM (lookupInstDeclBndr cls) name
 623     let plain_name = unLoc sel_name
 624         -- We use the selector name as the binder
 625
 626     (new_matches, fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 627                           mapFvRn (rn_match (FunRhs plain_name is_infix)) matches
 628     let new_group = MatchGroup new_matches placeHolderType
 629
 630     when is_infix $ checkPrecMatch plain_name new_group
 631     return (unitBag (L loc (FunBind {
 632                                 fun_id = sel_name, fun_infix = is_infix,
 633                                 fun_matches = new_group,
 634                                 bind_fvs = fvs, fun_co_fn = idHsWrapper,
 635                                 fun_tick = Nothing })),
 636              fvs `addOneFV` plain_name)
 637         -- The 'fvs' field isn't used for method binds
 638   where
 639         -- Truly gruesome; bring into scope the correct members of the generic
 640         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 641     rn_match info match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 642         = extendTyVarEnvFVRn gen_tvs    $
 643           rnMatch info match
 644         where
 645           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 646           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 647
 648     rn_match info match = rnMatch info match
 649
 650 -- Can't handle method pattern-bindings which bind multiple methods.
 651 rnMethodBind _ _ _ (L loc bind@(PatBind {})) = do
 652     addErrAt loc (methodBindErr bind)
 653     return (emptyBag, emptyFVs)
 654
 655 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 656 \end{code}
 657
 658
 659
 660 %************************************************************************
 661 %*                                                                      *
 662 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 663 %*                                                                      *
 664 %************************************************************************
 665
 666 @renameSigs@ checks for:
 667 \begin{enumerate}
 668 \item more than one sig for one thing;
 669 \item signatures given for things not bound here;
 670 \end{enumerate}
 671 %
 672 At the moment we don't gather free-var info from the types in
 673 signatures.  We'd only need this if we wanted to report unused tyvars.
 674
 675 \begin{code}
 676 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 677            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 678            -> [LSig RdrName]
 679            -> RnM [LSig Name]
 680 -- Renames the signatures and performs error checks
 681 renameSigs mb_names ok_sig sigs
 682   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 683         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 684         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 685         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 686         ; return sigs' }
 687
 688 ----------------------
 689 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 690 -- because this won't work for:
 691 --      instance Foo T where
 692 --        {-# INLINE op #-}
 693 --        Baz.op = ...
 694 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 695 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 696 -- Doesn't seem worth much trouble to sort this.
 697
 698 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 699 -- FixitySig is renamed elsewhere.
 700 renameSig _ (IdSig x)
 701   = return (IdSig x)      -- Actually this never occurs
 702 renameSig mb_names sig@(TypeSig v ty)
 703   = do  { new_v <- lookupSigOccRn mb_names sig v
 704         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 705         ; return (TypeSig new_v new_ty) }
 706
 707 renameSig _ (SpecInstSig ty)
 708   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 709         ; return (SpecInstSig new_ty) }
 710
 711 renameSig mb_names sig@(SpecSig v ty inl)
 712   = do  { new_v <- lookupSigOccRn mb_names sig v
 713         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 714         ; return (SpecSig new_v new_ty inl) }
 715
 716 renameSig mb_names sig@(InlineSig v s)
 717   = do  { new_v <- lookupSigOccRn mb_names sig v
 718         ; return (InlineSig new_v s) }
 719
 720 renameSig mb_names sig@(FixSig (FixitySig v f))
 721   = do  { new_v <- lookupSigOccRn mb_names sig v
 722         ; return (FixSig (FixitySig new_v f)) }
 723 \end{code}
 724
 725
 726 %************************************************************************
 727 %*                                                                      *
 728 \subsection{Match}
 729 %*                                                                      *
 730 %************************************************************************
 731
 732 \begin{code}
 733 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 734 rnMatchGroup ctxt (MatchGroup ms _)
 735   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 736        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 737
 738 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 739 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 740
 741 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 742 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 743   = do  {       -- Result type signatures are no longer supported
 744           case maybe_rhs_sig of
 745                 Nothing -> return ()
 746                 Just (L loc ty) -> addErrAt loc (resSigErr ctxt match ty)
 747
 748                -- Now the main event
 749                -- note that there are no local ficity decls for matches
 750         ; rnPats ctxt pats      $ \ pats' -> do
 751         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 752
 753         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 754         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 755
 756 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 757 resSigErr ctxt match ty
 758    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 759           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 760           , pprMatchInCtxt ctxt match ]
 761 \end{code}
 762
 763
 764 %************************************************************************
 765 %*                                                                      *
 766 \subsubsection{Guarded right-hand sides (GRHSs)}
 767 %*                                                                      *
 768 %************************************************************************
 769
 770 \begin{code}
 771 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 772
 773 rnGRHSs ctxt (GRHSs grhss binds)
 774   = rnLocalBindsAndThen binds   $ \ binds' -> do
 775     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 776     return (GRHSs grhss' binds', fvGRHSs)
 777
 778 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 779 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 780
 781 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 782 rnGRHS' ctxt (GRHS guards rhs)
 783   = do  { pattern_guards_allowed <- doptM Opt_PatternGuards
 784         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 785                                     rnLExpr rhs
 786
 787         ; unless (pattern_guards_allowed || is_standard_guard guards')
 788                  (addWarn (nonStdGuardErr guards'))
 789
 790         ; return (GRHS guards' rhs', fvs) }
 791   where
 792         -- Standard Haskell 1.4 guards are just a single boolean
 793         -- expression, rather than a list of qualifiers as in the
 794         -- Glasgow extension
 795     is_standard_guard []                     = True
 796     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 797     is_standard_guard _                      = False
 798 \end{code}
 799
 800 %************************************************************************
 801 %*                                                                      *
 802 \subsection{Error messages}
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 808 dupSigDeclErr sigs@(L loc sig : _)
 809   = addErrAt loc $
 810         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 811               nest 2 (vcat (map ppr_sig sigs))]
 812   where
 813     what_it_is = hsSigDoc sig
 814     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 815 dupSigDeclErr [] = panic "dupSigDeclErr"
 816
 817 unknownSigErr :: LSig RdrName -> RnM ()
 818 unknownSigErr (L loc sig)
 819   = addErrAt loc $
 820     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 821
 822 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 823 methodBindErr mbind
 824  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 825        2 (ppr mbind)
 826
 827 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 828 bindsInHsBootFile mbinds
 829   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 830        2 (ppr mbinds)
 831
 832 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 833 nonStdGuardErr guards
 834   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 835        4 (interpp'SP guards)
 836 \end{code}