compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import Coercion
  34 import ErrUtils
  35 import MkId
  36 import DataCon
  37 import Maybes
  38 import RdrName
  39 import Name
  40 import NameSet
  41 import TyCon
  42 import TcType
  43 import BuildTyCl
  44 import BasicTypes
  45 import Var
  46 import VarSet
  47 import PrelNames
  48 import SrcLoc
  49 import UniqSupply
  50 import Util
  51 import ListSetOps
  52 import Outputable
  53 import FastString
  54 import Bag
  55
  56 import Control.Monad
  57 \end{code}
  58
  59 %************************************************************************
  60 %*                                                                      *
  61                 Overview
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 Overall plan
  66 ~~~~~~~~~~~~
  67 1.  Convert the decls (i.e. data/newtype deriving clauses,
  68     plus standalone deriving) to [EarlyDerivSpec]
  69
  70 2.  Infer the missing contexts for the Left DerivSpecs
  71
  72 3.  Add the derived bindings, generating InstInfos
  73
  74
  75 \begin{code}
  76 -- DerivSpec is purely  local to this module
  77 data DerivSpec  = DS { ds_loc     :: SrcSpan
  78                      , ds_orig    :: CtOrigin
  79                      , ds_name    :: Name
  80                      , ds_tvs     :: [TyVar]
  81                      , ds_theta   :: ThetaType
  82                      , ds_cls     :: Class
  83                      , ds_tys     :: [Type]
  84                      , ds_tc      :: TyCon
  85                      , ds_tc_args :: [Type]
  86                      , ds_newtype :: Bool }
  87         -- This spec implies a dfun declaration of the form
  88         --       df :: forall tvs. theta => C tys
  89         -- The Name is the name for the DFun we'll build
  90         -- The tyvars bind all the variables in the theta
  91         -- For type families, the tycon in
  92         --       in ds_tys is the *family* tycon
  93         --       in ds_tc, ds_tc_args is the *representation* tycon
  94         -- For non-family tycons, both are the same
  95
  96         -- ds_newtype = True  <=> Newtype deriving
  97         --              False <=> Vanilla deriving
  98 \end{code}
  99
 100 Example:
 101
 102      newtype instance T [a] = MkT (Tree a) deriving( C s )
 103 ==>
 104      axiom T [a] = :RTList a
 105      axiom :RTList a = Tree a
 106
 107      DS { ds_tvs = [a,s], ds_cls = C, ds_tys = [s, T [a]]
 108         , ds_tc = :RTList, ds_tc_args = [a]
 109         , ds_newtype = True }
 110
 111 \begin{code}
 112 type DerivContext = Maybe ThetaType
 113    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
 114    -- Just theta <=> Standalone deriving: context supplied by programmer
 115
 116 type EarlyDerivSpec = Either DerivSpec DerivSpec
 117         -- Left  ds => the context for the instance should be inferred
 118         --             In this case ds_theta is the list of all the
 119         --                constraints needed, such as (Eq [a], Eq a)
 120         --                The inference process is to reduce this to a
 121         --                simpler form (e.g. Eq a)
 122         --
 123         -- Right ds => the exact context for the instance is supplied
 124         --             by the programmer; it is ds_theta
 125
 126 pprDerivSpec :: DerivSpec -> SDoc
 127 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
 128                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
 129   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
 130             <+> equals <+> ppr rhs)
 131 \end{code}
 132
 133
 134 Inferring missing contexts
 135 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 136 Consider
 137
 138         data T a b = C1 (Foo a) (Bar b)
 139                    | C2 Int (T b a)
 140                    | C3 (T a a)
 141                    deriving (Eq)
 142
 143 [NOTE: See end of these comments for what to do with
 144         data (C a, D b) => T a b = ...
 145 ]
 146
 147 We want to come up with an instance declaration of the form
 148
 149         instance (Ping a, Pong b, ...) => Eq (T a b) where
 150                 x == y = ...
 151
 152 It is pretty easy, albeit tedious, to fill in the code "...".  The
 153 trick is to figure out what the context for the instance decl is,
 154 namely @Ping@, @Pong@ and friends.
 155
 156 Let's call the context reqd for the T instance of class C at types
 157 (a,b, ...)  C (T a b).  Thus:
 158
 159         Eq (T a b) = (Ping a, Pong b, ...)
 160
 161 Now we can get a (recursive) equation from the @data@ decl:
 162
 163         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 164                    u Eq (T b a) u Eq Int        -- From C2
 165                    u Eq (T a a)                 -- From C3
 166
 167 Foo and Bar may have explicit instances for @Eq@, in which case we can
 168 just substitute for them.  Alternatively, either or both may have
 169 their @Eq@ instances given by @deriving@ clauses, in which case they
 170 form part of the system of equations.
 171
 172 Now all we need do is simplify and solve the equations, iterating to
 173 find the least fixpoint.  Notice that the order of the arguments can
 174 switch around, as here in the recursive calls to T.
 175
 176 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 177
 178 We start with:
 179
 180         Eq (T a b) = {}         -- The empty set
 181
 182 Next iteration:
 183         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 184                    u Eq (T b a) u Eq Int        -- From C2
 185                    u Eq (T a a)                 -- From C3
 186
 187         After simplification:
 188                    = Eq a u Ping b u {} u {} u {}
 189                    = Eq a u Ping b
 190
 191 Next iteration:
 192
 193         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 194                    u Eq (T b a) u Eq Int        -- From C2
 195                    u Eq (T a a)                 -- From C3
 196
 197         After simplification:
 198                    = Eq a u Ping b
 199                    u (Eq b u Ping a)
 200                    u (Eq a u Ping a)
 201
 202                    = Eq a u Ping b u Eq b u Ping a
 203
 204 The next iteration gives the same result, so this is the fixpoint.  We
 205 need to make a canonical form of the RHS to ensure convergence.  We do
 206 this by simplifying the RHS to a form in which
 207
 208         - the classes constrain only tyvars
 209         - the list is sorted by tyvar (major key) and then class (minor key)
 210         - no duplicates, of course
 211
 212 So, here are the synonyms for the ``equation'' structures:
 213
 214
 215 Note [Data decl contexts]
 216 ~~~~~~~~~~~~~~~~~~~~~~~~~
 217 Consider
 218
 219         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 220
 221 We will need an instance decl like:
 222
 223         instance (Read a, RealFloat a) => Read (Complex a) where
 224           ...
 225
 226 The RealFloat in the context is because the read method for Complex is bound
 227 to construct a Complex, and doing that requires that the argument type is
 228 in RealFloat.
 229
 230 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 231 a Complex; they only take them apart.
 232
 233 Our approach: identify the offending classes, and add the data type
 234 context to the instance decl.  The "offending classes" are
 235
 236         Read, Enum?
 237
 238 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 239 pattern matching against a constructor from a data type with a context
 240 gives rise to the constraints for that context -- or at least the thinned
 241 version.  So now all classes are "offending".
 242
 243 Note [Newtype deriving]
 244 ~~~~~~~~~~~~~~~~~~~~~~~
 245 Consider this:
 246     class C a b
 247     instance C [a] Char
 248     newtype T = T Char deriving( C [a] )
 249
 250 Notice the free 'a' in the deriving.  We have to fill this out to
 251     newtype T = T Char deriving( forall a. C [a] )
 252
 253 And then translate it to:
 254     instance C [a] Char => C [a] T where ...
 255
 256
 257 Note [Newtype deriving superclasses]
 258 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 259 (See also Trac #1220 for an interesting exchange on newtype
 260 deriving and superclasses.)
 261
 262 The 'tys' here come from the partial application in the deriving
 263 clause. The last arg is the new instance type.
 264
 265 We must pass the superclasses; the newtype might be an instance
 266 of them in a different way than the representation type
 267 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 268 Then the Show instance is not done via isomorphism; it shows
 269         Foo 3 as "Foo 3"
 270 The Num instance is derived via isomorphism, but the Show superclass
 271 dictionary must the Show instance for Foo, *not* the Show dictionary
 272 gotten from the Num dictionary. So we must build a whole new dictionary
 273 not just use the Num one.  The instance we want is something like:
 274      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 275         (+) = ((+)@a)
 276         ...etc...
 277 There may be a coercion needed which we get from the tycon for the newtype
 278 when the dict is constructed in TcInstDcls.tcInstDecl2
 279
 280
 281 Note [Unused constructors and deriving clauses]
 282 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 283 See Trac #3221.  Consider
 284    data T = T1 | T2 deriving( Show )
 285 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
 286 both of them.  So we gather defs/uses from deriving just like anything else.
 287
 288 %************************************************************************
 289 %*                                                                      *
 290 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 \begin{code}
 295 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
 296             -> [LInstDecl Name]  -- All instance declarations
 297             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 298             -> TcM ([InstInfo Name] -- The generated "instance decls"
 299                    ,HsValBinds Name -- Extra generated top-level bindings
 300                    ,DefUses
 301                    ,[TyCon]         -- Extra generated top-level types
 302                    ,[TyCon])        -- Extra generated type family instances
 303
 304 tcDeriving tycl_decls inst_decls deriv_decls
 305   = recoverM (return ([], emptyValBindsOut, emptyDUs, [], [])) $
 306     do  {       -- Fish the "deriving"-related information out of the TcEnv
 307                 -- And make the necessary "equations".
 308           is_boot <- tcIsHsBoot
 309         ; traceTc "tcDeriving" (ppr is_boot)
 310         ; early_specs <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 311
 312         ; overlap_flag <- getOverlapFlag
 313         ; let (infer_specs, given_specs) = splitEithers early_specs
 314         ; insts1 <- mapM (genInst True overlap_flag) given_specs
 315
 316         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
 317                          inferInstanceContexts overlap_flag infer_specs
 318
 319         ; insts2 <- mapM (genInst False overlap_flag) final_specs
 320
 321                  -- Generate the (old) generic to/from functions from each type declaration
 322         ; gen_binds <- return emptyBag -- mkGenericBinds is_boot tycl_decls
 323
 324          -- Generate the generic Representable0/1 instances from each type declaration
 325   ; repInstsMeta <- genGenericRepBinds is_boot tycl_decls
 326
 327         ; let repInsts   = concat (map (\(a,_,_) -> a) repInstsMeta)
 328               repMetaTys = map (\(_,b,_) -> b) repInstsMeta
 329               repTyCons  = map (\(_,_,c) -> c) repInstsMeta
 330         -- Should we extendLocalInstEnv with repInsts?
 331
 332         ; (inst_info, rn_binds, rn_dus) <- renameDeriv is_boot gen_binds (insts1 ++ insts2 ++ repInsts)
 333
 334         ; dflags <- getDOpts
 335         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 336                  (ddump_deriving inst_info rn_binds))
 337
 338         ; when (not (null inst_info)) $
 339           dumpDerivingInfo (ddump_deriving inst_info rn_binds)
 340         ; return ( inst_info, rn_binds, rn_dus
 341                  , concat (map metaTyCons2TyCons repMetaTys), repTyCons) }
 342   where
 343     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
 344     ddump_deriving inst_infos extra_binds
 345       = hang (ptext (sLit "Derived instances"))
 346            2 (vcat (map (\i -> pprInstInfoDetails i $$ text "") inst_infos)
 347               $$ ppr extra_binds)
 348
 349 renameDeriv :: Bool -> LHsBinds RdrName
 350             -> [(InstInfo RdrName, DerivAuxBinds)]
 351             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
 352 renameDeriv is_boot gen_binds insts
 353   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
 354                 -- The inst-info bindings will all be empty, but it's easier to
 355                 -- just use rn_inst_info to change the type appropriately
 356   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
 357         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
 358
 359   | otherwise
 360   = discardWarnings $    -- Discard warnings about unused bindings etc
 361     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns
 362                                                                   -- are used in the generic binds
 363                                rnTopBinds (ValBindsIn gen_binds [])
 364         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
 365
 366                 -- Generate and rename any extra not-one-inst-decl-specific binds,
 367                 -- notably "con2tag" and/or "tag2con" functions.
 368                 -- Bring those names into scope before renaming the instances themselves
 369         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
 370         ; let (aux_binds, aux_sigs) = unzip $ map (genAuxBind loc) $
 371                                       rm_dups [] $ concat deriv_aux_binds
 372               aux_val_binds = ValBindsIn (listToBag aux_binds) aux_sigs
 373         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv aux_val_binds
 374         ; bindLocalNames (collectHsValBinders rn_aux_lhs) $
 375     do  { (rn_aux, dus_aux) <- rnTopBindsRHS rn_aux_lhs
 376         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
 377         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
 378                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
 379
 380   where
 381     (inst_infos, deriv_aux_binds) = unzip insts
 382
 383         -- Remove duplicate requests for auxilliary bindings
 384     rm_dups acc [] = acc
 385     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
 386                        | otherwise            = rm_dups (b:acc) bs
 387
 388
 389     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
 390     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
 391         = return ( info { iBinds = NewTypeDerived coi tc }
 392                  , mkFVs (map dataConName (tyConDataCons tc)))
 393           -- See Note [Newtype deriving and unused constructors]
 394
 395     rn_inst_info inst_info@(InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
 396         =       -- Bring the right type variables into
 397                 -- scope (yuk), and rename the method binds
 398            ASSERT( null sigs )
 399            bindLocalNames (map Var.varName tyvars) $
 400            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) [] binds
 401               ; let binds' = VanillaInst rn_binds [] standalone_deriv
 402               ; return (inst_info { iBinds = binds' }, fvs) }
 403         where
 404           (tyvars,_, clas,_) = instanceHead inst
 405           clas_nm            = className clas
 406
 407 -----------------------------------------
 408 {- Now unused
 409 mkGenericBinds :: Bool -> [LTyClDecl Name] -> TcM (LHsBinds RdrName)
 410 mkGenericBinds is_boot tycl_decls
 411   | is_boot
 412   = return emptyBag
 413   | otherwise
 414   = do  { tcs <- mapM tcLookupTyCon [ tcdName d
 415                                     | L _ d <- tycl_decls, isDataDecl d ]
 416         ; return (unionManyBags [ mkTyConGenericBinds tc
 417                                 | tc <- tcs, tyConHasGenerics tc ]) }
 418                 -- We are only interested in the data type declarations,
 419                 -- and then only in the ones whose 'has-generics' flag is on
 420                 -- The predicate tyConHasGenerics finds both of these
 421 -}
 422 \end{code}
 423
 424 Note [Newtype deriving and unused constructors]
 425 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 426 Consider this (see Trac #1954):
 427
 428   module Bug(P) where
 429   newtype P a = MkP (IO a) deriving Monad
 430
 431 If you compile with -fwarn-unused-binds you do not expect the warning
 432 "Defined but not used: data consructor MkP". Yet the newtype deriving
 433 code does not explicitly mention MkP, but it should behave as if you
 434 had written
 435   instance Monad P where
 436      return x = MkP (return x)
 437      ...etc...
 438
 439 So we want to signal a user of the data constructor 'MkP'.  That's
 440 what we do in rn_inst_info, and it's the only reason we have the TyCon
 441 stored in NewTypeDerived.
 442
 443
 444 %************************************************************************
 445 %*                                                                      *
 446                 From HsSyn to DerivSpec
 447 %*                                                                      *
 448 %************************************************************************
 449
 450 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
 451
 452 \begin{code}
 453 makeDerivSpecs :: Bool
 454                -> [LTyClDecl Name]
 455                -> [LInstDecl Name]
 456                -> [LDerivDecl Name]
 457                -> TcM [EarlyDerivSpec]
 458
 459 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 460   | is_boot     -- No 'deriving' at all in hs-boot files
 461   = do  { mapM_ add_deriv_err deriv_locs
 462         ; return [] }
 463   | otherwise
 464   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
 465         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
 466         ; return (eqns1 ++ eqns2) }
 467   where
 468     extractTyDataPreds decls
 469       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
 470
 471     all_tydata :: [(LHsType Name, LTyClDecl Name)]
 472         -- Derived predicate paired with its data type declaration
 473     all_tydata = extractTyDataPreds (instDeclATs inst_decls ++ tycl_decls)
 474
 475     deriv_locs = map (getLoc . snd) all_tydata
 476                  ++ map getLoc deriv_decls
 477
 478     add_deriv_err loc = setSrcSpan loc $
 479                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
 480                                    2 (ptext (sLit "Use an instance declaration instead")))
 481
 482 ------------------------------------------------------------------
 483 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
 484 -- Standalone deriving declarations
 485 --  e.g.   deriving instance Show a => Show (T a)
 486 -- Rather like tcLocalInstDecl
 487 deriveStandalone (L loc (DerivDecl deriv_ty))
 488   = setSrcSpan loc                   $
 489     addErrCtxt (standaloneCtxt deriv_ty)  $
 490     do { traceTc "Standalone deriving decl for" (ppr deriv_ty)
 491        ; (tvs, theta, cls, inst_tys) <- tcHsInstHead deriv_ty
 492        ; traceTc "Standalone deriving;" $ vcat
 493               [ text "tvs:" <+> ppr tvs
 494               , text "theta:" <+> ppr theta
 495               , text "cls:" <+> ppr cls
 496               , text "tys:" <+> ppr inst_tys ]
 497        ; checkValidInstance deriv_ty tvs theta cls inst_tys
 498                 -- C.f. TcInstDcls.tcLocalInstDecl1
 499
 500        ; let cls_tys = take (length inst_tys - 1) inst_tys
 501              inst_ty = last inst_tys
 502        ; traceTc "Standalone deriving:" $ vcat
 503               [ text "class:" <+> ppr cls
 504               , text "class types:" <+> ppr cls_tys
 505               , text "type:" <+> ppr inst_ty ]
 506        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
 507                    (Just theta) }
 508
 509 ------------------------------------------------------------------
 510 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
 511 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name,
 512                                                    tcdTyVars = tv_names,
 513                                                    tcdTyPats = ty_pats }))
 514   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
 515     tcAddDeclCtxt decl $
 516     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
 517         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 518                                         -- the type variables for the type constructor
 519
 520     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 521                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 522                 -- newtype deriving we allow deriving (forall a. C [a]).
 523
 524         -- Given data T a b c = ... deriving( C d ),
 525         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
 526         ; let cls_tyvars = classTyVars cls
 527               kind = tyVarKind (last cls_tyvars)
 528               (arg_kinds, _) = splitKindFunTys kind
 529               n_args_to_drop = length arg_kinds
 530               n_args_to_keep = tyConArity tc - n_args_to_drop
 531               args_to_drop   = drop n_args_to_keep tc_args
 532               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
 533               inst_ty_kind   = typeKind inst_ty
 534               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
 535               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
 536                                         `minusVarSet` dropped_tvs
 537
 538         -- Check that the result really is well-kinded
 539         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
 540                   (derivingKindErr tc cls cls_tys kind)
 541
 542         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
 543                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
 544                   (derivingEtaErr cls cls_tys inst_ty)
 545                 -- Check that
 546                 --  (a) The data type can be eta-reduced; eg reject:
 547                 --              data instance T a a = ... deriving( Monad )
 548                 --  (b) The type class args do not mention any of the dropped type
 549                 --      variables
 550                 --              newtype T a s = ... deriving( ST s )
 551
 552         -- Type families can't be partially applied
 553         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
 554         -- Note [Deriving, type families, and partial applications]
 555         ; checkTc (not (isFamilyTyCon tc) || n_args_to_drop == 0)
 556                   (typeFamilyPapErr tc cls cls_tys inst_ty)
 557
 558         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
 559   where
 560         -- Tiresomely we must figure out the "lhs", which is awkward for type families
 561         -- E.g.   data T a b = .. deriving( Eq )
 562         --          Here, the lhs is (T a b)
 563         --        data instance TF Int b = ... deriving( Eq )
 564         --          Here, the lhs is (TF Int b)
 565         -- But if we just look up the tycon_name, we get is the *family*
 566         -- tycon, but not pattern types -- they are in the *rep* tycon.
 567     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
 568                              ; let tvs = tyConTyVars tc
 569                              ; return (tvs, tc, mkTyVarTys tvs) }
 570     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
 571                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 572                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
 573                              ; return (tvs, tc, tc_args) }
 574
 575 deriveTyData _other
 576   = panic "derivTyData" -- Caller ensures that only TyData can happen
 577 \end{code}
 578
 579 Note [Deriving, type families, and partial applications]
 580 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 581 When there are no type families, it's quite easy:
 582
 583     newtype S a = MkS [a]
 584     -- :CoS :: S  ~ []  -- Eta-reduced
 585
 586     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
 587     instance Monad [] => Monad S        -- by coercion sym (Monad :CoS)  : Monad [] ~ Monad S
 588
 589 When type familes are involved it's trickier:
 590
 591     data family T a b
 592     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
 593     -- :RT is the representation type for (T Int a)
 594     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
 595     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
 596
 597     instance Eq [a] => Eq (T Int a)     -- easy by coercion
 598     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 599
 600 The "???" bit is that we don't build the :CoF thing in eta-reduced form
 601 Henc the current typeFamilyPapErr, even though the instance makes sense.
 602 After all, we can write it out
 603     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 604       return x = MkT [x]
 605       ... etc ...
 606
 607 \begin{code}
 608 mkEqnHelp :: CtOrigin -> [TyVar] -> Class -> [Type] -> Type
 609           -> DerivContext       -- Just    => context supplied (standalone deriving)
 610                                 -- Nothing => context inferred (deriving on data decl)
 611           -> TcRn EarlyDerivSpec
 612 -- Make the EarlyDerivSpec for an instance
 613 --      forall tvs. theta => cls (tys ++ [ty])
 614 -- where the 'theta' is optional (that's the Maybe part)
 615 -- Assumes that this declaration is well-kinded
 616
 617 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
 618   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 619   , isAlgTyCon tycon    -- Check for functions, primitive types etc
 620   = mk_alg_eqn tycon tc_args
 621   | otherwise
 622   = failWithTc (derivingThingErr False cls cls_tys tc_app
 623                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
 624
 625   where
 626      bale_out msg = failWithTc (derivingThingErr False cls cls_tys tc_app msg)
 627
 628      mk_alg_eqn tycon tc_args
 629       | className cls `elem` typeableClassNames
 630       = do { dflags <- getDOpts
 631            ; case checkTypeableConditions (dflags, tycon) of
 632                Just err -> bale_out err
 633                Nothing  -> mk_typeable_eqn orig tvs cls tycon tc_args mtheta }
 634
 635       | isDataFamilyTyCon tycon
 636       , length tc_args /= tyConArity tycon
 637       = bale_out (ptext (sLit "Unsaturated data family application"))
 638
 639       | otherwise
 640       = do { (rep_tc, rep_tc_args) <- tcLookupDataFamInst tycon tc_args
 641                   -- Be careful to test rep_tc here: in the case of families,
 642                   -- we want to check the instance tycon, not the family tycon
 643
 644            -- For standalone deriving (mtheta /= Nothing),
 645            -- check that all the data constructors are in scope.
 646            ; rdr_env <- getGlobalRdrEnv
 647            ; let hidden_data_cons = isAbstractTyCon rep_tc ||
 648                                     any not_in_scope (tyConDataCons rep_tc)
 649                  not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
 650            ; unless (isNothing mtheta || not hidden_data_cons)
 651                     (bale_out (derivingHiddenErr tycon))
 652
 653            ; dflags <- getDOpts
 654            ; if isDataTyCon rep_tc then
 655                 mkDataTypeEqn orig dflags tvs cls cls_tys
 656                               tycon tc_args rep_tc rep_tc_args mtheta
 657              else
 658                 mkNewTypeEqn orig dflags tvs cls cls_tys
 659                              tycon tc_args rep_tc rep_tc_args mtheta }
 660 \end{code}
 661
 662
 663 %************************************************************************
 664 %*                                                                      *
 665                 Deriving data types
 666 %*                                                                      *
 667 %************************************************************************
 668
 669 \begin{code}
 670 mkDataTypeEqn :: CtOrigin
 671               -> DynFlags
 672               -> [Var]                  -- Universally quantified type variables in the instance
 673               -> Class                  -- Class for which we need to derive an instance
 674               -> [Type]                 -- Other parameters to the class except the last
 675               -> TyCon                  -- Type constructor for which the instance is requested
 676                                         --    (last parameter to the type class)
 677               -> [Type]                 -- Parameters to the type constructor
 678               -> TyCon                  -- rep of the above (for type families)
 679               -> [Type]                 -- rep of the above
 680               -> DerivContext        -- Context of the instance, for standalone deriving
 681               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
 682
 683 mkDataTypeEqn orig dflags tvs cls cls_tys
 684               tycon tc_args rep_tc rep_tc_args mtheta
 685   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
 686         -- NB: pass the *representation* tycon to checkSideConditions
 687         CanDerive               -> go_for_it
 688         NonDerivableClass       -> bale_out (nonStdErr cls)
 689         DerivableClassError msg -> bale_out msg
 690   where
 691     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 692     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
 693
 694 mk_data_eqn :: CtOrigin -> [TyVar] -> Class
 695             -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
 696             -> TcM EarlyDerivSpec
 697 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 698   = do  { dfun_name <- new_dfun_name cls tycon
 699         ; loc <- getSrcSpanM
 700         ; let inst_tys = [mkTyConApp tycon tc_args]
 701               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
 702               spec = DS { ds_loc = loc, ds_orig = orig
 703                         , ds_name = dfun_name, ds_tvs = tvs
 704                         , ds_cls = cls, ds_tys = inst_tys
 705                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 706                         , ds_theta =  mtheta `orElse` inferred_constraints
 707                         , ds_newtype = False }
 708
 709         ; return (if isJust mtheta then Right spec      -- Specified context
 710                                    else Left spec) }    -- Infer context
 711
 712 ----------------------
 713 mk_typeable_eqn :: CtOrigin -> [TyVar] -> Class
 714                 -> TyCon -> [TcType] -> DerivContext
 715                 -> TcM EarlyDerivSpec
 716 mk_typeable_eqn orig tvs cls tycon tc_args mtheta
 717         -- The Typeable class is special in several ways
 718         --        data T a b = ... deriving( Typeable )
 719         -- gives
 720         --        instance Typeable2 T where ...
 721         -- Notice that:
 722         -- 1. There are no constraints in the instance
 723         -- 2. There are no type variables either
 724         -- 3. The actual class we want to generate isn't necessarily
 725         --      Typeable; it depends on the arity of the type
 726   | isNothing mtheta    -- deriving on a data type decl
 727   = do  { checkTc (cls `hasKey` typeableClassKey)
 728                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
 729         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 730         ; mk_typeable_eqn orig tvs real_cls tycon [] (Just []) }
 731
 732   | otherwise           -- standaone deriving
 733   = do  { checkTc (null tc_args)
 734                   (ptext (sLit "Derived typeable instance must be of form (Typeable")
 735                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
 736         ; dfun_name <- new_dfun_name cls tycon
 737         ; loc <- getSrcSpanM
 738         ; return (Right $
 739                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
 740                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
 741                      , ds_tc = tycon, ds_tc_args = []
 742                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
 743
 744 ----------------------
 745 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
 746 -- Generate a sufficiently large set of constraints that typechecking the
 747 -- generated method definitions should succeed.   This set will be simplified
 748 -- before being used in the instance declaration
 749 inferConstraints _ cls inst_tys rep_tc rep_tc_args
 750   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
 751     stupid_constraints ++ extra_constraints
 752     ++ sc_constraints ++ con_arg_constraints
 753   where
 754        -- Constraints arising from the arguments of each constructor
 755     con_arg_constraints
 756       = [ mkClassPred cls [arg_ty]
 757         | data_con <- tyConDataCons rep_tc,
 758           arg_ty   <- ASSERT( isVanillaDataCon data_con )
 759                         get_constrained_tys $
 760                         dataConInstOrigArgTys data_con all_rep_tc_args,
 761           not (isUnLiftedType arg_ty) ]
 762                 -- No constraints for unlifted types
 763                 -- Where they are legal we generate specilised function calls
 764
 765                 -- For functor-like classes, two things are different
 766                 -- (a) We recurse over argument types to generate constraints
 767                 --     See Functor examples in TcGenDeriv
 768                 -- (b) The rep_tc_args will be one short
 769     is_functor_like = getUnique cls `elem` functorLikeClassKeys
 770
 771     get_constrained_tys :: [Type] -> [Type]
 772     get_constrained_tys tys
 773         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
 774         | otherwise       = tys
 775
 776     rep_tc_tvs = tyConTyVars rep_tc
 777     last_tv = last rep_tc_tvs
 778     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
 779                     | otherwise       = rep_tc_args
 780
 781         -- Constraints arising from superclasses
 782         -- See Note [Superclasses of derived instance]
 783     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
 784                                 (classSCTheta cls)
 785
 786         -- Stupid constraints
 787     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
 788     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
 789
 790         -- Extra Data constraints
 791         -- The Data class (only) requires that for
 792         --    instance (...) => Data (T t1 t2)
 793         -- IF   t1:*, t2:*
 794         -- THEN (Data t1, Data t2) are among the (...) constraints
 795         -- Reason: when the IF holds, we generate a method
 796         --             dataCast2 f = gcast2 f
 797         --         and we need the Data constraints to typecheck the method
 798     extra_constraints
 799       | cls `hasKey` dataClassKey
 800       , all (isLiftedTypeKind . typeKind) rep_tc_args
 801       = [mkClassPred cls [ty] | ty <- rep_tc_args]
 802       | otherwise
 803       = []
 804
 805 ------------------------------------------------------------------
 806 -- Check side conditions that dis-allow derivability for particular classes
 807 -- This is *apart* from the newtype-deriving mechanism
 808 --
 809 -- Here we get the representation tycon in case of family instances as it has
 810 -- the data constructors - but we need to be careful to fall back to the
 811 -- family tycon (with indexes) in error messages.
 812
 813 data DerivStatus = CanDerive
 814                  | DerivableClassError SDoc     -- Standard class, but can't do it
 815                  | NonDerivableClass            -- Non-standard class
 816
 817 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
 818 checkSideConditions dflags mtheta cls cls_tys rep_tc
 819   | Just cond <- sideConditions mtheta cls
 820   = case (cond (dflags, rep_tc)) of
 821         Just err -> DerivableClassError err     -- Class-specific error
 822         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
 823                                                 -- cls_tys (the type args other than last)
 824                                                 -- should be null
 825                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
 826   | otherwise = NonDerivableClass       -- Not a standard class
 827   where
 828     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
 829
 830 checkTypeableConditions :: Condition
 831 checkTypeableConditions = checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK
 832
 833 nonStdErr :: Class -> SDoc
 834 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
 835
 836 sideConditions :: DerivContext -> Class -> Maybe Condition
 837 sideConditions mtheta cls
 838   | cls_key == eqClassKey          = Just cond_std
 839   | cls_key == ordClassKey         = Just cond_std
 840   | cls_key == showClassKey        = Just cond_std
 841   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
 842   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
 843   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
 844   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
 845   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond`
 846                                            cond_std `andCond` cond_noUnliftedArgs)
 847   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
 848                                            cond_functorOK True)  -- NB: no cond_std!
 849   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
 850                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
 851   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
 852                                            cond_functorOK False)
 853   | otherwise = Nothing
 854   where
 855     cls_key = getUnique cls
 856     cond_std = cond_stdOK mtheta
 857
 858 type Condition = (DynFlags, TyCon) -> Maybe SDoc
 859         -- first Bool is whether or not we are allowed to derive Data and Typeable
 860         -- second Bool is whether or not we are allowed to derive Functor
 861         -- TyCon is the *representation* tycon if the
 862         --      data type is an indexed one
 863         -- Nothing => OK
 864
 865 orCond :: Condition -> Condition -> Condition
 866 orCond c1 c2 tc
 867   = case c1 tc of
 868         Nothing -> Nothing          -- c1 succeeds
 869         Just x  -> case c2 tc of    -- c1 fails
 870                      Nothing -> Nothing
 871                      Just y  -> Just (x $$ ptext (sLit "  and") $$ y)
 872                                     -- Both fail
 873
 874 andCond :: Condition -> Condition -> Condition
 875 andCond c1 c2 tc = case c1 tc of
 876                      Nothing -> c2 tc   -- c1 succeeds
 877                      Just x  -> Just x  -- c1 fails
 878
 879 cond_stdOK :: DerivContext -> Condition
 880 cond_stdOK (Just _) _
 881   = Nothing     -- Don't check these conservative conditions for
 882                 -- standalone deriving; just generate the code
 883                 -- and let the typechecker handle the result
 884 cond_stdOK Nothing (_, rep_tc)
 885   | null data_cons      = Just (no_cons_why rep_tc $$ suggestion)
 886   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
 887   | otherwise           = Nothing
 888   where
 889     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
 890     data_cons   = tyConDataCons rep_tc
 891     con_whys = mapCatMaybes check_con data_cons
 892
 893     check_con :: DataCon -> Maybe SDoc
 894     check_con con
 895       | isVanillaDataCon con
 896       , all isTauTy (dataConOrigArgTys con) = Nothing
 897       | otherwise = Just (badCon con (ptext (sLit "does not have a Haskell-98 type")))
 898
 899 no_cons_why :: TyCon -> SDoc
 900 no_cons_why rep_tc = quotes (pprSourceTyCon rep_tc) <+>
 901                      ptext (sLit "has no data constructors")
 902
 903 cond_enumOrProduct :: Condition
 904 cond_enumOrProduct = cond_isEnumeration `orCond`
 905                        (cond_isProduct `andCond` cond_noUnliftedArgs)
 906
 907 cond_noUnliftedArgs :: Condition
 908 -- For some classes (eg Eq, Ord) we allow unlifted arg types
 909 -- by generating specilaised code.  For others (eg Data) we don't.
 910 cond_noUnliftedArgs (_, tc)
 911   | null bad_cons = Nothing
 912   | otherwise     = Just why
 913   where
 914     bad_cons = [ con | con <- tyConDataCons tc
 915                      , any isUnLiftedType (dataConOrigArgTys con) ]
 916     why = badCon (head bad_cons) (ptext (sLit "has arguments of unlifted type"))
 917
 918 cond_isEnumeration :: Condition
 919 cond_isEnumeration (_, rep_tc)
 920   | isEnumerationTyCon rep_tc   = Nothing
 921   | otherwise                   = Just why
 922   where
 923     why = sep [ quotes (pprSourceTyCon rep_tc) <+>
 924                   ptext (sLit "is not an enumeration type")
 925               , ptext (sLit "(an enumeration consists of one or more nullary, non-GADT constructors)") ]
 926                   -- See Note [Enumeration types] in TyCon
 927
 928 cond_isProduct :: Condition
 929 cond_isProduct (_, rep_tc)
 930   | isProductTyCon rep_tc = Nothing
 931   | otherwise             = Just why
 932   where
 933     why = quotes (pprSourceTyCon rep_tc) <+>
 934           ptext (sLit "does not have precisely one constructor")
 935
 936 cond_typeableOK :: Condition
 937 -- OK for Typeable class
 938 -- Currently: (a) args all of kind *
 939 --            (b) 7 or fewer args
 940 cond_typeableOK (_, tc)
 941   | tyConArity tc > 7 = Just too_many
 942   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars tc))
 943                       = Just bad_kind
 944   | otherwise         = Nothing
 945   where
 946     too_many = quotes (pprSourceTyCon tc) <+>
 947                ptext (sLit "has too many arguments")
 948     bad_kind = quotes (pprSourceTyCon tc) <+>
 949                ptext (sLit "has arguments of kind other than `*'")
 950
 951 functorLikeClassKeys :: [Unique]
 952 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
 953
 954 cond_functorOK :: Bool -> Condition
 955 -- OK for Functor/Foldable/Traversable class
 956 -- Currently: (a) at least one argument
 957 --            (b) don't use argument contravariantly
 958 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
 959 --            (d) optionally: don't use function types
 960 --            (e) no "stupid context" on data type
 961 cond_functorOK allowFunctions (_, rep_tc)
 962   | null tc_tvs
 963   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
 964           <+> ptext (sLit "has no parameters"))
 965
 966   | not (null bad_stupid_theta)
 967   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
 968           <+> ptext (sLit "has a class context") <+> pprTheta bad_stupid_theta)
 969
 970   | otherwise
 971   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
 972   where
 973     tc_tvs            = tyConTyVars rep_tc
 974     Just (_, last_tv) = snocView tc_tvs
 975     bad_stupid_theta  = filter is_bad (tyConStupidTheta rep_tc)
 976     is_bad pred       = last_tv `elemVarSet` tyVarsOfPred pred
 977
 978     data_cons = tyConDataCons rep_tc
 979     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
 980
 981     check_vanilla :: DataCon -> Maybe SDoc
 982     check_vanilla con | isVanillaDataCon con = Nothing
 983                       | otherwise            = Just (badCon con existential)
 984
 985     ft_check :: DataCon -> FFoldType (Maybe SDoc)
 986     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
 987                       , ft_co_var = Just (badCon con covariant)
 988                       , ft_fun = \x y -> if allowFunctions then x `mplus` y
 989                                                            else Just (badCon con functions)
 990                       , ft_tup = \_ xs  -> msum xs
 991                       , ft_ty_app = \_ x   -> x
 992                       , ft_bad_app = Just (badCon con wrong_arg)
 993                       , ft_forall = \_ x   -> x }
 994
 995     existential = ptext (sLit "has existential arguments")
 996     covariant   = ptext (sLit "uses the type variable in a function argument")
 997     functions   = ptext (sLit "contains function types")
 998     wrong_arg   = ptext (sLit "uses the type variable in an argument other than the last")
 999
1000 checkFlag :: ExtensionFlag -> Condition
1001 checkFlag flag (dflags, _)
1002   | xopt flag dflags = Nothing
1003   | otherwise        = Just why
1004   where
1005     why = ptext (sLit "You need -X") <> text flag_str
1006           <+> ptext (sLit "to derive an instance for this class")
1007     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
1008                  [s]   -> s
1009                  other -> pprPanic "checkFlag" (ppr other)
1010
1011 std_class_via_iso :: Class -> Bool
1012 -- These standard classes can be derived for a newtype
1013 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
1014 -- because giving so gives the same results as generating the boilerplate
1015 std_class_via_iso clas
1016   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
1017         -- Not Read/Show because they respect the type
1018         -- Not Enum, because newtypes are never in Enum
1019
1020
1021 non_iso_class :: Class -> Bool
1022 -- *Never* derive Read,Show,Typeable,Data by isomorphism,
1023 -- even with -XGeneralizedNewtypeDeriving
1024 non_iso_class cls
1025   = classKey cls `elem` ([readClassKey, showClassKey, dataClassKey] ++
1026                          typeableClassKeys)
1027
1028 typeableClassKeys :: [Unique]
1029 typeableClassKeys = map getUnique typeableClassNames
1030
1031 new_dfun_name :: Class -> TyCon -> TcM Name
1032 new_dfun_name clas tycon        -- Just a simple wrapper
1033   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1034         ; newDFunName clas [mkTyConApp tycon []] loc }
1035         -- The type passed to newDFunName is only used to generate
1036         -- a suitable string; hence the empty type arg list
1037
1038 badCon :: DataCon -> SDoc -> SDoc
1039 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1040 \end{code}
1041
1042 Note [Superclasses of derived instance]
1043 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1044 In general, a derived instance decl needs the superclasses of the derived
1045 class too.  So if we have
1046         data T a = ...deriving( Ord )
1047 then the initial context for Ord (T a) should include Eq (T a).  Often this is
1048 redundant; we'll also generate an Ord constraint for each constructor argument,
1049 and that will probably generate enough constraints to make the Eq (T a) constraint
1050 be satisfied too.  But not always; consider:
1051
1052  data S a = S
1053  instance Eq (S a)
1054  instance Ord (S a)
1055
1056  data T a = MkT (S a) deriving( Ord )
1057  instance Num a => Eq (T a)
1058
1059 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1060 Similarly consider:
1061         data T a = MkT deriving( Data, Typeable )
1062 Here there *is* no argument field, but we must nevertheless generate
1063 a context for the Data instances:
1064         instance Typable a => Data (T a) where ...
1065
1066
1067 %************************************************************************
1068 %*                                                                      *
1069                 Deriving newtypes
1070 %*                                                                      *
1071 %************************************************************************
1072
1073 \begin{code}
1074 mkNewTypeEqn :: CtOrigin -> DynFlags -> [Var] -> Class
1075              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1076              -> DerivContext
1077              -> TcRn EarlyDerivSpec
1078 mkNewTypeEqn orig dflags tvs
1079              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1080 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1081   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1082   = do  { traceTc "newtype deriving:" (ppr tycon <+> ppr rep_tys <+> ppr all_preds)
1083         ; dfun_name <- new_dfun_name cls tycon
1084         ; loc <- getSrcSpanM
1085         ; let spec = DS { ds_loc = loc, ds_orig = orig
1086                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs
1087                         , ds_cls = cls, ds_tys = inst_tys
1088                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1089                         , ds_theta =  mtheta `orElse` all_preds
1090                         , ds_newtype = True }
1091         ; return (if isJust mtheta then Right spec
1092                                    else Left spec) }
1093
1094   | otherwise
1095   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1096       CanDerive -> go_for_it    -- Use the standard H98 method
1097       DerivableClassError msg   -- Error with standard class
1098         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1099         | otherwise                  -> bale_out msg
1100       NonDerivableClass         -- Must use newtype deriving
1101         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1102         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1103         | otherwise                  -> bale_out non_std
1104   where
1105         newtype_deriving = xopt Opt_GeneralizedNewtypeDeriving dflags
1106         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1107         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1108
1109         non_std    = nonStdErr cls
1110         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1111
1112         -- Here is the plan for newtype derivings.  We see
1113         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1114         -- where t is a type,
1115         --       ak+1...an is a suffix of a1..an, and are all tyars
1116         --       ak+1...an do not occur free in t, nor in the s1..sm
1117         --       (C s1 ... sm) is a  *partial applications* of class C
1118         --                      with the last parameter missing
1119         --       (T a1 .. ak) matches the kind of C's last argument
1120         --              (and hence so does t)
1121         -- The latter kind-check has been done by deriveTyData already,
1122         -- and tc_args are already trimmed
1123         --
1124         -- We generate the instance
1125         --       instance forall ({a1..ak} u fvs(s1..sm)).
1126         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1127         -- where T a1...ap is the partial application of
1128         --       the LHS of the correct kind and p >= k
1129         --
1130         --      NB: the variables below are:
1131         --              tc_tvs = [a1, ..., an]
1132         --              tyvars_to_keep = [a1, ..., ak]
1133         --              rep_ty = t ak .. an
1134         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1135         --              tys = [s1, ..., sm]
1136         --              rep_fn' = t
1137         --
1138         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1139         -- We generate the instance
1140         --      instance Monad (ST s) => Monad (T s) where
1141
1142         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1143                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1144                 -- eta-reduces the representation type, so we know that
1145                 --      T a ~ S a a
1146                 -- That's convenient here, because we may have to apply
1147                 -- it to fewer than its original complement of arguments
1148
1149         -- Note [Newtype representation]
1150         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1151         -- Need newTyConRhs (*not* a recursive representation finder)
1152         -- to get the representation type. For example
1153         --      newtype B = MkB Int
1154         --      newtype A = MkA B deriving( Num )
1155         -- We want the Num instance of B, *not* the Num instance of Int,
1156         -- when making the Num instance of A!
1157         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1158         rep_tys     = cls_tys ++ [rep_inst_ty]
1159         rep_pred    = mkClassPred cls rep_tys
1160                 -- rep_pred is the representation dictionary, from where
1161                 -- we are gong to get all the methods for the newtype
1162                 -- dictionary
1163
1164
1165     -- Next we figure out what superclass dictionaries to use
1166     -- See Note [Newtype deriving superclasses] above
1167
1168         cls_tyvars = classTyVars cls
1169         dfun_tvs = tyVarsOfTypes inst_tys
1170         inst_ty = mkTyConApp tycon tc_args
1171         inst_tys = cls_tys ++ [inst_ty]
1172         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1173                               (classSCTheta cls)
1174
1175                 -- If there are no tyvars, there's no need
1176                 -- to abstract over the dictionaries we need
1177                 -- Example:     newtype T = MkT Int deriving( C )
1178                 -- We get the derived instance
1179                 --              instance C T
1180                 -- rather than
1181                 --              instance C Int => C T
1182         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1183
1184         -------------------------------------------------------------------
1185         --  Figuring out whether we can only do this newtype-deriving thing
1186
1187         can_derive_via_isomorphism
1188            =  not (non_iso_class cls)
1189            && arity_ok
1190            && eta_ok
1191            && ats_ok
1192 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1193
1194         arity_ok = length cls_tys + 1 == classArity cls
1195                 -- Well kinded; eg not: newtype T ... deriving( ST )
1196                 --                      because ST needs *2* type params
1197
1198         -- Check that eta reduction is OK
1199         eta_ok = nt_eta_arity <= length rep_tc_args
1200                 -- The newtype can be eta-reduced to match the number
1201                 --     of type argument actually supplied
1202                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1203                 --     Here the 'b' must be the same in the rep type (S [a] b)
1204                 --     And the [a] must not mention 'b'.  That's all handled
1205                 --     by nt_eta_rity.
1206
1207         ats_ok = null (classATs cls)
1208                -- No associated types for the class, because we don't
1209                -- currently generate type 'instance' decls; and cannot do
1210                -- so for 'data' instance decls
1211
1212         cant_derive_err
1213            = vcat [ ppUnless arity_ok arity_msg
1214                   , ppUnless eta_ok eta_msg
1215                   , ppUnless ats_ok ats_msg ]
1216         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1217         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1218         ats_msg   = ptext (sLit "the class has associated types")
1219 \end{code}
1220
1221 Note [Recursive newtypes]
1222 ~~~~~~~~~~~~~~~~~~~~~~~~~
1223 Newtype deriving works fine, even if the newtype is recursive.
1224 e.g.    newtype S1 = S1 [T1 ()]
1225         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1226 Remember, too, that type families are curretly (conservatively) given
1227 a recursive flag, so this also allows newtype deriving to work
1228 for type famillies.
1229
1230 We used to exclude recursive types, because we had a rather simple
1231 minded way of generating the instance decl:
1232    newtype A = MkA [A]
1233    instance Eq [A] => Eq A      -- Makes typechecker loop!
1234 But now we require a simple context, so it's ok.
1235
1236
1237 %************************************************************************
1238 %*                                                                      *
1239 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1240 %*                                                                      *
1241 %************************************************************************
1242
1243 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1244 terms, which is the final correct RHS for the corresponding original
1245 equation.
1246 \begin{itemize}
1247 \item
1248 Each (k,TyVarTy tv) in a solution constrains only a type
1249 variable, tv.
1250
1251 \item
1252 The (k,TyVarTy tv) pairs in a solution are canonically
1253 ordered by sorting on type varible, tv, (major key) and then class, k,
1254 (minor key)
1255 \end{itemize}
1256
1257 \begin{code}
1258 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1259
1260 inferInstanceContexts _ [] = return []
1261
1262 inferInstanceContexts oflag infer_specs
1263   = do  { traceTc "inferInstanceContexts" $ vcat (map pprDerivSpec infer_specs)
1264         ; iterate_deriv 1 initial_solutions }
1265   where
1266     ------------------------------------------------------------------
1267         -- The initial solutions for the equations claim that each
1268         -- instance has an empty context; this solution is certainly
1269         -- in canonical form.
1270     initial_solutions :: [ThetaType]
1271     initial_solutions = [ [] | _ <- infer_specs ]
1272
1273     ------------------------------------------------------------------
1274         -- iterate_deriv calculates the next batch of solutions,
1275         -- compares it with the current one; finishes if they are the
1276         -- same, otherwise recurses with the new solutions.
1277         -- It fails if any iteration fails
1278     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1279     iterate_deriv n current_solns
1280       | n > 20  -- Looks as if we are in an infinite loop
1281                 -- This can happen if we have -XUndecidableInstances
1282                 -- (See TcSimplify.tcSimplifyDeriv.)
1283       = pprPanic "solveDerivEqns: probable loop"
1284                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1285       | otherwise
1286       = do {      -- Extend the inst info from the explicit instance decls
1287                   -- with the current set of solutions, and simplify each RHS
1288              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1289                                            current_solns infer_specs
1290            ; new_solns <- checkNoErrs $
1291                           extendLocalInstEnv inst_specs $
1292                           mapM gen_soln infer_specs
1293
1294            ; if (current_solns == new_solns) then
1295                 return [ spec { ds_theta = soln }
1296                        | (spec, soln) <- zip infer_specs current_solns ]
1297              else
1298                 iterate_deriv (n+1) new_solns }
1299
1300     ------------------------------------------------------------------
1301     gen_soln :: DerivSpec  -> TcM [PredType]
1302     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars
1303                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1304       = setSrcSpan loc  $
1305         addErrCtxt (derivInstCtxt the_pred) $
1306         do {      -- Check for a bizarre corner case, when the derived instance decl should
1307                   -- have form  instance C a b => D (T a) where ...
1308                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1309                   -- of problems; in particular, it's hard to compare solutions for
1310                   -- equality when finding the fixpoint.  Moreover, simplifyDeriv
1311                   -- has an assert failure because it finds a TyVar when it expects
1312                   -- only TcTyVars.  So I just rule it out for now.  I'm not
1313                   -- even sure how it can arise.
1314
1315            ; let tv_set = mkVarSet tyvars
1316                  weird_preds = [pred | pred <- deriv_rhs
1317                                      , not (tyVarsOfPred pred `subVarSet` tv_set)]
1318            ; mapM_ (addErrTc . badDerivedPred) weird_preds
1319
1320            ; theta <- simplifyDeriv orig the_pred tyvars deriv_rhs
1321                 -- checkValidInstance tyvars theta clas inst_tys
1322                 -- Not necessary; see Note [Exotic derived instance contexts]
1323                 --                in TcSimplify
1324
1325            ; traceTc "TcDeriv" (ppr deriv_rhs $$ ppr theta)
1326                 -- Claim: the result instance declaration is guaranteed valid
1327                 -- Hence no need to call:
1328                 --   checkValidInstance tyvars theta clas inst_tys
1329            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1330       where
1331         the_pred = mkClassPred clas inst_tys
1332
1333 ------------------------------------------------------------------
1334 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1335 mkInstance overlap_flag theta
1336             (DS { ds_name = dfun_name
1337                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1338   = mkLocalInstance dfun overlap_flag
1339   where
1340     dfun = mkDictFunId dfun_name tyvars theta clas tys
1341
1342
1343 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1344 -- Add new locally-defined instances; don't bother to check
1345 -- for functional dependency errors -- that'll happen in TcInstDcls
1346 extendLocalInstEnv dfuns thing_inside
1347  = do { env <- getGblEnv
1348       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1349              env'      = env { tcg_inst_env = inst_env' }
1350       ; setGblEnv env' thing_inside }
1351 \end{code}
1352
1353
1354 %************************************************************************
1355 %*                                                                      *
1356 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1357 %*                                                                      *
1358 %************************************************************************
1359
1360 After all the trouble to figure out the required context for the
1361 derived instance declarations, all that's left is to chug along to
1362 produce them.  They will then be shoved into @tcInstDecls2@, which
1363 will do all its usual business.
1364
1365 There are lots of possibilities for code to generate.  Here are
1366 various general remarks.
1367
1368 PRINCIPLES:
1369 \begin{itemize}
1370 \item
1371 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1372 ``you-couldn't-do-better-by-hand'' efficient.
1373
1374 \item
1375 Deriving @Show@---also pretty common--- should also be reasonable good code.
1376
1377 \item
1378 Deriving for the other classes isn't that common or that big a deal.
1379 \end{itemize}
1380
1381 PRAGMATICS:
1382
1383 \begin{itemize}
1384 \item
1385 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1386
1387 \item
1388 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1389
1390 \item
1391 We {\em normally} generate code only for the non-defaulted methods;
1392 there are some exceptions for @Eq@ and (especially) @Ord@...
1393
1394 \item
1395 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1396 constructor's numeric (@Int#@) tag.  These are generated by
1397 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1398 these is around is given by @hasCon2TagFun@.
1399
1400 The examples under the different sections below will make this
1401 clearer.
1402
1403 \item
1404 Much less often (really just for deriving @Ix@), we use a
1405 @_tag2con_<tycon>@ function.  See the examples.
1406
1407 \item
1408 We use the renamer!!!  Reason: we're supposed to be
1409 producing @LHsBinds Name@ for the methods, but that means
1410 producing correctly-uniquified code on the fly.  This is entirely
1411 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1412 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1413 the renamer.  What a great hack!
1414 \end{itemize}
1415
1416 \begin{code}
1417 -- Generate the InstInfo for the required instance paired with the
1418 --   *representation* tycon for that instance,
1419 -- plus any auxiliary bindings required
1420 --
1421 -- Representation tycons differ from the tycon in the instance signature in
1422 -- case of instances for indexed families.
1423 --
1424 genInst :: Bool         -- True <=> standalone deriving
1425         -> OverlapFlag
1426         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1427 genInst standalone_deriv oflag
1428         spec@(DS { ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1429                  , ds_theta = theta, ds_newtype = is_newtype
1430                  , ds_name = name, ds_cls = clas })
1431   | is_newtype
1432   = return (InstInfo { iSpec   = inst_spec
1433                      , iBinds  = NewTypeDerived co rep_tycon }, [])
1434
1435   | otherwise
1436   = do  { fix_env <- getFixityEnv
1437         ; let loc   = getSrcSpan name
1438               (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1439                    -- In case of a family instance, we need to use the representation
1440                    -- tycon (after all, it has the data constructors)
1441
1442         ; return (InstInfo { iSpec   = inst_spec
1443                            , iBinds  = VanillaInst meth_binds [] standalone_deriv }
1444                  , aux_binds) }
1445   where
1446     inst_spec = mkInstance oflag theta spec
1447     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1448               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1449               Nothing     -> id_co
1450               -- Not a family => rep_tycon = main tycon
1451     co2 = case newTyConCo_maybe rep_tycon of
1452               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1453               Nothing     -> id_co  -- The newtype is transparent; no need for a cast
1454     co = co1 `mkTransCoI` co2
1455     id_co = IdCo (mkTyConApp rep_tycon rep_tc_args)
1456
1457 -- Example: newtype instance N [a] = N1 (Tree a)
1458 --          deriving instance Eq b => Eq (N [(b,b)])
1459 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1460 -- When dealing with the deriving clause
1461 --    co1 : N [(b,b)] ~ R1:N (b,b)
1462 --    co2 : R1:N (b,b) ~ Tree (b,b)
1463 --    co  : N [(b,b)] ~ Tree (b,b)
1464
1465 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1466 genDerivBinds loc fix_env clas tycon
1467   | className clas `elem` typeableClassNames
1468   = (gen_Typeable_binds loc tycon, [])
1469
1470   | otherwise
1471   = case assocMaybe gen_list (getUnique clas) of
1472         Just gen_fn -> gen_fn loc tycon
1473         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1474   where
1475     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1476     gen_list = [(eqClassKey,       gen_Eq_binds)
1477                ,(ordClassKey,      gen_Ord_binds)
1478                ,(enumClassKey,     gen_Enum_binds)
1479                ,(boundedClassKey,  gen_Bounded_binds)
1480                ,(ixClassKey,       gen_Ix_binds)
1481                ,(showClassKey,     gen_Show_binds fix_env)
1482                ,(readClassKey,     gen_Read_binds fix_env)
1483                ,(dataClassKey,     gen_Data_binds)
1484                ,(functorClassKey,  gen_Functor_binds)
1485                ,(foldableClassKey, gen_Foldable_binds)
1486                ,(traversableClassKey, gen_Traversable_binds)
1487                ]
1488
1489 -- Generate the binds for the generic representation
1490 genGenericRepBinds :: Bool -> [LTyClDecl Name]
1491                    -> TcM [([(InstInfo RdrName, DerivAuxBinds)]
1492                            , MetaTyCons, TyCon)]
1493 genGenericRepBinds isBoot tyclDecls
1494   | isBoot    = return []
1495   | otherwise = do
1496       allTyDecls <- mapM tcLookupTyCon [ tcdName d | L _ d <- tyclDecls
1497                                        , isDataDecl d ]
1498       let tyDecls = filter tyConHasGenerics allTyDecls
1499       inst1 <- mapM genGenericRepBind tyDecls
1500       let (_repInsts, metaTyCons, _repTys) = unzip3 inst1
1501       metaInsts <- ASSERT (length tyDecls == length metaTyCons)
1502                      mapM genDtMeta (zip tyDecls metaTyCons)
1503       return (ASSERT (length inst1 == length metaInsts)
1504                 [ (ri : mi, ms, rt)
1505                 | ((ri, ms, rt), mi) <- zip inst1 metaInsts ])
1506
1507 genGenericRepBind :: TyCon -> TcM ((InstInfo RdrName, DerivAuxBinds)
1508                                   , MetaTyCons, TyCon)
1509 genGenericRepBind tc =
1510   do  clas <- tcLookupClass rep0ClassName
1511       uniqS <- newUniqueSupply
1512       dfun_name <- new_dfun_name clas tc
1513       let
1514         -- Uniques for everyone
1515         (uniqD:uniqs) = uniqsFromSupply uniqS
1516         (uniqsC,us) = splitAt (length tc_cons) uniqs
1517         uniqsS :: [[Unique]] -- Unique supply for the S datatypes
1518         uniqsS = mkUniqsS tc_arits us
1519         mkUniqsS []    _  = []
1520         mkUniqsS (n:t) us = case splitAt n us of
1521                               (us1,us2) -> us1 : mkUniqsS t us2
1522
1523         tc_name   = tyConName tc
1524         tc_cons   = tyConDataCons tc
1525         tc_arits  = map dataConSourceArity tc_cons
1526
1527         tc_occ    = nameOccName tc_name
1528         d_occ     = mkGenD tc_occ
1529         c_occ m   = mkGenC tc_occ m
1530         s_occ m n = mkGenS tc_occ m n
1531         mod_name  = nameModule (tyConName tc)
1532         d_name    = mkExternalName uniqD mod_name d_occ wiredInSrcSpan
1533         c_names   = [ mkExternalName u mod_name (c_occ m) wiredInSrcSpan
1534                       | (u,m) <- zip uniqsC [0..] ]
1535         s_names   = [ [ mkExternalName u mod_name (s_occ m n) wiredInSrcSpan
1536                         | (u,n) <- zip us [0..] ] | (us,m) <- zip uniqsS [0..] ]
1537         tvs       = tyConTyVars tc
1538         tc_ty     = mkTyConApp tc (mkTyVarTys tvs)
1539
1540         mkTyCon name = ASSERT( isExternalName name )
1541                          buildAlgTyCon name [] [] mkAbstractTyConRhs
1542                            NonRecursive False False NoParentTyCon Nothing
1543
1544       metaDTyCon  <- mkTyCon d_name
1545       metaCTyCons <- sequence [ mkTyCon c_name | c_name <- c_names ]
1546       metaSTyCons <- mapM sequence
1547                        [ [ mkTyCon s_name
1548                          | s_name <- s_namesC ] | s_namesC <- s_names ]
1549
1550       let metaDts = MetaTyCons metaDTyCon metaCTyCons metaSTyCons
1551
1552       rep0_tycon <- tc_mkRep0TyCon tc metaDts
1553
1554       let
1555         mkInstRep0 = (InstInfo { iSpec = inst, iBinds = binds }
1556                                , [ {- No DerivAuxBinds -} ])
1557         inst  = mkLocalInstance dfun NoOverlap
1558         binds = VanillaInst (mkBindsRep0 tc) [] False
1559
1560         dfun  = mkDictFunId dfun_name (tyConTyVars tc) [] clas [tc_ty]
1561       return (mkInstRep0, metaDts, rep0_tycon)
1562
1563 genDtMeta :: (TyCon, MetaTyCons) -> TcM [(InstInfo RdrName, DerivAuxBinds)]
1564 genDtMeta (tc,metaDts) =
1565   do  dClas <- tcLookupClass datatypeClassName
1566       d_dfun_name <- new_dfun_name dClas tc
1567       cClas <- tcLookupClass constructorClassName
1568       c_dfun_names <- sequence [ new_dfun_name cClas tc | _ <- metaC metaDts ]
1569       sClas <- tcLookupClass selectorClassName
1570       s_dfun_names <- sequence (map sequence [ [ new_dfun_name sClas tc
1571                                                | _ <- x ]
1572                                              | x <- metaS metaDts ])
1573       fix_env <- getFixityEnv
1574
1575       let
1576         (dBinds,cBinds,sBinds) = mkBindsMetaD fix_env tc
1577
1578         -- Datatype
1579         d_metaTycon = metaD metaDts
1580         d_inst = mkLocalInstance d_dfun NoOverlap
1581         d_binds = VanillaInst dBinds [] False
1582         d_dfun  = mkDictFunId d_dfun_name (tyConTyVars tc) [] dClas
1583                     [ mkTyConTy d_metaTycon ]
1584         d_mkInst = (InstInfo { iSpec = d_inst, iBinds = d_binds }, [])
1585
1586         -- Constructor
1587         c_metaTycons = metaC metaDts
1588         c_insts = [ mkLocalInstance (c_dfun c ds) NoOverlap
1589                   | (c, ds) <- myZip1 c_metaTycons c_dfun_names ]
1590         c_binds = [ VanillaInst c [] False | c <- cBinds ]
1591         c_dfun c dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] cClas
1592                                [ mkTyConTy c ]
1593         c_mkInst = [ (InstInfo { iSpec = is, iBinds = bs }, [])
1594                    | (is,bs) <- myZip1 c_insts c_binds ]
1595
1596         -- Selector
1597         s_metaTycons = metaS metaDts
1598         s_insts = map (map (\(s,ds) -> mkLocalInstance (s_dfun s ds) NoOverlap))
1599                     (myZip2 s_metaTycons s_dfun_names)
1600         s_binds = [ [ VanillaInst s [] False | s <- ss ] | ss <- sBinds ]
1601         s_dfun s dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] sClas
1602                                [ mkTyConTy s ]
1603         s_mkInst = map (map (\(is,bs) -> (InstInfo {iSpec=is, iBinds=bs}, [])))
1604                      (myZip2 s_insts s_binds)
1605
1606         myZip1 :: [a] -> [b] -> [(a,b)]
1607         myZip1 l1 l2 = ASSERT (length l1 == length l2) zip l1 l2
1608
1609         myZip2 :: [[a]] -> [[b]] -> [[(a,b)]]
1610         myZip2 l1 l2 =
1611           ASSERT (and (zipWith (>=) (map length l1) (map length l2)))
1612             [ zip x1 x2 | (x1,x2) <- zip l1 l2 ]
1613
1614       return (d_mkInst : c_mkInst ++ concat s_mkInst)
1615 \end{code}
1616
1617
1618 %************************************************************************
1619 %*                                                                      *
1620 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1621 %*                                                                      *
1622 %************************************************************************
1623
1624 \begin{code}
1625 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1626 derivingKindErr tc cls cls_tys cls_kind
1627   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1628                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1629        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1630             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1631
1632 derivingEtaErr :: Class -> [Type] -> Type -> Message
1633 derivingEtaErr cls cls_tys inst_ty
1634   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1635          nest 2 (ptext (sLit "instance (...) =>")
1636                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1637
1638 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1639 typeFamilyPapErr tc cls cls_tys inst_ty
1640   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1641        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc)
1642
1643 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1644 derivingThingErr newtype_deriving clas tys ty why
1645   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1646              2 (quotes (ppr pred))
1647           $$ nest 2 extra) <> colon,
1648          nest 2 why]
1649   where
1650     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1651           | otherwise        = empty
1652     pred = mkClassPred clas (tys ++ [ty])
1653
1654 derivingHiddenErr :: TyCon -> SDoc
1655 derivingHiddenErr tc
1656   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1657        2 (ptext (sLit "so you cannot derive an instance for it"))
1658
1659 standaloneCtxt :: LHsType Name -> SDoc
1660 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
1661                        2 (quotes (ppr ty))
1662
1663 derivInstCtxt :: PredType -> Message
1664 derivInstCtxt pred
1665   = ptext (sLit "When deriving the instance for") <+> parens (ppr pred)
1666
1667 badDerivedPred :: PredType -> Message
1668 badDerivedPred pred
1669   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1670           ptext (sLit "type variables that are not data type parameters"),
1671           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1672 \end{code}