add -fsimpleopt-before-flatten
[ghc-hetmet.git] / compiler / specialise / Specialise.lhs
1 %
2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
5
6 \begin{code}
7 module Specialise ( specProgram ) where
8
9 #include "HsVersions.h"
10
11 import Id
12 import TcType
13 import CoreMonad
14 import CoreSubst 
15 import CoreUnfold
16 import VarSet
17 import VarEnv
18 import CoreSyn
19 import Rules
20 import CoreUtils        ( exprIsTrivial, applyTypeToArgs, mkPiTypes )
21 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
22 import UniqSupply       ( UniqSM, initUs_, MonadUnique(..) )
23 import Name
24 import MkId             ( voidArgId, realWorldPrimId )
25 import Maybes           ( catMaybes, isJust )
26 import BasicTypes       
27 import HscTypes
28 import Bag
29 import Util
30 import Outputable
31 import FastString
32
33 import Data.Map (Map)
34 import qualified Data.Map as Map
35 import qualified FiniteMap as Map
36 \end{code}
37
38 %************************************************************************
39 %*                                                                      *
40 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
41 %*                                                                      *
42 %************************************************************************
43
44 These notes describe how we implement specialisation to eliminate
45 overloading.
46
47 The specialisation pass works on Core
48 syntax, complete with all the explicit dictionary application,
49 abstraction and construction as added by the type checker.  The
50 existing type checker remains largely as it is.
51
52 One important thought: the {\em types} passed to an overloaded
53 function, and the {\em dictionaries} passed are mutually redundant.
54 If the same function is applied to the same type(s) then it is sure to
55 be applied to the same dictionary(s)---or rather to the same {\em
56 values}.  (The arguments might look different but they will evaluate
57 to the same value.)
58
59 Second important thought: we know that we can make progress by
60 treating dictionary arguments as static and worth specialising on.  So
61 we can do without binding-time analysis, and instead specialise on
62 dictionary arguments and no others.
63
64 The basic idea
65 ~~~~~~~~~~~~~~
66 Suppose we have
67
68         let f = <f_rhs>
69         in <body>
70
71 and suppose f is overloaded.
72
73 STEP 1: CALL-INSTANCE COLLECTION
74
75 We traverse <body>, accumulating all applications of f to types and
76 dictionaries.
77
78 (Might there be partial applications, to just some of its types and
79 dictionaries?  In principle yes, but in practice the type checker only
80 builds applications of f to all its types and dictionaries, so partial
81 applications could only arise as a result of transformation, and even
82 then I think it's unlikely.  In any case, we simply don't accumulate such
83 partial applications.)
84
85
86 STEP 2: EQUIVALENCES
87
88 So now we have a collection of calls to f:
89         f t1 t2 d1 d2
90         f t3 t4 d3 d4
91         ...
92 Notice that f may take several type arguments.  To avoid ambiguity, we
93 say that f is called at type t1/t2 and t3/t4.
94
95 We take equivalence classes using equality of the *types* (ignoring
96 the dictionary args, which as mentioned previously are redundant).
97
98 STEP 3: SPECIALISATION
99
100 For each equivalence class, choose a representative (f t1 t2 d1 d2),
101 and create a local instance of f, defined thus:
102
103         f@t1/t2 = <f_rhs> t1 t2 d1 d2
104
105 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
106 of simplification will now result.  However we don't actually *do* that
107 simplification.  Rather, we leave it for the simplifier to do.  If we
108 *did* do it, though, we'd get more call instances from the specialised
109 RHS.  We can work out what they are by instantiating the call-instance
110 set from f's RHS with the types t1, t2.
111
112 Add this new id to f's IdInfo, to record that f has a specialised version.
113
114 Before doing any of this, check that f's IdInfo doesn't already
115 tell us about an existing instance of f at the required type/s.
116 (This might happen if specialisation was applied more than once, or
117 it might arise from user SPECIALIZE pragmas.)
118
119 Recursion
120 ~~~~~~~~~
121 Wait a minute!  What if f is recursive?  Then we can't just plug in
122 its right-hand side, can we?
123
124 But it's ok.  The type checker *always* creates non-recursive definitions
125 for overloaded recursive functions.  For example:
126
127         f x = f (x+x)           -- Yes I know its silly
128
129 becomes
130
131         f a (d::Num a) = let p = +.sel a d
132                          in
133                          letrec fl (y::a) = fl (p y y)
134                          in
135                          fl
136
137 We still have recusion for non-overloaded functions which we
138 speciailise, but the recursive call should get specialised to the
139 same recursive version.
140
141
142 Polymorphism 1
143 ~~~~~~~~~~~~~~
144
145 All this is crystal clear when the function is applied to *constant
146 types*; that is, types which have no type variables inside.  But what if
147 it is applied to non-constant types?  Suppose we find a call of f at type
148 t1/t2.  There are two possibilities:
149
150 (a) The free type variables of t1, t2 are in scope at the definition point
151 of f.  In this case there's no problem, we proceed just as before.  A common
152 example is as follows.  Here's the Haskell:
153
154         g y = let f x = x+x
155               in f y + f y
156
157 After typechecking we have
158
159         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
160                                 in +.sel a d (f a d y) (f a d y)
161
162 Notice that the call to f is at type type "a"; a non-constant type.
163 Both calls to f are at the same type, so we can specialise to give:
164
165         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
166                                 in +.sel a d (f@a y) (f@a y)
167
168
169 (b) The other case is when the type variables in the instance types
170 are *not* in scope at the definition point of f.  The example we are
171 working with above is a good case.  There are two instances of (+.sel a d),
172 but "a" is not in scope at the definition of +.sel.  Can we do anything?
173 Yes, we can "common them up", a sort of limited common sub-expression deal.
174 This would give:
175
176         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
177                                     f@a (x::a) = +.sel@a x x
178                                 in +.sel@a (f@a y) (f@a y)
179
180 This can save work, and can't be spotted by the type checker, because
181 the two instances of +.sel weren't originally at the same type.
182
183 Further notes on (b)
184
185 * There are quite a few variations here.  For example, the defn of
186   +.sel could be floated ouside the \y, to attempt to gain laziness.
187   It certainly mustn't be floated outside the \d because the d has to
188   be in scope too.
189
190 * We don't want to inline f_rhs in this case, because
191 that will duplicate code.  Just commoning up the call is the point.
192
193 * Nothing gets added to +.sel's IdInfo.
194
195 * Don't bother unless the equivalence class has more than one item!
196
197 Not clear whether this is all worth it.  It is of course OK to
198 simply discard call-instances when passing a big lambda.
199
200 Polymorphism 2 -- Overloading
201 ~~~~~~~~~~~~~~
202 Consider a function whose most general type is
203
204         f :: forall a b. Ord a => [a] -> b -> b
205
206 There is really no point in making a version of g at Int/Int and another
207 at Int/Bool, because it's only instancing the type variable "a" which
208 buys us any efficiency. Since g is completely polymorphic in b there
209 ain't much point in making separate versions of g for the different
210 b types.
211
212 That suggests that we should identify which of g's type variables
213 are constrained (like "a") and which are unconstrained (like "b").
214 Then when taking equivalence classes in STEP 2, we ignore the type args
215 corresponding to unconstrained type variable.  In STEP 3 we make
216 polymorphic versions.  Thus:
217
218         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
219
220 We do this.
221
222
223 Dictionary floating
224 ~~~~~~~~~~~~~~~~~~~
225 Consider this
226
227         f a (d::Num a) = let g = ...
228                          in
229                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
230
231 Here, g is only called at one type, but the dictionary isn't in scope at the
232 definition point for g.  Usually the type checker would build a
233 definition for d1 which enclosed g, but the transformation system
234 might have moved d1's defn inward.  Solution: float dictionary bindings
235 outwards along with call instances.
236
237 Consider
238
239         f x = let g p q = p==q
240                   h r s = (r+s, g r s)
241               in
242               h x x
243
244
245 Before specialisation, leaving out type abstractions we have
246
247         f df x = let g :: Eq a => a -> a -> Bool
248                      g dg p q = == dg p q
249                      h :: Num a => a -> a -> (a, Bool)
250                      h dh r s = let deq = eqFromNum dh
251                                 in (+ dh r s, g deq r s)
252               in
253               h df x x
254
255 After specialising h we get a specialised version of h, like this:
256
257                     h' r s = let deq = eqFromNum df
258                              in (+ df r s, g deq r s)
259
260 But we can't naively make an instance for g from this, because deq is not in scope
261 at the defn of g.  Instead, we have to float out the (new) defn of deq
262 to widen its scope.  Notice that this floating can't be done in advance -- it only
263 shows up when specialisation is done.
264
265 User SPECIALIZE pragmas
266 ~~~~~~~~~~~~~~~~~~~~~~~
267 Specialisation pragmas can be digested by the type checker, and implemented
268 by adding extra definitions along with that of f, in the same way as before
269
270         f@t1/t2 = <f_rhs> t1 t2 d1 d2
271
272 Indeed the pragmas *have* to be dealt with by the type checker, because
273 only it knows how to build the dictionaries d1 and d2!  For example
274
275         g :: Ord a => [a] -> [a]
276         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
277
278 Here, the specialised version of g is an application of g's rhs to the
279 Ord dictionary for (Tree Int), which only the type checker can conjure
280 up.  There might not even *be* one, if (Tree Int) is not an instance of
281 Ord!  (All the other specialision has suitable dictionaries to hand
282 from actual calls.)
283
284 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
285 it is buried in a complex (as-yet-un-desugared) binding group.
286 Maybe we should say
287
288         f@t1/t2 = f* t1 t2 d1 d2
289
290 where f* is the Id f with an IdInfo which says "inline me regardless!".
291 Indeed all the specialisation could be done in this way.
292 That in turn means that the simplifier has to be prepared to inline absolutely
293 any in-scope let-bound thing.
294
295
296 Again, the pragma should permit polymorphism in unconstrained variables:
297
298         h :: Ord a => [a] -> b -> b
299         {-# SPECIALIZE h :: [Int] -> b -> b #-}
300
301 We *insist* that all overloaded type variables are specialised to ground types,
302 (and hence there can be no context inside a SPECIALIZE pragma).
303 We *permit* unconstrained type variables to be specialised to
304         - a ground type
305         - or left as a polymorphic type variable
306 but nothing in between.  So
307
308         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
309
310 is *illegal*.  (It can be handled, but it adds complication, and gains the
311 programmer nothing.)
312
313
314 SPECIALISING INSTANCE DECLARATIONS
315 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
316 Consider
317
318         instance Foo a => Foo [a] where
319                 ...
320         {-# SPECIALIZE instance Foo [Int] #-}
321
322 The original instance decl creates a dictionary-function
323 definition:
324
325         dfun.Foo.List :: forall a. Foo a -> Foo [a]
326
327 The SPECIALIZE pragma just makes a specialised copy, just as for
328 ordinary function definitions:
329
330         dfun.Foo.List@Int :: Foo [Int]
331         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
332
333 The information about what instance of the dfun exist gets added to
334 the dfun's IdInfo in the same way as a user-defined function too.
335
336
337 Automatic instance decl specialisation?
338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
339 Can instance decls be specialised automatically?  It's tricky.
340 We could collect call-instance information for each dfun, but
341 then when we specialised their bodies we'd get new call-instances
342 for ordinary functions; and when we specialised their bodies, we might get
343 new call-instances of the dfuns, and so on.  This all arises because of
344 the unrestricted mutual recursion between instance decls and value decls.
345
346 Still, there's no actual problem; it just means that we may not do all
347 the specialisation we could theoretically do.
348
349 Furthermore, instance decls are usually exported and used non-locally,
350 so we'll want to compile enough to get those specialisations done.
351
352 Lastly, there's no such thing as a local instance decl, so we can
353 survive solely by spitting out *usage* information, and then reading that
354 back in as a pragma when next compiling the file.  So for now,
355 we only specialise instance decls in response to pragmas.
356
357
358 SPITTING OUT USAGE INFORMATION
359 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
360
361 To spit out usage information we need to traverse the code collecting
362 call-instance information for all imported (non-prelude?) functions
363 and data types. Then we equivalence-class it and spit it out.
364
365 This is done at the top-level when all the call instances which escape
366 must be for imported functions and data types.
367
368 *** Not currently done ***
369
370
371 Partial specialisation by pragmas
372 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
373 What about partial specialisation:
374
375         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
376         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
377
378 or even
379
380         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
381
382 Seems quite reasonable.  Similar things could be done with instance decls:
383
384         instance (Foo a, Foo b) => Foo (a,b) where
385                 ...
386         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
387         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
388
389 Ho hum.  Things are complex enough without this.  I pass.
390
391
392 Requirements for the simplifer
393 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
394 The simplifier has to be able to take advantage of the specialisation.
395
396 * When the simplifier finds an application of a polymorphic f, it looks in
397 f's IdInfo in case there is a suitable instance to call instead.  This converts
398
399         f t1 t2 d1 d2   ===>   f_t1_t2
400
401 Note that the dictionaries get eaten up too!
402
403 * Dictionary selection operations on constant dictionaries must be
404   short-circuited:
405
406         +.sel Int d     ===>  +Int
407
408 The obvious way to do this is in the same way as other specialised
409 calls: +.sel has inside it some IdInfo which tells that if it's applied
410 to the type Int then it should eat a dictionary and transform to +Int.
411
412 In short, dictionary selectors need IdInfo inside them for constant
413 methods.
414
415 * Exactly the same applies if a superclass dictionary is being
416   extracted:
417
418         Eq.sel Int d   ===>   dEqInt
419
420 * Something similar applies to dictionary construction too.  Suppose
421 dfun.Eq.List is the function taking a dictionary for (Eq a) to
422 one for (Eq [a]).  Then we want
423
424         dfun.Eq.List Int d      ===> dEq.List_Int
425
426 Where does the Eq [Int] dictionary come from?  It is built in
427 response to a SPECIALIZE pragma on the Eq [a] instance decl.
428
429 In short, dfun Ids need IdInfo with a specialisation for each
430 constant instance of their instance declaration.
431
432 All this uses a single mechanism: the SpecEnv inside an Id
433
434
435 What does the specialisation IdInfo look like?
436 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
437
438 The SpecEnv of an Id maps a list of types (the template) to an expression
439
440         [Type]  |->  Expr
441
442 For example, if f has this SpecInfo:
443
444         [Int, a]  ->  \d:Ord Int. f' a
445
446 it means that we can replace the call
447
448         f Int t  ===>  (\d. f' t)
449
450 This chucks one dictionary away and proceeds with the
451 specialised version of f, namely f'.
452
453
454 What can't be done this way?
455 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
456 There is no way, post-typechecker, to get a dictionary for (say)
457 Eq a from a dictionary for Eq [a].  So if we find
458
459         ==.sel [t] d
460
461 we can't transform to
462
463         eqList (==.sel t d')
464
465 where
466         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
467
468 Of course, we currently have no way to automatically derive
469 eqList, nor to connect it to the Eq [a] instance decl, but you
470 can imagine that it might somehow be possible.  Taking advantage
471 of this is permanently ruled out.
472
473 Still, this is no great hardship, because we intend to eliminate
474 overloading altogether anyway!
475
476 A note about non-tyvar dictionaries
477 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
478 Some Ids have types like
479
480         forall a,b,c. Eq a -> Ord [a] -> tau
481
482 This seems curious at first, because we usually only have dictionary
483 args whose types are of the form (C a) where a is a type variable.
484 But this doesn't hold for the functions arising from instance decls,
485 which sometimes get arguements with types of form (C (T a)) for some
486 type constructor T.
487
488 Should we specialise wrt this compound-type dictionary?  We used to say
489 "no", saying:
490         "This is a heuristic judgement, as indeed is the fact that we 
491         specialise wrt only dictionaries.  We choose *not* to specialise
492         wrt compound dictionaries because at the moment the only place
493         they show up is in instance decls, where they are simply plugged
494         into a returned dictionary.  So nothing is gained by specialising
495         wrt them."
496
497 But it is simpler and more uniform to specialise wrt these dicts too;
498 and in future GHC is likely to support full fledged type signatures 
499 like
500         f :: Eq [(a,b)] => ...
501
502
503 %************************************************************************
504 %*                                                                      *
505 \subsubsection{The new specialiser}
506 %*                                                                      *
507 %************************************************************************
508
509 Our basic game plan is this.  For let(rec) bound function
510         f :: (C a, D c) => (a,b,c,d) -> Bool
511
512 * Find any specialised calls of f, (f ts ds), where 
513   ts are the type arguments t1 .. t4, and
514   ds are the dictionary arguments d1 .. d2.
515
516 * Add a new definition for f1 (say):
517
518         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
519
520   Note that we abstract over the unconstrained type arguments.
521
522 * Add the mapping
523
524         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
525
526   to the specialisations of f.  This will be used by the
527   simplifier to replace calls 
528                 (f t1 t2 t3 t4) da db
529   by
530                 (\d1 d1 -> f1 t2 t4) da db
531
532   All the stuff about how many dictionaries to discard, and what types
533   to apply the specialised function to, are handled by the fact that the
534   SpecEnv contains a template for the result of the specialisation.
535
536 We don't build *partial* specialisations for f.  For example:
537
538   f :: Eq a => a -> a -> Bool
539   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
540
541 Here, little is gained by making a specialised copy of f.
542 There's a distinct danger that the specialised version would
543 first build a dictionary for (Eq b, Eq c), and then select the (==) 
544 method from it!  Even if it didn't, not a great deal is saved.
545
546 We do, however, generate polymorphic, but not overloaded, specialisations:
547
548   f :: Eq a => [a] -> b -> b -> b
549   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
550
551 Hence, the invariant is this: 
552
553         *** no specialised version is overloaded ***
554
555
556 %************************************************************************
557 %*                                                                      *
558 \subsubsection{The exported function}
559 %*                                                                      *
560 %************************************************************************
561
562 \begin{code}
563 specProgram :: ModGuts -> CoreM ModGuts
564 specProgram guts 
565   = do { hpt_rules <- getRuleBase
566        ; let local_rules = mg_rules guts
567              rule_base = extendRuleBaseList hpt_rules (mg_rules guts)
568
569              -- Specialise the bindings of this module
570        ; (binds', uds) <- runSpecM (go (mg_binds guts))
571
572              -- Specialise imported functions 
573        ; (new_rules, spec_binds) <- specImports emptyVarSet rule_base uds
574
575        ; let final_binds | null spec_binds = binds'
576                          | otherwise       = Rec (flattenBinds spec_binds) : binds'
577                    -- Note [Glom the bindings if imported functions are specialised]
578
579        ; return (guts { mg_binds = final_binds
580                       , mg_rules = new_rules ++ local_rules }) }
581   where
582         -- We need to start with a Subst that knows all the things
583         -- that are in scope, so that the substitution engine doesn't
584         -- accidentally re-use a unique that's already in use
585         -- Easiest thing is to do it all at once, as if all the top-level
586         -- decls were mutually recursive
587     top_subst = mkEmptySubst $ mkInScopeSet $ mkVarSet $ 
588                 bindersOfBinds $ mg_binds guts
589
590     go []           = return ([], emptyUDs)
591     go (bind:binds) = do (binds', uds) <- go binds
592                          (bind', uds') <- specBind top_subst bind uds
593                          return (bind' ++ binds', uds')
594
595 specImports :: VarSet           -- Don't specialise these ones
596                                 -- See Note [Avoiding recursive specialisation]
597             -> RuleBase         -- Rules from this module and the home package
598                                 -- (but not external packages, which can change)
599             -> UsageDetails     -- Calls for imported things, and floating bindings
600             -> CoreM ( [CoreRule]   -- New rules
601                      , [CoreBind] ) -- Specialised bindings and floating bindings
602 -- See Note [Specialise imported INLINABLE things]
603 specImports done rb uds
604   = do { let import_calls = varEnvElts (ud_calls uds)
605        ; (rules, spec_binds) <- go rb import_calls
606        ; return (rules, wrapDictBinds (ud_binds uds) spec_binds) }
607   where
608     go _ [] = return ([], [])
609     go rb (CIS fn calls_for_fn : other_calls)
610       = do { (rules1, spec_binds1) <- specImport done rb fn (Map.toList calls_for_fn)
611            ; (rules2, spec_binds2) <- go (extendRuleBaseList rb rules1) other_calls
612            ; return (rules1 ++ rules2, spec_binds1 ++ spec_binds2) }
613
614 specImport :: VarSet                -- Don't specialise these
615                                     -- See Note [Avoiding recursive specialisation]
616            -> RuleBase              -- Rules from this module
617            -> Id -> [CallInfo]      -- Imported function and calls for it
618            -> CoreM ( [CoreRule]    -- New rules
619                     , [CoreBind] )  -- Specialised bindings
620 specImport done rb fn calls_for_fn
621   | fn `elemVarSet` done
622   = return ([], [])     -- No warning.  This actually happens all the time
623                         -- when specialising a recursive function, becuase
624                         -- the RHS of the specialised function contains a recursive
625                         -- call to the original function
626
627   | isInlinablePragma (idInlinePragma fn)
628   , Just rhs <- maybeUnfoldingTemplate (realIdUnfolding fn)
629   = do {     -- Get rules from the external package state
630              -- We keep doing this in case we "page-fault in" 
631              -- more rules as we go along
632        ; hsc_env <- getHscEnv
633        ; eps <- liftIO $ hscEPS hsc_env 
634        ; let full_rb = unionRuleBase rb (eps_rule_base eps)
635              rules_for_fn = getRules full_rb fn 
636
637        ; (rules1, spec_pairs, uds) <- runSpecM $
638               specCalls emptySubst rules_for_fn calls_for_fn fn rhs
639        ; let spec_binds1 = [NonRec b r | (b,r) <- spec_pairs]
640              -- After the rules kick in we may get recursion, but 
641              -- we rely on a global GlomBinds to sort that out later
642              -- See Note [Glom the bindings if imported functions are specialised]
643        
644               -- Now specialise any cascaded calls
645        ; (rules2, spec_binds2) <- specImports (extendVarSet done fn) 
646                                               (extendRuleBaseList rb rules1)
647                                               uds
648
649        ; return (rules2 ++ rules1, spec_binds2 ++ spec_binds1) }
650
651   | otherwise
652   = WARN( True, ptext (sLit "specImport discard") <+> ppr fn <+> ppr calls_for_fn )
653     return ([], [])    
654 \end{code}
655
656 Note [Specialise imported INLINABLE things]
657 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
658 We specialise INLINABLE things but not INLINE things.  The latter
659 should be inlined bodily, so not much point in specialising them.
660 Moreover, we risk lots of orphan modules from vigorous specialisation.
661
662 Note [Glom the bindings if imported functions are specialised]
663 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
664 Suppose we have an imported, *recursive*, INLINABLE function 
665    f :: Eq a => a -> a
666    f = /\a \d x. ...(f a d)...
667 In the module being compiled we have
668    g x = f (x::Int)
669 Now we'll make a specialised function
670    f_spec :: Int -> Int
671    f_spec = \x -> ...(f Int dInt)...
672    {-# RULE  f Int _ = f_spec #-}
673    g = \x. f Int dInt x
674 Note that f_spec doesn't look recursive
675 After rewriting with the RULE, we get
676    f_spec = \x -> ...(f_spec)...
677 BUT since f_spec was non-recursive before it'll *stay* non-recursive.
678 The occurrence analyser never turns a NonRec into a Rec.  So we must
679 make sure that f_spec is recursive.  Easiest thing is to make all
680 the specialisations for imported bindings recursive.
681
682
683 Note [Avoiding recursive specialisation]
684 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
685 When we specialise 'f' we may find new overloaded calls to 'g', 'h' in
686 'f's RHS.  So we want to specialise g,h.  But we don't want to
687 specialise f any more!  It's possible that f's RHS might have a
688 recursive yet-more-specialised call, so we'd diverge in that case.
689 And if the call is to the same type, one specialisation is enough.
690 Avoiding this recursive specialisation loop is the reason for the 
691 'done' VarSet passed to specImports and specImport.
692
693 %************************************************************************
694 %*                                                                      *
695 \subsubsection{@specExpr@: the main function}
696 %*                                                                      *
697 %************************************************************************
698
699 \begin{code}
700 specVar :: Subst -> Id -> CoreExpr
701 specVar subst v = lookupIdSubst (text "specVar") subst v
702
703 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
704 -- We carry a substitution down:
705 --      a) we must clone any binding that might float outwards,
706 --         to avoid name clashes
707 --      b) we carry a type substitution to use when analysing
708 --         the RHS of specialised bindings (no type-let!)
709
710 ---------------- First the easy cases --------------------
711 specExpr subst (Type ty) = return (Type (CoreSubst.substTy subst ty), emptyUDs)
712 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
713 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
714 specExpr subst (Cast e co) = do
715     (e', uds) <- specExpr subst e
716     return ((Cast e' (CoreSubst.substTy subst co)), uds)
717 specExpr subst (Note note body) = do
718     (body', uds) <- specExpr subst body
719     return (Note (specNote subst note) body', uds)
720
721
722 ---------------- Applications might generate a call instance --------------------
723 specExpr subst expr@(App {})
724   = go expr []
725   where
726     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
727                                (fun', uds_app) <- go fun (arg':args)
728                                return (App fun' arg', uds_arg `plusUDs` uds_app)
729
730     go (Var f)       args = case specVar subst f of
731                                 Var f' -> return (Var f', mkCallUDs f' args)
732                                 e'     -> return (e', emptyUDs) -- I don't expect this!
733     go other         _    = specExpr subst other
734
735 ---------------- Lambda/case require dumping of usage details --------------------
736 specExpr subst e@(Lam _ _) = do
737     (body', uds) <- specExpr subst' body
738     let (free_uds, dumped_dbs) = dumpUDs bndrs' uds 
739     return (mkLams bndrs' (wrapDictBindsE dumped_dbs body'), free_uds)
740   where
741     (bndrs, body) = collectBinders e
742     (subst', bndrs') = substBndrs subst bndrs
743         -- More efficient to collect a group of binders together all at once
744         -- and we don't want to split a lambda group with dumped bindings
745
746 specExpr subst (Case scrut case_bndr ty alts) 
747   = do { (scrut', scrut_uds) <- specExpr subst scrut
748        ; (scrut'', case_bndr', alts', alts_uds) 
749              <- specCase subst scrut' case_bndr alts 
750        ; return (Case scrut'' case_bndr' (CoreSubst.substTy subst ty) alts'
751                 , scrut_uds `plusUDs` alts_uds) }
752
753 ---------------- Finally, let is the interesting case --------------------
754 specExpr subst (Let bind body) = do
755         -- Clone binders
756     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
757
758         -- Deal with the body
759     (body', body_uds) <- specExpr body_subst body
760
761         -- Deal with the bindings
762     (binds', uds) <- specBind rhs_subst bind' body_uds
763
764         -- All done
765     return (foldr Let body' binds', uds)
766
767 -- Must apply the type substitution to coerceions
768 specNote :: Subst -> Note -> Note
769 specNote _ note = note
770
771
772 specCase :: Subst 
773          -> CoreExpr            -- Scrutinee, already done
774          -> Id -> [CoreAlt]
775          -> SpecM ( CoreExpr    -- New scrutinee
776                   , Id
777                   , [CoreAlt]
778                   , UsageDetails)
779 specCase subst scrut' case_bndr [(con, args, rhs)]
780   | isDictId case_bndr           -- See Note [Floating dictionaries out of cases]
781   , interestingDict scrut'
782   , not (isDeadBinder case_bndr && null sc_args')
783   = do { (case_bndr_flt : sc_args_flt) <- mapM clone_me (case_bndr' : sc_args')
784
785        ; let sc_rhss = [ Case (Var case_bndr_flt) case_bndr' (idType sc_arg')
786                               [(con, args', Var sc_arg')]
787                        | sc_arg' <- sc_args' ]
788
789              -- Extend the substitution for RHS to map the *original* binders
790              -- to their floated verions.  Attach an unfolding to these floated
791              -- binders so they look interesting to interestingDict
792              mb_sc_flts :: [Maybe DictId]
793              mb_sc_flts = map (lookupVarEnv clone_env) args'
794              clone_env  = zipVarEnv sc_args' (zipWith add_unf sc_args_flt sc_rhss)
795              subst_prs  = (case_bndr, Var (add_unf case_bndr_flt scrut'))
796                         : [ (arg, Var sc_flt) 
797                           | (arg, Just sc_flt) <- args `zip` mb_sc_flts ]
798              subst_rhs' = extendIdSubstList subst_rhs subst_prs
799                                                       
800        ; (rhs',   rhs_uds)   <- specExpr subst_rhs' rhs
801        ; let scrut_bind    = mkDB (NonRec case_bndr_flt scrut')
802              case_bndr_set = unitVarSet case_bndr_flt
803              sc_binds      = [(NonRec sc_arg_flt sc_rhs, case_bndr_set)
804                              | (sc_arg_flt, sc_rhs) <- sc_args_flt `zip` sc_rhss ]
805              flt_binds     = scrut_bind : sc_binds
806              (free_uds, dumped_dbs) = dumpUDs (case_bndr':args') rhs_uds
807              all_uds = flt_binds `addDictBinds` free_uds
808              alt'    = (con, args', wrapDictBindsE dumped_dbs rhs')
809        ; return (Var case_bndr_flt, case_bndr', [alt'], all_uds) }
810   where
811     (subst_rhs, (case_bndr':args')) = substBndrs subst (case_bndr:args)
812     sc_args' = filter is_flt_sc_arg args'
813              
814     clone_me bndr = do { uniq <- getUniqueM
815                        ; return (mkUserLocal occ uniq ty loc) }
816        where
817          name = idName bndr
818          ty   = idType bndr
819          occ  = nameOccName name
820          loc  = getSrcSpan name
821
822     add_unf sc_flt sc_rhs  -- Sole purpose: make sc_flt respond True to interestingDictId
823       = setIdUnfolding sc_flt (mkSimpleUnfolding sc_rhs)
824
825     arg_set = mkVarSet args'
826     is_flt_sc_arg var =  isId var
827                       && not (isDeadBinder var)
828                       && isDictTy var_ty
829                       && not (tyVarsOfType var_ty `intersectsVarSet` arg_set)
830        where
831          var_ty = idType var
832
833
834 specCase subst scrut case_bndr alts
835   = do { (alts', uds_alts) <- mapAndCombineSM spec_alt alts
836        ; return (scrut, case_bndr', alts', uds_alts) }
837   where
838     (subst_alt, case_bndr') = substBndr subst case_bndr
839     spec_alt (con, args, rhs) = do
840           (rhs', uds) <- specExpr subst_rhs rhs
841           let (free_uds, dumped_dbs) = dumpUDs (case_bndr' : args') uds
842           return ((con, args', wrapDictBindsE dumped_dbs rhs'), free_uds)
843         where
844           (subst_rhs, args') = substBndrs subst_alt args
845 \end{code}
846
847 Note [Floating dictionaries out of cases]
848 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
849 Consider
850    g = \d. case d of { MkD sc ... -> ...(f sc)... }
851 Naively we can't float d2's binding out of the case expression,
852 because 'sc' is bound by the case, and that in turn means we can't
853 specialise f, which seems a pity.  
854
855 So we invert the case, by floating out a binding 
856 for 'sc_flt' thus:
857     sc_flt = case d of { MkD sc ... -> sc }
858 Now we can float the call instance for 'f'.  Indeed this is just
859 what'll happen if 'sc' was originally bound with a let binding,
860 but case is more efficient, and necessary with equalities. So it's
861 good to work with both.
862
863 You might think that this won't make any difference, because the
864 call instance will only get nuked by the \d.  BUT if 'g' itself is 
865 specialised, then transitively we should be able to specialise f.
866
867 In general, given
868    case e of cb { MkD sc ... -> ...(f sc)... }
869 we transform to
870    let cb_flt = e
871        sc_flt = case cb_flt of { MkD sc ... -> sc }
872    in
873    case cb_flt of bg { MkD sc ... -> ....(f sc_flt)... }
874
875 The "_flt" things are the floated binds; we use the current substitution
876 to substitute sc -> sc_flt in the RHS
877
878 %************************************************************************
879 %*                                                                      *
880                      Dealing with a binding
881 %*                                                                      *
882 %************************************************************************
883
884 \begin{code}
885 specBind :: Subst                       -- Use this for RHSs
886          -> CoreBind
887          -> UsageDetails                -- Info on how the scope of the binding
888          -> SpecM ([CoreBind],          -- New bindings
889                    UsageDetails)        -- And info to pass upstream
890
891 -- Returned UsageDetails:
892 --    No calls for binders of this bind
893 specBind rhs_subst (NonRec fn rhs) body_uds
894   = do { (rhs', rhs_uds) <- specExpr rhs_subst rhs
895        ; (fn', spec_defns, body_uds1) <- specDefn rhs_subst body_uds fn rhs
896
897        ; let pairs = spec_defns ++ [(fn', rhs')]
898                         -- fn' mentions the spec_defns in its rules, 
899                         -- so put the latter first
900
901              combined_uds = body_uds1 `plusUDs` rhs_uds
902                 -- This way round a call in rhs_uds of a function f
903                 -- at type T will override a call of f at T in body_uds1; and
904                 -- that is good because it'll tend to keep "earlier" calls
905                 -- See Note [Specialisation of dictionary functions]
906
907              (free_uds, dump_dbs, float_all) = dumpBindUDs [fn] combined_uds
908                 -- See Note [From non-recursive to recursive]
909
910              final_binds | isEmptyBag dump_dbs = [NonRec b r | (b,r) <- pairs]
911                          | otherwise = [Rec (flattenDictBinds dump_dbs pairs)]
912
913          ; if float_all then
914              -- Rather than discard the calls mentioning the bound variables
915              -- we float this binding along with the others
916               return ([], free_uds `snocDictBinds` final_binds)
917            else
918              -- No call in final_uds mentions bound variables, 
919              -- so we can just leave the binding here
920               return (final_binds, free_uds) }
921
922
923 specBind rhs_subst (Rec pairs) body_uds
924        -- Note [Specialising a recursive group]
925   = do { let (bndrs,rhss) = unzip pairs
926        ; (rhss', rhs_uds) <- mapAndCombineSM (specExpr rhs_subst) rhss
927        ; let scope_uds = body_uds `plusUDs` rhs_uds
928                        -- Includes binds and calls arising from rhss
929
930        ; (bndrs1, spec_defns1, uds1) <- specDefns rhs_subst scope_uds pairs
931
932        ; (bndrs3, spec_defns3, uds3)
933              <- if null spec_defns1  -- Common case: no specialisation
934                 then return (bndrs1, [], uds1)
935                 else do {            -- Specialisation occurred; do it again
936                           (bndrs2, spec_defns2, uds2)
937                               <- specDefns rhs_subst uds1 (bndrs1 `zip` rhss)
938                         ; return (bndrs2, spec_defns2 ++ spec_defns1, uds2) }
939
940        ; let (final_uds, dumped_dbs, float_all) = dumpBindUDs bndrs uds3
941              bind = Rec (flattenDictBinds dumped_dbs $
942                          spec_defns3 ++ zip bndrs3 rhss')
943              
944        ; if float_all then
945               return ([], final_uds `snocDictBind` bind)
946            else
947               return ([bind], final_uds) }
948
949
950 ---------------------------
951 specDefns :: Subst
952           -> UsageDetails               -- Info on how it is used in its scope
953           -> [(Id,CoreExpr)]            -- The things being bound and their un-processed RHS
954           -> SpecM ([Id],               -- Original Ids with RULES added
955                     [(Id,CoreExpr)],    -- Extra, specialised bindings
956                     UsageDetails)       -- Stuff to fling upwards from the specialised versions
957
958 -- Specialise a list of bindings (the contents of a Rec), but flowing usages
959 -- upwards binding by binding.  Example: { f = ...g ...; g = ...f .... }
960 -- Then if the input CallDetails has a specialised call for 'g', whose specialisation
961 -- in turn generates a specialised call for 'f', we catch that in this one sweep.
962 -- But not vice versa (it's a fixpoint problem).
963
964 specDefns _subst uds []
965   = return ([], [], uds)
966 specDefns subst uds ((bndr,rhs):pairs)
967   = do { (bndrs1, spec_defns1, uds1) <- specDefns subst uds pairs
968        ; (bndr1, spec_defns2, uds2)  <- specDefn subst uds1 bndr rhs
969        ; return (bndr1 : bndrs1, spec_defns1 ++ spec_defns2, uds2) }
970
971 ---------------------------
972 specDefn :: Subst
973          -> UsageDetails                -- Info on how it is used in its scope
974          -> Id -> CoreExpr              -- The thing being bound and its un-processed RHS
975          -> SpecM (Id,                  -- Original Id with added RULES
976                    [(Id,CoreExpr)],     -- Extra, specialised bindings
977                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
978
979 specDefn subst body_uds fn rhs
980   = do { let (body_uds_without_me, calls_for_me) = callsForMe fn body_uds
981              rules_for_me = idCoreRules fn
982        ; (rules, spec_defns, spec_uds) <- specCalls subst rules_for_me 
983                                                     calls_for_me fn rhs
984        ; return ( fn `addIdSpecialisations` rules
985                 , spec_defns
986                 , body_uds_without_me `plusUDs` spec_uds) }
987                 -- It's important that the `plusUDs` is this way
988                 -- round, because body_uds_without_me may bind
989                 -- dictionaries that are used in calls_for_me passed
990                 -- to specDefn.  So the dictionary bindings in
991                 -- spec_uds may mention dictionaries bound in
992                 -- body_uds_without_me
993
994 ---------------------------
995 specCalls :: Subst
996           -> [CoreRule]                 -- Existing RULES for the fn
997           -> [CallInfo] 
998           -> Id -> CoreExpr
999           -> SpecM ([CoreRule],         -- New RULES for the fn
1000                     [(Id,CoreExpr)],    -- Extra, specialised bindings
1001                     UsageDetails)       -- New usage details from the specialised RHSs
1002
1003 -- This function checks existing rules, and does not create
1004 -- duplicate ones. So the caller does not need to do this filtering.
1005 -- See 'already_covered'
1006
1007 specCalls subst rules_for_me calls_for_me fn rhs
1008         -- The first case is the interesting one
1009   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
1010   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
1011   && notNull calls_for_me               -- And there are some calls to specialise
1012   && not (isNeverActive (idInlineActivation fn))
1013         -- Don't specialise NOINLINE things
1014         -- See Note [Auto-specialisation and RULES]
1015
1016 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
1017 --      See Note [Inline specialisation] for why we do not 
1018 --      switch off specialisation for inline functions
1019
1020   = -- pprTrace "specDefn: some" (ppr fn $$ ppr calls_for_me $$ ppr rules_for_me) $
1021     do { stuff <- mapM spec_call calls_for_me
1022        ; let (spec_defns, spec_uds, spec_rules) = unzip3 (catMaybes stuff)
1023        ; return (spec_rules, spec_defns, plusUDList spec_uds) }
1024
1025   | otherwise   -- No calls or RHS doesn't fit our preconceptions
1026   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") 
1027                                  <+> ppr fn $$ _trace_doc )
1028           -- Note [Specialisation shape]
1029     -- pprTrace "specDefn: none" (ppr fn $$ ppr calls_for_me) $
1030     return ([], [], emptyUDs)
1031   where
1032     _trace_doc = vcat [ ppr rhs_tyvars, ppr n_tyvars
1033                       , ppr rhs_ids, ppr n_dicts
1034                       , ppr (idInlineActivation fn) ]
1035
1036     fn_type            = idType fn
1037     fn_arity           = idArity fn
1038     fn_unf             = realIdUnfolding fn     -- Ignore loop-breaker-ness here
1039     (tyvars, theta, _) = tcSplitSigmaTy fn_type
1040     n_tyvars           = length tyvars
1041     n_dicts            = length theta
1042     inl_prag           = idInlinePragma fn
1043     inl_act            = inlinePragmaActivation inl_prag
1044     is_local           = isLocalId fn
1045
1046         -- Figure out whether the function has an INLINE pragma
1047         -- See Note [Inline specialisations]
1048
1049     spec_arity = unfoldingArity fn_unf - n_dicts  -- Arity of the *specialised* inline rule
1050
1051     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs
1052
1053     rhs_dict_ids = take n_dicts rhs_ids
1054     body         = mkLams (drop n_dicts rhs_ids) rhs_body
1055                 -- Glue back on the non-dict lambdas
1056
1057     already_covered :: [CoreExpr] -> Bool
1058     already_covered args          -- Note [Specialisations already covered]
1059        = isJust (lookupRule (const True) realIdUnfolding 
1060                             (substInScope subst) 
1061                             fn args rules_for_me)
1062
1063     mk_ty_args :: [Maybe Type] -> [CoreExpr]
1064     mk_ty_args call_ts = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
1065                where
1066                   mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
1067                   mk_ty_arg _         (Just ty) = Type ty
1068
1069     ----------------------------------------------------------
1070         -- Specialise to one particular call pattern
1071     spec_call :: CallInfo                         -- Call instance
1072               -> SpecM (Maybe ((Id,CoreExpr),     -- Specialised definition
1073                                UsageDetails,      -- Usage details from specialised body
1074                                CoreRule))         -- Info for the Id's SpecEnv
1075     spec_call (CallKey call_ts, (call_ds, _))
1076       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
1077         
1078         -- Suppose f's defn is  f = /\ a b c -> \ d1 d2 -> rhs  
1079         -- Supppose the call is for f [Just t1, Nothing, Just t3] [dx1, dx2]
1080
1081         -- Construct the new binding
1082         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b -> rhs)
1083         -- PLUS the usage-details
1084         --      { d1' = dx1; d2' = dx2 }
1085         -- where d1', d2' are cloned versions of d1,d2, with the type substitution
1086         -- applied.  These auxiliary bindings just avoid duplication of dx1, dx2
1087         --
1088         -- Note that the substitution is applied to the whole thing.
1089         -- This is convenient, but just slightly fragile.  Notably:
1090         --      * There had better be no name clashes in a/b/c
1091         do { let
1092                 -- poly_tyvars = [b] in the example above
1093                 -- spec_tyvars = [a,c] 
1094                 -- ty_args     = [t1,b,t3]
1095                 poly_tyvars   = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
1096                 spec_tv_binds = [(tv,ty) | (tv, Just ty) <- rhs_tyvars `zip` call_ts]
1097                 spec_ty_args  = map snd spec_tv_binds
1098                 ty_args       = mk_ty_args call_ts
1099                 rhs_subst     = CoreSubst.extendTvSubstList subst spec_tv_binds
1100
1101            ; (rhs_subst1, inst_dict_ids) <- newDictBndrs rhs_subst rhs_dict_ids
1102                           -- Clone rhs_dicts, including instantiating their types
1103
1104            ; let (rhs_subst2, dx_binds) = bindAuxiliaryDicts rhs_subst1 $
1105                                           (my_zipEqual rhs_dict_ids inst_dict_ids call_ds)
1106                  inst_args = ty_args ++ map Var inst_dict_ids
1107
1108            ; if already_covered inst_args then
1109                 return Nothing
1110              else do
1111            {    -- Figure out the type of the specialised function
1112              let body_ty = applyTypeToArgs rhs fn_type inst_args
1113                  (lam_args, app_args)           -- Add a dummy argument if body_ty is unlifted
1114                    | isUnLiftedType body_ty     -- C.f. WwLib.mkWorkerArgs
1115                    = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
1116                    | otherwise = (poly_tyvars, poly_tyvars)
1117                  spec_id_ty = mkPiTypes lam_args body_ty
1118         
1119            ; spec_f <- newSpecIdSM fn spec_id_ty
1120            ; (spec_rhs, rhs_uds) <- specExpr rhs_subst2 (mkLams lam_args body)
1121            ; let
1122                 -- The rule to put in the function's specialisation is:
1123                 --      forall b, d1',d2'.  f t1 b t3 d1' d2' = f1 b  
1124                 rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
1125                 spec_env_rule = mkRule True {- Auto generated -} is_local
1126                                   rule_name
1127                                   inl_act       -- Note [Auto-specialisation and RULES]
1128                                   (idName fn)
1129                                   (poly_tyvars ++ inst_dict_ids)
1130                                   inst_args 
1131                                   (mkVarApps (Var spec_f) app_args)
1132
1133                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
1134                 final_uds = foldr consDictBind rhs_uds dx_binds
1135
1136                 --------------------------------------
1137                 -- Add a suitable unfolding if the spec_inl_prag says so
1138                 -- See Note [Inline specialisations]
1139                 spec_inl_prag 
1140                   = case inl_prag of
1141                        InlinePragma { inl_inline = Inlinable } 
1142                           -> inl_prag { inl_inline = EmptyInlineSpec }
1143                        _  -> inl_prag
1144
1145                 spec_unf
1146                   = case inlinePragmaSpec spec_inl_prag of
1147                       Inline    -> mkInlineUnfolding (Just spec_arity) spec_rhs
1148                       Inlinable -> mkInlinableUnfolding spec_rhs
1149                       _         -> NoUnfolding
1150
1151                 --------------------------------------
1152                 -- Adding arity information just propagates it a bit faster
1153                 --      See Note [Arity decrease] in Simplify
1154                 -- Copy InlinePragma information from the parent Id.
1155                 -- So if f has INLINE[1] so does spec_f
1156                 spec_f_w_arity = spec_f `setIdArity`      max 0 (fn_arity - n_dicts)
1157                                         `setInlinePragma` spec_inl_prag
1158                                         `setIdUnfolding`  spec_unf
1159
1160            ; return (Just ((spec_f_w_arity, spec_rhs), final_uds, spec_env_rule)) } }
1161       where
1162         my_zipEqual xs ys zs
1163          | debugIsOn && not (equalLength xs ys && equalLength ys zs)
1164              = pprPanic "my_zipEqual" (vcat [ ppr xs, ppr ys
1165                                             , ppr fn <+> ppr call_ts
1166                                             , ppr (idType fn), ppr theta
1167                                             , ppr n_dicts, ppr rhs_dict_ids 
1168                                             , ppr rhs])
1169          | otherwise = zip3 xs ys zs
1170
1171 bindAuxiliaryDicts
1172         :: Subst
1173         -> [(DictId,DictId,CoreExpr)]   -- (orig_dict, inst_dict, dx)
1174         -> (Subst,                      -- Substitute for all orig_dicts
1175             [CoreBind])                 -- Auxiliary bindings
1176 -- Bind any dictionary arguments to fresh names, to preserve sharing
1177 -- Substitution already substitutes orig_dict -> inst_dict
1178 bindAuxiliaryDicts subst triples = go subst [] triples
1179   where
1180     go subst binds []    = (subst, binds)
1181     go subst binds ((d, dx_id, dx) : pairs)
1182       | exprIsTrivial dx = go (extendIdSubst subst d dx) binds pairs
1183              -- No auxiliary binding necessary
1184              -- Note that we bind the *original* dict in the substitution,
1185              -- overriding any d->dx_id binding put there by substBndrs
1186
1187       | otherwise        = go subst_w_unf (NonRec dx_id dx : binds) pairs
1188       where
1189         dx_id1 = dx_id `setIdUnfolding` mkSimpleUnfolding dx
1190         subst_w_unf = extendIdSubst subst d (Var dx_id1)
1191              -- Important!  We're going to substitute dx_id1 for d
1192              -- and we want it to look "interesting", else we won't gather *any*
1193              -- consequential calls. E.g.
1194              --     f d = ...g d....
1195              -- If we specialise f for a call (f (dfun dNumInt)), we'll get 
1196              -- a consequent call (g d') with an auxiliary definition
1197              --     d' = df dNumInt
1198              -- We want that consequent call to look interesting
1199              --
1200              -- Again, note that we bind the *original* dict in the substitution,
1201              -- overriding any d->dx_id binding put there by substBndrs
1202 \end{code}
1203
1204 Note [From non-recursive to recursive]
1205 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1206 Even in the non-recursive case, if any dict-binds depend on 'fn' we might 
1207 have built a recursive knot
1208
1209       f a d x = <blah>
1210       MkUD { ud_binds = d7 = MkD ..f..
1211            , ud_calls = ...(f T d7)... }
1212
1213 The we generate
1214
1215       Rec { fs x = <blah>[T/a, d7/d]
1216             f a d x = <blah>
1217                RULE f T _ = fs
1218             d7 = ...f... }
1219
1220 Here the recursion is only through the RULE.
1221
1222  
1223 Note [Specialisation of dictionary functions]
1224 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1225 Here is a nasty example that bit us badly: see Trac #3591
1226
1227      class Eq a => C a
1228      instance Eq [a] => C [a]
1229
1230 ---------------
1231      dfun :: Eq [a] -> C [a]
1232      dfun a d = MkD a d (meth d)
1233
1234      d4 :: Eq [T] = <blah>
1235      d2 ::  C [T] = dfun T d4
1236      d1 :: Eq [T] = $p1 d2
1237      d3 ::  C [T] = dfun T d1
1238
1239 None of these definitions is recursive. What happened was that we 
1240 generated a specialisation:
1241
1242      RULE forall d. dfun T d = dT  :: C [T]
1243      dT = (MkD a d (meth d)) [T/a, d1/d]
1244         = MkD T d1 (meth d1)
1245
1246 But now we use the RULE on the RHS of d2, to get
1247
1248     d2 = dT = MkD d1 (meth d1)
1249     d1 = $p1 d2
1250
1251 and now d1 is bottom!  The problem is that when specialising 'dfun' we
1252 should first dump "below" the binding all floated dictionary bindings
1253 that mention 'dfun' itself.  So d2 and d3 (and hence d1) must be
1254 placed below 'dfun', and thus unavailable to it when specialising
1255 'dfun'.  That in turn means that the call (dfun T d1) must be
1256 discarded.  On the other hand, the call (dfun T d4) is fine, assuming
1257 d4 doesn't mention dfun.
1258
1259 But look at this:
1260
1261   class C a where { foo,bar :: [a] -> [a] }
1262
1263   instance C Int where 
1264      foo x = r_bar x    
1265      bar xs = reverse xs
1266
1267   r_bar :: C a => [a] -> [a]
1268   r_bar xs = bar (xs ++ xs)
1269
1270 That translates to:
1271
1272     r_bar a (c::C a) (xs::[a]) = bar a d (xs ++ xs)
1273
1274     Rec { $fCInt :: C Int = MkC foo_help reverse
1275           foo_help (xs::[Int]) = r_bar Int $fCInt xs }
1276
1277 The call (r_bar $fCInt) mentions $fCInt, 
1278                         which mentions foo_help, 
1279                         which mentions r_bar
1280 But we DO want to specialise r_bar at Int:
1281
1282     Rec { $fCInt :: C Int = MkC foo_help reverse
1283           foo_help (xs::[Int]) = r_bar Int $fCInt xs
1284
1285           r_bar a (c::C a) (xs::[a]) = bar a d (xs ++ xs)
1286             RULE r_bar Int _ = r_bar_Int
1287
1288           r_bar_Int xs = bar Int $fCInt (xs ++ xs)
1289            }
1290    
1291 Note that, because of its RULE, r_bar joins the recursive
1292 group.  (In this case it'll unravel a short moment later.)
1293
1294
1295 Conclusion: we catch the nasty case using filter_dfuns in
1296 callsForMe. To be honest I'm not 100% certain that this is 100%
1297 right, but it works.  Sigh.
1298
1299
1300 Note [Specialising a recursive group]
1301 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1302 Consider
1303     let rec { f x = ...g x'...
1304             ; g y = ...f y'.... }
1305     in f 'a'
1306 Here we specialise 'f' at Char; but that is very likely to lead to 
1307 a specialisation of 'g' at Char.  We must do the latter, else the
1308 whole point of specialisation is lost.
1309
1310 But we do not want to keep iterating to a fixpoint, because in the
1311 presence of polymorphic recursion we might generate an infinite number
1312 of specialisations.
1313
1314 So we use the following heuristic:
1315   * Arrange the rec block in dependency order, so far as possible
1316     (the occurrence analyser already does this)
1317
1318   * Specialise it much like a sequence of lets
1319
1320   * Then go through the block a second time, feeding call-info from
1321     the RHSs back in the bottom, as it were
1322
1323 In effect, the ordering maxmimises the effectiveness of each sweep,
1324 and we do just two sweeps.   This should catch almost every case of 
1325 monomorphic recursion -- the exception could be a very knotted-up
1326 recursion with multiple cycles tied up together.
1327
1328 This plan is implemented in the Rec case of specBindItself.
1329  
1330 Note [Specialisations already covered]
1331 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1332 We obviously don't want to generate two specialisations for the same
1333 argument pattern.  There are two wrinkles
1334
1335 1. We do the already-covered test in specDefn, not when we generate
1336 the CallInfo in mkCallUDs.  We used to test in the latter place, but
1337 we now iterate the specialiser somewhat, and the Id at the call site
1338 might therefore not have all the RULES that we can see in specDefn
1339
1340 2. What about two specialisations where the second is an *instance*
1341 of the first?  If the more specific one shows up first, we'll generate
1342 specialisations for both.  If the *less* specific one shows up first,
1343 we *don't* currently generate a specialisation for the more specific
1344 one.  (See the call to lookupRule in already_covered.)  Reasons:
1345   (a) lookupRule doesn't say which matches are exact (bad reason)
1346   (b) if the earlier specialisation is user-provided, it's
1347       far from clear that we should auto-specialise further
1348
1349 Note [Auto-specialisation and RULES]
1350 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1351 Consider:
1352    g :: Num a => a -> a
1353    g = ...
1354
1355    f :: (Int -> Int) -> Int
1356    f w = ...
1357    {-# RULE f g = 0 #-}
1358
1359 Suppose that auto-specialisation makes a specialised version of
1360 g::Int->Int That version won't appear in the LHS of the RULE for f.
1361 So if the specialisation rule fires too early, the rule for f may
1362 never fire. 
1363
1364 It might be possible to add new rules, to "complete" the rewrite system.
1365 Thus when adding
1366         RULE forall d. g Int d = g_spec
1367 also add
1368         RULE f g_spec = 0
1369
1370 But that's a bit complicated.  For now we ask the programmer's help,
1371 by *copying the INLINE activation pragma* to the auto-specialised
1372 rule.  So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule
1373 will also not be active until phase 2.  And that's what programmers
1374 should jolly well do anyway, even aside from specialisation, to ensure
1375 that g doesn't inline too early.
1376
1377 This in turn means that the RULE would never fire for a NOINLINE
1378 thing so not much point in generating a specialisation at all.
1379
1380 Note [Specialisation shape]
1381 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1382 We only specialise a function if it has visible top-level lambdas
1383 corresponding to its overloading.  E.g. if
1384         f :: forall a. Eq a => ....
1385 then its body must look like
1386         f = /\a. \d. ...
1387
1388 Reason: when specialising the body for a call (f ty dexp), we want to
1389 substitute dexp for d, and pick up specialised calls in the body of f.
1390
1391 This doesn't always work.  One example I came across was this:
1392         newtype Gen a = MkGen{ unGen :: Int -> a }
1393
1394         choose :: Eq a => a -> Gen a
1395         choose n = MkGen (\r -> n)
1396
1397         oneof = choose (1::Int)
1398
1399 It's a silly exapmle, but we get
1400         choose = /\a. g `cast` co
1401 where choose doesn't have any dict arguments.  Thus far I have not
1402 tried to fix this (wait till there's a real example).
1403
1404 Note [Inline specialisations]
1405 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1406 Here is what we do with the InlinePragma of the original function
1407   * Activation/RuleMatchInfo: both transferred to the
1408                               specialised function
1409   * InlineSpec:
1410        (a) An INLINE pragma is transferred
1411        (b) An INLINABLE pragma is *not* transferred
1412
1413 Why (a)? Previously the idea is that the point of INLINE was
1414 precisely to specialise the function at its call site, and that's not
1415 so important for the specialised copies.  But *pragma-directed*
1416 specialisation now takes place in the typechecker/desugarer, with
1417 manually specified INLINEs.  The specialiation here is automatic.
1418 It'd be very odd if a function marked INLINE was specialised (because
1419 of some local use), and then forever after (including importing
1420 modules) the specialised version wasn't INLINEd.  After all, the
1421 programmer said INLINE!
1422
1423 You might wonder why we don't just not-specialise INLINE functions.
1424 It's because even INLINE functions are sometimes not inlined, when 
1425 they aren't applied to interesting arguments.  But perhaps the type
1426 arguments alone are enough to specialise (even though the args are too
1427 boring to trigger inlining), and it's certainly better to call the 
1428 specialised version.
1429
1430 Why (b)? See Trac #4874 for persuasive examples.  Suppose we have
1431     {-# INLINABLE f #-}
1432     f :: Ord a => [a] -> Int
1433     f xs = letrec f' = ...f'... in f'
1434 Then, when f is specialised and optimised we might get
1435     wgo :: [Int] -> Int#
1436     wgo = ...wgo...
1437     f_spec :: [Int] -> Int
1438     f_spec xs = case wgo xs of { r -> I# r }
1439 and we clearly want to inline f_spec at call sites.  But if we still
1440 have the big, un-optimised of f (albeit specialised) captured in an
1441 INLINABLE pragma for f_spec, we won't get that optimisation.
1442
1443 So we simply drop INLINABLE pragmas when specialising. It's not really
1444 a complete solution; ignoring specalisation for now, INLINABLE functions
1445 don't get properly strictness analysed, for example. But it works well
1446 for examples involving specialisation, which is the dominant use of
1447 INLINABLE.  See Trac #4874.
1448
1449
1450 %************************************************************************
1451 %*                                                                      *
1452 \subsubsection{UsageDetails and suchlike}
1453 %*                                                                      *
1454 %************************************************************************
1455
1456 \begin{code}
1457 data UsageDetails 
1458   = MkUD {
1459         ud_binds :: !(Bag DictBind),
1460                         -- Floated dictionary bindings
1461                         -- The order is important; 
1462                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1463                         -- (Remember, Bags preserve order in GHC.)
1464
1465         ud_calls :: !CallDetails  
1466
1467         -- INVARIANT: suppose bs = bindersOf ud_binds
1468         -- Then 'calls' may *mention* 'bs', 
1469         -- but there should be no calls *for* bs
1470     }
1471
1472 instance Outputable UsageDetails where
1473   ppr (MkUD { ud_binds = dbs, ud_calls = calls })
1474         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma 
1475                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1476                  ptext (sLit "calls") <+> equals <+> ppr calls]))
1477
1478 type DictBind = (CoreBind, VarSet)
1479         -- The set is the free vars of the binding
1480         -- both tyvars and dicts
1481
1482 type DictExpr = CoreExpr
1483
1484 emptyUDs :: UsageDetails
1485 emptyUDs = MkUD { ud_binds = emptyBag, ud_calls = emptyVarEnv }
1486
1487 ------------------------------------------------------------                    
1488 type CallDetails  = IdEnv CallInfoSet
1489 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1490
1491 -- CallInfo uses a Map, thereby ensuring that
1492 -- we record only one call instance for any key
1493 --
1494 -- The list of types and dictionaries is guaranteed to
1495 -- match the type of f
1496 data CallInfoSet = CIS Id (Map CallKey ([DictExpr], VarSet))
1497                         -- Range is dict args and the vars of the whole
1498                         -- call (including tyvars)
1499                         -- [*not* include the main id itself, of course]
1500
1501 type CallInfo = (CallKey, ([DictExpr], VarSet))
1502
1503 instance Outputable CallInfoSet where
1504   ppr (CIS fn map) = hang (ptext (sLit "CIS") <+> ppr fn)
1505                         2 (ppr map)
1506
1507 instance Outputable CallKey where
1508   ppr (CallKey ts) = ppr ts
1509
1510 -- Type isn't an instance of Ord, so that we can control which
1511 -- instance we use.  That's tiresome here.  Oh well
1512 instance Eq CallKey where
1513   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1514
1515 instance Ord CallKey where
1516   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1517                 where
1518                   cmp Nothing   Nothing   = EQ
1519                   cmp Nothing   (Just _)  = LT
1520                   cmp (Just _)  Nothing   = GT
1521                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1522
1523 unionCalls :: CallDetails -> CallDetails -> CallDetails
1524 unionCalls c1 c2 = plusVarEnv_C unionCallInfoSet c1 c2
1525
1526 unionCallInfoSet :: CallInfoSet -> CallInfoSet -> CallInfoSet
1527 unionCallInfoSet (CIS f calls1) (CIS _ calls2) = CIS f (calls1 `Map.union` calls2)
1528
1529 callDetailsFVs :: CallDetails -> VarSet
1530 callDetailsFVs calls = foldVarEnv (unionVarSet . callInfoFVs) emptyVarSet calls
1531
1532 callInfoFVs :: CallInfoSet -> VarSet
1533 callInfoFVs (CIS _ call_info) = Map.foldRight (\(_,fv) vs -> unionVarSet fv vs) emptyVarSet call_info
1534
1535 ------------------------------------------------------------                    
1536 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1537 singleCall id tys dicts 
1538   = MkUD {ud_binds = emptyBag, 
1539           ud_calls = unitVarEnv id $ CIS id $ 
1540                      Map.singleton (CallKey tys) (dicts, call_fvs) }
1541   where
1542     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1543     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1544         -- The type args (tys) are guaranteed to be part of the dictionary
1545         -- types, because they are just the constrained types,
1546         -- and the dictionary is therefore sure to be bound
1547         -- inside the binding for any type variables free in the type;
1548         -- hence it's safe to neglect tyvars free in tys when making
1549         -- the free-var set for this call
1550         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1551         --
1552         -- We don't include the 'id' itself.
1553
1554 mkCallUDs :: Id -> [CoreExpr] -> UsageDetails
1555 mkCallUDs f args 
1556   | not (want_calls_for f)  -- Imported from elsewhere
1557   || null theta             -- Not overloaded
1558   || not (all isClassPred theta)        
1559         -- Only specialise if all overloading is on class params. 
1560         -- In ptic, with implicit params, the type args
1561         --  *don't* say what the value of the implicit param is!
1562   || not (spec_tys `lengthIs` n_tyvars)
1563   || not ( dicts   `lengthIs` n_dicts)
1564   || not (any interestingDict dicts)    -- Note [Interesting dictionary arguments]
1565   -- See also Note [Specialisations already covered]
1566   = -- pprTrace "mkCallUDs: discarding" _trace_doc
1567     emptyUDs    -- Not overloaded, or no specialisation wanted
1568
1569   | otherwise
1570   = -- pprTrace "mkCallUDs: keeping" _trace_doc
1571     singleCall f spec_tys dicts
1572   where
1573     _trace_doc = vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts
1574                       , ppr (map interestingDict dicts)]
1575     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1576     constrained_tyvars = tyVarsOfTheta theta 
1577     n_tyvars           = length tyvars
1578     n_dicts            = length theta
1579
1580     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1581     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1582     
1583     mk_spec_ty tyvar ty 
1584         | tyvar `elemVarSet` constrained_tyvars = Just ty
1585         | otherwise                             = Nothing
1586
1587     want_calls_for f = isLocalId f || isInlinablePragma (idInlinePragma f)
1588 \end{code}
1589
1590 Note [Interesting dictionary arguments]
1591 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1592 Consider this
1593          \a.\d:Eq a.  let f = ... in ...(f d)...
1594 There really is not much point in specialising f wrt the dictionary d,
1595 because the code for the specialised f is not improved at all, because
1596 d is lambda-bound.  We simply get junk specialisations.
1597
1598 What is "interesting"?  Just that it has *some* structure.  
1599
1600 \begin{code}
1601 interestingDict :: CoreExpr -> Bool
1602 -- A dictionary argument is interesting if it has *some* structure
1603 interestingDict (Var v) =  hasSomeUnfolding (idUnfolding v)
1604                         || isDataConWorkId v
1605 interestingDict (Type _)          = False
1606 interestingDict (App fn (Type _)) = interestingDict fn
1607 interestingDict (Note _ a)        = interestingDict a
1608 interestingDict (Cast e _)        = interestingDict e
1609 interestingDict _                 = True
1610 \end{code}
1611
1612 \begin{code}
1613 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1614 plusUDs (MkUD {ud_binds = db1, ud_calls = calls1})
1615         (MkUD {ud_binds = db2, ud_calls = calls2})
1616   = MkUD { ud_binds = db1    `unionBags`   db2 
1617          , ud_calls = calls1 `unionCalls`  calls2 }
1618
1619 plusUDList :: [UsageDetails] -> UsageDetails
1620 plusUDList = foldr plusUDs emptyUDs
1621
1622 -----------------------------
1623 _dictBindBndrs :: Bag DictBind -> [Id]
1624 _dictBindBndrs dbs = foldrBag ((++) . bindersOf . fst) [] dbs
1625
1626 mkDB :: CoreBind -> DictBind
1627 mkDB bind = (bind, bind_fvs bind)
1628
1629 bind_fvs :: CoreBind -> VarSet
1630 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1631 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1632                            where
1633                              bndrs = map fst prs
1634                              rhs_fvs = unionVarSets (map pair_fvs prs)
1635
1636 pair_fvs :: (Id, CoreExpr) -> VarSet
1637 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1638         -- Don't forget variables mentioned in the
1639         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1640         -- Also tyvars mentioned in its type; they may not appear in the RHS
1641         --      type T a = Int
1642         --      x :: T a = 3
1643
1644 flattenDictBinds :: Bag DictBind -> [(Id,CoreExpr)] -> [(Id,CoreExpr)]
1645 flattenDictBinds dbs pairs
1646   = foldrBag add pairs dbs
1647   where
1648     add (NonRec b r,_) pairs = (b,r) : pairs
1649     add (Rec prs1, _)  pairs = prs1 ++ pairs
1650
1651 snocDictBinds :: UsageDetails -> [CoreBind] -> UsageDetails
1652 -- Add ud_binds to the tail end of the bindings in uds
1653 snocDictBinds uds dbs
1654   = uds { ud_binds = ud_binds uds `unionBags` 
1655                      foldr (consBag . mkDB) emptyBag dbs }
1656
1657 consDictBind :: CoreBind -> UsageDetails -> UsageDetails
1658 consDictBind bind uds = uds { ud_binds = mkDB bind `consBag` ud_binds uds }
1659
1660 addDictBinds :: [DictBind] -> UsageDetails -> UsageDetails
1661 addDictBinds binds uds = uds { ud_binds = listToBag binds `unionBags` ud_binds uds }
1662
1663 snocDictBind :: UsageDetails -> CoreBind -> UsageDetails
1664 snocDictBind uds bind = uds { ud_binds = ud_binds uds `snocBag` mkDB bind }
1665
1666 wrapDictBinds :: Bag DictBind -> [CoreBind] -> [CoreBind]
1667 wrapDictBinds dbs binds
1668   = foldrBag add binds dbs
1669   where
1670     add (bind,_) binds = bind : binds
1671
1672 wrapDictBindsE :: Bag DictBind -> CoreExpr -> CoreExpr
1673 wrapDictBindsE dbs expr
1674   = foldrBag add expr dbs
1675   where
1676     add (bind,_) expr = Let bind expr
1677
1678 ----------------------
1679 dumpUDs :: [CoreBndr] -> UsageDetails -> (UsageDetails, Bag DictBind)
1680 -- Used at a lambda or case binder; just dump anything mentioning the binder
1681 dumpUDs bndrs uds@(MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1682   | null bndrs = (uds, emptyBag)  -- Common in case alternatives
1683   | otherwise  = -- pprTrace "dumpUDs" (ppr bndrs $$ ppr free_uds $$ ppr dump_dbs) $
1684                  (free_uds, dump_dbs)
1685   where
1686     free_uds = MkUD { ud_binds = free_dbs, ud_calls = free_calls }
1687     bndr_set = mkVarSet bndrs
1688     (free_dbs, dump_dbs, dump_set) = splitDictBinds orig_dbs bndr_set
1689     free_calls = deleteCallsMentioning dump_set $   -- Drop calls mentioning bndr_set on the floor
1690                  deleteCallsFor bndrs orig_calls    -- Discard calls for bndr_set; there should be 
1691                                                     -- no calls for any of the dicts in dump_dbs
1692
1693 dumpBindUDs :: [CoreBndr] -> UsageDetails -> (UsageDetails, Bag DictBind, Bool)
1694 -- Used at a lambda or case binder; just dump anything mentioning the binder
1695 dumpBindUDs bndrs (MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1696   = -- pprTrace "dumpBindUDs" (ppr bndrs $$ ppr free_uds $$ ppr dump_dbs) $
1697     (free_uds, dump_dbs, float_all)
1698   where
1699     free_uds = MkUD { ud_binds = free_dbs, ud_calls = free_calls }
1700     bndr_set = mkVarSet bndrs
1701     (free_dbs, dump_dbs, dump_set) = splitDictBinds orig_dbs bndr_set
1702     free_calls = deleteCallsFor bndrs orig_calls
1703     float_all = dump_set `intersectsVarSet` callDetailsFVs free_calls
1704
1705 callsForMe :: Id -> UsageDetails -> (UsageDetails, [CallInfo])
1706 callsForMe fn (MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1707   = -- pprTrace ("callsForMe")
1708     --         (vcat [ppr fn, 
1709     --                text "Orig dbs ="     <+> ppr (_dictBindBndrs orig_dbs), 
1710     --                text "Orig calls ="   <+> ppr orig_calls,
1711     --                text "Dep set ="      <+> ppr dep_set, 
1712     --                text "Calls for me =" <+> ppr calls_for_me]) $
1713     (uds_without_me, calls_for_me)
1714   where
1715     uds_without_me = MkUD { ud_binds = orig_dbs, ud_calls = delVarEnv orig_calls fn }
1716     calls_for_me = case lookupVarEnv orig_calls fn of
1717                         Nothing -> []
1718                         Just (CIS _ calls) -> filter_dfuns (Map.toList calls)
1719
1720     dep_set = foldlBag go (unitVarSet fn) orig_dbs
1721     go dep_set (db,fvs) | fvs `intersectsVarSet` dep_set
1722                         = extendVarSetList dep_set (bindersOf db)
1723                         | otherwise = dep_set
1724
1725         -- Note [Specialisation of dictionary functions]
1726     filter_dfuns | isDFunId fn = filter ok_call
1727                  | otherwise   = \cs -> cs
1728
1729     ok_call (_, (_,fvs)) = not (fvs `intersectsVarSet` dep_set)
1730
1731 ----------------------
1732 splitDictBinds :: Bag DictBind -> IdSet -> (Bag DictBind, Bag DictBind, IdSet)
1733 -- Returns (free_dbs, dump_dbs, dump_set)
1734 splitDictBinds dbs bndr_set
1735    = foldlBag split_db (emptyBag, emptyBag, bndr_set) dbs
1736                 -- Important that it's foldl not foldr;
1737                 -- we're accumulating the set of dumped ids in dump_set
1738    where
1739     split_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1740         | dump_idset `intersectsVarSet` fvs     -- Dump it
1741         = (free_dbs, dump_dbs `snocBag` db,
1742            extendVarSetList dump_idset (bindersOf bind))
1743
1744         | otherwise     -- Don't dump it
1745         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1746
1747
1748 ----------------------
1749 deleteCallsMentioning :: VarSet -> CallDetails -> CallDetails
1750 -- Remove calls *mentioning* bs 
1751 deleteCallsMentioning bs calls
1752   = mapVarEnv filter_calls calls
1753   where
1754     filter_calls :: CallInfoSet -> CallInfoSet
1755     filter_calls (CIS f calls) = CIS f (Map.filter keep_call calls)
1756     keep_call (_, fvs) = not (fvs `intersectsVarSet` bs)
1757
1758 deleteCallsFor :: [Id] -> CallDetails -> CallDetails
1759 -- Remove calls *for* bs
1760 deleteCallsFor bs calls = delVarEnvList calls bs
1761 \end{code}
1762
1763
1764 %************************************************************************
1765 %*                                                                      *
1766 \subsubsection{Boring helper functions}
1767 %*                                                                      *
1768 %************************************************************************
1769
1770 \begin{code}
1771 type SpecM a = UniqSM a
1772
1773 runSpecM:: SpecM a -> CoreM a
1774 runSpecM spec = do { us <- getUniqueSupplyM
1775                    ; return (initUs_ us spec) }
1776
1777 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1778 mapAndCombineSM _ []     = return ([], emptyUDs)
1779 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1780                               (ys, uds2) <- mapAndCombineSM f xs
1781                               return (y:ys, uds1 `plusUDs` uds2)
1782
1783 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1784 -- Clone the binders of the bind; return new bind with the cloned binders
1785 -- Return the substitution to use for RHSs, and the one to use for the body
1786 cloneBindSM subst (NonRec bndr rhs) = do
1787     us <- getUniqueSupplyM
1788     let (subst', bndr') = cloneIdBndr subst us bndr
1789     return (subst, subst', NonRec bndr' rhs)
1790
1791 cloneBindSM subst (Rec pairs) = do
1792     us <- getUniqueSupplyM
1793     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1794     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1795
1796 newDictBndrs :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1797 -- Make up completely fresh binders for the dictionaries
1798 -- Their bindings are going to float outwards
1799 newDictBndrs subst bndrs 
1800   = do { bndrs' <- mapM new bndrs
1801        ; let subst' = extendIdSubstList subst 
1802                         [(d, Var d') | (d,d') <- bndrs `zip` bndrs']
1803        ; return (subst', bndrs' ) }
1804   where
1805     new b = do { uniq <- getUniqueM
1806                ; let n   = idName b
1807                      ty' = CoreSubst.substTy subst (idType b)
1808                ; return (mkUserLocal (nameOccName n) uniq ty' (getSrcSpan n)) }
1809
1810 newSpecIdSM :: Id -> Type -> SpecM Id
1811     -- Give the new Id a similar occurrence name to the old one
1812 newSpecIdSM old_id new_ty
1813   = do  { uniq <- getUniqueM
1814         ; let name    = idName old_id
1815               new_occ = mkSpecOcc (nameOccName name)
1816               new_id  = mkUserLocal new_occ uniq new_ty (getSrcSpan name)
1817         ; return new_id }
1818 \end{code}
1819
1820
1821                 Old (but interesting) stuff about unboxed bindings
1822                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1823
1824 What should we do when a value is specialised to a *strict* unboxed value?
1825
1826         map_*_* f (x:xs) = let h = f x
1827                                t = map f xs
1828                            in h:t
1829
1830 Could convert let to case:
1831
1832         map_*_Int# f (x:xs) = case f x of h# ->
1833                               let t = map f xs
1834                               in h#:t
1835
1836 This may be undesirable since it forces evaluation here, but the value
1837 may not be used in all branches of the body. In the general case this
1838 transformation is impossible since the mutual recursion in a letrec
1839 cannot be expressed as a case.
1840
1841 There is also a problem with top-level unboxed values, since our
1842 implementation cannot handle unboxed values at the top level.
1843
1844 Solution: Lift the binding of the unboxed value and extract it when it
1845 is used:
1846
1847         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1848                                   t = map f xs
1849                               in case h of
1850                                  _Lift h# -> h#:t
1851
1852 Now give it to the simplifier and the _Lifting will be optimised away.
1853
1854 The benfit is that we have given the specialised "unboxed" values a
1855 very simplep lifted semantics and then leave it up to the simplifier to
1856 optimise it --- knowing that the overheads will be removed in nearly
1857 all cases.
1858
1859 In particular, the value will only be evaluted in the branches of the
1860 program which use it, rather than being forced at the point where the
1861 value is bound. For example:
1862
1863         filtermap_*_* p f (x:xs)
1864           = let h = f x
1865                 t = ...
1866             in case p x of
1867                 True  -> h:t
1868                 False -> t
1869    ==>
1870         filtermap_*_Int# p f (x:xs)
1871           = let h = case (f x) of h# -> _Lift h#
1872                 t = ...
1873             in case p x of
1874                 True  -> case h of _Lift h#
1875                            -> h#:t
1876                 False -> t
1877
1878 The binding for h can still be inlined in the one branch and the
1879 _Lifting eliminated.
1880
1881
1882 Question: When won't the _Lifting be eliminated?
1883
1884 Answer: When they at the top-level (where it is necessary) or when
1885 inlining would duplicate work (or possibly code depending on
1886 options). However, the _Lifting will still be eliminated if the
1887 strictness analyser deems the lifted binding strict.
1888