compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import Coercion
  34 import ErrUtils
  35 import MkId
  36 import DataCon
  37 import Maybes
  38 import RdrName
  39 import Name
  40 import NameSet
  41 import TyCon
  42 import TcType
  43 import Var
  44 import VarSet
  45 import PrelNames
  46 import SrcLoc
  47 import Util
  48 import ListSetOps
  49 import Outputable
  50 import FastString
  51 import Bag
  52
  53 import Control.Monad
  54 \end{code}
  55
  56 %************************************************************************
  57 %*                                                                      *
  58                 Overview
  59 %*                                                                      *
  60 %************************************************************************
  61
  62 Overall plan
  63 ~~~~~~~~~~~~
  64 1.  Convert the decls (i.e. data/newtype deriving clauses,
  65     plus standalone deriving) to [EarlyDerivSpec]
  66
  67 2.  Infer the missing contexts for the Left DerivSpecs
  68
  69 3.  Add the derived bindings, generating InstInfos
  70
  71
  72 \begin{code}
  73 -- DerivSpec is purely  local to this module
  74 data DerivSpec  = DS { ds_loc     :: SrcSpan
  75                      , ds_orig    :: CtOrigin
  76                      , ds_name    :: Name
  77                      , ds_tvs     :: [TyVar]
  78                      , ds_theta   :: ThetaType
  79                      , ds_cls     :: Class
  80                      , ds_tys     :: [Type]
  81                      , ds_tc      :: TyCon
  82                      , ds_tc_args :: [Type]
  83                      , ds_newtype :: Bool }
  84         -- This spec implies a dfun declaration of the form
  85         --       df :: forall tvs. theta => C tys
  86         -- The Name is the name for the DFun we'll build
  87         -- The tyvars bind all the variables in the theta
  88         -- For type families, the tycon in
  89         --       in ds_tys is the *family* tycon
  90         --       in ds_tc, ds_tc_args is the *representation* tycon
  91         -- For non-family tycons, both are the same
  92
  93         -- ds_newtype = True  <=> Newtype deriving
  94         --              False <=> Vanilla deriving
  95 \end{code}
  96
  97 Example:
  98
  99      newtype instance T [a] = MkT (Tree a) deriving( C s )
 100 ==>
 101      axiom T [a] = :RTList a
 102      axiom :RTList a = Tree a
 103
 104      DS { ds_tvs = [a,s], ds_cls = C, ds_tys = [s, T [a]]
 105         , ds_tc = :RTList, ds_tc_args = [a]
 106         , ds_newtype = True }
 107
 108 \begin{code}
 109 type DerivContext = Maybe ThetaType
 110    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
 111    -- Just theta <=> Standalone deriving: context supplied by programmer
 112
 113 type EarlyDerivSpec = Either DerivSpec DerivSpec
 114         -- Left  ds => the context for the instance should be inferred
 115         --             In this case ds_theta is the list of all the
 116         --                constraints needed, such as (Eq [a], Eq a)
 117         --                The inference process is to reduce this to a
 118         --                simpler form (e.g. Eq a)
 119         --
 120         -- Right ds => the exact context for the instance is supplied
 121         --             by the programmer; it is ds_theta
 122
 123 pprDerivSpec :: DerivSpec -> SDoc
 124 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
 125                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
 126   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
 127             <+> equals <+> ppr rhs)
 128 \end{code}
 129
 130
 131 Inferring missing contexts
 132 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 133 Consider
 134
 135         data T a b = C1 (Foo a) (Bar b)
 136                    | C2 Int (T b a)
 137                    | C3 (T a a)
 138                    deriving (Eq)
 139
 140 [NOTE: See end of these comments for what to do with
 141         data (C a, D b) => T a b = ...
 142 ]
 143
 144 We want to come up with an instance declaration of the form
 145
 146         instance (Ping a, Pong b, ...) => Eq (T a b) where
 147                 x == y = ...
 148
 149 It is pretty easy, albeit tedious, to fill in the code "...".  The
 150 trick is to figure out what the context for the instance decl is,
 151 namely @Ping@, @Pong@ and friends.
 152
 153 Let's call the context reqd for the T instance of class C at types
 154 (a,b, ...)  C (T a b).  Thus:
 155
 156         Eq (T a b) = (Ping a, Pong b, ...)
 157
 158 Now we can get a (recursive) equation from the @data@ decl:
 159
 160         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 161                    u Eq (T b a) u Eq Int        -- From C2
 162                    u Eq (T a a)                 -- From C3
 163
 164 Foo and Bar may have explicit instances for @Eq@, in which case we can
 165 just substitute for them.  Alternatively, either or both may have
 166 their @Eq@ instances given by @deriving@ clauses, in which case they
 167 form part of the system of equations.
 168
 169 Now all we need do is simplify and solve the equations, iterating to
 170 find the least fixpoint.  Notice that the order of the arguments can
 171 switch around, as here in the recursive calls to T.
 172
 173 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 174
 175 We start with:
 176
 177         Eq (T a b) = {}         -- The empty set
 178
 179 Next iteration:
 180         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 181                    u Eq (T b a) u Eq Int        -- From C2
 182                    u Eq (T a a)                 -- From C3
 183
 184         After simplification:
 185                    = Eq a u Ping b u {} u {} u {}
 186                    = Eq a u Ping b
 187
 188 Next iteration:
 189
 190         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 191                    u Eq (T b a) u Eq Int        -- From C2
 192                    u Eq (T a a)                 -- From C3
 193
 194         After simplification:
 195                    = Eq a u Ping b
 196                    u (Eq b u Ping a)
 197                    u (Eq a u Ping a)
 198
 199                    = Eq a u Ping b u Eq b u Ping a
 200
 201 The next iteration gives the same result, so this is the fixpoint.  We
 202 need to make a canonical form of the RHS to ensure convergence.  We do
 203 this by simplifying the RHS to a form in which
 204
 205         - the classes constrain only tyvars
 206         - the list is sorted by tyvar (major key) and then class (minor key)
 207         - no duplicates, of course
 208
 209 So, here are the synonyms for the ``equation'' structures:
 210
 211
 212 Note [Data decl contexts]
 213 ~~~~~~~~~~~~~~~~~~~~~~~~~
 214 Consider
 215
 216         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 217
 218 We will need an instance decl like:
 219
 220         instance (Read a, RealFloat a) => Read (Complex a) where
 221           ...
 222
 223 The RealFloat in the context is because the read method for Complex is bound
 224 to construct a Complex, and doing that requires that the argument type is
 225 in RealFloat.
 226
 227 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 228 a Complex; they only take them apart.
 229
 230 Our approach: identify the offending classes, and add the data type
 231 context to the instance decl.  The "offending classes" are
 232
 233         Read, Enum?
 234
 235 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 236 pattern matching against a constructor from a data type with a context
 237 gives rise to the constraints for that context -- or at least the thinned
 238 version.  So now all classes are "offending".
 239
 240 Note [Newtype deriving]
 241 ~~~~~~~~~~~~~~~~~~~~~~~
 242 Consider this:
 243     class C a b
 244     instance C [a] Char
 245     newtype T = T Char deriving( C [a] )
 246
 247 Notice the free 'a' in the deriving.  We have to fill this out to
 248     newtype T = T Char deriving( forall a. C [a] )
 249
 250 And then translate it to:
 251     instance C [a] Char => C [a] T where ...
 252
 253
 254 Note [Newtype deriving superclasses]
 255 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 256 (See also Trac #1220 for an interesting exchange on newtype
 257 deriving and superclasses.)
 258
 259 The 'tys' here come from the partial application in the deriving
 260 clause. The last arg is the new instance type.
 261
 262 We must pass the superclasses; the newtype might be an instance
 263 of them in a different way than the representation type
 264 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 265 Then the Show instance is not done via isomorphism; it shows
 266         Foo 3 as "Foo 3"
 267 The Num instance is derived via isomorphism, but the Show superclass
 268 dictionary must the Show instance for Foo, *not* the Show dictionary
 269 gotten from the Num dictionary. So we must build a whole new dictionary
 270 not just use the Num one.  The instance we want is something like:
 271      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 272         (+) = ((+)@a)
 273         ...etc...
 274 There may be a coercion needed which we get from the tycon for the newtype
 275 when the dict is constructed in TcInstDcls.tcInstDecl2
 276
 277
 278 Note [Unused constructors and deriving clauses]
 279 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 280 See Trac #3221.  Consider
 281    data T = T1 | T2 deriving( Show )
 282 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
 283 both of them.  So we gather defs/uses from deriving just like anything else.
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 \begin{code}
 292 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
 293             -> [LInstDecl Name]  -- All instance declarations
 294             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 295             -> TcM ([InstInfo Name],    -- The generated "instance decls"
 296                     HsValBinds Name,    -- Extra generated top-level bindings
 297                     DefUses)
 298
 299 tcDeriving tycl_decls inst_decls deriv_decls
 300   = recoverM (return ([], emptyValBindsOut, emptyDUs)) $
 301     do  {       -- Fish the "deriving"-related information out of the TcEnv
 302                 -- And make the necessary "equations".
 303           is_boot <- tcIsHsBoot
 304         ; traceTc "tcDeriving" (ppr is_boot)
 305         ; early_specs <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 306
 307         ; overlap_flag <- getOverlapFlag
 308         ; let (infer_specs, given_specs) = splitEithers early_specs
 309         ; insts1 <- mapM (genInst True overlap_flag) given_specs
 310
 311         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
 312                          inferInstanceContexts overlap_flag infer_specs
 313
 314         ; insts2 <- mapM (genInst False overlap_flag) final_specs
 315
 316                  -- Generate the generic to/from functions from each type declaration
 317         ; gen_binds <- mkGenericBinds is_boot tycl_decls
 318         ; (inst_info, rn_binds, rn_dus) <- renameDeriv is_boot gen_binds (insts1 ++ insts2)
 319
 320         ; dflags <- getDOpts
 321         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 322                  (ddump_deriving inst_info rn_binds))
 323
 324         ; return (inst_info, rn_binds, rn_dus) }
 325   where
 326     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
 327     ddump_deriving inst_infos extra_binds
 328       = vcat (map pprInstInfoDetails inst_infos) $$ ppr extra_binds
 329
 330 renameDeriv :: Bool -> LHsBinds RdrName
 331             -> [(InstInfo RdrName, DerivAuxBinds)]
 332             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
 333 renameDeriv is_boot gen_binds insts
 334   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
 335                 -- The inst-info bindings will all be empty, but it's easier to
 336                 -- just use rn_inst_info to change the type appropriately
 337   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
 338         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
 339
 340   | otherwise
 341   = discardWarnings $    -- Discard warnings about unused bindings etc
 342     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns
 343                                                                   -- are used in the generic binds
 344                                rnTopBinds (ValBindsIn gen_binds [])
 345         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
 346
 347                 -- Generate and rename any extra not-one-inst-decl-specific binds,
 348                 -- notably "con2tag" and/or "tag2con" functions.
 349                 -- Bring those names into scope before renaming the instances themselves
 350         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
 351         ; let (aux_binds, aux_sigs) = unzip $ map (genAuxBind loc) $
 352                                       rm_dups [] $ concat deriv_aux_binds
 353               aux_val_binds = ValBindsIn (listToBag aux_binds) aux_sigs
 354         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv aux_val_binds
 355         ; let aux_names = collectHsValBinders rn_aux_lhs
 356
 357         ; bindLocalNames aux_names $
 358     do  { (rn_aux, dus_aux) <- rnTopBindsRHS (mkNameSet aux_names) rn_aux_lhs
 359         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
 360         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
 361                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
 362
 363   where
 364     (inst_infos, deriv_aux_binds) = unzip insts
 365
 366         -- Remove duplicate requests for auxilliary bindings
 367     rm_dups acc [] = acc
 368     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
 369                        | otherwise            = rm_dups (b:acc) bs
 370
 371
 372     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
 373     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
 374         = return ( info { iBinds = NewTypeDerived coi tc }
 375                  , mkFVs (map dataConName (tyConDataCons tc)))
 376           -- See Note [Newtype deriving and unused constructors]
 377
 378     rn_inst_info (InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
 379         =       -- Bring the right type variables into
 380                 -- scope (yuk), and rename the method binds
 381            ASSERT( null sigs )
 382            bindLocalNames (map Var.varName tyvars) $
 383            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) [] binds
 384               ; let binds' = VanillaInst rn_binds [] standalone_deriv
 385               ; return (InstInfo { iSpec = inst, iBinds = binds' }, fvs) }
 386         where
 387           (tyvars,_, clas,_) = instanceHead inst
 388           clas_nm            = className clas
 389
 390 -----------------------------------------
 391 mkGenericBinds :: Bool -> [LTyClDecl Name] -> TcM (LHsBinds RdrName)
 392 mkGenericBinds is_boot tycl_decls
 393   | is_boot
 394   = return emptyBag
 395   | otherwise
 396   = do  { tcs <- mapM tcLookupTyCon [ tcdName d
 397                                     | L _ d <- tycl_decls, isDataDecl d ]
 398         ; return (unionManyBags [ mkTyConGenericBinds tc
 399                                 | tc <- tcs, tyConHasGenerics tc ]) }
 400                 -- We are only interested in the data type declarations,
 401                 -- and then only in the ones whose 'has-generics' flag is on
 402                 -- The predicate tyConHasGenerics finds both of these
 403 \end{code}
 404
 405 Note [Newtype deriving and unused constructors]
 406 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 407 Consider this (see Trac #1954):
 408
 409   module Bug(P) where
 410   newtype P a = MkP (IO a) deriving Monad
 411
 412 If you compile with -fwarn-unused-binds you do not expect the warning
 413 "Defined but not used: data consructor MkP". Yet the newtype deriving
 414 code does not explicitly mention MkP, but it should behave as if you
 415 had written
 416   instance Monad P where
 417      return x = MkP (return x)
 418      ...etc...
 419
 420 So we want to signal a user of the data constructor 'MkP'.  That's
 421 what we do in rn_inst_info, and it's the only reason we have the TyCon
 422 stored in NewTypeDerived.
 423
 424
 425 %************************************************************************
 426 %*                                                                      *
 427                 From HsSyn to DerivSpec
 428 %*                                                                      *
 429 %************************************************************************
 430
 431 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
 432
 433 \begin{code}
 434 makeDerivSpecs :: Bool
 435                -> [LTyClDecl Name]
 436                -> [LInstDecl Name]
 437                -> [LDerivDecl Name]
 438                -> TcM [EarlyDerivSpec]
 439
 440 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 441   | is_boot     -- No 'deriving' at all in hs-boot files
 442   = do  { mapM_ add_deriv_err deriv_locs
 443         ; return [] }
 444   | otherwise
 445   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
 446         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
 447         ; return (eqns1 ++ eqns2) }
 448   where
 449     extractTyDataPreds decls
 450       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
 451
 452     all_tydata :: [(LHsType Name, LTyClDecl Name)]
 453         -- Derived predicate paired with its data type declaration
 454     all_tydata = extractTyDataPreds (instDeclATs inst_decls ++ tycl_decls)
 455
 456     deriv_locs = map (getLoc . snd) all_tydata
 457                  ++ map getLoc deriv_decls
 458
 459     add_deriv_err loc = setSrcSpan loc $
 460                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
 461                                    2 (ptext (sLit "Use an instance declaration instead")))
 462
 463 ------------------------------------------------------------------
 464 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
 465 -- Standalone deriving declarations
 466 --  e.g.   deriving instance Show a => Show (T a)
 467 -- Rather like tcLocalInstDecl
 468 deriveStandalone (L loc (DerivDecl deriv_ty))
 469   = setSrcSpan loc                   $
 470     addErrCtxt (standaloneCtxt deriv_ty)  $
 471     do { traceTc "Standalone deriving decl for" (ppr deriv_ty)
 472        ; (tvs, theta, tau) <- tcHsInstHead deriv_ty
 473        ; traceTc "Standalone deriving;" $ vcat
 474               [ text "tvs:" <+> ppr tvs
 475               , text "theta:" <+> ppr theta
 476               , text "tau:" <+> ppr tau ]
 477        ; (cls, inst_tys) <- checkValidInstance deriv_ty tvs theta tau
 478                 -- C.f. TcInstDcls.tcLocalInstDecl1
 479
 480        ; let cls_tys = take (length inst_tys - 1) inst_tys
 481              inst_ty = last inst_tys
 482        ; traceTc "Standalone deriving:" $ vcat
 483               [ text "class:" <+> ppr cls
 484               , text "class types:" <+> ppr cls_tys
 485               , text "type:" <+> ppr inst_ty ]
 486        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
 487                    (Just theta) }
 488
 489 ------------------------------------------------------------------
 490 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
 491 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name,
 492                                                    tcdTyVars = tv_names,
 493                                                    tcdTyPats = ty_pats }))
 494   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
 495     tcAddDeclCtxt decl $
 496     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
 497         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 498                                         -- the type variables for the type constructor
 499
 500     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 501                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 502                 -- newtype deriving we allow deriving (forall a. C [a]).
 503
 504         -- Given data T a b c = ... deriving( C d ),
 505         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
 506         ; let cls_tyvars = classTyVars cls
 507               kind = tyVarKind (last cls_tyvars)
 508               (arg_kinds, _) = splitKindFunTys kind
 509               n_args_to_drop = length arg_kinds
 510               n_args_to_keep = tyConArity tc - n_args_to_drop
 511               args_to_drop   = drop n_args_to_keep tc_args
 512               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
 513               inst_ty_kind   = typeKind inst_ty
 514               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
 515               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
 516                                         `minusVarSet` dropped_tvs
 517
 518         -- Check that the result really is well-kinded
 519         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
 520                   (derivingKindErr tc cls cls_tys kind)
 521
 522         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
 523                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
 524                   (derivingEtaErr cls cls_tys inst_ty)
 525                 -- Check that
 526                 --  (a) The data type can be eta-reduced; eg reject:
 527                 --              data instance T a a = ... deriving( Monad )
 528                 --  (b) The type class args do not mention any of the dropped type
 529                 --      variables
 530                 --              newtype T a s = ... deriving( ST s )
 531
 532         -- Type families can't be partially applied
 533         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
 534         -- Note [Deriving, type families, and partial applications]
 535         ; checkTc (not (isFamilyTyCon tc) || n_args_to_drop == 0)
 536                   (typeFamilyPapErr tc cls cls_tys inst_ty)
 537
 538         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
 539   where
 540         -- Tiresomely we must figure out the "lhs", which is awkward for type families
 541         -- E.g.   data T a b = .. deriving( Eq )
 542         --          Here, the lhs is (T a b)
 543         --        data instance TF Int b = ... deriving( Eq )
 544         --          Here, the lhs is (TF Int b)
 545         -- But if we just look up the tycon_name, we get is the *family*
 546         -- tycon, but not pattern types -- they are in the *rep* tycon.
 547     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
 548                              ; let tvs = tyConTyVars tc
 549                              ; return (tvs, tc, mkTyVarTys tvs) }
 550     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
 551                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 552                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
 553                              ; return (tvs, tc, tc_args) }
 554
 555 deriveTyData _other
 556   = panic "derivTyData" -- Caller ensures that only TyData can happen
 557 \end{code}
 558
 559 Note [Deriving, type families, and partial applications]
 560 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 561 When there are no type families, it's quite easy:
 562
 563     newtype S a = MkS [a]
 564     -- :CoS :: S  ~ []  -- Eta-reduced
 565
 566     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
 567     instance Monad [] => Monad S        -- by coercion sym (Monad :CoS)  : Monad [] ~ Monad S
 568
 569 When type familes are involved it's trickier:
 570
 571     data family T a b
 572     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
 573     -- :RT is the representation type for (T Int a)
 574     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
 575     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
 576
 577     instance Eq [a] => Eq (T Int a)     -- easy by coercion
 578     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 579
 580 The "???" bit is that we don't build the :CoF thing in eta-reduced form
 581 Henc the current typeFamilyPapErr, even though the instance makes sense.
 582 After all, we can write it out
 583     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 584       return x = MkT [x]
 585       ... etc ...
 586
 587 \begin{code}
 588 mkEqnHelp :: CtOrigin -> [TyVar] -> Class -> [Type] -> Type
 589           -> DerivContext       -- Just    => context supplied (standalone deriving)
 590                                 -- Nothing => context inferred (deriving on data decl)
 591           -> TcRn EarlyDerivSpec
 592 -- Make the EarlyDerivSpec for an instance
 593 --      forall tvs. theta => cls (tys ++ [ty])
 594 -- where the 'theta' is optional (that's the Maybe part)
 595 -- Assumes that this declaration is well-kinded
 596
 597 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
 598   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 599   , isAlgTyCon tycon    -- Check for functions, primitive types etc
 600   = do  { (rep_tc, rep_tc_args) <- tcLookupDataFamInst tycon tc_args
 601                   -- Be careful to test rep_tc here: in the case of families,
 602                   -- we want to check the instance tycon, not the family tycon
 603
 604         -- For standalone deriving (mtheta /= Nothing),
 605         -- check that all the data constructors are in scope.
 606         -- No need for this when deriving Typeable, becuase we don't need
 607         -- the constructors for that.
 608         ; rdr_env <- getGlobalRdrEnv
 609         ; let hidden_data_cons = isAbstractTyCon rep_tc || any not_in_scope (tyConDataCons rep_tc)
 610               not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
 611         ; checkTc (isNothing mtheta ||
 612                    not hidden_data_cons ||
 613                    className cls `elem` typeableClassNames)
 614                   (derivingHiddenErr tycon)
 615
 616         ; dflags <- getDOpts
 617         ; if isDataTyCon rep_tc then
 618                 mkDataTypeEqn orig dflags tvs cls cls_tys
 619                               tycon tc_args rep_tc rep_tc_args mtheta
 620           else
 621                 mkNewTypeEqn orig dflags tvs cls cls_tys
 622                              tycon tc_args rep_tc rep_tc_args mtheta }
 623   | otherwise
 624   = failWithTc (derivingThingErr False cls cls_tys tc_app
 625                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
 626 \end{code}
 627
 628
 629 %************************************************************************
 630 %*                                                                      *
 631                 Deriving data types
 632 %*                                                                      *
 633 %************************************************************************
 634
 635 \begin{code}
 636 mkDataTypeEqn :: CtOrigin
 637               -> DynFlags
 638               -> [Var]                  -- Universally quantified type variables in the instance
 639               -> Class                  -- Class for which we need to derive an instance
 640               -> [Type]                 -- Other parameters to the class except the last
 641               -> TyCon                  -- Type constructor for which the instance is requested
 642                                         --    (last parameter to the type class)
 643               -> [Type]                 -- Parameters to the type constructor
 644               -> TyCon                  -- rep of the above (for type families)
 645               -> [Type]                 -- rep of the above
 646               -> DerivContext        -- Context of the instance, for standalone deriving
 647               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
 648
 649 mkDataTypeEqn orig dflags tvs cls cls_tys
 650               tycon tc_args rep_tc rep_tc_args mtheta
 651   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
 652         -- NB: pass the *representation* tycon to checkSideConditions
 653         CanDerive               -> go_for_it
 654         NonDerivableClass       -> bale_out (nonStdErr cls)
 655         DerivableClassError msg -> bale_out msg
 656   where
 657     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 658     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
 659
 660 mk_data_eqn, mk_typeable_eqn
 661    :: CtOrigin -> [TyVar] -> Class
 662    -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
 663    -> TcM EarlyDerivSpec
 664 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 665   | getName cls `elem` typeableClassNames
 666   = mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 667
 668   | otherwise
 669   = do  { dfun_name <- new_dfun_name cls tycon
 670         ; loc <- getSrcSpanM
 671         ; let inst_tys = [mkTyConApp tycon tc_args]
 672               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
 673               spec = DS { ds_loc = loc, ds_orig = orig
 674                         , ds_name = dfun_name, ds_tvs = tvs
 675                         , ds_cls = cls, ds_tys = inst_tys
 676                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 677                         , ds_theta =  mtheta `orElse` inferred_constraints
 678                         , ds_newtype = False }
 679
 680         ; return (if isJust mtheta then Right spec      -- Specified context
 681                                    else Left spec) }    -- Infer context
 682
 683 mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 684         -- The Typeable class is special in several ways
 685         --        data T a b = ... deriving( Typeable )
 686         -- gives
 687         --        instance Typeable2 T where ...
 688         -- Notice that:
 689         -- 1. There are no constraints in the instance
 690         -- 2. There are no type variables either
 691         -- 3. The actual class we want to generate isn't necessarily
 692         --      Typeable; it depends on the arity of the type
 693   | isNothing mtheta    -- deriving on a data type decl
 694   = do  { checkTc (cls `hasKey` typeableClassKey)
 695                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
 696         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 697         ; mk_typeable_eqn orig tvs real_cls tycon [] rep_tc [] (Just []) }
 698
 699   | otherwise           -- standaone deriving
 700   = do  { checkTc (null tc_args)
 701                   (ptext (sLit "Derived typeable instance must be of form (Typeable")
 702                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
 703         ; dfun_name <- new_dfun_name cls tycon
 704         ; loc <- getSrcSpanM
 705         ; return (Right $
 706                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
 707                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
 708                      , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 709                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
 710
 711
 712 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
 713 -- Generate a sufficiently large set of constraints that typechecking the
 714 -- generated method definitions should succeed.   This set will be simplified
 715 -- before being used in the instance declaration
 716 inferConstraints _ cls inst_tys rep_tc rep_tc_args
 717   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
 718     stupid_constraints ++ extra_constraints
 719     ++ sc_constraints ++ con_arg_constraints
 720   where
 721        -- Constraints arising from the arguments of each constructor
 722     con_arg_constraints
 723       = [ mkClassPred cls [arg_ty]
 724         | data_con <- tyConDataCons rep_tc,
 725           arg_ty   <- ASSERT( isVanillaDataCon data_con )
 726                         get_constrained_tys $
 727                         dataConInstOrigArgTys data_con all_rep_tc_args,
 728           not (isUnLiftedType arg_ty) ]
 729                 -- No constraints for unlifted types
 730                 -- Where they are legal we generate specilised function calls
 731
 732                 -- For functor-like classes, two things are different
 733                 -- (a) We recurse over argument types to generate constraints
 734                 --     See Functor examples in TcGenDeriv
 735                 -- (b) The rep_tc_args will be one short
 736     is_functor_like = getUnique cls `elem` functorLikeClassKeys
 737
 738     get_constrained_tys :: [Type] -> [Type]
 739     get_constrained_tys tys
 740         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
 741         | otherwise       = tys
 742
 743     rep_tc_tvs = tyConTyVars rep_tc
 744     last_tv = last rep_tc_tvs
 745     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
 746                     | otherwise       = rep_tc_args
 747
 748         -- Constraints arising from superclasses
 749         -- See Note [Superclasses of derived instance]
 750     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
 751                                 (classSCTheta cls)
 752
 753         -- Stupid constraints
 754     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
 755     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
 756
 757         -- Extra Data constraints
 758         -- The Data class (only) requires that for
 759         --    instance (...) => Data (T t1 t2)
 760         -- IF   t1:*, t2:*
 761         -- THEN (Data t1, Data t2) are among the (...) constraints
 762         -- Reason: when the IF holds, we generate a method
 763         --             dataCast2 f = gcast2 f
 764         --         and we need the Data constraints to typecheck the method
 765     extra_constraints
 766       | cls `hasKey` dataClassKey
 767       , all (isLiftedTypeKind . typeKind) rep_tc_args
 768       = [mkClassPred cls [ty] | ty <- rep_tc_args]
 769       | otherwise
 770       = []
 771
 772 ------------------------------------------------------------------
 773 -- Check side conditions that dis-allow derivability for particular classes
 774 -- This is *apart* from the newtype-deriving mechanism
 775 --
 776 -- Here we get the representation tycon in case of family instances as it has
 777 -- the data constructors - but we need to be careful to fall back to the
 778 -- family tycon (with indexes) in error messages.
 779
 780 data DerivStatus = CanDerive
 781                  | DerivableClassError SDoc     -- Standard class, but can't do it
 782                  | NonDerivableClass            -- Non-standard class
 783
 784 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
 785 checkSideConditions dflags mtheta cls cls_tys rep_tc
 786   | Just cond <- sideConditions mtheta cls
 787   = case (cond (dflags, rep_tc)) of
 788         Just err -> DerivableClassError err     -- Class-specific error
 789         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
 790                                                 -- cls_tys (the type args other than last)
 791                                                 -- should be null
 792                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
 793   | otherwise = NonDerivableClass       -- Not a standard class
 794   where
 795     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
 796
 797 nonStdErr :: Class -> SDoc
 798 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
 799
 800 sideConditions :: DerivContext -> Class -> Maybe Condition
 801 sideConditions mtheta cls
 802   | cls_key == eqClassKey          = Just cond_std
 803   | cls_key == ordClassKey         = Just cond_std
 804   | cls_key == showClassKey        = Just cond_std
 805   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
 806   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
 807   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
 808   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
 809   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond`
 810                                            cond_std `andCond` cond_noUnliftedArgs)
 811   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
 812                                            cond_functorOK True)  -- NB: no cond_std!
 813   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
 814                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
 815   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
 816                                            cond_functorOK False)
 817   | getName cls `elem` typeableClassNames = Just (checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK)
 818   | otherwise = Nothing
 819   where
 820     cls_key = getUnique cls
 821     cond_std = cond_stdOK mtheta
 822
 823 type Condition = (DynFlags, TyCon) -> Maybe SDoc
 824         -- first Bool is whether or not we are allowed to derive Data and Typeable
 825         -- second Bool is whether or not we are allowed to derive Functor
 826         -- TyCon is the *representation* tycon if the
 827         --      data type is an indexed one
 828         -- Nothing => OK
 829
 830 orCond :: Condition -> Condition -> Condition
 831 orCond c1 c2 tc
 832   = case c1 tc of
 833         Nothing -> Nothing          -- c1 succeeds
 834         Just x  -> case c2 tc of    -- c1 fails
 835                      Nothing -> Nothing
 836                      Just y  -> Just (x $$ ptext (sLit "  and") $$ y)
 837                                     -- Both fail
 838
 839 andCond :: Condition -> Condition -> Condition
 840 andCond c1 c2 tc = case c1 tc of
 841                      Nothing -> c2 tc   -- c1 succeeds
 842                      Just x  -> Just x  -- c1 fails
 843
 844 cond_stdOK :: DerivContext -> Condition
 845 cond_stdOK (Just _) _
 846   = Nothing     -- Don't check these conservative conditions for
 847                 -- standalone deriving; just generate the code
 848                 -- and let the typechecker handle the result
 849 cond_stdOK Nothing (_, rep_tc)
 850   | null data_cons      = Just (no_cons_why rep_tc $$ suggestion)
 851   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
 852   | otherwise           = Nothing
 853   where
 854     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
 855     data_cons   = tyConDataCons rep_tc
 856     con_whys = mapCatMaybes check_con data_cons
 857
 858     check_con :: DataCon -> Maybe SDoc
 859     check_con con
 860       | isVanillaDataCon con
 861       , all isTauTy (dataConOrigArgTys con) = Nothing
 862       | otherwise = Just (badCon con (ptext (sLit "does not have a Haskell-98 type")))
 863
 864 no_cons_why :: TyCon -> SDoc
 865 no_cons_why rep_tc = quotes (pprSourceTyCon rep_tc) <+>
 866                      ptext (sLit "has no data constructors")
 867
 868 cond_enumOrProduct :: Condition
 869 cond_enumOrProduct = cond_isEnumeration `orCond`
 870                        (cond_isProduct `andCond` cond_noUnliftedArgs)
 871
 872 cond_noUnliftedArgs :: Condition
 873 -- For some classes (eg Eq, Ord) we allow unlifted arg types
 874 -- by generating specilaised code.  For others (eg Data) we don't.
 875 cond_noUnliftedArgs (_, tc)
 876   | null bad_cons = Nothing
 877   | otherwise     = Just why
 878   where
 879     bad_cons = [ con | con <- tyConDataCons tc
 880                      , any isUnLiftedType (dataConOrigArgTys con) ]
 881     why = badCon (head bad_cons) (ptext (sLit "has arguments of unlifted type"))
 882
 883 cond_isEnumeration :: Condition
 884 cond_isEnumeration (_, rep_tc)
 885   | isEnumerationTyCon rep_tc   = Nothing
 886   | otherwise                   = Just why
 887   where
 888     why = sep [ quotes (pprSourceTyCon rep_tc) <+>
 889                   ptext (sLit "is not an enumeration type")
 890               , nest 2 $ ptext (sLit "(an enumeration consists of one or more nullary constructors)") ]
 891                   -- See Note [Enumeration types] in TyCon
 892
 893 cond_isProduct :: Condition
 894 cond_isProduct (_, rep_tc)
 895   | isProductTyCon rep_tc = Nothing
 896   | otherwise             = Just why
 897   where
 898     why = quotes (pprSourceTyCon rep_tc) <+>
 899           ptext (sLit "does not have precisely one constructor")
 900
 901 cond_typeableOK :: Condition
 902 -- OK for Typeable class
 903 -- Currently: (a) args all of kind *
 904 --            (b) 7 or fewer args
 905 cond_typeableOK (_, rep_tc)
 906   | tyConArity rep_tc > 7       = Just too_many
 907   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars rep_tc))
 908                                 = Just bad_kind
 909   | isFamInstTyCon rep_tc       = Just fam_inst  -- no Typable for family insts
 910   | otherwise                   = Nothing
 911   where
 912     too_many = quotes (pprSourceTyCon rep_tc) <+>
 913                ptext (sLit "has too many arguments")
 914     bad_kind = quotes (pprSourceTyCon rep_tc) <+>
 915                ptext (sLit "has arguments of kind other than `*'")
 916     fam_inst = quotes (pprSourceTyCon rep_tc) <+>
 917                ptext (sLit "is a type family")
 918
 919
 920 functorLikeClassKeys :: [Unique]
 921 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
 922
 923 cond_functorOK :: Bool -> Condition
 924 -- OK for Functor/Foldable/Traversable class
 925 -- Currently: (a) at least one argument
 926 --            (b) don't use argument contravariantly
 927 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
 928 --            (d) optionally: don't use function types
 929 --            (e) no "stupid context" on data type
 930 cond_functorOK allowFunctions (dflags, rep_tc)
 931   | not (xopt Opt_DeriveFunctor dflags)
 932   = Just (ptext (sLit "You need -XDeriveFunctor to derive an instance for this class"))
 933
 934   | null tc_tvs
 935   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
 936           <+> ptext (sLit "has no parameters"))
 937
 938   | not (null bad_stupid_theta)
 939   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
 940           <+> ptext (sLit "has a class context") <+> pprTheta bad_stupid_theta)
 941
 942   | otherwise
 943   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
 944   where
 945     tc_tvs            = tyConTyVars rep_tc
 946     Just (_, last_tv) = snocView tc_tvs
 947     bad_stupid_theta  = filter is_bad (tyConStupidTheta rep_tc)
 948     is_bad pred       = last_tv `elemVarSet` tyVarsOfPred pred
 949
 950     data_cons = tyConDataCons rep_tc
 951     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
 952
 953     check_vanilla :: DataCon -> Maybe SDoc
 954     check_vanilla con | isVanillaDataCon con = Nothing
 955                       | otherwise            = Just (badCon con existential)
 956
 957     ft_check :: DataCon -> FFoldType (Maybe SDoc)
 958     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
 959                       , ft_co_var = Just (badCon con covariant)
 960                       , ft_fun = \x y -> if allowFunctions then x `mplus` y
 961                                                            else Just (badCon con functions)
 962                       , ft_tup = \_ xs  -> msum xs
 963                       , ft_ty_app = \_ x   -> x
 964                       , ft_bad_app = Just (badCon con wrong_arg)
 965                       , ft_forall = \_ x   -> x }
 966
 967     existential = ptext (sLit "has existential arguments")
 968     covariant   = ptext (sLit "uses the type variable in a function argument")
 969     functions   = ptext (sLit "contains function types")
 970     wrong_arg   = ptext (sLit "uses the type variable in an argument other than the last")
 971
 972 checkFlag :: ExtensionFlag -> Condition
 973 checkFlag flag (dflags, _)
 974   | xopt flag dflags = Nothing
 975   | otherwise        = Just why
 976   where
 977     why = ptext (sLit "You need -X") <> text flag_str
 978           <+> ptext (sLit "to derive an instance for this class")
 979     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
 980                  [s]   -> s
 981                  other -> pprPanic "checkFlag" (ppr other)
 982
 983 std_class_via_iso :: Class -> Bool
 984 -- These standard classes can be derived for a newtype
 985 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
 986 -- because giving so gives the same results as generating the boilerplate
 987 std_class_via_iso clas
 988   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
 989         -- Not Read/Show because they respect the type
 990         -- Not Enum, because newtypes are never in Enum
 991
 992
 993 non_iso_class :: Class -> Bool
 994 -- *Never* derive Read,Show,Typeable,Data by isomorphism,
 995 -- even with -XGeneralizedNewtypeDeriving
 996 non_iso_class cls
 997   = classKey cls `elem` ([readClassKey, showClassKey, dataClassKey] ++
 998                          typeableClassKeys)
 999
1000 typeableClassKeys :: [Unique]
1001 typeableClassKeys = map getUnique typeableClassNames
1002
1003 new_dfun_name :: Class -> TyCon -> TcM Name
1004 new_dfun_name clas tycon        -- Just a simple wrapper
1005   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1006         ; newDFunName clas [mkTyConApp tycon []] loc }
1007         -- The type passed to newDFunName is only used to generate
1008         -- a suitable string; hence the empty type arg list
1009
1010 badCon :: DataCon -> SDoc -> SDoc
1011 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1012 \end{code}
1013
1014 Note [Superclasses of derived instance]
1015 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1016 In general, a derived instance decl needs the superclasses of the derived
1017 class too.  So if we have
1018         data T a = ...deriving( Ord )
1019 then the initial context for Ord (T a) should include Eq (T a).  Often this is
1020 redundant; we'll also generate an Ord constraint for each constructor argument,
1021 and that will probably generate enough constraints to make the Eq (T a) constraint
1022 be satisfied too.  But not always; consider:
1023
1024  data S a = S
1025  instance Eq (S a)
1026  instance Ord (S a)
1027
1028  data T a = MkT (S a) deriving( Ord )
1029  instance Num a => Eq (T a)
1030
1031 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1032 Similarly consider:
1033         data T a = MkT deriving( Data, Typeable )
1034 Here there *is* no argument field, but we must nevertheless generate
1035 a context for the Data instances:
1036         instance Typable a => Data (T a) where ...
1037
1038
1039 %************************************************************************
1040 %*                                                                      *
1041                 Deriving newtypes
1042 %*                                                                      *
1043 %************************************************************************
1044
1045 \begin{code}
1046 mkNewTypeEqn :: CtOrigin -> DynFlags -> [Var] -> Class
1047              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1048              -> DerivContext
1049              -> TcRn EarlyDerivSpec
1050 mkNewTypeEqn orig dflags tvs
1051              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1052 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1053   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1054   = do  { traceTc "newtype deriving:" (ppr tycon <+> ppr rep_tys <+> ppr all_preds)
1055         ; dfun_name <- new_dfun_name cls tycon
1056         ; loc <- getSrcSpanM
1057         ; let spec = DS { ds_loc = loc, ds_orig = orig
1058                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs
1059                         , ds_cls = cls, ds_tys = inst_tys
1060                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1061                         , ds_theta =  mtheta `orElse` all_preds
1062                         , ds_newtype = True }
1063         ; return (if isJust mtheta then Right spec
1064                                    else Left spec) }
1065
1066   | otherwise
1067   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1068       CanDerive -> go_for_it    -- Use the standard H98 method
1069       DerivableClassError msg   -- Error with standard class
1070         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1071         | otherwise                  -> bale_out msg
1072       NonDerivableClass         -- Must use newtype deriving
1073         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1074         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1075         | otherwise                  -> bale_out non_std
1076   where
1077         newtype_deriving = xopt Opt_GeneralizedNewtypeDeriving dflags
1078         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1079         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1080
1081         non_std    = nonStdErr cls
1082         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1083
1084         -- Here is the plan for newtype derivings.  We see
1085         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1086         -- where t is a type,
1087         --       ak+1...an is a suffix of a1..an, and are all tyars
1088         --       ak+1...an do not occur free in t, nor in the s1..sm
1089         --       (C s1 ... sm) is a  *partial applications* of class C
1090         --                      with the last parameter missing
1091         --       (T a1 .. ak) matches the kind of C's last argument
1092         --              (and hence so does t)
1093         -- The latter kind-check has been done by deriveTyData already,
1094         -- and tc_args are already trimmed
1095         --
1096         -- We generate the instance
1097         --       instance forall ({a1..ak} u fvs(s1..sm)).
1098         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1099         -- where T a1...ap is the partial application of
1100         --       the LHS of the correct kind and p >= k
1101         --
1102         --      NB: the variables below are:
1103         --              tc_tvs = [a1, ..., an]
1104         --              tyvars_to_keep = [a1, ..., ak]
1105         --              rep_ty = t ak .. an
1106         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1107         --              tys = [s1, ..., sm]
1108         --              rep_fn' = t
1109         --
1110         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1111         -- We generate the instance
1112         --      instance Monad (ST s) => Monad (T s) where
1113
1114         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1115                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1116                 -- eta-reduces the representation type, so we know that
1117                 --      T a ~ S a a
1118                 -- That's convenient here, because we may have to apply
1119                 -- it to fewer than its original complement of arguments
1120
1121         -- Note [Newtype representation]
1122         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1123         -- Need newTyConRhs (*not* a recursive representation finder)
1124         -- to get the representation type. For example
1125         --      newtype B = MkB Int
1126         --      newtype A = MkA B deriving( Num )
1127         -- We want the Num instance of B, *not* the Num instance of Int,
1128         -- when making the Num instance of A!
1129         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1130         rep_tys     = cls_tys ++ [rep_inst_ty]
1131         rep_pred    = mkClassPred cls rep_tys
1132                 -- rep_pred is the representation dictionary, from where
1133                 -- we are gong to get all the methods for the newtype
1134                 -- dictionary
1135
1136
1137     -- Next we figure out what superclass dictionaries to use
1138     -- See Note [Newtype deriving superclasses] above
1139
1140         cls_tyvars = classTyVars cls
1141         dfun_tvs = tyVarsOfTypes inst_tys
1142         inst_ty = mkTyConApp tycon tc_args
1143         inst_tys = cls_tys ++ [inst_ty]
1144         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1145                               (classSCTheta cls)
1146
1147                 -- If there are no tyvars, there's no need
1148                 -- to abstract over the dictionaries we need
1149                 -- Example:     newtype T = MkT Int deriving( C )
1150                 -- We get the derived instance
1151                 --              instance C T
1152                 -- rather than
1153                 --              instance C Int => C T
1154         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1155
1156         -------------------------------------------------------------------
1157         --  Figuring out whether we can only do this newtype-deriving thing
1158
1159         can_derive_via_isomorphism
1160            =  not (non_iso_class cls)
1161            && arity_ok
1162            && eta_ok
1163            && ats_ok
1164 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1165
1166         arity_ok = length cls_tys + 1 == classArity cls
1167                 -- Well kinded; eg not: newtype T ... deriving( ST )
1168                 --                      because ST needs *2* type params
1169
1170         -- Check that eta reduction is OK
1171         eta_ok = nt_eta_arity <= length rep_tc_args
1172                 -- The newtype can be eta-reduced to match the number
1173                 --     of type argument actually supplied
1174                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1175                 --     Here the 'b' must be the same in the rep type (S [a] b)
1176                 --     And the [a] must not mention 'b'.  That's all handled
1177                 --     by nt_eta_rity.
1178
1179         ats_ok = null (classATs cls)
1180                -- No associated types for the class, because we don't
1181                -- currently generate type 'instance' decls; and cannot do
1182                -- so for 'data' instance decls
1183
1184         cant_derive_err
1185            = vcat [ ppUnless arity_ok arity_msg
1186                   , ppUnless eta_ok eta_msg
1187                   , ppUnless ats_ok ats_msg ]
1188         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1189         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1190         ats_msg   = ptext (sLit "the class has associated types")
1191 \end{code}
1192
1193 Note [Recursive newtypes]
1194 ~~~~~~~~~~~~~~~~~~~~~~~~~
1195 Newtype deriving works fine, even if the newtype is recursive.
1196 e.g.    newtype S1 = S1 [T1 ()]
1197         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1198 Remember, too, that type families are curretly (conservatively) given
1199 a recursive flag, so this also allows newtype deriving to work
1200 for type famillies.
1201
1202 We used to exclude recursive types, because we had a rather simple
1203 minded way of generating the instance decl:
1204    newtype A = MkA [A]
1205    instance Eq [A] => Eq A      -- Makes typechecker loop!
1206 But now we require a simple context, so it's ok.
1207
1208
1209 %************************************************************************
1210 %*                                                                      *
1211 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1212 %*                                                                      *
1213 %************************************************************************
1214
1215 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1216 terms, which is the final correct RHS for the corresponding original
1217 equation.
1218 \begin{itemize}
1219 \item
1220 Each (k,TyVarTy tv) in a solution constrains only a type
1221 variable, tv.
1222
1223 \item
1224 The (k,TyVarTy tv) pairs in a solution are canonically
1225 ordered by sorting on type varible, tv, (major key) and then class, k,
1226 (minor key)
1227 \end{itemize}
1228
1229 \begin{code}
1230 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1231
1232 inferInstanceContexts _ [] = return []
1233
1234 inferInstanceContexts oflag infer_specs
1235   = do  { traceTc "inferInstanceContexts" $ vcat (map pprDerivSpec infer_specs)
1236         ; iterate_deriv 1 initial_solutions }
1237   where
1238     ------------------------------------------------------------------
1239         -- The initial solutions for the equations claim that each
1240         -- instance has an empty context; this solution is certainly
1241         -- in canonical form.
1242     initial_solutions :: [ThetaType]
1243     initial_solutions = [ [] | _ <- infer_specs ]
1244
1245     ------------------------------------------------------------------
1246         -- iterate_deriv calculates the next batch of solutions,
1247         -- compares it with the current one; finishes if they are the
1248         -- same, otherwise recurses with the new solutions.
1249         -- It fails if any iteration fails
1250     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1251     iterate_deriv n current_solns
1252       | n > 20  -- Looks as if we are in an infinite loop
1253                 -- This can happen if we have -XUndecidableInstances
1254                 -- (See TcSimplify.tcSimplifyDeriv.)
1255       = pprPanic "solveDerivEqns: probable loop"
1256                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1257       | otherwise
1258       = do {      -- Extend the inst info from the explicit instance decls
1259                   -- with the current set of solutions, and simplify each RHS
1260              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1261                                            current_solns infer_specs
1262            ; new_solns <- checkNoErrs $
1263                           extendLocalInstEnv inst_specs $
1264                           mapM gen_soln infer_specs
1265
1266            ; if (current_solns == new_solns) then
1267                 return [ spec { ds_theta = soln }
1268                        | (spec, soln) <- zip infer_specs current_solns ]
1269              else
1270                 iterate_deriv (n+1) new_solns }
1271
1272     ------------------------------------------------------------------
1273     gen_soln :: DerivSpec  -> TcM [PredType]
1274     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars
1275                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1276       = setSrcSpan loc  $
1277         addErrCtxt (derivInstCtxt clas inst_tys) $
1278         do {      -- Check for a bizarre corner case, when the derived instance decl should
1279                   -- have form  instance C a b => D (T a) where ...
1280                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1281                   -- of problems; in particular, it's hard to compare solutions for
1282                   -- equality when finding the fixpoint.  Moreover, simplifyDeriv
1283                   -- has an assert failure because it finds a TyVar when it expects
1284                   -- only TcTyVars.  So I just rule it out for now.  I'm not
1285                   -- even sure how it can arise.
1286
1287            ; let tv_set = mkVarSet tyvars
1288                  weird_preds = [pred | pred <- deriv_rhs
1289                                      , not (tyVarsOfPred pred `subVarSet` tv_set)]
1290            ; mapM_ (addErrTc . badDerivedPred) weird_preds
1291
1292            ; theta <- simplifyDeriv orig tyvars deriv_rhs
1293                 -- checkValidInstance tyvars theta clas inst_tys
1294                 -- Not necessary; see Note [Exotic derived instance contexts]
1295                 --                in TcSimplify
1296
1297            ; traceTc "TcDeriv" (ppr deriv_rhs $$ ppr theta)
1298                 -- Claim: the result instance declaration is guaranteed valid
1299                 -- Hence no need to call:
1300                 --   checkValidInstance tyvars theta clas inst_tys
1301            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1302
1303 ------------------------------------------------------------------
1304 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1305 mkInstance overlap_flag theta
1306             (DS { ds_name = dfun_name
1307                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1308   = mkLocalInstance dfun overlap_flag
1309   where
1310     dfun = mkDictFunId dfun_name tyvars theta clas tys
1311
1312
1313 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1314 -- Add new locally-defined instances; don't bother to check
1315 -- for functional dependency errors -- that'll happen in TcInstDcls
1316 extendLocalInstEnv dfuns thing_inside
1317  = do { env <- getGblEnv
1318       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1319              env'      = env { tcg_inst_env = inst_env' }
1320       ; setGblEnv env' thing_inside }
1321 \end{code}
1322
1323
1324 %************************************************************************
1325 %*                                                                      *
1326 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1327 %*                                                                      *
1328 %************************************************************************
1329
1330 After all the trouble to figure out the required context for the
1331 derived instance declarations, all that's left is to chug along to
1332 produce them.  They will then be shoved into @tcInstDecls2@, which
1333 will do all its usual business.
1334
1335 There are lots of possibilities for code to generate.  Here are
1336 various general remarks.
1337
1338 PRINCIPLES:
1339 \begin{itemize}
1340 \item
1341 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1342 ``you-couldn't-do-better-by-hand'' efficient.
1343
1344 \item
1345 Deriving @Show@---also pretty common--- should also be reasonable good code.
1346
1347 \item
1348 Deriving for the other classes isn't that common or that big a deal.
1349 \end{itemize}
1350
1351 PRAGMATICS:
1352
1353 \begin{itemize}
1354 \item
1355 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1356
1357 \item
1358 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1359
1360 \item
1361 We {\em normally} generate code only for the non-defaulted methods;
1362 there are some exceptions for @Eq@ and (especially) @Ord@...
1363
1364 \item
1365 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1366 constructor's numeric (@Int#@) tag.  These are generated by
1367 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1368 these is around is given by @hasCon2TagFun@.
1369
1370 The examples under the different sections below will make this
1371 clearer.
1372
1373 \item
1374 Much less often (really just for deriving @Ix@), we use a
1375 @_tag2con_<tycon>@ function.  See the examples.
1376
1377 \item
1378 We use the renamer!!!  Reason: we're supposed to be
1379 producing @LHsBinds Name@ for the methods, but that means
1380 producing correctly-uniquified code on the fly.  This is entirely
1381 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1382 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1383 the renamer.  What a great hack!
1384 \end{itemize}
1385
1386 \begin{code}
1387 -- Generate the InstInfo for the required instance paired with the
1388 --   *representation* tycon for that instance,
1389 -- plus any auxiliary bindings required
1390 --
1391 -- Representation tycons differ from the tycon in the instance signature in
1392 -- case of instances for indexed families.
1393 --
1394 genInst :: Bool         -- True <=> standalone deriving
1395         -> OverlapFlag
1396         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1397 genInst standalone_deriv oflag spec
1398   | ds_newtype spec
1399   = return (InstInfo { iSpec  = mkInstance oflag (ds_theta spec) spec
1400                      , iBinds = NewTypeDerived co rep_tycon }, [])
1401
1402   | otherwise
1403   = do  { let loc  = getSrcSpan (ds_name spec)
1404               inst = mkInstance oflag (ds_theta spec) spec
1405               clas = ds_cls spec
1406
1407           -- In case of a family instance, we need to use the representation
1408           -- tycon (after all, it has the data constructors)
1409         ; fix_env <- getFixityEnv
1410         ; let (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1411               binds = VanillaInst meth_binds [] standalone_deriv
1412         ; return (InstInfo { iSpec = inst, iBinds = binds }, aux_binds)
1413         }
1414   where
1415     rep_tycon   = ds_tc spec
1416     rep_tc_args = ds_tc_args spec
1417     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1418               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1419               Nothing     -> id_co
1420               -- Not a family => rep_tycon = main tycon
1421     co2 = case newTyConCo_maybe rep_tycon of
1422               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1423               Nothing     -> id_co  -- The newtype is transparent; no need for a cast
1424     co = co1 `mkTransCoI` co2
1425     id_co = IdCo (mkTyConApp rep_tycon rep_tc_args)
1426
1427 -- Example: newtype instance N [a] = N1 (Tree a)
1428 --          deriving instance Eq b => Eq (N [(b,b)])
1429 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1430 -- When dealing with the deriving clause
1431 --    co1 : N [(b,b)] ~ R1:N (b,b)
1432 --    co2 : R1:N (b,b) ~ Tree (b,b)
1433 --    co  : N [(b,b)] ~ Tree (b,b)
1434
1435 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1436 genDerivBinds loc fix_env clas tycon
1437   | className clas `elem` typeableClassNames
1438   = (gen_Typeable_binds loc tycon, [])
1439
1440   | otherwise
1441   = case assocMaybe gen_list (getUnique clas) of
1442         Just gen_fn -> gen_fn loc tycon
1443         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1444   where
1445     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1446     gen_list = [(eqClassKey,       gen_Eq_binds)
1447                ,(ordClassKey,      gen_Ord_binds)
1448                ,(enumClassKey,     gen_Enum_binds)
1449                ,(boundedClassKey,  gen_Bounded_binds)
1450                ,(ixClassKey,       gen_Ix_binds)
1451                ,(showClassKey,     gen_Show_binds fix_env)
1452                ,(readClassKey,     gen_Read_binds fix_env)
1453                ,(dataClassKey,     gen_Data_binds)
1454                ,(functorClassKey,  gen_Functor_binds)
1455                ,(foldableClassKey, gen_Foldable_binds)
1456                ,(traversableClassKey, gen_Traversable_binds)
1457                ]
1458 \end{code}
1459
1460
1461 %************************************************************************
1462 %*                                                                      *
1463 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1464 %*                                                                      *
1465 %************************************************************************
1466
1467 \begin{code}
1468 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1469 derivingKindErr tc cls cls_tys cls_kind
1470   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1471                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1472        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1473             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1474
1475 derivingEtaErr :: Class -> [Type] -> Type -> Message
1476 derivingEtaErr cls cls_tys inst_ty
1477   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1478          nest 2 (ptext (sLit "instance (...) =>")
1479                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1480
1481 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1482 typeFamilyPapErr tc cls cls_tys inst_ty
1483   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1484        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc)
1485
1486 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1487 derivingThingErr newtype_deriving clas tys ty why
1488   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1489              2 (quotes (ppr pred))
1490           $$ nest 2 extra) <> colon,
1491          nest 2 why]
1492   where
1493     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1494           | otherwise        = empty
1495     pred = mkClassPred clas (tys ++ [ty])
1496
1497 derivingHiddenErr :: TyCon -> SDoc
1498 derivingHiddenErr tc
1499   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1500        2 (ptext (sLit "so you cannot derive an instance for it"))
1501
1502 standaloneCtxt :: LHsType Name -> SDoc
1503 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
1504                        2 (quotes (ppr ty))
1505
1506 derivInstCtxt :: Class -> [Type] -> Message
1507 derivInstCtxt clas inst_tys
1508   = ptext (sLit "When deriving the instance for") <+> parens (pprClassPred clas inst_tys)
1509
1510 badDerivedPred :: PredType -> Message
1511 badDerivedPred pred
1512   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1513           ptext (sLit "type variables that are not data type parameters"),
1514           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1515 \end{code}