compiler/simplCore/SetLevels.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{SetLevels}
   5
   6                 ***************************
   7                         Overview
   8                 ***************************
   9
  10 1. We attach binding levels to Core bindings, in preparation for floating
  11    outwards (@FloatOut@).
  12
  13 2. We also let-ify many expressions (notably case scrutinees), so they
  14    will have a fighting chance of being floated sensible.
  15
  16 3. We clone the binders of any floatable let-binding, so that when it is
  17    floated out it will be unique.  (This used to be done by the simplifier
  18    but the latter now only ensures that there's no shadowing; indeed, even
  19    that may not be true.)
  20
  21    NOTE: this can't be done using the uniqAway idea, because the variable
  22          must be unique in the whole program, not just its current scope,
  23          because two variables in different scopes may float out to the
  24          same top level place
  25
  26    NOTE: Very tiresomely, we must apply this substitution to
  27          the rules stored inside a variable too.
  28
  29    We do *not* clone top-level bindings, because some of them must not change,
  30    but we *do* clone bindings that are heading for the top level
  31
  32 4. In the expression
  33         case x of wild { p -> ...wild... }
  34    we substitute x for wild in the RHS of the case alternatives:
  35         case x of wild { p -> ...x... }
  36    This means that a sub-expression involving x is not "trapped" inside the RHS.
  37    And it's not inconvenient because we already have a substitution.
  38
  39   Note that this is EXACTLY BACKWARDS from the what the simplifier does.
  40   The simplifier tries to get rid of occurrences of x, in favour of wild,
  41   in the hope that there will only be one remaining occurrence of x, namely
  42   the scrutinee of the case, and we can inline it.
  43
  44 \begin{code}
  45 module SetLevels (
  46         setLevels,
  47
  48         Level(..), tOP_LEVEL,
  49         LevelledBind, LevelledExpr,
  50
  51         incMinorLvl, ltMajLvl, ltLvl, isTopLvl
  52     ) where
  53
  54 #include "HsVersions.h"
  55
  56 import CoreSyn
  57
  58 import DynFlags         ( FloatOutSwitches(..) )
  59 import CoreUtils        ( exprType, exprIsTrivial, mkPiTypes )
  60 import CoreArity        ( exprBotStrictness_maybe )
  61 import CoreFVs          -- all of it
  62 import CoreSubst        ( Subst, emptySubst, extendInScope, extendInScopeList,
  63                           extendIdSubst, cloneIdBndr, cloneRecIdBndrs )
  64 import Id               ( idType, mkSysLocal, isOneShotLambda,
  65                           zapDemandIdInfo, transferPolyIdInfo,
  66                           idSpecialisation, idUnfolding, setIdInfo,
  67                           setIdStrictness, setIdArity
  68                         )
  69 import IdInfo
  70 import Var
  71 import VarSet
  72 import VarEnv
  73 import Name             ( getOccName )
  74 import OccName          ( occNameString )
  75 import Type             ( isUnLiftedType, Type )
  76 import BasicTypes       ( TopLevelFlag(..) )
  77 import UniqSupply
  78 import Util             ( sortLe, isSingleton, count )
  79 import Outputable
  80 import FastString
  81 \end{code}
  82
  83 %************************************************************************
  84 %*                                                                      *
  85 \subsection{Level numbers}
  86 %*                                                                      *
  87 %************************************************************************
  88
  89 \begin{code}
  90 data Level = Level Int  -- Level number of enclosing lambdas
  91                    Int  -- Number of big-lambda and/or case expressions between
  92                         -- here and the nearest enclosing lambda
  93 \end{code}
  94
  95 The {\em level number} on a (type-)lambda-bound variable is the
  96 nesting depth of the (type-)lambda which binds it.  The outermost lambda
  97 has level 1, so (Level 0 0) means that the variable is bound outside any lambda.
  98
  99 On an expression, it's the maximum level number of its free
 100 (type-)variables.  On a let(rec)-bound variable, it's the level of its
 101 RHS.  On a case-bound variable, it's the number of enclosing lambdas.
 102
 103 Top-level variables: level~0.  Those bound on the RHS of a top-level
 104 definition but ``before'' a lambda; e.g., the \tr{x} in (levels shown
 105 as ``subscripts'')...
 106 \begin{verbatim}
 107 a_0 = let  b_? = ...  in
 108            x_1 = ... b ... in ...
 109 \end{verbatim}
 110
 111 The main function @lvlExpr@ carries a ``context level'' (@ctxt_lvl@).
 112 That's meant to be the level number of the enclosing binder in the
 113 final (floated) program.  If the level number of a sub-expression is
 114 less than that of the context, then it might be worth let-binding the
 115 sub-expression so that it will indeed float.
 116
 117 If you can float to level @Level 0 0@ worth doing so because then your
 118 allocation becomes static instead of dynamic.  We always start with
 119 context @Level 0 0@.
 120
 121
 122 Note [FloatOut inside INLINE]
 123 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 124 @InlineCtxt@ very similar to @Level 0 0@, but is used for one purpose:
 125 to say "don't float anything out of here".  That's exactly what we
 126 want for the body of an INLINE, where we don't want to float anything
 127 out at all.  See notes with lvlMFE below.
 128
 129 But, check this out:
 130
 131 -- At one time I tried the effect of not float anything out of an InlineMe,
 132 -- but it sometimes works badly.  For example, consider PrelArr.done.  It
 133 -- has the form         __inline (\d. e)
 134 -- where e doesn't mention d.  If we float this to
 135 --      __inline (let x = e in \d. x)
 136 -- things are bad.  The inliner doesn't even inline it because it doesn't look
 137 -- like a head-normal form.  So it seems a lesser evil to let things float.
 138 -- In SetLevels we do set the context to (Level 0 0) when we get to an InlineMe
 139 -- which discourages floating out.
 140
 141 So the conclusion is: don't do any floating at all inside an InlineMe.
 142 (In the above example, don't float the {x=e} out of the \d.)
 143
 144 One particular case is that of workers: we don't want to float the
 145 call to the worker outside the wrapper, otherwise the worker might get
 146 inlined into the floated expression, and an importing module won't see
 147 the worker at all.
 148
 149 \begin{code}
 150 type LevelledExpr  = TaggedExpr Level
 151 type LevelledBind  = TaggedBind Level
 152
 153 tOP_LEVEL :: Level
 154 tOP_LEVEL   = Level 0 0
 155
 156 incMajorLvl :: Level -> Level
 157 incMajorLvl (Level major _) = Level (major + 1) 0
 158
 159 incMinorLvl :: Level -> Level
 160 incMinorLvl (Level major minor) = Level major (minor+1)
 161
 162 maxLvl :: Level -> Level -> Level
 163 maxLvl l1@(Level maj1 min1) l2@(Level maj2 min2)
 164   | (maj1 > maj2) || (maj1 == maj2 && min1 > min2) = l1
 165   | otherwise                                      = l2
 166
 167 ltLvl :: Level -> Level -> Bool
 168 ltLvl (Level maj1 min1) (Level maj2 min2)
 169   = (maj1 < maj2) || (maj1 == maj2 && min1 < min2)
 170
 171 ltMajLvl :: Level -> Level -> Bool
 172     -- Tells if one level belongs to a difft *lambda* level to another
 173 ltMajLvl (Level maj1 _) (Level maj2 _) = maj1 < maj2
 174
 175 isTopLvl :: Level -> Bool
 176 isTopLvl (Level 0 0) = True
 177 isTopLvl _           = False
 178
 179 instance Outputable Level where
 180   ppr (Level maj min) = hcat [ char '<', int maj, char ',', int min, char '>' ]
 181
 182 instance Eq Level where
 183   (Level maj1 min1) == (Level maj2 min2) = maj1 == maj2 && min1 == min2
 184 \end{code}
 185
 186
 187 %************************************************************************
 188 %*                                                                      *
 189 \subsection{Main level-setting code}
 190 %*                                                                      *
 191 %************************************************************************
 192
 193 \begin{code}
 194 setLevels :: FloatOutSwitches
 195           -> [CoreBind]
 196           -> UniqSupply
 197           -> [LevelledBind]
 198
 199 setLevels float_lams binds us
 200   = initLvl us (do_them init_env binds)
 201   where
 202     init_env = initialEnv float_lams
 203
 204     do_them :: LevelEnv -> [CoreBind] -> LvlM [LevelledBind]
 205     do_them _ [] = return []
 206     do_them env (b:bs)
 207       = do { (lvld_bind, env') <- lvlTopBind env b
 208            ; lvld_binds <- do_them env' bs
 209            ; return (lvld_bind : lvld_binds) }
 210
 211 lvlTopBind :: LevelEnv -> Bind Id -> LvlM (LevelledBind, LevelEnv)
 212 lvlTopBind env (NonRec binder rhs)
 213   = lvlBind TopLevel tOP_LEVEL env (AnnNonRec binder (freeVars rhs))
 214                                         -- Rhs can have no free vars!
 215
 216 lvlTopBind env (Rec pairs)
 217   = lvlBind TopLevel tOP_LEVEL env (AnnRec [(b,freeVars rhs) | (b,rhs) <- pairs])
 218 \end{code}
 219
 220 %************************************************************************
 221 %*                                                                      *
 222 \subsection{Setting expression levels}
 223 %*                                                                      *
 224 %************************************************************************
 225
 226 \begin{code}
 227 lvlExpr :: Level                -- ctxt_lvl: Level of enclosing expression
 228         -> LevelEnv             -- Level of in-scope names/tyvars
 229         -> CoreExprWithFVs      -- input expression
 230         -> LvlM LevelledExpr    -- Result expression
 231 \end{code}
 232
 233 The @ctxt_lvl@ is, roughly, the level of the innermost enclosing
 234 binder.  Here's an example
 235
 236         v = \x -> ...\y -> let r = case (..x..) of
 237                                         ..x..
 238                            in ..
 239
 240 When looking at the rhs of @r@, @ctxt_lvl@ will be 1 because that's
 241 the level of @r@, even though it's inside a level-2 @\y@.  It's
 242 important that @ctxt_lvl@ is 1 and not 2 in @r@'s rhs, because we
 243 don't want @lvlExpr@ to turn the scrutinee of the @case@ into an MFE
 244 --- because it isn't a *maximal* free expression.
 245
 246 If there were another lambda in @r@'s rhs, it would get level-2 as well.
 247
 248 \begin{code}
 249 lvlExpr _ _ (  _, AnnType ty) = return (Type ty)
 250 lvlExpr _ env (_, AnnVar v)   = return (lookupVar env v)
 251 lvlExpr _ _   (_, AnnLit lit) = return (Lit lit)
 252
 253 lvlExpr ctxt_lvl env (_, AnnApp fun arg) = do
 254     fun' <- lvlExpr ctxt_lvl env fun   -- We don't do MFE on partial applications
 255     arg' <- lvlMFE  False ctxt_lvl env arg
 256     return (App fun' arg')
 257
 258 lvlExpr ctxt_lvl env (_, AnnNote note expr) = do
 259     expr' <- lvlExpr ctxt_lvl env expr
 260     return (Note note expr')
 261
 262 lvlExpr ctxt_lvl env (_, AnnCast expr co) = do
 263     expr' <- lvlExpr ctxt_lvl env expr
 264     return (Cast expr' co)
 265
 266 -- We don't split adjacent lambdas.  That is, given
 267 --      \x y -> (x+1,y)
 268 -- we don't float to give
 269 --      \x -> let v = x+y in \y -> (v,y)
 270 -- Why not?  Because partial applications are fairly rare, and splitting
 271 -- lambdas makes them more expensive.
 272
 273 lvlExpr ctxt_lvl env expr@(_, AnnLam {}) = do
 274     new_body <- lvlMFE True new_lvl new_env body
 275     return (mkLams new_bndrs new_body)
 276   where
 277     (bndrs, body)        = collectAnnBndrs expr
 278     (new_lvl, new_bndrs) = lvlLamBndrs ctxt_lvl bndrs
 279     new_env              = extendLvlEnv env new_bndrs
 280         -- At one time we called a special verion of collectBinders,
 281         -- which ignored coercions, because we don't want to split
 282         -- a lambda like this (\x -> coerce t (\s -> ...))
 283         -- This used to happen quite a bit in state-transformer programs,
 284         -- but not nearly so much now non-recursive newtypes are transparent.
 285         -- [See SetLevels rev 1.50 for a version with this approach.]
 286
 287 lvlExpr ctxt_lvl env (_, AnnLet (AnnNonRec bndr rhs) body)
 288   | isUnLiftedType (idType bndr) = do
 289         -- Treat unlifted let-bindings (let x = b in e) just like (case b of x -> e)
 290         -- That is, leave it exactly where it is
 291         -- We used to float unlifted bindings too (e.g. to get a cheap primop
 292         -- outside a lambda (to see how, look at lvlBind in rev 1.58)
 293         -- but an unrelated change meant that these unlifed bindings
 294         -- could get to the top level which is bad.  And there's not much point;
 295         -- unlifted bindings are always cheap, and so hardly worth floating.
 296     rhs'  <- lvlExpr ctxt_lvl env rhs
 297     body' <- lvlExpr incd_lvl env' body
 298     return (Let (NonRec bndr' rhs') body')
 299   where
 300     incd_lvl = incMinorLvl ctxt_lvl
 301     bndr' = TB bndr incd_lvl
 302     env'  = extendLvlEnv env [bndr']
 303
 304 lvlExpr ctxt_lvl env (_, AnnLet bind body) = do
 305     (bind', new_env) <- lvlBind NotTopLevel ctxt_lvl env bind
 306     body' <- lvlExpr ctxt_lvl new_env body
 307     return (Let bind' body')
 308
 309 lvlExpr ctxt_lvl env (_, AnnCase expr case_bndr ty alts) = do
 310     expr' <- lvlMFE True ctxt_lvl env expr
 311     let alts_env = extendCaseBndrLvlEnv env expr' case_bndr incd_lvl
 312     alts' <- mapM (lvl_alt alts_env) alts
 313     return (Case expr' (TB case_bndr incd_lvl) ty alts')
 314   where
 315       incd_lvl  = incMinorLvl ctxt_lvl
 316
 317       lvl_alt alts_env (con, bs, rhs) = do
 318           rhs' <- lvlMFE True incd_lvl new_env rhs
 319           return (con, bs', rhs')
 320         where
 321           bs'     = [ TB b incd_lvl | b <- bs ]
 322           new_env = extendLvlEnv alts_env bs'
 323 \end{code}
 324
 325 @lvlMFE@ is just like @lvlExpr@, except that it might let-bind
 326 the expression, so that it can itself be floated.
 327
 328 Note [Unlifted MFEs]
 329 ~~~~~~~~~~~~~~~~~~~~
 330 We don't float unlifted MFEs, which potentially loses big opportunites.
 331 For example:
 332         \x -> f (h y)
 333 where h :: Int -> Int# is expensive. We'd like to float the (h y) outside
 334 the \x, but we don't because it's unboxed.  Possible solution: box it.
 335
 336 Note [Bottoming floats]
 337 ~~~~~~~~~~~~~~~~~~~~~~~
 338 If we see
 339         f = \x. g (error "urk")
 340 we'd like to float the call to error, to get
 341         lvl = error "urk"
 342         f = \x. g lvl
 343 But, it's very helpful for lvl to get a strictness signature, so that,
 344 for example, its unfolding is not exposed in interface files (unnecessary).
 345 But this float-out might occur after strictness analysis. So we use the
 346 cheap-and-cheerful exprBotStrictness_maybe function.
 347
 348 Note [Case MFEs]
 349 ~~~~~~~~~~~~~~~~
 350 We don't float a case expression as an MFE from a strict context.  Why not?
 351 Because in doing so we share a tiny bit of computation (the switch) but
 352 in exchange we build a thunk, which is bad.  This case reduces allocation
 353 by 7% in spectral/puzzle (a rather strange benchmark) and 1.2% in real/fem.
 354 Doesn't change any other allocation at all.
 355
 356 \begin{code}
 357 lvlMFE ::  Bool                 -- True <=> strict context [body of case or let]
 358         -> Level                -- Level of innermost enclosing lambda/tylam
 359         -> LevelEnv             -- Level of in-scope names/tyvars
 360         -> CoreExprWithFVs      -- input expression
 361         -> LvlM LevelledExpr    -- Result expression
 362
 363 lvlMFE _ _ _ (_, AnnType ty)
 364   = return (Type ty)
 365
 366 -- No point in floating out an expression wrapped in a coercion or note
 367 -- If we do we'll transform  lvl = e |> co
 368 --                       to  lvl' = e; lvl = lvl' |> co
 369 -- and then inline lvl.  Better just to float out the payload.
 370 lvlMFE strict_ctxt ctxt_lvl env (_, AnnNote n e)
 371   = do { e' <- lvlMFE strict_ctxt ctxt_lvl env e
 372        ; return (Note n e') }
 373
 374 lvlMFE strict_ctxt ctxt_lvl env (_, AnnCast e co)
 375   = do  { e' <- lvlMFE strict_ctxt ctxt_lvl env e
 376         ; return (Cast e' co) }
 377
 378 -- Note [Case MFEs]
 379 lvlMFE True ctxt_lvl env e@(_, AnnCase {})
 380   = lvlExpr ctxt_lvl env e     -- Don't share cases
 381
 382 lvlMFE strict_ctxt ctxt_lvl env ann_expr@(fvs, _)
 383   |  isUnLiftedType ty                  -- Can't let-bind it; see Note [Unlifted MFEs]
 384   || exprIsTrivial expr                 -- Never float if it's trivial
 385   || not good_destination
 386   =     -- Don't float it out
 387     lvlExpr ctxt_lvl env ann_expr
 388
 389   | otherwise   -- Float it out!
 390   = do expr' <- lvlFloatRhs abs_vars dest_lvl env ann_expr
 391        var <- newLvlVar "lvl" abs_vars ty
 392                 -- Note [Bottoming floats]
 393        let var_w_str = case exprBotStrictness_maybe expr of
 394                           Just (arity,str) -> var `setIdArity` arity
 395                                                   `setIdStrictness` str
 396                           Nothing  -> var
 397        return (Let (NonRec (TB var_w_str dest_lvl) expr')
 398                    (mkVarApps (Var var_w_str) abs_vars))
 399   where
 400     expr     = deAnnotate ann_expr
 401     ty       = exprType expr
 402     dest_lvl = destLevel env fvs (isFunction ann_expr)
 403     abs_vars = abstractVars dest_lvl env fvs
 404
 405         -- A decision to float entails let-binding this thing, and we only do
 406         -- that if we'll escape a value lambda, or will go to the top level.
 407     good_destination
 408         | dest_lvl `ltMajLvl` ctxt_lvl          -- Escapes a value lambda
 409         = True
 410         -- OLD CODE: not (exprIsCheap expr) || isTopLvl dest_lvl
 411         --           see Note [Escaping a value lambda]
 412
 413         | otherwise             -- Does not escape a value lambda
 414         = isTopLvl dest_lvl     -- Only float if we are going to the top level
 415         && floatConsts env      --   and the floatConsts flag is on
 416         && not strict_ctxt      -- Don't float from a strict context
 417           -- We are keen to float something to the top level, even if it does not
 418           -- escape a lambda, because then it needs no allocation.  But it's controlled
 419           -- by a flag, because doing this too early loses opportunities for RULES
 420           -- which (needless to say) are important in some nofib programs
 421           -- (gcd is an example).
 422           --
 423           -- Beware:
 424           --    concat = /\ a -> foldr ..a.. (++) []
 425           -- was getting turned into
 426           --    concat = /\ a -> lvl a
 427           --    lvl    = /\ a -> foldr ..a.. (++) []
 428           -- which is pretty stupid.  Hence the strict_ctxt test
 429 \end{code}
 430
 431 Note [Escaping a value lambda]
 432 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 433 We want to float even cheap expressions out of value lambdas,
 434 because that saves allocation.  Consider
 435         f = \x.  .. (\y.e) ...
 436 Then we'd like to avoid allocating the (\y.e) every time we call f,
 437 (assuming e does not mention x).
 438
 439 An example where this really makes a difference is simplrun009.
 440
 441 Another reason it's good is because it makes SpecContr fire on functions.
 442 Consider
 443         f = \x. ....(f (\y.e))....
 444 After floating we get
 445         lvl = \y.e
 446         f = \x. ....(f lvl)...
 447 and that is much easier for SpecConstr to generate a robust specialisation for.
 448
 449 The OLD CODE (given where this Note is referred to) prevents floating
 450 of the example above, so I just don't understand the old code.  I
 451 don't understand the old comment either (which appears below).  I
 452 measured the effect on nofib of changing OLD CODE to 'True', and got
 453 zeros everywhere, but a 4% win for 'puzzle'.  Very small 0.5% loss for
 454 'cse'; turns out to be because our arity analysis isn't good enough
 455 yet (mentioned in Simon-nofib-notes).
 456
 457 OLD comment was:
 458          Even if it escapes a value lambda, we only
 459          float if it's not cheap (unless it'll get all the
 460          way to the top).  I've seen cases where we
 461          float dozens of tiny free expressions, which cost
 462          more to allocate than to evaluate.
 463          NB: exprIsCheap is also true of bottom expressions, which
 464              is good; we don't want to share them
 465
 466         It's only Really Bad to float a cheap expression out of a
 467         strict context, because that builds a thunk that otherwise
 468         would never be built.  So another alternative would be to
 469         add
 470                 || (strict_ctxt && not (exprIsBottom expr))
 471         to the condition above. We should really try this out.
 472
 473
 474 %************************************************************************
 475 %*                                                                      *
 476 \subsection{Bindings}
 477 %*                                                                      *
 478 %************************************************************************
 479
 480 The binding stuff works for top level too.
 481
 482 \begin{code}
 483 lvlBind :: TopLevelFlag         -- Used solely to decide whether to clone
 484         -> Level                -- Context level; might be Top even for bindings nested in the RHS
 485                                 -- of a top level binding
 486         -> LevelEnv
 487         -> CoreBindWithFVs
 488         -> LvlM (LevelledBind, LevelEnv)
 489
 490 lvlBind top_lvl ctxt_lvl env (AnnNonRec bndr rhs@(rhs_fvs,_))
 491   |  isTyVar bndr               -- Don't do anything for TyVar binders
 492                                 --   (simplifier gets rid of them pronto)
 493   = do rhs' <- lvlExpr ctxt_lvl env rhs
 494        return (NonRec (TB bndr ctxt_lvl) rhs', env)
 495
 496   | null abs_vars
 497   = do  -- No type abstraction; clone existing binder
 498        rhs' <- lvlExpr dest_lvl env rhs
 499        (env', bndr') <- cloneVar top_lvl env bndr ctxt_lvl dest_lvl
 500        return (NonRec (TB bndr' dest_lvl) rhs', env')
 501
 502   | otherwise
 503   = do  -- Yes, type abstraction; create a new binder, extend substitution, etc
 504        rhs' <- lvlFloatRhs abs_vars dest_lvl env rhs
 505        (env', [bndr']) <- newPolyBndrs dest_lvl env abs_vars [bndr]
 506        return (NonRec (TB bndr' dest_lvl) rhs', env')
 507
 508   where
 509     bind_fvs = rhs_fvs `unionVarSet` idFreeVars bndr
 510     abs_vars = abstractVars dest_lvl env bind_fvs
 511     dest_lvl = destLevel env bind_fvs (isFunction rhs)
 512 \end{code}
 513
 514
 515 \begin{code}
 516 lvlBind top_lvl ctxt_lvl env (AnnRec pairs)
 517   | null abs_vars
 518   = do (new_env, new_bndrs) <- cloneRecVars top_lvl env bndrs ctxt_lvl dest_lvl
 519        new_rhss <- mapM (lvlExpr ctxt_lvl new_env) rhss
 520        return (Rec ([TB b dest_lvl | b <- new_bndrs] `zip` new_rhss), new_env)
 521
 522   | isSingleton pairs && count isId abs_vars > 1
 523   = do  -- Special case for self recursion where there are
 524         -- several variables carried around: build a local loop:
 525         --      poly_f = \abs_vars. \lam_vars . letrec f = \lam_vars. rhs in f lam_vars
 526         -- This just makes the closures a bit smaller.  If we don't do
 527         -- this, allocation rises significantly on some programs
 528         --
 529         -- We could elaborate it for the case where there are several
 530         -- mutually functions, but it's quite a bit more complicated
 531         --
 532         -- This all seems a bit ad hoc -- sigh
 533     let
 534         (bndr,rhs) = head pairs
 535         (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 536         rhs_env = extendLvlEnv env abs_vars_w_lvls
 537     (rhs_env', new_bndr) <- cloneVar NotTopLevel rhs_env bndr rhs_lvl rhs_lvl
 538     let
 539         (lam_bndrs, rhs_body)     = collectAnnBndrs rhs
 540         (body_lvl, new_lam_bndrs) = lvlLamBndrs rhs_lvl lam_bndrs
 541         body_env                  = extendLvlEnv rhs_env' new_lam_bndrs
 542     new_rhs_body <- lvlExpr body_lvl body_env rhs_body
 543     (poly_env, [poly_bndr]) <- newPolyBndrs dest_lvl env abs_vars [bndr]
 544     return (Rec [(TB poly_bndr dest_lvl,
 545                mkLams abs_vars_w_lvls $
 546                mkLams new_lam_bndrs $
 547                Let (Rec [(TB new_bndr rhs_lvl, mkLams new_lam_bndrs new_rhs_body)])
 548                    (mkVarApps (Var new_bndr) lam_bndrs))],
 549                poly_env)
 550
 551   | otherwise = do  -- Non-null abs_vars
 552     (new_env, new_bndrs) <- newPolyBndrs dest_lvl env abs_vars bndrs
 553     new_rhss <- mapM (lvlFloatRhs abs_vars dest_lvl new_env) rhss
 554     return (Rec ([TB b dest_lvl | b <- new_bndrs] `zip` new_rhss), new_env)
 555
 556   where
 557     (bndrs,rhss) = unzip pairs
 558
 559         -- Finding the free vars of the binding group is annoying
 560     bind_fvs        = (unionVarSets [ idFreeVars bndr `unionVarSet` rhs_fvs
 561                                     | (bndr, (rhs_fvs,_)) <- pairs])
 562                       `minusVarSet`
 563                       mkVarSet bndrs
 564
 565     dest_lvl = destLevel env bind_fvs (all isFunction rhss)
 566     abs_vars = abstractVars dest_lvl env bind_fvs
 567
 568 ----------------------------------------------------
 569 -- Three help functons for the type-abstraction case
 570
 571 lvlFloatRhs :: [CoreBndr] -> Level -> LevelEnv -> CoreExprWithFVs
 572             -> UniqSM (Expr (TaggedBndr Level))
 573 lvlFloatRhs abs_vars dest_lvl env rhs = do
 574     rhs' <- lvlExpr rhs_lvl rhs_env rhs
 575     return (mkLams abs_vars_w_lvls rhs')
 576   where
 577     (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 578     rhs_env = extendLvlEnv env abs_vars_w_lvls
 579 \end{code}
 580
 581
 582 %************************************************************************
 583 %*                                                                      *
 584 \subsection{Deciding floatability}
 585 %*                                                                      *
 586 %************************************************************************
 587
 588 \begin{code}
 589 lvlLamBndrs :: Level -> [CoreBndr] -> (Level, [TaggedBndr Level])
 590 -- Compute the levels for the binders of a lambda group
 591 -- The binders returned are exactly the same as the ones passed,
 592 -- but they are now paired with a level
 593 lvlLamBndrs lvl []
 594   = (lvl, [])
 595
 596 lvlLamBndrs lvl bndrs
 597   = go  (incMinorLvl lvl)
 598         False   -- Havn't bumped major level in this group
 599         [] bndrs
 600   where
 601     go old_lvl bumped_major rev_lvld_bndrs (bndr:bndrs)
 602         | isId bndr &&                  -- Go to the next major level if this is a value binder,
 603           not bumped_major &&           -- and we havn't already gone to the next level (one jump per group)
 604           not (isOneShotLambda bndr)    -- and it isn't a one-shot lambda
 605         = go new_lvl True (TB bndr new_lvl : rev_lvld_bndrs) bndrs
 606
 607         | otherwise
 608         = go old_lvl bumped_major (TB bndr old_lvl : rev_lvld_bndrs) bndrs
 609
 610         where
 611           new_lvl = incMajorLvl old_lvl
 612
 613     go old_lvl _ rev_lvld_bndrs []
 614         = (old_lvl, reverse rev_lvld_bndrs)
 615         -- a lambda like this (\x -> coerce t (\s -> ...))
 616         -- This happens quite a bit in state-transformer programs
 617 \end{code}
 618
 619 \begin{code}
 620   -- Destintion level is the max Id level of the expression
 621   -- (We'll abstract the type variables, if any.)
 622 destLevel :: LevelEnv -> VarSet -> Bool -> Level
 623 destLevel env fvs is_function
 624   |  floatLams env
 625   && is_function = tOP_LEVEL            -- Send functions to top level; see
 626                                         -- the comments with isFunction
 627   | otherwise    = maxIdLevel env fvs
 628
 629 isFunction :: CoreExprWithFVs -> Bool
 630 -- The idea here is that we want to float *functions* to
 631 -- the top level.  This saves no work, but
 632 --      (a) it can make the host function body a lot smaller,
 633 --              and hence inlinable.
 634 --      (b) it can also save allocation when the function is recursive:
 635 --          h = \x -> letrec f = \y -> ...f...y...x...
 636 --                    in f x
 637 --     becomes
 638 --          f = \x y -> ...(f x)...y...x...
 639 --          h = \x -> f x x
 640 --     No allocation for f now.
 641 -- We may only want to do this if there are sufficiently few free
 642 -- variables.  We certainly only want to do it for values, and not for
 643 -- constructors.  So the simple thing is just to look for lambdas
 644 isFunction (_, AnnLam b e) | isId b    = True
 645                            | otherwise = isFunction e
 646 isFunction (_, AnnNote _ e)            = isFunction e
 647 isFunction _                           = False
 648 \end{code}
 649
 650
 651 %************************************************************************
 652 %*                                                                      *
 653 \subsection{Free-To-Level Monad}
 654 %*                                                                      *
 655 %************************************************************************
 656
 657 \begin{code}
 658 type LevelEnv = (FloatOutSwitches,
 659                  VarEnv Level,                  -- Domain is *post-cloned* TyVars and Ids
 660                  Subst,                         -- Domain is pre-cloned Ids; tracks the in-scope set
 661                                                 --      so that subtitution is capture-avoiding
 662                  IdEnv ([Var], LevelledExpr))   -- Domain is pre-cloned Ids
 663         -- We clone let-bound variables so that they are still
 664         -- distinct when floated out; hence the SubstEnv/IdEnv.
 665         -- (see point 3 of the module overview comment).
 666         -- We also use these envs when making a variable polymorphic
 667         -- because we want to float it out past a big lambda.
 668         --
 669         -- The Subst and IdEnv always implement the same mapping, but the
 670         -- Subst maps to CoreExpr and the IdEnv to LevelledExpr
 671         -- Since the range is always a variable or type application,
 672         -- there is never any difference between the two, but sadly
 673         -- the types differ.  The SubstEnv is used when substituting in
 674         -- a variable's IdInfo; the IdEnv when we find a Var.
 675         --
 676         -- In addition the IdEnv records a list of tyvars free in the
 677         -- type application, just so we don't have to call freeVars on
 678         -- the type application repeatedly.
 679         --
 680         -- The domain of the both envs is *pre-cloned* Ids, though
 681         --
 682         -- The domain of the VarEnv Level is the *post-cloned* Ids
 683
 684 initialEnv :: FloatOutSwitches -> LevelEnv
 685 initialEnv float_lams = (float_lams, emptyVarEnv, emptySubst, emptyVarEnv)
 686
 687 floatLams :: LevelEnv -> Bool
 688 floatLams (fos, _, _, _) = floatOutLambdas fos
 689
 690 floatConsts :: LevelEnv -> Bool
 691 floatConsts (fos, _, _, _) = floatOutConstants fos
 692
 693 extendLvlEnv :: LevelEnv -> [TaggedBndr Level] -> LevelEnv
 694 -- Used when *not* cloning
 695 extendLvlEnv (float_lams, lvl_env, subst, id_env) prs
 696   = (float_lams,
 697      foldl add_lvl lvl_env prs,
 698      foldl del_subst subst prs,
 699      foldl del_id id_env prs)
 700   where
 701     add_lvl   env (TB v l) = extendVarEnv env v l
 702     del_subst env (TB v _) = extendInScope env v
 703     del_id    env (TB v _) = delVarEnv env v
 704   -- We must remove any clone for this variable name in case of
 705   -- shadowing.  This bit me in the following case
 706   -- (in nofib/real/gg/Spark.hs):
 707   --
 708   --   case ds of wild {
 709   --     ... -> case e of wild {
 710   --              ... -> ... wild ...
 711   --            }
 712   --   }
 713   --
 714   -- The inside occurrence of @wild@ was being replaced with @ds@,
 715   -- incorrectly, because the SubstEnv was still lying around.  Ouch!
 716   -- KSW 2000-07.
 717
 718 extendInScopeEnv :: LevelEnv -> Var -> LevelEnv
 719 extendInScopeEnv (fl, le, subst, ids) v = (fl, le, extendInScope subst v, ids)
 720
 721 extendInScopeEnvList :: LevelEnv -> [Var] -> LevelEnv
 722 extendInScopeEnvList (fl, le, subst, ids) vs = (fl, le, extendInScopeList subst vs, ids)
 723
 724 -- extendCaseBndrLvlEnv adds the mapping case-bndr->scrut-var if it can
 725 -- (see point 4 of the module overview comment)
 726 extendCaseBndrLvlEnv :: LevelEnv -> Expr (TaggedBndr Level) -> Var -> Level
 727                      -> LevelEnv
 728 extendCaseBndrLvlEnv (float_lams, lvl_env, subst, id_env) (Var scrut_var) case_bndr lvl
 729   = (float_lams,
 730      extendVarEnv lvl_env case_bndr lvl,
 731      extendIdSubst subst case_bndr (Var scrut_var),
 732      extendVarEnv id_env case_bndr ([scrut_var], Var scrut_var))
 733
 734 extendCaseBndrLvlEnv env _scrut case_bndr lvl
 735   = extendLvlEnv          env [TB case_bndr lvl]
 736
 737 extendPolyLvlEnv :: Level -> LevelEnv -> [Var] -> [(Var, Var)] -> LevelEnv
 738 extendPolyLvlEnv dest_lvl (float_lams, lvl_env, subst, id_env) abs_vars bndr_pairs
 739   = (float_lams,
 740      foldl add_lvl   lvl_env bndr_pairs,
 741      foldl add_subst subst   bndr_pairs,
 742      foldl add_id    id_env  bndr_pairs)
 743   where
 744      add_lvl   env (_, v') = extendVarEnv env v' dest_lvl
 745      add_subst env (v, v') = extendIdSubst env v (mkVarApps (Var v') abs_vars)
 746      add_id    env (v, v') = extendVarEnv env v ((v':abs_vars), mkVarApps (Var v') abs_vars)
 747
 748 extendCloneLvlEnv :: Level -> LevelEnv -> Subst -> [(Var, Var)] -> LevelEnv
 749 extendCloneLvlEnv lvl (float_lams, lvl_env, _, id_env) new_subst bndr_pairs
 750   = (float_lams,
 751      foldl add_lvl   lvl_env bndr_pairs,
 752      new_subst,
 753      foldl add_id    id_env  bndr_pairs)
 754   where
 755      add_lvl env (_, v') = extendVarEnv env v' lvl
 756      add_id  env (v, v') = extendVarEnv env v ([v'], Var v')
 757
 758
 759 maxIdLevel :: LevelEnv -> VarSet -> Level
 760 maxIdLevel (_, lvl_env,_,id_env) var_set
 761   = foldVarSet max_in tOP_LEVEL var_set
 762   where
 763     max_in in_var lvl = foldr max_out lvl (case lookupVarEnv id_env in_var of
 764                                                 Just (abs_vars, _) -> abs_vars
 765                                                 Nothing            -> [in_var])
 766
 767     max_out out_var lvl
 768         | isId out_var = case lookupVarEnv lvl_env out_var of
 769                                 Just lvl' -> maxLvl lvl' lvl
 770                                 Nothing   -> lvl
 771         | otherwise    = lvl    -- Ignore tyvars in *maxIdLevel*
 772
 773 lookupVar :: LevelEnv -> Id -> LevelledExpr
 774 lookupVar (_, _, _, id_env) v = case lookupVarEnv id_env v of
 775                                        Just (_, expr) -> expr
 776                                        _              -> Var v
 777
 778 abstractVars :: Level -> LevelEnv -> VarSet -> [Var]
 779         -- Find the variables in fvs, free vars of the target expresion,
 780         -- whose level is greater than the destination level
 781         -- These are the ones we are going to abstract out
 782 abstractVars dest_lvl (_, lvl_env, _, id_env) fvs
 783   = map zap $ uniq $ sortLe le
 784         [var | fv <- varSetElems fvs
 785              , var <- absVarsOf id_env fv
 786              , abstract_me var ]
 787         -- NB: it's important to call abstract_me only on the OutIds the
 788         -- come from absVarsOf (not on fv, which is an InId)
 789   where
 790         -- Sort the variables so the true type variables come first;
 791         -- the tyvars scope over Ids and coercion vars
 792     v1 `le` v2 = case (is_tv v1, is_tv v2) of
 793                    (True, False) -> True
 794                    (False, True) -> False
 795                    _             -> v1 <= v2    -- Same family
 796
 797     is_tv v = isTyVar v && not (isCoVar v)
 798
 799     uniq :: [Var] -> [Var]
 800         -- Remove adjacent duplicates; the sort will have brought them together
 801     uniq (v1:v2:vs) | v1 == v2  = uniq (v2:vs)
 802                     | otherwise = v1 : uniq (v2:vs)
 803     uniq vs = vs
 804
 805     abstract_me v = case lookupVarEnv lvl_env v of
 806                         Just lvl -> dest_lvl `ltLvl` lvl
 807                         Nothing  -> False
 808
 809         -- We are going to lambda-abstract, so nuke any IdInfo,
 810         -- and add the tyvars of the Id (if necessary)
 811     zap v | isId v = WARN( isInlineRule (idUnfolding v) ||
 812                            not (isEmptySpecInfo (idSpecialisation v)),
 813                            text "absVarsOf: discarding info on" <+> ppr v )
 814                      setIdInfo v vanillaIdInfo
 815           | otherwise = v
 816
 817 absVarsOf :: IdEnv ([Var], LevelledExpr) -> Var -> [Var]
 818         -- If f is free in the expression, and f maps to poly_f a b c in the
 819         -- current substitution, then we must report a b c as candidate type
 820         -- variables
 821         --
 822         -- Also, if x::a is an abstracted variable, then so is a; that is,
 823         --      we must look in x's type
 824         -- And similarly if x is a coercion variable.
 825 absVarsOf id_env v
 826   | isId v    = [av2 | av1 <- lookup_avs v
 827                      , av2 <- add_tyvars av1]
 828   | isCoVar v = add_tyvars v
 829   | otherwise = [v]
 830
 831   where
 832     lookup_avs v = case lookupVarEnv id_env v of
 833                         Just (abs_vars, _) -> abs_vars
 834                         Nothing            -> [v]
 835
 836     add_tyvars v = v : varSetElems (varTypeTyVars v)
 837 \end{code}
 838
 839 \begin{code}
 840 type LvlM result = UniqSM result
 841
 842 initLvl :: UniqSupply -> UniqSM a -> a
 843 initLvl = initUs_
 844 \end{code}
 845
 846
 847 \begin{code}
 848 newPolyBndrs :: Level -> LevelEnv -> [Var] -> [Id] -> UniqSM (LevelEnv, [Id])
 849 newPolyBndrs dest_lvl env abs_vars bndrs = do
 850     uniqs <- getUniquesM
 851     let new_bndrs = zipWith mk_poly_bndr bndrs uniqs
 852     return (extendPolyLvlEnv dest_lvl env abs_vars (bndrs `zip` new_bndrs), new_bndrs)
 853   where
 854     mk_poly_bndr bndr uniq = transferPolyIdInfo bndr abs_vars $         -- Note [transferPolyIdInfo] in Id.lhs
 855                              mkSysLocal (mkFastString str) uniq poly_ty
 856                            where
 857                              str     = "poly_" ++ occNameString (getOccName bndr)
 858                              poly_ty = mkPiTypes abs_vars (idType bndr)
 859
 860 newLvlVar :: String
 861           -> [CoreBndr] -> Type         -- Abstract wrt these bndrs
 862           -> LvlM Id
 863 newLvlVar str vars body_ty = do
 864     uniq <- getUniqueM
 865     return (mkSysLocal (mkFastString str) uniq (mkPiTypes vars body_ty))
 866
 867 -- The deeply tiresome thing is that we have to apply the substitution
 868 -- to the rules inside each Id.  Grr.  But it matters.
 869
 870 cloneVar :: TopLevelFlag -> LevelEnv -> Id -> Level -> Level -> LvlM (LevelEnv, Id)
 871 cloneVar TopLevel env v _ _
 872   = return (extendInScopeEnv env v, v)  -- Don't clone top level things
 873                 -- But do extend the in-scope env, to satisfy the in-scope invariant
 874
 875 cloneVar NotTopLevel env@(_,_,subst,_) v ctxt_lvl dest_lvl
 876   = ASSERT( isId v ) do
 877     us <- getUniqueSupplyM
 878     let
 879       (subst', v1) = cloneIdBndr subst us v
 880       v2           = zap_demand ctxt_lvl dest_lvl v1
 881       env'         = extendCloneLvlEnv dest_lvl env subst' [(v,v2)]
 882     return (env', v2)
 883
 884 cloneRecVars :: TopLevelFlag -> LevelEnv -> [Id] -> Level -> Level -> LvlM (LevelEnv, [Id])
 885 cloneRecVars TopLevel env vs _ _
 886   = return (extendInScopeEnvList env vs, vs)    -- Don't clone top level things
 887 cloneRecVars NotTopLevel env@(_,_,subst,_) vs ctxt_lvl dest_lvl
 888   = ASSERT( all isId vs ) do
 889     us <- getUniqueSupplyM
 890     let
 891       (subst', vs1) = cloneRecIdBndrs subst us vs
 892       vs2           = map (zap_demand ctxt_lvl dest_lvl) vs1
 893       env'          = extendCloneLvlEnv dest_lvl env subst' (vs `zip` vs2)
 894     return (env', vs2)
 895
 896         -- VERY IMPORTANT: we must zap the demand info
 897         -- if the thing is going to float out past a lambda,
 898         -- or if it's going to top level (where things can't be strict)
 899 zap_demand :: Level -> Level -> Id -> Id
 900 zap_demand dest_lvl ctxt_lvl id
 901   | ctxt_lvl == dest_lvl,
 902     not (isTopLvl dest_lvl) = id        -- Stays, and not going to top level
 903   | otherwise               = zapDemandIdInfo id        -- Floats out
 904 \end{code}
 905