compiler/simplCore/CoreMonad.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[CoreMonad]{The core pipeline monad}
   5
   6 \begin{code}
   7 {-# LANGUAGE UndecidableInstances #-}
   8
   9 module CoreMonad (
  10     -- * Configuration of the core-to-core passes
  11     CoreToDo(..),
  12     SimplifierMode(..),
  13     FloatOutSwitches(..),
  14     getCoreToDo, dumpSimplPhase,
  15
  16     -- * Counting
  17     SimplCount, doSimplTick, doFreeSimplTick, simplCountN,
  18     pprSimplCount, plusSimplCount, zeroSimplCount, isZeroSimplCount, Tick(..),
  19
  20     -- * The monad
  21     CoreM, runCoreM,
  22
  23     -- ** Reading from the monad
  24     getHscEnv, getRuleBase, getModule,
  25     getDynFlags, getOrigNameCache,
  26
  27     -- ** Writing to the monad
  28     addSimplCount,
  29
  30     -- ** Lifting into the monad
  31     liftIO, liftIOWithCount,
  32     liftIO1, liftIO2, liftIO3, liftIO4,
  33
  34     -- ** Dealing with annotations
  35     getAnnotations, getFirstAnnotations,
  36
  37     -- ** Debug output
  38     showPass, endPass, endIteration, dumpIfSet,
  39
  40     -- ** Screen output
  41     putMsg, putMsgS, errorMsg, errorMsgS,
  42     fatalErrorMsg, fatalErrorMsgS,
  43     debugTraceMsg, debugTraceMsgS,
  44     dumpIfSet_dyn,
  45
  46 #ifdef GHCI
  47     -- * Getting 'Name's
  48     thNameToGhcName
  49 #endif
  50   ) where
  51
  52 #ifdef GHCI
  53 import Name( Name )
  54 #endif
  55 import CoreSyn
  56 import PprCore
  57 import CoreUtils
  58 import CoreLint         ( lintCoreBindings )
  59 import PrelNames        ( iNTERACTIVE )
  60 import HscTypes
  61 import Module           ( Module )
  62 import DynFlags
  63 import StaticFlags
  64 import Rules            ( RuleBase )
  65 import BasicTypes       ( CompilerPhase(..) )
  66 import Annotations
  67 import Id               ( Id )
  68
  69 import IOEnv hiding     ( liftIO, failM, failWithM )
  70 import qualified IOEnv  ( liftIO )
  71 import TcEnv            ( tcLookupGlobal )
  72 import TcRnMonad        ( TcM, initTc )
  73
  74 import Outputable
  75 import FastString
  76 import qualified ErrUtils as Err
  77 import Bag
  78 import Maybes
  79 import UniqSupply
  80 import UniqFM       ( UniqFM, mapUFM, filterUFM )
  81 import MonadUtils
  82
  83 import Util             ( split )
  84 import Data.List        ( intersperse )
  85 import Data.Dynamic
  86 import Data.IORef
  87 import Data.Map (Map)
  88 import qualified Data.Map as Map
  89 import Data.Word
  90 import Control.Monad
  91
  92 import Prelude hiding   ( read )
  93
  94 #ifdef GHCI
  95 import {-# SOURCE #-} TcSplice ( lookupThName_maybe )
  96 import qualified Language.Haskell.TH as TH
  97 #endif
  98 \end{code}
  99
 100 %************************************************************************
 101 %*                                                                      *
 102                        Debug output
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 These functions are not CoreM monad stuff, but they probably ought to
 107 be, and it makes a conveneint place.  place for them.  They print out
 108 stuff before and after core passes, and do Core Lint when necessary.
 109
 110 \begin{code}
 111 showPass :: DynFlags -> CoreToDo -> IO ()
 112 showPass dflags pass = Err.showPass dflags (showSDoc (ppr pass))
 113
 114 endPass :: DynFlags -> CoreToDo -> [CoreBind] -> [CoreRule] -> IO ()
 115 endPass dflags pass = dumpAndLint dflags True pass empty (coreDumpFlag pass)
 116
 117 -- Same as endPass but doesn't dump Core even with -dverbose-core2core
 118 endIteration :: DynFlags -> CoreToDo -> Int -> [CoreBind] -> [CoreRule] -> IO ()
 119 endIteration dflags pass n
 120   = dumpAndLint dflags False pass (ptext (sLit "iteration=") <> int n)
 121                 (Just Opt_D_dump_simpl_iterations)
 122
 123 dumpIfSet :: Bool -> CoreToDo -> SDoc -> SDoc -> IO ()
 124 dumpIfSet dump_me pass extra_info doc
 125   = Err.dumpIfSet dump_me (showSDoc (ppr pass <+> extra_info)) doc
 126
 127 dumpAndLint :: DynFlags -> Bool -> CoreToDo -> SDoc -> Maybe DynFlag
 128             -> [CoreBind] -> [CoreRule] -> IO ()
 129 -- The "show_all" parameter says to print dump if -dverbose-core2core is on
 130 dumpAndLint dflags show_all pass extra_info mb_dump_flag binds rules
 131   = do {  -- Report result size if required
 132           -- This has the side effect of forcing the intermediate to be evaluated
 133        ; Err.debugTraceMsg dflags 2 $
 134                 (text "    Result size =" <+> int (coreBindsSize binds))
 135
 136         -- Report verbosely, if required
 137        ; let pass_name = showSDoc (ppr pass <+> extra_info)
 138              dump_doc  = pprCoreBindings binds
 139                          $$ ppUnless (null rules) pp_rules
 140
 141        ; case mb_dump_flag of
 142             Nothing        -> return ()
 143             Just dump_flag -> Err.dumpIfSet_dyn_or dflags dump_flags pass_name dump_doc
 144                where
 145                  dump_flags | show_all  = [dump_flag, Opt_D_verbose_core2core]
 146                             | otherwise = [dump_flag]
 147
 148         -- Type check
 149        ; when (dopt Opt_DoCoreLinting dflags) $
 150          do { let (warns, errs) = lintCoreBindings binds
 151             ; Err.showPass dflags ("Core Linted result of " ++ pass_name)
 152             ; displayLintResults dflags pass warns errs binds  } }
 153   where
 154     pp_rules = vcat [ blankLine
 155                     , ptext (sLit "------ Local rules for imported ids --------")
 156                     , pprRules rules ]
 157
 158 displayLintResults :: DynFlags -> CoreToDo
 159                    -> Bag Err.Message -> Bag Err.Message -> [CoreBind]
 160                    -> IO ()
 161 displayLintResults dflags pass warns errs binds
 162   | not (isEmptyBag errs)
 163   = do { printDump (vcat [ banner "errors", Err.pprMessageBag errs
 164                          , ptext (sLit "*** Offending Program ***")
 165                          , pprCoreBindings binds
 166                          , ptext (sLit "*** End of Offense ***") ])
 167        ; Err.ghcExit dflags 1 }
 168
 169   | not (isEmptyBag warns)
 170   , not (case pass of { CoreDesugar -> True; _ -> False })
 171         -- Suppress warnings after desugaring pass because some
 172         -- are legitimate. Notably, the desugarer generates instance
 173         -- methods with INLINE pragmas that form a mutually recursive
 174         -- group.  Only afer a round of simplification are they unravelled.
 175   , not opt_NoDebugOutput
 176   , showLintWarnings pass
 177   = printDump (banner "warnings" $$ Err.pprMessageBag warns)
 178
 179   | otherwise = return ()
 180   where
 181     banner string = ptext (sLit "*** Core Lint")      <+> text string
 182                     <+> ptext (sLit ": in result of") <+> ppr pass
 183                     <+> ptext (sLit "***")
 184
 185 showLintWarnings :: CoreToDo -> Bool
 186 -- Disable Lint warnings on the first simplifier pass, because
 187 -- there may be some INLINE knots still tied, which is tiresomely noisy
 188 showLintWarnings (CoreDoSimplify _ (SimplMode { sm_phase = InitialPhase })) = False
 189 showLintWarnings _ = True
 190 \end{code}
 191
 192
 193 %************************************************************************
 194 %*                                                                      *
 195               The CoreToDo type and related types
 196           Abstraction of core-to-core passes to run.
 197 %*                                                                      *
 198 %************************************************************************
 199
 200 \begin{code}
 201 data CoreToDo           -- These are diff core-to-core passes,
 202                         -- which may be invoked in any order,
 203                         -- as many times as you like.
 204
 205   = CoreDoSimplify      -- The core-to-core simplifier.
 206         Int                    -- Max iterations
 207         SimplifierMode
 208
 209   | CoreDoFloatInwards
 210   | CoreDoFloatOutwards FloatOutSwitches
 211   | CoreLiberateCase
 212   | CoreDoPrintCore
 213   | CoreDoStaticArgs
 214   | CoreDoStrictness
 215   | CoreDoWorkerWrapper
 216   | CoreDoSpecialising
 217   | CoreDoSpecConstr
 218   | CoreDoGlomBinds
 219   | CoreCSE
 220   | CoreDoRuleCheck CompilerPhase String   -- Check for non-application of rules
 221                                            -- matching this string
 222   | CoreDoVectorisation
 223   | CoreDoNothing                -- Useful when building up
 224   | CoreDoPasses [CoreToDo]      -- lists of these things
 225
 226   | CoreDesugar  -- Not strictly a core-to-core pass, but produces
 227                  -- Core output, and hence useful to pass to endPass
 228
 229   | CoreTidy
 230   | CorePrep
 231
 232 coreDumpFlag :: CoreToDo -> Maybe DynFlag
 233 coreDumpFlag (CoreDoSimplify {})      = Just Opt_D_dump_simpl_phases
 234 coreDumpFlag CoreDoFloatInwards       = Just Opt_D_verbose_core2core
 235 coreDumpFlag (CoreDoFloatOutwards {}) = Just Opt_D_verbose_core2core
 236 coreDumpFlag CoreLiberateCase         = Just Opt_D_verbose_core2core
 237 coreDumpFlag CoreDoStaticArgs         = Just Opt_D_verbose_core2core
 238 coreDumpFlag CoreDoStrictness         = Just Opt_D_dump_stranal
 239 coreDumpFlag CoreDoWorkerWrapper      = Just Opt_D_dump_worker_wrapper
 240 coreDumpFlag CoreDoSpecialising       = Just Opt_D_dump_spec
 241 coreDumpFlag CoreDoSpecConstr         = Just Opt_D_dump_spec
 242 coreDumpFlag CoreCSE                  = Just Opt_D_dump_cse
 243 coreDumpFlag CoreDoVectorisation      = Just Opt_D_dump_vect
 244 coreDumpFlag CoreDesugar              = Just Opt_D_dump_ds
 245 coreDumpFlag CoreTidy                 = Just Opt_D_dump_simpl
 246 coreDumpFlag CorePrep                 = Just Opt_D_dump_prep
 247
 248 coreDumpFlag CoreDoPrintCore         = Nothing
 249 coreDumpFlag (CoreDoRuleCheck {})    = Nothing
 250 coreDumpFlag CoreDoNothing           = Nothing
 251 coreDumpFlag CoreDoGlomBinds         = Nothing
 252 coreDumpFlag (CoreDoPasses {})       = Nothing
 253
 254 instance Outputable CoreToDo where
 255   ppr (CoreDoSimplify n md)  = ptext (sLit "Simplifier")
 256                                <+> ppr md
 257                                  <+> ptext (sLit "max-iterations=") <> int n
 258   ppr CoreDoFloatInwards       = ptext (sLit "Float inwards")
 259   ppr (CoreDoFloatOutwards f)  = ptext (sLit "Float out") <> parens (ppr f)
 260   ppr CoreLiberateCase         = ptext (sLit "Liberate case")
 261   ppr CoreDoStaticArgs         = ptext (sLit "Static argument")
 262   ppr CoreDoStrictness         = ptext (sLit "Demand analysis")
 263   ppr CoreDoWorkerWrapper      = ptext (sLit "Worker Wrapper binds")
 264   ppr CoreDoSpecialising       = ptext (sLit "Specialise")
 265   ppr CoreDoSpecConstr         = ptext (sLit "SpecConstr")
 266   ppr CoreCSE                  = ptext (sLit "Common sub-expression")
 267   ppr CoreDoVectorisation      = ptext (sLit "Vectorisation")
 268   ppr CoreDesugar              = ptext (sLit "Desugar")
 269   ppr CoreTidy                 = ptext (sLit "Tidy Core")
 270   ppr CorePrep                 = ptext (sLit "CorePrep")
 271   ppr CoreDoPrintCore          = ptext (sLit "Print core")
 272   ppr (CoreDoRuleCheck {})     = ptext (sLit "Rule check")
 273   ppr CoreDoGlomBinds          = ptext (sLit "Glom binds")
 274   ppr CoreDoNothing            = ptext (sLit "CoreDoNothing")
 275   ppr (CoreDoPasses {})        = ptext (sLit "CoreDoPasses")
 276 \end{code}
 277
 278 \begin{code}
 279 data SimplifierMode             -- See comments in SimplMonad
 280   = SimplMode
 281         { sm_names      :: [String] -- Name(s) of the phase
 282         , sm_phase      :: CompilerPhase
 283         , sm_rules      :: Bool     -- Whether RULES are enabled
 284         , sm_inline     :: Bool     -- Whether inlining is enabled
 285         , sm_case_case  :: Bool     -- Whether case-of-case is enabled
 286         , sm_eta_expand :: Bool     -- Whether eta-expansion is enabled
 287         }
 288
 289 instance Outputable SimplifierMode where
 290     ppr (SimplMode { sm_phase = p, sm_names = ss
 291                    , sm_rules = r, sm_inline = i
 292                    , sm_eta_expand = eta, sm_case_case = cc })
 293        = ptext (sLit "SimplMode") <+> braces (
 294          sep [ ptext (sLit "Phase =") <+> ppr p <+>
 295                brackets (text (concat $ intersperse "," ss)) <> comma
 296              , pp_flag i   (sLit "inline") <> comma
 297              , pp_flag r   (sLit "rules") <> comma
 298              , pp_flag eta (sLit "eta-expand") <> comma
 299              , pp_flag cc  (sLit "case-of-case") ])
 300          where
 301            pp_flag f s = ppUnless f (ptext (sLit "no")) <+> ptext s
 302 \end{code}
 303
 304
 305 \begin{code}
 306 data FloatOutSwitches = FloatOutSwitches {
 307   floatOutLambdas   :: Maybe Int,  -- ^ Just n <=> float lambdas to top level, if
 308                                    -- doing so will abstract over n or fewer
 309                                    -- value variables
 310                                    -- Nothing <=> float all lambdas to top level,
 311                                    --             regardless of how many free variables
 312                                    -- Just 0 is the vanilla case: float a lambda
 313                                    --    iff it has no free vars
 314
 315   floatOutConstants :: Bool,       -- ^ True <=> float constants to top level,
 316                                    --            even if they do not escape a lambda
 317   floatOutPartialApplications :: Bool -- ^ True <=> float out partial applications
 318                                             --            based on arity information.
 319   }
 320 instance Outputable FloatOutSwitches where
 321     ppr = pprFloatOutSwitches
 322
 323 pprFloatOutSwitches :: FloatOutSwitches -> SDoc
 324 pprFloatOutSwitches sw
 325   = ptext (sLit "FOS") <+> (braces $
 326      sep $ punctuate comma $
 327      [ ptext (sLit "Lam =")    <+> ppr (floatOutLambdas sw)
 328      , ptext (sLit "Consts =") <+> ppr (floatOutConstants sw)
 329      , ptext (sLit "PAPs =")   <+> ppr (floatOutPartialApplications sw) ])
 330 \end{code}
 331
 332
 333 %************************************************************************
 334 %*                                                                      *
 335            Generating the main optimisation pipeline
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 \begin{code}
 340 getCoreToDo :: DynFlags -> [CoreToDo]
 341 getCoreToDo dflags
 342   = core_todo
 343   where
 344     opt_level     = optLevel           dflags
 345     phases        = simplPhases        dflags
 346     max_iter      = maxSimplIterations dflags
 347     rule_check    = ruleCheck          dflags
 348     strictness    = dopt Opt_Strictness                   dflags
 349     full_laziness = dopt Opt_FullLaziness                 dflags
 350     do_specialise = dopt Opt_Specialise                   dflags
 351     do_float_in   = dopt Opt_FloatIn                      dflags
 352     cse           = dopt Opt_CSE                          dflags
 353     spec_constr   = dopt Opt_SpecConstr                   dflags
 354     liberate_case = dopt Opt_LiberateCase                 dflags
 355     static_args   = dopt Opt_StaticArgumentTransformation dflags
 356     rules_on      = dopt Opt_EnableRewriteRules           dflags
 357     eta_expand_on = dopt Opt_DoLambdaEtaExpansion         dflags
 358
 359     maybe_rule_check phase = runMaybe rule_check (CoreDoRuleCheck phase)
 360
 361     maybe_strictness_before phase
 362       = runWhen (phase `elem` strictnessBefore dflags) CoreDoStrictness
 363
 364     base_mode = SimplMode { sm_phase      = panic "base_mode"
 365                           , sm_names      = []
 366                           , sm_rules      = rules_on
 367                           , sm_eta_expand = eta_expand_on
 368                           , sm_inline     = True
 369                           , sm_case_case  = True }
 370
 371     simpl_phase phase names iter
 372       = CoreDoPasses
 373           [ maybe_strictness_before phase
 374           , CoreDoSimplify iter
 375                 (base_mode { sm_phase = Phase phase
 376                            , sm_names = names })
 377
 378           , maybe_rule_check (Phase phase)
 379           ]
 380
 381     vectorisation
 382       = runWhen (dopt Opt_Vectorise dflags) $
 383           CoreDoPasses [ simpl_gently, CoreDoVectorisation ]
 384
 385                 -- By default, we have 2 phases before phase 0.
 386
 387                 -- Want to run with inline phase 2 after the specialiser to give
 388                 -- maximum chance for fusion to work before we inline build/augment
 389                 -- in phase 1.  This made a difference in 'ansi' where an
 390                 -- overloaded function wasn't inlined till too late.
 391
 392                 -- Need phase 1 so that build/augment get
 393                 -- inlined.  I found that spectral/hartel/genfft lost some useful
 394                 -- strictness in the function sumcode' if augment is not inlined
 395                 -- before strictness analysis runs
 396     simpl_phases = CoreDoPasses [ simpl_phase phase ["main"] max_iter
 397                                 | phase <- [phases, phases-1 .. 1] ]
 398
 399
 400         -- initial simplify: mk specialiser happy: minimum effort please
 401     simpl_gently = CoreDoSimplify max_iter
 402                        (base_mode { sm_phase = InitialPhase
 403                                   , sm_names = ["Gentle"]
 404                                   , sm_rules = rules_on   -- Note [RULEs enabled in SimplGently]
 405                                   , sm_inline = False
 406                                   , sm_case_case = False })
 407                           -- Don't do case-of-case transformations.
 408                           -- This makes full laziness work better
 409
 410     core_todo =
 411      if opt_level == 0 then
 412        [vectorisation,
 413         simpl_phase 0 ["final"] max_iter]
 414      else {- opt_level >= 1 -} [
 415
 416     -- We want to do the static argument transform before full laziness as it
 417     -- may expose extra opportunities to float things outwards. However, to fix
 418     -- up the output of the transformation we need at do at least one simplify
 419     -- after this before anything else
 420         runWhen static_args (CoreDoPasses [ simpl_gently, CoreDoStaticArgs ]),
 421
 422         -- We run vectorisation here for now, but we might also try to run
 423         -- it later
 424         vectorisation,
 425
 426         -- initial simplify: mk specialiser happy: minimum effort please
 427         simpl_gently,
 428
 429         -- Specialisation is best done before full laziness
 430         -- so that overloaded functions have all their dictionary lambdas manifest
 431         runWhen do_specialise CoreDoSpecialising,
 432
 433         runWhen full_laziness $
 434            CoreDoFloatOutwards FloatOutSwitches {
 435                                  floatOutLambdas   = Just 0,
 436                                  floatOutConstants = True,
 437                                  floatOutPartialApplications = False },
 438                 -- Was: gentleFloatOutSwitches
 439                 --
 440                 -- I have no idea why, but not floating constants to
 441                 -- top level is very bad in some cases.
 442                 --
 443                 -- Notably: p_ident in spectral/rewrite
 444                 --          Changing from "gentle" to "constantsOnly"
 445                 --          improved rewrite's allocation by 19%, and
 446                 --          made 0.0% difference to any other nofib
 447                 --          benchmark
 448                 --
 449                 -- Not doing floatOutPartialApplications yet, we'll do
 450                 -- that later on when we've had a chance to get more
 451                 -- accurate arity information.  In fact it makes no
 452                 -- difference at all to performance if we do it here,
 453                 -- but maybe we save some unnecessary to-and-fro in
 454                 -- the simplifier.
 455
 456         runWhen do_float_in CoreDoFloatInwards,
 457
 458         simpl_phases,
 459
 460                 -- Phase 0: allow all Ids to be inlined now
 461                 -- This gets foldr inlined before strictness analysis
 462
 463                 -- At least 3 iterations because otherwise we land up with
 464                 -- huge dead expressions because of an infelicity in the
 465                 -- simpifier.
 466                 --      let k = BIG in foldr k z xs
 467                 -- ==>  let k = BIG in letrec go = \xs -> ...(k x).... in go xs
 468                 -- ==>  let k = BIG in letrec go = \xs -> ...(BIG x).... in go xs
 469                 -- Don't stop now!
 470         simpl_phase 0 ["main"] (max max_iter 3),
 471
 472         runWhen strictness (CoreDoPasses [
 473                 CoreDoStrictness,
 474                 CoreDoWorkerWrapper,
 475                 CoreDoGlomBinds,
 476                 simpl_phase 0 ["post-worker-wrapper"] max_iter
 477                 ]),
 478
 479         runWhen full_laziness $
 480            CoreDoFloatOutwards FloatOutSwitches {
 481                                  floatOutLambdas   = floatLamArgs dflags,
 482                                  floatOutConstants = True,
 483                                  floatOutPartialApplications = True },
 484                 -- nofib/spectral/hartel/wang doubles in speed if you
 485                 -- do full laziness late in the day.  It only happens
 486                 -- after fusion and other stuff, so the early pass doesn't
 487                 -- catch it.  For the record, the redex is
 488                 --        f_el22 (f_el21 r_midblock)
 489
 490
 491         runWhen cse CoreCSE,
 492                 -- We want CSE to follow the final full-laziness pass, because it may
 493                 -- succeed in commoning up things floated out by full laziness.
 494                 -- CSE used to rely on the no-shadowing invariant, but it doesn't any more
 495
 496         runWhen do_float_in CoreDoFloatInwards,
 497
 498         maybe_rule_check (Phase 0),
 499
 500                 -- Case-liberation for -O2.  This should be after
 501                 -- strictness analysis and the simplification which follows it.
 502         runWhen liberate_case (CoreDoPasses [
 503             CoreLiberateCase,
 504             simpl_phase 0 ["post-liberate-case"] max_iter
 505             ]),         -- Run the simplifier after LiberateCase to vastly
 506                         -- reduce the possiblility of shadowing
 507                         -- Reason: see Note [Shadowing] in SpecConstr.lhs
 508
 509         runWhen spec_constr CoreDoSpecConstr,
 510
 511         maybe_rule_check (Phase 0),
 512
 513         -- Final clean-up simplification:
 514         simpl_phase 0 ["final"] max_iter
 515      ]
 516
 517 -- The core-to-core pass ordering is derived from the DynFlags:
 518 runWhen :: Bool -> CoreToDo -> CoreToDo
 519 runWhen True  do_this = do_this
 520 runWhen False _       = CoreDoNothing
 521
 522 runMaybe :: Maybe a -> (a -> CoreToDo) -> CoreToDo
 523 runMaybe (Just x) f = f x
 524 runMaybe Nothing  _ = CoreDoNothing
 525
 526 dumpSimplPhase :: DynFlags -> SimplifierMode -> Bool
 527 dumpSimplPhase dflags mode
 528    | Just spec_string <- shouldDumpSimplPhase dflags
 529    = match_spec spec_string
 530    | otherwise
 531    = dopt Opt_D_verbose_core2core dflags
 532
 533   where
 534     match_spec :: String -> Bool
 535     match_spec spec_string
 536       = or $ map (and . map match . split ':')
 537            $ split ',' spec_string
 538
 539     match :: String -> Bool
 540     match "" = True
 541     match s  = case reads s of
 542                 [(n,"")] -> phase_num  n
 543                 _        -> phase_name s
 544
 545     phase_num :: Int -> Bool
 546     phase_num n = case sm_phase mode of
 547                     Phase k -> n == k
 548                     _       -> False
 549
 550     phase_name :: String -> Bool
 551     phase_name s = s `elem` sm_names mode
 552 \end{code}
 553
 554
 555 Note [RULEs enabled in SimplGently]
 556 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 557 RULES are enabled when doing "gentle" simplification.  Two reasons:
 558
 559   * We really want the class-op cancellation to happen:
 560         op (df d1 d2) --> $cop3 d1 d2
 561     because this breaks the mutual recursion between 'op' and 'df'
 562
 563   * I wanted the RULE
 564         lift String ===> ...
 565     to work in Template Haskell when simplifying
 566     splices, so we get simpler code for literal strings
 567
 568 But watch out: list fusion can prevent floating.  So use phase control
 569 to switch off those rules until after floating.
 570
 571
 572 %************************************************************************
 573 %*                                                                      *
 574              Counting and logging
 575 %*                                                                      *
 576 %************************************************************************
 577
 578 \begin{code}
 579 verboseSimplStats :: Bool
 580 verboseSimplStats = opt_PprStyle_Debug          -- For now, anyway
 581
 582 zeroSimplCount     :: DynFlags -> SimplCount
 583 isZeroSimplCount   :: SimplCount -> Bool
 584 pprSimplCount      :: SimplCount -> SDoc
 585 doSimplTick, doFreeSimplTick :: Tick -> SimplCount -> SimplCount
 586 plusSimplCount     :: SimplCount -> SimplCount -> SimplCount
 587 \end{code}
 588
 589 \begin{code}
 590 data SimplCount
 591    = VerySimplCount !Int        -- Used when don't want detailed stats
 592
 593    | SimplCount {
 594         ticks   :: !Int,        -- Total ticks
 595         details :: !TickCounts, -- How many of each type
 596
 597         n_log   :: !Int,        -- N
 598         log1    :: [Tick],      -- Last N events; <= opt_HistorySize,
 599                                 --   most recent first
 600         log2    :: [Tick]       -- Last opt_HistorySize events before that
 601                                 -- Having log1, log2 lets us accumulate the
 602                                 -- recent history reasonably efficiently
 603      }
 604
 605 type TickCounts = Map Tick Int
 606
 607 simplCountN :: SimplCount -> Int
 608 simplCountN (VerySimplCount n)         = n
 609 simplCountN (SimplCount { ticks = n }) = n
 610
 611 zeroSimplCount dflags
 612                 -- This is where we decide whether to do
 613                 -- the VerySimpl version or the full-stats version
 614   | dopt Opt_D_dump_simpl_stats dflags
 615   = SimplCount {ticks = 0, details = Map.empty,
 616                 n_log = 0, log1 = [], log2 = []}
 617   | otherwise
 618   = VerySimplCount 0
 619
 620 isZeroSimplCount (VerySimplCount n)         = n==0
 621 isZeroSimplCount (SimplCount { ticks = n }) = n==0
 622
 623 doFreeSimplTick tick sc@SimplCount { details = dts }
 624   = sc { details = dts `addTick` tick }
 625 doFreeSimplTick _ sc = sc
 626
 627 doSimplTick tick sc@SimplCount { ticks = tks, details = dts, n_log = nl, log1 = l1 }
 628   | nl >= opt_HistorySize = sc1 { n_log = 1, log1 = [tick], log2 = l1 }
 629   | otherwise             = sc1 { n_log = nl+1, log1 = tick : l1 }
 630   where
 631     sc1 = sc { ticks = tks+1, details = dts `addTick` tick }
 632
 633 doSimplTick _ (VerySimplCount n) = VerySimplCount (n+1)
 634
 635
 636 -- Don't use Map.unionWith because that's lazy, and we want to
 637 -- be pretty strict here!
 638 addTick :: TickCounts -> Tick -> TickCounts
 639 addTick fm tick = case Map.lookup tick fm of
 640                         Nothing -> Map.insert tick 1 fm
 641                         Just n  -> n1 `seq` Map.insert tick n1 fm
 642                                 where
 643                                    n1 = n+1
 644
 645
 646 plusSimplCount sc1@(SimplCount { ticks = tks1, details = dts1 })
 647                sc2@(SimplCount { ticks = tks2, details = dts2 })
 648   = log_base { ticks = tks1 + tks2, details = Map.unionWith (+) dts1 dts2 }
 649   where
 650         -- A hackish way of getting recent log info
 651     log_base | null (log1 sc2) = sc1    -- Nothing at all in sc2
 652              | null (log2 sc2) = sc2 { log2 = log1 sc1 }
 653              | otherwise       = sc2
 654
 655 plusSimplCount (VerySimplCount n) (VerySimplCount m) = VerySimplCount (n+m)
 656 plusSimplCount _                  _                  = panic "plusSimplCount"
 657        -- We use one or the other consistently
 658
 659 pprSimplCount (VerySimplCount n) = ptext (sLit "Total ticks:") <+> int n
 660 pprSimplCount (SimplCount { ticks = tks, details = dts, log1 = l1, log2 = l2 })
 661   = vcat [ptext (sLit "Total ticks:    ") <+> int tks,
 662           blankLine,
 663           pprTickCounts (Map.toList dts),
 664           if verboseSimplStats then
 665                 vcat [blankLine,
 666                       ptext (sLit "Log (most recent first)"),
 667                       nest 4 (vcat (map ppr l1) $$ vcat (map ppr l2))]
 668           else empty
 669     ]
 670
 671 pprTickCounts :: [(Tick,Int)] -> SDoc
 672 pprTickCounts [] = empty
 673 pprTickCounts ((tick1,n1):ticks)
 674   = vcat [int tot_n <+> text (tickString tick1),
 675           pprTCDetails real_these,
 676           pprTickCounts others
 677     ]
 678   where
 679     tick1_tag           = tickToTag tick1
 680     (these, others)     = span same_tick ticks
 681     real_these          = (tick1,n1):these
 682     same_tick (tick2,_) = tickToTag tick2 == tick1_tag
 683     tot_n               = sum [n | (_,n) <- real_these]
 684
 685 pprTCDetails :: [(Tick, Int)] -> SDoc
 686 pprTCDetails ticks
 687   = nest 4 (vcat [int n <+> pprTickCts tick | (tick,n) <- ticks])
 688 \end{code}
 689
 690
 691 \begin{code}
 692 data Tick
 693   = PreInlineUnconditionally    Id
 694   | PostInlineUnconditionally   Id
 695
 696   | UnfoldingDone               Id
 697   | RuleFired                   FastString      -- Rule name
 698
 699   | LetFloatFromLet
 700   | EtaExpansion                Id      -- LHS binder
 701   | EtaReduction                Id      -- Binder on outer lambda
 702   | BetaReduction               Id      -- Lambda binder
 703
 704
 705   | CaseOfCase                  Id      -- Bndr on *inner* case
 706   | KnownBranch                 Id      -- Case binder
 707   | CaseMerge                   Id      -- Binder on outer case
 708   | AltMerge                    Id      -- Case binder
 709   | CaseElim                    Id      -- Case binder
 710   | CaseIdentity                Id      -- Case binder
 711   | FillInCaseDefault           Id      -- Case binder
 712
 713   | BottomFound
 714   | SimplifierDone              -- Ticked at each iteration of the simplifier
 715
 716 instance Outputable Tick where
 717   ppr tick = text (tickString tick) <+> pprTickCts tick
 718
 719 instance Eq Tick where
 720   a == b = case a `cmpTick` b of
 721            EQ -> True
 722            _ -> False
 723
 724 instance Ord Tick where
 725   compare = cmpTick
 726
 727 tickToTag :: Tick -> Int
 728 tickToTag (PreInlineUnconditionally _)  = 0
 729 tickToTag (PostInlineUnconditionally _) = 1
 730 tickToTag (UnfoldingDone _)             = 2
 731 tickToTag (RuleFired _)                 = 3
 732 tickToTag LetFloatFromLet               = 4
 733 tickToTag (EtaExpansion _)              = 5
 734 tickToTag (EtaReduction _)              = 6
 735 tickToTag (BetaReduction _)             = 7
 736 tickToTag (CaseOfCase _)                = 8
 737 tickToTag (KnownBranch _)               = 9
 738 tickToTag (CaseMerge _)                 = 10
 739 tickToTag (CaseElim _)                  = 11
 740 tickToTag (CaseIdentity _)              = 12
 741 tickToTag (FillInCaseDefault _)         = 13
 742 tickToTag BottomFound                   = 14
 743 tickToTag SimplifierDone                = 16
 744 tickToTag (AltMerge _)                  = 17
 745
 746 tickString :: Tick -> String
 747 tickString (PreInlineUnconditionally _) = "PreInlineUnconditionally"
 748 tickString (PostInlineUnconditionally _)= "PostInlineUnconditionally"
 749 tickString (UnfoldingDone _)            = "UnfoldingDone"
 750 tickString (RuleFired _)                = "RuleFired"
 751 tickString LetFloatFromLet              = "LetFloatFromLet"
 752 tickString (EtaExpansion _)             = "EtaExpansion"
 753 tickString (EtaReduction _)             = "EtaReduction"
 754 tickString (BetaReduction _)            = "BetaReduction"
 755 tickString (CaseOfCase _)               = "CaseOfCase"
 756 tickString (KnownBranch _)              = "KnownBranch"
 757 tickString (CaseMerge _)                = "CaseMerge"
 758 tickString (AltMerge _)                 = "AltMerge"
 759 tickString (CaseElim _)                 = "CaseElim"
 760 tickString (CaseIdentity _)             = "CaseIdentity"
 761 tickString (FillInCaseDefault _)        = "FillInCaseDefault"
 762 tickString BottomFound                  = "BottomFound"
 763 tickString SimplifierDone               = "SimplifierDone"
 764
 765 pprTickCts :: Tick -> SDoc
 766 pprTickCts (PreInlineUnconditionally v) = ppr v
 767 pprTickCts (PostInlineUnconditionally v)= ppr v
 768 pprTickCts (UnfoldingDone v)            = ppr v
 769 pprTickCts (RuleFired v)                = ppr v
 770 pprTickCts LetFloatFromLet              = empty
 771 pprTickCts (EtaExpansion v)             = ppr v
 772 pprTickCts (EtaReduction v)             = ppr v
 773 pprTickCts (BetaReduction v)            = ppr v
 774 pprTickCts (CaseOfCase v)               = ppr v
 775 pprTickCts (KnownBranch v)              = ppr v
 776 pprTickCts (CaseMerge v)                = ppr v
 777 pprTickCts (AltMerge v)                 = ppr v
 778 pprTickCts (CaseElim v)                 = ppr v
 779 pprTickCts (CaseIdentity v)             = ppr v
 780 pprTickCts (FillInCaseDefault v)        = ppr v
 781 pprTickCts _                            = empty
 782
 783 cmpTick :: Tick -> Tick -> Ordering
 784 cmpTick a b = case (tickToTag a `compare` tickToTag b) of
 785                 GT -> GT
 786                 EQ -> cmpEqTick a b
 787                 LT -> LT
 788
 789 cmpEqTick :: Tick -> Tick -> Ordering
 790 cmpEqTick (PreInlineUnconditionally a)  (PreInlineUnconditionally b)    = a `compare` b
 791 cmpEqTick (PostInlineUnconditionally a) (PostInlineUnconditionally b)   = a `compare` b
 792 cmpEqTick (UnfoldingDone a)             (UnfoldingDone b)               = a `compare` b
 793 cmpEqTick (RuleFired a)                 (RuleFired b)                   = a `compare` b
 794 cmpEqTick (EtaExpansion a)              (EtaExpansion b)                = a `compare` b
 795 cmpEqTick (EtaReduction a)              (EtaReduction b)                = a `compare` b
 796 cmpEqTick (BetaReduction a)             (BetaReduction b)               = a `compare` b
 797 cmpEqTick (CaseOfCase a)                (CaseOfCase b)                  = a `compare` b
 798 cmpEqTick (KnownBranch a)               (KnownBranch b)                 = a `compare` b
 799 cmpEqTick (CaseMerge a)                 (CaseMerge b)                   = a `compare` b
 800 cmpEqTick (AltMerge a)                  (AltMerge b)                    = a `compare` b
 801 cmpEqTick (CaseElim a)                  (CaseElim b)                    = a `compare` b
 802 cmpEqTick (CaseIdentity a)              (CaseIdentity b)                = a `compare` b
 803 cmpEqTick (FillInCaseDefault a)         (FillInCaseDefault b)           = a `compare` b
 804 cmpEqTick _                             _                               = EQ
 805 \end{code}
 806
 807
 808 %************************************************************************
 809 %*                                                                      *
 810              Monad and carried data structure definitions
 811 %*                                                                      *
 812 %************************************************************************
 813
 814 \begin{code}
 815 newtype CoreState = CoreState {
 816         cs_uniq_supply :: UniqSupply
 817 }
 818
 819 data CoreReader = CoreReader {
 820         cr_hsc_env :: HscEnv,
 821         cr_rule_base :: RuleBase,
 822         cr_module :: Module
 823 }
 824
 825 data CoreWriter = CoreWriter {
 826         cw_simpl_count :: SimplCount
 827 }
 828
 829 emptyWriter :: DynFlags -> CoreWriter
 830 emptyWriter dflags = CoreWriter {
 831         cw_simpl_count = zeroSimplCount dflags
 832     }
 833
 834 plusWriter :: CoreWriter -> CoreWriter -> CoreWriter
 835 plusWriter w1 w2 = CoreWriter {
 836         cw_simpl_count = (cw_simpl_count w1) `plusSimplCount` (cw_simpl_count w2)
 837     }
 838
 839 type CoreIOEnv = IOEnv CoreReader
 840
 841 -- | The monad used by Core-to-Core passes to access common state, register simplification
 842 -- statistics and so on
 843 newtype CoreM a = CoreM { unCoreM :: CoreState -> CoreIOEnv (a, CoreState, CoreWriter) }
 844
 845 instance Functor CoreM where
 846     fmap f ma = do
 847         a <- ma
 848         return (f a)
 849
 850 instance Monad CoreM where
 851     return x = CoreM (\s -> nop s x)
 852     mx >>= f = CoreM $ \s -> do
 853             (x, s', w1) <- unCoreM mx s
 854             (y, s'', w2) <- unCoreM (f x) s'
 855             return (y, s'', w1 `plusWriter` w2)
 856
 857 instance Applicative CoreM where
 858     pure = return
 859     (<*>) = ap
 860
 861 -- For use if the user has imported Control.Monad.Error from MTL
 862 -- Requires UndecidableInstances
 863 instance MonadPlus IO => MonadPlus CoreM where
 864     mzero = CoreM (const mzero)
 865     m `mplus` n = CoreM (\rs -> unCoreM m rs `mplus` unCoreM n rs)
 866
 867 instance MonadUnique CoreM where
 868     getUniqueSupplyM = do
 869         us <- getS cs_uniq_supply
 870         let (us1, us2) = splitUniqSupply us
 871         modifyS (\s -> s { cs_uniq_supply = us2 })
 872         return us1
 873
 874 runCoreM :: HscEnv
 875          -> RuleBase
 876          -> UniqSupply
 877          -> Module
 878          -> CoreM a
 879          -> IO (a, SimplCount)
 880 runCoreM hsc_env rule_base us mod m =
 881         liftM extract $ runIOEnv reader $ unCoreM m state
 882   where
 883     reader = CoreReader {
 884             cr_hsc_env = hsc_env,
 885             cr_rule_base = rule_base,
 886             cr_module = mod
 887         }
 888     state = CoreState {
 889             cs_uniq_supply = us
 890         }
 891
 892     extract :: (a, CoreState, CoreWriter) -> (a, SimplCount)
 893     extract (value, _, writer) = (value, cw_simpl_count writer)
 894
 895 \end{code}
 896
 897
 898 %************************************************************************
 899 %*                                                                      *
 900              Core combinators, not exported
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 \begin{code}
 905
 906 nop :: CoreState -> a -> CoreIOEnv (a, CoreState, CoreWriter)
 907 nop s x = do
 908     r <- getEnv
 909     return (x, s, emptyWriter $ (hsc_dflags . cr_hsc_env) r)
 910
 911 read :: (CoreReader -> a) -> CoreM a
 912 read f = CoreM (\s -> getEnv >>= (\r -> nop s (f r)))
 913
 914 getS :: (CoreState -> a) -> CoreM a
 915 getS f = CoreM (\s -> nop s (f s))
 916
 917 modifyS :: (CoreState -> CoreState) -> CoreM ()
 918 modifyS f = CoreM (\s -> nop (f s) ())
 919
 920 write :: CoreWriter -> CoreM ()
 921 write w = CoreM (\s -> return ((), s, w))
 922
 923 \end{code}
 924
 925 \subsection{Lifting IO into the monad}
 926
 927 \begin{code}
 928
 929 -- | Lift an 'IOEnv' operation into 'CoreM'
 930 liftIOEnv :: CoreIOEnv a -> CoreM a
 931 liftIOEnv mx = CoreM (\s -> mx >>= (\x -> nop s x))
 932
 933 instance MonadIO CoreM where
 934     liftIO = liftIOEnv . IOEnv.liftIO
 935
 936 -- | Lift an 'IO' operation into 'CoreM' while consuming its 'SimplCount'
 937 liftIOWithCount :: IO (SimplCount, a) -> CoreM a
 938 liftIOWithCount what = liftIO what >>= (\(count, x) -> addSimplCount count >> return x)
 939
 940 \end{code}
 941
 942
 943 %************************************************************************
 944 %*                                                                      *
 945              Reader, writer and state accessors
 946 %*                                                                      *
 947 %************************************************************************
 948
 949 \begin{code}
 950
 951 getHscEnv :: CoreM HscEnv
 952 getHscEnv = read cr_hsc_env
 953
 954 getRuleBase :: CoreM RuleBase
 955 getRuleBase = read cr_rule_base
 956
 957 getModule :: CoreM Module
 958 getModule = read cr_module
 959
 960 addSimplCount :: SimplCount -> CoreM ()
 961 addSimplCount count = write (CoreWriter { cw_simpl_count = count })
 962
 963 -- Convenience accessors for useful fields of HscEnv
 964
 965 getDynFlags :: CoreM DynFlags
 966 getDynFlags = fmap hsc_dflags getHscEnv
 967
 968 -- | The original name cache is the current mapping from 'Module' and
 969 -- 'OccName' to a compiler-wide unique 'Name'
 970 getOrigNameCache :: CoreM OrigNameCache
 971 getOrigNameCache = do
 972     nameCacheRef <- fmap hsc_NC getHscEnv
 973     liftIO $ fmap nsNames $ readIORef nameCacheRef
 974
 975 \end{code}
 976
 977
 978 %************************************************************************
 979 %*                                                                      *
 980              Dealing with annotations
 981 %*                                                                      *
 982 %************************************************************************
 983
 984 \begin{code}
 985 -- | Get all annotations of a given type. This happens lazily, that is
 986 -- no deserialization will take place until the [a] is actually demanded and
 987 -- the [a] can also be empty (the UniqFM is not filtered).
 988 --
 989 -- This should be done once at the start of a Core-to-Core pass that uses
 990 -- annotations.
 991 --
 992 -- See Note [Annotations]
 993 getAnnotations :: Typeable a => ([Word8] -> a) -> ModGuts -> CoreM (UniqFM [a])
 994 getAnnotations deserialize guts = do
 995      hsc_env <- getHscEnv
 996      ann_env <- liftIO $ prepareAnnotations hsc_env (Just guts)
 997      return (deserializeAnns deserialize ann_env)
 998
 999 -- | Get at most one annotation of a given type per Unique.
1000 getFirstAnnotations :: Typeable a => ([Word8] -> a) -> ModGuts -> CoreM (UniqFM a)
1001 getFirstAnnotations deserialize guts
1002   = liftM (mapUFM head . filterUFM (not . null))
1003   $ getAnnotations deserialize guts
1004
1005 \end{code}
1006
1007 Note [Annotations]
1008 ~~~~~~~~~~~~~~~~~~
1009 A Core-to-Core pass that wants to make use of annotations calls
1010 getAnnotations or getFirstAnnotations at the beginning to obtain a UniqFM with
1011 annotations of a specific type. This produces all annotations from interface
1012 files read so far. However, annotations from interface files read during the
1013 pass will not be visible until getAnnotations is called again. This is similar
1014 to how rules work and probably isn't too bad.
1015
1016 The current implementation could be optimised a bit: when looking up
1017 annotations for a thing from the HomePackageTable, we could search directly in
1018 the module where the thing is defined rather than building one UniqFM which
1019 contains all annotations we know of. This would work because annotations can
1020 only be given to things defined in the same module. However, since we would
1021 only want to deserialise every annotation once, we would have to build a cache
1022 for every module in the HTP. In the end, it's probably not worth it as long as
1023 we aren't using annotations heavily.
1024
1025 %************************************************************************
1026 %*                                                                      *
1027                 Direct screen output
1028 %*                                                                      *
1029 %************************************************************************
1030
1031 \begin{code}
1032
1033 msg :: (DynFlags -> SDoc -> IO ()) -> SDoc -> CoreM ()
1034 msg how doc = do
1035         dflags <- getDynFlags
1036         liftIO $ how dflags doc
1037
1038 -- | Output a String message to the screen
1039 putMsgS :: String -> CoreM ()
1040 putMsgS = putMsg . text
1041
1042 -- | Output a message to the screen
1043 putMsg :: SDoc -> CoreM ()
1044 putMsg = msg Err.putMsg
1045
1046 -- | Output a string error to the screen
1047 errorMsgS :: String -> CoreM ()
1048 errorMsgS = errorMsg . text
1049
1050 -- | Output an error to the screen
1051 errorMsg :: SDoc -> CoreM ()
1052 errorMsg = msg Err.errorMsg
1053
1054 -- | Output a fatal string error to the screen. Note this does not by itself cause the compiler to die
1055 fatalErrorMsgS :: String -> CoreM ()
1056 fatalErrorMsgS = fatalErrorMsg . text
1057
1058 -- | Output a fatal error to the screen. Note this does not by itself cause the compiler to die
1059 fatalErrorMsg :: SDoc -> CoreM ()
1060 fatalErrorMsg = msg Err.fatalErrorMsg
1061
1062 -- | Output a string debugging message at verbosity level of @-v@ or higher
1063 debugTraceMsgS :: String -> CoreM ()
1064 debugTraceMsgS = debugTraceMsg . text
1065
1066 -- | Outputs a debugging message at verbosity level of @-v@ or higher
1067 debugTraceMsg :: SDoc -> CoreM ()
1068 debugTraceMsg = msg (flip Err.debugTraceMsg 3)
1069
1070 -- | Show some labelled 'SDoc' if a particular flag is set or at a verbosity level of @-v -ddump-most@ or higher
1071 dumpIfSet_dyn :: DynFlag -> String -> SDoc -> CoreM ()
1072 dumpIfSet_dyn flag str = msg (\dflags -> Err.dumpIfSet_dyn dflags flag str)
1073 \end{code}
1074
1075 \begin{code}
1076
1077 initTcForLookup :: HscEnv -> TcM a -> IO a
1078 initTcForLookup hsc_env = liftM (expectJust "initTcInteractive" . snd) . initTc hsc_env HsSrcFile False iNTERACTIVE
1079
1080 \end{code}
1081
1082
1083 %************************************************************************
1084 %*                                                                      *
1085                Finding TyThings
1086 %*                                                                      *
1087 %************************************************************************
1088
1089 \begin{code}
1090 instance MonadThings CoreM where
1091     lookupThing name = do
1092         hsc_env <- getHscEnv
1093         liftIO $ initTcForLookup hsc_env (tcLookupGlobal name)
1094 \end{code}
1095
1096 %************************************************************************
1097 %*                                                                      *
1098                Template Haskell interoperability
1099 %*                                                                      *
1100 %************************************************************************
1101
1102 \begin{code}
1103 #ifdef GHCI
1104 -- | Attempt to convert a Template Haskell name to one that GHC can
1105 -- understand. Original TH names such as those you get when you use
1106 -- the @'foo@ syntax will be translated to their equivalent GHC name
1107 -- exactly. Qualified or unqualifed TH names will be dynamically bound
1108 -- to names in the module being compiled, if possible. Exact TH names
1109 -- will be bound to the name they represent, exactly.
1110 thNameToGhcName :: TH.Name -> CoreM (Maybe Name)
1111 thNameToGhcName th_name = do
1112     hsc_env <- getHscEnv
1113     liftIO $ initTcForLookup hsc_env (lookupThName_maybe th_name)
1114 #endif
1115 \end{code}