compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 module Specialise ( specProgram ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags ( DynFlags, DynFlag(..) )
  12 import Id               ( Id, idName, idType, mkUserLocal,
  13                           idInlinePragma, setInlinePragma )
  14 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  15                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  16                           tcCmpType, isUnLiftedType
  17                         )
  18 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  19                           substBndr, substBndrs, substTy, substInScope,
  20                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs
  21                         )
  22 import VarSet
  23 import VarEnv
  24 import CoreSyn
  25 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  26 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  27 import CoreTidy         ( tidyRules )
  28 import CoreLint         ( showPass, endPass )
  29 import Rules            ( addIdSpecialisations, mkLocalRule, lookupRule, emptyRuleBase, rulesOfBinds )
  30 import PprCore          ( pprRules )
  31 import UniqSupply       ( UniqSupply,
  32                           UniqSM, initUs_, thenUs, returnUs, getUniqueUs,
  33                           getUs, mapUs
  34                         )
  35 import Name
  36 import MkId             ( voidArgId, realWorldPrimId )
  37 import FiniteMap
  38 import Maybes           ( catMaybes, maybeToBool )
  39 import ErrUtils         ( dumpIfSet_dyn )
  40 import BasicTypes       ( Activation( AlwaysActive ) )
  41 import Bag
  42 import List             ( partition )
  43 import Util             ( zipEqual, zipWithEqual, cmpList, lengthIs,
  44                           equalLength, lengthAtLeast, notNull )
  45 import Outputable
  46 import FastString
  47
  48 infixr 9 `thenSM`
  49 \end{code}
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 These notes describe how we implement specialisation to eliminate
  58 overloading.
  59
  60 The specialisation pass works on Core
  61 syntax, complete with all the explicit dictionary application,
  62 abstraction and construction as added by the type checker.  The
  63 existing type checker remains largely as it is.
  64
  65 One important thought: the {\em types} passed to an overloaded
  66 function, and the {\em dictionaries} passed are mutually redundant.
  67 If the same function is applied to the same type(s) then it is sure to
  68 be applied to the same dictionary(s)---or rather to the same {\em
  69 values}.  (The arguments might look different but they will evaluate
  70 to the same value.)
  71
  72 Second important thought: we know that we can make progress by
  73 treating dictionary arguments as static and worth specialising on.  So
  74 we can do without binding-time analysis, and instead specialise on
  75 dictionary arguments and no others.
  76
  77 The basic idea
  78 ~~~~~~~~~~~~~~
  79 Suppose we have
  80
  81         let f = <f_rhs>
  82         in <body>
  83
  84 and suppose f is overloaded.
  85
  86 STEP 1: CALL-INSTANCE COLLECTION
  87
  88 We traverse <body>, accumulating all applications of f to types and
  89 dictionaries.
  90
  91 (Might there be partial applications, to just some of its types and
  92 dictionaries?  In principle yes, but in practice the type checker only
  93 builds applications of f to all its types and dictionaries, so partial
  94 applications could only arise as a result of transformation, and even
  95 then I think it's unlikely.  In any case, we simply don't accumulate such
  96 partial applications.)
  97
  98
  99 STEP 2: EQUIVALENCES
 100
 101 So now we have a collection of calls to f:
 102         f t1 t2 d1 d2
 103         f t3 t4 d3 d4
 104         ...
 105 Notice that f may take several type arguments.  To avoid ambiguity, we
 106 say that f is called at type t1/t2 and t3/t4.
 107
 108 We take equivalence classes using equality of the *types* (ignoring
 109 the dictionary args, which as mentioned previously are redundant).
 110
 111 STEP 3: SPECIALISATION
 112
 113 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 114 and create a local instance of f, defined thus:
 115
 116         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 117
 118 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 119 of simplification will now result.  However we don't actually *do* that
 120 simplification.  Rather, we leave it for the simplifier to do.  If we
 121 *did* do it, though, we'd get more call instances from the specialised
 122 RHS.  We can work out what they are by instantiating the call-instance
 123 set from f's RHS with the types t1, t2.
 124
 125 Add this new id to f's IdInfo, to record that f has a specialised version.
 126
 127 Before doing any of this, check that f's IdInfo doesn't already
 128 tell us about an existing instance of f at the required type/s.
 129 (This might happen if specialisation was applied more than once, or
 130 it might arise from user SPECIALIZE pragmas.)
 131
 132 Recursion
 133 ~~~~~~~~~
 134 Wait a minute!  What if f is recursive?  Then we can't just plug in
 135 its right-hand side, can we?
 136
 137 But it's ok.  The type checker *always* creates non-recursive definitions
 138 for overloaded recursive functions.  For example:
 139
 140         f x = f (x+x)           -- Yes I know its silly
 141
 142 becomes
 143
 144         f a (d::Num a) = let p = +.sel a d
 145                          in
 146                          letrec fl (y::a) = fl (p y y)
 147                          in
 148                          fl
 149
 150 We still have recusion for non-overloaded functions which we
 151 speciailise, but the recursive call should get specialised to the
 152 same recursive version.
 153
 154
 155 Polymorphism 1
 156 ~~~~~~~~~~~~~~
 157
 158 All this is crystal clear when the function is applied to *constant
 159 types*; that is, types which have no type variables inside.  But what if
 160 it is applied to non-constant types?  Suppose we find a call of f at type
 161 t1/t2.  There are two possibilities:
 162
 163 (a) The free type variables of t1, t2 are in scope at the definition point
 164 of f.  In this case there's no problem, we proceed just as before.  A common
 165 example is as follows.  Here's the Haskell:
 166
 167         g y = let f x = x+x
 168               in f y + f y
 169
 170 After typechecking we have
 171
 172         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 173                                 in +.sel a d (f a d y) (f a d y)
 174
 175 Notice that the call to f is at type type "a"; a non-constant type.
 176 Both calls to f are at the same type, so we can specialise to give:
 177
 178         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 179                                 in +.sel a d (f@a y) (f@a y)
 180
 181
 182 (b) The other case is when the type variables in the instance types
 183 are *not* in scope at the definition point of f.  The example we are
 184 working with above is a good case.  There are two instances of (+.sel a d),
 185 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 186 Yes, we can "common them up", a sort of limited common sub-expression deal.
 187 This would give:
 188
 189         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 190                                     f@a (x::a) = +.sel@a x x
 191                                 in +.sel@a (f@a y) (f@a y)
 192
 193 This can save work, and can't be spotted by the type checker, because
 194 the two instances of +.sel weren't originally at the same type.
 195
 196 Further notes on (b)
 197
 198 * There are quite a few variations here.  For example, the defn of
 199   +.sel could be floated ouside the \y, to attempt to gain laziness.
 200   It certainly mustn't be floated outside the \d because the d has to
 201   be in scope too.
 202
 203 * We don't want to inline f_rhs in this case, because
 204 that will duplicate code.  Just commoning up the call is the point.
 205
 206 * Nothing gets added to +.sel's IdInfo.
 207
 208 * Don't bother unless the equivalence class has more than one item!
 209
 210 Not clear whether this is all worth it.  It is of course OK to
 211 simply discard call-instances when passing a big lambda.
 212
 213 Polymorphism 2 -- Overloading
 214 ~~~~~~~~~~~~~~
 215 Consider a function whose most general type is
 216
 217         f :: forall a b. Ord a => [a] -> b -> b
 218
 219 There is really no point in making a version of g at Int/Int and another
 220 at Int/Bool, because it's only instancing the type variable "a" which
 221 buys us any efficiency. Since g is completely polymorphic in b there
 222 ain't much point in making separate versions of g for the different
 223 b types.
 224
 225 That suggests that we should identify which of g's type variables
 226 are constrained (like "a") and which are unconstrained (like "b").
 227 Then when taking equivalence classes in STEP 2, we ignore the type args
 228 corresponding to unconstrained type variable.  In STEP 3 we make
 229 polymorphic versions.  Thus:
 230
 231         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 232
 233 We do this.
 234
 235
 236 Dictionary floating
 237 ~~~~~~~~~~~~~~~~~~~
 238 Consider this
 239
 240         f a (d::Num a) = let g = ...
 241                          in
 242                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 243
 244 Here, g is only called at one type, but the dictionary isn't in scope at the
 245 definition point for g.  Usually the type checker would build a
 246 definition for d1 which enclosed g, but the transformation system
 247 might have moved d1's defn inward.  Solution: float dictionary bindings
 248 outwards along with call instances.
 249
 250 Consider
 251
 252         f x = let g p q = p==q
 253                   h r s = (r+s, g r s)
 254               in
 255               h x x
 256
 257
 258 Before specialisation, leaving out type abstractions we have
 259
 260         f df x = let g :: Eq a => a -> a -> Bool
 261                      g dg p q = == dg p q
 262                      h :: Num a => a -> a -> (a, Bool)
 263                      h dh r s = let deq = eqFromNum dh
 264                                 in (+ dh r s, g deq r s)
 265               in
 266               h df x x
 267
 268 After specialising h we get a specialised version of h, like this:
 269
 270                     h' r s = let deq = eqFromNum df
 271                              in (+ df r s, g deq r s)
 272
 273 But we can't naively make an instance for g from this, because deq is not in scope
 274 at the defn of g.  Instead, we have to float out the (new) defn of deq
 275 to widen its scope.  Notice that this floating can't be done in advance -- it only
 276 shows up when specialisation is done.
 277
 278 User SPECIALIZE pragmas
 279 ~~~~~~~~~~~~~~~~~~~~~~~
 280 Specialisation pragmas can be digested by the type checker, and implemented
 281 by adding extra definitions along with that of f, in the same way as before
 282
 283         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 284
 285 Indeed the pragmas *have* to be dealt with by the type checker, because
 286 only it knows how to build the dictionaries d1 and d2!  For example
 287
 288         g :: Ord a => [a] -> [a]
 289         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 290
 291 Here, the specialised version of g is an application of g's rhs to the
 292 Ord dictionary for (Tree Int), which only the type checker can conjure
 293 up.  There might not even *be* one, if (Tree Int) is not an instance of
 294 Ord!  (All the other specialision has suitable dictionaries to hand
 295 from actual calls.)
 296
 297 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 298 it is buried in a complex (as-yet-un-desugared) binding group.
 299 Maybe we should say
 300
 301         f@t1/t2 = f* t1 t2 d1 d2
 302
 303 where f* is the Id f with an IdInfo which says "inline me regardless!".
 304 Indeed all the specialisation could be done in this way.
 305 That in turn means that the simplifier has to be prepared to inline absolutely
 306 any in-scope let-bound thing.
 307
 308
 309 Again, the pragma should permit polymorphism in unconstrained variables:
 310
 311         h :: Ord a => [a] -> b -> b
 312         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 313
 314 We *insist* that all overloaded type variables are specialised to ground types,
 315 (and hence there can be no context inside a SPECIALIZE pragma).
 316 We *permit* unconstrained type variables to be specialised to
 317         - a ground type
 318         - or left as a polymorphic type variable
 319 but nothing in between.  So
 320
 321         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 322
 323 is *illegal*.  (It can be handled, but it adds complication, and gains the
 324 programmer nothing.)
 325
 326
 327 SPECIALISING INSTANCE DECLARATIONS
 328 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 329 Consider
 330
 331         instance Foo a => Foo [a] where
 332                 ...
 333         {-# SPECIALIZE instance Foo [Int] #-}
 334
 335 The original instance decl creates a dictionary-function
 336 definition:
 337
 338         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 339
 340 The SPECIALIZE pragma just makes a specialised copy, just as for
 341 ordinary function definitions:
 342
 343         dfun.Foo.List@Int :: Foo [Int]
 344         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 345
 346 The information about what instance of the dfun exist gets added to
 347 the dfun's IdInfo in the same way as a user-defined function too.
 348
 349
 350 Automatic instance decl specialisation?
 351 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 352 Can instance decls be specialised automatically?  It's tricky.
 353 We could collect call-instance information for each dfun, but
 354 then when we specialised their bodies we'd get new call-instances
 355 for ordinary functions; and when we specialised their bodies, we might get
 356 new call-instances of the dfuns, and so on.  This all arises because of
 357 the unrestricted mutual recursion between instance decls and value decls.
 358
 359 Still, there's no actual problem; it just means that we may not do all
 360 the specialisation we could theoretically do.
 361
 362 Furthermore, instance decls are usually exported and used non-locally,
 363 so we'll want to compile enough to get those specialisations done.
 364
 365 Lastly, there's no such thing as a local instance decl, so we can
 366 survive solely by spitting out *usage* information, and then reading that
 367 back in as a pragma when next compiling the file.  So for now,
 368 we only specialise instance decls in response to pragmas.
 369
 370
 371 SPITTING OUT USAGE INFORMATION
 372 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 373
 374 To spit out usage information we need to traverse the code collecting
 375 call-instance information for all imported (non-prelude?) functions
 376 and data types. Then we equivalence-class it and spit it out.
 377
 378 This is done at the top-level when all the call instances which escape
 379 must be for imported functions and data types.
 380
 381 *** Not currently done ***
 382
 383
 384 Partial specialisation by pragmas
 385 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 386 What about partial specialisation:
 387
 388         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 389         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 390
 391 or even
 392
 393         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 394
 395 Seems quite reasonable.  Similar things could be done with instance decls:
 396
 397         instance (Foo a, Foo b) => Foo (a,b) where
 398                 ...
 399         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 400         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 401
 402 Ho hum.  Things are complex enough without this.  I pass.
 403
 404
 405 Requirements for the simplifer
 406 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 407 The simplifier has to be able to take advantage of the specialisation.
 408
 409 * When the simplifier finds an application of a polymorphic f, it looks in
 410 f's IdInfo in case there is a suitable instance to call instead.  This converts
 411
 412         f t1 t2 d1 d2   ===>   f_t1_t2
 413
 414 Note that the dictionaries get eaten up too!
 415
 416 * Dictionary selection operations on constant dictionaries must be
 417   short-circuited:
 418
 419         +.sel Int d     ===>  +Int
 420
 421 The obvious way to do this is in the same way as other specialised
 422 calls: +.sel has inside it some IdInfo which tells that if it's applied
 423 to the type Int then it should eat a dictionary and transform to +Int.
 424
 425 In short, dictionary selectors need IdInfo inside them for constant
 426 methods.
 427
 428 * Exactly the same applies if a superclass dictionary is being
 429   extracted:
 430
 431         Eq.sel Int d   ===>   dEqInt
 432
 433 * Something similar applies to dictionary construction too.  Suppose
 434 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 435 one for (Eq [a]).  Then we want
 436
 437         dfun.Eq.List Int d      ===> dEq.List_Int
 438
 439 Where does the Eq [Int] dictionary come from?  It is built in
 440 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 441
 442 In short, dfun Ids need IdInfo with a specialisation for each
 443 constant instance of their instance declaration.
 444
 445 All this uses a single mechanism: the SpecEnv inside an Id
 446
 447
 448 What does the specialisation IdInfo look like?
 449 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 450
 451 The SpecEnv of an Id maps a list of types (the template) to an expression
 452
 453         [Type]  |->  Expr
 454
 455 For example, if f has this SpecInfo:
 456
 457         [Int, a]  ->  \d:Ord Int. f' a
 458
 459 it means that we can replace the call
 460
 461         f Int t  ===>  (\d. f' t)
 462
 463 This chucks one dictionary away and proceeds with the
 464 specialised version of f, namely f'.
 465
 466
 467 What can't be done this way?
 468 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 469 There is no way, post-typechecker, to get a dictionary for (say)
 470 Eq a from a dictionary for Eq [a].  So if we find
 471
 472         ==.sel [t] d
 473
 474 we can't transform to
 475
 476         eqList (==.sel t d')
 477
 478 where
 479         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 480
 481 Of course, we currently have no way to automatically derive
 482 eqList, nor to connect it to the Eq [a] instance decl, but you
 483 can imagine that it might somehow be possible.  Taking advantage
 484 of this is permanently ruled out.
 485
 486 Still, this is no great hardship, because we intend to eliminate
 487 overloading altogether anyway!
 488
 489
 490
 491 A note about non-tyvar dictionaries
 492 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 493 Some Ids have types like
 494
 495         forall a,b,c. Eq a -> Ord [a] -> tau
 496
 497 This seems curious at first, because we usually only have dictionary
 498 args whose types are of the form (C a) where a is a type variable.
 499 But this doesn't hold for the functions arising from instance decls,
 500 which sometimes get arguements with types of form (C (T a)) for some
 501 type constructor T.
 502
 503 Should we specialise wrt this compound-type dictionary?  We used to say
 504 "no", saying:
 505         "This is a heuristic judgement, as indeed is the fact that we
 506         specialise wrt only dictionaries.  We choose *not* to specialise
 507         wrt compound dictionaries because at the moment the only place
 508         they show up is in instance decls, where they are simply plugged
 509         into a returned dictionary.  So nothing is gained by specialising
 510         wrt them."
 511
 512 But it is simpler and more uniform to specialise wrt these dicts too;
 513 and in future GHC is likely to support full fledged type signatures
 514 like
 515         f ;: Eq [(a,b)] => ...
 516
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsubsection{The new specialiser}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 Our basic game plan is this.  For let(rec) bound function
 525         f :: (C a, D c) => (a,b,c,d) -> Bool
 526
 527 * Find any specialised calls of f, (f ts ds), where
 528   ts are the type arguments t1 .. t4, and
 529   ds are the dictionary arguments d1 .. d2.
 530
 531 * Add a new definition for f1 (say):
 532
 533         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 534
 535   Note that we abstract over the unconstrained type arguments.
 536
 537 * Add the mapping
 538
 539         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 540
 541   to the specialisations of f.  This will be used by the
 542   simplifier to replace calls
 543                 (f t1 t2 t3 t4) da db
 544   by
 545                 (\d1 d1 -> f1 t2 t4) da db
 546
 547   All the stuff about how many dictionaries to discard, and what types
 548   to apply the specialised function to, are handled by the fact that the
 549   SpecEnv contains a template for the result of the specialisation.
 550
 551 We don't build *partial* specialisations for f.  For example:
 552
 553   f :: Eq a => a -> a -> Bool
 554   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 555
 556 Here, little is gained by making a specialised copy of f.
 557 There's a distinct danger that the specialised version would
 558 first build a dictionary for (Eq b, Eq c), and then select the (==)
 559 method from it!  Even if it didn't, not a great deal is saved.
 560
 561 We do, however, generate polymorphic, but not overloaded, specialisations:
 562
 563   f :: Eq a => [a] -> b -> b -> b
 564   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 565
 566 Hence, the invariant is this:
 567
 568         *** no specialised version is overloaded ***
 569
 570
 571 %************************************************************************
 572 %*                                                                      *
 573 \subsubsection{The exported function}
 574 %*                                                                      *
 575 %************************************************************************
 576
 577 \begin{code}
 578 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 579 specProgram dflags us binds
 580   = do
 581         showPass dflags "Specialise"
 582
 583         let binds' = initSM us (go binds        `thenSM` \ (binds', uds') ->
 584                                 returnSM (dumpAllDictBinds uds' binds'))
 585
 586         endPass dflags "Specialise" Opt_D_dump_spec binds'
 587
 588         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 589                   (pprRules (tidyRules emptyTidyEnv (rulesOfBinds binds')))
 590
 591         return binds'
 592   where
 593         -- We need to start with a Subst that knows all the things
 594         -- that are in scope, so that the substitution engine doesn't
 595         -- accidentally re-use a unique that's already in use
 596         -- Easiest thing is to do it all at once, as if all the top-level
 597         -- decls were mutually recursive
 598     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 599
 600     go []           = returnSM ([], emptyUDs)
 601     go (bind:binds) = go binds                          `thenSM` \ (binds', uds) ->
 602                       specBind top_subst bind uds       `thenSM` \ (bind', uds') ->
 603                       returnSM (bind' ++ binds', uds')
 604 \end{code}
 605
 606 %************************************************************************
 607 %*                                                                      *
 608 \subsubsection{@specExpr@: the main function}
 609 %*                                                                      *
 610 %************************************************************************
 611
 612 \begin{code}
 613 specVar :: Subst -> Id -> CoreExpr
 614 specVar subst v = lookupIdSubst subst v
 615
 616 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 617 -- We carry a substitution down:
 618 --      a) we must clone any binding that might flaot outwards,
 619 --         to avoid name clashes
 620 --      b) we carry a type substitution to use when analysing
 621 --         the RHS of specialised bindings (no type-let!)
 622
 623 ---------------- First the easy cases --------------------
 624 specExpr subst (Type ty) = returnSM (Type (substTy subst ty), emptyUDs)
 625 specExpr subst (Var v)   = returnSM (specVar subst v,         emptyUDs)
 626 specExpr subst (Lit lit) = returnSM (Lit lit,                 emptyUDs)
 627 specExpr subst (Cast e co) =
 628   specExpr subst e              `thenSM` \ (e', uds) ->
 629   returnSM ((Cast e' (substTy subst co)), uds)
 630 specExpr subst (Note note body)
 631   = specExpr subst body         `thenSM` \ (body', uds) ->
 632     returnSM (Note (specNote subst note) body', uds)
 633
 634
 635 ---------------- Applications might generate a call instance --------------------
 636 specExpr subst expr@(App fun arg)
 637   = go expr []
 638   where
 639     go (App fun arg) args = specExpr subst arg  `thenSM` \ (arg', uds_arg) ->
 640                             go fun (arg':args)  `thenSM` \ (fun', uds_app) ->
 641                             returnSM (App fun' arg', uds_arg `plusUDs` uds_app)
 642
 643     go (Var f)       args = case specVar subst f of
 644                                 Var f' -> returnSM (Var f', mkCallUDs subst f' args)
 645                                 e'     -> returnSM (e', emptyUDs)       -- I don't expect this!
 646     go other         args = specExpr subst other
 647
 648 ---------------- Lambda/case require dumping of usage details --------------------
 649 specExpr subst e@(Lam _ _)
 650   = specExpr subst' body        `thenSM` \ (body', uds) ->
 651     let
 652         (filtered_uds, body'') = dumpUDs bndrs' uds body'
 653     in
 654     returnSM (mkLams bndrs' body'', filtered_uds)
 655   where
 656     (bndrs, body) = collectBinders e
 657     (subst', bndrs') = substBndrs subst bndrs
 658         -- More efficient to collect a group of binders together all at once
 659         -- and we don't want to split a lambda group with dumped bindings
 660
 661 specExpr subst (Case scrut case_bndr ty alts)
 662   = specExpr subst scrut                `thenSM` \ (scrut', uds_scrut) ->
 663     mapAndCombineSM spec_alt alts       `thenSM` \ (alts', uds_alts) ->
 664     returnSM (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 665   where
 666     (subst_alt, case_bndr') = substBndr subst case_bndr
 667         -- No need to clone case binder; it can't float like a let(rec)
 668
 669     spec_alt (con, args, rhs)
 670         = specExpr subst_rhs rhs                `thenSM` \ (rhs', uds) ->
 671           let
 672              (uds', rhs'') = dumpUDs args uds rhs'
 673           in
 674           returnSM ((con, args', rhs''), uds')
 675         where
 676           (subst_rhs, args') = substBndrs subst_alt args
 677
 678 ---------------- Finally, let is the interesting case --------------------
 679 specExpr subst (Let bind body)
 680   =     -- Clone binders
 681     cloneBindSM subst bind                      `thenSM` \ (rhs_subst, body_subst, bind') ->
 682
 683         -- Deal with the body
 684     specExpr body_subst body                    `thenSM` \ (body', body_uds) ->
 685
 686         -- Deal with the bindings
 687     specBind rhs_subst bind' body_uds           `thenSM` \ (binds', uds) ->
 688
 689         -- All done
 690     returnSM (foldr Let body' binds', uds)
 691
 692 -- Must apply the type substitution to coerceions
 693 specNote subst note           = note
 694 \end{code}
 695
 696 %************************************************************************
 697 %*                                                                      *
 698 \subsubsection{Dealing with a binding}
 699 %*                                                                      *
 700 %************************************************************************
 701
 702 \begin{code}
 703 specBind :: Subst                       -- Use this for RHSs
 704          -> CoreBind
 705          -> UsageDetails                -- Info on how the scope of the binding
 706          -> SpecM ([CoreBind],          -- New bindings
 707                    UsageDetails)        -- And info to pass upstream
 708
 709 specBind rhs_subst bind body_uds
 710   = specBindItself rhs_subst bind (calls body_uds)      `thenSM` \ (bind', bind_uds) ->
 711     let
 712         bndrs   = bindersOf bind
 713         all_uds = zapCalls bndrs (body_uds `plusUDs` bind_uds)
 714                         -- It's important that the `plusUDs` is this way round,
 715                         -- because body_uds may bind dictionaries that are
 716                         -- used in the calls passed to specDefn.  So the
 717                         -- dictionary bindings in bind_uds may mention
 718                         -- dictionaries bound in body_uds.
 719     in
 720     case splitUDs bndrs all_uds of
 721
 722         (_, ([],[]))    -- This binding doesn't bind anything needed
 723                         -- in the UDs, so put the binding here
 724                         -- This is the case for most non-dict bindings, except
 725                         -- for the few that are mentioned in a dict binding
 726                         -- that is floating upwards in body_uds
 727                 -> returnSM ([bind'], all_uds)
 728
 729         (float_uds, (dict_binds, calls))        -- This binding is needed in the UDs, so float it out
 730                 -> returnSM ([], float_uds `plusUDs` mkBigUD bind' dict_binds calls)
 731
 732
 733 -- A truly gruesome function
 734 mkBigUD bind@(NonRec _ _) dbs calls
 735   =     -- Common case: non-recursive and no specialisations
 736         -- (if there were any specialistions it would have been made recursive)
 737     MkUD { dict_binds = listToBag (mkDB bind : dbs),
 738            calls = listToCallDetails calls }
 739
 740 mkBigUD bind dbs calls
 741   =     -- General case
 742     MkUD { dict_binds = unitBag (mkDB (Rec (bind_prs bind ++ dbsToPairs dbs))),
 743                         -- Make a huge Rec
 744            calls = listToCallDetails calls }
 745   where
 746     bind_prs (NonRec b r) = [(b,r)]
 747     bind_prs (Rec prs)    = prs
 748
 749     dbsToPairs []             = []
 750     dbsToPairs ((bind,_):dbs) = bind_prs bind ++ dbsToPairs dbs
 751
 752 -- specBindItself deals with the RHS, specialising it according
 753 -- to the calls found in the body (if any)
 754 specBindItself rhs_subst (NonRec bndr rhs) call_info
 755   = specDefn rhs_subst call_info (bndr,rhs)     `thenSM` \ ((bndr',rhs'), spec_defns, spec_uds) ->
 756     let
 757         new_bind | null spec_defns = NonRec bndr' rhs'
 758                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 759                 -- bndr' mentions the spec_defns in its SpecEnv
 760                 -- Not sure why we couln't just put the spec_defns first
 761     in
 762     returnSM (new_bind, spec_uds)
 763
 764 specBindItself rhs_subst (Rec pairs) call_info
 765   = mapSM (specDefn rhs_subst call_info) pairs  `thenSM` \ stuff ->
 766     let
 767         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 768         spec_defns = concat spec_defns_s
 769         spec_uds   = plusUDList spec_uds_s
 770         new_bind   = Rec (spec_defns ++ pairs')
 771     in
 772     returnSM (new_bind, spec_uds)
 773
 774
 775 specDefn :: Subst                       -- Subst to use for RHS
 776          -> CallDetails                 -- Info on how it is used in its scope
 777          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 778          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 779                                         --      the Id may now have specialisations attached
 780                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 781                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 782             )                           --      specialised versions
 783
 784 specDefn subst calls (fn, rhs)
 785         -- The first case is the interesting one
 786   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 787   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 788   && notNull calls_for_me               -- And there are some calls to specialise
 789
 790 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 791 --      See Note [Inline specialisation] for why we do not
 792 --      switch off specialisation for inline functions
 793
 794   =   -- Specialise the body of the function
 795     specExpr subst rhs                                  `thenSM` \ (rhs', rhs_uds) ->
 796
 797       -- Make a specialised version for each call in calls_for_me
 798     mapSM spec_call calls_for_me                `thenSM` \ stuff ->
 799     let
 800         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 801
 802         fn' = addIdSpecialisations fn spec_rules
 803     in
 804     returnSM ((fn',rhs'),
 805               spec_defns,
 806               rhs_uds `plusUDs` plusUDList spec_uds)
 807
 808   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 809   = WARN( notNull calls_for_me, ptext SLIT("Missed specialisation opportunity for") <+> ppr fn )
 810           -- Note [Specialisation shape]
 811     specExpr subst rhs                  `thenSM` \ (rhs', rhs_uds) ->
 812     returnSM ((fn, rhs'), [], rhs_uds)
 813
 814   where
 815     fn_type            = idType fn
 816     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 817     n_tyvars           = length tyvars
 818     n_dicts            = length theta
 819     inline_prag        = idInlinePragma fn
 820
 821         -- It's important that we "see past" any INLINE pragma
 822         -- else we'll fail to specialise an INLINE thing
 823     (inline_rhs, rhs_inside) = dropInline rhs
 824     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 825
 826     rhs_dicts = take n_dicts rhs_ids
 827     rhs_bndrs = rhs_tyvars ++ rhs_dicts
 828     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 829                 -- Glue back on the non-dict lambdas
 830
 831     calls_for_me = case lookupFM calls fn of
 832                         Nothing -> []
 833                         Just cs -> fmToList cs
 834
 835     ----------------------------------------------------------
 836         -- Specialise to one particular call pattern
 837     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 838               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 839                         UsageDetails,                   -- Usage details from specialised body
 840                         CoreRule)                       -- Info for the Id's SpecEnv
 841     spec_call (CallKey call_ts, (call_ds, call_fvs))
 842       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
 843                 -- Calls are only recorded for properly-saturated applications
 844
 845         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 846         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 847
 848         -- Construct the new binding
 849         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 850         -- PLUS the usage-details
 851         --      { d1' = dx1; d2' = dx2 }
 852         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 853         --
 854         -- Note that the substitution is applied to the whole thing.
 855         -- This is convenient, but just slightly fragile.  Notably:
 856         --      * There had better be no name clashes in a/b/c/d
 857         --
 858         let
 859                 -- poly_tyvars = [b,d] in the example above
 860                 -- spec_tyvars = [a,c]
 861                 -- ty_args     = [t1,b,t3,d]
 862            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 863            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 864            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 865                        where
 866                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 867                          mk_ty_arg rhs_tyvar (Just ty) = Type ty
 868            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` [ty | Just ty <- call_ts])
 869         in
 870         cloneBinders rhs_subst rhs_dicts                `thenSM` \ (rhs_subst', rhs_dicts') ->
 871         let
 872            inst_args = ty_args ++ map Var rhs_dicts'
 873
 874                 -- Figure out the type of the specialised function
 875            body_ty = applyTypeToArgs rhs fn_type inst_args
 876            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 877                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 878                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 879                 | otherwise = (poly_tyvars, poly_tyvars)
 880            spec_id_ty = mkPiTypes lam_args body_ty
 881         in
 882         newIdSM fn spec_id_ty                           `thenSM` \ spec_f ->
 883         specExpr rhs_subst' (mkLams lam_args body)      `thenSM` \ (spec_rhs, rhs_uds) ->
 884         let
 885                 -- The rule to put in the function's specialisation is:
 886                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 887            spec_env_rule = mkLocalRule (mkFastString ("SPEC " ++ showSDoc (ppr fn)))
 888                                 AlwaysActive (idName fn)
 889                                 (poly_tyvars ++ rhs_dicts')
 890                                 inst_args
 891                                 (mkVarApps (Var spec_f) app_args)
 892
 893                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 894            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 895
 896            spec_pr | inline_rhs = (spec_f `setInlinePragma` inline_prag, Note InlineMe spec_rhs)
 897                    | otherwise  = (spec_f,                               spec_rhs)
 898         in
 899         returnSM (spec_pr, final_uds, spec_env_rule)
 900
 901       where
 902         my_zipEqual doc xs ys
 903 #ifdef DEBUG
 904          | not (equalLength xs ys) = pprPanic "my_zipEqual" (vcat
 905                                                 [ ppr xs, ppr ys
 906                                                 , ppr fn <+> ppr call_ts
 907                                                 , ppr (idType fn), ppr theta
 908                                                 , ppr n_dicts, ppr rhs_dicts
 909                                                 , ppr rhs])
 910 #endif
 911          | otherwise               = zipEqual doc xs ys
 912 \end{code}
 913
 914 Note [Specialisation shape]
 915 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 916 We only specialise a function if it has visible top-level lambdas
 917 corresponding to its overloading.  E.g. if
 918         f :: forall a. Eq a => ....
 919 then its body must look like
 920         f = /\a. \d. ...
 921
 922 Reason: when specialising the body for a call (f ty dexp), we want to
 923 substitute dexp for d, and pick up specialised calls in the body of f.
 924
 925 This doesn't always work.  One example I came across was htis:
 926         newtype Gen a = MkGen{ unGen :: Int -> a }
 927
 928         choose :: Eq a => a -> Gen a
 929         choose n = MkGen (\r -> n)
 930
 931         oneof = choose (1::Int)
 932
 933 It's a silly exapmle, but we get
 934         choose = /\a. g `cast` co
 935 where choose doesn't have any dict arguments.  Thus far I have not
 936 tried to fix this (wait till there's a real example).
 937
 938
 939 Note [Inline specialisations]
 940 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 941 We transfer to the specialised function any INLINE stuff from the
 942 original.  This means (a) the Activation in the IdInfo, and (b) any
 943 InlineMe on the RHS.
 944
 945 This is a change (Jun06).  Previously the idea is that the point of
 946 inlining was precisely to specialise the function at its call site,
 947 and that's not so important for the specialised copies.  But
 948 *pragma-directed* specialisation now takes place in the
 949 typechecker/desugarer, with manually specified INLINEs.  The
 950 specialiation here is automatic.  It'd be very odd if a function
 951 marked INLINE was specialised (because of some local use), and then
 952 forever after (including importing modules) the specialised version
 953 wasn't INLINEd.  After all, the programmer said INLINE!
 954
 955 You might wonder why we don't just not specialise INLINE functions.
 956 It's because even INLINE functions are sometimes not inlined, when
 957 they aren't applied to interesting arguments.  But perhaps the type
 958 arguments alone are enough to specialise (even though the args are too
 959 boring to trigger inlining), and it's certainly better to call the
 960 specialised version.
 961
 962 A case in point is dictionary functions, which are current marked
 963 INLINE, but which are worth specialising.
 964
 965 \begin{code}
 966 dropInline :: CoreExpr -> (Bool, CoreExpr)
 967 dropInline (Note InlineMe rhs) = (True,  rhs)
 968 dropInline rhs                 = (False, rhs)
 969 \end{code}
 970
 971 %************************************************************************
 972 %*                                                                      *
 973 \subsubsection{UsageDetails and suchlike}
 974 %*                                                                      *
 975 %************************************************************************
 976
 977 \begin{code}
 978 data UsageDetails
 979   = MkUD {
 980         dict_binds :: !(Bag DictBind),
 981                         -- Floated dictionary bindings
 982                         -- The order is important;
 983                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
 984                         -- (Remember, Bags preserve order in GHC.)
 985
 986         calls     :: !CallDetails
 987     }
 988
 989 type DictBind = (CoreBind, VarSet)
 990         -- The set is the free vars of the binding
 991         -- both tyvars and dicts
 992
 993 type DictExpr = CoreExpr
 994
 995 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM }
 996
 997 type ProtoUsageDetails = ([DictBind],
 998                           [(Id, CallKey, ([DictExpr], VarSet))]
 999                          )
1000
1001 ------------------------------------------------------------
1002 type CallDetails  = FiniteMap Id CallInfo
1003 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1004 type CallInfo     = FiniteMap CallKey
1005                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
1006                                                                 -- call (including tyvars)
1007                                                                 -- [*not* include the main id itself, of course]
1008         -- The finite maps eliminate duplicates
1009         -- The list of types and dictionaries is guaranteed to
1010         -- match the type of f
1011
1012 -- Type isn't an instance of Ord, so that we can control which
1013 -- instance we use.  That's tiresome here.  Oh well
1014 instance Eq CallKey where
1015   k1 == k2 = case k1 `compare` k2 of { EQ -> True; other -> False }
1016
1017 instance Ord CallKey where
1018   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1019                 where
1020                   cmp Nothing Nothing     = EQ
1021                   cmp Nothing (Just t2)   = LT
1022                   cmp (Just t1) Nothing   = GT
1023                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1024
1025 unionCalls :: CallDetails -> CallDetails -> CallDetails
1026 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1027
1028 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> CallDetails
1029 singleCall id tys dicts
1030   = unitFM id (unitFM (CallKey tys) (dicts, call_fvs))
1031   where
1032     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1033     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1034         -- The type args (tys) are guaranteed to be part of the dictionary
1035         -- types, because they are just the constrained types,
1036         -- and the dictionary is therefore sure to be bound
1037         -- inside the binding for any type variables free in the type;
1038         -- hence it's safe to neglect tyvars free in tys when making
1039         -- the free-var set for this call
1040         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1041         --
1042         -- We don't include the 'id' itself.
1043
1044 listToCallDetails calls
1045   = foldr (unionCalls . mk_call) emptyFM calls
1046   where
1047     mk_call (id, tys, dicts_w_fvs) = unitFM id (unitFM tys dicts_w_fvs)
1048         -- NB: the free vars of the call are provided
1049
1050 callDetailsToList calls = [ (id,tys,dicts)
1051                           | (id,fm) <- fmToList calls,
1052                             (tys, dicts) <- fmToList fm
1053                           ]
1054
1055 mkCallUDs subst f args
1056   | null theta
1057   || not (all isClassPred theta)
1058         -- Only specialise if all overloading is on class params.
1059         -- In ptic, with implicit params, the type args
1060         --  *don't* say what the value of the implicit param is!
1061   || not (spec_tys `lengthIs` n_tyvars)
1062   || not ( dicts   `lengthIs` n_dicts)
1063   || maybeToBool (lookupRule (\act -> True) (substInScope subst) emptyRuleBase f args)
1064         -- There's already a rule covering this call.  A typical case
1065         -- is where there's an explicit user-provided rule.  Then
1066         -- we don't want to create a specialised version
1067         -- of the function that overlaps.
1068   = emptyUDs    -- Not overloaded, or no specialisation wanted
1069
1070   | otherwise
1071   = MkUD {dict_binds = emptyBag,
1072           calls      = singleCall f spec_tys dicts
1073     }
1074   where
1075     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1076     constrained_tyvars = tyVarsOfTheta theta
1077     n_tyvars           = length tyvars
1078     n_dicts            = length theta
1079
1080     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1081     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1082
1083     mk_spec_ty tyvar ty
1084         | tyvar `elemVarSet` constrained_tyvars = Just ty
1085         | otherwise                             = Nothing
1086
1087 ------------------------------------------------------------
1088 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1089 plusUDs (MkUD {dict_binds = db1, calls = calls1})
1090         (MkUD {dict_binds = db2, calls = calls2})
1091   = MkUD {dict_binds = d, calls = c}
1092   where
1093     d = db1    `unionBags`   db2
1094     c = calls1 `unionCalls`  calls2
1095
1096 plusUDList = foldr plusUDs emptyUDs
1097
1098 -- zapCalls deletes calls to ids from uds
1099 zapCalls ids uds = uds {calls = delListFromFM (calls uds) ids}
1100
1101 mkDB bind = (bind, bind_fvs bind)
1102
1103 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1104 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1105                            where
1106                              bndrs = map fst prs
1107                              rhs_fvs = unionVarSets (map pair_fvs prs)
1108
1109 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1110         -- Don't forget variables mentioned in the
1111         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1112         -- Also tyvars mentioned in its type; they may not appear in the RHS
1113         --      type T a = Int
1114         --      x :: T a = 3
1115
1116 addDictBind (dict,rhs) uds = uds { dict_binds = mkDB (NonRec dict rhs) `consBag` dict_binds uds }
1117
1118 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1119   = foldrBag add binds dbs
1120   where
1121     add (bind,_) binds = bind : binds
1122
1123 dumpUDs :: [CoreBndr]
1124         -> UsageDetails -> CoreExpr
1125         -> (UsageDetails, CoreExpr)
1126 dumpUDs bndrs uds body
1127   = (free_uds, foldr add_let body dict_binds)
1128   where
1129     (free_uds, (dict_binds, _)) = splitUDs bndrs uds
1130     add_let (bind,_) body       = Let bind body
1131
1132 splitUDs :: [CoreBndr]
1133          -> UsageDetails
1134          -> (UsageDetails,              -- These don't mention the binders
1135              ProtoUsageDetails)         -- These do
1136
1137 splitUDs bndrs uds@(MkUD {dict_binds = orig_dbs,
1138                           calls      = orig_calls})
1139
1140   = if isEmptyBag dump_dbs && null dump_calls then
1141         -- Common case: binder doesn't affect floats
1142         (uds, ([],[]))
1143
1144     else
1145         -- Binders bind some of the fvs of the floats
1146         (MkUD {dict_binds = free_dbs,
1147                calls      = listToCallDetails free_calls},
1148          (bagToList dump_dbs, dump_calls)
1149         )
1150
1151   where
1152     bndr_set = mkVarSet bndrs
1153
1154     (free_dbs, dump_dbs, dump_idset)
1155           = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1156                 -- Important that it's foldl not foldr;
1157                 -- we're accumulating the set of dumped ids in dump_set
1158
1159         -- Filter out any calls that mention things that are being dumped
1160     orig_call_list                 = callDetailsToList orig_calls
1161     (dump_calls, free_calls)       = partition captured orig_call_list
1162     captured (id,tys,(dicts, fvs)) =  fvs `intersectsVarSet` dump_idset
1163                                    || id `elemVarSet` dump_idset
1164
1165     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1166         | dump_idset `intersectsVarSet` fvs     -- Dump it
1167         = (free_dbs, dump_dbs `snocBag` db,
1168            extendVarSetList dump_idset (bindersOf bind))
1169
1170         | otherwise     -- Don't dump it
1171         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1172 \end{code}
1173
1174
1175 %************************************************************************
1176 %*                                                                      *
1177 \subsubsection{Boring helper functions}
1178 %*                                                                      *
1179 %************************************************************************
1180
1181 \begin{code}
1182 type SpecM a = UniqSM a
1183
1184 thenSM    = thenUs
1185 returnSM  = returnUs
1186 getUniqSM = getUniqueUs
1187 mapSM     = mapUs
1188 initSM    = initUs_
1189
1190 mapAndCombineSM f []     = returnSM ([], emptyUDs)
1191 mapAndCombineSM f (x:xs) = f x  `thenSM` \ (y, uds1) ->
1192                            mapAndCombineSM f xs `thenSM` \ (ys, uds2) ->
1193                            returnSM (y:ys, uds1 `plusUDs` uds2)
1194
1195 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1196 -- Clone the binders of the bind; return new bind with the cloned binders
1197 -- Return the substitution to use for RHSs, and the one to use for the body
1198 cloneBindSM subst (NonRec bndr rhs)
1199   = getUs       `thenUs` \ us ->
1200     let
1201         (subst', bndr') = cloneIdBndr subst us bndr
1202     in
1203     returnUs (subst, subst', NonRec bndr' rhs)
1204
1205 cloneBindSM subst (Rec pairs)
1206   = getUs       `thenUs` \ us ->
1207     let
1208         (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1209     in
1210     returnUs (subst', subst', Rec (bndrs' `zip` map snd pairs))
1211
1212 cloneBinders subst bndrs
1213   = getUs       `thenUs` \ us ->
1214     returnUs (cloneIdBndrs subst us bndrs)
1215
1216 newIdSM old_id new_ty
1217   = getUniqSM           `thenSM` \ uniq ->
1218     let
1219         -- Give the new Id a similar occurrence name to the old one
1220         name   = idName old_id
1221         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcSpan name)
1222     in
1223     returnSM new_id
1224 \end{code}
1225
1226
1227                 Old (but interesting) stuff about unboxed bindings
1228                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1229
1230 What should we do when a value is specialised to a *strict* unboxed value?
1231
1232         map_*_* f (x:xs) = let h = f x
1233                                t = map f xs
1234                            in h:t
1235
1236 Could convert let to case:
1237
1238         map_*_Int# f (x:xs) = case f x of h# ->
1239                               let t = map f xs
1240                               in h#:t
1241
1242 This may be undesirable since it forces evaluation here, but the value
1243 may not be used in all branches of the body. In the general case this
1244 transformation is impossible since the mutual recursion in a letrec
1245 cannot be expressed as a case.
1246
1247 There is also a problem with top-level unboxed values, since our
1248 implementation cannot handle unboxed values at the top level.
1249
1250 Solution: Lift the binding of the unboxed value and extract it when it
1251 is used:
1252
1253         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1254                                   t = map f xs
1255                               in case h of
1256                                  _Lift h# -> h#:t
1257
1258 Now give it to the simplifier and the _Lifting will be optimised away.
1259
1260 The benfit is that we have given the specialised "unboxed" values a
1261 very simplep lifted semantics and then leave it up to the simplifier to
1262 optimise it --- knowing that the overheads will be removed in nearly
1263 all cases.
1264
1265 In particular, the value will only be evaluted in the branches of the
1266 program which use it, rather than being forced at the point where the
1267 value is bound. For example:
1268
1269         filtermap_*_* p f (x:xs)
1270           = let h = f x
1271                 t = ...
1272             in case p x of
1273                 True  -> h:t
1274                 False -> t
1275    ==>
1276         filtermap_*_Int# p f (x:xs)
1277           = let h = case (f x) of h# -> _Lift h#
1278                 t = ...
1279             in case p x of
1280                 True  -> case h of _Lift h#
1281                            -> h#:t
1282                 False -> t
1283
1284 The binding for h can still be inlined in the one branch and the
1285 _Lifting eliminated.
1286
1287
1288 Question: When won't the _Lifting be eliminated?
1289
1290 Answer: When they at the top-level (where it is necessary) or when
1291 inlining would duplicate work (or possibly code depending on
1292 options). However, the _Lifting will still be eliminated if the
1293 strictness analyser deems the lifted binding strict.
1294