compiler/specialise/Rules.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[CoreRules]{Transformation rules}
   5
   6 \begin{code}
   7 module Rules (
   8         RuleBase, emptyRuleBase, mkRuleBase, extendRuleBaseList,
   9         unionRuleBase, pprRuleBase, ruleCheckProgram,
  10
  11         mkSpecInfo, extendSpecInfo, addSpecInfo,
  12         rulesOfBinds, addIdSpecialisations,
  13
  14         lookupRule, mkLocalRule, roughTopNames
  15     ) where
  16
  17 #include "HsVersions.h"
  18
  19 import CoreSyn          -- All of it
  20 import OccurAnal        ( occurAnalyseExpr )
  21 import CoreFVs          ( exprFreeVars, exprsFreeVars, bindFreeVars, rulesRhsFreeVars )
  22 import CoreUnfold       ( isCheapUnfolding, unfoldingTemplate )
  23 import CoreUtils        ( tcEqExprX )
  24 import PprCore          ( pprRules )
  25 import Type             ( TvSubstEnv )
  26 import TcType           ( tcSplitTyConApp_maybe )
  27 import CoreTidy         ( tidyRules )
  28 import Id               ( Id, idUnfolding, isLocalId, isGlobalId, idName,
  29                           idSpecialisation, idCoreRules, setIdSpecialisation )
  30 import IdInfo           ( SpecInfo( SpecInfo ) )
  31 import Var              ( Var )
  32 import VarEnv           ( IdEnv, InScopeSet, emptyTidyEnv,
  33                           emptyInScopeSet, mkInScopeSet, extendInScopeSetList,
  34                           emptyVarEnv, lookupVarEnv, extendVarEnv,
  35                           nukeRnEnvL, mkRnEnv2, rnOccR, rnOccL, inRnEnvR,
  36                           rnBndrR, rnBndr2, rnBndrL, rnBndrs2,
  37                           rnInScope, extendRnInScopeList, lookupRnInScope )
  38 import VarSet
  39 import Name             ( Name, NamedThing(..), nameOccName )
  40 import NameEnv
  41 import Unify            ( ruleMatchTyX, MatchEnv(..) )
  42 import BasicTypes       ( Activation, CompilerPhase, isActive )
  43 import Outputable
  44 import FastString
  45 import Maybes           ( isJust, orElse )
  46 import OrdList
  47 import Bag
  48 import Util             ( singleton, mapAccumL )
  49 import List             ( isPrefixOf )
  50 \end{code}
  51
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection[specialisation-IdInfo]{Specialisation info about an @Id@}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 A @CoreRule@ holds details of one rule for an @Id@, which
  60 includes its specialisations.
  61
  62 For example, if a rule for @f@ contains the mapping:
  63 \begin{verbatim}
  64         forall a b d. [Type (List a), Type b, Var d]  ===>  f' a b
  65 \end{verbatim}
  66 then when we find an application of f to matching types, we simply replace
  67 it by the matching RHS:
  68 \begin{verbatim}
  69         f (List Int) Bool dict ===>  f' Int Bool
  70 \end{verbatim}
  71 All the stuff about how many dictionaries to discard, and what types
  72 to apply the specialised function to, are handled by the fact that the
  73 Rule contains a template for the result of the specialisation.
  74
  75 There is one more exciting case, which is dealt with in exactly the same
  76 way.  If the specialised value is unboxed then it is lifted at its
  77 definition site and unlifted at its uses.  For example:
  78
  79         pi :: forall a. Num a => a
  80
  81 might have a specialisation
  82
  83         [Int#] ===>  (case pi' of Lift pi# -> pi#)
  84
  85 where pi' :: Lift Int# is the specialised version of pi.
  86
  87 \begin{code}
  88 mkLocalRule :: RuleName -> Activation
  89             -> Name -> [CoreBndr] -> [CoreExpr] -> CoreExpr -> CoreRule
  90 -- Used to make CoreRule for an Id defined in this module
  91 mkLocalRule name act fn bndrs args rhs
  92   = Rule { ru_name = name, ru_fn = fn, ru_act = act,
  93            ru_bndrs = bndrs, ru_args = args,
  94            ru_rhs = rhs, ru_rough = roughTopNames args,
  95            ru_orph = Just (nameOccName fn), ru_local = True }
  96
  97 --------------
  98 roughTopNames :: [CoreExpr] -> [Maybe Name]
  99 roughTopNames args = map roughTopName args
 100
 101 roughTopName :: CoreExpr -> Maybe Name
 102 -- Find the "top" free name of an expression
 103 -- a) the function in an App chain (if a GlobalId)
 104 -- b) the TyCon in a type
 105 -- This is used for the fast-match-check for rules;
 106 --      if the top names don't match, the rest can't
 107 roughTopName (Type ty) = case tcSplitTyConApp_maybe ty of
 108                           Just (tc,_) -> Just (getName tc)
 109                           Nothing     -> Nothing
 110 roughTopName (App f a) = roughTopName f
 111 roughTopName (Var f) | isGlobalId f = Just (idName f)
 112                      | otherwise    = Nothing
 113 roughTopName other = Nothing
 114
 115 ruleCantMatch :: [Maybe Name] -> [Maybe Name] -> Bool
 116 -- (ruleCantMatch tpl actual) returns True only if 'actual'
 117 -- definitely can't match 'tpl' by instantiating 'tpl'.
 118 -- It's only a one-way match; unlike instance matching we
 119 -- don't consider unification
 120 --
 121 -- Notice that there is no case
 122 --      ruleCantMatch (Just n1 : ts) (Nothing : as) = True
 123 -- Reason: a local variable 'v' in the actuals might
 124 --         have an unfolding which is a global.
 125 --         This quite often happens with case scrutinees.
 126 ruleCantMatch (Just n1 : ts) (Just n2 : as) = n1 /= n2 || ruleCantMatch ts as
 127 ruleCantMatch (t       : ts) (a       : as) = ruleCantMatch ts as
 128 ruleCantMatch ts             as             = False
 129 \end{code}
 130
 131
 132 %************************************************************************
 133 %*                                                                      *
 134                 SpecInfo: the rules in an IdInfo
 135 %*                                                                      *
 136 %************************************************************************
 137
 138 \begin{code}
 139 mkSpecInfo :: [CoreRule] -> SpecInfo
 140 mkSpecInfo rules = SpecInfo rules (rulesRhsFreeVars rules)
 141
 142 extendSpecInfo :: SpecInfo -> [CoreRule] -> SpecInfo
 143 extendSpecInfo (SpecInfo rs1 fvs1) rs2
 144   = SpecInfo (rs2 ++ rs1) (rulesRhsFreeVars rs2 `unionVarSet` fvs1)
 145
 146 addSpecInfo :: SpecInfo -> SpecInfo -> SpecInfo
 147 addSpecInfo (SpecInfo rs1 fvs1) (SpecInfo rs2 fvs2)
 148   = SpecInfo (rs1 ++ rs2) (fvs1 `unionVarSet` fvs2)
 149
 150 addIdSpecialisations :: Id -> [CoreRule] -> Id
 151 addIdSpecialisations id rules
 152   = setIdSpecialisation id $
 153     extendSpecInfo (idSpecialisation id) rules
 154
 155 rulesOfBinds :: [CoreBind] -> [CoreRule]
 156 rulesOfBinds binds = concatMap (concatMap idCoreRules . bindersOf) binds
 157 \end{code}
 158
 159
 160 %************************************************************************
 161 %*                                                                      *
 162                 RuleBase
 163 %*                                                                      *
 164 %************************************************************************
 165
 166 \begin{code}
 167 type RuleBase = NameEnv [CoreRule]
 168         -- Maps (the name of) an Id to its rules
 169         -- The rules are are unordered;
 170         -- we sort out any overlaps on lookup
 171
 172 emptyRuleBase = emptyNameEnv
 173
 174 mkRuleBase :: [CoreRule] -> RuleBase
 175 mkRuleBase rules = extendRuleBaseList emptyRuleBase rules
 176
 177 extendRuleBaseList :: RuleBase -> [CoreRule] -> RuleBase
 178 extendRuleBaseList rule_base new_guys
 179   = foldl extendRuleBase rule_base new_guys
 180
 181 unionRuleBase :: RuleBase -> RuleBase -> RuleBase
 182 unionRuleBase rb1 rb2 = plusNameEnv_C (++) rb1 rb2
 183
 184 extendRuleBase :: RuleBase -> CoreRule -> RuleBase
 185 extendRuleBase rule_base rule
 186   = extendNameEnv_Acc (:) singleton rule_base (ruleIdName rule) rule
 187
 188 pprRuleBase :: RuleBase -> SDoc
 189 pprRuleBase rules = vcat [ pprRules (tidyRules emptyTidyEnv rs)
 190                          | rs <- nameEnvElts rules ]
 191 \end{code}
 192
 193
 194 %************************************************************************
 195 %*                                                                      *
 196 \subsection{Matching}
 197 %*                                                                      *
 198 %************************************************************************
 199
 200 \begin{code}
 201 lookupRule :: (Activation -> Bool) -> InScopeSet
 202            -> RuleBase  -- Imported rules
 203            -> Id -> [CoreExpr] -> Maybe (RuleName, CoreExpr)
 204 lookupRule is_active in_scope rule_base fn args
 205   = matchRules is_active in_scope fn args rules
 206   where
 207         -- The rules for an Id come from two places:
 208         --      (a) the ones it is born with (idCoreRules fn)
 209         --      (b) rules added in subsequent modules (extra_rules)
 210         -- PrimOps, for example, are born with a bunch of rules under (a)
 211     rules = extra_rules ++ idCoreRules fn
 212     extra_rules | isLocalId fn = []
 213                 | otherwise    = lookupNameEnv rule_base (idName fn) `orElse` []
 214
 215 matchRules :: (Activation -> Bool) -> InScopeSet
 216            -> Id -> [CoreExpr]
 217            -> [CoreRule] -> Maybe (RuleName, CoreExpr)
 218 -- See comments on matchRule
 219 matchRules is_active in_scope fn args rules
 220   = case go [] rules of
 221         []     -> Nothing
 222         (m:ms) -> Just (case findBest (fn,args) m ms of
 223                           (rule, ans) -> (ru_name rule, ans))
 224   where
 225     rough_args = map roughTopName args
 226
 227     go :: [(CoreRule,CoreExpr)] -> [CoreRule] -> [(CoreRule,CoreExpr)]
 228     go ms []           = ms
 229     go ms (r:rs) = case (matchRule is_active in_scope args rough_args r) of
 230                         Just e  -> go ((r,e):ms) rs
 231                         Nothing -> go ms         rs
 232
 233 findBest :: (Id, [CoreExpr])
 234          -> (CoreRule,CoreExpr) -> [(CoreRule,CoreExpr)] -> (CoreRule,CoreExpr)
 235 -- All these pairs matched the expression
 236 -- Return the pair the the most specific rule
 237 -- The (fn,args) is just for overlap reporting
 238
 239 findBest target (rule,ans)   [] = (rule,ans)
 240 findBest target (rule1,ans1) ((rule2,ans2):prs)
 241   | rule1 `isMoreSpecific` rule2 = findBest target (rule1,ans1) prs
 242   | rule2 `isMoreSpecific` rule1 = findBest target (rule1,ans1) prs
 243 #ifdef DEBUG
 244   | otherwise = pprTrace "Rules.findBest: rule overlap (Rule 1 wins)"
 245                          (vcat [ptext SLIT("Expression to match:") <+> ppr fn <+> sep (map ppr args),
 246                                 ptext SLIT("Rule 1:") <+> ppr rule1,
 247                                 ptext SLIT("Rule 2:") <+> ppr rule2]) $
 248                 findBest target (rule1,ans1) prs
 249 #else
 250   | otherwise = findBest target (rule1,ans1) prs
 251 #endif
 252   where
 253     (fn,args) = target
 254
 255 isMoreSpecific :: CoreRule -> CoreRule -> Bool
 256 isMoreSpecific (BuiltinRule {}) r2 = True
 257 isMoreSpecific r1 (BuiltinRule {}) = False
 258 isMoreSpecific (Rule { ru_bndrs = bndrs1, ru_args = args1 })
 259                (Rule { ru_bndrs = bndrs2, ru_args = args2 })
 260   = isJust (matchN in_scope bndrs2 args2 args1)
 261   where
 262    in_scope = mkInScopeSet (mkVarSet bndrs1)
 263         -- Actually we should probably include the free vars
 264         -- of rule1's args, but I can't be bothered
 265
 266 noBlackList :: Activation -> Bool
 267 noBlackList act = False         -- Nothing is black listed
 268
 269 matchRule :: (Activation -> Bool) -> InScopeSet
 270           -> [CoreExpr] -> [Maybe Name]
 271           -> CoreRule -> Maybe CoreExpr
 272
 273 -- If (matchRule rule args) returns Just (name,rhs)
 274 -- then (f args) matches the rule, and the corresponding
 275 -- rewritten RHS is rhs
 276 --
 277 -- The bndrs and rhs is occurrence-analysed
 278 --
 279 --      Example
 280 --
 281 -- The rule
 282 --      forall f g x. map f (map g x) ==> map (f . g) x
 283 -- is stored
 284 --      CoreRule "map/map"
 285 --               [f,g,x]                -- tpl_vars
 286 --               [f,map g x]            -- tpl_args
 287 --               map (f.g) x)           -- rhs
 288 --
 289 -- Then the call: matchRule the_rule [e1,map e2 e3]
 290 --        = Just ("map/map", (\f,g,x -> rhs) e1 e2 e3)
 291 --
 292 -- Any 'surplus' arguments in the input are simply put on the end
 293 -- of the output.
 294
 295 matchRule is_active in_scope args rough_args
 296           (BuiltinRule { ru_name = name, ru_try = match_fn })
 297   = case match_fn args of
 298         Just expr -> Just expr
 299         Nothing   -> Nothing
 300
 301 matchRule is_active in_scope args rough_args
 302           (Rule { ru_name = rn, ru_act = act, ru_rough = tpl_tops,
 303                   ru_bndrs = tpl_vars, ru_args = tpl_args,
 304                   ru_rhs = rhs })
 305   | not (is_active act)               = Nothing
 306   | ruleCantMatch tpl_tops rough_args = Nothing
 307   | otherwise
 308   = case matchN in_scope tpl_vars tpl_args args of
 309         Nothing                    -> Nothing
 310         Just (binds, tpl_vals, leftovers) -> Just (mkLets binds $
 311                                                    rule_fn
 312                                                     `mkApps` tpl_vals
 313                                                     `mkApps` leftovers)
 314   where
 315     rule_fn = occurAnalyseExpr (mkLams tpl_vars rhs)
 316         -- We could do this when putting things into the rulebase, I guess
 317 \end{code}
 318
 319 \begin{code}
 320 matchN  :: InScopeSet
 321         -> [Var]                -- Template tyvars
 322         -> [CoreExpr]           -- Template
 323         -> [CoreExpr]           -- Target; can have more elts than template
 324         -> Maybe ([CoreBind],   -- Bindings to wrap around the entire result
 325                   [CoreExpr],   -- What is substituted for each template var
 326                   [CoreExpr])   -- Leftover target exprs
 327
 328 matchN in_scope tmpl_vars tmpl_es target_es
 329   = do  { ((tv_subst, id_subst, binds), leftover_es)
 330                 <- go init_menv emptySubstEnv tmpl_es target_es
 331         ; return (fromOL binds,
 332                   map (lookup_tmpl tv_subst id_subst) tmpl_vars,
 333                   leftover_es) }
 334   where
 335     init_menv = ME { me_tmpls = mkVarSet tmpl_vars, me_env = init_rn_env }
 336     init_rn_env = mkRnEnv2 (extendInScopeSetList in_scope tmpl_vars)
 337
 338     go menv subst []     es     = Just (subst, es)
 339     go menv subst ts     []     = Nothing       -- Fail if too few actual args
 340     go menv subst (t:ts) (e:es) = do { subst1 <- match menv subst t e
 341                                      ; go menv subst1 ts es }
 342
 343     lookup_tmpl :: TvSubstEnv -> IdSubstEnv -> Var -> CoreExpr
 344     lookup_tmpl tv_subst id_subst tmpl_var
 345         | isTyVar tmpl_var = case lookupVarEnv tv_subst tmpl_var of
 346                                 Just ty         -> Type ty
 347                                 Nothing         -> unbound tmpl_var
 348         | otherwise        = case lookupVarEnv id_subst tmpl_var of
 349                                 Just e -> e
 350                                 other  -> unbound tmpl_var
 351
 352     unbound var = pprPanic "Template variable unbound in rewrite rule" (ppr var)
 353 \end{code}
 354
 355
 356         ---------------------------------------------
 357                 The inner workings of matching
 358         ---------------------------------------------
 359
 360 \begin{code}
 361 -- These two definitions are not the same as in Subst,
 362 -- but they simple and direct, and purely local to this module
 363 --
 364 -- * The domain of the TvSubstEnv and IdSubstEnv are the template
 365 --   variables passed into the match.
 366 --
 367 -- * The (OrdList CoreBind) in a SubstEnv are the bindings floated out
 368 --   from nested matches; see the Let case of match, below
 369 --
 370 type SubstEnv   = (TvSubstEnv, IdSubstEnv, OrdList CoreBind)
 371 type IdSubstEnv = IdEnv CoreExpr
 372
 373 emptySubstEnv :: SubstEnv
 374 emptySubstEnv = (emptyVarEnv, emptyVarEnv, nilOL)
 375
 376
 377 --      At one stage I tried to match even if there are more
 378 --      template args than real args.
 379
 380 --      I now think this is probably a bad idea.
 381 --      Should the template (map f xs) match (map g)?  I think not.
 382 --      For a start, in general eta expansion wastes work.
 383 --      SLPJ July 99
 384
 385
 386 match :: MatchEnv
 387       -> SubstEnv
 388       -> CoreExpr               -- Template
 389       -> CoreExpr               -- Target
 390       -> Maybe SubstEnv
 391
 392 -- See the notes with Unify.match, which matches types
 393 -- Everything is very similar for terms
 394
 395 -- Interesting examples:
 396 -- Consider matching
 397 --      \x->f      against    \f->f
 398 -- When we meet the lambdas we must remember to rename f to f' in the
 399 -- second expresion.  The RnEnv2 does that.
 400 --
 401 -- Consider matching
 402 --      forall a. \b->b    against   \a->3
 403 -- We must rename the \a.  Otherwise when we meet the lambdas we
 404 -- might substitute [a/b] in the template, and then erroneously
 405 -- succeed in matching what looks like the template variable 'a' against 3.
 406
 407 -- The Var case follows closely what happens in Unify.match
 408 match menv subst (Var v1) e2
 409   | Just subst <- match_var menv subst v1 e2
 410   = Just subst
 411
 412 -- Here is another important rule: if the term being matched is a
 413 -- variable, we expand it so long as its unfolding is a WHNF
 414 -- (Its occurrence information is not necessarily up to date,
 415 --  so we don't use it.)
 416 match menv subst e1 (Var v2)
 417   | not (inRnEnvR rn_env v2),
 418         -- If v2 is in the RnEnvR, then it's locally bound and can't
 419         -- have an unfolding. We must make this check because if it
 420         -- is locally bound we must not look it up in the in-scope set
 421         -- E.g.         (\x->x) where x is already in scope
 422     isCheapUnfolding unfolding
 423   = match menv subst e1 (unfoldingTemplate unfolding)
 424   where
 425     rn_env    = me_env menv
 426     unfolding = idUnfolding (lookupRnInScope rn_env v2)
 427         -- Notice that we look up v2 in the in-scope set
 428         -- See Note [Lookup in-scope]
 429
 430 match menv subst (Lit lit1) (Lit lit2)
 431   | lit1 == lit2
 432   = Just subst
 433
 434 match menv subst (App f1 a1) (App f2 a2)
 435   = do  { subst' <- match menv subst f1 f2
 436         ; match menv subst' a1 a2 }
 437
 438 match menv subst (Lam x1 e1) (Lam x2 e2)
 439   = match menv' subst e1 e2
 440   where
 441     menv' = menv { me_env = rnBndr2 (me_env menv) x1 x2 }
 442
 443 -- This rule does eta expansion
 444 --              (\x.M)  ~  N    iff     M  ~  N x
 445 match menv subst (Lam x1 e1) e2
 446   = match menv' subst e1 (App e2 (varToCoreExpr new_x))
 447   where
 448     (rn_env', new_x) = rnBndrL (me_env menv) x1
 449     menv' = menv { me_env = rn_env' }
 450
 451 -- Eta expansion the other way
 452 --      M  ~  (\y.N)    iff   M y     ~  N
 453 match menv subst e1 (Lam x2 e2)
 454   = match menv' subst (App e1 (varToCoreExpr new_x)) e2
 455   where
 456     (rn_env', new_x) = rnBndrR (me_env menv) x2
 457     menv' = menv { me_env = rn_env' }
 458
 459 match menv subst (Case e1 x1 ty1 alts1) (Case e2 x2 ty2 alts2)
 460   = do  { subst1 <- match_ty menv subst ty1 ty2
 461         ; subst2 <- match menv subst1 e1 e2
 462         ; let menv' = menv { me_env = rnBndr2 (me_env menv) x2 x2 }
 463         ; match_alts menv' subst2 alts1 alts2   -- Alts are both sorted
 464         }
 465
 466 match menv subst (Type ty1) (Type ty2)
 467   = match_ty menv subst ty1 ty2
 468
 469 match menv subst (Note (Coerce to1 from1) e1) (Note (Coerce to2 from2) e2)
 470   = do  { subst1 <- match_ty menv subst  to1   to2
 471         ; subst2 <- match_ty menv subst1 from1 from2
 472         ; match menv subst2 e1 e2 }
 473
 474 -- Matching a let-expression.  Consider
 475 --      RULE forall x.  f (g x) = <rhs>
 476 -- and target expression
 477 --      f (let { w=R } in g E))
 478 -- Then we'd like the rule to match, to generate
 479 --      let { w=R } in (\x. <rhs>) E
 480 -- In effect, we want to float the let-binding outward, to enable
 481 -- the match to happen.  This is the WHOLE REASON for accumulating
 482 -- bindings in the SubstEnv
 483 --
 484 -- We can only do this if
 485 --      (a) Widening the scope of w does not capture any variables
 486 --          We use a conservative test: w is not already in scope
 487 --      (b) The free variables of R are not bound by the part of the
 488 --          target expression outside the let binding; e.g.
 489 --              f (\v. let w = v+1 in g E)
 490 --          Here we obviously cannot float the let-binding for w.
 491
 492 match menv subst@(tv_subst, id_subst, binds) e1 (Let bind e2)
 493   | all freshly_bound bndrs,
 494     not (any locally_bound bind_fvs)
 495   = match (menv { me_env = rn_env' })
 496           (tv_subst, id_subst, binds `snocOL` bind)
 497           e1 e2
 498   where
 499     rn_env   = me_env menv
 500     bndrs    = bindersOf bind
 501     bind_fvs = varSetElems (bindFreeVars bind)
 502     freshly_bound x = not (x `rnInScope` rn_env)
 503     locally_bound x = inRnEnvR rn_env x
 504     rn_env' = extendRnInScopeList rn_env bndrs
 505
 506 -- This is an interesting rule: we simply ignore lets in the
 507 -- term being matched against!  The unfolding inside it is (by assumption)
 508 -- already inside any occurrences of the bound variables, so we'll expand
 509 -- them when we encounter them.  This gives a chance of matching
 510 --      forall x,y.  f (g (x,y))
 511 -- against
 512 --      f (let v = (a,b) in g v)
 513
 514 match menv subst e1 (Let bind e2)
 515   = match (menv { me_env = rn_env' }) subst e1 e2
 516   where
 517     (rn_env', _bndrs') = mapAccumL rnBndrR (me_env menv) (bindersOf bind)
 518         -- It's important to do this renaming, so that the bndrs
 519         -- are brought into the local scope. For example:
 520         -- Matching
 521         --      forall f,x,xs. f (x:xs)
 522         --   against
 523         --      f (let y = e in (y:[]))
 524         -- We must not get success with x->y!  So we record that y is
 525         -- locally bound (with rnBndrR), and proceed.  The Var case
 526         -- will fail when trying to bind x->y
 527         --
 528
 529 -- Everything else fails
 530 match menv subst e1 e2 = Nothing
 531
 532 ------------------------------------------
 533 match_var :: MatchEnv
 534           -> SubstEnv
 535           -> Var                -- Template
 536           -> CoreExpr           -- Target
 537           -> Maybe SubstEnv
 538 match_var menv subst@(tv_subst, id_subst, binds) v1 e2
 539   | v1' `elemVarSet` me_tmpls menv
 540   = case lookupVarEnv id_subst v1' of
 541         Nothing | any (inRnEnvR rn_env) (varSetElems (exprFreeVars e2))
 542                 -> Nothing      -- Occurs check failure
 543                 -- e.g. match forall a. (\x-> a x) against (\y. y y)
 544
 545                 | otherwise     -- No renaming to do on e2
 546                 -> Just (tv_subst, extendVarEnv id_subst v1 e2, binds)
 547
 548         Just e2' | tcEqExprX (nukeRnEnvL rn_env) e2' e2
 549                  -> Just subst
 550
 551                  | otherwise
 552                  -> Nothing
 553
 554   | otherwise   -- v1 is not a template variable; check for an exact match with e2
 555   = case e2 of
 556        Var v2 | v1' == rnOccR rn_env v2 -> Just subst
 557        other                            -> Nothing
 558
 559   where
 560     rn_env = me_env menv
 561     v1'    = rnOccL rn_env v1
 562         -- If the template is
 563         --      forall x. f x (\x -> x) = ...
 564         -- Then the x inside the lambda isn't the
 565         -- template x, so we must rename first!
 566
 567
 568 ------------------------------------------
 569 match_alts :: MatchEnv
 570       -> SubstEnv
 571       -> [CoreAlt]              -- Template
 572       -> [CoreAlt]              -- Target
 573       -> Maybe SubstEnv
 574 match_alts menv subst [] []
 575   = return subst
 576 match_alts menv subst ((c1,vs1,r1):alts1) ((c2,vs2,r2):alts2)
 577   | c1 == c2
 578   = do  { subst1 <- match menv' subst r1 r2
 579         ; match_alts menv subst1 alts1 alts2 }
 580   where
 581     menv' :: MatchEnv
 582     menv' = menv { me_env = rnBndrs2 (me_env menv) vs1 vs2 }
 583
 584 match_alts menv subst alts1 alts2
 585   = Nothing
 586 \end{code}
 587
 588 Matching Core types: use the matcher in TcType.
 589 Notice that we treat newtypes as opaque.  For example, suppose
 590 we have a specialised version of a function at a newtype, say
 591         newtype T = MkT Int
 592 We only want to replace (f T) with f', not (f Int).
 593
 594 \begin{code}
 595 ------------------------------------------
 596 match_ty menv (tv_subst, id_subst, binds) ty1 ty2
 597   = do  { tv_subst' <- Unify.ruleMatchTyX menv tv_subst ty1 ty2
 598         ; return (tv_subst', id_subst, binds) }
 599 \end{code}
 600
 601
 602 Note [Lookup in-scope]
 603 ~~~~~~~~~~~~~~~~~~~~~~
 604 Consider this example
 605         foo :: Int -> Maybe Int -> Int
 606         foo 0 (Just n) = n
 607         foo m (Just n) = foo (m-n) (Just n)
 608
 609 SpecConstr sees this fragment:
 610
 611         case w_smT of wild_Xf [Just A] {
 612           Data.Maybe.Nothing -> lvl_smf;
 613           Data.Maybe.Just n_acT [Just S(L)] ->
 614             case n_acT of wild1_ams [Just A] { GHC.Base.I# y_amr [Just L] ->
 615             $wfoo_smW (GHC.Prim.-# ds_Xmb y_amr) wild_Xf
 616             }};
 617
 618 and correctly generates the rule
 619
 620         RULES: "SC:$wfoo1" [0] __forall {y_amr [Just L] :: GHC.Prim.Int#
 621                                           sc_snn :: GHC.Prim.Int#}
 622           $wfoo_smW sc_snn (Data.Maybe.Just @ GHC.Base.Int (GHC.Base.I# y_amr))
 623           = $s$wfoo_sno y_amr sc_snn ;]
 624
 625 BUT we must ensure that this rule matches in the original function!
 626 Note that the call to $wfoo is
 627             $wfoo_smW (GHC.Prim.-# ds_Xmb y_amr) wild_Xf
 628
 629 During matching we expand wild_Xf to (Just n_acT).  But then we must also
 630 expand n_acT to (I# y_amr).  And we can only do that if we look up n_acT
 631 in the in-scope set, because in wild_Xf's unfolding it won't have an unfolding
 632 at all.
 633
 634 That is why the 'lookupRnInScope' call in the (Var v2) case of 'match'
 635 is so important.
 636
 637
 638 %************************************************************************
 639 %*                                                                      *
 640 \subsection{Checking a program for failing rule applications}
 641 %*                                                                      *
 642 %************************************************************************
 643
 644 -----------------------------------------------------
 645                         Game plan
 646 -----------------------------------------------------
 647
 648 We want to know what sites have rules that could have fired but didn't.
 649 This pass runs over the tree (without changing it) and reports such.
 650
 651 NB: we assume that this follows a run of the simplifier, so every Id
 652 occurrence (including occurrences of imported Ids) is decorated with
 653 all its (active) rules.  No need to construct a rule base or anything
 654 like that.
 655
 656 \begin{code}
 657 ruleCheckProgram :: CompilerPhase -> String -> [CoreBind] -> SDoc
 658 -- Report partial matches for rules beginning
 659 -- with the specified string
 660 ruleCheckProgram phase rule_pat binds
 661   | isEmptyBag results
 662   = text "Rule check results: no rule application sites"
 663   | otherwise
 664   = vcat [text "Rule check results:",
 665           line,
 666           vcat [ p $$ line | p <- bagToList results ]
 667          ]
 668   where
 669     results = unionManyBags (map (ruleCheckBind (phase, rule_pat)) binds)
 670     line = text (replicate 20 '-')
 671
 672 type RuleCheckEnv = (CompilerPhase, String)     -- Phase and Pattern
 673
 674 ruleCheckBind :: RuleCheckEnv -> CoreBind -> Bag SDoc
 675    -- The Bag returned has one SDoc for each call site found
 676 ruleCheckBind env (NonRec b r) = ruleCheck env r
 677 ruleCheckBind env (Rec prs)    = unionManyBags [ruleCheck env r | (b,r) <- prs]
 678
 679 ruleCheck :: RuleCheckEnv -> CoreExpr -> Bag SDoc
 680 ruleCheck env (Var v)       = emptyBag
 681 ruleCheck env (Lit l)       = emptyBag
 682 ruleCheck env (Type ty)     = emptyBag
 683 ruleCheck env (App f a)     = ruleCheckApp env (App f a) []
 684 ruleCheck env (Note n e)    = ruleCheck env e
 685 ruleCheck env (Let bd e)    = ruleCheckBind env bd `unionBags` ruleCheck env e
 686 ruleCheck env (Lam b e)     = ruleCheck env e
 687 ruleCheck env (Case e _ _ as) = ruleCheck env e `unionBags`
 688                                 unionManyBags [ruleCheck env r | (_,_,r) <- as]
 689
 690 ruleCheckApp env (App f a) as = ruleCheck env a `unionBags` ruleCheckApp env f (a:as)
 691 ruleCheckApp env (Var f) as   = ruleCheckFun env f as
 692 ruleCheckApp env other as     = ruleCheck env other
 693 \end{code}
 694
 695 \begin{code}
 696 ruleCheckFun :: RuleCheckEnv -> Id -> [CoreExpr] -> Bag SDoc
 697 -- Produce a report for all rules matching the predicate
 698 -- saying why it doesn't match the specified application
 699
 700 ruleCheckFun (phase, pat) fn args
 701   | null name_match_rules = emptyBag
 702   | otherwise             = unitBag (ruleAppCheck_help phase fn args name_match_rules)
 703   where
 704     name_match_rules = filter match (idCoreRules fn)
 705     match rule = pat `isPrefixOf` unpackFS (ruleName rule)
 706
 707 ruleAppCheck_help :: CompilerPhase -> Id -> [CoreExpr] -> [CoreRule] -> SDoc
 708 ruleAppCheck_help phase fn args rules
 709   =     -- The rules match the pattern, so we want to print something
 710     vcat [text "Expression:" <+> ppr (mkApps (Var fn) args),
 711           vcat (map check_rule rules)]
 712   where
 713     n_args = length args
 714     i_args = args `zip` [1::Int ..]
 715     rough_args = map roughTopName args
 716
 717     check_rule rule = rule_herald rule <> colon <+> rule_info rule
 718
 719     rule_herald (BuiltinRule { ru_name = name })
 720         = ptext SLIT("Builtin rule") <+> doubleQuotes (ftext name)
 721     rule_herald (Rule { ru_name = name })
 722         = ptext SLIT("Rule") <+> doubleQuotes (ftext name)
 723
 724     rule_info rule
 725         | Just _ <- matchRule noBlackList emptyInScopeSet args rough_args rule
 726         = text "matches (which is very peculiar!)"
 727
 728     rule_info (BuiltinRule {}) = text "does not match"
 729
 730     rule_info (Rule { ru_name = name, ru_act = act,
 731                       ru_bndrs = rule_bndrs, ru_args = rule_args})
 732         | not (isActive phase act)    = text "active only in later phase"
 733         | n_args < n_rule_args        = text "too few arguments"
 734         | n_mismatches == n_rule_args = text "no arguments match"
 735         | n_mismatches == 0           = text "all arguments match (considered individually), but rule as a whole does not"
 736         | otherwise                   = text "arguments" <+> ppr mismatches <+> text "do not match (1-indexing)"
 737         where
 738           n_rule_args  = length rule_args
 739           n_mismatches = length mismatches
 740           mismatches   = [i | (rule_arg, (arg,i)) <- rule_args `zip` i_args,
 741                               not (isJust (match_fn rule_arg arg))]
 742
 743           lhs_fvs = exprsFreeVars rule_args     -- Includes template tyvars
 744           match_fn rule_arg arg = match menv emptySubstEnv rule_arg arg
 745                 where
 746                   in_scope = lhs_fvs `unionVarSet` exprFreeVars arg
 747                   menv = ME { me_env   = mkRnEnv2 (mkInScopeSet in_scope)
 748                             , me_tmpls = mkVarSet rule_bndrs }
 749 \end{code}
 750