compiler/typecheck/TcGenDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 TcGenDeriv: Generating derived instance declarations
   7
   8 This module is nominally ``subordinate'' to @TcDeriv@, which is the
   9 ``official'' interface to deriving-related things.
  10
  11 This is where we do all the grimy bindings' generation.
  12
  13 \begin{code}
  14 module TcGenDeriv (
  15         DerivAuxBinds, isDupAux,
  16
  17         gen_Bounded_binds,
  18         gen_Enum_binds,
  19         gen_Eq_binds,
  20         gen_Ix_binds,
  21         gen_Ord_binds,
  22         gen_Read_binds,
  23         gen_Show_binds,
  24         gen_Data_binds,
  25         gen_Typeable_binds,
  26         gen_Functor_binds,
  27         FFoldType(..), functorLikeTraverse,
  28         deepSubtypesContaining, foldDataConArgs,
  29         gen_Foldable_binds,
  30         gen_Traversable_binds,
  31         genAuxBind
  32     ) where
  33
  34 #include "HsVersions.h"
  35
  36 import HsSyn
  37 import RdrName
  38 import BasicTypes
  39 import DataCon
  40 import Name
  41
  42 import HscTypes
  43 import PrelInfo
  44 import MkCore   ( eRROR_ID )
  45 import PrelNames
  46 import PrimOp
  47 import SrcLoc
  48 import TyCon
  49 import TcType
  50 import TysPrim
  51 import TysWiredIn
  52 import Type
  53 import Var( TyVar )
  54 import TypeRep
  55 import VarSet
  56 import State
  57 import Util
  58 import MonadUtils
  59 import Outputable
  60 import FastString
  61 import Bag
  62 import Data.List        ( partition, intersperse )
  63 \end{code}
  64
  65 \begin{code}
  66 type DerivAuxBinds = [DerivAuxBind]
  67
  68 data DerivAuxBind               -- Please add these auxiliary top-level bindings
  69   = GenCon2Tag TyCon            -- The con2Tag for given TyCon
  70   | GenTag2Con TyCon            -- ...ditto tag2Con
  71   | GenMaxTag  TyCon            -- ...and maxTag
  72         -- All these generate ZERO-BASED tag operations
  73         -- I.e first constructor has tag 0
  74
  75         -- Scrap your boilerplate
  76   | MkDataCon DataCon           -- For constructor C we get $cC :: Constr
  77   | MkTyCon   TyCon             -- For tycon T we get       $tT :: DataType
  78
  79
  80 isDupAux :: DerivAuxBind -> DerivAuxBind -> Bool
  81 isDupAux (GenCon2Tag tc1) (GenCon2Tag tc2) = tc1 == tc2
  82 isDupAux (GenTag2Con tc1) (GenTag2Con tc2) = tc1 == tc2
  83 isDupAux (GenMaxTag tc1)  (GenMaxTag tc2)  = tc1 == tc2
  84 isDupAux (MkDataCon dc1)  (MkDataCon dc2)  = dc1 == dc2
  85 isDupAux (MkTyCon tc1)    (MkTyCon tc2)    = tc1 == tc2
  86 isDupAux _                _                = False
  87 \end{code}
  88
  89
  90 %************************************************************************
  91 %*                                                                      *
  92                 Eq instances
  93 %*                                                                      *
  94 %************************************************************************
  95
  96 Here are the heuristics for the code we generate for @Eq@:
  97 \begin{itemize}
  98 \item
  99   Let's assume we have a data type with some (possibly zero) nullary
 100   data constructors and some ordinary, non-nullary ones (the rest,
 101   also possibly zero of them).  Here's an example, with both \tr{N}ullary
 102   and \tr{O}rdinary data cons.
 103 \begin{verbatim}
 104 data Foo ... = N1 | N2 ... | Nn | O1 a b | O2 Int | O3 Double b b | ...
 105 \end{verbatim}
 106
 107 \item
 108   For the ordinary constructors (if any), we emit clauses to do The
 109   Usual Thing, e.g.,:
 110
 111 \begin{verbatim}
 112 (==) (O1 a1 b1)    (O1 a2 b2)    = a1 == a2 && b1 == b2
 113 (==) (O2 a1)       (O2 a2)       = a1 == a2
 114 (==) (O3 a1 b1 c1) (O3 a2 b2 c2) = a1 == a2 && b1 == b2 && c1 == c2
 115 \end{verbatim}
 116
 117   Note: if we're comparing unlifted things, e.g., if \tr{a1} and
 118   \tr{a2} are \tr{Float#}s, then we have to generate
 119 \begin{verbatim}
 120 case (a1 `eqFloat#` a2) of
 121   r -> r
 122 \end{verbatim}
 123   for that particular test.
 124
 125 \item
 126   If there are any nullary constructors, we emit a catch-all clause of
 127   the form:
 128
 129 \begin{verbatim}
 130 (==) a b  = case (con2tag_Foo a) of { a# ->
 131             case (con2tag_Foo b) of { b# ->
 132             case (a# ==# b#)     of {
 133               r -> r
 134             }}}
 135 \end{verbatim}
 136
 137   If there aren't any nullary constructors, we emit a simpler
 138   catch-all:
 139 \begin{verbatim}
 140 (==) a b  = False
 141 \end{verbatim}
 142
 143 \item
 144   For the @(/=)@ method, we normally just use the default method.
 145
 146   If the type is an enumeration type, we could/may/should? generate
 147   special code that calls @con2tag_Foo@, much like for @(==)@ shown
 148   above.
 149
 150 \item
 151   We thought about doing this: If we're also deriving @Ord@ for this
 152   tycon, we generate:
 153 \begin{verbatim}
 154 instance ... Eq (Foo ...) where
 155   (==) a b  = case (compare a b) of { _LT -> False; _EQ -> True ; _GT -> False}
 156   (/=) a b  = case (compare a b) of { _LT -> True ; _EQ -> False; _GT -> True }
 157 \begin{verbatim}
 158   However, that requires that \tr{Ord <whatever>} was put in the context
 159   for the instance decl, which it probably wasn't, so the decls
 160   produced don't get through the typechecker.
 161 \end{itemize}
 162
 163
 164 \begin{code}
 165 gen_Eq_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 166 gen_Eq_binds loc tycon
 167   = (method_binds, aux_binds)
 168   where
 169     (nullary_cons, nonnullary_cons)
 170        | isNewTyCon tycon = ([], tyConDataCons tycon)
 171        | otherwise        = partition isNullarySrcDataCon (tyConDataCons tycon)
 172
 173     no_nullary_cons = null nullary_cons
 174
 175     rest | no_nullary_cons
 176          = case tyConSingleDataCon_maybe tycon of
 177                   Just _ -> []
 178                   Nothing -> -- if cons don't match, then False
 179                      [([nlWildPat, nlWildPat], false_Expr)]
 180          | otherwise -- calc. and compare the tags
 181          = [([a_Pat, b_Pat],
 182             untag_Expr tycon [(a_RDR,ah_RDR), (b_RDR,bh_RDR)]
 183                        (genOpApp (nlHsVar ah_RDR) eqInt_RDR (nlHsVar bh_RDR)))]
 184
 185     aux_binds | no_nullary_cons = []
 186               | otherwise       = [GenCon2Tag tycon]
 187
 188     method_binds = listToBag [eq_bind, ne_bind]
 189     eq_bind = mk_FunBind loc eq_RDR (map pats_etc nonnullary_cons ++ rest)
 190     ne_bind = mk_easy_FunBind loc ne_RDR [a_Pat, b_Pat] (
 191                         nlHsApp (nlHsVar not_RDR) (nlHsPar (nlHsVarApps eq_RDR [a_RDR, b_RDR])))
 192
 193     ------------------------------------------------------------------
 194     pats_etc data_con
 195       = let
 196             con1_pat = nlConVarPat data_con_RDR as_needed
 197             con2_pat = nlConVarPat data_con_RDR bs_needed
 198
 199             data_con_RDR = getRdrName data_con
 200             con_arity   = length tys_needed
 201             as_needed   = take con_arity as_RDRs
 202             bs_needed   = take con_arity bs_RDRs
 203             tys_needed  = dataConOrigArgTys data_con
 204         in
 205         ([con1_pat, con2_pat], nested_eq_expr tys_needed as_needed bs_needed)
 206       where
 207         nested_eq_expr []  [] [] = true_Expr
 208         nested_eq_expr tys as bs
 209           = foldl1 and_Expr (zipWith3Equal "nested_eq" nested_eq tys as bs)
 210           where
 211             nested_eq ty a b = nlHsPar (eq_Expr tycon ty (nlHsVar a) (nlHsVar b))
 212 \end{code}
 213
 214 %************************************************************************
 215 %*                                                                      *
 216         Ord instances
 217 %*                                                                      *
 218 %************************************************************************
 219
 220 Note [Generating Ord instances]
 221 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 222 Suppose constructors are K1..Kn, and some are nullary.
 223 The general form we generate is:
 224
 225 * Do case on first argument
 226         case a of
 227           K1 ... -> rhs_1
 228           K2 ... -> rhs_2
 229           ...
 230           Kn ... -> rhs_n
 231           _ -> nullary_rhs
 232
 233 * To make rhs_i
 234      If i = 1, 2, n-1, n, generate a single case.
 235         rhs_2    case b of
 236                    K1 {}  -> LT
 237                    K2 ... -> ...eq_rhs(K2)...
 238                    _      -> GT
 239
 240      Otherwise do a tag compare against the bigger range
 241      (because this is the one most likely to succeed)
 242         rhs_3    case tag b of tb ->
 243                  if 3 <# tg then GT
 244                  else case b of
 245                          K3 ... -> ...eq_rhs(K3)....
 246                          _      -> LT
 247
 248 * To make eq_rhs(K), which knows that
 249     a = K a1 .. av
 250     b = K b1 .. bv
 251   we just want to compare (a1,b1) then (a2,b2) etc.
 252   Take care on the last field to tail-call into comparing av,bv
 253
 254 * To make nullary_rhs generate this
 255      case con2tag a of a# ->
 256      case con2tag b of ->
 257      a# `compare` b#
 258
 259 Several special cases:
 260
 261 * Two or fewer nullary constructors: don't generate nullary_rhs
 262
 263 * Be careful about unlifted comparisons.  When comparing unboxed
 264   values we can't call the overloaded functions.
 265   See function unliftedOrdOp
 266
 267 Note [Do not rely on compare]
 268 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 269 It's a bad idea to define only 'compare', and build the other binary
 270 comparisions on top of it; see Trac #2130, #4019.  Reason: we don't
 271 want to laboriously make a three-way comparison, only to extract a
 272 binary result, something like this:
 273      (>) (I# x) (I# y) = case <# x y of
 274                             True -> False
 275                             False -> case ==# x y of
 276                                        True  -> False
 277                                        False -> True
 278
 279 So for sufficiently small types (few constructors, or all nullary)
 280 we generate all methods; for large ones we just use 'compare'.
 281
 282 \begin{code}
 283 data OrdOp = OrdCompare | OrdLT | OrdLE | OrdGE | OrdGT
 284
 285 ------------
 286 ordMethRdr :: OrdOp -> RdrName
 287 ordMethRdr op
 288   = case op of
 289        OrdCompare -> compare_RDR
 290        OrdLT      -> lt_RDR
 291        OrdLE      -> le_RDR
 292        OrdGE      -> ge_RDR
 293        OrdGT      -> gt_RDR
 294
 295 ------------
 296 ltResult :: OrdOp -> LHsExpr RdrName
 297 -- Knowing a<b, what is the result for a `op` b?
 298 ltResult OrdCompare = ltTag_Expr
 299 ltResult OrdLT      = true_Expr
 300 ltResult OrdLE      = true_Expr
 301 ltResult OrdGE      = false_Expr
 302 ltResult OrdGT      = false_Expr
 303
 304 ------------
 305 eqResult :: OrdOp -> LHsExpr RdrName
 306 -- Knowing a=b, what is the result for a `op` b?
 307 eqResult OrdCompare = eqTag_Expr
 308 eqResult OrdLT      = false_Expr
 309 eqResult OrdLE      = true_Expr
 310 eqResult OrdGE      = true_Expr
 311 eqResult OrdGT      = false_Expr
 312
 313 ------------
 314 gtResult :: OrdOp -> LHsExpr RdrName
 315 -- Knowing a>b, what is the result for a `op` b?
 316 gtResult OrdCompare = gtTag_Expr
 317 gtResult OrdLT      = false_Expr
 318 gtResult OrdLE      = false_Expr
 319 gtResult OrdGE      = true_Expr
 320 gtResult OrdGT      = true_Expr
 321
 322 ------------
 323 gen_Ord_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 324 gen_Ord_binds loc tycon
 325   | null tycon_data_cons        -- No data-cons => invoke bale-out case
 326   = (unitBag $ mk_FunBind loc compare_RDR [], [])
 327   | otherwise
 328   = (unitBag (mkOrdOp OrdCompare) `unionBags` other_ops, aux_binds)
 329   where
 330     aux_binds | single_con_type = []
 331               | otherwise       = [GenCon2Tag tycon]
 332
 333         -- Note [Do not rely on compare]
 334     other_ops | (last_tag - first_tag) <= 2     -- 1-3 constructors
 335                 || null non_nullary_cons        -- Or it's an enumeration
 336               = listToBag (map mkOrdOp [OrdLT,OrdLE,OrdGE,OrdGT])
 337               | otherwise
 338               = emptyBag
 339
 340     get_tag con = dataConTag con - fIRST_TAG
 341         -- We want *zero-based* tags, because that's what
 342         -- con2Tag returns (generated by untag_Expr)!
 343
 344     tycon_data_cons = tyConDataCons tycon
 345     single_con_type = isSingleton tycon_data_cons
 346     (first_con : _) = tycon_data_cons
 347     (last_con : _)  = reverse tycon_data_cons
 348     first_tag       = get_tag first_con
 349     last_tag        = get_tag last_con
 350
 351     (nullary_cons, non_nullary_cons) = partition isNullarySrcDataCon tycon_data_cons
 352
 353
 354     mkOrdOp :: OrdOp -> LHsBind RdrName
 355     -- Returns a binding   op a b = ... compares a and b according to op ....
 356     mkOrdOp op = mk_easy_FunBind loc (ordMethRdr op) [a_Pat, b_Pat] (mkOrdOpRhs op)
 357
 358     mkOrdOpRhs :: OrdOp -> LHsExpr RdrName
 359     mkOrdOpRhs op       -- RHS for comparing 'a' and 'b' according to op
 360       | length nullary_cons <= 2  -- Two nullary or fewer, so use cases
 361       = nlHsCase (nlHsVar a_RDR) $
 362         map (mkOrdOpAlt op) tycon_data_cons
 363         -- i.e.  case a of { C1 x y -> case b of C1 x y -> ....compare x,y...
 364         --                   C2 x   -> case b of C2 x -> ....comopare x.... }
 365
 366       | null non_nullary_cons    -- All nullary, so go straight to comparing tags
 367       = mkTagCmp op
 368
 369       | otherwise                -- Mixed nullary and non-nullary
 370       = nlHsCase (nlHsVar a_RDR) $
 371         (map (mkOrdOpAlt op) non_nullary_cons
 372          ++ [mkSimpleHsAlt nlWildPat (mkTagCmp op)])
 373
 374
 375     mkOrdOpAlt :: OrdOp -> DataCon -> LMatch RdrName
 376     -- Make the alternative  (Ki a1 a2 .. av ->
 377     mkOrdOpAlt op data_con
 378       = mkSimpleHsAlt (nlConVarPat data_con_RDR as_needed) (mkInnerRhs op data_con)
 379       where
 380         as_needed    = take (dataConSourceArity data_con) as_RDRs
 381         data_con_RDR = getRdrName data_con
 382
 383     mkInnerRhs op data_con
 384       | single_con_type
 385       = nlHsCase (nlHsVar b_RDR) [ mkInnerEqAlt op data_con ]
 386
 387       | tag == first_tag
 388       = nlHsCase (nlHsVar b_RDR) [ mkInnerEqAlt op data_con
 389                                  , mkSimpleHsAlt nlWildPat (ltResult op) ]
 390       | tag == last_tag
 391       = nlHsCase (nlHsVar b_RDR) [ mkInnerEqAlt op data_con
 392                                  , mkSimpleHsAlt nlWildPat (gtResult op) ]
 393
 394       | tag == first_tag + 1
 395       = nlHsCase (nlHsVar b_RDR) [ mkSimpleHsAlt (nlConWildPat first_con) (gtResult op)
 396                                  , mkInnerEqAlt op data_con
 397                                  , mkSimpleHsAlt nlWildPat (ltResult op) ]
 398       | tag == last_tag - 1
 399       = nlHsCase (nlHsVar b_RDR) [ mkSimpleHsAlt (nlConWildPat last_con) (ltResult op)
 400                                  , mkInnerEqAlt op data_con
 401                                  , mkSimpleHsAlt nlWildPat (gtResult op) ]
 402
 403       | tag > last_tag `div` 2  -- lower range is larger
 404       = untag_Expr tycon [(b_RDR, bh_RDR)] $
 405         nlHsIf (genOpApp (nlHsVar bh_RDR) ltInt_RDR tag_lit)
 406                (gtResult op) $  -- Definitely GT
 407         nlHsCase (nlHsVar b_RDR) [ mkInnerEqAlt op data_con
 408                                  , mkSimpleHsAlt nlWildPat (ltResult op) ]
 409
 410       | otherwise               -- upper range is larger
 411       = untag_Expr tycon [(b_RDR, bh_RDR)] $
 412         nlHsIf (genOpApp (nlHsVar bh_RDR) gtInt_RDR tag_lit)
 413                (ltResult op) $  -- Definitely LT
 414         nlHsCase (nlHsVar b_RDR) [ mkInnerEqAlt op data_con
 415                                  , mkSimpleHsAlt nlWildPat (gtResult op) ]
 416       where
 417         tag     = get_tag data_con
 418         tag_lit = noLoc (HsLit (HsIntPrim (toInteger tag)))
 419
 420     mkInnerEqAlt :: OrdOp -> DataCon -> LMatch RdrName
 421     -- First argument 'a' known to be built with K
 422     -- Returns a case alternative  Ki b1 b2 ... bv -> compare (a1,a2,...) with (b1,b2,...)
 423     mkInnerEqAlt op data_con
 424       = mkSimpleHsAlt (nlConVarPat data_con_RDR bs_needed) $
 425         mkCompareFields tycon op (dataConOrigArgTys data_con)
 426       where
 427         data_con_RDR = getRdrName data_con
 428         bs_needed    = take (dataConSourceArity data_con) bs_RDRs
 429
 430     mkTagCmp :: OrdOp -> LHsExpr RdrName
 431     -- Both constructors known to be nullary
 432     -- genreates (case data2Tag a of a# -> case data2Tag b of b# -> a# `op` b#
 433     mkTagCmp op = untag_Expr tycon [(a_RDR, ah_RDR),(b_RDR, bh_RDR)] $
 434                   unliftedOrdOp tycon intPrimTy op ah_RDR bh_RDR
 435
 436 mkCompareFields :: TyCon -> OrdOp -> [Type] -> LHsExpr RdrName
 437 -- Generates nested comparisons for (a1,a2...) against (b1,b2,...)
 438 -- where the ai,bi have the given types
 439 mkCompareFields tycon op tys
 440   = go tys as_RDRs bs_RDRs
 441   where
 442     go []   _      _          = eqResult op
 443     go [ty] (a:_)  (b:_)
 444       | isUnLiftedType ty     = unliftedOrdOp tycon ty op a b
 445       | otherwise             = genOpApp (nlHsVar a) (ordMethRdr op) (nlHsVar b)
 446     go (ty:tys) (a:as) (b:bs) = mk_compare ty a b
 447                                   (ltResult op)
 448                                   (go tys as bs)
 449                                   (gtResult op)
 450     go _ _ _ = panic "mkCompareFields"
 451
 452     -- (mk_compare ty a b) generates
 453     --    (case (compare a b) of { LT -> <lt>; EQ -> <eq>; GT -> <bt> })
 454     -- but with suitable special cases for
 455     mk_compare ty a b lt eq gt
 456       | isUnLiftedType ty
 457       = unliftedCompare lt_op eq_op a_expr b_expr lt eq gt
 458       | otherwise
 459       = nlHsCase (nlHsPar (nlHsApp (nlHsApp (nlHsVar compare_RDR) a_expr) b_expr))
 460           [mkSimpleHsAlt (nlNullaryConPat ltTag_RDR) lt,
 461            mkSimpleHsAlt (nlNullaryConPat eqTag_RDR) eq,
 462            mkSimpleHsAlt (nlNullaryConPat gtTag_RDR) gt]
 463       where
 464         a_expr = nlHsVar a
 465         b_expr = nlHsVar b
 466         (lt_op, _, eq_op, _, _) = primOrdOps "Ord" tycon ty
 467
 468 unliftedOrdOp :: TyCon -> Type -> OrdOp -> RdrName -> RdrName -> LHsExpr RdrName
 469 unliftedOrdOp tycon ty op a b
 470   = case op of
 471        OrdCompare -> unliftedCompare lt_op eq_op a_expr b_expr
 472                                      ltTag_Expr eqTag_Expr gtTag_Expr
 473        OrdLT      -> wrap lt_op
 474        OrdLE      -> wrap le_op
 475        OrdGE      -> wrap ge_op
 476        OrdGT      -> wrap gt_op
 477   where
 478    (lt_op, le_op, eq_op, ge_op, gt_op) = primOrdOps "Ord" tycon ty
 479    wrap prim_op = genOpApp a_expr (primOpRdrName prim_op) b_expr
 480    a_expr = nlHsVar a
 481    b_expr = nlHsVar b
 482
 483 unliftedCompare :: PrimOp -> PrimOp
 484                 -> LHsExpr RdrName -> LHsExpr RdrName   -- What to cmpare
 485                 -> LHsExpr RdrName -> LHsExpr RdrName -> LHsExpr RdrName  -- Three results
 486                 -> LHsExpr RdrName
 487 -- Return (if a < b then lt else if a == b then eq else gt)
 488 unliftedCompare lt_op eq_op a_expr b_expr lt eq gt
 489   = nlHsIf (genOpApp a_expr (primOpRdrName lt_op) b_expr) lt $
 490                         -- Test (<) first, not (==), becuase the latter
 491                         -- is true less often, so putting it first would
 492                         -- mean more tests (dynamically)
 493         nlHsIf (genOpApp a_expr (primOpRdrName eq_op) b_expr) eq gt
 494
 495 nlConWildPat :: DataCon -> LPat RdrName
 496 -- The pattern (K {})
 497 nlConWildPat con = noLoc (ConPatIn (noLoc (getRdrName con))
 498                                    (RecCon (HsRecFields { rec_flds = []
 499                                                         , rec_dotdot = Nothing })))
 500 \end{code}
 501
 502
 503
 504 %************************************************************************
 505 %*                                                                      *
 506         Enum instances
 507 %*                                                                      *
 508 %************************************************************************
 509
 510 @Enum@ can only be derived for enumeration types.  For a type
 511 \begin{verbatim}
 512 data Foo ... = N1 | N2 | ... | Nn
 513 \end{verbatim}
 514
 515 we use both @con2tag_Foo@ and @tag2con_Foo@ functions, as well as a
 516 @maxtag_Foo@ variable (all generated by @gen_tag_n_con_binds@).
 517
 518 \begin{verbatim}
 519 instance ... Enum (Foo ...) where
 520     succ x   = toEnum (1 + fromEnum x)
 521     pred x   = toEnum (fromEnum x - 1)
 522
 523     toEnum i = tag2con_Foo i
 524
 525     enumFrom a = map tag2con_Foo [con2tag_Foo a .. maxtag_Foo]
 526
 527     -- or, really...
 528     enumFrom a
 529       = case con2tag_Foo a of
 530           a# -> map tag2con_Foo (enumFromTo (I# a#) maxtag_Foo)
 531
 532    enumFromThen a b
 533      = map tag2con_Foo [con2tag_Foo a, con2tag_Foo b .. maxtag_Foo]
 534
 535     -- or, really...
 536     enumFromThen a b
 537       = case con2tag_Foo a of { a# ->
 538         case con2tag_Foo b of { b# ->
 539         map tag2con_Foo (enumFromThenTo (I# a#) (I# b#) maxtag_Foo)
 540         }}
 541 \end{verbatim}
 542
 543 For @enumFromTo@ and @enumFromThenTo@, we use the default methods.
 544
 545 \begin{code}
 546 gen_Enum_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 547 gen_Enum_binds loc tycon
 548   = (method_binds, aux_binds)
 549   where
 550     method_binds = listToBag [
 551                         succ_enum,
 552                         pred_enum,
 553                         to_enum,
 554                         enum_from,
 555                         enum_from_then,
 556                         from_enum
 557                     ]
 558     aux_binds = [GenCon2Tag tycon, GenTag2Con tycon, GenMaxTag tycon]
 559
 560     occ_nm = getOccString tycon
 561
 562     succ_enum
 563       = mk_easy_FunBind loc succ_RDR [a_Pat] $
 564         untag_Expr tycon [(a_RDR, ah_RDR)] $
 565         nlHsIf (nlHsApps eq_RDR [nlHsVar (maxtag_RDR tycon),
 566                                nlHsVarApps intDataCon_RDR [ah_RDR]])
 567              (illegal_Expr "succ" occ_nm "tried to take `succ' of last tag in enumeration")
 568              (nlHsApp (nlHsVar (tag2con_RDR tycon))
 569                     (nlHsApps plus_RDR [nlHsVarApps intDataCon_RDR [ah_RDR],
 570                                         nlHsIntLit 1]))
 571
 572     pred_enum
 573       = mk_easy_FunBind loc pred_RDR [a_Pat] $
 574         untag_Expr tycon [(a_RDR, ah_RDR)] $
 575         nlHsIf (nlHsApps eq_RDR [nlHsIntLit 0,
 576                                nlHsVarApps intDataCon_RDR [ah_RDR]])
 577              (illegal_Expr "pred" occ_nm "tried to take `pred' of first tag in enumeration")
 578              (nlHsApp (nlHsVar (tag2con_RDR tycon))
 579                            (nlHsApps plus_RDR [nlHsVarApps intDataCon_RDR [ah_RDR],
 580                                                nlHsLit (HsInt (-1))]))
 581
 582     to_enum
 583       = mk_easy_FunBind loc toEnum_RDR [a_Pat] $
 584         nlHsIf (nlHsApps and_RDR
 585                 [nlHsApps ge_RDR [nlHsVar a_RDR, nlHsIntLit 0],
 586                  nlHsApps le_RDR [nlHsVar a_RDR, nlHsVar (maxtag_RDR tycon)]])
 587              (nlHsVarApps (tag2con_RDR tycon) [a_RDR])
 588              (illegal_toEnum_tag occ_nm (maxtag_RDR tycon))
 589
 590     enum_from
 591       = mk_easy_FunBind loc enumFrom_RDR [a_Pat] $
 592           untag_Expr tycon [(a_RDR, ah_RDR)] $
 593           nlHsApps map_RDR
 594                 [nlHsVar (tag2con_RDR tycon),
 595                  nlHsPar (enum_from_to_Expr
 596                             (nlHsVarApps intDataCon_RDR [ah_RDR])
 597                             (nlHsVar (maxtag_RDR tycon)))]
 598
 599     enum_from_then
 600       = mk_easy_FunBind loc enumFromThen_RDR [a_Pat, b_Pat] $
 601           untag_Expr tycon [(a_RDR, ah_RDR), (b_RDR, bh_RDR)] $
 602           nlHsApp (nlHsVarApps map_RDR [tag2con_RDR tycon]) $
 603             nlHsPar (enum_from_then_to_Expr
 604                     (nlHsVarApps intDataCon_RDR [ah_RDR])
 605                     (nlHsVarApps intDataCon_RDR [bh_RDR])
 606                     (nlHsIf  (nlHsApps gt_RDR [nlHsVarApps intDataCon_RDR [ah_RDR],
 607                                              nlHsVarApps intDataCon_RDR [bh_RDR]])
 608                            (nlHsIntLit 0)
 609                            (nlHsVar (maxtag_RDR tycon))
 610                            ))
 611
 612     from_enum
 613       = mk_easy_FunBind loc fromEnum_RDR [a_Pat] $
 614           untag_Expr tycon [(a_RDR, ah_RDR)] $
 615           (nlHsVarApps intDataCon_RDR [ah_RDR])
 616 \end{code}
 617
 618 %************************************************************************
 619 %*                                                                      *
 620         Bounded instances
 621 %*                                                                      *
 622 %************************************************************************
 623
 624 \begin{code}
 625 gen_Bounded_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 626 gen_Bounded_binds loc tycon
 627   | isEnumerationTyCon tycon
 628   = (listToBag [ min_bound_enum, max_bound_enum ], [])
 629   | otherwise
 630   = ASSERT(isSingleton data_cons)
 631     (listToBag [ min_bound_1con, max_bound_1con ], [])
 632   where
 633     data_cons = tyConDataCons tycon
 634
 635     ----- enum-flavored: ---------------------------
 636     min_bound_enum = mkHsVarBind loc minBound_RDR (nlHsVar data_con_1_RDR)
 637     max_bound_enum = mkHsVarBind loc maxBound_RDR (nlHsVar data_con_N_RDR)
 638
 639     data_con_1    = head data_cons
 640     data_con_N    = last data_cons
 641     data_con_1_RDR = getRdrName data_con_1
 642     data_con_N_RDR = getRdrName data_con_N
 643
 644     ----- single-constructor-flavored: -------------
 645     arity          = dataConSourceArity data_con_1
 646
 647     min_bound_1con = mkHsVarBind loc minBound_RDR $
 648                      nlHsVarApps data_con_1_RDR (nOfThem arity minBound_RDR)
 649     max_bound_1con = mkHsVarBind loc maxBound_RDR $
 650                      nlHsVarApps data_con_1_RDR (nOfThem arity maxBound_RDR)
 651 \end{code}
 652
 653 %************************************************************************
 654 %*                                                                      *
 655         Ix instances
 656 %*                                                                      *
 657 %************************************************************************
 658
 659 Deriving @Ix@ is only possible for enumeration types and
 660 single-constructor types.  We deal with them in turn.
 661
 662 For an enumeration type, e.g.,
 663 \begin{verbatim}
 664     data Foo ... = N1 | N2 | ... | Nn
 665 \end{verbatim}
 666 things go not too differently from @Enum@:
 667 \begin{verbatim}
 668 instance ... Ix (Foo ...) where
 669     range (a, b)
 670       = map tag2con_Foo [con2tag_Foo a .. con2tag_Foo b]
 671
 672     -- or, really...
 673     range (a, b)
 674       = case (con2tag_Foo a) of { a# ->
 675         case (con2tag_Foo b) of { b# ->
 676         map tag2con_Foo (enumFromTo (I# a#) (I# b#))
 677         }}
 678
 679     -- Generate code for unsafeIndex, becuase using index leads
 680     -- to lots of redundant range tests
 681     unsafeIndex c@(a, b) d
 682       = case (con2tag_Foo d -# con2tag_Foo a) of
 683                r# -> I# r#
 684
 685     inRange (a, b) c
 686       = let
 687             p_tag = con2tag_Foo c
 688         in
 689         p_tag >= con2tag_Foo a && p_tag <= con2tag_Foo b
 690
 691     -- or, really...
 692     inRange (a, b) c
 693       = case (con2tag_Foo a)   of { a_tag ->
 694         case (con2tag_Foo b)   of { b_tag ->
 695         case (con2tag_Foo c)   of { c_tag ->
 696         if (c_tag >=# a_tag) then
 697           c_tag <=# b_tag
 698         else
 699           False
 700         }}}
 701 \end{verbatim}
 702 (modulo suitable case-ification to handle the unlifted tags)
 703
 704 For a single-constructor type (NB: this includes all tuples), e.g.,
 705 \begin{verbatim}
 706     data Foo ... = MkFoo a b Int Double c c
 707 \end{verbatim}
 708 we follow the scheme given in Figure~19 of the Haskell~1.2 report
 709 (p.~147).
 710
 711 \begin{code}
 712 gen_Ix_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 713
 714 gen_Ix_binds loc tycon
 715   | isEnumerationTyCon tycon
 716   = (enum_ixes, [GenCon2Tag tycon, GenTag2Con tycon, GenMaxTag tycon])
 717   | otherwise
 718   = (single_con_ixes, [GenCon2Tag tycon])
 719   where
 720     --------------------------------------------------------------
 721     enum_ixes = listToBag [ enum_range, enum_index, enum_inRange ]
 722
 723     enum_range
 724       = mk_easy_FunBind loc range_RDR [nlTuplePat [a_Pat, b_Pat] Boxed] $
 725           untag_Expr tycon [(a_RDR, ah_RDR)] $
 726           untag_Expr tycon [(b_RDR, bh_RDR)] $
 727           nlHsApp (nlHsVarApps map_RDR [tag2con_RDR tycon]) $
 728               nlHsPar (enum_from_to_Expr
 729                         (nlHsVarApps intDataCon_RDR [ah_RDR])
 730                         (nlHsVarApps intDataCon_RDR [bh_RDR]))
 731
 732     enum_index
 733       = mk_easy_FunBind loc unsafeIndex_RDR
 734                 [noLoc (AsPat (noLoc c_RDR)
 735                            (nlTuplePat [a_Pat, nlWildPat] Boxed)),
 736                                 d_Pat] (
 737            untag_Expr tycon [(a_RDR, ah_RDR)] (
 738            untag_Expr tycon [(d_RDR, dh_RDR)] (
 739            let
 740                 rhs = nlHsVarApps intDataCon_RDR [c_RDR]
 741            in
 742            nlHsCase
 743              (genOpApp (nlHsVar dh_RDR) minusInt_RDR (nlHsVar ah_RDR))
 744              [mkSimpleHsAlt (nlVarPat c_RDR) rhs]
 745            ))
 746         )
 747
 748     enum_inRange
 749       = mk_easy_FunBind loc inRange_RDR [nlTuplePat [a_Pat, b_Pat] Boxed, c_Pat] $
 750           untag_Expr tycon [(a_RDR, ah_RDR)] (
 751           untag_Expr tycon [(b_RDR, bh_RDR)] (
 752           untag_Expr tycon [(c_RDR, ch_RDR)] (
 753           nlHsIf (genOpApp (nlHsVar ch_RDR) geInt_RDR (nlHsVar ah_RDR)) (
 754              (genOpApp (nlHsVar ch_RDR) leInt_RDR (nlHsVar bh_RDR))
 755           ) {-else-} (
 756              false_Expr
 757           ))))
 758
 759     --------------------------------------------------------------
 760     single_con_ixes
 761       = listToBag [single_con_range, single_con_index, single_con_inRange]
 762
 763     data_con
 764       = case tyConSingleDataCon_maybe tycon of -- just checking...
 765           Nothing -> panic "get_Ix_binds"
 766           Just dc -> dc
 767
 768     con_arity    = dataConSourceArity data_con
 769     data_con_RDR = getRdrName data_con
 770
 771     as_needed = take con_arity as_RDRs
 772     bs_needed = take con_arity bs_RDRs
 773     cs_needed = take con_arity cs_RDRs
 774
 775     con_pat  xs  = nlConVarPat data_con_RDR xs
 776     con_expr     = nlHsVarApps data_con_RDR cs_needed
 777
 778     --------------------------------------------------------------
 779     single_con_range
 780       = mk_easy_FunBind loc range_RDR
 781           [nlTuplePat [con_pat as_needed, con_pat bs_needed] Boxed] $
 782         nlHsDo ListComp stmts con_expr
 783       where
 784         stmts = zipWith3Equal "single_con_range" mk_qual as_needed bs_needed cs_needed
 785
 786         mk_qual a b c = noLoc $ mkBindStmt (nlVarPat c)
 787                                  (nlHsApp (nlHsVar range_RDR)
 788                                           (mkLHsVarTuple [a,b]))
 789
 790     ----------------
 791     single_con_index
 792       = mk_easy_FunBind loc unsafeIndex_RDR
 793                 [nlTuplePat [con_pat as_needed, con_pat bs_needed] Boxed,
 794                  con_pat cs_needed]
 795         -- We need to reverse the order we consider the components in
 796         -- so that
 797         --     range (l,u) !! index (l,u) i == i   -- when i is in range
 798         -- (from http://haskell.org/onlinereport/ix.html) holds.
 799                 (mk_index (reverse $ zip3 as_needed bs_needed cs_needed))
 800       where
 801         -- index (l1,u1) i1 + rangeSize (l1,u1) * (index (l2,u2) i2 + ...)
 802         mk_index []        = nlHsIntLit 0
 803         mk_index [(l,u,i)] = mk_one l u i
 804         mk_index ((l,u,i) : rest)
 805           = genOpApp (
 806                 mk_one l u i
 807             ) plus_RDR (
 808                 genOpApp (
 809                     (nlHsApp (nlHsVar unsafeRangeSize_RDR)
 810                              (mkLHsVarTuple [l,u]))
 811                 ) times_RDR (mk_index rest)
 812            )
 813         mk_one l u i
 814           = nlHsApps unsafeIndex_RDR [mkLHsVarTuple [l,u], nlHsVar i]
 815
 816     ------------------
 817     single_con_inRange
 818       = mk_easy_FunBind loc inRange_RDR
 819                 [nlTuplePat [con_pat as_needed, con_pat bs_needed] Boxed,
 820                  con_pat cs_needed] $
 821           foldl1 and_Expr (zipWith3Equal "single_con_inRange" in_range as_needed bs_needed cs_needed)
 822       where
 823         in_range a b c = nlHsApps inRange_RDR [mkLHsVarTuple [a,b], nlHsVar c]
 824 \end{code}
 825
 826 %************************************************************************
 827 %*                                                                      *
 828         Read instances
 829 %*                                                                      *
 830 %************************************************************************
 831
 832 Example
 833
 834   infix 4 %%
 835   data T = Int %% Int
 836          | T1 { f1 :: Int }
 837          | T2 T
 838
 839
 840 instance Read T where
 841   readPrec =
 842     parens
 843     ( prec 4 (
 844         do x           <- ReadP.step Read.readPrec
 845            Symbol "%%" <- Lex.lex
 846            y           <- ReadP.step Read.readPrec
 847            return (x %% y))
 848       +++
 849       prec (appPrec+1) (
 850         -- Note the "+1" part; "T2 T1 {f1=3}" should parse ok
 851         -- Record construction binds even more tightly than application
 852         do Ident "T1" <- Lex.lex
 853            Punc '{' <- Lex.lex
 854            Ident "f1" <- Lex.lex
 855            Punc '=' <- Lex.lex
 856            x          <- ReadP.reset Read.readPrec
 857            Punc '}' <- Lex.lex
 858            return (T1 { f1 = x }))
 859       +++
 860       prec appPrec (
 861         do Ident "T2" <- Lex.lexP
 862            x          <- ReadP.step Read.readPrec
 863            return (T2 x))
 864     )
 865
 866   readListPrec = readListPrecDefault
 867   readList     = readListDefault
 868
 869
 870 \begin{code}
 871 gen_Read_binds :: FixityEnv -> SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
 872
 873 gen_Read_binds get_fixity loc tycon
 874   = (listToBag [read_prec, default_readlist, default_readlistprec], [])
 875   where
 876     -----------------------------------------------------------------------
 877     default_readlist
 878         = mkHsVarBind loc readList_RDR     (nlHsVar readListDefault_RDR)
 879
 880     default_readlistprec
 881         = mkHsVarBind loc readListPrec_RDR (nlHsVar readListPrecDefault_RDR)
 882     -----------------------------------------------------------------------
 883
 884     data_cons = tyConDataCons tycon
 885     (nullary_cons, non_nullary_cons) = partition isNullarySrcDataCon data_cons
 886
 887     read_prec = mkHsVarBind loc readPrec_RDR
 888                               (nlHsApp (nlHsVar parens_RDR) read_cons)
 889
 890     read_cons             = foldr1 mk_alt (read_nullary_cons ++ read_non_nullary_cons)
 891     read_non_nullary_cons = map read_non_nullary_con non_nullary_cons
 892
 893     read_nullary_cons
 894       = case nullary_cons of
 895             []    -> []
 896             [con] -> [nlHsDo DoExpr (match_con con) (result_expr con [])]
 897             _     -> [nlHsApp (nlHsVar choose_RDR)
 898                               (nlList (map mk_pair nullary_cons))]
 899         -- NB For operators the parens around (:=:) are matched by the
 900         -- enclosing "parens" call, so here we must match the naked
 901         -- data_con_str con
 902
 903     match_con con | isSym con_str = [symbol_pat con_str]
 904                   | otherwise     = ident_h_pat  con_str
 905                   where
 906                     con_str = data_con_str con
 907         -- For nullary constructors we must match Ident s for normal constrs
 908         -- and   Symbol s   for operators
 909
 910     mk_pair con = mkLHsTupleExpr [nlHsLit (mkHsString (data_con_str con)),
 911                                   result_expr con []]
 912
 913     read_non_nullary_con data_con
 914       | is_infix  = mk_parser infix_prec  infix_stmts  body
 915       | is_record = mk_parser record_prec record_stmts body
 916 --              Using these two lines instead allows the derived
 917 --              read for infix and record bindings to read the prefix form
 918 --      | is_infix  = mk_alt prefix_parser (mk_parser infix_prec  infix_stmts  body)
 919 --      | is_record = mk_alt prefix_parser (mk_parser record_prec record_stmts body)
 920       | otherwise = prefix_parser
 921       where
 922         body = result_expr data_con as_needed
 923         con_str = data_con_str data_con
 924
 925         prefix_parser = mk_parser prefix_prec prefix_stmts body
 926
 927         read_prefix_con
 928             | isSym con_str = [read_punc "(", symbol_pat con_str, read_punc ")"]
 929             | otherwise     = ident_h_pat con_str
 930
 931         read_infix_con
 932             | isSym con_str = [symbol_pat con_str]
 933             | otherwise     = [read_punc "`"] ++ ident_h_pat con_str ++ [read_punc "`"]
 934
 935         prefix_stmts            -- T a b c
 936           = read_prefix_con ++ read_args
 937
 938         infix_stmts             -- a %% b, or  a `T` b
 939           = [read_a1]
 940             ++ read_infix_con
 941             ++ [read_a2]
 942
 943         record_stmts            -- T { f1 = a, f2 = b }
 944           = read_prefix_con
 945             ++ [read_punc "{"]
 946             ++ concat (intersperse [read_punc ","] field_stmts)
 947             ++ [read_punc "}"]
 948
 949         field_stmts  = zipWithEqual "lbl_stmts" read_field labels as_needed
 950
 951         con_arity    = dataConSourceArity data_con
 952         labels       = dataConFieldLabels data_con
 953         dc_nm        = getName data_con
 954         is_infix     = dataConIsInfix data_con
 955         is_record    = length labels > 0
 956         as_needed    = take con_arity as_RDRs
 957         read_args    = zipWithEqual "gen_Read_binds" read_arg as_needed (dataConOrigArgTys data_con)
 958         (read_a1:read_a2:_) = read_args
 959
 960         prefix_prec = appPrecedence
 961         infix_prec  = getPrecedence get_fixity dc_nm
 962         record_prec = appPrecedence + 1 -- Record construction binds even more tightly
 963                                         -- than application; e.g. T2 T1 {x=2} means T2 (T1 {x=2})
 964
 965     ------------------------------------------------------------------------
 966     --          Helpers
 967     ------------------------------------------------------------------------
 968     mk_alt e1 e2       = genOpApp e1 alt_RDR e2                                 -- e1 +++ e2
 969     mk_parser p ss b   = nlHsApps prec_RDR [nlHsIntLit p, nlHsDo DoExpr ss b]   -- prec p (do { ss ; b })
 970     bindLex pat        = noLoc (mkBindStmt pat (nlHsVar lexP_RDR))              -- pat <- lexP
 971     con_app con as     = nlHsVarApps (getRdrName con) as                        -- con as
 972     result_expr con as = nlHsApp (nlHsVar returnM_RDR) (con_app con as)         -- return (con as)
 973
 974     punc_pat s   = nlConPat punc_RDR   [nlLitPat (mkHsString s)]  -- Punc 'c'
 975
 976     -- For constructors and field labels ending in '#', we hackily
 977     -- let the lexer generate two tokens, and look for both in sequence
 978     -- Thus [Ident "I"; Symbol "#"].  See Trac #5041
 979     ident_h_pat s | Just (ss, '#') <- snocView s = [ ident_pat ss, symbol_pat "#" ]
 980                   | otherwise                    = [ ident_pat s ]
 981
 982     ident_pat  s = bindLex $ nlConPat ident_RDR  [nlLitPat (mkHsString s)]  -- Ident "foo" <- lexP
 983     symbol_pat s = bindLex $ nlConPat symbol_RDR [nlLitPat (mkHsString s)]  -- Symbol ">>" <- lexP
 984
 985     data_con_str con = occNameString (getOccName con)
 986
 987     read_punc c = bindLex (punc_pat c)
 988     read_arg a ty = ASSERT( not (isUnLiftedType ty) )
 989                     noLoc (mkBindStmt (nlVarPat a) (nlHsVarApps step_RDR [readPrec_RDR]))
 990
 991     read_field lbl a = read_lbl lbl ++
 992                        [read_punc "=",
 993                         noLoc (mkBindStmt (nlVarPat a) (nlHsVarApps reset_RDR [readPrec_RDR]))]
 994
 995         -- When reading field labels we might encounter
 996         --      a  = 3
 997         --      _a = 3
 998         -- or   (#) = 4
 999         -- Note the parens!
1000     read_lbl lbl | isSym lbl_str
1001                  = [read_punc "(", symbol_pat lbl_str, read_punc ")"]
1002                  | otherwise
1003                  = ident_h_pat lbl_str
1004                  where
1005                    lbl_str = occNameString (getOccName lbl)
1006 \end{code}
1007
1008
1009 %************************************************************************
1010 %*                                                                      *
1011         Show instances
1012 %*                                                                      *
1013 %************************************************************************
1014
1015 Example
1016
1017     infixr 5 :^:
1018
1019     data Tree a =  Leaf a  |  Tree a :^: Tree a
1020
1021     instance (Show a) => Show (Tree a) where
1022
1023         showsPrec d (Leaf m) = showParen (d > app_prec) showStr
1024           where
1025              showStr = showString "Leaf " . showsPrec (app_prec+1) m
1026
1027         showsPrec d (u :^: v) = showParen (d > up_prec) showStr
1028           where
1029              showStr = showsPrec (up_prec+1) u .
1030                        showString " :^: "      .
1031                        showsPrec (up_prec+1) v
1032                 -- Note: right-associativity of :^: ignored
1033
1034     up_prec  = 5    -- Precedence of :^:
1035     app_prec = 10   -- Application has precedence one more than
1036                     -- the most tightly-binding operator
1037
1038 \begin{code}
1039 gen_Show_binds :: FixityEnv -> SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1040
1041 gen_Show_binds get_fixity loc tycon
1042   = (listToBag [shows_prec, show_list], [])
1043   where
1044     -----------------------------------------------------------------------
1045     show_list = mkHsVarBind loc showList_RDR
1046                   (nlHsApp (nlHsVar showList___RDR) (nlHsPar (nlHsApp (nlHsVar showsPrec_RDR) (nlHsIntLit 0))))
1047     -----------------------------------------------------------------------
1048     data_cons = tyConDataCons tycon
1049     shows_prec = mk_FunBind loc showsPrec_RDR (map pats_etc data_cons)
1050
1051     pats_etc data_con
1052       | nullary_con =  -- skip the showParen junk...
1053          ASSERT(null bs_needed)
1054          ([nlWildPat, con_pat], mk_showString_app op_con_str)
1055       | otherwise   =
1056          ([a_Pat, con_pat],
1057           showParen_Expr (nlHsPar (genOpApp a_Expr ge_RDR (nlHsLit (HsInt con_prec_plus_one))))
1058                          (nlHsPar (nested_compose_Expr show_thingies)))
1059         where
1060              data_con_RDR  = getRdrName data_con
1061              con_arity     = dataConSourceArity data_con
1062              bs_needed     = take con_arity bs_RDRs
1063              arg_tys       = dataConOrigArgTys data_con         -- Correspond 1-1 with bs_needed
1064              con_pat       = nlConVarPat data_con_RDR bs_needed
1065              nullary_con   = con_arity == 0
1066              labels        = dataConFieldLabels data_con
1067              lab_fields    = length labels
1068              record_syntax = lab_fields > 0
1069
1070              dc_nm          = getName data_con
1071              dc_occ_nm      = getOccName data_con
1072              con_str        = occNameString dc_occ_nm
1073              op_con_str     = wrapOpParens con_str
1074              backquote_str  = wrapOpBackquotes con_str
1075
1076              show_thingies
1077                 | is_infix      = [show_arg1, mk_showString_app (" " ++ backquote_str ++ " "), show_arg2]
1078                 | record_syntax = mk_showString_app (op_con_str ++ " {") :
1079                                   show_record_args ++ [mk_showString_app "}"]
1080                 | otherwise     = mk_showString_app (op_con_str ++ " ") : show_prefix_args
1081
1082              show_label l = mk_showString_app (nm ++ " = ")
1083                         -- Note the spaces around the "=" sign.  If we don't have them
1084                         -- then we get Foo { x=-1 } and the "=-" parses as a single
1085                         -- lexeme.  Only the space after the '=' is necessary, but
1086                         -- it seems tidier to have them both sides.
1087                  where
1088                    occ_nm   = getOccName l
1089                    nm       = wrapOpParens (occNameString occ_nm)
1090
1091              show_args               = zipWith show_arg bs_needed arg_tys
1092              (show_arg1:show_arg2:_) = show_args
1093              show_prefix_args        = intersperse (nlHsVar showSpace_RDR) show_args
1094
1095                 --  Assumption for record syntax: no of fields == no of labelled fields
1096                 --            (and in same order)
1097              show_record_args = concat $
1098                                 intersperse [mk_showString_app ", "] $
1099                                 [ [show_label lbl, arg]
1100                                 | (lbl,arg) <- zipEqual "gen_Show_binds"
1101                                                         labels show_args ]
1102
1103                 -- Generates (showsPrec p x) for argument x, but it also boxes
1104                 -- the argument first if necessary.  Note that this prints unboxed
1105                 -- things without any '#' decorations; could change that if need be
1106              show_arg b arg_ty = nlHsApps showsPrec_RDR [nlHsLit (HsInt arg_prec),
1107                                                          box_if_necy "Show" tycon (nlHsVar b) arg_ty]
1108
1109                 -- Fixity stuff
1110              is_infix = dataConIsInfix data_con
1111              con_prec_plus_one = 1 + getPrec is_infix get_fixity dc_nm
1112              arg_prec | record_syntax = 0       -- Record fields don't need parens
1113                       | otherwise     = con_prec_plus_one
1114
1115 wrapOpParens :: String -> String
1116 wrapOpParens s | isSym s   = '(' : s ++ ")"
1117                | otherwise = s
1118
1119 wrapOpBackquotes :: String -> String
1120 wrapOpBackquotes s | isSym s   = s
1121                    | otherwise = '`' : s ++ "`"
1122
1123 isSym :: String -> Bool
1124 isSym ""      = False
1125 isSym (c : _) = startsVarSym c || startsConSym c
1126
1127 mk_showString_app :: String -> LHsExpr RdrName
1128 mk_showString_app str = nlHsApp (nlHsVar showString_RDR) (nlHsLit (mkHsString str))
1129 \end{code}
1130
1131 \begin{code}
1132 getPrec :: Bool -> FixityEnv -> Name -> Integer
1133 getPrec is_infix get_fixity nm
1134   | not is_infix   = appPrecedence
1135   | otherwise      = getPrecedence get_fixity nm
1136
1137 appPrecedence :: Integer
1138 appPrecedence = fromIntegral maxPrecedence + 1
1139   -- One more than the precedence of the most
1140   -- tightly-binding operator
1141
1142 getPrecedence :: FixityEnv -> Name -> Integer
1143 getPrecedence get_fixity nm
1144    = case lookupFixity get_fixity nm of
1145         Fixity x _assoc -> fromIntegral x
1146           -- NB: the Report says that associativity is not taken
1147           --     into account for either Read or Show; hence we
1148           --     ignore associativity here
1149 \end{code}
1150
1151
1152 %************************************************************************
1153 %*                                                                      *
1154 \subsection{Typeable}
1155 %*                                                                      *
1156 %************************************************************************
1157
1158 From the data type
1159
1160         data T a b = ....
1161
1162 we generate
1163
1164         instance Typeable2 T where
1165                 typeOf2 _ = mkTyConApp (mkTyConRep "T") []
1166
1167 We are passed the Typeable2 class as well as T
1168
1169 \begin{code}
1170 gen_Typeable_binds :: SrcSpan -> TyCon -> LHsBinds RdrName
1171 gen_Typeable_binds loc tycon
1172   = unitBag $
1173         mk_easy_FunBind loc
1174                 (mk_typeOf_RDR tycon)   -- Name of appropriate type0f function
1175                 [nlWildPat]
1176                 (nlHsApps mkTypeRep_RDR [tycon_rep, nlList []])
1177   where
1178     tycon_rep = nlHsVar mkTyConRep_RDR `nlHsApp` nlHsLit (mkHsString (showSDocOneLine (ppr tycon)))
1179
1180 mk_typeOf_RDR :: TyCon -> RdrName
1181 -- Use the arity of the TyCon to make the right typeOfn function
1182 mk_typeOf_RDR tycon = varQual_RDR tYPEABLE (mkFastString ("typeOf" ++ suffix))
1183                 where
1184                   arity = tyConArity tycon
1185                   suffix | arity == 0 = ""
1186                          | otherwise  = show arity
1187 \end{code}
1188
1189
1190
1191 %************************************************************************
1192 %*                                                                      *
1193         Data instances
1194 %*                                                                      *
1195 %************************************************************************
1196
1197 From the data type
1198
1199   data T a b = T1 a b | T2
1200
1201 we generate
1202
1203   $cT1 = mkDataCon $dT "T1" Prefix
1204   $cT2 = mkDataCon $dT "T2" Prefix
1205   $dT  = mkDataType "Module.T" [] [$con_T1, $con_T2]
1206   -- the [] is for field labels.
1207
1208   instance (Data a, Data b) => Data (T a b) where
1209     gfoldl k z (T1 a b) = z T `k` a `k` b
1210     gfoldl k z T2           = z T2
1211     -- ToDo: add gmapT,Q,M, gfoldr
1212
1213     gunfold k z c = case conIndex c of
1214                         I# 1# -> k (k (z T1))
1215                         I# 2# -> z T2
1216
1217     toConstr (T1 _ _) = $cT1
1218     toConstr T2       = $cT2
1219
1220     dataTypeOf _ = $dT
1221
1222     dataCast1 = gcast1   -- If T :: * -> *
1223     dataCast2 = gcast2   -- if T :: * -> * -> *
1224
1225
1226 \begin{code}
1227 gen_Data_binds :: SrcSpan
1228                -> TyCon
1229                -> (LHsBinds RdrName,    -- The method bindings
1230                    DerivAuxBinds)       -- Auxiliary bindings
1231 gen_Data_binds loc tycon
1232   = (listToBag [gfoldl_bind, gunfold_bind, toCon_bind, dataTypeOf_bind]
1233      `unionBags` gcast_binds,
1234                 -- Auxiliary definitions: the data type and constructors
1235      MkTyCon tycon : map MkDataCon data_cons)
1236   where
1237     data_cons  = tyConDataCons tycon
1238     n_cons     = length data_cons
1239     one_constr = n_cons == 1
1240
1241         ------------ gfoldl
1242     gfoldl_bind = mk_FunBind loc gfoldl_RDR (map gfoldl_eqn data_cons)
1243
1244     gfoldl_eqn con
1245       = ([nlVarPat k_RDR, nlVarPat z_RDR, nlConVarPat con_name as_needed],
1246                        foldl mk_k_app (nlHsVar z_RDR `nlHsApp` nlHsVar con_name) as_needed)
1247                    where
1248                      con_name ::  RdrName
1249                      con_name = getRdrName con
1250                      as_needed = take (dataConSourceArity con) as_RDRs
1251                      mk_k_app e v = nlHsPar (nlHsOpApp e k_RDR (nlHsVar v))
1252
1253         ------------ gunfold
1254     gunfold_bind = mk_FunBind loc
1255                               gunfold_RDR
1256                               [([k_Pat, z_Pat, if one_constr then nlWildPat else c_Pat],
1257                                 gunfold_rhs)]
1258
1259     gunfold_rhs
1260         | one_constr = mk_unfold_rhs (head data_cons)   -- No need for case
1261         | otherwise  = nlHsCase (nlHsVar conIndex_RDR `nlHsApp` c_Expr)
1262                                 (map gunfold_alt data_cons)
1263
1264     gunfold_alt dc = mkSimpleHsAlt (mk_unfold_pat dc) (mk_unfold_rhs dc)
1265     mk_unfold_rhs dc = foldr nlHsApp
1266                            (nlHsVar z_RDR `nlHsApp` nlHsVar (getRdrName dc))
1267                            (replicate (dataConSourceArity dc) (nlHsVar k_RDR))
1268
1269     mk_unfold_pat dc    -- Last one is a wild-pat, to avoid
1270                         -- redundant test, and annoying warning
1271       | tag-fIRST_TAG == n_cons-1 = nlWildPat   -- Last constructor
1272       | otherwise = nlConPat intDataCon_RDR [nlLitPat (HsIntPrim (toInteger tag))]
1273       where
1274         tag = dataConTag dc
1275
1276         ------------ toConstr
1277     toCon_bind = mk_FunBind loc toConstr_RDR (map to_con_eqn data_cons)
1278     to_con_eqn dc = ([nlWildConPat dc], nlHsVar (mk_constr_name dc))
1279
1280         ------------ dataTypeOf
1281     dataTypeOf_bind = mk_easy_FunBind
1282                         loc
1283                         dataTypeOf_RDR
1284                         [nlWildPat]
1285                         (nlHsVar (mk_data_type_name tycon))
1286
1287         ------------ gcast1/2
1288     tycon_kind = tyConKind tycon
1289     gcast_binds | tycon_kind `eqKind` kind1 = mk_gcast dataCast1_RDR gcast1_RDR
1290                 | tycon_kind `eqKind` kind2 = mk_gcast dataCast2_RDR gcast2_RDR
1291                 | otherwise           = emptyBag
1292     mk_gcast dataCast_RDR gcast_RDR
1293       = unitBag (mk_easy_FunBind loc dataCast_RDR [nlVarPat f_RDR]
1294                                  (nlHsVar gcast_RDR `nlHsApp` nlHsVar f_RDR))
1295
1296
1297 kind1, kind2 :: Kind
1298 kind1 = liftedTypeKind `mkArrowKind` liftedTypeKind
1299 kind2 = liftedTypeKind `mkArrowKind` kind1
1300
1301 gfoldl_RDR, gunfold_RDR, toConstr_RDR, dataTypeOf_RDR, mkConstr_RDR,
1302     mkDataType_RDR, conIndex_RDR, prefix_RDR, infix_RDR,
1303     dataCast1_RDR, dataCast2_RDR, gcast1_RDR, gcast2_RDR,
1304     constr_RDR, dataType_RDR :: RdrName
1305 gfoldl_RDR     = varQual_RDR  gENERICS (fsLit "gfoldl")
1306 gunfold_RDR    = varQual_RDR  gENERICS (fsLit "gunfold")
1307 toConstr_RDR   = varQual_RDR  gENERICS (fsLit "toConstr")
1308 dataTypeOf_RDR = varQual_RDR  gENERICS (fsLit "dataTypeOf")
1309 dataCast1_RDR  = varQual_RDR  gENERICS (fsLit "dataCast1")
1310 dataCast2_RDR  = varQual_RDR  gENERICS (fsLit "dataCast2")
1311 gcast1_RDR     = varQual_RDR  tYPEABLE (fsLit "gcast1")
1312 gcast2_RDR     = varQual_RDR  tYPEABLE (fsLit "gcast2")
1313 mkConstr_RDR   = varQual_RDR  gENERICS (fsLit "mkConstr")
1314 constr_RDR     = tcQual_RDR   gENERICS (fsLit "Constr")
1315 mkDataType_RDR = varQual_RDR  gENERICS (fsLit "mkDataType")
1316 dataType_RDR   = tcQual_RDR   gENERICS (fsLit "DataType")
1317 conIndex_RDR   = varQual_RDR  gENERICS (fsLit "constrIndex")
1318 prefix_RDR     = dataQual_RDR gENERICS (fsLit "Prefix")
1319 infix_RDR      = dataQual_RDR gENERICS (fsLit "Infix")
1320 \end{code}
1321
1322
1323
1324 %************************************************************************
1325 %*                                                                      *
1326                         Functor instances
1327
1328  see http://www.mail-archive.com/haskell-prime@haskell.org/msg02116.html
1329
1330 %*                                                                      *
1331 %************************************************************************
1332
1333 For the data type:
1334
1335   data T a = T1 Int a | T2 (T a)
1336
1337 We generate the instance:
1338
1339   instance Functor T where
1340       fmap f (T1 b1 a) = T1 b1 (f a)
1341       fmap f (T2 ta)   = T2 (fmap f ta)
1342
1343 Notice that we don't simply apply 'fmap' to the constructor arguments.
1344 Rather
1345   - Do nothing to an argument whose type doesn't mention 'a'
1346   - Apply 'f' to an argument of type 'a'
1347   - Apply 'fmap f' to other arguments
1348 That's why we have to recurse deeply into the constructor argument types,
1349 rather than just one level, as we typically do.
1350
1351 What about types with more than one type parameter?  In general, we only
1352 derive Functor for the last position:
1353
1354   data S a b = S1 [b] | S2 (a, T a b)
1355   instance Functor (S a) where
1356     fmap f (S1 bs)    = S1 (fmap f bs)
1357     fmap f (S2 (p,q)) = S2 (a, fmap f q)
1358
1359 However, we have special cases for
1360          - tuples
1361          - functions
1362
1363 More formally, we write the derivation of fmap code over type variable
1364 'a for type 'b as ($fmap 'a 'b).  In this general notation the derived
1365 instance for T is:
1366
1367   instance Functor T where
1368       fmap f (T1 x1 x2) = T1 ($(fmap 'a 'b1) x1) ($(fmap 'a 'a) x2)
1369       fmap f (T2 x1)    = T2 ($(fmap 'a '(T a)) x1)
1370
1371   $(fmap 'a 'b)         x  =  x     -- when b does not contain a
1372   $(fmap 'a 'a)         x  =  f x
1373   $(fmap 'a '(b1,b2))   x  =  case x of (x1,x2) -> ($(fmap 'a 'b1) x1, $(fmap 'a 'b2) x2)
1374   $(fmap 'a '(T b1 b2)) x  =  fmap $(fmap 'a 'b2) x   -- when a only occurs in the last parameter, b2
1375   $(fmap 'a '(b -> c))  x  =  \b -> $(fmap 'a' 'c) (x ($(cofmap 'a 'b) b))
1376
1377 For functions, the type parameter 'a can occur in a contravariant position,
1378 which means we need to derive a function like:
1379
1380   cofmap :: (a -> b) -> (f b -> f a)
1381
1382 This is pretty much the same as $fmap, only without the $(cofmap 'a 'a) case:
1383
1384   $(cofmap 'a 'b)         x  =  x     -- when b does not contain a
1385   $(cofmap 'a 'a)         x  =  error "type variable in contravariant position"
1386   $(cofmap 'a '(b1,b2))   x  =  case x of (x1,x2) -> ($(cofmap 'a 'b1) x1, $(cofmap 'a 'b2) x2)
1387   $(cofmap 'a '[b])       x  =  map $(cofmap 'a 'b) x
1388   $(cofmap 'a '(T b1 b2)) x  =  fmap $(cofmap 'a 'b2) x   -- when a only occurs in the last parameter, b2
1389   $(cofmap 'a '(b -> c))  x  =  \b -> $(cofmap 'a' 'c) (x ($(fmap 'a 'c) b))
1390
1391 \begin{code}
1392 gen_Functor_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1393 gen_Functor_binds loc tycon
1394   = (unitBag fmap_bind, [])
1395   where
1396     data_cons = tyConDataCons tycon
1397     fmap_bind = L loc $ mkRdrFunBind (L loc fmap_RDR) eqns
1398
1399     fmap_eqn con = evalState (match_for_con [f_Pat] con parts) bs_RDRs
1400       where
1401         parts = foldDataConArgs ft_fmap con
1402
1403     eqns | null data_cons = [mkSimpleMatch [nlWildPat, nlWildPat]
1404                                            (error_Expr "Void fmap")]
1405          | otherwise      = map fmap_eqn data_cons
1406
1407     ft_fmap :: FFoldType (LHsExpr RdrName -> State [RdrName] (LHsExpr RdrName))
1408     -- Tricky higher order type; I can't say I fully understand this code :-(
1409     ft_fmap = FT { ft_triv = \x -> return x                    -- fmap f x = x
1410                  , ft_var  = \x -> return (nlHsApp f_Expr x)   -- fmap f x = f x
1411                  , ft_fun = \g h x -> mkSimpleLam (\b -> h =<< (nlHsApp x `fmap` g b))
1412                                                                -- fmap f x = \b -> h (x (g b))
1413                  , ft_tup = mkSimpleTupleCase match_for_con    -- fmap f x = case x of (a1,a2,..) -> (g1 a1,g2 a2,..)
1414                  , ft_ty_app = \_ g  x -> do gg <- mkSimpleLam g      -- fmap f x = fmap g x
1415                                              return $ nlHsApps fmap_RDR [gg,x]
1416                  , ft_forall = \_ g  x -> g x
1417                  , ft_bad_app = panic "in other argument"
1418                  , ft_co_var = panic "contravariant" }
1419
1420     match_for_con = mkSimpleConMatch $
1421         \con_name xsM -> do xs <- sequence xsM
1422                             return (nlHsApps con_name xs)  -- Con (g1 v1) (g2 v2) ..
1423 \end{code}
1424
1425 Utility functions related to Functor deriving.
1426
1427 Since several things use the same pattern of traversal, this is abstracted into functorLikeTraverse.
1428 This function works like a fold: it makes a value of type 'a' in a bottom up way.
1429
1430 \begin{code}
1431 -- Generic traversal for Functor deriving
1432 data FFoldType a      -- Describes how to fold over a Type in a functor like way
1433    = FT { ft_triv    :: a                   -- Does not contain variable
1434         , ft_var     :: a                   -- The variable itself
1435         , ft_co_var  :: a                   -- The variable itself, contravariantly
1436         , ft_fun     :: a -> a -> a         -- Function type
1437         , ft_tup     :: Boxity -> [a] -> a  -- Tuple type
1438         , ft_ty_app  :: Type -> a -> a      -- Type app, variable only in last argument
1439         , ft_bad_app :: a                   -- Type app, variable other than in last argument
1440         , ft_forall  :: TcTyVar -> a -> a   -- Forall type
1441      }
1442
1443 functorLikeTraverse :: TyVar         -- ^ Variable to look for
1444                     -> FFoldType a   -- ^ How to fold
1445                     -> Type          -- ^ Type to process
1446                     -> a
1447 functorLikeTraverse var (FT { ft_triv = caseTrivial,     ft_var = caseVar
1448                             , ft_co_var = caseCoVar,     ft_fun = caseFun
1449                             , ft_tup = caseTuple,        ft_ty_app = caseTyApp
1450                             , ft_bad_app = caseWrongArg, ft_forall = caseForAll })
1451                     ty
1452   = fst (go False ty)
1453   where -- go returns (result of type a, does type contain var)
1454         go co ty | Just ty' <- coreView ty = go co ty'
1455         go co (TyVarTy    v) | v == var = (if co then caseCoVar else caseVar,True)
1456         go co (FunTy (PredTy _) b)      = go co b
1457         go co (FunTy x y)    | xc || yc = (caseFun xr yr,True)
1458             where (xr,xc) = go (not co) x
1459                   (yr,yc) = go co       y
1460         go co (AppTy    x y) | xc = (caseWrongArg,   True)
1461                              | yc = (caseTyApp x yr, True)
1462             where (_, xc) = go co x
1463                   (yr,yc) = go co y
1464         go co ty@(TyConApp con args)
1465                | not (or xcs)     = (caseTrivial, False)   -- Variable does not occur
1466                -- At this point we know that xrs, xcs is not empty,
1467                -- and at least one xr is True
1468                | isTupleTyCon con = (caseTuple (tupleTyConBoxity con) xrs, True)
1469                | or (init xcs)    = (caseWrongArg, True)   -- T (..var..)    ty
1470                | otherwise        =                        -- T (..no var..) ty
1471                                     (caseTyApp (fst (splitAppTy ty)) (last xrs), True)
1472             where (xrs,xcs) = unzip (map (go co) args)
1473         go co (ForAllTy v x) | v /= var && xc = (caseForAll v xr,True)
1474             where (xr,xc) = go co x
1475         go _ _ = (caseTrivial,False)
1476
1477 -- Return all syntactic subterms of ty that contain var somewhere
1478 -- These are the things that should appear in instance constraints
1479 deepSubtypesContaining :: TyVar -> Type -> [TcType]
1480 deepSubtypesContaining tv
1481   = functorLikeTraverse tv
1482         (FT { ft_triv = []
1483             , ft_var = []
1484             , ft_fun = (++), ft_tup = \_ xs -> concat xs
1485             , ft_ty_app = (:)
1486             , ft_bad_app = panic "in other argument"
1487             , ft_co_var = panic "contravariant"
1488             , ft_forall = \v xs -> filterOut ((v `elemVarSet`) . tyVarsOfType) xs })
1489
1490
1491 foldDataConArgs :: FFoldType a -> DataCon -> [a]
1492 -- Fold over the arguments of the datacon
1493 foldDataConArgs ft con
1494   = map (functorLikeTraverse tv ft) (dataConOrigArgTys con)
1495   where
1496     tv = last (dataConUnivTyVars con)
1497                     -- Argument to derive for, 'a in the above description
1498                     -- The validity checks have ensured that con is
1499                     -- a vanilla data constructor
1500
1501 -- Make a HsLam using a fresh variable from a State monad
1502 mkSimpleLam :: (LHsExpr id -> State [id] (LHsExpr id)) -> State [id] (LHsExpr id)
1503 -- (mkSimpleLam fn) returns (\x. fn(x))
1504 mkSimpleLam lam = do
1505     (n:names) <- get
1506     put names
1507     body <- lam (nlHsVar n)
1508     return (mkHsLam [nlVarPat n] body)
1509
1510 mkSimpleLam2 :: (LHsExpr id -> LHsExpr id -> State [id] (LHsExpr id)) -> State [id] (LHsExpr id)
1511 mkSimpleLam2 lam = do
1512     (n1:n2:names) <- get
1513     put names
1514     body <- lam (nlHsVar n1) (nlHsVar n2)
1515     return (mkHsLam [nlVarPat n1,nlVarPat n2] body)
1516
1517 -- "Con a1 a2 a3 -> fold [x1 a1, x2 a2, x3 a3]"
1518 mkSimpleConMatch :: Monad m => (RdrName -> [a] -> m (LHsExpr RdrName)) -> [LPat RdrName] -> DataCon -> [LHsExpr RdrName -> a] -> m (LMatch RdrName)
1519 mkSimpleConMatch fold extra_pats con insides = do
1520     let con_name = getRdrName con
1521     let vars_needed = takeList insides as_RDRs
1522     let pat = nlConVarPat con_name vars_needed
1523     rhs <- fold con_name (zipWith ($) insides (map nlHsVar vars_needed))
1524     return $ mkMatch (extra_pats ++ [pat]) rhs emptyLocalBinds
1525
1526 -- "case x of (a1,a2,a3) -> fold [x1 a1, x2 a2, x3 a3]"
1527 mkSimpleTupleCase :: Monad m => ([LPat RdrName] -> DataCon -> [LHsExpr RdrName -> a] -> m (LMatch RdrName))
1528                   -> Boxity -> [LHsExpr RdrName -> a] -> LHsExpr RdrName -> m (LHsExpr RdrName)
1529 mkSimpleTupleCase match_for_con boxity insides x = do
1530     let con = tupleCon boxity (length insides)
1531     match <- match_for_con [] con insides
1532     return $ nlHsCase x [match]
1533 \end{code}
1534
1535
1536 %************************************************************************
1537 %*                                                                      *
1538                         Foldable instances
1539
1540  see http://www.mail-archive.com/haskell-prime@haskell.org/msg02116.html
1541
1542 %*                                                                      *
1543 %************************************************************************
1544
1545 Deriving Foldable instances works the same way as Functor instances,
1546 only Foldable instances are not possible for function types at all.
1547 Here the derived instance for the type T above is:
1548
1549   instance Foldable T where
1550       foldr f z (T1 x1 x2 x3) = $(foldr 'a 'b1) x1 ( $(foldr 'a 'a) x2 ( $(foldr 'a 'b2) x3 z ) )
1551
1552 The cases are:
1553
1554   $(foldr 'a 'b)         x z  =  z     -- when b does not contain a
1555   $(foldr 'a 'a)         x z  =  f x z
1556   $(foldr 'a '(b1,b2))   x z  =  case x of (x1,x2) -> $(foldr 'a 'b1) x1 ( $(foldr 'a 'b2) x2 z )
1557   $(foldr 'a '(T b1 b2)) x z  =  foldr $(foldr 'a 'b2) x z  -- when a only occurs in the last parameter, b2
1558
1559 Note that the arguments to the real foldr function are the wrong way around,
1560 since (f :: a -> b -> b), while (foldr f :: b -> t a -> b).
1561
1562 \begin{code}
1563 gen_Foldable_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1564 gen_Foldable_binds loc tycon
1565   = (unitBag foldr_bind, [])
1566   where
1567     data_cons = tyConDataCons tycon
1568
1569     foldr_bind = L loc $ mkRdrFunBind (L loc foldable_foldr_RDR) eqns
1570     eqns = map foldr_eqn data_cons
1571     foldr_eqn con = evalState (match_for_con z_Expr [f_Pat,z_Pat] con parts) bs_RDRs
1572       where
1573         parts = foldDataConArgs ft_foldr con
1574
1575     ft_foldr :: FFoldType (LHsExpr RdrName -> LHsExpr RdrName -> State [RdrName] (LHsExpr RdrName))
1576     ft_foldr = FT { ft_triv = \_ z -> return z                        -- foldr f z x = z
1577                   , ft_var  = \x z -> return (nlHsApps f_RDR [x,z])   -- foldr f z x = f x z
1578                   , ft_tup = \b gs x z -> mkSimpleTupleCase (match_for_con z) b gs x
1579                   , ft_ty_app = \_ g  x z -> do gg <- mkSimpleLam2 g   -- foldr f z x = foldr (\xx zz -> g xx zz) z x
1580                                                 return $ nlHsApps foldable_foldr_RDR [gg,z,x]
1581                   , ft_forall = \_ g  x z -> g x z
1582                   , ft_co_var = panic "covariant"
1583                   , ft_fun = panic "function"
1584                   , ft_bad_app = panic "in other argument" }
1585
1586     match_for_con z = mkSimpleConMatch (\_con_name -> foldrM ($) z) -- g1 v1 (g2 v2 (.. z))
1587 \end{code}
1588
1589
1590 %************************************************************************
1591 %*                                                                      *
1592                         Traversable instances
1593
1594  see http://www.mail-archive.com/haskell-prime@haskell.org/msg02116.html
1595 %*                                                                      *
1596 %************************************************************************
1597
1598 Again, Traversable is much like Functor and Foldable.
1599
1600 The cases are:
1601
1602   $(traverse 'a 'b)         x  =  pure x     -- when b does not contain a
1603   $(traverse 'a 'a)         x  =  f x
1604   $(traverse 'a '(b1,b2))   x  =  case x of (x1,x2) -> (,) <$> $(traverse 'a 'b1) x1 <*> $(traverse 'a 'b2) x2
1605   $(traverse 'a '(T b1 b2)) x  =  traverse $(traverse 'a 'b2) x  -- when a only occurs in the last parameter, b2
1606
1607 Note that the generated code is not as efficient as it could be. For instance:
1608
1609   data T a = T Int a  deriving Traversable
1610
1611 gives the function: traverse f (T x y) = T <$> pure x <*> f y
1612 instead of:         traverse f (T x y) = T x <$> f y
1613
1614 \begin{code}
1615 gen_Traversable_binds :: SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1616 gen_Traversable_binds loc tycon
1617   = (unitBag traverse_bind, [])
1618   where
1619     data_cons = tyConDataCons tycon
1620
1621     traverse_bind = L loc $ mkRdrFunBind (L loc traverse_RDR) eqns
1622     eqns = map traverse_eqn data_cons
1623     traverse_eqn con = evalState (match_for_con [f_Pat] con parts) bs_RDRs
1624       where
1625         parts = foldDataConArgs ft_trav con
1626
1627
1628     ft_trav :: FFoldType (LHsExpr RdrName -> State [RdrName] (LHsExpr RdrName))
1629     ft_trav = FT { ft_triv = \x -> return (nlHsApps pure_RDR [x])   -- traverse f x = pure x
1630                  , ft_var = \x -> return (nlHsApps f_RDR [x])       -- travese f x = f x
1631                  , ft_tup = mkSimpleTupleCase match_for_con         -- travese f x z = case x of (a1,a2,..) ->
1632                                                                     --                   (,,) <$> g1 a1 <*> g2 a2 <*> ..
1633                  , ft_ty_app = \_ g  x -> do gg <- mkSimpleLam g    -- travese f x = travese (\xx -> g xx) x
1634                                              return $ nlHsApps traverse_RDR [gg,x]
1635                  , ft_forall = \_ g  x -> g x
1636                  , ft_co_var = panic "covariant"
1637                  , ft_fun = panic "function"
1638                  , ft_bad_app = panic "in other argument" }
1639
1640     match_for_con = mkSimpleConMatch $
1641         \con_name xsM -> do xs <- sequence xsM
1642                             return (mkApCon (nlHsVar con_name) xs)
1643
1644     -- ((Con <$> x1) <*> x2) <*> ..
1645     mkApCon con []     = nlHsApps pure_RDR [con]
1646     mkApCon con (x:xs) = foldl appAp (nlHsApps fmap_RDR [con,x]) xs
1647        where appAp x y = nlHsApps ap_RDR [x,y]
1648 \end{code}
1649
1650
1651
1652 %************************************************************************
1653 %*                                                                      *
1654 \subsection{Generating extra binds (@con2tag@ and @tag2con@)}
1655 %*                                                                      *
1656 %************************************************************************
1657
1658 \begin{verbatim}
1659 data Foo ... = ...
1660
1661 con2tag_Foo :: Foo ... -> Int#
1662 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
1663 maxtag_Foo  :: Int              -- ditto (NB: not unlifted)
1664 \end{verbatim}
1665
1666 The `tags' here start at zero, hence the @fIRST_TAG@ (currently one)
1667 fiddling around.
1668
1669 \begin{code}
1670 genAuxBind :: SrcSpan -> DerivAuxBind -> (LHsBind RdrName, LSig RdrName)
1671 genAuxBind loc (GenCon2Tag tycon)
1672   = (mk_FunBind loc rdr_name eqns,
1673      L loc (TypeSig (L loc rdr_name) (L loc sig_ty)))
1674   where
1675     rdr_name = con2tag_RDR tycon
1676
1677     sig_ty = HsCoreTy $
1678              mkSigmaTy (tyConTyVars tycon) (tyConStupidTheta tycon) $
1679              mkParentType tycon `mkFunTy` intPrimTy
1680
1681     lots_of_constructors = tyConFamilySize tycon > 8
1682                         -- was: mAX_FAMILY_SIZE_FOR_VEC_RETURNS
1683                         -- but we don't do vectored returns any more.
1684
1685     eqns | lots_of_constructors = [get_tag_eqn]
1686          | otherwise = map mk_eqn (tyConDataCons tycon)
1687
1688     get_tag_eqn = ([nlVarPat a_RDR], nlHsApp (nlHsVar getTag_RDR) a_Expr)
1689
1690     mk_eqn :: DataCon -> ([LPat RdrName], LHsExpr RdrName)
1691     mk_eqn con = ([nlWildConPat con],
1692                   nlHsLit (HsIntPrim (toInteger ((dataConTag con) - fIRST_TAG))))
1693
1694 genAuxBind loc (GenTag2Con tycon)
1695   = (mk_FunBind loc rdr_name
1696         [([nlConVarPat intDataCon_RDR [a_RDR]],
1697            nlHsApp (nlHsVar tagToEnum_RDR) a_Expr)],
1698      L loc (TypeSig (L loc rdr_name) (L loc sig_ty)))
1699   where
1700     sig_ty = HsCoreTy $ mkForAllTys (tyConTyVars tycon) $
1701              intTy `mkFunTy` mkParentType tycon
1702
1703     rdr_name = tag2con_RDR tycon
1704
1705 genAuxBind loc (GenMaxTag tycon)
1706   = (mkHsVarBind loc rdr_name rhs,
1707      L loc (TypeSig (L loc rdr_name) (L loc sig_ty)))
1708   where
1709     rdr_name = maxtag_RDR tycon
1710     sig_ty = HsCoreTy intTy
1711     rhs = nlHsApp (nlHsVar intDataCon_RDR) (nlHsLit (HsIntPrim max_tag))
1712     max_tag =  case (tyConDataCons tycon) of
1713                  data_cons -> toInteger ((length data_cons) - fIRST_TAG)
1714
1715 genAuxBind loc (MkTyCon tycon)  --  $dT
1716   = (mkHsVarBind loc rdr_name rhs,
1717      L loc (TypeSig (L loc rdr_name) sig_ty))
1718   where
1719     rdr_name = mk_data_type_name tycon
1720     sig_ty   = nlHsTyVar dataType_RDR
1721     constrs  = [nlHsVar (mk_constr_name con) | con <- tyConDataCons tycon]
1722     rhs = nlHsVar mkDataType_RDR
1723           `nlHsApp` nlHsLit (mkHsString (showSDocOneLine (ppr tycon)))
1724           `nlHsApp` nlList constrs
1725
1726 genAuxBind loc (MkDataCon dc)   --  $cT1 etc
1727   = (mkHsVarBind loc rdr_name rhs,
1728      L loc (TypeSig (L loc rdr_name) sig_ty))
1729   where
1730     rdr_name = mk_constr_name dc
1731     sig_ty   = nlHsTyVar constr_RDR
1732     rhs      = nlHsApps mkConstr_RDR constr_args
1733
1734     constr_args
1735        = [ -- nlHsIntLit (toInteger (dataConTag dc)),     -- Tag
1736            nlHsVar (mk_data_type_name (dataConTyCon dc)), -- DataType
1737            nlHsLit (mkHsString (occNameString dc_occ)),   -- String name
1738            nlList  labels,                                -- Field labels
1739            nlHsVar fixity]                                -- Fixity
1740
1741     labels   = map (nlHsLit . mkHsString . getOccString)
1742                    (dataConFieldLabels dc)
1743     dc_occ   = getOccName dc
1744     is_infix = isDataSymOcc dc_occ
1745     fixity | is_infix  = infix_RDR
1746            | otherwise = prefix_RDR
1747
1748 mk_data_type_name :: TyCon -> RdrName   -- "$tT"
1749 mk_data_type_name tycon = mkAuxBinderName (tyConName tycon) mkDataTOcc
1750
1751 mk_constr_name :: DataCon -> RdrName    -- "$cC"
1752 mk_constr_name con = mkAuxBinderName (dataConName con) mkDataCOcc
1753
1754 mkParentType :: TyCon -> Type
1755 -- Turn the representation tycon of a family into
1756 -- a use of its family constructor
1757 mkParentType tc
1758   = case tyConFamInst_maybe tc of
1759        Nothing  -> mkTyConApp tc (mkTyVarTys (tyConTyVars tc))
1760        Just (fam_tc,tys) -> mkTyConApp fam_tc tys
1761 \end{code}
1762
1763 %************************************************************************
1764 %*                                                                      *
1765 \subsection{Utility bits for generating bindings}
1766 %*                                                                      *
1767 %************************************************************************
1768
1769
1770 \begin{code}
1771 mk_FunBind :: SrcSpan -> RdrName
1772            -> [([LPat RdrName], LHsExpr RdrName)]
1773            -> LHsBind RdrName
1774 mk_FunBind loc fun pats_and_exprs
1775   = L loc $ mkRdrFunBind (L loc fun) matches
1776   where
1777     matches = [mkMatch p e emptyLocalBinds | (p,e) <-pats_and_exprs]
1778
1779 mkRdrFunBind :: Located RdrName -> [LMatch RdrName] -> HsBind RdrName
1780 mkRdrFunBind fun@(L _ fun_rdr) matches
1781  | null matches = mkFunBind fun [mkMatch [] (error_Expr str) emptyLocalBinds]
1782         -- Catch-all eqn looks like
1783         --     fmap = error "Void fmap"
1784         -- It's needed if there no data cons at all,
1785         -- which can happen with -XEmptyDataDecls
1786         -- See Trac #4302
1787  | otherwise    = mkFunBind fun matches
1788  where
1789    str = "Void " ++ occNameString (rdrNameOcc fun_rdr)
1790 \end{code}
1791
1792 \begin{code}
1793 box_if_necy :: String           -- The class involved
1794             -> TyCon            -- The tycon involved
1795             -> LHsExpr RdrName  -- The argument
1796             -> Type             -- The argument type
1797             -> LHsExpr RdrName  -- Boxed version of the arg
1798 box_if_necy cls_str tycon arg arg_ty
1799   | isUnLiftedType arg_ty = nlHsApp (nlHsVar box_con) arg
1800   | otherwise             = arg
1801   where
1802     box_con = assoc_ty_id cls_str tycon box_con_tbl arg_ty
1803
1804 ---------------------
1805 primOrdOps :: String    -- The class involved
1806            -> TyCon     -- The tycon involved
1807            -> Type      -- The type
1808            -> (PrimOp, PrimOp, PrimOp, PrimOp, PrimOp)  -- (lt,le,eq,ge,gt)
1809 primOrdOps str tycon ty = assoc_ty_id str tycon ord_op_tbl ty
1810
1811 ord_op_tbl :: [(Type, (PrimOp, PrimOp, PrimOp, PrimOp, PrimOp))]
1812 ord_op_tbl
1813  =  [(charPrimTy,       (CharLtOp,   CharLeOp,   CharEqOp,   CharGeOp,   CharGtOp))
1814     ,(intPrimTy,        (IntLtOp,    IntLeOp,    IntEqOp,    IntGeOp,    IntGtOp))
1815     ,(wordPrimTy,       (WordLtOp,   WordLeOp,   WordEqOp,   WordGeOp,   WordGtOp))
1816     ,(addrPrimTy,       (AddrLtOp,   AddrLeOp,   AddrEqOp,   AddrGeOp,   AddrGtOp))
1817     ,(floatPrimTy,      (FloatLtOp,  FloatLeOp,  FloatEqOp,  FloatGeOp,  FloatGtOp))
1818     ,(doublePrimTy,     (DoubleLtOp, DoubleLeOp, DoubleEqOp, DoubleGeOp, DoubleGtOp)) ]
1819
1820 box_con_tbl :: [(Type, RdrName)]
1821 box_con_tbl =
1822     [(charPrimTy,       getRdrName charDataCon)
1823     ,(intPrimTy,        getRdrName intDataCon)
1824     ,(wordPrimTy,       wordDataCon_RDR)
1825     ,(floatPrimTy,      getRdrName floatDataCon)
1826     ,(doublePrimTy,     getRdrName doubleDataCon)
1827     ]
1828
1829 assoc_ty_id :: String           -- The class involved
1830             -> TyCon            -- The tycon involved
1831             -> [(Type,a)]       -- The table
1832             -> Type             -- The type
1833             -> a                -- The result of the lookup
1834 assoc_ty_id cls_str _ tbl ty
1835   | null res = pprPanic "Error in deriving:" (text "Can't derive" <+> text cls_str <+>
1836                                               text "for primitive type" <+> ppr ty)
1837   | otherwise = head res
1838   where
1839     res = [id | (ty',id) <- tbl, ty `tcEqType` ty']
1840
1841 -----------------------------------------------------------------------
1842
1843 and_Expr :: LHsExpr RdrName -> LHsExpr RdrName -> LHsExpr RdrName
1844 and_Expr a b = genOpApp a and_RDR    b
1845
1846 -----------------------------------------------------------------------
1847
1848 eq_Expr :: TyCon -> Type -> LHsExpr RdrName -> LHsExpr RdrName -> LHsExpr RdrName
1849 eq_Expr tycon ty a b = genOpApp a eq_op b
1850  where
1851    eq_op | not (isUnLiftedType ty) = eq_RDR
1852          | otherwise               = primOpRdrName prim_eq
1853    (_, _, prim_eq, _, _) = primOrdOps "Eq" tycon ty
1854 \end{code}
1855
1856 \begin{code}
1857 untag_Expr :: TyCon -> [( RdrName,  RdrName)] -> LHsExpr RdrName -> LHsExpr RdrName
1858 untag_Expr _ [] expr = expr
1859 untag_Expr tycon ((untag_this, put_tag_here) : more) expr
1860   = nlHsCase (nlHsPar (nlHsVarApps (con2tag_RDR tycon) [untag_this])) {-of-}
1861       [mkSimpleHsAlt (nlVarPat put_tag_here) (untag_Expr tycon more expr)]
1862
1863 enum_from_to_Expr
1864         :: LHsExpr RdrName -> LHsExpr RdrName
1865         -> LHsExpr RdrName
1866 enum_from_then_to_Expr
1867         :: LHsExpr RdrName -> LHsExpr RdrName -> LHsExpr RdrName
1868         -> LHsExpr RdrName
1869
1870 enum_from_to_Expr      f   t2 = nlHsApp (nlHsApp (nlHsVar enumFromTo_RDR) f) t2
1871 enum_from_then_to_Expr f t t2 = nlHsApp (nlHsApp (nlHsApp (nlHsVar enumFromThenTo_RDR) f) t) t2
1872
1873 showParen_Expr
1874         :: LHsExpr RdrName -> LHsExpr RdrName
1875         -> LHsExpr RdrName
1876
1877 showParen_Expr e1 e2 = nlHsApp (nlHsApp (nlHsVar showParen_RDR) e1) e2
1878
1879 nested_compose_Expr :: [LHsExpr RdrName] -> LHsExpr RdrName
1880
1881 nested_compose_Expr []  = panic "nested_compose_expr"   -- Arg is always non-empty
1882 nested_compose_Expr [e] = parenify e
1883 nested_compose_Expr (e:es)
1884   = nlHsApp (nlHsApp (nlHsVar compose_RDR) (parenify e)) (nested_compose_Expr es)
1885
1886 -- impossible_Expr is used in case RHSs that should never happen.
1887 -- We generate these to keep the desugarer from complaining that they *might* happen!
1888 error_Expr :: String -> LHsExpr RdrName
1889 error_Expr string = nlHsApp (nlHsVar error_RDR) (nlHsLit (mkHsString string))
1890
1891 -- illegal_Expr is used when signalling error conditions in the RHS of a derived
1892 -- method. It is currently only used by Enum.{succ,pred}
1893 illegal_Expr :: String -> String -> String -> LHsExpr RdrName
1894 illegal_Expr meth tp msg =
1895    nlHsApp (nlHsVar error_RDR) (nlHsLit (mkHsString (meth ++ '{':tp ++ "}: " ++ msg)))
1896
1897 -- illegal_toEnum_tag is an extended version of illegal_Expr, which also allows you
1898 -- to include the value of a_RDR in the error string.
1899 illegal_toEnum_tag :: String -> RdrName -> LHsExpr RdrName
1900 illegal_toEnum_tag tp maxtag =
1901    nlHsApp (nlHsVar error_RDR)
1902            (nlHsApp (nlHsApp (nlHsVar append_RDR)
1903                        (nlHsLit (mkHsString ("toEnum{" ++ tp ++ "}: tag ("))))
1904                     (nlHsApp (nlHsApp (nlHsApp
1905                            (nlHsVar showsPrec_RDR)
1906                            (nlHsIntLit 0))
1907                            (nlHsVar a_RDR))
1908                            (nlHsApp (nlHsApp
1909                                (nlHsVar append_RDR)
1910                                (nlHsLit (mkHsString ") is outside of enumeration's range (0,")))
1911                                (nlHsApp (nlHsApp (nlHsApp
1912                                         (nlHsVar showsPrec_RDR)
1913                                         (nlHsIntLit 0))
1914                                         (nlHsVar maxtag))
1915                                         (nlHsLit (mkHsString ")"))))))
1916
1917 parenify :: LHsExpr RdrName -> LHsExpr RdrName
1918 parenify e@(L _ (HsVar _)) = e
1919 parenify e                 = mkHsPar e
1920
1921 -- genOpApp wraps brackets round the operator application, so that the
1922 -- renamer won't subsequently try to re-associate it.
1923 genOpApp :: LHsExpr RdrName -> RdrName -> LHsExpr RdrName -> LHsExpr RdrName
1924 genOpApp e1 op e2 = nlHsPar (nlHsOpApp e1 op e2)
1925 \end{code}
1926
1927 \begin{code}
1928 a_RDR, b_RDR, c_RDR, d_RDR, f_RDR, k_RDR, z_RDR, ah_RDR, bh_RDR, ch_RDR, dh_RDR
1929     :: RdrName
1930 a_RDR           = mkVarUnqual (fsLit "a")
1931 b_RDR           = mkVarUnqual (fsLit "b")
1932 c_RDR           = mkVarUnqual (fsLit "c")
1933 d_RDR           = mkVarUnqual (fsLit "d")
1934 f_RDR           = mkVarUnqual (fsLit "f")
1935 k_RDR           = mkVarUnqual (fsLit "k")
1936 z_RDR           = mkVarUnqual (fsLit "z")
1937 ah_RDR          = mkVarUnqual (fsLit "a#")
1938 bh_RDR          = mkVarUnqual (fsLit "b#")
1939 ch_RDR          = mkVarUnqual (fsLit "c#")
1940 dh_RDR          = mkVarUnqual (fsLit "d#")
1941
1942 as_RDRs, bs_RDRs, cs_RDRs :: [RdrName]
1943 as_RDRs         = [ mkVarUnqual (mkFastString ("a"++show i)) | i <- [(1::Int) .. ] ]
1944 bs_RDRs         = [ mkVarUnqual (mkFastString ("b"++show i)) | i <- [(1::Int) .. ] ]
1945 cs_RDRs         = [ mkVarUnqual (mkFastString ("c"++show i)) | i <- [(1::Int) .. ] ]
1946
1947 a_Expr, c_Expr, f_Expr, z_Expr, ltTag_Expr, eqTag_Expr, gtTag_Expr,
1948     false_Expr, true_Expr :: LHsExpr RdrName
1949 a_Expr          = nlHsVar a_RDR
1950 -- b_Expr       = nlHsVar b_RDR
1951 c_Expr          = nlHsVar c_RDR
1952 f_Expr          = nlHsVar f_RDR
1953 z_Expr          = nlHsVar z_RDR
1954 ltTag_Expr      = nlHsVar ltTag_RDR
1955 eqTag_Expr      = nlHsVar eqTag_RDR
1956 gtTag_Expr      = nlHsVar gtTag_RDR
1957 false_Expr      = nlHsVar false_RDR
1958 true_Expr       = nlHsVar true_RDR
1959
1960 a_Pat, b_Pat, c_Pat, d_Pat, f_Pat, k_Pat, z_Pat :: LPat RdrName
1961 a_Pat           = nlVarPat a_RDR
1962 b_Pat           = nlVarPat b_RDR
1963 c_Pat           = nlVarPat c_RDR
1964 d_Pat           = nlVarPat d_RDR
1965 f_Pat           = nlVarPat f_RDR
1966 k_Pat           = nlVarPat k_RDR
1967 z_Pat           = nlVarPat z_RDR
1968
1969 con2tag_RDR, tag2con_RDR, maxtag_RDR :: TyCon -> RdrName
1970 -- Generates Orig s RdrName, for the binding positions
1971 con2tag_RDR tycon = mk_tc_deriv_name tycon mkCon2TagOcc
1972 tag2con_RDR tycon = mk_tc_deriv_name tycon mkTag2ConOcc
1973 maxtag_RDR  tycon = mk_tc_deriv_name tycon mkMaxTagOcc
1974
1975 mk_tc_deriv_name :: TyCon -> (OccName -> OccName) -> RdrName
1976 mk_tc_deriv_name tycon occ_fun = mkAuxBinderName (tyConName tycon) occ_fun
1977
1978 mkAuxBinderName :: Name -> (OccName -> OccName) -> RdrName
1979 mkAuxBinderName parent occ_fun = mkRdrUnqual (occ_fun (nameOccName parent))
1980 -- Was: mkDerivedRdrName name occ_fun, which made an original name
1981 -- But:  (a) that does not work well for standalone-deriving
1982 --       (b) an unqualified name is just fine, provided it can't clash with user code
1983 \end{code}
1984
1985 s RdrName for PrimOps.  Can't be done in PrelNames, because PrimOp imports
1986 PrelNames, so PrelNames can't import PrimOp.
1987
1988 \begin{code}
1989 primOpRdrName :: PrimOp -> RdrName
1990 primOpRdrName op = getRdrName (primOpId op)
1991
1992 minusInt_RDR, eqInt_RDR, ltInt_RDR, geInt_RDR, gtInt_RDR, leInt_RDR,
1993     tagToEnum_RDR :: RdrName
1994 minusInt_RDR  = primOpRdrName IntSubOp
1995 eqInt_RDR     = primOpRdrName IntEqOp
1996 ltInt_RDR     = primOpRdrName IntLtOp
1997 geInt_RDR     = primOpRdrName IntGeOp
1998 gtInt_RDR     = primOpRdrName IntGtOp
1999 leInt_RDR     = primOpRdrName IntLeOp
2000 tagToEnum_RDR = primOpRdrName TagToEnumOp
2001
2002 error_RDR :: RdrName
2003 error_RDR = getRdrName eRROR_ID
2004 \end{code}