compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/CodingStyle#Warnings
  12 -- for details
  13
  14 module WorkWrap ( wwTopBinds, mkWrapper ) where
  15
  16 #include "HsVersions.h"
  17
  18 import CoreSyn
  19 import CoreUnfold       ( certainlyWillInline )
  20 import CoreLint         ( showPass, endPass )
  21 import CoreUtils        ( exprType, exprIsHNF, exprArity )
  22 import Id               ( Id, idType, isOneShotLambda,
  23                           setIdNewStrictness, mkWorkerId,
  24                           setIdWorkerInfo, setInlinePragma,
  25                           setIdArity, idInfo )
  26 import MkId             ( lazyIdKey, lazyIdUnfolding )
  27 import Type             ( Type )
  28 import IdInfo           ( WorkerInfo(..), arityInfo,
  29                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  30                         )
  31 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  32                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  33                         )
  34 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  35 import Unique           ( hasKey )
  36 import BasicTypes       ( RecFlag(..), isNonRec, isNeverActive )
  37 import VarEnv           ( isEmptyVarEnv )
  38 import Maybes           ( orElse )
  39 import DynFlags
  40 import WwLib
  41 import Util             ( lengthIs, notNull )
  42 import Outputable
  43 \end{code}
  44
  45 We take Core bindings whose binders have:
  46
  47 \begin{enumerate}
  48
  49 \item Strictness attached (by the front-end of the strictness
  50 analyser), and / or
  51
  52 \item Constructed Product Result information attached by the CPR
  53 analysis pass.
  54
  55 \end{enumerate}
  56
  57 and we return some ``plain'' bindings which have been
  58 worker/wrapper-ified, meaning:
  59
  60 \begin{enumerate}
  61
  62 \item Functions have been split into workers and wrappers where
  63 appropriate.  If a function has both strictness and CPR properties
  64 then only one worker/wrapper doing both transformations is produced;
  65
  66 \item Binders' @IdInfos@ have been updated to reflect the existence of
  67 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  68 info for exported values).
  69 \end{enumerate}
  70
  71 \begin{code}
  72
  73 wwTopBinds :: DynFlags
  74            -> UniqSupply
  75            -> [CoreBind]
  76            -> IO [CoreBind]
  77
  78 wwTopBinds dflags us binds
  79   = do {
  80         showPass dflags "Worker Wrapper binds";
  81
  82         -- Create worker/wrappers, and mark binders with their
  83         -- "strictness info" [which encodes their worker/wrapper-ness]
  84         let { binds' = workersAndWrappers us binds };
  85
  86         endPass dflags "Worker Wrapper binds"
  87                 Opt_D_dump_worker_wrapper binds'
  88     }
  89 \end{code}
  90
  91
  92 \begin{code}
  93 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  94
  95 workersAndWrappers us top_binds
  96   = initUs_ us $
  97     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  98     returnUs (concat top_binds')
  99 \end{code}
 100
 101 %************************************************************************
 102 %*                                                                      *
 103 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
 104 %*                                                                      *
 105 %************************************************************************
 106
 107 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 108 turn.  Non-recursive case first, then recursive...
 109
 110 \begin{code}
 111 wwBind  :: CoreBind
 112         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 113                                 -- the caller will convert to Expr/Binding,
 114                                 -- as appropriate.
 115
 116 wwBind (NonRec binder rhs)
 117   = wwExpr rhs                          `thenUs` \ new_rhs ->
 118     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 119     returnUs [NonRec b e | (b,e) <- new_pairs]
 120       -- Generated bindings must be non-recursive
 121       -- because the original binding was.
 122
 123 wwBind (Rec pairs)
 124   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 125     returnUs [Rec (concat new_pairs)]
 126   where
 127     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 128                            tryWW Recursive binder new_rhs
 129 \end{code}
 130
 131 @wwExpr@ basically just walks the tree, looking for appropriate
 132 annotations that can be used. Remember it is @wwBind@ that does the
 133 matching by looking for strict arguments of the correct type.
 134 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 135
 136 \begin{code}
 137 wwExpr :: CoreExpr -> UniqSM CoreExpr
 138
 139 wwExpr e@(Type _)             = returnUs e
 140 wwExpr e@(Lit _)              = returnUs e
 141 wwExpr e@(Note InlineMe expr) = returnUs e
 142         -- Don't w/w inside InlineMe's
 143
 144 wwExpr e@(Var v)
 145   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 146   | otherwise            = returnUs e
 147         -- HACK alert: Inline 'lazy' after strictness analysis
 148         -- (but not inside InlineMe's)
 149
 150 wwExpr (Lam binder expr)
 151   = wwExpr expr                 `thenUs` \ new_expr ->
 152     returnUs (Lam binder new_expr)
 153
 154 wwExpr (App f a)
 155   = wwExpr f                    `thenUs` \ new_f ->
 156     wwExpr a                    `thenUs` \ new_a ->
 157     returnUs (App new_f new_a)
 158
 159 wwExpr (Note note expr)
 160   = wwExpr expr                 `thenUs` \ new_expr ->
 161     returnUs (Note note new_expr)
 162
 163 wwExpr (Cast expr co)
 164   = wwExpr expr                 `thenUs` \ new_expr ->
 165     returnUs (Cast new_expr co)
 166
 167 wwExpr (Let bind expr)
 168   = wwBind bind                 `thenUs` \ intermediate_bind ->
 169     wwExpr expr                 `thenUs` \ new_expr ->
 170     returnUs (mkLets intermediate_bind new_expr)
 171
 172 wwExpr (Case expr binder ty alts)
 173   = wwExpr expr                         `thenUs` \ new_expr ->
 174     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 175     returnUs (Case new_expr binder ty new_alts)
 176   where
 177     ww_alt (con, binders, rhs)
 178       = wwExpr rhs                      `thenUs` \ new_rhs ->
 179         returnUs (con, binders, new_rhs)
 180 \end{code}
 181
 182 %************************************************************************
 183 %*                                                                      *
 184 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 185 %*                                                                      *
 186 %************************************************************************
 187
 188 @tryWW@ just accumulates arguments, converts strictness info from the
 189 front-end into the proper form, then calls @mkWwBodies@ to do
 190 the business.
 191
 192 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 193 already been w-w'd!  (You can end up with several liked-named Ids
 194 bouncing around at the same time---absolute mischief.)  So the
 195 criterion we use is: if an Id already has an unfolding (for whatever
 196 reason), then we don't w-w it.
 197
 198 The only reason this is monadised is for the unique supply.
 199
 200 \begin{code}
 201 tryWW   :: RecFlag
 202         -> Id                           -- The fn binder
 203         -> CoreExpr                     -- The bound rhs; its innards
 204                                         --   are already ww'd
 205         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 206                                         -- if one, then no worker (only
 207                                         -- the orig "wrapper" lives on);
 208                                         -- if two, then a worker and a
 209                                         -- wrapper.
 210 tryWW is_rec fn_id rhs
 211   |  isNonRec is_rec && certainlyWillInline unfolding
 212         -- No point in worker/wrappering a function that is going to be
 213         -- INLINEd wholesale anyway.  If the strictness analyser is run
 214         -- twice, this test also prevents wrappers (which are INLINEd)
 215         -- from being re-done.
 216         --
 217         -- It's very important to refrain from w/w-ing an INLINE function
 218         -- If we do so by mistake we transform
 219         --      f = __inline (\x -> E)
 220         -- into
 221         --      f = __inline (\x -> case x of (a,b) -> fw E)
 222         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 223         -- and the original __inline now vanishes, so E is no longer
 224         -- inside its __inline wrapper.  Death!  Disaster!
 225
 226   || isNeverActive inline_prag
 227         -- No point in worker/wrappering if the thing is never inlined!
 228         -- Because the no-inline prag will prevent the wrapper ever
 229         -- being inlined at a call site.
 230   = returnUs [ (new_fn_id, rhs) ]
 231
 232   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 233   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 234     splitThunk new_fn_id rhs
 235
 236   | is_fun && worthSplittingFun wrap_dmds res_info
 237   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 238
 239   | otherwise
 240   = returnUs [ (new_fn_id, rhs) ]
 241
 242   where
 243     fn_info      = idInfo fn_id
 244     maybe_fn_dmd = newDemandInfo fn_info
 245     unfolding    = unfoldingInfo fn_info
 246     inline_prag  = inlinePragInfo fn_info
 247
 248         -- In practice it always will have a strictness
 249         -- signature, even if it's a uninformative one
 250     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 251     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 252
 253         -- new_fn_id has the DmdEnv zapped.
 254         --      (a) it is never used again
 255         --      (b) it wastes space
 256         --      (c) it becomes incorrect as things are cloned, because
 257         --          we don't push the substitution into it
 258     new_fn_id | isEmptyVarEnv env = fn_id
 259               | otherwise         = fn_id `setIdNewStrictness`
 260                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 261
 262     is_fun    = notNull wrap_dmds
 263     is_thunk  = not is_fun && not (exprIsHNF rhs)
 264
 265 ---------------------
 266 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 267   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 268         -- The arity should match the signature
 269     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 270     getUniqueUs                                         `thenUs` \ work_uniq ->
 271     let
 272         work_rhs = work_fn rhs
 273         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 274                         `setInlinePragma` inline_prag
 275                                 -- Any inline pragma (which sets when inlining is active)
 276                                 -- on the original function is duplicated on the worker and wrapper
 277                                 -- It *matters* that the pragma stays on the wrapper
 278                                 -- It seems sensible to have it on the worker too, although we
 279                                 -- can't think of a compelling reason. (In ptic, INLINE things are
 280                                 -- not w/wd)
 281                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 282                                 -- Even though we may not be at top level,
 283                                 -- it's ok to give it an empty DmdEnv
 284                         `setIdArity` (exprArity work_rhs)
 285                                 -- Set the arity so that the Core Lint check that the
 286                                 -- arity is consistent with the demand type goes through
 287
 288         wrap_rhs = wrap_fn work_id
 289         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 290
 291     in
 292     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 293         -- Worker first, because wrapper mentions it
 294         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 295   where
 296     fun_ty = idType fn_id
 297
 298     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 299                                 -- So it may be more than the number of top-level-visible lambdas
 300
 301     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 302                   | otherwise         = TopRes
 303
 304     one_shots = get_one_shots rhs
 305
 306 -- If the original function has one-shot arguments, it is important to
 307 -- make the wrapper and worker have corresponding one-shot arguments too.
 308 -- Otherwise we spuriously float stuff out of case-expression join points,
 309 -- which is very annoying.
 310 get_one_shots (Lam b e)
 311   | isId b    = isOneShotLambda b : get_one_shots e
 312   | otherwise = get_one_shots e
 313 get_one_shots (Note _ e) = get_one_shots e
 314 get_one_shots other      = noOneShotInfo
 315 \end{code}
 316
 317 Thunk splitting
 318 ~~~~~~~~~~~~~~~
 319 Suppose x is used strictly (never mind whether it has the CPR
 320 property).
 321
 322       let
 323         x* = x-rhs
 324       in body
 325
 326 splitThunk transforms like this:
 327
 328       let
 329         x* = case x-rhs of { I# a -> I# a }
 330       in body
 331
 332 Now simplifier will transform to
 333
 334       case x-rhs of
 335         I# a -> let x* = I# a
 336                 in body
 337
 338 which is what we want. Now suppose x-rhs is itself a case:
 339
 340         x-rhs = case e of { T -> I# a; F -> I# b }
 341
 342 The join point will abstract over a, rather than over (which is
 343 what would have happened before) which is fine.
 344
 345 Notice that x certainly has the CPR property now!
 346
 347 In fact, splitThunk uses the function argument w/w splitting
 348 function, so that if x's demand is deeper (say U(U(L,L),L))
 349 then the splitting will go deeper too.
 350
 351 \begin{code}
 352 -- splitThunk converts the *non-recursive* binding
 353 --      x = e
 354 -- into
 355 --      x = let x = e
 356 --          in case x of
 357 --               I# y -> let x = I# y in x }
 358 -- See comments above. Is it not beautifully short?
 359
 360 splitThunk fn_id rhs
 361   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 362     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 363 \end{code}
 364
 365
 366 %************************************************************************
 367 %*                                                                      *
 368 \subsection{Functions over Demands}
 369 %*                                                                      *
 370 %************************************************************************
 371
 372 \begin{code}
 373 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 374                 -- True <=> the wrapper would not be an identity function
 375 worthSplittingFun ds res
 376   = any worth_it ds || returnsCPR res
 377         -- worthSplitting returns False for an empty list of demands,
 378         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 379
 380         -- We used not to split if the result is bottom.
 381         -- [Justification:  there's no efficiency to be gained.]
 382         -- But it's sometimes bad not to make a wrapper.  Consider
 383         --      fw = \x# -> let x = I# x# in case e of
 384         --                                      p1 -> error_fn x
 385         --                                      p2 -> error_fn x
 386         --                                      p3 -> the real stuff
 387         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 388         -- [We don't do reboxing now, but in general it's better to pass
 389         --  an unboxed thing to f, and have it reboxed in the error cases....]
 390   where
 391     worth_it Abs              = True    -- Absent arg
 392     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 393     worth_it other            = False
 394
 395 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 396                     -> DmdResult        -- CPR info for the thunk
 397                     -> Bool
 398 worthSplittingThunk maybe_dmd res
 399   = worth_it maybe_dmd || returnsCPR res
 400   where
 401         -- Split if the thing is unpacked
 402     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 403     worth_it other                   = False
 404 \end{code}
 405
 406
 407
 408 %************************************************************************
 409 %*                                                                      *
 410 \subsection{The worker wrapper core}
 411 %*                                                                      *
 412 %************************************************************************
 413
 414 @mkWrapper@ is called when importing a function.  We have the type of
 415 the function and the name of its worker, and we want to make its body (the wrapper).
 416
 417 \begin{code}
 418 mkWrapper :: Type               -- Wrapper type
 419           -> StrictSig          -- Wrapper strictness info
 420           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 421
 422 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 423   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 424     returnUs wrap_fn
 425
 426 noOneShotInfo = repeat False
 427 \end{code}