compiler/rename/RnNames.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnNames]{Extracting imported and top-level names in scope}
   5
   6 \begin{code}
   7 module RnNames (
   8         rnImports, mkRdrEnvAndImports, importsFromLocalDecls,
   9         rnExports, mkExportNameSet,
  10         getLocalDeclBinders, extendRdrEnvRn,
  11         reportUnusedNames, reportDeprecations
  12     ) where
  13
  14 #include "HsVersions.h"
  15
  16 import DynFlags         ( DynFlag(..), GhcMode(..), DynFlags(..) )
  17 import HsSyn            ( IE(..), ieName, ImportDecl(..), LImportDecl,
  18                           ForeignDecl(..), HsGroup(..), HsValBinds(..),
  19                           Sig(..), collectHsBindLocatedBinders, tyClDeclNames,
  20                           instDeclATs, isIdxTyDecl,
  21                           LIE )
  22 import RnEnv
  23 import IfaceEnv         ( ifaceExportNames )
  24 import LoadIface        ( loadSrcInterface )
  25 import TcRnMonad hiding (LIE)
  26
  27 import FiniteMap
  28 import PrelNames
  29 import Module
  30 import Name             ( Name, nameSrcLoc, nameOccName, nameModule, isWiredInName,
  31                           nameParent, nameParent_maybe, isExternalName,
  32                           isBuiltInSyntax, isTyConName )
  33 import NameSet
  34 import NameEnv
  35 import OccName          ( srcDataName, isTcOcc, pprNonVarNameSpace,
  36                           occNameSpace,
  37                           OccEnv, mkOccEnv, lookupOccEnv, emptyOccEnv,
  38                           extendOccEnv )
  39 import HscTypes         ( GenAvailInfo(..), AvailInfo,
  40                           HomePackageTable, PackageIfaceTable,
  41                           mkPrintUnqualified,
  42                           Deprecs(..), ModIface(..), Dependencies(..),
  43                           lookupIfaceByModule, ExternalPackageState(..)
  44                         )
  45 import RdrName          ( RdrName, rdrNameOcc, setRdrNameSpace,
  46                           GlobalRdrEnv, mkGlobalRdrEnv, GlobalRdrElt(..),
  47                           emptyGlobalRdrEnv, plusGlobalRdrEnv, globalRdrEnvElts,
  48                           extendGlobalRdrEnv, lookupGlobalRdrEnv, unQualOK, lookupGRE_Name,
  49                           Provenance(..), ImportSpec(..), ImpDeclSpec(..), ImpItemSpec(..),
  50                           importSpecLoc, importSpecModule, isLocalGRE, pprNameProvenance )
  51 import Outputable
  52 import UniqFM
  53 import Maybes           ( isNothing, catMaybes, mapCatMaybes, seqMaybe, orElse )
  54 import SrcLoc           ( Located(..), mkGeneralSrcSpan,
  55                           unLoc, noLoc, srcLocSpan, SrcSpan )
  56 import BasicTypes       ( DeprecTxt )
  57 import DriverPhases     ( isHsBoot )
  58 import Util             ( notNull )
  59 import List             ( partition )
  60 import IO               ( openFile, IOMode(..) )
  61 import Monad            ( liftM, when )
  62 \end{code}
  63
  64
  65
  66 %************************************************************************
  67 %*                                                                      *
  68                 rnImports
  69 %*                                                                      *
  70 %************************************************************************
  71
  72 \begin{code}
  73 rnImports :: [LImportDecl RdrName] -> RnM [LImportDecl Name]
  74 rnImports imports
  75          -- PROCESS IMPORT DECLS
  76          -- Do the non {- SOURCE -} ones first, so that we get a helpful
  77          -- warning for {- SOURCE -} ones that are unnecessary
  78     = do this_mod <- getModule
  79          implicit_prelude <- doptM Opt_ImplicitPrelude
  80          let all_imports               = mk_prel_imports this_mod implicit_prelude ++ imports
  81              (source, ordinary) = partition is_source_import all_imports
  82              is_source_import (L _ (ImportDecl _ is_boot _ _ _)) = is_boot
  83              get_imports = rnImportDecl this_mod
  84
  85          stuff1 <- mapM get_imports ordinary
  86          stuff2 <- mapM get_imports source
  87          return (stuff1 ++ stuff2)
  88     where
  89 -- NB: opt_NoImplicitPrelude is slightly different to import Prelude ();
  90 -- because the former doesn't even look at Prelude.hi for instance
  91 -- declarations, whereas the latter does.
  92    mk_prel_imports this_mod implicit_prelude
  93        |  this_mod == pRELUDE
  94           || explicit_prelude_import
  95           || not implicit_prelude
  96            = []
  97        | otherwise = [preludeImportDecl]
  98    explicit_prelude_import
  99        = notNull [ () | L _ (ImportDecl mod _ _ _ _) <- imports,
 100                    unLoc mod == pRELUDE_NAME ]
 101
 102 preludeImportDecl :: LImportDecl RdrName
 103 preludeImportDecl
 104   = L loc $
 105         ImportDecl (L loc pRELUDE_NAME)
 106                False {- Not a boot interface -}
 107                False    {- Not qualified -}
 108                Nothing  {- No "as" -}
 109                Nothing  {- No import list -}
 110   where
 111     loc = mkGeneralSrcSpan FSLIT("Implicit import declaration")
 112
 113 mkRdrEnvAndImports :: [LImportDecl Name] -> RnM (GlobalRdrEnv, ImportAvails)
 114 mkRdrEnvAndImports imports
 115   = do this_mod <- getModule
 116        let get_imports = importsFromImportDecl this_mod
 117        stuff <- mapM get_imports imports
 118        let (imp_gbl_envs, imp_avails) = unzip stuff
 119            gbl_env :: GlobalRdrEnv
 120            gbl_env = foldr plusGlobalRdrEnv emptyGlobalRdrEnv imp_gbl_envs
 121
 122            all_avails :: ImportAvails
 123            all_avails = foldr plusImportAvails emptyImportAvails imp_avails
 124        -- ALL DONE
 125        return (gbl_env, all_avails)
 126
 127 \end{code}
 128
 129 \begin{code}
 130 rnImportDecl :: Module
 131              -> LImportDecl RdrName
 132              -> RnM (LImportDecl Name)
 133 rnImportDecl this_mod (L loc importDecl@(ImportDecl loc_imp_mod_name want_boot qual_only as_mod imp_details))
 134     = setSrcSpan loc $
 135       do iface <- loadSrcInterface doc imp_mod_name want_boot
 136          let qual_mod_name = case as_mod of
 137                                Nothing           -> imp_mod_name
 138                                Just another_name -> another_name
 139              imp_spec  = ImpDeclSpec { is_mod = imp_mod_name, is_qual = qual_only,
 140                                        is_dloc = loc, is_as = qual_mod_name }
 141          total_avails <- ifaceExportNames (mi_exports iface)
 142          importDecl' <- rnImportDecl' iface imp_spec importDecl total_avails
 143          return (L loc importDecl')
 144     where imp_mod_name = unLoc loc_imp_mod_name
 145           doc = ppr imp_mod_name <+> ptext SLIT("is directly imported")
 146
 147 rnImportDecl' :: ModIface -> ImpDeclSpec -> ImportDecl RdrName -> NameSet -> RnM (ImportDecl Name)
 148 rnImportDecl' iface decl_spec (ImportDecl mod_name want_boot qual_only as_mod Nothing) all_names
 149     = return $ ImportDecl mod_name want_boot qual_only as_mod Nothing
 150 rnImportDecl' iface decl_spec (ImportDecl mod_name want_boot qual_only as_mod (Just (want_hiding,import_items))) all_names
 151     = do import_items_mbs <- mapM (srcSpanWrapper) import_items
 152          let rn_import_items = concat . catMaybes $ import_items_mbs
 153          return $ ImportDecl mod_name want_boot qual_only as_mod (Just (want_hiding,rn_import_items))
 154     where
 155     srcSpanWrapper (L span ieRdr)
 156         = case get_item ieRdr of
 157             Nothing
 158                 -> do addErrAt span (badImportItemErr iface decl_spec ieRdr)
 159                       return Nothing
 160             Just ieNames
 161                 -> return (Just [L span ie | ie <- ieNames])
 162     occ_env :: OccEnv Name      -- Maps OccName to corresponding Name
 163     occ_env = mkOccEnv [(nameOccName n, n) | n <- nameSetToList all_names]
 164         -- This env will have entries for data constructors too,
 165         -- they won't make any difference because naked entities like T
 166         -- in an import list map to TcOccs, not VarOccs.
 167
 168     sub_env :: NameEnv [Name]
 169     sub_env = mkSubNameEnv all_names
 170
 171     get_item :: IE RdrName -> Maybe [IE Name]
 172         -- Empty result for a bad item.
 173         -- Singleton result is typical case.
 174         -- Can have two when we are hiding, and mention C which might be
 175         --      both a class and a data constructor.
 176     get_item item@(IEModuleContents _)
 177         = Nothing
 178     get_item (IEThingAll tc)
 179         = do name <- check_name tc
 180              return [IEThingAll name]
 181     get_item (IEThingAbs tc)
 182         | want_hiding   -- hiding ( C )
 183                         -- Here the 'C' can be a data constructor
 184                         --  *or* a type/class, or even both
 185             = case catMaybes [check_name tc, check_name (setRdrNameSpace tc srcDataName)] of
 186                 []    -> Nothing
 187                 names -> return [ IEThingAbs n | n <- names ]
 188         | otherwise
 189             = do name <- check_name tc
 190                  return [IEThingAbs name]
 191     get_item (IEThingWith n ns) -- import (C (A,B))
 192         = do name <- check_name n
 193              let env = mkOccEnv [(nameOccName s, s) | s <- subNames sub_env name]
 194                  mb_names = map (lookupOccEnv env . rdrNameOcc) ns
 195              names <- sequence mb_names
 196              return [IEThingWith name names]
 197     get_item (IEVar n)
 198         = do name <- check_name n
 199              return [IEVar name]
 200
 201     check_name :: RdrName -> Maybe Name
 202     check_name rdrName
 203         = lookupOccEnv occ_env (rdrNameOcc rdrName)
 204
 205
 206 importsFromImportDecl :: Module
 207                       -> LImportDecl Name
 208                       -> RnM (GlobalRdrEnv, ImportAvails)
 209
 210 importsFromImportDecl this_mod
 211         (L loc (ImportDecl loc_imp_mod_name want_boot qual_only as_mod imp_details))
 212   =
 213     setSrcSpan loc $
 214
 215         -- If there's an error in loadInterface, (e.g. interface
 216         -- file not found) we get lots of spurious errors from 'filterImports'
 217     let
 218         imp_mod_name = unLoc loc_imp_mod_name
 219         doc = ppr imp_mod_name <+> ptext SLIT("is directly imported")
 220     in
 221     loadSrcInterface doc imp_mod_name want_boot `thenM` \ iface ->
 222
 223         -- Compiler sanity check: if the import didn't say
 224         -- {-# SOURCE #-} we should not get a hi-boot file
 225     WARN( not want_boot && mi_boot iface, ppr imp_mod_name )
 226
 227         -- Issue a user warning for a redundant {- SOURCE -} import
 228         -- NB that we arrange to read all the ordinary imports before
 229         -- any of the {- SOURCE -} imports
 230     warnIf (want_boot && not (mi_boot iface))
 231            (warnRedundantSourceImport imp_mod_name)     `thenM_`
 232
 233     let
 234         imp_mod = mi_module iface
 235         deprecs = mi_deprecs iface
 236         is_orph = mi_orphan iface
 237         deps    = mi_deps iface
 238
 239         filtered_exports = filter not_this_mod (mi_exports iface)
 240         not_this_mod (mod,_) = mod /= this_mod
 241         -- If the module exports anything defined in this module, just ignore it.
 242         -- Reason: otherwise it looks as if there are two local definition sites
 243         -- for the thing, and an error gets reported.  Easiest thing is just to
 244         -- filter them out up front. This situation only arises if a module
 245         -- imports itself, or another module that imported it.  (Necessarily,
 246         -- this invoves a loop.)
 247         --
 248         -- Tiresome consequence: if you say
 249         --      module A where
 250         --         import B( AType )
 251         --         type AType = ...
 252         --
 253         --      module B( AType ) where
 254         --         import {-# SOURCE #-} A( AType )
 255         --
 256         -- then you'll get a 'B does not export AType' message.  Oh well.
 257
 258         qual_mod_name = case as_mod of
 259                           Nothing           -> imp_mod_name
 260                           Just another_name -> another_name
 261         imp_spec  = ImpDeclSpec { is_mod = imp_mod_name, is_qual = qual_only,
 262                                   is_dloc = loc, is_as = qual_mod_name }
 263     in
 264         -- Get the total imports, and filter them according to the import list
 265     ifaceExportNames filtered_exports           `thenM` \ total_avails ->
 266     filterImports iface imp_spec
 267                   imp_details total_avails      `thenM` \ (avail_env, gbl_env) ->
 268
 269     getDOpts `thenM` \ dflags ->
 270
 271     let
 272         -- Compute new transitive dependencies
 273
 274         orphans | is_orph   = ASSERT( not (imp_mod `elem` dep_orphs deps) )
 275                               imp_mod : dep_orphs deps
 276                 | otherwise = dep_orphs deps
 277
 278         pkg = modulePackageId (mi_module iface)
 279
 280         (dependent_mods, dependent_pkgs)
 281            | pkg == thisPackage dflags =
 282                 -- Imported module is from the home package
 283                 -- Take its dependent modules and add imp_mod itself
 284                 -- Take its dependent packages unchanged
 285                 --
 286                 -- NB: (dep_mods deps) might include a hi-boot file
 287                 -- for the module being compiled, CM. Do *not* filter
 288                 -- this out (as we used to), because when we've
 289                 -- finished dealing with the direct imports we want to
 290                 -- know if any of them depended on CM.hi-boot, in
 291                 -- which case we should do the hi-boot consistency
 292                 -- check.  See LoadIface.loadHiBootInterface
 293                   ((imp_mod_name, want_boot) : dep_mods deps, dep_pkgs deps)
 294
 295            | otherwise =
 296                 -- Imported module is from another package
 297                 -- Dump the dependent modules
 298                 -- Add the package imp_mod comes from to the dependent packages
 299                  ASSERT2( not (pkg `elem` dep_pkgs deps), ppr pkg <+> ppr (dep_pkgs deps) )
 300                  ([], pkg : dep_pkgs deps)
 301
 302         -- True <=> import M ()
 303         import_all = case imp_details of
 304                         Just (is_hiding, ls) -> not is_hiding && null ls
 305                         other                -> False
 306
 307         -- unqual_avails is the Avails that are visible in *unqualified* form
 308         -- We need to know this so we know what to export when we see
 309         --      module M ( module P ) where ...
 310         -- Then we must export whatever came from P unqualified.
 311         imports   = ImportAvails {
 312                         imp_env      = unitUFM qual_mod_name avail_env,
 313                         imp_mods     = unitModuleEnv imp_mod (imp_mod, import_all, loc),
 314                         imp_orphs    = orphans,
 315                         imp_dep_mods = mkModDeps dependent_mods,
 316                         imp_dep_pkgs = dependent_pkgs }
 317
 318     in
 319         -- Complain if we import a deprecated module
 320     ifOptM Opt_WarnDeprecations (
 321        case deprecs of
 322           DeprecAll txt -> addWarn (moduleDeprec imp_mod_name txt)
 323           other         -> returnM ()
 324     )                                                   `thenM_`
 325
 326     returnM (gbl_env, imports)
 327
 328 warnRedundantSourceImport mod_name
 329   = ptext SLIT("Unnecessary {-# SOURCE #-} in the import of module")
 330           <+> quotes (ppr mod_name)
 331 \end{code}
 332
 333
 334 %************************************************************************
 335 %*                                                                      *
 336                 importsFromLocalDecls
 337 %*                                                                      *
 338 %************************************************************************
 339
 340 From the top-level declarations of this module produce
 341         * the lexical environment
 342         * the ImportAvails
 343 created by its bindings.
 344
 345 Complain about duplicate bindings
 346
 347 \begin{code}
 348 importsFromLocalDecls :: HsGroup RdrName -> RnM TcGblEnv
 349 importsFromLocalDecls group
 350   = do  { gbl_env  <- getGblEnv
 351
 352         ; names <- getLocalDeclBinders gbl_env group
 353
 354         ; implicit_prelude <- doptM Opt_ImplicitPrelude
 355         ; let {
 356             -- Optimisation: filter out names for built-in syntax
 357             -- They just clutter up the environment (esp tuples), and the parser
 358             -- will generate Exact RdrNames for them, so the cluttered
 359             -- envt is no use.  To avoid doing this filter all the time,
 360             -- we use -fno-implicit-prelude as a clue that the filter is
 361             -- worth while.  Really, it's only useful for GHC.Base and GHC.Tuple.
 362             --
 363             -- It's worth doing because it makes the environment smaller for
 364             -- every module that imports the Prelude
 365             --
 366             -- Note: don't filter the gbl_env (hence all_names, not filered_all_names
 367             -- in defn of gres above).      Stupid reason: when parsing
 368             -- data type decls, the constructors start as Exact tycon-names,
 369             -- and then get turned into data con names by zapping the name space;
 370             -- but that stops them being Exact, so they get looked up.
 371             -- Ditto in fixity decls; e.g.      infix 5 :
 372             -- Sigh. It doesn't matter because it only affects the Data.Tuple really.
 373             -- The important thing is to trim down the exports.
 374               filtered_names
 375                 | implicit_prelude = names
 376                 | otherwise        = filter (not . isBuiltInSyntax) names ;
 377
 378             ; this_mod = tcg_mod gbl_env
 379             ; imports = emptyImportAvails {
 380                           imp_env = unitUFM (moduleName this_mod) $
 381                                     mkNameSet filtered_names
 382                         }
 383             }
 384
 385         ; rdr_env' <- extendRdrEnvRn (tcg_rdr_env gbl_env) names
 386
 387         ; returnM (gbl_env { tcg_rdr_env = rdr_env',
 388                              tcg_imports = imports `plusImportAvails` tcg_imports gbl_env })
 389         }
 390
 391 extendRdrEnvRn :: GlobalRdrEnv -> [Name] -> RnM GlobalRdrEnv
 392 -- Add the new locally-bound names one by one, checking for duplicates as
 393 -- we do so.  Remember that in Template Haskell the duplicates
 394 -- might *already be* in the GlobalRdrEnv from higher up the module
 395 extendRdrEnvRn rdr_env names
 396   = foldlM add_local rdr_env names
 397   where
 398     add_local rdr_env name
 399         | gres <- lookupGlobalRdrEnv rdr_env (nameOccName name)
 400         , (dup_gre:_) <- filter isLocalGRE gres -- Check for existing *local* defns
 401         = do { addDupDeclErr (gre_name dup_gre) name
 402              ; return rdr_env }
 403         | otherwise
 404         = return (extendGlobalRdrEnv rdr_env new_gre)
 405         where
 406           new_gre = GRE {gre_name = name, gre_prov = LocalDef}
 407 \end{code}
 408
 409 @getLocalDeclBinders@ returns the names for an @HsDecl@.  It's
 410 used for source code.
 411
 412         *** See "THE NAMING STORY" in HsDecls ****
 413
 414 Instances of indexed types
 415 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 416 Indexed data/newtype instances contain data constructors that we need to
 417 collect, too.  Moreover, we need to descend into the data/newtypes instances
 418 of associated families.
 419
 420 We need to be careful with the handling of the type constructor of each type
 421 instance as the family constructor is already defined, and we want to avoid
 422 raising a duplicate declaration error.  So, we make a new name for it, but
 423 don't return it in the 'AvailInfo'.
 424
 425 \begin{code}
 426 getLocalDeclBinders :: TcGblEnv -> HsGroup RdrName -> RnM [Name]
 427 getLocalDeclBinders gbl_env (HsGroup {hs_valds = ValBindsIn val_decls val_sigs,
 428                                       hs_tyclds = tycl_decls,
 429                                       hs_instds = inst_decls,
 430                                       hs_fords = foreign_decls })
 431   = do  { tc_names_s <- mappM new_tc tycl_decls
 432         ; at_names_s <- mappM inst_ats inst_decls
 433         ; val_names  <- mappM new_simple val_bndrs
 434         ; return (foldr (++) val_names (tc_names_s ++ concat at_names_s)) }
 435   where
 436     mod        = tcg_mod gbl_env
 437     is_hs_boot = isHsBoot (tcg_src gbl_env) ;
 438     val_bndrs | is_hs_boot = sig_hs_bndrs
 439               | otherwise  = for_hs_bndrs ++ val_hs_bndrs
 440         -- In a hs-boot file, the value binders come from the
 441         --  *signatures*, and there should be no foreign binders
 442
 443     new_simple rdr_name = newTopSrcBinder mod Nothing rdr_name
 444
 445     sig_hs_bndrs = [nm | L _ (TypeSig nm _) <- val_sigs]
 446     val_hs_bndrs = collectHsBindLocatedBinders val_decls
 447     for_hs_bndrs = [nm | L _ (ForeignImport nm _ _) <- foreign_decls]
 448
 449     new_tc tc_decl
 450         = do { main_name <- newTopSrcBinder mod Nothing main_rdr
 451              ; sub_names <- mappM (newTopSrcBinder mod (Just main_name)) sub_rdrs
 452              ; if isIdxTyDecl (unLoc tc_decl)      -- index type definitions
 453                then return (            sub_names) -- are usage occurences
 454                else return (main_name : sub_names) }
 455         where
 456           (main_rdr : sub_rdrs) = tyClDeclNames (unLoc tc_decl)
 457
 458     inst_ats inst_decl
 459         = mappM new_tc (instDeclATs (unLoc inst_decl))
 460 \end{code}
 461
 462
 463 %************************************************************************
 464 %*                                                                      *
 465 \subsection{Filtering imports}
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 @filterImports@ takes the @ExportEnv@ telling what the imported module makes
 470 available, and filters it through the import spec (if any).
 471
 472 \begin{code}
 473 filterImports :: ModIface
 474               -> ImpDeclSpec                    -- The span for the entire import decl
 475               -> Maybe (Bool, [LIE Name])       -- Import spec; True => hiding
 476               -> NameSet                        -- What's available
 477               -> RnM (NameSet,                  -- What's imported (qualified or unqualified)
 478                       GlobalRdrEnv)             -- Same again, but in GRE form
 479
 480         -- Complains if import spec mentions things that the module doesn't export
 481         -- Warns/informs if import spec contains duplicates.
 482
 483 mkGenericRdrEnv decl_spec names
 484   = mkGlobalRdrEnv [ GRE { gre_name = name, gre_prov = Imported [imp_spec] }
 485                    | name <- nameSetToList names ]
 486   where
 487     imp_spec = ImpSpec { is_decl = decl_spec, is_item = ImpAll }
 488
 489 filterImports iface decl_spec Nothing all_names
 490   = return (all_names, mkGenericRdrEnv decl_spec all_names)
 491
 492 filterImports iface decl_spec (Just (want_hiding, import_items)) all_names
 493   = mapM (addLocM get_item) import_items >>= \gres_s ->
 494     let gres = concat gres_s
 495         specified_names = mkNameSet (map gre_name gres)
 496     in if not want_hiding then
 497        return (specified_names, mkGlobalRdrEnv gres)
 498     else let keep n = not (n `elemNameSet` specified_names)
 499              pruned_avails = filterNameSet keep all_names
 500          in return (pruned_avails, mkGenericRdrEnv decl_spec pruned_avails)
 501   where
 502     sub_env :: NameEnv [Name]   -- Classify each name by its parent
 503     sub_env = mkSubNameEnv all_names
 504
 505     succeed_with :: Bool -> [Name] -> RnM [GlobalRdrElt]
 506     succeed_with all_explicit names
 507       = do { loc <- getSrcSpanM
 508            ; returnM (map (mk_gre loc) names) }
 509       where
 510         mk_gre loc name = GRE { gre_name = name,
 511                                 gre_prov = Imported [imp_spec] }
 512           where
 513             imp_spec  = ImpSpec { is_decl = decl_spec, is_item = item_spec }
 514             item_spec = ImpSome { is_explicit = explicit, is_iloc = loc }
 515             explicit  = all_explicit || isNothing (nameParent_maybe name)
 516
 517     get_item :: IE Name -> RnM [GlobalRdrElt]
 518         -- Empty result for a bad item.
 519         -- Singleton result is typical case.
 520         -- Can have two when we are hiding, and mention C which might be
 521         --      both a class and a data constructor.
 522     get_item item@(IEModuleContents _)
 523         -- This case should be filtered out by 'rnImports'.
 524         = panic "filterImports: IEModuleContents?"
 525
 526     get_item (IEThingAll name)
 527         = case subNames sub_env name of
 528             [] ->       -- This occurs when you import T(..), but
 529                         -- only export T abstractly.
 530                   do ifOptM Opt_WarnDodgyImports (addWarn (dodgyImportWarn name))
 531                      succeed_with False [name]
 532             names -> succeed_with False (name:names)
 533
 534     get_item (IEThingAbs name)
 535         = succeed_with True [name]
 536
 537     get_item (IEThingWith name names)
 538         = do { optIdxTypes <- doptM Opt_IndexedTypes
 539              ; when (not optIdxTypes && any isTyConName names) $
 540                  addErr (typeItemErr (head . filter isTyConName $ names )
 541                                      (text "in import list"))
 542              ; succeed_with True (name:names) }
 543     get_item (IEVar name)
 544         = succeed_with True [name]
 545
 546 \end{code}
 547
 548
 549 %************************************************************************
 550 %*                                                                      *
 551 \subsection{Export list processing}
 552 %*                                                                      *
 553 %************************************************************************
 554
 555 Processing the export list.
 556
 557 You might think that we should record things that appear in the export
 558 list as ``occurrences'' (using @addOccurrenceName@), but you'd be
 559 wrong.  We do check (here) that they are in scope, but there is no
 560 need to slurp in their actual declaration (which is what
 561 @addOccurrenceName@ forces).
 562
 563 Indeed, doing so would big trouble when compiling @PrelBase@, because
 564 it re-exports @GHC@, which includes @takeMVar#@, whose type includes
 565 @ConcBase.StateAndSynchVar#@, and so on...
 566
 567 \begin{code}
 568 type ExportAccum        -- The type of the accumulating parameter of
 569                         -- the main worker function in rnExports
 570      = ([ModuleName],           -- 'module M's seen so far
 571         ExportOccMap,           -- Tracks exported occurrence names
 572         NameSet)                -- The accumulated exported stuff
 573 emptyExportAccum = ([], emptyOccEnv, emptyNameSet)
 574
 575 type ExportOccMap = OccEnv (Name, IE RdrName)
 576         -- Tracks what a particular exported OccName
 577         --   in an export list refers to, and which item
 578         --   it came from.  It's illegal to export two distinct things
 579         --   that have the same occurrence name
 580
 581 rnExports :: Maybe [LIE RdrName]
 582           -> RnM (Maybe [LIE Name])
 583 rnExports Nothing = return Nothing
 584 rnExports (Just exports)
 585   = do TcGblEnv { tcg_imports = ImportAvails { imp_env = imp_env } } <- getGblEnv
 586        let sub_env :: NameEnv [Name]    -- Classify each name by its parent
 587            sub_env = mkSubNameEnv (foldUFM unionNameSets emptyNameSet imp_env)
 588            rnExport (IEVar rdrName)
 589                = do name <- lookupGlobalOccRn rdrName
 590                     return (IEVar name)
 591            rnExport (IEThingAbs rdrName)
 592                = do name <- lookupGlobalOccRn rdrName
 593                     return (IEThingAbs name)
 594            rnExport (IEThingAll rdrName)
 595                = do name <- lookupGlobalOccRn rdrName
 596                     return (IEThingAll name)
 597            rnExport ie@(IEThingWith rdrName rdrNames)
 598                = do name <- lookupGlobalOccRn rdrName
 599                     if isUnboundName name
 600                        then return (IEThingWith name [])
 601                        else do
 602                     let env = mkOccEnv [(nameOccName s, s) | s <- subNames sub_env name]
 603                         mb_names = map (lookupOccEnv env . rdrNameOcc) rdrNames
 604                     if any isNothing mb_names
 605                       then do addErr (exportItemErr ie)
 606                               return (IEThingWith name [])
 607                       else do let names = catMaybes mb_names
 608                               optIdxTypes <- doptM Opt_IndexedTypes
 609                               when (not optIdxTypes && any isTyConName names) $
 610                                 addErr (typeItemErr (  head
 611                                                      . filter isTyConName
 612                                                      $ names )
 613                                                      (text "in export list"))
 614                               return (IEThingWith name names)
 615            rnExport (IEModuleContents mod)
 616                = return (IEModuleContents mod)
 617        rn_exports <- mapM (wrapLocM rnExport) exports
 618        return (Just rn_exports)
 619
 620 mkExportNameSet :: Bool  -- False => no 'module M(..) where' header at all
 621                 -> Maybe ([LIE Name], [LIE RdrName]) -- Nothing => no explicit export list
 622                 -> RnM NameSet
 623         -- Complains if two distinct exports have same OccName
 624         -- Warns about identical exports.
 625         -- Complains about exports items not in scope
 626
 627 mkExportNameSet explicit_mod exports
 628  = do TcGblEnv { tcg_rdr_env = rdr_env,
 629                  tcg_imports = imports } <- getGblEnv
 630
 631         -- If the module header is omitted altogether, then behave
 632         -- as if the user had written "module Main(main) where..."
 633         -- EXCEPT in interactive mode, when we behave as if he had
 634         -- written "module Main where ..."
 635         -- Reason: don't want to complain about 'main' not in scope
 636         --         in interactive mode
 637       ghc_mode <- getGhcMode
 638       real_exports <- case () of
 639                         () | explicit_mod
 640                                -> return exports
 641                            | ghc_mode == Interactive
 642                                -> return Nothing
 643                            | otherwise
 644                                -> do mainName <- lookupGlobalOccRn main_RDR_Unqual
 645                                      return (Just ([noLoc (IEVar mainName)]
 646                                                   ,[noLoc (IEVar main_RDR_Unqual)]))
 647                 -- ToDo: the 'noLoc' here is unhelpful if 'main' turns out to be out of scope
 648       exports_from_avail real_exports rdr_env imports
 649
 650
 651 exports_from_avail Nothing rdr_env imports
 652  =      -- Export all locally-defined things
 653         -- We do this by filtering the global RdrEnv,
 654         -- keeping only things that are locally-defined
 655    return (mkNameSet [ gre_name gre
 656                      | gre <- globalRdrEnvElts rdr_env,
 657                        isLocalGRE gre ])
 658
 659 exports_from_avail (Just (items,origItems)) rdr_env (ImportAvails { imp_env = imp_env })
 660   = do (_, _, exports) <- foldlM do_litem emptyExportAccum (zip items origItems)
 661        return exports
 662   where
 663     sub_env :: NameEnv [Name]   -- Classify each name by its parent
 664     sub_env = mkSubNameEnv (foldUFM unionNameSets emptyNameSet imp_env)
 665
 666     do_litem :: ExportAccum -> (LIE Name, LIE RdrName) -> RnM ExportAccum
 667     do_litem acc (ieName, ieRdr)
 668         = addLocM (exports_from_item acc (unLoc ieRdr)) ieName
 669
 670     exports_from_item :: ExportAccum -> IE RdrName -> IE Name -> RnM ExportAccum
 671     exports_from_item acc@(mods, occs, exports) ieRdr@(IEModuleContents mod) ie
 672         | mod `elem` mods       -- Duplicate export of M
 673         = do { warn_dup_exports <- doptM Opt_WarnDuplicateExports ;
 674                warnIf warn_dup_exports (dupModuleExport mod) ;
 675                returnM acc }
 676
 677         | otherwise
 678         = case lookupUFM imp_env mod of
 679             Nothing -> do addErr (modExportErr mod)
 680                           return acc
 681             Just names
 682                 -> do let new_exports = filterNameSet (inScopeUnqual rdr_env) names
 683                       -- This check_occs not only finds conflicts between this item
 684                       -- and others, but also internally within this item.  That is,
 685                       -- if 'M.x' is in scope in several ways, we'll have several
 686                       -- members of mod_avails with the same OccName.
 687                       occs' <- check_occs ieRdr occs (nameSetToList new_exports)
 688                       return (mod:mods, occs', exports `unionNameSets` new_exports)
 689
 690     exports_from_item acc@(mods, occs, exports) ieRdr ie
 691         = if isUnboundName (ieName ie)
 692           then return acc       -- Avoid error cascade
 693           else let new_exports = filterAvail ie sub_env in
 694           do -- checkErr (not (null (drop 1 new_exports))) (exportItemErr ie)
 695              checkForDodgyExport ie new_exports
 696              occs' <- check_occs ieRdr occs new_exports
 697              return (mods, occs', addListToNameSet exports new_exports)
 698
 699 -------------------------------
 700 filterAvail :: IE Name          -- Wanted
 701             -> NameEnv [Name]   -- Maps type/class names to their sub-names
 702             -> [Name]
 703
 704 filterAvail (IEVar n)          subs = [n]
 705 filterAvail (IEThingAbs n)     subs = [n]
 706 filterAvail (IEThingAll n)     subs = n : subNames subs n
 707 filterAvail (IEThingWith n ns) subs = n : ns
 708 filterAvail (IEModuleContents _) _  = panic "filterAvail"
 709
 710 subNames :: NameEnv [Name] -> Name -> [Name]
 711 subNames env n = lookupNameEnv env n `orElse` []
 712
 713 mkSubNameEnv :: NameSet -> NameEnv [Name]
 714 -- Maps types and classes to their constructors/classops respectively
 715 -- This mapping just makes it easier to deal with A(..) export items
 716 mkSubNameEnv names
 717   = foldNameSet add_name emptyNameEnv names
 718   where
 719     add_name name env
 720         | Just parent <- nameParent_maybe name
 721         = extendNameEnv_C (\ns _ -> name:ns) env parent [name]
 722         | otherwise = env
 723
 724 -------------------------------
 725 inScopeUnqual :: GlobalRdrEnv -> Name -> Bool
 726 -- Checks whether the Name is in scope unqualified,
 727 -- regardless of whether it's ambiguous or not
 728 inScopeUnqual env n = any unQualOK (lookupGRE_Name env n)
 729
 730 -------------------------------
 731 checkForDodgyExport :: IE Name -> [Name] -> RnM ()
 732 checkForDodgyExport ie@(IEThingAll tc) [n]
 733   | isTcOcc (nameOccName n) = addWarn (dodgyExportWarn tc)
 734         -- This occurs when you export T(..), but
 735         -- only import T abstractly, or T is a synonym.
 736         -- The single [n] is the type or class itself
 737   | otherwise = addErr (exportItemErr ie)
 738         -- This happes if you export x(..), which is bogus
 739 checkForDodgyExport _ _ = return ()
 740
 741 -------------------------------
 742 check_occs :: IE RdrName -> ExportOccMap -> [Name] -> RnM ExportOccMap
 743 check_occs ie occs names
 744   = foldlM check occs names
 745   where
 746     check occs name
 747       = case lookupOccEnv occs name_occ of
 748           Nothing -> returnM (extendOccEnv occs name_occ (name, ie))
 749
 750           Just (name', ie')
 751             | name == name'     -- Duplicate export
 752             ->  do { warn_dup_exports <- doptM Opt_WarnDuplicateExports ;
 753                      warnIf warn_dup_exports (dupExportWarn name_occ ie ie') ;
 754                      returnM occs }
 755
 756             | otherwise         -- Same occ name but different names: an error
 757             ->  do { global_env <- getGlobalRdrEnv ;
 758                      addErr (exportClashErr global_env name' name ie' ie) ;
 759                      returnM occs }
 760       where
 761         name_occ = nameOccName name
 762 \end{code}
 763
 764 %*********************************************************
 765 %*                                                       *
 766                 Deprecations
 767 %*                                                       *
 768 %*********************************************************
 769
 770 \begin{code}
 771 reportDeprecations :: DynFlags -> TcGblEnv -> RnM ()
 772 reportDeprecations dflags tcg_env
 773   = ifOptM Opt_WarnDeprecations $
 774     do  { (eps,hpt) <- getEpsAndHpt
 775                 -- By this time, typechecking is complete,
 776                 -- so the PIT is fully populated
 777         ; mapM_ (check hpt (eps_PIT eps)) all_gres }
 778   where
 779     used_names = allUses (tcg_dus tcg_env)
 780         -- Report on all deprecated uses; hence allUses
 781     all_gres   = globalRdrEnvElts (tcg_rdr_env tcg_env)
 782
 783     check hpt pit (GRE {gre_name = name, gre_prov = Imported (imp_spec:_)})
 784       | name `elemNameSet` used_names
 785       , Just deprec_txt <- lookupDeprec dflags hpt pit name
 786       = addWarnAt (importSpecLoc imp_spec)
 787                   (sep [ptext SLIT("Deprecated use of") <+>
 788                         pprNonVarNameSpace (occNameSpace (nameOccName name)) <+>
 789                         quotes (ppr name),
 790                       (parens imp_msg) <> colon,
 791                       (ppr deprec_txt) ])
 792         where
 793           name_mod = nameModule name
 794           imp_mod  = importSpecModule imp_spec
 795           imp_msg  = ptext SLIT("imported from") <+> ppr imp_mod <> extra
 796           extra | imp_mod == moduleName name_mod = empty
 797                 | otherwise = ptext SLIT(", but defined in") <+> ppr name_mod
 798
 799     check hpt pit ok_gre = returnM ()   -- Local, or not used, or not deprectated
 800             -- The Imported pattern-match: don't deprecate locally defined names
 801             -- For a start, we may be exporting a deprecated thing
 802             -- Also we may use a deprecated thing in the defn of another
 803             -- deprecated things.  We may even use a deprecated thing in
 804             -- the defn of a non-deprecated thing, when changing a module's
 805             -- interface
 806
 807 lookupDeprec :: DynFlags -> HomePackageTable -> PackageIfaceTable
 808              -> Name -> Maybe DeprecTxt
 809 lookupDeprec dflags hpt pit n
 810   = case lookupIfaceByModule dflags hpt pit (nameModule n) of
 811         Just iface -> mi_dep_fn iface n `seqMaybe`      -- Bleat if the thing, *or
 812                       mi_dep_fn iface (nameParent n)    -- its parent*, is deprec'd
 813         Nothing
 814           | isWiredInName n -> Nothing
 815                 -- We have not necessarily loaded the .hi file for a
 816                 -- wired-in name (yet), although we *could*.
 817                 -- And we never deprecate them
 818
 819          | otherwise -> pprPanic "lookupDeprec" (ppr n)
 820                 -- By now all the interfaces should have been loaded
 821
 822 gre_is_used :: NameSet -> GlobalRdrElt -> Bool
 823 gre_is_used used_names gre = gre_name gre `elemNameSet` used_names
 824 \end{code}
 825
 826 %*********************************************************
 827 %*                                                       *
 828                 Unused names
 829 %*                                                       *
 830 %*********************************************************
 831
 832 \begin{code}
 833 reportUnusedNames :: Maybe [LIE RdrName]        -- Export list
 834                   -> TcGblEnv -> RnM ()
 835 reportUnusedNames export_decls gbl_env
 836   = do  { traceRn ((text "RUN") <+> (ppr (tcg_dus gbl_env)))
 837         ; warnUnusedTopBinds   unused_locals
 838         ; warnUnusedModules    unused_imp_mods
 839         ; warnUnusedImports    unused_imports
 840         ; warnDuplicateImports defined_and_used
 841         ; printMinimalImports  minimal_imports }
 842   where
 843     used_names, all_used_names :: NameSet
 844     used_names = findUses (tcg_dus gbl_env) emptyNameSet
 845         -- NB: currently, if f x = g, we only treat 'g' as used if 'f' is used
 846         -- Hence findUses
 847
 848     all_used_names = used_names `unionNameSets`
 849                      mkNameSet (mapCatMaybes nameParent_maybe (nameSetToList used_names))
 850                         -- A use of C implies a use of T,
 851                         -- if C was brought into scope by T(..) or T(C)
 852
 853         -- Collect the defined names from the in-scope environment
 854     defined_names :: [GlobalRdrElt]
 855     defined_names = globalRdrEnvElts (tcg_rdr_env gbl_env)
 856
 857         -- Note that defined_and_used, defined_but_not_used
 858         -- are both [GRE]; that's why we need defined_and_used
 859         -- rather than just all_used_names
 860     defined_and_used, defined_but_not_used :: [GlobalRdrElt]
 861     (defined_and_used, defined_but_not_used)
 862         = partition (gre_is_used all_used_names) defined_names
 863
 864         -- Filter out the ones that are
 865         --  (a) defined in this module, and
 866         --  (b) not defined by a 'deriving' clause
 867         -- The latter have an Internal Name, so we can filter them out easily
 868     unused_locals :: [GlobalRdrElt]
 869     unused_locals = filter is_unused_local defined_but_not_used
 870     is_unused_local :: GlobalRdrElt -> Bool
 871     is_unused_local gre = isLocalGRE gre && isExternalName (gre_name gre)
 872
 873     unused_imports :: [GlobalRdrElt]
 874     unused_imports = filter unused_imp defined_but_not_used
 875     unused_imp (GRE {gre_prov = Imported imp_specs})
 876         = not (all (module_unused . importSpecModule) imp_specs)
 877           && or [exp | ImpSpec { is_item = ImpSome { is_explicit = exp } } <- imp_specs]
 878                 -- Don't complain about unused imports if we've already said the
 879                 -- entire import is unused
 880     unused_imp other = False
 881
 882     -- To figure out the minimal set of imports, start with the things
 883     -- that are in scope (i.e. in gbl_env).  Then just combine them
 884     -- into a bunch of avails, so they are properly grouped
 885     --
 886     -- BUG WARNING: this does not deal properly with qualified imports!
 887     minimal_imports :: FiniteMap ModuleName AvailEnv
 888     minimal_imports0 = foldr add_expall   emptyFM          expall_mods
 889     minimal_imports1 = foldr add_name     minimal_imports0 defined_and_used
 890     minimal_imports  = foldr add_inst_mod minimal_imports1 direct_import_mods
 891         -- The last line makes sure that we retain all direct imports
 892         -- even if we import nothing explicitly.
 893         -- It's not necessarily redundant to import such modules. Consider
 894         --            module This
 895         --              import M ()
 896         --
 897         -- The import M() is not *necessarily* redundant, even if
 898         -- we suck in no instance decls from M (e.g. it contains
 899         -- no instance decls, or This contains no code).  It may be
 900         -- that we import M solely to ensure that M's orphan instance
 901         -- decls (or those in its imports) are visible to people who
 902         -- import This.  Sigh.
 903         -- There's really no good way to detect this, so the error message
 904         -- in RnEnv.warnUnusedModules is weakened instead
 905
 906         -- We've carefully preserved the provenance so that we can
 907         -- construct minimal imports that import the name by (one of)
 908         -- the same route(s) as the programmer originally did.
 909     add_name (GRE {gre_name = n, gre_prov = Imported imp_specs}) acc
 910         = addToFM_C plusAvailEnv acc (importSpecModule (head imp_specs))
 911                     (unitAvailEnv (mk_avail n (nameParent_maybe n)))
 912     add_name other acc
 913         = acc
 914
 915         -- Modules mentioned as 'module M' in the export list
 916     expall_mods = case export_decls of
 917                     Nothing -> []
 918                     Just es -> [m | L _ (IEModuleContents m) <- es]
 919
 920         -- This is really bogus.  The idea is that if we see 'module M' in
 921         -- the export list we must retain the import decls that drive it
 922         -- If we aren't careful we might see
 923         --      module A( module M ) where
 924         --        import M
 925         --        import N
 926         -- and suppose that N exports everything that M does.  Then we
 927         -- must not drop the import of M even though N brings it all into
 928         -- scope.
 929         --
 930         -- BUG WARNING: 'module M' exports aside, what if M.x is mentioned?!
 931         --
 932         -- The reason that add_expall is bogus is that it doesn't take
 933         -- qualified imports into account.  But it's an improvement.
 934     add_expall mod acc = addToFM_C plusAvailEnv acc mod emptyAvailEnv
 935
 936         -- n is the name of the thing, p is the name of its parent
 937     mk_avail n (Just p)                          = AvailTC p [p,n]
 938     mk_avail n Nothing | isTcOcc (nameOccName n) = AvailTC n [n]
 939                        | otherwise               = Avail n
 940
 941     add_inst_mod (mod,_,_) acc
 942       | mod_name `elemFM` acc = acc     -- We import something already
 943       | otherwise             = addToFM acc mod_name emptyAvailEnv
 944       where
 945         mod_name = moduleName mod
 946         -- Add an empty collection of imports for a module
 947         -- from which we have sucked only instance decls
 948
 949     imports = tcg_imports gbl_env
 950
 951     direct_import_mods :: [(Module, Bool, SrcSpan)]
 952         -- See the type of the imp_mods for this triple
 953     direct_import_mods = moduleEnvElts (imp_mods imports)
 954
 955     -- unused_imp_mods are the directly-imported modules
 956     -- that are not mentioned in minimal_imports1
 957     -- [Note: not 'minimal_imports', because that includes directly-imported
 958     --        modules even if we use nothing from them; see notes above]
 959     --
 960     -- BUG WARNING: does not deal correctly with multiple imports of the same module
 961     --              becuase direct_import_mods has only one entry per module
 962     unused_imp_mods = [(mod_name,loc) | (mod,no_imp,loc) <- direct_import_mods,
 963                        let mod_name = moduleName mod,
 964                        not (mod_name `elemFM` minimal_imports1),
 965                        mod /= pRELUDE,
 966                        not no_imp]
 967         -- The not no_imp part is not to complain about
 968         -- import M (), which is an idiom for importing
 969         -- instance declarations
 970
 971     module_unused :: ModuleName -> Bool
 972     module_unused mod = any (((==) mod) . fst) unused_imp_mods
 973
 974 ---------------------
 975 warnDuplicateImports :: [GlobalRdrElt] -> RnM ()
 976 -- Given the GREs for names that are used, figure out which imports
 977 -- could be omitted without changing the top-level environment.
 978 --
 979 -- NB: Given import Foo( T )
 980 --           import qualified Foo
 981 -- we do not report a duplicate import, even though Foo.T is brought
 982 -- into scope by both, because there's nothing you can *omit* without
 983 -- changing the top-level environment.  So we complain only if it's
 984 -- explicitly named in both imports or neither.
 985 --
 986 -- Furthermore, we complain about Foo.T only if
 987 -- there is no complaint about (unqualified) T
 988
 989 warnDuplicateImports gres
 990   = ifOptM Opt_WarnUnusedImports $
 991     sequenceM_  [ warn name pr
 992                         -- The 'head' picks the first offending group
 993                         -- for this particular name
 994                 | GRE { gre_name = name, gre_prov = Imported imps } <- gres
 995                 , pr <- redundants imps ]
 996   where
 997     warn name (red_imp, cov_imp)
 998         = addWarnAt (importSpecLoc red_imp)
 999             (vcat [ptext SLIT("Redundant import of:") <+> quotes pp_name,
1000                    ptext SLIT("It is also") <+> ppr cov_imp])
1001         where
1002           pp_name | is_qual red_decl = ppr (is_as red_decl) <> dot <> ppr occ
1003                   | otherwise       = ppr occ
1004           occ = nameOccName name
1005           red_decl = is_decl red_imp
1006
1007     redundants :: [ImportSpec] -> [(ImportSpec,ImportSpec)]
1008         -- The returned pair is (redundant-import, covering-import)
1009     redundants imps
1010         = [ (red_imp, cov_imp)
1011           | red_imp <- imps
1012           , cov_imp <- take 1 (filter (covers red_imp) imps) ]
1013
1014         -- "red_imp" is a putative redundant import
1015         -- "cov_imp" potentially covers it
1016         -- This test decides whether red_imp could be dropped
1017         --
1018         -- NOTE: currently the test does not warn about
1019         --              import M( x )
1020         --              imoprt N( x )
1021         -- even if the same underlying 'x' is involved, because dropping
1022         -- either import would change the qualified names in scope (M.x, N.x)
1023         -- But if the qualified names aren't used, the import is indeed redundant
1024         -- Sadly we don't know that.  Oh well.
1025     covers red_imp@(ImpSpec { is_decl = red_decl, is_item = red_item })
1026            cov_imp@(ImpSpec { is_decl = cov_decl, is_item = cov_item })
1027         | red_loc == cov_loc
1028         = False         -- Ignore diagonal elements
1029         | not (is_as red_decl == is_as cov_decl)
1030         = False         -- They bring into scope different qualified names
1031         | not (is_qual red_decl) && is_qual cov_decl
1032         = False         -- Covering one doesn't bring unqualified name into scope
1033         | red_selective
1034         = not cov_selective     -- Redundant one is selective and covering one isn't
1035           || red_later          -- Both are explicit; tie-break using red_later
1036         | otherwise
1037         = not cov_selective     -- Neither import is selective
1038           && (is_mod red_decl == is_mod cov_decl)       -- They import the same module
1039           && red_later          -- Tie-break
1040         where
1041           red_loc   = importSpecLoc red_imp
1042           cov_loc   = importSpecLoc cov_imp
1043           red_later = red_loc > cov_loc
1044           cov_selective = selectiveImpItem cov_item
1045           red_selective = selectiveImpItem red_item
1046
1047 selectiveImpItem :: ImpItemSpec -> Bool
1048 selectiveImpItem ImpAll       = False
1049 selectiveImpItem (ImpSome {}) = True
1050
1051 -- ToDo: deal with original imports with 'qualified' and 'as M' clauses
1052 printMinimalImports :: FiniteMap ModuleName AvailEnv    -- Minimal imports
1053                     -> RnM ()
1054 printMinimalImports imps
1055  = ifOptM Opt_D_dump_minimal_imports $ do {
1056
1057    mod_ies  <-  mappM to_ies (fmToList imps) ;
1058    this_mod <- getModule ;
1059    rdr_env  <- getGlobalRdrEnv ;
1060    ioToTcRn (do { h <- openFile (mkFilename this_mod) WriteMode ;
1061                   printForUser h (mkPrintUnqualified rdr_env)
1062                                  (vcat (map ppr_mod_ie mod_ies)) })
1063    }
1064   where
1065     mkFilename this_mod = moduleNameString (moduleName this_mod) ++ ".imports"
1066     ppr_mod_ie (mod_name, ies)
1067         | mod_name == moduleName pRELUDE
1068         = empty
1069         | null ies      -- Nothing except instances comes from here
1070         = ptext SLIT("import") <+> ppr mod_name <> ptext SLIT("()    -- Instances only")
1071         | otherwise
1072         = ptext SLIT("import") <+> ppr mod_name <>
1073                     parens (fsep (punctuate comma (map ppr ies)))
1074
1075     to_ies (mod, avail_env) = do ies <- mapM to_ie (availEnvElts avail_env)
1076                                  returnM (mod, ies)
1077
1078     to_ie :: AvailInfo -> RnM (IE Name)
1079         -- The main trick here is that if we're importing all the constructors
1080         -- we want to say "T(..)", but if we're importing only a subset we want
1081         -- to say "T(A,B,C)".  So we have to find out what the module exports.
1082     to_ie (Avail n)       = returnM (IEVar n)
1083     to_ie (AvailTC n [m]) = ASSERT( n==m )
1084                             returnM (IEThingAbs n)
1085     to_ie (AvailTC n ns)
1086         = loadSrcInterface doc n_mod False                      `thenM` \ iface ->
1087           case [xs | (m,as) <- mi_exports iface,
1088                      moduleName m == n_mod,
1089                      AvailTC x xs <- as,
1090                      x == nameOccName n] of
1091               [xs] | all_used xs -> returnM (IEThingAll n)
1092                    | otherwise   -> returnM (IEThingWith n (filter (/= n) ns))
1093               other              -> pprTrace "to_ie" (ppr n <+> ppr n_mod <+> ppr other) $
1094                                     returnM (IEVar n)
1095         where
1096           all_used avail_occs = all (`elem` map nameOccName ns) avail_occs
1097           doc = text "Compute minimal imports from" <+> ppr n
1098           n_mod = moduleName (nameModule n)
1099 \end{code}
1100
1101
1102 %************************************************************************
1103 %*                                                                      *
1104 \subsection{Errors}
1105 %*                                                                      *
1106 %************************************************************************
1107
1108 \begin{code}
1109 badImportItemErr iface decl_spec ie
1110   = sep [ptext SLIT("Module"), quotes (ppr (is_mod decl_spec)), source_import,
1111          ptext SLIT("does not export"), quotes (ppr ie)]
1112   where
1113     source_import | mi_boot iface = ptext SLIT("(hi-boot interface)")
1114                   | otherwise     = empty
1115
1116 dodgyImportWarn item = dodgyMsg (ptext SLIT("import")) item
1117 dodgyExportWarn item = dodgyMsg (ptext SLIT("export")) item
1118
1119 dodgyMsg kind tc
1120   = sep [ ptext SLIT("The") <+> kind <+> ptext SLIT("item") <+> quotes (ppr (IEThingAll tc)),
1121           ptext SLIT("suggests that") <+> quotes (ppr tc) <+> ptext SLIT("has constructor or class methods"),
1122           ptext SLIT("but it has none; it is a type synonym or abstract type or class") ]
1123
1124 modExportErr mod
1125   = hsep [ ptext SLIT("Unknown module in export list: module"), quotes (ppr mod)]
1126
1127 exportItemErr export_item
1128   = sep [ ptext SLIT("The export item") <+> quotes (ppr export_item),
1129           ptext SLIT("attempts to export constructors or class methods that are not visible here") ]
1130
1131 typeItemErr name wherestr
1132   = sep [ ptext SLIT("Using 'type' tag on") <+> quotes (ppr name) <+> wherestr,
1133           ptext SLIT("Use -findexed-types to enable this extension") ]
1134
1135 exportClashErr global_env name1 name2 ie1 ie2
1136   = vcat [ ptext SLIT("Conflicting exports for") <+> quotes (ppr occ) <> colon
1137          , ppr_export ie1 name1
1138          , ppr_export ie2 name2  ]
1139   where
1140     occ = nameOccName name1
1141     ppr_export ie name = nest 2 (quotes (ppr ie) <+> ptext SLIT("exports") <+>
1142                                  quotes (ppr name) <+> pprNameProvenance (get_gre name))
1143
1144         -- get_gre finds a GRE for the Name, so that we can show its provenance
1145     get_gre name
1146         = case lookupGRE_Name global_env name of
1147              (gre:_) -> gre
1148              []      -> pprPanic "exportClashErr" (ppr name)
1149
1150 addDupDeclErr :: Name -> Name -> TcRn ()
1151 addDupDeclErr name_a name_b
1152   = addErrAt (srcLocSpan loc2) $
1153     vcat [ptext SLIT("Multiple declarations of") <+> quotes (ppr name1),
1154           ptext SLIT("Declared at:") <+> vcat [ppr (nameSrcLoc name1), ppr loc2]]
1155   where
1156     loc2 = nameSrcLoc name2
1157     (name1,name2) | nameSrcLoc name_a > nameSrcLoc name_b = (name_b,name_a)
1158                   | otherwise                             = (name_a,name_b)
1159         -- Report the error at the later location
1160
1161 dupExportWarn occ_name ie1 ie2
1162   = hsep [quotes (ppr occ_name),
1163           ptext SLIT("is exported by"), quotes (ppr ie1),
1164           ptext SLIT("and"),            quotes (ppr ie2)]
1165
1166 dupModuleExport mod
1167   = hsep [ptext SLIT("Duplicate"),
1168           quotes (ptext SLIT("Module") <+> ppr mod),
1169           ptext SLIT("in export list")]
1170
1171 moduleDeprec mod txt
1172   = sep [ ptext SLIT("Module") <+> quotes (ppr mod) <+> ptext SLIT("is deprecated:"),
1173           nest 4 (ppr txt) ]
1174 \end{code}