compiler/rename/RnBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnBinds]{Renaming and dependency analysis of bindings}
   5
   6 This module does renaming and dependency analysis on value bindings in
   7 the abstract syntax.  It does {\em not} do cycle-checks on class or
   8 type-synonym declarations; those cannot be done at this stage because
   9 they may be affected by renaming (which isn't fully worked out yet).
  10
  11 \begin{code}
  12 module RnBinds (rnTopBinds, rnTopBindsLHS, rnTopBindsRHS, -- use these for top-level bindings
  13                 rnLocalBindsAndThen, rnValBindsLHS, rnValBindsRHS, -- or these for local bindings
  14                 rnMethodBinds, renameSigs, mkSigTvFn,
  15                 rnMatchGroup, rnGRHSs,
  16                 makeMiniFixityEnv, MiniFixityEnv
  17    ) where
  18
  19 import {-# SOURCE #-} RnExpr( rnLExpr, rnStmts )
  20
  21 import HsSyn
  22 import RdrHsSyn
  23 import RnHsSyn
  24 import TcRnMonad
  25 import RnTypes        ( rnHsSigType, rnLHsType, checkPrecMatch)
  26 import RnPat          (rnPats, rnBindPat,
  27                        NameMaker, localRecNameMaker, topRecNameMaker, applyNameMaker
  28                       )
  29
  30 import RnEnv
  31 import DynFlags
  32 import Name
  33 import NameEnv
  34 import NameSet
  35 import RdrName          ( RdrName, rdrNameOcc )
  36 import SrcLoc
  37 import ListSetOps       ( findDupsEq )
  38 import BasicTypes       ( RecFlag(..) )
  39 import Digraph          ( SCC(..), stronglyConnCompFromEdgedVertices )
  40 import Bag
  41 import Outputable
  42 import FastString
  43 import Data.List        ( partition )
  44 import Maybes           ( orElse )
  45 import Control.Monad
  46 \end{code}
  47
  48 -- ToDo: Put the annotations into the monad, so that they arrive in the proper
  49 -- place and can be used when complaining.
  50
  51 The code tree received by the function @rnBinds@ contains definitions
  52 in where-clauses which are all apparently mutually recursive, but which may
  53 not really depend upon each other. For example, in the top level program
  54 \begin{verbatim}
  55 f x = y where a = x
  56               y = x
  57 \end{verbatim}
  58 the definitions of @a@ and @y@ do not depend on each other at all.
  59 Unfortunately, the typechecker cannot always check such definitions.
  60 \footnote{Mycroft, A. 1984. Polymorphic type schemes and recursive
  61 definitions. In Proceedings of the International Symposium on Programming,
  62 Toulouse, pp. 217-39. LNCS 167. Springer Verlag.}
  63 However, the typechecker usually can check definitions in which only the
  64 strongly connected components have been collected into recursive bindings.
  65 This is precisely what the function @rnBinds@ does.
  66
  67 ToDo: deal with case where a single monobinds binds the same variable
  68 twice.
  69
  70 The vertag tag is a unique @Int@; the tags only need to be unique
  71 within one @MonoBinds@, so that unique-Int plumbing is done explicitly
  72 (heavy monad machinery not needed).
  73
  74
  75 %************************************************************************
  76 %*                                                                      *
  77 %* naming conventions                                                   *
  78 %*                                                                      *
  79 %************************************************************************
  80
  81 \subsection[name-conventions]{Name conventions}
  82
  83 The basic algorithm involves walking over the tree and returning a tuple
  84 containing the new tree plus its free variables. Some functions, such
  85 as those walking polymorphic bindings (HsBinds) and qualifier lists in
  86 list comprehensions (@Quals@), return the variables bound in local
  87 environments. These are then used to calculate the free variables of the
  88 expression evaluated in these environments.
  89
  90 Conventions for variable names are as follows:
  91 \begin{itemize}
  92 \item
  93 new code is given a prime to distinguish it from the old.
  94
  95 \item
  96 a set of variables defined in @Exp@ is written @dvExp@
  97
  98 \item
  99 a set of variables free in @Exp@ is written @fvExp@
 100 \end{itemize}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 %* analysing polymorphic bindings (HsBindGroup, HsBind)
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 \subsubsection[dep-HsBinds]{Polymorphic bindings}
 109
 110 Non-recursive expressions are reconstructed without any changes at top
 111 level, although their component expressions may have to be altered.
 112 However, non-recursive expressions are currently not expected as
 113 \Haskell{} programs, and this code should not be executed.
 114
 115 Monomorphic bindings contain information that is returned in a tuple
 116 (a @FlatMonoBinds@) containing:
 117
 118 \begin{enumerate}
 119 \item
 120 a unique @Int@ that serves as the ``vertex tag'' for this binding.
 121
 122 \item
 123 the name of a function or the names in a pattern. These are a set
 124 referred to as @dvLhs@, the defined variables of the left hand side.
 125
 126 \item
 127 the free variables of the body. These are referred to as @fvBody@.
 128
 129 \item
 130 the definition's actual code. This is referred to as just @code@.
 131 \end{enumerate}
 132
 133 The function @nonRecDvFv@ returns two sets of variables. The first is
 134 the set of variables defined in the set of monomorphic bindings, while the
 135 second is the set of free variables in those bindings.
 136
 137 The set of variables defined in a non-recursive binding is just the
 138 union of all of them, as @union@ removes duplicates. However, the
 139 free variables in each successive set of cumulative bindings is the
 140 union of those in the previous set plus those of the newest binding after
 141 the defined variables of the previous set have been removed.
 142
 143 @rnMethodBinds@ deals only with the declarations in class and
 144 instance declarations.  It expects only to see @FunMonoBind@s, and
 145 it expects the global environment to contain bindings for the binders
 146 (which are all class operations).
 147
 148 %************************************************************************
 149 %*                                                                      *
 150 \subsubsection{ Top-level bindings}
 151 %*                                                                      *
 152 %************************************************************************
 153
 154 \begin{code}
 155 -- for top-level bindings, we need to make top-level names,
 156 -- so we have a different entry point than for local bindings
 157 rnTopBindsLHS :: MiniFixityEnv
 158               -> HsValBinds RdrName
 159               -> RnM (HsValBindsLR Name RdrName)
 160 rnTopBindsLHS fix_env binds
 161   = rnValBindsLHSFromDoc (topRecNameMaker fix_env) binds
 162
 163 rnTopBindsRHS :: NameSet        -- Names bound by these binds
 164               -> HsValBindsLR Name RdrName
 165               -> RnM (HsValBinds Name, DefUses)
 166 rnTopBindsRHS bound_names binds =
 167     do { is_boot <- tcIsHsBoot
 168        ; if is_boot
 169          then rnTopBindsBoot binds
 170          else rnValBindsRHSGen (\x -> x) -- don't trim free vars
 171                                bound_names binds }
 172
 173 -- Wrapper if we don't need to do anything in between the left and right,
 174 -- or anything else in the scope of the left
 175 --
 176 -- Never used when there are fixity declarations
 177 rnTopBinds :: HsValBinds RdrName
 178            -> RnM (HsValBinds Name, DefUses)
 179 rnTopBinds b =
 180   do nl <- rnTopBindsLHS emptyFsEnv b
 181      let bound_names = collectHsValBinders nl
 182      bindLocalNames bound_names $ rnTopBindsRHS (mkNameSet bound_names) nl
 183
 184
 185 rnTopBindsBoot :: HsValBindsLR Name RdrName -> RnM (HsValBinds Name, DefUses)
 186 -- A hs-boot file has no bindings.
 187 -- Return a single HsBindGroup with empty binds and renamed signatures
 188 rnTopBindsBoot (ValBindsIn mbinds sigs)
 189   = do  { checkErr (isEmptyLHsBinds mbinds) (bindsInHsBootFile mbinds)
 190         ; sigs' <- renameSigs Nothing okHsBootSig sigs
 191         ; return (ValBindsOut [] sigs', usesOnly (hsSigsFVs sigs')) }
 192 rnTopBindsBoot b = pprPanic "rnTopBindsBoot" (ppr b)
 193 \end{code}
 194
 195
 196
 197 %*********************************************************
 198 %*                                                      *
 199                 HsLocalBinds
 200 %*                                                      *
 201 %*********************************************************
 202
 203 \begin{code}
 204 rnLocalBindsAndThen :: HsLocalBinds RdrName
 205                     -> (HsLocalBinds Name -> RnM (result, FreeVars))
 206                     -> RnM (result, FreeVars)
 207 -- This version (a) assumes that the binding vars are *not* already in scope
 208 --               (b) removes the binders from the free vars of the thing inside
 209 -- The parser doesn't produce ThenBinds
 210 rnLocalBindsAndThen EmptyLocalBinds thing_inside
 211   = thing_inside EmptyLocalBinds
 212
 213 rnLocalBindsAndThen (HsValBinds val_binds) thing_inside
 214   = rnValBindsAndThen val_binds $ \ val_binds' ->
 215       thing_inside (HsValBinds val_binds')
 216
 217 rnLocalBindsAndThen (HsIPBinds binds) thing_inside = do
 218     (binds',fv_binds) <- rnIPBinds binds
 219     (thing, fvs_thing) <- thing_inside (HsIPBinds binds')
 220     return (thing, fvs_thing `plusFV` fv_binds)
 221
 222 rnIPBinds :: HsIPBinds RdrName -> RnM (HsIPBinds Name, FreeVars)
 223 rnIPBinds (IPBinds ip_binds _no_dict_binds) = do
 224     (ip_binds', fvs_s) <- mapAndUnzipM (wrapLocFstM rnIPBind) ip_binds
 225     return (IPBinds ip_binds' emptyTcEvBinds, plusFVs fvs_s)
 226
 227 rnIPBind :: IPBind RdrName -> RnM (IPBind Name, FreeVars)
 228 rnIPBind (IPBind n expr) = do
 229     name <- newIPNameRn  n
 230     (expr',fvExpr) <- rnLExpr expr
 231     return (IPBind name expr', fvExpr)
 232 \end{code}
 233
 234
 235 %************************************************************************
 236 %*                                                                      *
 237                 ValBinds
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 \begin{code}
 242 -- Renaming local binding gropus
 243 -- Does duplicate/shadow check
 244 rnValBindsLHS :: MiniFixityEnv
 245               -> HsValBinds RdrName
 246               -> RnM ([Name], HsValBindsLR Name RdrName)
 247 rnValBindsLHS fix_env binds
 248   = do { -- Do error checking: we need to check for dups here because we
 249          -- don't don't bind all of the variables from the ValBinds at once
 250          -- with bindLocatedLocals any more.
 251          --
 252          -- Note that we don't want to do this at the top level, since
 253          -- sorting out duplicates and shadowing there happens elsewhere.
 254          -- The behavior is even different. For example,
 255          --   import A(f)
 256          --   f = ...
 257          -- should not produce a shadowing warning (but it will produce
 258          -- an ambiguity warning if you use f), but
 259          --   import A(f)
 260          --   g = let f = ... in f
 261          -- should.
 262        ; binds' <- rnValBindsLHSFromDoc (localRecNameMaker fix_env) binds
 263        ; let bound_names = collectHsValBinders binds'
 264        ; envs <- getRdrEnvs
 265        ; checkDupAndShadowedNames envs bound_names
 266        ; return (bound_names, binds') }
 267
 268 -- renames the left-hand sides
 269 -- generic version used both at the top level and for local binds
 270 -- does some error checking, but not what gets done elsewhere at the top level
 271 rnValBindsLHSFromDoc :: NameMaker
 272                      -> HsValBinds RdrName
 273                      -> RnM (HsValBindsLR Name RdrName)
 274 rnValBindsLHSFromDoc topP (ValBindsIn mbinds sigs)
 275   = do { mbinds' <- mapBagM (rnBindLHS topP doc) mbinds
 276        ; return $ ValBindsIn mbinds' sigs }
 277   where
 278     bndrs = collectHsBindsBinders mbinds
 279     doc   = text "In the binding group for:" <+> pprWithCommas ppr bndrs
 280
 281 rnValBindsLHSFromDoc _ b = pprPanic "rnValBindsLHSFromDoc" (ppr b)
 282
 283 -- General version used both from the top-level and for local things
 284 -- Assumes the LHS vars are in scope
 285 --
 286 -- Does not bind the local fixity declarations
 287 rnValBindsRHSGen :: (FreeVars -> FreeVars)  -- for trimming free var sets
 288                      -- The trimming function trims the free vars we attach to a
 289                      -- binding so that it stays reasonably small
 290                  -> NameSet     -- Names bound by the LHSes
 291                  -> HsValBindsLR Name RdrName
 292                  -> RnM (HsValBinds Name, DefUses)
 293
 294 rnValBindsRHSGen trim bound_names (ValBindsIn mbinds sigs)
 295   = do {  -- rename the sigs
 296          sigs' <- renameSigs (Just bound_names) okBindSig sigs
 297           -- rename the RHSes
 298        ; binds_w_dus <- mapBagM (rnBind (mkSigTvFn sigs') trim) mbinds
 299        ; case depAnalBinds binds_w_dus of
 300             (anal_binds, anal_dus) -> do
 301        { let valbind' = ValBindsOut anal_binds sigs'
 302              valbind'_dus = usesOnly (hsSigsFVs sigs') `plusDU` anal_dus
 303        ; return (valbind', valbind'_dus) }}
 304
 305 rnValBindsRHSGen _ _ b = pprPanic "rnValBindsRHSGen" (ppr b)
 306
 307 -- Wrapper for local binds
 308 --
 309 -- The *client* of this function is responsible for checking for unused binders;
 310 -- it doesn't (and can't: we don't have the thing inside the binds) happen here
 311 --
 312 -- The client is also responsible for bringing the fixities into scope
 313 rnValBindsRHS :: NameSet  -- names bound by the LHSes
 314               -> HsValBindsLR Name RdrName
 315               -> RnM (HsValBinds Name, DefUses)
 316 rnValBindsRHS bound_names binds
 317   = rnValBindsRHSGen trim bound_names binds
 318   where
 319     trim fvs = intersectNameSet bound_names fvs
 320         -- Only keep the names the names from this group
 321
 322 -- for local binds
 323 -- wrapper that does both the left- and right-hand sides
 324 --
 325 -- here there are no local fixity decls passed in;
 326 -- the local fixity decls come from the ValBinds sigs
 327 rnValBindsAndThen :: HsValBinds RdrName
 328                   -> (HsValBinds Name -> RnM (result, FreeVars))
 329                   -> RnM (result, FreeVars)
 330 rnValBindsAndThen binds@(ValBindsIn _ sigs) thing_inside
 331  = do   {     -- (A) Create the local fixity environment
 332           new_fixities <- makeMiniFixityEnv [L loc sig | L loc (FixSig sig) <- sigs]
 333
 334               -- (B) Rename the LHSes
 335         ; (bound_names, new_lhs) <- rnValBindsLHS new_fixities binds
 336
 337               --     ...and bring them (and their fixities) into scope
 338         ; bindLocalNamesFV bound_names              $
 339           addLocalFixities new_fixities bound_names $ do
 340
 341         {      -- (C) Do the RHS and thing inside
 342           (binds', dus) <- rnValBindsRHS (mkNameSet bound_names) new_lhs
 343         ; (result, result_fvs) <- thing_inside binds'
 344
 345                 -- Report unused bindings based on the (accurate)
 346                 -- findUses.  E.g.
 347                 --      let x = x in 3
 348                 -- should report 'x' unused
 349         ; let real_uses = findUses dus result_fvs
 350         ; warnUnusedLocalBinds bound_names real_uses
 351
 352         ; let
 353             -- The variables "used" in the val binds are:
 354             --   (1) the uses of the binds (allUses)
 355             --   (2) the FVs of the thing-inside
 356             all_uses = allUses dus `plusFV` result_fvs
 357                 -- Note [Unused binding hack]
 358                 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~
 359                 -- Note that *in contrast* to the above reporting of
 360                 -- unused bindings, (1) above uses duUses to return *all*
 361                 -- the uses, even if the binding is unused.  Otherwise consider:
 362                 --      x = 3
 363                 --      y = let p = x in 'x'    -- NB: p not used
 364                 -- If we don't "see" the dependency of 'y' on 'x', we may put the
 365                 -- bindings in the wrong order, and the type checker will complain
 366                 -- that x isn't in scope
 367                 --
 368                 -- But note that this means we won't report 'x' as unused,
 369                 -- whereas we would if we had { x = 3; p = x; y = 'x' }
 370
 371         ; return (result, all_uses) }}
 372                 -- The bound names are pruned out of all_uses
 373                 -- by the bindLocalNamesFV call above
 374
 375 rnValBindsAndThen bs _ = pprPanic "rnValBindsAndThen" (ppr bs)
 376
 377
 378 -- Process the fixity declarations, making a FastString -> (Located Fixity) map
 379 -- (We keep the location around for reporting duplicate fixity declarations.)
 380 --
 381 -- Checks for duplicates, but not that only locally defined things are fixed.
 382 -- Note: for local fixity declarations, duplicates would also be checked in
 383 --       check_sigs below.  But we also use this function at the top level.
 384
 385 makeMiniFixityEnv :: [LFixitySig RdrName] -> RnM MiniFixityEnv
 386
 387 makeMiniFixityEnv decls = foldlM add_one emptyFsEnv decls
 388  where
 389    add_one env (L loc (FixitySig (L name_loc name) fixity)) = do
 390      { -- this fixity decl is a duplicate iff
 391        -- the ReaderName's OccName's FastString is already in the env
 392        -- (we only need to check the local fix_env because
 393        --  definitions of non-local will be caught elsewhere)
 394        let { fs = occNameFS (rdrNameOcc name)
 395            ; fix_item = L loc fixity };
 396
 397        case lookupFsEnv env fs of
 398          Nothing -> return $ extendFsEnv env fs fix_item
 399          Just (L loc' _) -> do
 400            { setSrcSpan loc $
 401              addErrAt name_loc (dupFixityDecl loc' name)
 402            ; return env}
 403      }
 404
 405 dupFixityDecl :: SrcSpan -> RdrName -> SDoc
 406 dupFixityDecl loc rdr_name
 407   = vcat [ptext (sLit "Multiple fixity declarations for") <+> quotes (ppr rdr_name),
 408           ptext (sLit "also at ") <+> ppr loc]
 409
 410 ---------------------
 411
 412 -- renaming a single bind
 413
 414 rnBindLHS :: NameMaker
 415           -> SDoc
 416           -> LHsBind RdrName
 417           -- returns the renamed left-hand side,
 418           -- and the FreeVars *of the LHS*
 419           -- (i.e., any free variables of the pattern)
 420           -> RnM (LHsBindLR Name RdrName)
 421
 422 rnBindLHS name_maker _ (L loc bind@(PatBind { pat_lhs = pat }))
 423   = setSrcSpan loc $ do
 424       -- we don't actually use the FV processing of rnPatsAndThen here
 425       (pat',pat'_fvs) <- rnBindPat name_maker pat
 426       return (L loc (bind { pat_lhs = pat', bind_fvs = pat'_fvs }))
 427                 -- We temporarily store the pat's FVs in bind_fvs;
 428                 -- gets updated to the FVs of the whole bind
 429                 -- when doing the RHS below
 430
 431 rnBindLHS name_maker _ (L loc bind@(FunBind { fun_id = name@(L nameLoc _) }))
 432   = setSrcSpan loc $
 433     do { newname <- applyNameMaker name_maker name
 434        ; return (L loc (bind { fun_id = L nameLoc newname })) }
 435
 436 rnBindLHS _ _ b = pprPanic "rnBindLHS" (ppr b)
 437
 438 -- assumes the left-hands-side vars are in scope
 439 rnBind :: (Name -> [Name])              -- Signature tyvar function
 440        -> (FreeVars -> FreeVars)        -- Trimming function for rhs free vars
 441        -> LHsBindLR Name RdrName
 442        -> RnM (LHsBind Name, [Name], Uses)
 443 rnBind _ trim (L loc bind@(PatBind { pat_lhs = pat
 444                                    , pat_rhs = grhss
 445                                       -- pat fvs were stored in bind_fvs
 446                                       -- after processing the LHS
 447                                    , bind_fvs = pat_fvs }))
 448   = setSrcSpan loc $
 449     do  { let bndrs = collectPatBinders pat
 450
 451         ; (grhss', fvs) <- rnGRHSs PatBindRhs grhss
 452                 -- No scoped type variables for pattern bindings
 453         ; let all_fvs = pat_fvs `plusFV` fvs
 454               fvs'    = trim all_fvs
 455
 456         ; fvs' `seq` -- See Note [Free-variable space leak]
 457           return (L loc (bind { pat_rhs  = grhss'
 458                               , bind_fvs = fvs' }),
 459                   bndrs, all_fvs) }
 460
 461 rnBind sig_fn trim
 462        (L loc bind@(FunBind { fun_id = name
 463                             , fun_infix = is_infix
 464                             , fun_matches = matches }))
 465        -- invariant: no free vars here when it's a FunBind
 466   = setSrcSpan loc $
 467     do  { let plain_name = unLoc name
 468
 469         ; (matches', fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 470                                 -- bindSigTyVars tests for Opt_ScopedTyVars
 471                              rnMatchGroup (FunRhs plain_name is_infix) matches
 472         ; let fvs' = trim fvs
 473
 474         ; when is_infix $ checkPrecMatch plain_name matches'
 475
 476         ; fvs' `seq` -- See Note [Free-variable space leak]
 477
 478           return (L loc (bind { fun_matches = matches'
 479                               , bind_fvs   = fvs' }),
 480                   [plain_name], fvs)
 481       }
 482
 483 rnBind _ _ b = pprPanic "rnBind" (ppr b)
 484
 485 {-
 486 Note [Free-variable space leak]
 487 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 488 We have
 489     fvs' = trim fvs
 490 and we seq fvs' before turning it as part of a record.
 491
 492 The reason is that trim is sometimes something like
 493     \xs -> intersectNameSet (mkNameSet bound_names) xs
 494 and we don't want to retain the list bound_names. This showed up in
 495 trac ticket #1136.
 496 -}
 497
 498 ---------------------
 499 depAnalBinds :: Bag (LHsBind Name, [Name], Uses)
 500              -> ([(RecFlag, LHsBinds Name)], DefUses)
 501 -- Dependency analysis; this is important so that
 502 -- unused-binding reporting is accurate
 503 depAnalBinds binds_w_dus
 504   = (map get_binds sccs, map get_du sccs)
 505   where
 506     sccs = stronglyConnCompFromEdgedVertices edges
 507
 508     keyd_nodes = bagToList binds_w_dus `zip` [0::Int ..]
 509
 510     edges = [ (node, key, [key | n <- nameSetToList uses,
 511                                  Just key <- [lookupNameEnv key_map n] ])
 512             | (node@(_,_,uses), key) <- keyd_nodes ]
 513
 514     key_map :: NameEnv Int      -- Which binding it comes from
 515     key_map = mkNameEnv [(bndr, key) | ((_, bndrs, _), key) <- keyd_nodes
 516                                      , bndr <- bndrs ]
 517
 518     get_binds (AcyclicSCC (bind, _, _)) = (NonRecursive, unitBag bind)
 519     get_binds (CyclicSCC  binds_w_dus)  = (Recursive, listToBag [b | (b,_,_) <- binds_w_dus])
 520
 521     get_du (AcyclicSCC (_, bndrs, uses)) = (Just (mkNameSet bndrs), uses)
 522     get_du (CyclicSCC  binds_w_dus)      = (Just defs, uses)
 523         where
 524           defs = mkNameSet [b | (_,bs,_) <- binds_w_dus, b <- bs]
 525           uses = unionManyNameSets [u | (_,_,u) <- binds_w_dus]
 526
 527
 528 ---------------------
 529 -- Bind the top-level forall'd type variables in the sigs.
 530 -- E.g  f :: a -> a
 531 --      f = rhs
 532 --      The 'a' scopes over the rhs
 533 --
 534 -- NB: there'll usually be just one (for a function binding)
 535 --     but if there are many, one may shadow the rest; too bad!
 536 --      e.g  x :: [a] -> [a]
 537 --           y :: [(a,a)] -> a
 538 --           (x,y) = e
 539 --      In e, 'a' will be in scope, and it'll be the one from 'y'!
 540
 541 mkSigTvFn :: [LSig Name] -> (Name -> [Name])
 542 -- Return a lookup function that maps an Id Name to the names
 543 -- of the type variables that should scope over its body..
 544 mkSigTvFn sigs
 545   = \n -> lookupNameEnv env n `orElse` []
 546   where
 547     env :: NameEnv [Name]
 548     env = mkNameEnv [ (name, map hsLTyVarName ltvs)
 549                     | L _ (TypeSig (L _ name)
 550                                    (L _ (HsForAllTy Explicit ltvs _ _))) <- sigs]
 551         -- Note the pattern-match on "Explicit"; we only bind
 552         -- type variables from signatures with an explicit top-level for-all
 553 \end{code}
 554
 555
 556 @rnMethodBinds@ is used for the method bindings of a class and an instance
 557 declaration.   Like @rnBinds@ but without dependency analysis.
 558
 559 NOTA BENE: we record each {\em binder} of a method-bind group as a free variable.
 560 That's crucial when dealing with an instance decl:
 561 \begin{verbatim}
 562         instance Foo (T a) where
 563            op x = ...
 564 \end{verbatim}
 565 This might be the {\em sole} occurrence of @op@ for an imported class @Foo@,
 566 and unless @op@ occurs we won't treat the type signature of @op@ in the class
 567 decl for @Foo@ as a source of instance-decl gates.  But we should!  Indeed,
 568 in many ways the @op@ in an instance decl is just like an occurrence, not
 569 a binder.
 570
 571 \begin{code}
 572 rnMethodBinds :: Name                   -- Class name
 573               -> (Name -> [Name])       -- Signature tyvar function
 574               -> [Name]                 -- Names for generic type variables
 575               -> LHsBinds RdrName
 576               -> RnM (LHsBinds Name, FreeVars)
 577
 578 rnMethodBinds cls sig_fn gen_tyvars binds
 579   = foldlM do_one (emptyBag,emptyFVs) (bagToList binds)
 580   where
 581     do_one (binds,fvs) bind
 582        = do { (bind', fvs_bind) <- rnMethodBind cls sig_fn gen_tyvars bind
 583             ; return (binds `unionBags` bind', fvs_bind `plusFV` fvs) }
 584
 585 rnMethodBind :: Name
 586               -> (Name -> [Name])
 587               -> [Name]
 588               -> LHsBindLR RdrName RdrName
 589               -> RnM (Bag (LHsBindLR Name Name), FreeVars)
 590 rnMethodBind cls sig_fn gen_tyvars
 591              (L loc bind@(FunBind { fun_id = name, fun_infix = is_infix
 592                                   , fun_matches = MatchGroup matches _ }))
 593   = setSrcSpan loc $ do
 594     sel_name <- wrapLocM (lookupInstDeclBndr cls) name
 595     let plain_name = unLoc sel_name
 596         -- We use the selector name as the binder
 597
 598     (new_matches, fvs) <- bindSigTyVarsFV (sig_fn plain_name) $
 599                           mapFvRn (rn_match (FunRhs plain_name is_infix)) matches
 600     let new_group = MatchGroup new_matches placeHolderType
 601
 602     when is_infix $ checkPrecMatch plain_name new_group
 603     return (unitBag (L loc (bind { fun_id      = sel_name
 604                                  , fun_matches = new_group
 605                                  , bind_fvs    = fvs })),
 606              fvs `addOneFV` plain_name)
 607         -- The 'fvs' field isn't used for method binds
 608   where
 609         -- Truly gruesome; bring into scope the correct members of the generic
 610         -- type variables.  See comments in RnSource.rnSourceDecl(ClassDecl)
 611     rn_match info match@(L _ (Match (L _ (TypePat ty) : _) _ _))
 612         = extendTyVarEnvFVRn gen_tvs    $
 613           rnMatch info match
 614         where
 615           tvs     = map (rdrNameOcc.unLoc) (extractHsTyRdrTyVars ty)
 616           gen_tvs = [tv | tv <- gen_tyvars, nameOccName tv `elem` tvs]
 617
 618     rn_match info match = rnMatch info match
 619
 620 -- Can't handle method pattern-bindings which bind multiple methods.
 621 rnMethodBind _ _ _ (L loc bind@(PatBind {})) = do
 622     addErrAt loc (methodBindErr bind)
 623     return (emptyBag, emptyFVs)
 624
 625 rnMethodBind _ _ _ b = pprPanic "rnMethodBind" (ppr b)
 626 \end{code}
 627
 628
 629
 630 %************************************************************************
 631 %*                                                                      *
 632 \subsubsection[dep-Sigs]{Signatures (and user-pragmas for values)}
 633 %*                                                                      *
 634 %************************************************************************
 635
 636 @renameSigs@ checks for:
 637 \begin{enumerate}
 638 \item more than one sig for one thing;
 639 \item signatures given for things not bound here;
 640 \end{enumerate}
 641 %
 642 At the moment we don't gather free-var info from the types in
 643 signatures.  We'd only need this if we wanted to report unused tyvars.
 644
 645 \begin{code}
 646 renameSigs :: Maybe NameSet             -- If (Just ns) complain if the sig isn't for one of ns
 647            -> (Sig RdrName -> Bool)     -- Complain about the wrong kind of signature if this is False
 648            -> [LSig RdrName]
 649            -> RnM [LSig Name]
 650 -- Renames the signatures and performs error checks
 651 renameSigs mb_names ok_sig sigs
 652   = do  { let (good_sigs, bad_sigs) = partition (ok_sig . unLoc) sigs
 653         ; mapM_ unknownSigErr bad_sigs                  -- Misplaced
 654         ; mapM_ dupSigDeclErr (findDupsEq eqHsSig sigs) -- Duplicate
 655         ; sigs' <- mapM (wrapLocM (renameSig mb_names)) good_sigs
 656         ; return sigs' }
 657
 658 ----------------------
 659 -- We use lookupSigOccRn in the signatures, which is a little bit unsatisfactory
 660 -- because this won't work for:
 661 --      instance Foo T where
 662 --        {-# INLINE op #-}
 663 --        Baz.op = ...
 664 -- We'll just rename the INLINE prag to refer to whatever other 'op'
 665 -- is in scope.  (I'm assuming that Baz.op isn't in scope unqualified.)
 666 -- Doesn't seem worth much trouble to sort this.
 667
 668 renameSig :: Maybe NameSet -> Sig RdrName -> RnM (Sig Name)
 669 -- FixitySig is renamed elsewhere.
 670 renameSig _ (IdSig x)
 671   = return (IdSig x)      -- Actually this never occurs
 672 renameSig mb_names sig@(TypeSig v ty)
 673   = do  { new_v <- lookupSigOccRn mb_names sig v
 674         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 675         ; return (TypeSig new_v new_ty) }
 676
 677 renameSig _ (SpecInstSig ty)
 678   = do  { new_ty <- rnLHsType (text "A SPECIALISE instance pragma") ty
 679         ; return (SpecInstSig new_ty) }
 680
 681 renameSig mb_names sig@(SpecSig v ty inl)
 682   = do  { new_v <- lookupSigOccRn mb_names sig v
 683         ; new_ty <- rnHsSigType (quotes (ppr v)) ty
 684         ; return (SpecSig new_v new_ty inl) }
 685
 686 renameSig mb_names sig@(InlineSig v s)
 687   = do  { new_v <- lookupSigOccRn mb_names sig v
 688         ; return (InlineSig new_v s) }
 689
 690 renameSig mb_names sig@(FixSig (FixitySig v f))
 691   = do  { new_v <- lookupSigOccRn mb_names sig v
 692         ; return (FixSig (FixitySig new_v f)) }
 693 \end{code}
 694
 695
 696 %************************************************************************
 697 %*                                                                      *
 698 \subsection{Match}
 699 %*                                                                      *
 700 %************************************************************************
 701
 702 \begin{code}
 703 rnMatchGroup :: HsMatchContext Name -> MatchGroup RdrName -> RnM (MatchGroup Name, FreeVars)
 704 rnMatchGroup ctxt (MatchGroup ms _)
 705   = do { (new_ms, ms_fvs) <- mapFvRn (rnMatch ctxt) ms
 706        ; return (MatchGroup new_ms placeHolderType, ms_fvs) }
 707
 708 rnMatch :: HsMatchContext Name -> LMatch RdrName -> RnM (LMatch Name, FreeVars)
 709 rnMatch ctxt  = wrapLocFstM (rnMatch' ctxt)
 710
 711 rnMatch' :: HsMatchContext Name -> Match RdrName -> RnM (Match Name, FreeVars)
 712 rnMatch' ctxt match@(Match pats maybe_rhs_sig grhss)
 713   = do  {       -- Result type signatures are no longer supported
 714           case maybe_rhs_sig of
 715                 Nothing -> return ()
 716                 Just (L loc ty) -> addErrAt loc (resSigErr ctxt match ty)
 717
 718                -- Now the main event
 719                -- note that there are no local ficity decls for matches
 720         ; rnPats ctxt pats      $ \ pats' -> do
 721         { (grhss', grhss_fvs) <- rnGRHSs ctxt grhss
 722
 723         ; return (Match pats' Nothing grhss', grhss_fvs) }}
 724         -- The bindPatSigTyVarsFV and rnPatsAndThen will remove the bound FVs
 725
 726 resSigErr :: HsMatchContext Name -> Match RdrName -> HsType RdrName -> SDoc
 727 resSigErr ctxt match ty
 728    = vcat [ ptext (sLit "Illegal result type signature") <+> quotes (ppr ty)
 729           , nest 2 $ ptext (sLit "Result signatures are no longer supported in pattern matches")
 730           , pprMatchInCtxt ctxt match ]
 731 \end{code}
 732
 733
 734 %************************************************************************
 735 %*                                                                      *
 736 \subsubsection{Guarded right-hand sides (GRHSs)}
 737 %*                                                                      *
 738 %************************************************************************
 739
 740 \begin{code}
 741 rnGRHSs :: HsMatchContext Name -> GRHSs RdrName -> RnM (GRHSs Name, FreeVars)
 742
 743 rnGRHSs ctxt (GRHSs grhss binds)
 744   = rnLocalBindsAndThen binds   $ \ binds' -> do
 745     (grhss', fvGRHSs) <- mapFvRn (rnGRHS ctxt) grhss
 746     return (GRHSs grhss' binds', fvGRHSs)
 747
 748 rnGRHS :: HsMatchContext Name -> LGRHS RdrName -> RnM (LGRHS Name, FreeVars)
 749 rnGRHS ctxt = wrapLocFstM (rnGRHS' ctxt)
 750
 751 rnGRHS' :: HsMatchContext Name -> GRHS RdrName -> RnM (GRHS Name, FreeVars)
 752 rnGRHS' ctxt (GRHS guards rhs)
 753   = do  { pattern_guards_allowed <- xoptM Opt_PatternGuards
 754         ; ((guards', rhs'), fvs) <- rnStmts (PatGuard ctxt) guards $
 755                                     rnLExpr rhs
 756
 757         ; unless (pattern_guards_allowed || is_standard_guard guards')
 758                  (addWarn (nonStdGuardErr guards'))
 759
 760         ; return (GRHS guards' rhs', fvs) }
 761   where
 762         -- Standard Haskell 1.4 guards are just a single boolean
 763         -- expression, rather than a list of qualifiers as in the
 764         -- Glasgow extension
 765     is_standard_guard []                     = True
 766     is_standard_guard [L _ (ExprStmt _ _ _)] = True
 767     is_standard_guard _                      = False
 768 \end{code}
 769
 770 %************************************************************************
 771 %*                                                                      *
 772 \subsection{Error messages}
 773 %*                                                                      *
 774 %************************************************************************
 775
 776 \begin{code}
 777 dupSigDeclErr :: [LSig RdrName] -> RnM ()
 778 dupSigDeclErr sigs@(L loc sig : _)
 779   = addErrAt loc $
 780         vcat [ptext (sLit "Duplicate") <+> what_it_is <> colon,
 781               nest 2 (vcat (map ppr_sig sigs))]
 782   where
 783     what_it_is = hsSigDoc sig
 784     ppr_sig (L loc sig) = ppr loc <> colon <+> ppr sig
 785 dupSigDeclErr [] = panic "dupSigDeclErr"
 786
 787 unknownSigErr :: LSig RdrName -> RnM ()
 788 unknownSigErr (L loc sig)
 789   = addErrAt loc $
 790     sep [ptext (sLit "Misplaced") <+> hsSigDoc sig <> colon, ppr sig]
 791
 792 methodBindErr :: HsBindLR RdrName RdrName -> SDoc
 793 methodBindErr mbind
 794  =  hang (ptext (sLit "Pattern bindings (except simple variables) not allowed in instance declarations"))
 795        2 (ppr mbind)
 796
 797 bindsInHsBootFile :: LHsBindsLR Name RdrName -> SDoc
 798 bindsInHsBootFile mbinds
 799   = hang (ptext (sLit "Bindings in hs-boot files are not allowed"))
 800        2 (ppr mbinds)
 801
 802 nonStdGuardErr :: [LStmtLR Name Name] -> SDoc
 803 nonStdGuardErr guards
 804   = hang (ptext (sLit "accepting non-standard pattern guards (use -XPatternGuards to suppress this message)"))
 805        4 (interpp'SP guards)
 806 \end{code}