compiler/simplCore/FloatIn.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 %************************************************************************
   5 %*                                                                      *
   6 \section[FloatIn]{Floating Inwards pass}
   7 %*                                                                      *
   8 %************************************************************************
   9
  10 The main purpose of @floatInwards@ is floating into branches of a
  11 case, so that we don't allocate things, save them on the stack, and
  12 then discover that they aren't needed in the chosen branch.
  13
  14 \begin{code}
  15 module FloatIn ( floatInwards ) where
  16
  17 #include "HsVersions.h"
  18
  19 import DynFlags ( DynFlags, DynFlag(..) )
  20 import CoreSyn
  21 import CoreUtils        ( exprIsHNF, exprIsDupable )
  22 import CoreLint         ( showPass, endPass )
  23 import CoreFVs          ( CoreExprWithFVs, freeVars, freeVarsOf )
  24 import Id               ( isOneShotBndr )
  25 import Var              ( Id, idType )
  26 import Type             ( isUnLiftedType )
  27 import VarSet
  28 import Util             ( zipEqual, zipWithEqual, count )
  29 import Outputable
  30 \end{code}
  31
  32 Top-level interface function, @floatInwards@.  Note that we do not
  33 actually float any bindings downwards from the top-level.
  34
  35 \begin{code}
  36 floatInwards :: DynFlags -> [CoreBind] -> IO [CoreBind]
  37
  38 floatInwards dflags binds
  39   = do {
  40         showPass dflags "Float inwards";
  41         let { binds' = map fi_top_bind binds };
  42         endPass dflags "Float inwards" Opt_D_verbose_core2core binds'
  43                                 {- no specific flag for dumping float-in -}
  44     }
  45
  46   where
  47     fi_top_bind (NonRec binder rhs)
  48       = NonRec binder (fiExpr [] (freeVars rhs))
  49     fi_top_bind (Rec pairs)
  50       = Rec [ (b, fiExpr [] (freeVars rhs)) | (b, rhs) <- pairs ]
  51 \end{code}
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection{Mail from Andr\'e [edited]}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 {\em Will wrote: What??? I thought the idea was to float as far
  60 inwards as possible, no matter what.  This is dropping all bindings
  61 every time it sees a lambda of any kind.  Help! }
  62
  63 You are assuming we DO DO full laziness AFTER floating inwards!  We
  64 have to [not float inside lambdas] if we don't.
  65
  66 If we indeed do full laziness after the floating inwards (we could
  67 check the compilation flags for that) then I agree we could be more
  68 aggressive and do float inwards past lambdas.
  69
  70 Actually we are not doing a proper full laziness (see below), which
  71 was another reason for not floating inwards past a lambda.
  72
  73 This can easily be fixed.  The problem is that we float lets outwards,
  74 but there are a few expressions which are not let bound, like case
  75 scrutinees and case alternatives.  After floating inwards the
  76 simplifier could decide to inline the let and the laziness would be
  77 lost, e.g.
  78
  79 \begin{verbatim}
  80 let a = expensive             ==> \b -> case expensive of ...
  81 in \ b -> case a of ...
  82 \end{verbatim}
  83 The fix is
  84 \begin{enumerate}
  85 \item
  86 to let bind the algebraic case scrutinees (done, I think) and
  87 the case alternatives (except the ones with an
  88 unboxed type)(not done, I think). This is best done in the
  89 SetLevels.lhs module, which tags things with their level numbers.
  90 \item
  91 do the full laziness pass (floating lets outwards).
  92 \item
  93 simplify. The simplifier inlines the (trivial) lets that were
  94  created but were not floated outwards.
  95 \end{enumerate}
  96
  97 With the fix I think Will's suggestion that we can gain even more from
  98 strictness by floating inwards past lambdas makes sense.
  99
 100 We still gain even without going past lambdas, as things may be
 101 strict in the (new) context of a branch (where it was floated to) or
 102 of a let rhs, e.g.
 103 \begin{verbatim}
 104 let a = something            case x of
 105 in case x of                   alt1 -> case something of a -> a + a
 106      alt1 -> a + a      ==>    alt2 -> b
 107      alt2 -> b
 108
 109 let a = something           let b = case something of a -> a + a
 110 in let b = a + a        ==> in (b,b)
 111 in (b,b)
 112 \end{verbatim}
 113 Also, even if a is not found to be strict in the new context and is
 114 still left as a let, if the branch is not taken (or b is not entered)
 115 the closure for a is not built.
 116
 117 %************************************************************************
 118 %*                                                                      *
 119 \subsection{Main floating-inwards code}
 120 %*                                                                      *
 121 %************************************************************************
 122
 123 \begin{code}
 124 type FreeVarsSet   = IdSet
 125
 126 type FloatingBinds = [(CoreBind, FreeVarsSet)]
 127         -- In reverse dependency order (innermost bindiner first)
 128
 129         -- The FreeVarsSet is the free variables of the binding.  In the case
 130         -- of recursive bindings, the set doesn't include the bound
 131         -- variables.
 132
 133 fiExpr :: FloatingBinds         -- Binds we're trying to drop
 134                                 -- as far "inwards" as possible
 135        -> CoreExprWithFVs       -- Input expr
 136        -> CoreExpr              -- Result
 137
 138 fiExpr to_drop (_, AnnVar v) = mkCoLets' to_drop (Var v)
 139
 140 fiExpr to_drop (_, AnnType ty) = ASSERT( null to_drop )
 141                                  Type ty
 142 fiExpr to_drop (_, AnnCast expr co)
 143   = Cast (fiExpr to_drop expr) co       -- Just float in past coercion
 144
 145 fiExpr to_drop (_, AnnLit lit) = Lit lit
 146 \end{code}
 147
 148 Applications: we do float inside applications, mainly because we
 149 need to get at all the arguments.  The next simplifier run will
 150 pull out any silly ones.
 151
 152 \begin{code}
 153 fiExpr to_drop (_,AnnApp fun arg)
 154   = mkCoLets' drop_here (App (fiExpr fun_drop fun) (fiExpr arg_drop arg))
 155   where
 156     [drop_here, fun_drop, arg_drop] = sepBindsByDropPoint False [freeVarsOf fun, freeVarsOf arg] to_drop
 157 \end{code}
 158
 159 We are careful about lambdas:
 160
 161 * We must be careful about floating inside inside a value lambda.
 162   That risks losing laziness.
 163   The float-out pass might rescue us, but then again it might not.
 164
 165 * We must be careful about type lambdas too.  At one time we did, and
 166   there is no risk of duplicating work thereby, but we do need to be
 167   careful.  In particular, here is a bad case (it happened in the
 168   cichelli benchmark:
 169         let v = ...
 170         in let f = /\t -> \a -> ...
 171            ==>
 172         let f = /\t -> let v = ... in \a -> ...
 173   This is bad as now f is an updatable closure (update PAP)
 174   and has arity 0.
 175
 176 So we treat lambda in groups, using the following rule:
 177
 178         Float inside a group of lambdas only if
 179         they are all either type lambdas or one-shot lambdas.
 180
 181         Otherwise drop all the bindings outside the group.
 182
 183 \begin{code}
 184         -- Hack alert!  We only float in through one-shot lambdas,
 185         -- not (as you might guess) through big lambdas.
 186         -- Reason: we float *out* past big lambdas (see the test in the Lam
 187         -- case of FloatOut.floatExpr) and we don't want to float straight
 188         -- back in again.
 189         --
 190         -- It *is* important to float into one-shot lambdas, however;
 191         -- see the remarks with noFloatIntoRhs.
 192 fiExpr to_drop lam@(_, AnnLam _ _)
 193   | all is_one_shot bndrs       -- Float in
 194   = mkLams bndrs (fiExpr to_drop body)
 195
 196   | otherwise           -- Dump it all here
 197   = mkCoLets' to_drop (mkLams bndrs (fiExpr [] body))
 198
 199   where
 200     (bndrs, body) = collectAnnBndrs lam
 201 \end{code}
 202
 203 We don't float lets inwards past an SCC.
 204         ToDo: keep info on current cc, and when passing
 205         one, if it is not the same, annotate all lets in binds with current
 206         cc, change current cc to the new one and float binds into expr.
 207
 208 \begin{code}
 209 fiExpr to_drop (_, AnnNote note@(SCC cc) expr)
 210   =     -- Wimp out for now
 211     mkCoLets' to_drop (Note note (fiExpr [] expr))
 212
 213 fiExpr to_drop (_, AnnNote InlineMe expr)
 214   =     -- Ditto... don't float anything into an INLINE expression
 215     mkCoLets' to_drop (Note InlineMe (fiExpr [] expr))
 216
 217 fiExpr to_drop (_, AnnNote note@(CoreNote _) expr)
 218   = Note note (fiExpr to_drop expr)
 219 \end{code}
 220
 221 For @Lets@, the possible ``drop points'' for the \tr{to_drop}
 222 bindings are: (a)~in the body, (b1)~in the RHS of a NonRec binding,
 223 or~(b2), in each of the RHSs of the pairs of a @Rec@.
 224
 225 Note that we do {\em weird things} with this let's binding.  Consider:
 226 \begin{verbatim}
 227 let
 228     w = ...
 229 in {
 230     let v = ... w ...
 231     in ... v .. w ...
 232 }
 233 \end{verbatim}
 234 Look at the inner \tr{let}.  As \tr{w} is used in both the bind and
 235 body of the inner let, we could panic and leave \tr{w}'s binding where
 236 it is.  But \tr{v} is floatable further into the body of the inner let, and
 237 {\em then} \tr{w} will also be only in the body of that inner let.
 238
 239 So: rather than drop \tr{w}'s binding here, we add it onto the list of
 240 things to drop in the outer let's body, and let nature take its
 241 course.
 242
 243 \begin{code}
 244 fiExpr to_drop (_,AnnLet (AnnNonRec id rhs@(rhs_fvs, ann_rhs)) body)
 245   = fiExpr new_to_drop body
 246   where
 247     body_fvs = freeVarsOf body
 248
 249     final_body_fvs | noFloatIntoRhs ann_rhs
 250                    || isUnLiftedType (idType id) = body_fvs `unionVarSet` rhs_fvs
 251                    | otherwise                   = body_fvs
 252         -- See commments with letrec below
 253         -- No point in floating in only to float straight out again
 254         -- Ditto ok-for-speculation unlifted RHSs
 255
 256     [shared_binds, rhs_binds, body_binds] = sepBindsByDropPoint False [rhs_fvs, final_body_fvs] to_drop
 257
 258     new_to_drop = body_binds ++                         -- the bindings used only in the body
 259                   [(NonRec id rhs', rhs_fvs')] ++       -- the new binding itself
 260                   shared_binds                          -- the bindings used both in rhs and body
 261
 262         -- Push rhs_binds into the right hand side of the binding
 263     rhs'     = fiExpr rhs_binds rhs
 264     rhs_fvs' = rhs_fvs `unionVarSet` floatedBindsFVs rhs_binds
 265
 266 fiExpr to_drop (_,AnnLet (AnnRec bindings) body)
 267   = fiExpr new_to_drop body
 268   where
 269     rhss = map snd bindings
 270
 271     rhss_fvs = map freeVarsOf rhss
 272     body_fvs = freeVarsOf body
 273
 274         -- Add to body_fvs the free vars of any RHS that has
 275         -- a lambda at the top.  This has the effect of making it seem
 276         -- that such things are used in the body as well, and hence prevents
 277         -- them getting floated in.  The big idea is to avoid turning:
 278         --      let x# = y# +# 1#
 279         --      in
 280         --      letrec f = \z. ...x#...f...
 281         --      in ...
 282         -- into
 283         --      letrec f = let x# = y# +# 1# in \z. ...x#...f... in ...
 284         --
 285         -- Because now we can't float the let out again, because a letrec
 286         -- can't have unboxed bindings.
 287
 288     final_body_fvs = foldr (unionVarSet . get_extras) body_fvs rhss
 289     get_extras (rhs_fvs, rhs) | noFloatIntoRhs rhs = rhs_fvs
 290                               | otherwise          = emptyVarSet
 291
 292     (shared_binds:body_binds:rhss_binds) = sepBindsByDropPoint False (final_body_fvs:rhss_fvs) to_drop
 293
 294     new_to_drop = -- the bindings used only in the body
 295                   body_binds ++
 296                   -- the new binding itself
 297                   [(Rec (fi_bind rhss_binds bindings), rhs_fvs')] ++
 298                   -- the bindings used both in rhs and body or in more than one rhs
 299                   shared_binds
 300
 301     rhs_fvs' = unionVarSet (unionVarSets rhss_fvs)
 302                            (unionVarSets (map floatedBindsFVs rhss_binds))
 303
 304     -- Push rhs_binds into the right hand side of the binding
 305     fi_bind :: [FloatingBinds]      -- one per "drop pt" conjured w/ fvs_of_rhss
 306             -> [(Id, CoreExprWithFVs)]
 307             -> [(Id, CoreExpr)]
 308
 309     fi_bind to_drops pairs
 310       = [ (binder, fiExpr to_drop rhs)
 311         | ((binder, rhs), to_drop) <- zipEqual "fi_bind" pairs to_drops ]
 312 \end{code}
 313
 314 For @Case@, the possible ``drop points'' for the \tr{to_drop}
 315 bindings are: (a)~inside the scrutinee, (b)~inside one of the
 316 alternatives/default [default FVs always {\em first}!].
 317
 318 \begin{code}
 319 fiExpr to_drop (_, AnnCase scrut case_bndr ty alts)
 320   = mkCoLets' drop_here1 $
 321     mkCoLets' drop_here2 $
 322     Case (fiExpr scrut_drops scrut) case_bndr ty
 323          (zipWith fi_alt alts_drops_s alts)
 324   where
 325         -- Float into the scrut and alts-considered-together just like App
 326     [drop_here1, scrut_drops, alts_drops] = sepBindsByDropPoint False [scrut_fvs, all_alts_fvs] to_drop
 327
 328         -- Float into the alts with the is_case flag set
 329     (drop_here2 : alts_drops_s)           = sepBindsByDropPoint True alts_fvs alts_drops
 330
 331     scrut_fvs    = freeVarsOf scrut
 332     alts_fvs     = map alt_fvs alts
 333     all_alts_fvs = unionVarSets alts_fvs
 334     alt_fvs (con, args, rhs) = foldl delVarSet (freeVarsOf rhs) (case_bndr:args)
 335                                 -- Delete case_bndr and args from free vars of rhs
 336                                 -- to get free vars of alt
 337
 338     fi_alt to_drop (con, args, rhs) = (con, args, fiExpr to_drop rhs)
 339
 340 noFloatIntoRhs (AnnNote InlineMe _) = True
 341 noFloatIntoRhs (AnnLam b _)         = not (is_one_shot b)
 342         -- IMPORTANT: don't say 'True' for a RHS with a one-shot lambda at the top.
 343         -- This makes a big difference for things like
 344         --      f x# = let x = I# x#
 345         --             in let j = \() -> ...x...
 346         --                in if <condition> then normal-path else j ()
 347         -- If x is used only in the error case join point, j, we must float the
 348         -- boxing constructor into it, else we box it every time which is very bad
 349         -- news indeed.
 350
 351 noFloatIntoRhs rhs = exprIsHNF (deAnnotate' rhs)        -- We'd just float right back out again...
 352
 353 is_one_shot b = isId b && isOneShotBndr b
 354 \end{code}
 355
 356
 357 %************************************************************************
 358 %*                                                                      *
 359 \subsection{@sepBindsByDropPoint@}
 360 %*                                                                      *
 361 %************************************************************************
 362
 363 This is the crucial function.  The idea is: We have a wad of bindings
 364 that we'd like to distribute inside a collection of {\em drop points};
 365 insides the alternatives of a \tr{case} would be one example of some
 366 drop points; the RHS and body of a non-recursive \tr{let} binding
 367 would be another (2-element) collection.
 368
 369 So: We're given a list of sets-of-free-variables, one per drop point,
 370 and a list of floating-inwards bindings.  If a binding can go into
 371 only one drop point (without suddenly making something out-of-scope),
 372 in it goes.  If a binding is used inside {\em multiple} drop points,
 373 then it has to go in a you-must-drop-it-above-all-these-drop-points
 374 point.
 375
 376 We have to maintain the order on these drop-point-related lists.
 377
 378 \begin{code}
 379 sepBindsByDropPoint
 380     :: Bool                 -- True <=> is case expression
 381     -> [FreeVarsSet]        -- One set of FVs per drop point
 382     -> FloatingBinds        -- Candidate floaters
 383     -> [FloatingBinds]      -- FIRST one is bindings which must not be floated
 384                             -- inside any drop point; the rest correspond
 385                             -- one-to-one with the input list of FV sets
 386
 387 -- Every input floater is returned somewhere in the result;
 388 -- none are dropped, not even ones which don't seem to be
 389 -- free in *any* of the drop-point fvs.  Why?  Because, for example,
 390 -- a binding (let x = E in B) might have a specialised version of
 391 -- x (say x') stored inside x, but x' isn't free in E or B.
 392
 393 type DropBox = (FreeVarsSet, FloatingBinds)
 394
 395 sepBindsByDropPoint is_case drop_pts []
 396   = [] : [[] | p <- drop_pts]   -- cut to the chase scene; it happens
 397
 398 sepBindsByDropPoint is_case drop_pts floaters
 399   = go floaters (map (\fvs -> (fvs, [])) (emptyVarSet : drop_pts))
 400   where
 401     go :: FloatingBinds -> [DropBox] -> [FloatingBinds]
 402         -- The *first* one in the argument list is the drop_here set
 403         -- The FloatingBinds in the lists are in the reverse of
 404         -- the normal FloatingBinds order; that is, they are the right way round!
 405
 406     go [] drop_boxes = map (reverse . snd) drop_boxes
 407
 408     go (bind_w_fvs@(bind, bind_fvs) : binds) drop_boxes@(here_box : fork_boxes)
 409         = go binds new_boxes
 410         where
 411           -- "here" means the group of bindings dropped at the top of the fork
 412
 413           (used_here : used_in_flags) = [ any (`elemVarSet` fvs) (bindersOf bind)
 414                                         | (fvs, drops) <- drop_boxes]
 415
 416           drop_here = used_here || not can_push
 417
 418                 -- For case expressions we duplicate the binding if it is
 419                 -- reasonably small, and if it is not used in all the RHSs
 420                 -- This is good for situations like
 421                 --      let x = I# y in
 422                 --      case e of
 423                 --        C -> error x
 424                 --        D -> error x
 425                 --        E -> ...not mentioning x...
 426
 427           n_alts      = length used_in_flags
 428           n_used_alts = count id used_in_flags -- returns number of Trues in list.
 429
 430           can_push = n_used_alts == 1           -- Used in just one branch
 431                    || (is_case &&               -- We are looking at case alternatives
 432                        n_used_alts > 1 &&       -- It's used in more than one
 433                        n_used_alts < n_alts &&  -- ...but not all
 434                        bindIsDupable bind)      -- and we can duplicate the binding
 435
 436           new_boxes | drop_here = (insert here_box : fork_boxes)
 437                     | otherwise = (here_box : new_fork_boxes)
 438
 439           new_fork_boxes = zipWithEqual "FloatIn.sepBinds" insert_maybe fork_boxes used_in_flags
 440
 441           insert :: DropBox -> DropBox
 442           insert (fvs,drops) = (fvs `unionVarSet` bind_fvs, bind_w_fvs:drops)
 443
 444           insert_maybe box True  = insert box
 445           insert_maybe box False = box
 446
 447
 448 floatedBindsFVs :: FloatingBinds -> FreeVarsSet
 449 floatedBindsFVs binds = unionVarSets (map snd binds)
 450
 451 mkCoLets' :: FloatingBinds -> CoreExpr -> CoreExpr
 452 mkCoLets' to_drop e = foldl (flip (Let . fst)) e to_drop
 453         -- Remember to_drop is in *reverse* dependency order
 454
 455 bindIsDupable (Rec prs)    = all (exprIsDupable . snd) prs
 456 bindIsDupable (NonRec b r) = exprIsDupable r
 457 \end{code}