compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import DynFlags ( DynFlags, DynFlag(..) )
  18 import Id               ( Id, idName, idType, mkUserLocal,
  19                           idInlinePragma, setInlinePragma )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs
  27                         )
  28 import VarSet
  29 import VarEnv
  30 import CoreSyn
  31 import CoreUtils        ( applyTypeToArgs, mkPiTypes )
  32 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  33 import CoreTidy         ( tidyRules )
  34 import CoreLint         ( showPass, endPass )
  35 import Rules            ( addIdSpecialisations, mkLocalRule, lookupRule, emptyRuleBase, rulesOfBinds )
  36 import PprCore          ( pprRules )
  37 import UniqSupply       ( UniqSupply,
  38                           UniqSM, initUs_,
  39                           MonadUnique(..)
  40                         )
  41 import Name
  42 import MkId             ( voidArgId, realWorldPrimId )
  43 import FiniteMap
  44 import Maybes           ( catMaybes, maybeToBool )
  45 import ErrUtils         ( dumpIfSet_dyn )
  46 import Bag
  47 import Util
  48 import Outputable
  49 import FastString
  50
  51 \end{code}
  52
  53 %************************************************************************
  54 %*                                                                      *
  55 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  56 %*                                                                      *
  57 %************************************************************************
  58
  59 These notes describe how we implement specialisation to eliminate
  60 overloading.
  61
  62 The specialisation pass works on Core
  63 syntax, complete with all the explicit dictionary application,
  64 abstraction and construction as added by the type checker.  The
  65 existing type checker remains largely as it is.
  66
  67 One important thought: the {\em types} passed to an overloaded
  68 function, and the {\em dictionaries} passed are mutually redundant.
  69 If the same function is applied to the same type(s) then it is sure to
  70 be applied to the same dictionary(s)---or rather to the same {\em
  71 values}.  (The arguments might look different but they will evaluate
  72 to the same value.)
  73
  74 Second important thought: we know that we can make progress by
  75 treating dictionary arguments as static and worth specialising on.  So
  76 we can do without binding-time analysis, and instead specialise on
  77 dictionary arguments and no others.
  78
  79 The basic idea
  80 ~~~~~~~~~~~~~~
  81 Suppose we have
  82
  83         let f = <f_rhs>
  84         in <body>
  85
  86 and suppose f is overloaded.
  87
  88 STEP 1: CALL-INSTANCE COLLECTION
  89
  90 We traverse <body>, accumulating all applications of f to types and
  91 dictionaries.
  92
  93 (Might there be partial applications, to just some of its types and
  94 dictionaries?  In principle yes, but in practice the type checker only
  95 builds applications of f to all its types and dictionaries, so partial
  96 applications could only arise as a result of transformation, and even
  97 then I think it's unlikely.  In any case, we simply don't accumulate such
  98 partial applications.)
  99
 100
 101 STEP 2: EQUIVALENCES
 102
 103 So now we have a collection of calls to f:
 104         f t1 t2 d1 d2
 105         f t3 t4 d3 d4
 106         ...
 107 Notice that f may take several type arguments.  To avoid ambiguity, we
 108 say that f is called at type t1/t2 and t3/t4.
 109
 110 We take equivalence classes using equality of the *types* (ignoring
 111 the dictionary args, which as mentioned previously are redundant).
 112
 113 STEP 3: SPECIALISATION
 114
 115 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 116 and create a local instance of f, defined thus:
 117
 118         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 119
 120 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 121 of simplification will now result.  However we don't actually *do* that
 122 simplification.  Rather, we leave it for the simplifier to do.  If we
 123 *did* do it, though, we'd get more call instances from the specialised
 124 RHS.  We can work out what they are by instantiating the call-instance
 125 set from f's RHS with the types t1, t2.
 126
 127 Add this new id to f's IdInfo, to record that f has a specialised version.
 128
 129 Before doing any of this, check that f's IdInfo doesn't already
 130 tell us about an existing instance of f at the required type/s.
 131 (This might happen if specialisation was applied more than once, or
 132 it might arise from user SPECIALIZE pragmas.)
 133
 134 Recursion
 135 ~~~~~~~~~
 136 Wait a minute!  What if f is recursive?  Then we can't just plug in
 137 its right-hand side, can we?
 138
 139 But it's ok.  The type checker *always* creates non-recursive definitions
 140 for overloaded recursive functions.  For example:
 141
 142         f x = f (x+x)           -- Yes I know its silly
 143
 144 becomes
 145
 146         f a (d::Num a) = let p = +.sel a d
 147                          in
 148                          letrec fl (y::a) = fl (p y y)
 149                          in
 150                          fl
 151
 152 We still have recusion for non-overloaded functions which we
 153 speciailise, but the recursive call should get specialised to the
 154 same recursive version.
 155
 156
 157 Polymorphism 1
 158 ~~~~~~~~~~~~~~
 159
 160 All this is crystal clear when the function is applied to *constant
 161 types*; that is, types which have no type variables inside.  But what if
 162 it is applied to non-constant types?  Suppose we find a call of f at type
 163 t1/t2.  There are two possibilities:
 164
 165 (a) The free type variables of t1, t2 are in scope at the definition point
 166 of f.  In this case there's no problem, we proceed just as before.  A common
 167 example is as follows.  Here's the Haskell:
 168
 169         g y = let f x = x+x
 170               in f y + f y
 171
 172 After typechecking we have
 173
 174         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 175                                 in +.sel a d (f a d y) (f a d y)
 176
 177 Notice that the call to f is at type type "a"; a non-constant type.
 178 Both calls to f are at the same type, so we can specialise to give:
 179
 180         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 181                                 in +.sel a d (f@a y) (f@a y)
 182
 183
 184 (b) The other case is when the type variables in the instance types
 185 are *not* in scope at the definition point of f.  The example we are
 186 working with above is a good case.  There are two instances of (+.sel a d),
 187 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 188 Yes, we can "common them up", a sort of limited common sub-expression deal.
 189 This would give:
 190
 191         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 192                                     f@a (x::a) = +.sel@a x x
 193                                 in +.sel@a (f@a y) (f@a y)
 194
 195 This can save work, and can't be spotted by the type checker, because
 196 the two instances of +.sel weren't originally at the same type.
 197
 198 Further notes on (b)
 199
 200 * There are quite a few variations here.  For example, the defn of
 201   +.sel could be floated ouside the \y, to attempt to gain laziness.
 202   It certainly mustn't be floated outside the \d because the d has to
 203   be in scope too.
 204
 205 * We don't want to inline f_rhs in this case, because
 206 that will duplicate code.  Just commoning up the call is the point.
 207
 208 * Nothing gets added to +.sel's IdInfo.
 209
 210 * Don't bother unless the equivalence class has more than one item!
 211
 212 Not clear whether this is all worth it.  It is of course OK to
 213 simply discard call-instances when passing a big lambda.
 214
 215 Polymorphism 2 -- Overloading
 216 ~~~~~~~~~~~~~~
 217 Consider a function whose most general type is
 218
 219         f :: forall a b. Ord a => [a] -> b -> b
 220
 221 There is really no point in making a version of g at Int/Int and another
 222 at Int/Bool, because it's only instancing the type variable "a" which
 223 buys us any efficiency. Since g is completely polymorphic in b there
 224 ain't much point in making separate versions of g for the different
 225 b types.
 226
 227 That suggests that we should identify which of g's type variables
 228 are constrained (like "a") and which are unconstrained (like "b").
 229 Then when taking equivalence classes in STEP 2, we ignore the type args
 230 corresponding to unconstrained type variable.  In STEP 3 we make
 231 polymorphic versions.  Thus:
 232
 233         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 234
 235 We do this.
 236
 237
 238 Dictionary floating
 239 ~~~~~~~~~~~~~~~~~~~
 240 Consider this
 241
 242         f a (d::Num a) = let g = ...
 243                          in
 244                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 245
 246 Here, g is only called at one type, but the dictionary isn't in scope at the
 247 definition point for g.  Usually the type checker would build a
 248 definition for d1 which enclosed g, but the transformation system
 249 might have moved d1's defn inward.  Solution: float dictionary bindings
 250 outwards along with call instances.
 251
 252 Consider
 253
 254         f x = let g p q = p==q
 255                   h r s = (r+s, g r s)
 256               in
 257               h x x
 258
 259
 260 Before specialisation, leaving out type abstractions we have
 261
 262         f df x = let g :: Eq a => a -> a -> Bool
 263                      g dg p q = == dg p q
 264                      h :: Num a => a -> a -> (a, Bool)
 265                      h dh r s = let deq = eqFromNum dh
 266                                 in (+ dh r s, g deq r s)
 267               in
 268               h df x x
 269
 270 After specialising h we get a specialised version of h, like this:
 271
 272                     h' r s = let deq = eqFromNum df
 273                              in (+ df r s, g deq r s)
 274
 275 But we can't naively make an instance for g from this, because deq is not in scope
 276 at the defn of g.  Instead, we have to float out the (new) defn of deq
 277 to widen its scope.  Notice that this floating can't be done in advance -- it only
 278 shows up when specialisation is done.
 279
 280 User SPECIALIZE pragmas
 281 ~~~~~~~~~~~~~~~~~~~~~~~
 282 Specialisation pragmas can be digested by the type checker, and implemented
 283 by adding extra definitions along with that of f, in the same way as before
 284
 285         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 286
 287 Indeed the pragmas *have* to be dealt with by the type checker, because
 288 only it knows how to build the dictionaries d1 and d2!  For example
 289
 290         g :: Ord a => [a] -> [a]
 291         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 292
 293 Here, the specialised version of g is an application of g's rhs to the
 294 Ord dictionary for (Tree Int), which only the type checker can conjure
 295 up.  There might not even *be* one, if (Tree Int) is not an instance of
 296 Ord!  (All the other specialision has suitable dictionaries to hand
 297 from actual calls.)
 298
 299 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 300 it is buried in a complex (as-yet-un-desugared) binding group.
 301 Maybe we should say
 302
 303         f@t1/t2 = f* t1 t2 d1 d2
 304
 305 where f* is the Id f with an IdInfo which says "inline me regardless!".
 306 Indeed all the specialisation could be done in this way.
 307 That in turn means that the simplifier has to be prepared to inline absolutely
 308 any in-scope let-bound thing.
 309
 310
 311 Again, the pragma should permit polymorphism in unconstrained variables:
 312
 313         h :: Ord a => [a] -> b -> b
 314         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 315
 316 We *insist* that all overloaded type variables are specialised to ground types,
 317 (and hence there can be no context inside a SPECIALIZE pragma).
 318 We *permit* unconstrained type variables to be specialised to
 319         - a ground type
 320         - or left as a polymorphic type variable
 321 but nothing in between.  So
 322
 323         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 324
 325 is *illegal*.  (It can be handled, but it adds complication, and gains the
 326 programmer nothing.)
 327
 328
 329 SPECIALISING INSTANCE DECLARATIONS
 330 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 331 Consider
 332
 333         instance Foo a => Foo [a] where
 334                 ...
 335         {-# SPECIALIZE instance Foo [Int] #-}
 336
 337 The original instance decl creates a dictionary-function
 338 definition:
 339
 340         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 341
 342 The SPECIALIZE pragma just makes a specialised copy, just as for
 343 ordinary function definitions:
 344
 345         dfun.Foo.List@Int :: Foo [Int]
 346         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 347
 348 The information about what instance of the dfun exist gets added to
 349 the dfun's IdInfo in the same way as a user-defined function too.
 350
 351
 352 Automatic instance decl specialisation?
 353 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 354 Can instance decls be specialised automatically?  It's tricky.
 355 We could collect call-instance information for each dfun, but
 356 then when we specialised their bodies we'd get new call-instances
 357 for ordinary functions; and when we specialised their bodies, we might get
 358 new call-instances of the dfuns, and so on.  This all arises because of
 359 the unrestricted mutual recursion between instance decls and value decls.
 360
 361 Still, there's no actual problem; it just means that we may not do all
 362 the specialisation we could theoretically do.
 363
 364 Furthermore, instance decls are usually exported and used non-locally,
 365 so we'll want to compile enough to get those specialisations done.
 366
 367 Lastly, there's no such thing as a local instance decl, so we can
 368 survive solely by spitting out *usage* information, and then reading that
 369 back in as a pragma when next compiling the file.  So for now,
 370 we only specialise instance decls in response to pragmas.
 371
 372
 373 SPITTING OUT USAGE INFORMATION
 374 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 375
 376 To spit out usage information we need to traverse the code collecting
 377 call-instance information for all imported (non-prelude?) functions
 378 and data types. Then we equivalence-class it and spit it out.
 379
 380 This is done at the top-level when all the call instances which escape
 381 must be for imported functions and data types.
 382
 383 *** Not currently done ***
 384
 385
 386 Partial specialisation by pragmas
 387 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 388 What about partial specialisation:
 389
 390         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 391         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 392
 393 or even
 394
 395         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 396
 397 Seems quite reasonable.  Similar things could be done with instance decls:
 398
 399         instance (Foo a, Foo b) => Foo (a,b) where
 400                 ...
 401         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 402         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 403
 404 Ho hum.  Things are complex enough without this.  I pass.
 405
 406
 407 Requirements for the simplifer
 408 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 409 The simplifier has to be able to take advantage of the specialisation.
 410
 411 * When the simplifier finds an application of a polymorphic f, it looks in
 412 f's IdInfo in case there is a suitable instance to call instead.  This converts
 413
 414         f t1 t2 d1 d2   ===>   f_t1_t2
 415
 416 Note that the dictionaries get eaten up too!
 417
 418 * Dictionary selection operations on constant dictionaries must be
 419   short-circuited:
 420
 421         +.sel Int d     ===>  +Int
 422
 423 The obvious way to do this is in the same way as other specialised
 424 calls: +.sel has inside it some IdInfo which tells that if it's applied
 425 to the type Int then it should eat a dictionary and transform to +Int.
 426
 427 In short, dictionary selectors need IdInfo inside them for constant
 428 methods.
 429
 430 * Exactly the same applies if a superclass dictionary is being
 431   extracted:
 432
 433         Eq.sel Int d   ===>   dEqInt
 434
 435 * Something similar applies to dictionary construction too.  Suppose
 436 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 437 one for (Eq [a]).  Then we want
 438
 439         dfun.Eq.List Int d      ===> dEq.List_Int
 440
 441 Where does the Eq [Int] dictionary come from?  It is built in
 442 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 443
 444 In short, dfun Ids need IdInfo with a specialisation for each
 445 constant instance of their instance declaration.
 446
 447 All this uses a single mechanism: the SpecEnv inside an Id
 448
 449
 450 What does the specialisation IdInfo look like?
 451 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 452
 453 The SpecEnv of an Id maps a list of types (the template) to an expression
 454
 455         [Type]  |->  Expr
 456
 457 For example, if f has this SpecInfo:
 458
 459         [Int, a]  ->  \d:Ord Int. f' a
 460
 461 it means that we can replace the call
 462
 463         f Int t  ===>  (\d. f' t)
 464
 465 This chucks one dictionary away and proceeds with the
 466 specialised version of f, namely f'.
 467
 468
 469 What can't be done this way?
 470 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 471 There is no way, post-typechecker, to get a dictionary for (say)
 472 Eq a from a dictionary for Eq [a].  So if we find
 473
 474         ==.sel [t] d
 475
 476 we can't transform to
 477
 478         eqList (==.sel t d')
 479
 480 where
 481         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 482
 483 Of course, we currently have no way to automatically derive
 484 eqList, nor to connect it to the Eq [a] instance decl, but you
 485 can imagine that it might somehow be possible.  Taking advantage
 486 of this is permanently ruled out.
 487
 488 Still, this is no great hardship, because we intend to eliminate
 489 overloading altogether anyway!
 490
 491
 492
 493 A note about non-tyvar dictionaries
 494 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 495 Some Ids have types like
 496
 497         forall a,b,c. Eq a -> Ord [a] -> tau
 498
 499 This seems curious at first, because we usually only have dictionary
 500 args whose types are of the form (C a) where a is a type variable.
 501 But this doesn't hold for the functions arising from instance decls,
 502 which sometimes get arguements with types of form (C (T a)) for some
 503 type constructor T.
 504
 505 Should we specialise wrt this compound-type dictionary?  We used to say
 506 "no", saying:
 507         "This is a heuristic judgement, as indeed is the fact that we
 508         specialise wrt only dictionaries.  We choose *not* to specialise
 509         wrt compound dictionaries because at the moment the only place
 510         they show up is in instance decls, where they are simply plugged
 511         into a returned dictionary.  So nothing is gained by specialising
 512         wrt them."
 513
 514 But it is simpler and more uniform to specialise wrt these dicts too;
 515 and in future GHC is likely to support full fledged type signatures
 516 like
 517         f ;: Eq [(a,b)] => ...
 518
 519
 520 %************************************************************************
 521 %*                                                                      *
 522 \subsubsection{The new specialiser}
 523 %*                                                                      *
 524 %************************************************************************
 525
 526 Our basic game plan is this.  For let(rec) bound function
 527         f :: (C a, D c) => (a,b,c,d) -> Bool
 528
 529 * Find any specialised calls of f, (f ts ds), where
 530   ts are the type arguments t1 .. t4, and
 531   ds are the dictionary arguments d1 .. d2.
 532
 533 * Add a new definition for f1 (say):
 534
 535         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 536
 537   Note that we abstract over the unconstrained type arguments.
 538
 539 * Add the mapping
 540
 541         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 542
 543   to the specialisations of f.  This will be used by the
 544   simplifier to replace calls
 545                 (f t1 t2 t3 t4) da db
 546   by
 547                 (\d1 d1 -> f1 t2 t4) da db
 548
 549   All the stuff about how many dictionaries to discard, and what types
 550   to apply the specialised function to, are handled by the fact that the
 551   SpecEnv contains a template for the result of the specialisation.
 552
 553 We don't build *partial* specialisations for f.  For example:
 554
 555   f :: Eq a => a -> a -> Bool
 556   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 557
 558 Here, little is gained by making a specialised copy of f.
 559 There's a distinct danger that the specialised version would
 560 first build a dictionary for (Eq b, Eq c), and then select the (==)
 561 method from it!  Even if it didn't, not a great deal is saved.
 562
 563 We do, however, generate polymorphic, but not overloaded, specialisations:
 564
 565   f :: Eq a => [a] -> b -> b -> b
 566   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 567
 568 Hence, the invariant is this:
 569
 570         *** no specialised version is overloaded ***
 571
 572
 573 %************************************************************************
 574 %*                                                                      *
 575 \subsubsection{The exported function}
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 \begin{code}
 580 specProgram :: DynFlags -> UniqSupply -> [CoreBind] -> IO [CoreBind]
 581 specProgram dflags us binds = do
 582
 583         showPass dflags "Specialise"
 584
 585         let binds' = initSM us (do (binds', uds') <- go binds
 586                                    return (dumpAllDictBinds uds' binds'))
 587
 588         endPass dflags "Specialise" Opt_D_dump_spec binds'
 589
 590         dumpIfSet_dyn dflags Opt_D_dump_rules "Top-level specialisations"
 591                   (pprRules (tidyRules emptyTidyEnv (rulesOfBinds binds')))
 592
 593         return binds'
 594   where
 595         -- We need to start with a Subst that knows all the things
 596         -- that are in scope, so that the substitution engine doesn't
 597         -- accidentally re-use a unique that's already in use
 598         -- Easiest thing is to do it all at once, as if all the top-level
 599         -- decls were mutually recursive
 600     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 601
 602     go []           = return ([], emptyUDs)
 603     go (bind:binds) = do (binds', uds) <- go binds
 604                          (bind', uds') <- specBind top_subst bind uds
 605                          return (bind' ++ binds', uds')
 606 \end{code}
 607
 608 %************************************************************************
 609 %*                                                                      *
 610 \subsubsection{@specExpr@: the main function}
 611 %*                                                                      *
 612 %************************************************************************
 613
 614 \begin{code}
 615 specVar :: Subst -> Id -> CoreExpr
 616 specVar subst v = lookupIdSubst subst v
 617
 618 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 619 -- We carry a substitution down:
 620 --      a) we must clone any binding that might flaot outwards,
 621 --         to avoid name clashes
 622 --      b) we carry a type substitution to use when analysing
 623 --         the RHS of specialised bindings (no type-let!)
 624
 625 ---------------- First the easy cases --------------------
 626 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 627 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 628 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 629 specExpr subst (Cast e co) = do
 630     (e', uds) <- specExpr subst e
 631     return ((Cast e' (substTy subst co)), uds)
 632 specExpr subst (Note note body) = do
 633     (body', uds) <- specExpr subst body
 634     return (Note (specNote subst note) body', uds)
 635
 636
 637 ---------------- Applications might generate a call instance --------------------
 638 specExpr subst expr@(App {})
 639   = go expr []
 640   where
 641     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 642                                (fun', uds_app) <- go fun (arg':args)
 643                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 644
 645     go (Var f)       args = case specVar subst f of
 646                                 Var f' -> return (Var f', mkCallUDs subst f' args)
 647                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 648     go other         _    = specExpr subst other
 649
 650 ---------------- Lambda/case require dumping of usage details --------------------
 651 specExpr subst e@(Lam _ _) = do
 652     (body', uds) <- specExpr subst' body
 653     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 654     return (mkLams bndrs' body'', filtered_uds)
 655   where
 656     (bndrs, body) = collectBinders e
 657     (subst', bndrs') = substBndrs subst bndrs
 658         -- More efficient to collect a group of binders together all at once
 659         -- and we don't want to split a lambda group with dumped bindings
 660
 661 specExpr subst (Case scrut case_bndr ty alts) = do
 662     (scrut', uds_scrut) <- specExpr subst scrut
 663     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 664     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 665   where
 666     (subst_alt, case_bndr') = substBndr subst case_bndr
 667         -- No need to clone case binder; it can't float like a let(rec)
 668
 669     spec_alt (con, args, rhs) = do
 670           (rhs', uds) <- specExpr subst_rhs rhs
 671           let (uds', rhs'') = dumpUDs args uds rhs'
 672           return ((con, args', rhs''), uds')
 673         where
 674           (subst_rhs, args') = substBndrs subst_alt args
 675
 676 ---------------- Finally, let is the interesting case --------------------
 677 specExpr subst (Let bind body) = do
 678         -- Clone binders
 679     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 680
 681         -- Deal with the body
 682     (body', body_uds) <- specExpr body_subst body
 683
 684         -- Deal with the bindings
 685     (binds', uds) <- specBind rhs_subst bind' body_uds
 686
 687         -- All done
 688     return (foldr Let body' binds', uds)
 689
 690 -- Must apply the type substitution to coerceions
 691 specNote :: Subst -> Note -> Note
 692 specNote _ note = note
 693 \end{code}
 694
 695 %************************************************************************
 696 %*                                                                      *
 697 \subsubsection{Dealing with a binding}
 698 %*                                                                      *
 699 %************************************************************************
 700
 701 \begin{code}
 702 specBind :: Subst                       -- Use this for RHSs
 703          -> CoreBind
 704          -> UsageDetails                -- Info on how the scope of the binding
 705          -> SpecM ([CoreBind],          -- New bindings
 706                    UsageDetails)        -- And info to pass upstream
 707
 708 specBind rhs_subst bind body_uds
 709   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 710         ; return (finishSpecBind bind' bind_uds body_uds) }
 711
 712 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 713 finishSpecBind bind
 714         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 715         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 716   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 717                 -- Common case 1: the bound variables are not
 718                 --                mentioned in the dictionary bindings
 719   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 720                         -- It's important that the `unionBags` is this way round,
 721                         -- because body_uds may bind dictionaries that are
 722                         -- used in the calls passed to specDefn.  So the
 723                         -- dictionary bindings in rhs_uds may mention
 724                         -- dictionaries bound in body_uds.
 725                   , calls  = all_calls
 726                   , ud_fvs = all_fvs })
 727
 728   | case bind of { NonRec {} -> True; Rec {} -> False }
 729                 -- Common case 2: no specialisation happened, and binding
 730                 --                is non-recursive.  But the binding may be
 731                 --                mentioned in body_dbs, so we should put it first
 732   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 733               , calls      = all_calls
 734               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 735
 736   | otherwise   -- General case: make a huge Rec (sigh)
 737   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 738               , calls      = all_calls
 739               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 740   where
 741     all_fvs = rhs_fvs `unionVarSet` body_fvs
 742     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 743
 744     bndrs   = bindersOf bind
 745     b_fvs   = bind_fvs bind
 746
 747     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 748                                foldrBag add ([], emptyVarSet) $
 749                                rhs_dbs `unionBags` body_dbs
 750     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 751     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 752
 753 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 754
 755 -- specBindItself deals with the RHS, specialising it according
 756 -- to the calls found in the body (if any)
 757 specBindItself rhs_subst (NonRec bndr rhs) call_info = do
 758     ((bndr',rhs'), spec_defns, spec_uds) <- specDefn rhs_subst call_info (bndr,rhs)
 759     let
 760         new_bind | null spec_defns = NonRec bndr' rhs'
 761                  | otherwise       = Rec ((bndr',rhs'):spec_defns)
 762                 -- bndr' mentions the spec_defns in its SpecEnv
 763                 -- Not sure why we couln't just put the spec_defns first
 764     return (new_bind, spec_uds)
 765
 766 specBindItself rhs_subst (Rec pairs) call_info = do
 767     stuff <- mapM (specDefn rhs_subst call_info) pairs
 768     let
 769         (pairs', spec_defns_s, spec_uds_s) = unzip3 stuff
 770         spec_defns = concat spec_defns_s
 771         spec_uds   = plusUDList spec_uds_s
 772         new_bind   = Rec (spec_defns ++ pairs')
 773     return (new_bind, spec_uds)
 774
 775
 776 specDefn :: Subst                       -- Subst to use for RHS
 777          -> CallDetails                 -- Info on how it is used in its scope
 778          -> (Id, CoreExpr)              -- The thing being bound and its un-processed RHS
 779          -> SpecM ((Id, CoreExpr),      -- The thing and its processed RHS
 780                                         --      the Id may now have specialisations attached
 781                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 782                    UsageDetails         -- Stuff to fling upwards from the RHS and its
 783             )                           --      specialised versions
 784
 785 specDefn subst calls (fn, rhs)
 786         -- The first case is the interesting one
 787   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 788   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 789   && notNull calls_for_me               -- And there are some calls to specialise
 790
 791 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 792 --      See Note [Inline specialisation] for why we do not
 793 --      switch off specialisation for inline functions = do
 794   = do
 795      -- Specialise the body of the function
 796     (rhs', rhs_uds) <- specExpr subst rhs
 797
 798       -- Make a specialised version for each call in calls_for_me
 799     stuff <- mapM spec_call calls_for_me
 800     let
 801         (spec_defns, spec_uds, spec_rules) = unzip3 stuff
 802
 803         fn' = addIdSpecialisations fn spec_rules
 804
 805     return ((fn',rhs'),
 806               spec_defns,
 807               rhs_uds `plusUDs` plusUDList spec_uds)
 808
 809   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 810   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 811           -- Note [Specialisation shape]
 812     (do  { (rhs', rhs_uds) <- specExpr subst rhs
 813         ; return ((fn, rhs'), [], rhs_uds) })
 814
 815   where
 816     fn_type            = idType fn
 817     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 818     n_tyvars           = length tyvars
 819     n_dicts            = length theta
 820     inline_prag        = idInlinePragma fn
 821
 822         -- It's important that we "see past" any INLINE pragma
 823         -- else we'll fail to specialise an INLINE thing
 824     (inline_rhs, rhs_inside) = dropInline rhs
 825     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 826
 827     rhs_dicts = take n_dicts rhs_ids
 828     body      = mkLams (drop n_dicts rhs_ids) rhs_body
 829                 -- Glue back on the non-dict lambdas
 830
 831     calls_for_me = case lookupFM calls fn of
 832                         Nothing -> []
 833                         Just cs -> fmToList cs
 834
 835     ----------------------------------------------------------
 836         -- Specialise to one particular call pattern
 837     spec_call :: (CallKey, ([DictExpr], VarSet))        -- Call instance
 838               -> SpecM ((Id,CoreExpr),                  -- Specialised definition
 839                         UsageDetails,                   -- Usage details from specialised body
 840                         CoreRule)                       -- Info for the Id's SpecEnv
 841     spec_call (CallKey call_ts, (call_ds, _))
 842       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts ) do
 843                 -- Calls are only recorded for properly-saturated applications
 844
 845         -- Suppose f's defn is  f = /\ a b c d -> \ d1 d2 -> rhs
 846         -- Supppose the call is for f [Just t1, Nothing, Just t3, Nothing] [dx1, dx2]
 847
 848         -- Construct the new binding
 849         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b d -> rhs)
 850         -- PLUS the usage-details
 851         --      { d1' = dx1; d2' = dx2 }
 852         -- where d1', d2' are cloned versions of d1,d2, with the type substitution applied.
 853         --
 854         -- Note that the substitution is applied to the whole thing.
 855         -- This is convenient, but just slightly fragile.  Notably:
 856         --      * There had better be no name clashes in a/b/c/d
 857         --
 858         let
 859                 -- poly_tyvars = [b,d] in the example above
 860                 -- spec_tyvars = [a,c]
 861                 -- ty_args     = [t1,b,t3,d]
 862            poly_tyvars = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 863            spec_tyvars = [tv | (tv, Just _)  <- rhs_tyvars `zip` call_ts]
 864            ty_args     = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 865                        where
 866                          mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 867                          mk_ty_arg _         (Just ty) = Type ty
 868            rhs_subst  = extendTvSubstList subst (spec_tyvars `zip` [ty | Just ty <- call_ts])
 869
 870         (rhs_subst', rhs_dicts') <- cloneBinders rhs_subst rhs_dicts
 871         let
 872            inst_args = ty_args ++ map Var rhs_dicts'
 873
 874                 -- Figure out the type of the specialised function
 875            body_ty = applyTypeToArgs rhs fn_type inst_args
 876            (lam_args, app_args)                 -- Add a dummy argument if body_ty is unlifted
 877                 | isUnLiftedType body_ty        -- C.f. WwLib.mkWorkerArgs
 878                 = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 879                 | otherwise = (poly_tyvars, poly_tyvars)
 880            spec_id_ty = mkPiTypes lam_args body_ty
 881
 882         spec_f <- newIdSM fn spec_id_ty
 883         (spec_rhs, rhs_uds) <- specExpr rhs_subst' (mkLams lam_args body)
 884         let
 885                 -- The rule to put in the function's specialisation is:
 886                 --      forall b,d, d1',d2'.  f t1 b t3 d d1' d2' = f1 b d
 887            spec_env_rule = mkLocalRule (mkFastString ("SPEC " ++ showSDoc (ppr fn)))
 888                                 inline_prag     -- Note [Auto-specialisation and RULES]
 889                                 (idName fn)
 890                                 (poly_tyvars ++ rhs_dicts')
 891                                 inst_args
 892                                 (mkVarApps (Var spec_f) app_args)
 893
 894                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 895            final_uds = foldr addDictBind rhs_uds (my_zipEqual "spec_call" rhs_dicts' call_ds)
 896
 897            spec_pr | inline_rhs = (spec_f `setInlinePragma` inline_prag, Note InlineMe spec_rhs)
 898                    | otherwise  = (spec_f,                               spec_rhs)
 899
 900         return (spec_pr, final_uds, spec_env_rule)
 901
 902       where
 903         my_zipEqual doc xs ys
 904          | debugIsOn && not (equalLength xs ys)
 905              = pprPanic "my_zipEqual" (vcat
 906                                                 [ ppr xs, ppr ys
 907                                                 , ppr fn <+> ppr call_ts
 908                                                 , ppr (idType fn), ppr theta
 909                                                 , ppr n_dicts, ppr rhs_dicts
 910                                                 , ppr rhs])
 911          | otherwise               = zipEqual doc xs ys
 912 \end{code}
 913
 914 Note [Auto-specialisation and RULES]
 915 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 916 Consider:
 917    g :: Num a => a -> a
 918    g = ...
 919
 920    f :: (Int -> Int) -> Int
 921    f w = ...
 922    {-# RULE f g = 0 #-}
 923
 924 Suppose that auto-specialisation makes a specialised version of
 925 g::Int->Int That version won't appear in the LHS of the RULE for f.
 926 So if the specialisation rule fires too early, the rule for f may
 927 never fire.
 928
 929 It might be possible to add new rules, to "complete" the rewrite system.
 930 Thus when adding
 931         RULE forall d. g Int d = g_spec
 932 also add
 933         RULE f g_spec = 0
 934
 935 But that's a bit complicated.  For now we ask the programmer's help,
 936 by *copying the INLINE activation pragma* to the auto-specialised rule.
 937 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
 938 not be active until phase 2.
 939
 940
 941 Note [Specialisation shape]
 942 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 943 We only specialise a function if it has visible top-level lambdas
 944 corresponding to its overloading.  E.g. if
 945         f :: forall a. Eq a => ....
 946 then its body must look like
 947         f = /\a. \d. ...
 948
 949 Reason: when specialising the body for a call (f ty dexp), we want to
 950 substitute dexp for d, and pick up specialised calls in the body of f.
 951
 952 This doesn't always work.  One example I came across was htis:
 953         newtype Gen a = MkGen{ unGen :: Int -> a }
 954
 955         choose :: Eq a => a -> Gen a
 956         choose n = MkGen (\r -> n)
 957
 958         oneof = choose (1::Int)
 959
 960 It's a silly exapmle, but we get
 961         choose = /\a. g `cast` co
 962 where choose doesn't have any dict arguments.  Thus far I have not
 963 tried to fix this (wait till there's a real example).
 964
 965
 966 Note [Inline specialisations]
 967 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 968 We transfer to the specialised function any INLINE stuff from the
 969 original.  This means (a) the Activation in the IdInfo, and (b) any
 970 InlineMe on the RHS.
 971
 972 This is a change (Jun06).  Previously the idea is that the point of
 973 inlining was precisely to specialise the function at its call site,
 974 and that's not so important for the specialised copies.  But
 975 *pragma-directed* specialisation now takes place in the
 976 typechecker/desugarer, with manually specified INLINEs.  The
 977 specialiation here is automatic.  It'd be very odd if a function
 978 marked INLINE was specialised (because of some local use), and then
 979 forever after (including importing modules) the specialised version
 980 wasn't INLINEd.  After all, the programmer said INLINE!
 981
 982 You might wonder why we don't just not specialise INLINE functions.
 983 It's because even INLINE functions are sometimes not inlined, when
 984 they aren't applied to interesting arguments.  But perhaps the type
 985 arguments alone are enough to specialise (even though the args are too
 986 boring to trigger inlining), and it's certainly better to call the
 987 specialised version.
 988
 989 A case in point is dictionary functions, which are current marked
 990 INLINE, but which are worth specialising.
 991
 992 \begin{code}
 993 dropInline :: CoreExpr -> (Bool, CoreExpr)
 994 dropInline (Note InlineMe rhs) = (True,  rhs)
 995 dropInline rhs                 = (False, rhs)
 996 \end{code}
 997
 998 %************************************************************************
 999 %*                                                                      *
1000 \subsubsection{UsageDetails and suchlike}
1001 %*                                                                      *
1002 %************************************************************************
1003
1004 \begin{code}
1005 data UsageDetails
1006   = MkUD {
1007         dict_binds :: !(Bag DictBind),
1008                         -- Floated dictionary bindings
1009                         -- The order is important;
1010                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1011                         -- (Remember, Bags preserve order in GHC.)
1012
1013         calls     :: !CallDetails,
1014
1015         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1016                                 -- either dict_binds or calls
1017     }
1018
1019 instance Outputable UsageDetails where
1020   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1021         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1022                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1023                  ptext (sLit "calls") <+> equals <+> ppr calls,
1024                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1025
1026 type DictBind = (CoreBind, VarSet)
1027         -- The set is the free vars of the binding
1028         -- both tyvars and dicts
1029
1030 type DictExpr = CoreExpr
1031
1032 emptyUDs :: UsageDetails
1033 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1034
1035 ------------------------------------------------------------
1036 type CallDetails  = FiniteMap Id CallInfo
1037 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1038 type CallInfo     = FiniteMap CallKey
1039                               ([DictExpr], VarSet)              -- Dict args and the vars of the whole
1040                                                                 -- call (including tyvars)
1041                                                                 -- [*not* include the main id itself, of course]
1042         -- The finite maps eliminate duplicates
1043         -- The list of types and dictionaries is guaranteed to
1044         -- match the type of f
1045
1046 instance Outputable CallKey where
1047   ppr (CallKey ts) = ppr ts
1048
1049 -- Type isn't an instance of Ord, so that we can control which
1050 -- instance we use.  That's tiresome here.  Oh well
1051 instance Eq CallKey where
1052   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1053
1054 instance Ord CallKey where
1055   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1056                 where
1057                   cmp Nothing   Nothing   = EQ
1058                   cmp Nothing   (Just _)  = LT
1059                   cmp (Just _)  Nothing   = GT
1060                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1061
1062 unionCalls :: CallDetails -> CallDetails -> CallDetails
1063 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1064
1065 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1066 singleCall id tys dicts
1067   = MkUD {dict_binds = emptyBag,
1068           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1069           ud_fvs     = call_fvs }
1070   where
1071     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1072     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1073         -- The type args (tys) are guaranteed to be part of the dictionary
1074         -- types, because they are just the constrained types,
1075         -- and the dictionary is therefore sure to be bound
1076         -- inside the binding for any type variables free in the type;
1077         -- hence it's safe to neglect tyvars free in tys when making
1078         -- the free-var set for this call
1079         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1080         --
1081         -- We don't include the 'id' itself.
1082
1083 mkCallUDs :: Subst -> Id -> [CoreExpr] -> UsageDetails
1084 mkCallUDs subst f args
1085   | null theta
1086   || not (all isClassPred theta)
1087         -- Only specialise if all overloading is on class params.
1088         -- In ptic, with implicit params, the type args
1089         --  *don't* say what the value of the implicit param is!
1090   || not (spec_tys `lengthIs` n_tyvars)
1091   || not ( dicts   `lengthIs` n_dicts)
1092   || maybeToBool (lookupRule (\_act -> True) (substInScope subst) emptyRuleBase f args)
1093         -- There's already a rule covering this call.  A typical case
1094         -- is where there's an explicit user-provided rule.  Then
1095         -- we don't want to create a specialised version
1096         -- of the function that overlaps.
1097   = emptyUDs    -- Not overloaded, or no specialisation wanted
1098
1099   | otherwise
1100   = singleCall f spec_tys dicts
1101   where
1102     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1103     constrained_tyvars = tyVarsOfTheta theta
1104     n_tyvars           = length tyvars
1105     n_dicts            = length theta
1106
1107     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1108     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1109
1110     mk_spec_ty tyvar ty
1111         | tyvar `elemVarSet` constrained_tyvars = Just ty
1112         | otherwise                             = Nothing
1113
1114 ------------------------------------------------------------
1115 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1116 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1117         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1118   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1119   where
1120     d = db1    `unionBags`   db2
1121     c = calls1 `unionCalls`  calls2
1122
1123 plusUDList :: [UsageDetails] -> UsageDetails
1124 plusUDList = foldr plusUDs emptyUDs
1125
1126 -- zapCalls deletes calls to ids from uds
1127 zapCalls :: [Id] -> CallDetails -> CallDetails
1128 zapCalls ids calls = delListFromFM calls ids
1129
1130 mkDB :: CoreBind -> DictBind
1131 mkDB bind = (bind, bind_fvs bind)
1132
1133 bind_fvs :: CoreBind -> VarSet
1134 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1135 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1136                            where
1137                              bndrs = map fst prs
1138                              rhs_fvs = unionVarSets (map pair_fvs prs)
1139
1140 pair_fvs :: (Id, CoreExpr) -> VarSet
1141 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1142         -- Don't forget variables mentioned in the
1143         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1144         -- Also tyvars mentioned in its type; they may not appear in the RHS
1145         --      type T a = Int
1146         --      x :: T a = 3
1147
1148 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1149 addDictBind (dict,rhs) uds
1150   = uds { dict_binds = db `consBag` dict_binds uds
1151         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1152   where
1153     db@(_, fvs) = mkDB (NonRec dict rhs)
1154
1155 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1156 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1157   = foldrBag add binds dbs
1158   where
1159     add (bind,_) binds = bind : binds
1160
1161 dumpUDs :: [CoreBndr]
1162         -> UsageDetails -> CoreExpr
1163         -> (UsageDetails, CoreExpr)
1164 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1165                     , calls = orig_calls
1166                     , ud_fvs = fvs}) body
1167   = (new_uds, foldrBag add_let body dump_dbs)
1168                 -- This may delete fewer variables
1169                 -- than in priciple possible
1170   where
1171     new_uds =
1172      MkUD { dict_binds = free_dbs
1173           , calls      = free_calls
1174           , ud_fvs     = fvs `minusVarSet` bndr_set}
1175
1176     bndr_set = mkVarSet bndrs
1177     add_let (bind,_) body = Let bind body
1178
1179     (free_dbs, dump_dbs, dump_set)
1180         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1181                 -- Important that it's foldl not foldr;
1182                 -- we're accumulating the set of dumped ids in dump_set
1183
1184     free_calls = filterCalls dump_set orig_calls
1185
1186     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1187         | dump_idset `intersectsVarSet` fvs     -- Dump it
1188         = (free_dbs, dump_dbs `snocBag` db,
1189            extendVarSetList dump_idset (bindersOf bind))
1190
1191         | otherwise     -- Don't dump it
1192         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1193
1194 filterCalls :: VarSet -> CallDetails -> CallDetails
1195 -- Remove any calls that mention the variables
1196 filterCalls bs calls
1197   = mapFM (\_ cs -> filter_calls cs) $
1198     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1199   where
1200     filter_calls :: CallInfo -> CallInfo
1201     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1202 \end{code}
1203
1204
1205 %************************************************************************
1206 %*                                                                      *
1207 \subsubsection{Boring helper functions}
1208 %*                                                                      *
1209 %************************************************************************
1210
1211 \begin{code}
1212 type SpecM a = UniqSM a
1213
1214 initSM :: UniqSupply -> SpecM a -> a
1215 initSM    = initUs_
1216
1217 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1218 mapAndCombineSM _ []     = return ([], emptyUDs)
1219 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1220                               (ys, uds2) <- mapAndCombineSM f xs
1221                               return (y:ys, uds1 `plusUDs` uds2)
1222
1223 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1224 -- Clone the binders of the bind; return new bind with the cloned binders
1225 -- Return the substitution to use for RHSs, and the one to use for the body
1226 cloneBindSM subst (NonRec bndr rhs) = do
1227     us <- getUniqueSupplyM
1228     let (subst', bndr') = cloneIdBndr subst us bndr
1229     return (subst, subst', NonRec bndr' rhs)
1230
1231 cloneBindSM subst (Rec pairs) = do
1232     us <- getUniqueSupplyM
1233     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1234     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1235
1236 cloneBinders :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1237 cloneBinders subst bndrs = do
1238     us <- getUniqueSupplyM
1239     return (cloneIdBndrs subst us bndrs)
1240
1241 newIdSM :: Id -> Type -> SpecM Id
1242 newIdSM old_id new_ty = do
1243     uniq <- getUniqueM
1244     let
1245         -- Give the new Id a similar occurrence name to the old one
1246         name   = idName old_id
1247         new_id = mkUserLocal (mkSpecOcc (nameOccName name)) uniq new_ty (getSrcSpan name)
1248     return new_id
1249 \end{code}
1250
1251
1252                 Old (but interesting) stuff about unboxed bindings
1253                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1254
1255 What should we do when a value is specialised to a *strict* unboxed value?
1256
1257         map_*_* f (x:xs) = let h = f x
1258                                t = map f xs
1259                            in h:t
1260
1261 Could convert let to case:
1262
1263         map_*_Int# f (x:xs) = case f x of h# ->
1264                               let t = map f xs
1265                               in h#:t
1266
1267 This may be undesirable since it forces evaluation here, but the value
1268 may not be used in all branches of the body. In the general case this
1269 transformation is impossible since the mutual recursion in a letrec
1270 cannot be expressed as a case.
1271
1272 There is also a problem with top-level unboxed values, since our
1273 implementation cannot handle unboxed values at the top level.
1274
1275 Solution: Lift the binding of the unboxed value and extract it when it
1276 is used:
1277
1278         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1279                                   t = map f xs
1280                               in case h of
1281                                  _Lift h# -> h#:t
1282
1283 Now give it to the simplifier and the _Lifting will be optimised away.
1284
1285 The benfit is that we have given the specialised "unboxed" values a
1286 very simplep lifted semantics and then leave it up to the simplifier to
1287 optimise it --- knowing that the overheads will be removed in nearly
1288 all cases.
1289
1290 In particular, the value will only be evaluted in the branches of the
1291 program which use it, rather than being forced at the point where the
1292 value is bound. For example:
1293
1294         filtermap_*_* p f (x:xs)
1295           = let h = f x
1296                 t = ...
1297             in case p x of
1298                 True  -> h:t
1299                 False -> t
1300    ==>
1301         filtermap_*_Int# p f (x:xs)
1302           = let h = case (f x) of h# -> _Lift h#
1303                 t = ...
1304             in case p x of
1305                 True  -> case h of _Lift h#
1306                            -> h#:t
1307                 False -> t
1308
1309 The binding for h can still be inlined in the one branch and the
1310 _Lifting eliminated.
1311
1312
1313 Question: When won't the _Lifting be eliminated?
1314
1315 Answer: When they at the top-level (where it is necessary) or when
1316 inlining would duplicate work (or possibly code depending on
1317 options). However, the _Lifting will still be eliminated if the
1318 strictness analyser deems the lifted binding strict.
1319