compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import Coercion
  34 import ErrUtils
  35 import MkId
  36 import DataCon
  37 import Maybes
  38 import RdrName
  39 import Name
  40 import NameSet
  41 import TyCon
  42 import TcType
  43 import BuildTyCl
  44 import BasicTypes
  45 import Var
  46 import VarSet
  47 import PrelNames
  48 import SrcLoc
  49 import UniqSupply
  50 import Util
  51 import ListSetOps
  52 import Outputable
  53 import FastString
  54 import Bag
  55
  56 import Control.Monad
  57 \end{code}
  58
  59 %************************************************************************
  60 %*                                                                      *
  61                 Overview
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 Overall plan
  66 ~~~~~~~~~~~~
  67 1.  Convert the decls (i.e. data/newtype deriving clauses,
  68     plus standalone deriving) to [EarlyDerivSpec]
  69
  70 2.  Infer the missing contexts for the Left DerivSpecs
  71
  72 3.  Add the derived bindings, generating InstInfos
  73
  74
  75 \begin{code}
  76 -- DerivSpec is purely  local to this module
  77 data DerivSpec  = DS { ds_loc     :: SrcSpan
  78                      , ds_orig    :: CtOrigin
  79                      , ds_name    :: Name
  80                      , ds_tvs     :: [TyVar]
  81                      , ds_theta   :: ThetaType
  82                      , ds_cls     :: Class
  83                      , ds_tys     :: [Type]
  84                      , ds_tc      :: TyCon
  85                      , ds_tc_args :: [Type]
  86                      , ds_newtype :: Bool }
  87         -- This spec implies a dfun declaration of the form
  88         --       df :: forall tvs. theta => C tys
  89         -- The Name is the name for the DFun we'll build
  90         -- The tyvars bind all the variables in the theta
  91         -- For type families, the tycon in
  92         --       in ds_tys is the *family* tycon
  93         --       in ds_tc, ds_tc_args is the *representation* tycon
  94         -- For non-family tycons, both are the same
  95
  96         -- ds_newtype = True  <=> Newtype deriving
  97         --              False <=> Vanilla deriving
  98 \end{code}
  99
 100 Example:
 101
 102      newtype instance T [a] = MkT (Tree a) deriving( C s )
 103 ==>
 104      axiom T [a] = :RTList a
 105      axiom :RTList a = Tree a
 106
 107      DS { ds_tvs = [a,s], ds_cls = C, ds_tys = [s, T [a]]
 108         , ds_tc = :RTList, ds_tc_args = [a]
 109         , ds_newtype = True }
 110
 111 \begin{code}
 112 type DerivContext = Maybe ThetaType
 113    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
 114    -- Just theta <=> Standalone deriving: context supplied by programmer
 115
 116 type EarlyDerivSpec = Either DerivSpec DerivSpec
 117         -- Left  ds => the context for the instance should be inferred
 118         --             In this case ds_theta is the list of all the
 119         --                constraints needed, such as (Eq [a], Eq a)
 120         --                The inference process is to reduce this to a
 121         --                simpler form (e.g. Eq a)
 122         --
 123         -- Right ds => the exact context for the instance is supplied
 124         --             by the programmer; it is ds_theta
 125
 126 pprDerivSpec :: DerivSpec -> SDoc
 127 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
 128                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
 129   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
 130             <+> equals <+> ppr rhs)
 131
 132 instance Outputable DerivSpec where
 133   ppr = pprDerivSpec
 134 \end{code}
 135
 136
 137 Inferring missing contexts
 138 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 139 Consider
 140
 141         data T a b = C1 (Foo a) (Bar b)
 142                    | C2 Int (T b a)
 143                    | C3 (T a a)
 144                    deriving (Eq)
 145
 146 [NOTE: See end of these comments for what to do with
 147         data (C a, D b) => T a b = ...
 148 ]
 149
 150 We want to come up with an instance declaration of the form
 151
 152         instance (Ping a, Pong b, ...) => Eq (T a b) where
 153                 x == y = ...
 154
 155 It is pretty easy, albeit tedious, to fill in the code "...".  The
 156 trick is to figure out what the context for the instance decl is,
 157 namely @Ping@, @Pong@ and friends.
 158
 159 Let's call the context reqd for the T instance of class C at types
 160 (a,b, ...)  C (T a b).  Thus:
 161
 162         Eq (T a b) = (Ping a, Pong b, ...)
 163
 164 Now we can get a (recursive) equation from the @data@ decl:
 165
 166         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 167                    u Eq (T b a) u Eq Int        -- From C2
 168                    u Eq (T a a)                 -- From C3
 169
 170 Foo and Bar may have explicit instances for @Eq@, in which case we can
 171 just substitute for them.  Alternatively, either or both may have
 172 their @Eq@ instances given by @deriving@ clauses, in which case they
 173 form part of the system of equations.
 174
 175 Now all we need do is simplify and solve the equations, iterating to
 176 find the least fixpoint.  Notice that the order of the arguments can
 177 switch around, as here in the recursive calls to T.
 178
 179 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 180
 181 We start with:
 182
 183         Eq (T a b) = {}         -- The empty set
 184
 185 Next iteration:
 186         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 187                    u Eq (T b a) u Eq Int        -- From C2
 188                    u Eq (T a a)                 -- From C3
 189
 190         After simplification:
 191                    = Eq a u Ping b u {} u {} u {}
 192                    = Eq a u Ping b
 193
 194 Next iteration:
 195
 196         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 197                    u Eq (T b a) u Eq Int        -- From C2
 198                    u Eq (T a a)                 -- From C3
 199
 200         After simplification:
 201                    = Eq a u Ping b
 202                    u (Eq b u Ping a)
 203                    u (Eq a u Ping a)
 204
 205                    = Eq a u Ping b u Eq b u Ping a
 206
 207 The next iteration gives the same result, so this is the fixpoint.  We
 208 need to make a canonical form of the RHS to ensure convergence.  We do
 209 this by simplifying the RHS to a form in which
 210
 211         - the classes constrain only tyvars
 212         - the list is sorted by tyvar (major key) and then class (minor key)
 213         - no duplicates, of course
 214
 215 So, here are the synonyms for the ``equation'' structures:
 216
 217
 218 Note [Data decl contexts]
 219 ~~~~~~~~~~~~~~~~~~~~~~~~~
 220 Consider
 221
 222         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 223
 224 We will need an instance decl like:
 225
 226         instance (Read a, RealFloat a) => Read (Complex a) where
 227           ...
 228
 229 The RealFloat in the context is because the read method for Complex is bound
 230 to construct a Complex, and doing that requires that the argument type is
 231 in RealFloat.
 232
 233 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 234 a Complex; they only take them apart.
 235
 236 Our approach: identify the offending classes, and add the data type
 237 context to the instance decl.  The "offending classes" are
 238
 239         Read, Enum?
 240
 241 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 242 pattern matching against a constructor from a data type with a context
 243 gives rise to the constraints for that context -- or at least the thinned
 244 version.  So now all classes are "offending".
 245
 246 Note [Newtype deriving]
 247 ~~~~~~~~~~~~~~~~~~~~~~~
 248 Consider this:
 249     class C a b
 250     instance C [a] Char
 251     newtype T = T Char deriving( C [a] )
 252
 253 Notice the free 'a' in the deriving.  We have to fill this out to
 254     newtype T = T Char deriving( forall a. C [a] )
 255
 256 And then translate it to:
 257     instance C [a] Char => C [a] T where ...
 258
 259
 260 Note [Newtype deriving superclasses]
 261 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 262 (See also Trac #1220 for an interesting exchange on newtype
 263 deriving and superclasses.)
 264
 265 The 'tys' here come from the partial application in the deriving
 266 clause. The last arg is the new instance type.
 267
 268 We must pass the superclasses; the newtype might be an instance
 269 of them in a different way than the representation type
 270 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 271 Then the Show instance is not done via isomorphism; it shows
 272         Foo 3 as "Foo 3"
 273 The Num instance is derived via isomorphism, but the Show superclass
 274 dictionary must the Show instance for Foo, *not* the Show dictionary
 275 gotten from the Num dictionary. So we must build a whole new dictionary
 276 not just use the Num one.  The instance we want is something like:
 277      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 278         (+) = ((+)@a)
 279         ...etc...
 280 There may be a coercion needed which we get from the tycon for the newtype
 281 when the dict is constructed in TcInstDcls.tcInstDecl2
 282
 283
 284 Note [Unused constructors and deriving clauses]
 285 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 286 See Trac #3221.  Consider
 287    data T = T1 | T2 deriving( Show )
 288 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
 289 both of them.  So we gather defs/uses from deriving just like anything else.
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 \begin{code}
 298 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
 299             -> [LInstDecl Name]  -- All instance declarations
 300             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 301             -> TcM ([InstInfo Name] -- The generated "instance decls"
 302                    ,HsValBinds Name -- Extra generated top-level bindings
 303                    ,DefUses
 304                    ,[TyCon]         -- Extra generated top-level types
 305                    ,[TyCon])        -- Extra generated type family instances
 306
 307 tcDeriving tycl_decls inst_decls deriv_decls
 308   = recoverM (return ([], emptyValBindsOut, emptyDUs, [], [])) $
 309     do  {       -- Fish the "deriving"-related information out of the TcEnv
 310                 -- And make the necessary "equations".
 311           is_boot <- tcIsHsBoot
 312         ; traceTc "tcDeriving" (ppr is_boot)
 313         ; (early_specs, genericsExtras)
 314                 <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 315         ; let (repMetaTys, repTyCons, metaInsts) = unzip3 genericsExtras
 316
 317         ; overlap_flag <- getOverlapFlag
 318         ; let (infer_specs, given_specs) = splitEithers early_specs
 319         ; insts1 <- mapM (genInst True overlap_flag) given_specs
 320
 321         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
 322                          inferInstanceContexts overlap_flag infer_specs
 323
 324         ; insts2 <- mapM (genInst False overlap_flag) final_specs
 325
 326         -- We no longer generate the old generic to/from functions
 327         -- from each type declaration, so this is emptyBag
 328         ; gen_binds <- return emptyBag -- mkGenericBinds is_boot tycl_decls
 329
 330 {-
 331          -- Generate the Generic instances
 332          -- from each type declaration
 333         ; repInstsMeta <- genGenericAlls is_boot tycl_decls
 334
 335         ; let repInsts   = concat (map (\(a,_,_) -> a) repInstsMeta)
 336               repMetaTys = map (\(_,b,_) -> b) repInstsMeta
 337               repTyCons  = map (\(_,_,c) -> c) repInstsMeta
 338 -}
 339         ; (inst_info, rn_binds, rn_dus)
 340                 <- renameDeriv is_boot gen_binds (insts1 ++ insts2 ++ concat metaInsts {- ++ repInsts -})
 341
 342         ; dflags <- getDOpts
 343         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 344                  (ddump_deriving inst_info rn_binds))
 345 {-
 346         ; when (not (null inst_info)) $
 347           dumpDerivingInfo (ddump_deriving inst_info rn_binds)
 348 -}
 349         ; return ( inst_info, rn_binds, rn_dus
 350                  , concat (map metaTyCons2TyCons repMetaTys), repTyCons) }
 351   where
 352     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
 353     ddump_deriving inst_infos extra_binds
 354       = hang (ptext (sLit "Derived instances"))
 355            2 (vcat (map (\i -> pprInstInfoDetails i $$ text "") inst_infos)
 356               $$ ppr extra_binds)
 357
 358
 359 renameDeriv :: Bool -> LHsBinds RdrName
 360             -> [(InstInfo RdrName, DerivAuxBinds)]
 361             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
 362 renameDeriv is_boot gen_binds insts
 363   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
 364                 -- The inst-info bindings will all be empty, but it's easier to
 365                 -- just use rn_inst_info to change the type appropriately
 366   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
 367         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
 368
 369   | otherwise
 370   = discardWarnings $    -- Discard warnings about unused bindings etc
 371     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns
 372                                                                   -- are used in the generic binds
 373                                rnTopBinds (ValBindsIn gen_binds [])
 374         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
 375
 376                 -- Generate and rename any extra not-one-inst-decl-specific binds,
 377                 -- notably "con2tag" and/or "tag2con" functions.
 378                 -- Bring those names into scope before renaming the instances themselves
 379         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
 380         ; let (aux_binds, aux_sigs) = unzip $ map (genAuxBind loc) $
 381                                       rm_dups [] $ concat deriv_aux_binds
 382               aux_val_binds = ValBindsIn (listToBag aux_binds) aux_sigs
 383         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv aux_val_binds
 384         ; bindLocalNames (collectHsValBinders rn_aux_lhs) $
 385     do  { (rn_aux, dus_aux) <- rnTopBindsRHS rn_aux_lhs
 386         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
 387         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
 388                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
 389
 390   where
 391     (inst_infos, deriv_aux_binds) = unzip insts
 392
 393         -- Remove duplicate requests for auxilliary bindings
 394     rm_dups acc [] = acc
 395     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
 396                        | otherwise            = rm_dups (b:acc) bs
 397
 398
 399     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
 400     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
 401         = return ( info { iBinds = NewTypeDerived coi tc }
 402                  , mkFVs (map dataConName (tyConDataCons tc)))
 403           -- See Note [Newtype deriving and unused constructors]
 404
 405     rn_inst_info inst_info@(InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
 406         =       -- Bring the right type variables into
 407                 -- scope (yuk), and rename the method binds
 408            ASSERT( null sigs )
 409            bindLocalNames (map Var.varName tyvars) $
 410            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) binds
 411               ; let binds' = VanillaInst rn_binds [] standalone_deriv
 412               ; return (inst_info { iBinds = binds' }, fvs) }
 413         where
 414           (tyvars,_, clas,_) = instanceHead inst
 415           clas_nm            = className clas
 416
 417 -----------------------------------------
 418 {- Now unused
 419 mkGenericBinds :: Bool -> [LTyClDecl Name] -> TcM (LHsBinds RdrName)
 420 mkGenericBinds is_boot tycl_decls
 421   | is_boot
 422   = return emptyBag
 423   | otherwise
 424   = do  { tcs <- mapM tcLookupTyCon [ tcdName d
 425                                     | L _ d <- tycl_decls, isDataDecl d ]
 426         ; return (unionManyBags [ mkTyConGenericBinds tc
 427                                 | tc <- tcs, tyConHasGenerics tc ]) }
 428                 -- We are only interested in the data type declarations,
 429                 -- and then only in the ones whose 'has-generics' flag is on
 430                 -- The predicate tyConHasGenerics finds both of these
 431 -}
 432 \end{code}
 433
 434 Note [Newtype deriving and unused constructors]
 435 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 436 Consider this (see Trac #1954):
 437
 438   module Bug(P) where
 439   newtype P a = MkP (IO a) deriving Monad
 440
 441 If you compile with -fwarn-unused-binds you do not expect the warning
 442 "Defined but not used: data consructor MkP". Yet the newtype deriving
 443 code does not explicitly mention MkP, but it should behave as if you
 444 had written
 445   instance Monad P where
 446      return x = MkP (return x)
 447      ...etc...
 448
 449 So we want to signal a user of the data constructor 'MkP'.  That's
 450 what we do in rn_inst_info, and it's the only reason we have the TyCon
 451 stored in NewTypeDerived.
 452
 453
 454 %************************************************************************
 455 %*                                                                      *
 456                 From HsSyn to DerivSpec
 457 %*                                                                      *
 458 %************************************************************************
 459
 460 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
 461
 462 \begin{code}
 463 {-
 464 -- Make the EarlyDerivSpec for Generic
 465 mkGenDerivSpec :: TyCon -> TcRn (EarlyDerivSpec)
 466 mkGenDerivSpec tc = do
 467         { cls           <- tcLookupClass genClassName
 468         ; let tc_tvs    = tyConTyVars tc
 469         ; let tc_app    = mkTyConApp tc (mkTyVarTys tc_tvs)
 470         ; let cls_tys   = []
 471         ; let mtheta    = Just []
 472         ; ds <- mkEqnHelp StandAloneDerivOrigin tc_tvs cls cls_tys tc_app mtheta
 473         -- JPM TODO: StandAloneDerivOrigin?...
 474         ; return ds }
 475 -}
 476 -- Make the "extras" for the generic representation
 477 mkGenDerivExtras :: TyCon
 478                  -> TcRn (MetaTyCons, TyCon, [(InstInfo RdrName, DerivAuxBinds)])
 479 mkGenDerivExtras tc = do
 480         { (metaTyCons, rep0TyInst) <- genGenericRepExtras tc
 481         ; metaInsts                <- genDtMeta (tc, metaTyCons)
 482         ; return (metaTyCons, rep0TyInst, metaInsts) }
 483
 484 makeDerivSpecs :: Bool
 485                -> [LTyClDecl Name]
 486                -> [LInstDecl Name]
 487                -> [LDerivDecl Name]
 488                -> TcM ( [EarlyDerivSpec]
 489                       , [(MetaTyCons, TyCon, [(InstInfo RdrName, DerivAuxBinds)])])
 490 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
 491   | is_boot     -- No 'deriving' at all in hs-boot files
 492   = do  { mapM_ add_deriv_err deriv_locs
 493         ; return ([],[]) }
 494   | otherwise
 495   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
 496         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
 497         -- Generate EarlyDerivSpec's for Generic, if asked for
 498         -- ; (xGenerics, xDerRep) <- genericsFlags
 499         ; xDerRep <- genericsFlag
 500         ; let allTyNames = [ tcdName d | L _ d <- tycl_decls, isDataDecl d ]
 501         -- ; allTyDecls <- mapM tcLookupTyCon allTyNames
 502         -- Select only those types that derive Generic
 503         ; let sel_tydata = [ tcdName t | (L _ c, L _ t) <- all_tydata
 504                                        , getClassName c == Just genClassName ]
 505         ; let sel_deriv_decls = catMaybes [ getTypeName t
 506                                   | L _ (DerivDecl (L _ t)) <- deriv_decls
 507                                   , getClassName t == Just genClassName ]
 508         ; derTyDecls <- mapM tcLookupTyCon $
 509                          filter (needsExtras xDerRep
 510                                   (sel_tydata ++ sel_deriv_decls)) allTyNames
 511         -- We need to generate the extras to add to what has
 512         -- already been derived
 513         ; generic_extras_deriv <- mapM mkGenDerivExtras derTyDecls
 514         -- For the remaining types, if Generics is on, we need to
 515         -- generate both the instances and the extras, but only for the
 516         -- types we can represent.
 517 {-
 518         ; let repTyDecls = filter canDoGenerics allTyDecls
 519         ; let remTyDecls = filter (\x -> not (x `elem` derTyDecls)) repTyDecls
 520         ; generic_instances    <- if xGenerics
 521                                    then mapM mkGenDerivSpec   remTyDecls
 522                                     else return []
 523         ; generic_extras_flag  <- if xGenerics
 524                                    then mapM mkGenDerivExtras remTyDecls
 525                                     else return []
 526 -}
 527         -- Merge and return everything
 528         ; return ( eqns1 ++ eqns2 -- ++ generic_instances
 529                  , generic_extras_deriv {- ++ generic_extras_flag -}) }
 530   where
 531       -- We need extras if the flag DeriveGeneric is on and this type is
 532       -- deriving Generic
 533     needsExtras xDerRep tydata tc_name = xDerRep && tc_name `elem` tydata
 534
 535     -- Extracts the name of the class in the deriving
 536     getClassName :: HsType Name -> Maybe Name
 537     getClassName (HsPredTy (HsClassP n _)) = Just n
 538     getClassName _                         = Nothing
 539
 540     -- Extracts the name of the type in the deriving
 541     getTypeName :: HsType Name -> Maybe Name
 542     getTypeName (HsTyVar n)                     = Just n
 543     getTypeName (HsOpTy _ (L _ n) _)            = Just n
 544     getTypeName (HsPredTy (HsClassP _ [L _ n])) = getTypeName n
 545     getTypeName _                               = Nothing
 546
 547     extractTyDataPreds decls
 548       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
 549
 550     all_tydata :: [(LHsType Name, LTyClDecl Name)]
 551         -- Derived predicate paired with its data type declaration
 552     all_tydata = extractTyDataPreds (instDeclATs inst_decls ++ tycl_decls)
 553
 554     deriv_locs = map (getLoc . snd) all_tydata
 555                  ++ map getLoc deriv_decls
 556
 557     add_deriv_err loc = setSrcSpan loc $
 558                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
 559                                    2 (ptext (sLit "Use an instance declaration instead")))
 560
 561 genericsFlag :: TcM Bool
 562 genericsFlag = do dOpts <- getDOpts
 563                   return (  xopt Opt_Generics            dOpts
 564                          || xopt Opt_DeriveGeneric dOpts)
 565
 566 ------------------------------------------------------------------
 567 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
 568 -- Standalone deriving declarations
 569 --  e.g.   deriving instance Show a => Show (T a)
 570 -- Rather like tcLocalInstDecl
 571 deriveStandalone (L loc (DerivDecl deriv_ty))
 572   = setSrcSpan loc                   $
 573     addErrCtxt (standaloneCtxt deriv_ty)  $
 574     do { traceTc "Standalone deriving decl for" (ppr deriv_ty)
 575        ; (tvs, theta, cls, inst_tys) <- tcHsInstHead deriv_ty
 576        ; traceTc "Standalone deriving;" $ vcat
 577               [ text "tvs:" <+> ppr tvs
 578               , text "theta:" <+> ppr theta
 579               , text "cls:" <+> ppr cls
 580               , text "tys:" <+> ppr inst_tys ]
 581        ; checkValidInstance deriv_ty tvs theta cls inst_tys
 582                 -- C.f. TcInstDcls.tcLocalInstDecl1
 583
 584        ; let cls_tys = take (length inst_tys - 1) inst_tys
 585              inst_ty = last inst_tys
 586        ; traceTc "Standalone deriving:" $ vcat
 587               [ text "class:" <+> ppr cls
 588               , text "class types:" <+> ppr cls_tys
 589               , text "type:" <+> ppr inst_ty ]
 590        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
 591                    (Just theta) }
 592
 593 ------------------------------------------------------------------
 594 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
 595 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name,
 596                                                    tcdTyVars = tv_names,
 597                                                    tcdTyPats = ty_pats }))
 598   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
 599     tcAddDeclCtxt decl $
 600     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
 601         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 602                                         -- the type variables for the type constructor
 603
 604     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 605                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 606                 -- newtype deriving we allow deriving (forall a. C [a]).
 607
 608         -- Given data T a b c = ... deriving( C d ),
 609         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
 610         ; let cls_tyvars = classTyVars cls
 611               kind = tyVarKind (last cls_tyvars)
 612               (arg_kinds, _) = splitKindFunTys kind
 613               n_args_to_drop = length arg_kinds
 614               n_args_to_keep = tyConArity tc - n_args_to_drop
 615               args_to_drop   = drop n_args_to_keep tc_args
 616               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
 617               inst_ty_kind   = typeKind inst_ty
 618               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
 619               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
 620                                         `minusVarSet` dropped_tvs
 621
 622         -- Check that the result really is well-kinded
 623         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
 624                   (derivingKindErr tc cls cls_tys kind)
 625
 626         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
 627                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
 628                   (derivingEtaErr cls cls_tys inst_ty)
 629                 -- Check that
 630                 --  (a) The data type can be eta-reduced; eg reject:
 631                 --              data instance T a a = ... deriving( Monad )
 632                 --  (b) The type class args do not mention any of the dropped type
 633                 --      variables
 634                 --              newtype T a s = ... deriving( ST s )
 635
 636         -- Type families can't be partially applied
 637         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
 638         -- Note [Deriving, type families, and partial applications]
 639         ; checkTc (not (isFamilyTyCon tc) || n_args_to_drop == 0)
 640                   (typeFamilyPapErr tc cls cls_tys inst_ty)
 641
 642         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
 643   where
 644         -- Tiresomely we must figure out the "lhs", which is awkward for type families
 645         -- E.g.   data T a b = .. deriving( Eq )
 646         --          Here, the lhs is (T a b)
 647         --        data instance TF Int b = ... deriving( Eq )
 648         --          Here, the lhs is (TF Int b)
 649         -- But if we just look up the tycon_name, we get is the *family*
 650         -- tycon, but not pattern types -- they are in the *rep* tycon.
 651     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
 652                              ; let tvs = tyConTyVars tc
 653                              ; return (tvs, tc, mkTyVarTys tvs) }
 654     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
 655                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 656                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
 657                              ; return (tvs, tc, tc_args) }
 658
 659 deriveTyData _other
 660   = panic "derivTyData" -- Caller ensures that only TyData can happen
 661 \end{code}
 662
 663 Note [Deriving, type families, and partial applications]
 664 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 665 When there are no type families, it's quite easy:
 666
 667     newtype S a = MkS [a]
 668     -- :CoS :: S  ~ []  -- Eta-reduced
 669
 670     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
 671     instance Monad [] => Monad S        -- by coercion sym (Monad :CoS)  : Monad [] ~ Monad S
 672
 673 When type familes are involved it's trickier:
 674
 675     data family T a b
 676     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
 677     -- :RT is the representation type for (T Int a)
 678     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
 679     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
 680
 681     instance Eq [a] => Eq (T Int a)     -- easy by coercion
 682     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 683
 684 The "???" bit is that we don't build the :CoF thing in eta-reduced form
 685 Henc the current typeFamilyPapErr, even though the instance makes sense.
 686 After all, we can write it out
 687     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
 688       return x = MkT [x]
 689       ... etc ...
 690
 691 \begin{code}
 692 mkEqnHelp :: CtOrigin -> [TyVar] -> Class -> [Type] -> Type
 693           -> DerivContext       -- Just    => context supplied (standalone deriving)
 694                                 -- Nothing => context inferred (deriving on data decl)
 695           -> TcRn EarlyDerivSpec
 696 -- Make the EarlyDerivSpec for an instance
 697 --      forall tvs. theta => cls (tys ++ [ty])
 698 -- where the 'theta' is optional (that's the Maybe part)
 699 -- Assumes that this declaration is well-kinded
 700
 701 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
 702   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 703   , isAlgTyCon tycon    -- Check for functions, primitive types etc
 704   = mk_alg_eqn tycon tc_args
 705   | otherwise
 706   = failWithTc (derivingThingErr False cls cls_tys tc_app
 707                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
 708
 709   where
 710      bale_out msg = failWithTc (derivingThingErr False cls cls_tys tc_app msg)
 711
 712      mk_alg_eqn tycon tc_args
 713       | className cls `elem` typeableClassNames
 714       = do { dflags <- getDOpts
 715            ; case checkTypeableConditions (dflags, tycon) of
 716                Just err -> bale_out err
 717                Nothing  -> mk_typeable_eqn orig tvs cls tycon tc_args mtheta }
 718
 719       | isDataFamilyTyCon tycon
 720       , length tc_args /= tyConArity tycon
 721       = bale_out (ptext (sLit "Unsaturated data family application"))
 722
 723       | otherwise
 724       = do { (rep_tc, rep_tc_args) <- tcLookupDataFamInst tycon tc_args
 725                   -- Be careful to test rep_tc here: in the case of families,
 726                   -- we want to check the instance tycon, not the family tycon
 727
 728            -- For standalone deriving (mtheta /= Nothing),
 729            -- check that all the data constructors are in scope.
 730            ; rdr_env <- getGlobalRdrEnv
 731            ; let hidden_data_cons = isAbstractTyCon rep_tc ||
 732                                     any not_in_scope (tyConDataCons rep_tc)
 733                  not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
 734            ; unless (isNothing mtheta || not hidden_data_cons)
 735                     (bale_out (derivingHiddenErr tycon))
 736
 737            ; dflags <- getDOpts
 738            ; if isDataTyCon rep_tc then
 739                 mkDataTypeEqn orig dflags tvs cls cls_tys
 740                               tycon tc_args rep_tc rep_tc_args mtheta
 741              else
 742                 mkNewTypeEqn orig dflags tvs cls cls_tys
 743                              tycon tc_args rep_tc rep_tc_args mtheta }
 744 \end{code}
 745
 746
 747 %************************************************************************
 748 %*                                                                      *
 749                 Deriving data types
 750 %*                                                                      *
 751 %************************************************************************
 752
 753 \begin{code}
 754 mkDataTypeEqn :: CtOrigin
 755               -> DynFlags
 756               -> [Var]                  -- Universally quantified type variables in the instance
 757               -> Class                  -- Class for which we need to derive an instance
 758               -> [Type]                 -- Other parameters to the class except the last
 759               -> TyCon                  -- Type constructor for which the instance is requested
 760                                         --    (last parameter to the type class)
 761               -> [Type]                 -- Parameters to the type constructor
 762               -> TyCon                  -- rep of the above (for type families)
 763               -> [Type]                 -- rep of the above
 764               -> DerivContext        -- Context of the instance, for standalone deriving
 765               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
 766
 767 mkDataTypeEqn orig dflags tvs cls cls_tys
 768               tycon tc_args rep_tc rep_tc_args mtheta
 769   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
 770         -- NB: pass the *representation* tycon to checkSideConditions
 771         CanDerive               -> go_for_it
 772         NonDerivableClass       -> bale_out (nonStdErr cls)
 773         DerivableClassError msg -> bale_out msg
 774   where
 775     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 776     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
 777
 778 mk_data_eqn :: CtOrigin -> [TyVar] -> Class
 779             -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
 780             -> TcM EarlyDerivSpec
 781 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
 782   = do  { dfun_name <- new_dfun_name cls tycon
 783         ; loc <- getSrcSpanM
 784         ; let inst_tys = [mkTyConApp tycon tc_args]
 785               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
 786               spec = DS { ds_loc = loc, ds_orig = orig
 787                         , ds_name = dfun_name, ds_tvs = tvs
 788                         , ds_cls = cls, ds_tys = inst_tys
 789                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
 790                         , ds_theta =  mtheta `orElse` inferred_constraints
 791                         , ds_newtype = False }
 792
 793         ; return (if isJust mtheta then Right spec      -- Specified context
 794                                    else Left spec) }    -- Infer context
 795
 796 ----------------------
 797 mk_typeable_eqn :: CtOrigin -> [TyVar] -> Class
 798                 -> TyCon -> [TcType] -> DerivContext
 799                 -> TcM EarlyDerivSpec
 800 mk_typeable_eqn orig tvs cls tycon tc_args mtheta
 801         -- The Typeable class is special in several ways
 802         --        data T a b = ... deriving( Typeable )
 803         -- gives
 804         --        instance Typeable2 T where ...
 805         -- Notice that:
 806         -- 1. There are no constraints in the instance
 807         -- 2. There are no type variables either
 808         -- 3. The actual class we want to generate isn't necessarily
 809         --      Typeable; it depends on the arity of the type
 810   | isNothing mtheta    -- deriving on a data type decl
 811   = do  { checkTc (cls `hasKey` typeableClassKey)
 812                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
 813         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 814         ; mk_typeable_eqn orig tvs real_cls tycon [] (Just []) }
 815
 816   | otherwise           -- standaone deriving
 817   = do  { checkTc (null tc_args)
 818                   (ptext (sLit "Derived typeable instance must be of form (Typeable")
 819                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
 820         ; dfun_name <- new_dfun_name cls tycon
 821         ; loc <- getSrcSpanM
 822         ; return (Right $
 823                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
 824                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
 825                      , ds_tc = tycon, ds_tc_args = []
 826                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
 827
 828 ----------------------
 829 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
 830 -- Generate a sufficiently large set of constraints that typechecking the
 831 -- generated method definitions should succeed.   This set will be simplified
 832 -- before being used in the instance declaration
 833 inferConstraints _ cls inst_tys rep_tc rep_tc_args
 834   -- Generic constraints are easy
 835   | cls `hasKey` genClassKey
 836   = []
 837   -- The others are a bit more complicated
 838   | otherwise
 839   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
 840     stupid_constraints ++ extra_constraints
 841     ++ sc_constraints ++ con_arg_constraints
 842   where
 843        -- Constraints arising from the arguments of each constructor
 844     con_arg_constraints
 845       = [ mkClassPred cls [arg_ty]
 846         | data_con <- tyConDataCons rep_tc,
 847           arg_ty   <- ASSERT( isVanillaDataCon data_con )
 848                         get_constrained_tys $
 849                         dataConInstOrigArgTys data_con all_rep_tc_args,
 850           not (isUnLiftedType arg_ty) ]
 851                 -- No constraints for unlifted types
 852                 -- Where they are legal we generate specilised function calls
 853
 854                 -- For functor-like classes, two things are different
 855                 -- (a) We recurse over argument types to generate constraints
 856                 --     See Functor examples in TcGenDeriv
 857                 -- (b) The rep_tc_args will be one short
 858     is_functor_like = getUnique cls `elem` functorLikeClassKeys
 859
 860     get_constrained_tys :: [Type] -> [Type]
 861     get_constrained_tys tys
 862         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
 863         | otherwise       = tys
 864
 865     rep_tc_tvs = tyConTyVars rep_tc
 866     last_tv = last rep_tc_tvs
 867     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
 868                     | otherwise       = rep_tc_args
 869
 870         -- Constraints arising from superclasses
 871         -- See Note [Superclasses of derived instance]
 872     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
 873                                 (classSCTheta cls)
 874
 875         -- Stupid constraints
 876     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
 877     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
 878
 879         -- Extra Data constraints
 880         -- The Data class (only) requires that for
 881         --    instance (...) => Data (T t1 t2)
 882         -- IF   t1:*, t2:*
 883         -- THEN (Data t1, Data t2) are among the (...) constraints
 884         -- Reason: when the IF holds, we generate a method
 885         --             dataCast2 f = gcast2 f
 886         --         and we need the Data constraints to typecheck the method
 887     extra_constraints
 888       | cls `hasKey` dataClassKey
 889       , all (isLiftedTypeKind . typeKind) rep_tc_args
 890       = [mkClassPred cls [ty] | ty <- rep_tc_args]
 891       | otherwise
 892       = []
 893
 894 ------------------------------------------------------------------
 895 -- Check side conditions that dis-allow derivability for particular classes
 896 -- This is *apart* from the newtype-deriving mechanism
 897 --
 898 -- Here we get the representation tycon in case of family instances as it has
 899 -- the data constructors - but we need to be careful to fall back to the
 900 -- family tycon (with indexes) in error messages.
 901
 902 data DerivStatus = CanDerive
 903                  | DerivableClassError SDoc     -- Standard class, but can't do it
 904                  | NonDerivableClass            -- Non-standard class
 905
 906 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
 907 checkSideConditions dflags mtheta cls cls_tys rep_tc
 908   | Just cond <- sideConditions mtheta cls
 909   = case (cond (dflags, rep_tc)) of
 910         Just err -> DerivableClassError err     -- Class-specific error
 911         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
 912                                                 -- cls_tys (the type args other than last)
 913                                                 -- should be null
 914                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
 915   | otherwise = NonDerivableClass       -- Not a standard class
 916   where
 917     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
 918
 919 checkTypeableConditions :: Condition
 920 checkTypeableConditions = checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK
 921
 922 nonStdErr :: Class -> SDoc
 923 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
 924
 925 sideConditions :: DerivContext -> Class -> Maybe Condition
 926 sideConditions mtheta cls
 927   | cls_key == eqClassKey          = Just cond_std
 928   | cls_key == ordClassKey         = Just cond_std
 929   | cls_key == showClassKey        = Just cond_std
 930   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
 931   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
 932   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
 933   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
 934   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond`
 935                                            cond_std `andCond` cond_noUnliftedArgs)
 936   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
 937                                            cond_functorOK True)  -- NB: no cond_std!
 938   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
 939                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
 940   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
 941                                            cond_functorOK False)
 942   | cls_key == genClassKey         = Just (cond_RepresentableOk `andCond`
 943                                            checkFlag Opt_DeriveGeneric)
 944   | otherwise = Nothing
 945   where
 946     cls_key = getUnique cls
 947     cond_std = cond_stdOK mtheta
 948
 949 type Condition = (DynFlags, TyCon) -> Maybe SDoc
 950         -- first Bool is whether or not we are allowed to derive Data and Typeable
 951         -- second Bool is whether or not we are allowed to derive Functor
 952         -- TyCon is the *representation* tycon if the
 953         --      data type is an indexed one
 954         -- Nothing => OK
 955
 956 orCond :: Condition -> Condition -> Condition
 957 orCond c1 c2 tc
 958   = case c1 tc of
 959         Nothing -> Nothing          -- c1 succeeds
 960         Just x  -> case c2 tc of    -- c1 fails
 961                      Nothing -> Nothing
 962                      Just y  -> Just (x $$ ptext (sLit "  or") $$ y)
 963                                     -- Both fail
 964
 965 andCond :: Condition -> Condition -> Condition
 966 andCond c1 c2 tc = case c1 tc of
 967                      Nothing -> c2 tc   -- c1 succeeds
 968                      Just x  -> Just x  -- c1 fails
 969
 970 cond_stdOK :: DerivContext -> Condition
 971 cond_stdOK (Just _) _
 972   = Nothing     -- Don't check these conservative conditions for
 973                 -- standalone deriving; just generate the code
 974                 -- and let the typechecker handle the result
 975 cond_stdOK Nothing (_, rep_tc)
 976   | null data_cons      = Just (no_cons_why rep_tc $$ suggestion)
 977   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
 978   | otherwise           = Nothing
 979   where
 980     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
 981     data_cons   = tyConDataCons rep_tc
 982     con_whys = mapCatMaybes check_con data_cons
 983
 984     check_con :: DataCon -> Maybe SDoc
 985     check_con con
 986       | isVanillaDataCon con
 987       , all isTauTy (dataConOrigArgTys con) = Nothing
 988       | otherwise = Just (badCon con (ptext (sLit "must have a Haskell-98 type")))
 989
 990 no_cons_why :: TyCon -> SDoc
 991 no_cons_why rep_tc = quotes (pprSourceTyCon rep_tc) <+>
 992                      ptext (sLit "must have at least one data constructor")
 993
 994 -- JPM TODO: should give better error message
 995 cond_RepresentableOk :: Condition
 996 cond_RepresentableOk (_,t) | canDoGenerics t = Nothing
 997                            | otherwise       = Just (ptext (sLit "Cannot derive Generic for type") <+> ppr t)
 998
 999 cond_enumOrProduct :: Condition
1000 cond_enumOrProduct = cond_isEnumeration `orCond`
1001                        (cond_isProduct `andCond` cond_noUnliftedArgs)
1002
1003 cond_noUnliftedArgs :: Condition
1004 -- For some classes (eg Eq, Ord) we allow unlifted arg types
1005 -- by generating specilaised code.  For others (eg Data) we don't.
1006 cond_noUnliftedArgs (_, tc)
1007   | null bad_cons = Nothing
1008   | otherwise     = Just why
1009   where
1010     bad_cons = [ con | con <- tyConDataCons tc
1011                      , any isUnLiftedType (dataConOrigArgTys con) ]
1012     why = badCon (head bad_cons) (ptext (sLit "must have only arguments of lifted type"))
1013
1014 cond_isEnumeration :: Condition
1015 cond_isEnumeration (_, rep_tc)
1016   | isEnumerationTyCon rep_tc   = Nothing
1017   | otherwise                   = Just why
1018   where
1019     why = sep [ quotes (pprSourceTyCon rep_tc) <+>
1020                   ptext (sLit "must be an enumeration type")
1021               , ptext (sLit "(an enumeration consists of one or more nullary, non-GADT constructors)") ]
1022                   -- See Note [Enumeration types] in TyCon
1023
1024 cond_isProduct :: Condition
1025 cond_isProduct (_, rep_tc)
1026   | isProductTyCon rep_tc = Nothing
1027   | otherwise             = Just why
1028   where
1029     why = quotes (pprSourceTyCon rep_tc) <+>
1030           ptext (sLit "must have precisely one constructor")
1031
1032 cond_typeableOK :: Condition
1033 -- OK for Typeable class
1034 -- Currently: (a) args all of kind *
1035 --            (b) 7 or fewer args
1036 cond_typeableOK (_, tc)
1037   | tyConArity tc > 7 = Just too_many
1038   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars tc))
1039                       = Just bad_kind
1040   | otherwise         = Nothing
1041   where
1042     too_many = quotes (pprSourceTyCon tc) <+>
1043                ptext (sLit "must have 7 or fewer arguments")
1044     bad_kind = quotes (pprSourceTyCon tc) <+>
1045                ptext (sLit "must only have arguments of kind `*'")
1046
1047 functorLikeClassKeys :: [Unique]
1048 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
1049
1050 cond_functorOK :: Bool -> Condition
1051 -- OK for Functor/Foldable/Traversable class
1052 -- Currently: (a) at least one argument
1053 --            (b) don't use argument contravariantly
1054 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
1055 --            (d) optionally: don't use function types
1056 --            (e) no "stupid context" on data type
1057 cond_functorOK allowFunctions (_, rep_tc)
1058   | null tc_tvs
1059   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1060           <+> ptext (sLit "must have some type parameters"))
1061
1062   | not (null bad_stupid_theta)
1063   = Just (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1064           <+> ptext (sLit "must not have a class context") <+> pprTheta bad_stupid_theta)
1065
1066   | otherwise
1067   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
1068   where
1069     tc_tvs            = tyConTyVars rep_tc
1070     Just (_, last_tv) = snocView tc_tvs
1071     bad_stupid_theta  = filter is_bad (tyConStupidTheta rep_tc)
1072     is_bad pred       = last_tv `elemVarSet` tyVarsOfPred pred
1073
1074     data_cons = tyConDataCons rep_tc
1075     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
1076
1077     check_vanilla :: DataCon -> Maybe SDoc
1078     check_vanilla con | isVanillaDataCon con = Nothing
1079                       | otherwise            = Just (badCon con existential)
1080
1081     ft_check :: DataCon -> FFoldType (Maybe SDoc)
1082     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
1083                       , ft_co_var = Just (badCon con covariant)
1084                       , ft_fun = \x y -> if allowFunctions then x `mplus` y
1085                                                            else Just (badCon con functions)
1086                       , ft_tup = \_ xs  -> msum xs
1087                       , ft_ty_app = \_ x   -> x
1088                       , ft_bad_app = Just (badCon con wrong_arg)
1089                       , ft_forall = \_ x   -> x }
1090
1091     existential = ptext (sLit "must not have existential arguments")
1092     covariant   = ptext (sLit "must not use the type variable in a function argument")
1093     functions   = ptext (sLit "must not contain function types")
1094     wrong_arg   = ptext (sLit "must not use the type variable in an argument other than the last")
1095
1096 checkFlag :: ExtensionFlag -> Condition
1097 checkFlag flag (dflags, _)
1098   | xopt flag dflags = Nothing
1099   | otherwise        = Just why
1100   where
1101     why = ptext (sLit "You need -X") <> text flag_str
1102           <+> ptext (sLit "to derive an instance for this class")
1103     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
1104                  [s]   -> s
1105                  other -> pprPanic "checkFlag" (ppr other)
1106
1107 std_class_via_iso :: Class -> Bool
1108 -- These standard classes can be derived for a newtype
1109 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
1110 -- because giving so gives the same results as generating the boilerplate
1111 std_class_via_iso clas
1112   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
1113         -- Not Read/Show because they respect the type
1114         -- Not Enum, because newtypes are never in Enum
1115
1116
1117 non_iso_class :: Class -> Bool
1118 -- *Never* derive Read, Show, Typeable, Data, Generic by isomorphism,
1119 -- even with -XGeneralizedNewtypeDeriving
1120 non_iso_class cls
1121   = classKey cls `elem` ([ readClassKey, showClassKey, dataClassKey
1122                          , genClassKey] ++ typeableClassKeys)
1123
1124 typeableClassKeys :: [Unique]
1125 typeableClassKeys = map getUnique typeableClassNames
1126
1127 new_dfun_name :: Class -> TyCon -> TcM Name
1128 new_dfun_name clas tycon        -- Just a simple wrapper
1129   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1130         ; newDFunName clas [mkTyConApp tycon []] loc }
1131         -- The type passed to newDFunName is only used to generate
1132         -- a suitable string; hence the empty type arg list
1133
1134 badCon :: DataCon -> SDoc -> SDoc
1135 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1136 \end{code}
1137
1138 Note [Superclasses of derived instance]
1139 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1140 In general, a derived instance decl needs the superclasses of the derived
1141 class too.  So if we have
1142         data T a = ...deriving( Ord )
1143 then the initial context for Ord (T a) should include Eq (T a).  Often this is
1144 redundant; we'll also generate an Ord constraint for each constructor argument,
1145 and that will probably generate enough constraints to make the Eq (T a) constraint
1146 be satisfied too.  But not always; consider:
1147
1148  data S a = S
1149  instance Eq (S a)
1150  instance Ord (S a)
1151
1152  data T a = MkT (S a) deriving( Ord )
1153  instance Num a => Eq (T a)
1154
1155 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1156 Similarly consider:
1157         data T a = MkT deriving( Data, Typeable )
1158 Here there *is* no argument field, but we must nevertheless generate
1159 a context for the Data instances:
1160         instance Typable a => Data (T a) where ...
1161
1162
1163 %************************************************************************
1164 %*                                                                      *
1165                 Deriving newtypes
1166 %*                                                                      *
1167 %************************************************************************
1168
1169 \begin{code}
1170 mkNewTypeEqn :: CtOrigin -> DynFlags -> [Var] -> Class
1171              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1172              -> DerivContext
1173              -> TcRn EarlyDerivSpec
1174 mkNewTypeEqn orig dflags tvs
1175              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1176 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1177   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1178   = do  { traceTc "newtype deriving:" (ppr tycon <+> ppr rep_tys <+> ppr all_preds)
1179         ; dfun_name <- new_dfun_name cls tycon
1180         ; loc <- getSrcSpanM
1181         ; let spec = DS { ds_loc = loc, ds_orig = orig
1182                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs
1183                         , ds_cls = cls, ds_tys = inst_tys
1184                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1185                         , ds_theta =  mtheta `orElse` all_preds
1186                         , ds_newtype = True }
1187         ; return (if isJust mtheta then Right spec
1188                                    else Left spec) }
1189
1190   | otherwise
1191   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1192       CanDerive -> go_for_it    -- Use the standard H98 method
1193       DerivableClassError msg   -- Error with standard class
1194         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1195         | otherwise                  -> bale_out msg
1196       NonDerivableClass         -- Must use newtype deriving
1197         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1198         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1199         | otherwise                  -> bale_out non_std
1200   where
1201         newtype_deriving = xopt Opt_GeneralizedNewtypeDeriving dflags
1202         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1203         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1204
1205         non_std    = nonStdErr cls
1206         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1207
1208         -- Here is the plan for newtype derivings.  We see
1209         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1210         -- where t is a type,
1211         --       ak+1...an is a suffix of a1..an, and are all tyars
1212         --       ak+1...an do not occur free in t, nor in the s1..sm
1213         --       (C s1 ... sm) is a  *partial applications* of class C
1214         --                      with the last parameter missing
1215         --       (T a1 .. ak) matches the kind of C's last argument
1216         --              (and hence so does t)
1217         -- The latter kind-check has been done by deriveTyData already,
1218         -- and tc_args are already trimmed
1219         --
1220         -- We generate the instance
1221         --       instance forall ({a1..ak} u fvs(s1..sm)).
1222         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1223         -- where T a1...ap is the partial application of
1224         --       the LHS of the correct kind and p >= k
1225         --
1226         --      NB: the variables below are:
1227         --              tc_tvs = [a1, ..., an]
1228         --              tyvars_to_keep = [a1, ..., ak]
1229         --              rep_ty = t ak .. an
1230         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1231         --              tys = [s1, ..., sm]
1232         --              rep_fn' = t
1233         --
1234         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1235         -- We generate the instance
1236         --      instance Monad (ST s) => Monad (T s) where
1237
1238         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1239                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1240                 -- eta-reduces the representation type, so we know that
1241                 --      T a ~ S a a
1242                 -- That's convenient here, because we may have to apply
1243                 -- it to fewer than its original complement of arguments
1244
1245         -- Note [Newtype representation]
1246         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1247         -- Need newTyConRhs (*not* a recursive representation finder)
1248         -- to get the representation type. For example
1249         --      newtype B = MkB Int
1250         --      newtype A = MkA B deriving( Num )
1251         -- We want the Num instance of B, *not* the Num instance of Int,
1252         -- when making the Num instance of A!
1253         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1254         rep_tys     = cls_tys ++ [rep_inst_ty]
1255         rep_pred    = mkClassPred cls rep_tys
1256                 -- rep_pred is the representation dictionary, from where
1257                 -- we are gong to get all the methods for the newtype
1258                 -- dictionary
1259
1260
1261     -- Next we figure out what superclass dictionaries to use
1262     -- See Note [Newtype deriving superclasses] above
1263
1264         cls_tyvars = classTyVars cls
1265         dfun_tvs = tyVarsOfTypes inst_tys
1266         inst_ty = mkTyConApp tycon tc_args
1267         inst_tys = cls_tys ++ [inst_ty]
1268         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1269                               (classSCTheta cls)
1270
1271                 -- If there are no tyvars, there's no need
1272                 -- to abstract over the dictionaries we need
1273                 -- Example:     newtype T = MkT Int deriving( C )
1274                 -- We get the derived instance
1275                 --              instance C T
1276                 -- rather than
1277                 --              instance C Int => C T
1278         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1279
1280         -------------------------------------------------------------------
1281         --  Figuring out whether we can only do this newtype-deriving thing
1282
1283         can_derive_via_isomorphism
1284            =  not (non_iso_class cls)
1285            && arity_ok
1286            && eta_ok
1287            && ats_ok
1288 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1289
1290         arity_ok = length cls_tys + 1 == classArity cls
1291                 -- Well kinded; eg not: newtype T ... deriving( ST )
1292                 --                      because ST needs *2* type params
1293
1294         -- Check that eta reduction is OK
1295         eta_ok = nt_eta_arity <= length rep_tc_args
1296                 -- The newtype can be eta-reduced to match the number
1297                 --     of type argument actually supplied
1298                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1299                 --     Here the 'b' must be the same in the rep type (S [a] b)
1300                 --     And the [a] must not mention 'b'.  That's all handled
1301                 --     by nt_eta_rity.
1302
1303         ats_ok = null (classATs cls)
1304                -- No associated types for the class, because we don't
1305                -- currently generate type 'instance' decls; and cannot do
1306                -- so for 'data' instance decls
1307
1308         cant_derive_err
1309            = vcat [ ppUnless arity_ok arity_msg
1310                   , ppUnless eta_ok eta_msg
1311                   , ppUnless ats_ok ats_msg ]
1312         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1313         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1314         ats_msg   = ptext (sLit "the class has associated types")
1315 \end{code}
1316
1317 Note [Recursive newtypes]
1318 ~~~~~~~~~~~~~~~~~~~~~~~~~
1319 Newtype deriving works fine, even if the newtype is recursive.
1320 e.g.    newtype S1 = S1 [T1 ()]
1321         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1322 Remember, too, that type families are curretly (conservatively) given
1323 a recursive flag, so this also allows newtype deriving to work
1324 for type famillies.
1325
1326 We used to exclude recursive types, because we had a rather simple
1327 minded way of generating the instance decl:
1328    newtype A = MkA [A]
1329    instance Eq [A] => Eq A      -- Makes typechecker loop!
1330 But now we require a simple context, so it's ok.
1331
1332
1333 %************************************************************************
1334 %*                                                                      *
1335 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1336 %*                                                                      *
1337 %************************************************************************
1338
1339 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1340 terms, which is the final correct RHS for the corresponding original
1341 equation.
1342 \begin{itemize}
1343 \item
1344 Each (k,TyVarTy tv) in a solution constrains only a type
1345 variable, tv.
1346
1347 \item
1348 The (k,TyVarTy tv) pairs in a solution are canonically
1349 ordered by sorting on type varible, tv, (major key) and then class, k,
1350 (minor key)
1351 \end{itemize}
1352
1353 \begin{code}
1354 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1355
1356 inferInstanceContexts _ [] = return []
1357
1358 inferInstanceContexts oflag infer_specs
1359   = do  { traceTc "inferInstanceContexts" $ vcat (map pprDerivSpec infer_specs)
1360         ; iterate_deriv 1 initial_solutions }
1361   where
1362     ------------------------------------------------------------------
1363         -- The initial solutions for the equations claim that each
1364         -- instance has an empty context; this solution is certainly
1365         -- in canonical form.
1366     initial_solutions :: [ThetaType]
1367     initial_solutions = [ [] | _ <- infer_specs ]
1368
1369     ------------------------------------------------------------------
1370         -- iterate_deriv calculates the next batch of solutions,
1371         -- compares it with the current one; finishes if they are the
1372         -- same, otherwise recurses with the new solutions.
1373         -- It fails if any iteration fails
1374     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1375     iterate_deriv n current_solns
1376       | n > 20  -- Looks as if we are in an infinite loop
1377                 -- This can happen if we have -XUndecidableInstances
1378                 -- (See TcSimplify.tcSimplifyDeriv.)
1379       = pprPanic "solveDerivEqns: probable loop"
1380                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1381       | otherwise
1382       = do {      -- Extend the inst info from the explicit instance decls
1383                   -- with the current set of solutions, and simplify each RHS
1384              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1385                                            current_solns infer_specs
1386            ; new_solns <- checkNoErrs $
1387                           extendLocalInstEnv inst_specs $
1388                           mapM gen_soln infer_specs
1389
1390            ; if (current_solns == new_solns) then
1391                 return [ spec { ds_theta = soln }
1392                        | (spec, soln) <- zip infer_specs current_solns ]
1393              else
1394                 iterate_deriv (n+1) new_solns }
1395
1396     ------------------------------------------------------------------
1397     gen_soln :: DerivSpec  -> TcM [PredType]
1398     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars
1399                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1400       = setSrcSpan loc  $
1401         addErrCtxt (derivInstCtxt the_pred) $
1402         do {      -- Check for a bizarre corner case, when the derived instance decl should
1403                   -- have form  instance C a b => D (T a) where ...
1404                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1405                   -- of problems; in particular, it's hard to compare solutions for
1406                   -- equality when finding the fixpoint.  Moreover, simplifyDeriv
1407                   -- has an assert failure because it finds a TyVar when it expects
1408                   -- only TcTyVars.  So I just rule it out for now.  I'm not
1409                   -- even sure how it can arise.
1410
1411            ; let tv_set = mkVarSet tyvars
1412                  weird_preds = [pred | pred <- deriv_rhs
1413                                      , not (tyVarsOfPred pred `subVarSet` tv_set)]
1414            ; mapM_ (addErrTc . badDerivedPred) weird_preds
1415
1416            ; theta <- simplifyDeriv orig the_pred tyvars deriv_rhs
1417                 -- checkValidInstance tyvars theta clas inst_tys
1418                 -- Not necessary; see Note [Exotic derived instance contexts]
1419                 --                in TcSimplify
1420
1421            ; traceTc "TcDeriv" (ppr deriv_rhs $$ ppr theta)
1422                 -- Claim: the result instance declaration is guaranteed valid
1423                 -- Hence no need to call:
1424                 --   checkValidInstance tyvars theta clas inst_tys
1425            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1426       where
1427         the_pred = mkClassPred clas inst_tys
1428
1429 ------------------------------------------------------------------
1430 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1431 mkInstance overlap_flag theta
1432             (DS { ds_name = dfun_name
1433                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1434   = mkLocalInstance dfun overlap_flag
1435   where
1436     dfun = mkDictFunId dfun_name tyvars theta clas tys
1437
1438
1439 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1440 -- Add new locally-defined instances; don't bother to check
1441 -- for functional dependency errors -- that'll happen in TcInstDcls
1442 extendLocalInstEnv dfuns thing_inside
1443  = do { env <- getGblEnv
1444       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1445              env'      = env { tcg_inst_env = inst_env' }
1446       ; setGblEnv env' thing_inside }
1447 \end{code}
1448
1449
1450 %************************************************************************
1451 %*                                                                      *
1452 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1453 %*                                                                      *
1454 %************************************************************************
1455
1456 After all the trouble to figure out the required context for the
1457 derived instance declarations, all that's left is to chug along to
1458 produce them.  They will then be shoved into @tcInstDecls2@, which
1459 will do all its usual business.
1460
1461 There are lots of possibilities for code to generate.  Here are
1462 various general remarks.
1463
1464 PRINCIPLES:
1465 \begin{itemize}
1466 \item
1467 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1468 ``you-couldn't-do-better-by-hand'' efficient.
1469
1470 \item
1471 Deriving @Show@---also pretty common--- should also be reasonable good code.
1472
1473 \item
1474 Deriving for the other classes isn't that common or that big a deal.
1475 \end{itemize}
1476
1477 PRAGMATICS:
1478
1479 \begin{itemize}
1480 \item
1481 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1482
1483 \item
1484 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1485
1486 \item
1487 We {\em normally} generate code only for the non-defaulted methods;
1488 there are some exceptions for @Eq@ and (especially) @Ord@...
1489
1490 \item
1491 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1492 constructor's numeric (@Int#@) tag.  These are generated by
1493 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1494 these is around is given by @hasCon2TagFun@.
1495
1496 The examples under the different sections below will make this
1497 clearer.
1498
1499 \item
1500 Much less often (really just for deriving @Ix@), we use a
1501 @_tag2con_<tycon>@ function.  See the examples.
1502
1503 \item
1504 We use the renamer!!!  Reason: we're supposed to be
1505 producing @LHsBinds Name@ for the methods, but that means
1506 producing correctly-uniquified code on the fly.  This is entirely
1507 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1508 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1509 the renamer.  What a great hack!
1510 \end{itemize}
1511
1512 \begin{code}
1513 -- Generate the InstInfo for the required instance paired with the
1514 --   *representation* tycon for that instance,
1515 -- plus any auxiliary bindings required
1516 --
1517 -- Representation tycons differ from the tycon in the instance signature in
1518 -- case of instances for indexed families.
1519 --
1520 genInst :: Bool         -- True <=> standalone deriving
1521         -> OverlapFlag
1522         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1523 genInst standalone_deriv oflag
1524         spec@(DS { ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1525                  , ds_theta = theta, ds_newtype = is_newtype
1526                  , ds_name = name, ds_cls = clas })
1527   | is_newtype
1528   = return (InstInfo { iSpec   = inst_spec
1529                      , iBinds  = NewTypeDerived co rep_tycon }, [])
1530
1531   | otherwise
1532   = do  { fix_env <- getFixityEnv
1533         ; let loc   = getSrcSpan name
1534               (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1535                    -- In case of a family instance, we need to use the representation
1536                    -- tycon (after all, it has the data constructors)
1537
1538         ; return (InstInfo { iSpec   = inst_spec
1539                            , iBinds  = VanillaInst meth_binds [] standalone_deriv }
1540                  , aux_binds) }
1541   where
1542     inst_spec = mkInstance oflag theta spec
1543     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1544               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1545               Nothing     -> id_co
1546               -- Not a family => rep_tycon = main tycon
1547     co2 = case newTyConCo_maybe rep_tycon of
1548               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1549               Nothing     -> id_co  -- The newtype is transparent; no need for a cast
1550     co = co1 `mkTransCoI` co2
1551     id_co = IdCo (mkTyConApp rep_tycon rep_tc_args)
1552
1553 -- Example: newtype instance N [a] = N1 (Tree a)
1554 --          deriving instance Eq b => Eq (N [(b,b)])
1555 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1556 -- When dealing with the deriving clause
1557 --    co1 : N [(b,b)] ~ R1:N (b,b)
1558 --    co2 : R1:N (b,b) ~ Tree (b,b)
1559 --    co  : N [(b,b)] ~ Tree (b,b)
1560
1561 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1562 genDerivBinds loc fix_env clas tycon
1563   | className clas `elem` typeableClassNames
1564   = (gen_Typeable_binds loc tycon, [])
1565
1566   | otherwise
1567   = case assocMaybe gen_list (getUnique clas) of
1568         Just gen_fn -> gen_fn loc tycon
1569         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1570   where
1571     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1572     gen_list = [(eqClassKey,            gen_Eq_binds)
1573                ,(ordClassKey,           gen_Ord_binds)
1574                ,(enumClassKey,          gen_Enum_binds)
1575                ,(boundedClassKey,       gen_Bounded_binds)
1576                ,(ixClassKey,            gen_Ix_binds)
1577                ,(showClassKey,          gen_Show_binds fix_env)
1578                ,(readClassKey,          gen_Read_binds fix_env)
1579                ,(dataClassKey,          gen_Data_binds)
1580                ,(functorClassKey,       gen_Functor_binds)
1581                ,(foldableClassKey,      gen_Foldable_binds)
1582                ,(traversableClassKey,   gen_Traversable_binds)
1583                ,(genClassKey,           genGenericBinds)
1584                ]
1585 \end{code}
1586
1587 %************************************************************************
1588 %*                                                                      *
1589 \subsection[TcDeriv-generic-binds]{Bindings for the new generic deriving mechanism}
1590 %*                                                                      *
1591 %************************************************************************
1592
1593 For the generic representation we need to generate:
1594 \begin{itemize}
1595 \item A Generic instance
1596 \item A Rep type instance
1597 \item Many auxiliary datatypes and instances for them (for the meta-information)
1598 \end{itemize}
1599
1600 @genGenericBinds@ does (1)
1601 @genGenericRepExtras@ does (2) and (3)
1602 @genGenericAll@ does all of them
1603
1604 \begin{code}
1605 genGenericBinds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1606 genGenericBinds _ tc = (mkBindsRep tc, [ {- No DerivAuxBinds -} ])
1607
1608 genGenericRepExtras :: TyCon -> TcM (MetaTyCons, TyCon)
1609 genGenericRepExtras tc =
1610   do  uniqS <- newUniqueSupply
1611       let
1612         -- Uniques for everyone
1613         (uniqD:uniqs) = uniqsFromSupply uniqS
1614         (uniqsC,us) = splitAt (length tc_cons) uniqs
1615         uniqsS :: [[Unique]] -- Unique supply for the S datatypes
1616         uniqsS = mkUniqsS tc_arits us
1617         mkUniqsS []    _  = []
1618         mkUniqsS (n:t) us = case splitAt n us of
1619                               (us1,us2) -> us1 : mkUniqsS t us2
1620
1621         tc_name   = tyConName tc
1622         tc_cons   = tyConDataCons tc
1623         tc_arits  = map dataConSourceArity tc_cons
1624
1625         tc_occ    = nameOccName tc_name
1626         d_occ     = mkGenD tc_occ
1627         c_occ m   = mkGenC tc_occ m
1628         s_occ m n = mkGenS tc_occ m n
1629         mod_name  = nameModule (tyConName tc)
1630         d_name    = mkExternalName uniqD mod_name d_occ wiredInSrcSpan
1631         c_names   = [ mkExternalName u mod_name (c_occ m) wiredInSrcSpan
1632                       | (u,m) <- zip uniqsC [0..] ]
1633         s_names   = [ [ mkExternalName u mod_name (s_occ m n) wiredInSrcSpan
1634                         | (u,n) <- zip us [0..] ] | (us,m) <- zip uniqsS [0..] ]
1635
1636         mkTyCon name = ASSERT( isExternalName name )
1637                          buildAlgTyCon name [] [] mkAbstractTyConRhs
1638                            NonRecursive False NoParentTyCon Nothing
1639
1640       metaDTyCon  <- mkTyCon d_name
1641       metaCTyCons <- sequence [ mkTyCon c_name | c_name <- c_names ]
1642       metaSTyCons <- mapM sequence
1643                        [ [ mkTyCon s_name
1644                          | s_name <- s_namesC ] | s_namesC <- s_names ]
1645
1646       let metaDts = MetaTyCons metaDTyCon metaCTyCons metaSTyCons
1647
1648       rep0_tycon <- tc_mkRepTyCon tc metaDts
1649
1650       return (metaDts, rep0_tycon)
1651 {-
1652 genGenericAll :: TyCon
1653                   -> TcM ((InstInfo RdrName, DerivAuxBinds), MetaTyCons, TyCon)
1654 genGenericAll tc =
1655   do  (metaDts, rep0_tycon)     <- genGenericRepExtras tc
1656       clas                      <- tcLookupClass genClassName
1657       dfun_name                 <- new_dfun_name clas tc
1658       let
1659         mkInstRep = (InstInfo { iSpec = inst, iBinds = binds }
1660                                , [ {- No DerivAuxBinds -} ])
1661         inst  = mkLocalInstance dfun NoOverlap
1662         binds = VanillaInst (mkBindsRep tc) [] False
1663
1664         tvs   = tyConTyVars tc
1665         tc_ty = mkTyConApp tc (mkTyVarTys tvs)
1666
1667         dfun  = mkDictFunId dfun_name (tyConTyVars tc) [] clas [tc_ty]
1668       return (mkInstRep, metaDts, rep0_tycon)
1669 -}
1670 genDtMeta :: (TyCon, MetaTyCons) -> TcM [(InstInfo RdrName, DerivAuxBinds)]
1671 genDtMeta (tc,metaDts) =
1672   do  dClas <- tcLookupClass datatypeClassName
1673       d_dfun_name <- new_dfun_name dClas tc
1674       cClas <- tcLookupClass constructorClassName
1675       c_dfun_names <- sequence [ new_dfun_name cClas tc | _ <- metaC metaDts ]
1676       sClas <- tcLookupClass selectorClassName
1677       s_dfun_names <- sequence (map sequence [ [ new_dfun_name sClas tc
1678                                                | _ <- x ]
1679                                              | x <- metaS metaDts ])
1680       fix_env <- getFixityEnv
1681
1682       let
1683         (dBinds,cBinds,sBinds) = mkBindsMetaD fix_env tc
1684
1685         -- Datatype
1686         d_metaTycon = metaD metaDts
1687         d_inst = mkLocalInstance d_dfun NoOverlap
1688         d_binds = VanillaInst dBinds [] False
1689         d_dfun  = mkDictFunId d_dfun_name (tyConTyVars tc) [] dClas
1690                     [ mkTyConTy d_metaTycon ]
1691         d_mkInst = (InstInfo { iSpec = d_inst, iBinds = d_binds }, [])
1692
1693         -- Constructor
1694         c_metaTycons = metaC metaDts
1695         c_insts = [ mkLocalInstance (c_dfun c ds) NoOverlap
1696                   | (c, ds) <- myZip1 c_metaTycons c_dfun_names ]
1697         c_binds = [ VanillaInst c [] False | c <- cBinds ]
1698         c_dfun c dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] cClas
1699                                [ mkTyConTy c ]
1700         c_mkInst = [ (InstInfo { iSpec = is, iBinds = bs }, [])
1701                    | (is,bs) <- myZip1 c_insts c_binds ]
1702
1703         -- Selector
1704         s_metaTycons = metaS metaDts
1705         s_insts = map (map (\(s,ds) -> mkLocalInstance (s_dfun s ds) NoOverlap))
1706                     (myZip2 s_metaTycons s_dfun_names)
1707         s_binds = [ [ VanillaInst s [] False | s <- ss ] | ss <- sBinds ]
1708         s_dfun s dfun_name = mkDictFunId dfun_name (tyConTyVars tc) [] sClas
1709                                [ mkTyConTy s ]
1710         s_mkInst = map (map (\(is,bs) -> (InstInfo {iSpec=is, iBinds=bs}, [])))
1711                      (myZip2 s_insts s_binds)
1712
1713         myZip1 :: [a] -> [b] -> [(a,b)]
1714         myZip1 l1 l2 = ASSERT (length l1 == length l2) zip l1 l2
1715
1716         myZip2 :: [[a]] -> [[b]] -> [[(a,b)]]
1717         myZip2 l1 l2 =
1718           ASSERT (and (zipWith (>=) (map length l1) (map length l2)))
1719             [ zip x1 x2 | (x1,x2) <- zip l1 l2 ]
1720
1721       return (d_mkInst : c_mkInst ++ concat s_mkInst)
1722 \end{code}
1723
1724
1725 %************************************************************************
1726 %*                                                                      *
1727 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1728 %*                                                                      *
1729 %************************************************************************
1730
1731 \begin{code}
1732 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1733 derivingKindErr tc cls cls_tys cls_kind
1734   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1735                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1736        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1737             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1738
1739 derivingEtaErr :: Class -> [Type] -> Type -> Message
1740 derivingEtaErr cls cls_tys inst_ty
1741   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1742          nest 2 (ptext (sLit "instance (...) =>")
1743                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1744
1745 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1746 typeFamilyPapErr tc cls cls_tys inst_ty
1747   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1748        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc)
1749
1750 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1751 derivingThingErr newtype_deriving clas tys ty why
1752   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1753              2 (quotes (ppr pred))
1754           $$ nest 2 extra) <> colon,
1755          nest 2 why]
1756   where
1757     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1758           | otherwise        = empty
1759     pred = mkClassPred clas (tys ++ [ty])
1760
1761 derivingHiddenErr :: TyCon -> SDoc
1762 derivingHiddenErr tc
1763   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1764        2 (ptext (sLit "so you cannot derive an instance for it"))
1765
1766 standaloneCtxt :: LHsType Name -> SDoc
1767 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
1768                        2 (quotes (ppr ty))
1769
1770 derivInstCtxt :: PredType -> Message
1771 derivInstCtxt pred
1772   = ptext (sLit "When deriving the instance for") <+> parens (ppr pred)
1773
1774 badDerivedPred :: PredType -> Message
1775 badDerivedPred pred
1776   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1777           ptext (sLit "type variables that are not data type parameters"),
1778           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1779 \end{code}