compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import ErrUtils
  34 import MkId
  35 import DataCon
  36 import Maybes
  37 import RdrName
  38 import Name
  39 import NameSet
  40 import TyCon
  41 import TcType
  42 import Var
  43 import VarSet
  44 import PrelNames
  45 import SrcLoc
  46 import Util
  47 import ListSetOps
  48 import Outputable
  49 import Bag
  50 \end{code}
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 Consider
  59
  60         data T a b = C1 (Foo a) (Bar b)
  61                    | C2 Int (T b a)
  62                    | C3 (T a a)
  63                    deriving (Eq)
  64
  65 [NOTE: See end of these comments for what to do with
  66         data (C a, D b) => T a b = ...
  67 ]
  68
  69 We want to come up with an instance declaration of the form
  70
  71         instance (Ping a, Pong b, ...) => Eq (T a b) where
  72                 x == y = ...
  73
  74 It is pretty easy, albeit tedious, to fill in the code "...".  The
  75 trick is to figure out what the context for the instance decl is,
  76 namely @Ping@, @Pong@ and friends.
  77
  78 Let's call the context reqd for the T instance of class C at types
  79 (a,b, ...)  C (T a b).  Thus:
  80
  81         Eq (T a b) = (Ping a, Pong b, ...)
  82
  83 Now we can get a (recursive) equation from the @data@ decl:
  84
  85         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  86                    u Eq (T b a) u Eq Int        -- From C2
  87                    u Eq (T a a)                 -- From C3
  88
  89 Foo and Bar may have explicit instances for @Eq@, in which case we can
  90 just substitute for them.  Alternatively, either or both may have
  91 their @Eq@ instances given by @deriving@ clauses, in which case they
  92 form part of the system of equations.
  93
  94 Now all we need do is simplify and solve the equations, iterating to
  95 find the least fixpoint.  Notice that the order of the arguments can
  96 switch around, as here in the recursive calls to T.
  97
  98 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
  99
 100 We start with:
 101
 102         Eq (T a b) = {}         -- The empty set
 103
 104 Next iteration:
 105         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 106                    u Eq (T b a) u Eq Int        -- From C2
 107                    u Eq (T a a)                 -- From C3
 108
 109         After simplification:
 110                    = Eq a u Ping b u {} u {} u {}
 111                    = Eq a u Ping b
 112
 113 Next iteration:
 114
 115         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 116                    u Eq (T b a) u Eq Int        -- From C2
 117                    u Eq (T a a)                 -- From C3
 118
 119         After simplification:
 120                    = Eq a u Ping b
 121                    u (Eq b u Ping a)
 122                    u (Eq a u Ping a)
 123
 124                    = Eq a u Ping b u Eq b u Ping a
 125
 126 The next iteration gives the same result, so this is the fixpoint.  We
 127 need to make a canonical form of the RHS to ensure convergence.  We do
 128 this by simplifying the RHS to a form in which
 129
 130         - the classes constrain only tyvars
 131         - the list is sorted by tyvar (major key) and then class (minor key)
 132         - no duplicates, of course
 133
 134 So, here are the synonyms for the ``equation'' structures:
 135
 136 \begin{code}
 137 type DerivRhs  = ThetaType
 138 type DerivSoln = DerivRhs
 139 type DerivEqn  = (SrcSpan, InstOrigin, Name, [TyVar], Class, Type, DerivRhs)
 140         -- (span, orig, df, tvs, C, ty, rhs)
 141         --    implies a dfun declaration of the form
 142         --       df :: forall tvs. rhs => C ty
 143         -- The Name is the name for the DFun we'll build
 144         -- The tyvars bind all the variables in the RHS
 145         -- For family indexes, the tycon is the *family* tycon
 146         --              (not the representation tycon)
 147
 148 pprDerivEqn :: DerivEqn -> SDoc
 149 pprDerivEqn (l, _, n, tvs, c, ty, rhs)
 150   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr ty]
 151             <+> equals <+> ppr rhs)
 152 \end{code}
 153
 154
 155 [Data decl contexts] A note about contexts on data decls
 156 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 157 Consider
 158
 159         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 160
 161 We will need an instance decl like:
 162
 163         instance (Read a, RealFloat a) => Read (Complex a) where
 164           ...
 165
 166 The RealFloat in the context is because the read method for Complex is bound
 167 to construct a Complex, and doing that requires that the argument type is
 168 in RealFloat.
 169
 170 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 171 a Complex; they only take them apart.
 172
 173 Our approach: identify the offending classes, and add the data type
 174 context to the instance decl.  The "offending classes" are
 175
 176         Read, Enum?
 177
 178 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 179 pattern matching against a constructor from a data type with a context
 180 gives rise to the constraints for that context -- or at least the thinned
 181 version.  So now all classes are "offending".
 182
 183 [Newtype deriving]
 184 ~~~~~~~~~~~~~~~~~~
 185 Consider this:
 186     class C a b
 187     instance C [a] Char
 188     newtype T = T Char deriving( C [a] )
 189
 190 Notice the free 'a' in the deriving.  We have to fill this out to
 191     newtype T = T Char deriving( forall a. C [a] )
 192
 193 And then translate it to:
 194     instance C [a] Char => C [a] T where ...
 195
 196
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcDeriving  :: [LTyClDecl Name] -- All type constructors
 207             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 208             -> TcM ([InstInfo],         -- The generated "instance decls"
 209                     HsValBinds Name)    -- Extra generated top-level bindings
 210
 211 tcDeriving tycl_decls deriv_decls
 212   = recoverM (returnM ([], emptyValBindsOut)) $
 213     do  {       -- Fish the "deriving"-related information out of the TcEnv
 214                 -- and make the necessary "equations".
 215         ; (ordinary_eqns, newtype_inst_info) <- makeDerivEqns tycl_decls deriv_decls
 216
 217         ; (ordinary_inst_info, deriv_binds)
 218                 <- extendLocalInstEnv (map iSpec newtype_inst_info)  $
 219                    deriveOrdinaryStuff ordinary_eqns
 220                 -- Add the newtype-derived instances to the inst env
 221                 -- before tacking the "ordinary" ones
 222
 223         ; let inst_info = newtype_inst_info ++ ordinary_inst_info
 224
 225         -- If we are compiling a hs-boot file,
 226         -- don't generate any derived bindings
 227         ; is_boot <- tcIsHsBoot
 228         ; if is_boot then
 229                 return (inst_info, emptyValBindsOut)
 230           else do
 231         {
 232
 233         -- Generate the generic to/from functions from each type declaration
 234         ; gen_binds <- mkGenericBinds tycl_decls
 235
 236         -- Rename these extra bindings, discarding warnings about unused bindings etc
 237         -- Set -fglasgow exts so that we can have type signatures in patterns,
 238         -- which is used in the generic binds
 239         ; rn_binds
 240                 <- discardWarnings $ setOptM Opt_GlasgowExts $ do
 241                         { (rn_deriv, _dus1) <- rnTopBinds (ValBindsIn deriv_binds [])
 242                         ; (rn_gen, dus_gen) <- rnTopBinds (ValBindsIn gen_binds   [])
 243                         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to
 244                                                                 -- be kept alive
 245                         ; return (rn_deriv `plusHsValBinds` rn_gen) }
 246
 247
 248         ; dflags <- getDOpts
 249         ; ioToTcRn (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 250                    (ddump_deriving inst_info rn_binds))
 251
 252         ; returnM (inst_info, rn_binds)
 253         }}
 254   where
 255     ddump_deriving :: [InstInfo] -> HsValBinds Name -> SDoc
 256     ddump_deriving inst_infos extra_binds
 257       = vcat (map pprInstInfoDetails inst_infos) $$ ppr extra_binds
 258
 259 -----------------------------------------
 260 deriveOrdinaryStuff []  -- Short cut
 261   = returnM ([], emptyLHsBinds)
 262
 263 deriveOrdinaryStuff eqns
 264   = do  {       -- Take the equation list and solve it, to deliver a list of
 265                 -- solutions, a.k.a. the contexts for the instance decls
 266                 -- required for the corresponding equations.
 267           overlap_flag <- getOverlapFlag
 268         ; inst_specs <- solveDerivEqns overlap_flag eqns
 269
 270         -- Generate the InstInfo for each dfun,
 271         -- plus any auxiliary bindings it needs
 272         ; (inst_infos, aux_binds_s) <- mapAndUnzipM genInst inst_specs
 273
 274         -- Generate any extra not-one-inst-decl-specific binds,
 275         -- notably "con2tag" and/or "tag2con" functions.
 276         ; extra_binds <- genTaggeryBinds inst_infos
 277
 278         -- Done
 279         ; returnM (map fst inst_infos,
 280                    unionManyBags (extra_binds : aux_binds_s))
 281    }
 282
 283 -----------------------------------------
 284 mkGenericBinds tycl_decls
 285   = do  { tcs <- mapM tcLookupTyCon
 286                         [ tc_name |
 287                           L _ (TyData { tcdLName = L _ tc_name }) <- tycl_decls]
 288                 -- We are only interested in the data type declarations
 289         ; return (unionManyBags [ mkTyConGenericBinds tc |
 290                                   tc <- tcs, tyConHasGenerics tc ]) }
 291                 -- And then only in the ones whose 'has-generics' flag is on
 292 \end{code}
 293
 294
 295 %************************************************************************
 296 %*                                                                      *
 297 \subsection[TcDeriv-eqns]{Forming the equations}
 298 %*                                                                      *
 299 %************************************************************************
 300
 301 @makeDerivEqns@ fishes around to find the info about needed derived
 302 instances.  Complicating factors:
 303 \begin{itemize}
 304 \item
 305 We can only derive @Enum@ if the data type is an enumeration
 306 type (all nullary data constructors).
 307
 308 \item
 309 We can only derive @Ix@ if the data type is an enumeration {\em
 310 or} has just one data constructor (e.g., tuples).
 311 \end{itemize}
 312
 313 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 314 all those.
 315
 316 Note [Newtype deriving superclasses]
 317 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 318 The 'tys' here come from the partial application in the deriving
 319 clause. The last arg is the new instance type.
 320
 321 We must pass the superclasses; the newtype might be an instance
 322 of them in a different way than the representation type
 323 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 324 Then the Show instance is not done via isomorphism; it shows
 325         Foo 3 as "Foo 3"
 326 The Num instance is derived via isomorphism, but the Show superclass
 327 dictionary must the Show instance for Foo, *not* the Show dictionary
 328 gotten from the Num dictionary. So we must build a whole new dictionary
 329 not just use the Num one.  The instance we want is something like:
 330      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 331         (+) = ((+)@a)
 332         ...etc...
 333 There may be a coercion needed which we get from the tycon for the newtype
 334 when the dict is constructed in TcInstDcls.tcInstDecl2
 335
 336
 337 \begin{code}
 338 makeDerivEqns :: [LTyClDecl Name]
 339               -> [LDerivDecl Name]
 340               -> TcM ([DerivEqn],       -- Ordinary derivings
 341                       [InstInfo])       -- Special newtype derivings
 342
 343 makeDerivEqns tycl_decls deriv_decls
 344   = do  { eqns1 <- mapM deriveTyData $
 345                    [ (p,d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- tycl_decls
 346                            , p <- preds ]
 347         ; eqns2 <- mapM deriveStandalone deriv_decls
 348         ; return ([eqn  | (Just eqn, _)  <- eqns1 ++ eqns2],
 349                   [inst | (_, Just inst) <- eqns1 ++ eqns2]) }
 350
 351 ------------------------------------------------------------------
 352 deriveStandalone :: LDerivDecl Name -> TcM (Maybe DerivEqn, Maybe InstInfo)
 353 -- Standalone deriving declarations
 354 --      e.g.   derive instance Show T
 355 -- Rather like tcLocalInstDecl
 356 deriveStandalone (L loc (DerivDecl deriv_ty))
 357   = setSrcSpan loc                   $
 358     addErrCtxt (standaloneCtxt deriv_ty)  $
 359     do  { (tvs, theta, tau) <- tcHsInstHead deriv_ty
 360         ; (cls, inst_tys) <- checkValidInstHead tau
 361         ; let cls_tys = take (length inst_tys - 1) inst_tys
 362               inst_ty = last inst_tys
 363
 364         ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty }
 365
 366 ------------------------------------------------------------------
 367 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM (Maybe DerivEqn, Maybe InstInfo)
 368 deriveTyData (deriv_pred, L loc decl@(TyData { tcdLName = L _ tycon_name,
 369                                                tcdTyVars = tv_names,
 370                                                tcdTyPats = ty_pats }))
 371   = setSrcSpan loc                   $
 372     tcAddDeclCtxt decl               $
 373     do  { let hs_ty_args = ty_pats `orElse` map (nlHsTyVar . hsLTyVarName) tv_names
 374               hs_app     = nlHsTyConApp tycon_name hs_ty_args
 375                 -- We get kinding info for the tyvars by typechecking (T a b)
 376                 -- Hence forming a tycon application and then dis-assembling it
 377         ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 378         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 379                                         -- the type variables for the type constructor
 380     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 381                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 382                 -- newtype deriving we allow deriving (forall a. C [a]).
 383         ; mkEqnHelp DerivOrigin (tvs++deriv_tvs) cls cls_tys tc_app } }
 384 deriveTyData (deriv_pred, other_decl)
 385   = panic "derivTyData" -- Caller ensures that only TyData can happen
 386
 387 ------------------------------------------------------------------
 388 mkEqnHelp orig tvs cls cls_tys tc_app
 389   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 390   = do  {       -- Make tc_app saturated, because that's what the
 391                 -- mkDataTypeEqn things expect
 392                 -- It might not be saturated in the standalone deriving case
 393                 --      derive instance Monad (T a)
 394           let extra_tvs = dropList tc_args (tyConTyVars tycon)
 395               full_tc_args = tc_args ++ mkTyVarTys extra_tvs
 396               full_tvs = tvs ++ extra_tvs
 397
 398         ; (rep_tc, rep_tc_args) <- tcLookupFamInst tycon full_tc_args
 399
 400         ; gla_exts <- doptM Opt_GlasgowExts
 401         ; overlap_flag <- getOverlapFlag
 402
 403           -- Be careful to test rep_tc here: in the case of families, we want
 404           -- to check the instance tycon, not the family tycon
 405         ; if isDataTyCon rep_tc then
 406                 mkDataTypeEqn orig gla_exts full_tvs cls cls_tys
 407                               tycon full_tc_args rep_tc rep_tc_args
 408           else
 409                 mkNewTypeEqn  orig gla_exts overlap_flag full_tvs cls cls_tys
 410                               tycon full_tc_args rep_tc rep_tc_args }
 411   | otherwise
 412   = baleOut (derivingThingErr cls cls_tys tc_app
 413                 (ptext SLIT("Last argument of the instance must be a type application")))
 414
 415 baleOut err = addErrTc err >> returnM (Nothing, Nothing)
 416 \end{code}
 417
 418
 419 %************************************************************************
 420 %*                                                                      *
 421                 Deriving data types
 422 %*                                                                      *
 423 %************************************************************************
 424
 425 \begin{code}
 426 mkDataTypeEqn orig gla_exts tvs cls cls_tys tycon tc_args rep_tc rep_tc_args
 427   | Just err <- checkSideConditions gla_exts cls cls_tys rep_tc
 428         -- NB: pass the *representation* tycon to checkSideConditions
 429   = baleOut (derivingThingErr cls cls_tys (mkTyConApp tycon tc_args) err)
 430
 431   | otherwise
 432   = ASSERT( null cls_tys )
 433     do  { loc <- getSrcSpanM
 434         ; eqn <- mk_data_eqn loc orig tvs cls tycon tc_args rep_tc rep_tc_args
 435         ; return (Just eqn, Nothing) }
 436
 437 mk_data_eqn :: SrcSpan -> InstOrigin -> [TyVar] -> Class
 438             -> TyCon -> [TcType] -> TyCon -> [TcType] -> TcM DerivEqn
 439 mk_data_eqn loc orig tvs cls tycon tc_args rep_tc rep_tc_args
 440   | cls `hasKey` typeableClassKey
 441   =     -- The Typeable class is special in several ways
 442         --        data T a b = ... deriving( Typeable )
 443         -- gives
 444         --        instance Typeable2 T where ...
 445         -- Notice that:
 446         -- 1. There are no constraints in the instance
 447         -- 2. There are no type variables either
 448         -- 3. The actual class we want to generate isn't necessarily
 449         --      Typeable; it depends on the arity of the type
 450     do  { real_clas <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 451         ; dfun_name <- new_dfun_name real_clas tycon
 452         ; return (loc, orig, dfun_name, [], real_clas, mkTyConApp tycon [], []) }
 453
 454   | otherwise
 455   = do  { dfun_name <- new_dfun_name cls tycon
 456         ; let ordinary_constraints
 457                 = [ mkClassPred cls [arg_ty]
 458                   | data_con <- tyConDataCons rep_tc,
 459                     arg_ty   <- dataConInstOrigArgTys data_con rep_tc_args,
 460                     not (isUnLiftedType arg_ty) ] -- No constraints for unlifted types?
 461
 462               tiresome_subst = zipTopTvSubst (tyConTyVars rep_tc) rep_tc_args
 463               stupid_constraints = substTheta tiresome_subst (tyConStupidTheta rep_tc)
 464                  -- see note [Data decl contexts] above
 465
 466         ; return (loc, orig, dfun_name, tvs, cls, mkTyConApp tycon tc_args,
 467                   stupid_constraints ++ ordinary_constraints)
 468         }
 469
 470 ------------------------------------------------------------------
 471 -- Check side conditions that dis-allow derivability for particular classes
 472 -- This is *apart* from the newtype-deriving mechanism
 473 --
 474 -- Here we get the representation tycon in case of family instances as it has
 475 -- the data constructors - but we need to be careful to fall back to the
 476 -- family tycon (with indexes) in error messages.
 477
 478 checkSideConditions :: Bool -> Class -> [TcType] -> TyCon -> Maybe SDoc
 479 checkSideConditions gla_exts cls cls_tys rep_tc
 480   | notNull cls_tys
 481   = Just ty_args_why    -- e.g. deriving( Foo s )
 482   | otherwise
 483   = case [cond | (key,cond) <- sideConditions, key == getUnique cls] of
 484         []     -> Just (non_std_why cls)
 485         [cond] -> cond (gla_exts, rep_tc)
 486         other  -> pprPanic "checkSideConditions" (ppr cls)
 487   where
 488     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext SLIT("is not a class")
 489
 490 non_std_why cls = quotes (ppr cls) <+> ptext SLIT("is not a derivable class")
 491
 492 sideConditions :: [(Unique, Condition)]
 493 sideConditions
 494   = [   (eqClassKey,       cond_std),
 495         (ordClassKey,      cond_std),
 496         (readClassKey,     cond_std),
 497         (showClassKey,     cond_std),
 498         (enumClassKey,     cond_std `andCond` cond_isEnumeration),
 499         (ixClassKey,       cond_std `andCond` (cond_isEnumeration `orCond` cond_isProduct)),
 500         (boundedClassKey,  cond_std `andCond` (cond_isEnumeration `orCond` cond_isProduct)),
 501         (typeableClassKey, cond_glaExts `andCond` cond_typeableOK),
 502         (dataClassKey,     cond_glaExts `andCond` cond_std)
 503     ]
 504
 505 type Condition = (Bool, TyCon) -> Maybe SDoc
 506         -- Bool is gla-exts flag
 507         -- TyCon is the *representation* tycon if the
 508         --      data type is an indexed one
 509         -- Nothing => OK
 510
 511 orCond :: Condition -> Condition -> Condition
 512 orCond c1 c2 tc
 513   = case c1 tc of
 514         Nothing -> Nothing              -- c1 succeeds
 515         Just x  -> case c2 tc of        -- c1 fails
 516                      Nothing -> Nothing
 517                      Just y  -> Just (x $$ ptext SLIT("  and") $$ y)
 518                                         -- Both fail
 519
 520 andCond c1 c2 tc = case c1 tc of
 521                      Nothing -> c2 tc   -- c1 succeeds
 522                      Just x  -> Just x  -- c1 fails
 523
 524 cond_std :: Condition
 525 cond_std (gla_exts, rep_tc)
 526   | any (not . isVanillaDataCon) data_cons = Just existential_why
 527   | null data_cons                         = Just no_cons_why
 528   | otherwise                              = Nothing
 529   where
 530     data_cons       = tyConDataCons rep_tc
 531     no_cons_why     = quotes (pprSourceTyCon rep_tc) <+>
 532                       ptext SLIT("has no data constructors")
 533     existential_why = quotes (pprSourceTyCon rep_tc) <+>
 534                       ptext SLIT("has non-Haskell-98 constructor(s)")
 535
 536 cond_isEnumeration :: Condition
 537 cond_isEnumeration (gla_exts, rep_tc)
 538   | isEnumerationTyCon rep_tc = Nothing
 539   | otherwise                 = Just why
 540   where
 541     why = quotes (pprSourceTyCon rep_tc) <+>
 542           ptext SLIT("has non-nullary constructors")
 543
 544 cond_isProduct :: Condition
 545 cond_isProduct (gla_exts, rep_tc)
 546   | isProductTyCon rep_tc = Nothing
 547   | otherwise             = Just why
 548   where
 549     why = quotes (pprSourceTyCon rep_tc) <+>
 550           ptext SLIT("has more than one constructor")
 551
 552 cond_typeableOK :: Condition
 553 -- OK for Typeable class
 554 -- Currently: (a) args all of kind *
 555 --            (b) 7 or fewer args
 556 cond_typeableOK (gla_exts, rep_tc)
 557   | tyConArity rep_tc > 7       = Just too_many
 558   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars rep_tc))
 559                                 = Just bad_kind
 560   | isFamInstTyCon rep_tc       = Just fam_inst  -- no Typable for family insts
 561   | otherwise                   = Nothing
 562   where
 563     too_many = quotes (pprSourceTyCon rep_tc) <+>
 564                ptext SLIT("has too many arguments")
 565     bad_kind = quotes (pprSourceTyCon rep_tc) <+>
 566                ptext SLIT("has arguments of kind other than `*'")
 567     fam_inst = quotes (pprSourceTyCon rep_tc) <+>
 568                ptext SLIT("is a type family")
 569
 570 cond_glaExts :: Condition
 571 cond_glaExts (gla_exts, _rep_tc) | gla_exts  = Nothing
 572                                  | otherwise = Just why
 573   where
 574     why  = ptext SLIT("You need -fglasgow-exts to derive an instance for this class")
 575
 576 std_class_via_iso clas  -- These standard classes can be derived for a newtype
 577                         -- using the isomorphism trick *even if no -fglasgow-exts*
 578   = classKey clas `elem`  [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
 579         -- Not Read/Show because they respect the type
 580         -- Not Enum, because newtypes are never in Enum
 581
 582
 583 new_dfun_name clas tycon        -- Just a simple wrapper
 584   = newDFunName clas [mkTyConApp tycon []] (getSrcSpan tycon)
 585         -- The type passed to newDFunName is only used to generate
 586         -- a suitable string; hence the empty type arg list
 587 \end{code}
 588
 589
 590 %************************************************************************
 591 %*                                                                      *
 592                 Deriving newtypes
 593 %*                                                                      *
 594 %************************************************************************
 595
 596 \begin{code}
 597 mkNewTypeEqn orig gla_exts overlap_flag tvs cls cls_tys
 598              tycon tc_args
 599              rep_tycon rep_tc_args
 600   | can_derive_via_isomorphism && (gla_exts || std_class_via_iso cls)
 601   = do  { traceTc (text "newtype deriving:" <+> ppr tycon <+> ppr rep_tys)
 602         ;       -- Go ahead and use the isomorphism
 603            dfun_name <- new_dfun_name cls tycon
 604         ; return (Nothing, Just (InstInfo { iSpec  = mk_inst_spec dfun_name,
 605                                             iBinds = NewTypeDerived ntd_info })) }
 606
 607   | isNothing mb_std_err        -- Use the standard H98 method
 608   = do  { loc <- getSrcSpanM
 609         ; eqn <- mk_data_eqn loc orig tvs cls tycon tc_args rep_tycon rep_tc_args
 610         ; return (Just eqn, Nothing) }
 611
 612         -- Otherwise we can't derive
 613   | gla_exts  = baleOut cant_derive_err -- Too hard
 614   | otherwise = baleOut std_err         -- Just complain about being a non-std instance
 615   where
 616         mb_std_err = checkSideConditions gla_exts cls cls_tys rep_tycon
 617         std_err = derivingThingErr cls cls_tys tc_app $
 618                   vcat [fromJust mb_std_err,
 619                         ptext SLIT("Try -fglasgow-exts for GHC's newtype-deriving extension")]
 620
 621         -- Here is the plan for newtype derivings.  We see
 622         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
 623         -- where t is a type,
 624         --       ak+1...an is a suffix of a1..an, and are all tyars
 625         --       ak+1...an do not occur free in t, nor in the s1..sm
 626         --       (C s1 ... sm) is a  *partial applications* of class C
 627         --                      with the last parameter missing
 628         --       (T a1 .. ak) matches the kind of C's last argument
 629         --              (and hence so does t)
 630         --
 631         -- We generate the instance
 632         --       instance forall ({a1..ak} u fvs(s1..sm)).
 633         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
 634         -- where T a1...ap is the partial application of
 635         --       the LHS of the correct kind and p >= k
 636         --
 637         --      NB: the variables below are:
 638         --              tc_tvs = [a1, ..., an]
 639         --              tyvars_to_keep = [a1, ..., ak]
 640         --              rep_ty = t ak .. an
 641         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
 642         --              tys = [s1, ..., sm]
 643         --              rep_fn' = t
 644         --
 645         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
 646         -- We generate the instance
 647         --      instance Monad (ST s) => Monad (T s) where
 648
 649         cls_tyvars = classTyVars cls
 650         kind = tyVarKind (last cls_tyvars)
 651                 -- Kind of the thing we want to instance
 652                 --   e.g. argument kind of Monad, *->*
 653
 654         (arg_kinds, _) = splitKindFunTys kind
 655         n_args_to_drop = length arg_kinds
 656                 -- Want to drop 1 arg from (T s a) and (ST s a)
 657                 -- to get       instance Monad (ST s) => Monad (T s)
 658
 659         -- Note [newtype representation]
 660         -- Need newTyConRhs *not* newTyConRep to get the representation
 661         -- type, because the latter looks through all intermediate newtypes
 662         -- For example
 663         --      newtype B = MkB Int
 664         --      newtype A = MkA B deriving( Num )
 665         -- We want the Num instance of B, *not* the Num instance of Int,
 666         -- when making the Num instance of A!
 667         rep_ty                = newTyConInstRhs rep_tycon rep_tc_args
 668         (rep_fn, rep_ty_args) = tcSplitAppTys rep_ty
 669
 670         n_tyargs_to_keep = tyConArity tycon - n_args_to_drop
 671         dropped_tc_args = drop n_tyargs_to_keep tc_args
 672         dropped_tvs     = tyVarsOfTypes dropped_tc_args
 673
 674         n_args_to_keep = length rep_ty_args - n_args_to_drop
 675         args_to_drop   = drop n_args_to_keep rep_ty_args
 676         args_to_keep   = take n_args_to_keep rep_ty_args
 677
 678         rep_fn'  = mkAppTys rep_fn args_to_keep
 679         rep_tys  = cls_tys ++ [rep_fn']
 680         rep_pred = mkClassPred cls rep_tys
 681                 -- rep_pred is the representation dictionary, from where
 682                 -- we are gong to get all the methods for the newtype
 683                 -- dictionary
 684
 685         tc_app = mkTyConApp tycon (take n_tyargs_to_keep tc_args)
 686
 687     -- Next we figure out what superclass dictionaries to use
 688     -- See Note [Newtype deriving superclasses] above
 689
 690         inst_tys = cls_tys ++ [tc_app]
 691         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
 692                               (classSCTheta cls)
 693
 694                 -- If there are no tyvars, there's no need
 695                 -- to abstract over the dictionaries we need
 696                 -- Example:     newtype T = MkT Int deriving( C )
 697                 -- We get the derived instance
 698                 --              instance C T
 699                 -- rather than
 700                 --              instance C Int => C T
 701         dict_tvs = filterOut (`elemVarSet` dropped_tvs) tvs
 702         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
 703         (dict_args, ntd_info) | null dict_tvs = ([], Just all_preds)
 704                               | otherwise     = (all_preds, Nothing)
 705
 706                 -- Finally! Here's where we build the dictionary Id
 707         mk_inst_spec dfun_name = mkLocalInstance dfun overlap_flag
 708           where
 709             dfun = mkDictFunId dfun_name dict_tvs dict_args cls inst_tys
 710
 711         -------------------------------------------------------------------
 712         --  Figuring out whether we can only do this newtype-deriving thing
 713
 714         right_arity = length cls_tys + 1 == classArity cls
 715
 716                 -- Never derive Read,Show,Typeable,Data this way
 717         non_iso_classes = [readClassKey, showClassKey, typeableClassKey, dataClassKey]
 718         can_derive_via_isomorphism
 719            =  not (getUnique cls `elem` non_iso_classes)
 720            && right_arity                       -- Well kinded;
 721                                                 -- eg not: newtype T ... deriving( ST )
 722                                                 --      because ST needs *2* type params
 723            && n_tyargs_to_keep >= 0             -- Type constructor has right kind:
 724                                                 -- eg not: newtype T = T Int deriving( Monad )
 725            && n_args_to_keep   >= 0             -- Rep type has right kind:
 726                                                 -- eg not: newtype T a = T Int deriving( Monad )
 727            && eta_ok                            -- Eta reduction works
 728            && not (isRecursiveTyCon tycon)      -- Does not work for recursive tycons:
 729                                                 --      newtype A = MkA [A]
 730                                                 -- Don't want
 731                                                 --      instance Eq [A] => Eq A !!
 732                         -- Here's a recursive newtype that's actually OK
 733                         --      newtype S1 = S1 [T1 ()]
 734                         --      newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
 735                         -- It's currently rejected.  Oh well.
 736                         -- In fact we generate an instance decl that has method of form
 737                         --      meth @ instTy = meth @ repTy
 738                         -- (no coerce's).  We'd need a coerce if we wanted to handle
 739                         -- recursive newtypes too
 740
 741         -- Check that eta reduction is OK
 742         eta_ok = (args_to_drop `tcEqTypes` dropped_tc_args)
 743                 -- (a) the dropped-off args are identical in the source and rep type
 744                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
 745                 --     Here the 'b' must be the same in the rep type (S [a] b)
 746
 747               && (tyVarsOfType rep_fn' `disjointVarSet` dropped_tvs)
 748                 -- (b) the remaining type args do not mention any of the dropped
 749                 --     type variables
 750
 751               && (tyVarsOfTypes cls_tys `disjointVarSet` dropped_tvs)
 752                 -- (c) the type class args do not mention any of the dropped type
 753                 --     variables
 754
 755               && all isTyVarTy dropped_tc_args
 756                 -- (d) in case of newtype family instances, the eta-dropped
 757                 --      arguments must be type variables (not more complex indexes)
 758
 759         cant_derive_err = derivingThingErr cls cls_tys tc_app
 760                                 (vcat [ptext SLIT("even with cunning newtype deriving:"),
 761                                         if isRecursiveTyCon tycon then
 762                                           ptext SLIT("the newtype may be recursive")
 763                                         else empty,
 764                                         if not right_arity then
 765                                           quotes (ppr (mkClassPred cls cls_tys)) <+> ptext SLIT("does not have arity 1")
 766                                         else empty,
 767                                         if not (n_tyargs_to_keep >= 0) then
 768                                           ptext SLIT("the type constructor has wrong kind")
 769                                         else if not (n_args_to_keep >= 0) then
 770                                           ptext SLIT("the representation type has wrong kind")
 771                                         else if not eta_ok then
 772                                           ptext SLIT("the eta-reduction property does not hold")
 773                                         else empty
 774                                       ])
 775 \end{code}
 776
 777
 778 %************************************************************************
 779 %*                                                                      *
 780 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 781 %*                                                                      *
 782 %************************************************************************
 783
 784 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 785 terms, which is the final correct RHS for the corresponding original
 786 equation.
 787 \begin{itemize}
 788 \item
 789 Each (k,TyVarTy tv) in a solution constrains only a type
 790 variable, tv.
 791
 792 \item
 793 The (k,TyVarTy tv) pairs in a solution are canonically
 794 ordered by sorting on type varible, tv, (major key) and then class, k,
 795 (minor key)
 796 \end{itemize}
 797
 798 \begin{code}
 799 solveDerivEqns :: OverlapFlag
 800                -> [DerivEqn]
 801                -> TcM [Instance]-- Solns in same order as eqns.
 802                                 -- This bunch is Absolutely minimal...
 803
 804 solveDerivEqns overlap_flag orig_eqns
 805   = do  { traceTc (text "solveDerivEqns" <+> vcat (map pprDerivEqn orig_eqns))
 806         ; iterateDeriv 1 initial_solutions }
 807   where
 808         -- The initial solutions for the equations claim that each
 809         -- instance has an empty context; this solution is certainly
 810         -- in canonical form.
 811     initial_solutions :: [DerivSoln]
 812     initial_solutions = [ [] | _ <- orig_eqns ]
 813
 814     ------------------------------------------------------------------
 815         -- iterateDeriv calculates the next batch of solutions,
 816         -- compares it with the current one; finishes if they are the
 817         -- same, otherwise recurses with the new solutions.
 818         -- It fails if any iteration fails
 819     iterateDeriv :: Int -> [DerivSoln] -> TcM [Instance]
 820     iterateDeriv n current_solns
 821       | n > 20  -- Looks as if we are in an infinite loop
 822                 -- This can happen if we have -fallow-undecidable-instances
 823                 -- (See TcSimplify.tcSimplifyDeriv.)
 824       = pprPanic "solveDerivEqns: probable loop"
 825                  (vcat (map pprDerivEqn orig_eqns) $$ ppr current_solns)
 826       | otherwise
 827       = let
 828             inst_specs = zipWithEqual "add_solns" mk_inst_spec
 829                                       orig_eqns current_solns
 830         in
 831         checkNoErrs (
 832                   -- Extend the inst info from the explicit instance decls
 833                   -- with the current set of solutions, and simplify each RHS
 834             extendLocalInstEnv inst_specs $
 835             mappM gen_soln orig_eqns
 836         )                               `thenM` \ new_solns ->
 837         if (current_solns == new_solns) then
 838             returnM inst_specs
 839         else
 840             iterateDeriv (n+1) new_solns
 841
 842     ------------------------------------------------------------------
 843     gen_soln :: DerivEqn -> TcM [PredType]
 844     gen_soln (loc, orig, _, tyvars, clas, inst_ty, deriv_rhs)
 845       = setSrcSpan loc  $
 846         do { theta <- tcSimplifyDeriv orig tyvars deriv_rhs
 847            ; addErrCtxt (derivInstCtxt theta clas [inst_ty]) $
 848         do { checkNoErrs (checkValidInstance tyvars theta clas [inst_ty])
 849                 -- See Note [Deriving context]
 850                 -- If this fails, don't continue
 851
 852                   -- Check for a bizarre corner case, when the derived instance decl should
 853                   -- have form  instance C a b => D (T a) where ...
 854                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
 855                   -- of problems; in particular, it's hard to compare solutions for
 856                   -- equality when finding the fixpoint.  So I just rule it out for now.
 857            ; let tv_set = mkVarSet tyvars
 858                  weird_preds = [pred | pred <- theta, not (tyVarsOfPred pred `subVarSet` tv_set)]
 859            ; mapM_ (addErrTc . badDerivedPred) weird_preds
 860
 861                 -- Claim: the result instance declaration is guaranteed valid
 862                 -- Hence no need to call:
 863                 --   checkValidInstance tyvars theta clas inst_tys
 864            ; return (sortLe (<=) theta) } }     -- Canonicalise before returning the solution
 865
 866     ------------------------------------------------------------------
 867     mk_inst_spec :: DerivEqn -> DerivSoln -> Instance
 868     mk_inst_spec (loc, orig, dfun_name, tyvars, clas, inst_ty, _) theta
 869         = mkLocalInstance dfun overlap_flag
 870         where
 871           dfun = mkDictFunId dfun_name tyvars theta clas [inst_ty]
 872
 873 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
 874 -- Add new locally-defined instances; don't bother to check
 875 -- for functional dependency errors -- that'll happen in TcInstDcls
 876 extendLocalInstEnv dfuns thing_inside
 877  = do { env <- getGblEnv
 878       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
 879              env'      = env { tcg_inst_env = inst_env' }
 880       ; setGblEnv env' thing_inside }
 881 \end{code}
 882
 883 Note [Deriving context]
 884 ~~~~~~~~~~~~~~~~~~~~~~~
 885 With -fglasgow-exts, we allow things like (C Int a) in the simplified
 886 context for a derived instance declaration, because at a use of this
 887 instance, we might know that a=Bool, and have an instance for (C Int
 888 Bool)
 889
 890 We nevertheless insist that each predicate meets the termination
 891 conditions. If not, the deriving mechanism generates larger and larger
 892 constraints.  Example:
 893   data Succ a = S a
 894   data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
 895
 896 Note the lack of a Show instance for Succ.  First we'll generate
 897   instance (Show (Succ a), Show a) => Show (Seq a)
 898 and then
 899   instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
 900 and so on.  Instead we want to complain of no instance for (Show (Succ a)).
 901
 902
 903 %************************************************************************
 904 %*                                                                      *
 905 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 906 %*                                                                      *
 907 %************************************************************************
 908
 909 After all the trouble to figure out the required context for the
 910 derived instance declarations, all that's left is to chug along to
 911 produce them.  They will then be shoved into @tcInstDecls2@, which
 912 will do all its usual business.
 913
 914 There are lots of possibilities for code to generate.  Here are
 915 various general remarks.
 916
 917 PRINCIPLES:
 918 \begin{itemize}
 919 \item
 920 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 921 ``you-couldn't-do-better-by-hand'' efficient.
 922
 923 \item
 924 Deriving @Show@---also pretty common--- should also be reasonable good code.
 925
 926 \item
 927 Deriving for the other classes isn't that common or that big a deal.
 928 \end{itemize}
 929
 930 PRAGMATICS:
 931
 932 \begin{itemize}
 933 \item
 934 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 935
 936 \item
 937 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 938
 939 \item
 940 We {\em normally} generate code only for the non-defaulted methods;
 941 there are some exceptions for @Eq@ and (especially) @Ord@...
 942
 943 \item
 944 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 945 constructor's numeric (@Int#@) tag.  These are generated by
 946 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 947 these is around is given by @hasCon2TagFun@.
 948
 949 The examples under the different sections below will make this
 950 clearer.
 951
 952 \item
 953 Much less often (really just for deriving @Ix@), we use a
 954 @_tag2con_<tycon>@ function.  See the examples.
 955
 956 \item
 957 We use the renamer!!!  Reason: we're supposed to be
 958 producing @LHsBinds Name@ for the methods, but that means
 959 producing correctly-uniquified code on the fly.  This is entirely
 960 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 961 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
 962 the renamer.  What a great hack!
 963 \end{itemize}
 964
 965 \begin{code}
 966 -- Generate the InstInfo for the required instance paired with the
 967 --   *representation* tycon for that instance,
 968 -- plus any auxiliary bindings required
 969 --
 970 -- Representation tycons differ from the tycon in the instance signature in
 971 -- case of instances for indexed families.
 972 --
 973 genInst :: Instance -> TcM ((InstInfo, TyCon), LHsBinds RdrName)
 974 genInst spec
 975   = do  { fix_env <- getFixityEnv
 976         ; let
 977             (tyvars,_,clas,[ty])    = instanceHead spec
 978             clas_nm                 = className clas
 979             (visible_tycon, tyArgs) = tcSplitTyConApp ty
 980
 981           -- In case of a family instance, we need to use the representation
 982           -- tycon (after all, it has the data constructors)
 983         ; (tycon, _) <- tcLookupFamInst visible_tycon tyArgs
 984         ; let (meth_binds, aux_binds) = genDerivBinds clas fix_env tycon
 985
 986         -- Bring the right type variables into
 987         -- scope, and rename the method binds
 988         -- It's a bit yukky that we return *renamed* InstInfo, but
 989         -- *non-renamed* auxiliary bindings
 990         ; (rn_meth_binds, _fvs) <- discardWarnings $
 991                                    bindLocalNames (map Var.varName tyvars) $
 992                                    rnMethodBinds clas_nm (\n -> []) [] meth_binds
 993
 994         -- Build the InstInfo
 995         ; return ((InstInfo { iSpec = spec,
 996                               iBinds = VanillaInst rn_meth_binds [] }, tycon),
 997                   aux_binds)
 998         }
 999
1000 genDerivBinds clas fix_env tycon
1001   | className clas `elem` typeableClassNames
1002   = (gen_Typeable_binds tycon, emptyLHsBinds)
1003
1004   | otherwise
1005   = case assocMaybe gen_list (getUnique clas) of
1006         Just gen_fn -> gen_fn fix_env tycon
1007         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1008   where
1009     gen_list :: [(Unique, FixityEnv -> TyCon -> (LHsBinds RdrName, LHsBinds RdrName))]
1010     gen_list = [(eqClassKey,      no_aux_binds (ignore_fix_env gen_Eq_binds))
1011                ,(ordClassKey,     no_aux_binds (ignore_fix_env gen_Ord_binds))
1012                ,(enumClassKey,    no_aux_binds (ignore_fix_env gen_Enum_binds))
1013                ,(boundedClassKey, no_aux_binds (ignore_fix_env gen_Bounded_binds))
1014                ,(ixClassKey,      no_aux_binds (ignore_fix_env gen_Ix_binds))
1015                ,(typeableClassKey,no_aux_binds (ignore_fix_env gen_Typeable_binds))
1016                ,(showClassKey,    no_aux_binds gen_Show_binds)
1017                ,(readClassKey,    no_aux_binds gen_Read_binds)
1018                ,(dataClassKey,    gen_Data_binds)
1019                ]
1020
1021       -- no_aux_binds is used for generators that don't
1022       -- need to produce any auxiliary bindings
1023     no_aux_binds f fix_env tc = (f fix_env tc, emptyLHsBinds)
1024     ignore_fix_env f fix_env tc = f tc
1025 \end{code}
1026
1027
1028 %************************************************************************
1029 %*                                                                      *
1030 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1031 %*                                                                      *
1032 %************************************************************************
1033
1034
1035 data Foo ... = ...
1036
1037 con2tag_Foo :: Foo ... -> Int#
1038 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
1039 maxtag_Foo  :: Int              -- ditto (NB: not unlifted)
1040
1041
1042 We have a @con2tag@ function for a tycon if:
1043 \begin{itemize}
1044 \item
1045 We're deriving @Eq@ and the tycon has nullary data constructors.
1046
1047 \item
1048 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
1049 (enum type only????)
1050 \end{itemize}
1051
1052 We have a @tag2con@ function for a tycon if:
1053 \begin{itemize}
1054 \item
1055 We're deriving @Enum@, or @Ix@ (enum type only???)
1056 \end{itemize}
1057
1058 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
1059
1060 \begin{code}
1061 genTaggeryBinds :: [(InstInfo, TyCon)] -> TcM (LHsBinds RdrName)
1062 genTaggeryBinds infos
1063   = do  { names_so_far <- foldlM do_con2tag []           tycons_of_interest
1064         ; nm_alist_etc <- foldlM do_tag2con names_so_far tycons_of_interest
1065         ; return (listToBag (map gen_tag_n_con_monobind nm_alist_etc)) }
1066   where
1067     all_CTs                 = [ (fst (simpleInstInfoClsTy info), tc)
1068                               | (info, tc) <- infos]
1069     all_tycons              = map snd all_CTs
1070     (tycons_of_interest, _) = removeDups compare all_tycons
1071
1072     do_con2tag acc_Names tycon
1073       | isDataTyCon tycon &&
1074         ((we_are_deriving eqClassKey tycon
1075             && any isNullarySrcDataCon (tyConDataCons tycon))
1076          || (we_are_deriving ordClassKey  tycon
1077             && not (isProductTyCon tycon))
1078          || (we_are_deriving enumClassKey tycon)
1079          || (we_are_deriving ixClassKey   tycon))
1080
1081       = returnM ((con2tag_RDR tycon, tycon, GenCon2Tag)
1082                    : acc_Names)
1083       | otherwise
1084       = returnM acc_Names
1085
1086     do_tag2con acc_Names tycon
1087       | isDataTyCon tycon &&
1088          (we_are_deriving enumClassKey tycon ||
1089           we_are_deriving ixClassKey   tycon
1090           && isEnumerationTyCon tycon)
1091       = returnM ( (tag2con_RDR tycon, tycon, GenTag2Con)
1092                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
1093                  : acc_Names)
1094       | otherwise
1095       = returnM acc_Names
1096
1097     we_are_deriving clas_key tycon
1098       = is_in_eqns clas_key tycon all_CTs
1099       where
1100         is_in_eqns clas_key tycon [] = False
1101         is_in_eqns clas_key tycon ((c,t):cts)
1102           =  (clas_key == classKey c && tycon == t)
1103           || is_in_eqns clas_key tycon cts
1104 \end{code}
1105
1106 \begin{code}
1107 derivingThingErr clas tys ty why
1108   = sep [hsep [ptext SLIT("Can't make a derived instance of"),
1109                quotes (ppr pred)],
1110          nest 2 (parens why)]
1111   where
1112     pred = mkClassPred clas (tys ++ [ty])
1113
1114 standaloneCtxt :: LHsType Name -> SDoc
1115 standaloneCtxt ty = ptext SLIT("In the stand-alone deriving instance for") <+> quotes (ppr ty)
1116
1117 derivInstCtxt theta clas inst_tys
1118   = hang (ptext SLIT("In the derived instance:"))
1119          2 (pprThetaArrow theta <+> pprClassPred clas inst_tys)
1120 -- Used for the ...Thetas variants; all top level
1121
1122 badDerivedPred pred
1123   = vcat [ptext SLIT("Can't derive instances where the instance context mentions"),
1124           ptext SLIT("type variables that are not data type parameters"),
1125           nest 2 (ptext SLIT("Offending constraint:") <+> ppr pred)]
1126 \end{code}
1127
1128