compiler/simplCore/SetLevels.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{SetLevels}
   5
   6                 ***************************
   7                         Overview
   8                 ***************************
   9
  10 1. We attach binding levels to Core bindings, in preparation for floating
  11    outwards (@FloatOut@).
  12
  13 2. We also let-ify many expressions (notably case scrutinees), so they
  14    will have a fighting chance of being floated sensible.
  15
  16 3. We clone the binders of any floatable let-binding, so that when it is
  17    floated out it will be unique.  (This used to be done by the simplifier
  18    but the latter now only ensures that there's no shadowing; indeed, even
  19    that may not be true.)
  20
  21    NOTE: this can't be done using the uniqAway idea, because the variable
  22          must be unique in the whole program, not just its current scope,
  23          because two variables in different scopes may float out to the
  24          same top level place
  25
  26    NOTE: Very tiresomely, we must apply this substitution to
  27          the rules stored inside a variable too.
  28
  29    We do *not* clone top-level bindings, because some of them must not change,
  30    but we *do* clone bindings that are heading for the top level
  31
  32 4. In the expression
  33         case x of wild { p -> ...wild... }
  34    we substitute x for wild in the RHS of the case alternatives:
  35         case x of wild { p -> ...x... }
  36    This means that a sub-expression involving x is not "trapped" inside the RHS.
  37    And it's not inconvenient because we already have a substitution.
  38
  39   Note that this is EXACTLY BACKWARDS from the what the simplifier does.
  40   The simplifier tries to get rid of occurrences of x, in favour of wild,
  41   in the hope that there will only be one remaining occurrence of x, namely
  42   the scrutinee of the case, and we can inline it.
  43
  44 \begin{code}
  45 module SetLevels (
  46         setLevels,
  47
  48         Level(..), tOP_LEVEL,
  49         LevelledBind, LevelledExpr,
  50
  51         incMinorLvl, ltMajLvl, ltLvl, isTopLvl, isInlineCtxt
  52     ) where
  53
  54 #include "HsVersions.h"
  55
  56 import CoreSyn
  57
  58 import DynFlags ( FloatOutSwitches(..) )
  59 import CoreUtils        ( exprType, exprIsTrivial, exprIsCheap, mkPiTypes )
  60 import CoreFVs          -- all of it
  61 import CoreSubst        ( Subst, emptySubst, extendInScope, extendIdSubst,
  62                           cloneIdBndr, cloneRecIdBndrs )
  63 import Id               ( Id, idType, mkSysLocal, isOneShotLambda,
  64                           zapDemandIdInfo,
  65                           idSpecialisation, idWorkerInfo, setIdInfo
  66                         )
  67 import IdInfo           ( workerExists, vanillaIdInfo, isEmptySpecInfo )
  68 import Var              ( Var )
  69 import VarSet
  70 import VarEnv
  71 import Name             ( getOccName )
  72 import OccName          ( occNameString )
  73 import Type             ( isUnLiftedType, Type )
  74 import BasicTypes       ( TopLevelFlag(..) )
  75 import UniqSupply
  76 import Util             ( sortLe, isSingleton, count )
  77 import Outputable
  78 import FastString
  79 \end{code}
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Level numbers}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 data Level = InlineCtxt -- A level that's used only for
  89                         -- the context parameter ctxt_lvl
  90            | Level Int  -- Level number of enclosing lambdas
  91                    Int  -- Number of big-lambda and/or case expressions between
  92                         -- here and the nearest enclosing lambda
  93 \end{code}
  94
  95 The {\em level number} on a (type-)lambda-bound variable is the
  96 nesting depth of the (type-)lambda which binds it.  The outermost lambda
  97 has level 1, so (Level 0 0) means that the variable is bound outside any lambda.
  98
  99 On an expression, it's the maximum level number of its free
 100 (type-)variables.  On a let(rec)-bound variable, it's the level of its
 101 RHS.  On a case-bound variable, it's the number of enclosing lambdas.
 102
 103 Top-level variables: level~0.  Those bound on the RHS of a top-level
 104 definition but ``before'' a lambda; e.g., the \tr{x} in (levels shown
 105 as ``subscripts'')...
 106 \begin{verbatim}
 107 a_0 = let  b_? = ...  in
 108            x_1 = ... b ... in ...
 109 \end{verbatim}
 110
 111 The main function @lvlExpr@ carries a ``context level'' (@ctxt_lvl@).
 112 That's meant to be the level number of the enclosing binder in the
 113 final (floated) program.  If the level number of a sub-expression is
 114 less than that of the context, then it might be worth let-binding the
 115 sub-expression so that it will indeed float.
 116
 117 If you can float to level @Level 0 0@ worth doing so because then your
 118 allocation becomes static instead of dynamic.  We always start with
 119 context @Level 0 0@.
 120
 121
 122 InlineCtxt
 123 ~~~~~~~~~~
 124 @InlineCtxt@ very similar to @Level 0 0@, but is used for one purpose:
 125 to say "don't float anything out of here".  That's exactly what we
 126 want for the body of an INLINE, where we don't want to float anything
 127 out at all.  See notes with lvlMFE below.
 128
 129 But, check this out:
 130
 131 -- At one time I tried the effect of not float anything out of an InlineMe,
 132 -- but it sometimes works badly.  For example, consider PrelArr.done.  It
 133 -- has the form         __inline (\d. e)
 134 -- where e doesn't mention d.  If we float this to
 135 --      __inline (let x = e in \d. x)
 136 -- things are bad.  The inliner doesn't even inline it because it doesn't look
 137 -- like a head-normal form.  So it seems a lesser evil to let things float.
 138 -- In SetLevels we do set the context to (Level 0 0) when we get to an InlineMe
 139 -- which discourages floating out.
 140
 141 So the conclusion is: don't do any floating at all inside an InlineMe.
 142 (In the above example, don't float the {x=e} out of the \d.)
 143
 144 One particular case is that of workers: we don't want to float the
 145 call to the worker outside the wrapper, otherwise the worker might get
 146 inlined into the floated expression, and an importing module won't see
 147 the worker at all.
 148
 149 \begin{code}
 150 type LevelledExpr  = TaggedExpr Level
 151 type LevelledBind  = TaggedBind Level
 152
 153 tOP_LEVEL   = Level 0 0
 154 iNLINE_CTXT = InlineCtxt
 155
 156 incMajorLvl :: Level -> Level
 157 -- For InlineCtxt we ignore any inc's; we don't want
 158 -- to do any floating at all; see notes above
 159 incMajorLvl InlineCtxt          = InlineCtxt
 160 incMajorLvl (Level major minor) = Level (major+1) 0
 161
 162 incMinorLvl :: Level -> Level
 163 incMinorLvl InlineCtxt          = InlineCtxt
 164 incMinorLvl (Level major minor) = Level major (minor+1)
 165
 166 maxLvl :: Level -> Level -> Level
 167 maxLvl InlineCtxt l2  = l2
 168 maxLvl l1  InlineCtxt = l1
 169 maxLvl l1@(Level maj1 min1) l2@(Level maj2 min2)
 170   | (maj1 > maj2) || (maj1 == maj2 && min1 > min2) = l1
 171   | otherwise                                      = l2
 172
 173 ltLvl :: Level -> Level -> Bool
 174 ltLvl any_lvl    InlineCtxt  = False
 175 ltLvl InlineCtxt (Level _ _) = True
 176 ltLvl (Level maj1 min1) (Level maj2 min2)
 177   = (maj1 < maj2) || (maj1 == maj2 && min1 < min2)
 178
 179 ltMajLvl :: Level -> Level -> Bool
 180     -- Tells if one level belongs to a difft *lambda* level to another
 181 ltMajLvl any_lvl        InlineCtxt     = False
 182 ltMajLvl InlineCtxt     (Level maj2 _) = 0 < maj2
 183 ltMajLvl (Level maj1 _) (Level maj2 _) = maj1 < maj2
 184
 185 isTopLvl :: Level -> Bool
 186 isTopLvl (Level 0 0) = True
 187 isTopLvl other       = False
 188
 189 isInlineCtxt :: Level -> Bool
 190 isInlineCtxt InlineCtxt = True
 191 isInlineCtxt other      = False
 192
 193 instance Outputable Level where
 194   ppr InlineCtxt      = text "<INLINE>"
 195   ppr (Level maj min) = hcat [ char '<', int maj, char ',', int min, char '>' ]
 196
 197 instance Eq Level where
 198   InlineCtxt        == InlineCtxt        = True
 199   (Level maj1 min1) == (Level maj2 min2) = maj1==maj2 && min1==min2
 200   l1                == l2                = False
 201 \end{code}
 202
 203
 204 %************************************************************************
 205 %*                                                                      *
 206 \subsection{Main level-setting code}
 207 %*                                                                      *
 208 %************************************************************************
 209
 210 \begin{code}
 211 setLevels :: FloatOutSwitches
 212           -> [CoreBind]
 213           -> UniqSupply
 214           -> [LevelledBind]
 215
 216 setLevels float_lams binds us
 217   = initLvl us (do_them binds)
 218   where
 219     -- "do_them"'s main business is to thread the monad along
 220     -- It gives each top binding the same empty envt, because
 221     -- things unbound in the envt have level number zero implicitly
 222     do_them :: [CoreBind] -> LvlM [LevelledBind]
 223
 224     do_them [] = returnLvl []
 225     do_them (b:bs)
 226       = lvlTopBind init_env b   `thenLvl` \ (lvld_bind, _) ->
 227         do_them bs              `thenLvl` \ lvld_binds ->
 228         returnLvl (lvld_bind : lvld_binds)
 229
 230     init_env = initialEnv float_lams
 231
 232 lvlTopBind env (NonRec binder rhs)
 233   = lvlBind TopLevel tOP_LEVEL env (AnnNonRec binder (freeVars rhs))
 234                                         -- Rhs can have no free vars!
 235
 236 lvlTopBind env (Rec pairs)
 237   = lvlBind TopLevel tOP_LEVEL env (AnnRec [(b,freeVars rhs) | (b,rhs) <- pairs])
 238 \end{code}
 239
 240 %************************************************************************
 241 %*                                                                      *
 242 \subsection{Setting expression levels}
 243 %*                                                                      *
 244 %************************************************************************
 245
 246 \begin{code}
 247 lvlExpr :: Level                -- ctxt_lvl: Level of enclosing expression
 248         -> LevelEnv             -- Level of in-scope names/tyvars
 249         -> CoreExprWithFVs      -- input expression
 250         -> LvlM LevelledExpr    -- Result expression
 251 \end{code}
 252
 253 The @ctxt_lvl@ is, roughly, the level of the innermost enclosing
 254 binder.  Here's an example
 255
 256         v = \x -> ...\y -> let r = case (..x..) of
 257                                         ..x..
 258                            in ..
 259
 260 When looking at the rhs of @r@, @ctxt_lvl@ will be 1 because that's
 261 the level of @r@, even though it's inside a level-2 @\y@.  It's
 262 important that @ctxt_lvl@ is 1 and not 2 in @r@'s rhs, because we
 263 don't want @lvlExpr@ to turn the scrutinee of the @case@ into an MFE
 264 --- because it isn't a *maximal* free expression.
 265
 266 If there were another lambda in @r@'s rhs, it would get level-2 as well.
 267
 268 \begin{code}
 269 lvlExpr _ _ (_, AnnType ty)   = returnLvl (Type ty)
 270 lvlExpr _ env (_, AnnVar v)   = returnLvl (lookupVar env v)
 271 lvlExpr _ env (_, AnnLit lit) = returnLvl (Lit lit)
 272
 273 lvlExpr ctxt_lvl env (_, AnnApp fun arg)
 274   = lvl_fun fun                         `thenLvl` \ fun' ->
 275     lvlMFE  False ctxt_lvl env arg      `thenLvl` \ arg' ->
 276     returnLvl (App fun' arg')
 277   where
 278 -- gaw 2004
 279     lvl_fun (_, AnnCase _ _ _ _) = lvlMFE True ctxt_lvl env fun
 280     lvl_fun other              = lvlExpr ctxt_lvl env fun
 281         -- We don't do MFE on partial applications generally,
 282         -- but we do if the function is big and hairy, like a case
 283
 284 lvlExpr ctxt_lvl env (_, AnnNote InlineMe expr)
 285 -- Don't float anything out of an InlineMe; hence the iNLINE_CTXT
 286   = lvlExpr iNLINE_CTXT env expr        `thenLvl` \ expr' ->
 287     returnLvl (Note InlineMe expr')
 288
 289 lvlExpr ctxt_lvl env (_, AnnNote note expr)
 290   = lvlExpr ctxt_lvl env expr           `thenLvl` \ expr' ->
 291     returnLvl (Note note expr')
 292
 293 -- We don't split adjacent lambdas.  That is, given
 294 --      \x y -> (x+1,y)
 295 -- we don't float to give
 296 --      \x -> let v = x+y in \y -> (v,y)
 297 -- Why not?  Because partial applications are fairly rare, and splitting
 298 -- lambdas makes them more expensive.
 299
 300 lvlExpr ctxt_lvl env expr@(_, AnnLam bndr rhs)
 301   = lvlMFE True new_lvl new_env body    `thenLvl` \ new_body ->
 302     returnLvl (mkLams new_bndrs new_body)
 303   where
 304     (bndrs, body)        = collectAnnBndrs expr
 305     (new_lvl, new_bndrs) = lvlLamBndrs ctxt_lvl bndrs
 306     new_env              = extendLvlEnv env new_bndrs
 307         -- At one time we called a special verion of collectBinders,
 308         -- which ignored coercions, because we don't want to split
 309         -- a lambda like this (\x -> coerce t (\s -> ...))
 310         -- This used to happen quite a bit in state-transformer programs,
 311         -- but not nearly so much now non-recursive newtypes are transparent.
 312         -- [See SetLevels rev 1.50 for a version with this approach.]
 313
 314 lvlExpr ctxt_lvl env (_, AnnLet (AnnNonRec bndr rhs) body)
 315   | isUnLiftedType (idType bndr)
 316         -- Treat unlifted let-bindings (let x = b in e) just like (case b of x -> e)
 317         -- That is, leave it exactly where it is
 318         -- We used to float unlifted bindings too (e.g. to get a cheap primop
 319         -- outside a lambda (to see how, look at lvlBind in rev 1.58)
 320         -- but an unrelated change meant that these unlifed bindings
 321         -- could get to the top level which is bad.  And there's not much point;
 322         -- unlifted bindings are always cheap, and so hardly worth floating.
 323   = lvlExpr ctxt_lvl env rhs            `thenLvl` \ rhs' ->
 324     lvlExpr incd_lvl env' body          `thenLvl` \ body' ->
 325     returnLvl (Let (NonRec bndr' rhs') body')
 326   where
 327     incd_lvl = incMinorLvl ctxt_lvl
 328     bndr' = TB bndr incd_lvl
 329     env'  = extendLvlEnv env [bndr']
 330
 331 lvlExpr ctxt_lvl env (_, AnnLet bind body)
 332   = lvlBind NotTopLevel ctxt_lvl env bind       `thenLvl` \ (bind', new_env) ->
 333     lvlExpr ctxt_lvl new_env body               `thenLvl` \ body' ->
 334     returnLvl (Let bind' body')
 335
 336 lvlExpr ctxt_lvl env (_, AnnCase expr case_bndr ty alts)
 337   = lvlMFE True ctxt_lvl env expr       `thenLvl` \ expr' ->
 338     let
 339         alts_env = extendCaseBndrLvlEnv env expr' case_bndr incd_lvl
 340     in
 341     mapLvl (lvl_alt alts_env) alts      `thenLvl` \ alts' ->
 342     returnLvl (Case expr' (TB case_bndr incd_lvl) ty alts')
 343   where
 344       incd_lvl  = incMinorLvl ctxt_lvl
 345
 346       lvl_alt alts_env (con, bs, rhs)
 347         = lvlMFE True incd_lvl new_env rhs      `thenLvl` \ rhs' ->
 348           returnLvl (con, bs', rhs')
 349         where
 350           bs'     = [ TB b incd_lvl | b <- bs ]
 351           new_env = extendLvlEnv alts_env bs'
 352 \end{code}
 353
 354 @lvlMFE@ is just like @lvlExpr@, except that it might let-bind
 355 the expression, so that it can itself be floated.
 356
 357 [NOTE: unlifted MFEs]
 358 We don't float unlifted MFEs, which potentially loses big opportunites.
 359 For example:
 360         \x -> f (h y)
 361 where h :: Int -> Int# is expensive. We'd like to float the (h y) outside
 362 the \x, but we don't because it's unboxed.  Possible solution: box it.
 363
 364 \begin{code}
 365 lvlMFE ::  Bool                 -- True <=> strict context [body of case or let]
 366         -> Level                -- Level of innermost enclosing lambda/tylam
 367         -> LevelEnv             -- Level of in-scope names/tyvars
 368         -> CoreExprWithFVs      -- input expression
 369         -> LvlM LevelledExpr    -- Result expression
 370
 371 lvlMFE strict_ctxt ctxt_lvl env (_, AnnType ty)
 372   = returnLvl (Type ty)
 373
 374
 375 lvlMFE strict_ctxt ctxt_lvl env ann_expr@(fvs, _)
 376   |  isUnLiftedType ty                  -- Can't let-bind it; see [NOTE: unlifted MFEs]
 377   || isInlineCtxt ctxt_lvl              -- Don't float out of an __inline__ context
 378   || exprIsTrivial expr                 -- Never float if it's trivial
 379   || not good_destination
 380   =     -- Don't float it out
 381     lvlExpr ctxt_lvl env ann_expr
 382
 383   | otherwise   -- Float it out!
 384   = lvlFloatRhs abs_vars dest_lvl env ann_expr  `thenLvl` \ expr' ->
 385     newLvlVar "lvl" abs_vars ty                 `thenLvl` \ var ->
 386     returnLvl (Let (NonRec (TB var dest_lvl) expr')
 387                    (mkVarApps (Var var) abs_vars))
 388   where
 389     expr     = deAnnotate ann_expr
 390     ty       = exprType expr
 391     dest_lvl = destLevel env fvs (isFunction ann_expr)
 392     abs_vars = abstractVars dest_lvl env fvs
 393
 394         -- A decision to float entails let-binding this thing, and we only do
 395         -- that if we'll escape a value lambda, or will go to the top level.
 396     good_destination
 397         | dest_lvl `ltMajLvl` ctxt_lvl          -- Escapes a value lambda
 398         = not (exprIsCheap expr) || isTopLvl dest_lvl
 399           -- Even if it escapes a value lambda, we only
 400           -- float if it's not cheap (unless it'll get all the
 401           -- way to the top).  I've seen cases where we
 402           -- float dozens of tiny free expressions, which cost
 403           -- more to allocate than to evaluate.
 404           -- NB: exprIsCheap is also true of bottom expressions, which
 405           --     is good; we don't want to share them
 406           --
 407           -- It's only Really Bad to float a cheap expression out of a
 408           -- strict context, because that builds a thunk that otherwise
 409           -- would never be built.  So another alternative would be to
 410           -- add
 411           --    || (strict_ctxt && not (exprIsBottom expr))
 412           -- to the condition above. We should really try this out.
 413
 414         | otherwise             -- Does not escape a value lambda
 415         = isTopLvl dest_lvl     -- Only float if we are going to the top level
 416         && floatConsts env      --   and the floatConsts flag is on
 417         && not strict_ctxt      -- Don't float from a strict context
 418           -- We are keen to float something to the top level, even if it does not
 419           -- escape a lambda, because then it needs no allocation.  But it's controlled
 420           -- by a flag, because doing this too early loses opportunities for RULES
 421           -- which (needless to say) are important in some nofib programs
 422           -- (gcd is an example).
 423           --
 424           -- Beware:
 425           --    concat = /\ a -> foldr ..a.. (++) []
 426           -- was getting turned into
 427           --    concat = /\ a -> lvl a
 428           --    lvl    = /\ a -> foldr ..a.. (++) []
 429           -- which is pretty stupid.  Hence the strict_ctxt test
 430 \end{code}
 431
 432
 433 %************************************************************************
 434 %*                                                                      *
 435 \subsection{Bindings}
 436 %*                                                                      *
 437 %************************************************************************
 438
 439 The binding stuff works for top level too.
 440
 441 \begin{code}
 442 lvlBind :: TopLevelFlag         -- Used solely to decide whether to clone
 443         -> Level                -- Context level; might be Top even for bindings nested in the RHS
 444                                 -- of a top level binding
 445         -> LevelEnv
 446         -> CoreBindWithFVs
 447         -> LvlM (LevelledBind, LevelEnv)
 448
 449 lvlBind top_lvl ctxt_lvl env (AnnNonRec bndr rhs@(rhs_fvs,_))
 450   | isInlineCtxt ctxt_lvl               -- Don't do anything inside InlineMe
 451   = lvlExpr ctxt_lvl env rhs                    `thenLvl` \ rhs' ->
 452     returnLvl (NonRec (TB bndr ctxt_lvl) rhs', env)
 453
 454   | null abs_vars
 455   =     -- No type abstraction; clone existing binder
 456     lvlExpr dest_lvl env rhs                    `thenLvl` \ rhs' ->
 457     cloneVar top_lvl env bndr ctxt_lvl dest_lvl `thenLvl` \ (env', bndr') ->
 458     returnLvl (NonRec (TB bndr' dest_lvl) rhs', env')
 459
 460   | otherwise
 461   = -- Yes, type abstraction; create a new binder, extend substitution, etc
 462     lvlFloatRhs abs_vars dest_lvl env rhs       `thenLvl` \ rhs' ->
 463     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (env', [bndr']) ->
 464     returnLvl (NonRec (TB bndr' dest_lvl) rhs', env')
 465
 466   where
 467     bind_fvs = rhs_fvs `unionVarSet` idFreeVars bndr
 468     abs_vars = abstractVars dest_lvl env bind_fvs
 469     dest_lvl = destLevel env bind_fvs (isFunction rhs)
 470 \end{code}
 471
 472
 473 \begin{code}
 474 lvlBind top_lvl ctxt_lvl env (AnnRec pairs)
 475   | isInlineCtxt ctxt_lvl       -- Don't do anything inside InlineMe
 476   = mapLvl (lvlExpr ctxt_lvl env) rhss                  `thenLvl` \ rhss' ->
 477     returnLvl (Rec ([TB b ctxt_lvl | b <- bndrs] `zip` rhss'), env)
 478
 479   | null abs_vars
 480   = cloneRecVars top_lvl env bndrs ctxt_lvl dest_lvl    `thenLvl` \ (new_env, new_bndrs) ->
 481     mapLvl (lvlExpr ctxt_lvl new_env) rhss              `thenLvl` \ new_rhss ->
 482     returnLvl (Rec ([TB b dest_lvl | b <- new_bndrs] `zip` new_rhss), new_env)
 483
 484   | isSingleton pairs && count isId abs_vars > 1
 485   =     -- Special case for self recursion where there are
 486         -- several variables carried around: build a local loop:
 487         --      poly_f = \abs_vars. \lam_vars . letrec f = \lam_vars. rhs in f lam_vars
 488         -- This just makes the closures a bit smaller.  If we don't do
 489         -- this, allocation rises significantly on some programs
 490         --
 491         -- We could elaborate it for the case where there are several
 492         -- mutually functions, but it's quite a bit more complicated
 493         --
 494         -- This all seems a bit ad hoc -- sigh
 495     let
 496         (bndr,rhs) = head pairs
 497         (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 498         rhs_env = extendLvlEnv env abs_vars_w_lvls
 499     in
 500     cloneVar NotTopLevel rhs_env bndr rhs_lvl rhs_lvl   `thenLvl` \ (rhs_env', new_bndr) ->
 501     let
 502         (lam_bndrs, rhs_body)     = collectAnnBndrs rhs
 503         (body_lvl, new_lam_bndrs) = lvlLamBndrs rhs_lvl lam_bndrs
 504         body_env                  = extendLvlEnv rhs_env' new_lam_bndrs
 505     in
 506     lvlExpr body_lvl body_env rhs_body          `thenLvl` \ new_rhs_body ->
 507     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (poly_env, [poly_bndr]) ->
 508     returnLvl (Rec [(TB poly_bndr dest_lvl,
 509                mkLams abs_vars_w_lvls $
 510                mkLams new_lam_bndrs $
 511                Let (Rec [(TB new_bndr rhs_lvl, mkLams new_lam_bndrs new_rhs_body)])
 512                    (mkVarApps (Var new_bndr) lam_bndrs))],
 513                poly_env)
 514
 515   | otherwise   -- Non-null abs_vars
 516   = newPolyBndrs dest_lvl env abs_vars bndrs            `thenLvl` \ (new_env, new_bndrs) ->
 517     mapLvl (lvlFloatRhs abs_vars dest_lvl new_env) rhss `thenLvl` \ new_rhss ->
 518     returnLvl (Rec ([TB b dest_lvl | b <- new_bndrs] `zip` new_rhss), new_env)
 519
 520   where
 521     (bndrs,rhss) = unzip pairs
 522
 523         -- Finding the free vars of the binding group is annoying
 524     bind_fvs        = (unionVarSets [ idFreeVars bndr `unionVarSet` rhs_fvs
 525                                     | (bndr, (rhs_fvs,_)) <- pairs])
 526                       `minusVarSet`
 527                       mkVarSet bndrs
 528
 529     dest_lvl = destLevel env bind_fvs (all isFunction rhss)
 530     abs_vars = abstractVars dest_lvl env bind_fvs
 531
 532 ----------------------------------------------------
 533 -- Three help functons for the type-abstraction case
 534
 535 lvlFloatRhs abs_vars dest_lvl env rhs
 536   = lvlExpr rhs_lvl rhs_env rhs `thenLvl` \ rhs' ->
 537     returnLvl (mkLams abs_vars_w_lvls rhs')
 538   where
 539     (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 540     rhs_env = extendLvlEnv env abs_vars_w_lvls
 541 \end{code}
 542
 543
 544 %************************************************************************
 545 %*                                                                      *
 546 \subsection{Deciding floatability}
 547 %*                                                                      *
 548 %************************************************************************
 549
 550 \begin{code}
 551 lvlLamBndrs :: Level -> [CoreBndr] -> (Level, [TaggedBndr Level])
 552 -- Compute the levels for the binders of a lambda group
 553 -- The binders returned are exactly the same as the ones passed,
 554 -- but they are now paired with a level
 555 lvlLamBndrs lvl []
 556   = (lvl, [])
 557
 558 lvlLamBndrs lvl bndrs
 559   = go  (incMinorLvl lvl)
 560         False   -- Havn't bumped major level in this group
 561         [] bndrs
 562   where
 563     go old_lvl bumped_major rev_lvld_bndrs (bndr:bndrs)
 564         | isId bndr &&                  -- Go to the next major level if this is a value binder,
 565           not bumped_major &&           -- and we havn't already gone to the next level (one jump per group)
 566           not (isOneShotLambda bndr)    -- and it isn't a one-shot lambda
 567         = go new_lvl True (TB bndr new_lvl : rev_lvld_bndrs) bndrs
 568
 569         | otherwise
 570         = go old_lvl bumped_major (TB bndr old_lvl : rev_lvld_bndrs) bndrs
 571
 572         where
 573           new_lvl = incMajorLvl old_lvl
 574
 575     go old_lvl _ rev_lvld_bndrs []
 576         = (old_lvl, reverse rev_lvld_bndrs)
 577         -- a lambda like this (\x -> coerce t (\s -> ...))
 578         -- This happens quite a bit in state-transformer programs
 579 \end{code}
 580
 581 \begin{code}
 582   -- Destintion level is the max Id level of the expression
 583   -- (We'll abstract the type variables, if any.)
 584 destLevel :: LevelEnv -> VarSet -> Bool -> Level
 585 destLevel env fvs is_function
 586   |  floatLams env
 587   && is_function = tOP_LEVEL            -- Send functions to top level; see
 588                                         -- the comments with isFunction
 589   | otherwise    = maxIdLevel env fvs
 590
 591 isFunction :: CoreExprWithFVs -> Bool
 592 -- The idea here is that we want to float *functions* to
 593 -- the top level.  This saves no work, but
 594 --      (a) it can make the host function body a lot smaller,
 595 --              and hence inlinable.
 596 --      (b) it can also save allocation when the function is recursive:
 597 --          h = \x -> letrec f = \y -> ...f...y...x...
 598 --                    in f x
 599 --     becomes
 600 --          f = \x y -> ...(f x)...y...x...
 601 --          h = \x -> f x x
 602 --     No allocation for f now.
 603 -- We may only want to do this if there are sufficiently few free
 604 -- variables.  We certainly only want to do it for values, and not for
 605 -- constructors.  So the simple thing is just to look for lambdas
 606 isFunction (_, AnnLam b e) | isId b    = True
 607                            | otherwise = isFunction e
 608 isFunction (_, AnnNote n e)            = isFunction e
 609 isFunction other                       = False
 610 \end{code}
 611
 612
 613 %************************************************************************
 614 %*                                                                      *
 615 \subsection{Free-To-Level Monad}
 616 %*                                                                      *
 617 %************************************************************************
 618
 619 \begin{code}
 620 type LevelEnv = (FloatOutSwitches,
 621                  VarEnv Level,                  -- Domain is *post-cloned* TyVars and Ids
 622                  Subst,                         -- Domain is pre-cloned Ids; tracks the in-scope set
 623                                                 --      so that subtitution is capture-avoiding
 624                  IdEnv ([Var], LevelledExpr))   -- Domain is pre-cloned Ids
 625         -- We clone let-bound variables so that they are still
 626         -- distinct when floated out; hence the SubstEnv/IdEnv.
 627         -- (see point 3 of the module overview comment).
 628         -- We also use these envs when making a variable polymorphic
 629         -- because we want to float it out past a big lambda.
 630         --
 631         -- The SubstEnv and IdEnv always implement the same mapping, but the
 632         -- SubstEnv maps to CoreExpr and the IdEnv to LevelledExpr
 633         -- Since the range is always a variable or type application,
 634         -- there is never any difference between the two, but sadly
 635         -- the types differ.  The SubstEnv is used when substituting in
 636         -- a variable's IdInfo; the IdEnv when we find a Var.
 637         --
 638         -- In addition the IdEnv records a list of tyvars free in the
 639         -- type application, just so we don't have to call freeVars on
 640         -- the type application repeatedly.
 641         --
 642         -- The domain of the both envs is *pre-cloned* Ids, though
 643         --
 644         -- The domain of the VarEnv Level is the *post-cloned* Ids
 645
 646 initialEnv :: FloatOutSwitches -> LevelEnv
 647 initialEnv float_lams = (float_lams, emptyVarEnv, emptySubst, emptyVarEnv)
 648
 649 floatLams :: LevelEnv -> Bool
 650 floatLams (FloatOutSw float_lams _, _, _, _) = float_lams
 651
 652 floatConsts :: LevelEnv -> Bool
 653 floatConsts (FloatOutSw _ float_consts, _, _, _) = float_consts
 654
 655 extendLvlEnv :: LevelEnv -> [TaggedBndr Level] -> LevelEnv
 656 -- Used when *not* cloning
 657 extendLvlEnv (float_lams, lvl_env, subst, id_env) prs
 658   = (float_lams,
 659      foldl add_lvl lvl_env prs,
 660      foldl del_subst subst prs,
 661      foldl del_id id_env prs)
 662   where
 663     add_lvl   env (TB v l) = extendVarEnv env v l
 664     del_subst env (TB v _) = extendInScope env v
 665     del_id    env (TB v _) = delVarEnv env v
 666   -- We must remove any clone for this variable name in case of
 667   -- shadowing.  This bit me in the following case
 668   -- (in nofib/real/gg/Spark.hs):
 669   --
 670   --   case ds of wild {
 671   --     ... -> case e of wild {
 672   --              ... -> ... wild ...
 673   --            }
 674   --   }
 675   --
 676   -- The inside occurrence of @wild@ was being replaced with @ds@,
 677   -- incorrectly, because the SubstEnv was still lying around.  Ouch!
 678   -- KSW 2000-07.
 679
 680 -- extendCaseBndrLvlEnv adds the mapping case-bndr->scrut-var if it can
 681 -- (see point 4 of the module overview comment)
 682 extendCaseBndrLvlEnv (float_lams, lvl_env, subst, id_env) (Var scrut_var) case_bndr lvl
 683   = (float_lams,
 684      extendVarEnv lvl_env case_bndr lvl,
 685      extendIdSubst subst case_bndr (Var scrut_var),
 686      extendVarEnv id_env case_bndr ([scrut_var], Var scrut_var))
 687
 688 extendCaseBndrLvlEnv env scrut case_bndr lvl
 689   = extendLvlEnv          env [TB case_bndr lvl]
 690
 691 extendPolyLvlEnv dest_lvl (float_lams, lvl_env, subst, id_env) abs_vars bndr_pairs
 692   = (float_lams,
 693      foldl add_lvl   lvl_env bndr_pairs,
 694      foldl add_subst subst   bndr_pairs,
 695      foldl add_id    id_env  bndr_pairs)
 696   where
 697      add_lvl   env (v,v') = extendVarEnv env v' dest_lvl
 698      add_subst env (v,v') = extendIdSubst env v (mkVarApps (Var v') abs_vars)
 699      add_id    env (v,v') = extendVarEnv env v ((v':abs_vars), mkVarApps (Var v') abs_vars)
 700
 701 extendCloneLvlEnv lvl (float_lams, lvl_env, _, id_env) new_subst bndr_pairs
 702   = (float_lams,
 703      foldl add_lvl   lvl_env bndr_pairs,
 704      new_subst,
 705      foldl add_id    id_env  bndr_pairs)
 706   where
 707      add_lvl   env (v,v') = extendVarEnv env v' lvl
 708      add_id    env (v,v') = extendVarEnv env v ([v'], Var v')
 709
 710
 711 maxIdLevel :: LevelEnv -> VarSet -> Level
 712 maxIdLevel (_, lvl_env,_,id_env) var_set
 713   = foldVarSet max_in tOP_LEVEL var_set
 714   where
 715     max_in in_var lvl = foldr max_out lvl (case lookupVarEnv id_env in_var of
 716                                                 Just (abs_vars, _) -> abs_vars
 717                                                 Nothing            -> [in_var])
 718
 719     max_out out_var lvl
 720         | isId out_var = case lookupVarEnv lvl_env out_var of
 721                                 Just lvl' -> maxLvl lvl' lvl
 722                                 Nothing   -> lvl
 723         | otherwise    = lvl    -- Ignore tyvars in *maxIdLevel*
 724
 725 lookupVar :: LevelEnv -> Id -> LevelledExpr
 726 lookupVar (_, _, _, id_env) v = case lookupVarEnv id_env v of
 727                                        Just (_, expr) -> expr
 728                                        other          -> Var v
 729
 730 abstractVars :: Level -> LevelEnv -> VarSet -> [Var]
 731         -- Find the variables in fvs, free vars of the target expresion,
 732         -- whose level is greater than the destination level
 733         -- These are the ones we are going to abstract out
 734 abstractVars dest_lvl env fvs
 735   = uniq (sortLe le [var | fv <- varSetElems fvs, var <- absVarsOf dest_lvl env fv])
 736   where
 737         -- Sort the variables so we don't get
 738         -- mixed-up tyvars and Ids; it's just messy
 739     v1 `le` v2 = case (isId v1, isId v2) of
 740                    (True, False) -> False
 741                    (False, True) -> True
 742                    other         -> v1 <= v2    -- Same family
 743
 744     uniq :: [Var] -> [Var]
 745         -- Remove adjacent duplicates; the sort will have brought them together
 746     uniq (v1:v2:vs) | v1 == v2  = uniq (v2:vs)
 747                     | otherwise = v1 : uniq (v2:vs)
 748     uniq vs = vs
 749
 750 absVarsOf :: Level -> LevelEnv -> Var -> [Var]
 751         -- If f is free in the expression, and f maps to poly_f a b c in the
 752         -- current substitution, then we must report a b c as candidate type
 753         -- variables
 754 absVarsOf dest_lvl (_, lvl_env, _, id_env) v
 755   | isId v
 756   = [zap av2 | av1 <- lookup_avs v, av2 <- add_tyvars av1, abstract_me av2]
 757
 758   | otherwise
 759   = if abstract_me v then [v] else []
 760
 761   where
 762     abstract_me v = case lookupVarEnv lvl_env v of
 763                         Just lvl -> dest_lvl `ltLvl` lvl
 764                         Nothing  -> False
 765
 766     lookup_avs v = case lookupVarEnv id_env v of
 767                         Just (abs_vars, _) -> abs_vars
 768                         Nothing            -> [v]
 769
 770     add_tyvars v | isId v    = v : varSetElems (idFreeTyVars v)
 771                  | otherwise = [v]
 772
 773         -- We are going to lambda-abstract, so nuke any IdInfo,
 774         -- and add the tyvars of the Id (if necessary)
 775     zap v | isId v = WARN( workerExists (idWorkerInfo v) ||
 776                            not (isEmptySpecInfo (idSpecialisation v)),
 777                            text "absVarsOf: discarding info on" <+> ppr v )
 778                      setIdInfo v vanillaIdInfo
 779           | otherwise = v
 780 \end{code}
 781
 782 \begin{code}
 783 type LvlM result = UniqSM result
 784
 785 initLvl         = initUs_
 786 thenLvl         = thenUs
 787 returnLvl       = returnUs
 788 mapLvl          = mapUs
 789 \end{code}
 790
 791 \begin{code}
 792 newPolyBndrs dest_lvl env abs_vars bndrs
 793   = getUniquesUs                `thenLvl` \ uniqs ->
 794     let
 795         new_bndrs = zipWith mk_poly_bndr bndrs uniqs
 796     in
 797     returnLvl (extendPolyLvlEnv dest_lvl env abs_vars (bndrs `zip` new_bndrs), new_bndrs)
 798   where
 799     mk_poly_bndr bndr uniq = mkSysLocal (mkFastString str) uniq poly_ty
 800                            where
 801                              str     = "poly_" ++ occNameString (getOccName bndr)
 802                              poly_ty = mkPiTypes abs_vars (idType bndr)
 803
 804
 805 newLvlVar :: String
 806           -> [CoreBndr] -> Type         -- Abstract wrt these bndrs
 807           -> LvlM Id
 808 newLvlVar str vars body_ty
 809   = getUniqueUs `thenLvl` \ uniq ->
 810     returnUs (mkSysLocal (mkFastString str) uniq (mkPiTypes vars body_ty))
 811
 812 -- The deeply tiresome thing is that we have to apply the substitution
 813 -- to the rules inside each Id.  Grr.  But it matters.
 814
 815 cloneVar :: TopLevelFlag -> LevelEnv -> Id -> Level -> Level -> LvlM (LevelEnv, Id)
 816 cloneVar TopLevel env v ctxt_lvl dest_lvl
 817   = returnUs (env, v)   -- Don't clone top level things
 818 cloneVar NotTopLevel env@(_,_,subst,_) v ctxt_lvl dest_lvl
 819   = ASSERT( isId v )
 820     getUs       `thenLvl` \ us ->
 821     let
 822       (subst', v1) = cloneIdBndr subst us v
 823       v2           = zap_demand ctxt_lvl dest_lvl v1
 824       env'         = extendCloneLvlEnv dest_lvl env subst' [(v,v2)]
 825     in
 826     returnUs (env', v2)
 827
 828 cloneRecVars :: TopLevelFlag -> LevelEnv -> [Id] -> Level -> Level -> LvlM (LevelEnv, [Id])
 829 cloneRecVars TopLevel env vs ctxt_lvl dest_lvl
 830   = returnUs (env, vs)  -- Don't clone top level things
 831 cloneRecVars NotTopLevel env@(_,_,subst,_) vs ctxt_lvl dest_lvl
 832   = ASSERT( all isId vs )
 833     getUs                       `thenLvl` \ us ->
 834     let
 835       (subst', vs1) = cloneRecIdBndrs subst us vs
 836       vs2           = map (zap_demand ctxt_lvl dest_lvl) vs1
 837       env'          = extendCloneLvlEnv dest_lvl env subst' (vs `zip` vs2)
 838     in
 839     returnUs (env', vs2)
 840
 841         -- VERY IMPORTANT: we must zap the demand info
 842         -- if the thing is going to float out past a lambda
 843 zap_demand dest_lvl ctxt_lvl id
 844   | ctxt_lvl == dest_lvl = id                   -- Stays put
 845   | otherwise            = zapDemandIdInfo id   -- Floats out
 846 \end{code}
 847