compiler/stgSyn/CoreToStg.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[CoreToStg]{Converts Core to STG Syntax}
   5
   6 And, as we have the info in hand, we may convert some lets to
   7 let-no-escapes.
   8
   9 \begin{code}
  10 module CoreToStg ( coreToStg, coreExprToStg ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CoreSyn
  15 import CoreUtils        ( rhsIsStatic, manifestArity, exprType, findDefault )
  16 import StgSyn
  17
  18 import Type
  19 import TyCon            ( isAlgTyCon )
  20 import Id
  21 import Var              ( Var, globalIdDetails, idType )
  22 import TyCon            ( isUnboxedTupleTyCon, isPrimTyCon, isFunTyCon, isHiBootTyCon )
  23 import IdInfo
  24 import DataCon
  25 import CostCentre       ( noCCS )
  26 import VarSet
  27 import VarEnv
  28 import Maybes           ( maybeToBool )
  29 import Name             ( getOccName, isExternalName, nameOccName )
  30 import OccName          ( occNameString, occNameFS )
  31 import BasicTypes       ( Arity )
  32 import StaticFlags      ( opt_RuntimeTypes )
  33 import PackageConfig    ( PackageId )
  34 import Outputable
  35
  36 infixr 9 `thenLne`
  37 \end{code}
  38
  39 %************************************************************************
  40 %*                                                                      *
  41 \subsection[live-vs-free-doc]{Documentation}
  42 %*                                                                      *
  43 %************************************************************************
  44
  45 (There is other relevant documentation in codeGen/CgLetNoEscape.)
  46
  47 The actual Stg datatype is decorated with {\em live variable}
  48 information, as well as {\em free variable} information.  The two are
  49 {\em not} the same.  Liveness is an operational property rather than a
  50 semantic one.  A variable is live at a particular execution point if
  51 it can be referred to {\em directly} again.  In particular, a dead
  52 variable's stack slot (if it has one):
  53 \begin{enumerate}
  54 \item
  55 should be stubbed to avoid space leaks, and
  56 \item
  57 may be reused for something else.
  58 \end{enumerate}
  59
  60 There ought to be a better way to say this.  Here are some examples:
  61 \begin{verbatim}
  62         let v = [q] \[x] -> e
  63         in
  64         ...v...  (but no q's)
  65 \end{verbatim}
  66
  67 Just after the `in', v is live, but q is dead.  If the whole of that
  68 let expression was enclosed in a case expression, thus:
  69 \begin{verbatim}
  70         case (let v = [q] \[x] -> e in ...v...) of
  71                 alts[...q...]
  72 \end{verbatim}
  73 (ie @alts@ mention @q@), then @q@ is live even after the `in'; because
  74 we'll return later to the @alts@ and need it.
  75
  76 Let-no-escapes make this a bit more interesting:
  77 \begin{verbatim}
  78         let-no-escape v = [q] \ [x] -> e
  79         in
  80         ...v...
  81 \end{verbatim}
  82 Here, @q@ is still live at the `in', because @v@ is represented not by
  83 a closure but by the current stack state.  In other words, if @v@ is
  84 live then so is @q@.  Furthermore, if @e@ mentions an enclosing
  85 let-no-escaped variable, then {\em its} free variables are also live
  86 if @v@ is.
  87
  88 %************************************************************************
  89 %*                                                                      *
  90 \subsection[caf-info]{Collecting live CAF info}
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 In this pass we also collect information on which CAFs are live for
  95 constructing SRTs (see SRT.lhs).
  96
  97 A top-level Id has CafInfo, which is
  98
  99         - MayHaveCafRefs, if it may refer indirectly to
 100           one or more CAFs, or
 101         - NoCafRefs if it definitely doesn't
 102
 103 The CafInfo has already been calculated during the CoreTidy pass.
 104
 105 During CoreToStg, we then pin onto each binding and case expression, a
 106 list of Ids which represents the "live" CAFs at that point.  The meaning
 107 of "live" here is the same as for live variables, see above (which is
 108 why it's convenient to collect CAF information here rather than elsewhere).
 109
 110 The later SRT pass takes these lists of Ids and uses them to construct
 111 the actual nested SRTs, and replaces the lists of Ids with (offset,length)
 112 pairs.
 113
 114
 115 Interaction of let-no-escape with SRTs   [Sept 01]
 116 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 117 Consider
 118
 119         let-no-escape x = ...caf1...caf2...
 120         in
 121         ...x...x...x...
 122
 123 where caf1,caf2 are CAFs.  Since x doesn't have a closure, we
 124 build SRTs just as if x's defn was inlined at each call site, and
 125 that means that x's CAF refs get duplicated in the overall SRT.
 126
 127 This is unlike ordinary lets, in which the CAF refs are not duplicated.
 128
 129 We could fix this loss of (static) sharing by making a sort of pseudo-closure
 130 for x, solely to put in the SRTs lower down.
 131
 132
 133 %************************************************************************
 134 %*                                                                      *
 135 \subsection[binds-StgVarInfo]{Setting variable info: top-level, binds, RHSs}
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 coreToStg :: PackageId -> [CoreBind] -> IO [StgBinding]
 141 coreToStg this_pkg pgm
 142   = return pgm'
 143   where (_, _, pgm') = coreTopBindsToStg this_pkg emptyVarEnv pgm
 144
 145 coreExprToStg :: CoreExpr -> StgExpr
 146 coreExprToStg expr
 147   = new_expr where (new_expr,_,_) = initLne emptyVarEnv (coreToStgExpr expr)
 148
 149
 150 coreTopBindsToStg
 151     :: PackageId
 152     -> IdEnv HowBound           -- environment for the bindings
 153     -> [CoreBind]
 154     -> (IdEnv HowBound, FreeVarsInfo, [StgBinding])
 155
 156 coreTopBindsToStg this_pkg env [] = (env, emptyFVInfo, [])
 157 coreTopBindsToStg this_pkg env (b:bs)
 158   = (env2, fvs2, b':bs')
 159   where
 160         -- env accumulates down the list of binds, fvs accumulates upwards
 161         (env1, fvs2, b' ) = coreTopBindToStg this_pkg env fvs1 b
 162         (env2, fvs1, bs') = coreTopBindsToStg this_pkg env1 bs
 163
 164
 165 coreTopBindToStg
 166         :: PackageId
 167         -> IdEnv HowBound
 168         -> FreeVarsInfo         -- Info about the body
 169         -> CoreBind
 170         -> (IdEnv HowBound, FreeVarsInfo, StgBinding)
 171
 172 coreTopBindToStg this_pkg env body_fvs (NonRec id rhs)
 173   = let
 174         env'      = extendVarEnv env id how_bound
 175         how_bound = LetBound TopLet $! manifestArity rhs
 176
 177         (stg_rhs, fvs') =
 178             initLne env (
 179               coreToTopStgRhs this_pkg body_fvs (id,rhs)        `thenLne` \ (stg_rhs, fvs') ->
 180               returnLne (stg_rhs, fvs')
 181            )
 182
 183         bind = StgNonRec id stg_rhs
 184     in
 185     ASSERT2(manifestArity rhs == stgRhsArity stg_rhs, ppr id $$ (ptext SLIT("rhs:")) <+> ppr rhs $$ (ptext SLIT("stg_rhs:"))<+> ppr stg_rhs $$ (ptext SLIT("Manifest:")) <+> (ppr $ manifestArity rhs) $$ (ptext SLIT("STG:")) <+>(ppr $ stgRhsArity stg_rhs) )
 186     ASSERT2(consistentCafInfo id bind, ppr id)
 187 --    WARN(not (consistent caf_info bind), ppr id <+> ppr cafs <+> ppCafInfo caf_info)
 188     (env', fvs' `unionFVInfo` body_fvs, bind)
 189
 190 coreTopBindToStg this_pkg env body_fvs (Rec pairs)
 191   = let
 192         (binders, rhss) = unzip pairs
 193
 194         extra_env' = [ (b, LetBound TopLet $! manifestArity rhs)
 195                      | (b, rhs) <- pairs ]
 196         env' = extendVarEnvList env extra_env'
 197
 198         (stg_rhss, fvs')
 199           = initLne env' (
 200                mapAndUnzipLne (coreToTopStgRhs this_pkg body_fvs) pairs
 201                                                 `thenLne` \ (stg_rhss, fvss') ->
 202                let fvs' = unionFVInfos fvss' in
 203                returnLne (stg_rhss, fvs')
 204            )
 205
 206         bind = StgRec (zip binders stg_rhss)
 207     in
 208     ASSERT2(and [manifestArity rhs == stgRhsArity stg_rhs | (rhs,stg_rhs) <- rhss `zip` stg_rhss], ppr binders)
 209     ASSERT2(consistentCafInfo (head binders) bind, ppr binders)
 210     (env', fvs' `unionFVInfo` body_fvs, bind)
 211
 212 #ifdef DEBUG
 213 -- Assertion helper: this checks that the CafInfo on the Id matches
 214 -- what CoreToStg has figured out about the binding's SRT.  The
 215 -- CafInfo will be exact in all cases except when CorePrep has
 216 -- floated out a binding, in which case it will be approximate.
 217 consistentCafInfo id bind
 218   | occNameFS (nameOccName (idName id)) == FSLIT("sat")
 219   = safe
 220   | otherwise
 221   = WARN (not exact, ppr id) safe
 222   where
 223         safe  = id_marked_caffy || not binding_is_caffy
 224         exact = id_marked_caffy == binding_is_caffy
 225         id_marked_caffy  = mayHaveCafRefs (idCafInfo id)
 226         binding_is_caffy = stgBindHasCafRefs bind
 227 #endif
 228 \end{code}
 229
 230 \begin{code}
 231 coreToTopStgRhs
 232         :: PackageId
 233         -> FreeVarsInfo         -- Free var info for the scope of the binding
 234         -> (Id,CoreExpr)
 235         -> LneM (StgRhs, FreeVarsInfo)
 236
 237 coreToTopStgRhs this_pkg scope_fv_info (bndr, rhs)
 238   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, _) ->
 239     freeVarsToLiveVars rhs_fvs  `thenLne` \ lv_info ->
 240     returnLne (mkTopStgRhs is_static rhs_fvs (mkSRT lv_info) bndr_info new_rhs, rhs_fvs)
 241   where
 242     bndr_info = lookupFVInfo scope_fv_info bndr
 243     is_static = rhsIsStatic this_pkg rhs
 244
 245 mkTopStgRhs :: Bool -> FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr
 246         -> StgRhs
 247
 248 mkTopStgRhs is_static rhs_fvs srt binder_info (StgLam _ bndrs body)
 249   = ASSERT( is_static )
 250     StgRhsClosure noCCS binder_info
 251                   (getFVs rhs_fvs)
 252                   ReEntrant
 253                   srt
 254                   bndrs body
 255
 256 mkTopStgRhs is_static rhs_fvs srt binder_info (StgConApp con args)
 257   | is_static    -- StgConApps can be updatable (see isCrossDllConApp)
 258   = StgRhsCon noCCS con args
 259
 260 mkTopStgRhs is_static rhs_fvs srt binder_info rhs
 261   = ASSERT2( not is_static, ppr rhs )
 262     StgRhsClosure noCCS binder_info
 263                   (getFVs rhs_fvs)
 264                   Updatable
 265                   srt
 266                   [] rhs
 267 \end{code}
 268
 269
 270 -- ---------------------------------------------------------------------------
 271 -- Expressions
 272 -- ---------------------------------------------------------------------------
 273
 274 \begin{code}
 275 coreToStgExpr
 276         :: CoreExpr
 277         -> LneM (StgExpr,       -- Decorated STG expr
 278                  FreeVarsInfo,  -- Its free vars (NB free, not live)
 279                  EscVarsSet)    -- Its escapees, a subset of its free vars;
 280                                 -- also a subset of the domain of the envt
 281                                 -- because we are only interested in the escapees
 282                                 -- for vars which might be turned into
 283                                 -- let-no-escaped ones.
 284 \end{code}
 285
 286 The second and third components can be derived in a simple bottom up pass, not
 287 dependent on any decisions about which variables will be let-no-escaped or
 288 not.  The first component, that is, the decorated expression, may then depend
 289 on these components, but it in turn is not scrutinised as the basis for any
 290 decisions.  Hence no black holes.
 291
 292 \begin{code}
 293 coreToStgExpr (Lit l) = returnLne (StgLit l, emptyFVInfo, emptyVarSet)
 294 coreToStgExpr (Var v) = coreToStgApp Nothing v []
 295
 296 coreToStgExpr expr@(App _ _)
 297   = coreToStgApp Nothing f args
 298   where
 299     (f, args) = myCollectArgs expr
 300
 301 coreToStgExpr expr@(Lam _ _)
 302   = let
 303         (args, body) = myCollectBinders expr
 304         args'        = filterStgBinders args
 305     in
 306     extendVarEnvLne [ (a, LambdaBound) | a <- args' ] $
 307     coreToStgExpr body  `thenLne` \ (body, body_fvs, body_escs) ->
 308     let
 309         fvs             = args' `minusFVBinders` body_fvs
 310         escs            = body_escs `delVarSetList` args'
 311         result_expr | null args' = body
 312                     | otherwise  = StgLam (exprType expr) args' body
 313     in
 314     returnLne (result_expr, fvs, escs)
 315
 316 coreToStgExpr (Note (SCC cc) expr)
 317   = coreToStgExpr expr          `thenLne` ( \ (expr2, fvs, escs) ->
 318     returnLne (StgSCC cc expr2, fvs, escs) )
 319
 320 coreToStgExpr (Case (Var id) _bndr ty [(DEFAULT,[],expr)])
 321   | Just (TickBox m n) <- isTickBoxOp_maybe id
 322   = coreToStgExpr expr         `thenLne` ( \ (expr2, fvs, escs) ->
 323     returnLne (StgTick m n expr2, fvs, escs) )
 324
 325 coreToStgExpr (Note other_note expr)
 326   = coreToStgExpr expr
 327
 328 coreToStgExpr (Cast expr co)
 329   = coreToStgExpr expr
 330
 331 -- Cases require a little more real work.
 332
 333 coreToStgExpr (Case scrut bndr _ alts)
 334   = extendVarEnvLne [(bndr, LambdaBound)]       (
 335          mapAndUnzip3Lne vars_alt alts  `thenLne` \ (alts2, fvs_s, escs_s) ->
 336          returnLne ( alts2,
 337                      unionFVInfos fvs_s,
 338                      unionVarSets escs_s )
 339     )                                   `thenLne` \ (alts2, alts_fvs, alts_escs) ->
 340     let
 341         -- Determine whether the default binder is dead or not
 342         -- This helps the code generator to avoid generating an assignment
 343         -- for the case binder (is extremely rare cases) ToDo: remove.
 344         bndr' | bndr `elementOfFVInfo` alts_fvs = bndr
 345               | otherwise                       = bndr `setIdOccInfo` IAmDead
 346
 347         -- Don't consider the default binder as being 'live in alts',
 348         -- since this is from the point of view of the case expr, where
 349         -- the default binder is not free.
 350         alts_fvs_wo_bndr  = bndr `minusFVBinder` alts_fvs
 351         alts_escs_wo_bndr = alts_escs `delVarSet` bndr
 352     in
 353
 354     freeVarsToLiveVars alts_fvs_wo_bndr         `thenLne` \ alts_lv_info ->
 355
 356         -- We tell the scrutinee that everything
 357         -- live in the alts is live in it, too.
 358     setVarsLiveInCont alts_lv_info (
 359         coreToStgExpr scrut       `thenLne` \ (scrut2, scrut_fvs, scrut_escs) ->
 360         freeVarsToLiveVars scrut_fvs `thenLne` \ scrut_lv_info ->
 361         returnLne (scrut2, scrut_fvs, scrut_escs, scrut_lv_info)
 362       )
 363                 `thenLne` \ (scrut2, scrut_fvs, scrut_escs, scrut_lv_info) ->
 364
 365     returnLne (
 366       StgCase scrut2 (getLiveVars scrut_lv_info)
 367                      (getLiveVars alts_lv_info)
 368                      bndr'
 369                      (mkSRT alts_lv_info)
 370                      (mkStgAltType (idType bndr) alts)
 371                      alts2,
 372       scrut_fvs `unionFVInfo` alts_fvs_wo_bndr,
 373       alts_escs_wo_bndr `unionVarSet` getFVSet scrut_fvs
 374                 -- You might think we should have scrut_escs, not
 375                 -- (getFVSet scrut_fvs), but actually we can't call, and
 376                 -- then return from, a let-no-escape thing.
 377       )
 378   where
 379     vars_alt (con, binders, rhs)
 380       = let     -- Remove type variables
 381             binders' = filterStgBinders binders
 382         in
 383         extendVarEnvLne [(b, LambdaBound) | b <- binders']      $
 384         coreToStgExpr rhs       `thenLne` \ (rhs2, rhs_fvs, rhs_escs) ->
 385         let
 386                 -- Records whether each param is used in the RHS
 387             good_use_mask = [ b `elementOfFVInfo` rhs_fvs | b <- binders' ]
 388         in
 389         returnLne ( (con, binders', good_use_mask, rhs2),
 390                     binders' `minusFVBinders` rhs_fvs,
 391                     rhs_escs `delVarSetList` binders' )
 392                 -- ToDo: remove the delVarSet;
 393                 -- since escs won't include any of these binders
 394 \end{code}
 395
 396 Lets not only take quite a bit of work, but this is where we convert
 397 then to let-no-escapes, if we wish.
 398
 399 (Meanwhile, we don't expect to see let-no-escapes...)
 400 \begin{code}
 401 coreToStgExpr (Let bind body)
 402   = fixLne (\ ~(_, _, _, no_binder_escapes) ->
 403         coreToStgLet no_binder_escapes bind body
 404     )                           `thenLne` \ (new_let, fvs, escs, _) ->
 405
 406     returnLne (new_let, fvs, escs)
 407 \end{code}
 408
 409 \begin{code}
 410 mkStgAltType scrut_ty alts
 411   = case splitTyConApp_maybe (repType scrut_ty) of
 412         Just (tc,_) | isUnboxedTupleTyCon tc -> UbxTupAlt tc
 413                     | isPrimTyCon tc         -> PrimAlt tc
 414                     | isHiBootTyCon tc       -> look_for_better_tycon
 415                     | isAlgTyCon tc          -> AlgAlt tc
 416                     | isFunTyCon tc          -> PolyAlt
 417                     | otherwise              -> pprPanic "mkStgAlts" (ppr tc)
 418         Nothing                              -> PolyAlt
 419
 420   where
 421    -- Sometimes, the TyCon in the type of the scrutinee is an HiBootTyCon,
 422    -- which may not have any constructors inside it.  If so, then we
 423    -- can get a better TyCon by grabbing the one from a constructor alternative
 424    -- if one exists.
 425    look_for_better_tycon
 426         | ((DataAlt con, _, _) : _) <- data_alts =
 427                 AlgAlt (dataConTyCon con)
 428         | otherwise =
 429                 ASSERT(null data_alts)
 430                 PolyAlt
 431         where
 432                 (data_alts, _deflt) = findDefault alts
 433 \end{code}
 434
 435
 436 -- ---------------------------------------------------------------------------
 437 -- Applications
 438 -- ---------------------------------------------------------------------------
 439
 440 \begin{code}
 441 coreToStgApp
 442          :: Maybe UpdateFlag            -- Just upd <=> this application is
 443                                         -- the rhs of a thunk binding
 444                                         --      x = [...] \upd [] -> the_app
 445                                         -- with specified update flag
 446         -> Id                           -- Function
 447         -> [CoreArg]                    -- Arguments
 448         -> LneM (StgExpr, FreeVarsInfo, EscVarsSet)
 449
 450
 451 coreToStgApp maybe_thunk_body f args
 452   = coreToStgArgs args          `thenLne` \ (args', args_fvs) ->
 453     lookupVarLne f              `thenLne` \ how_bound ->
 454
 455     let
 456         n_val_args       = valArgCount args
 457         not_letrec_bound = not (isLetBound how_bound)
 458         fun_fvs
 459           = let fvs = singletonFVInfo f how_bound fun_occ in
 460             -- e.g. (f :: a -> int) (x :: a)
 461             -- Here the free variables are "f", "x" AND the type variable "a"
 462             -- coreToStgArgs will deal with the arguments recursively
 463             if opt_RuntimeTypes then
 464               fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType (idType f))
 465             else fvs
 466
 467         -- Mostly, the arity info of a function is in the fn's IdInfo
 468         -- But new bindings introduced by CoreSat may not have no
 469         -- arity info; it would do us no good anyway.  For example:
 470         --      let f = \ab -> e in f
 471         -- No point in having correct arity info for f!
 472         -- Hence the hasArity stuff below.
 473         -- NB: f_arity is only consulted for LetBound things
 474         f_arity   = stgArity f how_bound
 475         saturated = f_arity <= n_val_args
 476
 477         fun_occ
 478          | not_letrec_bound         = noBinderInfo      -- Uninteresting variable
 479          | f_arity > 0 && saturated = stgSatOcc -- Saturated or over-saturated function call
 480          | otherwise                = stgUnsatOcc       -- Unsaturated function or thunk
 481
 482         fun_escs
 483          | not_letrec_bound      = emptyVarSet  -- Only letrec-bound escapees are interesting
 484          | f_arity == n_val_args = emptyVarSet  -- A function *or thunk* with an exactly
 485                                                 -- saturated call doesn't escape
 486                                                 -- (let-no-escape applies to 'thunks' too)
 487
 488          | otherwise         = unitVarSet f     -- Inexact application; it does escape
 489
 490         -- At the moment of the call:
 491
 492         --  either the function is *not* let-no-escaped, in which case
 493         --         nothing is live except live_in_cont
 494         --      or the function *is* let-no-escaped in which case the
 495         --         variables it uses are live, but still the function
 496         --         itself is not.  PS.  In this case, the function's
 497         --         live vars should already include those of the
 498         --         continuation, but it does no harm to just union the
 499         --         two regardless.
 500
 501         res_ty = exprType (mkApps (Var f) args)
 502         app = case globalIdDetails f of
 503                 DataConWorkId dc | saturated -> StgConApp dc args'
 504                 PrimOpId op      -> ASSERT( saturated )
 505                                     StgOpApp (StgPrimOp op) args' res_ty
 506                 FCallId call     -> ASSERT( saturated )
 507                                     StgOpApp (StgFCallOp call (idUnique f)) args' res_ty
 508                 TickBoxOpId {}   -> pprPanic "coreToStg TickBox" $ ppr (f,args')
 509                 _other           -> StgApp f args'
 510
 511     in
 512     returnLne (
 513         app,
 514         fun_fvs  `unionFVInfo` args_fvs,
 515         fun_escs `unionVarSet` (getFVSet args_fvs)
 516                                 -- All the free vars of the args are disqualified
 517                                 -- from being let-no-escaped.
 518     )
 519
 520
 521
 522 -- ---------------------------------------------------------------------------
 523 -- Argument lists
 524 -- This is the guy that turns applications into A-normal form
 525 -- ---------------------------------------------------------------------------
 526
 527 coreToStgArgs :: [CoreArg] -> LneM ([StgArg], FreeVarsInfo)
 528 coreToStgArgs []
 529   = returnLne ([], emptyFVInfo)
 530
 531 coreToStgArgs (Type ty : args)  -- Type argument
 532   = coreToStgArgs args  `thenLne` \ (args', fvs) ->
 533     if opt_RuntimeTypes then
 534         returnLne (StgTypeArg ty : args', fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType ty))
 535     else
 536     returnLne (args', fvs)
 537
 538 coreToStgArgs (arg : args)      -- Non-type argument
 539   = coreToStgArgs args  `thenLne` \ (stg_args, args_fvs) ->
 540     coreToStgExpr arg   `thenLne` \ (arg', arg_fvs, escs) ->
 541     let
 542         fvs = args_fvs `unionFVInfo` arg_fvs
 543         stg_arg = case arg' of
 544                        StgApp v []      -> StgVarArg v
 545                        StgConApp con [] -> StgVarArg (dataConWorkId con)
 546                        StgLit lit       -> StgLitArg lit
 547                        _                -> pprPanic "coreToStgArgs" (ppr arg)
 548     in
 549         -- WARNING: what if we have an argument like (v `cast` co)
 550         --          where 'co' changes the representation type?
 551         --          (This really only happens if co is unsafe.)
 552         -- Then all the getArgAmode stuff in CgBindery will set the
 553         -- cg_rep of the CgIdInfo based on the type of v, rather
 554         -- than the type of 'co'.
 555         -- This matters particularly when the function is a primop
 556         -- or foreign call.
 557         -- Wanted: a better solution than this hacky warning
 558     let
 559         arg_ty = exprType arg
 560         stg_arg_ty = stgArgType stg_arg
 561     in
 562     WARN( isUnLiftedType arg_ty /= isUnLiftedType stg_arg_ty,
 563           ptext SLIT("Dangerous-looking argument. Probable cause: bad unsafeCoerce#") $$ ppr arg)
 564     returnLne (stg_arg : stg_args, fvs)
 565
 566
 567 -- ---------------------------------------------------------------------------
 568 -- The magic for lets:
 569 -- ---------------------------------------------------------------------------
 570
 571 coreToStgLet
 572          :: Bool        -- True <=> yes, we are let-no-escaping this let
 573          -> CoreBind    -- bindings
 574          -> CoreExpr    -- body
 575          -> LneM (StgExpr,      -- new let
 576                   FreeVarsInfo, -- variables free in the whole let
 577                   EscVarsSet,   -- variables that escape from the whole let
 578                   Bool)         -- True <=> none of the binders in the bindings
 579                                 -- is among the escaping vars
 580
 581 coreToStgLet let_no_escape bind body
 582   = fixLne (\ ~(_, _, _, _, _, rec_body_fvs, _, _) ->
 583
 584         -- Do the bindings, setting live_in_cont to empty if
 585         -- we ain't in a let-no-escape world
 586         getVarsLiveInCont               `thenLne` \ live_in_cont ->
 587         setVarsLiveInCont (if let_no_escape
 588                                 then live_in_cont
 589                                 else emptyLiveInfo)
 590                           (vars_bind rec_body_fvs bind)
 591             `thenLne` \ ( bind2, bind_fvs, bind_escs, bind_lv_info, env_ext) ->
 592
 593         -- Do the body
 594         extendVarEnvLne env_ext (
 595           coreToStgExpr body          `thenLne` \(body2, body_fvs, body_escs) ->
 596           freeVarsToLiveVars body_fvs `thenLne` \ body_lv_info ->
 597
 598           returnLne (bind2, bind_fvs, bind_escs, getLiveVars bind_lv_info,
 599                      body2, body_fvs, body_escs, getLiveVars body_lv_info)
 600         )
 601
 602     ) `thenLne` (\ (bind2, bind_fvs, bind_escs, bind_lvs,
 603                     body2, body_fvs, body_escs, body_lvs) ->
 604
 605
 606         -- Compute the new let-expression
 607     let
 608         new_let | let_no_escape = StgLetNoEscape live_in_whole_let bind_lvs bind2 body2
 609                 | otherwise     = StgLet bind2 body2
 610
 611         free_in_whole_let
 612           = binders `minusFVBinders` (bind_fvs `unionFVInfo` body_fvs)
 613
 614         live_in_whole_let
 615           = bind_lvs `unionVarSet` (body_lvs `delVarSetList` binders)
 616
 617         real_bind_escs = if let_no_escape then
 618                             bind_escs
 619                          else
 620                             getFVSet bind_fvs
 621                             -- Everything escapes which is free in the bindings
 622
 623         let_escs = (real_bind_escs `unionVarSet` body_escs) `delVarSetList` binders
 624
 625         all_escs = bind_escs `unionVarSet` body_escs    -- Still includes binders of
 626                                                         -- this let(rec)
 627
 628         no_binder_escapes = isEmptyVarSet (set_of_binders `intersectVarSet` all_escs)
 629
 630 #ifdef DEBUG
 631         -- Debugging code as requested by Andrew Kennedy
 632         checked_no_binder_escapes
 633                 | not no_binder_escapes && any is_join_var binders
 634                 = pprTrace "Interesting!  A join var that isn't let-no-escaped" (ppr binders)
 635                   False
 636                 | otherwise = no_binder_escapes
 637 #else
 638         checked_no_binder_escapes = no_binder_escapes
 639 #endif
 640
 641                 -- Mustn't depend on the passed-in let_no_escape flag, since
 642                 -- no_binder_escapes is used by the caller to derive the flag!
 643     in
 644     returnLne (
 645         new_let,
 646         free_in_whole_let,
 647         let_escs,
 648         checked_no_binder_escapes
 649     ))
 650   where
 651     set_of_binders = mkVarSet binders
 652     binders        = bindersOf bind
 653
 654     mk_binding bind_lv_info binder rhs
 655         = (binder, LetBound (NestedLet live_vars) (manifestArity rhs))
 656         where
 657            live_vars | let_no_escape = addLiveVar bind_lv_info binder
 658                      | otherwise     = unitLiveVar binder
 659                 -- c.f. the invariant on NestedLet
 660
 661     vars_bind :: FreeVarsInfo           -- Free var info for body of binding
 662               -> CoreBind
 663               -> LneM (StgBinding,
 664                        FreeVarsInfo,
 665                        EscVarsSet,        -- free vars; escapee vars
 666                        LiveInfo,          -- Vars and CAFs live in binding
 667                        [(Id, HowBound)])  -- extension to environment
 668
 669
 670     vars_bind body_fvs (NonRec binder rhs)
 671       = coreToStgRhs body_fvs [] (binder,rhs)
 672                                 `thenLne` \ (rhs2, bind_fvs, bind_lv_info, escs) ->
 673         let
 674             env_ext_item = mk_binding bind_lv_info binder rhs
 675         in
 676         returnLne (StgNonRec binder rhs2,
 677                    bind_fvs, escs, bind_lv_info, [env_ext_item])
 678
 679
 680     vars_bind body_fvs (Rec pairs)
 681       = fixLne (\ ~(_, rec_rhs_fvs, _, bind_lv_info, _) ->
 682            let
 683                 rec_scope_fvs = unionFVInfo body_fvs rec_rhs_fvs
 684                 binders = map fst pairs
 685                 env_ext = [ mk_binding bind_lv_info b rhs
 686                           | (b,rhs) <- pairs ]
 687            in
 688            extendVarEnvLne env_ext (
 689               mapAndUnzip4Lne (coreToStgRhs rec_scope_fvs binders) pairs
 690                                         `thenLne` \ (rhss2, fvss, lv_infos, escss) ->
 691               let
 692                         bind_fvs = unionFVInfos fvss
 693                         bind_lv_info = foldr unionLiveInfo emptyLiveInfo lv_infos
 694                         escs     = unionVarSets escss
 695               in
 696               returnLne (StgRec (binders `zip` rhss2),
 697                          bind_fvs, escs, bind_lv_info, env_ext)
 698            )
 699         )
 700
 701 is_join_var :: Id -> Bool
 702 -- A hack (used only for compiler debuggging) to tell if
 703 -- a variable started life as a join point ($j)
 704 is_join_var j = occNameString (getOccName j) == "$j"
 705 \end{code}
 706
 707 \begin{code}
 708 coreToStgRhs :: FreeVarsInfo            -- Free var info for the scope of the binding
 709              -> [Id]
 710              -> (Id,CoreExpr)
 711              -> LneM (StgRhs, FreeVarsInfo, LiveInfo, EscVarsSet)
 712
 713 coreToStgRhs scope_fv_info binders (bndr, rhs)
 714   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, rhs_escs) ->
 715     getEnvLne                   `thenLne` \ env ->
 716     freeVarsToLiveVars (binders `minusFVBinders` rhs_fvs) `thenLne` \ lv_info ->
 717     returnLne (mkStgRhs rhs_fvs (mkSRT lv_info) bndr_info new_rhs,
 718                rhs_fvs, lv_info, rhs_escs)
 719   where
 720     bndr_info = lookupFVInfo scope_fv_info bndr
 721
 722 mkStgRhs :: FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr -> StgRhs
 723
 724 mkStgRhs rhs_fvs srt binder_info (StgConApp con args)
 725   = StgRhsCon noCCS con args
 726
 727 mkStgRhs rhs_fvs srt binder_info (StgLam _ bndrs body)
 728   = StgRhsClosure noCCS binder_info
 729                   (getFVs rhs_fvs)
 730                   ReEntrant
 731                   srt bndrs body
 732
 733 mkStgRhs rhs_fvs srt binder_info rhs
 734   = StgRhsClosure noCCS binder_info
 735                   (getFVs rhs_fvs)
 736                   upd_flag srt [] rhs
 737   where
 738    upd_flag = Updatable
 739   {-
 740     SDM: disabled.  Eval/Apply can't handle functions with arity zero very
 741     well; and making these into simple non-updatable thunks breaks other
 742     assumptions (namely that they will be entered only once).
 743
 744     upd_flag | isPAP env rhs  = ReEntrant
 745              | otherwise      = Updatable
 746   -}
 747
 748 {- ToDo:
 749           upd = if isOnceDem dem
 750                     then (if isNotTop toplev
 751                             then SingleEntry    -- HA!  Paydirt for "dem"
 752                             else
 753 #ifdef DEBUG
 754                      trace "WARNING: SE CAFs unsupported, forcing UPD instead" $
 755 #endif
 756                      Updatable)
 757                 else Updatable
 758         -- For now we forbid SingleEntry CAFs; they tickle the
 759         -- ASSERT in rts/Storage.c line 215 at newCAF() re mut_link,
 760         -- and I don't understand why.  There's only one SE_CAF (well,
 761         -- only one that tickled a great gaping bug in an earlier attempt
 762         -- at ClosureInfo.getEntryConvention) in the whole of nofib,
 763         -- specifically Main.lvl6 in spectral/cryptarithm2.
 764         -- So no great loss.  KSW 2000-07.
 765 -}
 766 \end{code}
 767
 768 Detect thunks which will reduce immediately to PAPs, and make them
 769 non-updatable.  This has several advantages:
 770
 771         - the non-updatable thunk behaves exactly like the PAP,
 772
 773         - the thunk is more efficient to enter, because it is
 774           specialised to the task.
 775
 776         - we save one update frame, one stg_update_PAP, one update
 777           and lots of PAP_enters.
 778
 779         - in the case where the thunk is top-level, we save building
 780           a black hole and futhermore the thunk isn't considered to
 781           be a CAF any more, so it doesn't appear in any SRTs.
 782
 783 We do it here, because the arity information is accurate, and we need
 784 to do it before the SRT pass to save the SRT entries associated with
 785 any top-level PAPs.
 786
 787 isPAP env (StgApp f args) = listLengthCmp args arity == LT -- idArity f > length args
 788                           where
 789                             arity = stgArity f (lookupBinding env f)
 790 isPAP env _               = False
 791
 792
 793 %************************************************************************
 794 %*                                                                      *
 795 \subsection[LNE-monad]{A little monad for this let-no-escaping pass}
 796 %*                                                                      *
 797 %************************************************************************
 798
 799 There's a lot of stuff to pass around, so we use this @LneM@ monad to
 800 help.  All the stuff here is only passed *down*.
 801
 802 \begin{code}
 803 type LneM a =  IdEnv HowBound
 804             -> LiveInfo         -- Vars and CAFs live in continuation
 805             -> a
 806
 807 type LiveInfo = (StgLiveVars,   -- Dynamic live variables;
 808                                 -- i.e. ones with a nested (non-top-level) binding
 809                  CafSet)        -- Static live variables;
 810                                 -- i.e. top-level variables that are CAFs or refer to them
 811
 812 type EscVarsSet = IdSet
 813 type CafSet     = IdSet
 814
 815 data HowBound
 816   = ImportBound         -- Used only as a response to lookupBinding; never
 817                         -- exists in the range of the (IdEnv HowBound)
 818
 819   | LetBound            -- A let(rec) in this module
 820         LetInfo         -- Whether top level or nested
 821         Arity           -- Its arity (local Ids don't have arity info at this point)
 822
 823   | LambdaBound         -- Used for both lambda and case
 824
 825 data LetInfo
 826   = TopLet              -- top level things
 827   | NestedLet LiveInfo  -- For nested things, what is live if this
 828                         -- thing is live?  Invariant: the binder
 829                         -- itself is always a member of
 830                         -- the dynamic set of its own LiveInfo
 831
 832 isLetBound (LetBound _ _) = True
 833 isLetBound other          = False
 834
 835 topLevelBound ImportBound         = True
 836 topLevelBound (LetBound TopLet _) = True
 837 topLevelBound other               = False
 838 \end{code}
 839
 840 For a let(rec)-bound variable, x, we record LiveInfo, the set of
 841 variables that are live if x is live.  This LiveInfo comprises
 842         (a) dynamic live variables (ones with a non-top-level binding)
 843         (b) static live variabes (CAFs or things that refer to CAFs)
 844
 845 For "normal" variables (a) is just x alone.  If x is a let-no-escaped
 846 variable then x is represented by a code pointer and a stack pointer
 847 (well, one for each stack).  So all of the variables needed in the
 848 execution of x are live if x is, and are therefore recorded in the
 849 LetBound constructor; x itself *is* included.
 850
 851 The set of dynamic live variables is guaranteed ot have no further let-no-escaped
 852 variables in it.
 853
 854 \begin{code}
 855 emptyLiveInfo :: LiveInfo
 856 emptyLiveInfo = (emptyVarSet,emptyVarSet)
 857
 858 unitLiveVar :: Id -> LiveInfo
 859 unitLiveVar lv = (unitVarSet lv, emptyVarSet)
 860
 861 unitLiveCaf :: Id -> LiveInfo
 862 unitLiveCaf caf = (emptyVarSet, unitVarSet caf)
 863
 864 addLiveVar :: LiveInfo -> Id -> LiveInfo
 865 addLiveVar (lvs, cafs) id = (lvs `extendVarSet` id, cafs)
 866
 867 unionLiveInfo :: LiveInfo -> LiveInfo -> LiveInfo
 868 unionLiveInfo (lv1,caf1) (lv2,caf2) = (lv1 `unionVarSet` lv2, caf1 `unionVarSet` caf2)
 869
 870 mkSRT :: LiveInfo -> SRT
 871 mkSRT (_, cafs) = SRTEntries cafs
 872
 873 getLiveVars :: LiveInfo -> StgLiveVars
 874 getLiveVars (lvs, _) = lvs
 875 \end{code}
 876
 877
 878 The std monad functions:
 879 \begin{code}
 880 initLne :: IdEnv HowBound -> LneM a -> a
 881 initLne env m = m env emptyLiveInfo
 882
 883
 884
 885 {-# INLINE thenLne #-}
 886 {-# INLINE returnLne #-}
 887
 888 returnLne :: a -> LneM a
 889 returnLne e env lvs_cont = e
 890
 891 thenLne :: LneM a -> (a -> LneM b) -> LneM b
 892 thenLne m k env lvs_cont
 893   = k (m env lvs_cont) env lvs_cont
 894
 895 mapAndUnzipLne  :: (a -> LneM (b,c))   -> [a] -> LneM ([b],[c])
 896 mapAndUnzipLne f [] = returnLne ([],[])
 897 mapAndUnzipLne f (x:xs)
 898   = f x                 `thenLne` \ (r1,  r2)  ->
 899     mapAndUnzipLne f xs `thenLne` \ (rs1, rs2) ->
 900     returnLne (r1:rs1, r2:rs2)
 901
 902 mapAndUnzip3Lne :: (a -> LneM (b,c,d)) -> [a] -> LneM ([b],[c],[d])
 903 mapAndUnzip3Lne f []    = returnLne ([],[],[])
 904 mapAndUnzip3Lne f (x:xs)
 905   = f x                  `thenLne` \ (r1,  r2,  r3)  ->
 906     mapAndUnzip3Lne f xs `thenLne` \ (rs1, rs2, rs3) ->
 907     returnLne (r1:rs1, r2:rs2, r3:rs3)
 908
 909 mapAndUnzip4Lne :: (a -> LneM (b,c,d,e)) -> [a] -> LneM ([b],[c],[d],[e])
 910 mapAndUnzip4Lne f []    = returnLne ([],[],[],[])
 911 mapAndUnzip4Lne f (x:xs)
 912   = f x                  `thenLne` \ (r1,  r2,  r3, r4)  ->
 913     mapAndUnzip4Lne f xs `thenLne` \ (rs1, rs2, rs3, rs4) ->
 914     returnLne (r1:rs1, r2:rs2, r3:rs3, r4:rs4)
 915
 916 fixLne :: (a -> LneM a) -> LneM a
 917 fixLne expr env lvs_cont
 918   = result
 919   where
 920     result = expr result env lvs_cont
 921 \end{code}
 922
 923 Functions specific to this monad:
 924
 925 \begin{code}
 926 getVarsLiveInCont :: LneM LiveInfo
 927 getVarsLiveInCont env lvs_cont = lvs_cont
 928
 929 setVarsLiveInCont :: LiveInfo -> LneM a -> LneM a
 930 setVarsLiveInCont new_lvs_cont expr env lvs_cont
 931   = expr env new_lvs_cont
 932
 933 extendVarEnvLne :: [(Id, HowBound)] -> LneM a -> LneM a
 934 extendVarEnvLne ids_w_howbound expr env lvs_cont
 935   = expr (extendVarEnvList env ids_w_howbound) lvs_cont
 936
 937 lookupVarLne :: Id -> LneM HowBound
 938 lookupVarLne v env lvs_cont = returnLne (lookupBinding env v) env lvs_cont
 939
 940 getEnvLne :: LneM (IdEnv HowBound)
 941 getEnvLne env lvs_cont = returnLne env env lvs_cont
 942
 943 lookupBinding :: IdEnv HowBound -> Id -> HowBound
 944 lookupBinding env v = case lookupVarEnv env v of
 945                         Just xx -> xx
 946                         Nothing -> ASSERT2( isGlobalId v, ppr v ) ImportBound
 947
 948
 949 -- The result of lookupLiveVarsForSet, a set of live variables, is
 950 -- only ever tacked onto a decorated expression. It is never used as
 951 -- the basis of a control decision, which might give a black hole.
 952
 953 freeVarsToLiveVars :: FreeVarsInfo -> LneM LiveInfo
 954 freeVarsToLiveVars fvs env live_in_cont
 955   = returnLne live_info env live_in_cont
 956   where
 957     live_info    = foldr unionLiveInfo live_in_cont lvs_from_fvs
 958     lvs_from_fvs = map do_one (allFreeIds fvs)
 959
 960     do_one (v, how_bound)
 961       = case how_bound of
 962           ImportBound                     -> unitLiveCaf v      -- Only CAF imports are
 963                                                                 -- recorded in fvs
 964           LetBound TopLet _
 965                 | mayHaveCafRefs (idCafInfo v) -> unitLiveCaf v
 966                 | otherwise                    -> emptyLiveInfo
 967
 968           LetBound (NestedLet lvs) _      -> lvs        -- lvs already contains v
 969                                                         -- (see the invariant on NestedLet)
 970
 971           _lambda_or_case_binding         -> unitLiveVar v      -- Bound by lambda or case
 972 \end{code}
 973
 974 %************************************************************************
 975 %*                                                                      *
 976 \subsection[Free-var info]{Free variable information}
 977 %*                                                                      *
 978 %************************************************************************
 979
 980 \begin{code}
 981 type FreeVarsInfo = VarEnv (Var, HowBound, StgBinderInfo)
 982         -- The Var is so we can gather up the free variables
 983         -- as a set.
 984         --
 985         -- The HowBound info just saves repeated lookups;
 986         -- we look up just once when we encounter the occurrence.
 987         -- INVARIANT: Any ImportBound Ids are HaveCafRef Ids
 988         --            Imported Ids without CAF refs are simply
 989         --            not put in the FreeVarsInfo for an expression.
 990         --            See singletonFVInfo and freeVarsToLiveVars
 991         --
 992         -- StgBinderInfo records how it occurs; notably, we
 993         -- are interested in whether it only occurs in saturated
 994         -- applications, because then we don't need to build a
 995         -- curried version.
 996         -- If f is mapped to noBinderInfo, that means
 997         -- that f *is* mentioned (else it wouldn't be in the
 998         -- IdEnv at all), but perhaps in an unsaturated applications.
 999         --
1000         -- All case/lambda-bound things are also mapped to
1001         -- noBinderInfo, since we aren't interested in their
1002         -- occurence info.
1003         --
1004         -- For ILX we track free var info for type variables too;
1005         -- hence VarEnv not IdEnv
1006 \end{code}
1007
1008 \begin{code}
1009 emptyFVInfo :: FreeVarsInfo
1010 emptyFVInfo = emptyVarEnv
1011
1012 singletonFVInfo :: Id -> HowBound -> StgBinderInfo -> FreeVarsInfo
1013 -- Don't record non-CAF imports at all, to keep free-var sets small
1014 singletonFVInfo id ImportBound info
1015    | mayHaveCafRefs (idCafInfo id) = unitVarEnv id (id, ImportBound, info)
1016    | otherwise                     = emptyVarEnv
1017 singletonFVInfo id how_bound info  = unitVarEnv id (id, how_bound, info)
1018
1019 tyvarFVInfo :: TyVarSet -> FreeVarsInfo
1020 tyvarFVInfo tvs = foldVarSet add emptyFVInfo tvs
1021         where
1022           add tv fvs = extendVarEnv fvs tv (tv, LambdaBound, noBinderInfo)
1023                 -- Type variables must be lambda-bound
1024
1025 unionFVInfo :: FreeVarsInfo -> FreeVarsInfo -> FreeVarsInfo
1026 unionFVInfo fv1 fv2 = plusVarEnv_C plusFVInfo fv1 fv2
1027
1028 unionFVInfos :: [FreeVarsInfo] -> FreeVarsInfo
1029 unionFVInfos fvs = foldr unionFVInfo emptyFVInfo fvs
1030
1031 minusFVBinders :: [Id] -> FreeVarsInfo -> FreeVarsInfo
1032 minusFVBinders vs fv = foldr minusFVBinder fv vs
1033
1034 minusFVBinder :: Id -> FreeVarsInfo -> FreeVarsInfo
1035 minusFVBinder v fv | isId v && opt_RuntimeTypes
1036                    = (fv `delVarEnv` v) `unionFVInfo`
1037                      tyvarFVInfo (tyVarsOfType (idType v))
1038                    | otherwise = fv `delVarEnv` v
1039         -- When removing a binder, remember to add its type variables
1040         -- c.f. CoreFVs.delBinderFV
1041
1042 elementOfFVInfo :: Id -> FreeVarsInfo -> Bool
1043 elementOfFVInfo id fvs = maybeToBool (lookupVarEnv fvs id)
1044
1045 lookupFVInfo :: FreeVarsInfo -> Id -> StgBinderInfo
1046 -- Find how the given Id is used.
1047 -- Externally visible things may be used any old how
1048 lookupFVInfo fvs id
1049   | isExternalName (idName id) = noBinderInfo
1050   | otherwise = case lookupVarEnv fvs id of
1051                         Nothing         -> noBinderInfo
1052                         Just (_,_,info) -> info
1053
1054 allFreeIds :: FreeVarsInfo -> [(Id,HowBound)]   -- Both top level and non-top-level Ids
1055 allFreeIds fvs = [(id,how_bound) | (id,how_bound,_) <- varEnvElts fvs, isId id]
1056
1057 -- Non-top-level things only, both type variables and ids
1058 -- (type variables only if opt_RuntimeTypes)
1059 getFVs :: FreeVarsInfo -> [Var]
1060 getFVs fvs = [id | (id, how_bound, _) <- varEnvElts fvs,
1061                     not (topLevelBound how_bound) ]
1062
1063 getFVSet :: FreeVarsInfo -> VarSet
1064 getFVSet fvs = mkVarSet (getFVs fvs)
1065
1066 plusFVInfo (id1,hb1,info1) (id2,hb2,info2)
1067   = ASSERT (id1 == id2 && hb1 `check_eq_how_bound` hb2)
1068     (id1, hb1, combineStgBinderInfo info1 info2)
1069
1070 #ifdef DEBUG
1071 -- The HowBound info for a variable in the FVInfo should be consistent
1072 check_eq_how_bound ImportBound        ImportBound        = True
1073 check_eq_how_bound LambdaBound        LambdaBound        = True
1074 check_eq_how_bound (LetBound li1 ar1) (LetBound li2 ar2) = ar1 == ar2 && check_eq_li li1 li2
1075 check_eq_how_bound hb1                hb2                = False
1076
1077 check_eq_li (NestedLet _) (NestedLet _) = True
1078 check_eq_li TopLet        TopLet        = True
1079 check_eq_li li1           li2           = False
1080 #endif
1081 \end{code}
1082
1083 Misc.
1084 \begin{code}
1085 filterStgBinders :: [Var] -> [Var]
1086 filterStgBinders bndrs
1087   | opt_RuntimeTypes = bndrs
1088   | otherwise        = filter isId bndrs
1089 \end{code}
1090
1091
1092 \begin{code}
1093         -- Ignore all notes except SCC
1094 myCollectBinders expr
1095   = go [] expr
1096   where
1097     go bs (Lam b e)          = go (b:bs) e
1098     go bs e@(Note (SCC _) _) = (reverse bs, e)
1099     go bs (Cast e co)        = go bs e
1100     go bs (Note _ e)         = go bs e
1101     go bs e                  = (reverse bs, e)
1102
1103 myCollectArgs :: CoreExpr -> (Id, [CoreArg])
1104         -- We assume that we only have variables
1105         -- in the function position by now
1106 myCollectArgs expr
1107   = go expr []
1108   where
1109     go (Var v)          as = (v, as)
1110     go (App f a) as        = go f (a:as)
1111     go (Note (SCC _) e) as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1112     go (Cast e co)      as = go e as
1113     go (Note n e)       as = go e as
1114     go _                as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1115 \end{code}
1116
1117 \begin{code}
1118 stgArity :: Id -> HowBound -> Arity
1119 stgArity f (LetBound _ arity) = arity
1120 stgArity f ImportBound        = idArity f
1121 stgArity f LambdaBound        = 0
1122 \end{code}