compiler/typecheck/TcBinds.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcBinds]{TcBinds}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcBinds ( tcLocalBinds, tcTopBinds,
  16                  tcHsBootSigs, tcMonoBinds,
  17                  TcPragFun, tcSpecPrag, tcPrags, mkPragFun,
  18                  TcSigInfo(..), TcSigFun, mkTcSigFun,
  19                  badBootDeclErr ) where
  20
  21 #include "HsVersions.h"
  22
  23 import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
  24 import {-# SOURCE #-} TcExpr  ( tcMonoExpr )
  25
  26 import DynFlags
  27 import HsSyn
  28 import TcHsSyn
  29
  30 import TcRnMonad
  31 import Inst
  32 import TcEnv
  33 import TcUnify
  34 import TcSimplify
  35 import TcHsType
  36 import TcPat
  37 import TcMType
  38 import TcType
  39 import {- Kind parts of -} Type
  40 import Coercion
  41 import VarEnv
  42 import TysPrim
  43 import Id
  44 import IdInfo
  45 import Var ( TyVar, varType )
  46 import Name
  47 import NameSet
  48 import NameEnv
  49 import VarSet
  50 import SrcLoc
  51 import Bag
  52 import ErrUtils
  53 import Digraph
  54 import Maybes
  55 import List
  56 import Util
  57 import BasicTypes
  58 import Outputable
  59 \end{code}
  60
  61
  62 %************************************************************************
  63 %*                                                                      *
  64 \subsection{Type-checking bindings}
  65 %*                                                                      *
  66 %************************************************************************
  67
  68 @tcBindsAndThen@ typechecks a @HsBinds@.  The "and then" part is because
  69 it needs to know something about the {\em usage} of the things bound,
  70 so that it can create specialisations of them.  So @tcBindsAndThen@
  71 takes a function which, given an extended environment, E, typechecks
  72 the scope of the bindings returning a typechecked thing and (most
  73 important) an LIE.  It is this LIE which is then used as the basis for
  74 specialising the things bound.
  75
  76 @tcBindsAndThen@ also takes a "combiner" which glues together the
  77 bindings and the "thing" to make a new "thing".
  78
  79 The real work is done by @tcBindWithSigsAndThen@.
  80
  81 Recursive and non-recursive binds are handled in essentially the same
  82 way: because of uniques there are no scoping issues left.  The only
  83 difference is that non-recursive bindings can bind primitive values.
  84
  85 Even for non-recursive binding groups we add typings for each binder
  86 to the LVE for the following reason.  When each individual binding is
  87 checked the type of its LHS is unified with that of its RHS; and
  88 type-checking the LHS of course requires that the binder is in scope.
  89
  90 At the top-level the LIE is sure to contain nothing but constant
  91 dictionaries, which we resolve at the module level.
  92
  93 \begin{code}
  94 tcTopBinds :: HsValBinds Name -> TcM (LHsBinds TcId, TcLclEnv)
  95         -- Note: returning the TcLclEnv is more than we really
  96         --       want.  The bit we care about is the local bindings
  97         --       and the free type variables thereof
  98 tcTopBinds binds
  99   = do  { (ValBindsOut prs _, env) <- tcValBinds TopLevel binds getLclEnv
 100         ; return (foldr (unionBags . snd) emptyBag prs, env) }
 101         -- The top level bindings are flattened into a giant
 102         -- implicitly-mutually-recursive LHsBinds
 103
 104 tcHsBootSigs :: HsValBinds Name -> TcM [Id]
 105 -- A hs-boot file has only one BindGroup, and it only has type
 106 -- signatures in it.  The renamer checked all this
 107 tcHsBootSigs (ValBindsOut binds sigs)
 108   = do  { checkTc (null binds) badBootDeclErr
 109         ; mapM (addLocM tc_boot_sig) (filter isVanillaLSig sigs) }
 110   where
 111     tc_boot_sig (TypeSig (L _ name) ty)
 112       = do { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
 113            ; return (mkVanillaGlobal name sigma_ty vanillaIdInfo) }
 114         -- Notice that we make GlobalIds, not LocalIds
 115 tcHsBootSigs groups = pprPanic "tcHsBootSigs" (ppr groups)
 116
 117 badBootDeclErr :: Message
 118 badBootDeclErr = ptext SLIT("Illegal declarations in an hs-boot file")
 119
 120 ------------------------
 121 tcLocalBinds :: HsLocalBinds Name -> TcM thing
 122              -> TcM (HsLocalBinds TcId, thing)
 123
 124 tcLocalBinds EmptyLocalBinds thing_inside
 125   = do  { thing <- thing_inside
 126         ; return (EmptyLocalBinds, thing) }
 127
 128 tcLocalBinds (HsValBinds binds) thing_inside
 129   = do  { (binds', thing) <- tcValBinds NotTopLevel binds thing_inside
 130         ; return (HsValBinds binds', thing) }
 131
 132 tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
 133   = do  { (thing, lie) <- getLIE thing_inside
 134         ; (avail_ips, ip_binds') <- mapAndUnzipM (wrapLocSndM tc_ip_bind) ip_binds
 135
 136         -- If the binding binds ?x = E, we  must now
 137         -- discharge any ?x constraints in expr_lie
 138         ; dict_binds <- tcSimplifyIPs avail_ips lie
 139         ; return (HsIPBinds (IPBinds ip_binds' dict_binds), thing) }
 140   where
 141         -- I wonder if we should do these one at at time
 142         -- Consider     ?x = 4
 143         --              ?y = ?x + 1
 144     tc_ip_bind (IPBind ip expr)
 145       = newFlexiTyVarTy argTypeKind             `thenM` \ ty ->
 146         newIPDict (IPBindOrigin ip) ip ty       `thenM` \ (ip', ip_inst) ->
 147         tcMonoExpr expr ty                      `thenM` \ expr' ->
 148         returnM (ip_inst, (IPBind ip' expr'))
 149
 150 ------------------------
 151 tcValBinds :: TopLevelFlag
 152            -> HsValBinds Name -> TcM thing
 153            -> TcM (HsValBinds TcId, thing)
 154
 155 tcValBinds top_lvl (ValBindsIn binds sigs) thing_inside
 156   = pprPanic "tcValBinds" (ppr binds)
 157
 158 tcValBinds top_lvl (ValBindsOut binds sigs) thing_inside
 159   = do  {       -- Typecheck the signature
 160         ; let { prag_fn = mkPragFun sigs
 161               ; ty_sigs = filter isVanillaLSig sigs
 162               ; sig_fn  = mkTcSigFun ty_sigs }
 163
 164         ; poly_ids <- mapM tcTySig ty_sigs
 165                 -- No recovery from bad signatures, because the type sigs
 166                 -- may bind type variables, so proceeding without them
 167                 -- can lead to a cascade of errors
 168                 -- ToDo: this means we fall over immediately if any type sig
 169                 -- is wrong, which is over-conservative, see Trac bug #745
 170
 171                 -- Extend the envt right away with all
 172                 -- the Ids declared with type signatures
 173         ; poly_rec <- doptM Opt_RelaxedPolyRec
 174         ; (binds', thing) <- tcExtendIdEnv poly_ids $
 175                              tc_val_binds poly_rec top_lvl sig_fn prag_fn
 176                                           binds thing_inside
 177
 178         ; return (ValBindsOut binds' sigs, thing) }
 179
 180 ------------------------
 181 tc_val_binds :: Bool -> TopLevelFlag -> TcSigFun -> TcPragFun
 182              -> [(RecFlag, LHsBinds Name)] -> TcM thing
 183              -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 184 -- Typecheck a whole lot of value bindings,
 185 -- one strongly-connected component at a time
 186
 187 tc_val_binds poly_rec top_lvl sig_fn prag_fn [] thing_inside
 188   = do  { thing <- thing_inside
 189         ; return ([], thing) }
 190
 191 tc_val_binds poly_rec top_lvl sig_fn prag_fn (group : groups) thing_inside
 192   = do  { (group', (groups', thing))
 193                 <- tc_group poly_rec top_lvl sig_fn prag_fn group $
 194                    tc_val_binds poly_rec top_lvl sig_fn prag_fn groups thing_inside
 195         ; return (group' ++ groups', thing) }
 196
 197 ------------------------
 198 tc_group :: Bool -> TopLevelFlag -> TcSigFun -> TcPragFun
 199          -> (RecFlag, LHsBinds Name) -> TcM thing
 200          -> TcM ([(RecFlag, LHsBinds TcId)], thing)
 201
 202 -- Typecheck one strongly-connected component of the original program.
 203 -- We get a list of groups back, because there may
 204 -- be specialisations etc as well
 205
 206 tc_group poly_rec top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
 207         -- A single non-recursive binding
 208         -- We want to keep non-recursive things non-recursive
 209         -- so that we desugar unlifted bindings correctly
 210  =  do  { (binds, thing) <- tc_haskell98 top_lvl sig_fn prag_fn NonRecursive binds thing_inside
 211         ; return ([(NonRecursive, b) | b <- binds], thing) }
 212
 213 tc_group poly_rec top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
 214   | not poly_rec        -- Recursive group, normal Haskell 98 route
 215   = do  { (binds1, thing) <- tc_haskell98 top_lvl sig_fn prag_fn Recursive binds thing_inside
 216         ; return ([(Recursive, unionManyBags binds1)], thing) }
 217
 218   | otherwise           -- Recursive group, with gla-exts
 219   =     -- To maximise polymorphism (with -fglasgow-exts), we do a new
 220         -- strongly-connected-component analysis, this time omitting
 221         -- any references to variables with type signatures.
 222         --
 223         -- Notice that the bindInsts thing covers *all* the bindings in the original
 224         -- group at once; an earlier one may use a later one!
 225     do  { traceTc (text "tc_group rec" <+> pprLHsBinds binds)
 226         ; (binds1,thing) <- bindLocalInsts top_lvl $
 227                             go (stronglyConnComp (mkEdges sig_fn binds))
 228         ; return ([(Recursive, unionManyBags binds1)], thing) }
 229                 -- Rec them all together
 230   where
 231 --  go :: SCC (LHsBind Name) -> TcM ([LHsBind TcId], [TcId], thing)
 232     go (scc:sccs) = do  { (binds1, ids1) <- tc_scc scc
 233                         ; (binds2, ids2, thing) <- tcExtendIdEnv ids1 $ go sccs
 234                         ; return (binds1 ++ binds2, ids1 ++ ids2, thing) }
 235     go []         = do  { thing <- thing_inside; return ([], [], thing) }
 236
 237     tc_scc (AcyclicSCC bind) = tc_sub_group NonRecursive (unitBag bind)
 238     tc_scc (CyclicSCC binds) = tc_sub_group Recursive    (listToBag binds)
 239
 240     tc_sub_group = tcPolyBinds top_lvl sig_fn prag_fn Recursive
 241
 242 tc_haskell98 top_lvl sig_fn prag_fn rec_flag binds thing_inside
 243   = bindLocalInsts top_lvl $ do
 244     { (binds1, ids) <- tcPolyBinds top_lvl sig_fn prag_fn rec_flag rec_flag binds
 245     ; thing <- tcExtendIdEnv ids thing_inside
 246     ; return (binds1, ids, thing) }
 247
 248 ------------------------
 249 bindLocalInsts :: TopLevelFlag -> TcM ([LHsBinds TcId], [TcId], a) -> TcM ([LHsBinds TcId], a)
 250 bindLocalInsts top_lvl thing_inside
 251   | isTopLevel top_lvl = do { (binds, ids, thing) <- thing_inside; return (binds, thing) }
 252         -- For the top level don't bother with all this bindInstsOfLocalFuns stuff.
 253         -- All the top level things are rec'd together anyway, so it's fine to
 254         -- leave them to the tcSimplifyTop, and quite a bit faster too
 255
 256   | otherwise   -- Nested case
 257   = do  { ((binds, ids, thing), lie) <- getLIE thing_inside
 258         ; lie_binds <- bindInstsOfLocalFuns lie ids
 259         ; return (binds ++ [lie_binds], thing) }
 260
 261 ------------------------
 262 mkEdges :: TcSigFun -> LHsBinds Name
 263         -> [(LHsBind Name, BKey, [BKey])]
 264
 265 type BKey  = Int -- Just number off the bindings
 266
 267 mkEdges sig_fn binds
 268   = [ (bind, key, [key | n <- nameSetToList (bind_fvs (unLoc bind)),
 269                          Just key <- [lookupNameEnv key_map n], no_sig n ])
 270     | (bind, key) <- keyd_binds
 271     ]
 272   where
 273     no_sig :: Name -> Bool
 274     no_sig n = isNothing (sig_fn n)
 275
 276     keyd_binds = bagToList binds `zip` [0::BKey ..]
 277
 278     key_map :: NameEnv BKey     -- Which binding it comes from
 279     key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
 280                                      , bndr <- bindersOfHsBind bind ]
 281
 282 bindersOfHsBind :: HsBind Name -> [Name]
 283 bindersOfHsBind (PatBind { pat_lhs = pat })  = collectPatBinders pat
 284 bindersOfHsBind (FunBind { fun_id = L _ f }) = [f]
 285
 286 ------------------------
 287 tcPolyBinds :: TopLevelFlag -> TcSigFun -> TcPragFun
 288             -> RecFlag                  -- Whether the group is really recursive
 289             -> RecFlag                  -- Whether it's recursive after breaking
 290                                         -- dependencies based on type signatures
 291             -> LHsBinds Name
 292             -> TcM ([LHsBinds TcId], [TcId])
 293
 294 -- Typechecks a single bunch of bindings all together,
 295 -- and generalises them.  The bunch may be only part of a recursive
 296 -- group, because we use type signatures to maximise polymorphism
 297 --
 298 -- Returns a list because the input may be a single non-recursive binding,
 299 -- in which case the dependency order of the resulting bindings is
 300 -- important.
 301 --
 302 -- Knows nothing about the scope of the bindings
 303
 304 tcPolyBinds top_lvl sig_fn prag_fn rec_group rec_tc binds
 305   = let
 306         bind_list    = bagToList binds
 307         binder_names = collectHsBindBinders binds
 308         loc          = getLoc (head bind_list)
 309                 -- TODO: location a bit awkward, but the mbinds have been
 310                 --       dependency analysed and may no longer be adjacent
 311     in
 312         -- SET UP THE MAIN RECOVERY; take advantage of any type sigs
 313     setSrcSpan loc                              $
 314     recoverM (recoveryCode binder_names sig_fn) $ do
 315
 316   { traceTc (ptext SLIT("------------------------------------------------"))
 317   ; traceTc (ptext SLIT("Bindings for") <+> ppr binder_names)
 318
 319         -- TYPECHECK THE BINDINGS
 320   ; ((binds', mono_bind_infos), lie_req)
 321         <- getLIE (tcMonoBinds bind_list sig_fn rec_tc)
 322   ; traceTc (text "temp" <+> (ppr binds' $$ ppr lie_req))
 323
 324         -- CHECK FOR UNLIFTED BINDINGS
 325         -- These must be non-recursive etc, and are not generalised
 326         -- They desugar to a case expression in the end
 327   ; zonked_mono_tys <- zonkTcTypes (map getMonoType mono_bind_infos)
 328   ; is_strict <- checkStrictBinds top_lvl rec_group binds'
 329                                   zonked_mono_tys mono_bind_infos
 330   ; if is_strict then
 331     do  { extendLIEs lie_req
 332         ; let exports = zipWith mk_export mono_bind_infos zonked_mono_tys
 333               mk_export (name, Nothing,  mono_id) mono_ty = ([], mkLocalId name mono_ty, mono_id, [])
 334               mk_export (name, Just sig, mono_id) mono_ty = ([], sig_id sig,             mono_id, [])
 335                         -- ToDo: prags for unlifted bindings
 336
 337         ; return ( [unitBag $ L loc $ AbsBinds [] [] exports binds'],
 338                    [poly_id | (_, poly_id, _, _) <- exports]) } -- Guaranteed zonked
 339
 340     else do     -- The normal lifted case: GENERALISE
 341   { dflags <- getDOpts
 342   ; (tyvars_to_gen, dicts, dict_binds)
 343         <- addErrCtxt (genCtxt (bndrNames mono_bind_infos)) $
 344            generalise dflags top_lvl bind_list sig_fn mono_bind_infos lie_req
 345
 346         -- BUILD THE POLYMORPHIC RESULT IDs
 347   ; let dict_vars = map instToVar dicts -- May include equality constraints
 348   ; exports <- mapM (mkExport top_lvl prag_fn tyvars_to_gen (map varType dict_vars))
 349                     mono_bind_infos
 350
 351   ; let poly_ids = [poly_id | (_, poly_id, _, _) <- exports]
 352   ; traceTc (text "binding:" <+> ppr (poly_ids `zip` map idType poly_ids))
 353
 354   ; let abs_bind = L loc $ AbsBinds tyvars_to_gen
 355                                     dict_vars exports
 356                                     (dict_binds `unionBags` binds')
 357
 358   ; return ([unitBag abs_bind], poly_ids)       -- poly_ids are guaranteed zonked by mkExport
 359   } }
 360
 361
 362 --------------
 363 mkExport :: TopLevelFlag -> TcPragFun -> [TyVar] -> [TcType]
 364          -> MonoBindInfo
 365          -> TcM ([TyVar], Id, Id, [LPrag])
 366 -- mkExport generates exports with
 367 --      zonked type variables,
 368 --      zonked poly_ids
 369 -- The former is just because no further unifications will change
 370 -- the quantified type variables, so we can fix their final form
 371 -- right now.
 372 -- The latter is needed because the poly_ids are used to extend the
 373 -- type environment; see the invariant on TcEnv.tcExtendIdEnv
 374
 375 -- Pre-condition: the inferred_tvs are already zonked
 376
 377 mkExport top_lvl prag_fn inferred_tvs dict_tys (poly_name, mb_sig, mono_id)
 378   = do  { warn_missing_sigs <- doptM Opt_WarnMissingSigs
 379         ; let warn = isTopLevel top_lvl && warn_missing_sigs
 380         ; (tvs, poly_id) <- mk_poly_id warn mb_sig
 381                 -- poly_id has a zonked type
 382
 383         ; prags <- tcPrags poly_id (prag_fn poly_name)
 384                 -- tcPrags requires a zonked poly_id
 385
 386         ; return (tvs, poly_id, mono_id, prags) }
 387   where
 388     poly_ty = mkForAllTys inferred_tvs (mkFunTys dict_tys (idType mono_id))
 389
 390     mk_poly_id warn Nothing    = do { poly_ty' <- zonkTcType poly_ty
 391                                     ; missingSigWarn warn poly_name poly_ty'
 392                                     ; return (inferred_tvs, mkLocalId poly_name poly_ty') }
 393     mk_poly_id warn (Just sig) = do { tvs <- mapM zonk_tv (sig_tvs sig)
 394                                     ; return (tvs,  sig_id sig) }
 395
 396     zonk_tv tv = do { ty <- zonkTcTyVar tv; return (tcGetTyVar "mkExport" ty) }
 397
 398 ------------------------
 399 type TcPragFun = Name -> [LSig Name]
 400
 401 mkPragFun :: [LSig Name] -> TcPragFun
 402 mkPragFun sigs = \n -> lookupNameEnv env n `orElse` []
 403         where
 404           prs = [(expectJust "mkPragFun" (sigName sig), sig)
 405                 | sig <- sigs, isPragLSig sig]
 406           env = foldl add emptyNameEnv prs
 407           add env (n,p) = extendNameEnv_Acc (:) singleton env n p
 408
 409 tcPrags :: Id -> [LSig Name] -> TcM [LPrag]
 410 tcPrags poly_id prags = mapM (wrapLocM tc_prag) prags
 411   where
 412     tc_prag prag = addErrCtxt (pragSigCtxt prag) $
 413                    tcPrag poly_id prag
 414
 415 pragSigCtxt prag = hang (ptext SLIT("In the pragma")) 2 (ppr prag)
 416
 417 tcPrag :: TcId -> Sig Name -> TcM Prag
 418 -- Pre-condition: the poly_id is zonked
 419 -- Reason: required by tcSubExp
 420 tcPrag poly_id (SpecSig orig_name hs_ty inl) = tcSpecPrag poly_id hs_ty inl
 421 tcPrag poly_id (SpecInstSig hs_ty)           = tcSpecPrag poly_id hs_ty defaultInlineSpec
 422 tcPrag poly_id (InlineSig v inl)             = return (InlinePrag inl)
 423
 424
 425 tcSpecPrag :: TcId -> LHsType Name -> InlineSpec -> TcM Prag
 426 tcSpecPrag poly_id hs_ty inl
 427   = do  { spec_ty <- tcHsSigType (FunSigCtxt (idName poly_id)) hs_ty
 428         ; (co_fn, lie) <- getLIE (tcSubExp (idType poly_id) spec_ty)
 429         ; extendLIEs lie
 430         ; let const_dicts = map instToId lie
 431         ; return (SpecPrag (mkHsWrap co_fn (HsVar poly_id)) spec_ty const_dicts inl) }
 432         -- Most of the work of specialisation is done by
 433         -- the desugarer, guided by the SpecPrag
 434
 435 --------------
 436 -- If typechecking the binds fails, then return with each
 437 -- signature-less binder given type (forall a.a), to minimise
 438 -- subsequent error messages
 439 recoveryCode binder_names sig_fn
 440   = do  { traceTc (text "tcBindsWithSigs: error recovery" <+> ppr binder_names)
 441         ; poly_ids <- mapM mk_dummy binder_names
 442         ; return ([], poly_ids) }
 443   where
 444     mk_dummy name
 445         | isJust (sig_fn name) = tcLookupId name        -- Had signature; look it up
 446         | otherwise            = return (mkLocalId name forall_a_a)    -- No signature
 447
 448 forall_a_a :: TcType
 449 forall_a_a = mkForAllTy alphaTyVar (mkTyVarTy alphaTyVar)
 450
 451
 452 -- Check that non-overloaded unlifted bindings are
 453 --      a) non-recursive,
 454 --      b) not top level,
 455 --      c) not a multiple-binding group (more or less implied by (a))
 456
 457 checkStrictBinds :: TopLevelFlag -> RecFlag
 458                  -> LHsBinds TcId -> [TcType] -> [MonoBindInfo]
 459                  -> TcM Bool
 460 checkStrictBinds top_lvl rec_group mbind mono_tys infos
 461   | unlifted || bang_pat
 462   = do  { checkTc (isNotTopLevel top_lvl)
 463                   (strictBindErr "Top-level" unlifted mbind)
 464         ; checkTc (isNonRec rec_group)
 465                   (strictBindErr "Recursive" unlifted mbind)
 466         ; checkTc (isSingletonBag mbind)
 467                   (strictBindErr "Multiple" unlifted mbind)
 468         ; mapM_ check_sig infos
 469         ; return True }
 470   | otherwise
 471   = return False
 472   where
 473     unlifted = any isUnLiftedType mono_tys
 474     bang_pat = anyBag (isBangHsBind . unLoc) mbind
 475     check_sig (_, Just sig, _) = checkTc (null (sig_tvs sig) && null (sig_theta sig))
 476                                          (badStrictSig unlifted sig)
 477     check_sig other            = return ()
 478
 479 strictBindErr flavour unlifted mbind
 480   = hang (text flavour <+> msg <+> ptext SLIT("aren't allowed:"))
 481          4 (pprLHsBinds mbind)
 482   where
 483     msg | unlifted  = ptext SLIT("bindings for unlifted types")
 484         | otherwise = ptext SLIT("bang-pattern bindings")
 485
 486 badStrictSig unlifted sig
 487   = hang (ptext SLIT("Illegal polymorphic signature in") <+> msg)
 488          4 (ppr sig)
 489   where
 490     msg | unlifted  = ptext SLIT("an unlifted binding")
 491         | otherwise = ptext SLIT("a bang-pattern binding")
 492 \end{code}
 493
 494
 495 %************************************************************************
 496 %*                                                                      *
 497 \subsection{tcMonoBind}
 498 %*                                                                      *
 499 %************************************************************************
 500
 501 @tcMonoBinds@ deals with a perhaps-recursive group of HsBinds.
 502 The signatures have been dealt with already.
 503
 504 \begin{code}
 505 tcMonoBinds :: [LHsBind Name]
 506             -> TcSigFun
 507             -> RecFlag  -- Whether the binding is recursive for typechecking purposes
 508                         -- i.e. the binders are mentioned in their RHSs, and
 509                         --      we are not resuced by a type signature
 510             -> TcM (LHsBinds TcId, [MonoBindInfo])
 511
 512 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 513                                 fun_matches = matches, bind_fvs = fvs })]
 514             sig_fn              -- Single function binding,
 515             NonRecursive        -- binder isn't mentioned in RHS,
 516   | Nothing <- sig_fn name      -- ...with no type signature
 517   =     -- In this very special case we infer the type of the
 518         -- right hand side first (it may have a higher-rank type)
 519         -- and *then* make the monomorphic Id for the LHS
 520         -- e.g.         f = \(x::forall a. a->a) -> <body>
 521         --      We want to infer a higher-rank type for f
 522     setSrcSpan b_loc    $
 523     do  { ((co_fn, matches'), rhs_ty) <- tcInfer (tcMatchesFun name inf matches)
 524
 525                 -- Check for an unboxed tuple type
 526                 --      f = (# True, False #)
 527                 -- Zonk first just in case it's hidden inside a meta type variable
 528                 -- (This shows up as a (more obscure) kind error
 529                 --  in the 'otherwise' case of tcMonoBinds.)
 530         ; zonked_rhs_ty <- zonkTcType rhs_ty
 531         ; checkTc (not (isUnboxedTupleType zonked_rhs_ty))
 532                   (unboxedTupleErr name zonked_rhs_ty)
 533
 534         ; mono_name <- newLocalName name
 535         ; let mono_id = mkLocalId mono_name zonked_rhs_ty
 536         ; return (unitBag (L b_loc (FunBind { fun_id = L nm_loc mono_id, fun_infix = inf,
 537                                               fun_matches = matches', bind_fvs = fvs,
 538                                               fun_co_fn = co_fn, fun_tick = Nothing })),
 539                   [(name, Nothing, mono_id)]) }
 540
 541 tcMonoBinds [L b_loc (FunBind { fun_id = L nm_loc name, fun_infix = inf,
 542                                 fun_matches = matches, bind_fvs = fvs })]
 543             sig_fn              -- Single function binding
 544             non_rec
 545   | Just scoped_tvs <- sig_fn name      -- ...with a type signature
 546   =     -- When we have a single function binding, with a type signature
 547         -- we can (a) use genuine, rigid skolem constants for the type variables
 548         --        (b) bring (rigid) scoped type variables into scope
 549     setSrcSpan b_loc    $
 550     do  { tc_sig <- tcInstSig True name scoped_tvs
 551         ; mono_name <- newLocalName name
 552         ; let mono_ty = sig_tau tc_sig
 553               mono_id = mkLocalId mono_name mono_ty
 554               rhs_tvs = [ (name, mkTyVarTy tv)
 555                         | (name, tv) <- sig_scoped tc_sig `zip` sig_tvs tc_sig ]
 556
 557         ; (co_fn, matches') <- tcExtendTyVarEnv2 rhs_tvs    $
 558                                tcMatchesFun mono_name inf matches mono_ty
 559
 560         ; let fun_bind' = FunBind { fun_id = L nm_loc mono_id,
 561                                     fun_infix = inf, fun_matches = matches',
 562                                     bind_fvs = placeHolderNames, fun_co_fn = co_fn,
 563                                     fun_tick = Nothing }
 564         ; return (unitBag (L b_loc fun_bind'),
 565                   [(name, Just tc_sig, mono_id)]) }
 566
 567 tcMonoBinds binds sig_fn non_rec
 568   = do  { tc_binds <- mapM (wrapLocM (tcLhs sig_fn)) binds
 569
 570         -- Bring the monomorphic Ids, into scope for the RHSs
 571         ; let mono_info  = getMonoBindInfo tc_binds
 572               rhs_id_env = [(name,mono_id) | (name, Nothing, mono_id) <- mono_info]
 573                                 -- A monomorphic binding for each term variable that lacks
 574                                 -- a type sig.  (Ones with a sig are already in scope.)
 575
 576         ; binds' <- tcExtendIdEnv2    rhs_id_env $
 577                     traceTc (text "tcMonoBinds" <+> vcat [ ppr n <+> ppr id <+> ppr (idType id)
 578                                                          | (n,id) <- rhs_id_env]) `thenM_`
 579                     mapM (wrapLocM tcRhs) tc_binds
 580         ; return (listToBag binds', mono_info) }
 581
 582 ------------------------
 583 -- tcLhs typechecks the LHS of the bindings, to construct the environment in which
 584 -- we typecheck the RHSs.  Basically what we are doing is this: for each binder:
 585 --      if there's a signature for it, use the instantiated signature type
 586 --      otherwise invent a type variable
 587 -- You see that quite directly in the FunBind case.
 588 --
 589 -- But there's a complication for pattern bindings:
 590 --      data T = MkT (forall a. a->a)
 591 --      MkT f = e
 592 -- Here we can guess a type variable for the entire LHS (which will be refined to T)
 593 -- but we want to get (f::forall a. a->a) as the RHS environment.
 594 -- The simplest way to do this is to typecheck the pattern, and then look up the
 595 -- bound mono-ids.  Then we want to retain the typechecked pattern to avoid re-doing
 596 -- it; hence the TcMonoBind data type in which the LHS is done but the RHS isn't
 597
 598 data TcMonoBind         -- Half completed; LHS done, RHS not done
 599   = TcFunBind  MonoBindInfo  (Located TcId) Bool (MatchGroup Name)
 600   | TcPatBind [MonoBindInfo] (LPat TcId) (GRHSs Name) TcSigmaType
 601
 602 type MonoBindInfo = (Name, Maybe TcSigInfo, TcId)
 603         -- Type signature (if any), and
 604         -- the monomorphic bound things
 605
 606 bndrNames :: [MonoBindInfo] -> [Name]
 607 bndrNames mbi = [n | (n,_,_) <- mbi]
 608
 609 getMonoType :: MonoBindInfo -> TcTauType
 610 getMonoType (_,_,mono_id) = idType mono_id
 611
 612 tcLhs :: TcSigFun -> HsBind Name -> TcM TcMonoBind
 613 tcLhs sig_fn (FunBind { fun_id = L nm_loc name, fun_infix = inf, fun_matches = matches })
 614   = do  { mb_sig <- tcInstSig_maybe sig_fn name
 615         ; mono_name <- newLocalName name
 616         ; mono_ty   <- mk_mono_ty mb_sig
 617         ; let mono_id = mkLocalId mono_name mono_ty
 618         ; return (TcFunBind (name, mb_sig, mono_id) (L nm_loc mono_id) inf matches) }
 619   where
 620     mk_mono_ty (Just sig) = return (sig_tau sig)
 621     mk_mono_ty Nothing    = newFlexiTyVarTy argTypeKind
 622
 623 tcLhs sig_fn bind@(PatBind { pat_lhs = pat, pat_rhs = grhss })
 624   = do  { mb_sigs <- mapM (tcInstSig_maybe sig_fn) names
 625         ; mono_pat_binds <- doptM Opt_MonoPatBinds
 626                 -- With -fmono-pat-binds, we do no generalisation of pattern bindings
 627                 -- But the signature can still be polymoprhic!
 628                 --      data T = MkT (forall a. a->a)
 629                 --      x :: forall a. a->a
 630                 --      MkT x = <rhs>
 631                 -- The function get_sig_ty decides whether the pattern-bound variables
 632                 -- should have exactly the type in the type signature (-fmono-pat-binds),
 633                 -- or the instantiated version (-fmono-pat-binds)
 634
 635         ; let nm_sig_prs  = names `zip` mb_sigs
 636               get_sig_ty | mono_pat_binds = idType . sig_id
 637                          | otherwise      = sig_tau
 638               tau_sig_env = mkNameEnv [ (name, get_sig_ty sig)
 639                                       | (name, Just sig) <- nm_sig_prs]
 640               sig_tau_fn  = lookupNameEnv tau_sig_env
 641
 642               tc_pat exp_ty = tcLetPat sig_tau_fn pat exp_ty $
 643                               mapM lookup_info nm_sig_prs
 644
 645                 -- After typechecking the pattern, look up the binder
 646                 -- names, which the pattern has brought into scope.
 647               lookup_info :: (Name, Maybe TcSigInfo) -> TcM MonoBindInfo
 648               lookup_info (name, mb_sig) = do { mono_id <- tcLookupId name
 649                                               ; return (name, mb_sig, mono_id) }
 650
 651         ; ((pat', infos), pat_ty) <- addErrCtxt (patMonoBindsCtxt pat grhss) $
 652                                      tcInfer tc_pat
 653
 654         ; return (TcPatBind infos pat' grhss pat_ty) }
 655   where
 656     names = collectPatBinders pat
 657
 658
 659 tcLhs sig_fn other_bind = pprPanic "tcLhs" (ppr other_bind)
 660         -- AbsBind, VarBind impossible
 661
 662 -------------------
 663 tcRhs :: TcMonoBind -> TcM (HsBind TcId)
 664 tcRhs (TcFunBind info fun'@(L _ mono_id) inf matches)
 665   = do  { (co_fn, matches') <- tcMatchesFun (idName mono_id) inf
 666                                             matches (idType mono_id)
 667         ; return (FunBind { fun_id = fun', fun_infix = inf, fun_matches = matches',
 668                             bind_fvs = placeHolderNames, fun_co_fn = co_fn,
 669                             fun_tick = Nothing }) }
 670
 671 tcRhs bind@(TcPatBind _ pat' grhss pat_ty)
 672   = do  { grhss' <- addErrCtxt (patMonoBindsCtxt pat' grhss) $
 673                     tcGRHSsPat grhss pat_ty
 674         ; return (PatBind { pat_lhs = pat', pat_rhs = grhss', pat_rhs_ty = pat_ty,
 675                             bind_fvs = placeHolderNames }) }
 676
 677
 678 ---------------------
 679 getMonoBindInfo :: [Located TcMonoBind] -> [MonoBindInfo]
 680 getMonoBindInfo tc_binds
 681   = foldr (get_info . unLoc) [] tc_binds
 682   where
 683     get_info (TcFunBind info _ _ _)  rest = info : rest
 684     get_info (TcPatBind infos _ _ _) rest = infos ++ rest
 685 \end{code}
 686
 687
 688 %************************************************************************
 689 %*                                                                      *
 690                 Generalisation
 691 %*                                                                      *
 692 %************************************************************************
 693
 694 \begin{code}
 695 generalise :: DynFlags -> TopLevelFlag
 696            -> [LHsBind Name] -> TcSigFun
 697            -> [MonoBindInfo] -> [Inst]
 698            -> TcM ([TyVar], [Inst], TcDictBinds)
 699 -- The returned [TyVar] are all ready to quantify
 700
 701 generalise dflags top_lvl bind_list sig_fn mono_infos lie_req
 702   | isMonoGroup dflags bind_list
 703   = do  { extendLIEs lie_req
 704         ; return ([], [], emptyBag) }
 705
 706   | isRestrictedGroup dflags bind_list sig_fn   -- RESTRICTED CASE
 707   =     -- Check signature contexts are empty
 708     do  { checkTc (all is_mono_sig sigs)
 709                   (restrictedBindCtxtErr bndrs)
 710
 711         -- Now simplify with exactly that set of tyvars
 712         -- We have to squash those Methods
 713         ; (qtvs, binds) <- tcSimplifyRestricted doc top_lvl bndrs
 714                                                 tau_tvs lie_req
 715
 716         -- Check that signature type variables are OK
 717         ; final_qtvs <- checkSigsTyVars qtvs sigs
 718
 719         ; return (final_qtvs, [], binds) }
 720
 721   | null sigs   -- UNRESTRICTED CASE, NO TYPE SIGS
 722   = tcSimplifyInfer doc tau_tvs lie_req
 723
 724   | otherwise   -- UNRESTRICTED CASE, WITH TYPE SIGS
 725   = do  { sig_lie <- unifyCtxts sigs    -- sigs is non-empty; sig_lie is zonked
 726         ; let   -- The "sig_avails" is the stuff available.  We get that from
 727                 -- the context of the type signature, BUT ALSO the lie_avail
 728                 -- so that polymorphic recursion works right (see Note [Polymorphic recursion])
 729                 local_meths = [mkMethInst sig mono_id | (_, Just sig, mono_id) <- mono_infos]
 730                 sig_avails = sig_lie ++ local_meths
 731                 loc = sig_loc (head sigs)
 732
 733         -- Check that the needed dicts can be
 734         -- expressed in terms of the signature ones
 735         ; (qtvs, binds) <- tcSimplifyInferCheck loc tau_tvs sig_avails lie_req
 736
 737         -- Check that signature type variables are OK
 738         ; final_qtvs <- checkSigsTyVars qtvs sigs
 739
 740         ; returnM (final_qtvs, sig_lie, binds) }
 741   where
 742     bndrs   = bndrNames mono_infos
 743     sigs    = [sig | (_, Just sig, _) <- mono_infos]
 744     get_tvs | isTopLevel top_lvl = tyVarsOfType  -- See Note [Silly type synonym] in TcType
 745             | otherwise          = exactTyVarsOfType
 746     tau_tvs = foldr (unionVarSet . get_tvs . getMonoType) emptyVarSet mono_infos
 747     is_mono_sig sig = null (sig_theta sig)
 748     doc = ptext SLIT("type signature(s) for") <+> pprBinders bndrs
 749
 750     mkMethInst (TcSigInfo { sig_id = poly_id, sig_tvs = tvs,
 751                             sig_theta = theta, sig_loc = loc }) mono_id
 752       = Method {tci_id = mono_id, tci_oid = poly_id, tci_tys = mkTyVarTys tvs,
 753                 tci_theta = theta, tci_loc = loc}
 754 \end{code}
 755
 756 unifyCtxts checks that all the signature contexts are the same
 757 The type signatures on a mutually-recursive group of definitions
 758 must all have the same context (or none).
 759
 760 The trick here is that all the signatures should have the same
 761 context, and we want to share type variables for that context, so that
 762 all the right hand sides agree a common vocabulary for their type
 763 constraints
 764
 765 We unify them because, with polymorphic recursion, their types
 766 might not otherwise be related.  This is a rather subtle issue.
 767
 768 \begin{code}
 769 unifyCtxts :: [TcSigInfo] -> TcM [Inst]
 770 -- Post-condition: the returned Insts are full zonked
 771 unifyCtxts (sig1 : sigs)        -- Argument is always non-empty
 772   = do  { mapM unify_ctxt sigs
 773         ; theta <- zonkTcThetaType (sig_theta sig1)
 774         ; newDictBndrs (sig_loc sig1) theta }
 775   where
 776     theta1 = sig_theta sig1
 777     unify_ctxt :: TcSigInfo -> TcM ()
 778     unify_ctxt sig@(TcSigInfo { sig_theta = theta })
 779         = setSrcSpan (instLocSpan (sig_loc sig))        $
 780           addErrCtxt (sigContextsCtxt sig1 sig)         $
 781           do { cois <- unifyTheta theta1 theta
 782              ; -- Check whether all coercions are identity coercions
 783                -- That can happen if we have, say
 784                --         f :: C [a]   => ...
 785                --         g :: C (F a) => ...
 786                -- where F is a type function and (F a ~ [a])
 787                -- Then unification might succeed with a coercion.  But it's much
 788                -- much simpler to require that such signatures have identical contexts
 789                checkTc (all isIdentityCoercion cois)
 790                        (ptext SLIT("Mutually dependent functions have syntactically distinct contexts"))
 791              }
 792
 793 checkSigsTyVars :: [TcTyVar] -> [TcSigInfo] -> TcM [TcTyVar]
 794 checkSigsTyVars qtvs sigs
 795   = do  { gbl_tvs <- tcGetGlobalTyVars
 796         ; sig_tvs_s <- mappM (check_sig gbl_tvs) sigs
 797
 798         ; let   -- Sigh.  Make sure that all the tyvars in the type sigs
 799                 -- appear in the returned ty var list, which is what we are
 800                 -- going to generalise over.  Reason: we occasionally get
 801                 -- silly types like
 802                 --      type T a = () -> ()
 803                 --      f :: T a
 804                 --      f () = ()
 805                 -- Here, 'a' won't appear in qtvs, so we have to add it
 806                 sig_tvs = foldl extendVarSetList emptyVarSet sig_tvs_s
 807                 all_tvs = varSetElems (extendVarSetList sig_tvs qtvs)
 808         ; returnM all_tvs }
 809   where
 810     check_sig gbl_tvs (TcSigInfo {sig_id = id, sig_tvs = tvs,
 811                                   sig_theta = theta, sig_tau = tau})
 812       = addErrCtxt (ptext SLIT("In the type signature for") <+> quotes (ppr id))        $
 813         addErrCtxtM (sigCtxt id tvs theta tau)                                          $
 814         do { tvs' <- checkDistinctTyVars tvs
 815            ; ifM (any (`elemVarSet` gbl_tvs) tvs')
 816                  (bleatEscapedTvs gbl_tvs tvs tvs')
 817            ; return tvs' }
 818
 819 checkDistinctTyVars :: [TcTyVar] -> TcM [TcTyVar]
 820 -- (checkDistinctTyVars tvs) checks that the tvs from one type signature
 821 -- are still all type variables, and all distinct from each other.
 822 -- It returns a zonked set of type variables.
 823 -- For example, if the type sig is
 824 --      f :: forall a b. a -> b -> b
 825 -- we want to check that 'a' and 'b' haven't
 826 --      (a) been unified with a non-tyvar type
 827 --      (b) been unified with each other (all distinct)
 828
 829 checkDistinctTyVars sig_tvs
 830   = do  { zonked_tvs <- mapM zonkSigTyVar sig_tvs
 831         ; foldlM check_dup emptyVarEnv (sig_tvs `zip` zonked_tvs)
 832         ; return zonked_tvs }
 833   where
 834     check_dup :: TyVarEnv TcTyVar -> (TcTyVar, TcTyVar) -> TcM (TyVarEnv TcTyVar)
 835         -- The TyVarEnv maps each zonked type variable back to its
 836         -- corresponding user-written signature type variable
 837     check_dup acc (sig_tv, zonked_tv)
 838         = case lookupVarEnv acc zonked_tv of
 839                 Just sig_tv' -> bomb_out sig_tv sig_tv'
 840
 841                 Nothing -> return (extendVarEnv acc zonked_tv sig_tv)
 842
 843     bomb_out sig_tv1 sig_tv2
 844        = do { env0 <- tcInitTidyEnv
 845             ; let (env1, tidy_tv1) = tidyOpenTyVar env0 sig_tv1
 846                   (env2, tidy_tv2) = tidyOpenTyVar env1 sig_tv2
 847                   msg = ptext SLIT("Quantified type variable") <+> quotes (ppr tidy_tv1)
 848                          <+> ptext SLIT("is unified with another quantified type variable")
 849                          <+> quotes (ppr tidy_tv2)
 850             ; failWithTcM (env2, msg) }
 851        where
 852 \end{code}
 853
 854
 855 @getTyVarsToGen@ decides what type variables to generalise over.
 856
 857 For a "restricted group" -- see the monomorphism restriction
 858 for a definition -- we bind no dictionaries, and
 859 remove from tyvars_to_gen any constrained type variables
 860
 861 *Don't* simplify dicts at this point, because we aren't going
 862 to generalise over these dicts.  By the time we do simplify them
 863 we may well know more.  For example (this actually came up)
 864         f :: Array Int Int
 865         f x = array ... xs where xs = [1,2,3,4,5]
 866 We don't want to generate lots of (fromInt Int 1), (fromInt Int 2)
 867 stuff.  If we simplify only at the f-binding (not the xs-binding)
 868 we'll know that the literals are all Ints, and we can just produce
 869 Int literals!
 870
 871 Find all the type variables involved in overloading, the
 872 "constrained_tyvars".  These are the ones we *aren't* going to
 873 generalise.  We must be careful about doing this:
 874
 875  (a) If we fail to generalise a tyvar which is not actually
 876         constrained, then it will never, ever get bound, and lands
 877         up printed out in interface files!  Notorious example:
 878                 instance Eq a => Eq (Foo a b) where ..
 879         Here, b is not constrained, even though it looks as if it is.
 880         Another, more common, example is when there's a Method inst in
 881         the LIE, whose type might very well involve non-overloaded
 882         type variables.
 883   [NOTE: Jan 2001: I don't understand the problem here so I'm doing
 884         the simple thing instead]
 885
 886  (b) On the other hand, we mustn't generalise tyvars which are constrained,
 887         because we are going to pass on out the unmodified LIE, with those
 888         tyvars in it.  They won't be in scope if we've generalised them.
 889
 890 So we are careful, and do a complete simplification just to find the
 891 constrained tyvars. We don't use any of the results, except to
 892 find which tyvars are constrained.
 893
 894 Note [Polymorphic recursion]
 895 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 896 The game plan for polymorphic recursion in the code above is
 897
 898         * Bind any variable for which we have a type signature
 899           to an Id with a polymorphic type.  Then when type-checking
 900           the RHSs we'll make a full polymorphic call.
 901
 902 This fine, but if you aren't a bit careful you end up with a horrendous
 903 amount of partial application and (worse) a huge space leak. For example:
 904
 905         f :: Eq a => [a] -> [a]
 906         f xs = ...f...
 907
 908 If we don't take care, after typechecking we get
 909
 910         f = /\a -> \d::Eq a -> let f' = f a d
 911                                in
 912                                \ys:[a] -> ...f'...
 913
 914 Notice the the stupid construction of (f a d), which is of course
 915 identical to the function we're executing.  In this case, the
 916 polymorphic recursion isn't being used (but that's a very common case).
 917 This can lead to a massive space leak, from the following top-level defn
 918 (post-typechecking)
 919
 920         ff :: [Int] -> [Int]
 921         ff = f Int dEqInt
 922
 923 Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
 924 f' is another thunk which evaluates to the same thing... and you end
 925 up with a chain of identical values all hung onto by the CAF ff.
 926
 927         ff = f Int dEqInt
 928
 929            = let f' = f Int dEqInt in \ys. ...f'...
 930
 931            = let f' = let f' = f Int dEqInt in \ys. ...f'...
 932                       in \ys. ...f'...
 933
 934 Etc.
 935
 936 NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
 937 which would make the space leak go away in this case
 938
 939 Solution: when typechecking the RHSs we always have in hand the
 940 *monomorphic* Ids for each binding.  So we just need to make sure that
 941 if (Method f a d) shows up in the constraints emerging from (...f...)
 942 we just use the monomorphic Id.  We achieve this by adding monomorphic Ids
 943 to the "givens" when simplifying constraints.  That's what the "lies_avail"
 944 is doing.
 945
 946 Then we get
 947
 948         f = /\a -> \d::Eq a -> letrec
 949                                  fm = \ys:[a] -> ...fm...
 950                                in
 951                                fm
 952
 953
 954
 955 %************************************************************************
 956 %*                                                                      *
 957                 Signatures
 958 %*                                                                      *
 959 %************************************************************************
 960
 961 Type signatures are tricky.  See Note [Signature skolems] in TcType
 962
 963 @tcSigs@ checks the signatures for validity, and returns a list of
 964 {\em freshly-instantiated} signatures.  That is, the types are already
 965 split up, and have fresh type variables installed.  All non-type-signature
 966 "RenamedSigs" are ignored.
 967
 968 The @TcSigInfo@ contains @TcTypes@ because they are unified with
 969 the variable's type, and after that checked to see whether they've
 970 been instantiated.
 971
 972 \begin{code}
 973 type TcSigFun = Name -> Maybe [Name]    -- Maps a let-binder to the list of
 974                                         -- type variables brought into scope
 975                                         -- by its type signature.
 976                                         -- Nothing => no type signature
 977
 978 mkTcSigFun :: [LSig Name] -> TcSigFun
 979 -- Search for a particular type signature
 980 -- Precondition: the sigs are all type sigs
 981 -- Precondition: no duplicates
 982 mkTcSigFun sigs = lookupNameEnv env
 983   where
 984     env = mkNameEnv [(name, hsExplicitTvs lhs_ty)
 985                     | L span (TypeSig (L _ name) lhs_ty) <- sigs]
 986         -- The scoped names are the ones explicitly mentioned
 987         -- in the HsForAll.  (There may be more in sigma_ty, because
 988         -- of nested type synonyms.  See Note [Scoped] with TcSigInfo.)
 989         -- See Note [Only scoped tyvars are in the TyVarEnv]
 990
 991 ---------------
 992 data TcSigInfo
 993   = TcSigInfo {
 994         sig_id     :: TcId,             --  *Polymorphic* binder for this value...
 995
 996         sig_scoped :: [Name],           -- Names for any scoped type variables
 997                                         -- Invariant: correspond 1-1 with an initial
 998                                         -- segment of sig_tvs (see Note [Scoped])
 999
1000         sig_tvs    :: [TcTyVar],        -- Instantiated type variables
1001                                         -- See Note [Instantiate sig]
1002
1003         sig_theta  :: TcThetaType,      -- Instantiated theta
1004         sig_tau    :: TcTauType,        -- Instantiated tau
1005         sig_loc    :: InstLoc           -- The location of the signature
1006     }
1007
1008
1009 --      Note [Only scoped tyvars are in the TyVarEnv]
1010 -- We are careful to keep only the *lexically scoped* type variables in
1011 -- the type environment.  Why?  After all, the renamer has ensured
1012 -- that only legal occurrences occur, so we could put all type variables
1013 -- into the type env.
1014 --
1015 -- But we want to check that two distinct lexically scoped type variables
1016 -- do not map to the same internal type variable.  So we need to know which
1017 -- the lexically-scoped ones are... and at the moment we do that by putting
1018 -- only the lexically scoped ones into the environment.
1019
1020
1021 --      Note [Scoped]
1022 -- There may be more instantiated type variables than scoped
1023 -- ones.  For example:
1024 --      type T a = forall b. b -> (a,b)
1025 --      f :: forall c. T c
1026 -- Here, the signature for f will have one scoped type variable, c,
1027 -- but two instantiated type variables, c' and b'.
1028 --
1029 -- We assume that the scoped ones are at the *front* of sig_tvs,
1030 -- and remember the names from the original HsForAllTy in sig_scoped
1031
1032 --      Note [Instantiate sig]
1033 -- It's vital to instantiate a type signature with fresh variables.
1034 -- For example:
1035 --      type S = forall a. a->a
1036 --      f,g :: S
1037 --      f = ...
1038 --      g = ...
1039 -- Here, we must use distinct type variables when checking f,g's right hand sides.
1040 -- (Instantiation is only necessary because of type synonyms.  Otherwise,
1041 -- it's all cool; each signature has distinct type variables from the renamer.)
1042
1043 instance Outputable TcSigInfo where
1044     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau})
1045         = ppr id <+> ptext SLIT("::") <+> ppr tyvars <+> ppr theta <+> ptext SLIT("=>") <+> ppr tau
1046 \end{code}
1047
1048 \begin{code}
1049 tcTySig :: LSig Name -> TcM TcId
1050 tcTySig (L span (TypeSig (L _ name) ty))
1051   = setSrcSpan span             $
1052     do  { sigma_ty <- tcHsSigType (FunSigCtxt name) ty
1053         ; return (mkLocalId name sigma_ty) }
1054
1055 -------------------
1056 tcInstSig_maybe :: TcSigFun -> Name -> TcM (Maybe TcSigInfo)
1057 -- Instantiate with *meta* type variables;
1058 -- this signature is part of a multi-signature group
1059 tcInstSig_maybe sig_fn name
1060   = case sig_fn name of
1061         Nothing  -> return Nothing
1062         Just tvs -> do  { tc_sig <- tcInstSig False name tvs
1063                         ; return (Just tc_sig) }
1064
1065 tcInstSig :: Bool -> Name -> [Name] -> TcM TcSigInfo
1066 -- Instantiate the signature, with either skolems or meta-type variables
1067 -- depending on the use_skols boolean.  This variable is set True
1068 -- when we are typechecking a single function binding; and False for
1069 -- pattern bindings and a group of several function bindings.
1070 -- Reason: in the latter cases, the "skolems" can be unified together,
1071 --         so they aren't properly rigid in the type-refinement sense.
1072 -- NB: unless we are doing H98, each function with a sig will be done
1073 --     separately, even if it's mutually recursive, so use_skols will be True
1074 --
1075 -- We always instantiate with fresh uniques,
1076 -- although we keep the same print-name
1077 --
1078 --      type T = forall a. [a] -> [a]
1079 --      f :: T;
1080 --      f = g where { g :: T; g = <rhs> }
1081 --
1082 -- We must not use the same 'a' from the defn of T at both places!!
1083
1084 tcInstSig use_skols name scoped_names
1085   = do  { poly_id <- tcLookupId name    -- Cannot fail; the poly ids are put into
1086                                         -- scope when starting the binding group
1087         ; let skol_info = SigSkol (FunSigCtxt name)
1088               inst_tyvars = tcInstSigTyVars use_skols skol_info
1089         ; (tvs, theta, tau) <- tcInstType inst_tyvars (idType poly_id)
1090         ; loc <- getInstLoc (SigOrigin skol_info)
1091         ; return (TcSigInfo { sig_id = poly_id,
1092                               sig_tvs = tvs, sig_theta = theta, sig_tau = tau,
1093                               sig_scoped = final_scoped_names, sig_loc = loc }) }
1094                 -- Note that the scoped_names and the sig_tvs will have
1095                 -- different Names. That's quite ok; when we bring the
1096                 -- scoped_names into scope, we just bind them to the sig_tvs
1097   where
1098         -- We also only have scoped type variables when we are instantiating
1099         -- with true skolems
1100     final_scoped_names | use_skols = scoped_names
1101                        | otherwise = []
1102
1103 -------------------
1104 isMonoGroup :: DynFlags -> [LHsBind Name] -> Bool
1105 -- No generalisation at all
1106 isMonoGroup dflags binds
1107   = dopt Opt_MonoPatBinds dflags && any is_pat_bind binds
1108   where
1109     is_pat_bind (L _ (PatBind {})) = True
1110     is_pat_bind other              = False
1111
1112 -------------------
1113 isRestrictedGroup :: DynFlags -> [LHsBind Name] -> TcSigFun -> Bool
1114 isRestrictedGroup dflags binds sig_fn
1115   = mono_restriction && not all_unrestricted
1116   where
1117     mono_restriction = dopt Opt_MonomorphismRestriction dflags
1118     all_unrestricted = all (unrestricted . unLoc) binds
1119     has_sig n = isJust (sig_fn n)
1120
1121     unrestricted (PatBind {})                                    = False
1122     unrestricted (VarBind { var_id = v })                        = has_sig v
1123     unrestricted (FunBind { fun_id = v, fun_matches = matches }) = unrestricted_match matches
1124                                                                  || has_sig (unLoc v)
1125
1126     unrestricted_match (MatchGroup (L _ (Match [] _ _) : _) _) = False
1127         -- No args => like a pattern binding
1128     unrestricted_match other              = True
1129         -- Some args => a function binding
1130 \end{code}
1131
1132
1133 %************************************************************************
1134 %*                                                                      *
1135 \subsection[TcBinds-errors]{Error contexts and messages}
1136 %*                                                                      *
1137 %************************************************************************
1138
1139
1140 \begin{code}
1141 -- This one is called on LHS, when pat and grhss are both Name
1142 -- and on RHS, when pat is TcId and grhss is still Name
1143 patMonoBindsCtxt pat grhss
1144   = hang (ptext SLIT("In a pattern binding:")) 4 (pprPatBind pat grhss)
1145
1146 -----------------------------------------------
1147 sigContextsCtxt sig1 sig2
1148   = vcat [ptext SLIT("When matching the contexts of the signatures for"),
1149           nest 2 (vcat [ppr id1 <+> dcolon <+> ppr (idType id1),
1150                         ppr id2 <+> dcolon <+> ppr (idType id2)]),
1151           ptext SLIT("The signature contexts in a mutually recursive group should all be identical")]
1152   where
1153     id1 = sig_id sig1
1154     id2 = sig_id sig2
1155
1156
1157 -----------------------------------------------
1158 unboxedTupleErr name ty
1159   = hang (ptext SLIT("Illegal binding of unboxed tuple"))
1160          4 (ppr name <+> dcolon <+> ppr ty)
1161
1162 -----------------------------------------------
1163 restrictedBindCtxtErr binder_names
1164   = hang (ptext SLIT("Illegal overloaded type signature(s)"))
1165        4 (vcat [ptext SLIT("in a binding group for") <+> pprBinders binder_names,
1166                 ptext SLIT("that falls under the monomorphism restriction")])
1167
1168 genCtxt binder_names
1169   = ptext SLIT("When generalising the type(s) for") <+> pprBinders binder_names
1170
1171 missingSigWarn False name ty = return ()
1172 missingSigWarn True  name ty
1173   = do  { env0 <- tcInitTidyEnv
1174         ; let (env1, tidy_ty) = tidyOpenType env0 ty
1175         ; addWarnTcM (env1, mk_msg tidy_ty) }
1176   where
1177     mk_msg ty = vcat [ptext SLIT("Definition but no type signature for") <+> quotes (ppr name),
1178                       sep [ptext SLIT("Inferred type:") <+> ppr name <+> dcolon <+> ppr ty]]
1179 \end{code}