compiler/typecheck/TcBinds.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcBinds]{TcBinds}
   6
   7 \begin{code}
   8 module TcBinds ( tcLocalBinds, tcTopBinds,
   9                  tcHsBootSigs, tcMonoBinds, tcPolyBinds,
  10                  TcPragFun, tcSpecPrag, tcPrags, mkPragFun,
  11                  TcSigInfo(..), TcSigFun, mkTcSigFun,
  12                  badBootDeclErr ) where
  13
  14 import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
  15 import {-# SOURCE #-} TcExpr  ( tcMonoExpr )
  16
  17 import DynFlags
  18 import HsSyn
  19
  20 import TcRnMonad
  21 import Inst
  22 import TcEnv
  23 import TcUnify
  24 import TcSimplify
  25 import TcHsType
  26 import TcPat
  27 import TcMType
  28 import TcType
  29 import {- Kind parts of -} Type
  30 import Coercion
  31 import VarEnv
  32 import TysPrim
  33 import Id
  34 import Var
  35 import Name
  36 import NameSet
  37 import NameEnv
  38 import VarSet
  39 import SrcLoc
  40 import Bag
  41 import ErrUtils
  42 import Digraph
  43 import Maybes
  44 import List
  45 import Util
  46 import BasicTypes
  47 import Outputable
  48 import FastString
  49
  50 import Control.Monad
  51 \end{code}
  52
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection{Type-checking bindings}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 @tcBindsAndThen@ typechecks a @HsBinds@.  The "and then" part is because
  61 it needs to know something about the {\em usage} of the things bound,
  62 so that it can create specialisations of them.  So @tcBindsAndThen@
  63 takes a function which, given an extended environment, E, typechecks
  64 the scope of the bindings returning a typechecked thing and (most
  65 important) an LIE.  It is this LIE which is then used as the basis for
  66 specialising the things bound.
  67
  68 @tcBindsAndThen@ also takes a "combiner" which glues together the
  69 bindings and the "thing" to make a new "thing".
  70
  71 The real work is done by @tcBindWithSigsAndThen@.
  72
  73 Recursive and non-recursive binds are handled in essentially the same
  74 way: because of uniques there are no scoping issues left.  The only
  75 difference is that non-recursive bindings can bind primitive values.
  76
  77 Even for non-recursive binding groups we add typings for each binder
  78 to the LVE for the following reason.  When each individual binding is
  79 checked the type of its LHS is unified with that of its RHS; and
  80 type-checking the LHS of course requires that the binder is in scope.
  81
  82 At the top-level the LIE is sure to contain nothing but constant
  83 dictionaries, which we resolve at the module level.
  84
  85 \begin{code}
  86 tcTopBinds :: HsValBinds Name -> TcM (LHsBinds TcId, TcLclEnv)
  87         -- Note: returning the TcLclEnv is more than we really
  88         --       want.  The bit we care about is the local bindings
  89         --       and the free type variables thereof
  90 tcTopBinds binds
  91   = do  { (ValBindsOut prs _, env) <- tcValBinds TopLevel binds getLclEnv
  92         ; return (foldr (unionBags . snd) emptyBag prs, env) }
  93         -- The top level bindings are flattened into a giant
  94         -- implicitly-mutually-recursive LHsBinds
  95
  96 tcHsBootSigs :: HsValBinds Name -> TcM [Id]
  97 -- A hs-boot file has only one BindGroup, and it only has type
  98 -- signatures in it.  The renamer checked all this
  99 tcHsBootSigs (ValBindsOut binds sigs)
 100   = do  { checkTc (null binds) badBootDeclErr
 101         ; mapM (addLocM tc_boot_sig) (filter isVanillaLSig sigs) }
 102   where
 103     tc_boot_sig (TypeSig (L _ name) ty)
 104       = do { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
 105            ; return (mkVanillaGlobal name sigma_ty) }
 106         -- Notice that we make GlobalIds, not LocalIds
 107     tc_boot_sig s = pprPanic "tcHsBootSigs/tc_boot_sig" (ppr s)
 108 tcHsBootSigs groups = pprPanic "tcHsBootSigs" (ppr groups)
 109
 110 badBootDeclErr :: Message
 111 badBootDeclErr = ptext (sLit "Illegal declarations in an hs-boot file")
 112
 113 ------------------------
 114 tcLocalBinds :: HsLocalBinds Name -> TcM thing
 115              -> TcM (HsLocalBinds TcId, thing)
 116
 117 tcLocalBinds EmptyLocalBinds thing_inside
 118   = do  { thing <- thing_inside
 119         ; return (EmptyLocalBinds, thing) }
 120
 121 tcLocalBinds (HsValBinds binds) thing_inside
 122   = do  { (binds', thing) <- tcValBinds NotTopLevel binds thing_inside
 123         ; return (HsValBinds binds', thing) }
 124
 125 tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
 126   = do  { (thing, lie) <- getLIE thing_inside
 127         ; (avail_ips, ip_binds') <- mapAndUnzipM (wrapLocSndM tc_ip_bind) ip_binds
 128
 129         -- If the binding binds ?x = E, we  must now
 130         -- discharge any ?x constraints in expr_lie
 131         ; dict_binds <- tcSimplifyIPs avail_ips lie
 132         ; return (HsIPBinds (IPBinds ip_binds' dict_binds), thing) }
 133   where
 134         -- I wonder if we should do these one at at time
 135         -- Consider     ?x = 4
 136         --              ?y = ?x + 1
 137     tc_ip_bind (IPBind ip expr) = do
 138         ty <- newFlexiTyVarTy argTypeKind
 139         (ip', ip_inst) <- newIPDict (IPBindOrigin ip) ip ty
 140         expr' <- tcMonoExpr expr ty
 141         return (ip_inst, (IPBind ip' expr'))
 142
 143 ------------------------
 144 tcValBinds :: TopLevelFlag
 145            -> HsValBinds Name -> TcM thing
 146            -> TcM (HsValBinds TcId, thing)
 147
 148 tcValBinds _ (ValBindsIn binds _) _
 149   = pprPanic "tcValBinds" (ppr binds)
 150
 151 tcValBinds top_lvl (ValBindsOut binds sigs) thing_inside
 152   = do  {       -- Typecheck the signature
 153         ; let { prag_fn = mkPragFun sigs
 154               ; ty_sigs = filter isVanillaLSig sigs
 155               ; sig_fn  = mkTcSigFun ty_sigs }
 156
 157         ; poly_ids <- checkNoErrs (mapAndRecoverM tcTySig ty_sigs)
 158                 -- No recovery from bad signatures, because the type sigs
 159                 -- may bind type variables, so proceeding without them
 160                 -- can lead to a cascade of errors
 161                 -- ToDo: this means we fall over immediately if any type sig
 162                 -- is wrong, which is over-conservative, see Trac bug #745
 163
 164                 -- Extend the envt right away with all
 165                 -- the Ids declared with type signatures
 166         ; poly_rec <- doptM Opt_RelaxedPolyRec
 167         ; (binds', thing) <- tcExtendIdEnv poly_ids $
 168                              tcBindGroups poly_rec top_lvl sig_fn prag_fn
 169                                           binds thing_inside
 170
 171         ; return (ValBindsOut binds' sigs, thing) }
 172
 173 ------------------------
 174 tcBindGroups :: Bool -> TopLevelFlag -> TcSigFun -> TcPragFun
 175              -> [(RecFlag, LHsBinds Name)] -> TcM thing
 176              -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 177 -- Typecheck a whole lot of value bindings,
 178 -- one strongly-connected component at a time
 179 -- Here a "strongly connected component" has the strightforward
 180 -- meaning of a group of bindings that mention each other,
 181 -- ignoring type signatures (that part comes later)
 182
 183 tcBindGroups _ _ _ _ [] thing_inside
 184   = do  { thing <- thing_inside
 185         ; return ([], thing) }
 186
 187 tcBindGroups poly_rec top_lvl sig_fn prag_fn (group : groups) thing_inside
 188   = do  { (group', (groups', thing))
 189                 <- tc_group poly_rec top_lvl sig_fn prag_fn group $
 190                    tcBindGroups poly_rec top_lvl sig_fn prag_fn groups thing_inside
 191         ; return (group' ++ groups', thing) }
 192
 193 ------------------------
 194 tc_group :: Bool -> TopLevelFlag -> TcSigFun -> TcPragFun
 195          -> (RecFlag, LHsBinds Name) -> TcM thing
 196          -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 197
 198 -- Typecheck one strongly-connected component of the original program.
 199 -- We get a list of groups back, because there may
 200 -- be specialisations etc as well
 201
 202 tc_group _ top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
 203         -- A single non-recursive binding
 204         -- We want to keep non-recursive things non-recursive
 205         -- so that we desugar unlifted bindings correctly
 206  =  do  { (binds1, lie_binds, thing) <- tc_haskell98 top_lvl sig_fn prag_fn
 207                                                      NonRecursive binds thing_inside
 208         ; return ( [(NonRecursive, unitBag b) | b <- bagToList binds1]
 209                      ++ [(Recursive, lie_binds)]  -- TcDictBinds have scrambled dependency order
 210                  , thing) }
 211
 212 tc_group poly_rec top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
 213   | not poly_rec        -- Recursive group, normal Haskell 98 route
 214   = do  { (binds1, lie_binds, thing) <- tc_haskell98 top_lvl sig_fn prag_fn
 215                                                      Recursive binds thing_inside
 216         ; return ([(Recursive, binds1 `unionBags` lie_binds)], thing) }
 217
 218   | otherwise           -- Recursive group, with -XRelaxedPolyRec
 219   =     -- To maximise polymorphism (with -XRelaxedPolyRec), we do a new
 220         -- strongly-connected-component analysis, this time omitting
 221         -- any references to variables with type signatures.
 222         --
 223         -- Notice that the bindInsts thing covers *all* the bindings in
 224         -- the original group at once; an earlier one may use a later one!
 225     do  { traceTc (text "tc_group rec" <+> pprLHsBinds binds)
 226         ; (binds1,lie_binds,thing) <- bindLocalInsts top_lvl $
 227                             go (stronglyConnCompFromEdgedVertices (mkEdges sig_fn binds))
 228         ; return ([(Recursive, binds1 `unionBags` lie_binds)], thing) }
 229                 -- Rec them all together
 230   where
 231 --  go :: SCC (LHsBind Name) -> TcM (LHsBinds TcId, [TcId], thing)
 232     go (scc:sccs) = do  { (binds1, ids1) <- tc_scc scc
 233                         ; (binds2, ids2, thing) <- tcExtendIdEnv ids1 $ go sccs
 234                         ; return (binds1 `unionBags` binds2, ids1 ++ ids2, thing) }
 235     go []         = do  { thing <- thing_inside; return (emptyBag, [], thing) }
 236
 237     tc_scc (AcyclicSCC bind) = tc_sub_group NonRecursive (unitBag bind)
 238     tc_scc (CyclicSCC binds) = tc_sub_group Recursive    (listToBag binds)
 239
 240     tc_sub_group = tcPolyBinds top_lvl sig_fn prag_fn Recursive
 241
 242 tc_haskell98 :: TopLevelFlag -> TcSigFun -> TcPragFun -> RecFlag
 243              -> LHsBinds Name -> TcM a -> TcM (LHsBinds TcId, TcDictBinds, a)
 244 tc_haskell98 top_lvl sig_fn prag_fn rec_flag binds thing_inside
 245   = bindLocalInsts top_lvl $
 246     do { (binds1, ids) <- tcPolyBinds top_lvl sig_fn prag_fn rec_flag rec_flag binds
 247        ; thing <- tcExtendIdEnv ids thing_inside
 248        ; return (binds1, ids, thing) }
 249
 250 ------------------------
 251 bindLocalInsts :: TopLevelFlag
 252                -> TcM (LHsBinds TcId, [TcId],      a)
 253                -> TcM (LHsBinds TcId, TcDictBinds, a)
 254 bindLocalInsts top_lvl thing_inside
 255   | isTopLevel top_lvl
 256   = do { (binds, _, thing) <- thing_inside; return (binds, emptyBag, thing) }
 257         -- For the top level don't bother with all this bindInstsOfLocalFuns stuff.
 258         -- All the top level things are rec'd together anyway, so it's fine to
 259         -- leave them to the tcSimplifyTop, and quite a bit faster too
 260
 261   | otherwise   -- Nested case
 262   = do  { ((binds, ids, thing), lie) <- getLIE thing_inside
 263         ; lie_binds <- bindInstsOfLocalFuns lie ids
 264         ; return (binds, lie_binds, thing) }
 265
 266 ------------------------
 267 mkEdges :: TcSigFun -> LHsBinds Name
 268         -> [(LHsBind Name, BKey, [BKey])]
 269
 270 type BKey  = Int -- Just number off the bindings
 271
 272 mkEdges sig_fn binds
 273   = [ (bind, key, [key | n <- nameSetToList (bind_fvs (unLoc bind)),
 274                          Just key <- [lookupNameEnv key_map n], no_sig n ])
 275     | (bind, key) <- keyd_binds
 276     ]
 277   where
 278     no_sig :: Name -> Bool
 279     no_sig n = isNothing (sig_fn n)
 280
 281     keyd_binds = bagToList binds `zip` [0::BKey ..]
 282
 283     key_map :: NameEnv BKey     -- Which binding it comes from
 284     key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
 285                                      , bndr <- bindersOfHsBind bind ]
 286
 287 bindersOfHsBind :: HsBind Name -> [Name]
 288 bindersOfHsBind (PatBind { pat_lhs = pat })  = collectPatBinders pat
 289 bindersOfHsBind (FunBind { fun_id = L _ f }) = [f]
 290 bindersOfHsBind (AbsBinds {})                = panic "bindersOfHsBind AbsBinds"
 291 bindersOfHsBind (VarBind {})                 = panic "bindersOfHsBind VarBind"
 292
 293 ------------------------
 294 tcPolyBinds :: TopLevelFlag -> TcSigFun -> TcPragFun
 295             -> RecFlag                  -- Whether the group is really recursive
 296             -> RecFlag                  -- Whether it's recursive after breaking
 297                                         -- dependencies based on type signatures
 298             -> LHsBinds Name
 299             -> TcM (LHsBinds TcId, [TcId])
 300
 301 -- Typechecks a single bunch of bindings all together,
 302 -- and generalises them.  The bunch may be only part of a recursive
 303 -- group, because we use type signatures to maximise polymorphism
 304 --
 305 -- Returns a list because the input may be a single non-recursive binding,
 306 -- in which case the dependency order of the resulting bindings is
 307 -- important.
 308 --
 309 -- Knows nothing about the scope of the bindings
 310
 311 tcPolyBinds top_lvl sig_fn prag_fn rec_group rec_tc binds
 312   = let
 313         bind_list    = bagToList binds
 314         binder_names = collectHsBindBinders binds
 315         loc          = getLoc (head bind_list)
 316                 -- TODO: location a bit awkward, but the mbinds have been
 317                 --       dependency analysed and may no longer be adjacent
 318     in
 319         -- SET UP THE MAIN RECOVERY; take advantage of any type sigs
 320     setSrcSpan loc                              $
 321     recoverM (recoveryCode binder_names sig_fn) $ do
 322
 323   { traceTc (ptext (sLit "------------------------------------------------"))
 324   ; traceTc (ptext (sLit "Bindings for") <+> ppr binder_names)
 325
 326         -- TYPECHECK THE BINDINGS
 327   ; ((binds', mono_bind_infos), lie_req)
 328         <- getLIE (tcMonoBinds bind_list sig_fn rec_tc)
 329   ; traceTc (text "temp" <+> (ppr binds' $$ ppr lie_req))
 330
 331         -- CHECK FOR UNLIFTED BINDINGS
 332         -- These must be non-recursive etc, and are not generalised
 333         -- They desugar to a case expression in the end
 334   ; zonked_mono_tys <- zonkTcTypes (map getMonoType mono_bind_infos)
 335   ; is_strict <- checkStrictBinds top_lvl rec_group binds'
 336                                   zonked_mono_tys mono_bind_infos
 337   ; if is_strict then
 338     do  { extendLIEs lie_req
 339         ; let exports = zipWith mk_export mono_bind_infos zonked_mono_tys
 340               mk_export (name, Nothing,  mono_id) mono_ty = ([], mkLocalId name mono_ty, mono_id, [])
 341               mk_export (_,    Just sig, mono_id) _       = ([], sig_id sig,             mono_id, [])
 342                         -- ToDo: prags for unlifted bindings
 343
 344         ; return ( unitBag $ L loc $ AbsBinds [] [] exports binds',
 345                    [poly_id | (_, poly_id, _, _) <- exports]) } -- Guaranteed zonked
 346
 347     else do     -- The normal lifted case: GENERALISE
 348   { dflags <- getDOpts
 349   ; (tyvars_to_gen, dicts, dict_binds)
 350         <- addErrCtxt (genCtxt (bndrNames mono_bind_infos)) $
 351            generalise dflags top_lvl bind_list sig_fn mono_bind_infos lie_req
 352
 353         -- BUILD THE POLYMORPHIC RESULT IDs
 354   ; let dict_vars = map instToVar dicts -- May include equality constraints
 355   ; exports <- mapM (mkExport top_lvl rec_group prag_fn tyvars_to_gen (map varType dict_vars))
 356                     mono_bind_infos
 357
 358   ; let poly_ids = [poly_id | (_, poly_id, _, _) <- exports]
 359   ; traceTc (text "binding:" <+> ppr (poly_ids `zip` map idType poly_ids))
 360
 361   ; let abs_bind = L loc $ AbsBinds tyvars_to_gen
 362                                     dict_vars exports
 363                                     (dict_binds `unionBags` binds')
 364
 365   ; return (unitBag abs_bind, poly_ids)       -- poly_ids are guaranteed zonked by mkExport
 366   } }
 367
 368
 369 --------------
 370 mkExport :: TopLevelFlag -> RecFlag -> TcPragFun -> [TyVar] -> [TcType]
 371          -> MonoBindInfo
 372          -> TcM ([TyVar], Id, Id, [LPrag])
 373 -- mkExport generates exports with
 374 --      zonked type variables,
 375 --      zonked poly_ids
 376 -- The former is just because no further unifications will change
 377 -- the quantified type variables, so we can fix their final form
 378 -- right now.
 379 -- The latter is needed because the poly_ids are used to extend the
 380 -- type environment; see the invariant on TcEnv.tcExtendIdEnv
 381
 382 -- Pre-condition: the inferred_tvs are already zonked
 383
 384 mkExport top_lvl rec_group prag_fn inferred_tvs dict_tys (poly_name, mb_sig, mono_id)
 385   = do  { warn_missing_sigs <- doptM Opt_WarnMissingSigs
 386         ; let warn = isTopLevel top_lvl && warn_missing_sigs
 387         ; (tvs, poly_id) <- mk_poly_id warn mb_sig
 388                 -- poly_id has a zonked type
 389
 390         ; prags <- tcPrags rec_group poly_id (prag_fn poly_name)
 391                 -- tcPrags requires a zonked poly_id
 392
 393         ; return (tvs, poly_id, mono_id, prags) }
 394   where
 395     poly_ty = mkForAllTys inferred_tvs (mkFunTys dict_tys (idType mono_id))
 396
 397     mk_poly_id warn Nothing    = do { poly_ty' <- zonkTcType poly_ty
 398                                     ; missingSigWarn warn poly_name poly_ty'
 399                                     ; return (inferred_tvs, mkLocalId poly_name poly_ty') }
 400     mk_poly_id _    (Just sig) = do { tvs <- mapM zonk_tv (sig_tvs sig)
 401                                     ; return (tvs,  sig_id sig) }
 402
 403     zonk_tv tv = do { ty <- zonkTcTyVar tv; return (tcGetTyVar "mkExport" ty) }
 404
 405 ------------------------
 406 type TcPragFun = Name -> [LSig Name]
 407
 408 mkPragFun :: [LSig Name] -> TcPragFun
 409 mkPragFun sigs = \n -> lookupNameEnv env n `orElse` []
 410         where
 411           prs = [(expectJust "mkPragFun" (sigName sig), sig)
 412                 | sig <- sigs, isPragLSig sig]
 413           env = foldl add emptyNameEnv prs
 414           add env (n,p) = extendNameEnv_Acc (:) singleton env n p
 415
 416 tcPrags :: RecFlag -> Id -> [LSig Name] -> TcM [LPrag]
 417 -- Pre-condition: the poly_id is zonked
 418 -- Reason: required by tcSubExp
 419 tcPrags rec_group poly_id prags = mapM tc_lprag prags
 420   where
 421     tc_lprag :: LSig Name -> TcM LPrag
 422     tc_lprag (L loc prag) = setSrcSpan loc                $
 423                             addErrCtxt (pragSigCtxt prag) $
 424                             do { prag' <- tc_prag prag
 425                                ; return (L loc prag') }
 426
 427     tc_prag (SpecSig _ hs_ty inl) = tcSpecPrag poly_id hs_ty inl
 428     tc_prag (SpecInstSig hs_ty)   = tcSpecPrag poly_id hs_ty defaultInlineSpec
 429     tc_prag (InlineSig _ inl)     = do { warnIfRecInline rec_group inl poly_id
 430                                        ; return (InlinePrag inl) }
 431     tc_prag (FixSig {})           = panic "tcPrag FixSig"
 432     tc_prag (TypeSig {})          = panic "tcPrag TypeSig"
 433
 434 pragSigCtxt :: Sig Name -> SDoc
 435 pragSigCtxt prag = hang (ptext (sLit "In the pragma")) 2 (ppr prag)
 436
 437 warnIfRecInline :: RecFlag -> InlineSpec -> TcId -> TcM ()
 438 warnIfRecInline rec_group (Inline _ is_inline) poly_id
 439   | is_inline && isRec rec_group = addWarnTc warn
 440   | otherwise                    = return ()
 441   where
 442     warn = ptext (sLit "INLINE pragma for recursive binder") <+> quotes (ppr poly_id)
 443            <+> ptext (sLit "may be discarded")
 444
 445 tcSpecPrag :: TcId -> LHsType Name -> InlineSpec -> TcM Prag
 446 tcSpecPrag poly_id hs_ty inl
 447   = do  { let name = idName poly_id
 448         ; spec_ty <- tcHsSigType (FunSigCtxt name) hs_ty
 449         ; co_fn <- tcSubExp (SpecPragOrigin name) (idType poly_id) spec_ty
 450         ; return (SpecPrag (mkHsWrap co_fn (HsVar poly_id)) spec_ty inl) }
 451         -- Most of the work of specialisation is done by
 452         -- the desugarer, guided by the SpecPrag
 453
 454 --------------
 455 -- If typechecking the binds fails, then return with each
 456 -- signature-less binder given type (forall a.a), to minimise
 457 -- subsequent error messages
 458 recoveryCode :: [Name] -> (Name -> Maybe [Name])
 459              -> TcM (LHsBinds TcId, [Id])
 460 recoveryCode binder_names sig_fn
 461   = do  { traceTc (text "tcBindsWithSigs: error recovery" <+> ppr binder_names)
 462         ; poly_ids <- mapM mk_dummy binder_names
 463         ; return (emptyBag, poly_ids) }
 464   where
 465     mk_dummy name
 466         | isJust (sig_fn name) = tcLookupId name        -- Had signature; look it up
 467         | otherwise            = return (mkLocalId name forall_a_a)    -- No signature
 468
 469 forall_a_a :: TcType
 470 forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 471
 472
 473 -- Check that non-overloaded unlifted bindings are
 474 --      a) non-recursive,
 475 --      b) not top level,
 476 --      c) not a multiple-binding group (more or less implied by (a))
 477
 478 checkStrictBinds :: TopLevelFlag -> RecFlag
 479                  -> LHsBinds TcId -> [TcType] -> [MonoBindInfo]
 480                  -> TcM Bool
 481 checkStrictBinds top_lvl rec_group mbind mono_tys infos
 482   | unlifted || bang_pat
 483   = do  { checkTc (isNotTopLevel top_lvl)
 484                   (strictBindErr "Top-level" unlifted mbind)
 485         ; checkTc (isNonRec rec_group)
 486                   (strictBindErr "Recursive" unlifted mbind)
 487         ; checkTc (isSingletonBag mbind)
 488                   (strictBindErr "Multiple" unlifted mbind)
 489         ; mapM_ check_sig infos
 490         ; return True }
 491   | otherwise
 492   = return False
 493   where
 494     unlifted = any isUnLiftedType mono_tys
 495     bang_pat = anyBag (isBangHsBind . unLoc) mbind
 496     check_sig (_, Just sig, _) = checkTc (null (sig_tvs sig) && null (sig_theta sig))
 497                                          (badStrictSig unlifted sig)
 498     check_sig _                = return ()
 499
 500 strictBindErr :: String -> Bool -> LHsBindsLR Var Var -> SDoc
 501 strictBindErr flavour unlifted mbind
 502   = hang (text flavour <+> msg <+> ptext (sLit "aren't allowed:"))
 503          4 (pprLHsBinds mbind)
 504   where
 505     msg | unlifted  = ptext (sLit "bindings for unlifted types")
 506         | otherwise = ptext (sLit "bang-pattern bindings")
 507
 508 badStrictSig :: Bool -> TcSigInfo -> SDoc
 509 badStrictSig unlifted sig
 510   = hang (ptext (sLit "Illegal polymorphic signature in") <+> msg)
 511          4 (ppr sig)
 512   where
 513     msg | unlifted  = ptext (sLit "an unlifted binding")
 514         | otherwise = ptext (sLit "a bang-pattern binding")
 515 \end{code}
 516
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsection{tcMonoBind}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 @tcMonoBinds@ deals with a perhaps-recursive group of HsBinds.
 525 The signatures have been dealt with already.
 526
 527 \begin{code}
 528 tcMonoBinds :: [LHsBind Name]
 529             -> TcSigFun
 530             -> RecFlag  -- Whether the binding is recursive for typechecking purposes
 531                         -- i.e. the binders are mentioned in their RHSs, and
 532                         --      we are not resuced by a type signature
 533             -> TcM (LHsBinds TcId, [MonoBindInfo])
 534
 535 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 536                                 fun_matches = matches, bind_fvs = fvs })]
 537             sig_fn              -- Single function binding,
 538             NonRecursive        -- binder isn't mentioned in RHS,
 539   | Nothing <- sig_fn name      -- ...with no type signature
 540   =     -- In this very special case we infer the type of the
 541         -- right hand side first (it may have a higher-rank type)
 542         -- and *then* make the monomorphic Id for the LHS
 543         -- e.g.         f = \(x::forall a. a->a) -> <body>
 544         --      We want to infer a higher-rank type for f
 545     setSrcSpan b_loc    $
 546     do  { ((co_fn, matches'), rhs_ty) <- tcInfer (tcMatchesFun name inf matches)
 547
 548                 -- Check for an unboxed tuple type
 549                 --      f = (# True, False #)
 550                 -- Zonk first just in case it's hidden inside a meta type variable
 551                 -- (This shows up as a (more obscure) kind error
 552                 --  in the 'otherwise' case of tcMonoBinds.)
 553         ; zonked_rhs_ty <- zonkTcType rhs_ty
 554         ; checkTc (not (isUnboxedTupleType zonked_rhs_ty))
 555                   (unboxedTupleErr name zonked_rhs_ty)
 556
 557         ; mono_name <- newLocalName name
 558         ; let mono_id = mkLocalId mono_name zonked_rhs_ty
 559         ; return (unitBag (L b_loc (FunBind { fun_id = L nm_loc mono_id, fun_infix = inf,
 560                                               fun_matches = matches', bind_fvs = fvs,
 561                                               fun_co_fn = co_fn, fun_tick = Nothing })),
 562                   [(name, Nothing, mono_id)]) }
 563
 564 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 565                                 fun_matches = matches })]
 566             sig_fn              -- Single function binding
 567             _
 568   | Just scoped_tvs <- sig_fn name      -- ...with a type signature
 569   =     -- When we have a single function binding, with a type signature
 570         -- we can (a) use genuine, rigid skolem constants for the type variables
 571         --        (b) bring (rigid) scoped type variables into scope
 572     setSrcSpan b_loc    $
 573     do  { tc_sig <- tcInstSig True name
 574         ; mono_name <- newLocalName name
 575         ; let mono_ty = sig_tau tc_sig
 576               mono_id = mkLocalId mono_name mono_ty
 577               rhs_tvs = [ (name, mkTyVarTy tv)
 578                         | (name, tv) <- scoped_tvs `zip` sig_tvs tc_sig ]
 579                         -- See Note [More instantiated than scoped]
 580                         -- Note that the scoped_tvs and the (sig_tvs sig)
 581                         -- may have different Names. That's quite ok.
 582
 583         ; traceTc (text "tcMoonBinds" <+> ppr scoped_tvs $$ ppr tc_sig)
 584         ; (co_fn, matches') <- tcExtendTyVarEnv2 rhs_tvs $
 585                                tcMatchesFun mono_name inf matches mono_ty
 586              -- Note that "mono_ty" might actually be a polymorphic type,
 587              -- if the original function had a signature like
 588              --    forall a. Eq a => forall b. Ord b => ....
 589              -- But that's ok: tcMatchesFun can deal with that
 590              -- It happens, too!  See Note [Polymorphic methods] in TcClassDcl.
 591
 592         ; let fun_bind' = FunBind { fun_id = L nm_loc mono_id,
 593                                     fun_infix = inf, fun_matches = matches',
 594                                     bind_fvs = placeHolderNames, fun_co_fn = co_fn,
 595                                     fun_tick = Nothing }
 596         ; return (unitBag (L b_loc fun_bind'),
 597                   [(name, Just tc_sig, mono_id)]) }
 598
 599 tcMonoBinds binds sig_fn _
 600   = do  { tc_binds <- mapM (wrapLocM (tcLhs sig_fn)) binds
 601
 602         -- Bring the monomorphic Ids, into scope for the RHSs
 603         ; let mono_info  = getMonoBindInfo tc_binds
 604               rhs_id_env = [(name,mono_id) | (name, Nothing, mono_id) <- mono_info]
 605                                 -- A monomorphic binding for each term variable that lacks
 606                                 -- a type sig.  (Ones with a sig are already in scope.)
 607
 608         ; binds' <- tcExtendIdEnv2 rhs_id_env $ do
 609                     traceTc (text "tcMonoBinds" <+> vcat [ ppr n <+> ppr id <+> ppr (idType id)
 610                                                          | (n,id) <- rhs_id_env])
 611                     mapM (wrapLocM tcRhs) tc_binds
 612         ; return (listToBag binds', mono_info) }
 613
 614 ------------------------
 615 -- tcLhs typechecks the LHS of the bindings, to construct the environment in which
 616 -- we typecheck the RHSs.  Basically what we are doing is this: for each binder:
 617 --      if there's a signature for it, use the instantiated signature type
 618 --      otherwise invent a type variable
 619 -- You see that quite directly in the FunBind case.
 620 --
 621 -- But there's a complication for pattern bindings:
 622 --      data T = MkT (forall a. a->a)
 623 --      MkT f = e
 624 -- Here we can guess a type variable for the entire LHS (which will be refined to T)
 625 -- but we want to get (f::forall a. a->a) as the RHS environment.
 626 -- The simplest way to do this is to typecheck the pattern, and then look up the
 627 -- bound mono-ids.  Then we want to retain the typechecked pattern to avoid re-doing
 628 -- it; hence the TcMonoBind data type in which the LHS is done but the RHS isn't
 629
 630 data TcMonoBind         -- Half completed; LHS done, RHS not done
 631   = TcFunBind  MonoBindInfo  (Located TcId) Bool (MatchGroup Name)
 632   | TcPatBind [MonoBindInfo] (LPat TcId) (GRHSs Name) TcSigmaType
 633
 634 type MonoBindInfo = (Name, Maybe TcSigInfo, TcId)
 635         -- Type signature (if any), and
 636         -- the monomorphic bound things
 637
 638 bndrNames :: [MonoBindInfo] -> [Name]
 639 bndrNames mbi = [n | (n,_,_) <- mbi]
 640
 641 getMonoType :: MonoBindInfo -> TcTauType
 642 getMonoType (_,_,mono_id) = idType mono_id
 643
 644 tcLhs :: TcSigFun -> HsBind Name -> TcM TcMonoBind
 645 tcLhs sig_fn (FunBind { fun_id = L nm_loc name, fun_infix = inf, fun_matches = matches })
 646   = do  { mb_sig <- tcInstSig_maybe sig_fn name
 647         ; mono_name <- newLocalName name
 648         ; mono_ty   <- mk_mono_ty mb_sig
 649         ; let mono_id = mkLocalId mono_name mono_ty
 650         ; return (TcFunBind (name, mb_sig, mono_id) (L nm_loc mono_id) inf matches) }
 651   where
 652     mk_mono_ty (Just sig) = return (sig_tau sig)
 653     mk_mono_ty Nothing    = newFlexiTyVarTy argTypeKind
 654
 655 tcLhs sig_fn (PatBind { pat_lhs = pat, pat_rhs = grhss })
 656   = do  { mb_sigs <- mapM (tcInstSig_maybe sig_fn) names
 657         ; mono_pat_binds <- doptM Opt_MonoPatBinds
 658                 -- With -XMonoPatBinds, we do no generalisation of pattern bindings
 659                 -- But the signature can still be polymoprhic!
 660                 --      data T = MkT (forall a. a->a)
 661                 --      x :: forall a. a->a
 662                 --      MkT x = <rhs>
 663                 -- The function get_sig_ty decides whether the pattern-bound variables
 664                 -- should have exactly the type in the type signature (-XMonoPatBinds),
 665                 -- or the instantiated version (-XMonoPatBinds)
 666
 667         ; let nm_sig_prs  = names `zip` mb_sigs
 668               get_sig_ty | mono_pat_binds = idType . sig_id
 669                          | otherwise      = sig_tau
 670               tau_sig_env = mkNameEnv [ (name, get_sig_ty sig)
 671                                       | (name, Just sig) <- nm_sig_prs]
 672               sig_tau_fn  = lookupNameEnv tau_sig_env
 673
 674               tc_pat exp_ty = tcLetPat sig_tau_fn pat exp_ty $
 675                               mapM lookup_info nm_sig_prs
 676
 677                 -- After typechecking the pattern, look up the binder
 678                 -- names, which the pattern has brought into scope.
 679               lookup_info :: (Name, Maybe TcSigInfo) -> TcM MonoBindInfo
 680               lookup_info (name, mb_sig) = do { mono_id <- tcLookupId name
 681                                               ; return (name, mb_sig, mono_id) }
 682
 683         ; ((pat', infos), pat_ty) <- addErrCtxt (patMonoBindsCtxt pat grhss) $
 684                                      tcInfer tc_pat
 685
 686         ; return (TcPatBind infos pat' grhss pat_ty) }
 687   where
 688     names = collectPatBinders pat
 689
 690
 691 tcLhs _ other_bind = pprPanic "tcLhs" (ppr other_bind)
 692         -- AbsBind, VarBind impossible
 693
 694 -------------------
 695 tcRhs :: TcMonoBind -> TcM (HsBind TcId)
 696 -- When we are doing pattern bindings, or multiple function bindings at a time
 697 -- we *don't* bring any scoped type variables into scope
 698 -- Wny not?  They are not completely rigid.
 699 -- That's why we have the special case for a single FunBind in tcMonoBinds
 700 tcRhs (TcFunBind (_,_,mono_id) fun' inf matches)
 701   = do  { (co_fn, matches') <- tcMatchesFun (idName mono_id) inf
 702                                             matches (idType mono_id)
 703         ; return (FunBind { fun_id = fun', fun_infix = inf, fun_matches = matches',
 704                             bind_fvs = placeHolderNames, fun_co_fn = co_fn,
 705                             fun_tick = Nothing }) }
 706
 707 tcRhs (TcPatBind _ pat' grhss pat_ty)
 708   = do  { grhss' <- addErrCtxt (patMonoBindsCtxt pat' grhss) $
 709                     tcGRHSsPat grhss pat_ty
 710         ; return (PatBind { pat_lhs = pat', pat_rhs = grhss', pat_rhs_ty = pat_ty,
 711                             bind_fvs = placeHolderNames }) }
 712
 713
 714 ---------------------
 715 getMonoBindInfo :: [Located TcMonoBind] -> [MonoBindInfo]
 716 getMonoBindInfo tc_binds
 717   = foldr (get_info . unLoc) [] tc_binds
 718   where
 719     get_info (TcFunBind info _ _ _)  rest = info : rest
 720     get_info (TcPatBind infos _ _ _) rest = infos ++ rest
 721 \end{code}
 722
 723
 724 %************************************************************************
 725 %*                                                                      *
 726                 Generalisation
 727 %*                                                                      *
 728 %************************************************************************
 729
 730 \begin{code}
 731 generalise :: DynFlags -> TopLevelFlag
 732            -> [LHsBind Name] -> TcSigFun
 733            -> [MonoBindInfo] -> [Inst]
 734            -> TcM ([TyVar], [Inst], TcDictBinds)
 735 -- The returned [TyVar] are all ready to quantify
 736
 737 generalise dflags top_lvl bind_list sig_fn mono_infos lie_req
 738   | isMonoGroup dflags bind_list
 739   = do  { extendLIEs lie_req
 740         ; return ([], [], emptyBag) }
 741
 742   | isRestrictedGroup dflags bind_list sig_fn   -- RESTRICTED CASE
 743   =     -- Check signature contexts are empty
 744     do  { checkTc (all is_mono_sig sigs)
 745                   (restrictedBindCtxtErr bndrs)
 746
 747         -- Now simplify with exactly that set of tyvars
 748         -- We have to squash those Methods
 749         ; (qtvs, binds) <- tcSimplifyRestricted doc top_lvl bndrs
 750                                                 tau_tvs lie_req
 751
 752         -- Check that signature type variables are OK
 753         ; final_qtvs <- checkSigsTyVars qtvs sigs
 754
 755         ; return (final_qtvs, [], binds) }
 756
 757   | null sigs   -- UNRESTRICTED CASE, NO TYPE SIGS
 758   = tcSimplifyInfer doc tau_tvs lie_req
 759
 760   | otherwise   -- UNRESTRICTED CASE, WITH TYPE SIGS
 761   = do  { sig_lie <- unifyCtxts sigs    -- sigs is non-empty; sig_lie is zonked
 762         ; let   -- The "sig_avails" is the stuff available.  We get that from
 763                 -- the context of the type signature, BUT ALSO the lie_avail
 764                 -- so that polymorphic recursion works right (see Note [Polymorphic recursion])
 765                 local_meths = [mkMethInst sig mono_id | (_, Just sig, mono_id) <- mono_infos]
 766                 sig_avails = sig_lie ++ local_meths
 767                 loc = sig_loc (head sigs)
 768
 769         -- Check that the needed dicts can be
 770         -- expressed in terms of the signature ones
 771         ; (qtvs, binds) <- tcSimplifyInferCheck loc tau_tvs sig_avails lie_req
 772
 773         -- Check that signature type variables are OK
 774         ; final_qtvs <- checkSigsTyVars qtvs sigs
 775
 776         ; return (final_qtvs, sig_lie, binds) }
 777   where
 778     bndrs   = bndrNames mono_infos
 779     sigs    = [sig | (_, Just sig, _) <- mono_infos]
 780     get_tvs | isTopLevel top_lvl = tyVarsOfType  -- See Note [Silly type synonym] in TcType
 781             | otherwise          = exactTyVarsOfType
 782     tau_tvs = foldr (unionVarSet . get_tvs . getMonoType) emptyVarSet mono_infos
 783     is_mono_sig sig = null (sig_theta sig)
 784     doc = ptext (sLit "type signature(s) for") <+> pprBinders bndrs
 785
 786     mkMethInst (TcSigInfo { sig_id = poly_id, sig_tvs = tvs,
 787                             sig_theta = theta, sig_loc = loc }) mono_id
 788       = Method {tci_id = mono_id, tci_oid = poly_id, tci_tys = mkTyVarTys tvs,
 789                 tci_theta = theta, tci_loc = loc}
 790 \end{code}
 791
 792 unifyCtxts checks that all the signature contexts are the same
 793 The type signatures on a mutually-recursive group of definitions
 794 must all have the same context (or none).
 795
 796 The trick here is that all the signatures should have the same
 797 context, and we want to share type variables for that context, so that
 798 all the right hand sides agree a common vocabulary for their type
 799 constraints
 800
 801 We unify them because, with polymorphic recursion, their types
 802 might not otherwise be related.  This is a rather subtle issue.
 803
 804 \begin{code}
 805 unifyCtxts :: [TcSigInfo] -> TcM [Inst]
 806 -- Post-condition: the returned Insts are full zonked
 807 unifyCtxts [] = panic "unifyCtxts []"
 808 unifyCtxts (sig1 : sigs)        -- Argument is always non-empty
 809   = do  { mapM unify_ctxt sigs
 810         ; theta <- zonkTcThetaType (sig_theta sig1)
 811         ; newDictBndrs (sig_loc sig1) theta }
 812   where
 813     theta1 = sig_theta sig1
 814     unify_ctxt :: TcSigInfo -> TcM ()
 815     unify_ctxt sig@(TcSigInfo { sig_theta = theta })
 816         = setSrcSpan (instLocSpan (sig_loc sig))        $
 817           addErrCtxt (sigContextsCtxt sig1 sig)         $
 818           do { cois <- unifyTheta theta1 theta
 819              ; -- Check whether all coercions are identity coercions
 820                -- That can happen if we have, say
 821                --         f :: C [a]   => ...
 822                --         g :: C (F a) => ...
 823                -- where F is a type function and (F a ~ [a])
 824                -- Then unification might succeed with a coercion.  But it's much
 825                -- much simpler to require that such signatures have identical contexts
 826                checkTc (all isIdentityCoercion cois)
 827                        (ptext (sLit "Mutually dependent functions have syntactically distinct contexts"))
 828              }
 829
 830 checkSigsTyVars :: [TcTyVar] -> [TcSigInfo] -> TcM [TcTyVar]
 831 checkSigsTyVars qtvs sigs
 832   = do  { gbl_tvs <- tcGetGlobalTyVars
 833         ; sig_tvs_s <- mapM (check_sig gbl_tvs) sigs
 834
 835         ; let   -- Sigh.  Make sure that all the tyvars in the type sigs
 836                 -- appear in the returned ty var list, which is what we are
 837                 -- going to generalise over.  Reason: we occasionally get
 838                 -- silly types like
 839                 --      type T a = () -> ()
 840                 --      f :: T a
 841                 --      f () = ()
 842                 -- Here, 'a' won't appear in qtvs, so we have to add it
 843                 sig_tvs = foldl extendVarSetList emptyVarSet sig_tvs_s
 844                 all_tvs = varSetElems (extendVarSetList sig_tvs qtvs)
 845         ; return all_tvs }
 846   where
 847     check_sig gbl_tvs (TcSigInfo {sig_id = id, sig_tvs = tvs,
 848                                   sig_theta = theta, sig_tau = tau})
 849       = addErrCtxt (ptext (sLit "In the type signature for") <+> quotes (ppr id))       $
 850         addErrCtxtM (sigCtxt id tvs theta tau)                                          $
 851         do { tvs' <- checkDistinctTyVars tvs
 852            ; when (any (`elemVarSet` gbl_tvs) tvs')
 853                   (bleatEscapedTvs gbl_tvs tvs tvs')
 854            ; return tvs' }
 855
 856 checkDistinctTyVars :: [TcTyVar] -> TcM [TcTyVar]
 857 -- (checkDistinctTyVars tvs) checks that the tvs from one type signature
 858 -- are still all type variables, and all distinct from each other.
 859 -- It returns a zonked set of type variables.
 860 -- For example, if the type sig is
 861 --      f :: forall a b. a -> b -> b
 862 -- we want to check that 'a' and 'b' haven't
 863 --      (a) been unified with a non-tyvar type
 864 --      (b) been unified with each other (all distinct)
 865
 866 checkDistinctTyVars sig_tvs
 867   = do  { zonked_tvs <- mapM zonkSigTyVar sig_tvs
 868         ; foldlM check_dup emptyVarEnv (sig_tvs `zip` zonked_tvs)
 869         ; return zonked_tvs }
 870   where
 871     check_dup :: TyVarEnv TcTyVar -> (TcTyVar, TcTyVar) -> TcM (TyVarEnv TcTyVar)
 872         -- The TyVarEnv maps each zonked type variable back to its
 873         -- corresponding user-written signature type variable
 874     check_dup acc (sig_tv, zonked_tv)
 875         = case lookupVarEnv acc zonked_tv of
 876                 Just sig_tv' -> bomb_out sig_tv sig_tv'
 877
 878                 Nothing -> return (extendVarEnv acc zonked_tv sig_tv)
 879
 880     bomb_out sig_tv1 sig_tv2
 881        = do { env0 <- tcInitTidyEnv
 882             ; let (env1, tidy_tv1) = tidyOpenTyVar env0 sig_tv1
 883                   (env2, tidy_tv2) = tidyOpenTyVar env1 sig_tv2
 884                   msg = ptext (sLit "Quantified type variable") <+> quotes (ppr tidy_tv1)
 885                          <+> ptext (sLit "is unified with another quantified type variable")
 886                          <+> quotes (ppr tidy_tv2)
 887             ; failWithTcM (env2, msg) }
 888 \end{code}
 889
 890
 891 @getTyVarsToGen@ decides what type variables to generalise over.
 892
 893 For a "restricted group" -- see the monomorphism restriction
 894 for a definition -- we bind no dictionaries, and
 895 remove from tyvars_to_gen any constrained type variables
 896
 897 *Don't* simplify dicts at this point, because we aren't going
 898 to generalise over these dicts.  By the time we do simplify them
 899 we may well know more.  For example (this actually came up)
 900         f :: Array Int Int
 901         f x = array ... xs where xs = [1,2,3,4,5]
 902 We don't want to generate lots of (fromInt Int 1), (fromInt Int 2)
 903 stuff.  If we simplify only at the f-binding (not the xs-binding)
 904 we'll know that the literals are all Ints, and we can just produce
 905 Int literals!
 906
 907 Find all the type variables involved in overloading, the
 908 "constrained_tyvars".  These are the ones we *aren't* going to
 909 generalise.  We must be careful about doing this:
 910
 911  (a) If we fail to generalise a tyvar which is not actually
 912         constrained, then it will never, ever get bound, and lands
 913         up printed out in interface files!  Notorious example:
 914                 instance Eq a => Eq (Foo a b) where ..
 915         Here, b is not constrained, even though it looks as if it is.
 916         Another, more common, example is when there's a Method inst in
 917         the LIE, whose type might very well involve non-overloaded
 918         type variables.
 919   [NOTE: Jan 2001: I don't understand the problem here so I'm doing
 920         the simple thing instead]
 921
 922  (b) On the other hand, we mustn't generalise tyvars which are constrained,
 923         because we are going to pass on out the unmodified LIE, with those
 924         tyvars in it.  They won't be in scope if we've generalised them.
 925
 926 So we are careful, and do a complete simplification just to find the
 927 constrained tyvars. We don't use any of the results, except to
 928 find which tyvars are constrained.
 929
 930 Note [Polymorphic recursion]
 931 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 932 The game plan for polymorphic recursion in the code above is
 933
 934         * Bind any variable for which we have a type signature
 935           to an Id with a polymorphic type.  Then when type-checking
 936           the RHSs we'll make a full polymorphic call.
 937
 938 This fine, but if you aren't a bit careful you end up with a horrendous
 939 amount of partial application and (worse) a huge space leak. For example:
 940
 941         f :: Eq a => [a] -> [a]
 942         f xs = ...f...
 943
 944 If we don't take care, after typechecking we get
 945
 946         f = /\a -> \d::Eq a -> let f' = f a d
 947                                in
 948                                \ys:[a] -> ...f'...
 949
 950 Notice the the stupid construction of (f a d), which is of course
 951 identical to the function we're executing.  In this case, the
 952 polymorphic recursion isn't being used (but that's a very common case).
 953 This can lead to a massive space leak, from the following top-level defn
 954 (post-typechecking)
 955
 956         ff :: [Int] -> [Int]
 957         ff = f Int dEqInt
 958
 959 Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
 960 f' is another thunk which evaluates to the same thing... and you end
 961 up with a chain of identical values all hung onto by the CAF ff.
 962
 963         ff = f Int dEqInt
 964
 965            = let f' = f Int dEqInt in \ys. ...f'...
 966
 967            = let f' = let f' = f Int dEqInt in \ys. ...f'...
 968                       in \ys. ...f'...
 969
 970 Etc.
 971
 972 NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
 973 which would make the space leak go away in this case
 974
 975 Solution: when typechecking the RHSs we always have in hand the
 976 *monomorphic* Ids for each binding.  So we just need to make sure that
 977 if (Method f a d) shows up in the constraints emerging from (...f...)
 978 we just use the monomorphic Id.  We achieve this by adding monomorphic Ids
 979 to the "givens" when simplifying constraints.  That's what the "lies_avail"
 980 is doing.
 981
 982 Then we get
 983
 984         f = /\a -> \d::Eq a -> letrec
 985                                  fm = \ys:[a] -> ...fm...
 986                                in
 987                                fm
 988
 989
 990
 991 %************************************************************************
 992 %*                                                                      *
 993                 Signatures
 994 %*                                                                      *
 995 %************************************************************************
 996
 997 Type signatures are tricky.  See Note [Signature skolems] in TcType
 998
 999 @tcSigs@ checks the signatures for validity, and returns a list of
1000 {\em freshly-instantiated} signatures.  That is, the types are already
1001 split up, and have fresh type variables installed.  All non-type-signature
1002 "RenamedSigs" are ignored.
1003
1004 The @TcSigInfo@ contains @TcTypes@ because they are unified with
1005 the variable's type, and after that checked to see whether they've
1006 been instantiated.
1007
1008 Note [Scoped tyvars]
1009 ~~~~~~~~~~~~~~~~~~~~
1010 The -XScopedTypeVariables flag brings lexically-scoped type variables
1011 into scope for any explicitly forall-quantified type variables:
1012         f :: forall a. a -> a
1013         f x = e
1014 Then 'a' is in scope inside 'e'.
1015
1016 However, we do *not* support this
1017   - For pattern bindings e.g
1018         f :: forall a. a->a
1019         (f,g) = e
1020
1021   - For multiple function bindings, unless Opt_RelaxedPolyRec is on
1022         f :: forall a. a -> a
1023         f = g
1024         g :: forall b. b -> b
1025         g = ...f...
1026     Reason: we use mutable variables for 'a' and 'b', since they may
1027     unify to each other, and that means the scoped type variable would
1028     not stand for a completely rigid variable.
1029
1030     Currently, we simply make Opt_ScopedTypeVariables imply Opt_RelaxedPolyRec
1031
1032
1033 Note [More instantiated than scoped]
1034 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1035 There may be more instantiated type variables than lexically-scoped
1036 ones.  For example:
1037         type T a = forall b. b -> (a,b)
1038         f :: forall c. T c
1039 Here, the signature for f will have one scoped type variable, c,
1040 but two instantiated type variables, c' and b'.
1041
1042 We assume that the scoped ones are at the *front* of sig_tvs,
1043 and remember the names from the original HsForAllTy in the TcSigFun.
1044
1045
1046 \begin{code}
1047 type TcSigFun = Name -> Maybe [Name]    -- Maps a let-binder to the list of
1048                                         -- type variables brought into scope
1049                                         -- by its type signature.
1050                                         -- Nothing => no type signature
1051
1052 mkTcSigFun :: [LSig Name] -> TcSigFun
1053 -- Search for a particular type signature
1054 -- Precondition: the sigs are all type sigs
1055 -- Precondition: no duplicates
1056 mkTcSigFun sigs = lookupNameEnv env
1057   where
1058     env = mkNameEnv [(name, hsExplicitTvs lhs_ty)
1059                     | L _ (TypeSig (L _ name) lhs_ty) <- sigs]
1060         -- The scoped names are the ones explicitly mentioned
1061         -- in the HsForAll.  (There may be more in sigma_ty, because
1062         -- of nested type synonyms.  See Note [More instantiated than scoped].)
1063         -- See Note [Only scoped tyvars are in the TyVarEnv]
1064
1065 ---------------
1066 data TcSigInfo
1067   = TcSigInfo {
1068         sig_id     :: TcId,             --  *Polymorphic* binder for this value...
1069
1070         sig_tvs    :: [TcTyVar],        -- Instantiated type variables
1071                                         -- See Note [Instantiate sig]
1072
1073         sig_theta  :: TcThetaType,      -- Instantiated theta
1074         sig_tau    :: TcTauType,        -- Instantiated tau
1075         sig_loc    :: InstLoc           -- The location of the signature
1076     }
1077
1078
1079 --      Note [Only scoped tyvars are in the TyVarEnv]
1080 -- We are careful to keep only the *lexically scoped* type variables in
1081 -- the type environment.  Why?  After all, the renamer has ensured
1082 -- that only legal occurrences occur, so we could put all type variables
1083 -- into the type env.
1084 --
1085 -- But we want to check that two distinct lexically scoped type variables
1086 -- do not map to the same internal type variable.  So we need to know which
1087 -- the lexically-scoped ones are... and at the moment we do that by putting
1088 -- only the lexically scoped ones into the environment.
1089
1090
1091 --      Note [Instantiate sig]
1092 -- It's vital to instantiate a type signature with fresh variables.
1093 -- For example:
1094 --      type S = forall a. a->a
1095 --      f,g :: S
1096 --      f = ...
1097 --      g = ...
1098 -- Here, we must use distinct type variables when checking f,g's right hand sides.
1099 -- (Instantiation is only necessary because of type synonyms.  Otherwise,
1100 -- it's all cool; each signature has distinct type variables from the renamer.)
1101
1102 instance Outputable TcSigInfo where
1103     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau})
1104         = ppr id <+> ptext (sLit "::") <+> ppr tyvars <+> ppr theta <+> ptext (sLit "=>") <+> ppr tau
1105 \end{code}
1106
1107 \begin{code}
1108 tcTySig :: LSig Name -> TcM TcId
1109 tcTySig (L span (TypeSig (L _ name) ty))
1110   = setSrcSpan span             $
1111     do  { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
1112         ; return (mkLocalId name sigma_ty) }
1113 tcTySig s = pprPanic "tcTySig" (ppr s)
1114
1115 -------------------
1116 tcInstSig_maybe :: TcSigFun -> Name -> TcM (Maybe TcSigInfo)
1117 -- Instantiate with *meta* type variables;
1118 -- this signature is part of a multi-signature group
1119 tcInstSig_maybe sig_fn name
1120   = case sig_fn name of
1121         Nothing -> return Nothing
1122         Just _scoped_tvs -> do   { tc_sig <- tcInstSig False name
1123                                  ; return (Just tc_sig) }
1124         -- NB: the _scoped_tvs may be non-empty, but we can
1125         -- just ignore them.  See Note [Scoped tyvars].
1126
1127 tcInstSig :: Bool -> Name -> TcM TcSigInfo
1128 -- Instantiate the signature, with either skolems or meta-type variables
1129 -- depending on the use_skols boolean.  This variable is set True
1130 -- when we are typechecking a single function binding; and False for
1131 -- pattern bindings and a group of several function bindings.
1132 -- Reason: in the latter cases, the "skolems" can be unified together,
1133 --         so they aren't properly rigid in the type-refinement sense.
1134 -- NB: unless we are doing H98, each function with a sig will be done
1135 --     separately, even if it's mutually recursive, so use_skols will be True
1136 --
1137 -- We always instantiate with fresh uniques,
1138 -- although we keep the same print-name
1139 --
1140 --      type T = forall a. [a] -> [a]
1141 --      f :: T;
1142 --      f = g where { g :: T; g = <rhs> }
1143 --
1144 -- We must not use the same 'a' from the defn of T at both places!!
1145
1146 tcInstSig use_skols name
1147   = do  { poly_id <- tcLookupId name    -- Cannot fail; the poly ids are put into
1148                                         -- scope when starting the binding group
1149         ; let skol_info = SigSkol (FunSigCtxt name)
1150         ; (tvs, theta, tau) <- tcInstSigType use_skols skol_info (idType poly_id)
1151         ; loc <- getInstLoc (SigOrigin skol_info)
1152         ; return (TcSigInfo { sig_id = poly_id,
1153                               sig_tvs = tvs, sig_theta = theta, sig_tau = tau,
1154                               sig_loc = loc }) }
1155
1156 -------------------
1157 isMonoGroup :: DynFlags -> [LHsBind Name] -> Bool
1158 -- No generalisation at all
1159 isMonoGroup dflags binds
1160   = dopt Opt_MonoPatBinds dflags && any is_pat_bind binds
1161   where
1162     is_pat_bind (L _ (PatBind {})) = True
1163     is_pat_bind _                  = False
1164
1165 -------------------
1166 isRestrictedGroup :: DynFlags -> [LHsBind Name] -> TcSigFun -> Bool
1167 isRestrictedGroup dflags binds sig_fn
1168   = mono_restriction && not all_unrestricted
1169   where
1170     mono_restriction = dopt Opt_MonomorphismRestriction dflags
1171     all_unrestricted = all (unrestricted . unLoc) binds
1172     has_sig n = isJust (sig_fn n)
1173
1174     unrestricted (PatBind {})                                    = False
1175     unrestricted (VarBind { var_id = v })                        = has_sig v
1176     unrestricted (FunBind { fun_id = v, fun_matches = matches }) = unrestricted_match matches
1177                                                                  || has_sig (unLoc v)
1178     unrestricted (AbsBinds {})
1179         = panic "isRestrictedGroup/unrestricted AbsBinds"
1180
1181     unrestricted_match (MatchGroup (L _ (Match [] _ _) : _) _) = False
1182         -- No args => like a pattern binding
1183     unrestricted_match _                                       = True
1184         -- Some args => a function binding
1185 \end{code}
1186
1187
1188 %************************************************************************
1189 %*                                                                      *
1190 \subsection[TcBinds-errors]{Error contexts and messages}
1191 %*                                                                      *
1192 %************************************************************************
1193
1194
1195 \begin{code}
1196 -- This one is called on LHS, when pat and grhss are both Name
1197 -- and on RHS, when pat is TcId and grhss is still Name
1198 patMonoBindsCtxt :: OutputableBndr id => LPat id -> GRHSs Name -> SDoc
1199 patMonoBindsCtxt pat grhss
1200   = hang (ptext (sLit "In a pattern binding:")) 4 (pprPatBind pat grhss)
1201
1202 -----------------------------------------------
1203 sigContextsCtxt :: TcSigInfo -> TcSigInfo -> SDoc
1204 sigContextsCtxt sig1 sig2
1205   = vcat [ptext (sLit "When matching the contexts of the signatures for"),
1206           nest 2 (vcat [ppr id1 <+> dcolon <+> ppr (idType id1),
1207                         ppr id2 <+> dcolon <+> ppr (idType id2)]),
1208           ptext (sLit "The signature contexts in a mutually recursive group should all be identical")]
1209   where
1210     id1 = sig_id sig1
1211     id2 = sig_id sig2
1212
1213
1214 -----------------------------------------------
1215 unboxedTupleErr :: Name -> Type -> SDoc
1216 unboxedTupleErr name ty
1217   = hang (ptext (sLit "Illegal binding of unboxed tuple"))
1218          4 (ppr name <+> dcolon <+> ppr ty)
1219
1220 -----------------------------------------------
1221 restrictedBindCtxtErr :: [Name] -> SDoc
1222 restrictedBindCtxtErr binder_names
1223   = hang (ptext (sLit "Illegal overloaded type signature(s)"))
1224        4 (vcat [ptext (sLit "in a binding group for") <+> pprBinders binder_names,
1225                 ptext (sLit "that falls under the monomorphism restriction")])
1226
1227 genCtxt :: [Name] -> SDoc
1228 genCtxt binder_names
1229   = ptext (sLit "When generalising the type(s) for") <+> pprBinders binder_names
1230
1231 missingSigWarn :: Bool -> Name -> Type -> TcM ()
1232 missingSigWarn False _    _  = return ()
1233 missingSigWarn True  name ty
1234   = do  { env0 <- tcInitTidyEnv
1235         ; let (env1, tidy_ty) = tidyOpenType env0 ty
1236         ; addWarnTcM (env1, mk_msg tidy_ty) }
1237   where
1238     mk_msg ty = vcat [ptext (sLit "Definition but no type signature for") <+> quotes (ppr name),
1239                       sep [ptext (sLit "Inferred type:") <+> pprHsVar name <+> dcolon <+> ppr ty]]
1240 \end{code}