compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import Coercion
  34 import ErrUtils
  35 import MkId
  36 import DataCon
  37 import Maybes
  38 import RdrName
  39 import Name
  40 import NameSet
  41 import TyCon
  42 import TcType
  43 import BuildTyCl
  44 import BasicTypes
  45 import Var
  46 import VarSet
  47 import PrelNames
  48 import SrcLoc
  49 import UniqSupply
  50 import Util
  51 import ListSetOps
  52 import Outputable
  53 import FastString
  54 import Bag
  55
  56 import Control.Monad
  57 \end{code}
  58
  59 %************************************************************************
  60 %*                                                                      *
  61                 Overview
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 Overall plan
  66 ~~~~~~~~~~~~
  67 1.  Convert the decls (i.e. data/newtype deriving clauses,
  68     plus standalone deriving) to [EarlyDerivSpec]
  69
  70 2.  Infer the missing contexts for the Left DerivSpecs
  71
  72 3.  Add the derived bindings, generating InstInfos
  73
  74
  75 \begin{code}
  76 -- DerivSpec is purely  local to this module
  77 data DerivSpec  = DS { ds_loc     :: SrcSpan
  78                      , ds_orig    :: CtOrigin
  79                      , ds_name    :: Name
  80                      , ds_tvs     :: [TyVar]
  81                      , ds_theta   :: ThetaType
  82                      , ds_cls     :: Class
  83                      , ds_tys     :: [Type]
  84                      , ds_tc      :: TyCon
  85                      , ds_tc_args :: [Type]
  86                      , ds_newtype :: Bool }
  87         -- This spec implies a dfun declaration of the form
  88         --       df :: forall tvs. theta => C tys
  89         -- The Name is the name for the DFun we'll build
  90         -- The tyvars bind all the variables in the theta
  91         -- For type families, the tycon in
  92         --       in ds_tys is the *family* tycon
  93         --       in ds_tc, ds_tc_args is the *representation* tycon
  94         -- For non-family tycons, both are the same
  95
  96         -- ds_newtype = True  <=> Newtype deriving
  97         --              False <=> Vanilla deriving
  98 \end{code}
  99
 100 Example:
 101
 102      newtype instance T [a] = MkT (Tree a) deriving( C s )
 103 ==>
 104      axiom T [a] = :RTList a
 105      axiom :RTList a = Tree a
 106
 107      DS { ds_tvs = [a,s], ds_cls = C, ds_tys = [s, T [a]]
 108         , ds_tc = :RTList, ds_tc_args = [a]
 109         , ds_newtype = True }
 110
 111 \begin{code}
 112 type DerivContext = Maybe ThetaType
 113    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
 114    -- Just theta <=> Standalone deriving: context supplied by programmer
 115
 116 type EarlyDerivSpec = Either DerivSpec DerivSpec
 117         -- Left  ds => the context for the instance should be inferred
 118         --             In this case ds_theta is the list of all the
 119         --                constraints needed, such as (Eq [a], Eq a)
 120         --                The inference process is to reduce this to a
 121         --                simpler form (e.g. Eq a)
 122         --
 123         -- Right ds => the exact context for the instance is supplied
 124         --             by the programmer; it is ds_theta
 125
 126 pprDerivSpec :: DerivSpec -> SDoc
 127 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
 128                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
 129   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
 130             <+> equals <+> ppr rhs)
 131
 132 instance Outputable DerivSpec where
 133   ppr = pprDerivSpec
 134 \end{code}
 135
 136
 137 Inferring missing contexts
 138 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 139 Consider
 140
 141         data T a b = C1 (Foo a) (Bar b)
 142                    | C2 Int (T b a)
 143                    | C3 (T a a)
 144                    deriving (Eq)
 145
 146 [NOTE: See end of these comments for what to do with
 147         data (C a, D b) => T a b = ...
 148 ]
 149
 150 We want to come up with an instance declaration of the form
 151
 152         instance (Ping a, Pong b, ...) => Eq (T a b) where
 153                 x == y = ...
 154
 155 It is pretty easy, albeit tedious, to fill in the code "...".  The
 156 trick is to figure out what the context for the instance decl is,
 157 namely @Ping@, @Pong@ and friends.
 158
 159 Let's call the context reqd for the T instance of class C at types
 160 (a,b, ...)  C (T a b).  Thus:
 161
 162         Eq (T a b) = (Ping a, Pong b, ...)
 163
 164 Now we can get a (recursive) equation from the @data@ decl:
 165
 166         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 167                    u Eq (T b a) u Eq Int        -- From C2
 168                    u Eq (T a a)                 -- From C3
 169
 170 Foo and Bar may have explicit instances for @Eq@, in which case we can
 171 just substitute for them.  Alternatively, either or both may have
 172 their @Eq@ instances given by @deriving@ clauses, in which case they
 173 form part of the system of equations.
 174
 175 Now all we need do is simplify and solve the equations, iterating to
 176 find the least fixpoint.  Notice that the order of the arguments can
 177 switch around, as here in the recursive calls to T.
 178
 179 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 180
 181 We start with:
 182
 183         Eq (T a b) = {}         -- The empty set
 184
 185 Next iteration:
 186         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 187                    u Eq (T b a) u Eq Int        -- From C2
 188                    u Eq (T a a)                 -- From C3
 189
 190         After simplification:
 191                    = Eq a u Ping b u {} u {} u {}
 192                    = Eq a u Ping b
 193
 194 Next iteration:
 195
 196         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 197                    u Eq (T b a) u Eq Int        -- From C2
 198                    u Eq (T a a)                 -- From C3
 199
 200         After simplification:
 201                    = Eq a u Ping b
 202                    u (Eq b u Ping a)
 203                    u (Eq a u Ping a)
 204
 205                    = Eq a u Ping b u Eq b u Ping a
 206
 207 The next iteration gives the same result, so this is the fixpoint.  We
 208 need to make a canonical form of the RHS to ensure convergence.  We do
 209 this by simplifying the RHS to a form in which
 210
 211         - the classes constrain only tyvars
 212         - the list is sorted by tyvar (major key) and then class (minor key)
 213         - no duplicates, of course
 214
 215 So, here are the synonyms for the ``equation'' structures:
 216
 217
 218 Note [Data decl contexts]
 219 ~~~~~~~~~~~~~~~~~~~~~~~~~
 220 Consider
 221
 222         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 223
 224 We will need an instance decl like:
 225
 226         instance (Read a, RealFloat a) => Read (Complex a) where
 227           ...
 228
 229 The RealFloat in the context is because the read method for Complex is bound
 230 to construct a Complex, and doing that requires that the argument type is
 231 in RealFloat.
 232
 233 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 234 a Complex; they only take them apart.
 235
 236 Our approach: identify the offending classes, and add the data type
 237 context to the instance decl.  The "offending classes" are
 238
 239         Read, Enum?
 240
 241 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 242 pattern matching against a constructor from a data type with a context
 243 gives rise to the constraints for that context -- or at least the thinned
 244 version.  So now all classes are "offending".
 245
 246 Note [Newtype deriving]
 247 ~~~~~~~~~~~~~~~~~~~~~~~
 248 Consider this:
 249     class C a b
 250     instance C [a] Char
 251     newtype T = T Char deriving( C [a] )
 252
 253 Notice the free 'a' in the deriving.  We have to fill this out to
 254     newtype T = T Char deriving( forall a. C [a] )
 255
 256 And then translate it to:
 257     instance C [a] Char => C [a] T where ...
 258
 259
 260 Note [Newtype deriving superclasses]
 261 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 262 (See also Trac #1220 for an interesting exchange on newtype
 263 deriving and superclasses.)
 264
 265 The 'tys' here come from the partial application in the deriving
 266 clause. The last arg is the new instance type.
 267
 268 We must pass the superclasses; the newtype might be an instance
 269 of them in a different way than the representation type
 270 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 271 Then the Show instance is not done via isomorphism; it shows
 272         Foo 3 as "Foo 3"
 273 The Num instance is derived via isomorphism, but the Show superclass
 274 dictionary must the Show instance for Foo, *not* the Show dictionary
 275 gotten from the Num dictionary. So we must build a whole new dictionary
 276 not just use the Num one.  The instance we want is something like:
 277      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 278         (+) = ((+)@a)
 279         ...etc...
 280 There may be a coercion needed which we get from the tycon for the newtype
 281 when the dict is constructed in TcInstDcls.tcInstDecl2
 282
 283
 284 Note [Unused constructors and deriving clauses]
 285 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 286 See Trac #3221.  Consider
 287    data T = T1 | T2 deriving( Show )
 288 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
 289 both of them.  So we gather defs/uses from deriving just like anything else.
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 \begin{code}
 298 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
 299             -> [LInstDecl Name]  -- All instance declarations
 300             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 301             -> TcM ([InstInfo Name] -- The generated "instance decls"
 302                    ,HsValBinds Name -- Extra generated top-level bindings
 303                    ,DefUses
 304                    ,[TyCon]         -- Extra generated top-level types
 305                    ,[TyCon])        -- Extra generated type family instances
 306
 307 tcDeriving tycl_decls inst_decls deriv_decls
 308   = recoverM (return ([], emptyValBindsOut, emptyDUs, [], [])) $
 309     do  {       -- Fish the "deriving"-related information out of the TcEnv
 310                 -- And make the necessary "equations".
 311           is_boot <- tcIsHsBoot
 312         ; traceTc "tcDeriving" (ppr is_boot)
 313         ; (early_specs, genericsExtras)
 314                 <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 315         ; let (repMetaTys, repTyCons, metaInsts) = unzip3 genericsExtras
 316
 317         ; overlap_flag <- getOverlapFlag
 318         ; let (infer_specs, given_specs) = splitEithers early_specs
 319         ; insts1 <- mapM (genInst True overlap_flag) given_specs
 320
 321         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
 322                          inferInstanceContexts overlap_flag infer_specs
 323
 324         ; insts2 <- mapM (genInst False overlap_flag) final_specs
 325
 326         -- We no longer generate the old generic to/from functions
 327         -- from each type declaration, so this is emptyBag
 328         ; gen_binds <- return emptyBag -- mkGenericBinds is_boot tycl_decls
 329
 330         ; (inst_info, rn_binds, rn_dus)
 331                 <- renameDeriv is_boot gen_binds (insts1 ++ insts2 ++ concat metaInsts)
 332
 333         ; dflags <- getDOpts
 334         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 335                  (ddump_deriving inst_info rn_binds))
 336 {-
 337         ; when (not (null inst_info)) $
 338           dumpDerivingInfo (ddump_deriving inst_info rn_binds)
 339 -}
 340         ; return ( inst_info, rn_binds, rn_dus
 341                  , concat (map metaTyCons2TyCons repMetaTys), repTyCons) }
 342   where
 343     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
 344     ddump_deriving inst_infos extra_binds
 345       = hang (ptext (sLit "Derived instances"))
 346            2 (vcat (map (\i -> pprInstInfoDetails i $$ text "") inst_infos)
 347               $$ ppr extra_binds)
 348
 349
 350 renameDeriv :: Bool -> LHsBinds RdrName
 351             -> [(InstInfo RdrName, DerivAuxBinds)]
 352             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
 353 renameDeriv is_boot gen_binds insts
 354   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
 355                 -- The inst-info bindings will all be empty, but it's easier to
 356                 -- just use rn_inst_info to change the type appropriately
 357   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
 358         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
 359
 360   | otherwise
 361   = discardWarnings $    -- Discard warnings about unused bindings etc
 362     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns
 363                                                                   -- are used in the generic binds
 364                                rnTopBinds (ValBindsIn gen_binds [])
 365         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
 366
 367                 -- Generate and rename any extra not-one-inst-decl-specific binds,
 368                 -- notably "con2tag" and/or "tag2con" functions.
 369                 -- Bring those names into scope before renaming the instances themselves
 370         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
 371         ; let (aux_binds, aux_sigs) = unzip $ map (genAuxBind loc) $
 372                                       rm_dups [] $ concat deriv_aux_binds
 373               aux_val_binds = ValBindsIn (listToBag aux_binds) aux_sigs
 374         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv aux_val_binds
 375         ; bindLocalNames (collectHsValBinders rn_aux_lhs) $
 376     do  { (rn_aux, dus_aux) <- rnTopBindsRHS rn_aux_lhs
 377         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
 378         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
 379                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
 380
 381   where
 382     (inst_infos, deriv_aux_binds) = unzip insts
 383
 384         -- Remove duplicate requests for auxilliary bindings
 385     rm_dups acc [] = acc
 386     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
 387                        | otherwise            = rm_dups (b:acc) bs
 388
 389
 390     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
 391     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
 392         = return ( info { iBinds = NewTypeDerived coi tc }
 393                  , mkFVs (map dataConName (tyConDataCons tc)))
 394           -- See Note [Newtype deriving and unused constructors]
 395
 396     rn_inst_info inst_info@(InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
 397         =       -- Bring the right type variables into
 398                 -- scope (yuk), and rename the method binds
 399            ASSERT( null sigs )
 400            bindLocalNames (map Var.varName tyvars) $
 401            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) binds
 402               ; let binds' = VanillaInst rn_binds [] standalone_deriv
 403               ; return (inst_info { iBinds = binds' }, fvs) }
 404         where
 405           (tyvars,_, clas,_) = instanceHead inst
 406           clas_nm            = className clas
 407 \end{code}
 408
 409 Note [Newtype deriving and unused constructors]
 410 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 411 Consider this (see Trac #1954):
 412
 413   module Bug(P) where
 414   newtype P a = MkP (IO a) deriving Monad
 415
 416 If you compile with -fwarn-unused-binds you do not expect the warning
 417 "Defined but not used: data consructor MkP". Yet the newtype deriving
 418 code does not explicitly mention MkP, but it should behave as if you
 419 had written
 420   instance Monad P where
 421      return x = MkP (return x)
 422      ...etc...
 423
 424 So we want to signal a user of the data constructor 'MkP'.  That's
 425 what we do in rn_inst_info, and it's the only reason we have the TyCon
 426 stored in NewTypeDerived.
 427
 428
 429 %************************************************************************
 430 %*                                                                      *
 431                 From HsSyn to DerivSpec
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
 436
 437 \begin{code}
 438 -- Make the "extras" for the generic representation
 439 mkGenDerivExtras :: TyCon
 440                  -> TcRn (MetaTyCons, TyCon, [(InstInfo RdrName, DerivAuxBinds)])
 441 mkGenDerivExtras tc = do
 442         { (metaTyCons, rep0TyInst) <- genGenericRepExtras tc
 443         ; metaInsts                <- genDtMeta (tc, metaTyCons)
 444         ; return (metaTyCons, rep0TyInst, metaInsts) }
 445
 446 makeDerivSpecs :: Bool
 447                -> [LTyClDecl Name]
 448                -> [LInstDecl Name]
 449                -> [LDerivDecl Name]
 450                -> TcM ( [EarlyDerivSpec]
 451                       , [(MetaTyCons, TyCon, [(InstInfo RdrName, DerivAuxBinds)])])
 452 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 453   | is_boot     -- No 'deriving' at all in hs-boot files
 454   = do  { mapM_ add_deriv_err deriv_locs
 455         ; return ([],[]) }
 456   | otherwise
 457   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
 458         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
 459
 460         -- Generic representation stuff: we might need to add some "extras"
 461         -- to the instances
 462         ; xDerRep <- getDOpts >>= return . xopt Opt_DeriveGeneric
 463         ; generic_extras_deriv <- if not xDerRep
 464                                    -- No extras if the flag is off
 465                                    then (return [])
 466                                     else do {
 467           let allTyNames = [ tcdName d | L _ d <- tycl_decls, isDataDecl d ]
 468         -- Select only those types that derive Generic
 469         ; let sel_tydata = [ tcdName t | (L _ c, L _ t) <- all_tydata
 470                                        , getClassName c == Just genClassName ]
 471         ; let sel_deriv_decls = catMaybes [ getTypeName t
 472                                   | L _ (DerivDecl (L _ t)) <- deriv_decls
 473                                   , getClassName t == Just genClassName ]
 474         ; derTyDecls <- mapM tcLookupTyCon $
 475                          filter (needsExtras xDerRep
 476                                   (sel_tydata ++ sel_deriv_decls)) allTyNames
 477         -- We need to generate the extras to add to what has
 478         -- already been derived
 479         ; mapM mkGenDerivExtras derTyDecls }
 480
 481         -- Merge and return
 482         ; return ( eqns1 ++ eqns2, generic_extras_deriv) }
 483   where
 484       -- We need extras if the flag DeriveGeneric is on and this type is
 485       -- deriving Generic
 486     needsExtras xDerRep tydata tc_name = xDerRep && tc_name `elem` tydata
 487
 488     -- Extracts the name of the class in the deriving
 489     getClassName :: HsType Name -> Maybe Name
 490     getClassName (HsPredTy (HsClassP n _)) = Just n
 491     getClassName _                         = Nothing
 492
 493     -- Extracts the name of the type in the deriving
 494     getTypeName :: HsType Name -> Maybe Name
 495     getTypeName (HsTyVar n)                     = Just n
 496     getTypeName (HsOpTy _ (L _ n) _)            = Just n
 497     getTypeName (HsPredTy (HsClassP _ [L _ n])) = getTypeName n
 498     getTypeName _                               = Nothing
 499
 500     extractTyDataPreds decls
 501       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
 502
 503     all_tydata :: [(LHsType Name, LTyClDecl Name)]
 504         -- Derived predicate paired with its data type declaration
 505     all_tydata = extractTyDataPreds (instDeclATs inst_decls ++ tycl_decls)
 506
 507     deriv_locs = map (getLoc . snd) all_tydata
 508                  ++ map getLoc deriv_decls
 509
 510     add_deriv_err loc = setSrcSpan loc $
 511                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
 512                                    2 (ptext (sLit "Use an instance declaration instead")))
 513
 514 ------------------------------------------------------------------
 515 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
 516 -- Standalone deriving declarations
 517 --  e.g.   deriving instance Show a => Show (T a)
 518 -- Rather like tcLocalInstDecl
 519 deriveStandalone (L loc (DerivDecl deriv_ty))
 520   = setSrcSpan loc                   $
 521     addErrCtxt (standaloneCtxt deriv_ty)  $
 522     do { traceTc "Standalone deriving decl for" (ppr deriv_ty)
 523        ; (tvs, theta, cls, inst_tys) <- tcHsInstHead deriv_ty
 524        ; traceTc "Standalone deriving;" $ vcat
 525               [ text "tvs:" <+> ppr tvs
 526               , text "theta:" <+> ppr theta
 527               , text "cls:" <+> ppr cls
 528               , text "tys:" <+> ppr inst_tys ]
 529        ; checkValidInstance deriv_ty tvs theta cls inst_tys
 530                 -- C.f. TcInstDcls.tcLocalInstDecl1
 531
 532        ; let cls_tys = take (length inst_tys - 1) inst_tys
 533              inst_ty = last inst_tys
 534        ; traceTc "Standalone deriving:" $ vcat
 535               [ text "class:" <+> ppr cls
 536               , text "class types:" <+> ppr cls_tys
 537               , text "type:" <+> ppr inst_ty ]
 538        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
 539                    (Just theta) }
 540
 541 ------------------------------------------------------------------
 542 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
 543 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name,
 544                                                    tcdTyVars = tv_names,
 545                                                    tcdTyPats = ty_pats }))
 546   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
 547     tcAddDeclCtxt decl $
 548     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
 549         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 550                                         -- the type variables for the type constructor
 551
 552     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 553                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 554                 -- newtype deriving we allow deriving (forall a. C [a]).
 555
 556         -- Given data T a b c = ... deriving( C d ),
 557         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
 558         ; let cls_tyvars = classTyVars cls
 559               kind = tyVarKind (last cls_tyvars)
 560               (arg_kinds, _) = splitKindFunTys kind
 561               n_args_to_drop = length arg_kinds
 562               n_args_to_keep = tyConArity tc - n_args_to_drop
 563               args_to_drop   = drop n_args_to_keep tc_args
 564               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
 565               inst_ty_kind   = typeKind inst_ty
 566               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
 567               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
 568                                         `minusVarSet` dropped_tvs
 569
 570         -- Check that the result really is well-kinded
 571         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
 572                   (derivingKindErr tc cls cls_tys kind)
 573
 574         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
 575                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
 576                   (derivingEtaErr cls cls_tys inst_ty)
 577                 -- Check that
 578                 --  (a) The data type can be eta-reduced; eg reject:
 579                 --              data instance T a a = ... deriving( Monad )
 580                 --  (b) The type class args do not mention any of the dropped type
 581                 --      variables
 582                 --              newtype T a s = ... deriving( ST s )
 583
 584         -- Type families can't be partially applied
 585         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
 586         -- Note [Deriving, type families, and partial applications]
 587         ; checkTc (not (isFamilyTyCon tc) || n_args_to_drop == 0)
 588                   (typeFamilyPapErr tc cls cls_tys inst_ty)
 589
 590         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
 591   where
 592         -- Tiresomely we must figure out the "lhs", which is awkward for type families
 593         -- E.g.   data T a b = .. deriving( Eq )
 594         --          Here, the lhs is (T a b)
 595         --        data instance TF Int b = ... deriving( Eq )
 596         --          Here, the lhs is (TF Int b)
 597         -- But if we just look up the tycon_name, we get is the *family*
 598         -- tycon, but not pattern types -- they are in the *rep* tycon.
 599     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
 600                              ; let tvs = tyConTyVars tc
 601                              ; return (tvs, tc, mkTyVarTys tvs) }
 602     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
 603                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 604                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
 605                              ; return (tvs, tc, tc_args) }
 606
 607 deriveTyData _other
 608   = panic "derivTyData" -- Caller ensures that only TyData can happen
 609 \end{code}
 610
 611 Note [Deriving, type families, and partial applications]
 612 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 613 When there are no type families, it's quite easy:
 614
 615     newtype S a = MkS [a]
 616     -- :CoS :: S  ~ []  -- Eta-reduced
 617
 618     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
 619     instance Monad [] => Monad S        -- by coercion sym (Monad :CoS)  : Monad [] ~ Monad S
 620
 621 When type familes are involved it's trickier:
 622
 623     data family T a b
 624     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
 625     -- :RT is the representation type for (T Int a)
 626     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
 627     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
 628
 629     instance Eq [a] => Eq (T Int a)     -- easy by coercion
 630     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 631
 632 The "???" bit is that we don't build the :CoF thing in eta-reduced form
 633 Henc the current typeFamilyPapErr, even though the instance makes sense.
 634 After all, we can write it out
 635     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 636       return x = MkT [x]
 637       ... etc ...
 638
 639 \begin{code}
 640 mkEqnHelp :: CtOrigin -> [TyVar] -> Class -> [Type] -> Type
 641           -> DerivContext       -- Just    => context supplied (standalone deriving)
 642                                 -- Nothing => context inferred (deriving on data decl)
 643           -> TcRn EarlyDerivSpec
 644 -- Make the EarlyDerivSpec for an instance
 645 --      forall tvs. theta => cls (tys ++ [ty])
 646 -- where the 'theta' is optional (that's the Maybe part)
 647 -- Assumes that this declaration is well-kinded
 648
 649 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
 650   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 651   , isAlgTyCon tycon    -- Check for functions, primitive types etc
 652   = mk_alg_eqn tycon tc_args
 653   | otherwise
 654   = failWithTc (derivingThingErr False cls cls_tys tc_app
 655                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
 656
 657   where
 658      bale_out msg = failWithTc (derivingThingErr False cls cls_tys tc_app msg)
 659
 660      mk_alg_eqn tycon tc_args
 661       | className cls `elem` typeableClassNames
 662       = do { dflags <- getDOpts
 663            ; case checkTypeableConditions (dflags, tycon) of
 664                Just err -> bale_out err
 665                Nothing  -> mk_typeable_eqn orig tvs cls tycon tc_args mtheta }
 666
 667       | isDataFamilyTyCon tycon
 668       , length tc_args /= tyConArity tycon
 669       = bale_out (ptext (sLit "Unsaturated data family application"))
 670
 671       | otherwise
 672       = do { (rep_tc, rep_tc_args) <- tcLookupDataFamInst tycon tc_args
 673                   -- Be careful to test rep_tc here: in the case of families,
 674                   -- we want to check the instance tycon, not the family tycon
 675
 676            -- For standalone deriving (mtheta /= Nothing),
 677            -- check that all the data constructors are in scope.
 678            ; rdr_env <- getGlobalRdrEnv
 679            ; let hidden_data_cons = isAbstractTyCon rep_tc ||
 680                                     any not_in_scope (tyConDataCons rep_tc)
 681                  not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
 682            ; unless (isNothing mtheta || not hidden_data_cons)
 683                     (bale_out (derivingHiddenErr tycon))
 684
 685            ; dflags <- getDOpts
 686            ; if isDataTyCon rep_tc then
 687                 mkDataTypeEqn orig dflags tvs cls cls_tys
 688                               tycon tc_args rep_tc rep_tc_args mtheta
 689              else
 690                 mkNewTypeEqn orig dflags tvs cls cls_tys
 691                              tycon tc_args rep_tc rep_tc_args mtheta }
 692 \end{code}
 693
 694
 695 %************************************************************************
 696 %*                                                                      *
 697                 Deriving data types
 698 %*                                                                      *
 699 %************************************************************************
 700
 701 \begin{code}
 702 mkDataTypeEqn :: CtOrigin
 703               -> DynFlags
 704               -> [Var]                  -- Universally quantified type variables in the instance
 705               -> Class                  -- Class for which we need to derive an instance
 706               -> [Type]                 -- Other parameters to the class except the last
 707               -> TyCon                  -- Type constructor for which the instance is requested
 708                                         --    (last parameter to the type class)
 709               -> [Type]                 -- Parameters to the type constructor
 710               -> TyCon                  -- rep of the above (for type families)
 711               -> [Type]                 -- rep of the above
 712               -> DerivContext        -- Context of the instance, for standalone deriving
 713               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
 714
 715 mkDataTypeEqn orig dflags tvs cls cls_tys
 716               tycon tc_args rep_tc rep_tc_args mtheta
 717   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
 718         -- NB: pass the *representation* tycon to checkSideConditions
 719         CanDerive               -> go_for_it
 720         NonDerivableClass       -> bale_out (nonStdErr cls)
 721         DerivableClassError msg -> bale_out msg
 722   where
 723     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 724     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
 725
 726 mk_data_eqn :: CtOrigin -> [TyVar] -> Class
 727             -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
 728             -> TcM EarlyDerivSpec
 729 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 730   = do  { dfun_name <- new_dfun_name cls tycon
 731         ; loc <- getSrcSpanM
 732         ; let inst_tys = [mkTyConApp tycon tc_args]
 733               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
 734               spec = DS { ds_loc = loc, ds_orig = orig
 735                         , ds_name = dfun_name, ds_tvs = tvs
 736                         , ds_cls = cls, ds_tys = inst_tys
 737                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 738                         , ds_theta =  mtheta `orElse` inferred_constraints
 739                         , ds_newtype = False }
 740
 741         ; return (if isJust mtheta then Right spec      -- Specified context
 742                                    else Left spec) }    -- Infer context
 743
 744 ----------------------
 745 mk_typeable_eqn :: CtOrigin -> [TyVar] -> Class
 746                 -> TyCon -> [TcType] -> DerivContext
 747                 -> TcM EarlyDerivSpec
 748 mk_typeable_eqn orig tvs cls tycon tc_args mtheta
 749         -- The Typeable class is special in several ways
 750         --        data T a b = ... deriving( Typeable )
 751         -- gives
 752         --        instance Typeable2 T where ...
 753         -- Notice that:
 754         -- 1. There are no constraints in the instance
 755         -- 2. There are no type variables either
 756         -- 3. The actual class we want to generate isn't necessarily
 757         --      Typeable; it depends on the arity of the type
 758   | isNothing mtheta    -- deriving on a data type decl
 759   = do  { checkTc (cls `hasKey` typeableClassKey)
 760                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
 761         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 762         ; mk_typeable_eqn orig tvs real_cls tycon [] (Just []) }
 763
 764   | otherwise           -- standaone deriving
 765   = do  { checkTc (null tc_args)
 766                   (ptext (sLit "Derived typeable instance must be of form (Typeable")
 767                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
 768         ; dfun_name <- new_dfun_name cls tycon
 769         ; loc <- getSrcSpanM
 770         ; return (Right $
 771                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
 772                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
 773                      , ds_tc = tycon, ds_tc_args = []
 774                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
 775
 776 ----------------------
 777 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
 778 -- Generate a sufficiently large set of constraints that typechecking the
 779 -- generated method definitions should succeed.   This set will be simplified
 780 -- before being used in the instance declaration
 781 inferConstraints _ cls inst_tys rep_tc rep_tc_args
 782   -- Generic constraints are easy
 783   | cls `hasKey` genClassKey
 784   = []
 785   -- The others are a bit more complicated
 786   | otherwise
 787   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
 788     stupid_constraints ++ extra_constraints
 789     ++ sc_constraints ++ con_arg_constraints
 790   where
 791        -- Constraints arising from the arguments of each constructor
 792     con_arg_constraints
 793       = [ mkClassPred cls [arg_ty]
 794         | data_con <- tyConDataCons rep_tc,
 795           arg_ty   <- ASSERT( isVanillaDataCon data_con )
 796                         get_constrained_tys $
 797                         dataConInstOrigArgTys data_con all_rep_tc_args,
 798           not (isUnLiftedType arg_ty) ]
 799                 -- No constraints for unlifted types
 800                 -- Where they are legal we generate specilised function calls
 801
 802                 -- For functor-like classes, two things are different
 803                 -- (a) We recurse over argument types to generate constraints
 804                 --     See Functor examples in TcGenDeriv
 805                 -- (b) The rep_tc_args will be one short
 806     is_functor_like = getUnique cls `elem` functorLikeClassKeys
 807
 808     get_constrained_tys :: [Type] -> [Type]
 809     get_constrained_tys tys
 810         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
 811         | otherwise       = tys
 812
 813     rep_tc_tvs = tyConTyVars rep_tc
 814     last_tv = last rep_tc_tvs
 815     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
 816                     | otherwise       = rep_tc_args
 817
 818         -- Constraints arising from superclasses
 819         -- See Note [Superclasses of derived instance]
 820     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
 821                                 (classSCTheta cls)
 822
 823         -- Stupid constraints
 824     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
 825     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
 826
 827         -- Extra Data constraints
 828         -- The Data class (only) requires that for
 829         --    instance (...) => Data (T t1 t2)
 830         -- IF   t1:*, t2:*
 831         -- THEN (Data t1, Data t2) are among the (...) constraints
 832         -- Reason: when the IF holds, we generate a method
 833         --             dataCast2 f = gcast2 f
 834         --         and we need the Data constraints to typecheck the method
 835     extra_constraints
 836       | cls `hasKey` dataClassKey
 837       , all (isLiftedTypeKind . typeKind) rep_tc_args
 838       = [mkClassPred cls [ty] | ty <- rep_tc_args]
 839       | otherwise
 840       = []
 841
 842 ------------------------------------------------------------------
 843 -- Check side conditions that dis-allow derivability for particular classes
 844 -- This is *apart* from the newtype-deriving mechanism
 845 --
 846 -- Here we get the representation tycon in case of family instances as it has
 847 -- the data constructors - but we need to be careful to fall back to the
 848 -- family tycon (with indexes) in error messages.
 849
 850 data DerivStatus = CanDerive
 851                  | DerivableClassError SDoc     -- Standard class, but can't do it
 852                  | NonDerivableClass            -- Non-standard class
 853
 854 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
 855 checkSideConditions dflags mtheta cls cls_tys rep_tc
 856   | Just cond <- sideConditions mtheta cls
 857   = case (cond (dflags, rep_tc)) of
 858         Just err -> DerivableClassError err     -- Class-specific error
 859         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
 860                                                 -- cls_tys (the type args other than last)
 861                                                 -- should be null
 862                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
 863   | otherwise = NonDerivableClass       -- Not a standard class
 864   where
 865     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
 866
 867 checkTypeableConditions :: Condition
 868 checkTypeableConditions = checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK
 869
 870 nonStdErr :: Class -> SDoc
 871 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
 872
 873 sideConditions :: DerivContext -> Class -> Maybe Condition
 874 sideConditions mtheta cls
 875   | cls_key == eqClassKey          = Just cond_std
 876   | cls_key == ordClassKey         = Just cond_std
 877   | cls_key == showClassKey        = Just cond_std
 878   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
 879   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
 880   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
 881   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
 882   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond`
 883                                            cond_std `andCond` cond_noUnliftedArgs)
 884   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
 885                                            cond_functorOK True)  -- NB: no cond_std!
 886   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
 887                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
 888   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
 889                                            cond_functorOK False)
 890   | cls_key == genClassKey         = Just (cond_RepresentableOk `andCond`
 891                                            checkFlag Opt_DeriveGeneric)
 892   | otherwise = Nothing
 893   where
 894     cls_key = getUnique cls
 895     cond_std = cond_stdOK mtheta
 896
 897 type Condition = (DynFlags, TyCon) -> Maybe SDoc
 898         -- first Bool is whether or not we are allowed to derive Data and Typeable
 899         -- second Bool is whether or not we are allowed to derive Functor
 900         -- TyCon is the *representation* tycon if the
 901         --      data type is an indexed one
 902         -- Nothing => OK
 903
 904 orCond :: Condition -> Condition -> Condition
 905 orCond c1 c2 tc
 906   = case c1 tc of
 907         Nothing -> Nothing          -- c1 succeeds
 908         Just x  -> case c2 tc of    -- c1 fails
 909                      Nothing -> Nothing
 910                      Just y  -> Just (x $$ ptext (sLit "  or") $$ y)
 911                                     -- Both fail
 912
 913 andCond :: Condition -> Condition -> Condition
 914 andCond c1 c2 tc = case c1 tc of
 915                      Nothing -> c2 tc   -- c1 succeeds
 916                      Just x  -> Just x  -- c1 fails
 917
 918 cond_stdOK :: DerivContext -> Condition
 919 cond_stdOK (Just _) _
 920   = Nothing     -- Don't check these conservative conditions for
 921                 -- standalone deriving; just generate the code
 922                 -- and let the typechecker handle the result
 923 cond_stdOK Nothing (_, rep_tc)
 924   | null data_cons      = Just (no_cons_why rep_tc $$ suggestion)
 925   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
 926   | otherwise           = Nothing
 927   where
 928     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
 929     data_cons   = tyConDataCons rep_tc
 930     con_whys = mapCatMaybes check_con data_cons
 931
 932     check_con :: DataCon -> Maybe SDoc
 933     check_con con
 934       | isVanillaDataCon con
 935       , all isTauTy (dataConOrigArgTys con) = Nothing
 936       | otherwise = Just (badCon con (ptext (sLit "must have a Haskell-98 type")))
 937
 938 no_cons_why :: TyCon -> SDoc
 939 no_cons_why rep_tc = quotes (pprSourceTyCon rep_tc) <+>
 940                      ptext (sLit "must have at least one data constructor")
 941
 942 cond_RepresentableOk :: Condition
 943 cond_RepresentableOk (_,t) = canDoGenerics t
 944
 945 cond_enumOrProduct :: Condition
 946 cond_enumOrProduct = cond_isEnumeration `orCond`
 947                        (cond_isProduct `andCond` cond_noUnliftedArgs)
 948
 949 cond_noUnliftedArgs :: Condition
 950 -- For some classes (eg Eq, Ord) we allow unlifted arg types
 951 -- by generating specilaised code.  For others (eg Data) we don't.
 952 cond_noUnliftedArgs (_, tc)
 953   | null bad_cons = Nothing
 954   | otherwise     = Just why
 955   where
 956     bad_cons = [ con | con <- tyConDataCons tc
 957                      , any isUnLiftedType (dataConOrigArgTys con) ]
 958     why = badCon (head bad_cons) (ptext (sLit "must have only arguments of lifted type"))
 959
 960 cond_isEnumeration :: Condition
 961 cond_isEnumeration (_, rep_tc)
 962   | isEnumerationTyCon rep_tc   = Nothing
 963   | otherwise                   = Just why
 964   where
 965     why = sep [ quotes (pprSourceTyCon rep_tc) <+>
 966                   ptext (sLit "must be an enumeration type")
 967               , ptext (sLit "(an enumeration consists of one or more nullary, non-GADT constructors)") ]
 968                   -- See Note [Enumeration types] in TyCon
 969
 970 cond_isProduct :: Condition
 971 cond_isProduct (_, rep_tc)
 972   | isProductTyCon rep_tc = Nothing
 973   | otherwise             = Just why
 974   where
 975     why = quotes (pprSourceTyCon rep_tc) <+>
 976           ptext (sLit "must have precisely one constructor")
 977
 978 cond_typeableOK :: Condition
 979 -- OK for Typeable class
 980 -- Currently: (a) args all of kind *
 981 --            (b) 7 or fewer args
 982 cond_typeableOK (_, tc)
 983   | tyConArity tc > 7 = Just too_many
 984   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars tc))
 985                       = Just bad_kind
 986   | otherwise         = Nothing
 987   where
 988     too_many = quotes (pprSourceTyCon tc) <+>
 989                ptext (sLit "must have 7 or fewer arguments")
 990     bad_kind = quotes (pprSourceTyCon tc) <+>
 991                ptext (sLit "must only have arguments of kind `*'")
 992
 993 functorLikeClassKeys :: [Unique]
 994 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
 995
 996 cond_functorOK :: Bool -> Condition
 997 -- OK for Functor/Foldable/Traversable class
 998 -- Currently: (a) at least one argument
 999 --            (b) don't use argument contravariantly
1000 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
1001 --            (d) optionally: don't use function types
1002 --            (e) no "stupid context" on data type
1003 cond_functorOK allowFunctions (_, rep_tc)
1004   | null tc_tvs
1005   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1006           <+> ptext (sLit "must have some type parameters"))
1007
1008   | not (null bad_stupid_theta)
1009   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1010           <+> ptext (sLit "must not have a class context") <+> pprTheta bad_stupid_theta)
1011
1012   | otherwise
1013   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
1014   where
1015     tc_tvs            = tyConTyVars rep_tc
1016     Just (_, last_tv) = snocView tc_tvs
1017     bad_stupid_theta  = filter is_bad (tyConStupidTheta rep_tc)
1018     is_bad pred       = last_tv `elemVarSet` tyVarsOfPred pred
1019
1020     data_cons = tyConDataCons rep_tc
1021     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
1022
1023     check_vanilla :: DataCon -> Maybe SDoc
1024     check_vanilla con | isVanillaDataCon con = Nothing
1025                       | otherwise            = Just (badCon con existential)
1026
1027     ft_check :: DataCon -> FFoldType (Maybe SDoc)
1028     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
1029                       , ft_co_var = Just (badCon con covariant)
1030                       , ft_fun = \x y -> if allowFunctions then x `mplus` y
1031                                                            else Just (badCon con functions)
1032                       , ft_tup = \_ xs  -> msum xs
1033                       , ft_ty_app = \_ x   -> x
1034                       , ft_bad_app = Just (badCon con wrong_arg)
1035                       , ft_forall = \_ x   -> x }
1036
1037     existential = ptext (sLit "must not have existential arguments")
1038     covariant   = ptext (sLit "must not use the type variable in a function argument")
1039     functions   = ptext (sLit "must not contain function types")
1040     wrong_arg   = ptext (sLit "must not use the type variable in an argument other than the last")
1041
1042 checkFlag :: ExtensionFlag -> Condition
1043 checkFlag flag (dflags, _)
1044   | xopt flag dflags = Nothing
1045   | otherwise        = Just why
1046   where
1047     why = ptext (sLit "You need -X") <> text flag_str
1048           <+> ptext (sLit "to derive an instance for this class")
1049     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
1050                  [s]   -> s
1051                  other -> pprPanic "checkFlag" (ppr other)
1052
1053 std_class_via_iso :: Class -> Bool
1054 -- These standard classes can be derived for a newtype
1055 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
1056 -- because giving so gives the same results as generating the boilerplate
1057 std_class_via_iso clas
1058   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
1059         -- Not Read/Show because they respect the type
1060         -- Not Enum, because newtypes are never in Enum
1061
1062
1063 non_iso_class :: Class -> Bool
1064 -- *Never* derive Read, Show, Typeable, Data, Generic by isomorphism,
1065 -- even with -XGeneralizedNewtypeDeriving
1066 non_iso_class cls
1067   = classKey cls `elem` ([ readClassKey, showClassKey, dataClassKey
1068                          , genClassKey] ++ typeableClassKeys)
1069
1070 typeableClassKeys :: [Unique]
1071 typeableClassKeys = map getUnique typeableClassNames
1072
1073 new_dfun_name :: Class -> TyCon -> TcM Name
1074 new_dfun_name clas tycon        -- Just a simple wrapper
1075   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1076         ; newDFunName clas [mkTyConApp tycon []] loc }
1077         -- The type passed to newDFunName is only used to generate
1078         -- a suitable string; hence the empty type arg list
1079
1080 badCon :: DataCon -> SDoc -> SDoc
1081 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1082 \end{code}
1083
1084 Note [Superclasses of derived instance]
1085 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1086 In general, a derived instance decl needs the superclasses of the derived
1087 class too.  So if we have
1088         data T a = ...deriving( Ord )
1089 then the initial context for Ord (T a) should include Eq (T a).  Often this is
1090 redundant; we'll also generate an Ord constraint for each constructor argument,
1091 and that will probably generate enough constraints to make the Eq (T a) constraint
1092 be satisfied too.  But not always; consider:
1093
1094  data S a = S
1095  instance Eq (S a)
1096  instance Ord (S a)
1097
1098  data T a = MkT (S a) deriving( Ord )
1099  instance Num a => Eq (T a)
1100
1101 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1102 Similarly consider:
1103         data T a = MkT deriving( Data, Typeable )
1104 Here there *is* no argument field, but we must nevertheless generate
1105 a context for the Data instances:
1106         instance Typable a => Data (T a) where ...
1107
1108
1109 %************************************************************************
1110 %*                                                                      *
1111                 Deriving newtypes
1112 %*                                                                      *
1113 %************************************************************************
1114
1115 \begin{code}
1116 mkNewTypeEqn :: CtOrigin -> DynFlags -> [Var] -> Class
1117              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1118              -> DerivContext
1119              -> TcRn EarlyDerivSpec
1120 mkNewTypeEqn orig dflags tvs
1121              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1122 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1123   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1124   = do  { traceTc "newtype deriving:" (ppr tycon <+> ppr rep_tys <+> ppr all_preds)
1125         ; dfun_name <- new_dfun_name cls tycon
1126         ; loc <- getSrcSpanM
1127         ; let spec = DS { ds_loc = loc, ds_orig = orig
1128                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs
1129                         , ds_cls = cls, ds_tys = inst_tys
1130                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1131                         , ds_theta =  mtheta `orElse` all_preds
1132                         , ds_newtype = True }
1133         ; return (if isJust mtheta then Right spec
1134                                    else Left spec) }
1135
1136   | otherwise
1137   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1138       CanDerive -> go_for_it    -- Use the standard H98 method
1139       DerivableClassError msg   -- Error with standard class
1140         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1141         | otherwise                  -> bale_out msg
1142       NonDerivableClass         -- Must use newtype deriving
1143         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1144         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1145         | otherwise                  -> bale_out non_std
1146   where
1147         newtype_deriving = xopt Opt_GeneralizedNewtypeDeriving dflags
1148         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1149         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1150
1151         non_std    = nonStdErr cls
1152         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1153
1154         -- Here is the plan for newtype derivings.  We see
1155         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1156         -- where t is a type,
1157         --       ak+1...an is a suffix of a1..an, and are all tyars
1158         --       ak+1...an do not occur free in t, nor in the s1..sm
1159         --       (C s1 ... sm) is a  *partial applications* of class C
1160         --                      with the last parameter missing
1161         --       (T a1 .. ak) matches the kind of C's last argument
1162         --              (and hence so does t)
1163         -- The latter kind-check has been done by deriveTyData already,
1164         -- and tc_args are already trimmed
1165         --
1166         -- We generate the instance
1167         --       instance forall ({a1..ak} u fvs(s1..sm)).
1168         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1169         -- where T a1...ap is the partial application of
1170         --       the LHS of the correct kind and p >= k
1171         --
1172         --      NB: the variables below are:
1173         --              tc_tvs = [a1, ..., an]
1174         --              tyvars_to_keep = [a1, ..., ak]
1175         --              rep_ty = t ak .. an
1176         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1177         --              tys = [s1, ..., sm]
1178         --              rep_fn' = t
1179         --
1180         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1181         -- We generate the instance
1182         --      instance Monad (ST s) => Monad (T s) where
1183
1184         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1185                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1186                 -- eta-reduces the representation type, so we know that
1187                 --      T a ~ S a a
1188                 -- That's convenient here, because we may have to apply
1189                 -- it to fewer than its original complement of arguments
1190
1191         -- Note [Newtype representation]
1192         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1193         -- Need newTyConRhs (*not* a recursive representation finder)
1194         -- to get the representation type. For example
1195         --      newtype B = MkB Int
1196         --      newtype A = MkA B deriving( Num )
1197         -- We want the Num instance of B, *not* the Num instance of Int,
1198         -- when making the Num instance of A!
1199         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1200         rep_tys     = cls_tys ++ [rep_inst_ty]
1201         rep_pred    = mkClassPred cls rep_tys
1202                 -- rep_pred is the representation dictionary, from where
1203                 -- we are gong to get all the methods for the newtype
1204                 -- dictionary
1205
1206
1207     -- Next we figure out what superclass dictionaries to use
1208     -- See Note [Newtype deriving superclasses] above
1209
1210         cls_tyvars = classTyVars cls
1211         dfun_tvs = tyVarsOfTypes inst_tys
1212         inst_ty = mkTyConApp tycon tc_args
1213         inst_tys = cls_tys ++ [inst_ty]
1214         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1215                               (classSCTheta cls)
1216
1217                 -- If there are no tyvars, there's no need
1218                 -- to abstract over the dictionaries we need
1219                 -- Example:     newtype T = MkT Int deriving( C )
1220                 -- We get the derived instance
1221                 --              instance C T
1222                 -- rather than
1223                 --              instance C Int => C T
1224         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1225
1226         -------------------------------------------------------------------
1227         --  Figuring out whether we can only do this newtype-deriving thing
1228
1229         can_derive_via_isomorphism
1230            =  not (non_iso_class cls)
1231            && arity_ok
1232            && eta_ok
1233            && ats_ok
1234 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1235
1236         arity_ok = length cls_tys + 1 == classArity cls
1237                 -- Well kinded; eg not: newtype T ... deriving( ST )
1238                 --                      because ST needs *2* type params
1239
1240         -- Check that eta reduction is OK
1241         eta_ok = nt_eta_arity <= length rep_tc_args
1242                 -- The newtype can be eta-reduced to match the number
1243                 --     of type argument actually supplied
1244                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1245                 --     Here the 'b' must be the same in the rep type (S [a] b)
1246                 --     And the [a] must not mention 'b'.  That's all handled
1247                 --     by nt_eta_rity.
1248
1249         ats_ok = null (classATs cls)
1250                -- No associated types for the class, because we don't
1251                -- currently generate type 'instance' decls; and cannot do
1252                -- so for 'data' instance decls
1253
1254         cant_derive_err
1255            = vcat [ ppUnless arity_ok arity_msg
1256                   , ppUnless eta_ok eta_msg
1257                   , ppUnless ats_ok ats_msg ]
1258         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1259         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1260         ats_msg   = ptext (sLit "the class has associated types")
1261 \end{code}
1262
1263 Note [Recursive newtypes]
1264 ~~~~~~~~~~~~~~~~~~~~~~~~~
1265 Newtype deriving works fine, even if the newtype is recursive.
1266 e.g.    newtype S1 = S1 [T1 ()]
1267         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1268 Remember, too, that type families are curretly (conservatively) given
1269 a recursive flag, so this also allows newtype deriving to work
1270 for type famillies.
1271
1272 We used to exclude recursive types, because we had a rather simple
1273 minded way of generating the instance decl:
1274    newtype A = MkA [A]
1275    instance Eq [A] => Eq A      -- Makes typechecker loop!
1276 But now we require a simple context, so it's ok.
1277
1278
1279 %************************************************************************
1280 %*                                                                      *
1281 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1282 %*                                                                      *
1283 %************************************************************************
1284
1285 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1286 terms, which is the final correct RHS for the corresponding original
1287 equation.
1288 \begin{itemize}
1289 \item
1290 Each (k,TyVarTy tv) in a solution constrains only a type
1291 variable, tv.
1292
1293 \item
1294 The (k,TyVarTy tv) pairs in a solution are canonically
1295 ordered by sorting on type varible, tv, (major key) and then class, k,
1296 (minor key)
1297 \end{itemize}
1298
1299 \begin{code}
1300 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1301
1302 inferInstanceContexts _ [] = return []
1303
1304 inferInstanceContexts oflag infer_specs
1305   = do  { traceTc "inferInstanceContexts" $ vcat (map pprDerivSpec infer_specs)
1306         ; iterate_deriv 1 initial_solutions }
1307   where
1308     ------------------------------------------------------------------
1309         -- The initial solutions for the equations claim that each
1310         -- instance has an empty context; this solution is certainly
1311         -- in canonical form.
1312     initial_solutions :: [ThetaType]
1313     initial_solutions = [ [] | _ <- infer_specs ]
1314
1315     ------------------------------------------------------------------
1316         -- iterate_deriv calculates the next batch of solutions,
1317         -- compares it with the current one; finishes if they are the
1318         -- same, otherwise recurses with the new solutions.
1319         -- It fails if any iteration fails
1320     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1321     iterate_deriv n current_solns
1322       | n > 20  -- Looks as if we are in an infinite loop
1323                 -- This can happen if we have -XUndecidableInstances
1324                 -- (See TcSimplify.tcSimplifyDeriv.)
1325       = pprPanic "solveDerivEqns: probable loop"
1326                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1327       | otherwise
1328       = do {      -- Extend the inst info from the explicit instance decls
1329                   -- with the current set of solutions, and simplify each RHS
1330              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1331                                            current_solns infer_specs
1332            ; new_solns <- checkNoErrs $
1333                           extendLocalInstEnv inst_specs $
1334                           mapM gen_soln infer_specs
1335
1336            ; if (current_solns == new_solns) then
1337                 return [ spec { ds_theta = soln }
1338                        | (spec, soln) <- zip infer_specs current_solns ]
1339              else
1340                 iterate_deriv (n+1) new_solns }
1341
1342     ------------------------------------------------------------------
1343     gen_soln :: DerivSpec  -> TcM [PredType]
1344     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars
1345                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1346       = setSrcSpan loc  $
1347         addErrCtxt (derivInstCtxt the_pred) $
1348         do {      -- Check for a bizarre corner case, when the derived instance decl should
1349                   -- have form  instance C a b => D (T a) where ...
1350                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1351                   -- of problems; in particular, it's hard to compare solutions for
1352                   -- equality when finding the fixpoint.  Moreover, simplifyDeriv
1353                   -- has an assert failure because it finds a TyVar when it expects
1354                   -- only TcTyVars.  So I just rule it out for now.  I'm not
1355                   -- even sure how it can arise.
1356
1357            ; let tv_set = mkVarSet tyvars
1358                  weird_preds = [pred | pred <- deriv_rhs
1359                                      , not (tyVarsOfPred pred `subVarSet` tv_set)]
1360            ; mapM_ (addErrTc . badDerivedPred) weird_preds
1361
1362            ; theta <- simplifyDeriv orig the_pred tyvars deriv_rhs
1363                 -- checkValidInstance tyvars theta clas inst_tys
1364                 -- Not necessary; see Note [Exotic derived instance contexts]
1365                 --                in TcSimplify
1366
1367            ; traceTc "TcDeriv" (ppr deriv_rhs $$ ppr theta)
1368                 -- Claim: the result instance declaration is guaranteed valid
1369                 -- Hence no need to call:
1370                 --   checkValidInstance tyvars theta clas inst_tys
1371            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1372       where
1373         the_pred = mkClassPred clas inst_tys
1374
1375 ------------------------------------------------------------------
1376 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1377 mkInstance overlap_flag theta
1378             (DS { ds_name = dfun_name
1379                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1380   = mkLocalInstance dfun overlap_flag
1381   where
1382     dfun = mkDictFunId dfun_name tyvars theta clas tys
1383
1384
1385 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1386 -- Add new locally-defined instances; don't bother to check
1387 -- for functional dependency errors -- that'll happen in TcInstDcls
1388 extendLocalInstEnv dfuns thing_inside
1389  = do { env <- getGblEnv
1390       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1391              env'      = env { tcg_inst_env = inst_env' }
1392       ; setGblEnv env' thing_inside }
1393 \end{code}
1394
1395
1396 %************************************************************************
1397 %*                                                                      *
1398 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1399 %*                                                                      *
1400 %************************************************************************
1401
1402 After all the trouble to figure out the required context for the
1403 derived instance declarations, all that's left is to chug along to
1404 produce them.  They will then be shoved into @tcInstDecls2@, which
1405 will do all its usual business.
1406
1407 There are lots of possibilities for code to generate.  Here are
1408 various general remarks.
1409
1410 PRINCIPLES:
1411 \begin{itemize}
1412 \item
1413 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1414 ``you-couldn't-do-better-by-hand'' efficient.
1415
1416 \item
1417 Deriving @Show@---also pretty common--- should also be reasonable good code.
1418
1419 \item
1420 Deriving for the other classes isn't that common or that big a deal.
1421 \end{itemize}
1422
1423 PRAGMATICS:
1424
1425 \begin{itemize}
1426 \item
1427 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1428
1429 \item
1430 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1431
1432 \item
1433 We {\em normally} generate code only for the non-defaulted methods;
1434 there are some exceptions for @Eq@ and (especially) @Ord@...
1435
1436 \item
1437 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1438 constructor's numeric (@Int#@) tag.  These are generated by
1439 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1440 these is around is given by @hasCon2TagFun@.
1441
1442 The examples under the different sections below will make this
1443 clearer.
1444
1445 \item
1446 Much less often (really just for deriving @Ix@), we use a
1447 @_tag2con_<tycon>@ function.  See the examples.
1448
1449 \item
1450 We use the renamer!!!  Reason: we're supposed to be
1451 producing @LHsBinds Name@ for the methods, but that means
1452 producing correctly-uniquified code on the fly.  This is entirely
1453 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1454 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1455 the renamer.  What a great hack!
1456 \end{itemize}
1457
1458 \begin{code}
1459 -- Generate the InstInfo for the required instance paired with the
1460 --   *representation* tycon for that instance,
1461 -- plus any auxiliary bindings required
1462 --
1463 -- Representation tycons differ from the tycon in the instance signature in
1464 -- case of instances for indexed families.
1465 --
1466 genInst :: Bool         -- True <=> standalone deriving
1467         -> OverlapFlag
1468         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1469 genInst standalone_deriv oflag
1470         spec@(DS { ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1471                  , ds_theta = theta, ds_newtype = is_newtype
1472                  , ds_name = name, ds_cls = clas })
1473   | is_newtype
1474   = return (InstInfo { iSpec   = inst_spec
1475                      , iBinds  = NewTypeDerived co rep_tycon }, [])
1476
1477   | otherwise
1478   = do  { fix_env <- getFixityEnv
1479         ; let loc   = getSrcSpan name
1480               (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1481                    -- In case of a family instance, we need to use the representation
1482                    -- tycon (after all, it has the data constructors)
1483
1484         ; return (InstInfo { iSpec   = inst_spec
1485                            , iBinds  = VanillaInst meth_binds [] standalone_deriv }
1486                  , aux_binds) }
1487   where
1488     inst_spec = mkInstance oflag theta spec
1489     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1490               Just co_con -> mkAxInstCo co_con rep_tc_args
1491               Nothing     -> id_co
1492               -- Not a family => rep_tycon = main tycon
1493     co2 = mkAxInstCo (newTyConCo rep_tycon) rep_tc_args
1494     co  = co1 `mkTransCo` co2
1495     id_co = mkReflCo (mkTyConApp rep_tycon rep_tc_args)
1496
1497 -- Example: newtype instance N [a] = N1 (Tree a)
1498 --          deriving instance Eq b => Eq (N [(b,b)])
1499 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1500 -- When dealing with the deriving clause
1501 --    co1 : N [(b,b)] ~ R1:N (b,b)
1502 --    co2 : R1:N (b,b) ~ Tree (b,b)
1503 --    co  : N [(b,b)] ~ Tree (b,b)
1504
1505 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1506 genDerivBinds loc fix_env clas tycon
1507   | className clas `elem` typeableClassNames
1508   = (gen_Typeable_binds loc tycon, [])
1509
1510   | otherwise
1511   = case assocMaybe gen_list (getUnique clas) of
1512         Just gen_fn -> gen_fn loc tycon
1513         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1514   where
1515     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1516     gen_list = [(eqClassKey,            gen_Eq_binds)
1517                ,(ordClassKey,           gen_Ord_binds)
1518                ,(enumClassKey,          gen_Enum_binds)
1519                ,(boundedClassKey,       gen_Bounded_binds)
1520                ,(ixClassKey,            gen_Ix_binds)
1521                ,(showClassKey,          gen_Show_binds fix_env)
1522                ,(readClassKey,          gen_Read_binds fix_env)
1523                ,(dataClassKey,          gen_Data_binds)
1524                ,(functorClassKey,       gen_Functor_binds)
1525                ,(foldableClassKey,      gen_Foldable_binds)
1526                ,(traversableClassKey,   gen_Traversable_binds)
1527                ,(genClassKey,           genGenericBinds)
1528                ]
1529 \end{code}
1530
1531 %************************************************************************
1532 %*                                                                      *
1533 \subsection[TcDeriv-generic-binds]{Bindings for the new generic deriving mechanism}
1534 %*                                                                      *
1535 %************************************************************************
1536
1537 For the generic representation we need to generate:
1538 \begin{itemize}
1539 \item A Generic instance
1540 \item A Rep type instance
1541 \item Many auxiliary datatypes and instances for them (for the meta-information)
1542 \end{itemize}
1543
1544 @genGenericBinds@ does (1)
1545 @genGenericRepExtras@ does (2) and (3)
1546 @genGenericAll@ does all of them
1547
1548 \begin{code}
1549 genGenericBinds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1550 genGenericBinds _ tc = (mkBindsRep tc, [ {- No DerivAuxBinds -} ])
1551
1552 genGenericRepExtras :: TyCon -> TcM (MetaTyCons, TyCon)
1553 genGenericRepExtras tc =
1554   do  uniqS <- newUniqueSupply
1555       let
1556         -- Uniques for everyone
1557         (uniqD:uniqs) = uniqsFromSupply uniqS
1558         (uniqsC,us) = splitAt (length tc_cons) uniqs
1559         uniqsS :: [[Unique]] -- Unique supply for the S datatypes
1560         uniqsS = mkUniqsS tc_arits us
1561         mkUniqsS []    _  = []
1562         mkUniqsS (n:t) us = case splitAt n us of
1563                               (us1,us2) -> us1 : mkUniqsS t us2
1564
1565         tc_name   = tyConName tc
1566         tc_cons   = tyConDataCons tc
1567         tc_arits  = map dataConSourceArity tc_cons
1568
1569         tc_occ    = nameOccName tc_name
1570         d_occ     = mkGenD tc_occ
1571         c_occ m   = mkGenC tc_occ m
1572         s_occ m n = mkGenS tc_occ m n
1573         mod_name  = nameModule (tyConName tc)
1574         d_name    = mkExternalName uniqD mod_name d_occ wiredInSrcSpan
1575         c_names   = [ mkExternalName u mod_name (c_occ m) wiredInSrcSpan
1576                       | (u,m) <- zip uniqsC [0..] ]
1577         s_names   = [ [ mkExternalName u mod_name (s_occ m n) wiredInSrcSpan
1578                         | (u,n) <- zip us [0..] ] | (us,m) <- zip uniqsS [0..] ]
1579
1580         mkTyCon name = ASSERT( isExternalName name )
1581                          buildAlgTyCon name [] [] mkAbstractTyConRhs
1582                            NonRecursive False NoParentTyCon Nothing
1583
1584       metaDTyCon  <- mkTyCon d_name
1585       metaCTyCons <- sequence [ mkTyCon c_name | c_name <- c_names ]
1586       metaSTyCons <- mapM sequence
1587                        [ [ mkTyCon s_name
1588                          | s_name <- s_namesC ] | s_namesC <- s_names ]
1589
1590       let metaDts = MetaTyCons metaDTyCon metaCTyCons metaSTyCons
1591
1592       rep0_tycon <- tc_mkRepTyCon tc metaDts
1593
1594       return (metaDts, rep0_tycon)
1595 {-
1596 genGenericAll :: TyCon
1597                   -> TcM ((InstInfo RdrName, DerivAuxBinds), MetaTyCons, TyCon)
1598 genGenericAll tc =
1599   do  (metaDts, rep0_tycon)     <- genGenericRepExtras tc
1600       clas                      <- tcLookupClass genClassName
1601       dfun_name                 <- new_dfun_name clas tc
1602       let
1603         mkInstRep = (InstInfo { iSpec = inst, iBinds = binds }
1604                                , [ {- No DerivAuxBinds -} ])
1605         inst  = mkLocalInstance dfun NoOverlap
1606         binds = VanillaInst (mkBindsRep tc) [] False
1607
1608         tvs   = tyConTyVars tc
1609         tc_ty = mkTyConApp tc (mkTyVarTys tvs)
1610
1611         dfun  = mkDictFunId dfun_name (tyConTyVars tc) [] clas [tc_ty]
1612       return (mkInstRep, metaDts, rep0_tycon)
1613 -}
1614 genDtMeta :: (TyCon, MetaTyCons) -> TcM [(InstInfo RdrName, DerivAuxBinds)]
1615 genDtMeta (tc,metaDts) =
1616   do  dClas <- tcLookupClass datatypeClassName
1617       d_dfun_name <- new_dfun_name dClas tc
1618       cClas <- tcLookupClass constructorClassName
1619       c_dfun_names <- sequence [ new_dfun_name cClas tc | _ <- metaC metaDts ]
1620       sClas <- tcLookupClass selectorClassName
1621       s_dfun_names <- sequence (map sequence [ [ new_dfun_name sClas tc
1622                                                | _ <- x ]
1623                                              | x <- metaS metaDts ])
1624       fix_env <- getFixityEnv
1625
1626       let
1627         (dBinds,cBinds,sBinds) = mkBindsMetaD fix_env tc
1628
1629         -- Datatype
1630         d_metaTycon = metaD metaDts
1631         d_inst = mkLocalInstance d_dfun NoOverlap
1632         d_binds = VanillaInst dBinds [] False
1633         d_dfun  = mkDictFunId d_dfun_name (tyConTyVars tc) [] dClas
1634                     [ mkTyConTy d_metaTycon ]
1635         d_mkInst = (InstInfo { iSpec = d_inst, iBinds = d_binds }, [])
1636
1637         -- Constructor
1638         c_metaTycons = metaC metaDts
1639         c_insts = [ mkLocalInstance (c_dfun c ds) NoOverlap
1640                   | (c, ds) <- myZip1 c_metaTycons c_dfun_names ]
1641         c_binds = [ VanillaInst c [] False | c <- cBinds ]
1642         c_dfun c dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] cClas
1643                                [ mkTyConTy c ]
1644         c_mkInst = [ (InstInfo { iSpec = is, iBinds = bs }, [])
1645                    | (is,bs) <- myZip1 c_insts c_binds ]
1646
1647         -- Selector
1648         s_metaTycons = metaS metaDts
1649         s_insts = map (map (\(s,ds) -> mkLocalInstance (s_dfun s ds) NoOverlap))
1650                     (myZip2 s_metaTycons s_dfun_names)
1651         s_binds = [ [ VanillaInst s [] False | s <- ss ] | ss <- sBinds ]
1652         s_dfun s dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] sClas
1653                                [ mkTyConTy s ]
1654         s_mkInst = map (map (\(is,bs) -> (InstInfo {iSpec=is, iBinds=bs}, [])))
1655                      (myZip2 s_insts s_binds)
1656
1657         myZip1 :: [a] -> [b] -> [(a,b)]
1658         myZip1 l1 l2 = ASSERT (length l1 == length l2) zip l1 l2
1659
1660         myZip2 :: [[a]] -> [[b]] -> [[(a,b)]]
1661         myZip2 l1 l2 =
1662           ASSERT (and (zipWith (>=) (map length l1) (map length l2)))
1663             [ zip x1 x2 | (x1,x2) <- zip l1 l2 ]
1664
1665       return (d_mkInst : c_mkInst ++ concat s_mkInst)
1666 \end{code}
1667
1668
1669 %************************************************************************
1670 %*                                                                      *
1671 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1672 %*                                                                      *
1673 %************************************************************************
1674
1675 \begin{code}
1676 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1677 derivingKindErr tc cls cls_tys cls_kind
1678   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1679                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1680        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1681             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1682
1683 derivingEtaErr :: Class -> [Type] -> Type -> Message
1684 derivingEtaErr cls cls_tys inst_ty
1685   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1686          nest 2 (ptext (sLit "instance (...) =>")
1687                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1688
1689 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1690 typeFamilyPapErr tc cls cls_tys inst_ty
1691   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1692        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc)
1693
1694 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1695 derivingThingErr newtype_deriving clas tys ty why
1696   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1697              2 (quotes (ppr pred))
1698           $$ nest 2 extra) <> colon,
1699          nest 2 why]
1700   where
1701     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1702           | otherwise        = empty
1703     pred = mkClassPred clas (tys ++ [ty])
1704
1705 derivingHiddenErr :: TyCon -> SDoc
1706 derivingHiddenErr tc
1707   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1708        2 (ptext (sLit "so you cannot derive an instance for it"))
1709
1710 standaloneCtxt :: LHsType Name -> SDoc
1711 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
1712                        2 (quotes (ppr ty))
1713
1714 derivInstCtxt :: PredType -> Message
1715 derivInstCtxt pred
1716   = ptext (sLit "When deriving the instance for") <+> parens (ppr pred)
1717
1718 badDerivedPred :: PredType -> Message
1719 badDerivedPred pred
1720   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1721           ptext (sLit "type variables that are not data type parameters"),
1722           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1723 \end{code}