compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplEnv
  16 import SimplUtils       ( mkCase, mkLam,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  mkLazyArgStop, pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType,
  21                           preInlineUnconditionally, postInlineUnconditionally,
  22                           interestingArgContext, inlineMode, activeInline, activeRule
  23                         )
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           idUnfolding, setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda
  28                         )
  29 import MkId             ( eRROR_ID )
  30 import Literal          ( mkStringLit )
  31 import IdInfo           ( OccInfo(..), isLoopBreaker,
  32                           setArityInfo, zapDemandInfo,
  33                           setUnfoldingInfo,
  34                           occInfo
  35                         )
  36 import NewDemand        ( isStrictDmd )
  37 import Unify            ( coreRefineTys, dataConCanMatch )
  38 import DataCon          ( DataCon, dataConTyCon, dataConRepStrictness, isVanillaDataCon,
  39                           dataConInstArgTys, dataConTyVars )
  40 import TyCon            ( tyConArity, isAlgTyCon, isNewTyCon, tyConDataCons_maybe )
  41 import CoreSyn
  42 import PprCore          ( pprParendExpr, pprCoreExpr )
  43 import CoreUnfold       ( mkUnfolding, callSiteInline )
  44 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  45                           exprIsConApp_maybe, mkPiTypes, findAlt,
  46                           exprType, exprIsHNF, findDefault, mergeAlts,
  47                           exprOkForSpeculation, exprArity,
  48                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, applyTypeToArg
  49                         )
  50 import Rules            ( lookupRule )
  51 import BasicTypes       ( isMarkedStrict )
  52 import CostCentre       ( currentCCS )
  53 import Type             ( TvSubstEnv, isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  54                           splitFunTy_maybe, splitFunTy, coreEqType, splitTyConApp_maybe,
  55                           isTyVarTy, mkTyVarTys
  56                         )
  57 import Var              ( tyVarKind, mkTyVar )
  58 import VarEnv           ( elemVarEnv, emptyVarEnv )
  59 import TysPrim          ( realWorldStatePrimTy )
  60 import PrelInfo         ( realWorldPrimId )
  61 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  62                           RecFlag(..), isNonRec
  63                         )
  64 import Name             ( mkSysTvName )
  65 import StaticFlags      ( opt_PprStyle_Debug )
  66 import OrdList
  67 import List             ( nub )
  68 import Maybes           ( orElse )
  69 import Outputable
  70 import Util             ( notNull, filterOut )
  71 \end{code}
  72
  73
  74 The guts of the simplifier is in this module, but the driver loop for
  75 the simplifier is in SimplCore.lhs.
  76
  77
  78 -----------------------------------------
  79         *** IMPORTANT NOTE ***
  80 -----------------------------------------
  81 The simplifier used to guarantee that the output had no shadowing, but
  82 it does not do so any more.   (Actually, it never did!)  The reason is
  83 documented with simplifyArgs.
  84
  85
  86 -----------------------------------------
  87         *** IMPORTANT NOTE ***
  88 -----------------------------------------
  89 Many parts of the simplifier return a bunch of "floats" as well as an
  90 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  91
  92 All "floats" are let-binds, not case-binds, but some non-rec lets may
  93 be unlifted (with RHS ok-for-speculation).
  94
  95
  96
  97 -----------------------------------------
  98         ORGANISATION OF FUNCTIONS
  99 -----------------------------------------
 100 simplTopBinds
 101   - simplify all top-level binders
 102   - for NonRec, call simplRecOrTopPair
 103   - for Rec,    call simplRecBind
 104
 105
 106         ------------------------------
 107 simplExpr (applied lambda)      ==> simplNonRecBind
 108 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 109 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 110
 111         ------------------------------
 112 simplRecBind    [binders already simplfied]
 113   - use simplRecOrTopPair on each pair in turn
 114
 115 simplRecOrTopPair [binder already simplified]
 116   Used for: recursive bindings (top level and nested)
 117             top-level non-recursive bindings
 118   Returns:
 119   - check for PreInlineUnconditionally
 120   - simplLazyBind
 121
 122 simplNonRecBind
 123   Used for: non-top-level non-recursive bindings
 124             beta reductions (which amount to the same thing)
 125   Because it can deal with strict arts, it takes a
 126         "thing-inside" and returns an expression
 127
 128   - check for PreInlineUnconditionally
 129   - simplify binder, including its IdInfo
 130   - if strict binding
 131         simplStrictArg
 132         mkAtomicArgs
 133         completeNonRecX
 134     else
 135         simplLazyBind
 136         addFloats
 137
 138 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 139   Used for: binding case-binder and constr args in a known-constructor case
 140   - check for PreInLineUnconditionally
 141   - simplify binder
 142   - completeNonRecX
 143
 144         ------------------------------
 145 simplLazyBind:  [binder already simplified, RHS not]
 146   Used for: recursive bindings (top level and nested)
 147             top-level non-recursive bindings
 148             non-top-level, but *lazy* non-recursive bindings
 149         [must not be strict or unboxed]
 150   Returns floats + an augmented environment, not an expression
 151   - substituteIdInfo and add result to in-scope
 152         [so that rules are available in rec rhs]
 153   - simplify rhs
 154   - mkAtomicArgs
 155   - float if exposes constructor or PAP
 156   - completeLazyBind
 157
 158
 159 completeNonRecX:        [binder and rhs both simplified]
 160   - if the the thing needs case binding (unlifted and not ok-for-spec)
 161         build a Case
 162    else
 163         completeLazyBind
 164         addFloats
 165
 166 completeLazyBind:       [given a simplified RHS]
 167         [used for both rec and non-rec bindings, top level and not]
 168   - try PostInlineUnconditionally
 169   - add unfolding [this is the only place we add an unfolding]
 170   - add arity
 171
 172
 173
 174 Right hand sides and arguments
 175 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 176 In many ways we want to treat
 177         (a) the right hand side of a let(rec), and
 178         (b) a function argument
 179 in the same way.  But not always!  In particular, we would
 180 like to leave these arguments exactly as they are, so they
 181 will match a RULE more easily.
 182
 183         f (g x, h x)
 184         g (+ x)
 185
 186 It's harder to make the rule match if we ANF-ise the constructor,
 187 or eta-expand the PAP:
 188
 189         f (let { a = g x; b = h x } in (a,b))
 190         g (\y. + x y)
 191
 192 On the other hand if we see the let-defns
 193
 194         p = (g x, h x)
 195         q = + x
 196
 197 then we *do* want to ANF-ise and eta-expand, so that p and q
 198 can be safely inlined.
 199
 200 Even floating lets out is a bit dubious.  For let RHS's we float lets
 201 out if that exposes a value, so that the value can be inlined more vigorously.
 202 For example
 203
 204         r = let x = e in (x,x)
 205
 206 Here, if we float the let out we'll expose a nice constructor. We did experiments
 207 that showed this to be a generally good thing.  But it was a bad thing to float
 208 lets out unconditionally, because that meant they got allocated more often.
 209
 210 For function arguments, there's less reason to expose a constructor (it won't
 211 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 212 So for the moment we don't float lets out of function arguments either.
 213
 214
 215 Eta expansion
 216 ~~~~~~~~~~~~~~
 217 For eta expansion, we want to catch things like
 218
 219         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 220
 221 If the \x was on the RHS of a let, we'd eta expand to bring the two
 222 lambdas together.  And in general that's a good thing to do.  Perhaps
 223 we should eta expand wherever we find a (value) lambda?  Then the eta
 224 expansion at a let RHS can concentrate solely on the PAP case.
 225
 226
 227 %************************************************************************
 228 %*                                                                      *
 229 \subsection{Bindings}
 230 %*                                                                      *
 231 %************************************************************************
 232
 233 \begin{code}
 234 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 235
 236 simplTopBinds env binds
 237   =     -- Put all the top-level binders into scope at the start
 238         -- so that if a transformation rule has unexpectedly brought
 239         -- anything into scope, then we don't get a complaint about that.
 240         -- It's rather as if the top-level binders were imported.
 241     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 242     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 243     freeTick SimplifierDone                     `thenSmpl_`
 244     returnSmpl (floatBinds floats)
 245   where
 246         -- We need to track the zapped top-level binders, because
 247         -- they should have their fragile IdInfo zapped (notably occurrence info)
 248         -- That's why we run down binds and bndrs' simultaneously.
 249     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 250     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 251     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 252                                       addFloats env floats              $ \env ->
 253                                       simpl_binds env binds (drop_bs bind bs)
 254
 255     drop_bs (NonRec _ _) (_ : bs) = bs
 256     drop_bs (Rec prs)    bs       = drop (length prs) bs
 257
 258     simpl_bind env bind bs
 259       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 260         if dopt Opt_D_dump_inlinings dflags then
 261            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 262         else
 263            simpl_bind1 env bind bs
 264
 265     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 266     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 267 \end{code}
 268
 269
 270 %************************************************************************
 271 %*                                                                      *
 272 \subsection{simplNonRec}
 273 %*                                                                      *
 274 %************************************************************************
 275
 276 simplNonRecBind is used for
 277   * non-top-level non-recursive lets in expressions
 278   * beta reduction
 279
 280 It takes
 281   * An unsimplified (binder, rhs) pair
 282   * The env for the RHS.  It may not be the same as the
 283         current env because the bind might occur via (\x.E) arg
 284
 285 It uses the CPS form because the binding might be strict, in which
 286 case we might discard the continuation:
 287         let x* = error "foo" in (...x...)
 288
 289 It needs to turn unlifted bindings into a @case@.  They can arise
 290 from, say:      (\x -> e) (4# + 3#)
 291
 292 \begin{code}
 293 simplNonRecBind :: SimplEnv
 294                 -> InId                                 -- Binder
 295                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 296                 -> OutType                              -- Type of thing computed by the context
 297                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 298                 -> SimplM FloatsWithExpr
 299 #ifdef DEBUG
 300 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 301   | isTyVar bndr
 302   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 303 #endif
 304
 305 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 306   = simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 307
 308 simplNonRecBind' env bndr rhs rhs_se cont_ty thing_inside
 309   | preInlineUnconditionally env NotTopLevel bndr rhs
 310   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 311     thing_inside (extendIdSubst env bndr (mkContEx rhs_se rhs))
 312
 313   | isStrictDmd (idNewDemandInfo bndr) || isStrictType bndr_ty  -- A strict let
 314   =     -- Don't use simplBinder because that doesn't keep
 315         -- fragile occurrence info in the substitution
 316     simplNonRecBndr env bndr                                    `thenSmpl` \ (env, bndr1) ->
 317     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 318
 319         -- Now complete the binding and simplify the body
 320     let
 321         (env2,bndr2) = addLetIdInfo env1 bndr bndr1
 322     in
 323     if needsCaseBinding bndr_ty rhs1
 324     then
 325       thing_inside env2                                 `thenSmpl` \ (floats, body) ->
 326       returnSmpl (emptyFloats env2, Case rhs1 bndr2 (exprType body)
 327                                         [(DEFAULT, [], wrapFloats floats body)])
 328     else
 329       completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 330
 331   | otherwise                                                   -- Normal, lazy case
 332   =     -- Don't use simplBinder because that doesn't keep
 333         -- fragile occurrence info in the substitution
 334     simplNonRecBndr env bndr                            `thenSmpl` \ (env, bndr') ->
 335     simplLazyBind env NotTopLevel NonRecursive
 336                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 337     addFloats env floats thing_inside
 338
 339   where
 340     bndr_ty = idType bndr
 341 \end{code}
 342
 343 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 344 in knownCon.  It uses case-binding where necessary.
 345
 346 \begin{code}
 347 simplNonRecX :: SimplEnv
 348              -> InId            -- Old binder
 349              -> OutExpr         -- Simplified RHS
 350              -> (SimplEnv -> SimplM FloatsWithExpr)
 351              -> SimplM FloatsWithExpr
 352
 353 simplNonRecX env bndr new_rhs thing_inside
 354   | needsCaseBinding (idType bndr) new_rhs
 355         -- Make this test *before* the preInlineUnconditionally
 356         -- Consider     case I# (quotInt# x y) of
 357         --                I# v -> let w = J# v in ...
 358         -- If we gaily inline (quotInt# x y) for v, we end up building an
 359         -- extra thunk:
 360         --                let w = J# (quotInt# x y) in ...
 361         -- because quotInt# can fail.
 362   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 363     thing_inside env            `thenSmpl` \ (floats, body) ->
 364     let body' = wrapFloats floats body in
 365     returnSmpl (emptyFloats env, Case new_rhs bndr' (exprType body') [(DEFAULT, [], body')])
 366
 367   | preInlineUnconditionally env NotTopLevel bndr new_rhs
 368         -- This happens; for example, the case_bndr during case of
 369         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 370         -- Here x isn't mentioned in the RHS, so we don't want to
 371         -- create the (dead) let-binding  let x = (a,b) in ...
 372         --
 373         -- Similarly, single occurrences can be inlined vigourously
 374         -- e.g.  case (f x, g y) of (a,b) -> ....
 375         -- If a,b occur once we can avoid constructing the let binding for them.
 376   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
 377
 378   | otherwise
 379   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 380     completeNonRecX env False {- Non-strict; pessimistic -}
 381                     bndr bndr' new_rhs thing_inside
 382
 383 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 384   = mkAtomicArgs is_strict
 385                  True {- OK to float unlifted -}
 386                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 387
 388         -- Make the arguments atomic if necessary,
 389         -- adding suitable bindings
 390     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 391     completeLazyBind env NotTopLevel
 392                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 393     addFloats env floats thing_inside
 394 \end{code}
 395
 396
 397 %************************************************************************
 398 %*                                                                      *
 399 \subsection{Lazy bindings}
 400 %*                                                                      *
 401 %************************************************************************
 402
 403 simplRecBind is used for
 404         * recursive bindings only
 405
 406 \begin{code}
 407 simplRecBind :: SimplEnv -> TopLevelFlag
 408              -> [(InId, InExpr)] -> [OutId]
 409              -> SimplM (FloatsWith SimplEnv)
 410 simplRecBind env top_lvl pairs bndrs'
 411   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 412     returnSmpl (flattenFloats floats, env)
 413   where
 414     go env [] _ = returnSmpl (emptyFloats env, env)
 415
 416     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 417         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 418           addFloats env floats (\env -> go env pairs bndrs')
 419 \end{code}
 420
 421
 422 simplRecOrTopPair is used for
 423         * recursive bindings (whether top level or not)
 424         * top-level non-recursive bindings
 425
 426 It assumes the binder has already been simplified, but not its IdInfo.
 427
 428 \begin{code}
 429 simplRecOrTopPair :: SimplEnv
 430                   -> TopLevelFlag
 431                   -> InId -> OutId              -- Binder, both pre-and post simpl
 432                   -> InExpr                     -- The RHS and its environment
 433                   -> SimplM (FloatsWith SimplEnv)
 434
 435 simplRecOrTopPair env top_lvl bndr bndr' rhs
 436   | preInlineUnconditionally env top_lvl bndr rhs       -- Check for unconditional inline
 437   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 438     returnSmpl (emptyFloats env, extendIdSubst env bndr (mkContEx env rhs))
 439
 440   | otherwise
 441   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 442         -- May not actually be recursive, but it doesn't matter
 443 \end{code}
 444
 445
 446 simplLazyBind is used for
 447         * recursive bindings (whether top level or not)
 448         * top-level non-recursive bindings
 449         * non-top-level *lazy* non-recursive bindings
 450
 451 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 452 from SimplRecOrTopBind]
 453
 454 Nota bene:
 455     1. It assumes that the binder is *already* simplified,
 456        and is in scope, but not its IdInfo
 457
 458     2. It assumes that the binder type is lifted.
 459
 460     3. It does not check for pre-inline-unconditionallly;
 461        that should have been done already.
 462
 463 \begin{code}
 464 simplLazyBind :: SimplEnv
 465               -> TopLevelFlag -> RecFlag
 466               -> InId -> OutId          -- Binder, both pre-and post simpl
 467               -> InExpr -> SimplEnv     -- The RHS and its environment
 468               -> SimplM (FloatsWith SimplEnv)
 469
 470 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 471   = let
 472         (env1,bndr2)      = addLetIdInfo env bndr bndr1
 473         rhs_env           = setInScope rhs_se env1
 474         is_top_level      = isTopLevel top_lvl
 475         ok_float_unlifted = not is_top_level && isNonRec is_rec
 476         rhs_cont          = mkRhsStop (idType bndr2)
 477     in
 478         -- Simplify the RHS; note the mkRhsStop, which tells
 479         -- the simplifier that this is the RHS of a let.
 480     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 481
 482         -- If any of the floats can't be floated, give up now
 483         -- (The allLifted predicate says True for empty floats.)
 484     if (not ok_float_unlifted && not (allLifted floats)) then
 485         completeLazyBind env1 top_lvl bndr bndr2
 486                          (wrapFloats floats rhs1)
 487     else
 488
 489         -- ANF-ise a constructor or PAP rhs
 490     mkAtomicArgs False {- Not strict -}
 491                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 492
 493         -- If the result is a PAP, float the floats out, else wrap them
 494         -- By this time it's already been ANF-ised (if necessary)
 495     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 496         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 497
 498     else if is_top_level || exprIsTrivial rhs2 || exprIsHNF rhs2 then
 499         --      WARNING: long dodgy argument coming up
 500         --      WANTED: a better way to do this
 501         --
 502         -- We can't use "exprIsCheap" instead of exprIsHNF,
 503         -- because that causes a strictness bug.
 504         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 505         -- The case expression is 'cheap', but it's wrong to transform to
 506         --         y* = E; x = case (scc y) of {...}
 507         -- Either we must be careful not to float demanded non-values, or
 508         -- we must use exprIsHNF for the test, which ensures that the
 509         -- thing is non-strict.  So exprIsHNF => bindings are non-strict
 510         -- I think.  The WARN below tests for this.
 511         --
 512         -- We use exprIsTrivial here because we want to reveal lone variables.
 513         -- E.g.  let { x = letrec { y = E } in y } in ...
 514         -- Here we definitely want to float the y=E defn.
 515         -- exprIsHNF definitely isn't right for that.
 516         --
 517         -- Again, the floated binding can't be strict; if it's recursive it'll
 518         -- be non-strict; if it's non-recursive it'd be inlined.
 519         --
 520         -- Note [SCC-and-exprIsTrivial]
 521         -- If we have
 522         --      y = let { x* = E } in scc "foo" x
 523         -- then we do *not* want to float out the x binding, because
 524         -- it's strict!  Fortunately, exprIsTrivial replies False to
 525         -- (scc "foo" x).
 526
 527                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 528                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 529                 -- to float it out?  Answer no, but it won't matter because
 530                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 531                 -- and so there can't be any 'will be demanded' bindings in the floats.
 532                 -- Hence the warning
 533         ASSERT2( is_top_level || not (any demanded_float (floatBinds floats)),
 534                  ppr (filter demanded_float (floatBinds floats)) )
 535
 536         tick LetFloatFromLet                    `thenSmpl_` (
 537         addFloats env1 floats                   $ \ env2 ->
 538         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 539         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 540
 541     else
 542         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 543
 544 #ifdef DEBUG
 545 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 546                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 547 demanded_float (Rec _)      = False
 548 #endif
 549 \end{code}
 550
 551
 552 %************************************************************************
 553 %*                                                                      *
 554 \subsection{Completing a lazy binding}
 555 %*                                                                      *
 556 %************************************************************************
 557
 558 completeLazyBind
 559         * deals only with Ids, not TyVars
 560         * takes an already-simplified binder and RHS
 561         * is used for both recursive and non-recursive bindings
 562         * is used for both top-level and non-top-level bindings
 563
 564 It does the following:
 565   - tries discarding a dead binding
 566   - tries PostInlineUnconditionally
 567   - add unfolding [this is the only place we add an unfolding]
 568   - add arity
 569
 570 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 571         - top-level bindings (when let-to-case is impossible)
 572         - many situations where the "rhs" is known to be a WHNF
 573                 (so let-to-case is inappropriate).
 574
 575 \begin{code}
 576 completeLazyBind :: SimplEnv
 577                  -> TopLevelFlag        -- Flag stuck into unfolding
 578                  -> InId                -- Old binder
 579                  -> OutId               -- New binder
 580                  -> OutExpr             -- Simplified RHS
 581                  -> SimplM (FloatsWith SimplEnv)
 582 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 583 -- by extending the substitution (e.g. let x = y in ...)
 584 -- The new binding (if any) is returned as part of the floats.
 585 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 586 --     (as usual) use the in-scope-env from the floats
 587
 588 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 589   | postInlineUnconditionally env top_lvl new_bndr occ_info new_rhs unfolding
 590   =             -- Drop the binding
 591     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 592     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 593                 -- Use the substitution to make quite, quite sure that the substitution
 594                 -- will happen, since we are going to discard the binding
 595
 596   |  otherwise
 597   = let
 598                 -- Add arity info
 599         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 600
 601         -- Add the unfolding *only* for non-loop-breakers
 602         -- Making loop breakers not have an unfolding at all
 603         -- means that we can avoid tests in exprIsConApp, for example.
 604         -- This is important: if exprIsConApp says 'yes' for a recursive
 605         -- thing, then we can get into an infinite loop
 606
 607         -- If the unfolding is a value, the demand info may
 608         -- go pear-shaped, so we nuke it.  Example:
 609         --      let x = (a,b) in
 610         --      case x of (p,q) -> h p q x
 611         -- Here x is certainly demanded. But after we've nuked
 612         -- the case, we'll get just
 613         --      let x = (a,b) in h a b x
 614         -- and now x is not demanded (I'm assuming h is lazy)
 615         -- This really happens.  Similarly
 616         --      let f = \x -> e in ...f..f...
 617         -- After inling f at some of its call sites the original binding may
 618         -- (for example) be no longer strictly demanded.
 619         -- The solution here is a bit ad hoc...
 620         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 621         final_info | loop_breaker               = new_bndr_info
 622                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 623                    | otherwise                  = info_w_unf
 624
 625         final_id = new_bndr `setIdInfo` final_info
 626     in
 627                 -- These seqs forces the Id, and hence its IdInfo,
 628                 -- and hence any inner substitutions
 629     final_id                                    `seq`
 630     returnSmpl (unitFloat env final_id new_rhs, env)
 631
 632   where
 633     unfolding    = mkUnfolding (isTopLevel top_lvl) new_rhs
 634     loop_breaker = isLoopBreaker occ_info
 635     old_info     = idInfo old_bndr
 636     occ_info     = occInfo old_info
 637 \end{code}
 638
 639
 640
 641 %************************************************************************
 642 %*                                                                      *
 643 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 644 %*                                                                      *
 645 %************************************************************************
 646
 647 The reason for this OutExprStuff stuff is that we want to float *after*
 648 simplifying a RHS, not before.  If we do so naively we get quadratic
 649 behaviour as things float out.
 650
 651 To see why it's important to do it after, consider this (real) example:
 652
 653         let t = f x
 654         in fst t
 655 ==>
 656         let t = let a = e1
 657                     b = e2
 658                 in (a,b)
 659         in fst t
 660 ==>
 661         let a = e1
 662             b = e2
 663             t = (a,b)
 664         in
 665         a       -- Can't inline a this round, cos it appears twice
 666 ==>
 667         e1
 668
 669 Each of the ==> steps is a round of simplification.  We'd save a
 670 whole round if we float first.  This can cascade.  Consider
 671
 672         let f = g d
 673         in \x -> ...f...
 674 ==>
 675         let f = let d1 = ..d.. in \y -> e
 676         in \x -> ...f...
 677 ==>
 678         let d1 = ..d..
 679         in \x -> ...(\y ->e)...
 680
 681 Only in this second round can the \y be applied, and it
 682 might do the same again.
 683
 684
 685 \begin{code}
 686 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 687 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 688                    where
 689                      expr_ty' = substTy env (exprType expr)
 690         -- The type in the Stop continuation, expr_ty', is usually not used
 691         -- It's only needed when discarding continuations after finding
 692         -- a function that returns bottom.
 693         -- Hence the lazy substitution
 694
 695
 696 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 697         -- Simplify an expression, given a continuation
 698 simplExprC env expr cont
 699   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 700     returnSmpl (wrapFloats floats expr)
 701
 702 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 703         -- Simplify an expression, returning floated binds
 704
 705 simplExprF env (Var v)          cont = simplVar env v cont
 706 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 707 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 708 simplExprF env (Note note expr) cont = simplNote env note expr cont
 709 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg env cont)
 710
 711 simplExprF env (Type ty) cont
 712   = ASSERT( contIsRhsOrArg cont )
 713     simplType env ty                    `thenSmpl` \ ty' ->
 714     rebuild env (Type ty') cont
 715
 716 simplExprF env (Case scrut bndr case_ty alts) cont
 717   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 718   =     -- Simplify the scrutinee with a Select continuation
 719     simplExprF env scrut (Select NoDup bndr alts env cont)
 720
 721   | otherwise
 722   =     -- If case-of-case is off, simply simplify the case expression
 723         -- in a vanilla Stop context, and rebuild the result around it
 724     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 725     rebuild env case_expr' cont
 726   where
 727     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 728     case_ty'  = substTy env case_ty     -- c.f. defn of simplExpr
 729
 730 simplExprF env (Let (Rec pairs) body) cont
 731   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 732         -- NB: bndrs' don't have unfoldings or rules
 733         -- We add them as we go down
 734
 735     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 736     addFloats env floats                        $ \ env ->
 737     simplExprF env body cont
 738
 739 -- A non-recursive let is dealt with by simplNonRecBind
 740 simplExprF env (Let (NonRec bndr rhs) body) cont
 741   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 742     simplExprF env body cont
 743
 744
 745 ---------------------------------
 746 simplType :: SimplEnv -> InType -> SimplM OutType
 747         -- Kept monadic just so we can do the seqType
 748 simplType env ty
 749   = seqType new_ty   `seq`   returnSmpl new_ty
 750   where
 751     new_ty = substTy env ty
 752 \end{code}
 753
 754
 755 %************************************************************************
 756 %*                                                                      *
 757 \subsection{Lambdas}
 758 %*                                                                      *
 759 %************************************************************************
 760
 761 \begin{code}
 762 simplLam env fun cont
 763   = go env fun cont
 764   where
 765     zap_it  = mkLamBndrZapper fun (countArgs cont)
 766     cont_ty = contResultType cont
 767
 768         -- Type-beta reduction
 769     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 770       = ASSERT( isTyVar bndr )
 771         tick (BetaReduction bndr)                       `thenSmpl_`
 772         simplType (setInScope arg_se env) ty_arg        `thenSmpl` \ ty_arg' ->
 773         go (extendTvSubst env bndr ty_arg') body body_cont
 774
 775         -- Ordinary beta reduction
 776     go env (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 777       = tick (BetaReduction bndr)                               `thenSmpl_`
 778         simplNonRecBind env (zap_it bndr) arg arg_se cont_ty    $ \ env ->
 779         go env body body_cont
 780
 781         -- Not enough args, so there are real lambdas left to put in the result
 782     go env lam@(Lam _ _) cont
 783       = simplLamBndrs env bndrs         `thenSmpl` \ (env, bndrs') ->
 784         simplExpr env body              `thenSmpl` \ body' ->
 785         mkLam env bndrs' body' cont     `thenSmpl` \ (floats, new_lam) ->
 786         addFloats env floats            $ \ env ->
 787         rebuild env new_lam cont
 788       where
 789         (bndrs,body) = collectBinders lam
 790
 791         -- Exactly enough args
 792     go env expr cont = simplExprF env expr cont
 793
 794 mkLamBndrZapper :: CoreExpr     -- Function
 795                 -> Int          -- Number of args supplied, *including* type args
 796                 -> Id -> Id     -- Use this to zap the binders
 797 mkLamBndrZapper fun n_args
 798   | n_args >= n_params fun = \b -> b            -- Enough args
 799   | otherwise              = \b -> zapLamIdInfo b
 800   where
 801         -- NB: we count all the args incl type args
 802         -- so we must count all the binders (incl type lambdas)
 803     n_params (Note _ e) = n_params e
 804     n_params (Lam b e)  = 1 + n_params e
 805     n_params other      = 0::Int
 806 \end{code}
 807
 808
 809 %************************************************************************
 810 %*                                                                      *
 811 \subsection{Notes}
 812 %*                                                                      *
 813 %************************************************************************
 814
 815 \begin{code}
 816 simplNote env (Coerce to from) body cont
 817   = let
 818         addCoerce s1 k1 cont    -- Drop redundant coerces.  This can happen if a polymoprhic
 819                                 -- (coerce a b e) is instantiated with a=ty1 b=ty2 and the
 820                                 -- two are the same. This happens a lot in Happy-generated parsers
 821           | s1 `coreEqType` k1 = cont
 822
 823         addCoerce s1 k1 (CoerceIt t1 cont)
 824                 --      coerce T1 S1 (coerce S1 K1 e)
 825                 -- ==>
 826                 --      e,                      if T1=K1
 827                 --      coerce T1 K1 e,         otherwise
 828                 --
 829                 -- For example, in the initial form of a worker
 830                 -- we may find  (coerce T (coerce S (\x.e))) y
 831                 -- and we'd like it to simplify to e[y/x] in one round
 832                 -- of simplification
 833           | t1 `coreEqType` k1  = cont                  -- The coerces cancel out
 834           | otherwise           = CoerceIt t1 cont      -- They don't cancel, but
 835                                                         -- the inner one is redundant
 836
 837         addCoerce t1t2 s1s2 (ApplyTo dup arg arg_se cont)
 838           | not (isTypeArg arg),        -- This whole case only works for value args
 839                                         -- Could upgrade to have equiv thing for type apps too
 840             Just (s1, s2) <- splitFunTy_maybe s1s2
 841                 --      (coerce (T1->T2) (S1->S2) F) E
 842                 -- ===>
 843                 --      coerce T2 S2 (F (coerce S1 T1 E))
 844                 --
 845                 -- t1t2 must be a function type, T1->T2, because it's applied to something
 846                 -- but s1s2 might conceivably not be
 847                 --
 848                 -- When we build the ApplyTo we can't mix the out-types
 849                 -- with the InExpr in the argument, so we simply substitute
 850                 -- to make it all consistent.  It's a bit messy.
 851                 -- But it isn't a common case.
 852           = let
 853                 (t1,t2) = splitFunTy t1t2
 854                 new_arg = mkCoerce2 s1 t1 (substExpr arg_env arg)
 855                 arg_env = setInScope arg_se env
 856             in
 857             ApplyTo dup new_arg (zapSubstEnv env) (addCoerce t2 s2 cont)
 858
 859         addCoerce to' _ cont = CoerceIt to' cont
 860     in
 861     simplType env to            `thenSmpl` \ to' ->
 862     simplType env from          `thenSmpl` \ from' ->
 863     simplExprF env body (addCoerce to' from' cont)
 864
 865
 866 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 867 -- inlining.  All other CCCSs are mapped to currentCCS.
 868 simplNote env (SCC cc) e cont
 869   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 870     rebuild env (mkSCC cc e') cont
 871
 872 -- See notes with SimplMonad.inlineMode
 873 simplNote env InlineMe e cont
 874   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 875   =                             -- Don't inline inside an INLINE expression
 876     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 877     rebuild env (mkInlineMe e') cont
 878
 879   | otherwise   -- Dissolve the InlineMe note if there's
 880                 -- an interesting context of any kind to combine with
 881                 -- (even a type application -- anything except Stop)
 882   = simplExprF env e cont
 883
 884 simplNote env (CoreNote s) e cont
 885   = simplExpr env e    `thenSmpl` \ e' ->
 886     rebuild env (Note (CoreNote s) e') cont
 887 \end{code}
 888
 889
 890 %************************************************************************
 891 %*                                                                      *
 892 \subsection{Dealing with calls}
 893 %*                                                                      *
 894 %************************************************************************
 895
 896 \begin{code}
 897 simplVar env var cont
 898   = case substId env var of
 899         DoneEx e         -> simplExprF (zapSubstEnv env) e cont
 900         ContEx tvs ids e -> simplExprF (setSubstEnv env tvs ids) e cont
 901         DoneId var1 occ  -> completeCall (zapSubstEnv env) var1 occ cont
 902                 -- Note [zapSubstEnv]
 903                 -- The template is already simplified, so don't re-substitute.
 904                 -- This is VITAL.  Consider
 905                 --      let x = e in
 906                 --      let y = \z -> ...x... in
 907                 --      \ x -> ...y...
 908                 -- We'll clone the inner \x, adding x->x' in the id_subst
 909                 -- Then when we inline y, we must *not* replace x by x' in
 910                 -- the inlined copy!!
 911
 912 ---------------------------------------------------------
 913 --      Dealing with a call site
 914
 915 completeCall env var occ_info cont
 916   =     -- Simplify the arguments
 917     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 918     let
 919         chkr              = getSwitchChecker env
 920         (args, call_cont) = getContArgs chkr var cont
 921         fn_ty             = idType var
 922     in
 923     simplifyArgs env fn_ty (interestingArgContext var call_cont) args
 924                  (contResultType call_cont)     $ \ env args ->
 925
 926         -- Next, look for rules or specialisations that match
 927         --
 928         -- It's important to simplify the args first, because the rule-matcher
 929         -- doesn't do substitution as it goes.  We don't want to use subst_args
 930         -- (defined in the 'where') because that throws away useful occurrence info,
 931         -- and perhaps-very-important specialisations.
 932         --
 933         -- Some functions have specialisations *and* are strict; in this case,
 934         -- we don't want to inline the wrapper of the non-specialised thing; better
 935         -- to call the specialised thing instead.
 936         -- We used to use the black-listing mechanism to ensure that inlining of
 937         -- the wrapper didn't occur for things that have specialisations till a
 938         -- later phase, so but now we just try RULES first
 939         --
 940         -- You might think that we shouldn't apply rules for a loop breaker:
 941         -- doing so might give rise to an infinite loop, because a RULE is
 942         -- rather like an extra equation for the function:
 943         --      RULE:           f (g x) y = x+y
 944         --      Eqn:            f a     y = a-y
 945         --
 946         -- But it's too drastic to disable rules for loop breakers.
 947         -- Even the foldr/build rule would be disabled, because foldr
 948         -- is recursive, and hence a loop breaker:
 949         --      foldr k z (build g) = g k z
 950         -- So it's up to the programmer: rules can cause divergence
 951
 952     let
 953         in_scope   = getInScope env
 954         rules      = getRules env
 955         maybe_rule = case activeRule env of
 956                         Nothing     -> Nothing  -- No rules apply
 957                         Just act_fn -> lookupRule act_fn in_scope rules var args
 958     in
 959     case maybe_rule of {
 960         Just (rule_name, rule_rhs) ->
 961                 tick (RuleFired rule_name)                      `thenSmpl_`
 962                 (if dopt Opt_D_dump_inlinings dflags then
 963                    pprTrace "Rule fired" (vcat [
 964                         text "Rule:" <+> ftext rule_name,
 965                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 966                         text "After: " <+> pprCoreExpr rule_rhs,
 967                         text "Cont:  " <+> ppr call_cont])
 968                  else
 969                         id)             $
 970                 simplExprF env rule_rhs call_cont ;
 971
 972         Nothing ->              -- No rules
 973
 974         -- Next, look for an inlining
 975     let
 976         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 977         interesting_cont = interestingCallContext (notNull args)
 978                                                   (notNull arg_infos)
 979                                                   call_cont
 980         active_inline = activeInline env var occ_info
 981         maybe_inline  = callSiteInline dflags active_inline occ_info
 982                                        var arg_infos interesting_cont
 983     in
 984     case maybe_inline of {
 985         Just unfolding          -- There is an inlining!
 986           ->  tick (UnfoldingDone var)          `thenSmpl_`
 987                 (if dopt Opt_D_dump_inlinings dflags then
 988                    pprTrace "Inlining done" (vcat [
 989                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 990                         text "Inlined fn: " <+> ppr unfolding,
 991                         text "Cont:  " <+> ppr call_cont])
 992                  else
 993                         id)             $
 994               makeThatCall env var unfolding args call_cont
 995
 996         ;
 997         Nothing ->              -- No inlining!
 998
 999         -- Done
1000     rebuild env (mkApps (Var var) args) call_cont
1001     }}
1002
1003 makeThatCall :: SimplEnv
1004              -> Id
1005              -> InExpr          -- Inlined function rhs
1006              -> [OutExpr]       -- Arguments, already simplified
1007              -> SimplCont       -- After the call
1008              -> SimplM FloatsWithExpr
1009 -- Similar to simplLam, but this time
1010 -- the arguments are already simplified
1011 makeThatCall orig_env var fun@(Lam _ _) args cont
1012   = go orig_env fun args
1013   where
1014     zap_it = mkLamBndrZapper fun (length args)
1015
1016         -- Type-beta reduction
1017     go env (Lam bndr body) (Type ty_arg : args)
1018       = ASSERT( isTyVar bndr )
1019         tick (BetaReduction bndr)                       `thenSmpl_`
1020         go (extendTvSubst env bndr ty_arg) body args
1021
1022         -- Ordinary beta reduction
1023     go env (Lam bndr body) (arg : args)
1024       = tick (BetaReduction bndr)                       `thenSmpl_`
1025         simplNonRecX env (zap_it bndr) arg              $ \ env ->
1026         go env body args
1027
1028         -- Not enough args, so there are real lambdas left to put in the result
1029     go env fun args
1030       = simplExprF env fun (pushContArgs orig_env args cont)
1031         -- NB: orig_env; the correct environment to capture with
1032         -- the arguments.... env has been augmented with substitutions
1033         -- from the beta reductions.
1034
1035 makeThatCall env var fun args cont
1036   = simplExprF env fun (pushContArgs env args cont)
1037 \end{code}
1038
1039
1040 %************************************************************************
1041 %*                                                                      *
1042 \subsection{Arguments}
1043 %*                                                                      *
1044 %************************************************************************
1045
1046 \begin{code}
1047 ---------------------------------------------------------
1048 --      Simplifying the arguments of a call
1049
1050 simplifyArgs :: SimplEnv
1051              -> OutType                         -- Type of the function
1052              -> Bool                            -- True if the fn has RULES
1053              -> [(InExpr, SimplEnv, Bool)]      -- Details of the arguments
1054              -> OutType                         -- Type of the continuation
1055              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1056              -> SimplM FloatsWithExpr
1057
1058 -- [CPS-like because of strict arguments]
1059
1060 -- Simplify the arguments to a call.
1061 -- This part of the simplifier may break the no-shadowing invariant
1062 -- Consider
1063 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1064 -- where f is strict in its second arg
1065 -- If we simplify the innermost one first we get (...(\a -> e)...)
1066 -- Simplifying the second arg makes us float the case out, so we end up with
1067 --      case y of (a,b) -> f (...(\a -> e)...) e'
1068 -- So the output does not have the no-shadowing invariant.  However, there is
1069 -- no danger of getting name-capture, because when the first arg was simplified
1070 -- we used an in-scope set that at least mentioned all the variables free in its
1071 -- static environment, and that is enough.
1072 --
1073 -- We can't just do innermost first, or we'd end up with a dual problem:
1074 --      case x of (a,b) -> f e (...(\a -> e')...)
1075 --
1076 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1077 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1078 -- continuations.  We have to keep the right in-scope set around; AND we have
1079 -- to get the effect that finding (error "foo") in a strict arg position will
1080 -- discard the entire application and replace it with (error "foo").  Getting
1081 -- all this at once is TOO HARD!
1082
1083 simplifyArgs env fn_ty has_rules args cont_ty thing_inside
1084   = go env fn_ty args thing_inside
1085   where
1086     go env fn_ty []         thing_inside = thing_inside env []
1087     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty has_rules arg cont_ty  $ \ env arg' ->
1088                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1089                                            thing_inside env (arg':args')
1090
1091 simplifyArg env fn_ty has_rules (Type ty_arg, se, _) cont_ty thing_inside
1092   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1093     thing_inside env (Type new_ty_arg)
1094
1095 simplifyArg env fn_ty has_rules (val_arg, arg_se, is_strict) cont_ty thing_inside
1096   | is_strict
1097   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1098
1099   | otherwise   -- Lazy argument
1100                 -- DO NOT float anything outside, hence simplExprC
1101                 -- There is no benefit (unlike in a let-binding), and we'd
1102                 -- have to be very careful about bogus strictness through
1103                 -- floating a demanded let.
1104   = simplExprC (setInScope arg_se env) val_arg
1105                (mkLazyArgStop arg_ty has_rules)         `thenSmpl` \ arg1 ->
1106     thing_inside env arg1
1107   where
1108     arg_ty = funArgTy fn_ty
1109
1110
1111 simplStrictArg ::  LetRhsFlag
1112                 -> SimplEnv             -- The env of the call
1113                 -> InExpr -> SimplEnv   -- The arg plus its env
1114                 -> OutType              -- arg_ty: type of the argument
1115                 -> OutType              -- cont_ty: Type of thing computed by the context
1116                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1117                                         -- Takes an expression of type rhs_ty,
1118                                         -- returns an expression of type cont_ty
1119                                         -- The env passed to this continuation is the
1120                                         -- env of the call, plus any new in-scope variables
1121                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1122
1123 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1124   = simplExprF (setInScope arg_env call_env) arg
1125                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1126   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1127   --    to simplify the argument
1128   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1129 \end{code}
1130
1131
1132 %************************************************************************
1133 %*                                                                      *
1134 \subsection{mkAtomicArgs}
1135 %*                                                                      *
1136 %************************************************************************
1137
1138 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1139 constructor application and, if so, converts it to ANF, so that the
1140 resulting thing can be inlined more easily.  Thus
1141         x = (f a, g b)
1142 becomes
1143         t1 = f a
1144         t2 = g b
1145         x = (t1,t2)
1146
1147 There are three sorts of binding context, specified by the two
1148 boolean arguments
1149
1150 Strict
1151    OK-unlifted
1152
1153 N  N    Top-level or recursive                  Only bind args of lifted type
1154
1155 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1156                 but lazy                        unlifted-and-ok-for-speculation
1157
1158 Y  Y    Non-top-level, non-recursive,           Bind all args
1159                  and strict (demanded)
1160
1161
1162 For example, given
1163
1164         x = MkC (y div# z)
1165
1166 there is no point in transforming to
1167
1168         x = case (y div# z) of r -> MkC r
1169
1170 because the (y div# z) can't float out of the let. But if it was
1171 a *strict* let, then it would be a good thing to do.  Hence the
1172 context information.
1173
1174 \begin{code}
1175 mkAtomicArgs :: Bool    -- A strict binding
1176              -> Bool    -- OK to float unlifted args
1177              -> OutExpr
1178              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1179                         OutExpr)                  -- things that need case-binding,
1180                                                   -- if the strict-binding flag is on
1181
1182 mkAtomicArgs is_strict ok_float_unlifted rhs
1183   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1184     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1185   = go fun nilOL [] args        -- Have a go
1186
1187   | otherwise = bale_out        -- Give up
1188
1189   where
1190     bale_out = returnSmpl (nilOL, rhs)
1191
1192     go fun binds rev_args []
1193         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1194
1195     go fun binds rev_args (arg : args)
1196         | exprIsTrivial arg     -- Easy case
1197         = go fun binds (arg:rev_args) args
1198
1199         | not can_float_arg     -- Can't make this arg atomic
1200         = bale_out              -- ... so give up
1201
1202         | otherwise     -- Don't forget to do it recursively
1203                         -- E.g.  x = a:b:c:[]
1204         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1205            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1206            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1207               (Var arg_id : rev_args) args
1208         where
1209           arg_ty        = exprType arg
1210           can_float_arg =  is_strict
1211                         || not (isUnLiftedType arg_ty)
1212                         || (ok_float_unlifted && exprOkForSpeculation arg)
1213
1214
1215 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1216                -> (SimplEnv -> SimplM (FloatsWith a))
1217                -> SimplM (FloatsWith a)
1218 addAtomicBinds env []         thing_inside = thing_inside env
1219 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1220                                              addAtomicBinds env bs thing_inside
1221
1222 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1223                 -> (SimplEnv -> SimplM FloatsWithExpr)
1224                 -> SimplM FloatsWithExpr
1225 -- Same again, but this time we're in an expression context,
1226 -- and may need to do some case bindings
1227
1228 addAtomicBindsE env [] thing_inside
1229   = thing_inside env
1230 addAtomicBindsE env ((v,r):bs) thing_inside
1231   | needsCaseBinding (idType v) r
1232   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1233     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1234     (let body = wrapFloats floats expr in
1235      returnSmpl (emptyFloats env, Case r v (exprType body) [(DEFAULT,[],body)]))
1236
1237   | otherwise
1238   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1239     addAtomicBindsE env bs thing_inside
1240 \end{code}
1241
1242
1243 %************************************************************************
1244 %*                                                                      *
1245 \subsection{The main rebuilder}
1246 %*                                                                      *
1247 %************************************************************************
1248
1249 \begin{code}
1250 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1251
1252 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1253 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1254 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1255 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1256 rebuild env expr (ApplyTo _ arg se cont)      = rebuildApp  (setInScope se env) expr arg cont
1257
1258 rebuildApp env fun arg cont
1259   = simplExpr env arg   `thenSmpl` \ arg' ->
1260     rebuild env (App fun arg') cont
1261
1262 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1263 \end{code}
1264
1265
1266 %************************************************************************
1267 %*                                                                      *
1268 \subsection{Functions dealing with a case}
1269 %*                                                                      *
1270 %************************************************************************
1271
1272 Blob of helper functions for the "case-of-something-else" situation.
1273
1274 \begin{code}
1275 ---------------------------------------------------------
1276 --      Eliminate the case if possible
1277
1278 rebuildCase :: SimplEnv
1279             -> OutExpr          -- Scrutinee
1280             -> InId             -- Case binder
1281             -> [InAlt]          -- Alternatives (inceasing order)
1282             -> SimplCont
1283             -> SimplM FloatsWithExpr
1284
1285 rebuildCase env scrut case_bndr alts cont
1286   | Just (con,args) <- exprIsConApp_maybe scrut
1287         -- Works when the scrutinee is a variable with a known unfolding
1288         -- as well as when it's an explicit constructor application
1289   = knownCon env (DataAlt con) args case_bndr alts cont
1290
1291   | Lit lit <- scrut    -- No need for same treatment as constructors
1292                         -- because literals are inlined more vigorously
1293   = knownCon env (LitAlt lit) [] case_bndr alts cont
1294
1295   | otherwise
1296   =     -- Prepare the continuation;
1297         -- The new subst_env is in place
1298     prepareCaseCont env alts cont       `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1299     addFloats env floats                $ \ env ->
1300
1301     let
1302         -- The case expression is annotated with the result type of the continuation
1303         -- This may differ from the type originally on the case.  For example
1304         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1305         --         a# -> <blob>
1306         -- ===>
1307         --      let j a# = <blob>
1308         --      in case(T) a of { True -> j 1#; False -> j 0# }
1309         -- Note that the case that scrutinises a now returns a T not an Int#
1310         res_ty' = contResultType dup_cont
1311     in
1312
1313         -- Deal with case binder
1314     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr') ->
1315
1316         -- Deal with the case alternatives
1317     simplAlts alt_env scrut case_bndr' alts dup_cont    `thenSmpl` \ alts' ->
1318
1319         -- Put the case back together
1320     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1321
1322         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1323         -- The case binder *not* scope over the whole returned case-expression
1324     rebuild env case_expr nondup_cont
1325 \end{code}
1326
1327 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1328 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1329 way, there's a chance that v will now only be used once, and hence
1330 inlined.
1331
1332 Note 1
1333 ~~~~~~
1334 There is a time we *don't* want to do that, namely when
1335 -fno-case-of-case is on.  This happens in the first simplifier pass,
1336 and enhances full laziness.  Here's the bad case:
1337         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1338 If we eliminate the inner case, we trap it inside the I# v -> arm,
1339 which might prevent some full laziness happening.  I've seen this
1340 in action in spectral/cichelli/Prog.hs:
1341          [(m,n) | m <- [1..max], n <- [1..max]]
1342 Hence the check for NoCaseOfCase.
1343
1344 Note 2
1345 ~~~~~~
1346 There is another situation when we don't want to do it.  If we have
1347
1348     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1349                    ...other cases .... }
1350
1351 We'll perform the binder-swap for the outer case, giving
1352
1353     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1354                    ...other cases .... }
1355
1356 But there is no point in doing it for the inner case, because w1 can't
1357 be inlined anyway.  Furthermore, doing the case-swapping involves
1358 zapping w2's occurrence info (see paragraphs that follow), and that
1359 forces us to bind w2 when doing case merging.  So we get
1360
1361     case x of w1 { A -> let w2 = w1 in e1
1362                    B -> let w2 = w1 in e2
1363                    ...other cases .... }
1364
1365 This is plain silly in the common case where w2 is dead.
1366
1367 Even so, I can't see a good way to implement this idea.  I tried
1368 not doing the binder-swap if the scrutinee was already evaluated
1369 but that failed big-time:
1370
1371         data T = MkT !Int
1372
1373         case v of w  { MkT x ->
1374         case x of x1 { I# y1 ->
1375         case x of x2 { I# y2 -> ...
1376
1377 Notice that because MkT is strict, x is marked "evaluated".  But to
1378 eliminate the last case, we must either make sure that x (as well as
1379 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1380 the binder-swap.  So this whole note is a no-op.
1381
1382 Note 3
1383 ~~~~~~
1384 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1385 any occurrence info (eg IAmDead) in the case binder, because the
1386 case-binder now effectively occurs whenever v does.  AND we have to do
1387 the same for the pattern-bound variables!  Example:
1388
1389         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1390
1391 Here, b and p are dead.  But when we move the argment inside the first
1392 case RHS, and eliminate the second case, we get
1393
1394         case x of { (a,b) -> a b }
1395
1396 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1397 happened.
1398
1399 Indeed, this can happen anytime the case binder isn't dead:
1400         case <any> of x { (a,b) ->
1401         case x of { (p,q) -> p } }
1402 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1403 The point is that we bring into the envt a binding
1404         let x = (a,b)
1405 after the outer case, and that makes (a,b) alive.  At least we do unless
1406 the case binder is guaranteed dead.
1407
1408 \begin{code}
1409 simplCaseBinder env (Var v) case_bndr
1410   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1411
1412 -- Failed try [see Note 2 above]
1413 --     not (isEvaldUnfolding (idUnfolding v))
1414
1415   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1416     returnSmpl (modifyInScope env v case_bndr', case_bndr')
1417         -- We could extend the substitution instead, but it would be
1418         -- a hack because then the substitution wouldn't be idempotent
1419         -- any more (v is an OutId).  And this does just as well.
1420   where
1421     zap b = b `setIdOccInfo` NoOccInfo
1422
1423 simplCaseBinder env other_scrut case_bndr
1424   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1425     returnSmpl (env, case_bndr')
1426 \end{code}
1427
1428
1429 simplAlts does two things:
1430
1431 1.  Eliminate alternatives that cannot match, including the
1432     DEFAULT alternative.
1433
1434 2.  If the DEFAULT alternative can match only one possible constructor,
1435     then make that constructor explicit.
1436     e.g.
1437         case e of x { DEFAULT -> rhs }
1438      ===>
1439         case e of x { (a,b) -> rhs }
1440     where the type is a single constructor type.  This gives better code
1441     when rhs also scrutinises x or e.
1442
1443 Here "cannot match" includes knowledge from GADTs
1444
1445 It's a good idea do do this stuff before simplifying the alternatives, to
1446 avoid simplifying alternatives we know can't happen, and to come up with
1447 the list of constructors that are handled, to put into the IdInfo of the
1448 case binder, for use when simplifying the alternatives.
1449
1450 Eliminating the default alternative in (1) isn't so obvious, but it can
1451 happen:
1452
1453 data Colour = Red | Green | Blue
1454
1455 f x = case x of
1456         Red -> ..
1457         Green -> ..
1458         DEFAULT -> h x
1459
1460 h y = case y of
1461         Blue -> ..
1462         DEFAULT -> [ case y of ... ]
1463
1464 If we inline h into f, the default case of the inlined h can't happen.
1465 If we don't notice this, we may end up filtering out *all* the cases
1466 of the inner case y, which give us nowhere to go!
1467
1468
1469 \begin{code}
1470 simplAlts :: SimplEnv
1471           -> OutExpr
1472           -> OutId                      -- Case binder
1473           -> [InAlt] -> SimplCont
1474           -> SimplM [OutAlt]            -- Includes the continuation
1475
1476 simplAlts env scrut case_bndr' alts cont'
1477   = do  { mb_alts      <- mapSmpl (simplAlt env imposs_cons case_bndr' cont') alts_wo_default
1478         ; default_alts <- simplDefault env case_bndr' imposs_deflt_cons cont' maybe_deflt
1479         ; return (mergeAlts default_alts [alt' | Just (_, alt') <- mb_alts]) }
1480         -- We need the mergeAlts in case the new default_alt
1481         -- has turned into a constructor alternative.
1482   where
1483     (alts_wo_default, maybe_deflt) = findDefault alts
1484     imposs_cons = case scrut of
1485                     Var v -> otherCons (idUnfolding v)
1486                     other -> []
1487
1488         -- "imposs_deflt_cons" are handled either by the context,
1489         -- OR by a branch in this case expression. (Don't include DEFAULT!!)
1490     imposs_deflt_cons = nub (imposs_cons ++ [con | (con,_,_) <- alts_wo_default])
1491
1492 simplDefault :: SimplEnv
1493              -> OutId           -- Case binder; need just for its type. Note that as an
1494                                 --   OutId, it has maximum information; this is important.
1495                                 --   Test simpl013 is an example
1496              -> [AltCon]        -- These cons can't happen when matching the default
1497              -> SimplCont
1498              -> Maybe InExpr
1499              -> SimplM [OutAlt] -- One branch or none; we use a list because it's what
1500                                 --   mergeAlts expects
1501
1502
1503 simplDefault env case_bndr' imposs_cons cont Nothing
1504   = return []   -- No default branch
1505 simplDefault env case_bndr' imposs_cons cont (Just rhs)
1506   |     -- This branch handles the case where we are
1507         -- scrutinisng an algebraic data type
1508     Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr'),
1509     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1510     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1511                                 --      case x of { DEFAULT -> e }
1512                                 -- and we don't want to fill in a default for them!
1513     Just all_cons <- tyConDataCons_maybe tycon,
1514     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1515                                 -- which GHC allows, then the case expression will have at most a default
1516                                 -- alternative.  We don't want to eliminate that alternative, because the
1517                                 -- invariant is that there's always one alternative.  It's more convenient
1518                                 -- to leave
1519                                 --      case x of { DEFAULT -> e }
1520                                 -- as it is, rather than transform it to
1521                                 --      error "case cant match"
1522                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1523                                 -- not worth wasting code on.
1524
1525     let imposs_data_cons = [con | DataAlt con <- imposs_cons]   -- We now know it's a data type
1526         poss_data_cons   = filterOut (`elem` imposs_data_cons) all_cons
1527         gadt_imposs      | all isTyVarTy inst_tys = []
1528                          | otherwise = filter (cant_match inst_tys) poss_data_cons
1529         final_poss       = filterOut (`elem` gadt_imposs) poss_data_cons
1530
1531   = case final_poss of
1532         []    -> returnSmpl []  -- Eliminate the default alternative
1533                                 -- altogether if it can't match
1534
1535         [con] ->        -- It matches exactly one constructor, so fill it in
1536                  do { con_alt <- mkDataConAlt case_bndr' con inst_tys rhs
1537                     ; Just (_, alt') <- simplAlt env [] case_bndr' cont con_alt
1538                         -- The simplAlt must succeed with Just because we have
1539                         -- already filtered out construtors that can't match
1540                     ; return [alt'] }
1541
1542         two_or_more -> simplify_default (map DataAlt gadt_imposs ++ imposs_cons)
1543
1544   | otherwise
1545   = simplify_default imposs_cons
1546   where
1547     cant_match tys data_con = not (dataConCanMatch data_con tys)
1548
1549     simplify_default imposs_cons
1550         = do { let env' = mk_rhs_env env case_bndr' (mkOtherCon imposs_cons)
1551                 -- Record the constructors that the case-binder *can't* be.
1552              ; rhs' <- simplExprC env' rhs cont
1553              ; return [(DEFAULT, [], rhs')] }
1554
1555 mkDataConAlt :: Id -> DataCon -> [OutType] -> InExpr -> SimplM InAlt
1556 -- Make a data-constructor alternative to replace the DEFAULT case
1557 -- NB: there's something a bit bogus here, because we put OutTypes into an InAlt
1558 mkDataConAlt case_bndr con tys rhs
1559   = do  { tick (FillInCaseDefault case_bndr)
1560         ; args <- mk_args con tys
1561         ; return (DataAlt con, args, rhs) }
1562   where
1563     mk_args con inst_tys
1564       = do { (tv_bndrs, inst_tys') <- mk_tv_bndrs con inst_tys
1565            ; let arg_tys = dataConInstArgTys con inst_tys'
1566            ; arg_ids <- mapM (newId FSLIT("a")) arg_tys
1567            ; returnSmpl (tv_bndrs ++ arg_ids) }
1568
1569     mk_tv_bndrs con inst_tys
1570       | isVanillaDataCon con
1571       = return ([], inst_tys)
1572       | otherwise
1573       = do { tv_uniqs <- getUniquesSmpl
1574            ; let new_tvs    = zipWith mk tv_uniqs (dataConTyVars con)
1575                  mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1576            ; return (new_tvs, mkTyVarTys new_tvs) }
1577
1578 simplAlt :: SimplEnv
1579          -> [AltCon]    -- These constructors can't be present when
1580                         -- matching this alternative
1581          -> OutId       -- The case binder
1582          -> SimplCont
1583          -> InAlt
1584          -> SimplM (Maybe (TvSubstEnv, OutAlt))
1585
1586 -- Simplify an alternative, returning the type refinement for the
1587 -- alternative, if the alternative does any refinement at all
1588 -- Nothing => the alternative is inaccessible
1589
1590 simplAlt env imposs_cons case_bndr' cont' (con, bndrs, rhs)
1591   | con `elem` imposs_cons      -- This case can't match
1592   = return Nothing
1593
1594 simplAlt env handled_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1595         -- TURGID DUPLICATION, needed only for the simplAlt call
1596         -- in mkDupableAlt.  Clean this up when moving to FC
1597   = ASSERT( null bndrs )
1598     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1599     returnSmpl (Just (emptyVarEnv, (DEFAULT, [], rhs')))
1600   where
1601     env' = mk_rhs_env env case_bndr' (mkOtherCon handled_cons)
1602         -- Record the constructors that the case-binder *can't* be.
1603
1604 simplAlt env handled_cons case_bndr' cont' (LitAlt lit, bndrs, rhs)
1605   = ASSERT( null bndrs )
1606     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1607     returnSmpl (Just (emptyVarEnv, (LitAlt lit, [], rhs')))
1608   where
1609     env' = mk_rhs_env env case_bndr' (mkUnfolding False (Lit lit))
1610
1611 simplAlt env handled_cons case_bndr' cont' (DataAlt con, vs, rhs)
1612   | isVanillaDataCon con
1613   =     -- Deal with the pattern-bound variables
1614         -- Mark the ones that are in ! positions in the data constructor
1615         -- as certainly-evaluated.
1616         -- NB: it happens that simplBinders does *not* erase the OtherCon
1617         --     form of unfolding, so it's ok to add this info before
1618         --     doing simplBinders
1619     simplBinders env (add_evals con vs)         `thenSmpl` \ (env, vs') ->
1620
1621                 -- Bind the case-binder to (con args)
1622     let unf       = mkUnfolding False (mkConApp con con_args)
1623         inst_tys' = tyConAppArgs (idType case_bndr')
1624         con_args  = map Type inst_tys' ++ map varToCoreExpr vs'
1625         env'      = mk_rhs_env env case_bndr' unf
1626     in
1627     simplExprC env' rhs cont'   `thenSmpl` \ rhs' ->
1628     returnSmpl (Just (emptyVarEnv, (DataAlt con, vs', rhs')))
1629
1630   | otherwise   -- GADT case
1631   = let
1632         (tvs,ids) = span isTyVar vs
1633     in
1634     simplBinders env tvs                        `thenSmpl` \ (env1, tvs') ->
1635     case coreRefineTys con tvs' (idType case_bndr') of {
1636         Nothing         -- Inaccessible
1637             | opt_PprStyle_Debug        -- Hack: if debugging is on, generate an error case
1638                                         --       so we can see it
1639             ->  let rhs' = mkApps (Var eRROR_ID)
1640                                 [Type (substTy env (exprType rhs)),
1641                                  Lit (mkStringLit "Impossible alternative (GADT)")]
1642                 in
1643                 simplBinders env1 ids           `thenSmpl` \ (env2, ids') ->
1644                 returnSmpl (Just (emptyVarEnv, (DataAlt con, tvs' ++ ids', rhs')))
1645
1646             | otherwise -- Filter out the inaccessible branch
1647             -> return Nothing ;
1648
1649         Just refine@(tv_subst_env, _) ->        -- The normal case
1650
1651     let
1652         env2 = refineSimplEnv env1 refine
1653         -- Simplify the Ids in the refined environment, so their types
1654         -- reflect the refinement.  Usually this doesn't matter, but it helps
1655         -- in mkDupableAlt, when we want to float a lambda that uses these binders
1656         -- Furthermore, it means the binders contain maximal type information
1657     in
1658     simplBinders env2 (add_evals con ids)       `thenSmpl` \ (env3, ids') ->
1659     let unf        = mkUnfolding False con_app
1660         con_app    = mkConApp con con_args
1661         con_args   = map varToCoreExpr vs'      -- NB: no inst_tys'
1662         env_w_unf  = mk_rhs_env env3 case_bndr' unf
1663         vs'        = tvs' ++ ids'
1664     in
1665     simplExprC env_w_unf rhs cont'      `thenSmpl` \ rhs' ->
1666     returnSmpl (Just (tv_subst_env, (DataAlt con, vs', rhs'))) }
1667
1668   where
1669         -- add_evals records the evaluated-ness of the bound variables of
1670         -- a case pattern.  This is *important*.  Consider
1671         --      data T = T !Int !Int
1672         --
1673         --      case x of { T a b -> T (a+1) b }
1674         --
1675         -- We really must record that b is already evaluated so that we don't
1676         -- go and re-evaluate it when constructing the result.
1677     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1678
1679     cat_evals dc vs strs
1680         = go vs strs
1681         where
1682           go [] [] = []
1683           go (v:vs) strs | isTyVar v = v : go vs strs
1684           go (v:vs) (str:strs)
1685             | isMarkedStrict str = evald_v  : go vs strs
1686             | otherwise          = zapped_v : go vs strs
1687             where
1688               zapped_v = zap_occ_info v
1689               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
1690           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1691
1692         -- If the case binder is alive, then we add the unfolding
1693         --      case_bndr = C vs
1694         -- to the envt; so vs are now very much alive
1695     zap_occ_info | isDeadBinder case_bndr' = \id -> id
1696                  | otherwise               = \id -> id `setIdOccInfo` NoOccInfo
1697
1698 mk_rhs_env env case_bndr' case_bndr_unf
1699   = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` case_bndr_unf)
1700 \end{code}
1701
1702
1703 %************************************************************************
1704 %*                                                                      *
1705 \subsection{Known constructor}
1706 %*                                                                      *
1707 %************************************************************************
1708
1709 We are a bit careful with occurrence info.  Here's an example
1710
1711         (\x* -> case x of (a*, b) -> f a) (h v, e)
1712
1713 where the * means "occurs once".  This effectively becomes
1714         case (h v, e) of (a*, b) -> f a)
1715 and then
1716         let a* = h v; b = e in f a
1717 and then
1718         f (h v)
1719
1720 All this should happen in one sweep.
1721
1722 \begin{code}
1723 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1724          -> InId -> [InAlt] -> SimplCont
1725          -> SimplM FloatsWithExpr
1726
1727 knownCon env con args bndr alts cont
1728   = tick (KnownBranch bndr)     `thenSmpl_`
1729     case findAlt con alts of
1730         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1731                                   simplNonRecX env bndr scrut   $ \ env ->
1732                                         -- This might give rise to a binding with non-atomic args
1733                                         -- like x = Node (f x) (g x)
1734                                         -- but no harm will be done
1735                                   simplExprF env rhs cont
1736                                 where
1737                                   scrut = case con of
1738                                             LitAlt lit -> Lit lit
1739                                             DataAlt dc -> mkConApp dc args
1740
1741         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1742                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1743                                   simplExprF env rhs cont
1744
1745         (DataAlt dc, bs, rhs)
1746                 -> ASSERT( n_drop_tys + length bs == length args )
1747                    bind_args env bs (drop n_drop_tys args)      $ \ env ->
1748                    let
1749                         con_app  = mkConApp dc (take n_drop_tys args ++ con_args)
1750                         con_args = [substExpr env (varToCoreExpr b) | b <- bs]
1751                                         -- args are aready OutExprs, but bs are InIds
1752                    in
1753                    simplNonRecX env bndr con_app                $ \ env ->
1754                    simplExprF env rhs cont
1755                 where
1756                    n_drop_tys | isVanillaDataCon dc = tyConArity (dataConTyCon dc)
1757                               | otherwise           = 0
1758                         -- Vanilla data constructors lack type arguments in the pattern
1759
1760 -- Ugh!
1761 bind_args env [] _ thing_inside = thing_inside env
1762
1763 bind_args env (b:bs) (Type ty : args) thing_inside
1764   = ASSERT( isTyVar b )
1765     bind_args (extendTvSubst env b ty) bs args thing_inside
1766
1767 bind_args env (b:bs) (arg : args) thing_inside
1768   = ASSERT( isId b )
1769     simplNonRecX env b arg      $ \ env ->
1770     bind_args env bs args thing_inside
1771 \end{code}
1772
1773
1774 %************************************************************************
1775 %*                                                                      *
1776 \subsection{Duplicating continuations}
1777 %*                                                                      *
1778 %************************************************************************
1779
1780 \begin{code}
1781 prepareCaseCont :: SimplEnv
1782                 -> [InAlt] -> SimplCont
1783                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1784                         -- Return a duplicatable continuation, a non-duplicable part
1785                         -- plus some extra bindings (that scope over the entire
1786                         -- continunation)
1787
1788         -- No need to make it duplicatable if there's only one alternative
1789 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1790 prepareCaseCont env alts  cont = mkDupableCont env cont
1791 \end{code}
1792
1793 \begin{code}
1794 mkDupableCont :: SimplEnv -> SimplCont
1795               -> SimplM (FloatsWith (SimplCont, SimplCont))
1796
1797 mkDupableCont env cont
1798   | contIsDupable cont
1799   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1800
1801 mkDupableCont env (CoerceIt ty cont)
1802   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1803     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1804
1805 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1806   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1807         -- Do *not* duplicate an ArgOf continuation
1808         -- Because ArgOf continuations are opaque, we gain nothing by
1809         -- propagating them into the expressions, and we do lose a lot.
1810         -- Here's an example:
1811         --      && (case x of { T -> F; F -> T }) E
1812         -- Now, && is strict so we end up simplifying the case with
1813         -- an ArgOf continuation.  If we let-bind it, we get
1814         --
1815         --      let $j = \v -> && v E
1816         --      in simplExpr (case x of { T -> F; F -> T })
1817         --                   (ArgOf (\r -> $j r)
1818         -- And after simplifying more we get
1819         --
1820         --      let $j = \v -> && v E
1821         --      in case of { T -> $j F; F -> $j T }
1822         -- Which is a Very Bad Thing
1823         --
1824         -- The desire not to duplicate is the entire reason that
1825         -- mkDupableCont returns a pair of continuations.
1826         --
1827         -- The original plan had:
1828         -- e.g.         (...strict-fn...) [...hole...]
1829         --      ==>
1830         --              let $j = \a -> ...strict-fn...
1831         --              in $j [...hole...]
1832
1833 mkDupableCont env (ApplyTo _ arg se cont)
1834   =     -- e.g.         [...hole...] (...arg...)
1835         --      ==>
1836         --              let a = ...arg...
1837         --              in [...hole...] a
1838     do  { (floats, (dup_cont, nondup_cont)) <- mkDupableCont env cont
1839         ; addFloats env floats $ \ env -> do
1840         { arg1 <- simplExpr (setInScope se env) arg
1841         ; (floats2, arg2) <- mkDupableArg env arg1
1842         ; return (floats2, (ApplyTo OkToDup arg2 (zapSubstEnv se) dup_cont, nondup_cont)) }}
1843
1844 mkDupableCont env (Select _ case_bndr alts se cont)
1845   =     -- e.g.         (case [...hole...] of { pi -> ei })
1846         --      ===>
1847         --              let ji = \xij -> ei
1848         --              in case [...hole...] of { pi -> ji xij }
1849     do  { tick (CaseOfCase case_bndr)
1850         ; let alt_env = setInScope se env
1851         ; (floats1, (dup_cont, nondup_cont)) <- mkDupableCont alt_env cont
1852                 -- NB: call mkDupableCont here, *not* prepareCaseCont
1853                 -- We must make a duplicable continuation, whereas prepareCaseCont
1854                 -- doesn't when there is a single case branch
1855         ; addFloats alt_env floats1     $ \ alt_env -> do
1856
1857         { (alt_env, case_bndr') <- simplBinder alt_env case_bndr
1858                 -- NB: simplBinder does not zap deadness occ-info, so
1859                 -- a dead case_bndr' will still advertise its deadness
1860                 -- This is really important because in
1861                 --      case e of b { (# a,b #) -> ... }
1862                 -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1863                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1864                 -- In the new alts we build, we have the new case binder, so it must retain
1865                 -- its deadness.
1866
1867         ; (floats2, alts') <- mkDupableAlts alt_env case_bndr' alts dup_cont
1868         ; return (floats2, (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1869                                    (mkBoringStop (contResultType dup_cont)),
1870                             nondup_cont))
1871         }}
1872
1873 mkDupableArg :: SimplEnv -> OutExpr -> SimplM (FloatsWith OutExpr)
1874 -- Let-bind the thing if necessary
1875 mkDupableArg env arg
1876   | exprIsDupable arg
1877   = return (emptyFloats env, arg)
1878   | otherwise
1879   = do  { arg_id <- newId FSLIT("a") (exprType arg)
1880         ; tick (CaseOfCase arg_id)
1881                 -- Want to tick here so that we go round again,
1882                 -- and maybe copy or inline the code.
1883                 -- Not strictly CaseOfCase, but never mind
1884         ; return (unitFloat env arg_id arg, Var arg_id) }
1885         -- What if the arg should be case-bound?
1886         -- This has been this way for a long time, so I'll leave it,
1887         -- but I can't convince myself that it's right.
1888
1889 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1890               -> SimplM (FloatsWith [InAlt])
1891 -- Absorbs the continuation into the new alternatives
1892
1893 mkDupableAlts env case_bndr' alts dupable_cont
1894   = go env alts
1895   where
1896     go env [] = returnSmpl (emptyFloats env, [])
1897     go env (alt:alts)
1898         = do { (floats1, mb_alt') <- mkDupableAlt env case_bndr' dupable_cont alt
1899              ; addFloats env floats1    $ \ env -> do
1900              { (floats2, alts') <- go env alts
1901              ; returnSmpl (floats2, case mb_alt' of
1902                                         Just alt' -> alt' : alts'
1903                                         Nothing   -> alts'
1904                           )}}
1905
1906 mkDupableAlt env case_bndr' cont alt
1907   = simplAlt env [] case_bndr' cont alt         `thenSmpl` \ mb_stuff ->
1908     case mb_stuff of {
1909         Nothing -> returnSmpl (emptyFloats env, Nothing) ;
1910
1911         Just (reft, (con, bndrs', rhs')) ->
1912         -- Safe to say that there are no handled-cons for the DEFAULT case
1913
1914     if exprIsDupable rhs' then
1915         returnSmpl (emptyFloats env, Just (con, bndrs', rhs'))
1916         -- It is worth checking for a small RHS because otherwise we
1917         -- get extra let bindings that may cause an extra iteration of the simplifier to
1918         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1919         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1920         -- iterations because the version with the let bindings looked big, and so wasn't
1921         -- inlined, but after the join points had been inlined it looked smaller, and so
1922         -- was inlined.
1923         --
1924         -- NB: we have to check the size of rhs', not rhs.
1925         -- Duplicating a small InAlt might invalidate occurrence information
1926         -- However, if it *is* dupable, we return the *un* simplified alternative,
1927         -- because otherwise we'd need to pair it up with an empty subst-env....
1928         -- but we only have one env shared between all the alts.
1929         -- (Remember we must zap the subst-env before re-simplifying something).
1930         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1931
1932     else
1933     let
1934         rhs_ty'     = exprType rhs'
1935         used_bndrs' = filter abstract_over (case_bndr' : bndrs')
1936         abstract_over bndr
1937           | isTyVar bndr = not (bndr `elemVarEnv` reft)
1938                 -- Don't abstract over tyvar binders which are refined away
1939                 -- See Note [Refinement] below
1940           | otherwise    = not (isDeadBinder bndr)
1941                 -- The deadness info on the new Ids is preserved by simplBinders
1942     in
1943         -- If we try to lift a primitive-typed something out
1944         -- for let-binding-purposes, we will *caseify* it (!),
1945         -- with potentially-disastrous strictness results.  So
1946         -- instead we turn it into a function: \v -> e
1947         -- where v::State# RealWorld#.  The value passed to this function
1948         -- is realworld#, which generates (almost) no code.
1949
1950         -- There's a slight infelicity here: we pass the overall
1951         -- case_bndr to all the join points if it's used in *any* RHS,
1952         -- because we don't know its usage in each RHS separately
1953
1954         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1955         -- we make the join point into a function whenever used_bndrs'
1956         -- is empty.  This makes the join-point more CPR friendly.
1957         -- Consider:    let j = if .. then I# 3 else I# 4
1958         --              in case .. of { A -> j; B -> j; C -> ... }
1959         --
1960         -- Now CPR doesn't w/w j because it's a thunk, so
1961         -- that means that the enclosing function can't w/w either,
1962         -- which is a lose.  Here's the example that happened in practice:
1963         --      kgmod :: Int -> Int -> Int
1964         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1965         --                  then 78
1966         --                  else 5
1967         --
1968         -- I have seen a case alternative like this:
1969         --      True -> \v -> ...
1970         -- It's a bit silly to add the realWorld dummy arg in this case, making
1971         --      $j = \s v -> ...
1972         --         True -> $j s
1973         -- (the \v alone is enough to make CPR happy) but I think it's rare
1974
1975     ( if not (any isId used_bndrs')
1976         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1977              returnSmpl ([rw_id], [Var realWorldPrimId])
1978         else
1979              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1980     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1981
1982         -- See comment about "$j" name above
1983     newId FSLIT("$j") (mkPiTypes final_bndrs' rhs_ty')  `thenSmpl` \ join_bndr ->
1984         -- Notice the funky mkPiTypes.  If the contructor has existentials
1985         -- it's possible that the join point will be abstracted over
1986         -- type varaibles as well as term variables.
1987         --  Example:  Suppose we have
1988         --      data T = forall t.  C [t]
1989         --  Then faced with
1990         --      case (case e of ...) of
1991         --          C t xs::[t] -> rhs
1992         --  We get the join point
1993         --      let j :: forall t. [t] -> ...
1994         --          j = /\t \xs::[t] -> rhs
1995         --      in
1996         --      case (case e of ...) of
1997         --          C t xs::[t] -> j t xs
1998     let
1999         -- We make the lambdas into one-shot-lambdas.  The
2000         -- join point is sure to be applied at most once, and doing so
2001         -- prevents the body of the join point being floated out by
2002         -- the full laziness pass
2003         really_final_bndrs     = map one_shot final_bndrs'
2004         one_shot v | isId v    = setOneShotLambda v
2005                    | otherwise = v
2006         join_rhs  = mkLams really_final_bndrs rhs'
2007         join_call = mkApps (Var join_bndr) final_args
2008     in
2009     returnSmpl (unitFloat env join_bndr join_rhs, Just (con, bndrs', join_call)) }
2010 \end{code}
2011
2012 Note [Refinement]
2013 ~~~~~~~~~~~~~~~~~
2014 Consider
2015         data T a where
2016           MkT :: a -> b -> T a
2017
2018         f = /\a. \(w::a).
2019            case (case ...) of
2020                   MkT a' b (p::a') (q::b) -> [p,w]
2021
2022 The danger is that we'll make a join point
2023
2024         j a' p = [p,w]
2025
2026 and that's ill-typed, because (p::a') but (w::a).
2027
2028 Solution so far: don't abstract over a', because the type refinement
2029 maps [a' -> a] .  Ultimately that won't work when real refinement goes on.
2030
2031 Then we must abstract over any refined free variables.  Hmm.  Maybe we
2032 could just abstract over *all* free variables, thereby lambda-lifting
2033 the join point?   We should try this.