compiler/typecheck/TcHsSyn.lhs

   1 1%
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcHsSyn: Specialisations of the @HsSyn@ syntax for the typechecker
   7
   8 This module is an extension of @HsSyn@ syntax, for use in the type
   9 checker.
  10
  11 \begin{code}
  12 module TcHsSyn (
  13         mkHsConApp, mkHsDictLet, mkHsApp,
  14         hsLitType, hsLPatType, hsPatType,
  15         mkHsAppTy, mkSimpleHsAlt,
  16         nlHsIntLit,
  17         shortCutLit, hsOverLitName,
  18
  19         -- re-exported from TcMonad
  20         TcId, TcIdSet,
  21
  22         zonkTopDecls, zonkTopExpr, zonkTopLExpr,
  23         zonkId, zonkTopBndrs
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsSyn    -- oodles of it
  30
  31 -- others:
  32 import Id
  33
  34 import TcRnMonad
  35 import PrelNames
  36 import TcType
  37 import TcMType
  38 import TysPrim
  39 import TysWiredIn
  40 import DataCon
  41 import Name
  42 import NameSet
  43 import Var
  44 import VarSet
  45 import VarEnv
  46 import Literal
  47 import BasicTypes
  48 import Maybes
  49 import SrcLoc
  50 import DynFlags( DynFlag(..) )
  51 import Bag
  52 import FastString
  53 import Outputable
  54 \end{code}
  55
  56 \begin{code}
  57 -- XXX
  58 thenM :: Monad a => a b -> (b -> a c) -> a c
  59 thenM = (>>=)
  60
  61 returnM :: Monad m => a -> m a
  62 returnM = return
  63
  64 mappM :: (Monad m) => (a -> m b) -> [a] -> m [b]
  65 mappM = mapM
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 Note: If @hsLPatType@ doesn't bear a strong resemblance to @exprType@,
  76 then something is wrong.
  77 \begin{code}
  78 hsLPatType :: OutPat Id -> Type
  79 hsLPatType (L _ pat) = hsPatType pat
  80
  81 hsPatType :: Pat Id -> Type
  82 hsPatType (ParPat pat)                = hsLPatType pat
  83 hsPatType (WildPat ty)                = ty
  84 hsPatType (VarPat var)                = idType var
  85 hsPatType (BangPat pat)               = hsLPatType pat
  86 hsPatType (LazyPat pat)               = hsLPatType pat
  87 hsPatType (LitPat lit)                = hsLitType lit
  88 hsPatType (AsPat var _)               = idType (unLoc var)
  89 hsPatType (ViewPat _ _ ty)            = ty
  90 hsPatType (ListPat _ ty)              = mkListTy ty
  91 hsPatType (PArrPat _ ty)              = mkPArrTy ty
  92 hsPatType (TuplePat _ _ ty)           = ty
  93 hsPatType (ConPatOut { pat_ty = ty }) = ty
  94 hsPatType (SigPatOut _ ty)            = ty
  95 hsPatType (NPat lit _ _)              = overLitType lit
  96 hsPatType (NPlusKPat id _ _ _)        = idType (unLoc id)
  97 hsPatType (CoPat _ _ ty)              = ty
  98 hsPatType p                           = pprPanic "hsPatType" (ppr p)
  99
 100 hsLitType :: HsLit -> TcType
 101 hsLitType (HsChar _)       = charTy
 102 hsLitType (HsCharPrim _)   = charPrimTy
 103 hsLitType (HsString _)     = stringTy
 104 hsLitType (HsStringPrim _) = addrPrimTy
 105 hsLitType (HsInt _)        = intTy
 106 hsLitType (HsIntPrim _)    = intPrimTy
 107 hsLitType (HsWordPrim _)   = wordPrimTy
 108 hsLitType (HsInteger _ ty) = ty
 109 hsLitType (HsRat _ ty)     = ty
 110 hsLitType (HsFloatPrim _)  = floatPrimTy
 111 hsLitType (HsDoublePrim _) = doublePrimTy
 112 \end{code}
 113
 114 Overloaded literals. Here mainly becuase it uses isIntTy etc
 115
 116 \begin{code}
 117 shortCutLit :: OverLitVal -> TcType -> Maybe (HsExpr TcId)
 118 shortCutLit (HsIntegral i) ty
 119   | isIntTy ty && inIntRange i   = Just (HsLit (HsInt i))
 120   | isWordTy ty && inWordRange i = Just (mkLit wordDataCon (HsWordPrim i))
 121   | isIntegerTy ty               = Just (HsLit (HsInteger i ty))
 122   | otherwise                    = shortCutLit (HsFractional (fromInteger i)) ty
 123         -- The 'otherwise' case is important
 124         -- Consider (3 :: Float).  Syntactically it looks like an IntLit,
 125         -- so we'll call shortCutIntLit, but of course it's a float
 126         -- This can make a big difference for programs with a lot of
 127         -- literals, compiled without -O
 128
 129 shortCutLit (HsFractional f) ty
 130   | isFloatTy ty  = Just (mkLit floatDataCon  (HsFloatPrim f))
 131   | isDoubleTy ty = Just (mkLit doubleDataCon (HsDoublePrim f))
 132   | otherwise     = Nothing
 133
 134 shortCutLit (HsIsString s) ty
 135   | isStringTy ty = Just (HsLit (HsString s))
 136   | otherwise     = Nothing
 137
 138 mkLit :: DataCon -> HsLit -> HsExpr Id
 139 mkLit con lit = HsApp (nlHsVar (dataConWrapId con)) (nlHsLit lit)
 140
 141 ------------------------------
 142 hsOverLitName :: OverLitVal -> Name
 143 -- Get the canonical 'fromX' name for a particular OverLitVal
 144 hsOverLitName (HsIntegral {})   = fromIntegerName
 145 hsOverLitName (HsFractional {}) = fromRationalName
 146 hsOverLitName (HsIsString {})   = fromStringName
 147 \end{code}
 148
 149 %************************************************************************
 150 %*                                                                      *
 151 \subsection[BackSubst-HsBinds]{Running a substitution over @HsBinds@}
 152 %*                                                                      *
 153 %************************************************************************
 154
 155 \begin{code}
 156 -- zonkId is used *during* typechecking just to zonk the Id's type
 157 zonkId :: TcId -> TcM TcId
 158 zonkId id
 159   = zonkTcType (idType id) `thenM` \ ty' ->
 160     returnM (Id.setIdType id ty')
 161 \end{code}
 162
 163 The rest of the zonking is done *after* typechecking.
 164 The main zonking pass runs over the bindings
 165
 166  a) to convert TcTyVars to TyVars etc, dereferencing any bindings etc
 167  b) convert unbound TcTyVar to Void
 168  c) convert each TcId to an Id by zonking its type
 169
 170 The type variables are converted by binding mutable tyvars to immutable ones
 171 and then zonking as normal.
 172
 173 The Ids are converted by binding them in the normal Tc envt; that
 174 way we maintain sharing; eg an Id is zonked at its binding site and they
 175 all occurrences of that Id point to the common zonked copy
 176
 177 It's all pretty boring stuff, because HsSyn is such a large type, and
 178 the environment manipulation is tiresome.
 179
 180 \begin{code}
 181 data ZonkEnv = ZonkEnv  (TcType -> TcM Type)    -- How to zonk a type
 182                         (VarEnv Var)            -- What variables are in scope
 183         -- Maps an Id or EvVar to its zonked version; both have the same Name
 184         -- Note that all evidence (coercion variables as well as dictionaries)
 185         --      are kept in the ZonkEnv
 186         -- Only *type* abstraction is done by side effect
 187         -- Is only consulted lazily; hence knot-tying
 188
 189 emptyZonkEnv :: ZonkEnv
 190 emptyZonkEnv = ZonkEnv zonkTypeZapping emptyVarEnv
 191
 192 extendZonkEnv :: ZonkEnv -> [Var] -> ZonkEnv
 193 extendZonkEnv (ZonkEnv zonk_ty env) ids
 194   = ZonkEnv zonk_ty (extendVarEnvList env [(id,id) | id <- ids])
 195
 196 extendZonkEnv1 :: ZonkEnv -> Var -> ZonkEnv
 197 extendZonkEnv1 (ZonkEnv zonk_ty env) id
 198   = ZonkEnv zonk_ty (extendVarEnv env id id)
 199
 200 setZonkType :: ZonkEnv -> (TcType -> TcM Type) -> ZonkEnv
 201 setZonkType (ZonkEnv _ env) zonk_ty = ZonkEnv zonk_ty env
 202
 203 zonkEnvIds :: ZonkEnv -> [Id]
 204 zonkEnvIds (ZonkEnv _ env) = varEnvElts env
 205
 206 zonkIdOcc :: ZonkEnv -> TcId -> Id
 207 -- Ids defined in this module should be in the envt;
 208 -- ignore others.  (Actually, data constructors are also
 209 -- not LocalVars, even when locally defined, but that is fine.)
 210 -- (Also foreign-imported things aren't currently in the ZonkEnv;
 211 --  that's ok because they don't need zonking.)
 212 --
 213 -- Actually, Template Haskell works in 'chunks' of declarations, and
 214 -- an earlier chunk won't be in the 'env' that the zonking phase
 215 -- carries around.  Instead it'll be in the tcg_gbl_env, already fully
 216 -- zonked.  There's no point in looking it up there (except for error
 217 -- checking), and it's not conveniently to hand; hence the simple
 218 -- 'orElse' case in the LocalVar branch.
 219 --
 220 -- Even without template splices, in module Main, the checking of
 221 -- 'main' is done as a separate chunk.
 222 zonkIdOcc (ZonkEnv _zonk_ty env) id
 223   | isLocalVar id = lookupVarEnv env id `orElse` id
 224   | otherwise     = id
 225
 226 zonkIdOccs :: ZonkEnv -> [TcId] -> [Id]
 227 zonkIdOccs env ids = map (zonkIdOcc env) ids
 228
 229 -- zonkIdBndr is used *after* typechecking to get the Id's type
 230 -- to its final form.  The TyVarEnv give
 231 zonkIdBndr :: ZonkEnv -> TcId -> TcM Id
 232 zonkIdBndr env id
 233   = zonkTcTypeToType env (idType id)    `thenM` \ ty' ->
 234     returnM (Id.setIdType id ty')
 235
 236 zonkIdBndrs :: ZonkEnv -> [TcId] -> TcM [Id]
 237 zonkIdBndrs env ids = mappM (zonkIdBndr env) ids
 238
 239 zonkTopBndrs :: [TcId] -> TcM [Id]
 240 zonkTopBndrs ids = zonkIdBndrs emptyZonkEnv ids
 241
 242 zonkEvBndrsX :: ZonkEnv -> [EvVar] -> TcM (ZonkEnv, [Var])
 243 zonkEvBndrsX = mapAccumLM zonkEvBndrX
 244
 245 zonkEvBndrX :: ZonkEnv -> EvVar -> TcM (ZonkEnv, EvVar)
 246 -- Works for dictionaries and coercions
 247 zonkEvBndrX env var
 248   = do { var' <- zonkEvBndr env var
 249        ; return (extendZonkEnv1 env var', var') }
 250
 251 zonkEvBndr :: ZonkEnv -> EvVar -> TcM EvVar
 252 -- Works for dictionaries and coercions
 253 -- Does not extend the ZonkEnv
 254 zonkEvBndr env var
 255   = do { ty' <- zonkTcTypeToType env (varType var)
 256        ; return (setVarType var ty') }
 257
 258 zonkEvVarOcc :: ZonkEnv -> EvVar -> EvVar
 259 zonkEvVarOcc env v = zonkIdOcc env v
 260 \end{code}
 261
 262
 263 \begin{code}
 264 zonkTopExpr :: HsExpr TcId -> TcM (HsExpr Id)
 265 zonkTopExpr e = zonkExpr emptyZonkEnv e
 266
 267 zonkTopLExpr :: LHsExpr TcId -> TcM (LHsExpr Id)
 268 zonkTopLExpr e = zonkLExpr emptyZonkEnv e
 269
 270 zonkTopDecls :: Bag EvBind
 271              -> LHsBinds TcId -> NameSet
 272              -> [LRuleDecl TcId] -> [LTcSpecPrag] -> [LForeignDecl TcId]
 273              -> TcM ([Id],
 274                      Bag EvBind,
 275                      Bag (LHsBind  Id),
 276                      [LForeignDecl Id],
 277                      [LTcSpecPrag],
 278                      [LRuleDecl    Id])
 279 zonkTopDecls ev_binds binds sig_ns rules imp_specs fords
 280   = do  { (env1, ev_binds') <- zonkEvBinds emptyZonkEnv ev_binds
 281
 282          -- Warn about missing signatures
 283          -- Do this only when we we have a type to offer
 284         ; warn_missing_sigs <- doptM Opt_WarnMissingSigs
 285         ; let sig_warn | warn_missing_sigs = topSigWarn sig_ns
 286                        | otherwise         = noSigWarn
 287
 288         ; (env2, binds') <- zonkRecMonoBinds env1 sig_warn binds
 289                         -- Top level is implicitly recursive
 290         ; rules' <- zonkRules env2 rules
 291         ; specs' <- zonkLTcSpecPrags env2 imp_specs
 292         ; fords' <- zonkForeignExports env2 fords
 293         ; return (zonkEnvIds env2, ev_binds', binds', fords', specs', rules') }
 294
 295 ---------------------------------------------
 296 zonkLocalBinds :: ZonkEnv -> HsLocalBinds TcId -> TcM (ZonkEnv, HsLocalBinds Id)
 297 zonkLocalBinds env EmptyLocalBinds
 298   = return (env, EmptyLocalBinds)
 299
 300 zonkLocalBinds _ (HsValBinds (ValBindsIn {}))
 301   = panic "zonkLocalBinds" -- Not in typechecker output
 302
 303 zonkLocalBinds env (HsValBinds vb@(ValBindsOut binds sigs))
 304   = do  { warn_missing_sigs <- doptM Opt_WarnMissingLocalSigs
 305         ; let sig_warn | not warn_missing_sigs = noSigWarn
 306                        | otherwise             = localSigWarn sig_ns
 307               sig_ns = getTypeSigNames vb
 308         ; (env1, new_binds) <- go env sig_warn binds
 309         ; return (env1, HsValBinds (ValBindsOut new_binds sigs)) }
 310   where
 311     go env _ []
 312       = return (env, [])
 313     go env sig_warn ((r,b):bs)
 314       = do { (env1, b')  <- zonkRecMonoBinds env sig_warn b
 315            ; (env2, bs') <- go env1 sig_warn bs
 316            ; return (env2, (r,b'):bs') }
 317
 318 zonkLocalBinds env (HsIPBinds (IPBinds binds dict_binds))
 319   = mappM (wrapLocM zonk_ip_bind) binds `thenM` \ new_binds ->
 320     let
 321         env1 = extendZonkEnv env [ipNameName n | L _ (IPBind n _) <- new_binds]
 322     in
 323     zonkTcEvBinds env1 dict_binds       `thenM` \ (env2, new_dict_binds) ->
 324     returnM (env2, HsIPBinds (IPBinds new_binds new_dict_binds))
 325   where
 326     zonk_ip_bind (IPBind n e)
 327         = mapIPNameTc (zonkIdBndr env) n        `thenM` \ n' ->
 328           zonkLExpr env e                       `thenM` \ e' ->
 329           returnM (IPBind n' e')
 330
 331 ---------------------------------------------
 332 zonkRecMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (ZonkEnv, LHsBinds Id)
 333 zonkRecMonoBinds env sig_warn binds
 334  = fixM (\ ~(_, new_binds) -> do
 335         { let env1 = extendZonkEnv env (collectHsBindsBinders new_binds)
 336         ; binds' <- zonkMonoBinds env1 sig_warn binds
 337         ; return (env1, binds') })
 338
 339 ---------------------------------------------
 340 type SigWarn = Bool -> [Id] -> TcM ()
 341      -- Missing-signature warning
 342      -- The Bool is True for an AbsBinds, False otherwise
 343
 344 noSigWarn :: SigWarn
 345 noSigWarn _ _ = return ()
 346
 347 topSigWarn :: NameSet -> SigWarn
 348 topSigWarn sig_ns _ ids = mapM_ (topSigWarnId sig_ns) ids
 349
 350 topSigWarnId :: NameSet -> Id -> TcM ()
 351 -- The NameSet is the Ids that *lack* a signature
 352 -- We have to do it this way round because there are
 353 -- lots of top-level bindings that are generated by GHC
 354 -- and that don't have signatures
 355 topSigWarnId sig_ns id
 356   | idName id `elemNameSet` sig_ns = warnMissingSig msg id
 357   | otherwise                      = return ()
 358   where
 359     msg = ptext (sLit "Top-level binding with no type signature:")
 360
 361 localSigWarn :: NameSet -> SigWarn
 362 localSigWarn sig_ns is_abs_bind ids
 363   | not is_abs_bind = return ()
 364   | otherwise       = mapM_ (localSigWarnId sig_ns) ids
 365
 366 localSigWarnId :: NameSet -> Id -> TcM ()
 367 -- NameSet are the Ids that *have* type signatures
 368 localSigWarnId sig_ns id
 369   | not (isSigmaTy (idType id))    = return ()
 370   | idName id `elemNameSet` sig_ns = return ()
 371   | otherwise                      = warnMissingSig msg id
 372   where
 373     msg = ptext (sLit "Polymophic local binding with no type signature:")
 374
 375 warnMissingSig :: SDoc -> Id -> TcM ()
 376 warnMissingSig msg id
 377   = do  { env0 <- tcInitTidyEnv
 378         ; let (env1, tidy_ty) = tidyOpenType env0 (idType id)
 379         ; addWarnTcM (env1, mk_msg tidy_ty) }
 380   where
 381     mk_msg ty = sep [ msg, nest 2 $ pprHsVar (idName id) <+> dcolon <+> ppr ty ]
 382
 383 ---------------------------------------------
 384 zonkMonoBinds :: ZonkEnv -> SigWarn -> LHsBinds TcId -> TcM (LHsBinds Id)
 385 zonkMonoBinds env sig_warn binds = mapBagM (wrapLocM (zonk_bind env sig_warn)) binds
 386
 387 zonk_bind :: ZonkEnv -> SigWarn -> HsBind TcId -> TcM (HsBind Id)
 388 zonk_bind env sig_warn bind@(PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty})
 389   = do  { (_env, new_pat) <- zonkPat env pat            -- Env already extended
 390         ; sig_warn False (collectPatBinders new_pat)
 391         ; new_grhss <- zonkGRHSs env grhss
 392         ; new_ty    <- zonkTcTypeToType env ty
 393         ; return (bind { pat_lhs = new_pat, pat_rhs = new_grhss, pat_rhs_ty = new_ty }) }
 394
 395 zonk_bind env sig_warn (VarBind { var_id = var, var_rhs = expr, var_inline = inl })
 396   = do { new_var  <- zonkIdBndr env var
 397        ; sig_warn False [new_var]
 398        ; new_expr <- zonkLExpr env expr
 399        ; return (VarBind { var_id = new_var, var_rhs = new_expr, var_inline = inl }) }
 400
 401 zonk_bind env sig_warn bind@(FunBind { fun_id = L loc var, fun_matches = ms
 402                                      , fun_co_fn = co_fn })
 403   = do { new_var <- zonkIdBndr env var
 404        ; sig_warn False [new_var]
 405        ; (env1, new_co_fn) <- zonkCoFn env co_fn
 406        ; new_ms <- zonkMatchGroup env1 ms
 407        ; return (bind { fun_id = L loc new_var, fun_matches = new_ms
 408                       , fun_co_fn = new_co_fn }) }
 409
 410 zonk_bind env sig_warn (AbsBinds { abs_tvs = tyvars, abs_ev_vars = evs
 411                                  , abs_ev_binds = ev_binds
 412                                  , abs_exports = exports
 413                                  , abs_binds = val_binds })
 414   = ASSERT( all isImmutableTyVar tyvars )
 415     do { (env1, new_evs) <- zonkEvBndrsX env evs
 416        ; (env2, new_ev_binds) <- zonkTcEvBinds env1 ev_binds
 417        ; (new_val_bind, new_exports) <- fixM $ \ ~(new_val_binds, _) ->
 418          do { let env3 = extendZonkEnv env2 (collectHsBindsBinders new_val_binds)
 419             ; new_val_binds <- zonkMonoBinds env3 noSigWarn val_binds
 420             ; new_exports   <- mapM (zonkExport env3) exports
 421             ; return (new_val_binds, new_exports) }
 422        ; sig_warn True [b | (_,b,_,_) <- new_exports]
 423        ; return (AbsBinds { abs_tvs = tyvars, abs_ev_vars = new_evs, abs_ev_binds = new_ev_binds
 424                           , abs_exports = new_exports, abs_binds = new_val_bind }) }
 425   where
 426     zonkExport env (tyvars, global, local, prags)
 427         -- The tyvars are already zonked
 428         = zonkIdBndr env global                 `thenM` \ new_global ->
 429           zonkSpecPrags env prags               `thenM` \ new_prags ->
 430           returnM (tyvars, new_global, zonkIdOcc env local, new_prags)
 431
 432 zonkSpecPrags :: ZonkEnv -> TcSpecPrags -> TcM TcSpecPrags
 433 zonkSpecPrags _   IsDefaultMethod = return IsDefaultMethod
 434 zonkSpecPrags env (SpecPrags ps)  = do { ps' <- zonkLTcSpecPrags env ps
 435                                        ; return (SpecPrags ps') }
 436
 437 zonkLTcSpecPrags :: ZonkEnv -> [LTcSpecPrag] -> TcM [LTcSpecPrag]
 438 zonkLTcSpecPrags env ps
 439   = mapM zonk_prag ps
 440   where
 441     zonk_prag (L loc (SpecPrag id co_fn inl))
 442         = do { (_, co_fn') <- zonkCoFn env co_fn
 443              ; return (L loc (SpecPrag (zonkIdOcc env id) co_fn' inl)) }
 444 \end{code}
 445
 446 %************************************************************************
 447 %*                                                                      *
 448 \subsection[BackSubst-Match-GRHSs]{Match and GRHSs}
 449 %*                                                                      *
 450 %************************************************************************
 451
 452 \begin{code}
 453 zonkMatchGroup :: ZonkEnv -> MatchGroup TcId-> TcM (MatchGroup Id)
 454 zonkMatchGroup env (MatchGroup ms ty)
 455   = do  { ms' <- mapM (zonkMatch env) ms
 456         ; ty' <- zonkTcTypeToType env ty
 457         ; return (MatchGroup ms' ty') }
 458
 459 zonkMatch :: ZonkEnv -> LMatch TcId-> TcM (LMatch Id)
 460 zonkMatch env (L loc (Match pats _ grhss))
 461   = do  { (env1, new_pats) <- zonkPats env pats
 462         ; new_grhss <- zonkGRHSs env1 grhss
 463         ; return (L loc (Match new_pats Nothing new_grhss)) }
 464
 465 -------------------------------------------------------------------------
 466 zonkGRHSs :: ZonkEnv -> GRHSs TcId -> TcM (GRHSs Id)
 467
 468 zonkGRHSs env (GRHSs grhss binds)
 469   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 470     let
 471         zonk_grhs (GRHS guarded rhs)
 472           = zonkStmts new_env guarded   `thenM` \ (env2, new_guarded) ->
 473             zonkLExpr env2 rhs          `thenM` \ new_rhs ->
 474             returnM (GRHS new_guarded new_rhs)
 475     in
 476     mappM (wrapLocM zonk_grhs) grhss    `thenM` \ new_grhss ->
 477     returnM (GRHSs new_grhss new_binds)
 478 \end{code}
 479
 480 %************************************************************************
 481 %*                                                                      *
 482 \subsection[BackSubst-HsExpr]{Running a zonkitution over a TypeCheckedExpr}
 483 %*                                                                      *
 484 %************************************************************************
 485
 486 \begin{code}
 487 zonkLExprs :: ZonkEnv -> [LHsExpr TcId] -> TcM [LHsExpr Id]
 488 zonkLExpr  :: ZonkEnv -> LHsExpr TcId   -> TcM (LHsExpr Id)
 489 zonkExpr   :: ZonkEnv -> HsExpr TcId    -> TcM (HsExpr Id)
 490
 491 zonkLExprs env exprs = mappM (zonkLExpr env) exprs
 492 zonkLExpr  env expr  = wrapLocM (zonkExpr env) expr
 493
 494 zonkExpr env (HsVar id)
 495   = returnM (HsVar (zonkIdOcc env id))
 496
 497 zonkExpr env (HsIPVar id)
 498   = returnM (HsIPVar (mapIPName (zonkIdOcc env) id))
 499
 500 zonkExpr env (HsLit (HsRat f ty))
 501   = zonkTcTypeToType env ty        `thenM` \ new_ty  ->
 502     returnM (HsLit (HsRat f new_ty))
 503
 504 zonkExpr _ (HsLit lit)
 505   = returnM (HsLit lit)
 506
 507 zonkExpr env (HsOverLit lit)
 508   = do  { lit' <- zonkOverLit env lit
 509         ; return (HsOverLit lit') }
 510
 511 zonkExpr env (HsLam matches)
 512   = zonkMatchGroup env matches  `thenM` \ new_matches ->
 513     returnM (HsLam new_matches)
 514
 515 zonkExpr env (HsApp e1 e2)
 516   = zonkLExpr env e1    `thenM` \ new_e1 ->
 517     zonkLExpr env e2    `thenM` \ new_e2 ->
 518     returnM (HsApp new_e1 new_e2)
 519
 520 zonkExpr env (HsBracketOut body bs)
 521   = mappM zonk_b bs     `thenM` \ bs' ->
 522     returnM (HsBracketOut body bs')
 523   where
 524     zonk_b (n,e) = zonkLExpr env e      `thenM` \ e' ->
 525                    returnM (n,e')
 526
 527 zonkExpr _ (HsSpliceE s) = WARN( True, ppr s ) -- Should not happen
 528                              returnM (HsSpliceE s)
 529
 530 zonkExpr env (OpApp e1 op fixity e2)
 531   = zonkLExpr env e1    `thenM` \ new_e1 ->
 532     zonkLExpr env op    `thenM` \ new_op ->
 533     zonkLExpr env e2    `thenM` \ new_e2 ->
 534     returnM (OpApp new_e1 new_op fixity new_e2)
 535
 536 zonkExpr env (NegApp expr op)
 537   = zonkLExpr env expr  `thenM` \ new_expr ->
 538     zonkExpr env op     `thenM` \ new_op ->
 539     returnM (NegApp new_expr new_op)
 540
 541 zonkExpr env (HsPar e)
 542   = zonkLExpr env e     `thenM` \new_e ->
 543     returnM (HsPar new_e)
 544
 545 zonkExpr env (SectionL expr op)
 546   = zonkLExpr env expr  `thenM` \ new_expr ->
 547     zonkLExpr env op            `thenM` \ new_op ->
 548     returnM (SectionL new_expr new_op)
 549
 550 zonkExpr env (SectionR op expr)
 551   = zonkLExpr env op            `thenM` \ new_op ->
 552     zonkLExpr env expr          `thenM` \ new_expr ->
 553     returnM (SectionR new_op new_expr)
 554
 555 zonkExpr env (ExplicitTuple tup_args boxed)
 556   = do { new_tup_args <- mapM zonk_tup_arg tup_args
 557        ; return (ExplicitTuple new_tup_args boxed) }
 558   where
 559     zonk_tup_arg (Present e) = do { e' <- zonkLExpr env e; return (Present e') }
 560     zonk_tup_arg (Missing t) = do { t' <- zonkTcTypeToType env t; return (Missing t') }
 561
 562 zonkExpr env (HsCase expr ms)
 563   = zonkLExpr env expr          `thenM` \ new_expr ->
 564     zonkMatchGroup env ms       `thenM` \ new_ms ->
 565     returnM (HsCase new_expr new_ms)
 566
 567 zonkExpr env (HsIf e0 e1 e2 e3)
 568   = do { new_e0 <- fmapMaybeM (zonkExpr env) e0
 569        ; new_e1 <- zonkLExpr env e1
 570        ; new_e2 <- zonkLExpr env e2
 571        ; new_e3 <- zonkLExpr env e3
 572        ; returnM (HsIf new_e0 new_e1 new_e2 new_e3) }
 573
 574 zonkExpr env (HsLet binds expr)
 575   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 576     zonkLExpr new_env expr      `thenM` \ new_expr ->
 577     returnM (HsLet new_binds new_expr)
 578
 579 zonkExpr env (HsDo do_or_lc stmts body ty)
 580   = zonkStmts env stmts         `thenM` \ (new_env, new_stmts) ->
 581     zonkLExpr new_env body      `thenM` \ new_body ->
 582     zonkTcTypeToType env ty     `thenM` \ new_ty   ->
 583     zonkDo env do_or_lc         `thenM` \ new_do_or_lc ->
 584     returnM (HsDo new_do_or_lc new_stmts new_body new_ty)
 585
 586 zonkExpr env (ExplicitList ty exprs)
 587   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 588     zonkLExprs env exprs        `thenM` \ new_exprs ->
 589     returnM (ExplicitList new_ty new_exprs)
 590
 591 zonkExpr env (ExplicitPArr ty exprs)
 592   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 593     zonkLExprs env exprs        `thenM` \ new_exprs ->
 594     returnM (ExplicitPArr new_ty new_exprs)
 595
 596 zonkExpr env (RecordCon data_con con_expr rbinds)
 597   = do  { new_con_expr <- zonkExpr env con_expr
 598         ; new_rbinds   <- zonkRecFields env rbinds
 599         ; return (RecordCon data_con new_con_expr new_rbinds) }
 600
 601 zonkExpr env (RecordUpd expr rbinds cons in_tys out_tys)
 602   = do  { new_expr    <- zonkLExpr env expr
 603         ; new_in_tys  <- mapM (zonkTcTypeToType env) in_tys
 604         ; new_out_tys <- mapM (zonkTcTypeToType env) out_tys
 605         ; new_rbinds  <- zonkRecFields env rbinds
 606         ; return (RecordUpd new_expr new_rbinds cons new_in_tys new_out_tys) }
 607
 608 zonkExpr env (ExprWithTySigOut e ty)
 609   = do { e' <- zonkLExpr env e
 610        ; return (ExprWithTySigOut e' ty) }
 611
 612 zonkExpr _ (ExprWithTySig _ _) = panic "zonkExpr env:ExprWithTySig"
 613
 614 zonkExpr env (ArithSeq expr info)
 615   = zonkExpr env expr           `thenM` \ new_expr ->
 616     zonkArithSeq env info       `thenM` \ new_info ->
 617     returnM (ArithSeq new_expr new_info)
 618
 619 zonkExpr env (PArrSeq expr info)
 620   = zonkExpr env expr           `thenM` \ new_expr ->
 621     zonkArithSeq env info       `thenM` \ new_info ->
 622     returnM (PArrSeq new_expr new_info)
 623
 624 zonkExpr env (HsSCC lbl expr)
 625   = zonkLExpr env expr  `thenM` \ new_expr ->
 626     returnM (HsSCC lbl new_expr)
 627
 628 zonkExpr env (HsTickPragma info expr)
 629   = zonkLExpr env expr  `thenM` \ new_expr ->
 630     returnM (HsTickPragma info new_expr)
 631
 632 -- hdaume: core annotations
 633 zonkExpr env (HsCoreAnn lbl expr)
 634   = zonkLExpr env expr   `thenM` \ new_expr ->
 635     returnM (HsCoreAnn lbl new_expr)
 636
 637 -- arrow notation extensions
 638 zonkExpr env (HsProc pat body)
 639   = do  { (env1, new_pat) <- zonkPat env pat
 640         ; new_body <- zonkCmdTop env1 body
 641         ; return (HsProc new_pat new_body) }
 642
 643 zonkExpr env (HsArrApp e1 e2 ty ho rl)
 644   = zonkLExpr env e1                    `thenM` \ new_e1 ->
 645     zonkLExpr env e2                    `thenM` \ new_e2 ->
 646     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 647     returnM (HsArrApp new_e1 new_e2 new_ty ho rl)
 648
 649 zonkExpr env (HsArrForm op fixity args)
 650   = zonkLExpr env op                    `thenM` \ new_op ->
 651     mappM (zonkCmdTop env) args         `thenM` \ new_args ->
 652     returnM (HsArrForm new_op fixity new_args)
 653
 654 zonkExpr env (HsWrap co_fn expr)
 655   = zonkCoFn env co_fn  `thenM` \ (env1, new_co_fn) ->
 656     zonkExpr env1 expr  `thenM` \ new_expr ->
 657     return (HsWrap new_co_fn new_expr)
 658
 659 zonkExpr _ expr = pprPanic "zonkExpr" (ppr expr)
 660
 661 zonkCmdTop :: ZonkEnv -> LHsCmdTop TcId -> TcM (LHsCmdTop Id)
 662 zonkCmdTop env cmd = wrapLocM (zonk_cmd_top env) cmd
 663
 664 zonk_cmd_top :: ZonkEnv -> HsCmdTop TcId -> TcM (HsCmdTop Id)
 665 zonk_cmd_top env (HsCmdTop cmd stack_tys ty ids)
 666   = zonkLExpr env cmd                   `thenM` \ new_cmd ->
 667     zonkTcTypeToTypes env stack_tys     `thenM` \ new_stack_tys ->
 668     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 669     mapSndM (zonkExpr env) ids          `thenM` \ new_ids ->
 670     returnM (HsCmdTop new_cmd new_stack_tys new_ty new_ids)
 671
 672 -------------------------------------------------------------------------
 673 zonkCoFn :: ZonkEnv -> HsWrapper -> TcM (ZonkEnv, HsWrapper)
 674 zonkCoFn env WpHole   = return (env, WpHole)
 675 zonkCoFn env (WpCompose c1 c2) = do { (env1, c1') <- zonkCoFn env c1
 676                                     ; (env2, c2') <- zonkCoFn env1 c2
 677                                     ; return (env2, WpCompose c1' c2') }
 678 zonkCoFn env (WpCast co)    = do { co' <- zonkTcTypeToType env co
 679                                  ; return (env, WpCast co') }
 680 zonkCoFn env (WpEvLam ev)   = do { (env', ev') <- zonkEvBndrX env ev
 681                                  ; return (env', WpEvLam ev') }
 682 zonkCoFn env (WpEvApp arg)  = do { arg' <- zonkEvTerm env arg
 683                                  ; return (env, WpEvApp arg') }
 684 zonkCoFn env (WpTyLam tv)   = ASSERT( isImmutableTyVar tv )
 685                               return (env, WpTyLam tv)
 686 zonkCoFn env (WpTyApp ty)   = do { ty' <- zonkTcTypeToType env ty
 687                                  ; return (env, WpTyApp ty') }
 688 zonkCoFn env (WpLet bs)     = do { (env1, bs') <- zonkTcEvBinds env bs
 689                                  ; return (env1, WpLet bs') }
 690
 691 -------------------------------------------------------------------------
 692 zonkDo :: ZonkEnv -> HsStmtContext Name -> TcM (HsStmtContext Name)
 693 -- Only used for 'do', so the only Ids are in a MDoExpr table
 694 zonkDo env (MDoExpr tbl) = do { tbl' <- mapSndM (zonkExpr env) tbl
 695                               ; return (MDoExpr tbl') }
 696 zonkDo _   do_or_lc      = return do_or_lc
 697
 698 -------------------------------------------------------------------------
 699 zonkOverLit :: ZonkEnv -> HsOverLit TcId -> TcM (HsOverLit Id)
 700 zonkOverLit env lit@(OverLit { ol_witness = e, ol_type = ty })
 701   = do  { ty' <- zonkTcTypeToType env ty
 702         ; e' <- zonkExpr env e
 703         ; return (lit { ol_witness = e', ol_type = ty' }) }
 704
 705 -------------------------------------------------------------------------
 706 zonkArithSeq :: ZonkEnv -> ArithSeqInfo TcId -> TcM (ArithSeqInfo Id)
 707
 708 zonkArithSeq env (From e)
 709   = zonkLExpr env e             `thenM` \ new_e ->
 710     returnM (From new_e)
 711
 712 zonkArithSeq env (FromThen e1 e2)
 713   = zonkLExpr env e1    `thenM` \ new_e1 ->
 714     zonkLExpr env e2    `thenM` \ new_e2 ->
 715     returnM (FromThen new_e1 new_e2)
 716
 717 zonkArithSeq env (FromTo e1 e2)
 718   = zonkLExpr env e1    `thenM` \ new_e1 ->
 719     zonkLExpr env e2    `thenM` \ new_e2 ->
 720     returnM (FromTo new_e1 new_e2)
 721
 722 zonkArithSeq env (FromThenTo e1 e2 e3)
 723   = zonkLExpr env e1    `thenM` \ new_e1 ->
 724     zonkLExpr env e2    `thenM` \ new_e2 ->
 725     zonkLExpr env e3    `thenM` \ new_e3 ->
 726     returnM (FromThenTo new_e1 new_e2 new_e3)
 727
 728
 729 -------------------------------------------------------------------------
 730 zonkStmts :: ZonkEnv -> [LStmt TcId] -> TcM (ZonkEnv, [LStmt Id])
 731 zonkStmts env []     = return (env, [])
 732 zonkStmts env (s:ss) = do { (env1, s')  <- wrapLocSndM (zonkStmt env) s
 733                           ; (env2, ss') <- zonkStmts env1 ss
 734                           ; return (env2, s' : ss') }
 735
 736 zonkStmt :: ZonkEnv -> Stmt TcId -> TcM (ZonkEnv, Stmt Id)
 737 zonkStmt env (ParStmt stmts_w_bndrs)
 738   = mappM zonk_branch stmts_w_bndrs     `thenM` \ new_stmts_w_bndrs ->
 739     let
 740         new_binders = concat (map snd new_stmts_w_bndrs)
 741         env1 = extendZonkEnv env new_binders
 742     in
 743     return (env1, ParStmt new_stmts_w_bndrs)
 744   where
 745     zonk_branch (stmts, bndrs) = zonkStmts env stmts    `thenM` \ (env1, new_stmts) ->
 746                                  returnM (new_stmts, zonkIdOccs env1 bndrs)
 747
 748 zonkStmt env (RecStmt { recS_stmts = segStmts, recS_later_ids = lvs, recS_rec_ids = rvs
 749                       , recS_ret_fn = ret_id, recS_mfix_fn = mfix_id, recS_bind_fn = bind_id
 750                       , recS_rec_rets = rets, recS_dicts = binds })
 751   = do { new_rvs <- zonkIdBndrs env rvs
 752        ; new_lvs <- zonkIdBndrs env lvs
 753        ; new_ret_id  <- zonkExpr env ret_id
 754        ; new_mfix_id <- zonkExpr env mfix_id
 755        ; new_bind_id <- zonkExpr env bind_id
 756        ; let env1 = extendZonkEnv env new_rvs
 757        ; (env2, new_segStmts) <- zonkStmts env1 segStmts
 758         -- Zonk the ret-expressions in an envt that
 759         -- has the polymorphic bindings in the envt
 760        ; new_rets <- mapM (zonkExpr env2) rets
 761        ; let env3 = extendZonkEnv env new_lvs   -- Only the lvs are needed
 762        ; (env4, new_binds) <- zonkTcEvBinds env3 binds
 763        ; return (env4,
 764                  RecStmt { recS_stmts = new_segStmts, recS_later_ids = new_lvs
 765                          , recS_rec_ids = new_rvs, recS_ret_fn = new_ret_id
 766                          , recS_mfix_fn = new_mfix_id, recS_bind_fn = new_bind_id
 767                          , recS_rec_rets = new_rets, recS_dicts = new_binds }) }
 768
 769 zonkStmt env (ExprStmt expr then_op ty)
 770   = zonkLExpr env expr          `thenM` \ new_expr ->
 771     zonkExpr env then_op        `thenM` \ new_then ->
 772     zonkTcTypeToType env ty     `thenM` \ new_ty ->
 773     returnM (env, ExprStmt new_expr new_then new_ty)
 774
 775 zonkStmt env (TransformStmt stmts binders usingExpr maybeByExpr)
 776   = do { (env', stmts') <- zonkStmts env stmts
 777     ; let binders' = zonkIdOccs env' binders
 778     ; usingExpr' <- zonkLExpr env' usingExpr
 779     ; maybeByExpr' <- zonkMaybeLExpr env' maybeByExpr
 780     ; return (env', TransformStmt stmts' binders' usingExpr' maybeByExpr') }
 781
 782 zonkStmt env (GroupStmt stmts binderMap by using)
 783   = do { (env', stmts') <- zonkStmts env stmts
 784     ; binderMap' <- mappM (zonkBinderMapEntry env') binderMap
 785     ; by' <- fmapMaybeM (zonkLExpr env') by
 786     ; using' <- fmapEitherM (zonkLExpr env) (zonkExpr env) using
 787     ; let env'' = extendZonkEnv env' (map snd binderMap')
 788     ; return (env'', GroupStmt stmts' binderMap' by' using') }
 789   where
 790     zonkBinderMapEntry env (oldBinder, newBinder) = do
 791         let oldBinder' = zonkIdOcc env oldBinder
 792         newBinder' <- zonkIdBndr env newBinder
 793         return (oldBinder', newBinder')
 794
 795 zonkStmt env (LetStmt binds)
 796   = zonkLocalBinds env binds    `thenM` \ (env1, new_binds) ->
 797     returnM (env1, LetStmt new_binds)
 798
 799 zonkStmt env (BindStmt pat expr bind_op fail_op)
 800   = do  { new_expr <- zonkLExpr env expr
 801         ; (env1, new_pat) <- zonkPat env pat
 802         ; new_bind <- zonkExpr env bind_op
 803         ; new_fail <- zonkExpr env fail_op
 804         ; return (env1, BindStmt new_pat new_expr new_bind new_fail) }
 805
 806 zonkMaybeLExpr :: ZonkEnv -> Maybe (LHsExpr TcId) -> TcM (Maybe (LHsExpr Id))
 807 zonkMaybeLExpr _   Nothing  = return Nothing
 808 zonkMaybeLExpr env (Just e) = (zonkLExpr env e) >>= (return . Just)
 809
 810
 811 -------------------------------------------------------------------------
 812 zonkRecFields :: ZonkEnv -> HsRecordBinds TcId -> TcM (HsRecordBinds TcId)
 813 zonkRecFields env (HsRecFields flds dd)
 814   = do  { flds' <- mappM zonk_rbind flds
 815         ; return (HsRecFields flds' dd) }
 816   where
 817     zonk_rbind fld
 818       = do { new_id   <- wrapLocM (zonkIdBndr env) (hsRecFieldId fld)
 819            ; new_expr <- zonkLExpr env (hsRecFieldArg fld)
 820            ; return (fld { hsRecFieldId = new_id, hsRecFieldArg = new_expr }) }
 821
 822 -------------------------------------------------------------------------
 823 mapIPNameTc :: (a -> TcM b) -> IPName a -> TcM (IPName b)
 824 mapIPNameTc f (IPName n) = f n  `thenM` \ r -> returnM (IPName r)
 825 \end{code}
 826
 827
 828 %************************************************************************
 829 %*                                                                      *
 830 \subsection[BackSubst-Pats]{Patterns}
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 \begin{code}
 835 zonkPat :: ZonkEnv -> OutPat TcId -> TcM (ZonkEnv, OutPat Id)
 836 -- Extend the environment as we go, because it's possible for one
 837 -- pattern to bind something that is used in another (inside or
 838 -- to the right)
 839 zonkPat env pat = wrapLocSndM (zonk_pat env) pat
 840
 841 zonk_pat :: ZonkEnv -> Pat TcId -> TcM (ZonkEnv, Pat Id)
 842 zonk_pat env (ParPat p)
 843   = do  { (env', p') <- zonkPat env p
 844         ; return (env', ParPat p') }
 845
 846 zonk_pat env (WildPat ty)
 847   = do  { ty' <- zonkTcTypeToType env ty
 848         ; return (env, WildPat ty') }
 849
 850 zonk_pat env (VarPat v)
 851   = do  { v' <- zonkIdBndr env v
 852         ; return (extendZonkEnv1 env v', VarPat v') }
 853
 854 zonk_pat env (LazyPat pat)
 855   = do  { (env', pat') <- zonkPat env pat
 856         ; return (env',  LazyPat pat') }
 857
 858 zonk_pat env (BangPat pat)
 859   = do  { (env', pat') <- zonkPat env pat
 860         ; return (env',  BangPat pat') }
 861
 862 zonk_pat env (AsPat (L loc v) pat)
 863   = do  { v' <- zonkIdBndr env v
 864         ; (env', pat') <- zonkPat (extendZonkEnv1 env v') pat
 865         ; return (env', AsPat (L loc v') pat') }
 866
 867 zonk_pat env (ViewPat expr pat ty)
 868   = do  { expr' <- zonkLExpr env expr
 869         ; (env', pat') <- zonkPat env pat
 870         ; ty' <- zonkTcTypeToType env ty
 871         ; return (env', ViewPat expr' pat' ty') }
 872
 873 zonk_pat env (ListPat pats ty)
 874   = do  { ty' <- zonkTcTypeToType env ty
 875         ; (env', pats') <- zonkPats env pats
 876         ; return (env', ListPat pats' ty') }
 877
 878 zonk_pat env (PArrPat pats ty)
 879   = do  { ty' <- zonkTcTypeToType env ty
 880         ; (env', pats') <- zonkPats env pats
 881         ; return (env', PArrPat pats' ty') }
 882
 883 zonk_pat env (TuplePat pats boxed ty)
 884   = do  { ty' <- zonkTcTypeToType env ty
 885         ; (env', pats') <- zonkPats env pats
 886         ; return (env', TuplePat pats' boxed ty') }
 887
 888 zonk_pat env p@(ConPatOut { pat_ty = ty, pat_dicts = evs, pat_binds = binds, pat_args = args })
 889   = ASSERT( all isImmutableTyVar (pat_tvs p) )
 890     do  { new_ty <- zonkTcTypeToType env ty
 891         ; (env1, new_evs) <- zonkEvBndrsX env evs
 892         ; (env2, new_binds) <- zonkTcEvBinds env1 binds
 893         ; (env', new_args) <- zonkConStuff env2 args
 894         ; returnM (env', p { pat_ty = new_ty, pat_dicts = new_evs,
 895                              pat_binds = new_binds, pat_args = new_args }) }
 896
 897 zonk_pat env (LitPat lit) = return (env, LitPat lit)
 898
 899 zonk_pat env (SigPatOut pat ty)
 900   = do  { ty' <- zonkTcTypeToType env ty
 901         ; (env', pat') <- zonkPat env pat
 902         ; return (env', SigPatOut pat' ty') }
 903
 904 zonk_pat env (NPat lit mb_neg eq_expr)
 905   = do  { lit' <- zonkOverLit env lit
 906         ; mb_neg' <- fmapMaybeM (zonkExpr env) mb_neg
 907         ; eq_expr' <- zonkExpr env eq_expr
 908         ; return (env, NPat lit' mb_neg' eq_expr') }
 909
 910 zonk_pat env (NPlusKPat (L loc n) lit e1 e2)
 911   = do  { n' <- zonkIdBndr env n
 912         ; lit' <- zonkOverLit env lit
 913         ; e1' <- zonkExpr env e1
 914         ; e2' <- zonkExpr env e2
 915         ; return (extendZonkEnv1 env n', NPlusKPat (L loc n') lit' e1' e2') }
 916
 917 zonk_pat env (CoPat co_fn pat ty)
 918   = do { (env', co_fn') <- zonkCoFn env co_fn
 919        ; (env'', pat') <- zonkPat env' (noLoc pat)
 920        ; ty' <- zonkTcTypeToType env'' ty
 921        ; return (env'', CoPat co_fn' (unLoc pat') ty') }
 922
 923 zonk_pat _ pat = pprPanic "zonk_pat" (ppr pat)
 924
 925 ---------------------------
 926 zonkConStuff :: ZonkEnv
 927              -> HsConDetails (OutPat TcId) (HsRecFields id (OutPat TcId))
 928              -> TcM (ZonkEnv,
 929                      HsConDetails (OutPat Id) (HsRecFields id (OutPat Id)))
 930 zonkConStuff env (PrefixCon pats)
 931   = do  { (env', pats') <- zonkPats env pats
 932         ; return (env', PrefixCon pats') }
 933
 934 zonkConStuff env (InfixCon p1 p2)
 935   = do  { (env1, p1') <- zonkPat env  p1
 936         ; (env', p2') <- zonkPat env1 p2
 937         ; return (env', InfixCon p1' p2') }
 938
 939 zonkConStuff env (RecCon (HsRecFields rpats dd))
 940   = do  { (env', pats') <- zonkPats env (map hsRecFieldArg rpats)
 941         ; let rpats' = zipWith (\rp p' -> rp { hsRecFieldArg = p' }) rpats pats'
 942         ; returnM (env', RecCon (HsRecFields rpats' dd)) }
 943         -- Field selectors have declared types; hence no zonking
 944
 945 ---------------------------
 946 zonkPats :: ZonkEnv -> [OutPat TcId] -> TcM (ZonkEnv, [OutPat Id])
 947 zonkPats env []         = return (env, [])
 948 zonkPats env (pat:pats) = do { (env1, pat') <- zonkPat env pat
 949                      ; (env', pats') <- zonkPats env1 pats
 950                      ; return (env', pat':pats') }
 951 \end{code}
 952
 953 %************************************************************************
 954 %*                                                                      *
 955 \subsection[BackSubst-Foreign]{Foreign exports}
 956 %*                                                                      *
 957 %************************************************************************
 958
 959
 960 \begin{code}
 961 zonkForeignExports :: ZonkEnv -> [LForeignDecl TcId] -> TcM [LForeignDecl Id]
 962 zonkForeignExports env ls = mappM (wrapLocM (zonkForeignExport env)) ls
 963
 964 zonkForeignExport :: ZonkEnv -> ForeignDecl TcId -> TcM (ForeignDecl Id)
 965 zonkForeignExport env (ForeignExport i _hs_ty spec) =
 966    returnM (ForeignExport (fmap (zonkIdOcc env) i) undefined spec)
 967 zonkForeignExport _ for_imp
 968   = returnM for_imp     -- Foreign imports don't need zonking
 969 \end{code}
 970
 971 \begin{code}
 972 zonkRules :: ZonkEnv -> [LRuleDecl TcId] -> TcM [LRuleDecl Id]
 973 zonkRules env rs = mappM (wrapLocM (zonkRule env)) rs
 974
 975 zonkRule :: ZonkEnv -> RuleDecl TcId -> TcM (RuleDecl Id)
 976 zonkRule env (HsRule name act (vars{-::[RuleBndr TcId]-}) lhs fv_lhs rhs fv_rhs)
 977   = do { (env_rhs, new_bndrs) <- mapAccumLM zonk_bndr env vars
 978
 979        ; unbound_tv_set <- newMutVar emptyVarSet
 980        ; let env_lhs = setZonkType env_rhs (zonkTypeCollecting unbound_tv_set)
 981         -- We need to gather the type variables mentioned on the LHS so we can
 982         -- quantify over them.  Example:
 983         --   data T a = C
 984         --
 985         --   foo :: T a -> Int
 986         --   foo C = 1
 987         --
 988         --   {-# RULES "myrule"  foo C = 1 #-}
 989         --
 990         -- After type checking the LHS becomes (foo a (C a))
 991         -- and we do not want to zap the unbound tyvar 'a' to (), because
 992         -- that limits the applicability of the rule.  Instead, we
 993         -- want to quantify over it!
 994         --
 995         -- It's easiest to find the free tyvars here. Attempts to do so earlier
 996         -- are tiresome, because (a) the data type is big and (b) finding the
 997         -- free type vars of an expression is necessarily monadic operation.
 998         --      (consider /\a -> f @ b, where b is side-effected to a)
 999
1000        ; new_lhs <- zonkLExpr env_lhs lhs
1001        ; new_rhs <- zonkLExpr env_rhs rhs
1002
1003        ; unbound_tvs <- readMutVar unbound_tv_set
1004        ; let final_bndrs :: [RuleBndr Var]
1005              final_bndrs = map (RuleBndr . noLoc) (varSetElems unbound_tvs) ++ new_bndrs
1006
1007        ; return (HsRule name act final_bndrs new_lhs fv_lhs new_rhs fv_rhs) }
1008   where
1009    zonk_bndr env (RuleBndr (L loc v))
1010       = do { (env', v') <- zonk_it env v; return (env', RuleBndr (L loc v')) }
1011    zonk_bndr _ (RuleBndrSig {}) = panic "zonk_bndr RuleBndrSig"
1012
1013    zonk_it env v
1014      | isId v     = do { v' <- zonkIdBndr env v; return (extendZonkEnv1 env v', v') }
1015      | isCoVar v  = do { v' <- zonkEvBndr env v; return (extendZonkEnv1 env v', v') }
1016      | otherwise  = ASSERT( isImmutableTyVar v) return (env, v)
1017 \end{code}
1018
1019
1020 %************************************************************************
1021 %*                                                                      *
1022               Constraints and evidence
1023 %*                                                                      *
1024 %************************************************************************
1025
1026 \begin{code}
1027 zonkEvTerm :: ZonkEnv -> EvTerm -> TcM EvTerm
1028 zonkEvTerm env (EvId v)           = ASSERT2( isId v, ppr v )
1029                                     return (EvId (zonkIdOcc env v))
1030 zonkEvTerm env (EvCoercion co)    = do { co' <- zonkTcTypeToType env co
1031                                        ; return (EvCoercion co') }
1032 zonkEvTerm env (EvCast v co)      = ASSERT( isId v)
1033                                     do { co' <- zonkTcTypeToType env co
1034                                        ; return (EvCast (zonkIdOcc env v) co') }
1035 zonkEvTerm env (EvSuperClass d n) = return (EvSuperClass (zonkIdOcc env d) n)
1036 zonkEvTerm env (EvDFunApp df tys tms _deps) -- Ignore the dependencies
1037   = do { tys' <- zonkTcTypeToTypes env tys
1038        ; let tms' = map (zonkEvVarOcc env) tms
1039        ; return (EvDFunApp (zonkIdOcc env df) tys' tms' _deps) }
1040
1041 zonkTcEvBinds :: ZonkEnv -> TcEvBinds -> TcM (ZonkEnv, TcEvBinds)
1042 zonkTcEvBinds env (TcEvBinds var) = do { (env', bs') <- zonkEvBindsVar env var
1043                                        ; return (env', EvBinds bs') }
1044 zonkTcEvBinds env (EvBinds bs)    = do { (env', bs') <- zonkEvBinds env bs
1045                                        ; return (env', EvBinds bs') }
1046
1047 zonkEvBindsVar :: ZonkEnv -> EvBindsVar -> TcM (ZonkEnv, Bag EvBind)
1048 zonkEvBindsVar env (EvBindsVar ref _) = do { bs <- readMutVar ref
1049                                            ; zonkEvBinds env (evBindMapBinds bs) }
1050
1051 zonkEvBinds :: ZonkEnv -> Bag EvBind -> TcM (ZonkEnv, Bag EvBind)
1052 zonkEvBinds env binds
1053   = fixM (\ ~( _, new_binds) -> do
1054          { let env1 = extendZonkEnv env (collect_ev_bndrs new_binds)
1055          ; binds' <- mapBagM (zonkEvBind env1) binds
1056          ; return (env1, binds') })
1057   where
1058     collect_ev_bndrs :: Bag EvBind -> [EvVar]
1059     collect_ev_bndrs = foldrBag add []
1060     add (EvBind var _) vars = var : vars
1061
1062 zonkEvBind :: ZonkEnv -> EvBind -> TcM EvBind
1063 zonkEvBind env (EvBind var term)
1064   = do { var' <- zonkEvBndr env var
1065        ; term' <- zonkEvTerm env term
1066        ; return (EvBind var' term') }
1067 \end{code}
1068
1069 %************************************************************************
1070 %*                                                                      *
1071                          Zonking types
1072 %*                                                                      *
1073 %************************************************************************
1074
1075 \begin{code}
1076 zonkTcTypeToType :: ZonkEnv -> TcType -> TcM Type
1077 zonkTcTypeToType (ZonkEnv zonk_ty _) ty = zonk_ty ty
1078
1079 zonkTcTypeToTypes :: ZonkEnv -> [TcType] -> TcM [Type]
1080 zonkTcTypeToTypes env tys = mapM (zonkTcTypeToType env) tys
1081
1082 zonkTypeCollecting :: TcRef TyVarSet -> TcType -> TcM Type
1083 -- This variant collects unbound type variables in a mutable variable
1084 zonkTypeCollecting unbound_tv_set
1085   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar)
1086   where
1087     zonk_unbound_tyvar tv
1088         = do { tv' <- zonkQuantifiedTyVar tv
1089              ; tv_set <- readMutVar unbound_tv_set
1090              ; writeMutVar unbound_tv_set (extendVarSet tv_set tv')
1091              ; return (mkTyVarTy tv') }
1092
1093 zonkTypeZapping :: TcType -> TcM Type
1094 -- This variant is used for everything except the LHS of rules
1095 -- It zaps unbound type variables to (), or some other arbitrary type
1096 zonkTypeZapping ty
1097   = zonkType (mkZonkTcTyVar zonk_unbound_tyvar) ty
1098   where
1099         -- Zonk a mutable but unbound type variable to an arbitrary type
1100         -- We know it's unbound even though we don't carry an environment,
1101         -- because at the binding site for a type variable we bind the
1102         -- mutable tyvar to a fresh immutable one.  So the mutable store
1103         -- plays the role of an environment.  If we come across a mutable
1104         -- type variable that isn't so bound, it must be completely free.
1105     zonk_unbound_tyvar tv = do { let ty = anyTypeOfKind (tyVarKind tv)
1106                                ; writeMetaTyVar tv ty
1107                                ; return ty }
1108 \end{code}