compiler/stgSyn/CoreToStg.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[CoreToStg]{Converts Core to STG Syntax}
   5
   6 And, as we have the info in hand, we may convert some lets to
   7 let-no-escapes.
   8
   9 \begin{code}
  10 module CoreToStg ( coreToStg, coreExprToStg ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CoreSyn
  15 import CoreUtils        ( rhsIsStatic, manifestArity, exprType, findDefault )
  16 import StgSyn
  17
  18 import Type
  19 import TyCon
  20 import Id
  21 import Var              ( Var, globalIdDetails, idType )
  22 import TyCon            ( isUnboxedTupleTyCon, isPrimTyCon, isFunTyCon, isHiBootTyCon )
  23 import IdInfo
  24 import DataCon
  25 import CostCentre       ( noCCS )
  26 import VarSet
  27 import VarEnv
  28 import Maybes           ( maybeToBool )
  29 import Name             ( getOccName, isExternalName, nameOccName )
  30 import OccName          ( occNameString, occNameFS )
  31 import BasicTypes       ( Arity )
  32 import StaticFlags      ( opt_RuntimeTypes )
  33 import PackageConfig    ( PackageId )
  34 import Outputable
  35
  36 infixr 9 `thenLne`
  37 \end{code}
  38
  39 %************************************************************************
  40 %*                                                                      *
  41 \subsection[live-vs-free-doc]{Documentation}
  42 %*                                                                      *
  43 %************************************************************************
  44
  45 (There is other relevant documentation in codeGen/CgLetNoEscape.)
  46
  47 The actual Stg datatype is decorated with {\em live variable}
  48 information, as well as {\em free variable} information.  The two are
  49 {\em not} the same.  Liveness is an operational property rather than a
  50 semantic one.  A variable is live at a particular execution point if
  51 it can be referred to {\em directly} again.  In particular, a dead
  52 variable's stack slot (if it has one):
  53 \begin{enumerate}
  54 \item
  55 should be stubbed to avoid space leaks, and
  56 \item
  57 may be reused for something else.
  58 \end{enumerate}
  59
  60 There ought to be a better way to say this.  Here are some examples:
  61 \begin{verbatim}
  62         let v = [q] \[x] -> e
  63         in
  64         ...v...  (but no q's)
  65 \end{verbatim}
  66
  67 Just after the `in', v is live, but q is dead.  If the whole of that
  68 let expression was enclosed in a case expression, thus:
  69 \begin{verbatim}
  70         case (let v = [q] \[x] -> e in ...v...) of
  71                 alts[...q...]
  72 \end{verbatim}
  73 (ie @alts@ mention @q@), then @q@ is live even after the `in'; because
  74 we'll return later to the @alts@ and need it.
  75
  76 Let-no-escapes make this a bit more interesting:
  77 \begin{verbatim}
  78         let-no-escape v = [q] \ [x] -> e
  79         in
  80         ...v...
  81 \end{verbatim}
  82 Here, @q@ is still live at the `in', because @v@ is represented not by
  83 a closure but by the current stack state.  In other words, if @v@ is
  84 live then so is @q@.  Furthermore, if @e@ mentions an enclosing
  85 let-no-escaped variable, then {\em its} free variables are also live
  86 if @v@ is.
  87
  88 %************************************************************************
  89 %*                                                                      *
  90 \subsection[caf-info]{Collecting live CAF info}
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 In this pass we also collect information on which CAFs are live for
  95 constructing SRTs (see SRT.lhs).
  96
  97 A top-level Id has CafInfo, which is
  98
  99         - MayHaveCafRefs, if it may refer indirectly to
 100           one or more CAFs, or
 101         - NoCafRefs if it definitely doesn't
 102
 103 The CafInfo has already been calculated during the CoreTidy pass.
 104
 105 During CoreToStg, we then pin onto each binding and case expression, a
 106 list of Ids which represents the "live" CAFs at that point.  The meaning
 107 of "live" here is the same as for live variables, see above (which is
 108 why it's convenient to collect CAF information here rather than elsewhere).
 109
 110 The later SRT pass takes these lists of Ids and uses them to construct
 111 the actual nested SRTs, and replaces the lists of Ids with (offset,length)
 112 pairs.
 113
 114
 115 Interaction of let-no-escape with SRTs   [Sept 01]
 116 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 117 Consider
 118
 119         let-no-escape x = ...caf1...caf2...
 120         in
 121         ...x...x...x...
 122
 123 where caf1,caf2 are CAFs.  Since x doesn't have a closure, we
 124 build SRTs just as if x's defn was inlined at each call site, and
 125 that means that x's CAF refs get duplicated in the overall SRT.
 126
 127 This is unlike ordinary lets, in which the CAF refs are not duplicated.
 128
 129 We could fix this loss of (static) sharing by making a sort of pseudo-closure
 130 for x, solely to put in the SRTs lower down.
 131
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection[binds-StgVarInfo]{Setting variable info: top-level, binds, RHSs}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 coreToStg :: PackageId -> [CoreBind] -> IO [StgBinding]
 141 coreToStg this_pkg pgm
 142   = return pgm'
 143   where (_, _, pgm') = coreTopBindsToStg this_pkg emptyVarEnv pgm
 144
 145 coreExprToStg :: CoreExpr -> StgExpr
 146 coreExprToStg expr
 147   = new_expr where (new_expr,_,_) = initLne emptyVarEnv (coreToStgExpr expr)
 148
 149
 150 coreTopBindsToStg
 151     :: PackageId
 152     -> IdEnv HowBound           -- environment for the bindings
 153     -> [CoreBind]
 154     -> (IdEnv HowBound, FreeVarsInfo, [StgBinding])
 155
 156 coreTopBindsToStg this_pkg env [] = (env, emptyFVInfo, [])
 157 coreTopBindsToStg this_pkg env (b:bs)
 158   = (env2, fvs2, b':bs')
 159   where
 160         -- env accumulates down the list of binds, fvs accumulates upwards
 161         (env1, fvs2, b' ) = coreTopBindToStg this_pkg env fvs1 b
 162         (env2, fvs1, bs') = coreTopBindsToStg this_pkg env1 bs
 163
 164
 165 coreTopBindToStg
 166         :: PackageId
 167         -> IdEnv HowBound
 168         -> FreeVarsInfo         -- Info about the body
 169         -> CoreBind
 170         -> (IdEnv HowBound, FreeVarsInfo, StgBinding)
 171
 172 coreTopBindToStg this_pkg env body_fvs (NonRec id rhs)
 173   = let
 174         env'      = extendVarEnv env id how_bound
 175         how_bound = LetBound TopLet $! manifestArity rhs
 176
 177         (stg_rhs, fvs') =
 178             initLne env (
 179               coreToTopStgRhs this_pkg body_fvs (id,rhs)        `thenLne` \ (stg_rhs, fvs') ->
 180               returnLne (stg_rhs, fvs')
 181            )
 182
 183         bind = StgNonRec id stg_rhs
 184     in
 185     ASSERT2(manifestArity rhs == stgRhsArity stg_rhs, ppr id $$ (ptext SLIT("rhs:")) <+> ppr rhs $$ (ptext SLIT("stg_rhs:"))<+> ppr stg_rhs $$ (ptext SLIT("Manifest:")) <+> (ppr $ manifestArity rhs) $$ (ptext SLIT("STG:")) <+>(ppr $ stgRhsArity stg_rhs) )
 186     ASSERT2(consistentCafInfo id bind, ppr id)
 187 --    WARN(not (consistent caf_info bind), ppr id <+> ppr cafs <+> ppCafInfo caf_info)
 188     (env', fvs' `unionFVInfo` body_fvs, bind)
 189
 190 coreTopBindToStg this_pkg env body_fvs (Rec pairs)
 191   = let
 192         (binders, rhss) = unzip pairs
 193
 194         extra_env' = [ (b, LetBound TopLet $! manifestArity rhs)
 195                      | (b, rhs) <- pairs ]
 196         env' = extendVarEnvList env extra_env'
 197
 198         (stg_rhss, fvs')
 199           = initLne env' (
 200                mapAndUnzipLne (coreToTopStgRhs this_pkg body_fvs) pairs
 201                                                 `thenLne` \ (stg_rhss, fvss') ->
 202                let fvs' = unionFVInfos fvss' in
 203                returnLne (stg_rhss, fvs')
 204            )
 205
 206         bind = StgRec (zip binders stg_rhss)
 207     in
 208     ASSERT2(and [manifestArity rhs == stgRhsArity stg_rhs | (rhs,stg_rhs) <- rhss `zip` stg_rhss], ppr binders)
 209     ASSERT2(consistentCafInfo (head binders) bind, ppr binders)
 210     (env', fvs' `unionFVInfo` body_fvs, bind)
 211
 212 #ifdef DEBUG
 213 -- Assertion helper: this checks that the CafInfo on the Id matches
 214 -- what CoreToStg has figured out about the binding's SRT.  The
 215 -- CafInfo will be exact in all cases except when CorePrep has
 216 -- floated out a binding, in which case it will be approximate.
 217 consistentCafInfo id bind
 218   | occNameFS (nameOccName (idName id)) == FSLIT("sat")
 219   = safe
 220   | otherwise
 221   = WARN (not exact, ppr id) safe
 222   where
 223         safe  = id_marked_caffy || not binding_is_caffy
 224         exact = id_marked_caffy == binding_is_caffy
 225         id_marked_caffy  = mayHaveCafRefs (idCafInfo id)
 226         binding_is_caffy = stgBindHasCafRefs bind
 227 #endif
 228 \end{code}
 229
 230 \begin{code}
 231 coreToTopStgRhs
 232         :: PackageId
 233         -> FreeVarsInfo         -- Free var info for the scope of the binding
 234         -> (Id,CoreExpr)
 235         -> LneM (StgRhs, FreeVarsInfo)
 236
 237 coreToTopStgRhs this_pkg scope_fv_info (bndr, rhs)
 238   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, _) ->
 239     freeVarsToLiveVars rhs_fvs  `thenLne` \ lv_info ->
 240     returnLne (mkTopStgRhs is_static rhs_fvs (mkSRT lv_info) bndr_info new_rhs, rhs_fvs)
 241   where
 242     bndr_info = lookupFVInfo scope_fv_info bndr
 243     is_static = rhsIsStatic this_pkg rhs
 244
 245 mkTopStgRhs :: Bool -> FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr
 246         -> StgRhs
 247
 248 mkTopStgRhs is_static rhs_fvs srt binder_info (StgLam _ bndrs body)
 249   = ASSERT( is_static )
 250     StgRhsClosure noCCS binder_info
 251                   (getFVs rhs_fvs)
 252                   ReEntrant
 253                   srt
 254                   bndrs body
 255
 256 mkTopStgRhs is_static rhs_fvs srt binder_info (StgConApp con args)
 257   | is_static    -- StgConApps can be updatable (see isCrossDllConApp)
 258   = StgRhsCon noCCS con args
 259
 260 mkTopStgRhs is_static rhs_fvs srt binder_info rhs
 261   = ASSERT2( not is_static, ppr rhs )
 262     StgRhsClosure noCCS binder_info
 263                   (getFVs rhs_fvs)
 264                   Updatable
 265                   srt
 266                   [] rhs
 267 \end{code}
 268
 269
 270 -- ---------------------------------------------------------------------------
 271 -- Expressions
 272 -- ---------------------------------------------------------------------------
 273
 274 \begin{code}
 275 coreToStgExpr
 276         :: CoreExpr
 277         -> LneM (StgExpr,       -- Decorated STG expr
 278                  FreeVarsInfo,  -- Its free vars (NB free, not live)
 279                  EscVarsSet)    -- Its escapees, a subset of its free vars;
 280                                 -- also a subset of the domain of the envt
 281                                 -- because we are only interested in the escapees
 282                                 -- for vars which might be turned into
 283                                 -- let-no-escaped ones.
 284 \end{code}
 285
 286 The second and third components can be derived in a simple bottom up pass, not
 287 dependent on any decisions about which variables will be let-no-escaped or
 288 not.  The first component, that is, the decorated expression, may then depend
 289 on these components, but it in turn is not scrutinised as the basis for any
 290 decisions.  Hence no black holes.
 291
 292 \begin{code}
 293 coreToStgExpr (Lit l) = returnLne (StgLit l, emptyFVInfo, emptyVarSet)
 294 coreToStgExpr (Var v) = coreToStgApp Nothing v []
 295
 296 coreToStgExpr expr@(App _ _)
 297   = coreToStgApp Nothing f args
 298   where
 299     (f, args) = myCollectArgs expr
 300
 301 coreToStgExpr expr@(Lam _ _)
 302   = let
 303         (args, body) = myCollectBinders expr
 304         args'        = filterStgBinders args
 305     in
 306     extendVarEnvLne [ (a, LambdaBound) | a <- args' ] $
 307     coreToStgExpr body  `thenLne` \ (body, body_fvs, body_escs) ->
 308     let
 309         fvs             = args' `minusFVBinders` body_fvs
 310         escs            = body_escs `delVarSetList` args'
 311         result_expr | null args' = body
 312                     | otherwise  = StgLam (exprType expr) args' body
 313     in
 314     returnLne (result_expr, fvs, escs)
 315
 316 coreToStgExpr (Note (SCC cc) expr)
 317   = coreToStgExpr expr          `thenLne` ( \ (expr2, fvs, escs) ->
 318     returnLne (StgSCC cc expr2, fvs, escs) )
 319
 320 coreToStgExpr (Case (Var id) _bndr ty [(DEFAULT,[],expr)])
 321   | Just (TickBox m n) <- isTickBoxOp_maybe id
 322   = coreToStgExpr expr         `thenLne` ( \ (expr2, fvs, escs) ->
 323     returnLne (StgTick m n expr2, fvs, escs) )
 324
 325 coreToStgExpr (Note other_note expr)
 326   = coreToStgExpr expr
 327
 328 coreToStgExpr (Cast expr co)
 329   = coreToStgExpr expr
 330
 331 -- Cases require a little more real work.
 332
 333 coreToStgExpr (Case scrut bndr _ alts)
 334   = extendVarEnvLne [(bndr, LambdaBound)]       (
 335          mapAndUnzip3Lne vars_alt alts  `thenLne` \ (alts2, fvs_s, escs_s) ->
 336          returnLne ( alts2,
 337                      unionFVInfos fvs_s,
 338                      unionVarSets escs_s )
 339     )                                   `thenLne` \ (alts2, alts_fvs, alts_escs) ->
 340     let
 341         -- Determine whether the default binder is dead or not
 342         -- This helps the code generator to avoid generating an assignment
 343         -- for the case binder (is extremely rare cases) ToDo: remove.
 344         bndr' | bndr `elementOfFVInfo` alts_fvs = bndr
 345               | otherwise                       = bndr `setIdOccInfo` IAmDead
 346
 347         -- Don't consider the default binder as being 'live in alts',
 348         -- since this is from the point of view of the case expr, where
 349         -- the default binder is not free.
 350         alts_fvs_wo_bndr  = bndr `minusFVBinder` alts_fvs
 351         alts_escs_wo_bndr = alts_escs `delVarSet` bndr
 352     in
 353
 354     freeVarsToLiveVars alts_fvs_wo_bndr         `thenLne` \ alts_lv_info ->
 355
 356         -- We tell the scrutinee that everything
 357         -- live in the alts is live in it, too.
 358     setVarsLiveInCont alts_lv_info (
 359         coreToStgExpr scrut       `thenLne` \ (scrut2, scrut_fvs, scrut_escs) ->
 360         freeVarsToLiveVars scrut_fvs `thenLne` \ scrut_lv_info ->
 361         returnLne (scrut2, scrut_fvs, scrut_escs, scrut_lv_info)
 362       )
 363                 `thenLne` \ (scrut2, scrut_fvs, scrut_escs, scrut_lv_info) ->
 364
 365     returnLne (
 366       StgCase scrut2 (getLiveVars scrut_lv_info)
 367                      (getLiveVars alts_lv_info)
 368                      bndr'
 369                      (mkSRT alts_lv_info)
 370                      (mkStgAltType (idType bndr) alts)
 371                      alts2,
 372       scrut_fvs `unionFVInfo` alts_fvs_wo_bndr,
 373       alts_escs_wo_bndr `unionVarSet` getFVSet scrut_fvs
 374                 -- You might think we should have scrut_escs, not
 375                 -- (getFVSet scrut_fvs), but actually we can't call, and
 376                 -- then return from, a let-no-escape thing.
 377       )
 378   where
 379     vars_alt (con, binders, rhs)
 380       = let     -- Remove type variables
 381             binders' = filterStgBinders binders
 382         in
 383         extendVarEnvLne [(b, LambdaBound) | b <- binders']      $
 384         coreToStgExpr rhs       `thenLne` \ (rhs2, rhs_fvs, rhs_escs) ->
 385         let
 386                 -- Records whether each param is used in the RHS
 387             good_use_mask = [ b `elementOfFVInfo` rhs_fvs | b <- binders' ]
 388         in
 389         returnLne ( (con, binders', good_use_mask, rhs2),
 390                     binders' `minusFVBinders` rhs_fvs,
 391                     rhs_escs `delVarSetList` binders' )
 392                 -- ToDo: remove the delVarSet;
 393                 -- since escs won't include any of these binders
 394 \end{code}
 395
 396 Lets not only take quite a bit of work, but this is where we convert
 397 then to let-no-escapes, if we wish.
 398
 399 (Meanwhile, we don't expect to see let-no-escapes...)
 400 \begin{code}
 401 coreToStgExpr (Let bind body)
 402   = fixLne (\ ~(_, _, _, no_binder_escapes) ->
 403         coreToStgLet no_binder_escapes bind body
 404     )                           `thenLne` \ (new_let, fvs, escs, _) ->
 405
 406     returnLne (new_let, fvs, escs)
 407 \end{code}
 408
 409 \begin{code}
 410 mkStgAltType scrut_ty alts
 411   = case splitTyConApp_maybe (repType scrut_ty) of
 412         Just (tc,_) | isUnboxedTupleTyCon tc -> UbxTupAlt tc
 413                     | isUnLiftedTyCon tc     -> PrimAlt tc
 414                     | isHiBootTyCon tc       -> look_for_better_tycon
 415                     | isAlgTyCon tc          -> AlgAlt tc
 416                     | isFunTyCon tc          -> PolyAlt
 417                     | isPrimTyCon tc         -> PolyAlt -- for "Any"
 418                     | otherwise              -> pprPanic "mkStgAlts" (ppr tc)
 419         Nothing                              -> PolyAlt
 420
 421   where
 422    -- Sometimes, the TyCon in the type of the scrutinee is an HiBootTyCon,
 423    -- which may not have any constructors inside it.  If so, then we
 424    -- can get a better TyCon by grabbing the one from a constructor alternative
 425    -- if one exists.
 426    look_for_better_tycon
 427         | ((DataAlt con, _, _) : _) <- data_alts =
 428                 AlgAlt (dataConTyCon con)
 429         | otherwise =
 430                 ASSERT(null data_alts)
 431                 PolyAlt
 432         where
 433                 (data_alts, _deflt) = findDefault alts
 434 \end{code}
 435
 436
 437 -- ---------------------------------------------------------------------------
 438 -- Applications
 439 -- ---------------------------------------------------------------------------
 440
 441 \begin{code}
 442 coreToStgApp
 443          :: Maybe UpdateFlag            -- Just upd <=> this application is
 444                                         -- the rhs of a thunk binding
 445                                         --      x = [...] \upd [] -> the_app
 446                                         -- with specified update flag
 447         -> Id                           -- Function
 448         -> [CoreArg]                    -- Arguments
 449         -> LneM (StgExpr, FreeVarsInfo, EscVarsSet)
 450
 451
 452 coreToStgApp maybe_thunk_body f args
 453   = coreToStgArgs args          `thenLne` \ (args', args_fvs) ->
 454     lookupVarLne f              `thenLne` \ how_bound ->
 455
 456     let
 457         n_val_args       = valArgCount args
 458         not_letrec_bound = not (isLetBound how_bound)
 459         fun_fvs
 460           = let fvs = singletonFVInfo f how_bound fun_occ in
 461             -- e.g. (f :: a -> int) (x :: a)
 462             -- Here the free variables are "f", "x" AND the type variable "a"
 463             -- coreToStgArgs will deal with the arguments recursively
 464             if opt_RuntimeTypes then
 465               fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType (idType f))
 466             else fvs
 467
 468         -- Mostly, the arity info of a function is in the fn's IdInfo
 469         -- But new bindings introduced by CoreSat may not have no
 470         -- arity info; it would do us no good anyway.  For example:
 471         --      let f = \ab -> e in f
 472         -- No point in having correct arity info for f!
 473         -- Hence the hasArity stuff below.
 474         -- NB: f_arity is only consulted for LetBound things
 475         f_arity   = stgArity f how_bound
 476         saturated = f_arity <= n_val_args
 477
 478         fun_occ
 479          | not_letrec_bound         = noBinderInfo      -- Uninteresting variable
 480          | f_arity > 0 && saturated = stgSatOcc -- Saturated or over-saturated function call
 481          | otherwise                = stgUnsatOcc       -- Unsaturated function or thunk
 482
 483         fun_escs
 484          | not_letrec_bound      = emptyVarSet  -- Only letrec-bound escapees are interesting
 485          | f_arity == n_val_args = emptyVarSet  -- A function *or thunk* with an exactly
 486                                                 -- saturated call doesn't escape
 487                                                 -- (let-no-escape applies to 'thunks' too)
 488
 489          | otherwise         = unitVarSet f     -- Inexact application; it does escape
 490
 491         -- At the moment of the call:
 492
 493         --  either the function is *not* let-no-escaped, in which case
 494         --         nothing is live except live_in_cont
 495         --      or the function *is* let-no-escaped in which case the
 496         --         variables it uses are live, but still the function
 497         --         itself is not.  PS.  In this case, the function's
 498         --         live vars should already include those of the
 499         --         continuation, but it does no harm to just union the
 500         --         two regardless.
 501
 502         res_ty = exprType (mkApps (Var f) args)
 503         app = case globalIdDetails f of
 504                 DataConWorkId dc | saturated -> StgConApp dc args'
 505                 PrimOpId op      -> ASSERT( saturated )
 506                                     StgOpApp (StgPrimOp op) args' res_ty
 507                 FCallId call     -> ASSERT( saturated )
 508                                     StgOpApp (StgFCallOp call (idUnique f)) args' res_ty
 509                 TickBoxOpId {}   -> pprPanic "coreToStg TickBox" $ ppr (f,args')
 510                 _other           -> StgApp f args'
 511
 512     in
 513     returnLne (
 514         app,
 515         fun_fvs  `unionFVInfo` args_fvs,
 516         fun_escs `unionVarSet` (getFVSet args_fvs)
 517                                 -- All the free vars of the args are disqualified
 518                                 -- from being let-no-escaped.
 519     )
 520
 521
 522
 523 -- ---------------------------------------------------------------------------
 524 -- Argument lists
 525 -- This is the guy that turns applications into A-normal form
 526 -- ---------------------------------------------------------------------------
 527
 528 coreToStgArgs :: [CoreArg] -> LneM ([StgArg], FreeVarsInfo)
 529 coreToStgArgs []
 530   = returnLne ([], emptyFVInfo)
 531
 532 coreToStgArgs (Type ty : args)  -- Type argument
 533   = coreToStgArgs args  `thenLne` \ (args', fvs) ->
 534     if opt_RuntimeTypes then
 535         returnLne (StgTypeArg ty : args', fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType ty))
 536     else
 537     returnLne (args', fvs)
 538
 539 coreToStgArgs (arg : args)      -- Non-type argument
 540   = coreToStgArgs args  `thenLne` \ (stg_args, args_fvs) ->
 541     coreToStgExpr arg   `thenLne` \ (arg', arg_fvs, escs) ->
 542     let
 543         fvs = args_fvs `unionFVInfo` arg_fvs
 544         stg_arg = case arg' of
 545                        StgApp v []      -> StgVarArg v
 546                        StgConApp con [] -> StgVarArg (dataConWorkId con)
 547                        StgLit lit       -> StgLitArg lit
 548                        _                -> pprPanic "coreToStgArgs" (ppr arg)
 549     in
 550         -- WARNING: what if we have an argument like (v `cast` co)
 551         --          where 'co' changes the representation type?
 552         --          (This really only happens if co is unsafe.)
 553         -- Then all the getArgAmode stuff in CgBindery will set the
 554         -- cg_rep of the CgIdInfo based on the type of v, rather
 555         -- than the type of 'co'.
 556         -- This matters particularly when the function is a primop
 557         -- or foreign call.
 558         -- Wanted: a better solution than this hacky warning
 559     let
 560         arg_ty = exprType arg
 561         stg_arg_ty = stgArgType stg_arg
 562     in
 563     WARN( isUnLiftedType arg_ty /= isUnLiftedType stg_arg_ty,
 564           ptext SLIT("Dangerous-looking argument. Probable cause: bad unsafeCoerce#") $$ ppr arg)
 565     returnLne (stg_arg : stg_args, fvs)
 566
 567
 568 -- ---------------------------------------------------------------------------
 569 -- The magic for lets:
 570 -- ---------------------------------------------------------------------------
 571
 572 coreToStgLet
 573          :: Bool        -- True <=> yes, we are let-no-escaping this let
 574          -> CoreBind    -- bindings
 575          -> CoreExpr    -- body
 576          -> LneM (StgExpr,      -- new let
 577                   FreeVarsInfo, -- variables free in the whole let
 578                   EscVarsSet,   -- variables that escape from the whole let
 579                   Bool)         -- True <=> none of the binders in the bindings
 580                                 -- is among the escaping vars
 581
 582 coreToStgLet let_no_escape bind body
 583   = fixLne (\ ~(_, _, _, _, _, rec_body_fvs, _, _) ->
 584
 585         -- Do the bindings, setting live_in_cont to empty if
 586         -- we ain't in a let-no-escape world
 587         getVarsLiveInCont               `thenLne` \ live_in_cont ->
 588         setVarsLiveInCont (if let_no_escape
 589                                 then live_in_cont
 590                                 else emptyLiveInfo)
 591                           (vars_bind rec_body_fvs bind)
 592             `thenLne` \ ( bind2, bind_fvs, bind_escs, bind_lv_info, env_ext) ->
 593
 594         -- Do the body
 595         extendVarEnvLne env_ext (
 596           coreToStgExpr body          `thenLne` \(body2, body_fvs, body_escs) ->
 597           freeVarsToLiveVars body_fvs `thenLne` \ body_lv_info ->
 598
 599           returnLne (bind2, bind_fvs, bind_escs, getLiveVars bind_lv_info,
 600                      body2, body_fvs, body_escs, getLiveVars body_lv_info)
 601         )
 602
 603     ) `thenLne` (\ (bind2, bind_fvs, bind_escs, bind_lvs,
 604                     body2, body_fvs, body_escs, body_lvs) ->
 605
 606
 607         -- Compute the new let-expression
 608     let
 609         new_let | let_no_escape = StgLetNoEscape live_in_whole_let bind_lvs bind2 body2
 610                 | otherwise     = StgLet bind2 body2
 611
 612         free_in_whole_let
 613           = binders `minusFVBinders` (bind_fvs `unionFVInfo` body_fvs)
 614
 615         live_in_whole_let
 616           = bind_lvs `unionVarSet` (body_lvs `delVarSetList` binders)
 617
 618         real_bind_escs = if let_no_escape then
 619                             bind_escs
 620                          else
 621                             getFVSet bind_fvs
 622                             -- Everything escapes which is free in the bindings
 623
 624         let_escs = (real_bind_escs `unionVarSet` body_escs) `delVarSetList` binders
 625
 626         all_escs = bind_escs `unionVarSet` body_escs    -- Still includes binders of
 627                                                         -- this let(rec)
 628
 629         no_binder_escapes = isEmptyVarSet (set_of_binders `intersectVarSet` all_escs)
 630
 631 #ifdef DEBUG
 632         -- Debugging code as requested by Andrew Kennedy
 633         checked_no_binder_escapes
 634                 | not no_binder_escapes && any is_join_var binders
 635                 = pprTrace "Interesting!  A join var that isn't let-no-escaped" (ppr binders)
 636                   False
 637                 | otherwise = no_binder_escapes
 638 #else
 639         checked_no_binder_escapes = no_binder_escapes
 640 #endif
 641
 642                 -- Mustn't depend on the passed-in let_no_escape flag, since
 643                 -- no_binder_escapes is used by the caller to derive the flag!
 644     in
 645     returnLne (
 646         new_let,
 647         free_in_whole_let,
 648         let_escs,
 649         checked_no_binder_escapes
 650     ))
 651   where
 652     set_of_binders = mkVarSet binders
 653     binders        = bindersOf bind
 654
 655     mk_binding bind_lv_info binder rhs
 656         = (binder, LetBound (NestedLet live_vars) (manifestArity rhs))
 657         where
 658            live_vars | let_no_escape = addLiveVar bind_lv_info binder
 659                      | otherwise     = unitLiveVar binder
 660                 -- c.f. the invariant on NestedLet
 661
 662     vars_bind :: FreeVarsInfo           -- Free var info for body of binding
 663               -> CoreBind
 664               -> LneM (StgBinding,
 665                        FreeVarsInfo,
 666                        EscVarsSet,        -- free vars; escapee vars
 667                        LiveInfo,          -- Vars and CAFs live in binding
 668                        [(Id, HowBound)])  -- extension to environment
 669
 670
 671     vars_bind body_fvs (NonRec binder rhs)
 672       = coreToStgRhs body_fvs [] (binder,rhs)
 673                                 `thenLne` \ (rhs2, bind_fvs, bind_lv_info, escs) ->
 674         let
 675             env_ext_item = mk_binding bind_lv_info binder rhs
 676         in
 677         returnLne (StgNonRec binder rhs2,
 678                    bind_fvs, escs, bind_lv_info, [env_ext_item])
 679
 680
 681     vars_bind body_fvs (Rec pairs)
 682       = fixLne (\ ~(_, rec_rhs_fvs, _, bind_lv_info, _) ->
 683            let
 684                 rec_scope_fvs = unionFVInfo body_fvs rec_rhs_fvs
 685                 binders = map fst pairs
 686                 env_ext = [ mk_binding bind_lv_info b rhs
 687                           | (b,rhs) <- pairs ]
 688            in
 689            extendVarEnvLne env_ext (
 690               mapAndUnzip4Lne (coreToStgRhs rec_scope_fvs binders) pairs
 691                                         `thenLne` \ (rhss2, fvss, lv_infos, escss) ->
 692               let
 693                         bind_fvs = unionFVInfos fvss
 694                         bind_lv_info = foldr unionLiveInfo emptyLiveInfo lv_infos
 695                         escs     = unionVarSets escss
 696               in
 697               returnLne (StgRec (binders `zip` rhss2),
 698                          bind_fvs, escs, bind_lv_info, env_ext)
 699            )
 700         )
 701
 702 is_join_var :: Id -> Bool
 703 -- A hack (used only for compiler debuggging) to tell if
 704 -- a variable started life as a join point ($j)
 705 is_join_var j = occNameString (getOccName j) == "$j"
 706 \end{code}
 707
 708 \begin{code}
 709 coreToStgRhs :: FreeVarsInfo            -- Free var info for the scope of the binding
 710              -> [Id]
 711              -> (Id,CoreExpr)
 712              -> LneM (StgRhs, FreeVarsInfo, LiveInfo, EscVarsSet)
 713
 714 coreToStgRhs scope_fv_info binders (bndr, rhs)
 715   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, rhs_escs) ->
 716     getEnvLne                   `thenLne` \ env ->
 717     freeVarsToLiveVars (binders `minusFVBinders` rhs_fvs) `thenLne` \ lv_info ->
 718     returnLne (mkStgRhs rhs_fvs (mkSRT lv_info) bndr_info new_rhs,
 719                rhs_fvs, lv_info, rhs_escs)
 720   where
 721     bndr_info = lookupFVInfo scope_fv_info bndr
 722
 723 mkStgRhs :: FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr -> StgRhs
 724
 725 mkStgRhs rhs_fvs srt binder_info (StgConApp con args)
 726   = StgRhsCon noCCS con args
 727
 728 mkStgRhs rhs_fvs srt binder_info (StgLam _ bndrs body)
 729   = StgRhsClosure noCCS binder_info
 730                   (getFVs rhs_fvs)
 731                   ReEntrant
 732                   srt bndrs body
 733
 734 mkStgRhs rhs_fvs srt binder_info rhs
 735   = StgRhsClosure noCCS binder_info
 736                   (getFVs rhs_fvs)
 737                   upd_flag srt [] rhs
 738   where
 739    upd_flag = Updatable
 740   {-
 741     SDM: disabled.  Eval/Apply can't handle functions with arity zero very
 742     well; and making these into simple non-updatable thunks breaks other
 743     assumptions (namely that they will be entered only once).
 744
 745     upd_flag | isPAP env rhs  = ReEntrant
 746              | otherwise      = Updatable
 747   -}
 748
 749 {- ToDo:
 750           upd = if isOnceDem dem
 751                     then (if isNotTop toplev
 752                             then SingleEntry    -- HA!  Paydirt for "dem"
 753                             else
 754 #ifdef DEBUG
 755                      trace "WARNING: SE CAFs unsupported, forcing UPD instead" $
 756 #endif
 757                      Updatable)
 758                 else Updatable
 759         -- For now we forbid SingleEntry CAFs; they tickle the
 760         -- ASSERT in rts/Storage.c line 215 at newCAF() re mut_link,
 761         -- and I don't understand why.  There's only one SE_CAF (well,
 762         -- only one that tickled a great gaping bug in an earlier attempt
 763         -- at ClosureInfo.getEntryConvention) in the whole of nofib,
 764         -- specifically Main.lvl6 in spectral/cryptarithm2.
 765         -- So no great loss.  KSW 2000-07.
 766 -}
 767 \end{code}
 768
 769 Detect thunks which will reduce immediately to PAPs, and make them
 770 non-updatable.  This has several advantages:
 771
 772         - the non-updatable thunk behaves exactly like the PAP,
 773
 774         - the thunk is more efficient to enter, because it is
 775           specialised to the task.
 776
 777         - we save one update frame, one stg_update_PAP, one update
 778           and lots of PAP_enters.
 779
 780         - in the case where the thunk is top-level, we save building
 781           a black hole and futhermore the thunk isn't considered to
 782           be a CAF any more, so it doesn't appear in any SRTs.
 783
 784 We do it here, because the arity information is accurate, and we need
 785 to do it before the SRT pass to save the SRT entries associated with
 786 any top-level PAPs.
 787
 788 isPAP env (StgApp f args) = listLengthCmp args arity == LT -- idArity f > length args
 789                           where
 790                             arity = stgArity f (lookupBinding env f)
 791 isPAP env _               = False
 792
 793
 794 %************************************************************************
 795 %*                                                                      *
 796 \subsection[LNE-monad]{A little monad for this let-no-escaping pass}
 797 %*                                                                      *
 798 %************************************************************************
 799
 800 There's a lot of stuff to pass around, so we use this @LneM@ monad to
 801 help.  All the stuff here is only passed *down*.
 802
 803 \begin{code}
 804 type LneM a =  IdEnv HowBound
 805             -> LiveInfo         -- Vars and CAFs live in continuation
 806             -> a
 807
 808 type LiveInfo = (StgLiveVars,   -- Dynamic live variables;
 809                                 -- i.e. ones with a nested (non-top-level) binding
 810                  CafSet)        -- Static live variables;
 811                                 -- i.e. top-level variables that are CAFs or refer to them
 812
 813 type EscVarsSet = IdSet
 814 type CafSet     = IdSet
 815
 816 data HowBound
 817   = ImportBound         -- Used only as a response to lookupBinding; never
 818                         -- exists in the range of the (IdEnv HowBound)
 819
 820   | LetBound            -- A let(rec) in this module
 821         LetInfo         -- Whether top level or nested
 822         Arity           -- Its arity (local Ids don't have arity info at this point)
 823
 824   | LambdaBound         -- Used for both lambda and case
 825
 826 data LetInfo
 827   = TopLet              -- top level things
 828   | NestedLet LiveInfo  -- For nested things, what is live if this
 829                         -- thing is live?  Invariant: the binder
 830                         -- itself is always a member of
 831                         -- the dynamic set of its own LiveInfo
 832
 833 isLetBound (LetBound _ _) = True
 834 isLetBound other          = False
 835
 836 topLevelBound ImportBound         = True
 837 topLevelBound (LetBound TopLet _) = True
 838 topLevelBound other               = False
 839 \end{code}
 840
 841 For a let(rec)-bound variable, x, we record LiveInfo, the set of
 842 variables that are live if x is live.  This LiveInfo comprises
 843         (a) dynamic live variables (ones with a non-top-level binding)
 844         (b) static live variabes (CAFs or things that refer to CAFs)
 845
 846 For "normal" variables (a) is just x alone.  If x is a let-no-escaped
 847 variable then x is represented by a code pointer and a stack pointer
 848 (well, one for each stack).  So all of the variables needed in the
 849 execution of x are live if x is, and are therefore recorded in the
 850 LetBound constructor; x itself *is* included.
 851
 852 The set of dynamic live variables is guaranteed ot have no further let-no-escaped
 853 variables in it.
 854
 855 \begin{code}
 856 emptyLiveInfo :: LiveInfo
 857 emptyLiveInfo = (emptyVarSet,emptyVarSet)
 858
 859 unitLiveVar :: Id -> LiveInfo
 860 unitLiveVar lv = (unitVarSet lv, emptyVarSet)
 861
 862 unitLiveCaf :: Id -> LiveInfo
 863 unitLiveCaf caf = (emptyVarSet, unitVarSet caf)
 864
 865 addLiveVar :: LiveInfo -> Id -> LiveInfo
 866 addLiveVar (lvs, cafs) id = (lvs `extendVarSet` id, cafs)
 867
 868 unionLiveInfo :: LiveInfo -> LiveInfo -> LiveInfo
 869 unionLiveInfo (lv1,caf1) (lv2,caf2) = (lv1 `unionVarSet` lv2, caf1 `unionVarSet` caf2)
 870
 871 mkSRT :: LiveInfo -> SRT
 872 mkSRT (_, cafs) = SRTEntries cafs
 873
 874 getLiveVars :: LiveInfo -> StgLiveVars
 875 getLiveVars (lvs, _) = lvs
 876 \end{code}
 877
 878
 879 The std monad functions:
 880 \begin{code}
 881 initLne :: IdEnv HowBound -> LneM a -> a
 882 initLne env m = m env emptyLiveInfo
 883
 884
 885
 886 {-# INLINE thenLne #-}
 887 {-# INLINE returnLne #-}
 888
 889 returnLne :: a -> LneM a
 890 returnLne e env lvs_cont = e
 891
 892 thenLne :: LneM a -> (a -> LneM b) -> LneM b
 893 thenLne m k env lvs_cont
 894   = k (m env lvs_cont) env lvs_cont
 895
 896 mapAndUnzipLne  :: (a -> LneM (b,c))   -> [a] -> LneM ([b],[c])
 897 mapAndUnzipLne f [] = returnLne ([],[])
 898 mapAndUnzipLne f (x:xs)
 899   = f x                 `thenLne` \ (r1,  r2)  ->
 900     mapAndUnzipLne f xs `thenLne` \ (rs1, rs2) ->
 901     returnLne (r1:rs1, r2:rs2)
 902
 903 mapAndUnzip3Lne :: (a -> LneM (b,c,d)) -> [a] -> LneM ([b],[c],[d])
 904 mapAndUnzip3Lne f []    = returnLne ([],[],[])
 905 mapAndUnzip3Lne f (x:xs)
 906   = f x                  `thenLne` \ (r1,  r2,  r3)  ->
 907     mapAndUnzip3Lne f xs `thenLne` \ (rs1, rs2, rs3) ->
 908     returnLne (r1:rs1, r2:rs2, r3:rs3)
 909
 910 mapAndUnzip4Lne :: (a -> LneM (b,c,d,e)) -> [a] -> LneM ([b],[c],[d],[e])
 911 mapAndUnzip4Lne f []    = returnLne ([],[],[],[])
 912 mapAndUnzip4Lne f (x:xs)
 913   = f x                  `thenLne` \ (r1,  r2,  r3, r4)  ->
 914     mapAndUnzip4Lne f xs `thenLne` \ (rs1, rs2, rs3, rs4) ->
 915     returnLne (r1:rs1, r2:rs2, r3:rs3, r4:rs4)
 916
 917 fixLne :: (a -> LneM a) -> LneM a
 918 fixLne expr env lvs_cont
 919   = result
 920   where
 921     result = expr result env lvs_cont
 922 \end{code}
 923
 924 Functions specific to this monad:
 925
 926 \begin{code}
 927 getVarsLiveInCont :: LneM LiveInfo
 928 getVarsLiveInCont env lvs_cont = lvs_cont
 929
 930 setVarsLiveInCont :: LiveInfo -> LneM a -> LneM a
 931 setVarsLiveInCont new_lvs_cont expr env lvs_cont
 932   = expr env new_lvs_cont
 933
 934 extendVarEnvLne :: [(Id, HowBound)] -> LneM a -> LneM a
 935 extendVarEnvLne ids_w_howbound expr env lvs_cont
 936   = expr (extendVarEnvList env ids_w_howbound) lvs_cont
 937
 938 lookupVarLne :: Id -> LneM HowBound
 939 lookupVarLne v env lvs_cont = returnLne (lookupBinding env v) env lvs_cont
 940
 941 getEnvLne :: LneM (IdEnv HowBound)
 942 getEnvLne env lvs_cont = returnLne env env lvs_cont
 943
 944 lookupBinding :: IdEnv HowBound -> Id -> HowBound
 945 lookupBinding env v = case lookupVarEnv env v of
 946                         Just xx -> xx
 947                         Nothing -> ASSERT2( isGlobalId v, ppr v ) ImportBound
 948
 949
 950 -- The result of lookupLiveVarsForSet, a set of live variables, is
 951 -- only ever tacked onto a decorated expression. It is never used as
 952 -- the basis of a control decision, which might give a black hole.
 953
 954 freeVarsToLiveVars :: FreeVarsInfo -> LneM LiveInfo
 955 freeVarsToLiveVars fvs env live_in_cont
 956   = returnLne live_info env live_in_cont
 957   where
 958     live_info    = foldr unionLiveInfo live_in_cont lvs_from_fvs
 959     lvs_from_fvs = map do_one (allFreeIds fvs)
 960
 961     do_one (v, how_bound)
 962       = case how_bound of
 963           ImportBound                     -> unitLiveCaf v      -- Only CAF imports are
 964                                                                 -- recorded in fvs
 965           LetBound TopLet _
 966                 | mayHaveCafRefs (idCafInfo v) -> unitLiveCaf v
 967                 | otherwise                    -> emptyLiveInfo
 968
 969           LetBound (NestedLet lvs) _      -> lvs        -- lvs already contains v
 970                                                         -- (see the invariant on NestedLet)
 971
 972           _lambda_or_case_binding         -> unitLiveVar v      -- Bound by lambda or case
 973 \end{code}
 974
 975 %************************************************************************
 976 %*                                                                      *
 977 \subsection[Free-var info]{Free variable information}
 978 %*                                                                      *
 979 %************************************************************************
 980
 981 \begin{code}
 982 type FreeVarsInfo = VarEnv (Var, HowBound, StgBinderInfo)
 983         -- The Var is so we can gather up the free variables
 984         -- as a set.
 985         --
 986         -- The HowBound info just saves repeated lookups;
 987         -- we look up just once when we encounter the occurrence.
 988         -- INVARIANT: Any ImportBound Ids are HaveCafRef Ids
 989         --            Imported Ids without CAF refs are simply
 990         --            not put in the FreeVarsInfo for an expression.
 991         --            See singletonFVInfo and freeVarsToLiveVars
 992         --
 993         -- StgBinderInfo records how it occurs; notably, we
 994         -- are interested in whether it only occurs in saturated
 995         -- applications, because then we don't need to build a
 996         -- curried version.
 997         -- If f is mapped to noBinderInfo, that means
 998         -- that f *is* mentioned (else it wouldn't be in the
 999         -- IdEnv at all), but perhaps in an unsaturated applications.
1000         --
1001         -- All case/lambda-bound things are also mapped to
1002         -- noBinderInfo, since we aren't interested in their
1003         -- occurence info.
1004         --
1005         -- For ILX we track free var info for type variables too;
1006         -- hence VarEnv not IdEnv
1007 \end{code}
1008
1009 \begin{code}
1010 emptyFVInfo :: FreeVarsInfo
1011 emptyFVInfo = emptyVarEnv
1012
1013 singletonFVInfo :: Id -> HowBound -> StgBinderInfo -> FreeVarsInfo
1014 -- Don't record non-CAF imports at all, to keep free-var sets small
1015 singletonFVInfo id ImportBound info
1016    | mayHaveCafRefs (idCafInfo id) = unitVarEnv id (id, ImportBound, info)
1017    | otherwise                     = emptyVarEnv
1018 singletonFVInfo id how_bound info  = unitVarEnv id (id, how_bound, info)
1019
1020 tyvarFVInfo :: TyVarSet -> FreeVarsInfo
1021 tyvarFVInfo tvs = foldVarSet add emptyFVInfo tvs
1022         where
1023           add tv fvs = extendVarEnv fvs tv (tv, LambdaBound, noBinderInfo)
1024                 -- Type variables must be lambda-bound
1025
1026 unionFVInfo :: FreeVarsInfo -> FreeVarsInfo -> FreeVarsInfo
1027 unionFVInfo fv1 fv2 = plusVarEnv_C plusFVInfo fv1 fv2
1028
1029 unionFVInfos :: [FreeVarsInfo] -> FreeVarsInfo
1030 unionFVInfos fvs = foldr unionFVInfo emptyFVInfo fvs
1031
1032 minusFVBinders :: [Id] -> FreeVarsInfo -> FreeVarsInfo
1033 minusFVBinders vs fv = foldr minusFVBinder fv vs
1034
1035 minusFVBinder :: Id -> FreeVarsInfo -> FreeVarsInfo
1036 minusFVBinder v fv | isId v && opt_RuntimeTypes
1037                    = (fv `delVarEnv` v) `unionFVInfo`
1038                      tyvarFVInfo (tyVarsOfType (idType v))
1039                    | otherwise = fv `delVarEnv` v
1040         -- When removing a binder, remember to add its type variables
1041         -- c.f. CoreFVs.delBinderFV
1042
1043 elementOfFVInfo :: Id -> FreeVarsInfo -> Bool
1044 elementOfFVInfo id fvs = maybeToBool (lookupVarEnv fvs id)
1045
1046 lookupFVInfo :: FreeVarsInfo -> Id -> StgBinderInfo
1047 -- Find how the given Id is used.
1048 -- Externally visible things may be used any old how
1049 lookupFVInfo fvs id
1050   | isExternalName (idName id) = noBinderInfo
1051   | otherwise = case lookupVarEnv fvs id of
1052                         Nothing         -> noBinderInfo
1053                         Just (_,_,info) -> info
1054
1055 allFreeIds :: FreeVarsInfo -> [(Id,HowBound)]   -- Both top level and non-top-level Ids
1056 allFreeIds fvs = [(id,how_bound) | (id,how_bound,_) <- varEnvElts fvs, isId id]
1057
1058 -- Non-top-level things only, both type variables and ids
1059 -- (type variables only if opt_RuntimeTypes)
1060 getFVs :: FreeVarsInfo -> [Var]
1061 getFVs fvs = [id | (id, how_bound, _) <- varEnvElts fvs,
1062                     not (topLevelBound how_bound) ]
1063
1064 getFVSet :: FreeVarsInfo -> VarSet
1065 getFVSet fvs = mkVarSet (getFVs fvs)
1066
1067 plusFVInfo (id1,hb1,info1) (id2,hb2,info2)
1068   = ASSERT (id1 == id2 && hb1 `check_eq_how_bound` hb2)
1069     (id1, hb1, combineStgBinderInfo info1 info2)
1070
1071 #ifdef DEBUG
1072 -- The HowBound info for a variable in the FVInfo should be consistent
1073 check_eq_how_bound ImportBound        ImportBound        = True
1074 check_eq_how_bound LambdaBound        LambdaBound        = True
1075 check_eq_how_bound (LetBound li1 ar1) (LetBound li2 ar2) = ar1 == ar2 && check_eq_li li1 li2
1076 check_eq_how_bound hb1                hb2                = False
1077
1078 check_eq_li (NestedLet _) (NestedLet _) = True
1079 check_eq_li TopLet        TopLet        = True
1080 check_eq_li li1           li2           = False
1081 #endif
1082 \end{code}
1083
1084 Misc.
1085 \begin{code}
1086 filterStgBinders :: [Var] -> [Var]
1087 filterStgBinders bndrs
1088   | opt_RuntimeTypes = bndrs
1089   | otherwise        = filter isId bndrs
1090 \end{code}
1091
1092
1093 \begin{code}
1094         -- Ignore all notes except SCC
1095 myCollectBinders expr
1096   = go [] expr
1097   where
1098     go bs (Lam b e)          = go (b:bs) e
1099     go bs e@(Note (SCC _) _) = (reverse bs, e)
1100     go bs (Cast e co)        = go bs e
1101     go bs (Note _ e)         = go bs e
1102     go bs e                  = (reverse bs, e)
1103
1104 myCollectArgs :: CoreExpr -> (Id, [CoreArg])
1105         -- We assume that we only have variables
1106         -- in the function position by now
1107 myCollectArgs expr
1108   = go expr []
1109   where
1110     go (Var v)          as = (v, as)
1111     go (App f a) as        = go f (a:as)
1112     go (Note (SCC _) e) as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1113     go (Cast e co)      as = go e as
1114     go (Note n e)       as = go e as
1115     go _                as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1116 \end{code}
1117
1118 \begin{code}
1119 stgArity :: Id -> HowBound -> Arity
1120 stgArity f (LetBound _ arity) = arity
1121 stgArity f ImportBound        = idArity f
1122 stgArity f LambdaBound        = 0
1123 \end{code}