compiler/typecheck/TcHsSyn.lhs

   1 1%
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcHsSyn: Specialisations of the @HsSyn@ syntax for the typechecker
   7
   8 This module is an extension of @HsSyn@ syntax, for use in the type
   9 checker.
  10
  11 \begin{code}
  12 module TcHsSyn (
  13         mkHsConApp, mkHsDictLet, mkHsApp,
  14         hsLitType, hsLPatType, hsPatType,
  15         mkHsAppTy, mkSimpleHsAlt,
  16         nlHsIntLit,
  17         shortCutLit, hsOverLitName,
  18
  19         -- re-exported from TcMonad
  20         TcId, TcIdSet,
  21
  22         zonkTopDecls, zonkTopExpr, zonkTopLExpr,
  23         zonkId, zonkTopBndrs
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsSyn    -- oodles of it
  30
  31 -- others:
  32 import Id
  33
  34 import TcRnMonad
  35 import PrelNames
  36 import TcType
  37 import TcMType
  38 import TysPrim
  39 import TysWiredIn
  40 import DataCon
  41 import Name
  42 import NameSet
  43 import Var
  44 import VarSet
  45 import VarEnv
  46 import Literal
  47 import BasicTypes
  48 import Maybes
  49 import SrcLoc
  50 import DynFlags( DynFlag(..) )
  51 import Bag
  52 import FastString
  53 import Outputable
  54 \end{code}
  55
  56 \begin{code}
  57 -- XXX
  58 thenM :: Monad a => a b -> (b -> a c) -> a c
  59 thenM = (>>=)
  60
  61 returnM :: Monad m => a -> m a
  62 returnM = return
  63
  64 mappM :: (Monad m) => (a -> m b) -> [a] -> m [b]
  65 mappM = mapM
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 Note: If @hsLPatType@ doesn't bear a strong resemblance to @exprType@,
  76 then something is wrong.
  77 \begin{code}
  78 hsLPatType :: OutPat Id -> Type
  79 hsLPatType (L _ pat) = hsPatType pat
  80
  81 hsPatType :: Pat Id -> Type
  82 hsPatType (ParPat pat)                = hsLPatType pat
  83 hsPatType (WildPat ty)                = ty
  84 hsPatType (VarPat var)                = idType var
  85 hsPatType (BangPat pat)               = hsLPatType pat
  86 hsPatType (LazyPat pat)               = hsLPatType pat
  87 hsPatType (LitPat lit)                = hsLitType lit
  88 hsPatType (AsPat var _)               = idType (unLoc var)
  89 hsPatType (ViewPat _ _ ty)            = ty
  90 hsPatType (ListPat _ ty)              = mkListTy ty
  91 hsPatType (PArrPat _ ty)              = mkPArrTy ty
  92 hsPatType (TuplePat _ _ ty)           = ty
  93 hsPatType (ConPatOut { pat_ty = ty }) = ty
  94 hsPatType (SigPatOut _ ty)            = ty
  95 hsPatType (NPat lit _ _)              = overLitType lit
  96 hsPatType (NPlusKPat id _ _ _)        = idType (unLoc id)
  97 hsPatType (CoPat _ _ ty)              = ty
  98 hsPatType p                           = pprPanic "hsPatType" (ppr p)
  99
 100 hsLitType :: HsLit -> TcType
 101 hsLitType (HsChar _)       = charTy
 102 hsLitType (HsCharPrim _)   = charPrimTy
 103 hsLitType (HsString _)     = stringTy
 104 hsLitType (HsStringPrim _) = addrPrimTy
 105 hsLitType (HsInt _)        = intTy
 106 hsLitType (HsIntPrim _)    = intPrimTy
 107 hsLitType (HsWordPrim _)   = wordPrimTy
 108 hsLitType (HsInteger _ ty) = ty
 109 hsLitType (HsRat _ ty)     = ty
 110 hsLitType (HsFloatPrim _)  = floatPrimTy
 111 hsLitType (HsDoublePrim _) = doublePrimTy
 112 \end{code}
 113
 114 Overloaded literals. Here mainly becuase it uses isIntTy etc
 115
 116 \begin{code}
 117 shortCutLit :: OverLitVal -> TcType -> Maybe (HsExpr TcId)
 118 shortCutLit (HsIntegral i) ty
 119   | isIntTy ty && inIntRange i   = Just (HsLit (HsInt i))
 120   | isWordTy ty && inWordRange i = Just (mkLit wordDataCon (HsWordPrim i))
 121   | isIntegerTy ty               = Just (HsLit (HsInteger i ty))
 122   | otherwise                    = shortCutLit (HsFractional (fromInteger i)) ty
 123         -- The 'otherwise' case is important
 124         -- Consider (3 :: Float).  Syntactically it looks like an IntLit,
 125         -- so we'll call shortCutIntLit, but of course it's a float
 126         -- This can make a big difference for programs with a lot of
 127         -- literals, compiled without -O
 128
 129 shortCutLit (HsFractional f) ty
 130   | isFloatTy ty  = Just (mkLit floatDataCon  (HsFloatPrim f))
 131   | isDoubleTy ty = Just (mkLit doubleDataCon (HsDoublePrim f))
 132   | otherwise     = Nothing
 133
 134 shortCutLit (HsIsString s) ty
 135   | isStringTy ty = Just (HsLit (HsString s))
 136   | otherwise     = Nothing
 137
 138 mkLit :: DataCon -> HsLit -> HsExpr Id
 139 mkLit con lit = HsApp (nlHsVar (dataConWrapId con)) (nlHsLit lit)
 140
 141 ------------------------------
 142 hsOverLitName :: OverLitVal -> Name
 143 -- Get the canonical 'fromX' name for a particular OverLitVal
 144 hsOverLitName (HsIntegral {})   = fromIntegerName
 145 hsOverLitName (HsFractional {}) = fromRationalName
 146 hsOverLitName (HsIsString {})   = fromStringName
 147 \end{code}
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsection[BackSubst-HsBinds]{Running a substitution over @HsBinds@}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- zonkId is used *during* typechecking just to zonk the Id's type
 157 zonkId :: TcId -> TcM TcId
 158 zonkId id
 159   = zonkTcType (idType id) `thenM` \ ty' ->
 160     returnM (Id.setIdType id ty')
 161 \end{code}
 162
 163 The rest of the zonking is done *after* typechecking.
 164 The main zonking pass runs over the bindings
 165
 166  a) to convert TcTyVars to TyVars etc, dereferencing any bindings etc
 167  b) convert unbound TcTyVar to Void
 168  c) convert each TcId to an Id by zonking its type
 169
 170 The type variables are converted by binding mutable tyvars to immutable ones
 171 and then zonking as normal.
 172
 173 The Ids are converted by binding them in the normal Tc envt; that
 174 way we maintain sharing; eg an Id is zonked at its binding site and they
 175 all occurrences of that Id point to the common zonked copy
 176
 177 It's all pretty boring stuff, because HsSyn is such a large type, and
 178 the environment manipulation is tiresome.
 179
 180 \begin{code}
 181 data ZonkEnv = ZonkEnv  (TcType -> TcM Type)    -- How to zonk a type
 182                         (VarEnv Var)            -- What variables are in scope
 183         -- Maps an Id or EvVar to its zonked version; both have the same Name
 184         -- Note that all evidence (coercion variables as well as dictionaries)
 185         --      are kept in the ZonkEnv
 186         -- Only *type* abstraction is done by side effect
 187         -- Is only consulted lazily; hence knot-tying
 188
 189 emptyZonkEnv :: ZonkEnv
 190 emptyZonkEnv = ZonkEnv zonkTypeZapping emptyVarEnv
 191
 192 extendZonkEnv :: ZonkEnv -> [Var] -> ZonkEnv
 193 extendZonkEnv (ZonkEnv zonk_ty env) ids
 194   = ZonkEnv zonk_ty (extendVarEnvList env [(id,id) | id <- ids])
 195
 196 extendZonkEnv1 :: ZonkEnv -> Var -> ZonkEnv
 197 extendZonkEnv1 (ZonkEnv zonk_ty env) id
 198   = ZonkEnv zonk_ty (extendVarEnv env id id)
 199
 200 setZonkType :: ZonkEnv -> (TcType -> TcM Type) -> ZonkEnv
 201 setZonkType (ZonkEnv _ env) zonk_ty = ZonkEnv zonk_ty env
 202
 203 zonkEnvIds :: ZonkEnv -> [Id]
 204 zonkEnvIds (ZonkEnv _ env) = varEnvElts env
 205
 206 zonkIdOcc :: ZonkEnv -> TcId -> Id
 207 -- Ids defined in this module should be in the envt;
 208 -- ignore others.  (Actually, data constructors are also
 209 -- not LocalVars, even when locally defined, but that is fine.)
 210 -- (Also foreign-imported things aren't currently in the ZonkEnv;
 211 --  that's ok because they don't need zonking.)
 212 --
 213 -- Actually, Template Haskell works in 'chunks' of declarations, and
 214 -- an earlier chunk won't be in the 'env' that the zonking phase
 215 -- carries around.  Instead it'll be in the tcg_gbl_env, already fully
 216 -- zonked.  There's no point in looking it up there (except for error
 217 -- checking), and it's not conveniently to hand; hence the simple
 218 -- 'orElse' case in the LocalVar branch.
 219 --
 220 -- Even without template splices, in module Main, the checking of
 221 -- 'main' is done as a separate chunk.
 222 zonkIdOcc (ZonkEnv _zonk_ty env) id
 223   | isLocalVar id = lookupVarEnv env id `orElse` id
 224   | otherwise     = id
 225
 226 zonkIdOccs :: ZonkEnv -> [TcId] -> [Id]
 227 zonkIdOccs env ids = map (zonkIdOcc env) ids
 228
 229 -- zonkIdBndr is used *after* typechecking to get the Id's type
 230 -- to its final form.  The TyVarEnv give
 231 zonkIdBndr :: ZonkEnv -> TcId -> TcM Id
 232 zonkIdBndr env id
 233   = zonkTcTypeToType env (idType id)    `thenM` \ ty' ->
 234     returnM (Id.setIdType id ty')
 235
 236 zonkIdBndrs :: ZonkEnv -> [TcId] -> TcM [Id]
 237 zonkIdBndrs env ids = mappM (zonkIdBndr env) ids
 238
 239 zonkTopBndrs :: [TcId] -> TcM [Id]
 240 zonkTopBndrs ids = zonkIdBndrs emptyZonkEnv ids
 241
 242 zonkEvBndrsX :: ZonkEnv -> [EvVar] -> TcM (ZonkEnv, [Var])
 243 zonkEvBndrsX = mapAccumLM zonkEvBndrX
 244
 245 zonkEvBndrX :: ZonkEnv -> EvVar -> TcM (ZonkEnv, EvVar)
 246 -- Works for dictionaries and coercions
 247 zonkEvBndrX env var
 248   = do { var' <- zonkEvBndr env var
 249        ; return (extendZonkEnv1 env var', var') }
 250
 251 zonkEvBndr :: ZonkEnv -> EvVar -> TcM EvVar
 252 -- Works for dictionaries and coercions
 253 -- Does not extend the ZonkEnv
 254 zonkEvBndr env var
 255   = do { ty' <- zonkTcTypeToType env (varType var)
 256        ; return (setVarType var ty') }
 257
 258 zonkEvVarOcc :: ZonkEnv -> EvVar -> EvVar
 259 zonkEvVarOcc env v = zonkIdOcc env v
 260 \end{code}
 261
 262
 263 \begin{code}
 264 zonkTopExpr :: HsExpr TcId -> TcM (HsExpr Id)
 265 zonkTopExpr e = zonkExpr emptyZonkEnv e
 266
 267 zonkTopLExpr :: LHsExpr TcId -> TcM (LHsExpr Id)
 268 zonkTopLExpr e = zonkLExpr emptyZonkEnv e
 269
 270 zonkTopDecls :: Bag EvBind
 271              -> LHsBinds TcId -> NameSet
 272              -> [LRuleDecl TcId] -> [LVectDecl TcId] -> [LTcSpecPrag] -> [LForeignDecl TcId]
 273              -> TcM ([Id],
 274                      Bag EvBind,
 275                      Bag (LHsBind  Id),
 276                      [LForeignDecl Id],
 277                      [LTcSpecPrag],
 278                      [LRuleDecl    Id],
 279                      [LVectDecl    Id])
 280 zonkTopDecls ev_binds binds sig_ns rules vects imp_specs fords
 281   = do  { (env1, ev_binds') <- zonkEvBinds emptyZonkEnv ev_binds
 282
 283          -- Warn about missing signatures
 284          -- Do this only when we we have a type to offer
 285         ; warn_missing_sigs <- doptM Opt_WarnMissingSigs
 286         ; let sig_warn | warn_missing_sigs = topSigWarn sig_ns
 287                        | otherwise         = noSigWarn
 288
 289         ; (env2, binds') <- zonkRecMonoBinds env1 sig_warn binds
 290                         -- Top level is implicitly recursive
 291         ; rules' <- zonkRules env2 rules
 292         ; vects' <- zonkVects env2 vects
 293         ; specs' <- zonkLTcSpecPrags env2 imp_specs
 294         ; fords' <- zonkForeignExports env2 fords
 295         ; return (zonkEnvIds env2, ev_binds', binds', fords', specs', rules', vects') }
 296
 297 ---------------------------------------------
 298 zonkLocalBinds :: ZonkEnv -> HsLocalBinds TcId -> TcM (ZonkEnv, HsLocalBinds Id)
 299 zonkLocalBinds env EmptyLocalBinds
 300   = return (env, EmptyLocalBinds)
 301
 302 zonkLocalBinds _ (HsValBinds (ValBindsIn {}))
 303   = panic "zonkLocalBinds" -- Not in typechecker output
 304
 305 zonkLocalBinds env (HsValBinds vb@(ValBindsOut binds sigs))
 306   = do  { warn_missing_sigs <- doptM Opt_WarnMissingLocalSigs
 307         ; let sig_warn | not warn_missing_sigs = noSigWarn
 308                        | otherwise             = localSigWarn sig_ns
 309               sig_ns = getTypeSigNames vb
 310         ; (env1, new_binds) <- go env sig_warn binds
 311         ; return (env1, HsValBinds (ValBindsOut new_binds sigs)) }
 312   where
 313     go env _ []
 314       = return (env, [])
 315     go env sig_warn ((r,b):bs)
 316       = do { (env1, b')  <- zonkRecMonoBinds env sig_warn b
 317            ; (env2, bs') <- go env1 sig_warn bs
 318            ; return (env2, (r,b'):bs') }
 319
 320 zonkLocalBinds env (HsIPBinds (IPBinds binds dict_binds))
 321   = mappM (wrapLocM zonk_ip_bind) binds `thenM` \ new_binds ->
 322     let
 323         env1 = extendZonkEnv env [ipNameName n | L _ (IPBind n _) <- new_binds]
 324     in
 325     zonkTcEvBinds env1 dict_binds       `thenM` \ (env2, new_dict_binds) ->
 326     returnM (env2, HsIPBinds (IPBinds new_binds new_dict_binds))
 327   where
 328     zonk_ip_bind (IPBind n e)
 329         = mapIPNameTc (zonkIdBndr env) n        `thenM` \ n' ->
 330           zonkLExpr env e                       `thenM` \ e' ->
 331           returnM (IPBind n' e')
 332
 333 ---------------------------------------------
 334 zonkRecMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (ZonkEnv, LHsBinds Id)
 335 zonkRecMonoBinds env sig_warn binds
 336  = fixM (\ ~(_, new_binds) -> do
 337         { let env1 = extendZonkEnv env (collectHsBindsBinders new_binds)
 338         ; binds' <- zonkMonoBinds env1 sig_warn binds
 339         ; return (env1, binds') })
 340
 341 ---------------------------------------------
 342 type SigWarn = Bool -> [Id] -> TcM ()
 343      -- Missing-signature warning
 344      -- The Bool is True for an AbsBinds, False otherwise
 345
 346 noSigWarn :: SigWarn
 347 noSigWarn _ _ = return ()
 348
 349 topSigWarn :: NameSet -> SigWarn
 350 topSigWarn sig_ns _ ids = mapM_ (topSigWarnId sig_ns) ids
 351
 352 topSigWarnId :: NameSet -> Id -> TcM ()
 353 -- The NameSet is the Ids that *lack* a signature
 354 -- We have to do it this way round because there are
 355 -- lots of top-level bindings that are generated by GHC
 356 -- and that don't have signatures
 357 topSigWarnId sig_ns id
 358   | idName id `elemNameSet` sig_ns = warnMissingSig msg id
 359   | otherwise                      = return ()
 360   where
 361     msg = ptext (sLit "Top-level binding with no type signature:")
 362
 363 localSigWarn :: NameSet -> SigWarn
 364 localSigWarn sig_ns is_abs_bind ids
 365   | not is_abs_bind = return ()
 366   | otherwise       = mapM_ (localSigWarnId sig_ns) ids
 367
 368 localSigWarnId :: NameSet -> Id -> TcM ()
 369 -- NameSet are the Ids that *have* type signatures
 370 localSigWarnId sig_ns id
 371   | not (isSigmaTy (idType id))    = return ()
 372   | idName id `elemNameSet` sig_ns = return ()
 373   | otherwise                      = warnMissingSig msg id
 374   where
 375     msg = ptext (sLit "Polymophic local binding with no type signature:")
 376
 377 warnMissingSig :: SDoc -> Id -> TcM ()
 378 warnMissingSig msg id
 379   = do  { env0 <- tcInitTidyEnv
 380         ; let (env1, tidy_ty) = tidyOpenType env0 (idType id)
 381         ; addWarnTcM (env1, mk_msg tidy_ty) }
 382   where
 383     mk_msg ty = sep [ msg, nest 2 $ pprHsVar (idName id) <+> dcolon <+> ppr ty ]
 384
 385 ---------------------------------------------
 386 zonkMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (LHsBinds Id)
 387 zonkMonoBinds env sig_warn binds = mapBagM (wrapLocM (zonk_bind env sig_warn)) binds
 388
 389 zonk_bind :: ZonkEnv -> SigWarn -> HsBind TcId -> TcM (HsBind Id)
 390 zonk_bind env sig_warn bind@(PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty})
 391   = do  { (_env, new_pat) <- zonkPat env pat            -- Env already extended
 392         ; sig_warn False (collectPatBinders new_pat)
 393         ; new_grhss <- zonkGRHSs env grhss
 394         ; new_ty    <- zonkTcTypeToType env ty
 395         ; return (bind { pat_lhs = new_pat, pat_rhs = new_grhss, pat_rhs_ty = new_ty }) }
 396
 397 zonk_bind env sig_warn (VarBind { var_id = var, var_rhs = expr, var_inline = inl })
 398   = do { new_var  <- zonkIdBndr env var
 399        ; sig_warn False [new_var]
 400        ; new_expr <- zonkLExpr env expr
 401        ; return (VarBind { var_id = new_var, var_rhs = new_expr, var_inline = inl }) }
 402
 403 zonk_bind env sig_warn bind@(FunBind { fun_id = L loc var, fun_matches = ms
 404                                      , fun_co_fn = co_fn })
 405   = do { new_var <- zonkIdBndr env var
 406        ; sig_warn False [new_var]
 407        ; (env1, new_co_fn) <- zonkCoFn env co_fn
 408        ; new_ms <- zonkMatchGroup env1 ms
 409        ; return (bind { fun_id = L loc new_var, fun_matches = new_ms
 410                       , fun_co_fn = new_co_fn }) }
 411
 412 zonk_bind env sig_warn (AbsBinds { abs_tvs = tyvars, abs_ev_vars = evs
 413                                  , abs_ev_binds = ev_binds
 414                                  , abs_exports = exports
 415                                  , abs_binds = val_binds })
 416   = ASSERT( all isImmutableTyVar tyvars )
 417     do { (env1, new_evs) <- zonkEvBndrsX env evs
 418        ; (env2, new_ev_binds) <- zonkTcEvBinds env1 ev_binds
 419        ; (new_val_bind, new_exports) <- fixM $ \ ~(new_val_binds, _) ->
 420          do { let env3 = extendZonkEnv env2 (collectHsBindsBinders new_val_binds)
 421             ; new_val_binds <- zonkMonoBinds env3 noSigWarn val_binds
 422             ; new_exports   <- mapM (zonkExport env3) exports
 423             ; return (new_val_binds, new_exports) }
 424        ; sig_warn True [b | (_,b,_,_) <- new_exports]
 425        ; return (AbsBinds { abs_tvs = tyvars, abs_ev_vars = new_evs, abs_ev_binds = new_ev_binds
 426                           , abs_exports = new_exports, abs_binds = new_val_bind }) }
 427   where
 428     zonkExport env (tyvars, global, local, prags)
 429         -- The tyvars are already zonked
 430         = zonkIdBndr env global                 `thenM` \ new_global ->
 431           zonkSpecPrags env prags               `thenM` \ new_prags ->
 432           returnM (tyvars, new_global, zonkIdOcc env local, new_prags)
 433
 434 zonkSpecPrags :: ZonkEnv -> TcSpecPrags -> TcM TcSpecPrags
 435 zonkSpecPrags _   IsDefaultMethod = return IsDefaultMethod
 436 zonkSpecPrags env (SpecPrags ps)  = do { ps' <- zonkLTcSpecPrags env ps
 437                                        ; return (SpecPrags ps') }
 438
 439 zonkLTcSpecPrags :: ZonkEnv -> [LTcSpecPrag] -> TcM [LTcSpecPrag]
 440 zonkLTcSpecPrags env ps
 441   = mapM zonk_prag ps
 442   where
 443     zonk_prag (L loc (SpecPrag id co_fn inl))
 444         = do { (_, co_fn') <- zonkCoFn env co_fn
 445              ; return (L loc (SpecPrag (zonkIdOcc env id) co_fn' inl)) }
 446 \end{code}
 447
 448 %************************************************************************
 449 %*                                                                      *
 450 \subsection[BackSubst-Match-GRHSs]{Match and GRHSs}
 451 %*                                                                      *
 452 %************************************************************************
 453
 454 \begin{code}
 455 zonkMatchGroup :: ZonkEnv -> MatchGroup TcId-> TcM (MatchGroup Id)
 456 zonkMatchGroup env (MatchGroup ms ty)
 457   = do  { ms' <- mapM (zonkMatch env) ms
 458         ; ty' <- zonkTcTypeToType env ty
 459         ; return (MatchGroup ms' ty') }
 460
 461 zonkMatch :: ZonkEnv -> LMatch TcId-> TcM (LMatch Id)
 462 zonkMatch env (L loc (Match pats _ grhss))
 463   = do  { (env1, new_pats) <- zonkPats env pats
 464         ; new_grhss <- zonkGRHSs env1 grhss
 465         ; return (L loc (Match new_pats Nothing new_grhss)) }
 466
 467 -------------------------------------------------------------------------
 468 zonkGRHSs :: ZonkEnv -> GRHSs TcId -> TcM (GRHSs Id)
 469
 470 zonkGRHSs env (GRHSs grhss binds)
 471   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 472     let
 473         zonk_grhs (GRHS guarded rhs)
 474           = zonkStmts new_env guarded   `thenM` \ (env2, new_guarded) ->
 475             zonkLExpr env2 rhs          `thenM` \ new_rhs ->
 476             returnM (GRHS new_guarded new_rhs)
 477     in
 478     mappM (wrapLocM zonk_grhs) grhss    `thenM` \ new_grhss ->
 479     returnM (GRHSs new_grhss new_binds)
 480 \end{code}
 481
 482 %************************************************************************
 483 %*                                                                      *
 484 \subsection[BackSubst-HsExpr]{Running a zonkitution over a TypeCheckedExpr}
 485 %*                                                                      *
 486 %************************************************************************
 487
 488 \begin{code}
 489 zonkLExprs :: ZonkEnv -> [LHsExpr TcId] -> TcM [LHsExpr Id]
 490 zonkLExpr  :: ZonkEnv -> LHsExpr TcId   -> TcM (LHsExpr Id)
 491 zonkExpr   :: ZonkEnv -> HsExpr TcId    -> TcM (HsExpr Id)
 492
 493 zonkLExprs env exprs = mappM (zonkLExpr env) exprs
 494 zonkLExpr  env expr  = wrapLocM (zonkExpr env) expr
 495
 496 zonkExpr env (HsVar id)
 497   = returnM (HsVar (zonkIdOcc env id))
 498
 499 zonkExpr env (HsIPVar id)
 500   = returnM (HsIPVar (mapIPName (zonkIdOcc env) id))
 501
 502 zonkExpr env (HsLit (HsRat f ty))
 503   = zonkTcTypeToType env ty        `thenM` \ new_ty  ->
 504     returnM (HsLit (HsRat f new_ty))
 505
 506 zonkExpr _ (HsLit lit)
 507   = returnM (HsLit lit)
 508
 509 zonkExpr env (HsOverLit lit)
 510   = do  { lit' <- zonkOverLit env lit
 511         ; return (HsOverLit lit') }
 512
 513 zonkExpr env (HsLam matches)
 514   = zonkMatchGroup env matches  `thenM` \ new_matches ->
 515     returnM (HsLam new_matches)
 516
 517 zonkExpr env (HsApp e1 e2)
 518   = zonkLExpr env e1    `thenM` \ new_e1 ->
 519     zonkLExpr env e2    `thenM` \ new_e2 ->
 520     returnM (HsApp new_e1 new_e2)
 521
 522 zonkExpr env (HsBracketOut body bs)
 523   = mappM zonk_b bs     `thenM` \ bs' ->
 524     returnM (HsBracketOut body bs')
 525   where
 526     zonk_b (n,e) = zonkLExpr env e      `thenM` \ e' ->
 527                    returnM (n,e')
 528
 529 zonkExpr _ (HsSpliceE s) = WARN( True, ppr s ) -- Should not happen
 530                              returnM (HsSpliceE s)
 531
 532 zonkExpr env (OpApp e1 op fixity e2)
 533   = zonkLExpr env e1    `thenM` \ new_e1 ->
 534     zonkLExpr env op    `thenM` \ new_op ->
 535     zonkLExpr env e2    `thenM` \ new_e2 ->
 536     returnM (OpApp new_e1 new_op fixity new_e2)
 537
 538 zonkExpr env (NegApp expr op)
 539   = zonkLExpr env expr  `thenM` \ new_expr ->
 540     zonkExpr env op     `thenM` \ new_op ->
 541     returnM (NegApp new_expr new_op)
 542
 543 zonkExpr env (HsPar e)
 544   = zonkLExpr env e     `thenM` \new_e ->
 545     returnM (HsPar new_e)
 546
 547 zonkExpr env (SectionL expr op)
 548   = zonkLExpr env expr  `thenM` \ new_expr ->
 549     zonkLExpr env op            `thenM` \ new_op ->
 550     returnM (SectionL new_expr new_op)
 551
 552 zonkExpr env (SectionR op expr)
 553   = zonkLExpr env op            `thenM` \ new_op ->
 554     zonkLExpr env expr          `thenM` \ new_expr ->
 555     returnM (SectionR new_op new_expr)
 556
 557 zonkExpr env (ExplicitTuple tup_args boxed)
 558   = do { new_tup_args <- mapM zonk_tup_arg tup_args
 559        ; return (ExplicitTuple new_tup_args boxed) }
 560   where
 561     zonk_tup_arg (Present e) = do { e' <- zonkLExpr env e; return (Present e') }
 562     zonk_tup_arg (Missing t) = do { t' <- zonkTcTypeToType env t; return (Missing t') }
 563
 564 zonkExpr env (HsCase expr ms)
 565   = zonkLExpr env expr          `thenM` \ new_expr ->
 566     zonkMatchGroup env ms       `thenM` \ new_ms ->
 567     returnM (HsCase new_expr new_ms)
 568
 569 zonkExpr env (HsIf e0 e1 e2 e3)
 570   = do { new_e0 <- fmapMaybeM (zonkExpr env) e0
 571        ; new_e1 <- zonkLExpr env e1
 572        ; new_e2 <- zonkLExpr env e2
 573        ; new_e3 <- zonkLExpr env e3
 574        ; returnM (HsIf new_e0 new_e1 new_e2 new_e3) }
 575
 576 zonkExpr env (HsLet binds expr)
 577   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 578     zonkLExpr new_env expr      `thenM` \ new_expr ->
 579     returnM (HsLet new_binds new_expr)
 580
 581 zonkExpr env (HsDo do_or_lc stmts body return_op ty)
 582   = zonkStmts env stmts         `thenM` \ (new_env, new_stmts) ->
 583     zonkLExpr new_env body      `thenM` \ new_body ->
 584     zonkExpr new_env return_op  `thenM` \ new_return ->
 585     zonkTcTypeToType env ty     `thenM` \ new_ty   ->
 586     returnM (HsDo do_or_lc new_stmts new_body new_return new_ty)
 587
 588 zonkExpr env (ExplicitList ty exprs)
 589   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 590     zonkLExprs env exprs        `thenM` \ new_exprs ->
 591     returnM (ExplicitList new_ty new_exprs)
 592
 593 zonkExpr env (ExplicitPArr ty exprs)
 594   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 595     zonkLExprs env exprs        `thenM` \ new_exprs ->
 596     returnM (ExplicitPArr new_ty new_exprs)
 597
 598 zonkExpr env (RecordCon data_con con_expr rbinds)
 599   = do  { new_con_expr <- zonkExpr env con_expr
 600         ; new_rbinds   <- zonkRecFields env rbinds
 601         ; return (RecordCon data_con new_con_expr new_rbinds) }
 602
 603 zonkExpr env (RecordUpd expr rbinds cons in_tys out_tys)
 604   = do  { new_expr    <- zonkLExpr env expr
 605         ; new_in_tys  <- mapM (zonkTcTypeToType env) in_tys
 606         ; new_out_tys <- mapM (zonkTcTypeToType env) out_tys
 607         ; new_rbinds  <- zonkRecFields env rbinds
 608         ; return (RecordUpd new_expr new_rbinds cons new_in_tys new_out_tys) }
 609
 610 zonkExpr env (ExprWithTySigOut e ty)
 611   = do { e' <- zonkLExpr env e
 612        ; return (ExprWithTySigOut e' ty) }
 613
 614 zonkExpr _ (ExprWithTySig _ _) = panic "zonkExpr env:ExprWithTySig"
 615
 616 zonkExpr env (ArithSeq expr info)
 617   = zonkExpr env expr           `thenM` \ new_expr ->
 618     zonkArithSeq env info       `thenM` \ new_info ->
 619     returnM (ArithSeq new_expr new_info)
 620
 621 zonkExpr env (PArrSeq expr info)
 622   = zonkExpr env expr           `thenM` \ new_expr ->
 623     zonkArithSeq env info       `thenM` \ new_info ->
 624     returnM (PArrSeq new_expr new_info)
 625
 626 zonkExpr env (HsSCC lbl expr)
 627   = zonkLExpr env expr  `thenM` \ new_expr ->
 628     returnM (HsSCC lbl new_expr)
 629
 630 zonkExpr env (HsTickPragma info expr)
 631   = zonkLExpr env expr  `thenM` \ new_expr ->
 632     returnM (HsTickPragma info new_expr)
 633
 634 -- hdaume: core annotations
 635 zonkExpr env (HsCoreAnn lbl expr)
 636   = zonkLExpr env expr   `thenM` \ new_expr ->
 637     returnM (HsCoreAnn lbl new_expr)
 638
 639 -- arrow notation extensions
 640 zonkExpr env (HsProc pat body)
 641   = do  { (env1, new_pat) <- zonkPat env pat
 642         ; new_body <- zonkCmdTop env1 body
 643         ; return (HsProc new_pat new_body) }
 644
 645 zonkExpr env (HsArrApp e1 e2 ty ho rl)
 646   = zonkLExpr env e1                    `thenM` \ new_e1 ->
 647     zonkLExpr env e2                    `thenM` \ new_e2 ->
 648     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 649     returnM (HsArrApp new_e1 new_e2 new_ty ho rl)
 650
 651 zonkExpr env (HsArrForm op fixity args)
 652   = zonkLExpr env op                    `thenM` \ new_op ->
 653     mappM (zonkCmdTop env) args         `thenM` \ new_args ->
 654     returnM (HsArrForm new_op fixity new_args)
 655
 656 zonkExpr env (HsWrap co_fn expr)
 657   = zonkCoFn env co_fn  `thenM` \ (env1, new_co_fn) ->
 658     zonkExpr env1 expr  `thenM` \ new_expr ->
 659     return (HsWrap new_co_fn new_expr)
 660
 661 zonkExpr _ expr = pprPanic "zonkExpr" (ppr expr)
 662
 663 zonkCmdTop :: ZonkEnv -> LHsCmdTop TcId -> TcM (LHsCmdTop Id)
 664 zonkCmdTop env cmd = wrapLocM (zonk_cmd_top env) cmd
 665
 666 zonk_cmd_top :: ZonkEnv -> HsCmdTop TcId -> TcM (HsCmdTop Id)
 667 zonk_cmd_top env (HsCmdTop cmd stack_tys ty ids)
 668   = zonkLExpr env cmd                   `thenM` \ new_cmd ->
 669     zonkTcTypeToTypes env stack_tys     `thenM` \ new_stack_tys ->
 670     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 671     mapSndM (zonkExpr env) ids          `thenM` \ new_ids ->
 672     returnM (HsCmdTop new_cmd new_stack_tys new_ty new_ids)
 673
 674 -------------------------------------------------------------------------
 675 zonkCoFn :: ZonkEnv -> HsWrapper -> TcM (ZonkEnv, HsWrapper)
 676 zonkCoFn env WpHole   = return (env, WpHole)
 677 zonkCoFn env (WpCompose c1 c2) = do { (env1, c1') <- zonkCoFn env c1
 678                                     ; (env2, c2') <- zonkCoFn env1 c2
 679                                     ; return (env2, WpCompose c1' c2') }
 680 zonkCoFn env (WpCast co)    = do { co' <- zonkTcTypeToType env co
 681                                  ; return (env, WpCast co') }
 682 zonkCoFn env (WpEvLam ev)   = do { (env', ev') <- zonkEvBndrX env ev
 683                                  ; return (env', WpEvLam ev') }
 684 zonkCoFn env (WpEvApp arg)  = do { arg' <- zonkEvTerm env arg
 685                                  ; return (env, WpEvApp arg') }
 686 zonkCoFn env (WpTyLam tv)   = ASSERT( isImmutableTyVar tv )
 687                               return (env, WpTyLam tv)
 688 zonkCoFn env (WpTyApp ty)   = do { ty' <- zonkTcTypeToType env ty
 689                                  ; return (env, WpTyApp ty') }
 690 zonkCoFn env (WpLet bs)     = do { (env1, bs') <- zonkTcEvBinds env bs
 691                                  ; return (env1, WpLet bs') }
 692
 693 -------------------------------------------------------------------------
 694 zonkOverLit :: ZonkEnv -> HsOverLit TcId -> TcM (HsOverLit Id)
 695 zonkOverLit env lit@(OverLit { ol_witness = e, ol_type = ty })
 696   = do  { ty' <- zonkTcTypeToType env ty
 697         ; e' <- zonkExpr env e
 698         ; return (lit { ol_witness = e', ol_type = ty' }) }
 699
 700 -------------------------------------------------------------------------
 701 zonkArithSeq :: ZonkEnv -> ArithSeqInfo TcId -> TcM (ArithSeqInfo Id)
 702
 703 zonkArithSeq env (From e)
 704   = zonkLExpr env e             `thenM` \ new_e ->
 705     returnM (From new_e)
 706
 707 zonkArithSeq env (FromThen e1 e2)
 708   = zonkLExpr env e1    `thenM` \ new_e1 ->
 709     zonkLExpr env e2    `thenM` \ new_e2 ->
 710     returnM (FromThen new_e1 new_e2)
 711
 712 zonkArithSeq env (FromTo e1 e2)
 713   = zonkLExpr env e1    `thenM` \ new_e1 ->
 714     zonkLExpr env e2    `thenM` \ new_e2 ->
 715     returnM (FromTo new_e1 new_e2)
 716
 717 zonkArithSeq env (FromThenTo e1 e2 e3)
 718   = zonkLExpr env e1    `thenM` \ new_e1 ->
 719     zonkLExpr env e2    `thenM` \ new_e2 ->
 720     zonkLExpr env e3    `thenM` \ new_e3 ->
 721     returnM (FromThenTo new_e1 new_e2 new_e3)
 722
 723
 724 -------------------------------------------------------------------------
 725 zonkStmts :: ZonkEnv -> [LStmt TcId] -> TcM (ZonkEnv, [LStmt Id])
 726 zonkStmts env []     = return (env, [])
 727 zonkStmts env (s:ss) = do { (env1, s')  <- wrapLocSndM (zonkStmt env) s
 728                           ; (env2, ss') <- zonkStmts env1 ss
 729                           ; return (env2, s' : ss') }
 730
 731 zonkStmt :: ZonkEnv -> Stmt TcId -> TcM (ZonkEnv, Stmt Id)
 732 zonkStmt env (ParStmt stmts_w_bndrs mzip_op bind_op return_op)
 733   = mappM zonk_branch stmts_w_bndrs     `thenM` \ new_stmts_w_bndrs ->
 734     let
 735         new_binders = concat (map snd new_stmts_w_bndrs)
 736         env1 = extendZonkEnv env new_binders
 737     in
 738     zonkExpr env1 mzip_op   `thenM` \ new_mzip ->
 739     zonkExpr env1 bind_op   `thenM` \ new_bind ->
 740     zonkExpr env1 return_op `thenM` \ new_return ->
 741     return (env1, ParStmt new_stmts_w_bndrs new_mzip new_bind new_return)
 742   where
 743     zonk_branch (stmts, bndrs) = zonkStmts env stmts    `thenM` \ (env1, new_stmts) ->
 744                                  returnM (new_stmts, zonkIdOccs env1 bndrs)
 745
 746 zonkStmt env (RecStmt { recS_stmts = segStmts, recS_later_ids = lvs, recS_rec_ids = rvs
 747                       , recS_ret_fn = ret_id, recS_mfix_fn = mfix_id, recS_bind_fn = bind_id
 748                       , recS_rec_rets = rets })
 749   = do { new_rvs <- zonkIdBndrs env rvs
 750        ; new_lvs <- zonkIdBndrs env lvs
 751        ; new_ret_id  <- zonkExpr env ret_id
 752        ; new_mfix_id <- zonkExpr env mfix_id
 753        ; new_bind_id <- zonkExpr env bind_id
 754        ; let env1 = extendZonkEnv env new_rvs
 755        ; (env2, new_segStmts) <- zonkStmts env1 segStmts
 756         -- Zonk the ret-expressions in an envt that
 757         -- has the polymorphic bindings in the envt
 758        ; new_rets <- mapM (zonkExpr env2) rets
 759        ; return (extendZonkEnv env new_lvs,     -- Only the lvs are needed
 760                  RecStmt { recS_stmts = new_segStmts, recS_later_ids = new_lvs
 761                          , recS_rec_ids = new_rvs, recS_ret_fn = new_ret_id
 762                          , recS_mfix_fn = new_mfix_id, recS_bind_fn = new_bind_id
 763                          , recS_rec_rets = new_rets }) }
 764
 765 zonkStmt env (ExprStmt expr then_op guard_op ty)
 766   = zonkLExpr env expr          `thenM` \ new_expr ->
 767     zonkExpr env then_op        `thenM` \ new_then ->
 768     zonkExpr env guard_op       `thenM` \ new_guard ->
 769     zonkTcTypeToType env ty     `thenM` \ new_ty ->
 770     returnM (env, ExprStmt new_expr new_then new_guard new_ty)
 771
 772 zonkStmt env (TransformStmt stmts binders usingExpr maybeByExpr return_op bind_op)
 773   = do { (env', stmts') <- zonkStmts env stmts
 774     ; let binders' = zonkIdOccs env' binders
 775     ; usingExpr' <- zonkLExpr env' usingExpr
 776     ; maybeByExpr' <- zonkMaybeLExpr env' maybeByExpr
 777     ; return_op' <- zonkExpr env' return_op
 778     ; bind_op' <- zonkExpr env' bind_op
 779     ; return (env', TransformStmt stmts' binders' usingExpr' maybeByExpr' return_op' bind_op') }
 780
 781 zonkStmt env (GroupStmt stmts binderMap by using return_op bind_op liftM_op)
 782   = do { (env', stmts') <- zonkStmts env stmts
 783     ; binderMap' <- mappM (zonkBinderMapEntry env') binderMap
 784     ; by' <- fmapMaybeM (zonkLExpr env') by
 785     ; using' <- fmapEitherM (zonkLExpr env) (zonkExpr env) using
 786     ; return_op' <- zonkExpr env' return_op
 787     ; bind_op' <- zonkExpr env' bind_op
 788     ; liftM_op' <- zonkExpr env' liftM_op
 789     ; let env'' = extendZonkEnv env' (map snd binderMap')
 790     ; return (env'', GroupStmt stmts' binderMap' by' using' return_op' bind_op' liftM_op') }
 791   where
 792     zonkBinderMapEntry env (oldBinder, newBinder) = do
 793         let oldBinder' = zonkIdOcc env oldBinder
 794         newBinder' <- zonkIdBndr env newBinder
 795         return (oldBinder', newBinder')
 796
 797 zonkStmt env (LetStmt binds)
 798   = zonkLocalBinds env binds    `thenM` \ (env1, new_binds) ->
 799     returnM (env1, LetStmt new_binds)
 800
 801 zonkStmt env (BindStmt pat expr bind_op fail_op)
 802   = do  { new_expr <- zonkLExpr env expr
 803         ; (env1, new_pat) <- zonkPat env pat
 804         ; new_bind <- zonkExpr env bind_op
 805         ; new_fail <- zonkExpr env fail_op
 806         ; return (env1, BindStmt new_pat new_expr new_bind new_fail) }
 807
 808 zonkMaybeLExpr :: ZonkEnv -> Maybe (LHsExpr TcId) -> TcM (Maybe (LHsExpr Id))
 809 zonkMaybeLExpr _   Nothing  = return Nothing
 810 zonkMaybeLExpr env (Just e) = (zonkLExpr env e) >>= (return . Just)
 811
 812
 813 -------------------------------------------------------------------------
 814 zonkRecFields :: ZonkEnv -> HsRecordBinds TcId -> TcM (HsRecordBinds TcId)
 815 zonkRecFields env (HsRecFields flds dd)
 816   = do  { flds' <- mappM zonk_rbind flds
 817         ; return (HsRecFields flds' dd) }
 818   where
 819     zonk_rbind fld
 820       = do { new_id   <- wrapLocM (zonkIdBndr env) (hsRecFieldId fld)
 821            ; new_expr <- zonkLExpr env (hsRecFieldArg fld)
 822            ; return (fld { hsRecFieldId = new_id, hsRecFieldArg = new_expr }) }
 823
 824 -------------------------------------------------------------------------
 825 mapIPNameTc :: (a -> TcM b) -> IPName a -> TcM (IPName b)
 826 mapIPNameTc f (IPName n) = f n  `thenM` \ r -> returnM (IPName r)
 827 \end{code}
 828
 829
 830 %************************************************************************
 831 %*                                                                      *
 832 \subsection[BackSubst-Pats]{Patterns}
 833 %*                                                                      *
 834 %************************************************************************
 835
 836 \begin{code}
 837 zonkPat :: ZonkEnv -> OutPat TcId -> TcM (ZonkEnv, OutPat Id)
 838 -- Extend the environment as we go, because it's possible for one
 839 -- pattern to bind something that is used in another (inside or
 840 -- to the right)
 841 zonkPat env pat = wrapLocSndM (zonk_pat env) pat
 842
 843 zonk_pat :: ZonkEnv -> Pat TcId -> TcM (ZonkEnv, Pat Id)
 844 zonk_pat env (ParPat p)
 845   = do  { (env', p') <- zonkPat env p
 846         ; return (env', ParPat p') }
 847
 848 zonk_pat env (WildPat ty)
 849   = do  { ty' <- zonkTcTypeToType env ty
 850         ; return (env, WildPat ty') }
 851
 852 zonk_pat env (VarPat v)
 853   = do  { v' <- zonkIdBndr env v
 854         ; return (extendZonkEnv1 env v', VarPat v') }
 855
 856 zonk_pat env (LazyPat pat)
 857   = do  { (env', pat') <- zonkPat env pat
 858         ; return (env',  LazyPat pat') }
 859
 860 zonk_pat env (BangPat pat)
 861   = do  { (env', pat') <- zonkPat env pat
 862         ; return (env',  BangPat pat') }
 863
 864 zonk_pat env (AsPat (L loc v) pat)
 865   = do  { v' <- zonkIdBndr env v
 866         ; (env', pat') <- zonkPat (extendZonkEnv1 env v') pat
 867         ; return (env', AsPat (L loc v') pat') }
 868
 869 zonk_pat env (ViewPat expr pat ty)
 870   = do  { expr' <- zonkLExpr env expr
 871         ; (env', pat') <- zonkPat env pat
 872         ; ty' <- zonkTcTypeToType env ty
 873         ; return (env', ViewPat expr' pat' ty') }
 874
 875 zonk_pat env (ListPat pats ty)
 876   = do  { ty' <- zonkTcTypeToType env ty
 877         ; (env', pats') <- zonkPats env pats
 878         ; return (env', ListPat pats' ty') }
 879
 880 zonk_pat env (PArrPat pats ty)
 881   = do  { ty' <- zonkTcTypeToType env ty
 882         ; (env', pats') <- zonkPats env pats
 883         ; return (env', PArrPat pats' ty') }
 884
 885 zonk_pat env (TuplePat pats boxed ty)
 886   = do  { ty' <- zonkTcTypeToType env ty
 887         ; (env', pats') <- zonkPats env pats
 888         ; return (env', TuplePat pats' boxed ty') }
 889
 890 zonk_pat env p@(ConPatOut { pat_ty = ty, pat_dicts = evs, pat_binds = binds, pat_args = args })
 891   = ASSERT( all isImmutableTyVar (pat_tvs p) )
 892     do  { new_ty <- zonkTcTypeToType env ty
 893         ; (env1, new_evs) <- zonkEvBndrsX env evs
 894         ; (env2, new_binds) <- zonkTcEvBinds env1 binds
 895         ; (env', new_args) <- zonkConStuff env2 args
 896         ; returnM (env', p { pat_ty = new_ty, pat_dicts = new_evs,
 897                              pat_binds = new_binds, pat_args = new_args }) }
 898
 899 zonk_pat env (LitPat lit) = return (env, LitPat lit)
 900
 901 zonk_pat env (SigPatOut pat ty)
 902   = do  { ty' <- zonkTcTypeToType env ty
 903         ; (env', pat') <- zonkPat env pat
 904         ; return (env', SigPatOut pat' ty') }
 905
 906 zonk_pat env (NPat lit mb_neg eq_expr)
 907   = do  { lit' <- zonkOverLit env lit
 908         ; mb_neg' <- fmapMaybeM (zonkExpr env) mb_neg
 909         ; eq_expr' <- zonkExpr env eq_expr
 910         ; return (env, NPat lit' mb_neg' eq_expr') }
 911
 912 zonk_pat env (NPlusKPat (L loc n) lit e1 e2)
 913   = do  { n' <- zonkIdBndr env n
 914         ; lit' <- zonkOverLit env lit
 915         ; e1' <- zonkExpr env e1
 916         ; e2' <- zonkExpr env e2
 917         ; return (extendZonkEnv1 env n', NPlusKPat (L loc n') lit' e1' e2') }
 918
 919 zonk_pat env (CoPat co_fn pat ty)
 920   = do { (env', co_fn') <- zonkCoFn env co_fn
 921        ; (env'', pat') <- zonkPat env' (noLoc pat)
 922        ; ty' <- zonkTcTypeToType env'' ty
 923        ; return (env'', CoPat co_fn' (unLoc pat') ty') }
 924
 925 zonk_pat _ pat = pprPanic "zonk_pat" (ppr pat)
 926
 927 ---------------------------
 928 zonkConStuff :: ZonkEnv
 929              -> HsConDetails (OutPat TcId) (HsRecFields id (OutPat TcId))
 930              -> TcM (ZonkEnv,
 931                      HsConDetails (OutPat Id) (HsRecFields id (OutPat Id)))
 932 zonkConStuff env (PrefixCon pats)
 933   = do  { (env', pats') <- zonkPats env pats
 934         ; return (env', PrefixCon pats') }
 935
 936 zonkConStuff env (InfixCon p1 p2)
 937   = do  { (env1, p1') <- zonkPat env  p1
 938         ; (env', p2') <- zonkPat env1 p2
 939         ; return (env', InfixCon p1' p2') }
 940
 941 zonkConStuff env (RecCon (HsRecFields rpats dd))
 942   = do  { (env', pats') <- zonkPats env (map hsRecFieldArg rpats)
 943         ; let rpats' = zipWith (\rp p' -> rp { hsRecFieldArg = p' }) rpats pats'
 944         ; returnM (env', RecCon (HsRecFields rpats' dd)) }
 945         -- Field selectors have declared types; hence no zonking
 946
 947 ---------------------------
 948 zonkPats :: ZonkEnv -> [OutPat TcId] -> TcM (ZonkEnv, [OutPat Id])
 949 zonkPats env []         = return (env, [])
 950 zonkPats env (pat:pats) = do { (env1, pat') <- zonkPat env pat
 951                      ; (env', pats') <- zonkPats env1 pats
 952                      ; return (env', pat':pats') }
 953 \end{code}
 954
 955 %************************************************************************
 956 %*                                                                      *
 957 \subsection[BackSubst-Foreign]{Foreign exports}
 958 %*                                                                      *
 959 %************************************************************************
 960
 961
 962 \begin{code}
 963 zonkForeignExports :: ZonkEnv -> [LForeignDecl TcId] -> TcM [LForeignDecl Id]
 964 zonkForeignExports env ls = mappM (wrapLocM (zonkForeignExport env)) ls
 965
 966 zonkForeignExport :: ZonkEnv -> ForeignDecl TcId -> TcM (ForeignDecl Id)
 967 zonkForeignExport env (ForeignExport i _hs_ty spec) =
 968    returnM (ForeignExport (fmap (zonkIdOcc env) i) undefined spec)
 969 zonkForeignExport _ for_imp
 970   = returnM for_imp     -- Foreign imports don't need zonking
 971 \end{code}
 972
 973 \begin{code}
 974 zonkRules :: ZonkEnv -> [LRuleDecl TcId] -> TcM [LRuleDecl Id]
 975 zonkRules env rs = mappM (wrapLocM (zonkRule env)) rs
 976
 977 zonkRule :: ZonkEnv -> RuleDecl TcId -> TcM (RuleDecl Id)
 978 zonkRule env (HsRule name act (vars{-::[RuleBndr TcId]-}) lhs fv_lhs rhs fv_rhs)
 979   = do { (env_rhs, new_bndrs) <- mapAccumLM zonk_bndr env vars
 980
 981        ; unbound_tv_set <- newMutVar emptyVarSet
 982        ; let env_lhs = setZonkType env_rhs (zonkTypeCollecting unbound_tv_set)
 983         -- We need to gather the type variables mentioned on the LHS so we can
 984         -- quantify over them.  Example:
 985         --   data T a = C
 986         --
 987         --   foo :: T a -> Int
 988         --   foo C = 1
 989         --
 990         --   {-# RULES "myrule"  foo C = 1 #-}
 991         --
 992         -- After type checking the LHS becomes (foo a (C a))
 993         -- and we do not want to zap the unbound tyvar 'a' to (), because
 994         -- that limits the applicability of the rule.  Instead, we
 995         -- want to quantify over it!
 996         --
 997         -- It's easiest to find the free tyvars here. Attempts to do so earlier
 998         -- are tiresome, because (a) the data type is big and (b) finding the
 999         -- free type vars of an expression is necessarily monadic operation.
1000         --      (consider /\a -> f @ b, where b is side-effected to a)
1001
1002        ; new_lhs <- zonkLExpr env_lhs lhs
1003        ; new_rhs <- zonkLExpr env_rhs rhs
1004
1005        ; unbound_tvs <- readMutVar unbound_tv_set
1006        ; let final_bndrs :: [RuleBndr Var]
1007              final_bndrs = map (RuleBndr . noLoc) (varSetElems unbound_tvs) ++ new_bndrs
1008
1009        ; return (HsRule name act final_bndrs new_lhs fv_lhs new_rhs fv_rhs) }
1010   where
1011    zonk_bndr env (RuleBndr (L loc v))
1012       = do { (env', v') <- zonk_it env v; return (env', RuleBndr (L loc v')) }
1013    zonk_bndr _ (RuleBndrSig {}) = panic "zonk_bndr RuleBndrSig"
1014
1015    zonk_it env v
1016      | isId v     = do { v' <- zonkIdBndr env v; return (extendZonkEnv1 env v', v') }
1017      | isCoVar v  = do { v' <- zonkEvBndr env v; return (extendZonkEnv1 env v', v') }
1018      | otherwise  = ASSERT( isImmutableTyVar v) return (env, v)
1019 \end{code}
1020
1021 \begin{code}
1022 zonkVects :: ZonkEnv -> [LVectDecl TcId] -> TcM [LVectDecl Id]
1023 zonkVects env = mappM (wrapLocM (zonkVect env))
1024
1025 zonkVect :: ZonkEnv -> VectDecl TcId -> TcM (VectDecl Id)
1026 zonkVect env (HsVect v Nothing)
1027   = do { v' <- wrapLocM (zonkIdBndr env) v
1028        ; return $ HsVect v' Nothing
1029        }
1030 zonkVect env (HsVect v (Just e))
1031   = do { v' <- wrapLocM (zonkIdBndr env) v
1032        ; e' <- zonkLExpr env e
1033        ; return $ HsVect v' (Just e')
1034        }
1035 \end{code}
1036
1037 %************************************************************************
1038 %*                                                                      *
1039               Constraints and evidence
1040 %*                                                                      *
1041 %************************************************************************
1042
1043 \begin{code}
1044 zonkEvTerm :: ZonkEnv -> EvTerm -> TcM EvTerm
1045 zonkEvTerm env (EvId v)           = ASSERT2( isId v, ppr v )
1046                                     return (EvId (zonkIdOcc env v))
1047 zonkEvTerm env (EvCoercion co)    = do { co' <- zonkTcTypeToType env co
1048                                        ; return (EvCoercion co') }
1049 zonkEvTerm env (EvCast v co)      = ASSERT( isId v)
1050                                     do { co' <- zonkTcTypeToType env co
1051                                        ; return (EvCast (zonkIdOcc env v) co') }
1052 zonkEvTerm env (EvSuperClass d n) = return (EvSuperClass (zonkIdOcc env d) n)
1053 zonkEvTerm env (EvDFunApp df tys tms)
1054   = do { tys' <- zonkTcTypeToTypes env tys
1055        ; let tms' = map (zonkEvVarOcc env) tms
1056        ; return (EvDFunApp (zonkIdOcc env df) tys' tms') }
1057
1058 zonkTcEvBinds :: ZonkEnv -> TcEvBinds -> TcM (ZonkEnv, TcEvBinds)
1059 zonkTcEvBinds env (TcEvBinds var) = do { (env', bs') <- zonkEvBindsVar env var
1060                                        ; return (env', EvBinds bs') }
1061 zonkTcEvBinds env (EvBinds bs)    = do { (env', bs') <- zonkEvBinds env bs
1062                                        ; return (env', EvBinds bs') }
1063
1064 zonkEvBindsVar :: ZonkEnv -> EvBindsVar -> TcM (ZonkEnv, Bag EvBind)
1065 zonkEvBindsVar env (EvBindsVar ref _) = do { bs <- readMutVar ref
1066                                            ; zonkEvBinds env (evBindMapBinds bs) }
1067
1068 zonkEvBinds :: ZonkEnv -> Bag EvBind -> TcM (ZonkEnv, Bag EvBind)
1069 zonkEvBinds env binds
1070   = fixM (\ ~( _, new_binds) -> do
1071          { let env1 = extendZonkEnv env (collect_ev_bndrs new_binds)
1072          ; binds' <- mapBagM (zonkEvBind env1) binds
1073          ; return (env1, binds') })
1074   where
1075     collect_ev_bndrs :: Bag EvBind -> [EvVar]
1076     collect_ev_bndrs = foldrBag add []
1077     add (EvBind var _) vars = var : vars
1078
1079 zonkEvBind :: ZonkEnv -> EvBind -> TcM EvBind
1080 zonkEvBind env (EvBind var term)
1081   = do { var' <- zonkEvBndr env var
1082        ; term' <- zonkEvTerm env term
1083        ; return (EvBind var' term') }
1084 \end{code}
1085
1086 %************************************************************************
1087 %*                                                                      *
1088                          Zonking types
1089 %*                                                                      *
1090 %************************************************************************
1091
1092 \begin{code}
1093 zonkTcTypeToType :: ZonkEnv -> TcType -> TcM Type
1094 zonkTcTypeToType (ZonkEnv zonk_ty _) ty = zonk_ty ty
1095
1096 zonkTcTypeToTypes :: ZonkEnv -> [TcType] -> TcM [Type]
1097 zonkTcTypeToTypes env tys = mapM (zonkTcTypeToType env) tys
1098
1099 zonkTypeCollecting :: TcRef TyVarSet -> TcType -> TcM Type
1100 -- This variant collects unbound type variables in a mutable variable
1101 zonkTypeCollecting unbound_tv_set
1102   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar)
1103   where
1104     zonk_unbound_tyvar tv
1105         = do { tv' <- zonkQuantifiedTyVar tv
1106              ; tv_set <- readMutVar unbound_tv_set
1107              ; writeMutVar unbound_tv_set (extendVarSet tv_set tv')
1108              ; return (mkTyVarTy tv') }
1109
1110 zonkTypeZapping :: TcType -> TcM Type
1111 -- This variant is used for everything except the LHS of rules
1112 -- It zaps unbound type variables to (), or some other arbitrary type
1113 zonkTypeZapping ty
1114   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar) ty
1115   where
1116         -- Zonk a mutable but unbound type variable to an arbitrary type
1117         -- We know it's unbound even though we don't carry an environment,
1118         -- because at the binding site for a type variable we bind the
1119         -- mutable tyvar to a fresh immutable one.  So the mutable store
1120         -- plays the role of an environment.  If we come across a mutable
1121         -- type variable that isn't so bound, it must be completely free.
1122     zonk_unbound_tyvar tv = do { let ty = anyTypeOfKind (tyVarKind tv)
1123                                ; writeMetaTyVar tv ty
1124                                ; return ty }
1125 \end{code}