compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 module Specialise ( specProgram ) where
   8
   9 #include "HsVersions.h"
  10
  11 import Id
  12 import TcType
  13 import CoreMonad
  14 import CoreSubst
  15 import CoreUnfold
  16 import VarSet
  17 import VarEnv
  18 import CoreSyn
  19 import Rules
  20 import CoreUtils        ( exprIsTrivial, applyTypeToArgs, mkPiTypes )
  21 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  22 import UniqSupply       ( UniqSM, initUs_, MonadUnique(..) )
  23 import Name
  24 import MkId             ( voidArgId, realWorldPrimId )
  25 import Maybes           ( catMaybes, isJust )
  26 import BasicTypes
  27 import HscTypes
  28 import Bag
  29 import Util
  30 import Outputable
  31 import FastString
  32
  33 import Data.Map (Map)
  34 import qualified Data.Map as Map
  35 import qualified FiniteMap as Map
  36 \end{code}
  37
  38 %************************************************************************
  39 %*                                                                      *
  40 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  41 %*                                                                      *
  42 %************************************************************************
  43
  44 These notes describe how we implement specialisation to eliminate
  45 overloading.
  46
  47 The specialisation pass works on Core
  48 syntax, complete with all the explicit dictionary application,
  49 abstraction and construction as added by the type checker.  The
  50 existing type checker remains largely as it is.
  51
  52 One important thought: the {\em types} passed to an overloaded
  53 function, and the {\em dictionaries} passed are mutually redundant.
  54 If the same function is applied to the same type(s) then it is sure to
  55 be applied to the same dictionary(s)---or rather to the same {\em
  56 values}.  (The arguments might look different but they will evaluate
  57 to the same value.)
  58
  59 Second important thought: we know that we can make progress by
  60 treating dictionary arguments as static and worth specialising on.  So
  61 we can do without binding-time analysis, and instead specialise on
  62 dictionary arguments and no others.
  63
  64 The basic idea
  65 ~~~~~~~~~~~~~~
  66 Suppose we have
  67
  68         let f = <f_rhs>
  69         in <body>
  70
  71 and suppose f is overloaded.
  72
  73 STEP 1: CALL-INSTANCE COLLECTION
  74
  75 We traverse <body>, accumulating all applications of f to types and
  76 dictionaries.
  77
  78 (Might there be partial applications, to just some of its types and
  79 dictionaries?  In principle yes, but in practice the type checker only
  80 builds applications of f to all its types and dictionaries, so partial
  81 applications could only arise as a result of transformation, and even
  82 then I think it's unlikely.  In any case, we simply don't accumulate such
  83 partial applications.)
  84
  85
  86 STEP 2: EQUIVALENCES
  87
  88 So now we have a collection of calls to f:
  89         f t1 t2 d1 d2
  90         f t3 t4 d3 d4
  91         ...
  92 Notice that f may take several type arguments.  To avoid ambiguity, we
  93 say that f is called at type t1/t2 and t3/t4.
  94
  95 We take equivalence classes using equality of the *types* (ignoring
  96 the dictionary args, which as mentioned previously are redundant).
  97
  98 STEP 3: SPECIALISATION
  99
 100 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 101 and create a local instance of f, defined thus:
 102
 103         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 104
 105 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 106 of simplification will now result.  However we don't actually *do* that
 107 simplification.  Rather, we leave it for the simplifier to do.  If we
 108 *did* do it, though, we'd get more call instances from the specialised
 109 RHS.  We can work out what they are by instantiating the call-instance
 110 set from f's RHS with the types t1, t2.
 111
 112 Add this new id to f's IdInfo, to record that f has a specialised version.
 113
 114 Before doing any of this, check that f's IdInfo doesn't already
 115 tell us about an existing instance of f at the required type/s.
 116 (This might happen if specialisation was applied more than once, or
 117 it might arise from user SPECIALIZE pragmas.)
 118
 119 Recursion
 120 ~~~~~~~~~
 121 Wait a minute!  What if f is recursive?  Then we can't just plug in
 122 its right-hand side, can we?
 123
 124 But it's ok.  The type checker *always* creates non-recursive definitions
 125 for overloaded recursive functions.  For example:
 126
 127         f x = f (x+x)           -- Yes I know its silly
 128
 129 becomes
 130
 131         f a (d::Num a) = let p = +.sel a d
 132                          in
 133                          letrec fl (y::a) = fl (p y y)
 134                          in
 135                          fl
 136
 137 We still have recusion for non-overloaded functions which we
 138 speciailise, but the recursive call should get specialised to the
 139 same recursive version.
 140
 141
 142 Polymorphism 1
 143 ~~~~~~~~~~~~~~
 144
 145 All this is crystal clear when the function is applied to *constant
 146 types*; that is, types which have no type variables inside.  But what if
 147 it is applied to non-constant types?  Suppose we find a call of f at type
 148 t1/t2.  There are two possibilities:
 149
 150 (a) The free type variables of t1, t2 are in scope at the definition point
 151 of f.  In this case there's no problem, we proceed just as before.  A common
 152 example is as follows.  Here's the Haskell:
 153
 154         g y = let f x = x+x
 155               in f y + f y
 156
 157 After typechecking we have
 158
 159         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 160                                 in +.sel a d (f a d y) (f a d y)
 161
 162 Notice that the call to f is at type type "a"; a non-constant type.
 163 Both calls to f are at the same type, so we can specialise to give:
 164
 165         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 166                                 in +.sel a d (f@a y) (f@a y)
 167
 168
 169 (b) The other case is when the type variables in the instance types
 170 are *not* in scope at the definition point of f.  The example we are
 171 working with above is a good case.  There are two instances of (+.sel a d),
 172 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 173 Yes, we can "common them up", a sort of limited common sub-expression deal.
 174 This would give:
 175
 176         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 177                                     f@a (x::a) = +.sel@a x x
 178                                 in +.sel@a (f@a y) (f@a y)
 179
 180 This can save work, and can't be spotted by the type checker, because
 181 the two instances of +.sel weren't originally at the same type.
 182
 183 Further notes on (b)
 184
 185 * There are quite a few variations here.  For example, the defn of
 186   +.sel could be floated ouside the \y, to attempt to gain laziness.
 187   It certainly mustn't be floated outside the \d because the d has to
 188   be in scope too.
 189
 190 * We don't want to inline f_rhs in this case, because
 191 that will duplicate code.  Just commoning up the call is the point.
 192
 193 * Nothing gets added to +.sel's IdInfo.
 194
 195 * Don't bother unless the equivalence class has more than one item!
 196
 197 Not clear whether this is all worth it.  It is of course OK to
 198 simply discard call-instances when passing a big lambda.
 199
 200 Polymorphism 2 -- Overloading
 201 ~~~~~~~~~~~~~~
 202 Consider a function whose most general type is
 203
 204         f :: forall a b. Ord a => [a] -> b -> b
 205
 206 There is really no point in making a version of g at Int/Int and another
 207 at Int/Bool, because it's only instancing the type variable "a" which
 208 buys us any efficiency. Since g is completely polymorphic in b there
 209 ain't much point in making separate versions of g for the different
 210 b types.
 211
 212 That suggests that we should identify which of g's type variables
 213 are constrained (like "a") and which are unconstrained (like "b").
 214 Then when taking equivalence classes in STEP 2, we ignore the type args
 215 corresponding to unconstrained type variable.  In STEP 3 we make
 216 polymorphic versions.  Thus:
 217
 218         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 219
 220 We do this.
 221
 222
 223 Dictionary floating
 224 ~~~~~~~~~~~~~~~~~~~
 225 Consider this
 226
 227         f a (d::Num a) = let g = ...
 228                          in
 229                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 230
 231 Here, g is only called at one type, but the dictionary isn't in scope at the
 232 definition point for g.  Usually the type checker would build a
 233 definition for d1 which enclosed g, but the transformation system
 234 might have moved d1's defn inward.  Solution: float dictionary bindings
 235 outwards along with call instances.
 236
 237 Consider
 238
 239         f x = let g p q = p==q
 240                   h r s = (r+s, g r s)
 241               in
 242               h x x
 243
 244
 245 Before specialisation, leaving out type abstractions we have
 246
 247         f df x = let g :: Eq a => a -> a -> Bool
 248                      g dg p q = == dg p q
 249                      h :: Num a => a -> a -> (a, Bool)
 250                      h dh r s = let deq = eqFromNum dh
 251                                 in (+ dh r s, g deq r s)
 252               in
 253               h df x x
 254
 255 After specialising h we get a specialised version of h, like this:
 256
 257                     h' r s = let deq = eqFromNum df
 258                              in (+ df r s, g deq r s)
 259
 260 But we can't naively make an instance for g from this, because deq is not in scope
 261 at the defn of g.  Instead, we have to float out the (new) defn of deq
 262 to widen its scope.  Notice that this floating can't be done in advance -- it only
 263 shows up when specialisation is done.
 264
 265 User SPECIALIZE pragmas
 266 ~~~~~~~~~~~~~~~~~~~~~~~
 267 Specialisation pragmas can be digested by the type checker, and implemented
 268 by adding extra definitions along with that of f, in the same way as before
 269
 270         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 271
 272 Indeed the pragmas *have* to be dealt with by the type checker, because
 273 only it knows how to build the dictionaries d1 and d2!  For example
 274
 275         g :: Ord a => [a] -> [a]
 276         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 277
 278 Here, the specialised version of g is an application of g's rhs to the
 279 Ord dictionary for (Tree Int), which only the type checker can conjure
 280 up.  There might not even *be* one, if (Tree Int) is not an instance of
 281 Ord!  (All the other specialision has suitable dictionaries to hand
 282 from actual calls.)
 283
 284 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 285 it is buried in a complex (as-yet-un-desugared) binding group.
 286 Maybe we should say
 287
 288         f@t1/t2 = f* t1 t2 d1 d2
 289
 290 where f* is the Id f with an IdInfo which says "inline me regardless!".
 291 Indeed all the specialisation could be done in this way.
 292 That in turn means that the simplifier has to be prepared to inline absolutely
 293 any in-scope let-bound thing.
 294
 295
 296 Again, the pragma should permit polymorphism in unconstrained variables:
 297
 298         h :: Ord a => [a] -> b -> b
 299         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 300
 301 We *insist* that all overloaded type variables are specialised to ground types,
 302 (and hence there can be no context inside a SPECIALIZE pragma).
 303 We *permit* unconstrained type variables to be specialised to
 304         - a ground type
 305         - or left as a polymorphic type variable
 306 but nothing in between.  So
 307
 308         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 309
 310 is *illegal*.  (It can be handled, but it adds complication, and gains the
 311 programmer nothing.)
 312
 313
 314 SPECIALISING INSTANCE DECLARATIONS
 315 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 316 Consider
 317
 318         instance Foo a => Foo [a] where
 319                 ...
 320         {-# SPECIALIZE instance Foo [Int] #-}
 321
 322 The original instance decl creates a dictionary-function
 323 definition:
 324
 325         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 326
 327 The SPECIALIZE pragma just makes a specialised copy, just as for
 328 ordinary function definitions:
 329
 330         dfun.Foo.List@Int :: Foo [Int]
 331         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 332
 333 The information about what instance of the dfun exist gets added to
 334 the dfun's IdInfo in the same way as a user-defined function too.
 335
 336
 337 Automatic instance decl specialisation?
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 Can instance decls be specialised automatically?  It's tricky.
 340 We could collect call-instance information for each dfun, but
 341 then when we specialised their bodies we'd get new call-instances
 342 for ordinary functions; and when we specialised their bodies, we might get
 343 new call-instances of the dfuns, and so on.  This all arises because of
 344 the unrestricted mutual recursion between instance decls and value decls.
 345
 346 Still, there's no actual problem; it just means that we may not do all
 347 the specialisation we could theoretically do.
 348
 349 Furthermore, instance decls are usually exported and used non-locally,
 350 so we'll want to compile enough to get those specialisations done.
 351
 352 Lastly, there's no such thing as a local instance decl, so we can
 353 survive solely by spitting out *usage* information, and then reading that
 354 back in as a pragma when next compiling the file.  So for now,
 355 we only specialise instance decls in response to pragmas.
 356
 357
 358 SPITTING OUT USAGE INFORMATION
 359 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 360
 361 To spit out usage information we need to traverse the code collecting
 362 call-instance information for all imported (non-prelude?) functions
 363 and data types. Then we equivalence-class it and spit it out.
 364
 365 This is done at the top-level when all the call instances which escape
 366 must be for imported functions and data types.
 367
 368 *** Not currently done ***
 369
 370
 371 Partial specialisation by pragmas
 372 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 373 What about partial specialisation:
 374
 375         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 376         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 377
 378 or even
 379
 380         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 381
 382 Seems quite reasonable.  Similar things could be done with instance decls:
 383
 384         instance (Foo a, Foo b) => Foo (a,b) where
 385                 ...
 386         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 387         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 388
 389 Ho hum.  Things are complex enough without this.  I pass.
 390
 391
 392 Requirements for the simplifer
 393 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 394 The simplifier has to be able to take advantage of the specialisation.
 395
 396 * When the simplifier finds an application of a polymorphic f, it looks in
 397 f's IdInfo in case there is a suitable instance to call instead.  This converts
 398
 399         f t1 t2 d1 d2   ===>   f_t1_t2
 400
 401 Note that the dictionaries get eaten up too!
 402
 403 * Dictionary selection operations on constant dictionaries must be
 404   short-circuited:
 405
 406         +.sel Int d     ===>  +Int
 407
 408 The obvious way to do this is in the same way as other specialised
 409 calls: +.sel has inside it some IdInfo which tells that if it's applied
 410 to the type Int then it should eat a dictionary and transform to +Int.
 411
 412 In short, dictionary selectors need IdInfo inside them for constant
 413 methods.
 414
 415 * Exactly the same applies if a superclass dictionary is being
 416   extracted:
 417
 418         Eq.sel Int d   ===>   dEqInt
 419
 420 * Something similar applies to dictionary construction too.  Suppose
 421 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 422 one for (Eq [a]).  Then we want
 423
 424         dfun.Eq.List Int d      ===> dEq.List_Int
 425
 426 Where does the Eq [Int] dictionary come from?  It is built in
 427 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 428
 429 In short, dfun Ids need IdInfo with a specialisation for each
 430 constant instance of their instance declaration.
 431
 432 All this uses a single mechanism: the SpecEnv inside an Id
 433
 434
 435 What does the specialisation IdInfo look like?
 436 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 437
 438 The SpecEnv of an Id maps a list of types (the template) to an expression
 439
 440         [Type]  |->  Expr
 441
 442 For example, if f has this SpecInfo:
 443
 444         [Int, a]  ->  \d:Ord Int. f' a
 445
 446 it means that we can replace the call
 447
 448         f Int t  ===>  (\d. f' t)
 449
 450 This chucks one dictionary away and proceeds with the
 451 specialised version of f, namely f'.
 452
 453
 454 What can't be done this way?
 455 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 456 There is no way, post-typechecker, to get a dictionary for (say)
 457 Eq a from a dictionary for Eq [a].  So if we find
 458
 459         ==.sel [t] d
 460
 461 we can't transform to
 462
 463         eqList (==.sel t d')
 464
 465 where
 466         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 467
 468 Of course, we currently have no way to automatically derive
 469 eqList, nor to connect it to the Eq [a] instance decl, but you
 470 can imagine that it might somehow be possible.  Taking advantage
 471 of this is permanently ruled out.
 472
 473 Still, this is no great hardship, because we intend to eliminate
 474 overloading altogether anyway!
 475
 476 A note about non-tyvar dictionaries
 477 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 478 Some Ids have types like
 479
 480         forall a,b,c. Eq a -> Ord [a] -> tau
 481
 482 This seems curious at first, because we usually only have dictionary
 483 args whose types are of the form (C a) where a is a type variable.
 484 But this doesn't hold for the functions arising from instance decls,
 485 which sometimes get arguements with types of form (C (T a)) for some
 486 type constructor T.
 487
 488 Should we specialise wrt this compound-type dictionary?  We used to say
 489 "no", saying:
 490         "This is a heuristic judgement, as indeed is the fact that we
 491         specialise wrt only dictionaries.  We choose *not* to specialise
 492         wrt compound dictionaries because at the moment the only place
 493         they show up is in instance decls, where they are simply plugged
 494         into a returned dictionary.  So nothing is gained by specialising
 495         wrt them."
 496
 497 But it is simpler and more uniform to specialise wrt these dicts too;
 498 and in future GHC is likely to support full fledged type signatures
 499 like
 500         f :: Eq [(a,b)] => ...
 501
 502
 503 %************************************************************************
 504 %*                                                                      *
 505 \subsubsection{The new specialiser}
 506 %*                                                                      *
 507 %************************************************************************
 508
 509 Our basic game plan is this.  For let(rec) bound function
 510         f :: (C a, D c) => (a,b,c,d) -> Bool
 511
 512 * Find any specialised calls of f, (f ts ds), where
 513   ts are the type arguments t1 .. t4, and
 514   ds are the dictionary arguments d1 .. d2.
 515
 516 * Add a new definition for f1 (say):
 517
 518         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 519
 520   Note that we abstract over the unconstrained type arguments.
 521
 522 * Add the mapping
 523
 524         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 525
 526   to the specialisations of f.  This will be used by the
 527   simplifier to replace calls
 528                 (f t1 t2 t3 t4) da db
 529   by
 530                 (\d1 d1 -> f1 t2 t4) da db
 531
 532   All the stuff about how many dictionaries to discard, and what types
 533   to apply the specialised function to, are handled by the fact that the
 534   SpecEnv contains a template for the result of the specialisation.
 535
 536 We don't build *partial* specialisations for f.  For example:
 537
 538   f :: Eq a => a -> a -> Bool
 539   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 540
 541 Here, little is gained by making a specialised copy of f.
 542 There's a distinct danger that the specialised version would
 543 first build a dictionary for (Eq b, Eq c), and then select the (==)
 544 method from it!  Even if it didn't, not a great deal is saved.
 545
 546 We do, however, generate polymorphic, but not overloaded, specialisations:
 547
 548   f :: Eq a => [a] -> b -> b -> b
 549   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 550
 551 Hence, the invariant is this:
 552
 553         *** no specialised version is overloaded ***
 554
 555
 556 %************************************************************************
 557 %*                                                                      *
 558 \subsubsection{The exported function}
 559 %*                                                                      *
 560 %************************************************************************
 561
 562 \begin{code}
 563 specProgram :: ModGuts -> CoreM ModGuts
 564 specProgram guts
 565   = do { hpt_rules <- getRuleBase
 566        ; let local_rules = mg_rules guts
 567              rule_base = extendRuleBaseList hpt_rules (mg_rules guts)
 568
 569              -- Specialise the bindings of this module
 570        ; (binds', uds) <- runSpecM (go (mg_binds guts))
 571
 572              -- Specialise imported functions
 573        ; (new_rules, spec_binds) <- specImports emptyVarSet rule_base uds
 574
 575        ; return (guts { mg_binds = spec_binds ++ binds'
 576                       , mg_rules = local_rules ++ new_rules }) }
 577   where
 578         -- We need to start with a Subst that knows all the things
 579         -- that are in scope, so that the substitution engine doesn't
 580         -- accidentally re-use a unique that's already in use
 581         -- Easiest thing is to do it all at once, as if all the top-level
 582         -- decls were mutually recursive
 583     top_subst = mkEmptySubst $ mkInScopeSet $ mkVarSet $
 584                 bindersOfBinds $ mg_binds guts
 585
 586     go []           = return ([], emptyUDs)
 587     go (bind:binds) = do (binds', uds) <- go binds
 588                          (bind', uds') <- specBind top_subst bind uds
 589                          return (bind' ++ binds', uds')
 590
 591 specImports :: VarSet           -- Don't specialise these ones
 592                                 -- See Note [Avoiding recursive specialisation]
 593             -> RuleBase         -- Rules from this module and the home package
 594                                 -- (but not external packages, which can change)
 595             -> UsageDetails     -- Calls for imported things, and floating bindings
 596             -> CoreM ( [CoreRule]   -- New rules
 597                      , [CoreBind] ) -- Specialised bindings and floating bindings
 598 specImports done rb uds
 599   = do { let import_calls = varEnvElts (ud_calls uds)
 600        ; (rules, spec_binds) <- go rb import_calls
 601        ; return (rules, wrapDictBinds (ud_binds uds) spec_binds) }
 602   where
 603     go _ [] = return ([], [])
 604     go rb (CIS fn calls_for_fn : other_calls)
 605       = do { (rules1, spec_binds1) <- specImport done rb fn (Map.toList calls_for_fn)
 606            ; (rules2, spec_binds2) <- go (extendRuleBaseList rb rules1) other_calls
 607            ; return (rules1 ++ rules2, spec_binds1 ++ spec_binds2) }
 608
 609 specImport :: VarSet                -- Don't specialise these
 610                                     -- See Note [Avoiding recursive specialisation]
 611            -> RuleBase              -- Rules from this module
 612            -> Id -> [CallInfo]      -- Imported function and calls for it
 613            -> CoreM ( [CoreRule]    -- New rules
 614                     , [CoreBind] )  -- Specialised bindings
 615 specImport done rb fn calls_for_fn
 616   | not (fn `elemVarSet` done)
 617   , isInlinablePragma (idInlinePragma fn)
 618   , Just rhs <- maybeUnfoldingTemplate (realIdUnfolding fn)
 619   = do {     -- Get rules from the external package state
 620              -- We keep doing this in case we "page-fault in"
 621              -- more rules as we go along
 622        ; hsc_env <- getHscEnv
 623        ; eps <- liftIO $ hscEPS hsc_env
 624        ; let full_rb = unionRuleBase rb (eps_rule_base eps)
 625              rules_for_fn = getRules full_rb fn
 626
 627        ; (rules1, spec_pairs, uds) <- runSpecM $
 628               specCalls emptySubst rules_for_fn calls_for_fn fn rhs
 629        ; let spec_binds1 = [NonRec b r | (b,r) <- spec_pairs]
 630              -- After the rules kick in we may get recursion, but
 631              -- we rely on a global GlomBinds to sort that out later
 632
 633               -- Now specialise any cascaded calls
 634        ; (rules2, spec_binds2) <- specImports (extendVarSet done fn)
 635                                               (extendRuleBaseList rb rules1)
 636                                               uds
 637
 638        ; return (rules2 ++ rules1, spec_binds2 ++ spec_binds1) }
 639
 640   | otherwise
 641   = WARN( True, ptext (sLit "specImport discard") <+> ppr fn <+> ppr calls_for_fn )
 642     return ([], [])
 643 \end{code}
 644
 645 Avoiding recursive specialisation
 646 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 647 When we specialise 'f' we may find new overloaded calls to 'g', 'h' in
 648 'f's RHS.  So we want to specialise g,h.  But we don't want to
 649 specialise f any more!  It's possible that f's RHS might have a
 650 recursive yet-more-specialised call, so we'd diverge in that case.
 651 And if the call is to the same type, one specialisation is enough.
 652 Avoiding this recursive specialisation loop is the reason for the
 653 'done' VarSet passed to specImports and specImport.
 654
 655 %************************************************************************
 656 %*                                                                      *
 657 \subsubsection{@specExpr@: the main function}
 658 %*                                                                      *
 659 %************************************************************************
 660
 661 \begin{code}
 662 specVar :: Subst -> Id -> CoreExpr
 663 specVar subst v = lookupIdSubst (text "specVar") subst v
 664
 665 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 666 -- We carry a substitution down:
 667 --      a) we must clone any binding that might float outwards,
 668 --         to avoid name clashes
 669 --      b) we carry a type substitution to use when analysing
 670 --         the RHS of specialised bindings (no type-let!)
 671
 672 ---------------- First the easy cases --------------------
 673 specExpr subst (Type ty) = return (Type (CoreSubst.substTy subst ty), emptyUDs)
 674 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 675 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 676 specExpr subst (Cast e co) = do
 677     (e', uds) <- specExpr subst e
 678     return ((Cast e' (CoreSubst.substTy subst co)), uds)
 679 specExpr subst (Note note body) = do
 680     (body', uds) <- specExpr subst body
 681     return (Note (specNote subst note) body', uds)
 682
 683
 684 ---------------- Applications might generate a call instance --------------------
 685 specExpr subst expr@(App {})
 686   = go expr []
 687   where
 688     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 689                                (fun', uds_app) <- go fun (arg':args)
 690                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 691
 692     go (Var f)       args = case specVar subst f of
 693                                 Var f' -> return (Var f', mkCallUDs f' args)
 694                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 695     go other         _    = specExpr subst other
 696
 697 ---------------- Lambda/case require dumping of usage details --------------------
 698 specExpr subst e@(Lam _ _) = do
 699     (body', uds) <- specExpr subst' body
 700     let (free_uds, dumped_dbs) = dumpUDs bndrs' uds
 701     return (mkLams bndrs' (wrapDictBindsE dumped_dbs body'), free_uds)
 702   where
 703     (bndrs, body) = collectBinders e
 704     (subst', bndrs') = substBndrs subst bndrs
 705         -- More efficient to collect a group of binders together all at once
 706         -- and we don't want to split a lambda group with dumped bindings
 707
 708 specExpr subst (Case scrut case_bndr ty alts)
 709   = do { (scrut', scrut_uds) <- specExpr subst scrut
 710        ; (scrut'', case_bndr', alts', alts_uds)
 711              <- specCase subst scrut' case_bndr alts
 712        ; return (Case scrut'' case_bndr' (CoreSubst.substTy subst ty) alts'
 713                 , scrut_uds `plusUDs` alts_uds) }
 714
 715 ---------------- Finally, let is the interesting case --------------------
 716 specExpr subst (Let bind body) = do
 717         -- Clone binders
 718     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 719
 720         -- Deal with the body
 721     (body', body_uds) <- specExpr body_subst body
 722
 723         -- Deal with the bindings
 724     (binds', uds) <- specBind rhs_subst bind' body_uds
 725
 726         -- All done
 727     return (foldr Let body' binds', uds)
 728
 729 -- Must apply the type substitution to coerceions
 730 specNote :: Subst -> Note -> Note
 731 specNote _ note = note
 732
 733
 734 specCase :: Subst
 735          -> CoreExpr            -- Scrutinee, already done
 736          -> Id -> [CoreAlt]
 737          -> SpecM ( CoreExpr    -- New scrutinee
 738                   , Id
 739                   , [CoreAlt]
 740                   , UsageDetails)
 741 specCase subst scrut' case_bndr [(con, args, rhs)]
 742   | isDictId case_bndr           -- See Note [Floating dictionaries out of cases]
 743   , interestingDict scrut'
 744   , not (isDeadBinder case_bndr && null sc_args')
 745   = do { (case_bndr_flt : sc_args_flt) <- mapM clone_me (case_bndr' : sc_args')
 746
 747        ; let sc_rhss = [ Case (Var case_bndr_flt) case_bndr' (idType sc_arg')
 748                               [(con, args', Var sc_arg')]
 749                        | sc_arg' <- sc_args' ]
 750
 751              -- Extend the substitution for RHS to map the *original* binders
 752              -- to their floated verions.  Attach an unfolding to these floated
 753              -- binders so they look interesting to interestingDict
 754              mb_sc_flts :: [Maybe DictId]
 755              mb_sc_flts = map (lookupVarEnv clone_env) args'
 756              clone_env  = zipVarEnv sc_args' (zipWith add_unf sc_args_flt sc_rhss)
 757              subst_prs  = (case_bndr, Var (add_unf case_bndr_flt scrut'))
 758                         : [ (arg, Var sc_flt)
 759                           | (arg, Just sc_flt) <- args `zip` mb_sc_flts ]
 760              subst_rhs' = extendIdSubstList subst_rhs subst_prs
 761
 762        ; (rhs',   rhs_uds)   <- specExpr subst_rhs' rhs
 763        ; let scrut_bind    = mkDB (NonRec case_bndr_flt scrut')
 764              case_bndr_set = unitVarSet case_bndr_flt
 765              sc_binds      = [(NonRec sc_arg_flt sc_rhs, case_bndr_set)
 766                              | (sc_arg_flt, sc_rhs) <- sc_args_flt `zip` sc_rhss ]
 767              flt_binds     = scrut_bind : sc_binds
 768              (free_uds, dumped_dbs) = dumpUDs (case_bndr':args') rhs_uds
 769              all_uds = flt_binds `addDictBinds` free_uds
 770              alt'    = (con, args', wrapDictBindsE dumped_dbs rhs')
 771        ; return (Var case_bndr_flt, case_bndr', [alt'], all_uds) }
 772   where
 773     (subst_rhs, (case_bndr':args')) = substBndrs subst (case_bndr:args)
 774     sc_args' = filter is_flt_sc_arg args'
 775
 776     clone_me bndr = do { uniq <- getUniqueM
 777                        ; return (mkUserLocal occ uniq ty loc) }
 778        where
 779          name = idName bndr
 780          ty   = idType bndr
 781          occ  = nameOccName name
 782          loc  = getSrcSpan name
 783
 784     add_unf sc_flt sc_rhs  -- Sole purpose: make sc_flt respond True to interestingDictId
 785       = setIdUnfolding sc_flt (mkSimpleUnfolding sc_rhs)
 786
 787     arg_set = mkVarSet args'
 788     is_flt_sc_arg var =  isId var
 789                       && not (isDeadBinder var)
 790                       && isDictTy var_ty
 791                       && not (tyVarsOfType var_ty `intersectsVarSet` arg_set)
 792        where
 793          var_ty = idType var
 794
 795
 796 specCase subst scrut case_bndr alts
 797   = do { (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 798        ; return (scrut, case_bndr', alts', uds_alts) }
 799   where
 800     (subst_alt, case_bndr') = substBndr subst case_bndr
 801     spec_alt (con, args, rhs) = do
 802           (rhs', uds) <- specExpr subst_rhs rhs
 803           let (free_uds, dumped_dbs) = dumpUDs (case_bndr' : args') uds
 804           return ((con, args', wrapDictBindsE dumped_dbs rhs'), free_uds)
 805         where
 806           (subst_rhs, args') = substBndrs subst_alt args
 807 \end{code}
 808
 809 Note [Floating dictionaries out of cases]
 810 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 811 Consider
 812    g = \d. case d of { MkD sc ... -> ...(f sc)... }
 813 Naively we can't float d2's binding out of the case expression,
 814 because 'sc' is bound by the case, and that in turn means we can't
 815 specialise f, which seems a pity.
 816
 817 So we invert the case, by floating out a binding
 818 for 'sc_flt' thus:
 819     sc_flt = case d of { MkD sc ... -> sc }
 820 Now we can float the call instance for 'f'.  Indeed this is just
 821 what'll happen if 'sc' was originally bound with a let binding,
 822 but case is more efficient, and necessary with equalities. So it's
 823 good to work with both.
 824
 825 You might think that this won't make any difference, because the
 826 call instance will only get nuked by the \d.  BUT if 'g' itself is
 827 specialised, then transitively we should be able to specialise f.
 828
 829 In general, given
 830    case e of cb { MkD sc ... -> ...(f sc)... }
 831 we transform to
 832    let cb_flt = e
 833        sc_flt = case cb_flt of { MkD sc ... -> sc }
 834    in
 835    case cb_flt of bg { MkD sc ... -> ....(f sc_flt)... }
 836
 837 The "_flt" things are the floated binds; we use the current substitution
 838 to substitute sc -> sc_flt in the RHS
 839
 840 %************************************************************************
 841 %*                                                                      *
 842                      Dealing with a binding
 843 %*                                                                      *
 844 %************************************************************************
 845
 846 \begin{code}
 847 specBind :: Subst                       -- Use this for RHSs
 848          -> CoreBind
 849          -> UsageDetails                -- Info on how the scope of the binding
 850          -> SpecM ([CoreBind],          -- New bindings
 851                    UsageDetails)        -- And info to pass upstream
 852
 853 -- Returned UsageDetails:
 854 --    No calls for binders of this bind
 855 specBind rhs_subst (NonRec fn rhs) body_uds
 856   = do { (rhs', rhs_uds) <- specExpr rhs_subst rhs
 857        ; (fn', spec_defns, body_uds1) <- specDefn rhs_subst body_uds fn rhs
 858
 859        ; let pairs = spec_defns ++ [(fn', rhs')]
 860                         -- fn' mentions the spec_defns in its rules,
 861                         -- so put the latter first
 862
 863              combined_uds = body_uds1 `plusUDs` rhs_uds
 864                 -- This way round a call in rhs_uds of a function f
 865                 -- at type T will override a call of f at T in body_uds1; and
 866                 -- that is good because it'll tend to keep "earlier" calls
 867                 -- See Note [Specialisation of dictionary functions]
 868
 869              (free_uds, dump_dbs, float_all) = dumpBindUDs [fn] combined_uds
 870                 -- See Note [From non-recursive to recursive]
 871
 872              final_binds | isEmptyBag dump_dbs = [NonRec b r | (b,r) <- pairs]
 873                          | otherwise = [Rec (flattenDictBinds dump_dbs pairs)]
 874
 875          ; if float_all then
 876              -- Rather than discard the calls mentioning the bound variables
 877              -- we float this binding along with the others
 878               return ([], free_uds `snocDictBinds` final_binds)
 879            else
 880              -- No call in final_uds mentions bound variables,
 881              -- so we can just leave the binding here
 882               return (final_binds, free_uds) }
 883
 884
 885 specBind rhs_subst (Rec pairs) body_uds
 886        -- Note [Specialising a recursive group]
 887   = do { let (bndrs,rhss) = unzip pairs
 888        ; (rhss', rhs_uds) <- mapAndCombineSM (specExpr rhs_subst) rhss
 889        ; let scope_uds = body_uds `plusUDs` rhs_uds
 890                        -- Includes binds and calls arising from rhss
 891
 892        ; (bndrs1, spec_defns1, uds1) <- specDefns rhs_subst scope_uds pairs
 893
 894        ; (bndrs3, spec_defns3, uds3)
 895              <- if null spec_defns1  -- Common case: no specialisation
 896                 then return (bndrs1, [], uds1)
 897                 else do {            -- Specialisation occurred; do it again
 898                           (bndrs2, spec_defns2, uds2)
 899                               <- specDefns rhs_subst uds1 (bndrs1 `zip` rhss)
 900                         ; return (bndrs2, spec_defns2 ++ spec_defns1, uds2) }
 901
 902        ; let (final_uds, dumped_dbs, float_all) = dumpBindUDs bndrs uds3
 903              bind = Rec (flattenDictBinds dumped_dbs $
 904                          spec_defns3 ++ zip bndrs3 rhss')
 905
 906        ; if float_all then
 907               return ([], final_uds `snocDictBind` bind)
 908            else
 909               return ([bind], final_uds) }
 910
 911
 912 ---------------------------
 913 specDefns :: Subst
 914           -> UsageDetails               -- Info on how it is used in its scope
 915           -> [(Id,CoreExpr)]            -- The things being bound and their un-processed RHS
 916           -> SpecM ([Id],               -- Original Ids with RULES added
 917                     [(Id,CoreExpr)],    -- Extra, specialised bindings
 918                     UsageDetails)       -- Stuff to fling upwards from the specialised versions
 919
 920 -- Specialise a list of bindings (the contents of a Rec), but flowing usages
 921 -- upwards binding by binding.  Example: { f = ...g ...; g = ...f .... }
 922 -- Then if the input CallDetails has a specialised call for 'g', whose specialisation
 923 -- in turn generates a specialised call for 'f', we catch that in this one sweep.
 924 -- But not vice versa (it's a fixpoint problem).
 925
 926 specDefns _subst uds []
 927   = return ([], [], uds)
 928 specDefns subst uds ((bndr,rhs):pairs)
 929   = do { (bndrs1, spec_defns1, uds1) <- specDefns subst uds pairs
 930        ; (bndr1, spec_defns2, uds2)  <- specDefn subst uds1 bndr rhs
 931        ; return (bndr1 : bndrs1, spec_defns1 ++ spec_defns2, uds2) }
 932
 933 ---------------------------
 934 specDefn :: Subst
 935          -> UsageDetails                -- Info on how it is used in its scope
 936          -> Id -> CoreExpr              -- The thing being bound and its un-processed RHS
 937          -> SpecM (Id,                  -- Original Id with added RULES
 938                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 939                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
 940
 941 specDefn subst body_uds fn rhs
 942   = do { let (body_uds_without_me, calls_for_me) = callsForMe fn body_uds
 943              rules_for_me = idCoreRules fn
 944        ; (rules, spec_defns, spec_uds) <- specCalls subst rules_for_me
 945                                                     calls_for_me fn rhs
 946        ; return ( fn `addIdSpecialisations` rules
 947                 , spec_defns
 948                 , body_uds_without_me `plusUDs` spec_uds) }
 949                 -- It's important that the `plusUDs` is this way
 950                 -- round, because body_uds_without_me may bind
 951                 -- dictionaries that are used in calls_for_me passed
 952                 -- to specDefn.  So the dictionary bindings in
 953                 -- spec_uds may mention dictionaries bound in
 954                 -- body_uds_without_me
 955
 956 ---------------------------
 957 specCalls :: Subst
 958           -> [CoreRule]                 -- Existing RULES for the fn
 959           -> [CallInfo]
 960           -> Id -> CoreExpr
 961           -> SpecM ([CoreRule],         -- New RULES for the fn
 962                     [(Id,CoreExpr)],    -- Extra, specialised bindings
 963                     UsageDetails)       -- New usage details from the specialised RHSs
 964
 965 -- This function checks existing rules, and does not create
 966 -- duplicate ones. So the caller does not nneed to do this filtering.
 967 -- See 'already_covered'
 968
 969 specCalls subst rules_for_me calls_for_me fn rhs
 970         -- The first case is the interesting one
 971   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 972   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 973   && notNull calls_for_me               -- And there are some calls to specialise
 974   && not (isNeverActive (idInlineActivation fn))
 975         -- Don't specialise NOINLINE things
 976         -- See Note [Auto-specialisation and RULES]
 977
 978 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 979 --      See Note [Inline specialisation] for why we do not
 980 --      switch off specialisation for inline functions
 981
 982   = -- pprTrace "specDefn: some" (ppr fn $$ ppr calls_for_me $$ ppr rules_for_me) $
 983     do { stuff <- mapM spec_call calls_for_me
 984        ; let (spec_defns, spec_uds, spec_rules) = unzip3 (catMaybes stuff)
 985        ; return (spec_rules, spec_defns, plusUDList spec_uds) }
 986
 987   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 988   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 989           -- Note [Specialisation shape]
 990     -- pprTrace "specDefn: none" (ppr fn $$ ppr calls_for_me) $
 991     return ([], [], emptyUDs)
 992
 993   where
 994     fn_type            = idType fn
 995     fn_arity           = idArity fn
 996     fn_unf             = realIdUnfolding fn     -- Ignore loop-breaker-ness here
 997     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 998     n_tyvars           = length tyvars
 999     n_dicts            = length theta
1000     inl_prag           = idInlinePragma fn
1001     inl_act            = inlinePragmaActivation inl_prag
1002     is_local           = isLocalId fn
1003
1004         -- Figure out whether the function has an INLINE pragma
1005         -- See Note [Inline specialisations]
1006
1007     spec_arity = unfoldingArity fn_unf - n_dicts  -- Arity of the *specialised* inline rule
1008
1009     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs
1010
1011     rhs_dict_ids = take n_dicts rhs_ids
1012     body         = mkLams (drop n_dicts rhs_ids) rhs_body
1013                 -- Glue back on the non-dict lambdas
1014
1015     already_covered :: [CoreExpr] -> Bool
1016     already_covered args          -- Note [Specialisations already covered]
1017        = isJust (lookupRule (const True) realIdUnfolding
1018                             (substInScope subst)
1019                             fn args rules_for_me)
1020
1021     mk_ty_args :: [Maybe Type] -> [CoreExpr]
1022     mk_ty_args call_ts = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
1023                where
1024                   mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
1025                   mk_ty_arg _         (Just ty) = Type ty
1026
1027     ----------------------------------------------------------
1028         -- Specialise to one particular call pattern
1029     spec_call :: CallInfo                         -- Call instance
1030               -> SpecM (Maybe ((Id,CoreExpr),     -- Specialised definition
1031                                UsageDetails,      -- Usage details from specialised body
1032                                CoreRule))         -- Info for the Id's SpecEnv
1033     spec_call (CallKey call_ts, (call_ds, _))
1034       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
1035
1036         -- Suppose f's defn is  f = /\ a b c -> \ d1 d2 -> rhs
1037         -- Supppose the call is for f [Just t1, Nothing, Just t3] [dx1, dx2]
1038
1039         -- Construct the new binding
1040         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b -> rhs)
1041         -- PLUS the usage-details
1042         --      { d1' = dx1; d2' = dx2 }
1043         -- where d1', d2' are cloned versions of d1,d2, with the type substitution
1044         -- applied.  These auxiliary bindings just avoid duplication of dx1, dx2
1045         --
1046         -- Note that the substitution is applied to the whole thing.
1047         -- This is convenient, but just slightly fragile.  Notably:
1048         --      * There had better be no name clashes in a/b/c
1049         do { let
1050                 -- poly_tyvars = [b] in the example above
1051                 -- spec_tyvars = [a,c]
1052                 -- ty_args     = [t1,b,t3]
1053                 poly_tyvars   = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
1054                 spec_tv_binds = [(tv,ty) | (tv, Just ty) <- rhs_tyvars `zip` call_ts]
1055                 spec_ty_args  = map snd spec_tv_binds
1056                 ty_args       = mk_ty_args call_ts
1057                 rhs_subst     = CoreSubst.extendTvSubstList subst spec_tv_binds
1058
1059            ; (rhs_subst1, inst_dict_ids) <- newDictBndrs rhs_subst rhs_dict_ids
1060                           -- Clone rhs_dicts, including instantiating their types
1061
1062            ; let (rhs_subst2, dx_binds) = bindAuxiliaryDicts rhs_subst1 $
1063                                           (my_zipEqual rhs_dict_ids inst_dict_ids call_ds)
1064                  inst_args = ty_args ++ map Var inst_dict_ids
1065
1066            ; if already_covered inst_args then
1067                 return Nothing
1068              else do
1069            {    -- Figure out the type of the specialised function
1070              let body_ty = applyTypeToArgs rhs fn_type inst_args
1071                  (lam_args, app_args)           -- Add a dummy argument if body_ty is unlifted
1072                    | isUnLiftedType body_ty     -- C.f. WwLib.mkWorkerArgs
1073                    = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
1074                    | otherwise = (poly_tyvars, poly_tyvars)
1075                  spec_id_ty = mkPiTypes lam_args body_ty
1076
1077            ; spec_f <- newSpecIdSM fn spec_id_ty
1078            ; (spec_rhs, rhs_uds) <- specExpr rhs_subst2 (mkLams lam_args body)
1079            ; let
1080                 -- The rule to put in the function's specialisation is:
1081                 --      forall b, d1',d2'.  f t1 b t3 d1' d2' = f1 b
1082                 rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
1083                 spec_env_rule = mkRule True {- Auto generated -} is_local
1084                                   rule_name
1085                                   inl_act       -- Note [Auto-specialisation and RULES]
1086                                   (idName fn)
1087                                   (poly_tyvars ++ inst_dict_ids)
1088                                   inst_args
1089                                   (mkVarApps (Var spec_f) app_args)
1090
1091                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
1092                 final_uds = foldr consDictBind rhs_uds dx_binds
1093
1094                 -- Add an InlineRule if the parent has one
1095                 -- See Note [Inline specialisations]
1096                 spec_unf
1097                   = case inlinePragmaSpec inl_prag of
1098                       Inline    -> mkInlineUnfolding (Just spec_arity) spec_rhs
1099                       Inlinable -> mkInlinableUnfolding spec_rhs
1100                       _         -> NoUnfolding
1101
1102                 -- Adding arity information just propagates it a bit faster
1103                 --      See Note [Arity decrease] in Simplify
1104                 -- Copy InlinePragma information from the parent Id.
1105                 -- So if f has INLINE[1] so does spec_f
1106                 spec_f_w_arity = spec_f `setIdArity`          max 0 (fn_arity - n_dicts)
1107                                         `setInlinePragma` inl_prag
1108                                         `setIdUnfolding`  spec_unf
1109
1110            ; return (Just ((spec_f_w_arity, spec_rhs), final_uds, spec_env_rule)) } }
1111       where
1112         my_zipEqual xs ys zs
1113          | debugIsOn && not (equalLength xs ys && equalLength ys zs)
1114              = pprPanic "my_zipEqual" (vcat [ ppr xs, ppr ys
1115                                             , ppr fn <+> ppr call_ts
1116                                             , ppr (idType fn), ppr theta
1117                                             , ppr n_dicts, ppr rhs_dict_ids
1118                                             , ppr rhs])
1119          | otherwise = zip3 xs ys zs
1120
1121 bindAuxiliaryDicts
1122         :: Subst
1123         -> [(DictId,DictId,CoreExpr)]   -- (orig_dict, inst_dict, dx)
1124         -> (Subst,                      -- Substitute for all orig_dicts
1125             [CoreBind])                 -- Auxiliary bindings
1126 -- Bind any dictionary arguments to fresh names, to preserve sharing
1127 -- Substitution already substitutes orig_dict -> inst_dict
1128 bindAuxiliaryDicts subst triples = go subst [] triples
1129   where
1130     go subst binds []    = (subst, binds)
1131     go subst binds ((d, dx_id, dx) : pairs)
1132       | exprIsTrivial dx = go (extendIdSubst subst d dx) binds pairs
1133              -- No auxiliary binding necessary
1134              -- Note that we bind the *original* dict in the substitution,
1135              -- overriding any d->dx_id binding put there by substBndrs
1136
1137       | otherwise        = go subst_w_unf (NonRec dx_id dx : binds) pairs
1138       where
1139         dx_id1 = dx_id `setIdUnfolding` mkSimpleUnfolding dx
1140         subst_w_unf = extendIdSubst subst d (Var dx_id1)
1141              -- Important!  We're going to substitute dx_id1 for d
1142              -- and we want it to look "interesting", else we won't gather *any*
1143              -- consequential calls. E.g.
1144              --     f d = ...g d....
1145              -- If we specialise f for a call (f (dfun dNumInt)), we'll get
1146              -- a consequent call (g d') with an auxiliary definition
1147              --     d' = df dNumInt
1148              -- We want that consequent call to look interesting
1149              --
1150              -- Again, note that we bind the *original* dict in the substitution,
1151              -- overriding any d->dx_id binding put there by substBndrs
1152 \end{code}
1153
1154 Note [From non-recursive to recursive]
1155 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1156 Even in the non-recursive case, if any dict-binds depend on 'fn' we might
1157 have built a recursive knot
1158
1159       f a d x = <blah>
1160       MkUD { ud_binds = d7 = MkD ..f..
1161            , ud_calls = ...(f T d7)... }
1162
1163 The we generate
1164
1165       Rec { fs x = <blah>[T/a, d7/d]
1166             f a d x = <blah>
1167                RULE f T _ = fs
1168             d7 = ...f... }
1169
1170 Here the recursion is only through the RULE.
1171
1172
1173 Note [Specialisation of dictionary functions]
1174 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1175 Here is a nasty example that bit us badly: see Trac #3591
1176
1177      dfun a d = MkD a d (meth d)
1178      d4 = <blah>
1179      d2 = dfun T d4
1180      d1 = $p1 d2
1181      d3 = dfun T d1
1182
1183 None of these definitions is recursive. What happened was that we
1184 generated a specialisation:
1185
1186      RULE forall d. dfun T d = dT
1187      dT = (MkD a d (meth d)) [T/a, d1/d]
1188         = MkD T d1 (meth d1)
1189
1190 But now we use the RULE on the RHS of d2, to get
1191
1192     d2 = dT = MkD d1 (meth d1)
1193     d1 = $p1 d2
1194
1195 and now d1 is bottom!  The problem is that when specialising 'dfun' we
1196 should first dump "below" the binding all floated dictionary bindings
1197 that mention 'dfun' itself.  So d2 and d3 (and hence d1) must be
1198 placed below 'dfun', and thus unavailable to it when specialising
1199 'dfun'.  That in turn means that the call (dfun T d1) must be
1200 discarded.  On the other hand, the call (dfun T d4) is fine, assuming
1201 d4 doesn't mention dfun.
1202
1203 But look at this:
1204
1205   class C a where { foo,bar :: [a] -> [a] }
1206
1207   instance C Int where
1208      foo x = r_bar x
1209      bar xs = reverse xs
1210
1211   r_bar :: C a => [a] -> [a]
1212   r_bar xs = bar (xs ++ xs)
1213
1214 That translates to:
1215
1216     r_bar a (c::C a) (xs::[a]) = bar a d (xs ++ xs)
1217
1218     Rec { $fCInt :: C Int = MkC foo_help reverse
1219           foo_help (xs::[Int]) = r_bar Int $fCInt xs }
1220
1221 The call (r_bar $fCInt) mentions $fCInt,
1222                         which mentions foo_help,
1223                         which mentions r_bar
1224 But we DO want to specialise r_bar at Int:
1225
1226     Rec { $fCInt :: C Int = MkC foo_help reverse
1227           foo_help (xs::[Int]) = r_bar Int $fCInt xs
1228
1229           r_bar a (c::C a) (xs::[a]) = bar a d (xs ++ xs)
1230             RULE r_bar Int _ = r_bar_Int
1231
1232           r_bar_Int xs = bar Int $fCInt (xs ++ xs)
1233            }
1234
1235 Note that, because of its RULE, r_bar joins the recursive
1236 group.  (In this case it'll unravel a short moment later.)
1237
1238
1239 Conclusion: we catch the nasty case using filter_dfuns in
1240 callsForMe. To be honest I'm not 100% certain that this is 100%
1241 right, but it works.  Sigh.
1242
1243
1244 Note [Specialising a recursive group]
1245 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1246 Consider
1247     let rec { f x = ...g x'...
1248             ; g y = ...f y'.... }
1249     in f 'a'
1250 Here we specialise 'f' at Char; but that is very likely to lead to
1251 a specialisation of 'g' at Char.  We must do the latter, else the
1252 whole point of specialisation is lost.
1253
1254 But we do not want to keep iterating to a fixpoint, because in the
1255 presence of polymorphic recursion we might generate an infinite number
1256 of specialisations.
1257
1258 So we use the following heuristic:
1259   * Arrange the rec block in dependency order, so far as possible
1260     (the occurrence analyser already does this)
1261
1262   * Specialise it much like a sequence of lets
1263
1264   * Then go through the block a second time, feeding call-info from
1265     the RHSs back in the bottom, as it were
1266
1267 In effect, the ordering maxmimises the effectiveness of each sweep,
1268 and we do just two sweeps.   This should catch almost every case of
1269 monomorphic recursion -- the exception could be a very knotted-up
1270 recursion with multiple cycles tied up together.
1271
1272 This plan is implemented in the Rec case of specBindItself.
1273
1274 Note [Specialisations already covered]
1275 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1276 We obviously don't want to generate two specialisations for the same
1277 argument pattern.  There are two wrinkles
1278
1279 1. We do the already-covered test in specDefn, not when we generate
1280 the CallInfo in mkCallUDs.  We used to test in the latter place, but
1281 we now iterate the specialiser somewhat, and the Id at the call site
1282 might therefore not have all the RULES that we can see in specDefn
1283
1284 2. What about two specialisations where the second is an *instance*
1285 of the first?  If the more specific one shows up first, we'll generate
1286 specialisations for both.  If the *less* specific one shows up first,
1287 we *don't* currently generate a specialisation for the more specific
1288 one.  (See the call to lookupRule in already_covered.)  Reasons:
1289   (a) lookupRule doesn't say which matches are exact (bad reason)
1290   (b) if the earlier specialisation is user-provided, it's
1291       far from clear that we should auto-specialise further
1292
1293 Note [Auto-specialisation and RULES]
1294 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1295 Consider:
1296    g :: Num a => a -> a
1297    g = ...
1298
1299    f :: (Int -> Int) -> Int
1300    f w = ...
1301    {-# RULE f g = 0 #-}
1302
1303 Suppose that auto-specialisation makes a specialised version of
1304 g::Int->Int That version won't appear in the LHS of the RULE for f.
1305 So if the specialisation rule fires too early, the rule for f may
1306 never fire.
1307
1308 It might be possible to add new rules, to "complete" the rewrite system.
1309 Thus when adding
1310         RULE forall d. g Int d = g_spec
1311 also add
1312         RULE f g_spec = 0
1313
1314 But that's a bit complicated.  For now we ask the programmer's help,
1315 by *copying the INLINE activation pragma* to the auto-specialised
1316 rule.  So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule
1317 will also not be active until phase 2.  And that's what programmers
1318 should jolly well do anyway, even aside from specialisation, to ensure
1319 that g doesn't inline too early.
1320
1321 This in turn means that the RULE would never fire for a NOINLINE
1322 thing so not much point in generating a specialisation at all.
1323
1324 Note [Specialisation shape]
1325 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1326 We only specialise a function if it has visible top-level lambdas
1327 corresponding to its overloading.  E.g. if
1328         f :: forall a. Eq a => ....
1329 then its body must look like
1330         f = /\a. \d. ...
1331
1332 Reason: when specialising the body for a call (f ty dexp), we want to
1333 substitute dexp for d, and pick up specialised calls in the body of f.
1334
1335 This doesn't always work.  One example I came across was this:
1336         newtype Gen a = MkGen{ unGen :: Int -> a }
1337
1338         choose :: Eq a => a -> Gen a
1339         choose n = MkGen (\r -> n)
1340
1341         oneof = choose (1::Int)
1342
1343 It's a silly exapmle, but we get
1344         choose = /\a. g `cast` co
1345 where choose doesn't have any dict arguments.  Thus far I have not
1346 tried to fix this (wait till there's a real example).
1347
1348 Note [Inline specialisations]
1349 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1350 We transfer to the specialised function any INLINE stuff from the
1351 original.  This means
1352    (a) the Activation for its inlining (from its InlinePragma)
1353    (b) any InlineRule
1354
1355 This is a change (Jun06).  Previously the idea is that the point of
1356 inlining was precisely to specialise the function at its call site,
1357 and that's not so important for the specialised copies.  But
1358 *pragma-directed* specialisation now takes place in the
1359 typechecker/desugarer, with manually specified INLINEs.  The
1360 specialiation here is automatic.  It'd be very odd if a function
1361 marked INLINE was specialised (because of some local use), and then
1362 forever after (including importing modules) the specialised version
1363 wasn't INLINEd.  After all, the programmer said INLINE!
1364
1365 You might wonder why we don't just not specialise INLINE functions.
1366 It's because even INLINE functions are sometimes not inlined, when
1367 they aren't applied to interesting arguments.  But perhaps the type
1368 arguments alone are enough to specialise (even though the args are too
1369 boring to trigger inlining), and it's certainly better to call the
1370 specialised version.
1371
1372
1373 %************************************************************************
1374 %*                                                                      *
1375 \subsubsection{UsageDetails and suchlike}
1376 %*                                                                      *
1377 %************************************************************************
1378
1379 \begin{code}
1380 data UsageDetails
1381   = MkUD {
1382         ud_binds :: !(Bag DictBind),
1383                         -- Floated dictionary bindings
1384                         -- The order is important;
1385                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1386                         -- (Remember, Bags preserve order in GHC.)
1387
1388         ud_calls :: !CallDetails
1389
1390         -- INVARIANT: suppose bs = bindersOf ud_binds
1391         -- Then 'calls' may *mention* 'bs',
1392         -- but there should be no calls *for* bs
1393     }
1394
1395 instance Outputable UsageDetails where
1396   ppr (MkUD { ud_binds = dbs, ud_calls = calls })
1397         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1398                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1399                  ptext (sLit "calls") <+> equals <+> ppr calls]))
1400
1401 type DictBind = (CoreBind, VarSet)
1402         -- The set is the free vars of the binding
1403         -- both tyvars and dicts
1404
1405 type DictExpr = CoreExpr
1406
1407 emptyUDs :: UsageDetails
1408 emptyUDs = MkUD { ud_binds = emptyBag, ud_calls = emptyVarEnv }
1409
1410 ------------------------------------------------------------
1411 type CallDetails  = IdEnv CallInfoSet
1412 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1413
1414 -- CallInfo uses a Map, thereby ensuring that
1415 -- we record only one call instance for any key
1416 --
1417 -- The list of types and dictionaries is guaranteed to
1418 -- match the type of f
1419 data CallInfoSet = CIS Id (Map CallKey ([DictExpr], VarSet))
1420                         -- Range is dict args and the vars of the whole
1421                         -- call (including tyvars)
1422                         -- [*not* include the main id itself, of course]
1423
1424 type CallInfo = (CallKey, ([DictExpr], VarSet))
1425
1426 instance Outputable CallInfoSet where
1427   ppr (CIS fn map) = hang (ptext (sLit "CIS") <+> ppr fn)
1428                         2 (ppr map)
1429
1430 instance Outputable CallKey where
1431   ppr (CallKey ts) = ppr ts
1432
1433 -- Type isn't an instance of Ord, so that we can control which
1434 -- instance we use.  That's tiresome here.  Oh well
1435 instance Eq CallKey where
1436   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1437
1438 instance Ord CallKey where
1439   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1440                 where
1441                   cmp Nothing   Nothing   = EQ
1442                   cmp Nothing   (Just _)  = LT
1443                   cmp (Just _)  Nothing   = GT
1444                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1445
1446 unionCalls :: CallDetails -> CallDetails -> CallDetails
1447 unionCalls c1 c2 = plusVarEnv_C unionCallInfoSet c1 c2
1448
1449 unionCallInfoSet :: CallInfoSet -> CallInfoSet -> CallInfoSet
1450 unionCallInfoSet (CIS f calls1) (CIS _ calls2) = CIS f (calls1 `Map.union` calls2)
1451
1452 callDetailsFVs :: CallDetails -> VarSet
1453 callDetailsFVs calls = foldVarEnv (unionVarSet . callInfoFVs) emptyVarSet calls
1454
1455 callInfoFVs :: CallInfoSet -> VarSet
1456 callInfoFVs (CIS _ call_info) = Map.foldRight (\(_,fv) vs -> unionVarSet fv vs) emptyVarSet call_info
1457
1458 ------------------------------------------------------------
1459 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1460 singleCall id tys dicts
1461   = MkUD {ud_binds = emptyBag,
1462           ud_calls = unitVarEnv id $ CIS id $
1463                      Map.singleton (CallKey tys) (dicts, call_fvs) }
1464   where
1465     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1466     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1467         -- The type args (tys) are guaranteed to be part of the dictionary
1468         -- types, because they are just the constrained types,
1469         -- and the dictionary is therefore sure to be bound
1470         -- inside the binding for any type variables free in the type;
1471         -- hence it's safe to neglect tyvars free in tys when making
1472         -- the free-var set for this call
1473         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1474         --
1475         -- We don't include the 'id' itself.
1476
1477 mkCallUDs :: Id -> [CoreExpr] -> UsageDetails
1478 mkCallUDs f args
1479   | not (want_calls_for f)  -- Imported from elsewhere
1480   || null theta             -- Not overloaded
1481   || not (all isClassPred theta)
1482         -- Only specialise if all overloading is on class params.
1483         -- In ptic, with implicit params, the type args
1484         --  *don't* say what the value of the implicit param is!
1485   || not (spec_tys `lengthIs` n_tyvars)
1486   || not ( dicts   `lengthIs` n_dicts)
1487   || not (any interestingDict dicts)    -- Note [Interesting dictionary arguments]
1488   -- See also Note [Specialisations already covered]
1489   = -- pprTrace "mkCallUDs: discarding" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingDict dicts)])
1490     emptyUDs    -- Not overloaded, or no specialisation wanted
1491
1492   | otherwise
1493   = -- pprTrace "mkCallUDs: keeping" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingDict dicts)])
1494     singleCall f spec_tys dicts
1495   where
1496     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1497     constrained_tyvars = tyVarsOfTheta theta
1498     n_tyvars           = length tyvars
1499     n_dicts            = length theta
1500
1501     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1502     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1503
1504     mk_spec_ty tyvar ty
1505         | tyvar `elemVarSet` constrained_tyvars = Just ty
1506         | otherwise                             = Nothing
1507
1508     want_calls_for f = isLocalId f || isInlinablePragma (idInlinePragma f)
1509 \end{code}
1510
1511 Note [Interesting dictionary arguments]
1512 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1513 Consider this
1514          \a.\d:Eq a.  let f = ... in ...(f d)...
1515 There really is not much point in specialising f wrt the dictionary d,
1516 because the code for the specialised f is not improved at all, because
1517 d is lambda-bound.  We simply get junk specialisations.
1518
1519 What is "interesting"?  Just that it has *some* structure.
1520
1521 \begin{code}
1522 interestingDict :: CoreExpr -> Bool
1523 -- A dictionary argument is interesting if it has *some* structure
1524 interestingDict (Var v) =  hasSomeUnfolding (idUnfolding v)
1525                         || isDataConWorkId v
1526 interestingDict (Type _)          = False
1527 interestingDict (App fn (Type _)) = interestingDict fn
1528 interestingDict (Note _ a)        = interestingDict a
1529 interestingDict (Cast e _)        = interestingDict e
1530 interestingDict _                 = True
1531 \end{code}
1532
1533 \begin{code}
1534 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1535 plusUDs (MkUD {ud_binds = db1, ud_calls = calls1})
1536         (MkUD {ud_binds = db2, ud_calls = calls2})
1537   = MkUD { ud_binds = db1    `unionBags`   db2
1538          , ud_calls = calls1 `unionCalls`  calls2 }
1539
1540 plusUDList :: [UsageDetails] -> UsageDetails
1541 plusUDList = foldr plusUDs emptyUDs
1542
1543 -----------------------------
1544 _dictBindBndrs :: Bag DictBind -> [Id]
1545 _dictBindBndrs dbs = foldrBag ((++) . bindersOf . fst) [] dbs
1546
1547 mkDB :: CoreBind -> DictBind
1548 mkDB bind = (bind, bind_fvs bind)
1549
1550 bind_fvs :: CoreBind -> VarSet
1551 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1552 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1553                            where
1554                              bndrs = map fst prs
1555                              rhs_fvs = unionVarSets (map pair_fvs prs)
1556
1557 pair_fvs :: (Id, CoreExpr) -> VarSet
1558 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1559         -- Don't forget variables mentioned in the
1560         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1561         -- Also tyvars mentioned in its type; they may not appear in the RHS
1562         --      type T a = Int
1563         --      x :: T a = 3
1564
1565 flattenDictBinds :: Bag DictBind -> [(Id,CoreExpr)] -> [(Id,CoreExpr)]
1566 flattenDictBinds dbs pairs
1567   = foldrBag add pairs dbs
1568   where
1569     add (NonRec b r,_) pairs = (b,r) : pairs
1570     add (Rec prs1, _)  pairs = prs1 ++ pairs
1571
1572 snocDictBinds :: UsageDetails -> [CoreBind] -> UsageDetails
1573 -- Add ud_binds to the tail end of the bindings in uds
1574 snocDictBinds uds dbs
1575   = uds { ud_binds = ud_binds uds `unionBags`
1576                      foldr (consBag . mkDB) emptyBag dbs }
1577
1578 consDictBind :: CoreBind -> UsageDetails -> UsageDetails
1579 consDictBind bind uds = uds { ud_binds = mkDB bind `consBag` ud_binds uds }
1580
1581 addDictBinds :: [DictBind] -> UsageDetails -> UsageDetails
1582 addDictBinds binds uds = uds { ud_binds = listToBag binds `unionBags` ud_binds uds }
1583
1584 snocDictBind :: UsageDetails -> CoreBind -> UsageDetails
1585 snocDictBind uds bind = uds { ud_binds = ud_binds uds `snocBag` mkDB bind }
1586
1587 wrapDictBinds :: Bag DictBind -> [CoreBind] -> [CoreBind]
1588 wrapDictBinds dbs binds
1589   = foldrBag add binds dbs
1590   where
1591     add (bind,_) binds = bind : binds
1592
1593 wrapDictBindsE :: Bag DictBind -> CoreExpr -> CoreExpr
1594 wrapDictBindsE dbs expr
1595   = foldrBag add expr dbs
1596   where
1597     add (bind,_) expr = Let bind expr
1598
1599 ----------------------
1600 dumpUDs :: [CoreBndr] -> UsageDetails -> (UsageDetails, Bag DictBind)
1601 -- Used at a lambda or case binder; just dump anything mentioning the binder
1602 dumpUDs bndrs uds@(MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1603   | null bndrs = (uds, emptyBag)  -- Common in case alternatives
1604   | otherwise  = -- pprTrace "dumpUDs" (ppr bndrs $$ ppr free_uds $$ ppr dump_dbs) $
1605                  (free_uds, dump_dbs)
1606   where
1607     free_uds = MkUD { ud_binds = free_dbs, ud_calls = free_calls }
1608     bndr_set = mkVarSet bndrs
1609     (free_dbs, dump_dbs, dump_set) = splitDictBinds orig_dbs bndr_set
1610     free_calls = deleteCallsMentioning dump_set $   -- Drop calls mentioning bndr_set on the floor
1611                  deleteCallsFor bndrs orig_calls    -- Discard calls for bndr_set; there should be
1612                                                     -- no calls for any of the dicts in dump_dbs
1613
1614 dumpBindUDs :: [CoreBndr] -> UsageDetails -> (UsageDetails, Bag DictBind, Bool)
1615 -- Used at a lambda or case binder; just dump anything mentioning the binder
1616 dumpBindUDs bndrs (MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1617   = -- pprTrace "dumpBindUDs" (ppr bndrs $$ ppr free_uds $$ ppr dump_dbs) $
1618     (free_uds, dump_dbs, float_all)
1619   where
1620     free_uds = MkUD { ud_binds = free_dbs, ud_calls = free_calls }
1621     bndr_set = mkVarSet bndrs
1622     (free_dbs, dump_dbs, dump_set) = splitDictBinds orig_dbs bndr_set
1623     free_calls = deleteCallsFor bndrs orig_calls
1624     float_all = dump_set `intersectsVarSet` callDetailsFVs free_calls
1625
1626 callsForMe :: Id -> UsageDetails -> (UsageDetails, [CallInfo])
1627 callsForMe fn (MkUD { ud_binds = orig_dbs, ud_calls = orig_calls })
1628   = -- pprTrace ("callsForMe")
1629     --         (vcat [ppr fn,
1630     --                text "Orig dbs ="     <+> ppr (_dictBindBndrs orig_dbs),
1631     --                text "Orig calls ="   <+> ppr orig_calls,
1632     --                text "Dep set ="      <+> ppr dep_set,
1633     --                text "Calls for me =" <+> ppr calls_for_me]) $
1634     (uds_without_me, calls_for_me)
1635   where
1636     uds_without_me = MkUD { ud_binds = orig_dbs, ud_calls = delVarEnv orig_calls fn }
1637     calls_for_me = case lookupVarEnv orig_calls fn of
1638                         Nothing -> []
1639                         Just (CIS _ calls) -> filter_dfuns (Map.toList calls)
1640
1641     dep_set = foldlBag go (unitVarSet fn) orig_dbs
1642     go dep_set (db,fvs) | fvs `intersectsVarSet` dep_set
1643                         = extendVarSetList dep_set (bindersOf db)
1644                         | otherwise = dep_set
1645
1646         -- Note [Specialisation of dictionary functions]
1647     filter_dfuns | isDFunId fn = filter ok_call
1648                  | otherwise   = \cs -> cs
1649
1650     ok_call (_, (_,fvs)) = not (fvs `intersectsVarSet` dep_set)
1651
1652 ----------------------
1653 splitDictBinds :: Bag DictBind -> IdSet -> (Bag DictBind, Bag DictBind, IdSet)
1654 -- Returns (free_dbs, dump_dbs, dump_set)
1655 splitDictBinds dbs bndr_set
1656    = foldlBag split_db (emptyBag, emptyBag, bndr_set) dbs
1657                 -- Important that it's foldl not foldr;
1658                 -- we're accumulating the set of dumped ids in dump_set
1659    where
1660     split_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1661         | dump_idset `intersectsVarSet` fvs     -- Dump it
1662         = (free_dbs, dump_dbs `snocBag` db,
1663            extendVarSetList dump_idset (bindersOf bind))
1664
1665         | otherwise     -- Don't dump it
1666         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1667
1668
1669 ----------------------
1670 deleteCallsMentioning :: VarSet -> CallDetails -> CallDetails
1671 -- Remove calls *mentioning* bs
1672 deleteCallsMentioning bs calls
1673   = mapVarEnv filter_calls calls
1674   where
1675     filter_calls :: CallInfoSet -> CallInfoSet
1676     filter_calls (CIS f calls) = CIS f (Map.filter keep_call calls)
1677     keep_call (_, fvs) = not (fvs `intersectsVarSet` bs)
1678
1679 deleteCallsFor :: [Id] -> CallDetails -> CallDetails
1680 -- Remove calls *for* bs
1681 deleteCallsFor bs calls = delVarEnvList calls bs
1682 \end{code}
1683
1684
1685 %************************************************************************
1686 %*                                                                      *
1687 \subsubsection{Boring helper functions}
1688 %*                                                                      *
1689 %************************************************************************
1690
1691 \begin{code}
1692 type SpecM a = UniqSM a
1693
1694 runSpecM:: SpecM a -> CoreM a
1695 runSpecM spec = do { us <- getUniqueSupplyM
1696                    ; return (initUs_ us spec) }
1697
1698 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1699 mapAndCombineSM _ []     = return ([], emptyUDs)
1700 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1701                               (ys, uds2) <- mapAndCombineSM f xs
1702                               return (y:ys, uds1 `plusUDs` uds2)
1703
1704 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1705 -- Clone the binders of the bind; return new bind with the cloned binders
1706 -- Return the substitution to use for RHSs, and the one to use for the body
1707 cloneBindSM subst (NonRec bndr rhs) = do
1708     us <- getUniqueSupplyM
1709     let (subst', bndr') = cloneIdBndr subst us bndr
1710     return (subst, subst', NonRec bndr' rhs)
1711
1712 cloneBindSM subst (Rec pairs) = do
1713     us <- getUniqueSupplyM
1714     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1715     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1716
1717 newDictBndrs :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1718 -- Make up completely fresh binders for the dictionaries
1719 -- Their bindings are going to float outwards
1720 newDictBndrs subst bndrs
1721   = do { bndrs' <- mapM new bndrs
1722        ; let subst' = extendIdSubstList subst
1723                         [(d, Var d') | (d,d') <- bndrs `zip` bndrs']
1724        ; return (subst', bndrs' ) }
1725   where
1726     new b = do { uniq <- getUniqueM
1727                ; let n   = idName b
1728                      ty' = CoreSubst.substTy subst (idType b)
1729                ; return (mkUserLocal (nameOccName n) uniq ty' (getSrcSpan n)) }
1730
1731 newSpecIdSM :: Id -> Type -> SpecM Id
1732     -- Give the new Id a similar occurrence name to the old one
1733 newSpecIdSM old_id new_ty
1734   = do  { uniq <- getUniqueM
1735         ; let name    = idName old_id
1736               new_occ = mkSpecOcc (nameOccName name)
1737               new_id  = mkUserLocal new_occ uniq new_ty (getSrcSpan name)
1738         ; return new_id }
1739 \end{code}
1740
1741
1742                 Old (but interesting) stuff about unboxed bindings
1743                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1744
1745 What should we do when a value is specialised to a *strict* unboxed value?
1746
1747         map_*_* f (x:xs) = let h = f x
1748                                t = map f xs
1749                            in h:t
1750
1751 Could convert let to case:
1752
1753         map_*_Int# f (x:xs) = case f x of h# ->
1754                               let t = map f xs
1755                               in h#:t
1756
1757 This may be undesirable since it forces evaluation here, but the value
1758 may not be used in all branches of the body. In the general case this
1759 transformation is impossible since the mutual recursion in a letrec
1760 cannot be expressed as a case.
1761
1762 There is also a problem with top-level unboxed values, since our
1763 implementation cannot handle unboxed values at the top level.
1764
1765 Solution: Lift the binding of the unboxed value and extract it when it
1766 is used:
1767
1768         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1769                                   t = map f xs
1770                               in case h of
1771                                  _Lift h# -> h#:t
1772
1773 Now give it to the simplifier and the _Lifting will be optimised away.
1774
1775 The benfit is that we have given the specialised "unboxed" values a
1776 very simplep lifted semantics and then leave it up to the simplifier to
1777 optimise it --- knowing that the overheads will be removed in nearly
1778 all cases.
1779
1780 In particular, the value will only be evaluted in the branches of the
1781 program which use it, rather than being forced at the point where the
1782 value is bound. For example:
1783
1784         filtermap_*_* p f (x:xs)
1785           = let h = f x
1786                 t = ...
1787             in case p x of
1788                 True  -> h:t
1789                 False -> t
1790    ==>
1791         filtermap_*_Int# p f (x:xs)
1792           = let h = case (f x) of h# -> _Lift h#
1793                 t = ...
1794             in case p x of
1795                 True  -> case h of _Lift h#
1796                            -> h#:t
1797                 False -> t
1798
1799 The binding for h can still be inlined in the one branch and the
1800 _Lifting eliminated.
1801
1802
1803 Question: When won't the _Lifting be eliminated?
1804
1805 Answer: When they at the top-level (where it is necessary) or when
1806 inlining would duplicate work (or possibly code depending on
1807 options). However, the _Lifting will still be eliminated if the
1808 strictness analyser deems the lifted binding strict.
1809