compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import Coercion
  34 import ErrUtils
  35 import MkId
  36 import DataCon
  37 import Maybes
  38 import RdrName
  39 import Name
  40 import NameSet
  41 import TyCon
  42 import TcType
  43 import Var
  44 import VarSet
  45 import PrelNames
  46 import SrcLoc
  47 import Util
  48 import ListSetOps
  49 import Outputable
  50 import FastString
  51 import Bag
  52
  53 import Control.Monad
  54 \end{code}
  55
  56 %************************************************************************
  57 %*                                                                      *
  58                 Overview
  59 %*                                                                      *
  60 %************************************************************************
  61
  62 Overall plan
  63 ~~~~~~~~~~~~
  64 1.  Convert the decls (i.e. data/newtype deriving clauses,
  65     plus standalone deriving) to [EarlyDerivSpec]
  66
  67 2.  Infer the missing contexts for the Left DerivSpecs
  68
  69 3.  Add the derived bindings, generating InstInfos
  70
  71 \begin{code}
  72 -- DerivSpec is purely  local to this module
  73 data DerivSpec  = DS { ds_loc     :: SrcSpan
  74                      , ds_orig    :: InstOrigin
  75                      , ds_name    :: Name
  76                      , ds_tvs     :: [TyVar]
  77                      , ds_theta   :: ThetaType
  78                      , ds_cls     :: Class
  79                      , ds_tys     :: [Type]
  80                      , ds_tc      :: TyCon
  81                      , ds_tc_args :: [Type]
  82                      , ds_newtype :: Bool }
  83         -- This spec implies a dfun declaration of the form
  84         --       df :: forall tvs. theta => C tys
  85         -- The Name is the name for the DFun we'll build
  86         -- The tyvars bind all the variables in the theta
  87         -- For family indexes, the tycon in
  88         --       in ds_tys is the *family* tycon
  89         --       in ds_tc, ds_tc_args is the *representation* tycon
  90         -- For non-family tycons, both are the same
  91
  92         -- ds_newtype = True  <=> Newtype deriving
  93         --              False <=> Vanilla deriving
  94
  95 type DerivContext = Maybe ThetaType
  96    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
  97    -- Just theta <=> Standalone deriving: context supplied by programmer
  98
  99 type EarlyDerivSpec = Either DerivSpec DerivSpec
 100         -- Left  ds => the context for the instance should be inferred
 101         --             In this case ds_theta is the list of all the
 102         --                constraints needed, such as (Eq [a], Eq a)
 103         --                The inference process is to reduce this to a
 104         --                simpler form (e.g. Eq a)
 105         --
 106         -- Right ds => the exact context for the instance is supplied
 107         --             by the programmer; it is ds_theta
 108
 109 pprDerivSpec :: DerivSpec -> SDoc
 110 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
 111                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
 112   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
 113             <+> equals <+> ppr rhs)
 114 \end{code}
 115
 116
 117 Inferring missing contexts
 118 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 119 Consider
 120
 121         data T a b = C1 (Foo a) (Bar b)
 122                    | C2 Int (T b a)
 123                    | C3 (T a a)
 124                    deriving (Eq)
 125
 126 [NOTE: See end of these comments for what to do with
 127         data (C a, D b) => T a b = ...
 128 ]
 129
 130 We want to come up with an instance declaration of the form
 131
 132         instance (Ping a, Pong b, ...) => Eq (T a b) where
 133                 x == y = ...
 134
 135 It is pretty easy, albeit tedious, to fill in the code "...".  The
 136 trick is to figure out what the context for the instance decl is,
 137 namely @Ping@, @Pong@ and friends.
 138
 139 Let's call the context reqd for the T instance of class C at types
 140 (a,b, ...)  C (T a b).  Thus:
 141
 142         Eq (T a b) = (Ping a, Pong b, ...)
 143
 144 Now we can get a (recursive) equation from the @data@ decl:
 145
 146         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 147                    u Eq (T b a) u Eq Int        -- From C2
 148                    u Eq (T a a)                 -- From C3
 149
 150 Foo and Bar may have explicit instances for @Eq@, in which case we can
 151 just substitute for them.  Alternatively, either or both may have
 152 their @Eq@ instances given by @deriving@ clauses, in which case they
 153 form part of the system of equations.
 154
 155 Now all we need do is simplify and solve the equations, iterating to
 156 find the least fixpoint.  Notice that the order of the arguments can
 157 switch around, as here in the recursive calls to T.
 158
 159 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 160
 161 We start with:
 162
 163         Eq (T a b) = {}         -- The empty set
 164
 165 Next iteration:
 166         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 167                    u Eq (T b a) u Eq Int        -- From C2
 168                    u Eq (T a a)                 -- From C3
 169
 170         After simplification:
 171                    = Eq a u Ping b u {} u {} u {}
 172                    = Eq a u Ping b
 173
 174 Next iteration:
 175
 176         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 177                    u Eq (T b a) u Eq Int        -- From C2
 178                    u Eq (T a a)                 -- From C3
 179
 180         After simplification:
 181                    = Eq a u Ping b
 182                    u (Eq b u Ping a)
 183                    u (Eq a u Ping a)
 184
 185                    = Eq a u Ping b u Eq b u Ping a
 186
 187 The next iteration gives the same result, so this is the fixpoint.  We
 188 need to make a canonical form of the RHS to ensure convergence.  We do
 189 this by simplifying the RHS to a form in which
 190
 191         - the classes constrain only tyvars
 192         - the list is sorted by tyvar (major key) and then class (minor key)
 193         - no duplicates, of course
 194
 195 So, here are the synonyms for the ``equation'' structures:
 196
 197
 198 Note [Data decl contexts]
 199 ~~~~~~~~~~~~~~~~~~~~~~~~~
 200 Consider
 201
 202         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 203
 204 We will need an instance decl like:
 205
 206         instance (Read a, RealFloat a) => Read (Complex a) where
 207           ...
 208
 209 The RealFloat in the context is because the read method for Complex is bound
 210 to construct a Complex, and doing that requires that the argument type is
 211 in RealFloat.
 212
 213 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 214 a Complex; they only take them apart.
 215
 216 Our approach: identify the offending classes, and add the data type
 217 context to the instance decl.  The "offending classes" are
 218
 219         Read, Enum?
 220
 221 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 222 pattern matching against a constructor from a data type with a context
 223 gives rise to the constraints for that context -- or at least the thinned
 224 version.  So now all classes are "offending".
 225
 226 Note [Newtype deriving]
 227 ~~~~~~~~~~~~~~~~~~~~~~~
 228 Consider this:
 229     class C a b
 230     instance C [a] Char
 231     newtype T = T Char deriving( C [a] )
 232
 233 Notice the free 'a' in the deriving.  We have to fill this out to
 234     newtype T = T Char deriving( forall a. C [a] )
 235
 236 And then translate it to:
 237     instance C [a] Char => C [a] T where ...
 238
 239
 240 Note [Newtype deriving superclasses]
 241 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 242 (See also Trac #1220 for an interesting exchange on newtype
 243 deriving and superclasses.)
 244
 245 The 'tys' here come from the partial application in the deriving
 246 clause. The last arg is the new instance type.
 247
 248 We must pass the superclasses; the newtype might be an instance
 249 of them in a different way than the representation type
 250 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 251 Then the Show instance is not done via isomorphism; it shows
 252         Foo 3 as "Foo 3"
 253 The Num instance is derived via isomorphism, but the Show superclass
 254 dictionary must the Show instance for Foo, *not* the Show dictionary
 255 gotten from the Num dictionary. So we must build a whole new dictionary
 256 not just use the Num one.  The instance we want is something like:
 257      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 258         (+) = ((+)@a)
 259         ...etc...
 260 There may be a coercion needed which we get from the tycon for the newtype
 261 when the dict is constructed in TcInstDcls.tcInstDecl2
 262
 263
 264 Note [Unused constructors and deriving clauses]
 265 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 266 See Trac #3221.  Consider
 267    data T = T1 | T2 deriving( Show )
 268 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
 269 both of them.  So we gather defs/uses from deriving just like anything else.
 270
 271 %************************************************************************
 272 %*                                                                      *
 273 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 274 %*                                                                      *
 275 %************************************************************************
 276
 277 \begin{code}
 278 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
 279             -> [LInstDecl Name]  -- All instance declarations
 280             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 281             -> TcM ([InstInfo Name],    -- The generated "instance decls"
 282                     HsValBinds Name,    -- Extra generated top-level bindings
 283                     DefUses)
 284
 285 tcDeriving tycl_decls inst_decls deriv_decls
 286   = recoverM (return ([], emptyValBindsOut, emptyDUs)) $
 287     do  {       -- Fish the "deriving"-related information out of the TcEnv
 288                 -- And make the necessary "equations".
 289           is_boot <- tcIsHsBoot
 290         ; traceTc (text "tcDeriving" <+> ppr is_boot)
 291         ; early_specs <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 292
 293         ; overlap_flag <- getOverlapFlag
 294         ; let (infer_specs, given_specs) = splitEithers early_specs
 295         ; insts1 <- mapM (genInst True overlap_flag) given_specs
 296
 297         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
 298                          inferInstanceContexts overlap_flag infer_specs
 299
 300         ; insts2 <- mapM (genInst False overlap_flag) final_specs
 301
 302                  -- Generate the generic to/from functions from each type declaration
 303         ; gen_binds <- mkGenericBinds is_boot tycl_decls
 304         ; (inst_info, rn_binds, rn_dus) <- renameDeriv is_boot gen_binds (insts1 ++ insts2)
 305
 306         ; dflags <- getDOpts
 307         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 308                  (ddump_deriving inst_info rn_binds))
 309
 310         ; return (inst_info, rn_binds, rn_dus) }
 311   where
 312     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
 313     ddump_deriving inst_infos extra_binds
 314       = vcat (map pprInstInfoDetails inst_infos) $$ ppr extra_binds
 315
 316 renameDeriv :: Bool -> LHsBinds RdrName
 317             -> [(InstInfo RdrName, DerivAuxBinds)]
 318             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
 319 renameDeriv is_boot gen_binds insts
 320   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
 321                 -- The inst-info bindings will all be empty, but it's easier to
 322                 -- just use rn_inst_info to change the type appropriately
 323   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
 324         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
 325
 326   | otherwise
 327   = discardWarnings $    -- Discard warnings about unused bindings etc
 328     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns
 329                                                                   -- are used in the generic binds
 330                                rnTopBinds (ValBindsIn gen_binds [])
 331         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
 332
 333                 -- Generate and rename any extra not-one-inst-decl-specific binds,
 334                 -- notably "con2tag" and/or "tag2con" functions.
 335                 -- Bring those names into scope before renaming the instances themselves
 336         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
 337         ; let aux_binds = listToBag $ map (genAuxBind loc) $
 338                           rm_dups [] $ concat deriv_aux_binds
 339         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv (ValBindsIn aux_binds [])
 340         ; let aux_names = collectHsValBinders rn_aux_lhs
 341
 342         ; bindLocalNames aux_names $
 343     do  { (rn_aux, dus_aux) <- rnTopBindsRHS (mkNameSet aux_names) rn_aux_lhs
 344         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
 345         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
 346                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
 347
 348   where
 349     (inst_infos, deriv_aux_binds) = unzip insts
 350
 351         -- Remove duplicate requests for auxilliary bindings
 352     rm_dups acc [] = acc
 353     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
 354                        | otherwise            = rm_dups (b:acc) bs
 355
 356
 357     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
 358     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
 359         = return ( info { iBinds = NewTypeDerived coi tc }
 360                  , mkFVs (map dataConName (tyConDataCons tc)))
 361           -- See Note [Newtype deriving and unused constructors]
 362
 363     rn_inst_info (InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
 364         =       -- Bring the right type variables into
 365                 -- scope (yuk), and rename the method binds
 366            ASSERT( null sigs )
 367            bindLocalNames (map Var.varName tyvars) $
 368            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) [] binds
 369               ; let binds' = VanillaInst rn_binds [] standalone_deriv
 370               ; return (InstInfo { iSpec = inst, iBinds = binds' }, fvs) }
 371         where
 372           (tyvars,_, clas,_) = instanceHead inst
 373           clas_nm            = className clas
 374
 375 -----------------------------------------
 376 mkGenericBinds :: Bool -> [LTyClDecl Name] -> TcM (LHsBinds RdrName)
 377 mkGenericBinds is_boot tycl_decls
 378   | is_boot
 379   = return emptyBag
 380   | otherwise
 381   = do  { tcs <- mapM tcLookupTyCon [ tcdName d
 382                                     | L _ d <- tycl_decls, isDataDecl d ]
 383         ; return (unionManyBags [ mkTyConGenericBinds tc
 384                                 | tc <- tcs, tyConHasGenerics tc ]) }
 385                 -- We are only interested in the data type declarations,
 386                 -- and then only in the ones whose 'has-generics' flag is on
 387                 -- The predicate tyConHasGenerics finds both of these
 388 \end{code}
 389
 390 Note [Newtype deriving and unused constructors]
 391 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 392 Consider this (see Trac #1954):
 393
 394   module Bug(P) where
 395   newtype P a = MkP (IO a) deriving Monad
 396
 397 If you compile with -fwarn-unused-binds you do not expect the warning
 398 "Defined but not used: data consructor MkP". Yet the newtype deriving
 399 code does not explicitly mention MkP, but it should behave as if you
 400 had written
 401   instance Monad P where
 402      return x = MkP (return x)
 403      ...etc...
 404
 405 So we want to signal a user of the data constructor 'MkP'.  That's
 406 what we do in rn_inst_info, and it's the only reason we have the TyCon
 407 stored in NewTypeDerived.
 408
 409
 410 %************************************************************************
 411 %*                                                                      *
 412                 From HsSyn to DerivSpec
 413 %*                                                                      *
 414 %************************************************************************
 415
 416 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
 417
 418 \begin{code}
 419 makeDerivSpecs :: Bool
 420                -> [LTyClDecl Name]
 421                -> [LInstDecl Name]
 422                -> [LDerivDecl Name]
 423                -> TcM [EarlyDerivSpec]
 424
 425 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 426   | is_boot     -- No 'deriving' at all in hs-boot files
 427   = do  { mapM_ add_deriv_err deriv_locs
 428         ; return [] }
 429   | otherwise
 430   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
 431         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
 432         ; return (eqns1 ++ eqns2) }
 433   where
 434     extractTyDataPreds decls
 435       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
 436
 437     all_tydata :: [(LHsType Name, LTyClDecl Name)]
 438         -- Derived predicate paired with its data type declaration
 439     all_tydata = extractTyDataPreds (instDeclATs inst_decls ++ tycl_decls)
 440
 441     deriv_locs = map (getLoc . snd) all_tydata
 442                  ++ map getLoc deriv_decls
 443
 444     add_deriv_err loc = setSrcSpan loc $
 445                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
 446                                    2 (ptext (sLit "Use an instance declaration instead")))
 447
 448 ------------------------------------------------------------------
 449 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
 450 -- Standalone deriving declarations
 451 --  e.g.   deriving instance Show a => Show (T a)
 452 -- Rather like tcLocalInstDecl
 453 deriveStandalone (L loc (DerivDecl deriv_ty))
 454   = setSrcSpan loc                   $
 455     addErrCtxt (standaloneCtxt deriv_ty)  $
 456     do { traceTc (text "standalone deriving decl for" <+> ppr deriv_ty)
 457        ; (tvs, theta, tau) <- tcHsInstHead deriv_ty
 458        ; traceTc (text "standalone deriving;"
 459               <+> text "tvs:" <+> ppr tvs
 460               <+> text "theta:" <+> ppr theta
 461               <+> text "tau:" <+> ppr tau)
 462        ; (cls, inst_tys) <- checkValidInstance deriv_ty tvs theta tau
 463                 -- C.f. TcInstDcls.tcLocalInstDecl1
 464
 465        ; let cls_tys = take (length inst_tys - 1) inst_tys
 466              inst_ty = last inst_tys
 467        ; traceTc (text "standalone deriving;"
 468               <+> text "class:" <+> ppr cls
 469               <+> text "class types:" <+> ppr cls_tys
 470               <+> text "type:" <+> ppr inst_ty)
 471        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
 472                    (Just theta) }
 473
 474 ------------------------------------------------------------------
 475 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
 476 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name,
 477                                                    tcdTyVars = tv_names,
 478                                                    tcdTyPats = ty_pats }))
 479   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
 480     tcAddDeclCtxt decl $
 481     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
 482         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 483                                         -- the type variables for the type constructor
 484
 485     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 486                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 487                 -- newtype deriving we allow deriving (forall a. C [a]).
 488
 489         -- Given data T a b c = ... deriving( C d ),
 490         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
 491         ; let cls_tyvars = classTyVars cls
 492               kind = tyVarKind (last cls_tyvars)
 493               (arg_kinds, _) = splitKindFunTys kind
 494               n_args_to_drop = length arg_kinds
 495               n_args_to_keep = tyConArity tc - n_args_to_drop
 496               args_to_drop   = drop n_args_to_keep tc_args
 497               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
 498               inst_ty_kind   = typeKind inst_ty
 499               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
 500               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
 501                                         `minusVarSet` dropped_tvs
 502
 503         -- Check that the result really is well-kinded
 504         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
 505                   (derivingKindErr tc cls cls_tys kind)
 506
 507         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
 508                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
 509                   (derivingEtaErr cls cls_tys inst_ty)
 510                 -- Check that
 511                 --  (a) The data type can be eta-reduced; eg reject:
 512                 --              data instance T a a = ... deriving( Monad )
 513                 --  (b) The type class args do not mention any of the dropped type
 514                 --      variables
 515                 --              newtype T a s = ... deriving( ST s )
 516
 517         -- Type families can't be partially applied
 518         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
 519         -- Note [Deriving, type families, and partial applications]
 520         ; checkTc (not (isOpenTyCon tc) || n_args_to_drop == 0)
 521                   (typeFamilyPapErr tc cls cls_tys inst_ty)
 522
 523         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
 524   where
 525         -- Tiresomely we must figure out the "lhs", which is awkward for type families
 526         -- E.g.   data T a b = .. deriving( Eq )
 527         --          Here, the lhs is (T a b)
 528         --        data instance TF Int b = ... deriving( Eq )
 529         --          Here, the lhs is (TF Int b)
 530         -- But if we just look up the tycon_name, we get is the *family*
 531         -- tycon, but not pattern types -- they are in the *rep* tycon.
 532     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
 533                              ; let tvs = tyConTyVars tc
 534                              ; return (tvs, tc, mkTyVarTys tvs) }
 535     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
 536                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 537                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
 538                              ; return (tvs, tc, tc_args) }
 539
 540 deriveTyData _other
 541   = panic "derivTyData" -- Caller ensures that only TyData can happen
 542 \end{code}
 543
 544 Note [Deriving, type families, and partial applications]
 545 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 546 When there are no type families, it's quite easy:
 547
 548     newtype S a = MkS [a]
 549     -- :CoS :: S  ~ []  -- Eta-reduced
 550
 551     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
 552     instance Monad [] => Monad S        -- by coercion sym (Monad :CoS)  : Monad [] ~ Monad S
 553
 554 When type familes are involved it's trickier:
 555
 556     data family T a b
 557     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
 558     -- :RT is the representation type for (T Int a)
 559     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
 560     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
 561
 562     instance Eq [a] => Eq (T Int a)     -- easy by coercion
 563     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 564
 565 The "???" bit is that we don't build the :CoF thing in eta-reduced form
 566 Henc the current typeFamilyPapErr, even though the instance makes sense.
 567 After all, we can write it out
 568     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 569       return x = MkT [x]
 570       ... etc ...
 571
 572 \begin{code}
 573 mkEqnHelp :: InstOrigin -> [TyVar] -> Class -> [Type] -> Type
 574           -> DerivContext       -- Just    => context supplied (standalone deriving)
 575                                 -- Nothing => context inferred (deriving on data decl)
 576           -> TcRn EarlyDerivSpec
 577 -- Make the EarlyDerivSpec for an instance
 578 --      forall tvs. theta => cls (tys ++ [ty])
 579 -- where the 'theta' is optional (that's the Maybe part)
 580 -- Assumes that this declaration is well-kinded
 581
 582 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
 583   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 584   , isAlgTyCon tycon    -- Check for functions, primitive types etc
 585   = do  { (rep_tc, rep_tc_args) <- tcLookupFamInstExact tycon tc_args
 586                   -- Be careful to test rep_tc here: in the case of families,
 587                   -- we want to check the instance tycon, not the family tycon
 588
 589         -- For standalone deriving (mtheta /= Nothing),
 590         -- check that all the data constructors are in scope.
 591         -- No need for this when deriving Typeable, becuase we don't need
 592         -- the constructors for that.
 593         ; rdr_env <- getGlobalRdrEnv
 594         ; let hidden_data_cons = isAbstractTyCon rep_tc || any not_in_scope (tyConDataCons rep_tc)
 595               not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
 596         ; checkTc (isNothing mtheta ||
 597                    not hidden_data_cons ||
 598                    className cls `elem` typeableClassNames)
 599                   (derivingHiddenErr tycon)
 600
 601         ; dflags <- getDOpts
 602         ; if isDataTyCon rep_tc then
 603                 mkDataTypeEqn orig dflags tvs cls cls_tys
 604                               tycon tc_args rep_tc rep_tc_args mtheta
 605           else
 606                 mkNewTypeEqn orig dflags tvs cls cls_tys
 607                              tycon tc_args rep_tc rep_tc_args mtheta }
 608   | otherwise
 609   = failWithTc (derivingThingErr False cls cls_tys tc_app
 610                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
 611 \end{code}
 612
 613 Note [Looking up family instances for deriving]
 614 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 615 tcLookupFamInstExact is an auxiliary lookup wrapper which requires
 616 that looked-up family instances exist.  If called with a vanilla
 617 tycon, the old type application is simply returned.
 618
 619 If we have
 620   data instance F () = ... deriving Eq
 621   data instance F () = ... deriving Eq
 622 then tcLookupFamInstExact will be confused by the two matches;
 623 but that can't happen because tcInstDecls1 doesn't call tcDeriving
 624 if there are any overlaps.
 625
 626 There are two other things that might go wrong with the lookup.
 627 First, we might see a standalone deriving clause
 628         deriving Eq (F ())
 629 when there is no data instance F () in scope.
 630
 631 Note that it's OK to have
 632   data instance F [a] = ...
 633   deriving Eq (F [(a,b)])
 634 where the match is not exact; the same holds for ordinary data types
 635 with standalone deriving declrations.
 636
 637 \begin{code}
 638 tcLookupFamInstExact :: TyCon -> [Type] -> TcM (TyCon, [Type])
 639 tcLookupFamInstExact tycon tys
 640   | not (isOpenTyCon tycon)
 641   = return (tycon, tys)
 642   | otherwise
 643   = do { maybeFamInst <- tcLookupFamInst tycon tys
 644        ; case maybeFamInst of
 645            Nothing      -> famInstNotFound tycon tys
 646            Just famInst -> return famInst
 647        }
 648
 649 famInstNotFound :: TyCon -> [Type] -> TcM a
 650 famInstNotFound tycon tys
 651   = failWithTc (ptext (sLit "No family instance for")
 652                         <+> quotes (pprTypeApp tycon tys))
 653 \end{code}
 654
 655
 656 %************************************************************************
 657 %*                                                                      *
 658                 Deriving data types
 659 %*                                                                      *
 660 %************************************************************************
 661
 662 \begin{code}
 663 mkDataTypeEqn :: InstOrigin
 664               -> DynFlags
 665               -> [Var]                  -- Universally quantified type variables in the instance
 666               -> Class                  -- Class for which we need to derive an instance
 667               -> [Type]                 -- Other parameters to the class except the last
 668               -> TyCon                  -- Type constructor for which the instance is requested
 669                                         --    (last parameter to the type class)
 670               -> [Type]                 -- Parameters to the type constructor
 671               -> TyCon                  -- rep of the above (for type families)
 672               -> [Type]                 -- rep of the above
 673               -> DerivContext        -- Context of the instance, for standalone deriving
 674               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
 675
 676 mkDataTypeEqn orig dflags tvs cls cls_tys
 677               tycon tc_args rep_tc rep_tc_args mtheta
 678   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
 679         -- NB: pass the *representation* tycon to checkSideConditions
 680         CanDerive               -> go_for_it
 681         NonDerivableClass       -> bale_out (nonStdErr cls)
 682         DerivableClassError msg -> bale_out msg
 683   where
 684     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 685     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
 686
 687 mk_data_eqn, mk_typeable_eqn
 688    :: InstOrigin -> [TyVar] -> Class
 689    -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
 690    -> TcM EarlyDerivSpec
 691 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 692   | getName cls `elem` typeableClassNames
 693   = mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 694
 695   | otherwise
 696   = do  { dfun_name <- new_dfun_name cls tycon
 697         ; loc <- getSrcSpanM
 698         ; let inst_tys = [mkTyConApp tycon tc_args]
 699               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
 700               spec = DS { ds_loc = loc, ds_orig = orig
 701                         , ds_name = dfun_name, ds_tvs = tvs
 702                         , ds_cls = cls, ds_tys = inst_tys
 703                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 704                         , ds_theta =  mtheta `orElse` inferred_constraints
 705                         , ds_newtype = False }
 706
 707         ; return (if isJust mtheta then Right spec      -- Specified context
 708                                    else Left spec) }    -- Infer context
 709
 710 mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 711         -- The Typeable class is special in several ways
 712         --        data T a b = ... deriving( Typeable )
 713         -- gives
 714         --        instance Typeable2 T where ...
 715         -- Notice that:
 716         -- 1. There are no constraints in the instance
 717         -- 2. There are no type variables either
 718         -- 3. The actual class we want to generate isn't necessarily
 719         --      Typeable; it depends on the arity of the type
 720   | isNothing mtheta    -- deriving on a data type decl
 721   = do  { checkTc (cls `hasKey` typeableClassKey)
 722                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
 723         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 724         ; mk_typeable_eqn orig tvs real_cls tycon [] rep_tc [] (Just []) }
 725
 726   | otherwise           -- standaone deriving
 727   = do  { checkTc (null tc_args)
 728                   (ptext (sLit "Derived typeable instance must be of form (Typeable")
 729                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
 730         ; dfun_name <- new_dfun_name cls tycon
 731         ; loc <- getSrcSpanM
 732         ; return (Right $
 733                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
 734                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
 735                      , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 736                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
 737
 738
 739 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
 740 -- Generate a sufficiently large set of constraints that typechecking the
 741 -- generated method definitions should succeed.   This set will be simplified
 742 -- before being used in the instance declaration
 743 inferConstraints _ cls inst_tys rep_tc rep_tc_args
 744   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
 745     stupid_constraints ++ extra_constraints
 746     ++ sc_constraints ++ con_arg_constraints
 747   where
 748        -- Constraints arising from the arguments of each constructor
 749     con_arg_constraints
 750       = [ mkClassPred cls [arg_ty]
 751         | data_con <- tyConDataCons rep_tc,
 752           arg_ty   <- ASSERT( isVanillaDataCon data_con )
 753                         get_constrained_tys $
 754                         dataConInstOrigArgTys data_con all_rep_tc_args,
 755           not (isUnLiftedType arg_ty) ]
 756                 -- No constraints for unlifted types
 757                 -- Where they are legal we generate specilised function calls
 758
 759                 -- For functor-like classes, two things are different
 760                 -- (a) We recurse over argument types to generate constraints
 761                 --     See Functor examples in TcGenDeriv
 762                 -- (b) The rep_tc_args will be one short
 763     is_functor_like = getUnique cls `elem` functorLikeClassKeys
 764
 765     get_constrained_tys :: [Type] -> [Type]
 766     get_constrained_tys tys
 767         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
 768         | otherwise       = tys
 769
 770     rep_tc_tvs = tyConTyVars rep_tc
 771     last_tv = last rep_tc_tvs
 772     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
 773                     | otherwise       = rep_tc_args
 774
 775         -- Constraints arising from superclasses
 776         -- See Note [Superclasses of derived instance]
 777     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
 778                                 (classSCTheta cls)
 779
 780         -- Stupid constraints
 781     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
 782     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
 783
 784         -- Extra Data constraints
 785         -- The Data class (only) requires that for
 786         --    instance (...) => Data (T t1 t2)
 787         -- IF   t1:*, t2:*
 788         -- THEN (Data t1, Data t2) are among the (...) constraints
 789         -- Reason: when the IF holds, we generate a method
 790         --             dataCast2 f = gcast2 f
 791         --         and we need the Data constraints to typecheck the method
 792     extra_constraints
 793       | cls `hasKey` dataClassKey
 794       , all (isLiftedTypeKind . typeKind) rep_tc_args
 795       = [mkClassPred cls [ty] | ty <- rep_tc_args]
 796       | otherwise
 797       = []
 798
 799 ------------------------------------------------------------------
 800 -- Check side conditions that dis-allow derivability for particular classes
 801 -- This is *apart* from the newtype-deriving mechanism
 802 --
 803 -- Here we get the representation tycon in case of family instances as it has
 804 -- the data constructors - but we need to be careful to fall back to the
 805 -- family tycon (with indexes) in error messages.
 806
 807 data DerivStatus = CanDerive
 808                  | DerivableClassError SDoc     -- Standard class, but can't do it
 809                  | NonDerivableClass            -- Non-standard class
 810
 811 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
 812 checkSideConditions dflags mtheta cls cls_tys rep_tc
 813   | Just cond <- sideConditions mtheta cls
 814   = case (cond (dflags, rep_tc)) of
 815         Just err -> DerivableClassError err     -- Class-specific error
 816         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
 817                                                 -- cls_tys (the type args other than last)
 818                                                 -- should be null
 819                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
 820   | otherwise = NonDerivableClass       -- Not a standard class
 821   where
 822     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
 823
 824 nonStdErr :: Class -> SDoc
 825 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
 826
 827 sideConditions :: DerivContext -> Class -> Maybe Condition
 828 sideConditions mtheta cls
 829   | cls_key == eqClassKey          = Just cond_std
 830   | cls_key == ordClassKey         = Just cond_std
 831   | cls_key == showClassKey        = Just cond_std
 832   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
 833   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
 834   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
 835   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
 836   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond`
 837                                            cond_std `andCond` cond_noUnliftedArgs)
 838   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
 839                                            cond_functorOK True)  -- NB: no cond_std!
 840   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
 841                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
 842   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
 843                                            cond_functorOK False)
 844   | getName cls `elem` typeableClassNames = Just (checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK)
 845   | otherwise = Nothing
 846   where
 847     cls_key = getUnique cls
 848     cond_std = cond_stdOK mtheta
 849
 850 type Condition = (DynFlags, TyCon) -> Maybe SDoc
 851         -- first Bool is whether or not we are allowed to derive Data and Typeable
 852         -- second Bool is whether or not we are allowed to derive Functor
 853         -- TyCon is the *representation* tycon if the
 854         --      data type is an indexed one
 855         -- Nothing => OK
 856
 857 orCond :: Condition -> Condition -> Condition
 858 orCond c1 c2 tc
 859   = case c1 tc of
 860         Nothing -> Nothing              -- c1 succeeds
 861         Just x  -> case c2 tc of        -- c1 fails
 862                      Nothing -> Nothing
 863                      Just y  -> Just (x $$ ptext (sLit "  and") $$ y)
 864                                         -- Both fail
 865
 866 andCond :: Condition -> Condition -> Condition
 867 andCond c1 c2 tc = case c1 tc of
 868                      Nothing -> c2 tc   -- c1 succeeds
 869                      Just x  -> Just x  -- c1 fails
 870
 871 cond_stdOK :: DerivContext -> Condition
 872 cond_stdOK (Just _) _
 873   = Nothing     -- Don't check these conservative conditions for
 874                 -- standalone deriving; just generate the code
 875 cond_stdOK Nothing (_, rep_tc)
 876   | null data_cons      = Just (no_cons_why $$ suggestion)
 877   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
 878   | otherwise           = Nothing
 879   where
 880     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
 881     data_cons   = tyConDataCons rep_tc
 882     no_cons_why = quotes (pprSourceTyCon rep_tc) <+>
 883                   ptext (sLit "has no data constructors")
 884
 885     con_whys = mapCatMaybes check_con data_cons
 886
 887     check_con :: DataCon -> Maybe SDoc
 888     check_con con
 889       | isVanillaDataCon con
 890       , all isTauTy (dataConOrigArgTys con) = Nothing
 891       | otherwise = Just (badCon con (ptext (sLit "does not have a Haskell-98 type")))
 892
 893 cond_enumOrProduct :: Condition
 894 cond_enumOrProduct = cond_isEnumeration `orCond`
 895                        (cond_isProduct `andCond` cond_noUnliftedArgs)
 896
 897 cond_noUnliftedArgs :: Condition
 898 -- For some classes (eg Eq, Ord) we allow unlifted arg types
 899 -- by generating specilaised code.  For others (eg Data) we don't.
 900 cond_noUnliftedArgs (_, tc)
 901   | null bad_cons = Nothing
 902   | otherwise     = Just why
 903   where
 904     bad_cons = [ con | con <- tyConDataCons tc
 905                      , any isUnLiftedType (dataConOrigArgTys con) ]
 906     why = badCon (head bad_cons) (ptext (sLit "has arguments of unlifted type"))
 907
 908 cond_isEnumeration :: Condition
 909 cond_isEnumeration (_, rep_tc)
 910   | isEnumerationTyCon rep_tc = Nothing
 911   | otherwise                 = Just why
 912   where
 913     why = quotes (pprSourceTyCon rep_tc) <+>
 914           ptext (sLit "has non-nullary constructors")
 915
 916 cond_isProduct :: Condition
 917 cond_isProduct (_, rep_tc)
 918   | isProductTyCon rep_tc = Nothing
 919   | otherwise             = Just why
 920   where
 921     why = quotes (pprSourceTyCon rep_tc) <+>
 922           ptext (sLit "has more than one constructor")
 923
 924 cond_typeableOK :: Condition
 925 -- OK for Typeable class
 926 -- Currently: (a) args all of kind *
 927 --            (b) 7 or fewer args
 928 cond_typeableOK (_, rep_tc)
 929   | tyConArity rep_tc > 7       = Just too_many
 930   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars rep_tc))
 931                                 = Just bad_kind
 932   | isFamInstTyCon rep_tc       = Just fam_inst  -- no Typable for family insts
 933   | otherwise                   = Nothing
 934   where
 935     too_many = quotes (pprSourceTyCon rep_tc) <+>
 936                ptext (sLit "has too many arguments")
 937     bad_kind = quotes (pprSourceTyCon rep_tc) <+>
 938                ptext (sLit "has arguments of kind other than `*'")
 939     fam_inst = quotes (pprSourceTyCon rep_tc) <+>
 940                ptext (sLit "is a type family")
 941
 942
 943 functorLikeClassKeys :: [Unique]
 944 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
 945
 946 cond_functorOK :: Bool -> Condition
 947 -- OK for Functor class
 948 -- Currently: (a) at least one argument
 949 --            (b) don't use argument contravariantly
 950 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
 951 --            (d) optionally: don't use function types
 952 cond_functorOK allowFunctions (dflags, rep_tc)
 953   | not (dopt Opt_DeriveFunctor dflags)
 954   = Just (ptext (sLit "You need -XDeriveFunctor to derive an instance for this class"))
 955   | otherwise
 956   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
 957   where
 958     data_cons = tyConDataCons rep_tc
 959     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
 960
 961     check_vanilla :: DataCon -> Maybe SDoc
 962     check_vanilla con | isVanillaDataCon con = Nothing
 963                       | otherwise            = Just (badCon con existential)
 964
 965     ft_check :: DataCon -> FFoldType (Maybe SDoc)
 966     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
 967                       , ft_co_var = Just (badCon con covariant)
 968                       , ft_fun = \x y -> if allowFunctions then x `mplus` y
 969                                                            else Just (badCon con functions)
 970                       , ft_tup = \_ xs  -> msum xs
 971                       , ft_ty_app = \_ x   -> x
 972                       , ft_bad_app = Just (badCon con wrong_arg)
 973                       , ft_forall = \_ x   -> x }
 974
 975     existential = ptext (sLit "has existential arguments")
 976     covariant   = ptext (sLit "uses the type variable in a function argument")
 977     functions   = ptext (sLit "contains function types")
 978     wrong_arg   = ptext (sLit "uses the type variable in an argument other than the last")
 979
 980 checkFlag :: LanguageFlag -> Condition
 981 checkFlag flag (dflags, _)
 982   | dopt flag dflags = Nothing
 983   | otherwise        = Just why
 984   where
 985     why = ptext (sLit "You need -X") <> text flag_str
 986           <+> ptext (sLit "to derive an instance for this class")
 987     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
 988                  [s]   -> s
 989                  other -> pprPanic "checkFlag" (ppr other)
 990
 991 std_class_via_iso :: Class -> Bool
 992 -- These standard classes can be derived for a newtype
 993 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
 994 -- because giving so gives the same results as generating the boilerplate
 995 std_class_via_iso clas
 996   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
 997         -- Not Read/Show because they respect the type
 998         -- Not Enum, because newtypes are never in Enum
 999
1000
1001 non_iso_class :: Class -> Bool
1002 -- *Never* derive Read,Show,Typeable,Data by isomorphism,
1003 -- even with -XGeneralizedNewtypeDeriving
1004 non_iso_class cls
1005   = classKey cls `elem` ([readClassKey, showClassKey, dataClassKey] ++
1006                          typeableClassKeys)
1007
1008 typeableClassKeys :: [Unique]
1009 typeableClassKeys = map getUnique typeableClassNames
1010
1011 new_dfun_name :: Class -> TyCon -> TcM Name
1012 new_dfun_name clas tycon        -- Just a simple wrapper
1013   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1014         ; newDFunName clas [mkTyConApp tycon []] loc }
1015         -- The type passed to newDFunName is only used to generate
1016         -- a suitable string; hence the empty type arg list
1017
1018 badCon :: DataCon -> SDoc -> SDoc
1019 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1020 \end{code}
1021
1022 Note [Superclasses of derived instance]
1023 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1024 In general, a derived instance decl needs the superclasses of the derived
1025 class too.  So if we have
1026         data T a = ...deriving( Ord )
1027 then the initial context for Ord (T a) should include Eq (T a).  Often this is
1028 redundant; we'll also generate an Ord constraint for each constructor argument,
1029 and that will probably generate enough constraints to make the Eq (T a) constraint
1030 be satisfied too.  But not always; consider:
1031
1032  data S a = S
1033  instance Eq (S a)
1034  instance Ord (S a)
1035
1036  data T a = MkT (S a) deriving( Ord )
1037  instance Num a => Eq (T a)
1038
1039 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1040 Similarly consider:
1041         data T a = MkT deriving( Data, Typeable )
1042 Here there *is* no argument field, but we must nevertheless generate
1043 a context for the Data instances:
1044         instance Typable a => Data (T a) where ...
1045
1046
1047 %************************************************************************
1048 %*                                                                      *
1049                 Deriving newtypes
1050 %*                                                                      *
1051 %************************************************************************
1052
1053 \begin{code}
1054 mkNewTypeEqn :: InstOrigin -> DynFlags -> [Var] -> Class
1055              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1056              -> DerivContext
1057              -> TcRn EarlyDerivSpec
1058 mkNewTypeEqn orig dflags tvs
1059              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1060 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1061   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1062   = do  { traceTc (text "newtype deriving:" <+> ppr tycon <+> ppr rep_tys)
1063         ; dfun_name <- new_dfun_name cls tycon
1064         ; loc <- getSrcSpanM
1065         ; let spec = DS { ds_loc = loc, ds_orig = orig
1066                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs
1067                         , ds_cls = cls, ds_tys = inst_tys
1068                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1069                         , ds_theta =  mtheta `orElse` all_preds
1070                         , ds_newtype = True }
1071         ; return (if isJust mtheta then Right spec
1072                                    else Left spec) }
1073
1074   | otherwise
1075   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1076       CanDerive -> go_for_it    -- Use the standard H98 method
1077       DerivableClassError msg   -- Error with standard class
1078         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1079         | otherwise                  -> bale_out msg
1080       NonDerivableClass         -- Must use newtype deriving
1081         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1082         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1083         | otherwise                  -> bale_out non_std
1084   where
1085         newtype_deriving = dopt Opt_GeneralizedNewtypeDeriving dflags
1086         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1087         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1088
1089         non_std    = nonStdErr cls
1090         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1091
1092         -- Here is the plan for newtype derivings.  We see
1093         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1094         -- where t is a type,
1095         --       ak+1...an is a suffix of a1..an, and are all tyars
1096         --       ak+1...an do not occur free in t, nor in the s1..sm
1097         --       (C s1 ... sm) is a  *partial applications* of class C
1098         --                      with the last parameter missing
1099         --       (T a1 .. ak) matches the kind of C's last argument
1100         --              (and hence so does t)
1101         -- The latter kind-check has been done by deriveTyData already,
1102         -- and tc_args are already trimmed
1103         --
1104         -- We generate the instance
1105         --       instance forall ({a1..ak} u fvs(s1..sm)).
1106         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1107         -- where T a1...ap is the partial application of
1108         --       the LHS of the correct kind and p >= k
1109         --
1110         --      NB: the variables below are:
1111         --              tc_tvs = [a1, ..., an]
1112         --              tyvars_to_keep = [a1, ..., ak]
1113         --              rep_ty = t ak .. an
1114         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1115         --              tys = [s1, ..., sm]
1116         --              rep_fn' = t
1117         --
1118         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1119         -- We generate the instance
1120         --      instance Monad (ST s) => Monad (T s) where
1121
1122         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1123                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1124                 -- eta-reduces the representation type, so we know that
1125                 --      T a ~ S a a
1126                 -- That's convenient here, because we may have to apply
1127                 -- it to fewer than its original complement of arguments
1128
1129         -- Note [Newtype representation]
1130         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1131         -- Need newTyConRhs (*not* a recursive representation finder)
1132         -- to get the representation type. For example
1133         --      newtype B = MkB Int
1134         --      newtype A = MkA B deriving( Num )
1135         -- We want the Num instance of B, *not* the Num instance of Int,
1136         -- when making the Num instance of A!
1137         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1138         rep_tys     = cls_tys ++ [rep_inst_ty]
1139         rep_pred    = mkClassPred cls rep_tys
1140                 -- rep_pred is the representation dictionary, from where
1141                 -- we are gong to get all the methods for the newtype
1142                 -- dictionary
1143
1144
1145     -- Next we figure out what superclass dictionaries to use
1146     -- See Note [Newtype deriving superclasses] above
1147
1148         cls_tyvars = classTyVars cls
1149         dfun_tvs = tyVarsOfTypes inst_tys
1150         inst_ty = mkTyConApp tycon tc_args
1151         inst_tys = cls_tys ++ [inst_ty]
1152         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1153                               (classSCTheta cls)
1154
1155                 -- If there are no tyvars, there's no need
1156                 -- to abstract over the dictionaries we need
1157                 -- Example:     newtype T = MkT Int deriving( C )
1158                 -- We get the derived instance
1159                 --              instance C T
1160                 -- rather than
1161                 --              instance C Int => C T
1162         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1163
1164         -------------------------------------------------------------------
1165         --  Figuring out whether we can only do this newtype-deriving thing
1166
1167         can_derive_via_isomorphism
1168            =  not (non_iso_class cls)
1169            && arity_ok
1170            && eta_ok
1171            && ats_ok
1172 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1173
1174         arity_ok = length cls_tys + 1 == classArity cls
1175                 -- Well kinded; eg not: newtype T ... deriving( ST )
1176                 --                      because ST needs *2* type params
1177
1178         -- Check that eta reduction is OK
1179         eta_ok = nt_eta_arity <= length rep_tc_args
1180                 -- The newtype can be eta-reduced to match the number
1181                 --     of type argument actually supplied
1182                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1183                 --     Here the 'b' must be the same in the rep type (S [a] b)
1184                 --     And the [a] must not mention 'b'.  That's all handled
1185                 --     by nt_eta_rity.
1186
1187         ats_ok = null (classATs cls)
1188                -- No associated types for the class, because we don't
1189                -- currently generate type 'instance' decls; and cannot do
1190                -- so for 'data' instance decls
1191
1192         cant_derive_err
1193            = vcat [ ppUnless arity_ok arity_msg
1194                   , ppUnless eta_ok eta_msg
1195                   , ppUnless ats_ok ats_msg ]
1196         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1197         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1198         ats_msg   = ptext (sLit "the class has associated types")
1199 \end{code}
1200
1201 Note [Recursive newtypes]
1202 ~~~~~~~~~~~~~~~~~~~~~~~~~
1203 Newtype deriving works fine, even if the newtype is recursive.
1204 e.g.    newtype S1 = S1 [T1 ()]
1205         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1206 Remember, too, that type families are curretly (conservatively) given
1207 a recursive flag, so this also allows newtype deriving to work
1208 for type famillies.
1209
1210 We used to exclude recursive types, because we had a rather simple
1211 minded way of generating the instance decl:
1212    newtype A = MkA [A]
1213    instance Eq [A] => Eq A      -- Makes typechecker loop!
1214 But now we require a simple context, so it's ok.
1215
1216
1217 %************************************************************************
1218 %*                                                                      *
1219 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1220 %*                                                                      *
1221 %************************************************************************
1222
1223 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1224 terms, which is the final correct RHS for the corresponding original
1225 equation.
1226 \begin{itemize}
1227 \item
1228 Each (k,TyVarTy tv) in a solution constrains only a type
1229 variable, tv.
1230
1231 \item
1232 The (k,TyVarTy tv) pairs in a solution are canonically
1233 ordered by sorting on type varible, tv, (major key) and then class, k,
1234 (minor key)
1235 \end{itemize}
1236
1237 \begin{code}
1238 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1239
1240 inferInstanceContexts _ [] = return []
1241
1242 inferInstanceContexts oflag infer_specs
1243   = do  { traceTc (text "inferInstanceContexts" <+> vcat (map pprDerivSpec infer_specs))
1244         ; iterate_deriv 1 initial_solutions }
1245   where
1246     ------------------------------------------------------------------
1247         -- The initial solutions for the equations claim that each
1248         -- instance has an empty context; this solution is certainly
1249         -- in canonical form.
1250     initial_solutions :: [ThetaType]
1251     initial_solutions = [ [] | _ <- infer_specs ]
1252
1253     ------------------------------------------------------------------
1254         -- iterate_deriv calculates the next batch of solutions,
1255         -- compares it with the current one; finishes if they are the
1256         -- same, otherwise recurses with the new solutions.
1257         -- It fails if any iteration fails
1258     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1259     iterate_deriv n current_solns
1260       | n > 20  -- Looks as if we are in an infinite loop
1261                 -- This can happen if we have -XUndecidableInstances
1262                 -- (See TcSimplify.tcSimplifyDeriv.)
1263       = pprPanic "solveDerivEqns: probable loop"
1264                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1265       | otherwise
1266       = do {      -- Extend the inst info from the explicit instance decls
1267                   -- with the current set of solutions, and simplify each RHS
1268              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1269                                            current_solns infer_specs
1270            ; new_solns <- checkNoErrs $
1271                           extendLocalInstEnv inst_specs $
1272                           mapM gen_soln infer_specs
1273
1274            ; if (current_solns == new_solns) then
1275                 return [ spec { ds_theta = soln }
1276                        | (spec, soln) <- zip infer_specs current_solns ]
1277              else
1278                 iterate_deriv (n+1) new_solns }
1279
1280     ------------------------------------------------------------------
1281     gen_soln :: DerivSpec  -> TcM [PredType]
1282     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars
1283                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1284       = setSrcSpan loc  $
1285         addErrCtxt (derivInstCtxt clas inst_tys) $
1286         do { theta <- tcSimplifyDeriv orig tyvars deriv_rhs
1287                 -- checkValidInstance tyvars theta clas inst_tys
1288                 -- Not necessary; see Note [Exotic derived instance contexts]
1289                 --                in TcSimplify
1290
1291                   -- Check for a bizarre corner case, when the derived instance decl should
1292                   -- have form  instance C a b => D (T a) where ...
1293                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1294                   -- of problems; in particular, it's hard to compare solutions for
1295                   -- equality when finding the fixpoint.  So I just rule it out for now.
1296            ; let tv_set = mkVarSet tyvars
1297                  weird_preds = [pred | pred <- theta, not (tyVarsOfPred pred `subVarSet` tv_set)]
1298            ; mapM_ (addErrTc . badDerivedPred) weird_preds
1299
1300            ; traceTc (text "TcDeriv" <+> (ppr deriv_rhs $$ ppr theta))
1301                 -- Claim: the result instance declaration is guaranteed valid
1302                 -- Hence no need to call:
1303                 --   checkValidInstance tyvars theta clas inst_tys
1304            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1305
1306 ------------------------------------------------------------------
1307 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1308 mkInstance overlap_flag theta
1309             (DS { ds_name = dfun_name
1310                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1311   = mkLocalInstance dfun overlap_flag
1312   where
1313     dfun = mkDictFunId dfun_name tyvars theta clas tys
1314
1315
1316 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1317 -- Add new locally-defined instances; don't bother to check
1318 -- for functional dependency errors -- that'll happen in TcInstDcls
1319 extendLocalInstEnv dfuns thing_inside
1320  = do { env <- getGblEnv
1321       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1322              env'      = env { tcg_inst_env = inst_env' }
1323       ; setGblEnv env' thing_inside }
1324 \end{code}
1325
1326
1327 %************************************************************************
1328 %*                                                                      *
1329 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1330 %*                                                                      *
1331 %************************************************************************
1332
1333 After all the trouble to figure out the required context for the
1334 derived instance declarations, all that's left is to chug along to
1335 produce them.  They will then be shoved into @tcInstDecls2@, which
1336 will do all its usual business.
1337
1338 There are lots of possibilities for code to generate.  Here are
1339 various general remarks.
1340
1341 PRINCIPLES:
1342 \begin{itemize}
1343 \item
1344 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1345 ``you-couldn't-do-better-by-hand'' efficient.
1346
1347 \item
1348 Deriving @Show@---also pretty common--- should also be reasonable good code.
1349
1350 \item
1351 Deriving for the other classes isn't that common or that big a deal.
1352 \end{itemize}
1353
1354 PRAGMATICS:
1355
1356 \begin{itemize}
1357 \item
1358 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1359
1360 \item
1361 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1362
1363 \item
1364 We {\em normally} generate code only for the non-defaulted methods;
1365 there are some exceptions for @Eq@ and (especially) @Ord@...
1366
1367 \item
1368 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1369 constructor's numeric (@Int#@) tag.  These are generated by
1370 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1371 these is around is given by @hasCon2TagFun@.
1372
1373 The examples under the different sections below will make this
1374 clearer.
1375
1376 \item
1377 Much less often (really just for deriving @Ix@), we use a
1378 @_tag2con_<tycon>@ function.  See the examples.
1379
1380 \item
1381 We use the renamer!!!  Reason: we're supposed to be
1382 producing @LHsBinds Name@ for the methods, but that means
1383 producing correctly-uniquified code on the fly.  This is entirely
1384 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1385 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1386 the renamer.  What a great hack!
1387 \end{itemize}
1388
1389 \begin{code}
1390 -- Generate the InstInfo for the required instance paired with the
1391 --   *representation* tycon for that instance,
1392 -- plus any auxiliary bindings required
1393 --
1394 -- Representation tycons differ from the tycon in the instance signature in
1395 -- case of instances for indexed families.
1396 --
1397 genInst :: Bool         -- True <=> standalone deriving
1398         -> OverlapFlag
1399         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1400 genInst standalone_deriv oflag spec
1401   | ds_newtype spec
1402   = return (InstInfo { iSpec  = mkInstance oflag (ds_theta spec) spec
1403                      , iBinds = NewTypeDerived co rep_tycon }, [])
1404
1405   | otherwise
1406   = do  { let loc  = getSrcSpan (ds_name spec)
1407               inst = mkInstance oflag (ds_theta spec) spec
1408               clas = ds_cls spec
1409
1410           -- In case of a family instance, we need to use the representation
1411           -- tycon (after all, it has the data constructors)
1412         ; fix_env <- getFixityEnv
1413         ; let (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1414               binds = VanillaInst meth_binds [] standalone_deriv
1415         ; return (InstInfo { iSpec = inst, iBinds = binds }, aux_binds)
1416         }
1417   where
1418     rep_tycon   = ds_tc spec
1419     rep_tc_args = ds_tc_args spec
1420     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1421               Nothing     -> IdCo
1422               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1423     co2 = case newTyConCo_maybe rep_tycon of
1424               Nothing     -> IdCo       -- The newtype is transparent; no need for a cast
1425               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1426     co = co1 `mkTransCoI` co2
1427
1428 -- Example: newtype instance N [a] = N1 (Tree a)
1429 --          deriving instance Eq b => Eq (N [(b,b)])
1430 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1431 -- When dealing with the deriving clause
1432 --    co1 : N [(b,b)] ~ R1:N (b,b)
1433 --    co2 : R1:N (b,b) ~ Tree (b,b)
1434 --    co  : N [(b,b)] ~ Tree (b,b)
1435
1436 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1437 genDerivBinds loc fix_env clas tycon
1438   | className clas `elem` typeableClassNames
1439   = (gen_Typeable_binds loc tycon, [])
1440
1441   | otherwise
1442   = case assocMaybe gen_list (getUnique clas) of
1443         Just gen_fn -> gen_fn loc tycon
1444         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1445   where
1446     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1447     gen_list = [(eqClassKey,       gen_Eq_binds)
1448                ,(ordClassKey,      gen_Ord_binds)
1449                ,(enumClassKey,     gen_Enum_binds)
1450                ,(boundedClassKey,  gen_Bounded_binds)
1451                ,(ixClassKey,       gen_Ix_binds)
1452                ,(showClassKey,     gen_Show_binds fix_env)
1453                ,(readClassKey,     gen_Read_binds fix_env)
1454                ,(dataClassKey,     gen_Data_binds)
1455                ,(functorClassKey,  gen_Functor_binds)
1456                ,(foldableClassKey, gen_Foldable_binds)
1457                ,(traversableClassKey, gen_Traversable_binds)
1458                ]
1459 \end{code}
1460
1461
1462 %************************************************************************
1463 %*                                                                      *
1464 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1465 %*                                                                      *
1466 %************************************************************************
1467
1468 \begin{code}
1469 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1470 derivingKindErr tc cls cls_tys cls_kind
1471   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1472                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1473        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1474             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1475
1476 derivingEtaErr :: Class -> [Type] -> Type -> Message
1477 derivingEtaErr cls cls_tys inst_ty
1478   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1479          nest 2 (ptext (sLit "instance (...) =>")
1480                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1481
1482 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1483 typeFamilyPapErr tc cls cls_tys inst_ty
1484   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1485        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc)
1486
1487 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1488 derivingThingErr newtype_deriving clas tys ty why
1489   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1490              2 (quotes (ppr pred))
1491           $$ nest 2 extra) <> colon,
1492          nest 2 why]
1493   where
1494     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1495           | otherwise        = empty
1496     pred = mkClassPred clas (tys ++ [ty])
1497
1498 derivingHiddenErr :: TyCon -> SDoc
1499 derivingHiddenErr tc
1500   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1501        2 (ptext (sLit "so you cannot derive an instance for it"))
1502
1503 standaloneCtxt :: LHsType Name -> SDoc
1504 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
1505                        2 (quotes (ppr ty))
1506
1507 derivInstCtxt :: Class -> [Type] -> Message
1508 derivInstCtxt clas inst_tys
1509   = ptext (sLit "When deriving the instance for") <+> parens (pprClassPred clas inst_tys)
1510
1511 badDerivedPred :: PredType -> Message
1512 badDerivedPred pred
1513   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1514           ptext (sLit "type variables that are not data type parameters"),
1515           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1516 \end{code}