compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         -- Rebuilding
   9         mkLam, mkCase, prepareAlts,
  10
  11         -- Inlining,
  12         preInlineUnconditionally, postInlineUnconditionally,
  13         activeInline, activeRule,
  14         simplEnvForGHCi, simplEnvForRules, updModeForInlineRules,
  15
  16         -- The continuation type
  17         SimplCont(..), DupFlag(..), ArgInfo(..),
  18         contIsDupable, contResultType, contIsTrivial, contArgs, dropArgs,
  19         pushArgs, countValArgs, countArgs, addArgTo,
  20         mkBoringStop, mkRhsStop, mkLazyArgStop, contIsRhsOrArg,
  21         interestingCallContext,
  22
  23         interestingArg, mkArgInfo,
  24
  25         abstractFloats
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 import SimplEnv
  31 import DynFlags
  32 import StaticFlags
  33 import CoreSyn
  34 import qualified CoreSubst
  35 import PprCore
  36 import CoreFVs
  37 import CoreUtils
  38 import CoreArity        ( etaExpand, exprEtaExpandArity )
  39 import CoreUnfold
  40 import Name
  41 import Id
  42 import Var      ( isCoVar )
  43 import Demand
  44 import SimplMonad
  45 import Type     hiding( substTy )
  46 import Coercion ( coercionKind )
  47 import TyCon
  48 import Unify    ( dataConCannotMatch )
  49 import VarSet
  50 import BasicTypes
  51 import Util
  52 import MonadUtils
  53 import Outputable
  54 import FastString
  55
  56 import Data.List
  57 \end{code}
  58
  59
  60 %************************************************************************
  61 %*                                                                      *
  62                 The SimplCont type
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 A SimplCont allows the simplifier to traverse the expression in a
  67 zipper-like fashion.  The SimplCont represents the rest of the expression,
  68 "above" the point of interest.
  69
  70 You can also think of a SimplCont as an "evaluation context", using
  71 that term in the way it is used for operational semantics. This is the
  72 way I usually think of it, For example you'll often see a syntax for
  73 evaluation context looking like
  74         C ::= []  |  C e   |  case C of alts  |  C `cast` co
  75 That's the kind of thing we are doing here, and I use that syntax in
  76 the comments.
  77
  78
  79 Key points:
  80   * A SimplCont describes a *strict* context (just like
  81     evaluation contexts do).  E.g. Just [] is not a SimplCont
  82
  83   * A SimplCont describes a context that *does not* bind
  84     any variables.  E.g. \x. [] is not a SimplCont
  85
  86 \begin{code}
  87 data SimplCont
  88   = Stop                -- An empty context, or hole, []
  89         CallCtxt        -- True <=> There is something interesting about
  90                         --          the context, and hence the inliner
  91                         --          should be a bit keener (see interestingCallContext)
  92                         -- Specifically:
  93                         --     This is an argument of a function that has RULES
  94                         --     Inlining the call might allow the rule to fire
  95
  96   | CoerceIt            -- C `cast` co
  97         OutCoercion             -- The coercion simplified
  98         SimplCont
  99
 100   | ApplyTo             -- C arg
 101         DupFlag
 102         InExpr StaticEnv                -- The argument and its static env
 103         SimplCont
 104
 105   | Select              -- case C of alts
 106         DupFlag
 107         InId [InAlt] StaticEnv  -- The case binder, alts, and subst-env
 108         SimplCont
 109
 110   -- The two strict forms have no DupFlag, because we never duplicate them
 111   | StrictBind          -- (\x* \xs. e) C
 112         InId [InBndr]           -- let x* = [] in e
 113         InExpr StaticEnv        --      is a special case
 114         SimplCont
 115
 116   | StrictArg           -- f e1 ..en C
 117         ArgInfo         -- Specifies f, e1..en, Whether f has rules, etc
 118                         --     plus strictness flags for *further* args
 119         CallCtxt        -- Whether *this* argument position is interesting
 120         SimplCont
 121
 122 data ArgInfo
 123   = ArgInfo {
 124         ai_fun   :: Id,         -- The function
 125         ai_args  :: [OutExpr],  -- ...applied to these args (which are in *reverse* order)
 126         ai_rules :: [CoreRule], -- Rules for this function
 127
 128         ai_encl :: Bool,        -- Flag saying whether this function
 129                                 -- or an enclosing one has rules (recursively)
 130                                 --      True => be keener to inline in all args
 131
 132         ai_strs :: [Bool],      -- Strictness of remaining arguments
 133                                 --   Usually infinite, but if it is finite it guarantees
 134                                 --   that the function diverges after being given
 135                                 --   that number of args
 136         ai_discs :: [Int]       -- Discounts for remaining arguments; non-zero => be keener to inline
 137                                 --   Always infinite
 138     }
 139
 140 addArgTo :: ArgInfo -> OutExpr -> ArgInfo
 141 addArgTo ai arg = ai { ai_args = arg : ai_args ai }
 142
 143 instance Outputable SimplCont where
 144   ppr (Stop interesting)             = ptext (sLit "Stop") <> brackets (ppr interesting)
 145   ppr (ApplyTo dup arg _ cont)       = ((ptext (sLit "ApplyTo") <+> ppr dup <+> pprParendExpr arg)
 146                                           {-  $$ nest 2 (pprSimplEnv se) -}) $$ ppr cont
 147   ppr (StrictBind b _ _ _ cont)      = (ptext (sLit "StrictBind") <+> ppr b) $$ ppr cont
 148   ppr (StrictArg ai _ cont)          = (ptext (sLit "StrictArg") <+> ppr (ai_fun ai)) $$ ppr cont
 149   ppr (Select dup bndr alts _ cont)  = (ptext (sLit "Select") <+> ppr dup <+> ppr bndr) $$
 150                                        (nest 4 (ppr alts)) $$ ppr cont
 151   ppr (CoerceIt co cont)             = (ptext (sLit "CoerceIt") <+> ppr co) $$ ppr cont
 152
 153 data DupFlag = OkToDup | NoDup
 154
 155 instance Outputable DupFlag where
 156   ppr OkToDup = ptext (sLit "ok")
 157   ppr NoDup   = ptext (sLit "nodup")
 158
 159
 160
 161 -------------------
 162 mkBoringStop :: SimplCont
 163 mkBoringStop = Stop BoringCtxt
 164
 165 mkRhsStop :: SimplCont  -- See Note [RHS of lets] in CoreUnfold
 166 mkRhsStop = Stop (ArgCtxt False)
 167
 168 mkLazyArgStop :: CallCtxt -> SimplCont
 169 mkLazyArgStop cci = Stop cci
 170
 171 -------------------
 172 contIsRhsOrArg :: SimplCont -> Bool
 173 contIsRhsOrArg (Stop {})       = True
 174 contIsRhsOrArg (StrictBind {}) = True
 175 contIsRhsOrArg (StrictArg {})  = True
 176 contIsRhsOrArg _               = False
 177
 178 -------------------
 179 contIsDupable :: SimplCont -> Bool
 180 contIsDupable (Stop {})                  = True
 181 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 182 contIsDupable (Select   OkToDup _ _ _ _) = True
 183 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 184 contIsDupable _                          = False
 185
 186 -------------------
 187 contIsTrivial :: SimplCont -> Bool
 188 contIsTrivial (Stop {})                   = True
 189 contIsTrivial (ApplyTo _ (Type _) _ cont) = contIsTrivial cont
 190 contIsTrivial (CoerceIt _ cont)           = contIsTrivial cont
 191 contIsTrivial _                           = False
 192
 193 -------------------
 194 contResultType :: SimplEnv -> OutType -> SimplCont -> OutType
 195 contResultType env ty cont
 196   = go cont ty
 197   where
 198     subst_ty se ty = substTy (se `setInScope` env) ty
 199
 200     go (Stop {})                      ty = ty
 201     go (CoerceIt co cont)             _  = go cont (snd (coercionKind co))
 202     go (StrictBind _ bs body se cont) _  = go cont (subst_ty se (exprType (mkLams bs body)))
 203     go (StrictArg ai _ cont)          _  = go cont (funResultTy (argInfoResultTy ai))
 204     go (Select _ _ alts se cont)      _  = go cont (subst_ty se (coreAltsType alts))
 205     go (ApplyTo _ arg se cont)        ty = go cont (apply_to_arg ty arg se)
 206
 207     apply_to_arg ty (Type ty_arg) se = applyTy ty (subst_ty se ty_arg)
 208     apply_to_arg ty _             _  = funResultTy ty
 209
 210 argInfoResultTy :: ArgInfo -> OutType
 211 argInfoResultTy (ArgInfo { ai_fun = fun, ai_args = args })
 212   = foldr (\arg fn_ty -> applyTypeToArg fn_ty arg) (idType fun) args
 213
 214 -------------------
 215 countValArgs :: SimplCont -> Int
 216 countValArgs (ApplyTo _ (Type _) _ cont) = countValArgs cont
 217 countValArgs (ApplyTo _ _        _ cont) = 1 + countValArgs cont
 218 countValArgs _                           = 0
 219
 220 countArgs :: SimplCont -> Int
 221 countArgs (ApplyTo _ _ _ cont) = 1 + countArgs cont
 222 countArgs _                    = 0
 223
 224 contArgs :: SimplCont -> ([OutExpr], SimplCont)
 225 -- Uses substitution to turn each arg into an OutExpr
 226 contArgs cont = go [] cont
 227   where
 228     go args (ApplyTo _ arg se cont) = go (substExpr se arg : args) cont
 229     go args cont                    = (reverse args, cont)
 230
 231 pushArgs :: SimplEnv -> [CoreExpr] -> SimplCont -> SimplCont
 232 pushArgs _env []         cont = cont
 233 pushArgs env  (arg:args) cont = ApplyTo NoDup arg env (pushArgs env args cont)
 234
 235 dropArgs :: Int -> SimplCont -> SimplCont
 236 dropArgs 0 cont = cont
 237 dropArgs n (ApplyTo _ _ _ cont) = dropArgs (n-1) cont
 238 dropArgs n other                = pprPanic "dropArgs" (ppr n <+> ppr other)
 239 \end{code}
 240
 241
 242 Note [Interesting call context]
 243 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 244 We want to avoid inlining an expression where there can't possibly be
 245 any gain, such as in an argument position.  Hence, if the continuation
 246 is interesting (eg. a case scrutinee, application etc.) then we
 247 inline, otherwise we don't.
 248
 249 Previously some_benefit used to return True only if the variable was
 250 applied to some value arguments.  This didn't work:
 251
 252         let x = _coerce_ (T Int) Int (I# 3) in
 253         case _coerce_ Int (T Int) x of
 254                 I# y -> ....
 255
 256 we want to inline x, but can't see that it's a constructor in a case
 257 scrutinee position, and some_benefit is False.
 258
 259 Another example:
 260
 261 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 262
 263 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 264
 265 we'd really like to inline dMonadST here, but we *don't* want to
 266 inline if the case expression is just
 267
 268         case x of y { DEFAULT -> ... }
 269
 270 since we can just eliminate this case instead (x is in WHNF).  Similar
 271 applies when x is bound to a lambda expression.  Hence
 272 contIsInteresting looks for case expressions with just a single
 273 default case.
 274
 275
 276 \begin{code}
 277 interestingCallContext :: SimplCont -> CallCtxt
 278 -- See Note [Interesting call context]
 279 interestingCallContext cont
 280   = interesting cont
 281   where
 282     interesting (Select _ bndr _ _ _)
 283         | isDeadBinder bndr = CaseCtxt
 284         | otherwise         = ArgCtxt False     -- If the binder is used, this
 285                                                 -- is like a strict let
 286                                                 -- See Note [RHS of lets] in CoreUnfold
 287
 288     interesting (ApplyTo _ arg _ cont)
 289         | isTypeArg arg = interesting cont
 290         | otherwise     = ValAppCtxt    -- Can happen if we have (f Int |> co) y
 291                                         -- If f has an INLINE prag we need to give it some
 292                                         -- motivation to inline. See Note [Cast then apply]
 293                                         -- in CoreUnfold
 294
 295     interesting (StrictArg _ cci _) = cci
 296     interesting (StrictBind {})     = BoringCtxt
 297     interesting (Stop cci)          = cci
 298     interesting (CoerceIt _ cont)   = interesting cont
 299         -- If this call is the arg of a strict function, the context
 300         -- is a bit interesting.  If we inline here, we may get useful
 301         -- evaluation information to avoid repeated evals: e.g.
 302         --      x + (y * z)
 303         -- Here the contIsInteresting makes the '*' keener to inline,
 304         -- which in turn exposes a constructor which makes the '+' inline.
 305         -- Assuming that +,* aren't small enough to inline regardless.
 306         --
 307         -- It's also very important to inline in a strict context for things
 308         -- like
 309         --              foldr k z (f x)
 310         -- Here, the context of (f x) is strict, and if f's unfolding is
 311         -- a build it's *great* to inline it here.  So we must ensure that
 312         -- the context for (f x) is not totally uninteresting.
 313
 314
 315 -------------------
 316 mkArgInfo :: Id
 317           -> [CoreRule] -- Rules for function
 318           -> Int        -- Number of value args
 319           -> SimplCont  -- Context of the call
 320           -> ArgInfo
 321
 322 mkArgInfo fun rules n_val_args call_cont
 323   | n_val_args < idArity fun            -- Note [Unsaturated functions]
 324   = ArgInfo { ai_fun = fun, ai_args = [], ai_rules = rules
 325             , ai_encl = False
 326             , ai_strs = vanilla_stricts
 327             , ai_discs = vanilla_discounts }
 328   | otherwise
 329   = ArgInfo { ai_fun = fun, ai_args = [], ai_rules = rules
 330             , ai_encl = interestingArgContext rules call_cont
 331             , ai_strs  = add_type_str (idType fun) arg_stricts
 332             , ai_discs = arg_discounts }
 333   where
 334     vanilla_discounts, arg_discounts :: [Int]
 335     vanilla_discounts = repeat 0
 336     arg_discounts = case idUnfolding fun of
 337                         CoreUnfolding {uf_guidance = UnfoldIfGoodArgs {ug_args = discounts}}
 338                               -> discounts ++ vanilla_discounts
 339                         _     -> vanilla_discounts
 340
 341     vanilla_stricts, arg_stricts :: [Bool]
 342     vanilla_stricts  = repeat False
 343
 344     arg_stricts
 345       = case splitStrictSig (idStrictness fun) of
 346           (demands, result_info)
 347                 | not (demands `lengthExceeds` n_val_args)
 348                 ->      -- Enough args, use the strictness given.
 349                         -- For bottoming functions we used to pretend that the arg
 350                         -- is lazy, so that we don't treat the arg as an
 351                         -- interesting context.  This avoids substituting
 352                         -- top-level bindings for (say) strings into
 353                         -- calls to error.  But now we are more careful about
 354                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 355                    if isBotRes result_info then
 356                         map isStrictDmd demands         -- Finite => result is bottom
 357                    else
 358                         map isStrictDmd demands ++ vanilla_stricts
 359                | otherwise
 360                -> WARN( True, text "More demands than arity" <+> ppr fun <+> ppr (idArity fun)
 361                                 <+> ppr n_val_args <+> ppr demands )
 362                    vanilla_stricts      -- Not enough args, or no strictness
 363
 364     add_type_str :: Type -> [Bool] -> [Bool]
 365     -- If the function arg types are strict, record that in the 'strictness bits'
 366     -- No need to instantiate because unboxed types (which dominate the strict
 367     -- types) can't instantiate type variables.
 368     -- add_type_str is done repeatedly (for each call); might be better
 369     -- once-for-all in the function
 370     -- But beware primops/datacons with no strictness
 371     add_type_str _ [] = []
 372     add_type_str fun_ty strs            -- Look through foralls
 373         | Just (_, fun_ty') <- splitForAllTy_maybe fun_ty       -- Includes coercions
 374         = add_type_str fun_ty' strs
 375     add_type_str fun_ty (str:strs)      -- Add strict-type info
 376         | Just (arg_ty, fun_ty') <- splitFunTy_maybe fun_ty
 377         = (str || isStrictType arg_ty) : add_type_str fun_ty' strs
 378     add_type_str _ strs
 379         = strs
 380
 381 {- Note [Unsaturated functions]
 382   ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 383 Consider (test eyeball/inline4)
 384         x = a:as
 385         y = f x
 386 where f has arity 2.  Then we do not want to inline 'x', because
 387 it'll just be floated out again.  Even if f has lots of discounts
 388 on its first argument -- it must be saturated for these to kick in
 389 -}
 390
 391 interestingArgContext :: [CoreRule] -> SimplCont -> Bool
 392 -- If the argument has form (f x y), where x,y are boring,
 393 -- and f is marked INLINE, then we don't want to inline f.
 394 -- But if the context of the argument is
 395 --      g (f x y)
 396 -- where g has rules, then we *do* want to inline f, in case it
 397 -- exposes a rule that might fire.  Similarly, if the context is
 398 --      h (g (f x x))
 399 -- where h has rules, then we do want to inline f; hence the
 400 -- call_cont argument to interestingArgContext
 401 --
 402 -- The ai-rules flag makes this happen; if it's
 403 -- set, the inliner gets just enough keener to inline f
 404 -- regardless of how boring f's arguments are, if it's marked INLINE
 405 --
 406 -- The alternative would be to *always* inline an INLINE function,
 407 -- regardless of how boring its context is; but that seems overkill
 408 -- For example, it'd mean that wrapper functions were always inlined
 409 interestingArgContext rules call_cont
 410   = notNull rules || enclosing_fn_has_rules
 411   where
 412     enclosing_fn_has_rules = go call_cont
 413
 414     go (Select {})         = False
 415     go (ApplyTo {})        = False
 416     go (StrictArg _ cci _) = interesting cci
 417     go (StrictBind {})     = False      -- ??
 418     go (CoerceIt _ c)      = go c
 419     go (Stop cci)          = interesting cci
 420
 421     interesting (ArgCtxt rules) = rules
 422     interesting _               = False
 423 \end{code}
 424
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429 \subsection{Decisions about inlining}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 \begin{code}
 434 simplEnvForGHCi :: SimplEnv
 435 simplEnvForGHCi = mkSimplEnv allOffSwitchChecker $
 436                   SimplGently { sm_rules = False, sm_inline = False }
 437    -- Do not do any inlining, in case we expose some unboxed
 438    -- tuple stuff that confuses the bytecode interpreter
 439
 440 simplEnvForRules :: SimplEnv
 441 simplEnvForRules = mkSimplEnv allOffSwitchChecker $
 442                    SimplGently { sm_rules = True, sm_inline = False }
 443
 444 updModeForInlineRules :: SimplifierMode -> SimplifierMode
 445 updModeForInlineRules mode
 446   = case mode of
 447       SimplGently {} -> mode    -- Don't modify mode if we already gentle
 448       SimplPhase  {} -> SimplGently { sm_rules = True, sm_inline = True }
 449         -- Simplify as much as possible, subject to the usual "gentle" rules
 450 \end{code}
 451
 452 Inlining is controlled partly by the SimplifierMode switch.  This has two
 453 settings
 454
 455         SimplGently     (a) Simplifying before specialiser/full laziness
 456                         (b) Simplifiying inside InlineRules
 457                         (c) Simplifying the LHS of a rule
 458                         (d) Simplifying a GHCi expression or Template
 459                                 Haskell splice
 460
 461         SimplPhase n _   Used at all other times
 462
 463 Note [Gentle mode]
 464 ~~~~~~~~~~~~~~~~~~
 465 Gentle mode has a separate boolean flag to control
 466         a) inlining (sm_inline flag)
 467         b) rules    (sm_rules  flag)
 468 A key invariant about Gentle mode is that it is treated as the EARLIEST
 469 phase.  Something is inlined if the sm_inline flag is on AND the thing
 470 is inlinable in the earliest phase.  This is important. Example
 471
 472   {-# INLINE [~1] g #-}
 473   g = ...
 474
 475   {-# INLINE f #-}
 476   f x = g (g x)
 477
 478 If we were to inline g into f's inlining, then an importing module would
 479 never be able to do
 480         f e --> g (g e) ---> RULE fires
 481 because the InlineRule for f has had g inlined into it.
 482
 483 On the other hand, it is bad not to do ANY inlining into an
 484 InlineRule, because then recursive knots in instance declarations
 485 don't get unravelled.
 486
 487 However, *sometimes* SimplGently must do no call-site inlining at all.
 488 Before full laziness we must be careful not to inline wrappers,
 489 because doing so inhibits floating
 490     e.g. ...(case f x of ...)...
 491     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 492     ==> ...(case x of I# x# -> case fw x# of ...)...
 493 and now the redex (f x) isn't floatable any more.
 494
 495 The no-inlining thing is also important for Template Haskell.  You might be
 496 compiling in one-shot mode with -O2; but when TH compiles a splice before
 497 running it, we don't want to use -O2.  Indeed, we don't want to inline
 498 anything, because the byte-code interpreter might get confused about
 499 unboxed tuples and suchlike.
 500
 501 Note [RULEs enabled in SimplGently]
 502 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 503 RULES are enabled when doing "gentle" simplification.  Two reasons:
 504
 505   * We really want the class-op cancellation to happen:
 506         op (df d1 d2) --> $cop3 d1 d2
 507     because this breaks the mutual recursion between 'op' and 'df'
 508
 509   * I wanted the RULE
 510         lift String ===> ...
 511     to work in Template Haskell when simplifying
 512     splices, so we get simpler code for literal strings
 513
 514 Note [Simplifying gently inside InlineRules]
 515 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 516 We don't do much simplification inside InlineRules (which come from
 517 INLINE pragmas).  It really is important to switch off inlinings
 518 inside such expressions.  Consider the following example
 519
 520         let f = \pq -> BIG
 521         in
 522         let g = \y -> f y y
 523             {-# INLINE g #-}
 524         in ...g...g...g...g...g...
 525
 526 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 527 and thence copied multiple times when g is inlined.
 528
 529 This function may be inlinined in other modules, so we don't want to
 530 remove (by inlining) calls to functions that have specialisations, or
 531 that may have transformation rules in an importing scope.
 532
 533 E.g.    {-# INLINE f #-}
 534         f x = ...g...
 535
 536 and suppose that g is strict *and* has specialisations.  If we inline
 537 g's wrapper, we deny f the chance of getting the specialised version
 538 of g when f is inlined at some call site (perhaps in some other
 539 module).
 540
 541 It's also important not to inline a worker back into a wrapper.
 542 A wrapper looks like
 543         wraper = inline_me (\x -> ...worker... )
 544 Normally, the inline_me prevents the worker getting inlined into
 545 the wrapper (initially, the worker's only call site!).  But,
 546 if the wrapper is sure to be called, the strictness analyser will
 547 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 548 continuation.  That's why the keep_inline predicate returns True for
 549 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 550 inline-me note under these circumstances.
 551
 552 Although we do very little simplification inside an InlineRule,
 553 the RHS is simplified as normal.  For example:
 554
 555         all xs = foldr (&&) True xs
 556         any p = all . map p  {-# INLINE any #-}
 557
 558 The RHS of 'any' will get optimised and deforested; but the InlineRule
 559 will still mention the original RHS.
 560
 561
 562 preInlineUnconditionally
 563 ~~~~~~~~~~~~~~~~~~~~~~~~
 564 @preInlineUnconditionally@ examines a bndr to see if it is used just
 565 once in a completely safe way, so that it is safe to discard the
 566 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 567 big the RHS might be.  If this is the case we don't simplify the RHS
 568 first, but just inline it un-simplified.
 569
 570 This is much better than first simplifying a perhaps-huge RHS and then
 571 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 572 better.  Consider
 573
 574         x1 = e1
 575         x2 = e2[x1]
 576         x3 = e3[x2]
 577         ...etc...
 578         xN = eN[xN-1]
 579
 580 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 581 This can happen with cascades of functions too:
 582
 583         f1 = \x1.e1
 584         f2 = \xs.e2[f1]
 585         f3 = \xs.e3[f3]
 586         ...etc...
 587
 588 THE MAIN INVARIANT is this:
 589
 590         ----  preInlineUnconditionally invariant -----
 591    IF preInlineUnconditionally chooses to inline x = <rhs>
 592    THEN doing the inlining should not change the occurrence
 593         info for the free vars of <rhs>
 594         ----------------------------------------------
 595
 596 For example, it's tempting to look at trivial binding like
 597         x = y
 598 and inline it unconditionally.  But suppose x is used many times,
 599 but this is the unique occurrence of y.  Then inlining x would change
 600 y's occurrence info, which breaks the invariant.  It matters: y
 601 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 602
 603
 604 Even RHSs labelled InlineMe aren't caught here, because there might be
 605 no benefit from inlining at the call site.
 606
 607 [Sept 01] Don't unconditionally inline a top-level thing, because that
 608 can simply make a static thing into something built dynamically.  E.g.
 609         x = (a,b)
 610         main = \s -> h x
 611
 612 [Remember that we treat \s as a one-shot lambda.]  No point in
 613 inlining x unless there is something interesting about the call site.
 614
 615 But watch out: if you aren't careful, some useful foldr/build fusion
 616 can be lost (most notably in spectral/hartel/parstof) because the
 617 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 618 deal, in fact, but losing the fusion can be.  But the right thing here
 619 seems to be to do a callSiteInline based on the fact that there is
 620 something interesting about the call site (it's strict).  Hmm.  That
 621 seems a bit fragile.
 622
 623 Conclusion: inline top level things gaily until Phase 0 (the last
 624 phase), at which point don't.
 625
 626 Note [pre/postInlineUnconditionally in gentle mode]
 627 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 628 Even in gentle mode we want to do preInlineUnconditionally.  The
 629 reason is that too little clean-up happens if you don't inline
 630 use-once things.  Also a bit of inlining is *good* for full laziness;
 631 it can expose constant sub-expressions.  Example in
 632 spectral/mandel/Mandel.hs, where the mandelset function gets a useful
 633 let-float if you inline windowToViewport
 634
 635 However, as usual for Gentle mode, do not inline things that are
 636 inactive in the intial stages.  See Note [Gentle mode].
 637
 638 \begin{code}
 639 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 640 preInlineUnconditionally env top_lvl bndr rhs
 641   | not active             = False
 642   | opt_SimplNoPreInlining = False
 643   | otherwise = case idOccInfo bndr of
 644                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 645                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 646                   _                          -> False
 647   where
 648     phase = getMode env
 649     active = case phase of
 650                    SimplGently {} -> isEarlyActive act
 651                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 652                    SimplPhase n _ -> isActive n act
 653     act = idInlineActivation bndr
 654
 655     try_once in_lam int_cxt     -- There's one textual occurrence
 656         | not in_lam = isNotTopLevel top_lvl || early_phase
 657         | otherwise  = int_cxt && canInlineInLam rhs
 658
 659 -- Be very careful before inlining inside a lambda, becuase (a) we must not
 660 -- invalidate occurrence information, and (b) we want to avoid pushing a
 661 -- single allocation (here) into multiple allocations (inside lambda).
 662 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
 663 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
 664 --      where
 665 --              is_cheap = exprIsCheap rhs
 666 --              ok = is_cheap && int_cxt
 667
 668         --      int_cxt         The context isn't totally boring
 669         -- E.g. let f = \ab.BIG in \y. map f xs
 670         --      Don't want to substitute for f, because then we allocate
 671         --      its closure every time the \y is called
 672         -- But: let f = \ab.BIG in \y. map (f y) xs
 673         --      Now we do want to substitute for f, even though it's not
 674         --      saturated, because we're going to allocate a closure for
 675         --      (f y) every time round the loop anyhow.
 676
 677         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
 678         -- so substituting rhs inside a lambda doesn't change the occ info.
 679         -- Sadly, not quite the same as exprIsHNF.
 680     canInlineInLam (Lit _)              = True
 681     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
 682     canInlineInLam (Note _ e)           = canInlineInLam e
 683     canInlineInLam _                    = False
 684
 685     early_phase = case phase of
 686                         SimplPhase 0 _ -> False
 687                         _              -> True
 688 -- If we don't have this early_phase test, consider
 689 --      x = length [1,2,3]
 690 -- The full laziness pass carefully floats all the cons cells to
 691 -- top level, and preInlineUnconditionally floats them all back in.
 692 -- Result is (a) static allocation replaced by dynamic allocation
 693 --           (b) many simplifier iterations because this tickles
 694 --               a related problem; only one inlining per pass
 695 --
 696 -- On the other hand, I have seen cases where top-level fusion is
 697 -- lost if we don't inline top level thing (e.g. string constants)
 698 -- Hence the test for phase zero (which is the phase for all the final
 699 -- simplifications).  Until phase zero we take no special notice of
 700 -- top level things, but then we become more leery about inlining
 701 -- them.
 702
 703 \end{code}
 704
 705 postInlineUnconditionally
 706 ~~~~~~~~~~~~~~~~~~~~~~~~~
 707 @postInlineUnconditionally@ decides whether to unconditionally inline
 708 a thing based on the form of its RHS; in particular if it has a
 709 trivial RHS.  If so, we can inline and discard the binding altogether.
 710
 711 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 712 only have *forward* references Hence, it's safe to discard the binding
 713
 714 NOTE: This isn't our last opportunity to inline.  We're at the binding
 715 site right now, and we'll get another opportunity when we get to the
 716 ocurrence(s)
 717
 718 Note that we do this unconditional inlining only for trival RHSs.
 719 Don't inline even WHNFs inside lambdas; doing so may simply increase
 720 allocation when the function is called. This isn't the last chance; see
 721 NOTE above.
 722
 723 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 724 Because we don't even want to inline them into the RHS of constructor
 725 arguments. See NOTE above
 726
 727 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 728 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 729 with both a and b marked NOINLINE.  But that seems incompatible with
 730 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 731 story for now.
 732
 733 \begin{code}
 734 postInlineUnconditionally
 735     :: SimplEnv -> TopLevelFlag
 736     -> OutId            -- The binder (an InId would be fine too)
 737     -> OccInfo          -- From the InId
 738     -> OutExpr
 739     -> Unfolding
 740     -> Bool
 741 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
 742   | not active             = False
 743   | isLoopBreaker occ_info = False      -- If it's a loop-breaker of any kind, don't inline
 744                                         -- because it might be referred to "earlier"
 745   | isExportedId bndr      = False
 746   | isInlineRule unfolding = False      -- Note [InlineRule and postInlineUnconditionally]
 747   | exprIsTrivial rhs      = True
 748   | otherwise
 749   = case occ_info of
 750         -- The point of examining occ_info here is that for *non-values*
 751         -- that occur outside a lambda, the call-site inliner won't have
 752         -- a chance (becuase it doesn't know that the thing
 753         -- only occurs once).   The pre-inliner won't have gotten
 754         -- it either, if the thing occurs in more than one branch
 755         -- So the main target is things like
 756         --      let x = f y in
 757         --      case v of
 758         --         True  -> case x of ...
 759         --         False -> case x of ...
 760         -- I'm not sure how important this is in practice
 761       OneOcc in_lam _one_br int_cxt     -- OneOcc => no code-duplication issue
 762         ->     smallEnoughToInline unfolding    -- Small enough to dup
 763                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
 764                         --
 765                         -- NB: Do NOT inline arbitrarily big things, even if one_br is True
 766                         -- Reason: doing so risks exponential behaviour.  We simplify a big
 767                         --         expression, inline it, and simplify it again.  But if the
 768                         --         very same thing happens in the big expression, we get
 769                         --         exponential cost!
 770                         -- PRINCIPLE: when we've already simplified an expression once,
 771                         -- make sure that we only inline it if it's reasonably small.
 772
 773            &&  ((isNotTopLevel top_lvl && not in_lam) ||
 774                         -- But outside a lambda, we want to be reasonably aggressive
 775                         -- about inlining into multiple branches of case
 776                         -- e.g. let x = <non-value>
 777                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... }
 778                         -- Inlining can be a big win if C3 is the hot-spot, even if
 779                         -- the uses in C1, C2 are not 'interesting'
 780                         -- An example that gets worse if you add int_cxt here is 'clausify'
 781
 782                 (isCheapUnfolding unfolding && int_cxt))
 783                         -- isCheap => acceptable work duplication; in_lam may be true
 784                         -- int_cxt to prevent us inlining inside a lambda without some
 785                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
 786
 787       IAmDead -> True   -- This happens; for example, the case_bndr during case of
 788                         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 789                         -- Here x isn't mentioned in the RHS, so we don't want to
 790                         -- create the (dead) let-binding  let x = (a,b) in ...
 791
 792       _ -> False
 793
 794 -- Here's an example that we don't handle well:
 795 --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
 796 --      in \y. ....case f of {...} ....
 797 -- Here f is used just once, and duplicating the case work is fine (exprIsCheap).
 798 -- But
 799 --  - We can't preInlineUnconditionally because that woud invalidate
 800 --    the occ info for b.
 801 --  - We can't postInlineUnconditionally because the RHS is big, and
 802 --    that risks exponential behaviour
 803 --  - We can't call-site inline, because the rhs is big
 804 -- Alas!
 805
 806   where
 807     active = case getMode env of
 808                    SimplGently {} -> isEarlyActive act
 809                         -- See Note [pre/postInlineUnconditionally in gentle mode]
 810                    SimplPhase n _ -> isActive n act
 811     act = idInlineActivation bndr
 812
 813 activeInline :: SimplEnv -> OutId -> Bool
 814 activeInline env id
 815   | isNonRuleLoopBreaker (idOccInfo id)   -- Things with an INLINE pragma may have
 816                                           -- an unfolding *and* be a loop breaker
 817   = False                                 -- (maybe the knot is not yet untied)
 818   | otherwise
 819   = case getMode env of
 820       SimplGently { sm_inline = inlining_on }
 821          -> inlining_on && isEarlyActive act
 822         -- See Note [Gentle mode]
 823
 824         -- NB: we used to have a second exception, for data con wrappers.
 825         -- On the grounds that we use gentle mode for rule LHSs, and
 826         -- they match better when data con wrappers are inlined.
 827         -- But that only really applies to the trivial wrappers (like (:)),
 828         -- and they are now constructed as Compulsory unfoldings (in MkId)
 829         -- so they'll happen anyway.
 830
 831       SimplPhase n _ -> isActive n act
 832   where
 833     act = idInlineActivation id
 834
 835 activeRule :: DynFlags -> SimplEnv -> Maybe (Activation -> Bool)
 836 -- Nothing => No rules at all
 837 activeRule dflags env
 838   | not (dopt Opt_EnableRewriteRules dflags)
 839   = Nothing     -- Rewriting is off
 840   | otherwise
 841   = case getMode env of
 842       SimplGently { sm_rules = rules_on }
 843         | rules_on  -> Just isEarlyActive       -- Note [RULEs enabled in SimplGently]
 844         | otherwise -> Nothing
 845       SimplPhase n _ -> Just (isActive n)
 846 \end{code}
 847
 848 Note [InlineRule and postInlineUnconditionally]
 849 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 850 Do not do postInlineUnconditionally if the Id has an InlineRule, otherwise
 851 we lose the unfolding.  Example
 852
 853      -- f has InlineRule with rhs (e |> co)
 854      --   where 'e' is big
 855      f = e |> co
 856
 857 Then there's a danger we'll optimise to
 858
 859      f' = e
 860      f = f' |> co
 861
 862 and now postInlineUnconditionally, losing the InlineRule on f.  Now f'
 863 won't inline because 'e' is too big.
 864
 865
 866 %************************************************************************
 867 %*                                                                      *
 868         Rebuilding a lambda
 869 %*                                                                      *
 870 %************************************************************************
 871
 872 \begin{code}
 873 mkLam :: SimplEnv -> [OutBndr] -> OutExpr -> SimplM OutExpr
 874 -- mkLam tries three things
 875 --      a) eta reduction, if that gives a trivial expression
 876 --      b) eta expansion [only if there are some value lambdas]
 877
 878 mkLam _b [] body
 879   = return body
 880 mkLam env bndrs body
 881   = do  { dflags <- getDOptsSmpl
 882         ; mkLam' dflags bndrs body }
 883   where
 884     mkLam' :: DynFlags -> [OutBndr] -> OutExpr -> SimplM OutExpr
 885     mkLam' dflags bndrs (Cast body co)
 886       | not (any bad bndrs)
 887         -- Note [Casts and lambdas]
 888       = do { lam <- mkLam' dflags bndrs body
 889            ; return (mkCoerce (mkPiTypes bndrs co) lam) }
 890       where
 891         co_vars  = tyVarsOfType co
 892         bad bndr = isCoVar bndr && bndr `elemVarSet` co_vars
 893
 894     mkLam' dflags bndrs body
 895       | dopt Opt_DoEtaReduction dflags,
 896         Just etad_lam <- tryEtaReduce bndrs body
 897       = do { tick (EtaReduction (head bndrs))
 898            ; return etad_lam }
 899
 900       | dopt Opt_DoLambdaEtaExpansion dflags,
 901         not (inGentleMode env),       -- In gentle mode don't eta-expansion
 902         any isRuntimeVar bndrs        -- because it can clutter up the code
 903                                       -- with casts etc that may not be removed
 904       = do { let body' = tryEtaExpansion dflags body
 905            ; return (mkLams bndrs body') }
 906
 907       | otherwise
 908       = return (mkLams bndrs body)
 909 \end{code}
 910
 911 Note [Casts and lambdas]
 912 ~~~~~~~~~~~~~~~~~~~~~~~~
 913 Consider
 914         (\x. (\y. e) `cast` g1) `cast` g2
 915 There is a danger here that the two lambdas look separated, and the
 916 full laziness pass might float an expression to between the two.
 917
 918 So this equation in mkLam' floats the g1 out, thus:
 919         (\x. e `cast` g1)  -->  (\x.e) `cast` (tx -> g1)
 920 where x:tx.
 921
 922 In general, this floats casts outside lambdas, where (I hope) they
 923 might meet and cancel with some other cast:
 924         \x. e `cast` co   ===>   (\x. e) `cast` (tx -> co)
 925         /\a. e `cast` co  ===>   (/\a. e) `cast` (/\a. co)
 926         /\g. e `cast` co  ===>   (/\g. e) `cast` (/\g. co)
 927                           (if not (g `in` co))
 928
 929 Notice that it works regardless of 'e'.  Originally it worked only
 930 if 'e' was itself a lambda, but in some cases that resulted in
 931 fruitless iteration in the simplifier.  A good example was when
 932 compiling Text.ParserCombinators.ReadPrec, where we had a definition
 933 like    (\x. Get `cast` g)
 934 where Get is a constructor with nonzero arity.  Then mkLam eta-expanded
 935 the Get, and the next iteration eta-reduced it, and then eta-expanded
 936 it again.
 937
 938 Note also the side condition for the case of coercion binders.
 939 It does not make sense to transform
 940         /\g. e `cast` g  ==>  (/\g.e) `cast` (/\g.g)
 941 because the latter is not well-kinded.
 942
 943 --      c) floating lets out through big lambdas
 944 --              [only if all tyvar lambdas, and only if this lambda
 945 --               is the RHS of a let]
 946
 947 {-      Sept 01: I'm experimenting with getting the
 948         full laziness pass to float out past big lambdsa
 949  | all isTyVar bndrs,   -- Only for big lambdas
 950    contIsRhs cont       -- Only try the rhs type-lambda floating
 951                         -- if this is indeed a right-hand side; otherwise
 952                         -- we end up floating the thing out, only for float-in
 953                         -- to float it right back in again!
 954  = do (floats, body') <- tryRhsTyLam env bndrs body
 955       return (floats, mkLams bndrs body')
 956 -}
 957
 958
 959 %************************************************************************
 960 %*                                                                      *
 961                 Eta reduction
 962 %*                                                                      *
 963 %************************************************************************
 964
 965 Note [Eta reduction conditions]
 966 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 967 We try for eta reduction here, but *only* if we get all the way to an
 968 trivial expression.  We don't want to remove extra lambdas unless we
 969 are going to avoid allocating this thing altogether.
 970
 971 There are some particularly delicate points here:
 972
 973 * Eta reduction is not valid in general:
 974         \x. bot  /=  bot
 975   This matters, partly for old-fashioned correctness reasons but,
 976   worse, getting it wrong can yield a seg fault. Consider
 977         f = \x.f x
 978         h y = case (case y of { True -> f `seq` True; False -> False }) of
 979                 True -> ...; False -> ...
 980
 981   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
 982   says f=bottom, and replaces the (f `seq` True) with just
 983   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
 984   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
 985   the definition again, so that it does not termninate after all.
 986   Result: seg-fault because the boolean case actually gets a function value.
 987   See Trac #1947.
 988
 989   So it's important to to the right thing.
 990
 991 * Note [Arity care]: we need to be careful if we just look at f's
 992   arity. Currently (Dec07), f's arity is visible in its own RHS (see
 993   Note [Arity robustness] in SimplEnv) so we must *not* trust the
 994   arity when checking that 'f' is a value.  Otherwise we will
 995   eta-reduce
 996       f = \x. f x
 997   to
 998       f = f
 999   Which might change a terminiating program (think (f `seq` e)) to a
1000   non-terminating one.  So we check for being a loop breaker first.
1001
1002   However for GlobalIds we can look at the arity; and for primops we
1003   must, since they have no unfolding.
1004
1005 * Regardless of whether 'f' is a value, we always want to
1006   reduce (/\a -> f a) to f
1007   This came up in a RULE: foldr (build (/\a -> g a))
1008   did not match           foldr (build (/\b -> ...something complex...))
1009   The type checker can insert these eta-expanded versions,
1010   with both type and dictionary lambdas; hence the slightly
1011   ad-hoc isDictId
1012
1013 * Never *reduce* arity. For example
1014       f = \xy. g x y
1015   Then if h has arity 1 we don't want to eta-reduce because then
1016   f's arity would decrease, and that is bad
1017
1018 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1019 Alas.
1020
1021 \begin{code}
1022 tryEtaReduce :: [OutBndr] -> OutExpr -> Maybe OutExpr
1023 tryEtaReduce bndrs body
1024   = go (reverse bndrs) body
1025   where
1026     incoming_arity = count isId bndrs
1027
1028     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
1029     go []       fun           | ok_fun fun   = Just fun         -- Success!
1030     go _        _                            = Nothing          -- Failure!
1031
1032         -- Note [Eta reduction conditions]
1033     ok_fun (App fun (Type ty))
1034         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1035         =  ok_fun fun
1036     ok_fun (Var fun_id)
1037         =  not (fun_id `elem` bndrs)
1038         && (ok_fun_id fun_id || all ok_lam bndrs)
1039     ok_fun _fun = False
1040
1041     ok_fun_id fun = fun_arity fun >= incoming_arity
1042
1043     fun_arity fun             -- See Note [Arity care]
1044        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1045        | otherwise = idArity fun
1046
1047     ok_lam v = isTyVar v || isDictId v
1048
1049     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
1050 \end{code}
1051
1052
1053 %************************************************************************
1054 %*                                                                      *
1055                 Eta expansion
1056 %*                                                                      *
1057 %************************************************************************
1058
1059
1060 We go for:
1061    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
1062                                  (n >= 0)
1063
1064 where (in both cases)
1065
1066         * The xi can include type variables
1067
1068         * The yi are all value variables
1069
1070         * N is a NORMAL FORM (i.e. no redexes anywhere)
1071           wanting a suitable number of extra args.
1072
1073 The biggest reason for doing this is for cases like
1074
1075         f = \x -> case x of
1076                     True  -> \y -> e1
1077                     False -> \y -> e2
1078
1079 Here we want to get the lambdas together.  A good exmaple is the nofib
1080 program fibheaps, which gets 25% more allocation if you don't do this
1081 eta-expansion.
1082
1083 We may have to sandwich some coerces between the lambdas
1084 to make the types work.   exprEtaExpandArity looks through coerces
1085 when computing arity; and etaExpand adds the coerces as necessary when
1086 actually computing the expansion.
1087
1088 \begin{code}
1089 tryEtaExpansion :: DynFlags -> OutExpr -> OutExpr
1090 -- There is at least one runtime binder in the binders
1091 tryEtaExpansion dflags body
1092   = etaExpand fun_arity body
1093   where
1094     fun_arity = exprEtaExpandArity dflags body
1095 \end{code}
1096
1097
1098 %************************************************************************
1099 %*                                                                      *
1100 \subsection{Floating lets out of big lambdas}
1101 %*                                                                      *
1102 %************************************************************************
1103
1104 Note [Floating and type abstraction]
1105 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1106 Consider this:
1107         x = /\a. C e1 e2
1108 We'd like to float this to
1109         y1 = /\a. e1
1110         y2 = /\a. e2
1111         x  = /\a. C (y1 a) (y2 a)
1112 for the usual reasons: we want to inline x rather vigorously.
1113
1114 You may think that this kind of thing is rare.  But in some programs it is
1115 common.  For example, if you do closure conversion you might get:
1116
1117         data a :-> b = forall e. (e -> a -> b) :$ e
1118
1119         f_cc :: forall a. a :-> a
1120         f_cc = /\a. (\e. id a) :$ ()
1121
1122 Now we really want to inline that f_cc thing so that the
1123 construction of the closure goes away.
1124
1125 So I have elaborated simplLazyBind to understand right-hand sides that look
1126 like
1127         /\ a1..an. body
1128
1129 and treat them specially. The real work is done in SimplUtils.abstractFloats,
1130 but there is quite a bit of plumbing in simplLazyBind as well.
1131
1132 The same transformation is good when there are lets in the body:
1133
1134         /\abc -> let(rec) x = e in b
1135    ==>
1136         let(rec) x' = /\abc -> let x = x' a b c in e
1137         in
1138         /\abc -> let x = x' a b c in b
1139
1140 This is good because it can turn things like:
1141
1142         let f = /\a -> letrec g = ... g ... in g
1143 into
1144         letrec g' = /\a -> ... g' a ...
1145         in
1146         let f = /\ a -> g' a
1147
1148 which is better.  In effect, it means that big lambdas don't impede
1149 let-floating.
1150
1151 This optimisation is CRUCIAL in eliminating the junk introduced by
1152 desugaring mutually recursive definitions.  Don't eliminate it lightly!
1153
1154 [May 1999]  If we do this transformation *regardless* then we can
1155 end up with some pretty silly stuff.  For example,
1156
1157         let
1158             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
1159         in ..
1160 becomes
1161         let y1 = /\s -> r1
1162             y2 = /\s -> r2
1163             st = /\s -> ...[y1 s/x1, y2 s/x2]
1164         in ..
1165
1166 Unless the "..." is a WHNF there is really no point in doing this.
1167 Indeed it can make things worse.  Suppose x1 is used strictly,
1168 and is of the form
1169
1170         x1* = case f y of { (a,b) -> e }
1171
1172 If we abstract this wrt the tyvar we then can't do the case inline
1173 as we would normally do.
1174
1175 That's why the whole transformation is part of the same process that
1176 floats let-bindings and constructor arguments out of RHSs.  In particular,
1177 it is guarded by the doFloatFromRhs call in simplLazyBind.
1178
1179
1180 \begin{code}
1181 abstractFloats :: [OutTyVar] -> SimplEnv -> OutExpr -> SimplM ([OutBind], OutExpr)
1182 abstractFloats main_tvs body_env body
1183   = ASSERT( notNull body_floats )
1184     do  { (subst, float_binds) <- mapAccumLM abstract empty_subst body_floats
1185         ; return (float_binds, CoreSubst.substExpr subst body) }
1186   where
1187     main_tv_set = mkVarSet main_tvs
1188     body_floats = getFloats body_env
1189     empty_subst = CoreSubst.mkEmptySubst (seInScope body_env)
1190
1191     abstract :: CoreSubst.Subst -> OutBind -> SimplM (CoreSubst.Subst, OutBind)
1192     abstract subst (NonRec id rhs)
1193       = do { (poly_id, poly_app) <- mk_poly tvs_here id
1194            ; let poly_rhs = mkLams tvs_here rhs'
1195                  subst'   = CoreSubst.extendIdSubst subst id poly_app
1196            ; return (subst', (NonRec poly_id poly_rhs)) }
1197       where
1198         rhs' = CoreSubst.substExpr subst rhs
1199         tvs_here | any isCoVar main_tvs = main_tvs      -- Note [Abstract over coercions]
1200                  | otherwise
1201                  = varSetElems (main_tv_set `intersectVarSet` exprSomeFreeVars isTyVar rhs')
1202
1203                 -- Abstract only over the type variables free in the rhs
1204                 -- wrt which the new binding is abstracted.  But the naive
1205                 -- approach of abstract wrt the tyvars free in the Id's type
1206                 -- fails. Consider:
1207                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1208                 --                    x :: a     = fst t
1209                 --                in ...
1210                 -- Here, b isn't free in x's type, but we must nevertheless
1211                 -- abstract wrt b as well, because t's type mentions b.
1212                 -- Since t is floated too, we'd end up with the bogus:
1213                 --      poly_t = /\ a b -> (e1, e2)
1214                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1215                 -- So for now we adopt the even more naive approach of
1216                 -- abstracting wrt *all* the tyvars.  We'll see if that
1217                 -- gives rise to problems.   SLPJ June 98
1218
1219     abstract subst (Rec prs)
1220        = do { (poly_ids, poly_apps) <- mapAndUnzipM (mk_poly tvs_here) ids
1221             ; let subst' = CoreSubst.extendSubstList subst (ids `zip` poly_apps)
1222                   poly_rhss = [mkLams tvs_here (CoreSubst.substExpr subst' rhs) | rhs <- rhss]
1223             ; return (subst', Rec (poly_ids `zip` poly_rhss)) }
1224        where
1225          (ids,rhss) = unzip prs
1226                 -- For a recursive group, it's a bit of a pain to work out the minimal
1227                 -- set of tyvars over which to abstract:
1228                 --      /\ a b c.  let x = ...a... in
1229                 --                 letrec { p = ...x...q...
1230                 --                          q = .....p...b... } in
1231                 --                 ...
1232                 -- Since 'x' is abstracted over 'a', the {p,q} group must be abstracted
1233                 -- over 'a' (because x is replaced by (poly_x a)) as well as 'b'.
1234                 -- Since it's a pain, we just use the whole set, which is always safe
1235                 --
1236                 -- If you ever want to be more selective, remember this bizarre case too:
1237                 --      x::a = x
1238                 -- Here, we must abstract 'x' over 'a'.
1239          tvs_here = main_tvs
1240
1241     mk_poly tvs_here var
1242       = do { uniq <- getUniqueM
1243            ; let  poly_name = setNameUnique (idName var) uniq           -- Keep same name
1244                   poly_ty   = mkForAllTys tvs_here (idType var) -- But new type of course
1245                   poly_id   = transferPolyIdInfo var tvs_here $ -- Note [transferPolyIdInfo] in Id.lhs
1246                               mkLocalId poly_name poly_ty
1247            ; return (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tvs_here)) }
1248                 -- In the olden days, it was crucial to copy the occInfo of the original var,
1249                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1250                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1251                 -- at already simplified code, so it doesn't matter
1252                 --
1253                 -- It's even right to retain single-occurrence or dead-var info:
1254                 -- Suppose we started with  /\a -> let x = E in B
1255                 -- where x occurs once in B. Then we transform to:
1256                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1257                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1258                 -- the occurrences of x' will be just the occurrences originally
1259                 -- pinned on x.
1260 \end{code}
1261
1262 Note [Abstract over coercions]
1263 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1264 If a coercion variable (g :: a ~ Int) is free in the RHS, then so is the
1265 type variable a.  Rather than sort this mess out, we simply bale out and abstract
1266 wrt all the type variables if any of them are coercion variables.
1267
1268
1269 Historical note: if you use let-bindings instead of a substitution, beware of this:
1270
1271                 -- Suppose we start with:
1272                 --
1273                 --      x = /\ a -> let g = G in E
1274                 --
1275                 -- Then we'll float to get
1276                 --
1277                 --      x = let poly_g = /\ a -> G
1278                 --          in /\ a -> let g = poly_g a in E
1279                 --
1280                 -- But now the occurrence analyser will see just one occurrence
1281                 -- of poly_g, not inside a lambda, so the simplifier will
1282                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1283                 -- (I used to think that the "don't inline lone occurrences" stuff
1284                 --  would stop this happening, but since it's the *only* occurrence,
1285                 --  PreInlineUnconditionally kicks in first!)
1286                 --
1287                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1288                 --           to appear many times.  (NB: mkInlineMe eliminates
1289                 --           such notes on trivial RHSs, so do it manually.)
1290
1291 %************************************************************************
1292 %*                                                                      *
1293                 prepareAlts
1294 %*                                                                      *
1295 %************************************************************************
1296
1297 prepareAlts tries these things:
1298
1299 1.  Eliminate alternatives that cannot match, including the
1300     DEFAULT alternative.
1301
1302 2.  If the DEFAULT alternative can match only one possible constructor,
1303     then make that constructor explicit.
1304     e.g.
1305         case e of x { DEFAULT -> rhs }
1306      ===>
1307         case e of x { (a,b) -> rhs }
1308     where the type is a single constructor type.  This gives better code
1309     when rhs also scrutinises x or e.
1310
1311 3. Returns a list of the constructors that cannot holds in the
1312    DEFAULT alternative (if there is one)
1313
1314 Here "cannot match" includes knowledge from GADTs
1315
1316 It's a good idea do do this stuff before simplifying the alternatives, to
1317 avoid simplifying alternatives we know can't happen, and to come up with
1318 the list of constructors that are handled, to put into the IdInfo of the
1319 case binder, for use when simplifying the alternatives.
1320
1321 Eliminating the default alternative in (1) isn't so obvious, but it can
1322 happen:
1323
1324 data Colour = Red | Green | Blue
1325
1326 f x = case x of
1327         Red -> ..
1328         Green -> ..
1329         DEFAULT -> h x
1330
1331 h y = case y of
1332         Blue -> ..
1333         DEFAULT -> [ case y of ... ]
1334
1335 If we inline h into f, the default case of the inlined h can't happen.
1336 If we don't notice this, we may end up filtering out *all* the cases
1337 of the inner case y, which give us nowhere to go!
1338
1339 \begin{code}
1340 prepareAlts :: OutExpr -> OutId -> [InAlt] -> SimplM ([AltCon], [InAlt])
1341 prepareAlts scrut case_bndr' alts
1342   = do  { let (alts_wo_default, maybe_deflt) = findDefault alts
1343               alt_cons = [con | (con,_,_) <- alts_wo_default]
1344               imposs_deflt_cons = nub (imposs_cons ++ alt_cons)
1345                 -- "imposs_deflt_cons" are handled
1346                 --   EITHER by the context,
1347                 --   OR by a non-DEFAULT branch in this case expression.
1348
1349         ; default_alts <- prepareDefault case_bndr' mb_tc_app
1350                                          imposs_deflt_cons maybe_deflt
1351
1352         ; let trimmed_alts = filterOut impossible_alt alts_wo_default
1353               merged_alts  = mergeAlts trimmed_alts default_alts
1354                 -- We need the mergeAlts in case the new default_alt
1355                 -- has turned into a constructor alternative.
1356                 -- The merge keeps the inner DEFAULT at the front, if there is one
1357                 -- and interleaves the alternatives in the right order
1358
1359         ; return (imposs_deflt_cons, merged_alts) }
1360   where
1361     mb_tc_app = splitTyConApp_maybe (idType case_bndr')
1362     Just (_, inst_tys) = mb_tc_app
1363
1364     imposs_cons = case scrut of
1365                     Var v -> otherCons (idUnfolding v)
1366                     _     -> []
1367
1368     impossible_alt :: CoreAlt -> Bool
1369     impossible_alt (con, _, _) | con `elem` imposs_cons = True
1370     impossible_alt (DataAlt con, _, _) = dataConCannotMatch inst_tys con
1371     impossible_alt _                   = False
1372
1373
1374 prepareDefault :: OutId         -- Case binder; need just for its type. Note that as an
1375                                 --   OutId, it has maximum information; this is important.
1376                                 --   Test simpl013 is an example
1377                -> Maybe (TyCon, [Type]) -- Type of scrutinee, decomposed
1378                -> [AltCon]      -- These cons can't happen when matching the default
1379                -> Maybe InExpr  -- Rhs
1380                -> SimplM [InAlt]        -- Still unsimplified
1381                                         -- We use a list because it's what mergeAlts expects,
1382
1383 --------- Fill in known constructor -----------
1384 prepareDefault case_bndr (Just (tycon, inst_tys)) imposs_cons (Just deflt_rhs)
1385   |     -- This branch handles the case where we are
1386         -- scrutinisng an algebraic data type
1387     isAlgTyCon tycon            -- It's a data type, tuple, or unboxed tuples.
1388   , not (isNewTyCon tycon)      -- We can have a newtype, if we are just doing an eval:
1389                                 --      case x of { DEFAULT -> e }
1390                                 -- and we don't want to fill in a default for them!
1391   , Just all_cons <- tyConDataCons_maybe tycon
1392   , not (null all_cons)         -- This is a tricky corner case.  If the data type has no constructors,
1393                                 -- which GHC allows, then the case expression will have at most a default
1394                                 -- alternative.  We don't want to eliminate that alternative, because the
1395                                 -- invariant is that there's always one alternative.  It's more convenient
1396                                 -- to leave
1397                                 --      case x of { DEFAULT -> e }
1398                                 -- as it is, rather than transform it to
1399                                 --      error "case cant match"
1400                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1401                                 -- not worth wasting code on.
1402   , let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1403         impossible con   = con `elem` imposs_data_cons || dataConCannotMatch inst_tys con
1404   = case filterOut impossible all_cons of
1405         []    -> return []      -- Eliminate the default alternative
1406                                 -- altogether if it can't match
1407
1408         [con] ->        -- It matches exactly one constructor, so fill it in
1409                  do { tick (FillInCaseDefault case_bndr)
1410                     ; us <- getUniquesM
1411                     ; let (ex_tvs, co_tvs, arg_ids) =
1412                               dataConRepInstPat us con inst_tys
1413                     ; return [(DataAlt con, ex_tvs ++ co_tvs ++ arg_ids, deflt_rhs)] }
1414
1415         _ -> return [(DEFAULT, [], deflt_rhs)]
1416
1417   | debugIsOn, isAlgTyCon tycon, not (isOpenTyCon tycon), null (tyConDataCons tycon)
1418         -- Check for no data constructors
1419         -- This can legitimately happen for type families, so don't report that
1420   = pprTrace "prepareDefault" (ppr case_bndr <+> ppr tycon)
1421         $ return [(DEFAULT, [], deflt_rhs)]
1422
1423 --------- Catch-all cases -----------
1424 prepareDefault _case_bndr _bndr_ty _imposs_cons (Just deflt_rhs)
1425   = return [(DEFAULT, [], deflt_rhs)]
1426
1427 prepareDefault _case_bndr _bndr_ty _imposs_cons Nothing
1428   = return []   -- No default branch
1429 \end{code}
1430
1431
1432
1433 %************************************************************************
1434 %*                                                                      *
1435                 mkCase
1436 %*                                                                      *
1437 %************************************************************************
1438
1439 mkCase tries these things
1440
1441 1.  Merge Nested Cases
1442
1443        case e of b {             ==>   case e of b {
1444          p1 -> rhs1                      p1 -> rhs1
1445          ...                             ...
1446          pm -> rhsm                      pm -> rhsm
1447          _  -> case b of b' {            pn -> let b'=b in rhsn
1448                      pn -> rhsn          ...
1449                      ...                 po -> let b'=b in rhso
1450                      po -> rhso          _  -> let b'=b in rhsd
1451                      _  -> rhsd
1452        }
1453
1454     which merges two cases in one case when -- the default alternative of
1455     the outer case scrutises the same variable as the outer case. This
1456     transformation is called Case Merging.  It avoids that the same
1457     variable is scrutinised multiple times.
1458
1459 2.  Eliminate Identity Case
1460
1461         case e of               ===> e
1462                 True  -> True;
1463                 False -> False
1464
1465     and similar friends.
1466
1467 3.  Merge identical alternatives.
1468     If several alternatives are identical, merge them into
1469     a single DEFAULT alternative.  I've occasionally seen this
1470     making a big difference:
1471
1472         case e of               =====>     case e of
1473           C _ -> f x                         D v -> ....v....
1474           D v -> ....v....                   DEFAULT -> f x
1475           DEFAULT -> f x
1476
1477    The point is that we merge common RHSs, at least for the DEFAULT case.
1478    [One could do something more elaborate but I've never seen it needed.]
1479    To avoid an expensive test, we just merge branches equal to the *first*
1480    alternative; this picks up the common cases
1481         a) all branches equal
1482         b) some branches equal to the DEFAULT (which occurs first)
1483
1484 The case where Merge Identical Alternatives transformation showed up
1485 was like this (base/Foreign/C/Err/Error.lhs):
1486
1487         x | p `is` 1 -> e1
1488           | p `is` 2 -> e2
1489         ...etc...
1490
1491 where @is@ was something like
1492
1493         p `is` n = p /= (-1) && p == n
1494
1495 This gave rise to a horrible sequence of cases
1496
1497         case p of
1498           (-1) -> $j p
1499           1    -> e1
1500           DEFAULT -> $j p
1501
1502 and similarly in cascade for all the join points!
1503
1504
1505 \begin{code}
1506 mkCase, mkCase1, mkCase2
1507    :: DynFlags
1508    -> OutExpr -> OutId
1509    -> [OutAlt]          -- Alternatives in standard (increasing) order
1510    -> SimplM OutExpr
1511
1512 --------------------------------------------------
1513 --      1. Merge Nested Cases
1514 --------------------------------------------------
1515
1516 mkCase dflags scrut outer_bndr ((DEFAULT, _, deflt_rhs) : outer_alts)
1517   | dopt Opt_CaseMerge dflags
1518   , Case (Var inner_scrut_var) inner_bndr _ inner_alts <- deflt_rhs
1519   , inner_scrut_var == outer_bndr
1520   = do  { tick (CaseMerge outer_bndr)
1521
1522         ; let wrap_alt (con, args, rhs) = ASSERT( outer_bndr `notElem` args )
1523                                           (con, args, wrap_rhs rhs)
1524                 -- Simplifier's no-shadowing invariant should ensure
1525                 -- that outer_bndr is not shadowed by the inner patterns
1526               wrap_rhs rhs = Let (NonRec inner_bndr (Var outer_bndr)) rhs
1527                 -- The let is OK even for unboxed binders,
1528
1529               wrapped_alts | isDeadBinder inner_bndr = inner_alts
1530                            | otherwise               = map wrap_alt inner_alts
1531
1532               merged_alts = mergeAlts outer_alts wrapped_alts
1533                 -- NB: mergeAlts gives priority to the left
1534                 --      case x of
1535                 --        A -> e1
1536                 --        DEFAULT -> case x of
1537                 --                      A -> e2
1538                 --                      B -> e3
1539                 -- When we merge, we must ensure that e1 takes
1540                 -- precedence over e2 as the value for A!
1541
1542         ; mkCase1 dflags scrut outer_bndr merged_alts
1543         }
1544         -- Warning: don't call mkCase recursively!
1545         -- Firstly, there's no point, because inner alts have already had
1546         -- mkCase applied to them, so they won't have a case in their default
1547         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1548         -- in munge_rhs may put a case into the DEFAULT branch!
1549
1550 mkCase dflags scrut bndr alts = mkCase1 dflags scrut bndr alts
1551
1552 --------------------------------------------------
1553 --      2. Eliminate Identity Case
1554 --------------------------------------------------
1555
1556 mkCase1 _dflags scrut case_bndr alts    -- Identity case
1557   | all identity_alt alts
1558   = do { tick (CaseIdentity case_bndr)
1559        ; return (re_cast scrut) }
1560   where
1561     identity_alt (con, args, rhs) = check_eq con args (de_cast rhs)
1562
1563     check_eq DEFAULT       _    (Var v)   = v == case_bndr
1564     check_eq (LitAlt lit') _    (Lit lit) = lit == lit'
1565     check_eq (DataAlt con) args rhs       = rhs `cheapEqExpr` mkConApp con (arg_tys ++ varsToCoreExprs args)
1566                                          || rhs `cheapEqExpr` Var case_bndr
1567     check_eq _ _ _ = False
1568
1569     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1570
1571         -- We've seen this:
1572         --      case e of x { _ -> x `cast` c }
1573         -- And we definitely want to eliminate this case, to give
1574         --      e `cast` c
1575         -- So we throw away the cast from the RHS, and reconstruct
1576         -- it at the other end.  All the RHS casts must be the same
1577         -- if (all identity_alt alts) holds.
1578         --
1579         -- Don't worry about nested casts, because the simplifier combines them
1580     de_cast (Cast e _) = e
1581     de_cast e          = e
1582
1583     re_cast scrut = case head alts of
1584                         (_,_,Cast _ co) -> Cast scrut co
1585                         _               -> scrut
1586
1587 --------------------------------------------------
1588 --      3. Merge Identical Alternatives
1589 --------------------------------------------------
1590 mkCase1 dflags scrut case_bndr ((_con1,bndrs1,rhs1) : con_alts)
1591   | all isDeadBinder bndrs1                     -- Remember the default
1592   , length filtered_alts < length con_alts      -- alternative comes first
1593         -- Also Note [Dead binders]
1594   = do  { tick (AltMerge case_bndr)
1595         ; mkCase2 dflags scrut case_bndr alts' }
1596   where
1597     alts' = (DEFAULT, [], rhs1) : filtered_alts
1598     filtered_alts         = filter keep con_alts
1599     keep (_con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1600
1601 mkCase1 dflags scrut bndr alts = mkCase2 dflags scrut bndr alts
1602
1603 --------------------------------------------------
1604 --      Catch-all
1605 --------------------------------------------------
1606 mkCase2 _dflags scrut bndr alts
1607   = return (Case scrut bndr (coreAltsType alts) alts)
1608 \end{code}
1609
1610 Note [Dead binders]
1611 ~~~~~~~~~~~~~~~~~~~~
1612 Note that dead-ness is maintained by the simplifier, so that it is
1613 accurate after simplification as well as before.
1614
1615
1616 Note [Cascading case merge]
1617 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1618 Case merging should cascade in one sweep, because it
1619 happens bottom-up
1620
1621       case e of a {
1622         DEFAULT -> case a of b
1623                       DEFAULT -> case b of c {
1624                                      DEFAULT -> e
1625                                      A -> ea
1626                       B -> eb
1627         C -> ec
1628 ==>
1629       case e of a {
1630         DEFAULT -> case a of b
1631                       DEFAULT -> let c = b in e
1632                       A -> let c = b in ea
1633                       B -> eb
1634         C -> ec
1635 ==>
1636       case e of a {
1637         DEFAULT -> let b = a in let c = b in e
1638         A -> let b = a in let c = b in ea
1639         B -> let b = a in eb
1640         C -> ec
1641
1642
1643 However here's a tricky case that we still don't catch, and I don't
1644 see how to catch it in one pass:
1645
1646   case x of c1 { I# a1 ->
1647   case a1 of c2 ->
1648     0 -> ...
1649     DEFAULT -> case x of c3 { I# a2 ->
1650                case a2 of ...
1651
1652 After occurrence analysis (and its binder-swap) we get this
1653
1654   case x of c1 { I# a1 ->
1655   let x = c1 in         -- Binder-swap addition
1656   case a1 of c2 ->
1657     0 -> ...
1658     DEFAULT -> case x of c3 { I# a2 ->
1659                case a2 of ...
1660
1661 When we simplify the inner case x, we'll see that
1662 x=c1=I# a1.  So we'll bind a2 to a1, and get
1663
1664   case x of c1 { I# a1 ->
1665   case a1 of c2 ->
1666     0 -> ...
1667     DEFAULT -> case a1 of ...
1668
1669 This is corect, but we can't do a case merge in this sweep
1670 because c2 /= a1.  Reason: the binding c1=I# a1 went inwards
1671 without getting changed to c1=I# c2.
1672
1673 I don't think this is worth fixing, even if I knew how. It'll
1674 all come out in the next pass anyway.
1675
1676