compiler/specialise/SpecConstr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SpecConstr]{Specialise over constructors}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module SpecConstr(
  14         specConstrProgram
  15     ) where
  16
  17 #include "HsVersions.h"
  18
  19 import CoreSyn
  20 import CoreSubst
  21 import CoreUtils
  22 import CoreUnfold       ( couldBeSmallEnoughToInline )
  23 import CoreFVs          ( exprsFreeVars )
  24 import WwLib            ( mkWorkerArgs )
  25 import DataCon          ( dataConRepArity, dataConUnivTyVars )
  26 import Coercion
  27 import Rules
  28 import Type             hiding( substTy )
  29 import Id
  30 import Var
  31 import VarEnv
  32 import VarSet
  33 import Name
  34 import OccName          ( mkSpecOcc )
  35 import DynFlags         ( DynFlags(..) )
  36 import StaticFlags      ( opt_PprStyle_Debug )
  37 import StaticFlags      ( opt_SpecInlineJoinPoints )
  38 import BasicTypes       ( Activation(..) )
  39 import Maybes           ( orElse, catMaybes, isJust, isNothing )
  40 import Util
  41 import List             ( nubBy, partition )
  42 import UniqSupply
  43 import Outputable
  44 import FastString
  45 import UniqFM
  46 import MonadUtils
  47 import Control.Monad    ( zipWithM )
  48 \end{code}
  49
  50 -----------------------------------------------------
  51                         Game plan
  52 -----------------------------------------------------
  53
  54 Consider
  55         drop n []     = []
  56         drop 0 xs     = []
  57         drop n (x:xs) = drop (n-1) xs
  58
  59 After the first time round, we could pass n unboxed.  This happens in
  60 numerical code too.  Here's what it looks like in Core:
  61
  62         drop n xs = case xs of
  63                       []     -> []
  64                       (y:ys) -> case n of
  65                                   I# n# -> case n# of
  66                                              0 -> []
  67                                              _ -> drop (I# (n# -# 1#)) xs
  68
  69 Notice that the recursive call has an explicit constructor as argument.
  70 Noticing this, we can make a specialised version of drop
  71
  72         RULE: drop (I# n#) xs ==> drop' n# xs
  73
  74         drop' n# xs = let n = I# n# in ...orig RHS...
  75
  76 Now the simplifier will apply the specialisation in the rhs of drop', giving
  77
  78         drop' n# xs = case xs of
  79                       []     -> []
  80                       (y:ys) -> case n# of
  81                                   0 -> []
  82                                   _ -> drop (n# -# 1#) xs
  83
  84 Much better!
  85
  86 We'd also like to catch cases where a parameter is carried along unchanged,
  87 but evaluated each time round the loop:
  88
  89         f i n = if i>0 || i>n then i else f (i*2) n
  90
  91 Here f isn't strict in n, but we'd like to avoid evaluating it each iteration.
  92 In Core, by the time we've w/wd (f is strict in i) we get
  93
  94         f i# n = case i# ># 0 of
  95                    False -> I# i#
  96                    True  -> case n of n' { I# n# ->
  97                             case i# ># n# of
  98                                 False -> I# i#
  99                                 True  -> f (i# *# 2#) n'
 100
 101 At the call to f, we see that the argument, n is know to be (I# n#),
 102 and n is evaluated elsewhere in the body of f, so we can play the same
 103 trick as above.
 104
 105
 106 Note [Reboxing]
 107 ~~~~~~~~~~~~~~~
 108 We must be careful not to allocate the same constructor twice.  Consider
 109         f p = (...(case p of (a,b) -> e)...p...,
 110                ...let t = (r,s) in ...t...(f t)...)
 111 At the recursive call to f, we can see that t is a pair.  But we do NOT want
 112 to make a specialised copy:
 113         f' a b = let p = (a,b) in (..., ...)
 114 because now t is allocated by the caller, then r and s are passed to the
 115 recursive call, which allocates the (r,s) pair again.
 116
 117 This happens if
 118   (a) the argument p is used in other than a case-scrutinsation way.
 119   (b) the argument to the call is not a 'fresh' tuple; you have to
 120         look into its unfolding to see that it's a tuple
 121
 122 Hence the "OR" part of Note [Good arguments] below.
 123
 124 ALTERNATIVE 2: pass both boxed and unboxed versions.  This no longer saves
 125 allocation, but does perhaps save evals. In the RULE we'd have
 126 something like
 127
 128   f (I# x#) = f' (I# x#) x#
 129
 130 If at the call site the (I# x) was an unfolding, then we'd have to
 131 rely on CSE to eliminate the duplicate allocation.... This alternative
 132 doesn't look attractive enough to pursue.
 133
 134 ALTERNATIVE 3: ignore the reboxing problem.  The trouble is that
 135 the conservative reboxing story prevents many useful functions from being
 136 specialised.  Example:
 137         foo :: Maybe Int -> Int -> Int
 138         foo   (Just m) 0 = 0
 139         foo x@(Just m) n = foo x (n-m)
 140 Here the use of 'x' will clearly not require boxing in the specialised function.
 141
 142 The strictness analyser has the same problem, in fact.  Example:
 143         f p@(a,b) = ...
 144 If we pass just 'a' and 'b' to the worker, it might need to rebox the
 145 pair to create (a,b).  A more sophisticated analysis might figure out
 146 precisely the cases in which this could happen, but the strictness
 147 analyser does no such analysis; it just passes 'a' and 'b', and hopes
 148 for the best.
 149
 150 So my current choice is to make SpecConstr similarly aggressive, and
 151 ignore the bad potential of reboxing.
 152
 153
 154 Note [Good arguments]
 155 ~~~~~~~~~~~~~~~~~~~~~
 156 So we look for
 157
 158 * A self-recursive function.  Ignore mutual recursion for now,
 159   because it's less common, and the code is simpler for self-recursion.
 160
 161 * EITHER
 162
 163    a) At a recursive call, one or more parameters is an explicit
 164       constructor application
 165         AND
 166       That same parameter is scrutinised by a case somewhere in
 167       the RHS of the function
 168
 169   OR
 170
 171     b) At a recursive call, one or more parameters has an unfolding
 172        that is an explicit constructor application
 173         AND
 174       That same parameter is scrutinised by a case somewhere in
 175       the RHS of the function
 176         AND
 177       Those are the only uses of the parameter (see Note [Reboxing])
 178
 179
 180 What to abstract over
 181 ~~~~~~~~~~~~~~~~~~~~~
 182 There's a bit of a complication with type arguments.  If the call
 183 site looks like
 184
 185         f p = ...f ((:) [a] x xs)...
 186
 187 then our specialised function look like
 188
 189         f_spec x xs = let p = (:) [a] x xs in ....as before....
 190
 191 This only makes sense if either
 192   a) the type variable 'a' is in scope at the top of f, or
 193   b) the type variable 'a' is an argument to f (and hence fs)
 194
 195 Actually, (a) may hold for value arguments too, in which case
 196 we may not want to pass them.  Supose 'x' is in scope at f's
 197 defn, but xs is not.  Then we'd like
 198
 199         f_spec xs = let p = (:) [a] x xs in ....as before....
 200
 201 Similarly (b) may hold too.  If x is already an argument at the
 202 call, no need to pass it again.
 203
 204 Finally, if 'a' is not in scope at the call site, we could abstract
 205 it as we do the term variables:
 206
 207         f_spec a x xs = let p = (:) [a] x xs in ...as before...
 208
 209 So the grand plan is:
 210
 211         * abstract the call site to a constructor-only pattern
 212           e.g.  C x (D (f p) (g q))  ==>  C s1 (D s2 s3)
 213
 214         * Find the free variables of the abstracted pattern
 215
 216         * Pass these variables, less any that are in scope at
 217           the fn defn.  But see Note [Shadowing] below.
 218
 219
 220 NOTICE that we only abstract over variables that are not in scope,
 221 so we're in no danger of shadowing variables used in "higher up"
 222 in f_spec's RHS.
 223
 224
 225 Note [Shadowing]
 226 ~~~~~~~~~~~~~~~~
 227 In this pass we gather up usage information that may mention variables
 228 that are bound between the usage site and the definition site; or (more
 229 seriously) may be bound to something different at the definition site.
 230 For example:
 231
 232         f x = letrec g y v = let x = ...
 233                              in ...(g (a,b) x)...
 234
 235 Since 'x' is in scope at the call site, we may make a rewrite rule that
 236 looks like
 237         RULE forall a,b. g (a,b) x = ...
 238 But this rule will never match, because it's really a different 'x' at
 239 the call site -- and that difference will be manifest by the time the
 240 simplifier gets to it.  [A worry: the simplifier doesn't *guarantee*
 241 no-shadowing, so perhaps it may not be distinct?]
 242
 243 Anyway, the rule isn't actually wrong, it's just not useful.  One possibility
 244 is to run deShadowBinds before running SpecConstr, but instead we run the
 245 simplifier.  That gives the simplest possible program for SpecConstr to
 246 chew on; and it virtually guarantees no shadowing.
 247
 248 Note [Specialising for constant parameters]
 249 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 250 This one is about specialising on a *constant* (but not necessarily
 251 constructor) argument
 252
 253     foo :: Int -> (Int -> Int) -> Int
 254     foo 0 f = 0
 255     foo m f = foo (f m) (+1)
 256
 257 It produces
 258
 259     lvl_rmV :: GHC.Base.Int -> GHC.Base.Int
 260     lvl_rmV =
 261       \ (ds_dlk :: GHC.Base.Int) ->
 262         case ds_dlk of wild_alH { GHC.Base.I# x_alG ->
 263         GHC.Base.I# (GHC.Prim.+# x_alG 1)
 264
 265     T.$wfoo :: GHC.Prim.Int# -> (GHC.Base.Int -> GHC.Base.Int) ->
 266     GHC.Prim.Int#
 267     T.$wfoo =
 268       \ (ww_sme :: GHC.Prim.Int#) (w_smg :: GHC.Base.Int -> GHC.Base.Int) ->
 269         case ww_sme of ds_Xlw {
 270           __DEFAULT ->
 271         case w_smg (GHC.Base.I# ds_Xlw) of w1_Xmo { GHC.Base.I# ww1_Xmz ->
 272         T.$wfoo ww1_Xmz lvl_rmV
 273         };
 274           0 -> 0
 275         }
 276
 277 The recursive call has lvl_rmV as its argument, so we could create a specialised copy
 278 with that argument baked in; that is, not passed at all.   Now it can perhaps be inlined.
 279
 280 When is this worth it?  Call the constant 'lvl'
 281 - If 'lvl' has an unfolding that is a constructor, see if the corresponding
 282   parameter is scrutinised anywhere in the body.
 283
 284 - If 'lvl' has an unfolding that is a inlinable function, see if the corresponding
 285   parameter is applied (...to enough arguments...?)
 286
 287   Also do this is if the function has RULES?
 288
 289 Also
 290
 291 Note [Specialising for lambda parameters]
 292 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 293     foo :: Int -> (Int -> Int) -> Int
 294     foo 0 f = 0
 295     foo m f = foo (f m) (\n -> n-m)
 296
 297 This is subtly different from the previous one in that we get an
 298 explicit lambda as the argument:
 299
 300     T.$wfoo :: GHC.Prim.Int# -> (GHC.Base.Int -> GHC.Base.Int) ->
 301     GHC.Prim.Int#
 302     T.$wfoo =
 303       \ (ww_sm8 :: GHC.Prim.Int#) (w_sma :: GHC.Base.Int -> GHC.Base.Int) ->
 304         case ww_sm8 of ds_Xlr {
 305           __DEFAULT ->
 306         case w_sma (GHC.Base.I# ds_Xlr) of w1_Xmf { GHC.Base.I# ww1_Xmq ->
 307         T.$wfoo
 308           ww1_Xmq
 309           (\ (n_ad3 :: GHC.Base.Int) ->
 310              case n_ad3 of wild_alB { GHC.Base.I# x_alA ->
 311              GHC.Base.I# (GHC.Prim.-# x_alA ds_Xlr)
 312              })
 313         };
 314           0 -> 0
 315         }
 316
 317 I wonder if SpecConstr couldn't be extended to handle this? After all,
 318 lambda is a sort of constructor for functions and perhaps it already
 319 has most of the necessary machinery?
 320
 321 Furthermore, there's an immediate win, because you don't need to allocate the lamda
 322 at the call site; and if perchance it's called in the recursive call, then you
 323 may avoid allocating it altogether.  Just like for constructors.
 324
 325 Looks cool, but probably rare...but it might be easy to implement.
 326
 327
 328 Note [SpecConstr for casts]
 329 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 330 Consider
 331     data family T a :: *
 332     data instance T Int = T Int
 333
 334     foo n = ...
 335        where
 336          go (T 0) = 0
 337          go (T n) = go (T (n-1))
 338
 339 The recursive call ends up looking like
 340         go (T (I# ...) `cast` g)
 341 So we want to spot the construtor application inside the cast.
 342 That's why we have the Cast case in argToPat
 343
 344 Note [Local recursive groups]
 345 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 346 For a *local* recursive group, we can see all the calls to the
 347 function, so we seed the specialisation loop from the calls in the
 348 body, not from the calls in the RHS.  Consider:
 349
 350   bar m n = foo n (n,n) (n,n) (n,n) (n,n)
 351    where
 352      foo n p q r s
 353        | n == 0    = m
 354        | n > 3000  = case p of { (p1,p2) -> foo (n-1) (p2,p1) q r s }
 355        | n > 2000  = case q of { (q1,q2) -> foo (n-1) p (q2,q1) r s }
 356        | n > 1000  = case r of { (r1,r2) -> foo (n-1) p q (r2,r1) s }
 357        | otherwise = case s of { (s1,s2) -> foo (n-1) p q r (s2,s1) }
 358
 359 If we start with the RHSs of 'foo', we get lots and lots of specialisations,
 360 most of which are not needed.  But if we start with the (single) call
 361 in the rhs of 'bar' we get exactly one fully-specialised copy, and all
 362 the recursive calls go to this fully-specialised copy. Indeed, the original
 363 function is later collected as dead code.  This is very important in
 364 specialising the loops arising from stream fusion, for example in NDP where
 365 we were getting literally hundreds of (mostly unused) specialisations of
 366 a local function.
 367
 368 Note [Do not specialise diverging functions]
 369 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 370 Specialising a function that just diverges is a waste of code.
 371 Furthermore, it broke GHC (simpl014) thus:
 372    {-# STR Sb #-}
 373    f = \x. case x of (a,b) -> f x
 374 If we specialise f we get
 375    f = \x. case x of (a,b) -> fspec a b
 376 But fspec doesn't have decent strictnes info.  As it happened,
 377 (f x) :: IO t, so the state hack applied and we eta expanded fspec,
 378 and hence f.  But now f's strictness is less than its arity, which
 379 breaks an invariant.
 380
 381 -----------------------------------------------------
 382                 Stuff not yet handled
 383 -----------------------------------------------------
 384
 385 Here are notes arising from Roman's work that I don't want to lose.
 386
 387 Example 1
 388 ~~~~~~~~~
 389     data T a = T !a
 390
 391     foo :: Int -> T Int -> Int
 392     foo 0 t = 0
 393     foo x t | even x    = case t of { T n -> foo (x-n) t }
 394             | otherwise = foo (x-1) t
 395
 396 SpecConstr does no specialisation, because the second recursive call
 397 looks like a boxed use of the argument.  A pity.
 398
 399     $wfoo_sFw :: GHC.Prim.Int# -> T.T GHC.Base.Int -> GHC.Prim.Int#
 400     $wfoo_sFw =
 401       \ (ww_sFo [Just L] :: GHC.Prim.Int#) (w_sFq [Just L] :: T.T GHC.Base.Int) ->
 402          case ww_sFo of ds_Xw6 [Just L] {
 403            __DEFAULT ->
 404                 case GHC.Prim.remInt# ds_Xw6 2 of wild1_aEF [Dead Just A] {
 405                   __DEFAULT -> $wfoo_sFw (GHC.Prim.-# ds_Xw6 1) w_sFq;
 406                   0 ->
 407                     case w_sFq of wild_Xy [Just L] { T.T n_ad5 [Just U(L)] ->
 408                     case n_ad5 of wild1_aET [Just A] { GHC.Base.I# y_aES [Just L] ->
 409                     $wfoo_sFw (GHC.Prim.-# ds_Xw6 y_aES) wild_Xy
 410                     } } };
 411            0 -> 0
 412
 413 Example 2
 414 ~~~~~~~~~
 415     data a :*: b = !a :*: !b
 416     data T a = T !a
 417
 418     foo :: (Int :*: T Int) -> Int
 419     foo (0 :*: t) = 0
 420     foo (x :*: t) | even x    = case t of { T n -> foo ((x-n) :*: t) }
 421                   | otherwise = foo ((x-1) :*: t)
 422
 423 Very similar to the previous one, except that the parameters are now in
 424 a strict tuple. Before SpecConstr, we have
 425
 426     $wfoo_sG3 :: GHC.Prim.Int# -> T.T GHC.Base.Int -> GHC.Prim.Int#
 427     $wfoo_sG3 =
 428       \ (ww_sFU [Just L] :: GHC.Prim.Int#) (ww_sFW [Just L] :: T.T
 429     GHC.Base.Int) ->
 430         case ww_sFU of ds_Xws [Just L] {
 431           __DEFAULT ->
 432         case GHC.Prim.remInt# ds_Xws 2 of wild1_aEZ [Dead Just A] {
 433           __DEFAULT ->
 434             case ww_sFW of tpl_B2 [Just L] { T.T a_sFo [Just A] ->
 435             $wfoo_sG3 (GHC.Prim.-# ds_Xws 1) tpl_B2             -- $wfoo1
 436             };
 437           0 ->
 438             case ww_sFW of wild_XB [Just A] { T.T n_ad7 [Just S(L)] ->
 439             case n_ad7 of wild1_aFd [Just L] { GHC.Base.I# y_aFc [Just L] ->
 440             $wfoo_sG3 (GHC.Prim.-# ds_Xws y_aFc) wild_XB        -- $wfoo2
 441             } } };
 442           0 -> 0 }
 443
 444 We get two specialisations:
 445 "SC:$wfoo1" [0] __forall {a_sFB :: GHC.Base.Int sc_sGC :: GHC.Prim.Int#}
 446                   Foo.$wfoo sc_sGC (Foo.T @ GHC.Base.Int a_sFB)
 447                   = Foo.$s$wfoo1 a_sFB sc_sGC ;
 448 "SC:$wfoo2" [0] __forall {y_aFp :: GHC.Prim.Int# sc_sGC :: GHC.Prim.Int#}
 449                   Foo.$wfoo sc_sGC (Foo.T @ GHC.Base.Int (GHC.Base.I# y_aFp))
 450                   = Foo.$s$wfoo y_aFp sc_sGC ;
 451
 452 But perhaps the first one isn't good.  After all, we know that tpl_B2 is
 453 a T (I# x) really, because T is strict and Int has one constructor.  (We can't
 454 unbox the strict fields, becuase T is polymorphic!)
 455
 456
 457
 458 %************************************************************************
 459 %*                                                                      *
 460 \subsection{Top level wrapper stuff}
 461 %*                                                                      *
 462 %************************************************************************
 463
 464 \begin{code}
 465 specConstrProgram :: DynFlags -> UniqSupply -> [CoreBind] -> [CoreBind]
 466 specConstrProgram dflags us binds = fst $ initUs us (go (initScEnv dflags) binds)
 467   where
 468     go _   []           = return []
 469     go env (bind:binds) = do (env', bind') <- scTopBind env bind
 470                              binds' <- go env' binds
 471                              return (bind' : binds')
 472 \end{code}
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection{Environment: goes downwards}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 \begin{code}
 482 data ScEnv = SCE { sc_size  :: Maybe Int,       -- Size threshold
 483                    sc_count :: Maybe Int,       -- Max # of specialisations for any one fn
 484
 485                    sc_subst :: Subst,           -- Current substitution
 486                                                 -- Maps InIds to OutExprs
 487
 488                    sc_how_bound :: HowBoundEnv,
 489                         -- Binds interesting non-top-level variables
 490                         -- Domain is OutVars (*after* applying the substitution)
 491
 492                    sc_vals  :: ValueEnv
 493                         -- Domain is OutIds (*after* applying the substitution)
 494                         -- Used even for top-level bindings (but not imported ones)
 495              }
 496
 497 ---------------------
 498 -- As we go, we apply a substitution (sc_subst) to the current term
 499 type InExpr = CoreExpr          -- _Before_ applying the subst
 500
 501 type OutExpr = CoreExpr         -- _After_ applying the subst
 502 type OutId   = Id
 503 type OutVar  = Var
 504
 505 ---------------------
 506 type HowBoundEnv = VarEnv HowBound      -- Domain is OutVars
 507
 508 ---------------------
 509 type ValueEnv = IdEnv Value             -- Domain is OutIds
 510 data Value    = ConVal AltCon [CoreArg] -- _Saturated_ constructors
 511               | LambdaVal               -- Inlinable lambdas or PAPs
 512
 513 instance Outputable Value where
 514    ppr (ConVal con args) = ppr con <+> interpp'SP args
 515    ppr LambdaVal         = ptext (sLit "<Lambda>")
 516
 517 ---------------------
 518 initScEnv :: DynFlags -> ScEnv
 519 initScEnv dflags
 520   = SCE { sc_size = specConstrThreshold dflags,
 521           sc_count = specConstrCount dflags,
 522           sc_subst = emptySubst,
 523           sc_how_bound = emptyVarEnv,
 524           sc_vals = emptyVarEnv }
 525
 526 data HowBound = RecFun  -- These are the recursive functions for which
 527                         -- we seek interesting call patterns
 528
 529               | RecArg  -- These are those functions' arguments, or their sub-components;
 530                         -- we gather occurrence information for these
 531
 532 instance Outputable HowBound where
 533   ppr RecFun = text "RecFun"
 534   ppr RecArg = text "RecArg"
 535
 536 lookupHowBound :: ScEnv -> Id -> Maybe HowBound
 537 lookupHowBound env id = lookupVarEnv (sc_how_bound env) id
 538
 539 scSubstId :: ScEnv -> Id -> CoreExpr
 540 scSubstId env v = lookupIdSubst (sc_subst env) v
 541
 542 scSubstTy :: ScEnv -> Type -> Type
 543 scSubstTy env ty = substTy (sc_subst env) ty
 544
 545 zapScSubst :: ScEnv -> ScEnv
 546 zapScSubst env = env { sc_subst = zapSubstEnv (sc_subst env) }
 547
 548 extendScInScope :: ScEnv -> [Var] -> ScEnv
 549         -- Bring the quantified variables into scope
 550 extendScInScope env qvars = env { sc_subst = extendInScopeList (sc_subst env) qvars }
 551
 552         -- Extend the substitution
 553 extendScSubst :: ScEnv -> Var -> OutExpr -> ScEnv
 554 extendScSubst env var expr = env { sc_subst = extendSubst (sc_subst env) var expr }
 555
 556 extendScSubstList :: ScEnv -> [(Var,OutExpr)] -> ScEnv
 557 extendScSubstList env prs = env { sc_subst = extendSubstList (sc_subst env) prs }
 558
 559 extendHowBound :: ScEnv -> [Var] -> HowBound -> ScEnv
 560 extendHowBound env bndrs how_bound
 561   = env { sc_how_bound = extendVarEnvList (sc_how_bound env)
 562                             [(bndr,how_bound) | bndr <- bndrs] }
 563
 564 extendBndrsWith :: HowBound -> ScEnv -> [Var] -> (ScEnv, [Var])
 565 extendBndrsWith how_bound env bndrs
 566   = (env { sc_subst = subst', sc_how_bound = hb_env' }, bndrs')
 567   where
 568     (subst', bndrs') = substBndrs (sc_subst env) bndrs
 569     hb_env' = sc_how_bound env `extendVarEnvList`
 570                     [(bndr,how_bound) | bndr <- bndrs']
 571
 572 extendBndrWith :: HowBound -> ScEnv -> Var -> (ScEnv, Var)
 573 extendBndrWith how_bound env bndr
 574   = (env { sc_subst = subst', sc_how_bound = hb_env' }, bndr')
 575   where
 576     (subst', bndr') = substBndr (sc_subst env) bndr
 577     hb_env' = extendVarEnv (sc_how_bound env) bndr' how_bound
 578
 579 extendRecBndrs :: ScEnv -> [Var] -> (ScEnv, [Var])
 580 extendRecBndrs env bndrs  = (env { sc_subst = subst' }, bndrs')
 581                       where
 582                         (subst', bndrs') = substRecBndrs (sc_subst env) bndrs
 583
 584 extendBndr :: ScEnv -> Var -> (ScEnv, Var)
 585 extendBndr  env bndr  = (env { sc_subst = subst' }, bndr')
 586                       where
 587                         (subst', bndr') = substBndr (sc_subst env) bndr
 588
 589 extendValEnv :: ScEnv -> Id -> Maybe Value -> ScEnv
 590 extendValEnv env _  Nothing   = env
 591 extendValEnv env id (Just cv) = env { sc_vals = extendVarEnv (sc_vals env) id cv }
 592
 593 extendCaseBndrs :: ScEnv -> Id -> AltCon -> [Var] -> (ScEnv, [Var])
 594 -- When we encounter
 595 --      case scrut of b
 596 --          C x y -> ...
 597 -- we want to bind b, to (C x y)
 598 -- NB1: Extends only the sc_vals part of the envt
 599 -- NB2: Kill the dead-ness info on the pattern binders x,y, since
 600 --      they are potentially made alive by the [b -> C x y] binding
 601 extendCaseBndrs env case_bndr con alt_bndrs
 602   | isDeadBinder case_bndr
 603   = (env, alt_bndrs)
 604   | otherwise
 605   = (env1, map zap alt_bndrs)
 606         -- NB: We used to bind v too, if scrut = (Var v); but
 607         --     the simplifer has already done this so it seems
 608         --     redundant to do so here
 609         -- case scrut of
 610         --      Var v  -> extendValEnv env1 v cval
 611         --      _other -> env1
 612  where
 613    zap v | isTyVar v = v                -- See NB2 above
 614          | otherwise = zapIdOccInfo v
 615    env1 = extendValEnv env case_bndr cval
 616    cval = case con of
 617                 DEFAULT    -> Nothing
 618                 LitAlt {}  -> Just (ConVal con [])
 619                 DataAlt {} -> Just (ConVal con vanilla_args)
 620                       where
 621                         vanilla_args = map Type (tyConAppArgs (idType case_bndr)) ++
 622                                        varsToCoreExprs alt_bndrs
 623 \end{code}
 624
 625
 626 %************************************************************************
 627 %*                                                                      *
 628 \subsection{Usage information: flows upwards}
 629 %*                                                                      *
 630 %************************************************************************
 631
 632 \begin{code}
 633 data ScUsage
 634    = SCU {
 635         scu_calls :: CallEnv,           -- Calls
 636                                         -- The functions are a subset of the
 637                                         --      RecFuns in the ScEnv
 638
 639         scu_occs :: !(IdEnv ArgOcc)     -- Information on argument occurrences
 640      }                                  -- The domain is OutIds
 641
 642 type CallEnv = IdEnv [Call]
 643 type Call = (ValueEnv, [CoreArg])
 644         -- The arguments of the call, together with the
 645         -- env giving the constructor bindings at the call site
 646
 647 nullUsage :: ScUsage
 648 nullUsage = SCU { scu_calls = emptyVarEnv, scu_occs = emptyVarEnv }
 649
 650 combineCalls :: CallEnv -> CallEnv -> CallEnv
 651 combineCalls = plusVarEnv_C (++)
 652
 653 combineUsage :: ScUsage -> ScUsage -> ScUsage
 654 combineUsage u1 u2 = SCU { scu_calls = combineCalls (scu_calls u1) (scu_calls u2),
 655                            scu_occs  = plusVarEnv_C combineOcc (scu_occs u1) (scu_occs u2) }
 656
 657 combineUsages :: [ScUsage] -> ScUsage
 658 combineUsages [] = nullUsage
 659 combineUsages us = foldr1 combineUsage us
 660
 661 lookupOcc :: ScUsage -> OutVar -> (ScUsage, ArgOcc)
 662 lookupOcc (SCU { scu_calls = sc_calls, scu_occs = sc_occs }) bndr
 663   = (SCU {scu_calls = sc_calls, scu_occs = delVarEnv sc_occs bndr},
 664      lookupVarEnv sc_occs bndr `orElse` NoOcc)
 665
 666 lookupOccs :: ScUsage -> [OutVar] -> (ScUsage, [ArgOcc])
 667 lookupOccs (SCU { scu_calls = sc_calls, scu_occs = sc_occs }) bndrs
 668   = (SCU {scu_calls = sc_calls, scu_occs = delVarEnvList sc_occs bndrs},
 669      [lookupVarEnv sc_occs b `orElse` NoOcc | b <- bndrs])
 670
 671 data ArgOcc = NoOcc     -- Doesn't occur at all; or a type argument
 672             | UnkOcc    -- Used in some unknown way
 673
 674             | ScrutOcc (UniqFM [ArgOcc])        -- See Note [ScrutOcc]
 675
 676             | BothOcc   -- Definitely taken apart, *and* perhaps used in some other way
 677
 678 {-      Note  [ScrutOcc]
 679
 680 An occurrence of ScrutOcc indicates that the thing, or a `cast` version of the thing,
 681 is *only* taken apart or applied.
 682
 683   Functions, literal: ScrutOcc emptyUFM
 684   Data constructors:  ScrutOcc subs,
 685
 686 where (subs :: UniqFM [ArgOcc]) gives usage of the *pattern-bound* components,
 687 The domain of the UniqFM is the Unique of the data constructor
 688
 689 The [ArgOcc] is the occurrences of the *pattern-bound* components
 690 of the data structure.  E.g.
 691         data T a = forall b. MkT a b (b->a)
 692 A pattern binds b, x::a, y::b, z::b->a, but not 'a'!
 693
 694 -}
 695
 696 instance Outputable ArgOcc where
 697   ppr (ScrutOcc xs) = ptext (sLit "scrut-occ") <> ppr xs
 698   ppr UnkOcc        = ptext (sLit "unk-occ")
 699   ppr BothOcc       = ptext (sLit "both-occ")
 700   ppr NoOcc         = ptext (sLit "no-occ")
 701
 702 -- Experimentally, this vesion of combineOcc makes ScrutOcc "win", so
 703 -- that if the thing is scrutinised anywhere then we get to see that
 704 -- in the overall result, even if it's also used in a boxed way
 705 -- This might be too agressive; see Note [Reboxing] Alternative 3
 706 combineOcc :: ArgOcc -> ArgOcc -> ArgOcc
 707 combineOcc NoOcc         occ           = occ
 708 combineOcc occ           NoOcc         = occ
 709 combineOcc (ScrutOcc xs) (ScrutOcc ys) = ScrutOcc (plusUFM_C combineOccs xs ys)
 710 combineOcc _occ          (ScrutOcc ys) = ScrutOcc ys
 711 combineOcc (ScrutOcc xs) _occ          = ScrutOcc xs
 712 combineOcc UnkOcc        UnkOcc        = UnkOcc
 713 combineOcc _        _                  = BothOcc
 714
 715 combineOccs :: [ArgOcc] -> [ArgOcc] -> [ArgOcc]
 716 combineOccs xs ys = zipWithEqual "combineOccs" combineOcc xs ys
 717
 718 setScrutOcc :: ScEnv -> ScUsage -> OutExpr -> ArgOcc -> ScUsage
 719 -- _Overwrite_ the occurrence info for the scrutinee, if the scrutinee
 720 -- is a variable, and an interesting variable
 721 setScrutOcc env usg (Cast e _) occ = setScrutOcc env usg e occ
 722 setScrutOcc env usg (Note _ e) occ = setScrutOcc env usg e occ
 723 setScrutOcc env usg (Var v)    occ
 724   | Just RecArg <- lookupHowBound env v = usg { scu_occs = extendVarEnv (scu_occs usg) v occ }
 725   | otherwise                           = usg
 726 setScrutOcc _env usg _other _occ        -- Catch-all
 727   = usg
 728
 729 conArgOccs :: ArgOcc -> AltCon -> [ArgOcc]
 730 -- Find usage of components of data con; returns [UnkOcc...] if unknown
 731 -- See Note [ScrutOcc] for the extra UnkOccs in the vanilla datacon case
 732
 733 conArgOccs (ScrutOcc fm) (DataAlt dc)
 734   | Just pat_arg_occs <- lookupUFM fm dc
 735   = [UnkOcc | _ <- dataConUnivTyVars dc] ++ pat_arg_occs
 736
 737 conArgOccs _other _con = repeat UnkOcc
 738 \end{code}
 739
 740 %************************************************************************
 741 %*                                                                      *
 742 \subsection{The main recursive function}
 743 %*                                                                      *
 744 %************************************************************************
 745
 746 The main recursive function gathers up usage information, and
 747 creates specialised versions of functions.
 748
 749 \begin{code}
 750 scExpr, scExpr' :: ScEnv -> CoreExpr -> UniqSM (ScUsage, CoreExpr)
 751         -- The unique supply is needed when we invent
 752         -- a new name for the specialised function and its args
 753
 754 scExpr env e = scExpr' env e
 755
 756
 757 scExpr' env (Var v)     = case scSubstId env v of
 758                             Var v' -> return (varUsage env v' UnkOcc, Var v')
 759                             e'     -> scExpr (zapScSubst env) e'
 760
 761 scExpr' env (Type t)    = return (nullUsage, Type (scSubstTy env t))
 762 scExpr' _   e@(Lit {})  = return (nullUsage, e)
 763 scExpr' env (Note n e)  = do (usg,e') <- scExpr env e
 764                              return (usg, Note n e')
 765 scExpr' env (Cast e co) = do (usg, e') <- scExpr env e
 766                              return (usg, Cast e' (scSubstTy env co))
 767 scExpr' env e@(App _ _) = scApp env (collectArgs e)
 768 scExpr' env (Lam b e)   = do let (env', b') = extendBndr env b
 769                              (usg, e') <- scExpr env' e
 770                              return (usg, Lam b' e')
 771
 772 scExpr' env (Case scrut b ty alts)
 773   = do  { (scrut_usg, scrut') <- scExpr env scrut
 774         ; case isValue (sc_vals env) scrut' of
 775                 Just (ConVal con args) -> sc_con_app con args scrut'
 776                 _other                 -> sc_vanilla scrut_usg scrut'
 777         }
 778   where
 779     sc_con_app con args scrut'  -- Known constructor; simplify
 780         = do { let (_, bs, rhs) = findAlt con alts
 781                    alt_env' = extendScSubstList env ((b,scrut') : bs `zip` trimConArgs con args)
 782              ; scExpr alt_env' rhs }
 783
 784     sc_vanilla scrut_usg scrut' -- Normal case
 785      = do { let (alt_env,b') = extendBndrWith RecArg env b
 786                         -- Record RecArg for the components
 787
 788           ; (alt_usgs, alt_occs, alts')
 789                 <- mapAndUnzip3M (sc_alt alt_env scrut' b') alts
 790
 791           ; let (alt_usg, b_occ) = lookupOcc (combineUsages alt_usgs) b'
 792                 scrut_occ        = foldr combineOcc b_occ alt_occs
 793                 scrut_usg'       = setScrutOcc env scrut_usg scrut' scrut_occ
 794                 -- The combined usage of the scrutinee is given
 795                 -- by scrut_occ, which is passed to scScrut, which
 796                 -- in turn treats a bare-variable scrutinee specially
 797
 798           ; return (alt_usg `combineUsage` scrut_usg',
 799                     Case scrut' b' (scSubstTy env ty) alts') }
 800
 801     sc_alt env _scrut' b' (con,bs,rhs)
 802       = do { let (env1, bs1)  = extendBndrsWith RecArg env bs
 803                  (env2, bs2) = extendCaseBndrs env1 b' con bs1
 804            ; (usg,rhs') <- scExpr env2 rhs
 805            ; let (usg', arg_occs) = lookupOccs usg bs2
 806                  scrut_occ = case con of
 807                                 DataAlt dc -> ScrutOcc (unitUFM dc arg_occs)
 808                                 _          -> ScrutOcc emptyUFM
 809            ; return (usg', scrut_occ, (con, bs2, rhs')) }
 810
 811 scExpr' env (Let (NonRec bndr rhs) body)
 812   | isTyVar bndr        -- Type-lets may be created by doBeta
 813   = scExpr' (extendScSubst env bndr rhs) body
 814   | otherwise
 815   = do  { let (body_env, bndr') = extendBndr env bndr
 816         ; (rhs_usg, (_, args', rhs_body', _)) <- scRecRhs env (bndr',rhs)
 817         ; let rhs' = mkLams args' rhs_body'
 818
 819         ; if not opt_SpecInlineJoinPoints || null args' || isEmptyVarEnv (scu_calls rhs_usg) then do
 820             do  {       -- Vanilla case
 821                   let body_env2 = extendValEnv body_env bndr' (isValue (sc_vals env) rhs')
 822                         -- Record if the RHS is a value
 823                 ; (body_usg, body') <- scExpr body_env2 body
 824                 ; return (body_usg `combineUsage` rhs_usg, Let (NonRec bndr' rhs') body') }
 825           else  -- For now, just brutally inline the join point
 826             do { let body_env2 = extendScSubst env bndr rhs'
 827                ; scExpr body_env2 body } }
 828
 829
 830 {-  Old code
 831             do  {       -- Join-point case
 832                   let body_env2 = extendHowBound body_env [bndr'] RecFun
 833                         -- If the RHS of this 'let' contains calls
 834                         -- to recursive functions that we're trying
 835                         -- to specialise, then treat this let too
 836                         -- as one to specialise
 837                 ; (body_usg, body') <- scExpr body_env2 body
 838
 839                 ; (spec_usg, _, specs) <- specialise env (scu_calls body_usg) ([], rhs_info)
 840
 841                 ; return (body_usg { scu_calls = scu_calls body_usg `delVarEnv` bndr' }
 842                           `combineUsage` rhs_usg `combineUsage` spec_usg,
 843                           mkLets [NonRec b r | (b,r) <- specInfoBinds rhs_info specs] body')
 844         }
 845 -}
 846
 847 -- A *local* recursive group: see Note [Local recursive groups]
 848 scExpr' env (Let (Rec prs) body)
 849   = do  { let (bndrs,rhss) = unzip prs
 850               (rhs_env1,bndrs') = extendRecBndrs env bndrs
 851               rhs_env2 = extendHowBound rhs_env1 bndrs' RecFun
 852
 853         ; (rhs_usgs, rhs_infos) <- mapAndUnzipM (scRecRhs rhs_env2) (bndrs' `zip` rhss)
 854         ; (body_usg, body')     <- scExpr rhs_env2 body
 855
 856         -- NB: start specLoop from body_usg
 857         ; (spec_usg, specs) <- specLoop rhs_env2 (scu_calls body_usg) rhs_infos nullUsage
 858                                         [SI [] 0 (Just usg) | usg <- rhs_usgs]
 859
 860         ; let all_usg = spec_usg `combineUsage` body_usg
 861               bind'   = Rec (concat (zipWith specInfoBinds rhs_infos specs))
 862
 863         ; return (all_usg { scu_calls = scu_calls all_usg `delVarEnvList` bndrs' },
 864                   Let bind' body') }
 865
 866 -----------------------------------
 867 scApp :: ScEnv -> (InExpr, [InExpr]) -> UniqSM (ScUsage, CoreExpr)
 868
 869 scApp env (Var fn, args)        -- Function is a variable
 870   = ASSERT( not (null args) )
 871     do  { args_w_usgs <- mapM (scExpr env) args
 872         ; let (arg_usgs, args') = unzip args_w_usgs
 873               arg_usg = combineUsages arg_usgs
 874         ; case scSubstId env fn of
 875             fn'@(Lam {}) -> scExpr (zapScSubst env) (doBeta fn' args')
 876                         -- Do beta-reduction and try again
 877
 878             Var fn' -> return (arg_usg `combineUsage` fn_usg, mkApps (Var fn') args')
 879                 where
 880                   fn_usg = case lookupHowBound env fn' of
 881                                 Just RecFun -> SCU { scu_calls = unitVarEnv fn' [(sc_vals env, args')],
 882                                                      scu_occs  = emptyVarEnv }
 883                                 Just RecArg -> SCU { scu_calls = emptyVarEnv,
 884                                                      scu_occs  = unitVarEnv fn' (ScrutOcc emptyUFM) }
 885                                 Nothing     -> nullUsage
 886
 887
 888             other_fn' -> return (arg_usg, mkApps other_fn' args') }
 889                 -- NB: doing this ignores any usage info from the substituted
 890                 --     function, but I don't think that matters.  If it does
 891                 --     we can fix it.
 892   where
 893     doBeta :: OutExpr -> [OutExpr] -> OutExpr
 894     -- ToDo: adjust for System IF
 895     doBeta (Lam bndr body) (arg : args) = Let (NonRec bndr arg) (doBeta body args)
 896     doBeta fn              args         = mkApps fn args
 897
 898 -- The function is almost always a variable, but not always.
 899 -- In particular, if this pass follows float-in,
 900 -- which it may, we can get
 901 --      (let f = ...f... in f) arg1 arg2
 902 scApp env (other_fn, args)
 903   = do  { (fn_usg,   fn')   <- scExpr env other_fn
 904         ; (arg_usgs, args') <- mapAndUnzipM (scExpr env) args
 905         ; return (combineUsages arg_usgs `combineUsage` fn_usg, mkApps fn' args') }
 906
 907 ----------------------
 908 scTopBind :: ScEnv -> CoreBind -> UniqSM (ScEnv, CoreBind)
 909 scTopBind env (Rec prs)
 910   | Just threshold <- sc_size env
 911   , not (all (couldBeSmallEnoughToInline threshold) rhss)
 912                 -- No specialisation
 913   = do  { let (rhs_env,bndrs') = extendRecBndrs env bndrs
 914         ; (_, rhss') <- mapAndUnzipM (scExpr rhs_env) rhss
 915         ; return (rhs_env, Rec (bndrs' `zip` rhss')) }
 916   | otherwise   -- Do specialisation
 917   = do  { let (rhs_env1,bndrs') = extendRecBndrs env bndrs
 918               rhs_env2 = extendHowBound rhs_env1 bndrs' RecFun
 919
 920         ; (rhs_usgs, rhs_infos) <- mapAndUnzipM (scRecRhs rhs_env2) (bndrs' `zip` rhss)
 921         ; let rhs_usg = combineUsages rhs_usgs
 922
 923         ; (_, specs) <- specLoop rhs_env2 (scu_calls rhs_usg) rhs_infos nullUsage
 924                                  [SI [] 0 Nothing | _ <- bndrs]
 925
 926         ; return (rhs_env1,  -- For the body of the letrec, delete the RecFun business
 927                   Rec (concat (zipWith specInfoBinds rhs_infos specs))) }
 928   where
 929     (bndrs,rhss) = unzip prs
 930
 931 scTopBind env (NonRec bndr rhs)
 932   = do  { (_, rhs') <- scExpr env rhs
 933         ; let (env1, bndr') = extendBndr env bndr
 934               env2 = extendValEnv env1 bndr' (isValue (sc_vals env) rhs')
 935         ; return (env2, NonRec bndr' rhs') }
 936
 937 ----------------------
 938 scRecRhs :: ScEnv -> (OutId, InExpr) -> UniqSM (ScUsage, RhsInfo)
 939 scRecRhs env (bndr,rhs)
 940   = do  { let (arg_bndrs,body) = collectBinders rhs
 941               (body_env, arg_bndrs') = extendBndrsWith RecArg env arg_bndrs
 942         ; (body_usg, body') <- scExpr body_env body
 943         ; let (rhs_usg, arg_occs) = lookupOccs body_usg arg_bndrs'
 944         ; return (rhs_usg, (bndr, arg_bndrs', body', arg_occs)) }
 945
 946                 -- The arg_occs says how the visible,
 947                 -- lambda-bound binders of the RHS are used
 948                 -- (including the TyVar binders)
 949                 -- Two pats are the same if they match both ways
 950
 951 ----------------------
 952 specInfoBinds :: RhsInfo -> SpecInfo -> [(Id,CoreExpr)]
 953 specInfoBinds (fn, args, body, _) (SI specs _ _)
 954   = [(id,rhs) | OS _ _ id rhs <- specs] ++
 955     [(fn `addIdSpecialisations` rules, mkLams args body)]
 956   where
 957     rules = [r | OS _ r _ _ <- specs]
 958
 959 ----------------------
 960 varUsage :: ScEnv -> OutVar -> ArgOcc -> ScUsage
 961 varUsage env v use
 962   | Just RecArg <- lookupHowBound env v = SCU { scu_calls = emptyVarEnv
 963                                               , scu_occs = unitVarEnv v use }
 964   | otherwise                           = nullUsage
 965 \end{code}
 966
 967
 968 %************************************************************************
 969 %*                                                                      *
 970                 The specialiser itself
 971 %*                                                                      *
 972 %************************************************************************
 973
 974 \begin{code}
 975 type RhsInfo = (OutId, [OutVar], OutExpr, [ArgOcc])
 976         -- Info about the *original* RHS of a binding we are specialising
 977         -- Original binding f = \xs.body
 978         -- Plus info about usage of arguments
 979
 980 data SpecInfo = SI [OneSpec]            -- The specialisations we have generated
 981                    Int                  -- Length of specs; used for numbering them
 982                    (Maybe ScUsage)      -- Nothing => we have generated specialisations
 983                                         --            from calls in the *original* RHS
 984                                         -- Just cs => we haven't, and this is the usage
 985                                         --            of the original RHS
 986
 987         -- One specialisation: Rule plus definition
 988 data OneSpec  = OS CallPat              -- Call pattern that generated this specialisation
 989                    CoreRule             -- Rule connecting original id with the specialisation
 990                    OutId OutExpr        -- Spec id + its rhs
 991
 992
 993 specLoop :: ScEnv
 994          -> CallEnv
 995          -> [RhsInfo]
 996          -> ScUsage -> [SpecInfo]               -- One per binder; acccumulating parameter
 997          -> UniqSM (ScUsage, [SpecInfo])        -- ...ditto...
 998 specLoop env all_calls rhs_infos usg_so_far specs_so_far
 999   = do  { specs_w_usg <- zipWithM (specialise env all_calls) rhs_infos specs_so_far
1000         ; let (new_usg_s, all_specs) = unzip specs_w_usg
1001               new_usg   = combineUsages new_usg_s
1002               new_calls = scu_calls new_usg
1003               all_usg   = usg_so_far `combineUsage` new_usg
1004         ; if isEmptyVarEnv new_calls then
1005                 return (all_usg, all_specs)
1006           else
1007                 specLoop env new_calls rhs_infos all_usg all_specs }
1008
1009 specialise
1010    :: ScEnv
1011    -> CallEnv                           -- Info on calls
1012    -> RhsInfo
1013    -> SpecInfo                          -- Original RHS plus patterns dealt with
1014    -> UniqSM (ScUsage, SpecInfo)        -- New specialised versions and their usage
1015
1016 -- Note: the rhs here is the optimised version of the original rhs
1017 -- So when we make a specialised copy of the RHS, we're starting
1018 -- from an RHS whose nested functions have been optimised already.
1019
1020 specialise env bind_calls (fn, arg_bndrs, body, arg_occs)
1021                           spec_info@(SI specs spec_count mb_unspec)
1022   | not (isBottomingId fn)      -- Note [Do not specialise diverging functions]
1023   , notNull arg_bndrs           -- Only specialise functions
1024   , Just all_calls <- lookupVarEnv bind_calls fn
1025   = do  { (boring_call, pats) <- callsToPats env specs arg_occs all_calls
1026 --      ; pprTrace "specialise" (vcat [ppr fn <+> ppr arg_occs,
1027 --                                      text "calls" <+> ppr all_calls,
1028 --                                      text "good pats" <+> ppr pats])  $
1029 --        return ()
1030
1031                 -- Bale out if too many specialisations
1032                 -- Rather a hacky way to do so, but it'll do for now
1033         ; let spec_count' = length pats + spec_count
1034         ; case sc_count env of
1035             Just max | spec_count' > max
1036                 -> WARN( True, msg ) return (nullUsage, spec_info)
1037                 where
1038                    msg = vcat [ sep [ ptext (sLit "SpecConstr: specialisation of") <+> quotes (ppr fn)
1039                                     , nest 2 (ptext (sLit "limited by bound of")) <+> int max ]
1040                               , ptext (sLit "Use -fspec-constr-count=n to set the bound")
1041                               , extra ]
1042                    extra | not opt_PprStyle_Debug = ptext (sLit "Use -dppr-debug to see specialisations")
1043                          | otherwise = ptext (sLit "Specialisations:") <+> ppr (pats ++ [p | OS p _ _ _ <- specs])
1044
1045             _normal_case -> do {
1046
1047           (spec_usgs, new_specs) <- mapAndUnzipM (spec_one env fn arg_bndrs body)
1048                                                  (pats `zip` [spec_count..])
1049
1050         ; let spec_usg = combineUsages spec_usgs
1051               (new_usg, mb_unspec')
1052                   = case mb_unspec of
1053                       Just rhs_usg | boring_call -> (spec_usg `combineUsage` rhs_usg, Nothing)
1054                       _                          -> (spec_usg,                      mb_unspec)
1055
1056         ; return (new_usg, SI (new_specs ++ specs) spec_count' mb_unspec') } }
1057   | otherwise
1058   = return (nullUsage, spec_info)               -- The boring case
1059
1060
1061 ---------------------
1062 spec_one :: ScEnv
1063          -> OutId       -- Function
1064          -> [Var]       -- Lambda-binders of RHS; should match patterns
1065          -> CoreExpr    -- Body of the original function
1066          -> (CallPat, Int)
1067          -> UniqSM (ScUsage, OneSpec)   -- Rule and binding
1068
1069 -- spec_one creates a specialised copy of the function, together
1070 -- with a rule for using it.  I'm very proud of how short this
1071 -- function is, considering what it does :-).
1072
1073 {-
1074   Example
1075
1076      In-scope: a, x::a
1077      f = /\b \y::[(a,b)] -> ....f (b,c) ((:) (a,(b,c)) (x,v) (h w))...
1078           [c::*, v::(b,c) are presumably bound by the (...) part]
1079   ==>
1080      f_spec = /\ b c \ v::(b,c) hw::[(a,(b,c))] ->
1081                   (...entire body of f...) [b -> (b,c),
1082                                             y -> ((:) (a,(b,c)) (x,v) hw)]
1083
1084      RULE:  forall b::* c::*,           -- Note, *not* forall a, x
1085                    v::(b,c),
1086                    hw::[(a,(b,c))] .
1087
1088             f (b,c) ((:) (a,(b,c)) (x,v) hw) = f_spec b c v hw
1089 -}
1090
1091 spec_one env fn arg_bndrs body (call_pat@(qvars, pats), rule_number)
1092   = do  {       -- Specialise the body
1093           let spec_env = extendScSubstList (extendScInScope env qvars)
1094                                            (arg_bndrs `zip` pats)
1095         ; (spec_usg, spec_body) <- scExpr spec_env body
1096
1097 --      ; pprTrace "spec_one" (ppr fn <+> vcat [text "pats" <+> ppr pats,
1098 --                      text "calls" <+> (ppr (scu_calls spec_usg))])
1099 --        (return ())
1100
1101                 -- And build the results
1102         ; spec_uniq <- getUniqueUs
1103         ; let (spec_lam_args, spec_call_args) = mkWorkerArgs qvars body_ty
1104                 -- Usual w/w hack to avoid generating
1105                 -- a spec_rhs of unlifted type and no args
1106
1107               fn_name   = idName fn
1108               fn_loc    = nameSrcSpan fn_name
1109               spec_occ  = mkSpecOcc (nameOccName fn_name)
1110               rule_name = mkFastString ("SC:" ++ showSDoc (ppr fn <> int rule_number))
1111               spec_rhs  = mkLams spec_lam_args spec_body
1112               spec_id   = mkUserLocal spec_occ spec_uniq (mkPiTypes spec_lam_args body_ty) fn_loc
1113               body_ty   = exprType spec_body
1114               rule_rhs  = mkVarApps (Var spec_id) spec_call_args
1115               rule      = mkLocalRule rule_name specConstrActivation fn_name qvars pats rule_rhs
1116         ; return (spec_usg, OS call_pat rule spec_id spec_rhs) }
1117
1118 -- In which phase should the specialise-constructor rules be active?
1119 -- Originally I made them always-active, but Manuel found that
1120 -- this defeated some clever user-written rules.  So Plan B
1121 -- is to make them active only in Phase 0; after all, currently,
1122 -- the specConstr transformation is only run after the simplifier
1123 -- has reached Phase 0.  In general one would want it to be
1124 -- flag-controllable, but for now I'm leaving it baked in
1125 --                                      [SLPJ Oct 01]
1126 specConstrActivation :: Activation
1127 specConstrActivation = ActiveAfter 0    -- Baked in; see comments above
1128 \end{code}
1129
1130 %************************************************************************
1131 %*                                                                      *
1132 \subsection{Argument analysis}
1133 %*                                                                      *
1134 %************************************************************************
1135
1136 This code deals with analysing call-site arguments to see whether
1137 they are constructor applications.
1138
1139
1140 \begin{code}
1141 type CallPat = ([Var], [CoreExpr])      -- Quantified variables and arguments
1142
1143
1144 callsToPats :: ScEnv -> [OneSpec] -> [ArgOcc] -> [Call] -> UniqSM (Bool, [CallPat])
1145         -- Result has no duplicate patterns,
1146         -- nor ones mentioned in done_pats
1147         -- Bool indicates that there was at least one boring pattern
1148 callsToPats env done_specs bndr_occs calls
1149   = do  { mb_pats <- mapM (callToPats env bndr_occs) calls
1150
1151         ; let good_pats :: [([Var], [CoreArg])]
1152               good_pats = catMaybes mb_pats
1153               done_pats = [p | OS p _ _ _ <- done_specs]
1154               is_done p = any (samePat p) done_pats
1155
1156         ; return (any isNothing mb_pats,
1157                   filterOut is_done (nubBy samePat good_pats)) }
1158
1159 callToPats :: ScEnv -> [ArgOcc] -> Call -> UniqSM (Maybe CallPat)
1160         -- The [Var] is the variables to quantify over in the rule
1161         --      Type variables come first, since they may scope
1162         --      over the following term variables
1163         -- The [CoreExpr] are the argument patterns for the rule
1164 callToPats env bndr_occs (con_env, args)
1165   | length args < length bndr_occs      -- Check saturated
1166   = return Nothing
1167   | otherwise
1168   = do  { let in_scope = substInScope (sc_subst env)
1169         ; prs <- argsToPats in_scope con_env (args `zip` bndr_occs)
1170         ; let (interesting_s, pats) = unzip prs
1171               pat_fvs = varSetElems (exprsFreeVars pats)
1172               qvars   = filterOut (`elemInScopeSet` in_scope) pat_fvs
1173                 -- Quantify over variables that are not in sccpe
1174                 -- at the call site
1175                 -- See Note [Shadowing] at the top
1176
1177               (tvs, ids) = partition isTyVar qvars
1178               qvars'     = tvs ++ ids
1179                 -- Put the type variables first; the type of a term
1180                 -- variable may mention a type variable
1181
1182         ; -- pprTrace "callToPats"  (ppr args $$ ppr prs $$ ppr bndr_occs) $
1183           if or interesting_s
1184           then return (Just (qvars', pats))
1185           else return Nothing }
1186
1187     -- argToPat takes an actual argument, and returns an abstracted
1188     -- version, consisting of just the "constructor skeleton" of the
1189     -- argument, with non-constructor sub-expression replaced by new
1190     -- placeholder variables.  For example:
1191     --    C a (D (f x) (g y))  ==>  C p1 (D p2 p3)
1192
1193 argToPat :: InScopeSet                  -- What's in scope at the fn defn site
1194          -> ValueEnv                    -- ValueEnv at the call site
1195          -> CoreArg                     -- A call arg (or component thereof)
1196          -> ArgOcc
1197          -> UniqSM (Bool, CoreArg)
1198 -- Returns (interesting, pat),
1199 -- where pat is the pattern derived from the argument
1200 --            intersting=True if the pattern is non-trivial (not a variable or type)
1201 -- E.g.         x:xs         --> (True, x:xs)
1202 --              f xs         --> (False, w)        where w is a fresh wildcard
1203 --              (f xs, 'c')  --> (True, (w, 'c'))  where w is a fresh wildcard
1204 --              \x. x+y      --> (True, \x. x+y)
1205 --              lvl7         --> (True, lvl7)      if lvl7 is bound
1206 --                                                 somewhere further out
1207
1208 argToPat _in_scope _val_env arg@(Type {}) _arg_occ
1209   = return (False, arg)
1210
1211 argToPat in_scope val_env (Note _ arg) arg_occ
1212   = argToPat in_scope val_env arg arg_occ
1213         -- Note [Notes in call patterns]
1214         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1215         -- Ignore Notes.  In particular, we want to ignore any InlineMe notes
1216         -- Perhaps we should not ignore profiling notes, but I'm going to
1217         -- ride roughshod over them all for now.
1218         --- See Note [Notes in RULE matching] in Rules
1219
1220 argToPat in_scope val_env (Let _ arg) arg_occ
1221   = argToPat in_scope val_env arg arg_occ
1222         -- Look through let expressions
1223         -- e.g.         f (let v = rhs in \y -> ...v...)
1224         -- Here we can specialise for f (\y -> ...)
1225         -- because the rule-matcher will look through the let.
1226
1227 argToPat in_scope val_env (Cast arg co) arg_occ
1228   = do  { (interesting, arg') <- argToPat in_scope val_env arg arg_occ
1229         ; let (ty1,ty2) = coercionKind co
1230         ; if not interesting then
1231                 wildCardPat ty2
1232           else do
1233         { -- Make a wild-card pattern for the coercion
1234           uniq <- getUniqueUs
1235         ; let co_name = mkSysTvName uniq (fsLit "sg")
1236               co_var = mkCoVar co_name (mkCoKind ty1 ty2)
1237         ; return (interesting, Cast arg' (mkTyVarTy co_var)) } }
1238
1239 {-      Disabling lambda specialisation for now
1240         It's fragile, and the spec_loop can be infinite
1241 argToPat in_scope val_env arg arg_occ
1242   | is_value_lam arg
1243   = return (True, arg)
1244   where
1245     is_value_lam (Lam v e)      -- Spot a value lambda, even if
1246         | isId v = True         -- it is inside a type lambda
1247         | otherwise = is_value_lam e
1248     is_value_lam other = False
1249 -}
1250
1251   -- Check for a constructor application
1252   -- NB: this *precedes* the Var case, so that we catch nullary constrs
1253 argToPat in_scope val_env arg arg_occ
1254   | Just (ConVal dc args) <- isValue val_env arg
1255   , case arg_occ of
1256         ScrutOcc _ -> True              -- Used only by case scrutinee
1257         BothOcc    -> case arg of       -- Used elsewhere
1258                         App {} -> True  --     see Note [Reboxing]
1259                         _other -> False
1260         _other     -> False     -- No point; the arg is not decomposed
1261   = do  { args' <- argsToPats in_scope val_env (args `zip` conArgOccs arg_occ dc)
1262         ; return (True, mk_con_app dc (map snd args')) }
1263
1264   -- Check if the argument is a variable that
1265   -- is in scope at the function definition site
1266   -- It's worth specialising on this if
1267   --    (a) it's used in an interesting way in the body
1268   --    (b) we know what its value is
1269 argToPat in_scope val_env (Var v) arg_occ
1270   | case arg_occ of { UnkOcc -> False; _other -> True },        -- (a)
1271     is_value                                                    -- (b)
1272   = return (True, Var v)
1273   where
1274     is_value
1275         | isLocalId v = v `elemInScopeSet` in_scope
1276                         && isJust (lookupVarEnv val_env v)
1277                 -- Local variables have values in val_env
1278         | otherwise   = isValueUnfolding (idUnfolding v)
1279                 -- Imports have unfoldings
1280
1281 --      I'm really not sure what this comment means
1282 --      And by not wild-carding we tend to get forall'd
1283 --      variables that are in soope, which in turn can
1284 --      expose the weakness in let-matching
1285 --      See Note [Matching lets] in Rules
1286
1287   -- Check for a variable bound inside the function.
1288   -- Don't make a wild-card, because we may usefully share
1289   --    e.g.  f a = let x = ... in f (x,x)
1290   -- NB: this case follows the lambda and con-app cases!!
1291 -- argToPat _in_scope _val_env (Var v) _arg_occ
1292 --   = return (False, Var v)
1293         -- SLPJ : disabling this to avoid proliferation of versions
1294         -- also works badly when thinking about seeding the loop
1295         -- from the body of the let
1296         --       f x y = letrec g z = ... in g (x,y)
1297         -- We don't want to specialise for that *particular* x,y
1298
1299   -- The default case: make a wild-card
1300 argToPat _in_scope _val_env arg _arg_occ
1301   = wildCardPat (exprType arg)
1302
1303 wildCardPat :: Type -> UniqSM (Bool, CoreArg)
1304 wildCardPat ty = do { uniq <- getUniqueUs
1305                     ; let id = mkSysLocal (fsLit "sc") uniq ty
1306                     ; return (False, Var id) }
1307
1308 argsToPats :: InScopeSet -> ValueEnv
1309            -> [(CoreArg, ArgOcc)]
1310            -> UniqSM [(Bool, CoreArg)]
1311 argsToPats in_scope val_env args
1312   = mapM do_one args
1313   where
1314     do_one (arg,occ) = argToPat in_scope val_env arg occ
1315 \end{code}
1316
1317
1318 \begin{code}
1319 isValue :: ValueEnv -> CoreExpr -> Maybe Value
1320 isValue _env (Lit lit)
1321   = Just (ConVal (LitAlt lit) [])
1322
1323 isValue env (Var v)
1324   | Just stuff <- lookupVarEnv env v
1325   = Just stuff  -- You might think we could look in the idUnfolding here
1326                 -- but that doesn't take account of which branch of a
1327                 -- case we are in, which is the whole point
1328
1329   | not (isLocalId v) && isCheapUnfolding unf
1330   = isValue env (unfoldingTemplate unf)
1331   where
1332     unf = idUnfolding v
1333         -- However we do want to consult the unfolding
1334         -- as well, for let-bound constructors!
1335
1336 isValue env (Lam b e)
1337   | isTyVar b = case isValue env e of
1338                   Just _  -> Just LambdaVal
1339                   Nothing -> Nothing
1340   | otherwise = Just LambdaVal
1341
1342 isValue _env expr       -- Maybe it's a constructor application
1343   | (Var fun, args) <- collectArgs expr
1344   = case isDataConWorkId_maybe fun of
1345
1346         Just con | args `lengthAtLeast` dataConRepArity con
1347                 -- Check saturated; might be > because the
1348                 --                  arity excludes type args
1349                 -> Just (ConVal (DataAlt con) args)
1350
1351         _other | valArgCount args < idArity fun
1352                 -- Under-applied function
1353                -> Just LambdaVal        -- Partial application
1354
1355         _other -> Nothing
1356
1357 isValue _env _expr = Nothing
1358
1359 mk_con_app :: AltCon -> [CoreArg] -> CoreExpr
1360 mk_con_app (LitAlt lit)  []   = Lit lit
1361 mk_con_app (DataAlt con) args = mkConApp con args
1362 mk_con_app _other _args = panic "SpecConstr.mk_con_app"
1363
1364 samePat :: CallPat -> CallPat -> Bool
1365 samePat (vs1, as1) (vs2, as2)
1366   = all2 same as1 as2
1367   where
1368     same (Var v1) (Var v2)
1369         | v1 `elem` vs1 = v2 `elem` vs2
1370         | v2 `elem` vs2 = False
1371         | otherwise     = v1 == v2
1372
1373     same (Lit l1)    (Lit l2)    = l1==l2
1374     same (App f1 a1) (App f2 a2) = same f1 f2 && same a1 a2
1375
1376     same (Type {}) (Type {}) = True     -- Note [Ignore type differences]
1377     same (Note _ e1) e2 = same e1 e2    -- Ignore casts and notes
1378     same (Cast e1 _) e2 = same e1 e2
1379     same e1 (Note _ e2) = same e1 e2
1380     same e1 (Cast e2 _) = same e1 e2
1381
1382     same e1 e2 = WARN( bad e1 || bad e2, ppr e1 $$ ppr e2)
1383                  False  -- Let, lambda, case should not occur
1384     bad (Case {}) = True
1385     bad (Let {})  = True
1386     bad (Lam {})  = True
1387     bad _other    = False
1388 \end{code}
1389
1390 Note [Ignore type differences]
1391 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1392 We do not want to generate specialisations where the call patterns
1393 differ only in their type arguments!  Not only is it utterly useless,
1394 but it also means that (with polymorphic recursion) we can generate
1395 an infinite number of specialisations. Example is Data.Sequence.adjustTree,
1396 I think.
1397