compiler/simplCore/SimplCore.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SimplCore]{Driver for simplifying @Core@ programs}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module SimplCore ( core2core, simplifyExpr ) where
  15
  16 #include "HsVersions.h"
  17
  18 import DynFlags         ( DynFlags, DynFlag(..), dopt )
  19 import CoreSyn
  20 import CoreSubst
  21 import HscTypes
  22 import CSE              ( cseProgram )
  23 import Rules            ( RuleBase, emptyRuleBase, mkRuleBase, unionRuleBase,
  24                           extendRuleBaseList, pprRuleBase, pprRulesForUser,
  25                           ruleCheckProgram, rulesOfBinds,
  26                           addSpecInfo, addIdSpecialisations )
  27 import PprCore          ( pprCoreBindings, pprCoreExpr, pprRules )
  28 import OccurAnal        ( occurAnalysePgm, occurAnalyseExpr )
  29 import IdInfo
  30 import CoreUtils        ( coreBindsSize )
  31 import Simplify         ( simplTopBinds, simplExpr )
  32 import SimplUtils       ( simplEnvForGHCi, simplEnvForRules )
  33 import SimplEnv
  34 import SimplMonad
  35 import CoreMonad
  36 import qualified ErrUtils as Err
  37 import CoreLint
  38 import FloatIn          ( floatInwards )
  39 import FloatOut         ( floatOutwards )
  40 import FamInstEnv
  41 import Id
  42 import DataCon
  43 import TyCon            ( tyConDataCons )
  44 import Class            ( classSelIds )
  45 import BasicTypes       ( CompilerPhase, isActive, isDefaultInlinePragma )
  46 import VarSet
  47 import VarEnv
  48 import NameEnv          ( lookupNameEnv )
  49 import LiberateCase     ( liberateCase )
  50 import SAT              ( doStaticArgs )
  51 import Specialise       ( specProgram)
  52 import SpecConstr       ( specConstrProgram)
  53 import DmdAnal          ( dmdAnalPgm )
  54 import WorkWrap         ( wwTopBinds )
  55 import Vectorise        ( vectorise )
  56 import FastString
  57 import Util
  58
  59 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, splitUniqSupply )
  60 import Outputable
  61 import Control.Monad
  62 import Data.List
  63 import System.IO
  64 import Maybes
  65 \end{code}
  66
  67 %************************************************************************
  68 %*                                                                      *
  69 \subsection{The driver for the simplifier}
  70 %*                                                                      *
  71 %************************************************************************
  72
  73 \begin{code}
  74 core2core :: HscEnv
  75           -> ModGuts
  76           -> IO ModGuts
  77
  78 core2core hsc_env guts = do
  79     let dflags = hsc_dflags hsc_env
  80
  81     us <- mkSplitUniqSupply 's'
  82     let (cp_us, ru_us) = splitUniqSupply us
  83
  84     -- COMPUTE THE RULE BASE TO USE
  85     -- See Note [Overall plumbing for rules] in Rules.lhs
  86     (hpt_rule_base, guts1) <- prepareRules hsc_env guts ru_us
  87
  88     -- Get the module out of the current HscEnv so we can retrieve it from the monad.
  89     -- This is very convienent for the users of the monad (e.g. plugins do not have to
  90     -- consume the ModGuts to find the module) but somewhat ugly because mg_module may
  91     -- _theoretically_ be changed during the Core pipeline (it's part of ModGuts), which
  92     -- would mean our cached value would go out of date.
  93     let mod = mg_module guts
  94     (guts2, stats) <- runCoreM hsc_env hpt_rule_base cp_us mod $ do
  95         -- FIND BUILT-IN PASSES
  96         let builtin_core_todos = getCoreToDo dflags
  97
  98         -- DO THE BUSINESS
  99         doCorePasses builtin_core_todos guts1
 100
 101     Err.dumpIfSet_dyn dflags Opt_D_dump_simpl_stats
 102         "Grand total simplifier statistics"
 103         (pprSimplCount stats)
 104
 105     return guts2
 106
 107
 108 type CorePass = CoreToDo
 109
 110 simplifyExpr :: DynFlags -- includes spec of what core-to-core passes to do
 111              -> CoreExpr
 112              -> IO CoreExpr
 113 -- simplifyExpr is called by the driver to simplify an
 114 -- expression typed in at the interactive prompt
 115 --
 116 -- Also used by Template Haskell
 117 simplifyExpr dflags expr
 118   = do  {
 119         ; Err.showPass dflags "Simplify"
 120
 121         ; us <-  mkSplitUniqSupply 's'
 122
 123         ; let (expr', _counts) = initSmpl dflags emptyRuleBase emptyFamInstEnvs us $
 124                                  simplExprGently simplEnvForGHCi expr
 125
 126         ; Err.dumpIfSet_dyn dflags Opt_D_dump_simpl "Simplified expression"
 127                         (pprCoreExpr expr')
 128
 129         ; return expr'
 130         }
 131
 132 doCorePasses :: [CorePass] -> ModGuts -> CoreM ModGuts
 133 doCorePasses passes guts
 134   = foldM do_pass guts passes
 135   where
 136     do_pass guts CoreDoNothing = return guts
 137     do_pass guts (CoreDoPasses ps) = doCorePasses ps guts
 138     do_pass guts pass
 139        = do { dflags <- getDynFlags
 140             ; liftIO $ showPass dflags pass
 141             ; guts' <- doCorePass pass guts
 142             ; liftIO $ endPass dflags pass (mg_binds guts') (mg_rules guts')
 143             ; return guts' }
 144
 145 doCorePass :: CorePass -> ModGuts -> CoreM ModGuts
 146 doCorePass pass@(CoreDoSimplify {})  = {-# SCC "Simplify" #-}
 147                                        simplifyPgm pass
 148
 149 doCorePass CoreCSE                   = {-# SCC "CommonSubExpr" #-}
 150                                        doPass cseProgram
 151
 152 doCorePass CoreLiberateCase          = {-# SCC "LiberateCase" #-}
 153                                        doPassD liberateCase
 154
 155 doCorePass CoreDoFloatInwards        = {-# SCC "FloatInwards" #-}
 156                                        doPass floatInwards
 157
 158 doCorePass (CoreDoFloatOutwards f)   = {-# SCC "FloatOutwards" #-}
 159                                        doPassDUM (floatOutwards f)
 160
 161 doCorePass CoreDoStaticArgs          = {-# SCC "StaticArgs" #-}
 162                                        doPassU doStaticArgs
 163
 164 doCorePass CoreDoStrictness          = {-# SCC "Stranal" #-}
 165                                        doPassDM dmdAnalPgm
 166
 167 doCorePass CoreDoWorkerWrapper       = {-# SCC "WorkWrap" #-}
 168                                        doPassU wwTopBinds
 169
 170 doCorePass CoreDoSpecialising        = {-# SCC "Specialise" #-}
 171                                        doPassU specProgram
 172
 173 doCorePass CoreDoSpecConstr          = {-# SCC "SpecConstr" #-}
 174                                        specConstrProgram
 175
 176 doCorePass (CoreDoVectorisation be)  = {-# SCC "Vectorise" #-}
 177                                        vectorise be
 178
 179 doCorePass CoreDoGlomBinds              = doPassDM  glomBinds
 180 doCorePass CoreDoPrintCore              = observe   printCore
 181 doCorePass (CoreDoRuleCheck phase pat)  = ruleCheck phase pat
 182 doCorePass CoreDoNothing                = return
 183 doCorePass (CoreDoPasses passes)        = doCorePasses passes
 184 \end{code}
 185
 186 %************************************************************************
 187 %*                                                                      *
 188 \subsection{Core pass combinators}
 189 %*                                                                      *
 190 %************************************************************************
 191
 192 \begin{code}
 193 printCore _ binds = Err.dumpIfSet True "Print Core" (pprCoreBindings binds)
 194
 195 ruleCheck :: CompilerPhase -> String -> ModGuts -> CoreM ModGuts
 196 ruleCheck current_phase pat guts = do
 197     rb <- getRuleBase
 198     dflags <- getDynFlags
 199     liftIO $ Err.showPass dflags "RuleCheck"
 200     liftIO $ printDump (ruleCheckProgram current_phase pat rb (mg_binds guts))
 201     return guts
 202
 203
 204 doPassDMS :: (DynFlags -> [CoreBind] -> IO (SimplCount, [CoreBind])) -> ModGuts -> CoreM ModGuts
 205 doPassDMS do_pass = doPassM $ \binds -> do
 206     dflags <- getDynFlags
 207     liftIOWithCount $ do_pass dflags binds
 208
 209 doPassDUM :: (DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 210 doPassDUM do_pass = doPassM $ \binds -> do
 211     dflags <- getDynFlags
 212     us     <- getUniqueSupplyM
 213     liftIO $ do_pass dflags us binds
 214
 215 doPassDM :: (DynFlags -> [CoreBind] -> IO [CoreBind]) -> ModGuts -> CoreM ModGuts
 216 doPassDM do_pass = doPassDUM (\dflags -> const (do_pass dflags))
 217
 218 doPassD :: (DynFlags -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 219 doPassD do_pass = doPassDM (\dflags -> return . do_pass dflags)
 220
 221 doPassDU :: (DynFlags -> UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 222 doPassDU do_pass = doPassDUM (\dflags us -> return . do_pass dflags us)
 223
 224 doPassU :: (UniqSupply -> [CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 225 doPassU do_pass = doPassDU (const do_pass)
 226
 227 -- Most passes return no stats and don't change rules: these combinators
 228 -- let us lift them to the full blown ModGuts+CoreM world
 229 doPassM :: Monad m => ([CoreBind] -> m [CoreBind]) -> ModGuts -> m ModGuts
 230 doPassM bind_f guts = do
 231     binds' <- bind_f (mg_binds guts)
 232     return (guts { mg_binds = binds' })
 233
 234 doPassMG :: Monad m => (ModGuts -> m [CoreBind]) -> ModGuts -> m ModGuts
 235 doPassMG bind_f guts = do
 236     binds' <- bind_f guts
 237     return (guts { mg_binds = binds' })
 238
 239 doPass :: ([CoreBind] -> [CoreBind]) -> ModGuts -> CoreM ModGuts
 240 doPass bind_f guts = return $ guts { mg_binds = bind_f (mg_binds guts) }
 241
 242 -- Observer passes just peek; don't modify the bindings at all
 243 observe :: (DynFlags -> [CoreBind] -> IO a) -> ModGuts -> CoreM ModGuts
 244 observe do_pass = doPassM $ \binds -> do
 245     dflags <- getDynFlags
 246     liftIO $ do_pass dflags binds
 247     return binds
 248 \end{code}
 249
 250
 251 %************************************************************************
 252 %*                                                                      *
 253         Dealing with rules
 254 %*                                                                      *
 255 %************************************************************************
 256
 257 -- prepareLocalRuleBase takes the CoreBinds and rules defined in this module.
 258 -- It attaches those rules that are for local Ids to their binders, and
 259 -- returns the remainder attached to Ids in an IdSet.
 260
 261 \begin{code}
 262 prepareRules :: HscEnv
 263              -> ModGuts
 264              -> UniqSupply
 265              -> IO (RuleBase,           -- Rule base for imported things, incl
 266                                         -- (a) rules defined in this module (orphans)
 267                                         -- (b) rules from other modules in home package
 268                                         -- but not things from other packages
 269
 270                     ModGuts)            -- Modified fields are
 271                                         --      (a) Bindings have rules attached,
 272                                         --              and INLINE rules simplified
 273                                         --      (b) Rules are now just orphan rules
 274
 275 prepareRules hsc_env@(HscEnv { hsc_dflags = dflags, hsc_HPT = hpt })
 276              guts@(ModGuts { mg_binds = binds, mg_deps = deps
 277                            , mg_rules = local_rules, mg_rdr_env = rdr_env })
 278              us
 279   = do  { us <- mkSplitUniqSupply 'w'
 280
 281         ; let   -- Simplify the local rules; boringly, we need to make an in-scope set
 282                 -- from the local binders, to avoid warnings from Simplify.simplVar
 283               local_ids        = mkInScopeSet (mkVarSet (bindersOfBinds binds))
 284               env              = setInScopeSet simplEnvForRules local_ids
 285               (simpl_rules, _) = initSmpl dflags emptyRuleBase emptyFamInstEnvs us $
 286                                  mapM (simplRule env) local_rules
 287
 288         ; let (rules_for_locals, rules_for_imps) = partition isLocalRule simpl_rules
 289
 290               home_pkg_rules = hptRules hsc_env (dep_mods deps)
 291               hpt_rule_base  = mkRuleBase home_pkg_rules
 292               binds_w_rules  = updateBinders rules_for_locals binds
 293
 294
 295         ; Err.dumpIfSet_dyn dflags Opt_D_dump_rules "Transformation rules"
 296                 (withPprStyle (mkUserStyle (mkPrintUnqualified dflags rdr_env) AllTheWay) $
 297                  vcat [text "Local rules for local Ids", pprRules simpl_rules,
 298                        blankLine,
 299                        text "Local rules for imported Ids", pprRuleBase hpt_rule_base])
 300
 301         ; return (hpt_rule_base, guts { mg_binds = binds_w_rules,
 302                                         mg_rules = rules_for_imps })
 303     }
 304
 305 -- Note [Attach rules to local ids]
 306 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 307 -- Find the rules for locally-defined Ids; then we can attach them
 308 -- to the binders in the top-level bindings
 309 --
 310 -- Reason
 311 --      - It makes the rules easier to look up
 312 --      - It means that transformation rules and specialisations for
 313 --        locally defined Ids are handled uniformly
 314 --      - It keeps alive things that are referred to only from a rule
 315 --        (the occurrence analyser knows about rules attached to Ids)
 316 --      - It makes sure that, when we apply a rule, the free vars
 317 --        of the RHS are more likely to be in scope
 318 --      - The imported rules are carried in the in-scope set
 319 --        which is extended on each iteration by the new wave of
 320 --        local binders; any rules which aren't on the binding will
 321 --        thereby get dropped
 322
 323 updateBinders :: [CoreRule] -> [CoreBind] -> [CoreBind]
 324 updateBinders rules_for_locals binds
 325   = map update_bind binds
 326   where
 327     local_rules = extendRuleBaseList emptyRuleBase rules_for_locals
 328
 329     update_bind (NonRec b r) = NonRec (add_rules b) r
 330     update_bind (Rec prs)    = Rec (mapFst add_rules prs)
 331
 332         -- See Note [Attach rules to local ids]
 333         -- NB: the binder might have some existing rules,
 334         -- arising from specialisation pragmas
 335     add_rules bndr
 336         | Just rules <- lookupNameEnv local_rules (idName bndr)
 337         = bndr `addIdSpecialisations` rules
 338         | otherwise
 339         = bndr
 340 \end{code}
 341
 342 Note [Simplifying the left-hand side of a RULE]
 343 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 344 We must do some gentle simplification on the lhs (template) of each
 345 rule.  The case that forced me to add this was the fold/build rule,
 346 which without simplification looked like:
 347         fold k z (build (/\a. g a))  ==>  ...
 348 This doesn't match unless you do eta reduction on the build argument.
 349 Similarly for a LHS like
 350         augment g (build h)
 351 we do not want to get
 352         augment (\a. g a) (build h)
 353 otherwise we don't match when given an argument like
 354         augment (\a. h a a) (build h)
 355
 356 The simplifier does indeed do eta reduction (it's in
 357 Simplify.completeLam) but only if -O is on.
 358
 359 \begin{code}
 360 simplRule :: SimplEnv -> CoreRule -> SimplM CoreRule
 361 simplRule env rule@(BuiltinRule {})
 362   = return rule
 363 simplRule env rule@(Rule { ru_bndrs = bndrs, ru_args = args, ru_rhs = rhs })
 364   = do (env, bndrs') <- simplBinders env bndrs
 365        args' <- mapM (simplExprGently env) args
 366        rhs' <- simplExprGently env rhs
 367        return (rule { ru_bndrs = bndrs', ru_args = args'
 368                     , ru_rhs = occurAnalyseExpr rhs' })
 369 \end{code}
 370
 371 \begin{code}
 372 simplExprGently :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 373 -- Simplifies an expression
 374 --      does occurrence analysis, then simplification
 375 --      and repeats (twice currently) because one pass
 376 --      alone leaves tons of crud.
 377 -- Used (a) for user expressions typed in at the interactive prompt
 378 --      (b) the LHS and RHS of a RULE
 379 --      (c) Template Haskell splices
 380 --
 381 -- The name 'Gently' suggests that the SimplifierMode is SimplGently,
 382 -- and in fact that is so.... but the 'Gently' in simplExprGently doesn't
 383 -- enforce that; it just simplifies the expression twice
 384
 385 -- It's important that simplExprGently does eta reduction; see
 386 -- Note [Simplifying the left-hand side of a RULE] above.  The
 387 -- simplifier does indeed do eta reduction (it's in Simplify.completeLam)
 388 -- but only if -O is on.
 389
 390 simplExprGently env expr = do
 391     expr1 <- simplExpr env (occurAnalyseExpr expr)
 392     simplExpr env (occurAnalyseExpr expr1)
 393 \end{code}
 394
 395
 396 %************************************************************************
 397 %*                                                                      *
 398 \subsection{Glomming}
 399 %*                                                                      *
 400 %************************************************************************
 401
 402 \begin{code}
 403 glomBinds :: DynFlags -> [CoreBind] -> IO [CoreBind]
 404 -- Glom all binds together in one Rec, in case any
 405 -- transformations have introduced any new dependencies
 406 --
 407 -- NB: the global invariant is this:
 408 --      *** the top level bindings are never cloned, and are always unique ***
 409 --
 410 -- We sort them into dependency order, but applying transformation rules may
 411 -- make something at the top refer to something at the bottom:
 412 --      f = \x -> p (q x)
 413 --      h = \y -> 3
 414 --
 415 --      RULE:  p (q x) = h x
 416 --
 417 -- Applying this rule makes f refer to h,
 418 -- although it doesn't appear to in the source program.
 419 -- This pass lets us control where it happens.
 420 --
 421 -- NOTICE that this cannot happen for rules whose head is a locally-defined
 422 -- function.  It only happens for rules whose head is an imported function
 423 -- (p in the example above).  So, for example, the rule had been
 424 --      RULE: f (p x) = h x
 425 -- then the rule for f would be attached to f itself (in its IdInfo)
 426 -- by prepareLocalRuleBase and h would be regarded by the occurrency
 427 -- analyser as free in f.
 428
 429 glomBinds dflags binds
 430   = do { Err.showPass dflags "GlomBinds" ;
 431          let { recd_binds = [Rec (flattenBinds binds)] } ;
 432          return recd_binds }
 433         -- Not much point in printing the result...
 434         -- just consumes output bandwidth
 435 \end{code}
 436
 437
 438 %************************************************************************
 439 %*                                                                      *
 440 \subsection{The driver for the simplifier}
 441 %*                                                                      *
 442 %************************************************************************
 443
 444 \begin{code}
 445 simplifyPgm :: CoreToDo -> ModGuts -> CoreM ModGuts
 446 simplifyPgm pass guts
 447   = do { hsc_env <- getHscEnv
 448        ; us <- getUniqueSupplyM
 449        ; rb <- getRuleBase
 450        ; liftIOWithCount $
 451          simplifyPgmIO pass hsc_env us rb guts }
 452
 453 simplifyPgmIO :: CoreToDo
 454               -> HscEnv
 455               -> UniqSupply
 456               -> RuleBase
 457               -> ModGuts
 458               -> IO (SimplCount, ModGuts)  -- New bindings
 459
 460 simplifyPgmIO pass@(CoreDoSimplify mode max_iterations switches)
 461               hsc_env us hpt_rule_base
 462               guts@(ModGuts { mg_binds = binds, mg_rules = rules
 463                             , mg_fam_inst_env = fam_inst_env })
 464   = do {
 465         (termination_msg, it_count, counts_out, guts')
 466            <- do_iteration us 1 (zeroSimplCount dflags) binds rules ;
 467
 468         Err.dumpIfSet (dump_phase && dopt Opt_D_dump_simpl_stats dflags)
 469                   "Simplifier statistics for following pass"
 470                   (vcat [text termination_msg <+> text "after" <+> ppr it_count <+> text "iterations",
 471                          blankLine,
 472                          pprSimplCount counts_out]);
 473
 474         return (counts_out, guts')
 475     }
 476   where
 477     dflags       = hsc_dflags hsc_env
 478     dump_phase   = dumpSimplPhase dflags mode
 479     sw_chkr      = isAmongSimpl switches
 480     do_iteration :: UniqSupply
 481                  -> Int         -- Counts iterations
 482                  -> SimplCount  -- Logs optimisations performed
 483                  -> [CoreBind]  -- Bindings in
 484                  -> [CoreRule]  -- and orphan rules
 485                  -> IO (String, Int, SimplCount, ModGuts)
 486
 487     do_iteration us iteration_no counts binds rules
 488         -- iteration_no is the number of the iteration we are
 489         -- about to begin, with '1' for the first
 490       | iteration_no > max_iterations   -- Stop if we've run out of iterations
 491       =  WARN(debugIsOn && (max_iterations > 2),
 492                 text ("Simplifier still going after " ++
 493                                 show max_iterations ++
 494                                 " iterations; bailing out.  Size = " ++ show (coreBindsSize binds) ++ "\n" ))
 495                 -- Subtract 1 from iteration_no to get the
 496                 -- number of iterations we actually completed
 497             return ("Simplifier bailed out", iteration_no - 1, counts,
 498                     guts { mg_binds = binds, mg_rules = rules })
 499
 500       -- Try and force thunks off the binds; significantly reduces
 501       -- space usage, especially with -O.  JRS, 000620.
 502       | let sz = coreBindsSize binds in sz == sz
 503       = do {
 504                 -- Occurrence analysis
 505            let { tagged_binds = {-# SCC "OccAnal" #-} occurAnalysePgm binds rules } ;
 506            Err.dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
 507                      (pprCoreBindings tagged_binds);
 508
 509                 -- Get any new rules, and extend the rule base
 510                 -- See Note [Overall plumbing for rules] in Rules.lhs
 511                 -- We need to do this regularly, because simplification can
 512                 -- poke on IdInfo thunks, which in turn brings in new rules
 513                 -- behind the scenes.  Otherwise there's a danger we'll simply
 514                 -- miss the rules for Ids hidden inside imported inlinings
 515            eps <- hscEPS hsc_env ;
 516            let  { rule_base1 = unionRuleBase hpt_rule_base (eps_rule_base eps)
 517                 ; rule_base2 = extendRuleBaseList rule_base1 rules
 518                 ; simpl_env  = mkSimplEnv sw_chkr mode
 519                 ; simpl_binds = {-# SCC "SimplTopBinds" #-}
 520                                 simplTopBinds simpl_env tagged_binds
 521                 ; fam_envs = (eps_fam_inst_env eps, fam_inst_env) } ;
 522
 523                 -- Simplify the program
 524                 -- We do this with a *case* not a *let* because lazy pattern
 525                 -- matching bit us with bad space leak!
 526                 -- With a let, we ended up with
 527                 --   let
 528                 --      t = initSmpl ...
 529                 --      counts' = snd t
 530                 --   in
 531                 --      case t of {(_,counts') -> if counts'=0 then ... }
 532                 -- So the conditional didn't force counts', because the
 533                 -- selection got duplicated.  Sigh!
 534            case initSmpl dflags rule_base2 fam_envs us1 simpl_binds of {
 535                 (env1, counts1) -> do {
 536
 537            let  { all_counts = counts `plusSimplCount` counts1
 538                 ; binds1 = getFloats env1
 539                 ; rules1 = substRulesForImportedIds (mkCoreSubst (text "imp-rules") env1) rules
 540                 } ;
 541
 542                 -- Stop if nothing happened; don't dump output
 543            if isZeroSimplCount counts1 then
 544                 return ("Simplifier reached fixed point", iteration_no, all_counts,
 545                         guts { mg_binds = binds1, mg_rules = rules1 })
 546            else do {
 547                 -- Short out indirections
 548                 -- We do this *after* at least one run of the simplifier
 549                 -- because indirection-shorting uses the export flag on *occurrences*
 550                 -- and that isn't guaranteed to be ok until after the first run propagates
 551                 -- stuff from the binding site to its occurrences
 552                 --
 553                 -- ToDo: alas, this means that indirection-shorting does not happen at all
 554                 --       if the simplifier does nothing (not common, I know, but unsavoury)
 555            let { binds2 = {-# SCC "ZapInd" #-} shortOutIndirections binds1 } ;
 556
 557                 -- Dump the result of this iteration
 558            end_iteration dflags pass iteration_no counts1 binds2 rules1 ;
 559
 560                 -- Loop
 561            do_iteration us2 (iteration_no + 1) all_counts binds2 rules1
 562         }  } } }
 563       where
 564           (us1, us2) = splitUniqSupply us
 565
 566 -------------------
 567 end_iteration :: DynFlags -> CoreToDo -> Int
 568              -> SimplCount -> [CoreBind] -> [CoreRule] -> IO ()
 569 -- Same as endIteration but with simplifier counts
 570 end_iteration dflags pass iteration_no counts binds rules
 571   = do { dumpIfSet (dopt Opt_D_dump_simpl_iterations dflags)
 572                    pass (ptext (sLit "Simplifier counts"))
 573                    (pprSimplCount counts)
 574
 575        ; endIteration dflags pass iteration_no binds rules }
 576 \end{code}
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581                 Shorting out indirections
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 If we have this:
 586
 587         x_local = <expression>
 588         ...bindings...
 589         x_exported = x_local
 590
 591 where x_exported is exported, and x_local is not, then we replace it with this:
 592
 593         x_exported = <expression>
 594         x_local = x_exported
 595         ...bindings...
 596
 597 Without this we never get rid of the x_exported = x_local thing.  This
 598 save a gratuitous jump (from \tr{x_exported} to \tr{x_local}), and
 599 makes strictness information propagate better.  This used to happen in
 600 the final phase, but it's tidier to do it here.
 601
 602 Note [Transferring IdInfo]
 603 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 604 We want to propagage any useful IdInfo on x_local to x_exported.
 605
 606 STRICTNESS: if we have done strictness analysis, we want the strictness info on
 607 x_local to transfer to x_exported.  Hence the copyIdInfo call.
 608
 609 RULES: we want to *add* any RULES for x_local to x_exported.
 610
 611
 612 Note [Messing up the exported Id's RULES]
 613 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 614 We must be careful about discarding (obviously) or even merging the
 615 RULES on the exported Id. The example that went bad on me at one stage
 616 was this one:
 617
 618     iterate :: (a -> a) -> a -> [a]
 619         [Exported]
 620     iterate = iterateList
 621
 622     iterateFB c f x = x `c` iterateFB c f (f x)
 623     iterateList f x =  x : iterateList f (f x)
 624         [Not exported]
 625
 626     {-# RULES
 627     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 628     "iterateFB"                 iterateFB (:) = iterateList
 629      #-}
 630
 631 This got shorted out to:
 632
 633     iterateList :: (a -> a) -> a -> [a]
 634     iterateList = iterate
 635
 636     iterateFB c f x = x `c` iterateFB c f (f x)
 637     iterate f x =  x : iterate f (f x)
 638
 639     {-# RULES
 640     "iterate"   forall f x.     iterate f x = build (\c _n -> iterateFB c f x)
 641     "iterateFB"                 iterateFB (:) = iterate
 642      #-}
 643
 644 And now we get an infinite loop in the rule system
 645         iterate f x -> build (\cn -> iterateFB c f x)
 646                     -> iterateFB (:) f x
 647                     -> iterate f x
 648
 649 Old "solution":
 650         use rule switching-off pragmas to get rid
 651         of iterateList in the first place
 652
 653 But in principle the user *might* want rules that only apply to the Id
 654 he says.  And inline pragmas are similar
 655    {-# NOINLINE f #-}
 656    f = local
 657    local = <stuff>
 658 Then we do not want to get rid of the NOINLINE.
 659
 660 Hence hasShortableIdinfo.
 661
 662
 663 Note [Rules and indirection-zapping]
 664 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 665 Problem: what if x_exported has a RULE that mentions something in ...bindings...?
 666 Then the things mentioned can be out of scope!  Solution
 667  a) Make sure that in this pass the usage-info from x_exported is
 668         available for ...bindings...
 669  b) If there are any such RULES, rec-ify the entire top-level.
 670     It'll get sorted out next time round
 671
 672 Other remarks
 673 ~~~~~~~~~~~~~
 674 If more than one exported thing is equal to a local thing (i.e., the
 675 local thing really is shared), then we do one only:
 676 \begin{verbatim}
 677         x_local = ....
 678         x_exported1 = x_local
 679         x_exported2 = x_local
 680 ==>
 681         x_exported1 = ....
 682
 683         x_exported2 = x_exported1
 684 \end{verbatim}
 685
 686 We rely on prior eta reduction to simplify things like
 687 \begin{verbatim}
 688         x_exported = /\ tyvars -> x_local tyvars
 689 ==>
 690         x_exported = x_local
 691 \end{verbatim}
 692 Hence,there's a possibility of leaving unchanged something like this:
 693 \begin{verbatim}
 694         x_local = ....
 695         x_exported1 = x_local Int
 696 \end{verbatim}
 697 By the time we've thrown away the types in STG land this
 698 could be eliminated.  But I don't think it's very common
 699 and it's dangerous to do this fiddling in STG land
 700 because we might elminate a binding that's mentioned in the
 701 unfolding for something.
 702
 703 \begin{code}
 704 type IndEnv = IdEnv Id          -- Maps local_id -> exported_id
 705
 706 shortOutIndirections :: [CoreBind] -> [CoreBind]
 707 shortOutIndirections binds
 708   | isEmptyVarEnv ind_env = binds
 709   | no_need_to_flatten    = binds'                      -- See Note [Rules and indirect-zapping]
 710   | otherwise             = [Rec (flattenBinds binds')] -- for this no_need_to_flatten stuff
 711   where
 712     ind_env            = makeIndEnv binds
 713     exp_ids            = varSetElems ind_env    -- These exported Ids are the subjects
 714     exp_id_set         = mkVarSet exp_ids       -- of the indirection-elimination
 715     no_need_to_flatten = all (null . specInfoRules . idSpecialisation) exp_ids
 716     binds'             = concatMap zap binds
 717
 718     zap (NonRec bndr rhs) = [NonRec b r | (b,r) <- zapPair (bndr,rhs)]
 719     zap (Rec pairs)       = [Rec (concatMap zapPair pairs)]
 720
 721     zapPair (bndr, rhs)
 722         | bndr `elemVarSet` exp_id_set             = []
 723         | Just exp_id <- lookupVarEnv ind_env bndr = [(transferIdInfo exp_id bndr, rhs),
 724                                                       (bndr, Var exp_id)]
 725         | otherwise                                = [(bndr,rhs)]
 726
 727 makeIndEnv :: [CoreBind] -> IndEnv
 728 makeIndEnv binds
 729   = foldr add_bind emptyVarEnv binds
 730   where
 731     add_bind :: CoreBind -> IndEnv -> IndEnv
 732     add_bind (NonRec exported_id rhs) env = add_pair (exported_id, rhs) env
 733     add_bind (Rec pairs)              env = foldr add_pair env pairs
 734
 735     add_pair :: (Id,CoreExpr) -> IndEnv -> IndEnv
 736     add_pair (exported_id, Var local_id) env
 737         | shortMeOut env exported_id local_id = extendVarEnv env local_id exported_id
 738     add_pair (exported_id, rhs) env
 739         = env
 740
 741 -----------------
 742 shortMeOut ind_env exported_id local_id
 743 -- The if-then-else stuff is just so I can get a pprTrace to see
 744 -- how often I don't get shorting out becuase of IdInfo stuff
 745   = if isExportedId exported_id &&              -- Only if this is exported
 746
 747        isLocalId local_id &&                    -- Only if this one is defined in this
 748                                                 --      module, so that we *can* change its
 749                                                 --      binding to be the exported thing!
 750
 751        not (isExportedId local_id) &&           -- Only if this one is not itself exported,
 752                                                 --      since the transformation will nuke it
 753
 754        not (local_id `elemVarEnv` ind_env)      -- Only if not already substituted for
 755     then
 756         if hasShortableIdInfo exported_id
 757         then True       -- See Note [Messing up the exported Id's IdInfo]
 758         else WARN( True, ptext (sLit "Not shorting out:") <+> ppr exported_id )
 759              False
 760     else
 761         False
 762
 763 -----------------
 764 hasShortableIdInfo :: Id -> Bool
 765 -- True if there is no user-attached IdInfo on exported_id,
 766 -- so we can safely discard it
 767 -- See Note [Messing up the exported Id's IdInfo]
 768 hasShortableIdInfo id
 769   =  isEmptySpecInfo (specInfo info)
 770   && isDefaultInlinePragma (inlinePragInfo info)
 771   where
 772      info = idInfo id
 773
 774 -----------------
 775 transferIdInfo :: Id -> Id -> Id
 776 -- See Note [Transferring IdInfo]
 777 -- If we have
 778 --      lcl_id = e; exp_id = lcl_id
 779 -- and lcl_id has useful IdInfo, we don't want to discard it by going
 780 --      gbl_id = e; lcl_id = gbl_id
 781 -- Instead, transfer IdInfo from lcl_id to exp_id
 782 -- Overwriting, rather than merging, seems to work ok.
 783 transferIdInfo exported_id local_id
 784   = modifyIdInfo transfer exported_id
 785   where
 786     local_info = idInfo local_id
 787     transfer exp_info = exp_info `setStrictnessInfo` strictnessInfo local_info
 788                                  `setUnfoldingInfo`     unfoldingInfo local_info
 789                                  `setInlinePragInfo`    inlinePragInfo local_info
 790                                  `setSpecInfo`          addSpecInfo (specInfo exp_info) new_info
 791     new_info = setSpecInfoHead (idName exported_id)
 792                                (specInfo local_info)
 793         -- Remember to set the function-name field of the
 794         -- rules as we transfer them from one function to another
 795 \end{code}