compiler/specialise/Specialise.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Specialise]{Stamping out overloading, and (optionally) polymorphism}
   5
   6 \begin{code}
   7 -- The above warning supression flag is a temporary kludge.
   8 -- While working on this module you are encouraged to remove it and fix
   9 -- any warnings in the module. See
  10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  11 -- for details
  12
  13 module Specialise ( specProgram ) where
  14
  15 #include "HsVersions.h"
  16
  17 import Id               ( Id, idName, idType, mkUserLocal, idCoreRules, idUnfolding,
  18                           idInlineActivation, setInlineActivation, setIdUnfolding,
  19                           isLocalId, isDataConWorkId, idArity, setIdArity )
  20 import TcType           ( Type, mkTyVarTy, tcSplitSigmaTy,
  21                           tyVarsOfTypes, tyVarsOfTheta, isClassPred,
  22                           tcCmpType, isUnLiftedType
  23                         )
  24 import CoreSubst        ( Subst, mkEmptySubst, extendTvSubstList, lookupIdSubst,
  25                           substBndr, substBndrs, substTy, substInScope,
  26                           cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs,
  27                           extendIdSubst
  28                         )
  29 import CoreUnfold       ( mkUnfolding )
  30 import Var              ( DictId )
  31 import VarSet
  32 import VarEnv
  33 import CoreSyn
  34 import Rules
  35 import CoreUtils        ( exprIsTrivial, applyTypeToArgs, mkPiTypes )
  36 import CoreFVs          ( exprFreeVars, exprsFreeVars, idFreeVars )
  37 import UniqSupply       ( UniqSupply,
  38                           UniqSM, initUs_,
  39                           MonadUnique(..)
  40                         )
  41 import Name
  42 import MkId             ( voidArgId, realWorldPrimId )
  43 import FiniteMap
  44 import Maybes           ( catMaybes, isJust )
  45 import Bag
  46 import Util
  47 import Outputable
  48 import FastString
  49
  50 \end{code}
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection[notes-Specialise]{Implementation notes [SLPJ, Aug 18 1993]}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 These notes describe how we implement specialisation to eliminate
  59 overloading.
  60
  61 The specialisation pass works on Core
  62 syntax, complete with all the explicit dictionary application,
  63 abstraction and construction as added by the type checker.  The
  64 existing type checker remains largely as it is.
  65
  66 One important thought: the {\em types} passed to an overloaded
  67 function, and the {\em dictionaries} passed are mutually redundant.
  68 If the same function is applied to the same type(s) then it is sure to
  69 be applied to the same dictionary(s)---or rather to the same {\em
  70 values}.  (The arguments might look different but they will evaluate
  71 to the same value.)
  72
  73 Second important thought: we know that we can make progress by
  74 treating dictionary arguments as static and worth specialising on.  So
  75 we can do without binding-time analysis, and instead specialise on
  76 dictionary arguments and no others.
  77
  78 The basic idea
  79 ~~~~~~~~~~~~~~
  80 Suppose we have
  81
  82         let f = <f_rhs>
  83         in <body>
  84
  85 and suppose f is overloaded.
  86
  87 STEP 1: CALL-INSTANCE COLLECTION
  88
  89 We traverse <body>, accumulating all applications of f to types and
  90 dictionaries.
  91
  92 (Might there be partial applications, to just some of its types and
  93 dictionaries?  In principle yes, but in practice the type checker only
  94 builds applications of f to all its types and dictionaries, so partial
  95 applications could only arise as a result of transformation, and even
  96 then I think it's unlikely.  In any case, we simply don't accumulate such
  97 partial applications.)
  98
  99
 100 STEP 2: EQUIVALENCES
 101
 102 So now we have a collection of calls to f:
 103         f t1 t2 d1 d2
 104         f t3 t4 d3 d4
 105         ...
 106 Notice that f may take several type arguments.  To avoid ambiguity, we
 107 say that f is called at type t1/t2 and t3/t4.
 108
 109 We take equivalence classes using equality of the *types* (ignoring
 110 the dictionary args, which as mentioned previously are redundant).
 111
 112 STEP 3: SPECIALISATION
 113
 114 For each equivalence class, choose a representative (f t1 t2 d1 d2),
 115 and create a local instance of f, defined thus:
 116
 117         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 118
 119 f_rhs presumably has some big lambdas and dictionary lambdas, so lots
 120 of simplification will now result.  However we don't actually *do* that
 121 simplification.  Rather, we leave it for the simplifier to do.  If we
 122 *did* do it, though, we'd get more call instances from the specialised
 123 RHS.  We can work out what they are by instantiating the call-instance
 124 set from f's RHS with the types t1, t2.
 125
 126 Add this new id to f's IdInfo, to record that f has a specialised version.
 127
 128 Before doing any of this, check that f's IdInfo doesn't already
 129 tell us about an existing instance of f at the required type/s.
 130 (This might happen if specialisation was applied more than once, or
 131 it might arise from user SPECIALIZE pragmas.)
 132
 133 Recursion
 134 ~~~~~~~~~
 135 Wait a minute!  What if f is recursive?  Then we can't just plug in
 136 its right-hand side, can we?
 137
 138 But it's ok.  The type checker *always* creates non-recursive definitions
 139 for overloaded recursive functions.  For example:
 140
 141         f x = f (x+x)           -- Yes I know its silly
 142
 143 becomes
 144
 145         f a (d::Num a) = let p = +.sel a d
 146                          in
 147                          letrec fl (y::a) = fl (p y y)
 148                          in
 149                          fl
 150
 151 We still have recusion for non-overloaded functions which we
 152 speciailise, but the recursive call should get specialised to the
 153 same recursive version.
 154
 155
 156 Polymorphism 1
 157 ~~~~~~~~~~~~~~
 158
 159 All this is crystal clear when the function is applied to *constant
 160 types*; that is, types which have no type variables inside.  But what if
 161 it is applied to non-constant types?  Suppose we find a call of f at type
 162 t1/t2.  There are two possibilities:
 163
 164 (a) The free type variables of t1, t2 are in scope at the definition point
 165 of f.  In this case there's no problem, we proceed just as before.  A common
 166 example is as follows.  Here's the Haskell:
 167
 168         g y = let f x = x+x
 169               in f y + f y
 170
 171 After typechecking we have
 172
 173         g a (d::Num a) (y::a) = let f b (d'::Num b) (x::b) = +.sel b d' x x
 174                                 in +.sel a d (f a d y) (f a d y)
 175
 176 Notice that the call to f is at type type "a"; a non-constant type.
 177 Both calls to f are at the same type, so we can specialise to give:
 178
 179         g a (d::Num a) (y::a) = let f@a (x::a) = +.sel a d x x
 180                                 in +.sel a d (f@a y) (f@a y)
 181
 182
 183 (b) The other case is when the type variables in the instance types
 184 are *not* in scope at the definition point of f.  The example we are
 185 working with above is a good case.  There are two instances of (+.sel a d),
 186 but "a" is not in scope at the definition of +.sel.  Can we do anything?
 187 Yes, we can "common them up", a sort of limited common sub-expression deal.
 188 This would give:
 189
 190         g a (d::Num a) (y::a) = let +.sel@a = +.sel a d
 191                                     f@a (x::a) = +.sel@a x x
 192                                 in +.sel@a (f@a y) (f@a y)
 193
 194 This can save work, and can't be spotted by the type checker, because
 195 the two instances of +.sel weren't originally at the same type.
 196
 197 Further notes on (b)
 198
 199 * There are quite a few variations here.  For example, the defn of
 200   +.sel could be floated ouside the \y, to attempt to gain laziness.
 201   It certainly mustn't be floated outside the \d because the d has to
 202   be in scope too.
 203
 204 * We don't want to inline f_rhs in this case, because
 205 that will duplicate code.  Just commoning up the call is the point.
 206
 207 * Nothing gets added to +.sel's IdInfo.
 208
 209 * Don't bother unless the equivalence class has more than one item!
 210
 211 Not clear whether this is all worth it.  It is of course OK to
 212 simply discard call-instances when passing a big lambda.
 213
 214 Polymorphism 2 -- Overloading
 215 ~~~~~~~~~~~~~~
 216 Consider a function whose most general type is
 217
 218         f :: forall a b. Ord a => [a] -> b -> b
 219
 220 There is really no point in making a version of g at Int/Int and another
 221 at Int/Bool, because it's only instancing the type variable "a" which
 222 buys us any efficiency. Since g is completely polymorphic in b there
 223 ain't much point in making separate versions of g for the different
 224 b types.
 225
 226 That suggests that we should identify which of g's type variables
 227 are constrained (like "a") and which are unconstrained (like "b").
 228 Then when taking equivalence classes in STEP 2, we ignore the type args
 229 corresponding to unconstrained type variable.  In STEP 3 we make
 230 polymorphic versions.  Thus:
 231
 232         f@t1/ = /\b -> <f_rhs> t1 b d1 d2
 233
 234 We do this.
 235
 236
 237 Dictionary floating
 238 ~~~~~~~~~~~~~~~~~~~
 239 Consider this
 240
 241         f a (d::Num a) = let g = ...
 242                          in
 243                          ...(let d1::Ord a = Num.Ord.sel a d in g a d1)...
 244
 245 Here, g is only called at one type, but the dictionary isn't in scope at the
 246 definition point for g.  Usually the type checker would build a
 247 definition for d1 which enclosed g, but the transformation system
 248 might have moved d1's defn inward.  Solution: float dictionary bindings
 249 outwards along with call instances.
 250
 251 Consider
 252
 253         f x = let g p q = p==q
 254                   h r s = (r+s, g r s)
 255               in
 256               h x x
 257
 258
 259 Before specialisation, leaving out type abstractions we have
 260
 261         f df x = let g :: Eq a => a -> a -> Bool
 262                      g dg p q = == dg p q
 263                      h :: Num a => a -> a -> (a, Bool)
 264                      h dh r s = let deq = eqFromNum dh
 265                                 in (+ dh r s, g deq r s)
 266               in
 267               h df x x
 268
 269 After specialising h we get a specialised version of h, like this:
 270
 271                     h' r s = let deq = eqFromNum df
 272                              in (+ df r s, g deq r s)
 273
 274 But we can't naively make an instance for g from this, because deq is not in scope
 275 at the defn of g.  Instead, we have to float out the (new) defn of deq
 276 to widen its scope.  Notice that this floating can't be done in advance -- it only
 277 shows up when specialisation is done.
 278
 279 User SPECIALIZE pragmas
 280 ~~~~~~~~~~~~~~~~~~~~~~~
 281 Specialisation pragmas can be digested by the type checker, and implemented
 282 by adding extra definitions along with that of f, in the same way as before
 283
 284         f@t1/t2 = <f_rhs> t1 t2 d1 d2
 285
 286 Indeed the pragmas *have* to be dealt with by the type checker, because
 287 only it knows how to build the dictionaries d1 and d2!  For example
 288
 289         g :: Ord a => [a] -> [a]
 290         {-# SPECIALIZE f :: [Tree Int] -> [Tree Int] #-}
 291
 292 Here, the specialised version of g is an application of g's rhs to the
 293 Ord dictionary for (Tree Int), which only the type checker can conjure
 294 up.  There might not even *be* one, if (Tree Int) is not an instance of
 295 Ord!  (All the other specialision has suitable dictionaries to hand
 296 from actual calls.)
 297
 298 Problem.  The type checker doesn't have to hand a convenient <f_rhs>, because
 299 it is buried in a complex (as-yet-un-desugared) binding group.
 300 Maybe we should say
 301
 302         f@t1/t2 = f* t1 t2 d1 d2
 303
 304 where f* is the Id f with an IdInfo which says "inline me regardless!".
 305 Indeed all the specialisation could be done in this way.
 306 That in turn means that the simplifier has to be prepared to inline absolutely
 307 any in-scope let-bound thing.
 308
 309
 310 Again, the pragma should permit polymorphism in unconstrained variables:
 311
 312         h :: Ord a => [a] -> b -> b
 313         {-# SPECIALIZE h :: [Int] -> b -> b #-}
 314
 315 We *insist* that all overloaded type variables are specialised to ground types,
 316 (and hence there can be no context inside a SPECIALIZE pragma).
 317 We *permit* unconstrained type variables to be specialised to
 318         - a ground type
 319         - or left as a polymorphic type variable
 320 but nothing in between.  So
 321
 322         {-# SPECIALIZE h :: [Int] -> [c] -> [c] #-}
 323
 324 is *illegal*.  (It can be handled, but it adds complication, and gains the
 325 programmer nothing.)
 326
 327
 328 SPECIALISING INSTANCE DECLARATIONS
 329 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 330 Consider
 331
 332         instance Foo a => Foo [a] where
 333                 ...
 334         {-# SPECIALIZE instance Foo [Int] #-}
 335
 336 The original instance decl creates a dictionary-function
 337 definition:
 338
 339         dfun.Foo.List :: forall a. Foo a -> Foo [a]
 340
 341 The SPECIALIZE pragma just makes a specialised copy, just as for
 342 ordinary function definitions:
 343
 344         dfun.Foo.List@Int :: Foo [Int]
 345         dfun.Foo.List@Int = dfun.Foo.List Int dFooInt
 346
 347 The information about what instance of the dfun exist gets added to
 348 the dfun's IdInfo in the same way as a user-defined function too.
 349
 350
 351 Automatic instance decl specialisation?
 352 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 353 Can instance decls be specialised automatically?  It's tricky.
 354 We could collect call-instance information for each dfun, but
 355 then when we specialised their bodies we'd get new call-instances
 356 for ordinary functions; and when we specialised their bodies, we might get
 357 new call-instances of the dfuns, and so on.  This all arises because of
 358 the unrestricted mutual recursion between instance decls and value decls.
 359
 360 Still, there's no actual problem; it just means that we may not do all
 361 the specialisation we could theoretically do.
 362
 363 Furthermore, instance decls are usually exported and used non-locally,
 364 so we'll want to compile enough to get those specialisations done.
 365
 366 Lastly, there's no such thing as a local instance decl, so we can
 367 survive solely by spitting out *usage* information, and then reading that
 368 back in as a pragma when next compiling the file.  So for now,
 369 we only specialise instance decls in response to pragmas.
 370
 371
 372 SPITTING OUT USAGE INFORMATION
 373 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 374
 375 To spit out usage information we need to traverse the code collecting
 376 call-instance information for all imported (non-prelude?) functions
 377 and data types. Then we equivalence-class it and spit it out.
 378
 379 This is done at the top-level when all the call instances which escape
 380 must be for imported functions and data types.
 381
 382 *** Not currently done ***
 383
 384
 385 Partial specialisation by pragmas
 386 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 387 What about partial specialisation:
 388
 389         k :: (Ord a, Eq b) => [a] -> b -> b -> [a]
 390         {-# SPECIALIZE k :: Eq b => [Int] -> b -> b -> [a] #-}
 391
 392 or even
 393
 394         {-# SPECIALIZE k :: Eq b => [Int] -> [b] -> [b] -> [a] #-}
 395
 396 Seems quite reasonable.  Similar things could be done with instance decls:
 397
 398         instance (Foo a, Foo b) => Foo (a,b) where
 399                 ...
 400         {-# SPECIALIZE instance Foo a => Foo (a,Int) #-}
 401         {-# SPECIALIZE instance Foo b => Foo (Int,b) #-}
 402
 403 Ho hum.  Things are complex enough without this.  I pass.
 404
 405
 406 Requirements for the simplifer
 407 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 408 The simplifier has to be able to take advantage of the specialisation.
 409
 410 * When the simplifier finds an application of a polymorphic f, it looks in
 411 f's IdInfo in case there is a suitable instance to call instead.  This converts
 412
 413         f t1 t2 d1 d2   ===>   f_t1_t2
 414
 415 Note that the dictionaries get eaten up too!
 416
 417 * Dictionary selection operations on constant dictionaries must be
 418   short-circuited:
 419
 420         +.sel Int d     ===>  +Int
 421
 422 The obvious way to do this is in the same way as other specialised
 423 calls: +.sel has inside it some IdInfo which tells that if it's applied
 424 to the type Int then it should eat a dictionary and transform to +Int.
 425
 426 In short, dictionary selectors need IdInfo inside them for constant
 427 methods.
 428
 429 * Exactly the same applies if a superclass dictionary is being
 430   extracted:
 431
 432         Eq.sel Int d   ===>   dEqInt
 433
 434 * Something similar applies to dictionary construction too.  Suppose
 435 dfun.Eq.List is the function taking a dictionary for (Eq a) to
 436 one for (Eq [a]).  Then we want
 437
 438         dfun.Eq.List Int d      ===> dEq.List_Int
 439
 440 Where does the Eq [Int] dictionary come from?  It is built in
 441 response to a SPECIALIZE pragma on the Eq [a] instance decl.
 442
 443 In short, dfun Ids need IdInfo with a specialisation for each
 444 constant instance of their instance declaration.
 445
 446 All this uses a single mechanism: the SpecEnv inside an Id
 447
 448
 449 What does the specialisation IdInfo look like?
 450 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 451
 452 The SpecEnv of an Id maps a list of types (the template) to an expression
 453
 454         [Type]  |->  Expr
 455
 456 For example, if f has this SpecInfo:
 457
 458         [Int, a]  ->  \d:Ord Int. f' a
 459
 460 it means that we can replace the call
 461
 462         f Int t  ===>  (\d. f' t)
 463
 464 This chucks one dictionary away and proceeds with the
 465 specialised version of f, namely f'.
 466
 467
 468 What can't be done this way?
 469 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 470 There is no way, post-typechecker, to get a dictionary for (say)
 471 Eq a from a dictionary for Eq [a].  So if we find
 472
 473         ==.sel [t] d
 474
 475 we can't transform to
 476
 477         eqList (==.sel t d')
 478
 479 where
 480         eqList :: (a->a->Bool) -> [a] -> [a] -> Bool
 481
 482 Of course, we currently have no way to automatically derive
 483 eqList, nor to connect it to the Eq [a] instance decl, but you
 484 can imagine that it might somehow be possible.  Taking advantage
 485 of this is permanently ruled out.
 486
 487 Still, this is no great hardship, because we intend to eliminate
 488 overloading altogether anyway!
 489
 490 A note about non-tyvar dictionaries
 491 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 492 Some Ids have types like
 493
 494         forall a,b,c. Eq a -> Ord [a] -> tau
 495
 496 This seems curious at first, because we usually only have dictionary
 497 args whose types are of the form (C a) where a is a type variable.
 498 But this doesn't hold for the functions arising from instance decls,
 499 which sometimes get arguements with types of form (C (T a)) for some
 500 type constructor T.
 501
 502 Should we specialise wrt this compound-type dictionary?  We used to say
 503 "no", saying:
 504         "This is a heuristic judgement, as indeed is the fact that we
 505         specialise wrt only dictionaries.  We choose *not* to specialise
 506         wrt compound dictionaries because at the moment the only place
 507         they show up is in instance decls, where they are simply plugged
 508         into a returned dictionary.  So nothing is gained by specialising
 509         wrt them."
 510
 511 But it is simpler and more uniform to specialise wrt these dicts too;
 512 and in future GHC is likely to support full fledged type signatures
 513 like
 514         f :: Eq [(a,b)] => ...
 515
 516
 517 %************************************************************************
 518 %*                                                                      *
 519 \subsubsection{The new specialiser}
 520 %*                                                                      *
 521 %************************************************************************
 522
 523 Our basic game plan is this.  For let(rec) bound function
 524         f :: (C a, D c) => (a,b,c,d) -> Bool
 525
 526 * Find any specialised calls of f, (f ts ds), where
 527   ts are the type arguments t1 .. t4, and
 528   ds are the dictionary arguments d1 .. d2.
 529
 530 * Add a new definition for f1 (say):
 531
 532         f1 = /\ b d -> (..body of f..) t1 b t3 d d1 d2
 533
 534   Note that we abstract over the unconstrained type arguments.
 535
 536 * Add the mapping
 537
 538         [t1,b,t3,d]  |->  \d1 d2 -> f1 b d
 539
 540   to the specialisations of f.  This will be used by the
 541   simplifier to replace calls
 542                 (f t1 t2 t3 t4) da db
 543   by
 544                 (\d1 d1 -> f1 t2 t4) da db
 545
 546   All the stuff about how many dictionaries to discard, and what types
 547   to apply the specialised function to, are handled by the fact that the
 548   SpecEnv contains a template for the result of the specialisation.
 549
 550 We don't build *partial* specialisations for f.  For example:
 551
 552   f :: Eq a => a -> a -> Bool
 553   {-# SPECIALISE f :: (Eq b, Eq c) => (b,c) -> (b,c) -> Bool #-}
 554
 555 Here, little is gained by making a specialised copy of f.
 556 There's a distinct danger that the specialised version would
 557 first build a dictionary for (Eq b, Eq c), and then select the (==)
 558 method from it!  Even if it didn't, not a great deal is saved.
 559
 560 We do, however, generate polymorphic, but not overloaded, specialisations:
 561
 562   f :: Eq a => [a] -> b -> b -> b
 563   {#- SPECIALISE f :: [Int] -> b -> b -> b #-}
 564
 565 Hence, the invariant is this:
 566
 567         *** no specialised version is overloaded ***
 568
 569
 570 %************************************************************************
 571 %*                                                                      *
 572 \subsubsection{The exported function}
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 \begin{code}
 577 specProgram :: UniqSupply -> [CoreBind] -> [CoreBind]
 578 specProgram us binds = initSM us (do (binds', uds') <- go binds
 579                                      return (dumpAllDictBinds uds' binds'))
 580   where
 581         -- We need to start with a Subst that knows all the things
 582         -- that are in scope, so that the substitution engine doesn't
 583         -- accidentally re-use a unique that's already in use
 584         -- Easiest thing is to do it all at once, as if all the top-level
 585         -- decls were mutually recursive
 586     top_subst       = mkEmptySubst (mkInScopeSet (mkVarSet (bindersOfBinds binds)))
 587
 588     go []           = return ([], emptyUDs)
 589     go (bind:binds) = do (binds', uds) <- go binds
 590                          (bind', uds') <- specBind top_subst bind uds
 591                          return (bind' ++ binds', uds')
 592 \end{code}
 593
 594 %************************************************************************
 595 %*                                                                      *
 596 \subsubsection{@specExpr@: the main function}
 597 %*                                                                      *
 598 %************************************************************************
 599
 600 \begin{code}
 601 specVar :: Subst -> Id -> CoreExpr
 602 specVar subst v = lookupIdSubst subst v
 603
 604 specExpr :: Subst -> CoreExpr -> SpecM (CoreExpr, UsageDetails)
 605 -- We carry a substitution down:
 606 --      a) we must clone any binding that might float outwards,
 607 --         to avoid name clashes
 608 --      b) we carry a type substitution to use when analysing
 609 --         the RHS of specialised bindings (no type-let!)
 610
 611 ---------------- First the easy cases --------------------
 612 specExpr subst (Type ty) = return (Type (substTy subst ty), emptyUDs)
 613 specExpr subst (Var v)   = return (specVar subst v,         emptyUDs)
 614 specExpr _     (Lit lit) = return (Lit lit,                 emptyUDs)
 615 specExpr subst (Cast e co) = do
 616     (e', uds) <- specExpr subst e
 617     return ((Cast e' (substTy subst co)), uds)
 618 specExpr subst (Note note body) = do
 619     (body', uds) <- specExpr subst body
 620     return (Note (specNote subst note) body', uds)
 621
 622
 623 ---------------- Applications might generate a call instance --------------------
 624 specExpr subst expr@(App {})
 625   = go expr []
 626   where
 627     go (App fun arg) args = do (arg', uds_arg) <- specExpr subst arg
 628                                (fun', uds_app) <- go fun (arg':args)
 629                                return (App fun' arg', uds_arg `plusUDs` uds_app)
 630
 631     go (Var f)       args = case specVar subst f of
 632                                 Var f' -> return (Var f', mkCallUDs f' args)
 633                                 e'     -> return (e', emptyUDs) -- I don't expect this!
 634     go other         _    = specExpr subst other
 635
 636 ---------------- Lambda/case require dumping of usage details --------------------
 637 specExpr subst e@(Lam _ _) = do
 638     (body', uds) <- specExpr subst' body
 639     let (filtered_uds, body'') = dumpUDs bndrs' uds body'
 640     return (mkLams bndrs' body'', filtered_uds)
 641   where
 642     (bndrs, body) = collectBinders e
 643     (subst', bndrs') = substBndrs subst bndrs
 644         -- More efficient to collect a group of binders together all at once
 645         -- and we don't want to split a lambda group with dumped bindings
 646
 647 specExpr subst (Case scrut case_bndr ty alts) = do
 648     (scrut', uds_scrut) <- specExpr subst scrut
 649     (alts', uds_alts) <- mapAndCombineSM spec_alt alts
 650     return (Case scrut' case_bndr' (substTy subst ty) alts', uds_scrut `plusUDs` uds_alts)
 651   where
 652     (subst_alt, case_bndr') = substBndr subst case_bndr
 653         -- No need to clone case binder; it can't float like a let(rec)
 654
 655     spec_alt (con, args, rhs) = do
 656           (rhs', uds) <- specExpr subst_rhs rhs
 657           let (uds', rhs'') = dumpUDs args uds rhs'
 658           return ((con, args', rhs''), uds')
 659         where
 660           (subst_rhs, args') = substBndrs subst_alt args
 661
 662 ---------------- Finally, let is the interesting case --------------------
 663 specExpr subst (Let bind body) = do
 664         -- Clone binders
 665     (rhs_subst, body_subst, bind') <- cloneBindSM subst bind
 666
 667         -- Deal with the body
 668     (body', body_uds) <- specExpr body_subst body
 669
 670         -- Deal with the bindings
 671     (binds', uds) <- specBind rhs_subst bind' body_uds
 672
 673         -- All done
 674     return (foldr Let body' binds', uds)
 675
 676 -- Must apply the type substitution to coerceions
 677 specNote :: Subst -> Note -> Note
 678 specNote _ note = note
 679 \end{code}
 680
 681 %************************************************************************
 682 %*                                                                      *
 683 \subsubsection{Dealing with a binding}
 684 %*                                                                      *
 685 %************************************************************************
 686
 687 \begin{code}
 688 specBind :: Subst                       -- Use this for RHSs
 689          -> CoreBind
 690          -> UsageDetails                -- Info on how the scope of the binding
 691          -> SpecM ([CoreBind],          -- New bindings
 692                    UsageDetails)        -- And info to pass upstream
 693
 694 specBind rhs_subst bind body_uds
 695   = do  { (bind', bind_uds) <- specBindItself rhs_subst bind (calls body_uds)
 696         ; return (finishSpecBind bind' bind_uds body_uds) }
 697
 698 finishSpecBind :: CoreBind -> UsageDetails -> UsageDetails -> ([CoreBind], UsageDetails)
 699 finishSpecBind bind
 700         (MkUD { dict_binds = rhs_dbs,  calls = rhs_calls,  ud_fvs = rhs_fvs })
 701         (MkUD { dict_binds = body_dbs, calls = body_calls, ud_fvs = body_fvs })
 702   | not (mkVarSet bndrs `intersectsVarSet` all_fvs)
 703                 -- Common case 1: the bound variables are not
 704                 --                mentioned in the dictionary bindings
 705   = ([bind], MkUD { dict_binds = body_dbs `unionBags` rhs_dbs
 706                         -- It's important that the `unionBags` is this way round,
 707                         -- because body_uds may bind dictionaries that are
 708                         -- used in the calls passed to specDefn.  So the
 709                         -- dictionary bindings in rhs_uds may mention
 710                         -- dictionaries bound in body_uds.
 711                   , calls  = all_calls
 712                   , ud_fvs = all_fvs })
 713
 714   | case bind of { NonRec {} -> True; Rec {} -> False }
 715                 -- Common case 2: no specialisation happened, and binding
 716                 --                is non-recursive.  But the binding may be
 717                 --                mentioned in body_dbs, so we should put it first
 718   = ([], MkUD { dict_binds = rhs_dbs `unionBags` ((bind, b_fvs) `consBag` body_dbs)
 719               , calls      = all_calls
 720               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 721
 722   | otherwise   -- General case: make a huge Rec (sigh)
 723   = ([], MkUD { dict_binds = unitBag (Rec all_db_prs, all_db_fvs)
 724               , calls      = all_calls
 725               , ud_fvs     = all_fvs `unionVarSet` b_fvs })
 726   where
 727     all_fvs = rhs_fvs `unionVarSet` body_fvs
 728     all_calls = zapCalls bndrs (rhs_calls `unionCalls` body_calls)
 729
 730     bndrs   = bindersOf bind
 731     b_fvs   = bind_fvs bind
 732
 733     (all_db_prs, all_db_fvs) = add (bind, b_fvs) $
 734                                foldrBag add ([], emptyVarSet) $
 735                                rhs_dbs `unionBags` body_dbs
 736     add (NonRec b r, b_fvs) (prs, fvs) = ((b,r)  : prs, b_fvs `unionVarSet` fvs)
 737     add (Rec b_prs,  b_fvs) (prs, fvs) = (b_prs ++ prs, b_fvs `unionVarSet` fvs)
 738
 739 ---------------------------
 740 specBindItself :: Subst -> CoreBind -> CallDetails -> SpecM (CoreBind, UsageDetails)
 741
 742 -- specBindItself deals with the RHS, specialising it according
 743 -- to the calls found in the body (if any)
 744 specBindItself rhs_subst (NonRec fn rhs) call_info
 745   = do { (rhs', rhs_uds) <- specExpr rhs_subst rhs           -- Do RHS of original fn
 746        ; (fn', spec_defns, spec_uds) <- specDefn rhs_subst call_info fn rhs
 747        ; if null spec_defns then
 748             return (NonRec fn rhs', rhs_uds)
 749          else
 750             return (Rec ((fn',rhs') : spec_defns), rhs_uds `plusUDs` spec_uds) }
 751                 -- bndr' mentions the spec_defns in its SpecEnv
 752                 -- Not sure why we couln't just put the spec_defns first
 753
 754 specBindItself rhs_subst (Rec pairs) call_info
 755        -- Note [Specialising a recursive group]
 756   = do { let (bndrs,rhss) = unzip pairs
 757        ; (rhss', rhs_uds) <- mapAndCombineSM (specExpr rhs_subst) rhss
 758        ; let all_calls = call_info `unionCalls` calls rhs_uds
 759        ; (bndrs1, spec_defns1, spec_uds1) <- specDefns rhs_subst all_calls pairs
 760
 761        ; if null spec_defns1 then   -- Common case: no specialisation
 762             return (Rec (bndrs `zip` rhss'), rhs_uds)
 763          else do                     -- Specialisation occurred; do it again
 764        { (bndrs2, spec_defns2, spec_uds2) <-
 765                   -- pprTrace "specB" (ppr bndrs $$ ppr rhs_uds) $
 766                   specDefns rhs_subst (calls spec_uds1) (bndrs1 `zip` rhss)
 767
 768        ; let all_defns = spec_defns1 ++ spec_defns2 ++ zip bndrs2 rhss'
 769
 770        ; return (Rec all_defns, rhs_uds `plusUDs` spec_uds1 `plusUDs` spec_uds2) } }
 771
 772
 773 ---------------------------
 774 specDefns :: Subst
 775          -> CallDetails                 -- Info on how it is used in its scope
 776          -> [(Id,CoreExpr)]             -- The things being bound and their un-processed RHS
 777          -> SpecM ([Id],                -- Original Ids with RULES added
 778                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 779                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
 780
 781 -- Specialise a list of bindings (the contents of a Rec), but flowing usages
 782 -- upwards binding by binding.  Example: { f = ...g ...; g = ...f .... }
 783 -- Then if the input CallDetails has a specialised call for 'g', whose specialisation
 784 -- in turn generates a specialised call for 'f', we catch that in this one sweep.
 785 -- But not vice versa (it's a fixpoint problem).
 786
 787 specDefns _subst _call_info []
 788   = return ([], [], emptyUDs)
 789 specDefns subst call_info ((bndr,rhs):pairs)
 790   = do { (bndrs', spec_defns, spec_uds) <- specDefns subst call_info pairs
 791        ; let all_calls = call_info `unionCalls` calls spec_uds
 792        ; (bndr', spec_defns1, spec_uds1) <- specDefn subst all_calls bndr rhs
 793        ; return (bndr' : bndrs',
 794                  spec_defns1 ++ spec_defns,
 795                  spec_uds1 `plusUDs` spec_uds) }
 796
 797 ---------------------------
 798 specDefn :: Subst
 799          -> CallDetails                 -- Info on how it is used in its scope
 800          -> Id -> CoreExpr              -- The thing being bound and its un-processed RHS
 801          -> SpecM (Id,                  -- Original Id with added RULES
 802                    [(Id,CoreExpr)],     -- Extra, specialised bindings
 803                    UsageDetails)        -- Stuff to fling upwards from the specialised versions
 804
 805 specDefn subst calls fn rhs
 806         -- The first case is the interesting one
 807   |  rhs_tyvars `lengthIs`     n_tyvars -- Rhs of fn's defn has right number of big lambdas
 808   && rhs_ids    `lengthAtLeast` n_dicts -- and enough dict args
 809   && notNull calls_for_me               -- And there are some calls to specialise
 810
 811 --   && not (certainlyWillInline (idUnfolding fn))      -- And it's not small
 812 --      See Note [Inline specialisation] for why we do not
 813 --      switch off specialisation for inline functions
 814
 815   = do {       -- Make a specialised version for each call in calls_for_me
 816          stuff <- mapM spec_call calls_for_me
 817        ; let (spec_defns, spec_uds, spec_rules) = unzip3 (catMaybes stuff)
 818              fn' = addIdSpecialisations fn spec_rules
 819        ; return (fn', spec_defns, plusUDList spec_uds) }
 820
 821   | otherwise   -- No calls or RHS doesn't fit our preconceptions
 822   = WARN( notNull calls_for_me, ptext (sLit "Missed specialisation opportunity for") <+> ppr fn )
 823           -- Note [Specialisation shape]
 824     return (fn, [], emptyUDs)
 825
 826   where
 827     fn_type            = idType fn
 828     fn_arity           = idArity fn
 829     (tyvars, theta, _) = tcSplitSigmaTy fn_type
 830     n_tyvars           = length tyvars
 831     n_dicts            = length theta
 832     inline_act         = idInlineActivation fn
 833
 834         -- It's important that we "see past" any INLINE pragma
 835         -- else we'll fail to specialise an INLINE thing
 836     (inline_rhs, rhs_inside) = dropInline rhs
 837     (rhs_tyvars, rhs_ids, rhs_body) = collectTyAndValBinders rhs_inside
 838
 839     rhs_dict_ids = take n_dicts rhs_ids
 840     body         = mkLams (drop n_dicts rhs_ids) rhs_body
 841                 -- Glue back on the non-dict lambdas
 842
 843     calls_for_me = case lookupFM calls fn of
 844                         Nothing -> []
 845                         Just cs -> fmToList cs
 846
 847     already_covered :: [CoreExpr] -> Bool
 848     already_covered args          -- Note [Specialisations already covered]
 849        = isJust (lookupRule (const True) (substInScope subst)
 850                             fn args (idCoreRules fn))
 851
 852     mk_ty_args :: [Maybe Type] -> [CoreExpr]
 853     mk_ty_args call_ts = zipWithEqual "spec_call" mk_ty_arg rhs_tyvars call_ts
 854                where
 855                   mk_ty_arg rhs_tyvar Nothing   = Type (mkTyVarTy rhs_tyvar)
 856                   mk_ty_arg _         (Just ty) = Type ty
 857
 858     ----------------------------------------------------------
 859         -- Specialise to one particular call pattern
 860     spec_call :: (CallKey, ([DictExpr], VarSet))  -- Call instance
 861               -> SpecM (Maybe ((Id,CoreExpr),     -- Specialised definition
 862                                UsageDetails,      -- Usage details from specialised body
 863                                CoreRule))         -- Info for the Id's SpecEnv
 864     spec_call (CallKey call_ts, (call_ds, _))
 865       = ASSERT( call_ts `lengthIs` n_tyvars  && call_ds `lengthIs` n_dicts )
 866
 867         -- Suppose f's defn is  f = /\ a b c -> \ d1 d2 -> rhs
 868         -- Supppose the call is for f [Just t1, Nothing, Just t3] [dx1, dx2]
 869
 870         -- Construct the new binding
 871         --      f1 = SUBST[a->t1,c->t3, d1->d1', d2->d2'] (/\ b -> rhs)
 872         -- PLUS the usage-details
 873         --      { d1' = dx1; d2' = dx2 }
 874         -- where d1', d2' are cloned versions of d1,d2, with the type substitution
 875         -- applied.  These auxiliary bindings just avoid duplication of dx1, dx2
 876         --
 877         -- Note that the substitution is applied to the whole thing.
 878         -- This is convenient, but just slightly fragile.  Notably:
 879         --      * There had better be no name clashes in a/b/c
 880         do { let
 881                 -- poly_tyvars = [b] in the example above
 882                 -- spec_tyvars = [a,c]
 883                 -- ty_args     = [t1,b,t3]
 884                 poly_tyvars   = [tv | (tv, Nothing) <- rhs_tyvars `zip` call_ts]
 885                 spec_tv_binds = [(tv,ty) | (tv, Just ty) <- rhs_tyvars `zip` call_ts]
 886                 spec_ty_args  = map snd spec_tv_binds
 887                 ty_args       = mk_ty_args call_ts
 888                 rhs_subst     = extendTvSubstList subst spec_tv_binds
 889
 890            ; (rhs_subst1, inst_dict_ids) <- cloneDictBndrs rhs_subst rhs_dict_ids
 891                           -- Clone rhs_dicts, including instantiating their types
 892
 893            ; let (rhs_subst2, dx_binds) = bindAuxiliaryDicts rhs_subst1 $
 894                                           (my_zipEqual rhs_dict_ids inst_dict_ids call_ds)
 895                  inst_args = ty_args ++ map Var inst_dict_ids
 896
 897            ; if already_covered inst_args then
 898                 return Nothing
 899              else do
 900            {    -- Figure out the type of the specialised function
 901              let body_ty = applyTypeToArgs rhs fn_type inst_args
 902                  (lam_args, app_args)           -- Add a dummy argument if body_ty is unlifted
 903                    | isUnLiftedType body_ty     -- C.f. WwLib.mkWorkerArgs
 904                    = (poly_tyvars ++ [voidArgId], poly_tyvars ++ [realWorldPrimId])
 905                    | otherwise = (poly_tyvars, poly_tyvars)
 906                  spec_id_ty = mkPiTypes lam_args body_ty
 907
 908            ; spec_f <- newSpecIdSM fn spec_id_ty
 909            ; let spec_f_w_arity = setIdArity spec_f (max 0 (fn_arity - n_dicts))
 910                 -- Adding arity information just propagates it a bit faster
 911                 -- See Note [Arity decrease] in Simplify
 912
 913            ; (spec_rhs, rhs_uds) <- specExpr rhs_subst2 (mkLams lam_args body)
 914            ; let
 915                 -- The rule to put in the function's specialisation is:
 916                 --      forall b, d1',d2'.  f t1 b t3 d1' d2' = f1 b
 917                 rule_name = mkFastString ("SPEC " ++ showSDoc (ppr fn <+> ppr spec_ty_args))
 918                 spec_env_rule = mkLocalRule
 919                                   rule_name
 920                                   inline_act    -- Note [Auto-specialisation and RULES]
 921                                   (idName fn)
 922                                   (poly_tyvars ++ inst_dict_ids)
 923                                   inst_args
 924                                   (mkVarApps (Var spec_f_w_arity) app_args)
 925
 926                 -- Add the { d1' = dx1; d2' = dx2 } usage stuff
 927                 final_uds = foldr addDictBind rhs_uds dx_binds
 928
 929                 spec_pr | inline_rhs = (spec_f_w_arity `setInlineActivation` inline_act, Note InlineMe spec_rhs)
 930                         | otherwise  = (spec_f_w_arity,                                  spec_rhs)
 931
 932            ; return (Just (spec_pr, final_uds, spec_env_rule)) } }
 933       where
 934         my_zipEqual xs ys zs
 935          | debugIsOn && not (equalLength xs ys && equalLength ys zs)
 936              = pprPanic "my_zipEqual" (vcat [ ppr xs, ppr ys
 937                                             , ppr fn <+> ppr call_ts
 938                                             , ppr (idType fn), ppr theta
 939                                             , ppr n_dicts, ppr rhs_dict_ids
 940                                             , ppr rhs])
 941          | otherwise = zip3 xs ys zs
 942
 943 bindAuxiliaryDicts
 944         :: Subst
 945         -> [(DictId,DictId,CoreExpr)]   -- (orig_dict, inst_dict, dx)
 946         -> (Subst,                      -- Substitute for all orig_dicts
 947             [(DictId, CoreExpr)])       -- Auxiliary bindings
 948 -- Bind any dictionary arguments to fresh names, to preserve sharing
 949 -- Substitution already substitutes orig_dict -> inst_dict
 950 bindAuxiliaryDicts subst triples = go subst [] triples
 951   where
 952     go subst binds []    = (subst, binds)
 953     go subst binds ((d, dx_id, dx) : pairs)
 954       | exprIsTrivial dx = go (extendIdSubst subst d dx) binds pairs
 955              -- No auxiliary binding necessary
 956       | otherwise        = go subst_w_unf ((dx_id,dx) : binds) pairs
 957       where
 958         dx_id1 = dx_id `setIdUnfolding` mkUnfolding False dx
 959         subst_w_unf = extendIdSubst subst d (Var dx_id1)
 960              -- Important!  We're going to substitute dx_id1 for d
 961              -- and we want it to look "interesting", else we won't gather *any*
 962              -- consequential calls. E.g.
 963              --     f d = ...g d....
 964              -- If we specialise f for a call (f (dfun dNumInt)), we'll get
 965              -- a consequent call (g d') with an auxiliary definition
 966              --     d' = df dNumInt
 967              -- We want that consequent call to look interesting
 968 \end{code}
 969
 970 Note [Specialising a recursive group]
 971 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 972 Consider
 973     let rec { f x = ...g x'...
 974             ; g y = ...f y'.... }
 975     in f 'a'
 976 Here we specialise 'f' at Char; but that is very likely to lead to
 977 a specialisation of 'g' at Char.  We must do the latter, else the
 978 whole point of specialisation is lost.
 979
 980 But we do not want to keep iterating to a fixpoint, because in the
 981 presence of polymorphic recursion we might generate an infinite number
 982 of specialisations.
 983
 984 So we use the following heuristic:
 985   * Arrange the rec block in dependency order, so far as possible
 986     (the occurrence analyser already does this)
 987
 988   * Specialise it much like a sequence of lets
 989
 990   * Then go through the block a second time, feeding call-info from
 991     the RHSs back in the bottom, as it were
 992
 993 In effect, the ordering maxmimises the effectiveness of each sweep,
 994 and we do just two sweeps.   This should catch almost every case of
 995 monomorphic recursion -- the exception could be a very knotted-up
 996 recursion with multiple cycles tied up together.
 997
 998 This plan is implemented in the Rec case of specBindItself.
 999
1000 Note [Specialisations already covered]
1001 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1002 We obviously don't want to generate two specialisations for the same
1003 argument pattern.  There are two wrinkles
1004
1005 1. We do the already-covered test in specDefn, not when we generate
1006 the CallInfo in mkCallUDs.  We used to test in the latter place, but
1007 we now iterate the specialiser somewhat, and the Id at the call site
1008 might therefore not have all the RULES that we can see in specDefn
1009
1010 2. What about two specialisations where the second is an *instance*
1011 of the first?  If the more specific one shows up first, we'll generate
1012 specialisations for both.  If the *less* specific one shows up first,
1013 we *don't* currently generate a specialisation for the more specific
1014 one.  (See the call to lookupRule in already_covered.)  Reasons:
1015   (a) lookupRule doesn't say which matches are exact (bad reason)
1016   (b) if the earlier specialisation is user-provided, it's
1017       far from clear that we should auto-specialise further
1018
1019 Note [Auto-specialisation and RULES]
1020 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1021 Consider:
1022    g :: Num a => a -> a
1023    g = ...
1024
1025    f :: (Int -> Int) -> Int
1026    f w = ...
1027    {-# RULE f g = 0 #-}
1028
1029 Suppose that auto-specialisation makes a specialised version of
1030 g::Int->Int That version won't appear in the LHS of the RULE for f.
1031 So if the specialisation rule fires too early, the rule for f may
1032 never fire.
1033
1034 It might be possible to add new rules, to "complete" the rewrite system.
1035 Thus when adding
1036         RULE forall d. g Int d = g_spec
1037 also add
1038         RULE f g_spec = 0
1039
1040 But that's a bit complicated.  For now we ask the programmer's help,
1041 by *copying the INLINE activation pragma* to the auto-specialised rule.
1042 So if g says {-# NOINLINE[2] g #-}, then the auto-spec rule will also
1043 not be active until phase 2.
1044
1045
1046 Note [Specialisation shape]
1047 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1048 We only specialise a function if it has visible top-level lambdas
1049 corresponding to its overloading.  E.g. if
1050         f :: forall a. Eq a => ....
1051 then its body must look like
1052         f = /\a. \d. ...
1053
1054 Reason: when specialising the body for a call (f ty dexp), we want to
1055 substitute dexp for d, and pick up specialised calls in the body of f.
1056
1057 This doesn't always work.  One example I came across was this:
1058         newtype Gen a = MkGen{ unGen :: Int -> a }
1059
1060         choose :: Eq a => a -> Gen a
1061         choose n = MkGen (\r -> n)
1062
1063         oneof = choose (1::Int)
1064
1065 It's a silly exapmle, but we get
1066         choose = /\a. g `cast` co
1067 where choose doesn't have any dict arguments.  Thus far I have not
1068 tried to fix this (wait till there's a real example).
1069
1070
1071 Note [Inline specialisations]
1072 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1073 We transfer to the specialised function any INLINE stuff from the
1074 original.  This means (a) the Activation in the IdInfo, and (b) any
1075 InlineMe on the RHS.  We do not, however, transfer the RuleMatchInfo
1076 since we do not expect the specialisation to occur in rewrite rules.
1077
1078 This is a change (Jun06).  Previously the idea is that the point of
1079 inlining was precisely to specialise the function at its call site,
1080 and that's not so important for the specialised copies.  But
1081 *pragma-directed* specialisation now takes place in the
1082 typechecker/desugarer, with manually specified INLINEs.  The
1083 specialiation here is automatic.  It'd be very odd if a function
1084 marked INLINE was specialised (because of some local use), and then
1085 forever after (including importing modules) the specialised version
1086 wasn't INLINEd.  After all, the programmer said INLINE!
1087
1088 You might wonder why we don't just not specialise INLINE functions.
1089 It's because even INLINE functions are sometimes not inlined, when
1090 they aren't applied to interesting arguments.  But perhaps the type
1091 arguments alone are enough to specialise (even though the args are too
1092 boring to trigger inlining), and it's certainly better to call the
1093 specialised version.
1094
1095 A case in point is dictionary functions, which are current marked
1096 INLINE, but which are worth specialising.
1097
1098 \begin{code}
1099 dropInline :: CoreExpr -> (Bool, CoreExpr)
1100 dropInline (Note InlineMe rhs) = (True,  rhs)
1101 dropInline rhs                 = (False, rhs)
1102 \end{code}
1103
1104 %************************************************************************
1105 %*                                                                      *
1106 \subsubsection{UsageDetails and suchlike}
1107 %*                                                                      *
1108 %************************************************************************
1109
1110 \begin{code}
1111 data UsageDetails
1112   = MkUD {
1113         dict_binds :: !(Bag DictBind),
1114                         -- Floated dictionary bindings
1115                         -- The order is important;
1116                         -- in ds1 `union` ds2, bindings in ds2 can depend on those in ds1
1117                         -- (Remember, Bags preserve order in GHC.)
1118
1119         calls     :: !CallDetails,
1120
1121         ud_fvs :: !VarSet       -- A superset of the variables mentioned in
1122                                 -- either dict_binds or calls
1123     }
1124
1125 instance Outputable UsageDetails where
1126   ppr (MkUD { dict_binds = dbs, calls = calls, ud_fvs = fvs })
1127         = ptext (sLit "MkUD") <+> braces (sep (punctuate comma
1128                 [ptext (sLit "binds") <+> equals <+> ppr dbs,
1129                  ptext (sLit "calls") <+> equals <+> ppr calls,
1130                  ptext (sLit "fvs")   <+> equals <+> ppr fvs]))
1131
1132 type DictBind = (CoreBind, VarSet)
1133         -- The set is the free vars of the binding
1134         -- both tyvars and dicts
1135
1136 type DictExpr = CoreExpr
1137
1138 emptyUDs :: UsageDetails
1139 emptyUDs = MkUD { dict_binds = emptyBag, calls = emptyFM, ud_fvs = emptyVarSet }
1140
1141 ------------------------------------------------------------
1142 type CallDetails  = FiniteMap Id CallInfo
1143 newtype CallKey   = CallKey [Maybe Type]                        -- Nothing => unconstrained type argument
1144
1145 -- CallInfo uses a FiniteMap, thereby ensuring that
1146 -- we record only one call instance for any key
1147 --
1148 -- The list of types and dictionaries is guaranteed to
1149 -- match the type of f
1150 type CallInfo = FiniteMap CallKey ([DictExpr], VarSet)
1151                         -- Range is dict args and the vars of the whole
1152                         -- call (including tyvars)
1153                         -- [*not* include the main id itself, of course]
1154
1155 instance Outputable CallKey where
1156   ppr (CallKey ts) = ppr ts
1157
1158 -- Type isn't an instance of Ord, so that we can control which
1159 -- instance we use.  That's tiresome here.  Oh well
1160 instance Eq CallKey where
1161   k1 == k2 = case k1 `compare` k2 of { EQ -> True; _ -> False }
1162
1163 instance Ord CallKey where
1164   compare (CallKey k1) (CallKey k2) = cmpList cmp k1 k2
1165                 where
1166                   cmp Nothing   Nothing   = EQ
1167                   cmp Nothing   (Just _)  = LT
1168                   cmp (Just _)  Nothing   = GT
1169                   cmp (Just t1) (Just t2) = tcCmpType t1 t2
1170
1171 unionCalls :: CallDetails -> CallDetails -> CallDetails
1172 unionCalls c1 c2 = plusFM_C plusFM c1 c2
1173
1174 singleCall :: Id -> [Maybe Type] -> [DictExpr] -> UsageDetails
1175 singleCall id tys dicts
1176   = MkUD {dict_binds = emptyBag,
1177           calls      = unitFM id (unitFM (CallKey tys) (dicts, call_fvs)),
1178           ud_fvs     = call_fvs }
1179   where
1180     call_fvs = exprsFreeVars dicts `unionVarSet` tys_fvs
1181     tys_fvs  = tyVarsOfTypes (catMaybes tys)
1182         -- The type args (tys) are guaranteed to be part of the dictionary
1183         -- types, because they are just the constrained types,
1184         -- and the dictionary is therefore sure to be bound
1185         -- inside the binding for any type variables free in the type;
1186         -- hence it's safe to neglect tyvars free in tys when making
1187         -- the free-var set for this call
1188         -- BUT I don't trust this reasoning; play safe and include tys_fvs
1189         --
1190         -- We don't include the 'id' itself.
1191
1192 mkCallUDs :: Id -> [CoreExpr] -> UsageDetails
1193 mkCallUDs f args
1194   | not (isLocalId f)   -- Imported from elsewhere
1195   || null theta         -- Not overloaded
1196   || not (all isClassPred theta)
1197         -- Only specialise if all overloading is on class params.
1198         -- In ptic, with implicit params, the type args
1199         --  *don't* say what the value of the implicit param is!
1200   || not (spec_tys `lengthIs` n_tyvars)
1201   || not ( dicts   `lengthIs` n_dicts)
1202   || not (any interestingDict dicts)    -- Note [Interesting dictionary arguments]
1203   -- See also Note [Specialisations already covered]
1204   = -- pprTrace "mkCallUDs: discarding" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingDict dicts)])
1205     emptyUDs    -- Not overloaded, or no specialisation wanted
1206
1207   | otherwise
1208   = -- pprTrace "mkCallUDs: keeping" (vcat [ppr f, ppr args, ppr n_tyvars, ppr n_dicts, ppr (map interestingDict dicts)])
1209     singleCall f spec_tys dicts
1210   where
1211     (tyvars, theta, _) = tcSplitSigmaTy (idType f)
1212     constrained_tyvars = tyVarsOfTheta theta
1213     n_tyvars           = length tyvars
1214     n_dicts            = length theta
1215
1216     spec_tys = [mk_spec_ty tv ty | (tv, Type ty) <- tyvars `zip` args]
1217     dicts    = [dict_expr | (_, dict_expr) <- theta `zip` (drop n_tyvars args)]
1218
1219     mk_spec_ty tyvar ty
1220         | tyvar `elemVarSet` constrained_tyvars = Just ty
1221         | otherwise                             = Nothing
1222 \end{code}
1223
1224 Note [Interesting dictionary arguments]
1225 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1226 Consider this
1227          \a.\d:Eq a.  let f = ... in ...(f d)...
1228 There really is not much point in specialising f wrt the dictionary d,
1229 because the code for the specialised f is not improved at all, because
1230 d is lambda-bound.  We simply get junk specialisations.
1231
1232 What is "interesting"?  Just that it has *some* structure.
1233
1234 \begin{code}
1235 interestingDict :: CoreExpr -> Bool
1236 -- A dictionary argument is interesting if it has *some* structure
1237 interestingDict (Var v) =  hasSomeUnfolding (idUnfolding v)
1238                         || isDataConWorkId v
1239 interestingDict (Type _)          = False
1240 interestingDict (App fn (Type _)) = interestingDict fn
1241 interestingDict (Note _ a)        = interestingDict a
1242 interestingDict (Cast e _)        = interestingDict e
1243 interestingDict _                 = True
1244 \end{code}
1245
1246 \begin{code}
1247 plusUDs :: UsageDetails -> UsageDetails -> UsageDetails
1248 plusUDs (MkUD {dict_binds = db1, calls = calls1, ud_fvs = fvs1})
1249         (MkUD {dict_binds = db2, calls = calls2, ud_fvs = fvs2})
1250   = MkUD {dict_binds = d, calls = c, ud_fvs = fvs1 `unionVarSet` fvs2}
1251   where
1252     d = db1    `unionBags`   db2
1253     c = calls1 `unionCalls`  calls2
1254
1255 plusUDList :: [UsageDetails] -> UsageDetails
1256 plusUDList = foldr plusUDs emptyUDs
1257
1258 -- zapCalls deletes calls to ids from uds
1259 zapCalls :: [Id] -> CallDetails -> CallDetails
1260 zapCalls ids calls = delListFromFM calls ids
1261
1262 mkDB :: CoreBind -> DictBind
1263 mkDB bind = (bind, bind_fvs bind)
1264
1265 bind_fvs :: CoreBind -> VarSet
1266 bind_fvs (NonRec bndr rhs) = pair_fvs (bndr,rhs)
1267 bind_fvs (Rec prs)         = foldl delVarSet rhs_fvs bndrs
1268                            where
1269                              bndrs = map fst prs
1270                              rhs_fvs = unionVarSets (map pair_fvs prs)
1271
1272 pair_fvs :: (Id, CoreExpr) -> VarSet
1273 pair_fvs (bndr, rhs) = exprFreeVars rhs `unionVarSet` idFreeVars bndr
1274         -- Don't forget variables mentioned in the
1275         -- rules of the bndr.  C.f. OccAnal.addRuleUsage
1276         -- Also tyvars mentioned in its type; they may not appear in the RHS
1277         --      type T a = Int
1278         --      x :: T a = 3
1279
1280 addDictBind :: (Id,CoreExpr) -> UsageDetails -> UsageDetails
1281 addDictBind (dict,rhs) uds
1282   = uds { dict_binds = db `consBag` dict_binds uds
1283         , ud_fvs = ud_fvs uds `unionVarSet` fvs }
1284   where
1285     db@(_, fvs) = mkDB (NonRec dict rhs)
1286
1287 dumpAllDictBinds :: UsageDetails -> [CoreBind] -> [CoreBind]
1288 dumpAllDictBinds (MkUD {dict_binds = dbs}) binds
1289   = foldrBag add binds dbs
1290   where
1291     add (bind,_) binds = bind : binds
1292
1293 dumpUDs :: [CoreBndr]
1294         -> UsageDetails -> CoreExpr
1295         -> (UsageDetails, CoreExpr)
1296 dumpUDs bndrs (MkUD { dict_binds = orig_dbs
1297                     , calls = orig_calls
1298                     , ud_fvs = fvs}) body
1299   = (new_uds, foldrBag add_let body dump_dbs)
1300                 -- This may delete fewer variables
1301                 -- than in priciple possible
1302   where
1303     new_uds =
1304      MkUD { dict_binds = free_dbs
1305           , calls      = free_calls
1306           , ud_fvs     = fvs `minusVarSet` bndr_set}
1307
1308     bndr_set = mkVarSet bndrs
1309     add_let (bind,_) body = Let bind body
1310
1311     (free_dbs, dump_dbs, dump_set)
1312         = foldlBag dump_db (emptyBag, emptyBag, bndr_set) orig_dbs
1313                 -- Important that it's foldl not foldr;
1314                 -- we're accumulating the set of dumped ids in dump_set
1315
1316     free_calls = filterCalls dump_set orig_calls
1317
1318     dump_db (free_dbs, dump_dbs, dump_idset) db@(bind, fvs)
1319         | dump_idset `intersectsVarSet` fvs     -- Dump it
1320         = (free_dbs, dump_dbs `snocBag` db,
1321            extendVarSetList dump_idset (bindersOf bind))
1322
1323         | otherwise     -- Don't dump it
1324         = (free_dbs `snocBag` db, dump_dbs, dump_idset)
1325
1326 filterCalls :: VarSet -> CallDetails -> CallDetails
1327 -- Remove any calls that mention the variables
1328 filterCalls bs calls
1329   = mapFM (\_ cs -> filter_calls cs) $
1330     filterFM (\k _ -> not (k `elemVarSet` bs)) calls
1331   where
1332     filter_calls :: CallInfo -> CallInfo
1333     filter_calls = filterFM (\_ (_, fvs) -> not (fvs `intersectsVarSet` bs))
1334 \end{code}
1335
1336
1337 %************************************************************************
1338 %*                                                                      *
1339 \subsubsection{Boring helper functions}
1340 %*                                                                      *
1341 %************************************************************************
1342
1343 \begin{code}
1344 type SpecM a = UniqSM a
1345
1346 initSM :: UniqSupply -> SpecM a -> a
1347 initSM    = initUs_
1348
1349 mapAndCombineSM :: (a -> SpecM (b, UsageDetails)) -> [a] -> SpecM ([b], UsageDetails)
1350 mapAndCombineSM _ []     = return ([], emptyUDs)
1351 mapAndCombineSM f (x:xs) = do (y, uds1) <- f x
1352                               (ys, uds2) <- mapAndCombineSM f xs
1353                               return (y:ys, uds1 `plusUDs` uds2)
1354
1355 cloneBindSM :: Subst -> CoreBind -> SpecM (Subst, Subst, CoreBind)
1356 -- Clone the binders of the bind; return new bind with the cloned binders
1357 -- Return the substitution to use for RHSs, and the one to use for the body
1358 cloneBindSM subst (NonRec bndr rhs) = do
1359     us <- getUniqueSupplyM
1360     let (subst', bndr') = cloneIdBndr subst us bndr
1361     return (subst, subst', NonRec bndr' rhs)
1362
1363 cloneBindSM subst (Rec pairs) = do
1364     us <- getUniqueSupplyM
1365     let (subst', bndrs') = cloneRecIdBndrs subst us (map fst pairs)
1366     return (subst', subst', Rec (bndrs' `zip` map snd pairs))
1367
1368 cloneDictBndrs :: Subst -> [CoreBndr] -> SpecM (Subst, [CoreBndr])
1369 cloneDictBndrs subst bndrs
1370   = do { us <- getUniqueSupplyM
1371        ; return (cloneIdBndrs subst us bndrs) }
1372
1373 newSpecIdSM :: Id -> Type -> SpecM Id
1374     -- Give the new Id a similar occurrence name to the old one
1375 newSpecIdSM old_id new_ty
1376   = do  { uniq <- getUniqueM
1377         ; let
1378             name    = idName old_id
1379             new_occ = mkSpecOcc (nameOccName name)
1380             new_id  = mkUserLocal new_occ uniq new_ty (getSrcSpan name)
1381         ; return new_id }
1382 \end{code}
1383
1384
1385                 Old (but interesting) stuff about unboxed bindings
1386                 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1387
1388 What should we do when a value is specialised to a *strict* unboxed value?
1389
1390         map_*_* f (x:xs) = let h = f x
1391                                t = map f xs
1392                            in h:t
1393
1394 Could convert let to case:
1395
1396         map_*_Int# f (x:xs) = case f x of h# ->
1397                               let t = map f xs
1398                               in h#:t
1399
1400 This may be undesirable since it forces evaluation here, but the value
1401 may not be used in all branches of the body. In the general case this
1402 transformation is impossible since the mutual recursion in a letrec
1403 cannot be expressed as a case.
1404
1405 There is also a problem with top-level unboxed values, since our
1406 implementation cannot handle unboxed values at the top level.
1407
1408 Solution: Lift the binding of the unboxed value and extract it when it
1409 is used:
1410
1411         map_*_Int# f (x:xs) = let h = case (f x) of h# -> _Lift h#
1412                                   t = map f xs
1413                               in case h of
1414                                  _Lift h# -> h#:t
1415
1416 Now give it to the simplifier and the _Lifting will be optimised away.
1417
1418 The benfit is that we have given the specialised "unboxed" values a
1419 very simplep lifted semantics and then leave it up to the simplifier to
1420 optimise it --- knowing that the overheads will be removed in nearly
1421 all cases.
1422
1423 In particular, the value will only be evaluted in the branches of the
1424 program which use it, rather than being forced at the point where the
1425 value is bound. For example:
1426
1427         filtermap_*_* p f (x:xs)
1428           = let h = f x
1429                 t = ...
1430             in case p x of
1431                 True  -> h:t
1432                 False -> t
1433    ==>
1434         filtermap_*_Int# p f (x:xs)
1435           = let h = case (f x) of h# -> _Lift h#
1436                 t = ...
1437             in case p x of
1438                 True  -> case h of _Lift h#
1439                            -> h#:t
1440                 False -> t
1441
1442 The binding for h can still be inlined in the one branch and the
1443 _Lifting eliminated.
1444
1445
1446 Question: When won't the _Lifting be eliminated?
1447
1448 Answer: When they at the top-level (where it is necessary) or when
1449 inlining would duplicate work (or possibly code depending on
1450 options). However, the _Lifting will still be eliminated if the
1451 strictness analyser deems the lifted binding strict.
1452